configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 m4_define([glib_major_version], [2])
  24 m4_define([glib_minor_version], [25])
  25 m4_define([glib_micro_version], [12])
  26 m4_define([glib_interface_age], [0])
  27 m4_define([glib_binary_age],
  28           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  29 m4_define([glib_version],
  30           [glib_major_version.glib_minor_version.glib_micro_version])
  31
  32 # libtool version related macros
  33 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  34 m4_define([glib_lt_current],
  35           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  36 m4_define([glib_lt_revision], [glib_interface_age])
  37 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  38 m4_define([glib_lt_current_minus_age],
  39           [m4_eval(glib_lt_current - glib_lt_age)])
  40
  41 # if the minor version number is odd, then we want debugging.  Otherwise
  42 # we only want minimal debugging support.
  43 m4_define([glib_debug_default],
  44           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  45
  46
  47 AC_INIT(glib, [glib_version],
  48         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  49
  50 AC_CONFIG_HEADER([config.h])
  51 AC_CONFIG_SRCDIR([glib/glib.h])
  52
  53 # Save this value here, since automake will set cflags later
  54 cflags_set=${CFLAGS+set}
  55
  56 AM_INIT_AUTOMAKE([1.10 no-define])
  57
  58 # Support silent build rules, requires at least automake-1.11. Enable
  59 # by either passing --enable-silent-rules to configure or passing V=0
  60 # to make
  61 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([no])])
  62
  63 GLIB_MAJOR_VERSION=glib_major_version
  64 GLIB_MINOR_VERSION=glib_minor_version
  65 GLIB_MICRO_VERSION=glib_micro_version
  66 GLIB_INTERFACE_AGE=glib_interface_age
  67 GLIB_BINARY_AGE=glib_binary_age
  68 GLIB_VERSION=glib_version
  69
  70 AC_SUBST(GLIB_MAJOR_VERSION)
  71 AC_SUBST(GLIB_MINOR_VERSION)
  72 AC_SUBST(GLIB_MICRO_VERSION)
  73 AC_SUBST(GLIB_VERSION)
  74 AC_SUBST(GLIB_INTERFACE_AGE)
  75 AC_SUBST(GLIB_BINARY_AGE)
  76
  77 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  78           [Define to the GLIB major version])
  79 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  80           [Define to the GLIB minor version])
  81 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  82           [Define to the GLIB micro version])
  83 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  84           [Define to the GLIB interface age])
  85 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  86           [Define to the GLIB binary age])
  87
  88 # libtool versioning
  89 LT_RELEASE=glib_lt_release
  90 LT_CURRENT=glib_lt_current
  91 LT_REVISION=glib_lt_revision
  92 LT_AGE=glib_lt_age
  93 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  94 AC_SUBST(LT_RELEASE)
  95 AC_SUBST(LT_CURRENT)
  96 AC_SUBST(LT_REVISION)
  97 AC_SUBST(LT_AGE)
  98 AC_SUBST(LT_CURRENT_MINUS_AGE)
  99
 100 dnl Initialize maintainer mode
 101 AM_MAINTAINER_MODE
 102
 103 AC_CANONICAL_HOST
 104
 105 AC_MSG_CHECKING([for the BeOS])
 106 case $host in
 107   *-*-beos*)
 108     glib_native_beos="yes"
 109     ;;
 110   *)
 111     glib_native_beos="no"
 112     ;;
 113 esac
 114 AC_MSG_RESULT([$glib_native_beos])
 115
 116 dnl
 117
 118 AC_MSG_CHECKING([for Win32])
 119 LIB_EXE_MACHINE_FLAG=X86
 120 case "$host" in
 121   *-*-mingw*)
 122     glib_native_win32=yes
 123     glib_pid_type='void *'
 124     glib_cv_stack_grows=no
 125     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 126     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 127     # (Sorry, I don't know exactly what is the problem, but it is related to
 128     # floating point formatting and decimal point vs. comma.)
 129     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 130     # rigorous enough to notice, though.
 131     # So preset the autoconf cache variables.
 132     ac_cv_func_vsnprintf_c99=no
 133     ac_cv_func_snprintf_c99=no
 134     case "$host" in
 135     x86_64-*-*)
 136       LIB_EXE_MACHINE_FLAG=X64
 137       ;;
 138     esac
 139     ;;
 140   *)
 141     glib_native_win32=no
 142     glib_pid_type=int
 143     ;;
 144 esac
 145 case $host in
 146   *-*-linux*)
 147     glib_os_linux=yes
 148     ;;
 149 esac
 150
 151 AC_MSG_RESULT([$glib_native_win32])
 152
 153 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 154
 155 glib_have_carbon=no
 156 AC_MSG_CHECKING([for Mac OS X Carbon support])
 157 AC_TRY_CPP([
 158 #include <Carbon/Carbon.h>
 159 #include <CoreServices/CoreServices.h>
 160 ], glib_have_carbon=yes)
 161
 162 AC_MSG_RESULT([$glib_have_carbon])
 163
 164 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 165 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 166 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 167 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 168 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 169
 170 if test "$glib_native_win32" = "yes"; then
 171   AC_CHECK_TOOL(WINDRES, windres, no)
 172   if test "$WINDRES" = no; then
 173     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 174   fi
 175   AC_CHECK_TOOL(NM, nm, no)
 176   if test "$NM" = no; then
 177     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 178   fi
 179   AC_CHECK_TOOL(RANLIB, ranlib, :)
 180   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 181 fi
 182 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 183
 184 if test "$glib_native_win32" != yes; then
 185     # libtool option to control which symbols are exported
 186     # right now, symbols starting with _ are not exported
 187     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 188 else
 189     # We currently use .def files on Windows
 190     LIBTOOL_EXPORT_OPTIONS=
 191 fi
 192 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 193
 194 if test "x$glib_have_carbon" = "xyes"; then
 195   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 196   LDFLAGS="$LDFLAGS -framework Carbon"
 197 fi
 198
 199
 200 dnl declare --enable-* args and collect ac_help strings
 201 AC_ARG_ENABLE(debug,
 202               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 203                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 204               enable_debug=glib_debug_default)
 205
 206 AC_ARG_ENABLE(gc_friendly,
 207               [AC_HELP_STRING([--enable-gc-friendly],
 208                               [turn on garbage collector friendliness [default=no]])],,
 209               [enable_gc_friendly=no])
 210 AC_ARG_ENABLE(mem_pools,
 211               [AC_HELP_STRING([--disable-mem-pools],
 212                               [disable all glib memory pools])],,
 213               [disable_mem_pools=no])
 214 AC_ARG_ENABLE(threads,
 215               [AC_HELP_STRING([--enable-threads],
 216                               [turn on basic thread support [default=yes]
 217 ([=no] will override --with-threads)])],,
 218               [enable_threads=yes])
 219 AC_ARG_ENABLE(rebuilds,
 220               [AC_HELP_STRING([--disable-rebuilds],
 221                               [disable all source autogeneration rules])],,
 222               [enable_rebuilds=yes])
 223 AC_ARG_ENABLE(visibility,
 224               [AC_HELP_STRING([--disable-visibility],
 225                               [don't use ELF visibility attributes])],,
 226               [enable_visibility=yes])
 227
 228 if test "x$enable_threads" != "xyes"; then
 229   enable_threads=no
 230 fi
 231
 232 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 233 if test "x$enable_gc_friendly" = "xyes"; then
 234   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 235   AC_MSG_RESULT([yes])
 236 else
 237   AC_MSG_RESULT([no])
 238 fi
 239
 240 AC_MSG_CHECKING([whether to disable memory pools])
 241 if test "x$disable_mem_pools" = "xno"; then
 242   AC_MSG_RESULT([no])
 243 else
 244   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 245   AC_SUBST(DISABLE_MEM_POOLS)
 246   AC_MSG_RESULT([yes])
 247 fi
 248
 249 dnl location to install runtime libraries, e.g. ../../lib to install
 250 dnl to /lib if libdir is /usr/lib
 251 AC_ARG_WITH(runtime-libdir,
 252            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 253                            [Install runtime libraries relative to libdir])],
 254            [],
 255            [with_runtime_libdir=""])
 256 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 257 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 258 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 259 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 260 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 261
 262 dnl Checks for programs.
 263 AC_PROG_CC
 264 AC_PROG_CPP
 265
 266 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 267 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 268 AC_LANG_SAVE
 269 AC_LANG_CPLUSPLUS
 270 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 271 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 272 AC_LANG_RESTORE
 273
 274 AM_PROG_CC_STDC
 275 AM_PROG_CC_C_O
 276 AC_PROG_INSTALL
 277
 278 AC_SYS_LARGEFILE
 279
 280 #
 281 # Find pkg-config
 282 #
 283 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 284 if test x$PKG_CONFIG = xno ; then
 285   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 286 fi
 287
 288 if $PKG_CONFIG --atleast-pkgconfig-version 0.16 ; then
 289   :
 290 else
 291   AC_MSG_ERROR([*** pkg-config too old; version 0.16 or better required.])
 292 fi
 293
 294 if test "x$enable_debug" = "xyes"; then
 295   if test x$cflags_set != xset ; then
 296       case " $CFLAGS " in
 297       *[[\ \    ]]-g[[\ \       ]]*) ;;
 298       *) CFLAGS="$CFLAGS -g" ;;
 299       esac
 300   fi
 301
 302   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 303 else
 304   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 305
 306   if test "x$enable_debug" = "xno"; then
 307     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 308   fi
 309 fi
 310
 311 if test "x$enable_visibility" = "xno"; then
 312   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 313 fi
 314
 315 # Ensure MSVC-compatible struct packing convention is used when
 316 # compiling for Win32 with gcc.
 317 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 318 # gcc2 uses "-fnative-struct".
 319 if test x"$glib_native_win32" = xyes; then
 320   if test x"$GCC" = xyes; then
 321     msnative_struct=''
 322     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 323     if test -z "$ac_cv_prog_CC"; then
 324       our_gcc="$CC"
 325     else
 326       our_gcc="$ac_cv_prog_CC"
 327     fi
 328     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 329       2.)
 330         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 331           msnative_struct='-fnative-struct'
 332         fi
 333         ;;
 334       *)
 335         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 336           msnative_struct='-mms-bitfields'
 337         fi
 338         ;;
 339     esac
 340     if test x"$msnative_struct" = x ; then
 341       AC_MSG_RESULT([no way])
 342       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 343     else
 344       CFLAGS="$CFLAGS $msnative_struct"
 345       AC_MSG_RESULT([${msnative_struct}])
 346     fi
 347   fi
 348 fi
 349 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 350 AC_SUBST(GLIB_EXTRA_CFLAGS)
 351
 352 AC_EXEEXT
 353
 354 # define a MAINT-like variable REBUILD which is set if Perl
 355 # and awk are found, so autogenerated sources can be rebuilt
 356 AC_PROG_AWK
 357 AC_CHECK_PROGS(PERL, [perl5 perl])
 358 # We would like indent, but don't require it.
 359 AC_CHECK_PROG(INDENT, indent, indent)
 360 REBUILD=\#
 361 if test "x$enable_rebuilds" = "xyes" && \
 362      test -n "$PERL" && \
 363      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 364      test -n "$AWK" ; then
 365   REBUILD=
 366 fi
 367 AC_SUBST(REBUILD)
 368
 369 # Need full path to Perl for glib-mkenums
 370 #
 371 if test "x$PERL" != x ; then
 372   AC_PATH_PROG(PERL_PATH, [$PERL])
 373 fi
 374 if test "x$PERL_PATH" = x ; then
 375   PERL_PATH="/usr/bin/env perl"
 376 fi
 377 AC_SUBST(PERL_PATH)
 378
 379 # Need suitable python path for greport
 380 AM_PATH_PYTHON(2.4,,PYTHON="/usr/bin/env python2.4")
 381
 382
 383 dnl ***********************
 384 dnl *** Tests for iconv ***
 385 dnl ***********************
 386 dnl
 387 dnl We do this before the gettext checks, to avoid distortion
 388
 389 dnl On Windows we use a native implementation
 390
 391 if test x"$glib_native_win32" = xyes; then
 392   with_libiconv=native
 393 else
 394   AC_ARG_WITH(libiconv,
 395               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 396                               [use the libiconv library])],,
 397               [with_libiconv=maybe])
 398
 399   found_iconv=no
 400   case $with_libiconv in
 401     maybe)
 402       # Check in the C library first
 403       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 404       # Check if we have GNU libiconv
 405       if test $found_iconv = "no"; then
 406         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 407       fi
 408       # Check if we have a iconv in -liconv, possibly from vendor
 409       if test $found_iconv = "no"; then
 410         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 411       fi
 412       ;;
 413     no)
 414       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 415       ;;
 416     gnu|yes)
 417       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 418       ;;
 419     native)
 420       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 421       ;;
 422   esac
 423
 424   if test "x$found_iconv" = "xno" ; then
 425      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 426   fi
 427 fi
 428
 429 gl_GLIBC21
 430 AC_ARG_ENABLE(iconv-cache,
 431               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 432                               [cache iconv descriptors [default=auto]])],,
 433               [enable_iconv_cache=auto])
 434
 435 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 436 case $enable_iconv_cache in
 437   auto)
 438     if test $ac_cv_gnu_library_2_1 = yes; then
 439       enable_iconv_cache=no
 440     else
 441       enable_iconv_cache=yes
 442     fi
 443   ;;
 444   yes|no)
 445   ;;
 446   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 447   ;;
 448 esac
 449
 450 if test $enable_iconv_cache = yes; then
 451    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 452 fi
 453
 454 AC_MSG_RESULT($enable_iconv_cache)
 455
 456
 457 dnl
 458 dnl zlib support
 459 dnl
 460 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 461 if test "x$found_zlib" = "xno" ; then
 462   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 463   if test "x$found_zlib" = "xno" ; then
 464     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 465   fi
 466   ZLIB_LIBS='-lz'
 467   AC_SUBST(ZLIB_LIBS)
 468 fi
 469
 470 dnl
 471 dnl gettext support
 472 dnl
 473
 474 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 475 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 476 GLIB_GNU_GETTEXT
 477
 478 if test "$gt_cv_have_gettext" != "yes" ; then
 479   AC_MSG_ERROR([
 480 *** You must have either have gettext support in your C library, or use the
 481 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 482 ])
 483 fi
 484
 485 LIBS="$INTLLIBS $LIBS"
 486
 487 GETTEXT_PACKAGE=glib20
 488 AC_SUBST(GETTEXT_PACKAGE)
 489 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 490   [Define the gettext package to be used])
 491
 492 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 493
 494 dnl
 495 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 496 dnl
 497
 498 if test x"$glib_native_win32" != xyes; then
 499   if test x$with_libiconv != xno ; then
 500     case " $INTLLIBS " in
 501     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 502     *) ICONV_LIBS="-liconv" ;;
 503     esac
 504   fi
 505 fi
 506 AC_SUBST(ICONV_LIBS)
 507
 508 case $with_libiconv in
 509   gnu)
 510     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 511     ;;
 512   native)
 513     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 514     ;;
 515 esac
 516
 517 dnl Initialize libtool
 518 LT_PREREQ([2.2])
 519 LT_INIT([disable-static win32-dll])
 520 dnl when using libtool 2.x create libtool early, because it's used in configure
 521 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 522
 523
 524 if test "x$GCC" = "xyes"; then
 525   case " $CFLAGS " in
 526   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 527   *) CFLAGS="$CFLAGS -Wall" ;;
 528   esac
 529 fi
 530
 531 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 532
 533 if test "$glib_native_win32" = "yes"; then
 534   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 535     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 536   fi
 537   if test x$enable_static = xyes; then
 538     glib_win32_static_compilation=yes
 539     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 540 #define GOBJECT_STATIC_COMPILATION 1"
 541     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 542   fi
 543 fi
 544 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 545
 546 dnl
 547 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 548 dnl
 549 if test $cross_compiling != yes ; then
 550     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 551     glib_save_LIBS=$LIBS
 552     LIBS="$LIBS -lm"
 553     AC_TRY_RUN([#include <math.h>
 554                  int main (void) { return (log(1) != log(1.)); }],
 555          AC_MSG_RESULT(none needed),
 556          glib_save_CFLAGS=$CFLAGS
 557          CFLAGS="$CFLAGS -std1"
 558          AC_TRY_RUN([#include <math.h>
 559                      int main (void) { return (log(1) != log(1.)); }],
 560              AC_MSG_RESULT(-std1),
 561              AC_MSG_RESULT()
 562              CFLAGS=$glib_save_CFLAGS
 563              AC_MSG_WARN(
 564                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 565          )
 566     )
 567     LIBS=$glib_save_LIBS
 568 fi
 569
 570 dnl NeXTStep cc seems to need this
 571 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 572 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 573   AC_MSG_RESULT(none needed),
 574   glib_save_CFLAGS=$CFLAGS
 575   CFLAGS="$CFLAGS -posix"
 576   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 577     AC_MSG_RESULT(-posix),
 578     AC_MSG_RESULT()
 579     CFLAGS=$glib_save_CFLAGS
 580     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 581
 582 # Checks for header files.
 583 AC_HEADER_STDC
 584
 585 # Checks for library functions.
 586 AC_FUNC_VPRINTF
 587 AC_FUNC_ALLOCA
 588 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 589 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 590
 591 AC_CHECK_SIZEOF(char)
 592 AC_CHECK_SIZEOF(short)
 593 AC_CHECK_SIZEOF(long)
 594 AC_CHECK_SIZEOF(int)
 595 AC_CHECK_SIZEOF(void *)
 596 AC_CHECK_SIZEOF(long long)
 597 AC_CHECK_SIZEOF(__int64)
 598
 599 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 600   :
 601 else
 602   AC_MSG_ERROR([
 603 *** GLib requires a 64 bit type. You might want to consider
 604 *** using the GNU C compiler.
 605 ])
 606 fi
 607
 608 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 609         # long long is a 64 bit integer.
 610         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 611         AC_CACHE_VAL(glib_cv_long_long_format,[
 612                 for format in ll q I64; do
 613                   AC_TRY_RUN([#include <stdio.h>
 614                         int main()
 615                         {
 616                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 617                           char buffer[1000];
 618                           sprintf (buffer, "%${format}u", a);
 619                           sscanf (buffer, "%${format}u", &b);
 620                           exit (b!=a);
 621                         }
 622                         ],
 623                         [glib_cv_long_long_format=${format}
 624                         break],
 625                         [],[:])
 626                 done])
 627         if test -n "$glib_cv_long_long_format"; then
 628           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 629           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 630           if test x"$glib_cv_long_long_format" = xI64; then
 631             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 632           fi
 633         else
 634           AC_MSG_RESULT(none)
 635         fi
 636 elif test x$ac_cv_sizeof___int64 = x8; then
 637         # __int64 is a 64 bit integer.
 638         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 639         # We know this is MSVCRT.DLL, and what the formats are
 640         glib_cv_long_long_format=I64
 641         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 642         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 643         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 644 fi
 645
 646 dnl long doubles were not used, and a portability problem
 647 dnl AC_C_LONG_DOUBLE
 648 AC_C_CONST
 649
 650 dnl ok, here we try to check whether the systems prototypes for
 651 dnl malloc and friends actually match the prototypes provided
 652 dnl by gmem.h (keep in sync). i currently only know how to check
 653 dnl this reliably with gcc (-Werror), improvements for other
 654 dnl compilers are apprechiated.
 655 SANE_MALLOC_PROTOS=no
 656 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 657 glib_save_CFLAGS=$CFLAGS
 658 if test "x$GCC" = "xyes"; then
 659   CFLAGS="$CFLAGS -Werror"
 660   AC_TRY_COMPILE([#include <stdlib.h>], [
 661     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 662     void* (*my_malloc_p)  (size_t)         = malloc;
 663     void  (*my_free_p)    (void*)          = free;
 664     void* (*my_realloc_p) (void*, size_t)  = realloc;
 665     my_calloc_p = 0;
 666     my_malloc_p = 0;
 667     my_free_p = 0;
 668     my_realloc_p = 0;
 669   ],
 670     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 671       [Define if you have correct malloc prototypes])
 672     SANE_MALLOC_PROTOS=yes)
 673 fi
 674 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 675 CFLAGS=$glib_save_CFLAGS
 676
 677 dnl
 678 dnl check in which direction the stack grows
 679 dnl
 680 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 681         AC_TRY_RUN([
 682         volatile int *a = 0, *b = 0;
 683         void foo (void);
 684         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 685         void foo (void) { volatile int x = 5; b = &x; }
 686         ],
 687         glib_cv_stack_grows=no
 688         ,
 689         glib_cv_stack_grows=yes
 690         ,)
 691 ])
 692
 693 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 694 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 695 dnl actually supported.
 696 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 697         AC_COMPILE_IFELSE([
 698         __inline int foo () { return 0; }
 699         int main () { return foo (); }
 700         ],
 701         glib_cv_has__inline=yes
 702         ,
 703         glib_cv_has__inline=no
 704         ,)
 705 ])
 706 case x$glib_cv_has__inline in
 707 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 708 esac
 709 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 710         AC_COMPILE_IFELSE([
 711         __inline__ int foo () { return 0; }
 712         int main () { return foo (); }
 713         ],
 714         glib_cv_has__inline__=yes
 715         ,
 716         glib_cv_has__inline__=no
 717         ,)
 718 ])
 719 case x$glib_cv_has__inline__ in
 720 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 721 esac
 722 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 723         AC_COMPILE_IFELSE([
 724         #undef inline
 725         inline int foo () { return 0; }
 726         int main () { return foo (); }
 727         ],
 728         glib_cv_hasinline=yes
 729         ,
 730         glib_cv_hasinline=no
 731         ,)
 732 ])
 733 case x$glib_cv_hasinline in
 734 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 735 esac
 736
 737 # if we can use inline functions in headers
 738 AC_MSG_CHECKING(if inline functions in headers work)
 739 AC_LINK_IFELSE([
 740 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 741 #  undef inline
 742 #  define inline __inline__
 743 #elif !defined (G_HAVE_INLINE)
 744 #  undef inline
 745 #  if defined (G_HAVE___INLINE__)
 746 #    define inline __inline__
 747 #  elif defined (G_HAVE___INLINE)
 748 #    define inline __inline
 749 #  endif
 750 #endif
 751
 752 int glib_test_func2 (int);
 753
 754 static inline int
 755 glib_test_func1 (void) {
 756   return glib_test_func2 (1);
 757 }
 758
 759 int
 760 main (void) {
 761   int i = 1;
 762 }],[g_can_inline=yes],[g_can_inline=no])
 763 AC_MSG_RESULT($g_can_inline)
 764
 765 dnl *** check for working do while(0) macros ***
 766 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 767         AC_TRY_COMPILE([],[
 768         #define STMT_START do
 769         #define STMT_END while(0)
 770         #define STMT_TEST STMT_START { i = 0; } STMT_END
 771         int main(void) { int i = 1; STMT_TEST; return i; }],
 772         [g_cv_support_dowhile_macros=yes],
 773         [g_cv_support_dowhile_macros=no],
 774         [g_cv_support_dowhile_macros=yes])
 775 ])
 776 if test x$g_cv_support_dowhile_macros = xyes; then
 777   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 778 fi
 779
 780 # check for flavours of varargs macros
 781 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 782 AC_TRY_COMPILE([],[
 783 int a(int p1, int p2, int p3);
 784 #define call_a(...) a(1,__VA_ARGS__)
 785 call_a(2,3);
 786 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 787 AC_MSG_RESULT($g_have_iso_c_varargs)
 788
 789 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 790 if test "$CXX" = ""; then
 791 dnl No C++ compiler
 792   g_have_iso_cxx_varargs=no
 793 else
 794   AC_LANG_CPLUSPLUS
 795   AC_TRY_COMPILE([],[
 796 int a(int p1, int p2, int p3);
 797 #define call_a(...) a(1,__VA_ARGS__)
 798 call_a(2,3);
 799 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 800   AC_LANG_C
 801 fi
 802 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 803
 804 AC_MSG_CHECKING(for GNUC varargs macros)
 805 AC_TRY_COMPILE([],[
 806 int a(int p1, int p2, int p3);
 807 #define call_a(params...) a(1,params)
 808 call_a(2,3);
 809 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 810 AC_MSG_RESULT($g_have_gnuc_varargs)
 811
 812 # check for GNUC visibility support
 813 AC_MSG_CHECKING(for GNUC visibility attribute)
 814 GLIB_CHECK_COMPILE_WARNINGS([
 815 void
 816 __attribute__ ((visibility ("hidden")))
 817      f_hidden (void)
 818 {
 819 }
 820 void
 821 __attribute__ ((visibility ("internal")))
 822      f_internal (void)
 823 {
 824 }
 825 void
 826 __attribute__ ((visibility ("protected")))
 827      f_protected (void)
 828 {
 829 }
 830 void
 831 __attribute__ ((visibility ("default")))
 832      f_default (void)
 833 {
 834 }
 835 int main (int argc, char **argv)
 836 {
 837         f_hidden();
 838         f_internal();
 839         f_protected();
 840         f_default();
 841         return 0;
 842 }
 843 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 844 AC_MSG_RESULT($g_have_gnuc_visibility)
 845 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 846
 847 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 848 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 849 #else
 850 # include "error: this is not Sun Studio."
 851 #endif
 852 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 853 AC_MSG_RESULT($g_have_sunstudio_visibility)
 854 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 855
 856 # check for bytesex stuff
 857 AC_C_BIGENDIAN
 858 if test x$ac_cv_c_bigendian = xuniversal ; then
 859 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 860 #else
 861 #error Not a big endian.
 862 #endif],
 863     ac_cv_c_bigendian=yes
 864     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 865 #else
 866 #error Not a little endian.
 867 #endif],
 868     ac_cv_c_bigendian=no
 869     ,AC_MSG_WARN([Could not determine endianness.])))
 870 fi
 871
 872
 873 # check for header files
 874 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 875 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 876 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 877 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 878 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 879 AC_CHECK_HEADERS([sys/uio.h])
 880
 881 # check for structure fields
 882 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 883 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 884 #include <sys/stat.h>
 885 #include <unistd.h>
 886 #ifdef HAVE_SYS_STATFS_H
 887 #include <sys/statfs.h>
 888 #endif
 889 #ifdef HAVE_SYS_PARAM_H
 890 #include <sys/param.h>
 891 #endif
 892 #ifdef HAVE_SYS_MOUNT_H
 893 #include <sys/mount.h>
 894 #endif])
 895 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 896 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 897
 898 # Checks for libcharset
 899 AM_LANGINFO_CODESET
 900 gl_GLIBC21
 901 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 902 AC_CHECK_FUNCS(setlocale)
 903
 904 # check additional type sizes
 905 AC_CHECK_SIZEOF(size_t)
 906
 907 dnl Try to figure out whether gsize, gssize should be long or int
 908 AC_MSG_CHECKING([for the appropriate definition for size_t])
 909
 910 case $ac_cv_sizeof_size_t in
 911   $ac_cv_sizeof_short)
 912       glib_size_type=short
 913       ;;
 914   $ac_cv_sizeof_int)
 915       glib_size_type=int
 916       ;;
 917   $ac_cv_sizeof_long)
 918       glib_size_type=long
 919       ;;
 920   $ac_cv_sizeof_long_long)
 921       glib_size_type='long long'
 922       ;;
 923   $ac_cv_sizeof__int64)
 924       glib_size_type='__int64'
 925       ;;
 926   *)  AC_MSG_ERROR([No type matching size_t in size])
 927       ;;
 928 esac
 929
 930 dnl If int/long are the same size, we see which one produces
 931 dnl warnings when used in the location as size_t. (This matters
 932 dnl on AIX with xlc)
 933 dnl
 934 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 935    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 936   GLIB_CHECK_COMPILE_WARNINGS([
 937 #if defined(_AIX) && !defined(__GNUC__)
 938 #pragma options langlvl=stdc89
 939 #endif
 940 #include <stddef.h>
 941 int main ()
 942 {
 943   size_t s = 1;
 944   unsigned int *size_int = &s;
 945   return (int)*size_int;
 946 }
 947     ],glib_size_type=int,
 948       [GLIB_CHECK_COMPILE_WARNINGS([
 949 #if defined(_AIX) && !defined(__GNUC__)
 950 #pragma options langlvl=stdc89
 951 #endif
 952 #include <stddef.h>
 953 int main ()
 954 {
 955    size_t s = 1;
 956    unsigned long *size_long = &s;
 957    return (int)*size_long;
 958 }
 959         ],glib_size_type=long)])
 960 fi
 961
 962 AC_MSG_RESULT(unsigned $glib_size_type)
 963
 964 # Check for some functions
 965 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 966 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link statvfs statfs utimes getgrgid getpwuid)
 967 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
 968 # Check for high-resolution sleep functions
 969 AC_CHECK_FUNCS(nanosleep nsleep)
 970 AC_CHECK_FUNCS(splice)
 971
 972 AC_CHECK_HEADERS(crt_externs.h)
 973 AC_CHECK_FUNCS(_NSGetEnviron)
 974
 975 AC_FUNC_VSNPRINTF_C99
 976 AC_FUNC_PRINTF_UNIX98
 977
 978 # Internet address families
 979 if test $glib_native_win32 = yes; then
 980   glib_inet_includes=["
 981 #include <winsock2.h>
 982   "]
 983 else
 984   glib_inet_includes=["
 985 #include <sys/types.h>
 986 #include <sys/socket.h>
 987   "]
 988 fi
 989
 990 glib_failed=false
 991 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
 992 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
 993 # winsock defines this even though it doesn't support it
 994 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
 995 if $glib_failed ; then
 996   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
 997 fi
 998
 999 glib_failed=false
1000 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1001 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1002 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1003 if $glib_failed ; then
1004   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1005 fi
1006
1007 AC_CHECK_FUNCS(getprotobyname_r endservent)
1008 AC_CHECK_HEADERS([netdb.h wspiapi.h])
1009
1010 # For gio/libasyncns
1011 if test $glib_native_win32 = no; then
1012   AC_CHECK_FUNCS(strndup setresuid setreuid)
1013   AC_CHECK_HEADERS(sys/prctl.h arpa/nameser_compat.h)
1014
1015   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1016   AC_MSG_CHECKING([for res_query])
1017   AC_TRY_LINK([#include <sys/types.h>
1018 #include <netinet/in.h>
1019 #include <arpa/nameser.h>
1020 #include <resolv.h>],
1021               [res_query("test", 0, 0, (void *)0, 0);],
1022               [AC_MSG_RESULT([yes])],
1023               [save_libs="$LIBS"
1024                LIBS="-lresolv $LIBS"
1025                AC_TRY_LINK([#include <sys/types.h>
1026 #include <netinet/in.h>
1027 #include <arpa/nameser.h>
1028 #include <resolv.h>],
1029                            [res_query("test", 0, 0, (void *)0, 0);],
1030                            [AC_MSG_RESULT([in -lresolv])
1031                             LIBASYNCNS_LIBADD="-lresolv"],
1032                            [LIBS="-lbind $save_libs"
1033                             AC_TRY_LINK([#include <resolv.h>],
1034                                         [res_query("test", 0, 0, (void *)0, 0);],
1035                                         [AC_MSG_RESULT([in -lbind])
1036                                          LIBASYNCNS_LIBADD="-lbind"],
1037                                         [AC_MSG_ERROR(not found)])])
1038                LIBS="$save_libs"])
1039   AC_SUBST(LIBASYNCNS_LIBADD)
1040 fi
1041
1042 case $host in
1043   *-*-solaris* )
1044      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1045      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1046      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1047      ;;
1048 esac
1049
1050 dnl
1051 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1052 dnl
1053 if test "$ac_cv_func_statfs" = yes ; then
1054   AC_MSG_CHECKING([number of arguments to statfs()])
1055   AC_TRY_COMPILE([#include <unistd.h>
1056   #ifdef HAVE_SYS_PARAM_H
1057   #include <sys/param.h>
1058   #endif
1059   #ifdef HAVE_SYS_VFS_H
1060   #include <sys/vfs.h>
1061   #endif
1062   #ifdef HAVE_SYS_MOUNT_H
1063   #include <sys/mount.h>
1064   #endif
1065   #ifdef HAVE_SYS_STATFS_H
1066   #include <sys/statfs.h>
1067   #endif], [struct statfs st;
1068   statfs(NULL, &st);],[
1069     AC_MSG_RESULT([2])
1070     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1071     AC_TRY_COMPILE([#include <unistd.h>
1072   #ifdef HAVE_SYS_PARAM_H
1073   #include <sys/param.h>
1074   #endif
1075   #ifdef HAVE_SYS_VFS_H
1076   #include <sys/vfs.h>
1077   #endif
1078   #ifdef HAVE_SYS_MOUNT_H
1079   #include <sys/mount.h>
1080   #endif
1081   #ifdef HAVE_SYS_STATFS_H
1082   #include <sys/statfs.h>
1083   #endif], [struct statfs st;
1084   statfs(NULL, &st, sizeof (st), 0);],[
1085       AC_MSG_RESULT([4])
1086       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1087       AC_MSG_RESULT(unknown)
1088       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1089 fi
1090
1091 #
1092 # Check whether to use an included printf
1093 #
1094
1095 AC_ARG_ENABLE(included-printf,
1096               [AC_HELP_STRING([--enable-included-printf],
1097                               [use included printf [default=auto]])],
1098               enable_included_printf="$enableval")
1099
1100 need_included_printf=no
1101 if test "x$enable_included_printf" = "xyes" ; then
1102   need_included_printf=yes
1103 fi
1104 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1105   need_included_printf=yes
1106 fi
1107 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1108   need_included_printf=yes
1109 fi
1110 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1111    test -z "$glib_cv_long_long_format" ; then
1112   need_included_printf=yes
1113 fi
1114
1115 if test "x$enable_included_printf" = "xno" &&
1116    test "x$need_included_printf" = "xyes" ; then
1117   AC_MSG_ERROR([
1118 *** Your C library's printf doesn't appear to have the features that
1119 *** GLib needs, but you specified --enable-included-printf=no.])
1120 fi
1121
1122 enable_included_printf=$need_included_printf
1123
1124 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1125 if test "$enable_included_printf" != "yes" ; then
1126   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1127 else
1128   if test -z "$glib_cv_long_long_format" ; then
1129     glib_cv_long_long_format="ll"
1130   fi
1131   AC_DEFINE(HAVE_VASPRINTF,1)
1132 fi
1133
1134 # Checks needed for gnulib vasnprintf
1135 bh_C_SIGNED
1136 jm_AC_TYPE_LONG_LONG
1137 gt_TYPE_LONGDOUBLE
1138 gt_TYPE_WCHAR_T
1139 gt_TYPE_WINT_T
1140 AC_TYPE_SIZE_T
1141 AC_CHECK_TYPES(ptrdiff_t)
1142 jm_AC_TYPE_INTMAX_T
1143 AC_CHECK_FUNCS([snprintf wcslen])
1144 AC_FUNC_SNPRINTF_C99
1145
1146 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1147 # The check is borrowed from the PERL Configure script.
1148 if test "$ac_cv_func_memmove" != "yes"; then
1149   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1150     glib_cv_working_bcopy,[AC_TRY_RUN([
1151       int main() {
1152         char buf[128], abc[128], *b;
1153         int len, off, align;
1154         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1155         for (align = 7; align >= 0; align--) {
1156           for (len = 36; len; len--) {
1157             b = buf+align; bcopy(abc, b, len);
1158             for (off = 1; off <= len; off++) {
1159               bcopy(b, b+off, len); bcopy(b+off, b, len);
1160                 if (bcmp(b, abc, len)) return(1);
1161             }
1162           }
1163         }
1164         return(0);
1165       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1166
1167   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1168   if test "$glib_cv_working_bcopy" = "yes"; then
1169     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1170   fi
1171 fi
1172
1173 # Check for sys_errlist
1174 AC_MSG_CHECKING(for sys_errlist)
1175 AC_TRY_LINK(, [
1176 extern char *sys_errlist[];
1177 extern int sys_nerr;
1178 sys_errlist[sys_nerr-1][0] = 0;
1179 ], glib_ok=yes, glib_ok=no)
1180 AC_MSG_RESULT($glib_ok)
1181 if test "$glib_ok" = "no"; then
1182     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1183 fi
1184
1185 # Check for sys_siglist
1186 AC_MSG_CHECKING(for sys_siglist)
1187 AC_TRY_LINK(, [
1188 extern char *sys_siglist[];
1189 exit (sys_siglist[0]);
1190 ], glib_ok=yes, glib_ok=no)
1191 AC_MSG_RESULT($glib_ok)
1192 if test "$glib_ok" = "no"; then
1193     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1194 fi
1195
1196 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1197 AC_MSG_CHECKING(for sys_siglist declaration)
1198 AC_TRY_COMPILE([#include <signal.h>], [
1199 strlen (sys_siglist[0]);
1200 ], glib_ok=yes, glib_ok=no)
1201 AC_MSG_RESULT($glib_ok)
1202 if test "$glib_ok" = "no"; then
1203     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1204 fi
1205
1206 # Check if <sys/select.h> needs to be included for fd_set
1207 AC_MSG_CHECKING([for fd_set])
1208 AC_TRY_COMPILE([#include <sys/types.h>],
1209         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1210 if test "$gtk_ok" = "yes"; then
1211     AC_MSG_RESULT([yes, found in sys/types.h])
1212 else
1213     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1214     if test "$gtk_ok" = "yes"; then
1215         # *** FIXME: give it a different name
1216         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1217         AC_MSG_RESULT([yes, found in sys/select.h])
1218     else
1219         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1220         AC_MSG_RESULT(no)
1221     fi
1222 fi
1223
1224 dnl *** check for sane realloc() ***
1225 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1226         AC_TRY_RUN([#include <stdlib.h>
1227         int main() {
1228           return realloc (0, sizeof (int)) == 0;
1229         }],
1230         [glib_cv_sane_realloc=yes],
1231         [glib_cv_sane_realloc=no],
1232         [glib_cv_sane_realloc=yes])
1233 ])
1234 if test x$glib_cv_sane_realloc = xyes; then
1235   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1236 fi
1237
1238 dnl Check for nl_langinfo and CODESET
1239 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1240         AC_TRY_COMPILE([#include <langinfo.h>],
1241                 [char *codeset = nl_langinfo (CODESET);],
1242                 [glib_cv_langinfo_codeset=yes],
1243                 [glib_cv_langinfo_codeset=no])])
1244 if test x$glib_cv_langinfo_codeset = xyes; then
1245   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1246 fi
1247
1248 dnl ****************************************
1249 dnl *** posix_memalign                   ***
1250 dnl ****************************************
1251 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1252 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1253     glib_cv_compliant_posix_memalign=0
1254     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1255         AC_TRY_RUN([
1256                 #define _XOPEN_SOURCE 600
1257                 #include <stdlib.h> /* posix_memalign() should be defined here */
1258                 /* some systems break if #include <malloc.h> used */
1259                 static void test_memalign (size_t boundary, size_t size) {
1260                     void *mem = 0;
1261                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1262                         exit (1);
1263                     else
1264                       free (mem);
1265                 }
1266                 int main() {
1267                     test_memalign (  128,   128 - 2 * sizeof (void*));
1268                     test_memalign (  256,   256 - 2 * sizeof (void*));
1269                     test_memalign (  512,   512 - 2 * sizeof (void*));
1270                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1271                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1272                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1273                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1274                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1275                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1276                     exit (0); /* success */
1277                 }
1278                 ],
1279             [glib_cv_compliant_posix_memalign=1], [], [:])
1280       :
1281     fi
1282     ])
1283 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1284     AC_MSG_RESULT(yes)
1285     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1286 else
1287     AC_MSG_RESULT(no)
1288 fi
1289
1290
1291 dnl ****************************************
1292 dnl *** strlcpy/strlcat                  ***
1293 dnl ****************************************
1294 # Check for strlcpy
1295 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1296 AC_TRY_RUN([#include <stdlib.h>
1297 #include <string.h>
1298 int main() {
1299   char p[10];
1300   (void) strlcpy (p, "hi", 10);
1301   if (strlcat (p, "bye", 0) != 3)
1302     return 1;
1303   return 0;
1304 }], glib_cv_have_strlcpy=yes,
1305     glib_cv_have_strlcpy=no,
1306     glib_cv_have_strlcpy=no)])
1307 if test "$glib_cv_have_strlcpy" = "yes"; then
1308     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1309 fi
1310
1311
1312 dnl **********************
1313 dnl *** va_copy checks ***
1314 dnl **********************
1315 dnl we currently check for all three va_copy possibilities, so we get
1316 dnl all results in config.log for bug reports.
1317 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1318         AC_LINK_IFELSE([#include <stdarg.h>
1319 #include <stdlib.h>
1320         void f (int i, ...) {
1321         va_list args1, args2;
1322         va_start (args1, i);
1323         va_copy (args2, args1);
1324         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1325           exit (1);
1326         va_end (args1); va_end (args2);
1327         }
1328         int main() {
1329           f (0, 42);
1330           return 0;
1331         }],
1332         [glib_cv_va_copy=yes],
1333         [glib_cv_va_copy=no])
1334 ])
1335 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1336         AC_LINK_IFELSE([#include <stdarg.h>
1337 #include <stdlib.h>
1338         void f (int i, ...) {
1339         va_list args1, args2;
1340         va_start (args1, i);
1341         __va_copy (args2, args1);
1342         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1343           exit (1);
1344         va_end (args1); va_end (args2);
1345         }
1346         int main() {
1347           f (0, 42);
1348           return 0;
1349         }],
1350         [glib_cv___va_copy=yes],
1351         [glib_cv___va_copy=no])
1352 ])
1353
1354 if test "x$glib_cv_va_copy" = "xyes"; then
1355   g_va_copy_func=va_copy
1356 else if test "x$glib_cv___va_copy" = "xyes"; then
1357   g_va_copy_func=__va_copy
1358 fi
1359 fi
1360
1361 if test -n "$g_va_copy_func"; then
1362   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1363 fi
1364
1365 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1366         AC_TRY_RUN([#include <stdarg.h>
1367 #include <stdlib.h>
1368         void f (int i, ...) {
1369         va_list args1, args2;
1370         va_start (args1, i);
1371         args2 = args1;
1372         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1373           exit (1);
1374         va_end (args1); va_end (args2);
1375         }
1376         int main() {
1377           f (0, 42);
1378           return 0;
1379         }],
1380         [glib_cv_va_val_copy=yes],
1381         [glib_cv_va_val_copy=no],
1382         [glib_cv_va_val_copy=yes])
1383 ])
1384
1385 if test "x$glib_cv_va_val_copy" = "xno"; then
1386   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1387 fi
1388
1389 dnl ***********************
1390 dnl *** g_module checks ***
1391 dnl ***********************
1392 G_MODULE_LIBS=
1393 G_MODULE_LIBS_EXTRA=
1394 G_MODULE_PLUGIN_LIBS=
1395 if test x"$glib_native_win32" = xyes; then
1396   dnl No use for this on Win32
1397   G_MODULE_LDFLAGS=
1398 else
1399   export SED
1400   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1401 fi
1402 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1403 G_MODULE_NEED_USCORE=0
1404 G_MODULE_BROKEN_RTLD_GLOBAL=0
1405 G_MODULE_HAVE_DLERROR=0
1406 dnl *** force native WIN32 shared lib loader
1407 if test -z "$G_MODULE_IMPL"; then
1408   case "$host" in
1409   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1410   esac
1411 fi
1412 dnl *** force native AIX library loader
1413 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1414 if test -z "$G_MODULE_IMPL"; then
1415   case "$host" in
1416   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1417   esac
1418 fi
1419 dnl *** dlopen() and dlsym() in system libraries
1420 if test -z "$G_MODULE_IMPL"; then
1421         AC_CHECK_FUNC(dlopen,
1422                       [AC_CHECK_FUNC(dlsym,
1423                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1424                       [])
1425 fi
1426 dnl *** load_image (BeOS)
1427 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1428   AC_CHECK_LIB(root, load_image,
1429       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1430       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1431       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1432       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1433       [])
1434 fi
1435 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1436 if test -z "$G_MODULE_IMPL"; then
1437         AC_CHECK_FUNC(NSLinkModule,
1438                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1439                        G_MODULE_NEED_USCORE=1],
1440                       [])
1441 fi
1442 dnl *** dlopen() and dlsym() in libdl
1443 if test -z "$G_MODULE_IMPL"; then
1444         AC_CHECK_LIB(dl, dlopen,
1445                      [AC_CHECK_LIB(dl, dlsym,
1446                                    [G_MODULE_LIBS=-ldl
1447                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1448                      [])
1449 fi
1450 dnl *** shl_load() in libdld (HP-UX)
1451 if test -z "$G_MODULE_IMPL"; then
1452         AC_CHECK_LIB(dld, shl_load,
1453                 [G_MODULE_LIBS=-ldld
1454                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1455                 [])
1456 fi
1457 dnl *** additional checks for G_MODULE_IMPL_DL
1458 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1459         LIBS_orig="$LIBS"
1460         LDFLAGS_orig="$LDFLAGS"
1461         LIBS="$G_MODULE_LIBS $LIBS"
1462         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1463 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1464         echo "void glib_plugin_test(void) { }" > plugin.c
1465         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1466                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1467         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1468                 glib_cv_rtldglobal_broken,[
1469                 AC_TRY_RUN([
1470 #include <dlfcn.h>
1471 #ifndef RTLD_GLOBAL
1472 #  define RTLD_GLOBAL 0
1473 #endif
1474 #ifndef RTLD_LAZY
1475 #  define RTLD_LAZY 0
1476 #endif
1477 int glib_plugin_test;
1478 int main () {
1479     void *handle, *global, *local;
1480     global = &glib_plugin_test;
1481     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1482     if (!handle) return 0;
1483     local = dlsym (handle, "glib_plugin_test");
1484     return global == local;
1485 }                       ],
1486                         [glib_cv_rtldglobal_broken=no],
1487                         [glib_cv_rtldglobal_broken=yes],
1488                         [glib_cv_rtldglobal_broken=no])
1489                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1490                 rmdir .libs 2>/dev/null
1491         ])
1492         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1493                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1494         else
1495                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1496         fi
1497 dnl *** check whether we need preceeding underscores
1498         AC_CACHE_CHECK([for preceeding underscore in symbols],
1499                 glib_cv_uscore,[
1500                 AC_TRY_RUN([#include <dlfcn.h>
1501                 int glib_underscore_test (void) { return 42; }
1502                 int main() {
1503                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1504                   handle = dlopen ((void*)0, 0);
1505                   if (handle) {
1506                     f1 = dlsym (handle, "glib_underscore_test");
1507                     f2 = dlsym (handle, "_glib_underscore_test");
1508                   } return (!f2 || f1);
1509                 }],
1510                         [glib_cv_uscore=yes],
1511                         [glib_cv_uscore=no],
1512                         [])
1513                 rm -f plugin.c plugin.$ac_objext plugin.lo
1514         ])
1515         GLIB_ASSERT_SET(glib_cv_uscore)
1516         if test "x$glib_cv_uscore" = "xyes"; then
1517                 G_MODULE_NEED_USCORE=1
1518         else
1519                 G_MODULE_NEED_USCORE=0
1520         fi
1521
1522         LDFLAGS="$LDFLAGS_orig"
1523 dnl *** check for having dlerror()
1524         AC_CHECK_FUNC(dlerror,
1525                 [G_MODULE_HAVE_DLERROR=1],
1526                 [G_MODULE_HAVE_DLERROR=0])
1527         LIBS="$LIBS_orig"
1528 fi
1529 dnl *** done, have we got an implementation?
1530 if test -z "$G_MODULE_IMPL"; then
1531         G_MODULE_IMPL=0
1532         G_MODULE_SUPPORTED=false
1533 else
1534         G_MODULE_SUPPORTED=true
1535 fi
1536
1537 AC_MSG_CHECKING(for the suffix of module shared libraries)
1538 export SED
1539 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1540 eval $shrext_cmds
1541 module=yes eval std_shrext=$shrext_cmds
1542 # chop the initial dot
1543 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1544 AC_MSG_RESULT(.$glib_gmodule_suffix)
1545 # any reason it may fail?
1546 if test "x$glib_gmodule_suffix" = x; then
1547         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1548 fi
1549
1550 AC_SUBST(G_MODULE_SUPPORTED)
1551 AC_SUBST(G_MODULE_IMPL)
1552 AC_SUBST(G_MODULE_LIBS)
1553 AC_SUBST(G_MODULE_LIBS_EXTRA)
1554 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1555 AC_SUBST(G_MODULE_LDFLAGS)
1556 AC_SUBST(G_MODULE_HAVE_DLERROR)
1557 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1558 AC_SUBST(G_MODULE_NEED_USCORE)
1559 AC_SUBST(GLIB_DEBUG_FLAGS)
1560
1561 dnl **********************
1562 dnl *** g_spawn checks ***
1563 dnl **********************
1564
1565 AC_MSG_CHECKING(for gspawn implementation)
1566 case "$host" in
1567   *-*-mingw*)
1568     GSPAWN=gspawn-win32.lo
1569     ;;
1570   *)
1571     GSPAWN=gspawn.lo
1572     ;;
1573 esac
1574 AC_MSG_RESULT($GSPAWN)
1575 AC_SUBST(GSPAWN)
1576
1577 dnl *************************
1578 dnl *** GIOChannel checks ***
1579 dnl *************************
1580
1581 AC_MSG_CHECKING(for GIOChannel implementation)
1582 case "$host" in
1583   *-*-mingw*)
1584     GIO=giowin32.lo
1585     ;;
1586   *)
1587     GIO=giounix.lo
1588     ;;
1589 esac
1590 AC_MSG_RESULT($GIO)
1591 AC_SUBST(GIO)
1592
1593 dnl *********************************
1594 dnl *** Directory for GIO modules ***
1595 dnl *********************************
1596
1597 AC_ARG_WITH(gio-module-dir,
1598            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1599                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1600            [],
1601            [with_gio_module_dir='${libdir}/gio/modules'])
1602 GIO_MODULE_DIR=$with_gio_module_dir
1603 AC_SUBST(GIO_MODULE_DIR)
1604
1605 dnl **********************************
1606 dnl *** Check for libselinux (GIO) ***
1607 dnl **********************************
1608 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1609 msg_selinux=no
1610 SELINUX_LIBS=
1611 if test "x$enable_selinux" != "xno"; then
1612
1613  AC_CHECK_LIB(selinux, is_selinux_enabled,
1614    [AC_CHECK_HEADERS(selinux/selinux.h,
1615      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1616        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1617         SELINUX_LIBS="-lselinux"
1618         msg_selinux=yes])
1619      ])
1620    ])
1621 fi
1622 AC_SUBST(SELINUX_LIBS)
1623
1624 dnl *****************************
1625 dnl ** Check for inotify (GIO) **
1626 dnl *****************************
1627 inotify_support=no
1628 AC_CHECK_HEADERS([sys/inotify.h],
1629 [
1630         inotify_support=yes
1631         AC_CHECK_FUNCS(inotify_init1)
1632 ])
1633
1634 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1635
1636 dnl *********************************
1637 dnl ** Check for Solaris FEN (GIO) **
1638 dnl *********************************
1639 fen_support=no
1640 AC_COMPILE_IFELSE([
1641 #include <port.h>
1642 #ifndef PORT_SOURCE_FILE
1643 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1644 #endif
1645 int main() { return 0; } ],
1646 [
1647         fen_support=yes
1648 ],)
1649
1650 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1651
1652 dnl ****************************
1653 dnl *** Checks for FAM (GIO) ***
1654 dnl ****************************
1655
1656 should_disable_fam=no
1657
1658 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1659                          [
1660                                 if test "x$enable_fam" = "xno"; then
1661                                         should_disable_fam=yes
1662                                         echo "Not building FAM support"
1663                                 fi
1664                          ]
1665                          )
1666 fam_support=no
1667 FAM_LIBS=
1668 if test "x$should_disable_fam" = "xno"; then
1669 AC_CHECK_LIB(fam, FAMOpen,
1670   [AC_CHECK_HEADERS(fam.h,
1671     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1672      AC_CHECK_LIB(fam, FAMNoExists,
1673                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1674      FAM_LIBS="-lfam"]
1675      fam_support=yes,
1676     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1677   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1678 AC_SUBST(FAM_LIBS)
1679 fi
1680 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1681
1682
1683 dnl *****************************
1684 dnl *** Check for xattr (GIO) ***
1685 dnl *****************************
1686 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1687 msg_xattr=no
1688 XATTR_LIBS=
1689 if test "x$enable_xattr" != "xno"; then
1690
1691 dnl either glibc or libattr can provide xattr support
1692
1693 dnl for both of them, we check for getxattr being in
1694 dnl the library and a valid xattr header.
1695
1696 dnl try glibc
1697  AC_CHECK_LIB(c, getxattr,
1698    [AC_CHECK_HEADERS(sys/xattr.h,
1699      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1700       msg_xattr=yes])
1701    ])
1702
1703   if test "x$msg_xattr" != "xyes"; then
1704 dnl   failure. try libattr
1705    AC_CHECK_LIB(attr, getxattr,
1706       [AC_CHECK_HEADERS(attr/xattr.h,
1707        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1708         XATTR_LIBS="-lattr"
1709         msg_xattr=yes])
1710       ])
1711   fi
1712
1713   if test "x$msg_xattr" = "xyes"; then
1714     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1715     AC_TRY_COMPILE([
1716       #include <stdio.h>
1717       #ifdef HAVE_SYS_TYPES_H
1718       #include <sys/types.h>
1719       #endif
1720       #ifdef HAVE_SYS_XATTR_H
1721       #include <sys/xattr.h>
1722       #elif HAVE_ATTR_XATTR_H
1723       #include <attr/xattr.h>
1724       #endif
1725     ],
1726     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1727     [
1728       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1729       AC_MSG_RESULT([yes])
1730     ],
1731     [AC_MSG_RESULT([no])]
1732     )
1733   fi
1734
1735 fi
1736 AC_SUBST(XATTR_LIBS)
1737
1738 dnl ****************************************
1739 dnl *** platform dependent source checks ***
1740 dnl ****************************************
1741
1742 AC_MSG_CHECKING(for platform-dependent source)
1743 case "$host" in
1744   *-*-cygwin*|*-*-mingw*)
1745     PLATFORMDEP=gwin32.lo
1746     ;;
1747   *)
1748     PLATFORMDEP=
1749     ;;
1750 esac
1751 AC_MSG_RESULT($PLATFORMDEP)
1752 AC_SUBST(PLATFORMDEP)
1753
1754 AC_MSG_CHECKING([whether to compile timeloop])
1755 case "$host" in
1756   *-*-cygwin*|*-*-mingw*|*-*-minix)
1757     enable_timeloop=no
1758     ;;
1759   *)
1760     enable_timeloop=yes
1761     ;;
1762 esac
1763 AC_MSG_RESULT($enable_timeloop)
1764 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1765
1766 AC_MSG_CHECKING([if building for some Win32 platform])
1767 case "$host" in
1768   *-*-mingw*|*-*-cygwin*)
1769     platform_win32=yes
1770     ;;
1771   *)
1772     platform_win32=no
1773     ;;
1774 esac
1775 AC_MSG_RESULT($platform_win32)
1776 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1777
1778 dnl ***********************
1779 dnl *** g_thread checks ***
1780 dnl ***********************
1781
1782 AC_ARG_WITH(threads,
1783            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1784                            [specify a thread implementation to use])],
1785            [if test "x$with_threads" = x; then
1786                 want_threads=yes
1787             else
1788                 want_threads=$with_threads
1789             fi],
1790            [want_threads=yes])
1791 if test "x$enable_threads" = "xno"; then
1792         want_threads=no
1793 fi
1794
1795 dnl error and warning message
1796 dnl *************************
1797
1798 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1799                 computer. GLib will not have a default thread implementation."
1800
1801 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1802                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1803                 compilation now, but then your programs might not work.
1804                 Please provide information on how it is done on your system."
1805
1806 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1807                 "
1808
1809 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1810                 provide information on your thread implementation.
1811                 You can also run 'configure --disable-threads'
1812                 to compile without thread support."
1813
1814 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1815                 functions will not be MT-safe during their first call because
1816                 there is no working 'getpwuid_r' on your system."
1817
1818 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1819                 because there is no 'localtime_r' on your system."
1820
1821 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1822                 crude surrogate will be used. If you happen to know a
1823                 yield function for your system, please inform the GLib
1824                 developers."
1825
1826 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1827                 threads on your system. Thus threads can only have the default
1828                 priority. If you happen to know these main/max
1829                 priorities, please inform the GLib developers."
1830
1831 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1832                 linking threaded applications. As GLib cannot do that
1833                 automatically, you will get an linkg error everytime you are
1834                 not using the right compiler. In that case you have to relink
1835                 with the right compiler. Ususally just '_r' is appended
1836                 to the compiler name."
1837
1838 dnl determination of thread implementation
1839 dnl ***************************************
1840
1841 # have_threads=no   means no thread support
1842 # have_threads=none means no default thread implementation
1843
1844 have_threads=no
1845 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1846                                 || test "x$want_threads" = xdce; then
1847         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1848         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1849         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1850         glib_save_CPPFLAGS="$CPPFLAGS"
1851         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1852         if test "x$have_threads" = xno; then
1853                 AC_TRY_COMPILE([#include <pthread.h>],
1854                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1855                         have_threads=posix)
1856         fi
1857         if test "x$have_threads" = xno; then
1858                 AC_TRY_COMPILE([#include <pthread.h>],
1859                         [pthread_mutex_t m;
1860                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1861                         have_threads=dce)
1862         fi
1863         # Tru64Unix requires -pthread to find pthread.h. See #103020
1864         CPPFLAGS="$CPPFLAGS -pthread"
1865         if test "x$have_threads" = xno; then
1866         AC_TRY_COMPILE([#include <pthread.h>],
1867                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1868                        have_threads=posix)
1869         fi
1870         CPPFLAGS="$glib_save_CPPFLAGS"
1871 fi
1872 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1873         case $host in
1874                 *-*-mingw*)
1875                 have_threads=win32
1876                 ;;
1877         esac
1878 fi
1879 if test "x$want_threads" = xnone; then
1880         have_threads=none
1881 fi
1882
1883 AC_MSG_CHECKING(for thread implementation)
1884
1885 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1886         AC_MSG_RESULT(none available)
1887         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1888 else
1889         AC_MSG_RESULT($have_threads)
1890 fi
1891
1892
1893 dnl determination of G_THREAD_CFLAGS
1894 dnl ********************************
1895
1896 G_THREAD_LIBS=
1897 G_THREAD_LIBS_EXTRA=
1898 G_THREAD_CFLAGS=
1899
1900 dnl
1901 dnl Test program for basic POSIX threads functionality
1902 dnl
1903 m4_define([glib_thread_test],[
1904 #include <pthread.h>
1905 int check_me = 0;
1906 void* func(void* data) {check_me = 42; return &check_me;}
1907 int main()
1908  { pthread_t t;
1909    void *ret;
1910    pthread_create (&t, $1, func, 0);
1911    pthread_join (t, &ret);
1912    return (check_me != 42 || ret != &check_me);
1913 }])
1914
1915 dnl
1916 dnl Test program for sched_get_priority_min()
1917 dnl
1918 m4_define([glib_sched_priority_test],[
1919 #include <sched.h>
1920 #include <errno.h>
1921 int main() {
1922     errno = 0;
1923     return sched_get_priority_min(SCHED_OTHER)==-1
1924            && errno != 0;
1925 }])
1926
1927 if test x"$have_threads" != xno; then
1928
1929   if test x"$have_threads" = xposix; then
1930     # First we test for posix, whether -pthread or -pthreads do the trick as
1931     # both CPPFLAG and LIBS.
1932     # One of them does for most gcc versions and some other platforms/compilers
1933     # too and could be considered as the canonical way to go.
1934     case $host in
1935       *-*-cygwin*|*-*-darwin*)
1936          # skip cygwin and darwin -pthread or -pthreads test
1937          ;;
1938       *-solaris*)
1939         # These compiler/linker flags work with both Sun Studio and gcc
1940         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1941         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1942         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1943         G_THREAD_LIBS="-lpthread -lthread"
1944         ;;
1945       *)
1946         for flag in pthread pthreads mt; do
1947           glib_save_CFLAGS="$CFLAGS"
1948           CFLAGS="$CFLAGS -$flag"
1949           AC_TRY_RUN(glib_thread_test(0),
1950                      glib_flag_works=yes,
1951                      glib_flag_works=no,
1952                      [AC_LINK_IFELSE(glib_thread_test(0),
1953                                      glib_flag_works=yes,
1954                                      glib_flag_works=no)])
1955           CFLAGS="$glib_save_CFLAGS"
1956           if test $glib_flag_works = yes ; then
1957              G_THREAD_CFLAGS=-$flag
1958              G_THREAD_LIBS=-$flag
1959              break;
1960           fi
1961         done
1962          ;;
1963     esac
1964   fi
1965
1966   if test x"$G_THREAD_CFLAGS" = x; then
1967
1968     # The canonical -pthread[s] does not work. Try something different.
1969
1970     case $host in
1971         *-aix*)
1972                 if test x"$GCC" = xyes; then
1973                         # GCC 3.0 and above needs -pthread.
1974                         # Should be coverd by the case above.
1975                         # GCC 2.x and below needs -mthreads
1976                         G_THREAD_CFLAGS="-mthreads"
1977                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1978                 else
1979                         # We are probably using the aix compiler. Normaly a
1980                         # program would have to be compiled with the _r variant
1981                         # of the corresponding compiler, but we as GLib cannot
1982                         # do that: but the good news is that for compiling the
1983                         # only difference is the added -D_THREAD_SAFE compile
1984                         # option. This is according to the "C for AIX User's
1985                         # Guide".
1986                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1987                 fi
1988                 ;;
1989         *-dg-dgux*)  # DG/UX
1990                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1991                 ;;
1992         *-osf*)
1993                 # So we are using dce threads. posix threads are already
1994                 # catched above.
1995                 G_THREAD_CFLAGS="-threads"
1996                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1997                 ;;
1998         *-sysv5uw7*) # UnixWare 7
1999                 # We are not using gcc with -pthread. Catched above.
2000                 G_THREAD_CFLAGS="-Kthread"
2001                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2002                 ;;
2003         *-mingw*)
2004                 # No flag needed when using MSVCRT.DLL
2005                 G_THREAD_CFLAGS=""
2006                 ;;
2007         *)
2008                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2009                 ;;
2010     esac
2011
2012   fi
2013
2014     # if we are not finding the localtime_r function, then we probably are
2015     # not using the proper multithread flag
2016
2017     glib_save_CPPFLAGS="$CPPFLAGS"
2018     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2019
2020     # First we test, whether localtime_r is declared in time.h
2021     # directly. Then we test whether a macro localtime_r exists, in
2022     # which case localtime_r in the test program is replaced and thus
2023     # if we still find localtime_r in the output, it is not defined as
2024     # a macro.
2025
2026     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2027       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2028                                                            localtime_r(a,b)],
2029                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2030
2031     CPPFLAGS="$glib_save_CPPFLAGS"
2032
2033     AC_MSG_CHECKING(thread related cflags)
2034     AC_MSG_RESULT($G_THREAD_CFLAGS)
2035     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2036 fi
2037
2038 dnl determination of G_THREAD_LIBS
2039 dnl ******************************
2040
2041 mutex_has_default=no
2042 case $have_threads in
2043         posix|dce)
2044           glib_save_CPPFLAGS="$CPPFLAGS"
2045           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2046           if test x"$G_THREAD_LIBS" = x; then
2047             case $host in
2048               *-aix*)
2049                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2050                 # probably using the aix compiler.
2051                 AC_MSG_WARN($AIX_COMPILE_INFO)
2052                 ;;
2053               *)
2054                 G_THREAD_LIBS=error
2055                 glib_save_LIBS="$LIBS"
2056                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2057                         if test x"$thread_lib" = x; then
2058                                 add_thread_lib=""
2059                                 IN=""
2060                         else
2061                                 add_thread_lib="-l$thread_lib"
2062                                 IN=" in -l$thread_lib"
2063                         fi
2064                         if test x"$have_threads" = xposix; then
2065                                 defattr=0
2066                         else
2067                                 defattr=pthread_attr_default
2068                         fi
2069
2070                         LIBS="$add_thread_lib $glib_save_LIBS"
2071
2072                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2073                         AC_TRY_RUN(glib_thread_test($defattr),
2074                                    glib_result=yes,
2075                                    glib_result=no,
2076                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
2077                                                    glib_result=yes,
2078                                                    glib_result=no)])
2079                         AC_MSG_RESULT($glib_result)
2080
2081                         if test "$glib_result" = "yes" ; then
2082                           G_THREAD_LIBS="$add_thread_lib"
2083                           break
2084                         fi
2085                 done
2086                 if test "x$G_THREAD_LIBS" = xerror; then
2087                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2088                 fi
2089                 LIBS="$glib_save_LIBS"
2090                 ;;
2091             esac
2092           fi
2093
2094           glib_save_LIBS="$LIBS"
2095           for thread_lib in "" rt rte; do
2096             if test x"$thread_lib" = x; then
2097               add_thread_lib=""
2098               IN=""
2099             else
2100               add_thread_lib="-l$thread_lib"
2101               IN=" in -l$thread_lib"
2102             fi
2103             LIBS="$add_thread_lib $glib_save_LIBS"
2104
2105             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2106             AC_TRY_RUN(glib_sched_priority_test,
2107                        glib_result=yes,
2108                        glib_result=no,
2109                        [AC_LINK_IFELSE(glib_sched_priority_test,
2110                                        glib_result=yes,
2111                                        glib_result=no)])
2112             AC_MSG_RESULT($glib_result)
2113
2114             if test "$glib_result" = "yes" ; then
2115                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2116                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2117                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2118                break
2119             fi
2120           done
2121           LIBS="$glib_save_LIBS"
2122           mutex_has_default=yes
2123           mutex_default_type='pthread_mutex_t'
2124           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2125           mutex_header_file='pthread.h'
2126           if test "x$have_threads" = "xposix"; then
2127             g_threads_impl="POSIX"
2128           else
2129             g_threads_impl="DCE"
2130             have_threads="posix"
2131           fi
2132           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2133           CPPFLAGS="$glib_save_CPPFLAGS"
2134           ;;
2135         win32)
2136            g_threads_impl="WIN32"
2137            ;;
2138         none|no)
2139            g_threads_impl="NONE"
2140            ;;
2141         *)
2142            g_threads_impl="NONE"
2143            G_THREAD_LIBS=error
2144            ;;
2145 esac
2146
2147 if test "x$G_THREAD_LIBS" = xerror; then
2148         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2149 fi
2150
2151 case $host in
2152   *-*-beos*)
2153     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2154     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2155     ;;
2156   *)
2157     ;;
2158 esac
2159
2160 AC_MSG_CHECKING(thread related libraries)
2161 AC_MSG_RESULT($G_THREAD_LIBS)
2162
2163 dnl check for mt safe function variants and some posix functions
2164 dnl ************************************************************
2165
2166 if test x"$have_threads" != xno; then
2167         glib_save_LIBS="$LIBS"
2168         # we are not doing the following for now, as this might require glib
2169         # to always be linked with the thread libs on some platforms.
2170         # LIBS="$LIBS $G_THREAD_LIBS"
2171         AC_CHECK_FUNCS(localtime_r gmtime_r)
2172         if test "$ac_cv_header_pwd_h" = "yes"; then
2173                 AC_CACHE_CHECK([for posix getpwuid_r],
2174                         ac_cv_func_posix_getpwuid_r,
2175                         [AC_TRY_RUN([
2176 #include <errno.h>
2177 #include <pwd.h>
2178 int main () {
2179     char buffer[10000];
2180     struct passwd pwd, *pwptr = &pwd;
2181     int error;
2182     errno = 0;
2183     error = getpwuid_r (0, &pwd, buffer,
2184                         sizeof (buffer), &pwptr);
2185    return (error < 0 && errno == ENOSYS)
2186            || error == ENOSYS;
2187 }                               ],
2188                                 [ac_cv_func_posix_getpwuid_r=yes],
2189                                 [ac_cv_func_posix_getpwuid_r=no])])
2190                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2191                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2192                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2193                                 [Have POSIX function getpwuid_r])
2194                 else
2195                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2196                                 ac_cv_func_nonposix_getpwuid_r,
2197                                 [AC_TRY_LINK([#include <pwd.h>],
2198                                         [char buffer[10000];
2199                                         struct passwd pwd;
2200                                         getpwuid_r (0, &pwd, buffer,
2201                                                         sizeof (buffer));],
2202                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2203                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2204                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2205                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2206                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2207                                         [Have non-POSIX function getpwuid_r])
2208                         fi
2209                 fi
2210         fi
2211         if test "$ac_cv_header_grp_h" = "yes"; then
2212                 AC_CACHE_CHECK([for posix getgrgid_r],
2213                         ac_cv_func_posix_getgrgid_r,
2214                         [AC_TRY_RUN([
2215 #include <errno.h>
2216 #include <grp.h>
2217 int main () {
2218     char buffer[10000];
2219     struct group grp, *grpptr = &grp;
2220     int error;
2221     errno = 0;
2222     error = getgrgid_r (0, &grp, buffer,
2223                         sizeof (buffer), &grpptr);
2224    return (error < 0 && errno == ENOSYS)
2225            || error == ENOSYS;
2226 }                              ],
2227                                [ac_cv_func_posix_getgrgid_r=yes],
2228                                [ac_cv_func_posix_getgrgid_r=no])])
2229                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2230                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2231                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2232                                 [Have POSIX function getgrgid_r])
2233                 else
2234                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2235                                 ac_cv_func_nonposix_getgrgid_r,
2236                                 [AC_TRY_LINK([#include <grp.h>],
2237                                         [char buffer[10000];
2238                                         struct group grp;
2239                                         getgrgid_r (0, &grp, buffer,
2240                                         sizeof (buffer));],
2241                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2242                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2243                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2244                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2245                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2246                                         [Have non-POSIX function getgrgid_r])
2247                         fi
2248                 fi
2249         fi
2250         LIBS="$G_THREAD_LIBS $LIBS"
2251         if test x"$have_threads" = xposix; then
2252                 glib_save_CPPFLAGS="$CPPFLAGS"
2253                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2254                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2255                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2256                 # This is not AC_CHECK_FUNC to also work with function
2257                 # name mangling in header files.
2258                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2259                 AC_TRY_LINK([#include <pthread.h>],
2260                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2261                         [AC_MSG_RESULT(yes)
2262                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2263                                   [Have function pthread_attr_setstacksize])],
2264                         [AC_MSG_RESULT(no)])
2265                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2266                 if test x"$posix_priority_min" = x; then
2267                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2268                                 PX_PRIO_MIN],,[
2269                                 posix_priority_min=PX_PRIO_MIN
2270                                 posix_priority_max=PX_PRIO_MAX])
2271                 fi
2272                 if test x"$posix_priority_min" = x; then
2273                         # AIX
2274                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2275                                 PTHREAD_PRIO_MIN],,[
2276                                 posix_priority_min=PTHREAD_PRIO_MIN
2277                                 posix_priority_max=PTHREAD_PRIO_MAX])
2278                 fi
2279                 if test x"$posix_priority_min" = x; then
2280                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2281                                 PRI_OTHER_MIN],,[
2282                                 posix_priority_min=PRI_OTHER_MIN
2283                                 posix_priority_max=PRI_OTHER_MAX])
2284                 fi
2285                 if test x"$posix_priority_min" = x; then
2286                         AC_MSG_RESULT(none found)
2287                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2288                         posix_priority_min=-1
2289                         posix_priority_max=-1
2290                 else
2291                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2292                         AC_MSG_CHECKING(for pthread_setschedparam)
2293                         AC_TRY_LINK([#include <pthread.h>],
2294                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2295                           [AC_MSG_RESULT(yes)
2296                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2297                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2298                           [AC_MSG_RESULT(no)
2299                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2300                 fi
2301                 posix_yield_func=none
2302                 AC_MSG_CHECKING(for posix yield function)
2303                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2304                                                         thr_yield; do
2305                         AC_TRY_LINK([#include <pthread.h>],
2306                                 [$yield_func()],
2307                                 [posix_yield_func="$yield_func"
2308                                 break])
2309                 done
2310                 if test x"$posix_yield_func" = xnone; then
2311                         AC_MSG_RESULT(none found)
2312                         AC_MSG_WARN($POSIX_NO_YIELD)
2313                         posix_yield_func="g_usleep(1000)"
2314                 else
2315                         AC_MSG_RESULT($posix_yield_func)
2316                         posix_yield_func="$posix_yield_func()"
2317                 fi
2318                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2319                 CPPFLAGS="$glib_save_CPPFLAGS"
2320
2321         elif test x"$have_threads" = xwin32; then
2322                 # It's a pointer to a private struct
2323                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2324         fi
2325
2326         LIBS="$glib_save_LIBS"
2327
2328         # now spit out all the warnings.
2329         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2330            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2331                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2332         fi
2333         if test "$ac_cv_func_localtime_r" != "yes"; then
2334                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2335         fi
2336 fi
2337
2338 if test x"$glib_cv_sizeof_system_thread" = x; then
2339    # use a pointer as a fallback.
2340    GLIB_SIZEOF(,void *, system_thread)
2341 fi
2342
2343 #
2344 # Hack to deal with:
2345 #
2346 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2347 #     building shared libraries with linux.
2348 #  b) FreeBSD doesn't do this either.
2349 #
2350 case $host in
2351   *-*-freebsd*|*-*-linux*)
2352     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2353     ;;
2354   *)
2355     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2356     ;;
2357 esac
2358
2359 AM_CONDITIONAL(HAVE_THREADS, [test "$have_threads" != "none"])
2360 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2361                    [Source file containing theread implementation])
2362 AC_SUBST(G_THREAD_CFLAGS)
2363 AC_SUBST(G_THREAD_LIBS)
2364 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2365 AC_SUBST(G_THREAD_LIBS_EXTRA)
2366
2367 dnl **********************************************
2368 dnl *** GDefaultMutex setup and initialization ***
2369 dnl **********************************************
2370 dnl
2371 dnl if mutex_has_default = yes, we also got
2372 dnl mutex_default_type, mutex_default_init and mutex_header_file
2373 if test $mutex_has_default = yes ; then
2374         glib_save_CPPFLAGS="$CPPFLAGS"
2375         glib_save_LIBS="$LIBS"
2376         LIBS="$G_THREAD_LIBS $LIBS"
2377         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2378         GLIB_SIZEOF([#include <$mutex_header_file>],
2379                     $mutex_default_type,
2380                     gmutex)
2381         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2382                            $mutex_default_type,
2383                            gmutex,
2384                            $glib_cv_sizeof_gmutex,
2385                            $mutex_default_init)
2386         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2387                 mutex_has_default=no
2388         fi
2389         CPPFLAGS="$glib_save_CPPFLAGS"
2390         LIBS="$glib_save_LIBS"
2391 fi
2392
2393 AC_CHECK_FUNCS(clock_gettime, [], [
2394   AC_CHECK_LIB(rt, clock_gettime, [
2395     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2396     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2397     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2398   ])
2399 ])
2400
2401 AC_CACHE_CHECK(for monotonic clocks,
2402     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2403 #include <time.h>
2404 #include <unistd.h>
2405 int main() {
2406 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2407         #error No monotonic clock
2408 #endif
2409         return 0;
2410 }
2411 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2412 if test "$glib_cv_monotonic_clock" = "yes"; then
2413   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2414 fi
2415
2416
2417 dnl ********************************
2418 dnl *** g_atomic_* tests for gcc ***
2419 dnl ********************************
2420
2421 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2422
2423 glib_cv_gcc_has_builtin_atomic_operations=no
2424 if test x"$GCC" = xyes; then
2425   AC_MSG_CHECKING([whether GCC supports build-in atomic intrinsics])
2426   AC_TRY_LINK([],
2427               [int i;
2428                __sync_synchronize ();
2429                __sync_bool_compare_and_swap (&i, 0, 1);
2430                __sync_fetch_and_add (&i, 1);
2431               ],
2432               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2433               [glib_cv_gcc_has_builtin_atomic_operations=no])
2434
2435   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2436   if test $glib_cv_gcc_has_builtin_atomic_operations = yes; then
2437     glib_memory_barrier_needed=yes
2438   else
2439     case $host_cpu in
2440       i386)
2441         AC_MSG_RESULT([none])
2442         glib_memory_barrier_needed=no
2443         ;;
2444       i?86)
2445         AC_MSG_RESULT([i486])
2446         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2447                            [i486 atomic implementation])
2448         glib_memory_barrier_needed=no
2449         ;;
2450       sparc*)
2451         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2452                          when you are using a sparc with v9 instruction set (most
2453                          sparcs nowadays). This will make the code for atomic
2454                          operations much faster. The resulting code will not run
2455                          on very old sparcs though."
2456
2457         AC_LINK_IFELSE([[
2458           main ()
2459           {
2460             int tmp1, tmp2, tmp3;
2461             __asm__ __volatile__("casx [%2], %0, %1"
2462                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2463           }]],
2464           AC_MSG_RESULT([sparcv9])
2465           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2466                              [sparcv9 atomic implementation]),
2467           AC_MSG_RESULT([no])
2468           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2469         glib_memory_barrier_needed=yes
2470         ;;
2471       alpha*)
2472         AC_MSG_RESULT([alpha])
2473         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2474                            [alpha atomic implementation])
2475         glib_memory_barrier_needed=yes
2476         ;;
2477       x86_64)
2478         AC_MSG_RESULT([x86_64])
2479         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2480                            [x86_64 atomic implementation])
2481         glib_memory_barrier_needed=no
2482        ;;
2483       powerpc*)
2484         AC_MSG_RESULT([powerpc])
2485         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2486                            [powerpc atomic implementation])
2487         glib_memory_barrier_needed=yes
2488         AC_MSG_CHECKING([whether asm supports numbered local labels])
2489         AC_TRY_COMPILE(
2490                        ,[
2491                        __asm__ __volatile__ ("1:       nop\n"
2492                                "         bne-    1b")
2493                        ],[
2494                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2495                        AC_MSG_RESULT([yes])
2496                        ],[
2497                        AC_MSG_RESULT([no])
2498                        ])
2499         ;;
2500       ia64)
2501         AC_MSG_RESULT([ia64])
2502         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2503                            [ia64 atomic implementation])
2504         glib_memory_barrier_needed=yes
2505         ;;
2506       s390|s390x)
2507         AC_MSG_RESULT([s390])
2508         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2509                            [s390 atomic implementation])
2510         glib_memory_barrier_needed=no
2511         ;;
2512       arm*)
2513         AC_MSG_RESULT([arm])
2514         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2515                            [arm atomic implementation])
2516         glib_memory_barrier_needed=no
2517         ;;
2518       crisv32*|etraxfs*)
2519         AC_MSG_RESULT([crisv32])
2520         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2521                            [crisv32 atomic implementation])
2522         glib_memory_barrier_needed=no
2523         ;;
2524       cris*|etrax*)
2525         AC_MSG_RESULT([cris])
2526         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2527                            [cris atomic implementation])
2528         glib_memory_barrier_needed=no
2529         ;;
2530       *)
2531         AC_MSG_RESULT([none])
2532         glib_memory_barrier_needed=yes
2533         ;;
2534     esac
2535   fi
2536 else
2537   if test $glib_native_win32 = yes; then
2538     # For Windows but not using gcc. No barriers needed then either.
2539     glib_memory_barrier_needed=no
2540   fi
2541 fi
2542
2543 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2544                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2545
2546 dnl ************************
2547 dnl ** Check for futex(2) **
2548 dnl ************************
2549 AC_MSG_CHECKING([for futex(2) system call])
2550 AC_COMPILE_IFELSE([
2551 #include <linux/futex.h>
2552 #include <syscall.h>
2553 #include <unistd.h>
2554
2555 int
2556 main (void)
2557 {
2558   /* it's not like this actually runs or anything... */
2559   syscall (SYS_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2560   return 0;
2561 }
2562 ],
2563 [
2564   AC_MSG_RESULT(yes)
2565   AC_DEFINE(HAVE_FUTEX, [test "$have_futex" = "yes"],
2566             [we have the futex(2) system call])
2567 ],
2568 [
2569   AC_MSG_RESULT(no)
2570 ])
2571
2572 dnl ****************************************
2573 dnl *** GLib POLL* compatibility defines ***
2574 dnl ****************************************
2575
2576 glib_poll_includes=["
2577 #include <sys/types.h>
2578 #include <sys/poll.h>
2579 "]
2580
2581 if test $ac_cv_header_sys_types_h = yes &&
2582    test $ac_cv_header_sys_poll_h = yes ; then
2583   glib_failed=false
2584   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2585   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2586   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2587   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2588   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2589   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2590   if $glib_failed ; then
2591     AC_MSG_ERROR([Could not determine values for POLL* constants])
2592   fi
2593 else
2594   glib_cv_value_POLLIN=1
2595   glib_cv_value_POLLOUT=4
2596   glib_cv_value_POLLPRI=2
2597   glib_cv_value_POLLERR=8
2598   glib_cv_value_POLLHUP=16
2599   glib_cv_value_POLLNVAL=32
2600 fi
2601
2602 AC_MSG_CHECKING([for broken poll])
2603 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2604         #include <stdlib.h>
2605         #include <fcntl.h>
2606         #include <poll.h>
2607         #ifdef HAVE_SYS_POLL_H
2608         #include <sys/poll.h>
2609         #endif
2610         int main(void) {
2611           struct pollfd fds[1];
2612           int fd;
2613           fd = open("/dev/null", 1);
2614           fds[0].fd = fd;
2615           fds[0].events = POLLIN;
2616           fds[0].revents = 0;
2617           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2618                 exit(1);  /* Does not work for devices -- fail */
2619           }
2620           exit(0);
2621         }]])],
2622   [broken_poll=no],
2623   [broken_poll=yes
2624    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2625   [broken_poll="no (cross compiling)"])
2626 AC_MSG_RESULT($broken_poll)
2627
2628 dnl *********************
2629 dnl *** GRegex checks ***
2630 dnl *********************
2631 PCRE_REQUIRED_VERSION=7.2
2632
2633 # Check if we should compile GRegex
2634 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2635               [disable the compilation of GRegex]),
2636 [case "${enableval}" in
2637   yes) enable_regex=true ;;
2638   no)  enable_regex=false ;;
2639   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2640 esac],
2641 [enable_regex=true])
2642
2643 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2644
2645 if test x$enable_regex = xtrue; then
2646   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2647   # Check if we should use the internal or the system-supplied pcre
2648   AC_ARG_WITH(pcre,
2649              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2650                              [specify whether to use the internal or the
2651                               system-supplied PCRE library])])
2652
2653   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2654
2655   if test "x$with_pcre" = xsystem; then
2656     PKG_CHECK_MODULES(PCRE,
2657                       libpcre >= $PCRE_REQUIRED_VERSION)
2658     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2659                    glib_save_CFLAGS="$CFLAGS"
2660                    glib_save_LIBS="$LIBS"
2661                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2662                    AC_TRY_RUN([#include <pcre.h>
2663                                int main () {
2664                                  int support;
2665                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2666                                  if (!support)
2667                                    return 1;
2668                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2669                                  if (!support)
2670                                    return 1;
2671                                  return 0;
2672                                }],
2673                    glib_cv_pcre_has_unicode=yes,
2674                    glib_cv_pcre_has_unicode=no,
2675                    glib_cv_pcre_has_unicode=yes)
2676                    CFLAGS="$glib_save_CFLAGS"
2677                    LIBS="$glib_save_LIBS"
2678         ])
2679     if test "$glib_cv_pcre_has_unicode" = "no"; then
2680       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2681     fi
2682     AC_SUBST(PCRE_CFLAGS)
2683     AC_SUBST(PCRE_LIBS)
2684     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2685     PCRE_REQUIRES=libpcre
2686     AC_SUBST(PCRE_REQUIRES)
2687   else
2688     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2689     if test x"$GCC" = xyes; then
2690       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2691       save_CFLAGS="$CFLAGS"
2692       CFLAGS="$CFLAGS -Wno-pointer-sign"
2693       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2694                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2695       CFLAGS="$save_CFLAGS"
2696     fi
2697   fi
2698   AC_SUBST(PCRE_WARN_CFLAGS)
2699 else
2700   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2701 fi
2702
2703 dnl **********************
2704 dnl *** Win32 API libs ***
2705 dnl **********************
2706
2707 case $host in
2708   *-*-cygwin*)
2709         G_LIBS_EXTRA="-luser32 -lkernel32"
2710     ;;
2711   *-*-mingw*)
2712         G_LIBS_EXTRA="-lws2_32 -lole32"
2713     ;;
2714   *)
2715         G_LIBS_EXTRA=""
2716     ;;
2717 esac
2718 AC_SUBST(G_LIBS_EXTRA)
2719
2720 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2721 dnl since we need it for g_iconv()
2722
2723 AC_MSG_CHECKING([for EILSEQ])
2724 AC_TRY_COMPILE([
2725 #include <errno.h>
2726 ],
2727 [
2728 int error = EILSEQ;
2729 ], have_eilseq=yes, have_eilseq=no);
2730 AC_MSG_RESULT($have_eilseq)
2731
2732 dnl ******************************************************************
2733 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2734 dnl *** glib-compile-schemas in PATH                               ***
2735 dnl ******************************************************************
2736
2737 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2738
2739 if test $cross_compiling = yes; then
2740   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2741   if test x$GLIB_GENMARSHAL = xno; then
2742     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2743   fi
2744
2745   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2746   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2747     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2748   fi
2749 fi
2750
2751 dnl **************************
2752 dnl *** Checks for gtk-doc ***
2753 dnl **************************
2754
2755 GTK_DOC_CHECK([1.15])
2756
2757 AC_ARG_ENABLE(man,
2758               [AC_HELP_STRING([--enable-man],
2759                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2760               enable_man=no)
2761
2762 if test "${enable_man}" != no; then
2763 dnl
2764 dnl Check for xsltproc
2765 dnl
2766 AC_PATH_PROG([XSLTPROC], [xsltproc])
2767   if test -z "$XSLTPROC"; then
2768     enable_man=no
2769   fi
2770
2771   dnl check for DocBook DTD and stylesheets in the local catalog.
2772   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2773      [DocBook XML DTD V4.1.2],,enable_man=no)
2774   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2775      [DocBook XSL Stylesheets],,enable_man=no)
2776 fi
2777
2778 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2779
2780 dnl
2781 dnl Tracing
2782 dnl
2783
2784 AC_ARG_ENABLE([dtrace],
2785              [AS_HELP_STRING([--enable-dtrace],
2786                               [Enable inclusion of dtrace trace support])])
2787 have_dtrace=no
2788 AC_MSG_CHECKING([whether to include dtrace tracing support])
2789 if test "x$enable_dtrace" != xno; then
2790   if test x$glib_have_carbon = xyes; then
2791     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2792   else
2793     AC_MSG_RESULT([yes])
2794     AC_CHECK_PROGS(DTRACE, dtrace)
2795     if test -z "$DTRACE"; then
2796       if test "x$enable_dtrace" = xyes; then
2797         AC_MSG_ERROR([dtrace not found])
2798       fi
2799     fi
2800     AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2801                     [if test "x$enable_dtrace" = xyes; then
2802                       AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2803                      fi])
2804   fi
2805 else
2806   AC_MSG_RESULT([no])
2807 fi
2808 if test "x$have_dtrace" = xyes; then
2809   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2810 fi
2811 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2812
2813 AC_MSG_CHECKING([whether to include systemtap tracing support])
2814 AC_ARG_ENABLE([systemtap],
2815              [AS_HELP_STRING([--enable-systemtap],
2816                               [Enable inclusion of systemtap trace support])])
2817 have_systemtap=no
2818 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2819   have_systemtap=yes
2820 fi
2821 AC_MSG_RESULT(${have_systemtap})
2822
2823 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2824
2825 AC_ARG_WITH([tapset-install-dir],
2826             [AS_HELP_STRING([--with-tapset-install-dir],
2827             [The absolute path where the systemtap tapsets will be installed])],
2828             [if test "x${withval}" = x; then
2829                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2830              else
2831                ABS_TAPSET_DIR="${withval}"
2832               fi],
2833             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2834 AC_SUBST(ABS_TAPSET_DIR)
2835
2836 dnl ************************************
2837 dnl *** Enable lcov coverage reports ***
2838 dnl ************************************
2839
2840 AC_ARG_ENABLE(gcov,
2841   AS_HELP_STRING([--enable-gcov],
2842                  [Enable gcov]),
2843   [use_gcov=$enableval], [use_gcov=no])
2844
2845 if test "x$use_gcov" = "xyes"; then
2846   dnl we need gcc:
2847   if test "$GCC" != "yes"; then
2848     AC_MSG_ERROR([GCC is required for --enable-gcov])
2849   fi
2850
2851   dnl Check if ccache is being used
2852   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2853   case `$SHTOOL path $CC` in
2854     *ccache*[)] gcc_ccache=yes;;
2855     *[)] gcc_ccache=no;;
2856   esac
2857
2858   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2859     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2860   fi
2861
2862   ltp_version_list="1.6 1.7 1.8"
2863   AC_CHECK_PROG(LTP, lcov, lcov)
2864   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2865
2866   if test "$LTP"; then
2867     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2868       glib_cv_ltp_version=invalid
2869       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2870       for ltp_check_version in $ltp_version_list; do
2871         if test "$ltp_version" = "$ltp_check_version"; then
2872           glib_cv_ltp_version="$ltp_check_version (ok)"
2873         fi
2874       done
2875     ])
2876   else
2877     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2878     AC_MSG_ERROR([$ltp_msg])
2879   fi
2880
2881   case $glib_cv_ltp_version in
2882     ""|invalid[)]
2883       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2884       AC_MSG_ERROR([$ltp_msg])
2885       LTP="exit 0;"
2886       ;;
2887   esac
2888
2889   if test -z "$LTP_GENHTML"; then
2890     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2891   fi
2892
2893   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2894
2895   dnl Remove all optimization flags from CFLAGS
2896   changequote({,})
2897   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2898   changequote([,])
2899
2900   dnl Add the special gcc flags
2901   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2902   LDFLAGS="$LDFLAGS -lgcov"
2903 fi
2904
2905 dnl ******************************
2906 dnl *** output the whole stuff ***
2907 dnl ******************************
2908
2909 dnl this section will only be run if config.status is invoked with no
2910 dnl arguments, or with "glib/glibconfig.h" as an argument.
2911 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2912 [
2913         outfile=glib/glibconfig.h-tmp
2914         cat > $outfile <<\_______EOF
2915 /* glibconfig.h
2916  *
2917  * This is a generated file.  Please modify 'configure.ac'
2918  */
2919
2920 #ifndef __G_LIBCONFIG_H__
2921 #define __G_LIBCONFIG_H__
2922
2923 #include <glib/gmacros.h>
2924
2925 _______EOF
2926
2927         if test x$glib_limits_h = xyes; then
2928           echo '#include <limits.h>' >> $outfile
2929         fi
2930         if test x$glib_float_h = xyes; then
2931           echo '#include <float.h>' >> $outfile
2932         fi
2933         if test x$glib_values_h = xyes; then
2934           echo '#include <values.h>' >> $outfile
2935         fi
2936         if test "$glib_header_alloca_h" = "yes"; then
2937           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2938         fi
2939         if test x$glib_sys_poll_h = xyes; then
2940           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2941         fi
2942         if test x$glib_included_printf != xyes; then
2943           echo "
2944 /* Specifies that GLib's g_print*() functions wrap the
2945  * system printf functions.  This is useful to know, for example,
2946  * when using glibc's register_printf_function().
2947  */" >> $outfile
2948           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2949         fi
2950
2951         cat >> $outfile <<_______EOF
2952
2953 G_BEGIN_DECLS
2954
2955 #define G_MINFLOAT      $glib_mf
2956 #define G_MAXFLOAT      $glib_Mf
2957 #define G_MINDOUBLE     $glib_md
2958 #define G_MAXDOUBLE     $glib_Md
2959 #define G_MINSHORT      $glib_ms
2960 #define G_MAXSHORT      $glib_Ms
2961 #define G_MAXUSHORT     $glib_Mus
2962 #define G_MININT        $glib_mi
2963 #define G_MAXINT        $glib_Mi
2964 #define G_MAXUINT       $glib_Mui
2965 #define G_MINLONG       $glib_ml
2966 #define G_MAXLONG       $glib_Ml
2967 #define G_MAXULONG      $glib_Mul
2968
2969 _______EOF
2970
2971
2972         ### this should always be true in a modern C/C++ compiler
2973         cat >>$outfile <<_______EOF
2974 typedef signed char gint8;
2975 typedef unsigned char guint8;
2976 _______EOF
2977
2978
2979         if test -n "$gint16"; then
2980           cat >>$outfile <<_______EOF
2981 typedef signed $gint16 gint16;
2982 typedef unsigned $gint16 guint16;
2983 #define G_GINT16_MODIFIER $gint16_modifier
2984 #define G_GINT16_FORMAT $gint16_format
2985 #define G_GUINT16_FORMAT $guint16_format
2986 _______EOF
2987         fi
2988
2989
2990         if test -n "$gint32"; then
2991           cat >>$outfile <<_______EOF
2992 typedef signed $gint32 gint32;
2993 typedef unsigned $gint32 guint32;
2994 #define G_GINT32_MODIFIER $gint32_modifier
2995 #define G_GINT32_FORMAT $gint32_format
2996 #define G_GUINT32_FORMAT $guint32_format
2997 _______EOF
2998         fi
2999
3000         cat >>$outfile <<_______EOF
3001 #define G_HAVE_GINT64 1          /* deprecated, always true */
3002
3003 ${glib_extension}typedef signed $gint64 gint64;
3004 ${glib_extension}typedef unsigned $gint64 guint64;
3005
3006 #define G_GINT64_CONSTANT(val)  $gint64_constant
3007 #define G_GUINT64_CONSTANT(val) $guint64_constant
3008 _______EOF
3009
3010         if test x$gint64_format != x ; then
3011           cat >>$outfile <<_______EOF
3012 #define G_GINT64_MODIFIER $gint64_modifier
3013 #define G_GINT64_FORMAT $gint64_format
3014 #define G_GUINT64_FORMAT $guint64_format
3015 _______EOF
3016         else
3017           cat >>$outfile <<_______EOF
3018 #undef G_GINT64_MODIFIER
3019 #undef G_GINT64_FORMAT
3020 #undef G_GUINT64_FORMAT
3021 _______EOF
3022         fi
3023
3024         cat >>$outfile <<_______EOF
3025
3026 #define GLIB_SIZEOF_VOID_P $glib_void_p
3027 #define GLIB_SIZEOF_LONG   $glib_long
3028 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3029
3030 _______EOF
3031
3032         cat >>$outfile <<_______EOF
3033 typedef signed $glib_size_type_define gssize;
3034 typedef unsigned $glib_size_type_define gsize;
3035 #define G_GSIZE_MODIFIER $gsize_modifier
3036 #define G_GSSIZE_FORMAT $gssize_format
3037 #define G_GSIZE_FORMAT $gsize_format
3038
3039 #define G_MAXSIZE       G_MAXU$glib_msize_type
3040 #define G_MINSSIZE      G_MIN$glib_msize_type
3041 #define G_MAXSSIZE      G_MAX$glib_msize_type
3042
3043 typedef gint64 goffset;
3044 #define G_MINOFFSET     G_MININT64
3045 #define G_MAXOFFSET     G_MAXINT64
3046
3047 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3048 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3049 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3050
3051 _______EOF
3052
3053         if test -z "$glib_unknown_void_p"; then
3054           cat >>$outfile <<_______EOF
3055
3056 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3057 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3058
3059 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3060 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3061
3062 typedef signed $glib_intptr_type_define gintptr;
3063 typedef unsigned $glib_intptr_type_define guintptr;
3064
3065 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3066 #define G_GINTPTR_FORMAT        $gintptr_format
3067 #define G_GUINTPTR_FORMAT       $guintptr_format
3068 _______EOF
3069         else
3070           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3071         fi
3072
3073
3074
3075         cat >>$outfile <<_______EOF
3076 $glib_atexit
3077 $glib_memmove
3078 $glib_defines
3079 $glib_os
3080 $glib_static_compilation
3081
3082 $glib_vacopy
3083
3084 #ifdef  __cplusplus
3085 #define G_HAVE_INLINE   1
3086 #else   /* !__cplusplus */
3087 $glib_inline
3088 #endif  /* !__cplusplus */
3089
3090 #ifdef  __cplusplus
3091 #define G_CAN_INLINE    1
3092 _______EOF
3093
3094         if test x$g_can_inline = xyes ; then
3095                 cat >>$outfile <<_______EOF
3096 #else   /* !__cplusplus */
3097 #define G_CAN_INLINE    1
3098 _______EOF
3099         fi
3100
3101         cat >>$outfile <<_______EOF
3102 #endif
3103
3104 _______EOF
3105
3106         if test x$g_have_iso_c_varargs = xyes ; then
3107                 cat >>$outfile <<_______EOF
3108 #ifndef __cplusplus
3109 # define G_HAVE_ISO_VARARGS 1
3110 #endif
3111 _______EOF
3112         fi
3113         if test x$g_have_iso_cxx_varargs = xyes ; then
3114                 cat >>$outfile <<_______EOF
3115 #ifdef __cplusplus
3116 # define G_HAVE_ISO_VARARGS 1
3117 #endif
3118 _______EOF
3119         fi
3120         if test x$g_have_gnuc_varargs = xyes ; then
3121                 cat >>$outfile <<_______EOF
3122
3123 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3124  * is passed ISO vararg support is turned off, and there is no work
3125  * around to turn it on, so we unconditionally turn it off.
3126  */
3127 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3128 #  undef G_HAVE_ISO_VARARGS
3129 #endif
3130
3131 #define G_HAVE_GNUC_VARARGS 1
3132 _______EOF
3133         fi
3134
3135         case x$g_stack_grows in
3136         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3137         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3138         esac
3139
3140
3141         echo >>$outfile
3142         if test x$g_have_eilseq = xno; then
3143                 cat >>$outfile <<_______EOF
3144 #ifndef EILSEQ
3145 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3146  * The correspondence between this and the corresponding definition
3147  * in libiconv is essential.
3148  */
3149 #  define EILSEQ ENOENT
3150 #endif
3151 _______EOF
3152
3153         fi
3154
3155         if test x$g_have_gnuc_visibility = xyes; then
3156                 cat >>$outfile <<_______EOF
3157 #define G_HAVE_GNUC_VISIBILITY 1
3158 _______EOF
3159         fi
3160                 cat >>$outfile <<_______EOF
3161 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3162 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3163 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3164 #define G_GNUC_INTERNAL __hidden
3165 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3166 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3167 #else
3168 #define G_GNUC_INTERNAL
3169 #endif
3170 _______EOF
3171
3172
3173         echo >>$outfile
3174         if test x$g_mutex_has_default = xyes; then
3175                 cat >>$outfile <<_______EOF
3176 $g_enable_threads_def G_THREADS_ENABLED
3177 #define G_THREADS_IMPL_$g_threads_impl_def
3178 typedef struct _GStaticMutex GStaticMutex;
3179 struct _GStaticMutex
3180 {
3181   struct _GMutex *runtime_mutex;
3182   union {
3183     char   pad[[$g_mutex_sizeof]];
3184     double dummy_double;
3185     void  *dummy_pointer;
3186     long   dummy_long;
3187   } static_mutex;
3188 };
3189 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3190 #define g_static_mutex_get_mutex(mutex) \\
3191   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3192    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3193 _______EOF
3194         else
3195                 cat >>$outfile <<_______EOF
3196 $g_enable_threads_def G_THREADS_ENABLED
3197 #define G_THREADS_IMPL_$g_threads_impl_def
3198 typedef struct _GMutex* GStaticMutex;
3199 #define G_STATIC_MUTEX_INIT NULL
3200 #define g_static_mutex_get_mutex(mutex) \\
3201   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3202 _______EOF
3203         fi
3204
3205         cat >>$outfile <<_______EOF
3206 /* This represents a system thread as used by the implementation. An
3207  * alien implementaion, as loaded by g_thread_init can only count on
3208  * "sizeof (gpointer)" bytes to store their info. We however need more
3209  * for some of our native implementations. */
3210 typedef union _GSystemThread GSystemThread;
3211 union _GSystemThread
3212 {
3213   char   data[[$g_system_thread_sizeof]];
3214   double dummy_double;
3215   void  *dummy_pointer;
3216   long   dummy_long;
3217 };
3218 _______EOF
3219         if test x"$g_memory_barrier_needed" != xno; then
3220           echo >>$outfile
3221           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3222         fi
3223
3224         echo >>$outfile
3225         g_bit_sizes="16 32 64"
3226         for bits in $g_bit_sizes; do
3227           cat >>$outfile <<_______EOF
3228 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3229 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3230 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3231 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3232 _______EOF
3233         done
3234
3235         cat >>$outfile <<_______EOF
3236 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3237 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3238 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3239 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3240 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3241 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3242 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3243 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3244 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3245 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3246 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3247 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3248 #define G_BYTE_ORDER $g_byte_order
3249
3250 #define GLIB_SYSDEF_POLLIN =$g_pollin
3251 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3252 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3253 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3254 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3255 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3256
3257 #define G_MODULE_SUFFIX "$g_module_suffix"
3258
3259 /* A GPid is an abstraction for a process "handle". It is *not* an
3260  * abstraction for a process identifier in general. GPid is used in
3261  * GLib only for descendant processes spawned with the g_spawn*
3262  * functions. On POSIX there is no "process handle" concept as such,
3263  * but on Windows a GPid is a handle to a process, a kind of pointer,
3264  * not a process identifier.
3265  */
3266 typedef $g_pid_type GPid;
3267
3268 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3269 #define GLIB_SYSDEF_AF_INET $g_af_inet
3270 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3271
3272 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3273 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3274 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3275
3276 G_END_DECLS
3277
3278 #endif /* GLIBCONFIG_H */
3279 _______EOF
3280
3281
3282         if cmp -s $outfile glib/glibconfig.h; then
3283           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3284           rm -f $outfile
3285         else
3286           mv $outfile glib/glibconfig.h
3287         fi
3288 ],[
3289
3290 # Note that if two cases are the same, case goes with the first one.
3291 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3292 # on variable expansion in case labels.  Look at the generated config.status
3293 # for a hint.
3294
3295 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3296   glib_header_alloca_h="$ac_cv_working_alloca_h"
3297 else
3298   glib_header_alloca_h="$ac_cv_header_alloca_h"
3299 fi
3300
3301 case xyes in
3302 x$ac_cv_header_float_h)
3303   glib_float_h=yes
3304   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3305   glib_md=DBL_MIN glib_Md=DBL_MAX
3306   ;;
3307 x$ac_cv_header_values_h)
3308   glib_values_h=yes
3309   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3310   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3311   ;;
3312 esac
3313
3314 case xyes in
3315 x$ac_cv_header_limits_h)
3316   glib_limits_h=yes
3317   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3318   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3319   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3320   ;;
3321 x$ac_cv_header_values_h)
3322   glib_values_h=yes
3323   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3324   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3325   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3326   ;;
3327 esac
3328
3329 if test x$ac_cv_header_sys_poll_h = xyes ; then
3330   glib_sys_poll_h=yes
3331 fi
3332
3333 if test x$enable_included_printf = xyes ; then
3334   glib_included_printf=yes
3335 fi
3336
3337 case 2 in
3338 $ac_cv_sizeof_short)
3339   gint16=short
3340   gint16_modifier='"h"'
3341   gint16_format='"hi"'
3342   guint16_format='"hu"'
3343   ;;
3344 $ac_cv_sizeof_int)
3345   gint16=int
3346   gint16_modifier='""'
3347   gint16_format='"i"'
3348   guint16_format='"u"'
3349   ;;
3350 esac
3351 case 4 in
3352 $ac_cv_sizeof_short)
3353   gint32=short
3354   gint32_modifier='"h"'
3355   gint32_format='"hi"'
3356   guint32_format='"hu"'
3357   ;;
3358 $ac_cv_sizeof_int)
3359   gint32=int
3360   gint32_modifier='""'
3361   gint32_format='"i"'
3362   guint32_format='"u"'
3363   ;;
3364 $ac_cv_sizeof_long)
3365   gint32=long
3366   gint32_modifier='"l"'
3367   gint32_format='"li"'
3368   guint32_format='"lu"'
3369   ;;
3370 esac
3371 case 8 in
3372 $ac_cv_sizeof_int)
3373   gint64=int
3374   gint64_modifier='""'
3375   gint64_format='"i"'
3376   guint64_format='"u"'
3377   glib_extension=
3378   gint64_constant='(val)'
3379   guint64_constant='(val)'
3380   ;;
3381 $ac_cv_sizeof_long)
3382   gint64=long
3383   gint64_modifier='"l"'
3384   gint64_format='"li"'
3385   guint64_format='"lu"'
3386   glib_extension=
3387   gint64_constant='(val##L)'
3388   guint64_constant='(val##UL)'
3389   ;;
3390 $ac_cv_sizeof_long_long)
3391   gint64='long long'
3392   if test -n "$glib_cv_long_long_format"; then
3393     gint64_modifier='"'$glib_cv_long_long_format'"'
3394     gint64_format='"'$glib_cv_long_long_format'i"'
3395     guint64_format='"'$glib_cv_long_long_format'u"'
3396   fi
3397   glib_extension='G_GNUC_EXTENSION '
3398   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3399   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3400   ;;
3401 $ac_cv_sizeof___int64)
3402   gint64='__int64'
3403   if test -n "$glib_cv_long_long_format"; then
3404     gint64_modifier='"'$glib_cv_long_long_format'"'
3405     gint64_format='"'$glib_cv_long_long_format'i"'
3406     guint64_format='"'$glib_cv_long_long_format'u"'
3407   fi
3408   glib_extension=
3409   gint64_constant='(val##i64)'
3410   guint64_constant='(val##ui64)'
3411   ;;
3412 esac
3413 glib_size_t=$ac_cv_sizeof_size_t
3414 glib_size_type_define="$glib_size_type"
3415 glib_void_p=$ac_cv_sizeof_void_p
3416 glib_long=$ac_cv_sizeof_long
3417
3418 case "$glib_size_type" in
3419 short)
3420   gsize_modifier='"h"'
3421   gsize_format='"hu"'
3422   gssize_format='"hi"'
3423   glib_msize_type='SHRT'
3424   ;;
3425 int)
3426   gsize_modifier='""'
3427   gsize_format='"u"'
3428   gssize_format='"i"'
3429   glib_msize_type='INT'
3430   ;;
3431 long)
3432   gsize_modifier='"l"'
3433   gsize_format='"lu"'
3434   gssize_format='"li"'
3435   glib_msize_type='LONG'
3436   ;;
3437 "long long"|__int64)
3438   gsize_modifier='"I64"'
3439   gsize_format='"I64u"'
3440   gssize_format='"I64i"'
3441   glib_msize_type='INT64'
3442   ;;
3443 esac
3444
3445 gintbits=`expr $ac_cv_sizeof_int \* 8`
3446 glongbits=`expr $ac_cv_sizeof_long \* 8`
3447 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3448
3449 case $ac_cv_sizeof_void_p in
3450 $ac_cv_sizeof_int)
3451   glib_intptr_type_define=int
3452   gintptr_modifier='""'
3453   gintptr_format='"i"'
3454   guintptr_format='"u"'
3455   glib_gpi_cast=''
3456   glib_gpui_cast=''
3457   ;;
3458 $ac_cv_sizeof_long)
3459   glib_intptr_type_define=long
3460   gintptr_modifier='"l"'
3461   gintptr_format='"li"'
3462   guintptr_format='"lu"'
3463   glib_gpi_cast='(glong)'
3464   glib_gpui_cast='(gulong)'
3465   ;;
3466 $ac_cv_sizeof_long_long)
3467   glib_intptr_type_define='long long'
3468   gintptr_modifier='"I64"'
3469   gintptr_format='"I64i"'
3470   guintptr_format='"I64u"'
3471   glib_gpi_cast='(gint64)'
3472   glib_gpui_cast='(guint64)'
3473   ;;
3474 $ac_cv_sizeof___int64)
3475   glib_intptr_type_define=__int64
3476   gintptr_modifier='"I64"'
3477   gintptr_format='"I64i"'
3478   guintptr_format='"I64u"'
3479   glib_gpi_cast='(gint64)'
3480   glib_gpui_cast='(guint64)'
3481   ;;
3482 *)
3483   glib_unknown_void_p=yes
3484   ;;
3485 esac
3486
3487
3488 case xyes in
3489 x$ac_cv_func_atexit)
3490   glib_atexit="
3491 #ifdef NeXT /* @#%@! NeXTStep */
3492 # define g_ATEXIT(proc) (!atexit (proc))
3493 #else
3494 # define g_ATEXIT(proc) (atexit (proc))
3495 #endif"
3496   ;;
3497 x$ac_cv_func_on_exit)
3498   glib_atexit="
3499 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3500   ;;
3501 esac
3502
3503 case xyes in
3504 x$ac_cv_func_memmove)
3505   glib_memmove='
3506 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3507   ;;
3508 x$glib_cv_working_bcopy)
3509   glib_memmove="
3510 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3511 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3512   ;;
3513 *)
3514   glib_memmove="
3515 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3516  * so we have to roll our own copy routine. */
3517 void g_memmove (void* dest, const void * src, unsigned long len);"
3518   ;;
3519 esac
3520
3521 glib_defines="
3522 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3523 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3524 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3525 "
3526
3527 case xyes in
3528 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3529 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3530 *)                      glib_vacopy=''
3531 esac
3532
3533 if test x$glib_cv_va_val_copy = xno; then
3534   glib_vacopy="\$glib_vacopy
3535 #define G_VA_COPY_AS_ARRAY 1"
3536 fi
3537
3538 if test x$glib_cv_hasinline = xyes; then
3539     glib_inline='#define G_HAVE_INLINE 1'
3540 fi
3541 if test x$glib_cv_has__inline = xyes; then
3542     glib_inline="\$glib_inline
3543 #define G_HAVE___INLINE 1"
3544 fi
3545 if test x$glib_cv_has__inline__ = xyes; then
3546     glib_inline="\$glib_inline
3547 #define G_HAVE___INLINE__ 1"
3548 fi
3549
3550 g_have_gnuc_varargs=$g_have_gnuc_varargs
3551 g_have_iso_c_varargs=$g_have_iso_c_varargs
3552 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3553
3554 g_can_inline=$g_can_inline
3555 g_have_gnuc_visibility=$g_have_gnuc_visibility
3556 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3557
3558 if test x$ac_cv_c_bigendian = xyes; then
3559   g_byte_order=G_BIG_ENDIAN
3560   g_bs_native=BE
3561   g_bs_alien=LE
3562 else
3563   g_byte_order=G_LITTLE_ENDIAN
3564   g_bs_native=LE
3565   g_bs_alien=BE
3566 fi
3567
3568 g_pollin=$glib_cv_value_POLLIN
3569 g_pollout=$glib_cv_value_POLLOUT
3570 g_pollpri=$glib_cv_value_POLLPRI
3571 g_pollhup=$glib_cv_value_POLLHUP
3572 g_pollerr=$glib_cv_value_POLLERR
3573 g_pollnval=$glib_cv_value_POLLNVAL
3574
3575 g_af_unix=$glib_cv_value_AF_UNIX
3576 g_af_inet=$glib_cv_value_AF_INET
3577 g_af_inet6=$glib_cv_value_AF_INET6
3578
3579 g_msg_peek=$glib_cv_value_MSG_PEEK
3580 g_msg_oob=$glib_cv_value_MSG_OOB
3581 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3582
3583 g_stack_grows=$glib_cv_stack_grows
3584
3585 g_have_eilseq=$have_eilseq
3586
3587 case x$have_threads in
3588 xno)    g_enable_threads_def="#undef";;
3589 *)      g_enable_threads_def="#define";;
3590 esac
3591
3592 g_threads_impl_def=$g_threads_impl
3593
3594 g_mutex_has_default="$mutex_has_default"
3595 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3596 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3597 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3598
3599 g_memory_barrier_needed="$glib_memory_barrier_needed"
3600
3601 g_module_suffix="$glib_gmodule_suffix"
3602
3603 g_pid_type="$glib_pid_type"
3604 case $host in
3605   *-*-beos*)
3606     glib_os="#define G_OS_BEOS"
3607     ;;
3608   *-*-cygwin*)
3609     glib_os="#define G_OS_UNIX
3610 #define G_PLATFORM_WIN32
3611 #define G_WITH_CYGWIN"
3612     ;;
3613   *-*-mingw*)
3614     glib_os="#define G_OS_WIN32
3615 #define G_PLATFORM_WIN32"
3616     ;;
3617   *)
3618     glib_os="#define G_OS_UNIX"
3619     ;;
3620 esac
3621 glib_static_compilation=""
3622 if test x$glib_win32_static_compilation = xyes; then
3623   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3624 #define GOBJECT_STATIC_COMPILATION 1"
3625 fi
3626 ])
3627
3628 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3629 #
3630 # 1.2.14 required for dbus_message_set_serial
3631 PKG_CHECK_MODULES(DBUS1,
3632                   dbus-1 >= 1.2.14,
3633                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3634                   have_dbus1=no)
3635 AC_SUBST(DBUS1_CFLAGS)
3636 AC_SUBST(DBUS1_LIBS)
3637 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3638
3639 dnl
3640 dnl Check for -Bsymbolic-functions linker flag used to avoid
3641 dnl intra-library PLT jumps, if available.
3642 dnl
3643
3644 AC_ARG_ENABLE(Bsymbolic,
3645               [AC_HELP_STRING([--disable-Bsymbolic],
3646                               [avoid linking with -Bsymbolic])],,
3647               [SAVED_LDFLAGS="${LDFLAGS}"
3648                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3649                LDFLAGS=-Wl,-Bsymbolic-functions
3650                AC_TRY_LINK([], [int main (void) { return 0; }],
3651                            AC_MSG_RESULT(yes)
3652                            enable_Bsymbolic=yes,
3653                            AC_MSG_RESULT(no)
3654                            enable_Bsymbolic=no)
3655                LDFLAGS="${SAVED_LDFLAGS}"])
3656
3657 if test "x${enable_Bsymbolic}" == "xyes"; then
3658   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3659 fi
3660
3661 AC_SUBST(GLIB_LINK_FLAGS)
3662
3663 AC_CONFIG_FILES([
3664 glib-2.0.pc
3665 glib-2.0-uninstalled.pc
3666 gmodule-2.0.pc
3667 gmodule-export-2.0.pc
3668 gmodule-no-export-2.0.pc
3669 gmodule-2.0-uninstalled.pc
3670 gmodule-no-export-2.0-uninstalled.pc
3671 gthread-2.0.pc
3672 gthread-2.0-uninstalled.pc
3673 gobject-2.0.pc
3674 gobject-2.0-uninstalled.pc
3675 gio-2.0.pc
3676 gio-unix-2.0.pc
3677 gio-windows-2.0.pc
3678 gio-2.0-uninstalled.pc
3679 gio-unix-2.0-uninstalled.pc
3680 glib-zip
3681 glib-gettextize
3682 Makefile
3683 build/Makefile
3684 build/win32/Makefile
3685 build/win32/dirent/Makefile
3686 build/win32/vs9/Makefile
3687 glib/Makefile
3688 glib/glib.stp
3689 glib/libcharset/Makefile
3690 glib/gnulib/Makefile
3691 glib/pcre/Makefile
3692 glib/update-pcre/Makefile
3693 glib/tests/Makefile
3694 gmodule/Makefile
3695 gmodule/gmoduleconf.h
3696 gobject/Makefile
3697 gobject/gobject.stp
3698 gobject/glib-mkenums
3699 gobject/tests/Makefile
3700 gthread/Makefile
3701 gthread/tests/Makefile
3702 gio/Makefile
3703 gio/xdgmime/Makefile
3704 gio/inotify/Makefile
3705 gio/libasyncns/Makefile
3706 gio/fen/Makefile
3707 gio/fam/Makefile
3708 gio/win32/Makefile
3709 gio/tests/Makefile
3710 po/Makefile.in
3711 docs/Makefile
3712 docs/reference/Makefile
3713 docs/reference/glib/Makefile
3714 docs/reference/glib/version.xml
3715 docs/reference/gobject/Makefile
3716 docs/reference/gobject/version.xml
3717 docs/reference/gio/Makefile
3718 docs/reference/gio/version.xml
3719 tests/Makefile
3720 tests/gobject/Makefile
3721 tests/refcount/Makefile
3722 m4macros/Makefile
3723 ])
3724
3725 AC_CONFIG_COMMANDS([chmod-scripts],
3726 [chmod 0755 glib-zip
3727 chmod 0755 glib-gettextize
3728 chmod 0755 gobject/glib-mkenums])
3729
3730 # we want to invoke this macro solely so that the config.status script
3731 # and automake generated makefiles know about these generated files.
3732 # They are only needed to distcheck the package
3733 if false; then
3734   AC_CONFIG_FILES([
3735     INSTALL
3736     README
3737     config.h.win32
3738     glib/glibconfig.h.win32
3739     glib/makefile.msc
3740     glib/glib.rc
3741     gmodule/makefile.msc
3742     gmodule/gmodule.rc
3743     gobject/makefile.msc
3744     gobject/gobject.rc
3745     gthread/makefile.msc
3746     gthread/gthread.rc
3747     gio/gio.rc
3748     tests/makefile.msc
3749   ])
3750 fi
3751
3752 AC_OUTPUT