configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 2, 0, 2)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.1.0
  50 GSTPB_REQ=1.1.0
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 dnl *** set variables based on configure arguments ***
 254
 255 dnl set license and copyright notice
 256 GST_LICENSE="LGPL"
 257 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 258 AC_SUBST(GST_LICENSE)
 259
 260 dnl set location of plugin directory
 261 AG_GST_SET_PLUGINDIR
 262
 263 dnl set release date/time
 264 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 265   ["${srcdir}/gst-plugins-good.doap"],
 266   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 267
 268 dnl build static plugins or not
 269 AC_MSG_CHECKING([whether to build static plugins or not])
 270 AC_ARG_ENABLE(
 271   static-plugins,
 272   AC_HELP_STRING(
 273     [--enable-static-plugins],
 274     [build static plugins @<:@default=no@:>@]),
 275   [AS_CASE(
 276     [$enableval], [no], [], [yes], [],
 277     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 278   [enable_static_plugins=no])
 279 AC_MSG_RESULT([$enable_static_plugins])
 280 if test "x$enable_static_plugins" = xyes; then
 281   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 282     [Define if static plugins should be built])
 283   GST_PLUGIN_LIBTOOLFLAGS=""
 284 else
 285   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 286 fi
 287 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 288 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 289
 290 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 291 dnl make sure it doesn't complain about unused variables if debugging is disabled
 292 NO_WARNINGS=""
 293 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 294
 295 dnl define an ERROR_CFLAGS Makefile variable
 296 dnl -Wundef: too many broken headers
 297 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 298       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 299       -Wwrite-strings -Wold-style-definition -Waggregate-return
 300       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 301       -Wnested-externs $NO_WARNINGS])
 302
 303 dnl define an ERROR_CXXFLAGS Makefile variable
 304 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 305         -Wmissing-declarations -Wredundant-decls
 306         -Wwrite-strings
 307         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 308         $NO_WARNINGS])
 309
 310 dnl define an ERROR_OBJCFLAGS Makefile variable
 311 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 312       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 313       -Wwrite-strings -Wold-style-definition
 314       -Winit-self -Wmissing-include-dirs -Wno-multichar
 315       -Wnested-externs $NO_WARNINGS])
 316
 317 dnl define correct level for debugging messages
 318 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 319
 320 dnl used in examples
 321 AG_GST_DEFAULT_ELEMENTS
 322
 323 dnl *** plug-ins to include ***
 324
 325 dnl these are all the gst plug-ins, compilable without additional libs
 326 dnl videofilter is at the top because others depend on it
 327 AG_GST_CHECK_PLUGIN(alpha)
 328 AG_GST_CHECK_PLUGIN(apetag)
 329 AG_GST_CHECK_PLUGIN(audiofx)
 330 AG_GST_CHECK_PLUGIN(audioparsers)
 331 AG_GST_CHECK_PLUGIN(auparse)
 332 AG_GST_CHECK_PLUGIN(autodetect)
 333 AG_GST_CHECK_PLUGIN(avi)
 334 AG_GST_CHECK_PLUGIN(cutter)
 335 AG_GST_CHECK_PLUGIN(debugutils)
 336 AG_GST_CHECK_PLUGIN(deinterlace)
 337 AG_GST_CHECK_PLUGIN(dtmf)
 338 AG_GST_CHECK_PLUGIN(effectv)
 339 AG_GST_CHECK_PLUGIN(equalizer)
 340 AG_GST_CHECK_PLUGIN(flv)
 341 AG_GST_CHECK_PLUGIN(flx)
 342 AG_GST_CHECK_PLUGIN(goom)
 343 AG_GST_CHECK_PLUGIN(goom2k1)
 344 AG_GST_CHECK_PLUGIN(icydemux)
 345 AG_GST_CHECK_PLUGIN(id3demux)
 346 AG_GST_CHECK_PLUGIN(imagefreeze)
 347 AG_GST_CHECK_PLUGIN(interleave)
 348 AG_GST_CHECK_PLUGIN(isomp4)
 349 AG_GST_CHECK_PLUGIN(law)
 350 AG_GST_CHECK_PLUGIN(level)
 351 AG_GST_CHECK_PLUGIN(matroska)
 352 AG_GST_CHECK_PLUGIN(monoscope)
 353 AG_GST_CHECK_PLUGIN(multifile)
 354 AG_GST_CHECK_PLUGIN(multipart)
 355 AG_GST_CHECK_PLUGIN(replaygain)
 356 AG_GST_CHECK_PLUGIN(rtp)
 357 AG_GST_CHECK_PLUGIN(rtpmanager)
 358 AG_GST_CHECK_PLUGIN(rtsp)
 359 AG_GST_CHECK_PLUGIN(shapewipe)
 360 AG_GST_CHECK_PLUGIN(smpte)
 361 AG_GST_CHECK_PLUGIN(spectrum)
 362 AG_GST_CHECK_PLUGIN(udp)
 363 AG_GST_CHECK_PLUGIN(videobox)
 364 AG_GST_CHECK_PLUGIN(videocrop)
 365 AG_GST_CHECK_PLUGIN(videofilter)
 366 AG_GST_CHECK_PLUGIN(videomixer)
 367 AG_GST_CHECK_PLUGIN(wavenc)
 368 AG_GST_CHECK_PLUGIN(wavparse)
 369 AG_GST_CHECK_PLUGIN(y4m)
 370
 371 dnl disable experimental plug-ins
 372 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 373   AG_GST_DISABLE_PLUGIN(monoscope)
 374 fi
 375
 376 dnl *** sys plug-ins ***
 377
 378 echo
 379 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 380 echo
 381
 382 dnl DirectSound
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 384 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 385   HAVE_DIRECTSOUND="no"
 386   save_CFLAGS="$CFLAGS"
 387   save_LDFLAGS="$LDFLAGS"
 388   save_LIBS="$LIBS"
 389   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 390   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 391   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 392   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 393   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 394 #include <windows.h>
 395 #include <dxerr9.h>
 396 #include <dsound.h>
 397 ]], [[
 398   DXGetErrorString9 (0);
 399   DirectSoundCreate(NULL, NULL, NULL);
 400 ]])
 401 ],
 402     [HAVE_DIRECTSOUND="yes"],
 403     [HAVE_DIRECTSOUND="no"])
 404   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 405   CFLAGS=$save_CFLAGS
 406   LDFLAGS=$save_LDFLAGS
 407   LIBS=$save_LIBS
 408
 409   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 410     dnl this is much more than we want
 411     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 412     AC_SUBST(DIRECTSOUND_CFLAGS)
 413     AC_SUBST(DIRECTSOUND_LDFLAGS)
 414     AC_SUBST(DIRECTSOUND_LIBS)
 415   fi
 416   AC_SUBST(HAVE_DIRECTSOUND)
 417 ])
 418
 419 dnl *** Win32 WaveOut ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 421 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 422   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 423 ])
 424
 425 dnl *** OSS audio *** (Linux, *BSD)
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 427 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 428  HAVE_OSS="yes"
 429 dnl Linux and newer BSD versions :
 430  AC_CHECK_HEADER(sys/soundcard.h, [
 431    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 432    ] , [
 433 dnl Some old BSD versions and also newer OpenBSD versions :
 434    AC_CHECK_HEADER(soundcard.h, [
 435      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 436      ], [
 437   dnl Some old BSD versions :
 438      AC_CHECK_HEADER(machine/soundcard.h, [
 439        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 440          [Define if OSS includes are in /machine/])
 441        ], [
 442        HAVE_OSS="no"
 443      ])
 444    ])
 445  ])
 446 ])
 447
 448 dnl *** oss4 ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 450 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 451   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 452   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 453       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 454       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 455 ])
 456
 457 dnl *** Sun Audio ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 459 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 460   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 461 ])
 462
 463 dnl *** OSX Audio ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 465 have_ios="no"
 466 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 467   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 468     HAVE_OSX_AUDIO="yes",
 469     dnl *** Check for the iOS headers ***
 470     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 471       [HAVE_OSX_AUDIO="YES";have_ios="yes"], [HAVE_OSX_AUDIO="yes";have_ios="no"]
 472     )])
 473 ])
 474 if test "x$have_ios" = "xyes"; then
 475   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 476 fi
 477 AM_CONDITIONAL(HAVE_IOS, test "x$have_ios" = "xyes")
 478
 479 dnl *** OS X video ***
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 481 HAVE_OSX_VIDEO="no"
 482 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 483   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 484 ])
 485 dnl in case header OpenGL/gl.h is found on other platforms
 486 case "$host" in
 487   *-*darwin*)
 488     dnl do nothing
 489     ;;
 490   *)
 491     HAVE_OSX_VIDEO="no"
 492     ;;
 493 esac
 494
 495
 496 dnl *** Video 4 Linux 2 ***
 497 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 498 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 499 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 500 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 501   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 502   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 503 #include <sys/types.h>
 504 #ifdef __sun /* Solaris */
 505 #include <sys/types.h>
 506 #include <sys/videodev2.h>
 507 #elif __FreeBSD__
 508 #include <linux/videodev2.h>
 509 #else /* Linux */
 510 #include <linux/types.h>
 511 #define _LINUX_TIME_H
 512 #define __user
 513 #include <linux/videodev2.h>
 514 #endif
 515 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 516 #error too early v4l2 version or no v4l2 at all
 517 #endif
 518     ]], [[
 519 return 0;
 520     ]])],[
 521       HAVE_GST_V4L2="yes"
 522       AC_MSG_RESULT(yes)
 523     ],[
 524       HAVE_GST_V4L2="no"
 525       AC_MSG_RESULT(no)
 526
 527       HAVE_VIDEODEV=no
 528       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 529       [
 530         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 531       ])
 532
 533       if test "x$HAVE_VIDEODEV" = "xyes"; then
 534         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 535         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 536       else
 537         AC_MSG_WARN([video4linux2 was not found])
 538       fi
 539     ])
 540
 541   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 542     dnl check for missing v4l2_buffer declaration (see #135919)
 543     MISSING_DECL=0
 544     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 545     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 546 #include <sys/types.h>
 547 #ifdef __sun /* Solaris */
 548 #include <sys/types.h>
 549 #include <sys/videodev2.h>
 550 #elif __FreeBSD__
 551 #include <linux/videodev2.h>
 552 #else /* Linux */
 553 #include <linux/types.h>
 554 #define _LINUX_TIME_H
 555 #define __user
 556 #include <linux/videodev2.h>
 557 #endif
 558     ]], [[
 559 struct v4l2_buffer buf;
 560 buf.index = 0;
 561 return 0;
 562     ]])],[ AC_MSG_RESULT(yes) ],[ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 563     if [ test x$MISSING_DECL = x1 ]; then
 564       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 565     fi
 566
 567     dnl check for XOverlay libraries
 568     AG_GST_CHECK_XV
 569   fi
 570 ])
 571
 572 # Optional gudev for device probing
 573 AC_ARG_WITH([gudev],
 574   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 575   [],
 576   [with_gudev=check])
 577 if test x$HAVE_GST_V4L2 = xyes; then
 578   if test x$with_gudev != xno; then
 579       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 580           [ have_gudev=yes
 581             AC_DEFINE(HAVE_GUDEV, 1,
 582                [Whether gudev is available for device detection])
 583             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 584           ], [
 585           have_gudev=no
 586           ])
 587   else
 588     have_gudev=no
 589   fi
 590 fi
 591 AC_SUBST(GUDEV_CFLAGS)
 592 AC_SUBST(GUDEV_LIBS)
 593
 594 # Make libv4l2 non-automagic
 595 AC_ARG_WITH([libv4l2],
 596   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 597   [],
 598   [with_libv4l2=check])
 599 if test x$HAVE_GST_V4L2 = xyes; then
 600   if test x$with_libv4l2 != xno; then
 601       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 602           [ have_libv4l2=yes
 603             AC_DEFINE(HAVE_LIBV4L2, 1,
 604                 [Whether libv4l2 is available for video buffer conversion])
 605           ], [
 606           have_libv4l2=no
 607           ])
 608   else
 609     have_libv4l2=no
 610   fi
 611 fi
 612
 613 # Check if v4l2 support dmabuf
 614 if test x$HAVE_GST_V4L2 = xyes; then
 615         AC_CHECK_DECLS(V4L2_MEMORY_DMABUF,,,[
 616                                         #include <sys/types.h>
 617                                         #ifdef __sun /* Solaris */
 618                                         #include <sys/types.h>
 619                                         #include <sys/videodev2.h>
 620                                         #elif __FreeBSD__
 621                                         #include <linux/videodev2.h>
 622                                         #else /* Linux */
 623                                         #include <linux/types.h>
 624                                         #define _LINUX_TIME_H
 625                                         #define __user
 626                                         #include <linux/videodev2.h>
 627                                         #endif
 628                                         ])
 629 fi
 630
 631 dnl Check for X11
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 633 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 634                   [ximagesrc], [
 635   AC_PATH_XTRA
 636
 637   dnl now try to find the HEADER
 638   ac_cflags_save="$CFLAGS"
 639   ac_cppflags_save="$CPPFLAGS"
 640   CFLAGS="$CFLAGS $X_CFLAGS"
 641   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 642   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 643
 644   if test "x$HAVE_X" = "xno"
 645   then
 646     AC_MSG_NOTICE([cannot find X11 development files])
 647   else
 648     dnl this is much more than we want
 649     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 650     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 651     dnl it does not add the libs; therefore we add them here
 652     X_LIBS="$X_LIBS -lX11"
 653     AC_SUBST(X_CFLAGS)
 654     AC_SUBST(X_LIBS)
 655
 656     dnl check for Xfixes
 657     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 658     if test "x$HAVE_XFIXES" = "xyes"
 659     then
 660         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 661     fi
 662     AC_SUBST(XFIXES_LIBS)
 663     AC_SUBST(XFIXES_CFLAGS)
 664
 665     dnl check for Xdamage
 666     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 667     if test "x$HAVE_XDAMAGE" = "xyes"
 668     then
 669         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 670     fi
 671     AC_SUBST(XDAMAGE_LIBS)
 672     AC_SUBST(XDAMAGE_CFLAGS)
 673   fi
 674   AC_SUBST(HAVE_X)
 675   CFLAGS="$ac_cflags_save"
 676   CPPFLAGS="$ac_cppflags_save"
 677 ])
 678
 679 dnl FIXME: this should be rolled into the test above, it's just an additional
 680 dnl feature of the ximagesrc plug-in
 681 dnl This is the same as in gst-plugins-base
 682 dnl check for X Shm
 683 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 684 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 685   if test x$HAVE_X = xyes; then
 686     AC_CHECK_LIB(Xext, XShmAttach,
 687                  HAVE_XSHM="yes", HAVE_XSHM="no",
 688                  $X_LIBS)
 689     if test "x$HAVE_XSHM" = "xyes"; then
 690       XSHM_LIBS="-lXext"
 691     else
 692       dnl On AIX, it is in XextSam instead, but we still need -lXext
 693       AC_CHECK_LIB(XextSam, XShmAttach,
 694                    HAVE_XSHM="yes", HAVE_XSHM="no",
 695                    $X_LIBS)
 696       if test "x$HAVE_XSHM" = "xyes"; then
 697         XSHM_LIBS="-lXext -lXextSam"
 698       fi
 699     fi
 700   fi
 701 ], ,[
 702   AC_SUBST(HAVE_XSHM)
 703   AC_SUBST(XSHM_LIBS)
 704 ])
 705
 706 dnl for V4L2, we also need to know if we have XVIDEO
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 708 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 709                   [], [
 710   AG_GST_CHECK_XV
 711 ])
 712
 713 dnl *** ext plug-ins ***
 714 dnl keep this list sorted alphabetically !
 715
 716 if test "x$BUILD_EXTERNAL" = "xyes"; then
 717
 718 echo
 719 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 720 echo
 721
 722 dnl *** aalib ***
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 724 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 725   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 726   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 727 ])
 728
 729 dnl *** cairo ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 731 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 732   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 733 ])
 734
 735 dnl *** FLAC ***
 736 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 737 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 738   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 739 ])
 740
 741 dnl *** GDK pixbuf ***
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 743 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 744   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 745 ])
 746
 747 dnl *** Jack ***
 748 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 749 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 750   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 751   AC_SUBST(JACK_CFLAGS)
 752   AC_SUBST(JACK_LIBS)
 753
 754   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 755   if test x$HAVE_JACK_0_120_1 = xyes; then
 756     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 757   fi
 758   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 759   if test x$HAVE_JACK_1_9_7 = xyes; then
 760     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 761   fi
 762
 763 ])
 764
 765 dnl *** jpeg ***
 766 dnl FIXME: we could use header checks here as well IMO
 767 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 768 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 769   AC_ARG_WITH(jpeg-mmx,
 770     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 771   OLD_LIBS="$LIBS"
 772   if test x$with_jpeg_mmx != x; then
 773     LIBS="$LIBS -L$with_jpeg_mmx"
 774   fi
 775   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 776   JPEG_LIBS="$LIBS -ljpeg-mmx"
 777   LIBS="$OLD_LIBS"
 778   if test x$HAVE_JPEG != xyes; then
 779     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 780     JPEG_LIBS="-ljpeg"
 781   fi
 782   AC_SUBST(JPEG_LIBS)
 783 ])
 784
 785 dnl *** libcaca ***
 786 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 787 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 788   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 789 ])
 790
 791 dnl *** libdv ***
 792 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 793 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 794   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 795 ])
 796
 797 dnl *** libpng ***
 798 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 799 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 800   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 801 ])
 802
 803 dnl *** pulseaudio ***
 804 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 805 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 806
 807   dnl used in ext/pulse/pulseutil.c
 808   AC_CHECK_HEADERS([process.h])
 809
 810   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 811 ])
 812
 813 dnl *** dv1394 ***
 814 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 815 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 816   dnl first test for libraw1394 >= 2.0.0
 817   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 818   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 819   dnl now see how far we got
 820   if test x$HAVE_RAW1394 = xyes && \
 821      test x$HAVE_LIBIEC61883 = xyes; then
 822        AG_GST_CHECK_LIBHEADER(AVC1394,
 823         avc1394, avc1394_send_command, $RAW1394_LIBS,
 824         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 825        AG_GST_CHECK_LIBHEADER(ROM1394,
 826         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 827         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 828        if test x$HAVE_AVC1394 = xyes && \
 829           test x$HAVE_AVC1394 = xyes && \
 830           test x$HAVE_ROM1394 = xyes; then
 831           HAVE_DV1394=yes
 832           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 833           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 834           AC_SUBST(DV1394_CFLAGS)
 835           AC_SUBST(DV1394_LIBS)
 836         fi
 837   else
 838        if test x$HAVE_RAW1394 = xno; then
 839           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 840           AG_GST_CHECK_LIBHEADER(AVC1394,
 841            avc1394, avc1394_send_command, $RAW1394_LIBS,
 842            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 843           AG_GST_CHECK_LIBHEADER(ROM1394,
 844            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 845            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 846           if test x$HAVE_RAW1394 = xyes && \
 847              test x$HAVE_AVC1394 = xyes && \
 848              test x$HAVE_ROM1394 = xyes; then
 849              HAVE_DV1394=yes
 850              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 851              DV1394_CFLAGS="$RAW1394_CFLAGS"
 852              if test x$HAVE_LIBIEC61883 = xyes; then
 853                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 854                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 855              fi
 856              AC_SUBST(DV1394_CFLAGS)
 857              AC_SUBST(DV1394_LIBS)
 858            fi
 859          fi
 860   fi
 861 ])
 862 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 863
 864 dnl *** shout2 ***
 865 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 866 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 867   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 868 ])
 869
 870 dnl *** soup ***
 871 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 872 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 873   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26.1, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 874   AC_SUBST(SOUP_CFLAGS)
 875   AC_SUBST(SOUP_LIBS)
 876 ])
 877
 878 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 879 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 880 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 881 dnl   speex_jitter.h is 1.1.x only
 882 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 883 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 884   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 885   if test $HAVE_SPEEX = no
 886   then
 887     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 888       AC_CHECK_HEADER(speex/speex_jitter.h, [
 889         dnl speex 1.1.x :
 890         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 891           dnl speex 1.1.5 or + :
 892           HAVE_SPEEX="yes"
 893           SPEEX_LIBS="-lspeex"
 894           AC_SUBST(SPEEX_CFLAGS)
 895           AC_SUBST(SPEEX_LIBS)
 896         ],[
 897           HAVE_SPEEX="no"
 898         ])
 899       ],[
 900         dnl speex 1.0.x :
 901           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 902             dnl speex 1.0.4
 903             HAVE_SPEEX="yes"
 904             SPEEX_LIBS="-lspeex"
 905             AC_SUBST(SPEEX_CFLAGS)
 906             AC_SUBST(SPEEX_LIBS)
 907
 908             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 909               [defined if speex 1.0.x API detected])
 910         ],[
 911             HAVE_SPEEX="no"
 912             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 913         ], [
 914 #include <speex/speex.h>
 915         ])
 916       ])
 917     ])
 918   fi
 919 ])
 920
 921 dnl *** taglib ***
 922 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 923 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 924   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 925   if test "x$HAVE_CXX" != "xyes"; then
 926     USE_TAGLIB=false
 927     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 928   else
 929     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 930     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 931         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 932       ], [
 933         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 934     ])
 935     AC_SUBST(TAGLIB_CXXFLAGS)
 936   fi
 937 ])
 938
 939 dnl *** vpx ***
 940 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 941 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 942   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 943
 944   if test $HAVE_VPX = "yes"; then
 945     OLD_LIBS="$LIBS"
 946     OLD_CFLAGS="$CFLAGS"
 947     CFLAGS="$CFLAGS $VPX_CFLAGS"
 948     LIBS="$LIBS $VPX_LIBS"
 949     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 950       HAVE_VP8=yes
 951       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 952     ])
 953     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 954       HAVE_VP8=yes
 955       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 956     ])
 957     LIBS="$OLD_LIBS"
 958     CFLAGS="$OLD_CFLAGS"
 959   fi
 960   AC_SUBST(VPX_LIBS)
 961   AC_SUBST(VPX_CFLAGS)
 962 ])
 963
 964 dnl *** wavpack ***
 965 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 966 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 967   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 968     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 969       HAVE_WAVPACK=yes
 970       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 971     ],[
 972       HAVE_WAVPACK=no
 973     ])
 974   ])
 975   AC_SUBST(WAVPACK_CFLAGS)
 976   AC_SUBST(WAVPACK_LIBS)
 977 ])
 978
 979 dnl *** qtdemux & matroska prefer to have zlib ***
 980 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 981 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 982   AG_GST_CHECK_LIBHEADER(ZLIB,
 983     z, uncompress,, zlib.h, [
 984     HAVE_ZLIB="yes"
 985     ZLIB_LIBS="-lz"
 986     AC_SUBST(ZLIB_LIBS)
 987   ])
 988 ])
 989
 990 dnl *** matroska prefers to have bz2 ***
 991 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 992 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 993   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 994   AC_SUBST(BZ2_LIBS)
 995 ])
 996
 997 else
 998
 999 dnl not building plugins with external dependencies,
