configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [4])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # glib version number
  13 m4_define([glib_major_version], [2])
  14 m4_define([glib_minor_version], [4])
  15 m4_define([glib_micro_version], [0])
  16 m4_define([glib_major_minor_version],
  17           [glib_major_version.glib_minor_version])
  18 m4_define([glib_version],
  19           [glib_major_version.glib_minor_version.glib_micro_version])
  20
  21 # gst version number
  22 m4_define([gst_major_version], [0])
  23 m4_define([gst_minor_version], [10])
  24 m4_define([gst_micro_version], [14])
  25 m4_define([gst_major_minor_version],
  26           [gst_major_version.gst_minor_version])
  27 m4_define([gst_version],
  28           [gst_major_version.gst_minor_version.gst_micro_version])
  29
  30 # gst plugins-base version number
  31 m4_define([gst_plugins_base_major_version], [0])
  32 m4_define([gst_plugins_base_minor_version], [10])
  33 m4_define([gst_plugins_base_micro_version], [31])
  34 m4_define([gst_plugins_base_version],
  35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  36
  37 # VA-API minimum version number
  38 m4_define([va_api_x11_version], [0.31.0])
  39 m4_define([va_api_glx_version], [0.32.0])
  40
  41 # gst plugins-bad version number
  42 m4_define([gst_plugins_bad_major_version], [0])
  43 m4_define([gst_plugins_bad_minor_version], [10])
  44 m4_define([gst_plugins_bad_micro_version], [22])
  45 m4_define([gst_plugins_bad_version],
  46           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  47
  48 # libva package version number
  49 m4_define([libva_x11_package_version], [1.0.3])
  50 m4_define([libva_glx_package_version], [1.0.9])
  51
  52 # gtk-doc version number
  53 # XXX: introspection annotations require gtk-doc >= 1.12
  54 m4_define([gtkdoc_major_version], [1])
  55 m4_define([gtkdoc_minor_version], [9])
  56 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  57
  58 AC_PREREQ([2.58])
  59 AC_INIT([gst_vaapi], [gst_vaapi_version],
  60     [gwenole.beauchesne@intel.com],
  61     [gstreamer-vaapi])
  62
  63 AC_CONFIG_HEADERS([config.h])
  64 AC_CONFIG_SRCDIR([Makefile.am])
  65 AC_CONFIG_MACRO_DIR([m4])
  66 AC_CONFIG_AUX_DIR([build-aux])
  67
  68 AC_CANONICAL_TARGET
  69
  70 AM_INIT_AUTOMAKE
  71
  72 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  73 AC_SUBST(TODAY)
  74
  75 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  76 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  77
  78 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  79 AC_SUBST(LIBVA_PACKAGE_VERSION)
  80
  81 dnl Versions for GStreamer and plugins-base
  82 GST_MAJORMINOR=gst_major_minor_version
  83 GST_VERSION_REQUIRED=gst_version
  84 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  85 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
  86 AC_SUBST(GST_MAJORMINOR)
  87 AC_SUBST(GST_VERSION_REQUIRED)
  88 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
  89
  90 dnl Use pretty build output with automake >= 1.11
  91 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  92   AM_DEFAULT_VERBOSITY=1
  93   AC_SUBST(AM_DEFAULT_VERBOSITY)
  94 ])
  95
  96 dnl Check for tools
  97 AC_PROG_CC
  98 AM_PROG_CC_C_O
  99 AC_PROG_LIBTOOL
 100
 101 AC_ARG_ENABLE(glx,
 102     AS_HELP_STRING([--enable-glx],
 103                    [enable OpenGL/X11 @<:@default=yes@:>@]),
 104     [], [enable_glx="yes"])
 105
 106 AC_ARG_ENABLE(vaapi-glx,
 107     AS_HELP_STRING([--enable-vaapi-glx],
 108                    [enable VA/GLX extensions @<:@default=yes@:>@]),
 109     [], [enable_vaapi_glx="yes"])
 110
 111 AC_ARG_ENABLE(vaapisink-glx,
 112     AS_HELP_STRING([--enable-vaapisink-glx],
 113                    [enable OpenGL/X11 to vaapisink @<:@default=yes@:>@]),
 114     [], [enable_vaapisink_glx="no"])
 115
 116 AC_ARG_ENABLE(ffmpeg,
 117     AS_HELP_STRING([--enable-ffmpeg],
 118                    [enable bitstream parsing from FFmpeg @<:@default=no@:>@]),
 119     [], [enable_ffmpeg="no"])
 120
 121 AC_ARG_ENABLE(codecparsers,
 122     AS_HELP_STRING([--enable-codecparsers],
 123                    [enable adhoc bitstream parsers from GStreamer @<:@default=yes@:>@]),
 124     [], [enable_codecparsers="yes"])
 125
 126 dnl Check for __attribute__((visibility()))
 127 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 128   vaapi_cv_visibility_attribute,
 129   [cat > conftest.c <<EOF
 130 int foo __attribute__ ((visibility ("hidden"))) = 1;
 131 int bar __attribute__ ((visibility ("protected"))) = 1;
 132 EOF
 133   vaapi_cv_visibility_attribute=no
 134   if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 135     if grep '\.hidden.*foo' conftest.s >/dev/null; then
 136       if grep '\.protected.*bar' conftest.s >/dev/null; then
 137         vaapi_cv_visibility_attribute=yes
 138       fi
 139     fi
 140   fi
 141   rm -f conftest.[cs]
 142 ])
 143 if test $vaapi_cv_visibility_attribute = yes; then
 144   vaapi_cv_visibility_attribute_hidden="__attribute__((visibility(\"hidden\")))"
 145 else
 146   vaapi_cv_visibility_attribute_hidden=""
 147 fi
 148 AC_DEFINE_UNQUOTED([attribute_hidden],
 149                    [$vaapi_cv_visibility_attribute_hidden],
 150                    [Define the "hidden" visibility attribute])
 151
 152 dnl Check for basic libraries
 153 AC_CHECK_LIB(m, tan)
 154
 155 dnl Check for Gtk doc
 156 GTKDOC_VERSION=gtkdoc_version
 157 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 158 m4_ifdef([GTK_DOC_CHECK], [
 159 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 160 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 161 AC_SUBST(GTKDOC_VERSION)
 162
 163 dnl Check for GLib
 164 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= glib_version])
 165
 166 dnl Check for GStreamer
 167 PKG_CHECK_MODULES([GST],
 168     [gstreamer-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 169 )
 170
 171 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 172     saved_CFLAGS="$CFLAGS"
 173     CFLAGS="$CFLAGS $GST_CFLAGS"
 174     saved_LIBS="$LIBS"
 175     LIBS="$LIBS $GST_LIBS"
 176     AC_COMPILE_IFELSE(
 177         [AC_LANG_PROGRAM(
 178             [[#include <gst/base/gstbasesink.h>]],
 179             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 180         [ac_cv_have_gst_base_sink_query="yes"],
 181         [ac_cv_have_gst_base_sink_query="no"]
 182     )
 183     CFLAGS="$saved_CFLAGS"
 184     LIBS="$saved_LIBS"
 185 ])
 186 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 187     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 188 fi
 189
 190 dnl Check for GStreamer plugins-base
 191 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 192     [gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_VERSION_REQUIRED]
 193 )
 194
 195 V=`$PKG_CONFIG --modversion gstreamer-plugins-base-$GST_MAJORMINOR`
 196 GST_PLUGINS_BASE_MAJOR_VERSION=`echo "$V" | cut -d'.' -f1`
 197 GST_PLUGINS_BASE_MINOR_VERSION=`echo "$V" | cut -d'.' -f2`
 198 GST_PLUGINS_BASE_MICRO_VERSION=`echo "$V" | cut -d'.' -f3`
 199 AC_SUBST(GST_PLUGINS_BASE_MAJOR_VERSION)
 200 AC_SUBST(GST_PLUGINS_BASE_MINOR_VERSION)
 201 AC_SUBST(GST_PLUGINS_BASE_MICRO_VERSION)
 202
 203 dnl Check for GStreamer base
 204 PKG_CHECK_MODULES([GST_BASE],
 205     [gstreamer-base-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 206 )
 207
 208 dnl Check for GStreamer video
 209 PKG_CHECK_MODULES([GST_VIDEO],
 210     [gstreamer-video-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 211 )
 212
 213 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 214     ac_cv_have_gst_video_overlay_composition, [
 215     saved_CFLAGS="$CFLAGS"
 216     CFLAGS="$CFLAGS $GST_CFLAGS"
 217     saved_LIBS="$LIBS"
 218     LIBS="$LIBS $GST_LIBS"
 219     AC_COMPILE_IFELSE(
 220         [AC_LANG_PROGRAM(
 221             [[#include <gst/video/video-overlay-composition.h>]],
 222             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 223         [ac_cv_have_gst_video_overlay_composition="yes"],
 224         [ac_cv_have_gst_video_overlay_composition="no"]
 225     )
 226     CFLAGS="$saved_CFLAGS"
 227     LIBS="$saved_LIBS"
 228 ])
 229 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 230     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 231 fi
 232
 233 dnl Check for GStreamer basevideo
 234 PKG_CHECK_MODULES([GST_BASEVIDEO],
 235     [gstreamer-basevideo-$GST_MAJORMINOR >= $GST_PLUGINS_BAD_VERSION_REQUIRED]
 236 )
 237
 238 dnl Check for GStreamer codec parsers
 239 USE_CODEC_PARSERS=0
 240 if test "$enable_codecparsers" = "yes"; then
 241 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 242     [gstreamer-codecparsers-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED],
 243     [enable_codecparsers="yes" USE_CODEC_PARSERS=1],
 244     [enable_codecparsers="no"  USE_CODEC_PARSERS=0]
 245 )
 246 fi
 247
 248 AC_DEFINE_UNQUOTED(USE_CODEC_PARSERS, $USE_CODEC_PARSERS,
 249     [Defined to 1 if GStreamer codec parsers are used])
 250 AM_CONDITIONAL(USE_CODEC_PARSERS, test $USE_CODEC_PARSERS -eq 1)
 251
 252 USE_LOCAL_CODEC_PARSERS=0
 253 if test "$enable_codecparsers" = "yes"; then
 254 AC_CACHE_CHECK([for GstH264SliceHdr::n_emulation_prevention_bytes],
 255     ac_cv_have_gst_h264_slice_hdr_epb_count, [
 256     saved_CFLAGS="$CFLAGS"
 257     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 258     saved_LIBS="$LIBS"
 259     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 260     AC_COMPILE_IFELSE(
 261         [AC_LANG_PROGRAM(
 262             [[#include <gst/codecparsers/gsth264parser.h>]],
 263             [[GstH264SliceHdr slice_hdr;
 264               slice_hdr.n_emulation_prevention_bytes = 0;]])],
 265         [ac_cv_have_gst_h264_slice_hdr_epb_count="yes"],
 266         [ac_cv_have_gst_h264_slice_hdr_epb_count="no"]
 267     )
 268     CFLAGS="$saved_CFLAGS"
 269     LIBS="$saved_LIBS"
 270 ])
 271
 272 AC_CACHE_CHECK([for JPEG parser],
 273     ac_cv_have_gst_jpeg_parser, [
 274     saved_CFLAGS="$CFLAGS"
 275     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 276     saved_LIBS="$LIBS"
 277     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 278     AC_COMPILE_IFELSE(
 279         [AC_LANG_PROGRAM(
 280             [[#include <gst/codecparsers/gstjpegparser.h>]],
 281             [[GstJpegImage jpeg_image;]])],
 282         [ac_cv_have_gst_jpeg_parser="yes"],
 283         [ac_cv_have_gst_jpeg_parser="no" USE_LOCAL_CODEC_PARSERS=1]
 284     )
 285     CFLAGS="$saved_CFLAGS"
 286     LIBS="$saved_LIBS"
 287 ])
 288 fi
 289
 290 if test "$ac_cv_have_gst_h264_slice_hdr_epb_count" = "yes"; then
 291     AC_DEFINE_UNQUOTED(HAVE_GST_H264_SLICE_HDR_EPB_COUNT, 1,
 292         [Defined to 1 if GstH264SliceHdr::n_emulation_prevention_bytes exists.])
 293 fi
 294
 295 if test "$ac_cv_have_gst_jpeg_parser" = "yes"; then
 296     AC_DEFINE_UNQUOTED(HAVE_GST_JPEG_PARSER, 1,
 297         [Defined to 1 if JPEG parser exists.])
 298 fi
 299 AM_CONDITIONAL(USE_LOCAL_CODEC_PARSERS, test $USE_LOCAL_CODEC_PARSERS -eq 1)
 300
 301 dnl Check for GStreamer interfaces
 302 PKG_CHECK_MODULES([GST_INTERFACES],
 303     [gstreamer-interfaces-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_VERSION_REQUIRED]
 304 )
 305
 306 dnl GST_ALL_LDFLAGS:
 307 dnl LDFLAGS really should only contain flags, not libs - they get added before
 308 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 309 GST_ALL_LDFLAGS="-no-undefined"
 310 AC_SUBST(GST_ALL_LDFLAGS)
 311
 312 dnl GST_PLUGIN_LDFLAGS:
 313 dnl this really should only contain flags, not libs - they get added before
 314 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 315 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 316 AC_SUBST(GST_PLUGIN_LDFLAGS)
 317
 318 dnl Check for the GStreamer plugins directory
 319 AC_MSG_CHECKING([for GStreamer plugins directory])
 320 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 321 if test -z "$GST_PLUGINS_DIR"; then
 322     echo "FAIL FAIL FAIL"
 323     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 324 fi
 325 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 326 plugindir="$GST_PLUGINS_DIR"
 327 AC_SUBST(plugindir)
 328
 329 dnl Check for X11
 330 PKG_CHECK_MODULES(X11, [x11])
 331
 332 dnl Check for OpenGL
 333 USE_GLX=1
 334 if test "$enable_glx" != "yes"; then
 335     USE_GLX=0
 336 fi
 337 GLX_CFLAGS=""
 338 GLX_LIBS=""
 339 AC_CHECK_HEADERS([GL/gl.h GL/glext.h GL/glx.h], [], [USE_GLX=0], [
 340 #ifdef HAVE_GL_GL_H
 341 # include <GL/gl.h>
 342 #endif
 343 ])
 344 AC_CHECK_LIB(GL, glXCreateContext, [GLX_LIBS="-lGL"], [USE_GLX=0])
 345 AC_SUBST(GLX_CFLAGS)
 346 AC_SUBST(GLX_LIBS)
 347
 348 dnl Check for VA-API
 349 LIBVA_PKGNAME="libva"
 350 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME])
 351 AC_SUBST(LIBVA_PKGNAME)
 352
 353 dnl ... original VA-API 0.29
 354 AC_CACHE_CHECK([for old VA-API 0.29],
 355     ac_cv_have_vaapi_old, [
 356     saved_CFLAGS="$CFLAGS"
 357     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 358     saved_LIBS="$LIBS"
 359     LIBS="$LIBS $LIBVA_LIBS"
 360     AC_LINK_IFELSE(
 361         [AC_LANG_PROGRAM(
 362             [[#include <va_x11.h>]],
 363             [[vaGetDisplay(NULL)]])],
 364         [ac_cv_have_vaapi_old="yes"],
 365         [ac_cv_have_vaapi_old="no"]
 366     )
 367     CFLAGS="$saved_CFLAGS"
 368     LIBS="$saved_LIBS"
 369 ])
 370 if test "$ac_cv_have_vaapi_old" = "yes"; then
 371     LIBVA_EXTRA_CFLAGS="$LIBVA_CFLAGS -DGST_VAAPI_USE_OLD_VAAPI_0_29"
 372 fi
 373
 374 dnl ... VA-API >= 0.31 or -sds
 375 LIBVA_X11_PKGNAME="libva-x11"
 376 PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME],
 377     [ac_cv_have_vaapi_x11="yes"],
 378     [ac_cv_have_vaapi_x11="no"]
 379 )
 380 if test "$ac_cv_have_vaapi_x11" = "no"; then
 381     if test "$ac_cv_have_vaapi_old" = "yes"; then
 382         LIBVA_X11_PKGNAME="libva"
 383         CFLAGS="$CFLAGS $LIBVA_EXTRA_CFLAGS"
 384         LIBS="$LIBS $LIBVA_EXTRA_LIBS"
 385     else
 386         AC_MSG_ERROR([could not find VA-API])
 387     fi
 388 fi
 389 AC_SUBST(LIBVA_X11_PKGNAME)
 390
 391 dnl ... VA-API >= 0.31 or -sds (VA/GLX extensions)
 392 USE_VAAPI_GLX=0
 393 if test $USE_GLX -eq 1; then
 394     if test "$enable_vaapi_glx" = "yes"; then
 395         LIBVA_GLX_PKGNAME="libva-glx"
 396         PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME],
 397             [ac_cv_have_vaapi_glx="yes" USE_VAAPI_GLX=1],
 398             [ac_cv_have_vaapi_glx="no"]
 399         )
 400     fi
 401     if test $USE_VAAPI_GLX -eq 0; then
 402         AC_MSG_WARN([VA/GLX not found or disabled. Fallbacking to TFP+FBO])
 403         LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"
 404     fi
 405 fi
 406 AC_SUBST(LIBVA_GLX_PKGNAME)
 407
 408 AC_SUBST(LIBVA_EXTRA_CFLAGS)
 409 AC_SUBST(LIBVA_EXTRA_LIBS)
 410
 411 dnl Check for JPEG decoding API (0.33+)
 412 USE_JPEG_DECODER=0
 413 if test "$enable_codecparsers" = "yes"; then
 414 AC_CACHE_CHECK([for JPEG decoding API],
 415     ac_cv_have_jpeg_decoding_api, [
 416     saved_CFLAGS="$CFLAGS"
 417     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 418     saved_LIBS="$LIBS"
 419     LIBS="$CFLAGS $LIBVA_LIBS"
 420     AC_COMPILE_IFELSE(
 421         [AC_LANG_PROGRAM(
 422             [[#include <va/va.h>
 423               #include <va/va_dec_jpeg.h>]],
 424             [[VAPictureParameterBufferJPEG pic_param;
 425               VASliceParameterBufferJPEG slice_param;
 426               VAHuffmanTableBufferJPEG huffman_table;
 427               VAIQMatrixBufferJPEG iq_matrix;]])],
 428         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 429         [ac_cv_have_jpeg_decoding_api="no"]
 430     )
 431     CFLAGS="$saved_CFLAGS"
 432     LIBS="$saved_LIBS"
 433 ])
 434 fi
 435
 436 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 437     [Defined to 1 if JPEG decoder is used])
 438 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 439
 440 dnl Check for OpenGL support to vaapisink
 441 if test "$enable_vaapisink_glx:$USE_GLX" = "yes:1"; then
 442     USE_VAAPISINK_GLX=1
 443 else
 444     USE_VAAPISINK_GLX=0
 445 fi
 446
 447 dnl Check for FFmpeg
 448 USE_FFMPEG=0
 449 if test "$enable_ffmpeg" = "yes"; then
 450 PKG_CHECK_MODULES(LIBAVCODEC, [libavcodec],
 451     [enable_ffmpeg="yes" USE_FFMPEG=1],
 452     [enable_ffmpeg="no"  USE_FFMPEG=0]
 453 )
 454 fi
 455 if test "$enable_ffmpeg" = "yes"; then
 456 AC_CHECK_HEADERS([libavcodec/avcodec.h ffmpeg/avcodec.h])
 457 AC_CHECK_HEADERS([libavcodec/vaapi.h ffmpeg/vaapi.h],
 458     [break],
 459     [enable_ffmpeg="no"  USE_FFMPEG=0]
 460 )
 461 fi
 462
 463 if test "$enable_ffmpeg:$enable_codecparsers" = "no:no"; then
 464     AC_MSG_ERROR([Found neither suitable FFmpeg with VA-API support nor GStreamer bitstream parsers])
 465 fi
 466
 467 AC_DEFINE_UNQUOTED(USE_FFMPEG, $USE_FFMPEG,
 468     [Defined to 1 if FFmpeg is used])
 469 AM_CONDITIONAL(USE_FFMPEG, test $USE_FFMPEG -eq 1)
 470
 471 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 472     [Defined to 1 if GLX is enabled])
 473 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 474
 475 AC_DEFINE_UNQUOTED(USE_VAAPI_GLX, $USE_VAAPI_GLX,
 476     [Defined to 1 if VA/GLX is enabled])
 477 AM_CONDITIONAL(USE_VAAPI_GLX, test $USE_VAAPI_GLX -eq 1)
 478
 479 AC_DEFINE_UNQUOTED(USE_VAAPISINK_GLX, $USE_VAAPISINK_GLX,
 480     [Defined to 1 to enable GLX support to vaapisink])
 481 AM_CONDITIONAL(USE_VAAPISINK_GLX, test $USE_VAAPISINK_GLX -eq 1)
 482
 483 VA_VERSION=`$PKG_CONFIG --modversion libva`
 484 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 485 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 486 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 487 VA_VERSION_STR="$VA_VERSION"
 488
 489 pkgconfigdir=${libdir}/pkgconfig
 490 AC_SUBST(pkgconfigdir)
 491
 492 AC_CONFIG_FILES([
 493     Makefile
 494     debian.upstream/Makefile
 495     debian.upstream/changelog
 496     debian.upstream/control
 497     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 498 debian.upstream/gstreamer-vaapi.install.in
 499     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 500 debian.upstream/gstreamer-vaapi-doc.install.in
 501     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 502 debian.upstream/libgstvaapi.install.in
 503     debian.upstream/libgstvaapi-dev.install
 504     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 505 debian.upstream/libgstvaapi-x11.install.in
 506     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 507 debian.upstream/libgstvaapi-glx.install.in
 508     docs/Makefile
 509     docs/reference/Makefile
 510     docs/reference/libs/Makefile
 511     docs/reference/libs/libs-docs.xml
 512     docs/reference/plugins/Makefile
 513     docs/reference/plugins/plugins-docs.xml
 514     gst-libs/Makefile
 515     gst-libs/gst/Makefile
 516     gst-libs/gst/gstutils_version.h
 517     gst-libs/gst/codecparsers/Makefile
 518     gst-libs/gst/vaapi/Makefile
 519     pkgconfig/Makefile
 520     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 521 pkgconfig/gstreamer-vaapi.pc.in
 522     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 523 pkgconfig/gstreamer-vaapi-glx.pc.in
 524     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 525 pkgconfig/gstreamer-vaapi-x11.pc.in
 526     gst/Makefile
 527     gst/vaapi/Makefile
 528     tests/Makefile
 529 ])
 530 AC_OUTPUT
 531
 532 dnl Print summary
 533 yesno() {
 534     test $1 -eq 1 && echo yes || echo no
 535 }
 536
 537 echo
 538 echo $PACKAGE configuration summary:
 539 echo
 540 echo VA-API version ................... : $VA_VERSION_STR
 541 echo GLX support ...................... : $(yesno $USE_GLX)
 542 echo VA/GLX support ................... : $(yesno $USE_VAAPI_GLX)
 543 echo VaapiSink/GL ..................... : $(yesno $USE_VAAPISINK_GLX)
 544 echo FFmpeg bitstream parsers ......... : $(yesno $USE_FFMPEG)
 545 echo GStreamer bitstream parsers ...... : $(yesno $USE_CODEC_PARSERS)
 546 echo