configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [41])
  34 m4_define([glib_micro_version], [2])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS:+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_cv_stack_grows=no
 129     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 130     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 131     # (Sorry, I don't know exactly what is the problem, but it is related to
 132     # floating point formatting and decimal point vs. comma.)
 133     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 134     # rigorous enough to notice, though.
 135     # So preset the autoconf cache variables.
 136     ac_cv_func_vsnprintf_c99=no
 137     ac_cv_func_snprintf_c99=no
 138     case "$host" in
 139     x86_64-*-*)
 140       LIB_EXE_MACHINE_FLAG=X64
 141       ;;
 142     esac
 143
 144     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 145     ;;
 146   *)
 147     glib_native_win32=no
 148     glib_pid_type=int
 149     ;;
 150 esac
 151 case $host in
 152   *-*-linux*)
 153     glib_os_linux=yes
 154     ;;
 155 esac
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158
 159 AC_MSG_CHECKING([for the Android])
 160 case $host in
 161   *android*)
 162     glib_native_android="yes"
 163     ;;
 164   *)
 165     glib_native_android="no"
 166     ;;
 167 esac
 168 AC_MSG_RESULT([$glib_native_android])
 169
 170 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 171
 172 glib_have_carbon=no
 173 AC_MSG_CHECKING([for Mac OS X Carbon support])
 174 AC_TRY_CPP([
 175 #include <Carbon/Carbon.h>
 176 #include <CoreServices/CoreServices.h>
 177 ], glib_have_carbon=yes)
 178
 179 AC_MSG_RESULT([$glib_have_carbon])
 180
 181 glib_have_cocoa=no
 182 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 183 AC_TRY_CPP([
 184 #include <Cocoa/Cocoa.h>
 185 #ifdef GNUSTEP_BASE_VERSION
 186 #error "Detected GNUstep, not Cocoa"
 187 #endif
 188 ], glib_have_cocoa=yes)
 189
 190 AC_MSG_RESULT([$glib_have_cocoa])
 191
 192 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 193 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 194 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 195 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 196 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 197 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 198
 199 AS_IF([test "$glib_native_win32" = "yes"], [
 200   AC_CHECK_TOOL(WINDRES, windres, no)
 201   if test "$WINDRES" = no; then
 202     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 203   fi
 204   AC_CHECK_TOOL(NM, nm, no)
 205   if test "$NM" = no; then
 206     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 207   fi
 208   AC_CHECK_TOOL(RANLIB, ranlib, :)
 209   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 210   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 211 ])
 212 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 213
 214 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 215   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 216   CARBON_LIBS="-Wl,-framework,Carbon"
 217   LDFLAGS="$LDFLAGS $CARBON_LIBS"
 218 ], [CARBON_LIBS=""])
 219
 220 AC_SUBST([CARBON_LIBS])
 221
 222 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
 223   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 224   COCOA_LIBS="-Wl,-framework,Foundation"
 225   LDFLAGS="$LDFLAGS $COCOA_LIBS"
 226 ], [COCOA_LIBS=""])
 227
 228 AC_SUBST([COCOA_LIBS])
 229
 230 dnl declare --enable-* args and collect ac_help strings
 231 AC_ARG_ENABLE(debug,
 232               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 233                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 234               enable_debug=glib_debug_default)
 235
 236 AC_ARG_ENABLE(gc_friendly,
 237               [AS_HELP_STRING([--enable-gc-friendly],
 238                               [turn on garbage collector friendliness [default=no]])],,
 239               [enable_gc_friendly=no])
 240 AC_ARG_ENABLE(mem_pools,
 241               [AS_HELP_STRING([--disable-mem-pools],
 242                               [disable all glib memory pools])],,
 243               [disable_mem_pools=no])
 244 AC_ARG_ENABLE(rebuilds,
 245               [AS_HELP_STRING([--disable-rebuilds],
 246                               [disable all source autogeneration rules])],,
 247               [enable_rebuilds=yes])
 248
 249 GLIB_TESTS
 250
 251 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 252 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 253   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 254   AC_MSG_RESULT([yes])
 255 ], [ AC_MSG_RESULT([no]) ])
 256
 257 AC_MSG_CHECKING([whether to disable memory pools])
 258 AS_IF([test "x$disable_mem_pools" = "xno"], [
 259   AC_MSG_RESULT([no])
 260 ], [
 261   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 262   AC_MSG_RESULT([yes])
 263 ])
 264
 265 dnl location to install runtime libraries, e.g. ../../lib to install
 266 dnl to /lib if libdir is /usr/lib
 267 AC_ARG_WITH(runtime-libdir,
 268            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 269                            [install runtime libraries relative to libdir])],
 270            [],
 271            [with_runtime_libdir=""])
 272 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 273 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 274 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 275 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 276 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 277
 278 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 279 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 280 AC_LANG_SAVE
 281 AC_LANG_CPLUSPLUS
 282 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 283 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 284 AC_LANG_RESTORE
 285
 286 AM_PROG_CC_C_O
 287 AC_PROG_INSTALL
 288
 289 AC_SYS_LARGEFILE
 290
 291 PKG_PROG_PKG_CONFIG(0.16)
 292
 293 if test "x$enable_debug" = "xyes"; then
 294   if test "x$cflags_set" != "x" ; then
 295       case " $CFLAGS " in
 296       *[[\ \    ]]-g[[\ \       ]]*) ;;
 297       *) CFLAGS="$CFLAGS -g" ;;
 298       esac
 299   fi
 300   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 301 else
 302   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 303
 304   if test "x$enable_debug" = "xno"; then
 305     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 306   fi
 307 fi
 308
 309 # Ensure MSVC-compatible struct packing convention is used when
 310 # compiling for Win32 with gcc.
 311 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 312 # gcc2 uses "-fnative-struct".
 313 if test x"$glib_native_win32" = xyes; then
 314   if test x"$GCC" = xyes; then
 315     msnative_struct=''
 316     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 317     if test -z "$ac_cv_prog_CC"; then
 318       our_gcc="$CC"
 319     else
 320       our_gcc="$ac_cv_prog_CC"
 321     fi
 322     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 323       2.)
 324         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 325           msnative_struct='-fnative-struct'
 326         fi
 327         ;;
 328       *)
 329         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 330           msnative_struct='-mms-bitfields'
 331         fi
 332         ;;
 333     esac
 334     if test x"$msnative_struct" = x ; then
 335       AC_MSG_RESULT([no way])
 336       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 337     else
 338       CFLAGS="$CFLAGS $msnative_struct"
 339       AC_MSG_RESULT([${msnative_struct}])
 340     fi
 341   fi
 342 fi
 343 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 344 AC_SUBST(GLIB_EXTRA_CFLAGS)
 345
 346 AC_EXEEXT
 347
 348 # define a MAINT-like variable REBUILD which is set if Perl
 349 # and awk are found, so autogenerated sources can be rebuilt
 350 AC_PROG_AWK
 351 AC_CHECK_PROGS(PERL, [perl5 perl])
 352 # We would like indent, but don't require it.
 353 AC_CHECK_PROG(INDENT, indent, indent)
 354 REBUILD=\#
 355 if test "x$enable_rebuilds" = "xyes" && \
 356      test -n "$PERL" && \
 357      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 358      test -n "$AWK" ; then
 359   REBUILD=
 360 fi
 361 AC_SUBST(REBUILD)
 362
 363 # Need full path to Perl for glib-mkenums
 364 #
 365 if test "x$PERL" != x ; then
 366   AC_PATH_PROG(PERL_PATH, [$PERL])
 367 fi
 368 if test "x$PERL_PATH" = x ; then
 369   PERL_PATH="/usr/bin/env perl"
 370 fi
 371 AC_SUBST(PERL_PATH)
 372
 373 # option to specify python interpreter to use; this just sets $PYTHON, so that
 374 # we will fallback to reading $PYTHON if --with-python is not given, and
 375 # python.m4 will get the expected input
 376 AC_ARG_WITH(python,
 377             AS_HELP_STRING([--with-python=PATH],
 378                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 379             [PYTHON="$withval"], [])
 380 if test x"$PYTHON" = xyes; then
 381   AC_MSG_ERROR([--with-python option requires a path or program argument])
 382 fi
 383 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 384
 385
 386 dnl ***********************
 387 dnl *** Tests for iconv ***
 388 dnl ***********************
 389 dnl
 390 dnl We do this before the gettext checks, to avoid distortion
 391
 392 dnl On Windows we use a native implementation
 393
 394 AS_IF([ test x"$glib_native_win32" = xyes], [
 395   with_libiconv=native
 396 ], [
 397   AC_ARG_WITH(libiconv,
 398               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 399                               [use the libiconv library])],,
 400               [with_libiconv=maybe])
 401
 402   found_iconv=no
 403   case $with_libiconv in
 404     maybe)
 405       # Check in the C library first
 406       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 407       # Check if we have GNU libiconv
 408       if test $found_iconv = "no"; then
 409         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 410       fi
 411       # Check if we have a iconv in -liconv, possibly from vendor
 412       if test $found_iconv = "no"; then
 413         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 414       fi
 415       ;;
 416     no)
 417       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 418       ;;
 419     gnu|yes)
 420       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 421       ;;
 422     native)
 423       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 424       ;;
 425   esac
 426
 427   if test "x$found_iconv" = "xno" ; then
 428      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 429   fi
 430 ])
 431
 432 dnl
 433 dnl zlib support
 434 dnl
 435 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 436 AS_IF([test "x$found_zlib" = "xno"], [
 437   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 438   if test "x$found_zlib" = "xno" ; then
 439     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 440   fi
 441   ZLIB_LIBS='-lz'
 442   AC_SUBST(ZLIB_LIBS)
 443 ])
 444
 445 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 446 AC_SUBST(LIBFFI_CFLAGS)
 447 AC_SUBST(LIBFFI_LIBS)
 448
 449 dnl
 450 dnl gettext support
 451 dnl
 452
 453 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 454 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 455 GLIB_GNU_GETTEXT
 456
 457 if test "$gt_cv_have_gettext" != "yes" ; then
 458   AC_MSG_ERROR([
 459 *** You must have either have gettext support in your C library, or use the
 460 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 461 ])
 462 fi
 463
 464 LIBS="$INTLLIBS $LIBS"
 465
 466 GETTEXT_PACKAGE=glib20
 467 AC_SUBST(GETTEXT_PACKAGE)
 468 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 469   [Define the gettext package to be used])
 470
 471 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 472
 473 dnl
 474 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 475 dnl
 476
 477 AS_IF([test x"$glib_native_win32" != xyes], [
 478   if test x$with_libiconv != xno ; then
 479     case " $INTLLIBS " in
 480     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 481     *) ICONV_LIBS="-liconv" ;;
 482     esac
 483   fi
 484 ])
 485 AC_SUBST(ICONV_LIBS)
 486
 487 case $with_libiconv in
 488   gnu)
 489     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 490     ;;
 491   native)
 492     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 493     ;;
 494 esac
 495
 496 dnl Initialize libtool
 497 LT_PREREQ([2.2])
 498 LT_INIT([disable-static win32-dll])
 499 dnl when using libtool 2.x create libtool early, because it's used in configure
 500 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 501
 502
 503 AS_IF([test "$glib_native_win32" = "yes"], [
 504   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 505     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 506   fi
 507   if test x$enable_static = xyes; then
 508     glib_win32_static_compilation=yes
 509     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 510 #define GOBJECT_STATIC_COMPILATION 1"
 511     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 512   fi
 513 ])
 514 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 515
 516 # Checks for library functions.
 517 AC_FUNC_ALLOCA
 518 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 519 AC_CHECK_FUNCS(timegm gmtime_r)
 520
 521 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 522   [AC_TRY_LINK([#include <unistd.h>
 523     extern int __libc_enable_secure;],
 524     [return __libc_enable_secure;],
 525    glib_cv_have_libc_enable_secure=yes,
 526    glib_cv_have_libc_enable_secure=no)])
 527 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 528    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 529      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 530 ])
 531
 532 AC_CHECK_SIZEOF(char)
 533 AC_CHECK_SIZEOF(short)
 534 AC_CHECK_SIZEOF(long)
 535 AC_CHECK_SIZEOF(int)
 536 AC_CHECK_SIZEOF(void *)
 537 AC_CHECK_SIZEOF(long long)
 538 AC_CHECK_SIZEOF(__int64)
 539
 540 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 541   [AC_TRY_LINK([#include <signal.h>
 542      #include <sys/types.h>
 543      sig_atomic_t val = 42;],
 544     [return val == 42 ? 0 : 1],
 545    ac_cv_type_sig_atomic_t=yes,
 546    ac_cv_type_sig_atomic_t=no)])
 547 if test x$ac_cv_type_sig_atomic_t = xyes; then
 548    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 549      [Define if you have the 'sig_atomic_t' type.])
 550 fi
 551
 552 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 553   :
 554 else
 555   AC_MSG_ERROR([
 556 *** GLib requires a 64 bit type. You might want to consider
 557 *** using the GNU C compiler.
 558 ])
 559 fi
 560
 561 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 562         # long long is a 64 bit integer.
 563         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 564         AC_CACHE_VAL(glib_cv_long_long_format,[
 565                 for format in ll q I64; do
 566                   AC_TRY_RUN([#include <stdio.h>
 567                         int main()
 568                         {
 569                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 570                           char buffer[1000];
 571                           sprintf (buffer, "%${format}u", a);
 572                           sscanf (buffer, "%${format}u", &b);
 573                           exit (b!=a);
 574                         }
 575                         ],
 576                         [glib_cv_long_long_format=${format}
 577                         break],
 578                         [],[:])
 579                 done])
 580         AS_IF([ test -n "$glib_cv_long_long_format"], [
 581           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 582           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 583           if test x"$glib_cv_long_long_format" = xI64; then
 584             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 585           fi
 586         ], [AC_MSG_RESULT(none)])
 587 ],[ test x$ac_cv_sizeof___int64 = x8], [
 588         # __int64 is a 64 bit integer.
 589         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 590         # We know this is MSVCRT.DLL, and what the formats are
 591         glib_cv_long_long_format=I64
 592         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 593         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 594         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 595 ])
 596
 597 AC_C_CONST
 598
 599 dnl
 600 dnl check in which direction the stack grows
 601 dnl
 602 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 603         AC_TRY_RUN([
 604         volatile int *a = 0, *b = 0;
 605         void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
 606         int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
 607         ],
 608         glib_cv_stack_grows=yes
 609         ,
 610         glib_cv_stack_grows=no
 611         ,)
 612 ])
 613
 614 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 615 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 616 dnl actually supported.
 617 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 618         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 619         __inline int foo () { return 0; }
 620         int main () { return foo (); }
 621         ]])],
 622         glib_cv_has__inline=yes
 623         ,
 624         glib_cv_has__inline=no
 625         ,)
 626 ])
 627 case x$glib_cv_has__inline in
 628 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 629 esac
 630 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 631         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 632         __inline__ int foo () { return 0; }
 633         int main () { return foo (); }
 634         ]])],
 635         glib_cv_has__inline__=yes
 636         ,
 637         glib_cv_has__inline__=no
 638         ,)
 639 ])
 640 case x$glib_cv_has__inline__ in
 641 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 642 esac
 643 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 644         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 645         #undef inline
 646         inline int foo () { return 0; }
 647         int main () { return foo (); }
 648         ]])],
 649         glib_cv_hasinline=yes
 650         ,
 651         glib_cv_hasinline=no
 652         ,)
 653 ])
 654 case x$glib_cv_hasinline in
 655 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 656 esac
 657
 658 # if we can use inline functions in headers
 659 AC_MSG_CHECKING(if inline functions in headers work)
 660 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 661 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 662 #  undef inline
 663 #  define inline __inline__
 664 #elif !defined (G_HAVE_INLINE)
 665 #  undef inline
 666 #  if defined (G_HAVE___INLINE__)
 667 #    define inline __inline__
 668 #  elif defined (G_HAVE___INLINE)
 669 #    define inline __inline
 670 #  endif
 671 #endif
 672
 673 int glib_test_func2 (int);
 674
 675 static inline int
 676 glib_test_func1 (void) {
 677   return glib_test_func2 (1);
 678 }
 679
 680 int
 681 main (void) {
 682   int i = 1;
 683 }]])],[g_can_inline=yes],[g_can_inline=no])
 684 AC_MSG_RESULT($g_can_inline)
 685
 686 # check for flavours of varargs macros
 687 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 688 AC_TRY_COMPILE([],[
 689 int a(int p1, int p2, int p3);
 690 #define call_a(...) a(1,__VA_ARGS__)
 691 call_a(2,3);
 692 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 693 AC_MSG_RESULT($g_have_iso_c_varargs)
 694
 695 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 696 AS_IF([test "$CXX" = ""], [
 697 dnl No C++ compiler
 698   g_have_iso_cxx_varargs=no
 699 else
 700   AC_LANG_CPLUSPLUS
 701   AC_TRY_COMPILE([],[
 702 int a(int p1, int p2, int p3);
 703 #define call_a(...) a(1,__VA_ARGS__)
 704 call_a(2,3);
 705 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 706   AC_LANG_C
 707 ])
 708 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 709
 710 AC_MSG_CHECKING(for GNUC varargs macros)
 711 AC_TRY_COMPILE([],[
 712 int a(int p1, int p2, int p3);
 713 #define call_a(params...) a(1,params)
 714 call_a(2,3);
 715 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 716 AC_MSG_RESULT($g_have_gnuc_varargs)
 717
 718 # check for GNUC visibility support
 719 AC_MSG_CHECKING(for GNUC visibility attribute)
 720 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 721 void
 722 __attribute__ ((visibility ("hidden")))
 723      f_hidden (void)
 724 {
 725 }
 726 void
 727 __attribute__ ((visibility ("internal")))
 728      f_internal (void)
 729 {
 730 }
 731 void
 732 __attribute__ ((visibility ("protected")))
 733      f_protected (void)
 734 {
 735 }
 736 void
 737 __attribute__ ((visibility ("default")))
 738      f_default (void)
 739 {
 740 }
 741 int main (void)
 742 {
 743         f_hidden();
 744         f_internal();
 745         f_protected();
 746         f_default();
 747         return 0;
 748 }
 749 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 750 AC_MSG_RESULT($g_have_gnuc_visibility)
 751 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 752
 753 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 754 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 755 #else
 756 # include "error: this is not Sun Studio."
 757 #endif
 758 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 759 AC_MSG_RESULT($g_have_sunstudio_visibility)
 760 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 761
 762 # check for bytesex stuff
 763 AC_C_BIGENDIAN
 764 if test x$ac_cv_c_bigendian = xuniversal ; then
 765 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 766 #else
 767 #error Not a big endian.
 768 #endif],
 769     ac_cv_c_bigendian=yes
 770     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 771 #else
 772 #error Not a little endian.
 773 #endif],
 774     ac_cv_c_bigendian=no
 775     ,AC_MSG_WARN([Could not determine endianness.])))
 776 fi
 777
 778
 779 # check for header files
 780 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
 781 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
 782 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 783 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 784 AC_CHECK_HEADERS([linux/magic.h sys/prctl.h])
 785
 786 # Some versions of MSC lack these
 787 AC_CHECK_HEADERS([dirent.h sys/time.h])
 788
 789 # We don't care about this, but we need to keep including it in
 790 # glibconfig.h for backward compatibility
 791 AC_CHECK_HEADERS([values.h])
 792
 793 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 794 [#if HAVE_SYS_PARAM_H
 795  #include <sys/param.h>
 796  #endif
 797 ])
 798 AC_CHECK_FUNCS(sysctlbyname)
 799
 800 AC_HEADER_MAJOR
 801 AC_CHECK_HEADERS([xlocale.h])
 802
 803 # check for structure fields
 804 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 805 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 806 #include <sys/stat.h>
 807 #ifdef G_OS_UNIX
 808 #include <unistd.h>
 809 #endif
 810 #ifdef HAVE_SYS_STATFS_H
 811 #include <sys/statfs.h>
 812 #endif
 813 #ifdef HAVE_SYS_PARAM_H
 814 #include <sys/param.h>
 815 #endif
 816 #ifdef HAVE_SYS_MOUNT_H
 817 #include <sys/mount.h>
 818 #endif])
 819 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 820 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 821 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 822 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 823
 824 AC_STRUCT_DIRENT_D_TYPE
 825
 826 # Checks for libcharset
 827 AM_LANGINFO_CODESET
 828 gl_GLIBC21
 829
 830 # check additional type sizes
 831 AC_CHECK_SIZEOF(size_t)
 832
 833 dnl Try to figure out whether gsize should be long or int
 834 AC_MSG_CHECKING([for the appropriate definition for size_t])
 835
 836 case $ac_cv_sizeof_size_t in
 837   $ac_cv_sizeof_short)
 838       glib_size_type=short
 839       ;;
 840   $ac_cv_sizeof_int)
 841       glib_size_type=int
 842       ;;
 843   $ac_cv_sizeof_long)
 844       glib_size_type=long
 845       ;;
 846   $ac_cv_sizeof_long_long)
 847       glib_size_type='long long'
 848       ;;
 849   $ac_cv_sizeof__int64)
 850       glib_size_type='__int64'
 851       ;;
 852   *)  AC_MSG_ERROR([No type matching size_t in size])
 853       ;;
 854 esac
 855
 856 dnl If int/long are the same size, we see which one produces
 857 dnl warnings when used in the location as size_t. (This matters
 858 dnl on AIX with xlc)
 859 dnl
 860 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 861        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 862   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 863 #if defined(_AIX) && !defined(__GNUC__)
 864 #pragma options langlvl=stdc89
 865 #endif
 866 #include <stddef.h>
 867 int main ()
 868 {
 869   size_t s = 1;
 870   unsigned int *size_int = &s;
 871   return (int)*size_int;
 872 }
 873     ]])],glib_size_type=int,
 874       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 875 #if defined(_AIX) && !defined(__GNUC__)
 876 #pragma options langlvl=stdc89
 877 #endif
 878 #include <stddef.h>
 879 int main ()
 880 {
 881    size_t s = 1;
 882    unsigned long *size_long = &s;
 883    return (int)*size_long;
 884 }
 885         ]])],glib_size_type=long)])
 886 ])
 887
 888 AC_MSG_RESULT(unsigned $glib_size_type)
 889
 890 AC_CHECK_SIZEOF(ssize_t)
 891
 892 dnl Try to figure out whether gssize should be long or int
 893 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 894
 895 case $ac_cv_sizeof_ssize_t in
 896   $ac_cv_sizeof_short)
 897       glib_ssize_type=short
 898       ;;
 899   $ac_cv_sizeof_int)
 900       glib_ssize_type=int
 901       ;;
 902   $ac_cv_sizeof_long)
 903       glib_ssize_type=long
 904       ;;
 905   $ac_cv_sizeof_long_long)
 906       glib_ssize_type='long long'
 907       ;;
 908   $ac_cv_sizeof__int64)
 909       glib_ssize_type='__int64'
 910       ;;
 911   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 912       ;;
 913 esac
 914
 915 dnl If int/long are the same size, we see which one produces
 916 dnl warnings when used in the location as ssize_t. (This matters
 917 dnl on Android where ssize_t is long and size_t is unsigned int)
 918 dnl
 919 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 920        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 921   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 922 #if defined(_AIX) && !defined(__GNUC__)
 923 #pragma options langlvl=stdc89
 924 #endif
 925 #include <stddef.h>
 926 #ifdef HAVE_INTTYPES_H
 927 # include <inttypes.h>
 928 #endif
 929 #ifdef HAVE_STDINT_H
 930 # include <stdint.h>
 931 #endif
 932 #include <sys/types.h>
 933 int main ()
 934 {
 935   ssize_t s = 1;
 936   int *size_int = &s;
 937   return (int)*size_int;
 938 }
 939     ]])],glib_ssize_type=int,
 940       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 941 #if defined(_AIX) && !defined(__GNUC__)
 942 #pragma options langlvl=stdc89
 943 #endif
 944 #include <stddef.h>
 945 #ifdef HAVE_INTTYPES_H
 946 # include <inttypes.h>
 947 #endif
 948 #ifdef HAVE_STDINT_H
 949 # include <stdint.h>
 950 #endif
 951 #include <sys/types.h>
 952 int main ()
 953 {
 954    ssize_t s = 1;
 955    long *size_long = &s;
 956    return (int)*size_long;
 957 }
 958         ]])],glib_ssize_type=long)])
 959 ])
 960
 961 AC_MSG_RESULT($glib_ssize_type)
 962
 963 # Check for some functions
 964 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 965 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
 966 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
 967 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
 968 AC_CHECK_FUNCS(splice)
 969 AC_CHECK_FUNCS(prlimit)
 970
 971 # To avoid finding a compatibility unusable statfs, which typically
 972 # successfully compiles, but warns to use the newer statvfs interface:
 973 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 974 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 975
 976 AC_MSG_CHECKING([whether to use statfs or statvfs])
 977 # Some systems have both statfs and statvfs, pick the most "native" for these
 978 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 979    [
 980    # on solaris and irix, statfs doesn't even have the f_bavail field
 981    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
 982       [ac_cv_func_statfs=no],
 983    # else, at least on linux, statfs is the actual syscall
 984       [ac_cv_func_statvfs=no])
 985    ])
 986
 987 AS_IF([test x$ac_cv_func_statfs = xyes],
 988       [
 989          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
 990          AC_MSG_RESULT([statfs])
 991       ],
 992       [test x$ac_cv_func_statvfs = xyes],
 993       [
 994          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
 995          AC_MSG_RESULT([statvfs])
 996       ],
 997       [  AC_MSG_RESULT([neither])])
 998
 999 AC_CHECK_HEADERS(crt_externs.h)