1000 dnl but we still need to set the conditionals
1001 AM_CONDITIONAL(USE_AALIB, false)
1002 AM_CONDITIONAL(USE_BZ2, false)
1003 AM_CONDITIONAL(USE_CAIRO, false)
1004 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1005 AM_CONDITIONAL(USE_DV1394, false)
1006 AM_CONDITIONAL(USE_FLAC, false)
1007 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1008 AM_CONDITIONAL(USE_GST_V4L2, false)
1009 AM_CONDITIONAL(USE_JACK, false)
1010 AM_CONDITIONAL(USE_JPEG, false)
1011 AM_CONDITIONAL(USE_LIBCACA, false)
1012 AM_CONDITIONAL(USE_LIBDV, false)
1013 AM_CONDITIONAL(USE_LIBIEC61883, false)
1014 AM_CONDITIONAL(USE_LIBPNG, false)
1015 AM_CONDITIONAL(USE_OSS, false)
1016 AM_CONDITIONAL(USE_OSS4, false)
1017 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1018 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1019 AM_CONDITIONAL(USE_PULSE, false)
1020 AM_CONDITIONAL(USE_SHOUT2, false)
1021 AM_CONDITIONAL(USE_SOUP, false)
1022 AM_CONDITIONAL(USE_SPEEX, false)
1023 AM_CONDITIONAL(USE_SUNAUDIO, false)
1024 AM_CONDITIONAL(USE_TAGLIB, false)
1025 AM_CONDITIONAL(USE_VPX, false)
1026 AM_CONDITIONAL(USE_WAVEFORM, false)
1027 AM_CONDITIONAL(USE_WAVPACK, false)
1028 AM_CONDITIONAL(USE_X, false)
1029 AM_CONDITIONAL(USE_XSHM, false)
1030 AM_CONDITIONAL(USE_XVIDEO, false)
1031 AM_CONDITIONAL(USE_ZLIB, false)
1032
1033 fi dnl of EXT plugins
1034
1035 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1036
1037 dnl Overview:
1038 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1039 dnl GST_*:              flags shared by all built objects
1040 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1041 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1042 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1043 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1044
1045 dnl GST_OPTION_CFLAGS
1046 if test "x$USE_DEBUG" = xyes; then
1047    PROFILE_CFLAGS="-g"
1048 fi
1049 AC_SUBST(PROFILE_CFLAGS)
1050
1051 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1052   dnl Define _only_ for git (not pre-releases or releases)
1053   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1054 else
1055   DEPRECATED_CFLAGS=""
1056 fi
1057 AC_SUBST(DEPRECATED_CFLAGS)
1058
1059 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1060 dnl at make time with e.g. make ERROR_CFLAGS=""
1061 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1062 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1063 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1064 AC_SUBST(GST_OPTION_CFLAGS)
1065 AC_SUBST(GST_OPTION_CXXFLAGS)
1066 AC_SUBST(GST_OPTION_OBJCFLAGS)
1067
1068 dnl our libraries need to be versioned correctly
1069 AC_SUBST(GST_LT_LDFLAGS)
1070
1071 dnl FIXME: do we want to rename to GST_ALL_* ?
1072 dnl prefer internal headers to already installed ones
1073 dnl also add builddir include for enumtypes and marshal
1074 dnl add ERROR_CFLAGS, but overridable
1075 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1076 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1077 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1078 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1079 AC_SUBST(GST_CFLAGS)
1080 AC_SUBST(GST_CXXFLAGS)
1081 AC_SUBST(GST_OBJCFLAGS)
1082 AC_SUBST(GST_LIBS)
1083
1084 dnl LDFLAGS really should only contain flags, not libs - they get added before
1085 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1086 GST_ALL_LDFLAGS="-no-undefined"
1087 AC_SUBST(GST_ALL_LDFLAGS)
1088
1089 dnl this really should only contain flags, not libs - they get added before
1090 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1091 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1092 AC_SUBST(GST_PLUGIN_LDFLAGS)
1093
1094 dnl *** output files ***
1095
1096 dnl keep this alphabetic per directory, please
1097 AC_CONFIG_FILES(
1098 Makefile
1099 gst/Makefile
1100 gst/alpha/Makefile
1101 gst/apetag/Makefile
1102 gst/audiofx/Makefile
1103 gst/audioparsers/Makefile
1104 gst/auparse/Makefile
1105 gst/autodetect/Makefile
1106 gst/avi/Makefile
1107 gst/cutter/Makefile
1108 gst/deinterlace/Makefile
1109 gst/dtmf/Makefile
1110 gst/debugutils/Makefile
1111 gst/effectv/Makefile
1112 gst/equalizer/Makefile
1113 gst/flv/Makefile
1114 gst/goom/Makefile
1115 gst/goom2k1/Makefile
1116 gst/id3demux/Makefile
1117 gst/icydemux/Makefile
1118 gst/imagefreeze/Makefile
1119 gst/interleave/Makefile
1120 gst/isomp4/Makefile
1121 gst/law/Makefile
1122 gst/level/Makefile
1123 gst/matroska/Makefile
1124 gst/monoscope/Makefile
1125 gst/multifile/Makefile
1126 gst/multipart/Makefile
1127 gst/replaygain/Makefile
1128 gst/rtp/Makefile
1129 gst/rtpmanager/Makefile
1130 gst/rtsp/Makefile
1131 gst/shapewipe/Makefile
1132 gst/smpte/Makefile
1133 gst/spectrum/Makefile
1134 gst/udp/Makefile
1135 gst/videobox/Makefile
1136 gst/videocrop/Makefile
1137 gst/videofilter/Makefile
1138 gst/videomixer/Makefile
1139 gst/wavenc/Makefile
1140 gst/wavparse/Makefile
1141 gst/flx/Makefile
1142 gst/y4m/Makefile
1143 ext/Makefile
1144 ext/aalib/Makefile
1145 ext/cairo/Makefile
1146 ext/dv/Makefile
1147 ext/flac/Makefile
1148 ext/gdk_pixbuf/Makefile
1149 ext/jack/Makefile
1150 ext/jpeg/Makefile
1151 ext/libcaca/Makefile
1152 ext/libpng/Makefile
1153 ext/pulse/Makefile
1154 ext/raw1394/Makefile
1155 ext/shout2/Makefile
1156 ext/soup/Makefile
1157 ext/speex/Makefile
1158 ext/taglib/Makefile
1159 ext/vpx/Makefile
1160 ext/wavpack/Makefile
1161 sys/Makefile
1162 sys/directsound/Makefile
1163 sys/oss/Makefile
1164 sys/oss4/Makefile
1165 sys/osxaudio/Makefile
1166 sys/osxvideo/Makefile
1167 sys/sunaudio/Makefile
1168 sys/v4l2/Makefile
1169 sys/waveform/Makefile
1170 sys/ximage/Makefile
1171 po/Makefile.in
1172 tests/Makefile
1173 tests/check/Makefile
1174 tests/examples/Makefile
1175 tests/examples/audiofx/Makefile
1176 tests/examples/cairo/Makefile
1177 tests/examples/equalizer/Makefile
1178 tests/examples/jack/Makefile
1179 tests/examples/level/Makefile
1180 tests/examples/pulse/Makefile
1181 tests/examples/rtp/Makefile
1182 tests/examples/shapewipe/Makefile
1183 tests/examples/spectrum/Makefile
1184 tests/examples/v4l2/Makefile
1185 tests/files/Makefile
1186 tests/icles/Makefile
1187 common/Makefile
1188 common/m4/Makefile
1189 m4/Makefile
1190 docs/Makefile
1191 docs/plugins/Makefile
1192 docs/version.entities
1193 pkgconfig/Makefile
1194 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1195 gst-plugins-good.spec
1196 )
1197
1198 dnl Create the config.h file for Visual Studio builds
1199 dnl Beware of spaces and /'s in some of the shell variable contents.
1200 sed \
1201     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1202     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1203     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1204     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1205     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1206     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1207     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1208     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1209     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1210     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1211     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1212     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1213     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1214     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1215     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1216     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1217     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1218     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1219     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1220     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1221     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1222     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1223     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1224     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1225     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1226     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1227     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1228     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1229     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1230     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1231     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1232     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1233     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1234     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1235     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1236     config.h.in >win32/common/config.h-new
1237
1238 AC_OUTPUT
1239
1240 AG_GST_OUTPUT_PLUGINS
1241 ORC_OUTPUT
1242