configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/rygel/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 VALA_REQUIRED=0.11.6
  32 GSSDP_MAX_VERSION=0.10.9999
  33 GSSDP_REQUIRED=0.9.2
  34 GUPNP_MAX_VERSION=0.16.9999
  35 GUPNP_REQUIRED=0.13.4
  36 GUPNP_AV_MAX_VERSION=0.8.9999
  37 GUPNP_AV_REQUIRED=0.7.0
  38 GUPNP_DLNA_MAX_VERSION=0.6.9999
  39 GUPNP_DLNA_REQUIRED=0.5.0
  40 GUPNP_VALA_REQUIRED=0.7.5
  41 GSTREAMER_REQUIRED=0.10.23
  42 GSTPBU_REQUIRED=0.10.30
  43 GIO_REQUIRED=2.26
  44 GEE_MAX_VERSION=0.6.9999
  45 GEE_REQUIRED=0.5.2
  46 UUID_REQUIRED=1.41.3
  47 LIBSOUP_MAX_VERSION=2.34.9999
  48 LIBSOUP_REQUIRED=2.26.0
  49 GTK_REQUIRED=2.90.3
  50
  51 dnl Additional requirements for media-export plugin
  52 GSTREAMER_TAG_REQUIRED=0.10.28
  53 GSTREAMER_APP_REQUIRED=0.10.28
  54 LIBSQLITE3_REQUIRED=3.5
  55
  56 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED
  57                             gssdp-1.0 <= $GSSDP_MAX_VERSION)
  58 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED
  59                             gupnp-1.0 <= $GUPNP_MAX_VERSION)
  60 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED
  61                                gupnp-av-1.0 <= $GUPNP_AV_MAX_VERSION)
  62 PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED
  63                                  gupnp-dlna-1.0 <= $GUPNP_DLNA_MAX_VERSION)
  64 PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  65 PKG_CHECK_MODULES(GSTREAMER_BASE, gstreamer-base-0.10 >= $GSTREAMER_REQUIRED)
  66 PKG_CHECK_MODULES(GST_PBU, gstreamer-pbutils-0.10 >= $GSTPBU_REQUIRED)
  67 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  68 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  69 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  70 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED
  71                            libsoup-2.4 <= $LIBSOUP_MAX_VERSION)
  72
  73 dnl glib-genmarshal
  74 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  75 AC_SUBST(GLIB_GENMARSHAL)
  76
  77 AC_ARG_ENABLE(sql-debugging,
  78     AS_HELP_STRING([--enable-sql-debugging],[enable SQL statement debugging]),,
  79         enable_sql_debugging=no)
  80 AS_IF([test x$enable_sql_debugging = xyes],
  81       [RYGEL_ADD_VALAFLAGS([-D RYGEL_DEBUG_SQL])])
  82
  83 dnl Add plugins
  84 RYGEL_ADD_PLUGIN([test],[Test],[no])
  85 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
  86 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
  87 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
  88 RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
  89 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
  90 RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
  91 RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
  92
  93 dnl Explicitly add stamp files for targets that are not plugins
  94 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
  95 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
  96
  97 RYGEL_CHECK_VALA([$VALA_REQUIRED],
  98                  [gupnp-1.0
  99                   gupnp-av-1.0
 100                   gupnp-dlna-1.0
 101                   gstreamer-0.10
 102                   gstreamer-pbutils-0.10
 103                   gio-2.0
 104                   gee-1.0
 105                   posix])
 106
 107 dnl Debugging
 108 AC_ARG_ENABLE(debug,
 109         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 110         enable_debug=no)
 111 if test "x$enable_debug" = "xyes"; then
 112         CFLAGS="$CFLAGS -O0 -g"
 113 fi
 114
 115 dnl Strict compiler
 116 AC_ARG_ENABLE(strict-cc,
 117         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 118         enable_strict_cc=no)
 119 if test "x$enable_strict_cc" = "xyes"; then
 120         CFLAGS="$CFLAGS -Wall -Werror"
 121 else
 122         CFLAGS="$CFLAGS -w"
 123 fi
 124
 125 dnl Run uninstalled
 126 AC_ARG_ENABLE(uninstalled,
 127     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 128         enable_uninstalled=no)
 129 if test "x$enable_uninstalled" = "xyes"; then
 130         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 131 fi
 132 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 133
 134 dnl Check wether user wants to build UIs
 135 AC_ARG_WITH( ui,
 136   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 137   try_ui=$withval, try_ui=yes )
 138
 139 HAVE_GTK=no
 140 if test x$try_ui = xyes ; then
 141     dnl check for gtk
 142     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 143       [
 144         if test x$enable_vala = xyes ; then
 145                 VALA_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 146         else
 147                 HAVE_GTK=yes
 148         fi
 149       ],
 150       [
 151         HAVE_GTK=no
 152         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 153         AC_MSG_WARN([UI applications will not be built.])
 154       ])
 155 else
 156     AC_MSG_NOTICE([UI applications disabled.])
 157 fi
 158
 159 if test x$HAVE_GTK = xno; then
 160   BUILD_UI=no
 161 else
 162   BUILD_UI=yes
 163   AC_DEFINE(HAVE_GTK, , [Build UI applications])
 164 fi
 165
 166 AC_SUBST(HAVE_GTK)
 167 AM_CONDITIONAL(BUILD_UI, test x$BUILD_UI = xyes)
 168
 169 dnl Check additional requirements for MediaExport plugins
 170 if test "x$enable_media_export_plugin" = "xyes";
 171 then
 172     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 173     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 174     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 175     if test x$enable_vala = xyes ; then
 176         VALA_CHECK_PACKAGES([sqlite3
 177                              gstreamer-tag-0.10
 178                              gstreamer-app-0.10])
 179     fi
 180 fi
 181
 182 dnl Gettext
 183 GETTEXT_PACKAGE=rygel
 184 AC_SUBST(GETTEXT_PACKAGE)
 185 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 186   [Define the gettext package to be used])
 187
 188 AM_GLIB_GNU_GETTEXT
 189 IT_PROG_INTLTOOL([0.40.0])
 190
 191 dnl Shave the output
 192 AM_SILENT_RULES([yes])
 193
 194 dnl documenation
 195 AC_PATH_PROG([XSLTPROC], [xsltproc])
 196 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 197
 198
 199 AC_CONFIG_FILES([
 200 Makefile
 201 src/Makefile
 202 src/rygel/Makefile
 203 src/ui/Makefile
 204 src/plugins/Makefile
 205 data/Makefile
 206 data/xml/Makefile
 207 data/icons/Makefile
 208 data/icons/32x32/Makefile
 209 data/icons/48x48/Makefile
 210 data/icons/120x120/Makefile
 211 data/icons/scalable/Makefile
 212 data/rygel.desktop.in
 213 data/rygel-preferences.desktop.in
 214 doc/Makefile
 215 po/Makefile.in
 216 rygel-1.0.pc
 217 tests/Makefile
 218 ])
 219 AC_OUTPUT
 220
 221 echo "
 222
 223                     ${PACKAGE} ${VERSION}
 224                     ============
 225
 226
 227         Prefix:                 ${prefix}
 228         Source code location:   ${srcdir}
 229         Compiler:               ${CC}
 230         CFLAGS:                 ${CFLAGS}
 231         VALAFLAGS:              ${VALAFLAGS}
 232         uninstalled:            ${enable_uninstalled}
 233         preferences ui:         ${BUILD_UI}
 234         SQL debugging:          ${enable_sql_debugging}
 235     Plugins:
 236         test:                   ${enable_test_plugin}
 237         tracker:                ${enable_tracker_plugin}
 238         mediathek:              ${enable_mediathek_plugin}
 239         media-export            ${enable_media_export_plugin}
 240         external:               ${enable_external_plugin}
 241         MPRIS2:                 ${enable_mpris_plugin}
 242         gst-launch:             ${enable_gst_launch_plugin}
 243         playbin:                ${enable_playbin_plugin}
 244 "