1000 AC_CHECK_FUNCS(_NSGetEnviron)
1001
1002 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1003
1004 # Internet address families
1005 if test $glib_native_win32 = yes; then
1006   glib_inet_includes=["
1007 #include <winsock2.h>
1008   "]
1009 else
1010   glib_inet_includes=["
1011 #include <sys/types.h>
1012 #include <sys/socket.h>
1013   "]
1014 fi
1015
1016 glib_failed=false
1017 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1018 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1019 # winsock defines this even though it doesn't support it
1020 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1021 if $glib_failed ; then
1022   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1023 fi
1024
1025 glib_failed=false
1026 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1027 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1028 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1029 if $glib_failed ; then
1030   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1031 fi
1032
1033 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname)
1034
1035 AS_IF([test $glib_native_win32 = yes], [
1036   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1037   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1038   # they aren't present at run-time (on Windows 2000).
1039   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1040   AC_SUBST(WSPIAPI_INCLUDE)
1041 ], [
1042   # Android does not have C_IN in public headers, we define it wherever necessary
1043   AS_IF([test $glib_native_android != yes], [
1044     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1045     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1046                                         #include <arpa/nameser.h>],
1047                                        [int qclass = C_IN;])],
1048                       [AC_MSG_RESULT([no])],
1049                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1050                                                            #include <arpa/nameser.h>
1051                                                            #include <arpa/nameser_compat.h>],
1052                                                           [int qclass = C_IN;])],
1053                                          [AC_MSG_RESULT([yes])
1054                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1055                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1056   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1057
1058   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1059   NETWORK_LIBS=""
1060   AC_MSG_CHECKING([for res_query])
1061   AC_TRY_LINK([#include <sys/types.h>
1062                #include <netinet/in.h>
1063                #include <arpa/nameser.h>
1064                #include <resolv.h>
1065               ],[
1066                res_query("test", 0, 0, (void *)0, 0);
1067               ],[AC_MSG_RESULT([yes])],
1068               [save_libs="$LIBS"
1069                LIBS="-lresolv $LIBS"
1070                AC_TRY_LINK([#include <sys/types.h>
1071                             #include <netinet/in.h>
1072                             #include <arpa/nameser.h>
1073                             #include <resolv.h>
1074                            ],[
1075                             res_query("test", 0, 0, (void *)0, 0);
1076                            ],[AC_MSG_RESULT([in -lresolv])
1077                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1078                            [LIBS="-lbind $save_libs"
1079                             AC_TRY_LINK([#include <resolv.h>],
1080                                         [res_query("test", 0, 0, (void *)0, 0);],
1081                                         [AC_MSG_RESULT([in -lbind])
1082                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1083                                         [AC_MSG_ERROR(not found)])])
1084                LIBS="$save_libs"])
1085   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1086                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1087                                         [AC_MSG_ERROR(Could not find socket())]))
1088   save_libs="$LIBS"
1089   LIBS="$LIBS $NETWORK_LIBS"
1090   AC_MSG_CHECKING([for res_init])
1091   AC_TRY_LINK([#include <sys/types.h>
1092                #include <netinet/in.h>
1093                #include <arpa/nameser.h>
1094                #include <resolv.h>
1095               ],[
1096                res_init();
1097               ],[AC_MSG_RESULT([yes])
1098                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1099               ],[AC_MSG_RESULT([no])])
1100   LIBS="$save_libs"
1101 ])
1102 AC_SUBST(NETWORK_LIBS)
1103
1104 AC_CHECK_HEADER([linux/netlink.h],
1105                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1106                 [#include <sys/socket.h>])
1107 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1108
1109 AC_CHECK_TYPE([struct ip_mreqn], [
1110               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1111               [#include <netinet/in.h>])
1112
1113 case $host in
1114   *-*-solaris* )
1115      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1116      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1117      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1118      ;;
1119 esac
1120
1121 dnl
1122 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1123 dnl
1124 AS_IF([test "$ac_cv_func_statfs" = yes], [
1125   AC_MSG_CHECKING([number of arguments to statfs()])
1126   AC_TRY_COMPILE([#include <unistd.h>
1127   #ifdef HAVE_SYS_PARAM_H
1128   #include <sys/param.h>
1129   #endif
1130   #ifdef HAVE_SYS_VFS_H
1131   #include <sys/vfs.h>
1132   #endif
1133   #ifdef HAVE_SYS_MOUNT_H
1134   #include <sys/mount.h>
1135   #endif
1136   #ifdef HAVE_SYS_STATFS_H
1137   #include <sys/statfs.h>
1138   #endif], [struct statfs st;
1139   statfs(NULL, &st);],[
1140     AC_MSG_RESULT([2])
1141     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1142     AC_TRY_COMPILE([#include <unistd.h>
1143   #ifdef HAVE_SYS_PARAM_H
1144   #include <sys/param.h>
1145   #endif
1146   #ifdef HAVE_SYS_VFS_H
1147   #include <sys/vfs.h>
1148   #endif
1149   #ifdef HAVE_SYS_MOUNT_H
1150   #include <sys/mount.h>
1151   #endif
1152   #ifdef HAVE_SYS_STATFS_H
1153   #include <sys/statfs.h>
1154   #endif], [struct statfs st;
1155   statfs(NULL, &st, sizeof (st), 0);],[
1156       AC_MSG_RESULT([4])
1157       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1158       AC_MSG_RESULT(unknown)
1159       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1160 ])
1161
1162 dnl
1163 dnl open takes O_DIRECTORY as an option
1164 dnl
1165 AC_MSG_CHECKING([open() option O_DIRECTORY])
1166 AC_TRY_COMPILE([#include <fcntl.h>
1167 #include <sys/types.h>
1168 #include <sys/stat.h>],
1169 [open(0, O_DIRECTORY, 0);],[
1170         AC_MSG_RESULT([yes])
1171         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1172         AC_MSG_RESULT([no])])
1173
1174 #
1175 # Check whether to use an included printf
1176 #
1177 AC_FUNC_VSNPRINTF_C99
1178 AC_FUNC_PRINTF_UNIX98
1179
1180 AC_ARG_ENABLE(included-printf,
1181               [AS_HELP_STRING([--enable-included-printf],
1182                               [use included printf [default=auto]])],
1183               enable_included_printf="$enableval")
1184
1185 need_included_printf=no
1186 if test "x$enable_included_printf" = "xyes" ; then
1187   need_included_printf=yes
1188 fi
1189 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1190   need_included_printf=yes
1191 fi
1192 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1193   need_included_printf=yes
1194 fi
1195 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1196    test -z "$glib_cv_long_long_format" ; then
1197   need_included_printf=yes
1198 fi
1199
1200 if test "x$enable_included_printf" = "xno" &&
1201    test "x$need_included_printf" = "xyes" ; then
1202   AC_MSG_ERROR([
1203 *** Your C library's printf doesn't appear to have the features that
1204 *** GLib needs, but you specified --enable-included-printf=no.])
1205 fi
1206
1207 enable_included_printf=$need_included_printf
1208
1209 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1210 AS_IF([test "$enable_included_printf" != "yes"], [
1211   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1212 ], [
1213   if test -z "$glib_cv_long_long_format" ; then
1214     glib_cv_long_long_format="ll"
1215   fi
1216   AC_DEFINE(HAVE_VASPRINTF,1)
1217 ])
1218
1219 # Checks needed for gnulib vasnprintf
1220 bh_C_SIGNED
1221 jm_AC_TYPE_LONG_LONG
1222 gt_TYPE_LONGDOUBLE
1223 gt_TYPE_WCHAR_T
1224 gt_TYPE_WINT_T
1225 AC_TYPE_SIZE_T
1226 AC_CHECK_TYPES(ptrdiff_t)
1227 jm_AC_TYPE_INTMAX_T
1228 AC_CHECK_FUNCS([snprintf wcslen])
1229 AC_FUNC_SNPRINTF_C99
1230
1231 # Check if <sys/select.h> needs to be included for fd_set
1232 AC_MSG_CHECKING([for fd_set])
1233 AC_TRY_COMPILE([#include <sys/types.h>],
1234         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1235 AS_IF([test "$gtk_ok" = "yes"], [
1236     AC_MSG_RESULT([yes, found in sys/types.h])
1237 ], [
1238     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1239     if test "$gtk_ok" = "yes"; then
1240         # *** FIXME: give it a different name
1241         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1242         AC_MSG_RESULT([yes, found in sys/select.h])
1243     else
1244         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1245         AC_MSG_RESULT(no)
1246     fi
1247 ])
1248
1249 dnl Check for nl_langinfo and CODESET
1250 AC_LANG_SAVE
1251 AC_LANG_C
1252 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1253         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1254                        [char *codeset = nl_langinfo (CODESET);])],
1255                 [glib_cv_langinfo_codeset=yes],
1256                 [glib_cv_langinfo_codeset=no])])
1257 if test x$glib_cv_langinfo_codeset = xyes; then
1258   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1259 fi
1260
1261 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1262 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1263         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1264                  [char *str;
1265                  str = nl_langinfo (PM_STR);
1266                  str = nl_langinfo (D_T_FMT);
1267                  str = nl_langinfo (D_FMT);
1268                  str = nl_langinfo (T_FMT);
1269                  str = nl_langinfo (T_FMT_AMPM);
1270                  str = nl_langinfo (MON_1);
1271                  str = nl_langinfo (ABMON_12);
1272                  str = nl_langinfo (DAY_1);
1273                  str = nl_langinfo (ABDAY_7);])],
1274                 [glib_cv_langinfo_time=yes],
1275                 [glib_cv_langinfo_time=no])])
1276 if test x$glib_cv_langinfo_time = xyes; then
1277   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1278 fi
1279
1280 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1281 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1282         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1283                 [char *str;
1284                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1285                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1286                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1287                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1288                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1289                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1290                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1291                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1292                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1293                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1294                 [glib_cv_langinfo_outdigit=yes],
1295                 [glib_cv_langinfo_outdigit=no])])
1296 if test x$glib_cv_langinfo_outdigit = xyes; then
1297   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1298 fi
1299 AC_LANG_RESTORE
1300
1301 dnl ****************************************
1302 dnl *** posix_memalign                   ***
1303 dnl ****************************************
1304 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1305 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1306     glib_cv_compliant_posix_memalign=0
1307     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1308         AC_TRY_RUN([
1309                 #define _XOPEN_SOURCE 600
1310                 #include <stdlib.h> /* posix_memalign() should be defined here */
1311                 /* some systems break if #include <malloc.h> used */
1312                 static void test_memalign (size_t boundary, size_t size) {
1313                     void *mem = 0;
1314                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1315                         exit (1);
1316                     else
1317                       free (mem);
1318                 }
1319                 int main() {
1320                     test_memalign (  128,   128 - 2 * sizeof (void*));
1321                     test_memalign (  256,   256 - 2 * sizeof (void*));
1322                     test_memalign (  512,   512 - 2 * sizeof (void*));
1323                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1324                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1325                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1326                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1327                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1328                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1329                     exit (0); /* success */
1330                 }
1331                 ],
1332             [glib_cv_compliant_posix_memalign=1], [], [:])
1333       :
1334     fi
1335     ])
1336 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1337     AC_MSG_RESULT(yes)
1338     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1339 ], [
1340     AC_MSG_RESULT(no)
1341 ])
1342
1343
1344 dnl ****************************************
1345 dnl *** strlcpy/strlcat                  ***
1346 dnl ****************************************
1347 # Check for strlcpy
1348 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1349 AC_TRY_RUN([#include <stdlib.h>
1350 #include <string.h>
1351 int main() {
1352   char p[10];
1353   (void) strlcpy (p, "hi", 10);
1354   if (strlcat (p, "bye", 0) != 3)
1355     return 1;
1356   return 0;
1357 }], glib_cv_have_strlcpy=yes,
1358     glib_cv_have_strlcpy=no,
1359     glib_cv_have_strlcpy=no)])
1360 if test "$glib_cv_have_strlcpy" = "yes"; then
1361     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1362 fi
1363
1364
1365 dnl **********************
1366 dnl *** va_copy checks ***
1367 dnl **********************
1368 dnl we currently check for all three va_copy possibilities, so we get
1369 dnl all results in config.log for bug reports.
1370 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1371         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1372 #include <stdlib.h>
1373         void f (int i, ...) {
1374         va_list args1, args2;
1375         va_start (args1, i);
1376         va_copy (args2, args1);
1377         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1378           exit (1);
1379         va_end (args1); va_end (args2);
1380         }
1381         int main() {
1382           f (0, 42);
1383           return 0;
1384         }]])],
1385         [glib_cv_va_copy=yes],
1386         [glib_cv_va_copy=no])
1387 ])
1388 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1389         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1390 #include <stdlib.h>
1391         void f (int i, ...) {
1392         va_list args1, args2;
1393         va_start (args1, i);
1394         __va_copy (args2, args1);
1395         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1396           exit (1);
1397         va_end (args1); va_end (args2);
1398         }
1399         int main() {
1400           f (0, 42);
1401           return 0;
1402         }]])],
1403         [glib_cv___va_copy=yes],
1404         [glib_cv___va_copy=no])
1405 ])
1406
1407 if test "x$glib_cv_va_copy" = "xyes"; then
1408   g_va_copy_func=va_copy
1409 else if test "x$glib_cv___va_copy" = "xyes"; then
1410   g_va_copy_func=__va_copy
1411 fi
1412 fi
1413
1414 if test -n "$g_va_copy_func"; then
1415   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1416 fi
1417
1418 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1419         AC_TRY_RUN([#include <stdarg.h>
1420 #include <stdlib.h>
1421         void f (int i, ...) {
1422         va_list args1, args2;
1423         va_start (args1, i);
1424         args2 = args1;
1425         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1426           exit (1);
1427         va_end (args1); va_end (args2);
1428         }
1429         int main() {
1430           f (0, 42);
1431           return 0;
1432         }],
1433         [glib_cv_va_val_copy=yes],
1434         [glib_cv_va_val_copy=no],
1435         [glib_cv_va_val_copy=yes])
1436 ])
1437
1438 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1439   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1440 ])
1441
1442 dnl ***********************
1443 dnl *** g_module checks ***
1444 dnl ***********************
1445 G_MODULE_LIBS=
1446 G_MODULE_LIBS_EXTRA=
1447 G_MODULE_PLUGIN_LIBS=
1448 if test x"$glib_native_win32" = xyes; then
1449   dnl No use for this on Win32
1450   G_MODULE_LDFLAGS=
1451 else
1452   export SED
1453   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1454 fi
1455 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1456 G_MODULE_NEED_USCORE=0
1457 G_MODULE_BROKEN_RTLD_GLOBAL=0
1458 G_MODULE_HAVE_DLERROR=0
1459 dnl *** force native WIN32 shared lib loader
1460 if test -z "$G_MODULE_IMPL"; then
1461   case "$host" in
1462   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1463   esac
1464 fi
1465 dnl *** force native AIX library loader
1466 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1467 if test -z "$G_MODULE_IMPL"; then
1468   case "$host" in
1469   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1470   esac
1471 fi
1472 dnl *** dlopen() and dlsym() in system libraries
1473 AS_IF([ test -z "$G_MODULE_IMPL"], [
1474         AC_CHECK_FUNC(dlopen,
1475                       [AC_CHECK_FUNC(dlsym,
1476                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1477                       [])
1478 ])
1479 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1480 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1481         AC_CHECK_FUNC(NSLinkModule,
1482                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1483                        G_MODULE_NEED_USCORE=1],
1484                       [])
1485 ])
1486 dnl *** dlopen() and dlsym() in libdl
1487 AS_IF([ test -z "$G_MODULE_IMPL"], [
1488         AC_CHECK_LIB(dl, dlopen,
1489                      [AC_CHECK_LIB(dl, dlsym,
1490                                    [G_MODULE_LIBS=-ldl
1491                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1492                      [])
1493 ])
1494 dnl *** additional checks for G_MODULE_IMPL_DL
1495 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1496         LIBS_orig="$LIBS"
1497         LDFLAGS_orig="$LDFLAGS"
1498         LIBS="$G_MODULE_LIBS $LIBS"
1499         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1500 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1501         echo "void glib_plugin_test(void) { }" > plugin.c
1502         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1503                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1504         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1505                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1506                 -shrext ".o" -avoid-version plugin.lo \
1507                 -rpath /dont/care >/dev/null 2>&1
1508         eval `./libtool --config | grep ^objdir`
1509         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1510                 glib_cv_rtldglobal_broken,[
1511                 AC_TRY_RUN([
1512 #include <dlfcn.h>
1513 #ifndef RTLD_GLOBAL
1514 #  define RTLD_GLOBAL 0
1515 #endif
1516 #ifndef RTLD_LAZY
1517 #  define RTLD_LAZY 0
1518 #endif
1519 int glib_plugin_test;
1520 int main () {
1521     void *handle, *global, *local;
1522     global = &glib_plugin_test;
1523     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1524     if (!handle) return 0;
1525     local = dlsym (handle, "glib_plugin_test");
1526     return global == local;
1527 }                       ],
1528                         [glib_cv_rtldglobal_broken=no],
1529                         [glib_cv_rtldglobal_broken=yes],
1530                         [glib_cv_rtldglobal_broken=no])
1531                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1532                 rmdir ${objdir} 2>/dev/null
1533         ])
1534         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1535                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1536         else
1537                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1538         fi
1539 dnl *** check whether we need preceeding underscores
1540         AC_CACHE_CHECK([for preceeding underscore in symbols],
1541                 glib_cv_uscore,[
1542                 AC_TRY_RUN([#include <dlfcn.h>
1543                 int glib_underscore_test (void) { return 42; }
1544                 int main() {
1545                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1546                   handle = dlopen ((void*)0, 0);
1547                   if (handle) {
1548                     f1 = dlsym (handle, "glib_underscore_test");
1549                     f2 = dlsym (handle, "_glib_underscore_test");
1550                   } return (!f2 || f1);
1551                 }],
1552                         [glib_cv_uscore=yes],
1553                         [glib_cv_uscore=no],
1554                         [])
1555                 rm -f plugin.c plugin.$ac_objext plugin.lo
1556         ])
1557         GLIB_ASSERT_SET(glib_cv_uscore)
1558         if test "x$glib_cv_uscore" = "xyes"; then
1559                 G_MODULE_NEED_USCORE=1
1560         else
1561                 G_MODULE_NEED_USCORE=0
1562         fi
1563
1564         LDFLAGS="$LDFLAGS_orig"
1565 dnl *** check for having dlerror()
1566         AC_CHECK_FUNC(dlerror,
1567                 [G_MODULE_HAVE_DLERROR=1],
1568                 [G_MODULE_HAVE_DLERROR=0])
1569         LIBS="$LIBS_orig"
1570 ])
1571 dnl *** done, have we got an implementation?
1572 if test -z "$G_MODULE_IMPL"; then
1573         G_MODULE_IMPL=0
1574         G_MODULE_SUPPORTED=false
1575 else
1576         G_MODULE_SUPPORTED=true
1577 fi
1578
1579 AC_MSG_CHECKING(for the suffix of module shared libraries)
1580 export SED
1581 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1582 eval $shrext_cmds
1583 module=yes eval std_shrext=$shrext_cmds
1584 # chop the initial dot
1585 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1586 AC_MSG_RESULT(.$glib_gmodule_suffix)
1587 # any reason it may fail?
1588 if test "x$glib_gmodule_suffix" = x; then
1589         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1590 fi
1591
1592 AC_SUBST(G_MODULE_SUPPORTED)
1593 AC_SUBST(G_MODULE_IMPL)
1594 AC_SUBST(G_MODULE_LIBS)
1595 AC_SUBST(G_MODULE_LIBS_EXTRA)
1596 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1597 AC_SUBST(G_MODULE_LDFLAGS)
1598 AC_SUBST(G_MODULE_HAVE_DLERROR)
1599 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1600 AC_SUBST(G_MODULE_NEED_USCORE)
1601 AC_SUBST(GLIB_DEBUG_FLAGS)
1602
1603 dnl **********************
1604 dnl *** g_spawn checks ***
1605 dnl **********************
1606
1607 AC_MSG_CHECKING(for gspawn implementation)
1608 case "$host" in
1609   *-*-mingw*)
1610     GSPAWN=gspawn-win32.lo
1611     ;;
1612   *)
1613     GSPAWN=gspawn.lo
1614     ;;
1615 esac
1616 AC_MSG_RESULT($GSPAWN)
1617 AC_SUBST(GSPAWN)
1618
1619 dnl *************************
1620 dnl *** GIOChannel checks ***
1621 dnl *************************
1622
1623 AC_MSG_CHECKING(for GIOChannel implementation)
1624 case "$host" in
1625   *-*-mingw*)
1626     GIO=giowin32.lo
1627     ;;
1628   *)
1629     GIO=giounix.lo
1630     ;;
1631 esac
1632 AC_MSG_RESULT($GIO)
1633 AC_SUBST(GIO)
1634
1635 dnl *********************************
1636 dnl *** Directory for GIO modules ***
1637 dnl *********************************
1638
1639 AC_ARG_WITH(gio-module-dir,
1640            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1641                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1642            [],
1643            [with_gio_module_dir='${libdir}/gio/modules'])
1644 GIO_MODULE_DIR=$with_gio_module_dir
1645 AC_SUBST(GIO_MODULE_DIR)
1646
1647 dnl **********************************
1648 dnl *** Check for libselinux (GIO) ***
1649 dnl **********************************
1650 AC_ARG_ENABLE(selinux,
1651               AS_HELP_STRING([--disable-selinux],
1652                              [build without selinux support]))
1653 msg_selinux=no
1654 SELINUX_LIBS=
1655 AS_IF([ test "x$enable_selinux" != "xno"], [
1656
1657  AC_CHECK_LIB(selinux, is_selinux_enabled,
1658    [AC_CHECK_HEADERS(selinux/selinux.h,
1659      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1660        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1661         SELINUX_LIBS="-lselinux"
1662         msg_selinux=yes])
1663      ])
1664    ])
1665 ])
1666 AC_SUBST(SELINUX_LIBS)
1667
1668 dnl *****************************
1669 dnl ** Check for inotify (GIO) **
1670 dnl *****************************
1671 inotify_support=no
1672 AC_CHECK_HEADERS([sys/inotify.h],
1673 [
1674   AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1675 ])
1676
1677 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1678
1679 dnl ****************************
1680 dnl ** Check for kqueue (GIO) **
1681 dnl ****************************
1682 kqueue_support=no
1683 AC_CHECK_HEADERS([sys/event.h],
1684 [
1685         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1686 ])
1687
1688 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1689
1690 dnl *********************************
1691 dnl ** Check for Solaris FEN (GIO) **
1692 dnl *********************************
1693 fen_support=no
1694 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1695 #include <port.h>
1696 #ifndef PORT_SOURCE_FILE
1697 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1698 #endif
1699 int main() { return 0; } ]])],
1700 [
1701         fen_support=yes
1702 ],)
1703
1704 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1705
1706 dnl ****************************
1707 dnl *** Checks for FAM (GIO) ***
1708 dnl ****************************
1709
1710 should_disable_fam=no
1711
1712 AC_ARG_ENABLE(fam,
1713               AS_HELP_STRING([--disable-fam],
1714                              [don't use fam for file system monitoring]),
1715                          [
1716                                 if test "x$enable_fam" = "xno"; then
1717                                         should_disable_fam=yes
1718                                 fi
1719                          ]
1720                          )
1721 fam_support=no
1722 FAM_LIBS=
1723 if test "x$should_disable_fam" = "xno"; then
1724 AC_CHECK_LIB(fam, FAMOpen,
1725   [AC_CHECK_HEADERS(fam.h,
1726     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1727      AC_CHECK_LIB(fam, FAMNoExists,
1728                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1729      FAM_LIBS="-lfam"]
1730      fam_support=yes,
1731     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1732   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1733 AC_SUBST(FAM_LIBS)
1734 fi
1735 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1736
1737
1738 dnl *****************************
1739 dnl *** Check for xattr (GIO) ***
1740 dnl *****************************
1741 AC_ARG_ENABLE(xattr,
1742               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1743 msg_xattr=no
1744 XATTR_LIBS=
1745 AS_IF([ test "x$enable_xattr" != "xno"], [
1746
1747 dnl either glibc or libattr can provide xattr support
1748
1749 dnl for both of them, we check for getxattr being in
1750 dnl the library and a valid xattr header.
1751
1752 dnl try glibc
1753  AC_CHECK_LIB(c, getxattr,
1754    [AC_CHECK_HEADERS(sys/xattr.h,
1755      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1756       msg_xattr=yes])
1757    ])
1758
1759   AS_IF([ test "x$msg_xattr" != "xyes"], [
1760 dnl   failure. try libattr
1761    AC_CHECK_LIB(attr, getxattr,
1762       [AC_CHECK_HEADERS(attr/xattr.h,
1763        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1764         XATTR_LIBS="-lattr"
1765         msg_xattr=yes])
1766       ])
1767   ])
1768
1769   AS_IF([ test "x$msg_xattr" = "xyes"], [
1770     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1771     AC_TRY_COMPILE([
1772       #include <stdio.h>
1773       #ifdef HAVE_SYS_TYPES_H
1774       #include <sys/types.h>
1775       #endif
1776       #ifdef HAVE_SYS_XATTR_H
1777       #include <sys/xattr.h>
1778       #elif HAVE_ATTR_XATTR_H
1779       #include <attr/xattr.h>
1780       #endif
1781     ],
1782     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1783     [
1784       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1785       AC_MSG_RESULT([yes])
1786     ],
1787     [AC_MSG_RESULT([no])]
1788     )
1789   ])
1790 ])
1791 AC_SUBST(XATTR_LIBS)
1792
1793 dnl ************************
1794 dnl *** check for libelf ***
1795 dnl ************************
1796 AC_ARG_ENABLE(libelf,
1797               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1798 AS_IF([ test "x$enable_libelf" != "xno"],[
1799 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1800 AS_IF([ test $have_libelf = maybe ], [
1801   glib_save_LIBS=$LIBS
1802   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1803   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1804   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1805   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1806   LIBS=$glib_save_LIBS
1807
1808   if test $have_libelf != no; then
1809     LIBELF_LIBS=-lelf
1810     have_libelf=yes
1811   fi
1812 ])
1813 ])
1814
1815 if test x$have_libelf = xyes; then
1816   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1817 fi
1818
1819 dnl ****************************************
1820 dnl *** platform dependent source checks ***
1821 dnl ****************************************
1822
1823 AC_MSG_CHECKING(for platform-dependent source)
1824 case "$host" in
1825   *-*-cygwin*|*-*-mingw*)
1826     PLATFORMDEP=gwin32.lo
1827     ;;
1828   *)
1829     PLATFORMDEP=
1830     ;;
1831 esac
1832 AC_MSG_RESULT($PLATFORMDEP)
1833 AC_SUBST(PLATFORMDEP)
1834
1835 AC_MSG_CHECKING([whether to compile timeloop])
1836 case "$host" in
1837   *-*-cygwin*|*-*-mingw*|*-*-minix)
1838     enable_timeloop=no
1839     ;;
1840   *)
1841     enable_timeloop=yes
1842     ;;
1843 esac
1844 AC_MSG_RESULT($enable_timeloop)
1845 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1846
1847 AC_MSG_CHECKING([if building for some Win32 platform])
1848 case "$host" in
1849   *-*-mingw*|*-*-cygwin*)
1850     platform_win32=yes
1851     ;;
1852   *)
1853     platform_win32=no
1854     ;;
1855 esac
1856 AC_MSG_RESULT($platform_win32)
1857 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1858
1859 dnl ***********************
1860 dnl *** g_thread checks ***
1861 dnl ***********************
1862
1863 AC_ARG_WITH(threads,
1864            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1865                            [specify a thread implementation to use])],
1866            [],
1867            [with_threads=yes])
1868
1869 dnl error and warning message
1870 dnl *************************
1871
1872 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1873
1874 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1875                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1876                 compilation now, but then your programs might not work.
1877                 Please provide information on how it is done on your system."
1878
1879 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1880                  "
1881
1882 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1883                   provide information on your thread implementation."
1884
1885 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1886                 functions will not be MT-safe during their first call because
1887                 there is no working 'getpwuid_r' on your system."
1888
1889 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1890                 because there is no 'localtime_r' on your system."
1891
1892 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1893                 linking threaded applications. As GLib cannot do that
1894                 automatically, you will get an linkg error everytime you are
1895                 not using the right compiler. In that case you have to relink
1896                 with the right compiler. Ususally just '_r' is appended
1897                 to the compiler name."
1898
1899 dnl determination of thread implementation
1900 dnl ***************************************
1901
1902 AC_MSG_CHECKING(for thread implementation)
1903
1904 have_threads=no
1905 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1906         AS_IF([ test "x$have_threads" = xno], [
1907                 AC_TRY_COMPILE([#include <pthread.h>],
1908                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1909                         have_threads=posix)
1910         ])
1911         # Tru64Unix requires -pthread to find pthread.h. See #103020
1912         if test "x$have_threads" = xno; then
1913                 glib_save_CPPFLAGS="$CPPFLAGS"
1914                 CPPFLAGS="$CPPFLAGS -pthread"
1915                 AC_TRY_COMPILE([#include <pthread.h>],
1916                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1917                        have_threads=posix)
1918                 CPPFLAGS="$glib_save_CPPFLAGS"
1919         fi
1920 ])
1921 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1922         case $host in
1923                 *-*-mingw*)
1924                 have_threads=win32
1925                 ;;
1926         esac
1927 fi
1928
1929 if test "x$have_threads" = xno; then
1930         AC_MSG_RESULT(none available)
1931         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1932 else
1933         AC_MSG_RESULT($have_threads)
1934 fi
1935
1936
1937 dnl determination of G_THREAD_CFLAGS
1938 dnl ********************************
1939
1940 G_THREAD_LIBS=
1941 G_THREAD_LIBS_EXTRA=
1942 G_THREAD_CFLAGS=
1943
1944 dnl
1945 dnl Test program for basic POSIX threads functionality
1946 dnl
1947 m4_define([glib_thread_test],[
1948 #include <pthread.h>
1949 int check_me = 0;
1950 void* func(void* data) {check_me = 42; return &check_me;}
1951 int main()
1952  { pthread_t t;
1953    void *ret;
1954    pthread_create (&t, $1, func, 0);
1955    pthread_join (t, &ret);
1956    return (check_me != 42 || ret != &check_me);
1957 }])
1958
1959 AS_IF([ test x"$have_threads" = xposix], [
1960   # First we test for posix, whether -pthread or -pthreads do the trick as
1961   # both CPPFLAG and LIBS.
1962   # One of them does for most gcc versions and some other platforms/compilers
1963   # too and could be considered as the canonical way to go.
1964   case $host in
1965     *-*-cygwin*|*-*-darwin*)
1966        # skip cygwin and darwin -pthread or -pthreads test
1967        ;;
1968     *-solaris*)
1969       # These compiler/linker flags work with both Sun Studio and gcc
1970       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1971       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1972       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1973       G_THREAD_LIBS="-lpthread -lthread"
1974       ;;
1975     *)
1976       for flag in pthread pthreads mt; do
1977         glib_save_CFLAGS="$CFLAGS"
1978         CFLAGS="$CFLAGS -$flag"
1979         AC_TRY_RUN(glib_thread_test(0),
1980                    glib_flag_works=yes,
1981                    glib_flag_works=no,
1982                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1983                                    glib_flag_works=yes,
1984                                    glib_flag_works=no)])
1985         CFLAGS="$glib_save_CFLAGS"
1986         if test $glib_flag_works = yes ; then
1987            G_THREAD_CFLAGS=-$flag
1988         G_THREAD_LIBS=-$flag
1989         break;
1990         fi
1991       done
1992        ;;
1993   esac
1994 ])
1995
1996 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1997
1998   # The canonical -pthread[s] does not work. Try something different.
1999
2000   case $host in
2001         *-aix*)
2002                 if test x"$GCC" = xyes; then
2003                         # GCC 3.0 and above needs -pthread.
2004                         # Should be coverd by the case above.
2005                         # GCC 2.x and below needs -mthreads
2006                         G_THREAD_CFLAGS="-mthreads"
2007                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2008                 else
2009                         # We are probably using the aix compiler. Normaly a
2010                         # program would have to be compiled with the _r variant
2011                         # of the corresponding compiler, but we as GLib cannot
2012                         # do that: but the good news is that for compiling the
2013                         # only difference is the added -D_THREAD_SAFE compile
2014                         # option. This is according to the "C for AIX User's
2015                         # Guide".
2016                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2017                 fi
2018                 ;;
2019         *-sysv5uw7*) # UnixWare 7
2020                 # We are not using gcc with -pthread. Catched above.
2021                 G_THREAD_CFLAGS="-Kthread"
2022                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2023                 ;;
2024         *-mingw*)
2025                 # No flag needed when using MSVCRT.DLL
2026                 G_THREAD_CFLAGS=""
2027                 ;;
2028         *)
2029                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2030                 ;;
2031   esac
2032 ])
2033
2034 # if we are not finding the localtime_r function, then we probably are
2035 # not using the proper multithread flag
2036
2037 glib_save_CPPFLAGS="$CPPFLAGS"
2038 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2039
2040 # First we test, whether localtime_r is declared in time.h
2041 # directly. Then we test whether a macro localtime_r exists, in
2042 # which case localtime_r in the test program is replaced and thus
2043 # if we still find localtime_r in the output, it is not defined as
2044 # a macro.
2045
2046 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2047   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2048                                                            localtime_r(a,b)],
2049                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2050
2051 CPPFLAGS="$glib_save_CPPFLAGS"
2052
2053 AC_MSG_CHECKING(thread related cflags)
2054 AC_MSG_RESULT($G_THREAD_CFLAGS)
2055 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2056
2057 dnl determination of G_THREAD_LIBS
2058 dnl ******************************
2059
2060 AS_IF([test x$have_threads = xposix], [
2061           glib_save_CPPFLAGS="$CPPFLAGS"
2062           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2063           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2064             case $host in
2065               *-aix*)
2066                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2067                 # probably using the aix compiler.
2068                 AC_MSG_WARN($AIX_COMPILE_INFO)
2069                 ;;
2070               *)
2071                 G_THREAD_LIBS=error
2072                 glib_save_LIBS="$LIBS"
2073                 for thread_lib in "" pthread pthread32 pthreads thread; do
2074                         if test x"$thread_lib" = x; then
2075                                 add_thread_lib=""
2076                                 IN=""
2077                         else
2078                                 add_thread_lib="-l$thread_lib"
2079                                 IN=" in -l$thread_lib"
2080                         fi
2081                         if test x"$have_threads" = xposix; then
2082                                 defattr=0
2083                         else
2084                                 defattr=pthread_attr_default
2085                         fi
2086
2087                         LIBS="$add_thread_lib $glib_save_LIBS"
2088
2089                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2090                         AC_TRY_RUN(glib_thread_test($defattr),
2091                                    glib_result=yes,
2092                                    glib_result=no,
2093                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2094                                                    glib_result=yes,
2095                                                    glib_result=no)])
2096                         AC_MSG_RESULT($glib_result)
2097
2098                         if test "$glib_result" = "yes" ; then
2099                           G_THREAD_LIBS="$add_thread_lib"
2100                           break
2101                         fi
2102                 done
2103                 if test "x$G_THREAD_LIBS" = xerror; then
2104                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2105                 fi
2106                 LIBS="$glib_save_LIBS"
2107                 ;;
2108             esac
2109           ])
2110
2111           g_threads_impl="POSIX"
2112           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2113           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2114           CPPFLAGS="$glib_save_CPPFLAGS"
2115 ], [test x$have_threads = xwin32], [
2116            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2117            g_threads_impl="WIN32"
2118 ], [
2119            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2120            g_threads_impl="NONE"
2121            G_THREAD_LIBS=error
2122 ])
2123 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2124 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2125 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2126
2127 if test "x$G_THREAD_LIBS" = xerror; then
2128         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2129 fi
2130
2131 AC_MSG_CHECKING(thread related libraries)
2132 AC_MSG_RESULT($G_THREAD_LIBS)
2133
2134 dnl check for mt safe function variants and some posix functions
2135 dnl ************************************************************
2136
2137 glib_save_LIBS="$LIBS"
2138 # we are not doing the following for now, as this might require glib
2139 # to always be linked with the thread libs on some platforms.
2140 # LIBS="$LIBS $G_THREAD_LIBS"
2141 AC_CHECK_FUNCS(localtime_r gmtime_r)
2142 AS_IF([ test "$glib_native_win32" != "yes"], [
2143         AC_CACHE_CHECK([for posix getpwuid_r],
2144                 ac_cv_func_posix_getpwuid_r,
2145                 [AC_TRY_RUN([
2146 #include <errno.h>
2147 #include <pwd.h>
2148 int main () {
2149     char buffer[10000];
2150     struct passwd pwd, *pwptr = &pwd;
2151     int error;
2152     errno = 0;
2153     error = getpwuid_r (0, &pwd, buffer,
2154                         sizeof (buffer), &pwptr);
2155    return (error < 0 && errno == ENOSYS)
2156            || error == ENOSYS;
2157 }                               ],
2158                         [ac_cv_func_posix_getpwuid_r=yes],
2159                         [ac_cv_func_posix_getpwuid_r=no])])
2160         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2161         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2162                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2163                         [Have POSIX function getpwuid_r])
2164         else
2165                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2166                         ac_cv_func_nonposix_getpwuid_r,
2167                         [AC_TRY_LINK([#include <pwd.h>],
2168                                 [char buffer[10000];
2169                                 struct passwd pwd;
2170                                 getpwuid_r (0, &pwd, buffer,
2171                                                 sizeof (buffer));],
2172                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2173                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2174                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2175                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2176                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2177                                 [Have non-POSIX function getpwuid_r])
2178                 fi
2179         fi
2180 ])
2181 AS_IF([ test "$glib_native_win32" != "yes"], [
2182         AC_CACHE_CHECK([for posix getgrgid_r],
2183                 ac_cv_func_posix_getgrgid_r,
2184                 [AC_TRY_RUN([
2185 #include <errno.h>
2186 #include <grp.h>
2187 int main () {
2188     char buffer[10000];
2189     struct group grp, *grpptr = &grp;
2190     int error;
2191     errno = 0;
2192     error = getgrgid_r (0, &grp, buffer,
2193                         sizeof (buffer), &grpptr);
2194    return (error < 0 && errno == ENOSYS)
2195            || error == ENOSYS;
2196 }                              ],
2197                        [ac_cv_func_posix_getgrgid_r=yes],
2198                        [ac_cv_func_posix_getgrgid_r=no])])
2199         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2200         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2201                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2202                         [Have POSIX function getgrgid_r])
2203         ], [
2204                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2205                         ac_cv_func_nonposix_getgrgid_r,
2206                         [AC_TRY_LINK([#include <grp.h>],
2207                                 [char buffer[10000];
2208                                 struct group grp;
2209                                 getgrgid_r (0, &grp, buffer,
2210                                 sizeof (buffer));],
2211                         [ac_cv_func_nonposix_getgrgid_r=yes],
2212                         [ac_cv_func_nonposix_getgrgid_r=no])])
2213                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2214                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2215                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2216                                 [Have non-POSIX function getgrgid_r])
2217                 fi
2218         ])
2219 ])
2220 LIBS="$G_THREAD_LIBS $LIBS"
2221 AS_IF([ test x"$have_threads" = xposix], [
2222         glib_save_CPPFLAGS="$CPPFLAGS"
2223         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2224         # This is not AC_CHECK_FUNC to also work with function
2225         # name mangling in header files.
2226         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2227         AC_LINK_IFELSE(
2228             [AC_LANG_PROGRAM(
2229                 [#include <pthread.h>],
2230                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2231             [AC_MSG_RESULT(yes)
2232              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2233                 [Have function pthread_attr_setstacksize])],
2234             [AC_MSG_RESULT(no)])
2235         AC_MSG_CHECKING(for pthread_condattr_setclock)
2236         AC_LINK_IFELSE(
2237             [AC_LANG_PROGRAM(
2238                 [#include <pthread.h>],
2239                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2240             [AC_MSG_RESULT(yes)
2241              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2242                 [Have function pthread_condattr_setclock])],
2243             [AC_MSG_RESULT(no)])
2244         AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2245         AC_LINK_IFELSE(
2246             [AC_LANG_PROGRAM(
2247                 [#include <pthread.h>],
2248                 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2249             [AC_MSG_RESULT(yes)
2250              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2251                 [Have function pthread_cond_timedwait_relative_np])],
2252             [AC_MSG_RESULT(no)])
2253         CPPFLAGS="$glib_save_CPPFLAGS"
2254 ])
2255
2256 LIBS="$glib_save_LIBS"
2257
2258 # now spit out all the warnings.
2259 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2260    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2261         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2262 fi
2263 if test "$ac_cv_func_localtime_r" != "yes"; then
2264         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2265 fi
2266
2267 #
2268 # Hack to deal with:
2269 #
2270 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2271 #     building shared libraries with linux.
2272 #  b) FreeBSD doesn't do this either.
2273 #
2274 case $host in
2275   *android*)
2276     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2277     ;;
2278   *-*-freebsd*|*-*-linux*)
2279     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2280     ;;
2281   *)
2282     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2283     ;;
2284 esac
2285
2286 AC_SUBST(G_THREAD_CFLAGS)
2287 AC_SUBST(G_THREAD_LIBS)
2288 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2289 AC_SUBST(G_THREAD_LIBS_EXTRA)
2290
2291 AC_CHECK_FUNCS(clock_gettime, [], [
2292   AC_CHECK_LIB(rt, clock_gettime, [
2293     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2294     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2295   ])
2296 ])
2297
2298
2299 dnl ************************
2300 dnl *** g_atomic_* tests ***
2301 dnl ************************
2302
2303 dnl We need to decide at configure time if GLib will use real atomic
2304 dnl operations ("lock free") or emulated ones with a mutex.  This is
2305 dnl because we must put this information in glibconfig.h so we know if
2306 dnl it is safe or not to inline using compiler intrinsics directly from
2307 dnl the header.
2308 dnl
2309 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2310 dnl user is interested in knowing if they can use the atomic ops across
2311 dnl processes.
2312 dnl
2313 dnl We can currently support the atomic ops natively when building GLib
2314 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2315 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2316 dnl we are using GCC (and not mingw*).
2317 dnl
2318 dnl Note that the atomic ops are only available with GCC on x86 when
2319 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2320 dnl not available but would be available given the right flags, we want
2321 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2322 dnl that then to silently fall back on emulated atomic ops just because
2323 dnl the user had the wrong build environment.
2324
2325 dnl We may add other compilers here in the future...
2326
2327 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2328   case $host in
2329     *-*-mingw*)
2330       glib_cv_g_atomic_lock_free=yes
2331       ;;
2332     *)
2333       AC_TRY_LINK([],
2334                      [volatile int atomic = 2;\
2335                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2336                      [glib_cv_g_atomic_lock_free=yes],
2337                      [glib_cv_g_atomic_lock_free=no])
2338       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2339         SAVE_CFLAGS="${CFLAGS}"
2340         CFLAGS="-march=i486"
2341         AC_TRY_LINK([],
2342                        [volatile int atomic = 2;\
2343                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2344                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2345                        [])
2346         CFLAGS="${SAVE_CFLAGS}"
2347       fi
2348       ;;
2349   esac])
2350
2351
2352 case $host in
2353   *-*-mingw*)
2354     ;;
2355   *)
2356     # Some compilers support atomic operations but do not define
2357     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2358     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2359       AC_TRY_LINK([],
2360                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2361                      [],
2362                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2363     fi
2364     ;;
2365  esac
2366
2367 dnl We need a more robust approach here...
2368 case $host_cpu in
2369   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2370     glib_memory_barrier_needed=no
2371     ;;
2372   sparc*|alpha*|powerpc*|ia64)
2373     glib_memory_barrier_needed=yes
2374     ;;
2375   *)
2376     glib_memory_barrier_needed=yes
2377     ;;
2378 esac
2379
2380 dnl ************************
2381 dnl ** Check for futex(2) **
2382 dnl ************************
2383 AC_CACHE_CHECK(for futex(2) system call,
2384     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2385 #include <linux/futex.h>
2386 #include <sys/syscall.h>
2387 #include <unistd.h>
2388 ],[
2389   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2390 ])],glib_cv_futex=yes,glib_cv_futex=no))
2391 if test x"$glib_cv_futex" = xyes; then
2392   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2393 fi
2394
2395 AC_CACHE_CHECK(for eventfd(2) system call,
2396     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2397 #include <sys/eventfd.h>
2398 #include <unistd.h>
2399 ],[
2400   eventfd (0, EFD_CLOEXEC);
2401 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2402 if test x"$glib_cv_eventfd" = x"yes"; then
2403   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2404 fi
2405 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2406
2407 dnl ****************************************
2408 dnl *** GLib POLL* compatibility defines ***
2409 dnl ****************************************
2410
2411 glib_poll_includes=["
2412 #include <sys/types.h>
2413 #include <poll.h>
2414 "]
2415
2416 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2417    test $ac_cv_func_poll = yes ], [
2418   glib_failed=false
2419   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2420   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2421   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2422   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2423   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2424   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2425   if $glib_failed ; then
2426     AC_MSG_ERROR([Could not determine values for POLL* constants])
2427   fi
2428 ], [
2429   glib_cv_value_POLLIN=1
2430   glib_cv_value_POLLOUT=4
2431   glib_cv_value_POLLPRI=2
2432   glib_cv_value_POLLERR=8
2433   glib_cv_value_POLLHUP=16
2434   glib_cv_value_POLLNVAL=32
2435 ])
2436
2437 AC_MSG_CHECKING([for broken poll])
2438 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2439         #include <stdlib.h>
2440         #include <fcntl.h>
2441         #include <poll.h>
2442         int main(void) {
2443           struct pollfd fds[1];
2444           int fd;
2445           fd = open("/dev/null", 1);
2446           fds[0].fd = fd;
2447           fds[0].events = POLLIN;
2448           fds[0].revents = 0;
2449           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2450                 exit(1);  /* Does not work for devices -- fail */
2451           }
2452           exit(0);
2453         }]])],
2454   [broken_poll=no],
2455   [broken_poll=yes
2456    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2457   [broken_poll="no (cross compiling)"])
2458 AC_MSG_RESULT($broken_poll)
2459
2460 dnl *********************
2461 dnl *** GRegex checks ***
2462 dnl *********************
2463
2464 PCRE_REQUIRED_VERSION=8.13
2465
2466 # Check if we should use the internal or the system-supplied pcre
2467 AC_ARG_WITH(pcre,
2468             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2469                             [whether to use system PCRE [default=internal]])])
2470
2471 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2472
2473 AS_IF([ test "x$with_pcre" = xsystem], [
2474   PKG_CHECK_MODULES(PCRE,
2475                     libpcre >= $PCRE_REQUIRED_VERSION)
2476   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2477                   glib_save_CFLAGS="$CFLAGS"
2478                   glib_save_LIBS="$LIBS"
2479                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2480                   AC_TRY_RUN([#include <pcre.h>
2481                               int main () {
2482                                 int support;
2483                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2484                                 if (!support)
2485                                   return 1;
2486                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2487                                 if (!support)
2488                                   return 1;
2489                                 return 0;
2490                               }],
2491                   glib_cv_pcre_has_unicode=yes,
2492                   glib_cv_pcre_has_unicode=no,
2493                   glib_cv_pcre_has_unicode=yes)
2494                   CFLAGS="$glib_save_CFLAGS"
2495                   LIBS="$glib_save_LIBS"
2496       ])
2497   if test "$glib_cv_pcre_has_unicode" = "no"; then
2498     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2499   fi
2500   AC_SUBST(PCRE_CFLAGS)
2501   AC_SUBST(PCRE_LIBS)
2502   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2503   PCRE_REQUIRES=libpcre
2504   AC_SUBST(PCRE_REQUIRES)
2505 ], [
2506   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2507   AS_IF([ test x"$GCC" = xyes], [
2508     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2509     save_CFLAGS="$CFLAGS"
2510     CFLAGS="$CFLAGS -Wno-pointer-sign"
2511     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2512                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2513     CFLAGS="$save_CFLAGS"
2514   ])
2515 ])
2516 AC_SUBST(PCRE_WARN_CFLAGS)
2517
2518 dnl **********************
2519 dnl *** Win32 API libs ***
2520 dnl **********************
2521
2522 case $host in
2523   *-*-cygwin*)
2524         G_LIBS_EXTRA="-luser32 -lkernel32"
2525     ;;
2526   *-*-mingw*)
2527         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2528     ;;
2529   *)
2530         G_LIBS_EXTRA=""
2531     ;;
2532 esac
2533 AC_SUBST(G_LIBS_EXTRA)
2534
2535 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2536 dnl since we need it for g_iconv()
2537
2538 AC_MSG_CHECKING([for EILSEQ])
2539 AC_TRY_COMPILE([
2540 #include <errno.h>
2541 ],
2542 [
2543 int error = EILSEQ;
2544 ], have_eilseq=yes, have_eilseq=no);
2545 AC_MSG_RESULT($have_eilseq)
2546
2547 dnl ******************************************************************
2548 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2549 dnl *** glib-compile-schemas in PATH                               ***
2550 dnl ******************************************************************
2551
2552 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2553
2554 AS_IF([ test $cross_compiling = yes ], [
2555   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2556   if test x$GLIB_GENMARSHAL = xno; then
2557     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2558   fi
2559
2560   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2561   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2562     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2563   fi
2564
2565   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2566   if test x$GLIB_COMPILE_RESOURCES = xno; then
2567     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2568   fi
2569 ])
2570
2571 dnl **************************
2572 dnl *** Checks for gtk-doc ***
2573 dnl **************************
2574 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2575 # it on it's own line.
2576 m4_ifdef([GTK_DOC_CHECK], [
2577 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2578 ],[
2579 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2580 ])
2581
2582 AC_ARG_ENABLE(man,
2583               [AS_HELP_STRING([--enable-man],
2584                               [generate man pages [default=auto]])],,
2585               enable_man=maybe)
2586
2587 AS_IF([test "$enable_man" != no], [
2588   AC_PATH_PROG([XSLTPROC], [xsltproc])
2589   AS_IF([test -z "$XSLTPROC"], [
2590     AS_IF([test "$enable_man" = yes], [
2591       AC_MSG_ERROR([xsltproc is required for --enable-man])
2592     ])
2593     enable_man=no
2594   ])
2595 ])
2596
2597 AS_IF([ test "$enable_man" != no ], [
2598   dnl check for DocBook DTD in the local catalog
2599   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2600      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2601   AS_IF([test "$have_docbook_dtd" != yes], [
2602     AS_IF([test "$enable_man" = yes ], [
2603       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2604     ])
2605     enable_man=no
2606   ])
2607 ])
2608
2609 AS_IF([test "$enable_man" != no], [
2610   dnl check for DocBook XSL stylesheets in the local catalog
2611   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2612      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2613   AS_IF([ test "$have_docbook_dtd" != yes ], [
2614     AS_IF([ test "$enable_man" = yes ], [
2615       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2616     ])
2617     enable_man=no
2618   ])
2619 ])
2620
2621 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2622
2623 AC_MSG_CHECKING([whether to generate man pages])
2624 AS_IF([ test "$enable_man" != no ], [
2625   AC_MSG_RESULT([yes])
2626 ], [
2627   AC_MSG_RESULT([no])
2628 ])
2629
2630 dnl
2631 dnl Tracing
2632 dnl
2633
2634 AC_ARG_ENABLE([dtrace],
2635              [AS_HELP_STRING([--enable-dtrace],
2636                               [include tracing support for dtrace])])
2637 have_dtrace=no
2638 AC_MSG_CHECKING([whether to include dtrace tracing support])
2639 AS_IF([ test "x$enable_dtrace" != xno], [
2640   if test x$glib_have_carbon = xyes; then
2641     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2642   else
2643     AC_MSG_RESULT([yes])
2644     AC_CHECK_PROGS(DTRACE, dtrace)
2645     if test -z "$DTRACE"; then
2646       if test "x$enable_dtrace" = xyes; then
2647         AC_MSG_ERROR([dtrace not found])
2648       fi
2649     else
2650       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2651                       [if test "x$enable_dtrace" = xyes; then
2652                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2653                        fi])
2654     fi
2655   fi
2656 ], [
2657   AC_MSG_RESULT([no])
2658 ])
2659 if test "x$have_dtrace" = xyes; then
2660   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2661 fi
2662 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2663
2664 AC_MSG_CHECKING([whether to include systemtap tracing support])
2665 AC_ARG_ENABLE([systemtap],
2666              [AS_HELP_STRING([--enable-systemtap],
2667                               [include tracing support for systemtap])])
2668 have_systemtap=no
2669 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2670   have_systemtap=yes
2671 fi
2672 AC_MSG_RESULT(${have_systemtap})
2673
2674 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2675
2676 AC_ARG_WITH([tapset-install-dir],
2677             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2678                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2679             [if test "x${withval}" = x; then
2680                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2681              else
2682                ABS_TAPSET_DIR="${withval}"
2683               fi],
2684             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2685 AC_SUBST(ABS_TAPSET_DIR)
2686
2687 dnl ************************************
2688 dnl *** Enable lcov coverage reports ***
2689 dnl ************************************
2690
2691 AC_ARG_ENABLE(coverage,
2692   AS_HELP_STRING([--enable-coverage],
2693                  [enable coverage testing with gcov]),
2694   [use_gcov=$enableval], [use_gcov=no])
2695
2696 AS_IF([ test "x$use_gcov" = "xyes"], [
2697   dnl we need gcc:
2698   if test "$GCC" != "yes"; then
2699     AC_MSG_ERROR([GCC is required for --enable-coverage])
2700   fi
2701
2702   dnl Check if ccache is being used
2703   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2704   case `$SHTOOL path $CC` in
2705     *ccache*[)] gcc_ccache=yes;;
2706     *[)] gcc_ccache=no;;
2707   esac
2708
2709   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2710     AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2711   fi
2712
2713   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2714   AC_CHECK_PROG(LTP, lcov, lcov)
2715   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2716
2717   AS_IF([ test "$LTP" ], [
2718     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2719       glib_cv_ltp_version=invalid
2720       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2721       for ltp_check_version in $ltp_version_list; do
2722         if test "$ltp_version" = "$ltp_check_version"; then
2723           glib_cv_ltp_version="$ltp_check_version (ok)"
2724         fi
2725       done
2726     ])
2727   ], [
2728     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2729     AC_MSG_ERROR([$ltp_msg])
2730   ])
2731
2732   case $glib_cv_ltp_version in
2733     ""|invalid[)]
2734       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2735       AC_MSG_ERROR([$ltp_msg])
2736       LTP="exit 0;"
2737       ;;
2738   esac
2739
2740   if test -z "$LTP_GENHTML"; then
2741     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2742   fi
2743
2744   dnl Remove all optimization flags from CFLAGS
2745   changequote({,})
2746   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2747   changequote([,])
2748
2749   dnl Add the special gcc flags
2750   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2751   LDFLAGS="$LDFLAGS -lgcov"
2752 ])
2753
2754 dnl ******************************
2755 dnl *** output the whole stuff ***
2756 dnl ******************************
2757
2758 dnl this section will only be run if config.status is invoked with no
2759 dnl arguments, or with "glib/glibconfig.h" as an argument.
2760 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2761 [
2762         outfile=glib/glibconfig.h-tmp
2763         cat > $outfile <<\_______EOF
2764 /* glibconfig.h
2765  *
2766  * This is a generated file.  Please modify 'configure.ac'
2767  */
2768
2769 #ifndef __GLIBCONFIG_H__
2770 #define __GLIBCONFIG_H__
2771
2772 #include <glib/gmacros.h>
2773
2774 _______EOF
2775
2776         echo '#include <limits.h>' >> $outfile
2777         echo '#include <float.h>' >> $outfile
2778         if test x$glib_values_h = xyes; then
2779           echo '#include <values.h>' >> $outfile
2780         fi
2781         if test "$glib_header_alloca_h" = "yes"; then
2782           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2783         fi
2784         if test x$glib_included_printf != xyes; then
2785           echo "
2786 /* Specifies that GLib's g_print*() functions wrap the
2787  * system printf functions.  This is useful to know, for example,
2788  * when using glibc's register_printf_function().
2789  */" >> $outfile
2790           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2791         fi
2792
2793         cat >> $outfile <<_______EOF
2794
2795 G_BEGIN_DECLS
2796
2797 #define G_MINFLOAT      FLT_MIN
2798 #define G_MAXFLOAT      FLT_MAX
2799 #define G_MINDOUBLE     DBL_MIN
2800 #define G_MAXDOUBLE     DBL_MAX
2801 #define G_MINSHORT      SHRT_MIN
2802 #define G_MAXSHORT      SHRT_MAX
2803 #define G_MAXUSHORT     USHRT_MAX
2804 #define G_MININT        INT_MIN
2805 #define G_MAXINT        INT_MAX
2806 #define G_MAXUINT       UINT_MAX
2807 #define G_MINLONG       LONG_MIN
2808 #define G_MAXLONG       LONG_MAX
2809 #define G_MAXULONG      ULONG_MAX
2810
2811 _______EOF
2812
2813
2814         ### this should always be true in a modern C/C++ compiler
2815         cat >>$outfile <<_______EOF
2816 typedef signed char gint8;
2817 typedef unsigned char guint8;
2818 _______EOF
2819
2820
2821         if test -n "$gint16"; then
2822           cat >>$outfile <<_______EOF
2823 typedef signed $gint16 gint16;
2824 typedef unsigned $gint16 guint16;
2825 #define G_GINT16_MODIFIER $gint16_modifier
2826 #define G_GINT16_FORMAT $gint16_format
2827 #define G_GUINT16_FORMAT $guint16_format
2828 _______EOF
2829         fi
2830
2831
2832         if test -n "$gint32"; then
2833           cat >>$outfile <<_______EOF
2834 typedef signed $gint32 gint32;
2835 typedef unsigned $gint32 guint32;
2836 #define G_GINT32_MODIFIER $gint32_modifier
2837 #define G_GINT32_FORMAT $gint32_format
2838 #define G_GUINT32_FORMAT $guint32_format
2839 _______EOF
2840         fi
2841
2842         cat >>$outfile <<_______EOF
2843 #define G_HAVE_GINT64 1          /* deprecated, always true */
2844
2845 ${glib_extension}typedef signed $gint64 gint64;
2846 ${glib_extension}typedef unsigned $gint64 guint64;
2847
2848 #define G_GINT64_CONSTANT(val)  $gint64_constant
2849 #define G_GUINT64_CONSTANT(val) $guint64_constant
2850 _______EOF
2851
2852         if test x$gint64_format != x ; then
2853           cat >>$outfile <<_______EOF
2854 #define G_GINT64_MODIFIER $gint64_modifier
2855 #define G_GINT64_FORMAT $gint64_format
2856 #define G_GUINT64_FORMAT $guint64_format
2857 _______EOF
2858         else
2859           cat >>$outfile <<_______EOF
2860 #undef G_GINT64_MODIFIER
2861 #undef G_GINT64_FORMAT
2862 #undef G_GUINT64_FORMAT
2863 _______EOF
2864         fi
2865
2866         cat >>$outfile <<_______EOF
2867
2868 #define GLIB_SIZEOF_VOID_P $glib_void_p
2869 #define GLIB_SIZEOF_LONG   $glib_long
2870 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2871 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2872
2873 _______EOF
2874
2875         cat >>$outfile <<_______EOF
2876 typedef signed $glib_ssize_type_define gssize;
2877 typedef unsigned $glib_size_type_define gsize;
2878 #define G_GSIZE_MODIFIER $gsize_modifier
2879 #define G_GSSIZE_MODIFIER $gssize_modifier
2880 #define G_GSIZE_FORMAT $gsize_format
2881 #define G_GSSIZE_FORMAT $gssize_format
2882
2883 #define G_MAXSIZE       G_MAXU$glib_msize_type
2884 #define G_MINSSIZE      G_MIN$glib_mssize_type
2885 #define G_MAXSSIZE      G_MAX$glib_mssize_type
2886
2887 typedef gint64 goffset;
2888 #define G_MINOFFSET     G_MININT64
2889 #define G_MAXOFFSET     G_MAXINT64
2890
2891 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2892 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2893 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2894
2895 _______EOF
2896
2897         if test -z "$glib_unknown_void_p"; then
2898           cat >>$outfile <<_______EOF
2899
2900 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2901 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2902
2903 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2904 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2905
2906 typedef signed $glib_intptr_type_define gintptr;
2907 typedef unsigned $glib_intptr_type_define guintptr;
2908
2909 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2910 #define G_GINTPTR_FORMAT        $gintptr_format
2911 #define G_GUINTPTR_FORMAT       $guintptr_format
2912 _______EOF
2913         else
2914           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2915         fi
2916
2917
2918
2919         cat >>$outfile <<_______EOF
2920 #ifndef G_DISABLE_DEPRECATED
2921 #define g_ATEXIT(proc)  (atexit (proc))
2922 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2923 #endif
2924 $glib_defines
2925 $glib_os
2926 $glib_static_compilation
2927
2928 $glib_vacopy
2929
2930 #ifdef  __cplusplus
2931 #define G_HAVE_INLINE   1
2932 #else   /* !__cplusplus */
2933 $glib_inline
2934 #endif  /* !__cplusplus */
2935
2936 #ifdef  __cplusplus
2937 #define G_CAN_INLINE    1
2938 _______EOF
2939
2940         if test x$g_can_inline = xyes ; then
2941                 cat >>$outfile <<_______EOF
2942 #else   /* !__cplusplus */
2943 #define G_CAN_INLINE    1
2944 _______EOF
2945         fi
2946
2947         cat >>$outfile <<_______EOF
2948 #endif
2949
2950 _______EOF
2951
2952         if test x$g_have_iso_c_varargs = xyes ; then
2953                 cat >>$outfile <<_______EOF
2954 #ifndef __cplusplus
2955 # define G_HAVE_ISO_VARARGS 1
2956 #endif
2957 _______EOF
2958         fi
2959         if test x$g_have_iso_cxx_varargs = xyes ; then
2960                 cat >>$outfile <<_______EOF
2961 #ifdef __cplusplus
2962 # define G_HAVE_ISO_VARARGS 1
2963 #endif
2964 _______EOF
2965         fi
2966         if test x$g_have_gnuc_varargs = xyes ; then
2967                 cat >>$outfile <<_______EOF
2968
2969 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2970  * is passed ISO vararg support is turned off, and there is no work
2971  * around to turn it on, so we unconditionally turn it off.
2972  */
2973 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2974 #  undef G_HAVE_ISO_VARARGS
2975 #endif
2976
2977 #define G_HAVE_GNUC_VARARGS 1
2978 _______EOF
2979         fi
2980
2981         case x$g_stack_grows in
2982         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2983         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2984         esac
2985
2986
2987         echo >>$outfile
2988         if test x$g_have_eilseq = xno; then
2989                 cat >>$outfile <<_______EOF
2990 #ifndef EILSEQ
2991 /* On some pre-C99 systems, EILSEQ is not defined.
2992  * The correspondence between this and the corresponding definition
2993  * in libiconv is essential.
2994  */
2995 #  define EILSEQ ENOENT
2996 #endif
2997 _______EOF
2998
2999         fi
3000
3001         if test x$g_have_gnuc_visibility = xyes; then
3002                 cat >>$outfile <<_______EOF
3003 #define G_HAVE_GNUC_VISIBILITY 1
3004 _______EOF
3005         fi
3006                 cat >>$outfile <<_______EOF
3007 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3008 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3009 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3010 #define G_GNUC_INTERNAL __hidden
3011 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3012 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3013 #else
3014 #define G_GNUC_INTERNAL
3015 #endif
3016 _______EOF
3017
3018         echo >>$outfile
3019         cat >>$outfile <<_______EOF
3020 #define G_THREADS_ENABLED
3021 #define G_THREADS_IMPL_$g_threads_impl_def
3022 _______EOF
3023
3024         if test x"$g_memory_barrier_needed" != xno; then
3025           echo >>$outfile
3026           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3027         fi
3028         if test x"$g_atomic_lock_free" = xyes; then
3029           echo >>$outfile
3030           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3031         fi
3032         echo >>$outfile
3033         g_bit_sizes="16 32 64"
3034         for bits in $g_bit_sizes; do
3035           cat >>$outfile <<_______EOF
3036 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3037 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3038 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3039 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3040 _______EOF
3041         done
3042
3043         cat >>$outfile <<_______EOF
3044 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3045 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3046 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3047 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3048 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3049 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3050 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3051 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3052 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3053 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3054 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3055 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3056 #define G_BYTE_ORDER $g_byte_order
3057
3058 #define GLIB_SYSDEF_POLLIN =$g_pollin
3059 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3060 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3061 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3062 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3063 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3064
3065 #define G_MODULE_SUFFIX "$g_module_suffix"
3066
3067 typedef $g_pid_type GPid;
3068
3069 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3070 #define GLIB_SYSDEF_AF_INET $g_af_inet
3071 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3072
3073 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3074 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3075 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3076
3077 G_END_DECLS
3078
3079 #endif /* __GLIBCONFIG_H__ */
3080 _______EOF
3081
3082
3083         if cmp -s $outfile glib/glibconfig.h; then
3084           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3085           rm -f $outfile
3086         else
3087           mv $outfile glib/glibconfig.h
3088         fi
3089 ],[
3090
3091 # Note that if two cases are the same, case goes with the first one.
3092 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3093 # on variable expansion in case labels.  Look at the generated config.status
3094 # for a hint.
3095
3096 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3097   glib_header_alloca_h="$ac_cv_working_alloca_h"
3098 else
3099   glib_header_alloca_h="$ac_cv_header_alloca_h"
3100 fi
3101
3102 if test x$enable_included_printf = xyes ; then
3103   glib_included_printf=yes
3104 fi
3105
3106 case 2 in
3107 $ac_cv_sizeof_short)
3108   gint16=short
3109   gint16_modifier='"h"'
3110   gint16_format='"hi"'
3111   guint16_format='"hu"'
3112   ;;
3113 $ac_cv_sizeof_int)
3114   gint16=int
3115   gint16_modifier='""'
3116   gint16_format='"i"'
3117   guint16_format='"u"'
3118   ;;
3119 esac
3120 case 4 in
3121 $ac_cv_sizeof_short)
3122   gint32=short
3123   gint32_modifier='"h"'
3124   gint32_format='"hi"'
3125   guint32_format='"hu"'
3126   ;;
3127 $ac_cv_sizeof_int)
3128   gint32=int
3129   gint32_modifier='""'
3130   gint32_format='"i"'
3131   guint32_format='"u"'
3132   ;;
3133 $ac_cv_sizeof_long)
3134   gint32=long
3135   gint32_modifier='"l"'
3136   gint32_format='"li"'
3137   guint32_format='"lu"'
3138   ;;
3139 esac
3140 case 8 in
3141 $ac_cv_sizeof_int)
3142   gint64=int
3143   gint64_modifier='""'
3144   gint64_format='"i"'
3145   guint64_format='"u"'
3146   glib_extension=
3147   gint64_constant='(val)'
3148   guint64_constant='(val)'
3149   ;;
3150 $ac_cv_sizeof_long)
3151   gint64=long
3152   gint64_modifier='"l"'
3153   gint64_format='"li"'
3154   guint64_format='"lu"'
3155   glib_extension=
3156   gint64_constant='(val##L)'
3157   guint64_constant='(val##UL)'
3158   ;;
3159 $ac_cv_sizeof_long_long)
3160   gint64='long long'
3161   if test -n "$glib_cv_long_long_format"; then
3162     gint64_modifier='"'$glib_cv_long_long_format'"'
3163     gint64_format='"'$glib_cv_long_long_format'i"'
3164     guint64_format='"'$glib_cv_long_long_format'u"'
3165   fi
3166   glib_extension='G_GNUC_EXTENSION '
3167   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3168   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3169   ;;
3170 $ac_cv_sizeof___int64)
3171   gint64='__int64'
3172   if test -n "$glib_cv_long_long_format"; then
3173     gint64_modifier='"'$glib_cv_long_long_format'"'
3174     gint64_format='"'$glib_cv_long_long_format'i"'
3175     guint64_format='"'$glib_cv_long_long_format'u"'
3176   fi
3177   glib_extension=
3178   gint64_constant='(val##i64)'
3179   guint64_constant='(val##ui64)'
3180   ;;
3181 esac
3182 glib_size_t=$ac_cv_sizeof_size_t
3183 glib_ssize_t=$ac_cv_sizeof_ssize_t
3184 glib_size_type_define="$glib_size_type"
3185 glib_ssize_type_define="$glib_ssize_type"
3186 glib_void_p=$ac_cv_sizeof_void_p
3187 glib_long=$ac_cv_sizeof_long
3188
3189 case "$glib_size_type" in
3190 short)
3191   gsize_modifier='"h"'
3192   gsize_format='"hu"'
3193   glib_msize_type='SHRT'
3194   ;;
3195 int)
3196   gsize_modifier='""'
3197   gsize_format='"u"'
3198   glib_msize_type='INT'
3199   ;;
3200 long)
3201   gsize_modifier='"l"'
3202   gsize_format='"lu"'
3203   glib_msize_type='LONG'
3204   ;;
3205 "long long"|__int64)
3206   gsize_modifier='"I64"'
3207   gsize_format='"I64u"'
3208   glib_msize_type='INT64'
3209   ;;
3210 esac
3211
3212 case "$glib_ssize_type" in
3213 short)
3214   gssize_modifier='"h"'
3215   gssize_format='"hi"'
3216   glib_mssize_type='SHRT'
3217   ;;
3218 int)
3219   gssize_modifier='""'
3220   gssize_format='"i"'
3221   glib_mssize_type='INT'
3222   ;;
3223 long)
3224   gssize_modifier='"l"'
3225   gssize_format='"li"'
3226   glib_mssize_type='LONG'
3227   ;;
3228 "long long"|__int64)
3229   gssize_modifier='"I64"'
3230   gssize_format='"I64i"'
3231   glib_mssize_type='INT64'
3232   ;;
3233 esac
3234
3235 gintbits=`expr $ac_cv_sizeof_int \* 8`
3236 glongbits=`expr $ac_cv_sizeof_long \* 8`
3237 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3238 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3239
3240 case $ac_cv_sizeof_void_p in
3241 $ac_cv_sizeof_int)
3242   glib_intptr_type_define=int
3243   gintptr_modifier='""'
3244   gintptr_format='"i"'
3245   guintptr_format='"u"'
3246   glib_gpi_cast='(gint)'
3247   glib_gpui_cast='(guint)'
3248   ;;
3249 $ac_cv_sizeof_long)
3250   glib_intptr_type_define=long
3251   gintptr_modifier='"l"'
3252   gintptr_format='"li"'
3253   guintptr_format='"lu"'
3254   glib_gpi_cast='(glong)'
3255   glib_gpui_cast='(gulong)'
3256   ;;
3257 $ac_cv_sizeof_long_long)
3258   glib_intptr_type_define='long long'
3259   gintptr_modifier='"I64"'
3260   gintptr_format='"I64i"'
3261   guintptr_format='"I64u"'
3262   glib_gpi_cast='(gint64)'
3263   glib_gpui_cast='(guint64)'
3264   ;;
3265 $ac_cv_sizeof___int64)
3266   glib_intptr_type_define=__int64
3267   gintptr_modifier='"I64"'
3268   gintptr_format='"I64i"'
3269   guintptr_format='"I64u"'
3270   glib_gpi_cast='(gint64)'
3271   glib_gpui_cast='(guint64)'
3272   ;;
3273 *)
3274   glib_unknown_void_p=yes
3275   ;;
3276 esac
3277
3278
3279 glib_defines="
3280 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3281 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3282 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3283 "
3284
3285 case xyes in
3286 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3287 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3288 *)                      glib_vacopy=''
3289 esac
3290
3291 if test x$glib_cv_va_val_copy = xno; then
3292   glib_vacopy="\$glib_vacopy
3293 #define G_VA_COPY_AS_ARRAY 1"
3294 fi
3295
3296 if test x$glib_cv_hasinline = xyes; then
3297     glib_inline='#define G_HAVE_INLINE 1'
3298 fi
3299 if test x$glib_cv_has__inline = xyes; then
3300     glib_inline="\$glib_inline
3301 #define G_HAVE___INLINE 1"
3302 fi
3303 if test x$glib_cv_has__inline__ = xyes; then
3304     glib_inline="\$glib_inline
3305 #define G_HAVE___INLINE__ 1"
3306 fi
3307
3308 g_have_gnuc_varargs=$g_have_gnuc_varargs
3309 g_have_iso_c_varargs=$g_have_iso_c_varargs
3310 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3311
3312 g_can_inline=$g_can_inline
3313 g_have_gnuc_visibility=$g_have_gnuc_visibility
3314 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3315
3316 if test x$ac_cv_c_bigendian = xyes; then
3317   g_byte_order=G_BIG_ENDIAN
3318   g_bs_native=BE
3319   g_bs_alien=LE
3320 else
3321   g_byte_order=G_LITTLE_ENDIAN
3322   g_bs_native=LE
3323   g_bs_alien=BE
3324 fi
3325
3326 g_pollin=$glib_cv_value_POLLIN
3327 g_pollout=$glib_cv_value_POLLOUT
3328 g_pollpri=$glib_cv_value_POLLPRI
3329 g_pollhup=$glib_cv_value_POLLHUP
3330 g_pollerr=$glib_cv_value_POLLERR
3331 g_pollnval=$glib_cv_value_POLLNVAL
3332
3333 # If a family is not found on the system, define that family to
3334 # a negative value, picking a different one for each undefined
3335 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3336 # This is needed because glib-mkenums doesn't handle optional
3337 # values in enums, and thus we have to have all existing values
3338 # defined in the enum.
3339 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3340   g_af_unix=$glib_cv_value_AF_UNIX
3341 else
3342   g_af_unix=-1
3343 fi
3344 g_af_inet=$glib_cv_value_AF_INET
3345 g_af_inet6=$glib_cv_value_AF_INET6
3346
3347 g_msg_peek=$glib_cv_value_MSG_PEEK
3348 g_msg_oob=$glib_cv_value_MSG_OOB
3349 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3350
3351 g_stack_grows=$glib_cv_stack_grows
3352
3353 g_have_eilseq=$have_eilseq
3354
3355 g_threads_impl_def=$g_threads_impl
3356
3357 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3358 g_memory_barrier_needed="$glib_memory_barrier_needed"
3359 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3360
3361 g_module_suffix="$glib_gmodule_suffix"
3362
3363 g_pid_type="$glib_pid_type"
3364 case $host in
3365   *-*-cygwin*)
3366     glib_os="#define G_OS_UNIX
3367 #define G_PLATFORM_WIN32
3368 #define G_WITH_CYGWIN"
3369     ;;
3370   *-*-mingw*)
3371     glib_os="#define G_OS_WIN32
3372 #define G_PLATFORM_WIN32"
3373     ;;
3374   *)
3375     glib_os="#define G_OS_UNIX"
3376     ;;
3377 esac
3378 glib_static_compilation=""
3379 if test x$glib_win32_static_compilation = xyes; then
3380   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3381 #define GOBJECT_STATIC_COMPILATION 1"
3382 fi
3383 ])
3384
3385 # Redo enough to get guint32 and guint64 for the alignment checks below
3386 case 4 in
3387 $ac_cv_sizeof_short)
3388   gint32=short
3389   ;;
3390 $ac_cv_sizeof_int)
3391   gint32=int
3392   ;;
3393 $ac_cv_sizeof_long)
3394   gint32=long
3395   ;;
3396 esac
3397 case 8 in
3398 $ac_cv_sizeof_int)
3399   gint64=int
3400   ;;
3401 $ac_cv_sizeof_long)
3402   gint64=long
3403   ;;
3404 $ac_cv_sizeof_long_long)
3405   gint64='long long'
3406   ;;
3407 $ac_cv_sizeof___int64)
3408   gint64='__int64'
3409   ;;
3410 esac
3411
3412 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3413 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3414 typedef unsigned $gint32 guint32;])
3415 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3416 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3417 typedef unsigned $gint64 guint64;])
3418 AC_CHECK_TYPE([unsigned long])
3419 AC_CHECK_ALIGNOF([unsigned long])
3420
3421 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3422 #
3423 # 1.2.14 required for dbus_message_set_serial
3424 PKG_CHECK_MODULES(DBUS1,
3425      dbus-1 >= 1.2.14,
3426      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3427      have_dbus1=no)
3428 AC_SUBST(DBUS1_CFLAGS)
3429 AC_SUBST(DBUS1_LIBS)
3430 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3431
3432 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3433 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3434
3435 dnl
3436 dnl Check for -Bsymbolic-functions linker flag used to avoid
3437 dnl intra-library PLT jumps, if available.
3438 dnl
3439
3440 AC_ARG_ENABLE(Bsymbolic,
3441               [AS_HELP_STRING([--disable-Bsymbolic],
3442                               [avoid linking with -Bsymbolic])],,
3443               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3444                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3445                LDFLAGS=-Wl,-Bsymbolic-functions
3446                LIBS=
3447                AC_TRY_LINK([], [int main (void) { return 0; }],
3448                            AC_MSG_RESULT(yes)
3449                            enable_Bsymbolic=yes,
3450                            AC_MSG_RESULT(no)
3451                            enable_Bsymbolic=no)
3452                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3453
3454 if test "x${enable_Bsymbolic}" = "xyes"; then
3455   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3456 fi
3457
3458 AC_SUBST(GLIB_LINK_FLAGS)
3459
3460 dnl
3461 dnl Check for -z,nodelete linker flag: the type system assumes that
3462 dnl libgobject stays loaded for the lifetime of the process.
3463 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3464 dnl we also try to check for the --fatal-warnings linker flag if
3465 dnl auto-detecting.
3466 dnl
3467
3468 AC_ARG_ENABLE([znodelete],
3469               [AS_HELP_STRING([--disable-znodelete],
3470                               [avoid linking with -z,nodelete])],,
3471               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3472                AC_MSG_CHECKING([for --fatal-warnings linker flag])
3473                LDFLAGS=-Wl,--fatal-warnings
3474                LIBS=
3475                AC_TRY_LINK([], [int main (void) { return 0; }],
3476                            AC_MSG_RESULT(yes)
3477                            [ldflags_fatal=-Wl,--fatal-warnings],
3478                            AC_MSG_RESULT(no)
3479                            ldflags_fatal=)
3480                AC_MSG_CHECKING([for -z,nodelete linker flag])
3481                LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3482                AC_TRY_LINK([], [int main (void) { return 0; }],
3483                            AC_MSG_RESULT(yes)
3484                            enable_znodelete=yes,
3485                            AC_MSG_RESULT(no)
3486                            enable_znodelete=no)
3487                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3488
3489 if test "x${enable_znodelete}" = "xyes"; then
3490   GOBJECT_LINK_FLAGS=-Wl,-z,nodelete
3491 fi
3492
3493 AC_SUBST(GOBJECT_LINK_FLAGS)
3494
3495 dnl
3496 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3497 dnl visibility attributes for symbol export control
3498 dnl
3499 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3500 case "$host" in
3501   *-*-mingw*)
3502     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3503     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3504               [defines how to decorate public symbols while building])
3505     CFLAGS="${CFLAGS} -fvisibility=hidden"
3506     ;;
3507   *)
3508     dnl on other compilers, check if we can do -fvisibility=hidden
3509     SAVED_CFLAGS="${CFLAGS}"
3510     CFLAGS="-fvisibility=hidden"
3511     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3512     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3513                    AC_MSG_RESULT(yes)
3514                    enable_fvisibility_hidden=yes,
3515                    AC_MSG_RESULT(no)
3516                    enable_fvisibility_hidden=no)
3517     CFLAGS="${SAVED_CFLAGS}"
3518
3519     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3520       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3521                 [defines how to decorate public symbols while building])
3522       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3523     ])
3524     ;;
3525 esac
3526 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3527
3528 dnl Compiler flags; macro originates from systemd
3529 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3530 AC_ARG_ENABLE(compile-warnings,
3531               [AS_HELP_STRING([--disable-compile-warnings],
3532                               [Don't use builtin compiler warnings])],,
3533                               enable_compile_warnings=yes)
3534 AS_IF([test "x$enable_compile_warnings" = xyes], [
3535   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3536    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3537    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3538    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3539    -Werror=format=2 -Werror=missing-include-dirs])
3540 ])
3541 AC_SUBST(GLIB_WARN_CFLAGS)
3542
3543 #
3544 # Define variables corresponding to the correct include paths to use for
3545 # in-tree building.
3546 #
3547
3548 # for config.h:
3549 config_h_INCLUDES='-I$(top_builddir)'
3550 AC_SUBST(config_h_INCLUDES)
3551
3552 # glib:
3553 #   config.h
3554 #   $(top_builddir)/glib: for glibconfig.h
3555 #   $(top_srcdir)/glib:   for glib.h
3556 #   $(top_srcdir):        for everything
3557 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3558 AC_SUBST(glib_INCLUDES)
3559
3560 # gobject:
3561 #   same as glib
3562 gobject_INCLUDES='$(glib_INCLUDES)'
3563 AC_SUBST(gobject_INCLUDES)
3564
3565 # gmodule:
3566 #   glib includes
3567 #   $(top_srcdir)/gmodule: for gmodule.h
3568 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3569 AC_SUBST(gmodule_INCLUDES)
3570
3571 # gio:
3572 #   same as gmodule
3573 gio_INCLUDES='$(gmodule_INCLUDES)'
3574 AC_SUBST(gio_INCLUDES)
3575
3576
3577 AC_CONFIG_FILES([
3578 glib-2.0.pc
3579 gmodule-2.0.pc
3580 gmodule-export-2.0.pc
3581 gmodule-no-export-2.0.pc
3582 gthread-2.0.pc
3583 gobject-2.0.pc
3584 gio-2.0.pc
3585 gio-unix-2.0.pc
3586 gio-windows-2.0.pc
3587 glib-zip
3588 glib-gettextize
3589 Makefile
3590 build/Makefile
3591 build/win32/Makefile
3592 build/win32/dirent/Makefile
3593 build/win32/vs9/Makefile
3594 build/win32/vs10/Makefile
3595 build/win32/vs11/Makefile
3596 build/win32/vs12/Makefile
3597 glib/Makefile
3598 glib/glib.stp
3599 glib/libcharset/Makefile
3600 glib/gnulib/Makefile
3601 glib/pcre/Makefile
3602 glib/update-pcre/Makefile
3603 glib/tests/Makefile
3604 gmodule/Makefile
3605 gmodule/gmoduleconf.h
3606 gobject/Makefile
3607 gobject/gobject.stp
3608 gobject/glib-mkenums
3609 gobject/tests/Makefile
3610 gthread/Makefile
3611 gio/Makefile
3612 gio/gdbus-2.0/codegen/Makefile
3613 gio/gdbus-2.0/codegen/config.py
3614 gio/gnetworking.h
3615 gio/xdgmime/Makefile
3616 gio/inotify/Makefile
3617 gio/kqueue/Makefile
3618 gio/fen/Makefile
3619 gio/fam/Makefile
3620 gio/win32/Makefile
3621 gio/tests/Makefile
3622 gio/tests/gdbus-object-manager-example/Makefile
3623 gio/tests/services/Makefile
3624 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3625 gio/tests/modules/Makefile
3626 po/Makefile.in
3627 docs/Makefile
3628 docs/reference/Makefile
3629 docs/reference/glib/Makefile
3630 docs/reference/glib/version.xml
3631 docs/reference/gobject/Makefile
3632 docs/reference/gobject/version.xml
3633 docs/reference/gio/Makefile
3634 docs/reference/gio/gdbus-object-manager-example/Makefile
3635 docs/reference/gio/version.xml
3636 tests/Makefile
3637 tests/gobject/Makefile
3638 tests/refcount/Makefile
3639 m4macros/Makefile
3640 ])
3641
3642 AC_CONFIG_COMMANDS([chmod-scripts],
3643 [chmod 0755 glib-zip
3644 chmod 0755 glib-gettextize
3645 chmod 0755 gobject/glib-mkenums])
3646
3647 # we want to invoke this macro solely so that the config.status script
3648 # and automake generated makefiles know about these generated files.
3649 # They are only needed to distcheck the package
3650 if false; then
3651   AC_CONFIG_FILES([
3652     INSTALL
3653     README
3654     config.h.win32
3655     glib/glibconfig.h.win32
3656     glib/makefile.msc
3657     glib/glib.rc
3658     gmodule/makefile.msc
3659     gmodule/gmodule.rc
3660     gobject/makefile.msc
3661     gobject/gobject.rc
3662     gthread/makefile.msc
3663     gthread/gthread.rc
3664     gio/gio.rc
3665     tests/makefile.msc
3666   ])
3667 fi
3668
3669 AC_OUTPUT