configure.ac

   1 dnl Note: this file is generated from configure.base by autogen.sh
   2 AC_INIT
   3 AC_CONFIG_SRCDIR([gst/gstobject.h])
   4
   5 AC_CANONICAL_TARGET([])
   6
   7 AM_CONFIG_HEADER(config.h)
   8
   9 GST_VERSION_MAJOR=0
  10 GST_VERSION_MINOR=2
  11 GST_VERSION_MICRO=999
  12 GST_VERSION=$GST_VERSION_MAJOR.$GST_VERSION_MINOR.$GST_VERSION_MICRO
  13
  14 PACKAGE=gstreamer
  15 VERSION=$GST_VERSION
  16
  17 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
  18 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  19 AC_SUBST(PACKAGE)
  20 AC_SUBST(VERSION)
  21
  22 dnl libtool
  23 GST_CURRENT=0
  24 GST_REVISION=0
  25 GST_AGE=0
  26 GST_LIBVERSION=$GST_CURRENT:$GST_REVISION:$GST_AGE
  27
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  29 dnl Add parameters for aclocal
  30 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  31 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  32
  33 AC_SUBST(GST_VERSION_MAJOR)
  34 AC_SUBST(GST_VERSION_MINOR)
  35 AC_SUBST(GST_VERSION_MICRO)
  36 AC_SUBST(GST_VERSION)
  37
  38 AC_SUBST(GST_CURRENT)
  39 AC_SUBST(GST_REVISION)
  40 AC_SUBST(GST_AGE)
  41 AC_SUBST(GST_LIBVERSION)
  42
  43 AM_MAINTAINER_MODE
  44
  45 AC_PROG_CC
  46 AM_PROG_CC_STDC
  47 dnl you need automake 1.5 for AM_PROG_AS to work !
  48 AM_PROG_AS
  49 AS="${CC}"
  50 AC_PROG_CXX
  51 AC_PROG_CXXCPP
  52 AC_ISC_POSIX
  53
  54 dnl We disable static building for development, for time savings
  55 dnl *NOTE*: dnl this line before release, so release does static too
  56 dnl AM_DISABLE_STATIC
  57 AC_LIBTOOL_DLOPEN
  58 AM_PROG_LIBTOOL
  59
  60 AC_HEADER_STDC([])
  61
  62 dnl This is used for the -config script...
  63 builddir=`pwd`
  64 AC_SUBST(builddir)
  65
  66 dnl ##############################
  67 dnl # Do automated configuration #
  68 dnl ##############################
  69
  70 dnl Check for tools:
  71 dnl ================
  72
  73 dnl Check for nasm
  74 AC_PATH_PROG(NASM_PATH, nasm, no)
  75 AC_SUBST(NASM_PATH)
  76 if test x$NASM_PATH = xno; then
  77   AC_MSG_WARN(Couldn't find nasm)
  78   HAVE_NASM="no"
  79 else
  80   AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
  81   HAVE_NASM="yes"
  82 fi
  83
  84 dnl fix pkg-config's broken default search path
  85 if test -z "$PKG_CONFIG_PATH"; then
  86   PKG_CONFIG_PATH=/usr/local/lib/pkgconfig:/usr/lib/pkgconfig
  87 fi
  88 export PKG_CONFIG_PATH
  89
  90 dnl Check for pkgconfig
  91 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, true, false)
  92
  93 dnl check for gtkdoc
  94 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mkdb, true, false)
  95 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-scanobj, :, false)
  96 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-scan, :, false)
  97 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mktmpl, :, false)
  98 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mkdb, :, false)
  99 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-mkhtml, :, false)
 100 AC_CHECK_PROG(HAVE_GTK_DOC, gtkdoc-fixxref, :, false)
 101
 102 dnl check for docbook tools
 103 AC_CHECK_PROG(HAVE_DB2HTML, db2html, true, false)
 104 AC_CHECK_PROG(HAVE_DB2PS, db2ps, true, false)
 105 AC_CHECK_PROG(HAVE_PS2PDF, ps2pdf, true, false)
 106
 107 dnl check for image conversion tool
 108 AC_CHECK_PROG(HAVE_FIG2DEV, fig2dev, true, false)
 109
 110 dnl The following is a hack: if fig2dev doesn't display an error message
 111 dnl for the desired type, we assume it supports it.
 112 HAVE_FIG2DEV_PNG=false
 113 if test "x$HAVE_FIG2DEV" = "xtrue" ; then
 114   fig2dev_quiet=`fig2dev -L png </dev/null 2>&1 >/dev/null`
 115   if test "x$fig2dev_quiet" = "x" ; then
 116     HAVE_FIG2DEV_PNG=true
 117   fi
 118 fi
 119 HAVE_FIG2DEV_EPS=false
 120 if test "x$HAVE_FIG2DEV" = "xtrue" ; then
 121   fig2dev_quiet=`fig2dev -L eps </dev/null 2>&1 >/dev/null`
 122   if test "x$fig2dev_quiet" = "x" ; then
 123     HAVE_FIG2DEV_EPS=true
 124   fi
 125 fi
 126
 127
 128 dnl Set up conditionals for (target) architecture:
 129 dnl ==============================================
 130
 131 dnl Determine CPU
 132 case "x${target_cpu}" in
 133   xi?86 | k?) HAVE_CPU_I386=yes
 134               AC_DEFINE(HAVE_CPU_I386, 1, [Define if the target CPU is an x86])
 135               dnl FIXME could use some better detection
 136               dnl       (ie CPUID)
 137               case "x${target_cpu}" in
 138                 xi386 | xi486) ;;
 139                 *)             AC_DEFINE(HAVE_RDTSC) ;;
 140               esac ;;
 141   xpowerpc)   HAVE_CPU_PPC=yes
 142               AC_DEFINE(HAVE_CPU_PPC, 1, [Define if the target CPU is a PPC]) ;;
 143   xalpha)     HAVE_CPU_ALPHA=yes
 144               AC_DEFINE(HAVE_CPU_ALPHA, 1, [Define if the target CPU is an Alpha]) ;;
 145   xarm*)      HAVE_CPU_ARM=yes
 146               AC_DEFINE(HAVE_CPU_ARM, 1, [Define if the target CPU is an ARM]) ;;
 147   xsparc*)    HAVE_CPU_SPARC=yes
 148               AC_DEFINE(HAVE_CPU_SPARC, 1, [Define if the target CPU is a PPC]) ;;
 149   xmips*)     HAVE_CPU_MIPS=yes
 150               AC_DEFINE(HAVE_CPU_MIPS, 1, [Define if the target CPU is a MIPS]) ;;
 151   xhppa*)     HAVE_CPU_HPPA=yes
 152               AC_DEFINE(HAVE_CPU_HPPA, 1, [Define if the target CPU is a HPPA]) ;;
 153 esac
 154
 155 dnl Determine endianness
 156 AC_C_BIGENDIAN
 157
 158 dnl Check for MMX-capable compiler
 159 AC_MSG_CHECKING(for MMX-capable compiler)
 160 AC_TRY_RUN([
 161 #include "include/mmx.h"
 162
 163 main()
 164 { movq_r2r(mm0, mm1); return 0; }
 165 ],
 166 [
 167 HAVE_LIBMMX="yes"
 168 AC_MSG_RESULT(yes)
 169 ],
 170 HAVE_LIBMMX="no"
 171 AC_MSG_RESULT(no)
 172 ,
 173 HAVE_LIBMMX="no"
 174 AC_MSG_RESULT(no)
 175 )
 176
 177 dnl
 178 dnl We should really use AC_SYS_LARGEFILE, but the problem is
 179 dnl many of the plugins don't include "config.h".  To assure
 180 dnl binary compatibility, it is necessary that all gstreamer
 181 dnl code be compiled with the same sizeof(off_t), so we use
 182 dnl the following crude hack.
 183 dnl
 184
 185 AC_MSG_CHECKING(for large file support)
 186 AC_TRY_RUN([
 187 #define _LARGEFILE_SOURCE
 188 #define _FILE_OFFSET_BITS 64
 189 #include <sys/types.h>
 190 int main () { return !(sizeof(off_t) == 8); }
 191 ],
 192 [
 193 AC_MSG_RESULT(yes)
 194 GST_CFLAGS="$GST_CFLAGS -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 195 ],
 196 [
 197 AC_MSG_RESULT(no)
 198 ],
 199 [
 200 AC_MSG_RESULT(no)
 201 ])
 202
 203 dnl Check for essential libraries first:
 204 dnl ====================================
 205
 206 dnl Check for glib2
 207 translit(dnm, m, l) AM_CONDITIONAL(USE_GLIB2, true)
 208 GST_CHECK_FEATURE(GLIB2, [use of glib-2.0 and GObject], , [
 209   PKG_CHECK_MODULES(GLIB2, glib-2.0 gobject-2.0 gthread-2.0 gmodule-2.0,
 210     HAVE_GLIB2=yes,HAVE_GLIB2=no)
 211   GLIB_LIBS=$GLIB2_LIBS
 212   GLIB_CFLAGS=$GLIB2_CFLAGS
 213   AC_SUBST(GLIB_LIBS)
 214   AC_SUBST(GLIB_CFLAGS)
 215 ], disabled, [
 216   AC_DEFINE(USE_GLIB2)
 217   GST_CFLAGS="$GST_CFLAGS -DUSE_GLIB2"
 218 ])
 219 AC_SUBST(USE_GLIB2)
 220
 221 if test x$USE_GLIB2 = xno; then
 222   GST_PKG_DEPS="glib >= 1.2.0, gtk+ >= 1.2.0"
 223
 224   dnl Check for glib and gtk
 225   AM_PATH_GLIB(1.2.0,,
 226               AC_MSG_ERROR(Cannot find glib: Is glib-config in path?),
 227               glib gmodule gthread)
 228   AM_PATH_GTK(1.2.0,,
 229               AC_MSG_ERROR(Cannot find gtk: Is gtk-config in path?))
 230   HAVE_GTK=yes
 231
 232   GLIB_LIBS="$GLIB_LIBS $GTK_LIBS"
 233   GLIB_CFLAGS="$GLIB_CFLAGS $GTK_CFLAGS"
 234 else
 235   GST_PKG_DEPS="glib-2.0 gobject-2.0 gmodule-2.0 gthread-2.0"
 236
 237   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK=yes, HAVE_GTK=no)
 238
 239   GTK_FLAGS=$GTK2_CFLAGS
 240   GTK_LIBS=$GTK2_LIBS
 241
 242   dnl FIXME: check for  gnome2 - this conditional is currently
 243   dnl always false.
 244   AM_CONDITIONAL(USE_GNOME2, test "x$USE_GNOME2" = "xyes")
 245   AC_SUBST(USE_GNOME2)
 246 fi
 247
 248 AC_SUBST(GST_PKG_DEPS)
 249 AC_SUBST(GTK_LIBS)
 250 AC_SUBST(GTK_CFLAGS)
 251
 252 dnl Check for libxml
 253 dnl Thomas tries to convert this to pkg-config
 254 PKG_CHECK_MODULES(XML, libxml >= 1.8.1, XML_CONFIG=yes, XML_CONFIG=no)
 255 dnl AC_PATH_PROG(XML_CONFIG, xml-config, no)
 256 if test x$XML_CONFIG = xno; then
 257   AC_MSG_ERROR(Couldn't find xml-config)
 258 fi
 259 dnl XML_LIBS="`xml-config --libs`"
 260 dnl XML_CFLAGS="`xml-config --cflags`"
 261 dnl AC_CHECK_LIB(xml, xmlDocGetRootElement, :,
 262 dnl  [ AC_MSG_ERROR(Need version 1.8.1 or better of libxml) ],
 263 dnl  $XML_LIBS)
 264 AC_SUBST(XML_LIBS)
 265 AC_SUBST(XML_CFLAGS)
 266
 267
 268 dnl ==========================================================================
 269 dnl ========================= Macro definitions ==============================
 270 dnl ==========================================================================
 271
 272 dnl These macros should be moved out to separate files (acinclude.m4?), but
 273 dnl can't currently be because of the SUBSTFOR magic.
 274
 275 dnl Perform a check for existence of ARTS
 276 dnl Richard Boulton <richard-alsa@tartarus.org>
 277 dnl Last modification: 26/06/2001
 278 dnl GST_CHECK_FEATURE(FEATURE-NAME, FEATURE-DESCRIPTION,
 279 dnl                   DEPENDENT-PLUGINS, TEST-FOR-FEATURE)
 280 dnl
 281 dnl This check was written for GStreamer: it should be renamed and checked
 282 dnl for portability if you decide to use it elsewhere.
 283 dnl
 284 AC_DEFUN(GST_CHECK_ARTS,
 285 [
 286 dnl Set the flags
 287 ARTS_LIBS="-L/usr/local/lib -L/usr/lib -lmcop -lartsflow -lartsflow_idl"
 288 ARTS_CFLAGS="-I/usr/local/include/arts -I/usr/include/kde/arts -I/usr/include/arts"
 289 ARTS_MCOPFLAGS=$ARTS_CFLAGS
 290 dnl There's no arts-config script, so we make a guess based on the artsc-config
 291 AC_PATH_PROG(ARTSC_CONFIG, artsc-config, no)
 292 if test x$ARTSC_CONFIG = xyes; then
 293   ARTS_ARTSC_CFLAGS=`artsc-config --cflags | sed 's/artsc/arts/g'`
 294   ARTS_CFLAGS="$ARTS_CFLAGS $ARTS_ARTSC_CFLAGS"
 295   ARTS_MCOPFLAGS="$ARTS_MCOPFLAGS $ARTS_ARTSC_CFLAGS"
 296 fi
 297 AC_SUBST(ARTS_LIBS)
 298 AC_SUBST(ARTS_CFLAGS)
 299 AC_SUBST(ARTS_MCOPFLAGS)
 300
 301 dnl Now check if it exists
 302 AC_LANG_PUSH(C++)
 303 HAVE_ARTS=yes
 304 dnl FIXME: Can't get this test to pass, so commented it out.  Rely on header check.
 305 dnl AC_CHECK_LIB(artsflow, convert_stereo_2float_i16le, :, HAVE_ARTS=no, $LIBS)
 306
 307 dnl AC_CHECK_HEADER uses CPPFLAGS, but not CFLAGS.
 308 dnl FIXME: ensure only suitable flags result from artsc-config --cflags
 309 AC_CHECK_HEADER(artsflow.h, :, HAVE_ARTS=no)
 310
 311 AC_LANG_POP(C++)
 312 dnl Check for the idl generator
 313 AC_CHECK_PROG(HAVE_MCOPIDL, mcopidl, yes, no)
 314 if test x$HAVE_MCOPIDL = xno; then
 315   HAVE_ARTS=no
 316 fi
 317 ])
 318
 319 dnl ==========================================================================
 320 dnl ========================= End macro definitions ==========================
 321 dnl ==========================================================================
 322
 323
 324 dnl Next, check for the optional libraries:
 325 dnl =======================================
 326
 327
 328 dnl ***** ESound *****
 329 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBESD, true)
 330 GST_CHECK_FEATURE(LIBESD, [esound plugins], esdsrc esdsink, [
 331   AM_PATH_ESD(0.2.12, HAVE_LIBESD=yes, HAVE_LIBESD=no)
 332 ])
 333
 334 dnl Check for artsc
 335 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
 336 GST_CHECK_FEATURE(ARTSC, [artsd plugins], artsdsink, [GST_CHECK_ARTSC()])
 337
 338 dnl Check for arts
 339 dnl FIXME: thomasvs: I don't understand this, have replaced the check
 340 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
 341 dnl GST_CHECK_FEATURE(ARTS, [arts plugins], arts, [GST_CHECK_ARTS()])
 342
 343 dnl Check for xmms
 344 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_LIBXMMS, true)
 345 dnl GST_CHECK_FEATURE(LIBXMMS, [xmms plugin], xmms, [
 346 dnl  AM_PATH_XMMS(0.1.0, HAVE_LIBXMMS=yes, HAVE_LIBXMMS=no)
 347 dnl ], disabled)
 348
 349 dnl Check for alsa
 350 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 351 GST_CHECK_FEATURE(ALSA, [alsa plugins], gstalsa, [
 352   AM_PATH_ALSA(0.9.0, HAVE_ALSA=yes, HAVE_ALSA=no)
 353 ])
 354 if test x$HAVE_ALSA = xno; then
 355   unset USE_ALSA
 356   ALSA_CFLAGS=
 357   ALSA_LIBS=
 358 fi
 359
 360 dnl Check for libaudiofile
 361 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBAUDIOFILE, true)
 362 GST_CHECK_FEATURE(LIBAUDIOFILE, [use gdk pixbuf], afsink afsrc, [
 363 translit(dnm, m, l) AC_SUBST(LIBAUDIOFILE_LIBS)
 364 translit(dnm, m, l) AC_SUBST(LIBAUDIOFILE_CFLAGS)
 365 GST_CHECK_CONFIGPROG(LIBAUDIOFILE, audiofile-config)
 366 ])
 367
 368 dnl Check for libgdk-pixbuf
 369 dnl FIXME: not sure that this is still used anywhere.
 370 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 371 GST_CHECK_FEATURE(GDK_PIXBUF, [use gdk pixbuf], , [
 372 translit(dnm, m, l) AC_SUBST(GDK_PIXBUF_LIBS)
 373 translit(dnm, m, l) AC_SUBST(GDK_PIXBUF_CFLAGS)
 374 GST_CHECK_CONFIGPROG(GDK_PIXBUF, gdk-pixbuf-config)
 375 ])
 376
 377 if test x$USE_GLIB2 = xyes; then
 378   dnl we don't support gnome/gtk with glib2.0 yet
 379   GNOME_LIBS=
 380   GNOME_CFLAGS=
 381   HAVE_GNOME=no
 382   AC_MSG_WARN(gnome disabled for glib2.0)
 383 else
 384   dnl Check for libgnome
 385 translit(dnm, m, l) AC_SUBST(GNOME_LIBS)
 386 translit(dnm, m, l) AC_SUBST(GNOME_CFLAGS)
 387 GST_CHECK_CONFIGPROG(GNOME, gnome-config, gnome gnomeui)
 388 fi
 389
 390 dnl Check for libghttp
 391 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBGHTTP, true)
 392 GST_CHECK_FEATURE(LIBGHTTP, [libghttp plugins], gsthttpsrc, [
 393   dnl FIXME: need to check for header
 394   GHTTP_LIBS=
 395   GST_HTTPSRC_GET_TYPE=
 396   if test x$USE_GLIB2 = xyes; then
 397     AC_MSG_WARN(ghttp disabled for glib2.0)
 398   else
 399     AC_CHECK_LIB(ghttp, ghttp_request_new,
 400       [GHTTP_LIBS="-lghttp"
 401        GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
 402        HAVE_LIBGHTTP=yes
 403       ], :, $LIBS)
 404   fi
 405   AC_SUBST(GHTTP_LIBS)
 406   AC_SUBST(GST_HTTPSRC_GET_TYPE)
 407 ])
 408
 409 dnl thomas : adding an arts check taken from xine with it's own .m4
 410 AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
 411
 412 dnl Check for xmms
 413 AM_PATH_XMMS(0.9.4, HAVE_XXMS=yes, HAVE_XMMS=no)
 414
 415 dnl Check for libglade
 416 HAVE_LIBGLADE_GNOME="no"
 417 if test x$USE_GLIB2 = xyes; then
 418   dnl no glade for glib2.0
 419   LIBGLADE_GNOME_LIBS=
 420   LIBGLADE_GNOME_CFLAGS=
 421   AC_MSG_WARN(libglade disabled for glib2.0)
 422 else
 423   AM_PATH_LIBGLADE(HAVE_LIBGLADE_GNOME="yes", HAVE_LIBGLADE_GNOME="no", gnome)
 424   if test x$HAVE_LIBGLADE_GNOME = xno; then
 425     AC_MSG_WARN(Couldn't find libglade-config - Can't build gstplay)
 426     LIBGLADE_GNOME_LIBS=
 427     LIBGLADE_GNOME_CFLAGS=
 428   else
 429     LIBGLADE_GNOME_LIBS=$LIBGLADE_LIBS
 430     LIBGLADE_GNOME_CFLAGS=$LIBGLADE_CFLAGS
 431         AC_TRY_LINK([#include <glade/glade.h>],[glade_gnome_init();],
 432                 HAVE_LIBGLADE_GNOME="yes"
 433                 AC_MSG_WARN(
 434         [Couldn't find gnome libraries for libglade - Can't build gstmediaplay and gsteditor])
 435                )
 436   fi
 437 fi
 438 AC_SUBST(LIBGLADE_GNOME_LIBS)
 439 AC_SUBST(LIBGLADE_GNOME_CFLAGS)
 440
 441 dnl Check for Gnome VFS
 442 HAVE_GNOME_VFS="no"
 443 if test x$USE_GLIB2 = xyes; then
 444   VFS_LIBS=
 445   VFS_CFLAGS=
 446   AC_MSG_WARN(Gnome-VFS disabled for glib2.0)
 447 else
 448   AC_MSG_CHECKING(for Gnome VFS)
 449   if gnome-config --libs vfs > /dev/null 2>&1; then
 450         HAVE_GNOME_VFS="yes"
 451         AC_MSG_RESULT(found)
 452         VFS_LIBS="`gnome-config --libs vfs`"
 453         VFS_CFLAGS="`gnome-config --cflags vfs`"
 454   else
 455         AC_MSG_WARN(Did not find Gnome-VFS installed)
 456         VFS_LIBS=
 457         VFS_CFLAGS=
 458   fi
 459 fi
 460 AC_SUBST(VFS_LIBS)
 461 AC_SUBST(VFS_CFLAGS)
 462
 463 dnl Check for Avifile
 464 HAVE_AVIFILE="no"
 465 AC_MSG_CHECKING(for Avifile)
 466 if avifile-config --libs > /dev/null 2>&1; then
 467         HAVE_AVIFILE="yes"
 468         AC_MSG_RESULT(found)
 469 else
 470         AC_MSG_WARN(Did not find Avifile installed)
 471 fi
 472 AVIFILE_LIBS="`avifile-config --libs`"
 473 AVIFILE_CFLAGS="`avifile-config --cflags`"
 474 AC_SUBST(AVIFILE_LIBS)
 475 AC_SUBST(AVIFILE_CFLAGS)
 476
 477 dnl Check for atomic.h
 478 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 479 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 480 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 481 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 482 if test x$HAVE_ATOMIC_H = xyes; then
 483   AC_TRY_RUN([
 484 #include "asm/atomic.h"
 485 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 486   ],, [
 487     # Not successful
 488     if test x$HAVE_ATOMIC_H = xyes; then
 489       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 490     fi
 491     HAVE_ATOMIC_H=no
 492   ], [
 493     # Cross compiling
 494     AC_MSG_RESULT(yes)
 495     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 496   ])
 497 fi
 498
 499
 500 dnl Check for X11 extensions
 501 AC_PATH_XTRA
 502 if test "-DX_DISPLAY_MISSING" = "$X_CFLAGS"; then
 503   AC_MSG_ERROR(can not find X11)
 504 fi
 505 AC_SUBST(X_CFLAGS)
 506 AC_SUBST(X_PRE_LIBS)
 507 AC_SUBST(X_EXTRA_LIBS)
 508 AC_SUBST(X_LIBS)
 509
 510
 511 dnl Check for the Xv library
 512 xvsave_LIBS=${LIBS}
 513 AC_CHECK_LIB(Xv, XvQueryExtension,
 514   HAVE_LIBXV=yes,
 515   HAVE_LIBXV=no,
 516   $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS
 517 )
 518 LIBS=${xvsave_LIBS}
 519 AC_CHECK_HEADER(X11/extensions/Xv.h, :, HAVE_LIBXV=no)
 520 AC_CHECK_HEADER(X11/extensions/Xvlib.h, :, HAVE_LIBXV=no)
 521
 522 dnl Check for OSS audio
 523 AC_CHECK_HEADER(sys/soundcard.h, HAVE_OSS=yes, HAVE_OSS=no)
 524
 525 dnl Check for xaudio
 526 AC_CHECK_HEADER(xaudio/decoder.h,
 527   AC_DEFINE(HAVE_XAUDIO, 1, [Define if xaudio is available])
 528   HAVE_XAUDIO="yes",
 529   AC_MSG_WARN(
 530 ***** NOTE: These plugins won't be built: gstxa
 531 )
 532   HAVE_XAUDIO="no",
 533 )
 534
 535 dnl Check for libmad
 536 AC_MSG_CHECKING(MAD library)
 537 AC_CHECK_LIB(mad, mad_decoder_finish,
 538   HAVE_LIBMAD=yes
 539   AC_DEFINE(HAVE_LIBMAD, 1, [Define if libmad is available]),
 540   AC_MSG_WARN(
 541 ***** NOTE: These plugins won't be built: mad
 542 )
 543   HAVE_LIBMAD=no,
 544 )
 545
 546 dnl Check for libmikmod
 547 AC_MSG_CHECKING(Mikmod library)
 548 AC_CHECK_LIB(mikmod, MikMod_Init,
 549   HAVE_LIBMIKMOD=yes
 550   AC_DEFINE(HAVE_LIBMIKMOD, 1, [Define if libmikmod is available]),
 551   AC_MSG_WARN(
 552 ***** NOTE: These plugins won't be built: mikmod
 553 )
 554   HAVE_LIBMIKMOD=no,
 555 )
 556
 557
 558 dnl Check for libvorbis
 559 AC_MSG_CHECKING(Vorbis library)
 560 AC_CHECK_LIB(vorbis, ogg_sync_init,
 561   HAVE_VORBIS=yes
 562   AC_DEFINE(HAVE_VORBIS, 1, [Define if vorbis library is available]),
 563   AC_MSG_WARN(
 564 ***** NOTE: These plugins won't be built: vorbisdec vorbisenc
 565 )
 566   HAVE_VORBIS=no,
 567 )
 568
 569 dnl Check for libjpeg
 570 AC_MSG_CHECKING(libjpeg library)
 571 AC_CHECK_LIB(jpeg, jpeg_set_defaults,
 572   HAVE_LIBJPEG=yes
 573   AC_DEFINE(HAVE_LIBJPEG, 1, [Define if libjpeg is available]),
 574   AC_MSG_WARN(
 575 ***** NOTE: These plugins won't be built: jpegdec jpegenc
 576 )
 577   HAVE_LIBJPEG=no,
 578 )
 579
 580 dnl Check for libHermes
 581 AC_MSG_CHECKING(Hermes library)
 582 AC_CHECK_LIB(Hermes, Hermes_ConverterInstance,
 583   HAVE_LIBHERMES=yes
 584   AC_DEFINE(HAVE_LIBHERMES, 1, [Define if Hermes library is available]),
 585   AC_MSG_WARN(
 586 ***** NOTE: These plugins won't be built: colorspace
 587 )
 588   HAVE_LIBHERMES=no,
 589 )
 590 AC_CHECK_HEADER(Hermes/Hermes.h, :, HAVE_LIBHERMES=no)
 591
 592 dnl Check for libgsm
 593 AC_MSG_CHECKING(GSM library)
 594 AC_CHECK_LIB(gsm, gsm_create, HAVE_LIBGSM=yes, HAVE_LIBGSM=no,)
 595 GSM_CFLAGS=
 596 GSM_LIBS=-lgsm
 597 AC_CHECK_HEADER(gsm.h, :,
 598   GSM_CFLAGS="$GSM_CFLAGS -DGSM_HEADER_IN_SUBDIR"
 599   AC_CHECK_HEADER(gsm/gsm.h, :, HAVE_LIBGSM=no)
 600 )
 601 AC_SUBST(GSM_CFLAGS)
 602 AC_SUBST(GSM_LIBS)
 603
 604 if test "x$HAVE_LIBGSM" = "xyes"; then
 605   AC_DEFINE(HAVE_LIBGSM, 1, [Define if GSM library is available])
 606 else
 607   AC_MSG_WARN(
 608 ***** NOTE: These plugins won't be built: gsmdec, gsmenc
 609 )
 610 fi
 611
 612 dnl Check for cdparanoia
 613 AC_MSG_CHECKING(CDparanoia library)
 614 HAVE_CDPARANOIA=yes
 615 AC_CHECK_LIB(cdda_interface, cdda_open, : , HAVE_CDPARANOIA=no, )
 616 AC_CHECK_HEADER(cdda_interface.h, :, HAVE_CDPARANOIA=no)
 617 AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 618 AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 619
 620 dnl Check for liblame
 621 AC_MSG_CHECKING(LAME library)
 622 AC_CHECK_LIB(mp3lame, lame_init, HAVE_LIBLAME=yes, HAVE_LIBLAME=no, -lm)
 623 AC_CHECK_HEADER(lame/lame.h, :, HAVE_LIBLAME=no)
 624
 625 dnl Check for libshout
 626 AC_MSG_CHECKING(Shout library)
 627 AC_CHECK_LIB(shout, shout_init_connection, HAVE_LIBSHOUT=yes, HAVE_LIBSHOUT=no, )
 628 AC_CHECK_HEADER(shout/shout.h, :, HAVE_LIBSHOUT=no)
 629
 630 dnl Check for mpeg2dec
 631 AC_MSG_CHECKING(mpeg2dec library)
 632 AC_CHECK_LIB(mpeg2, mpeg2_init, HAVE_MPEG2DEC=yes, HAVE_MPEG2DEC=no, )
 633 AC_CHECK_HEADER(mpeg2dec/mpeg2.h, :, HAVE_MPEG2DEC=no)
 634
 635 dnl Check for a52dec
 636 AC_MSG_CHECKING(a52dec library)
 637 AC_CHECK_LIB(a52, a52_init, HAVE_A52DEC=yes, HAVE_A52DEC=no, -lm)
 638 AC_CHECK_HEADER(a52dec/a52.h, :, HAVE_A52DEC=no)
 639
 640 dnl Check for sidplay
 641 AC_PATH_LIBSIDPLAY
 642
 643 dnl Check for librtp
 644 AC_MSG_CHECKING(rtp library)
 645 AC_CHECK_LIB(rtp, rtp_packet_new_take_data, HAVE_LIBRTP=yes, HAVE_LIBRTP=no, $GLIB_LIBS $GLIB_CFLAGS)
 646 AC_CHECK_HEADERS(rtp/rtp.h, HAVE_LIBRTP=yes, HAVE_LIBRTP=no)
 647 AC_CHECK_HEADERS(rtp/rtp-packet.h, :, HAVE_LIBRTP=no)
 648 AC_CHECK_HEADERS(rtp/rtcp-packet.h, :, HAVE_LIBRTP=no)
 649 AC_CHECK_HEADERS(rtp/rtp-audio.h, :, HAVE_LIBRTP=no)
 650
 651 dnl Check for FLAC
 652 dnl thomas : checking for compile with main instead of actual function,
 653 dnl since that made autoconf break (for version 2.13)
 654 AC_MSG_CHECKING(FLAC library)
 655 AC_CHECK_LIB(FLAC, main, HAVE_FLACLIB=yes, HAVE_FLACLIB=no, -lm)
 656 AC_CHECK_HEADER(FLAC/all.h, :, HAVE_FLACLIB=no)
 657
 658 dnl Check for libraw1394
 659 AC_MSG_CHECKING(raw1394 library)
 660 AC_CHECK_LIB(raw1394, raw1394_get_handle, HAVE_RAW1394=yes, HAVE_RAW1394=no, )
 661 AC_CHECK_HEADER(libraw1394/raw1394.h, :, HAVE_RAW1394=no)
 662
 663 dnl Check for libdv
 664 AC_MSG_CHECKING(libdv)
 665 AC_CHECK_LIB(dv, dv_init, HAVE_LIBDV=yes, HAVE_LIBDV=no, -lm $GLIB_LIBS $GLIB_CFLAGS)
 666 libdvcheck_save_CPPFLAGS="$CPPFLAGS"
 667 CPPFLAGS="$CPPFLAGS $GLIB_CFLAGS"
 668 AC_CHECK_HEADER(libdv/dv.h, :, HAVE_LIBDV=no)
 669 CPPFLAGS="$libdvcheck_save_CPPFLAGS"
 670
 671 dnl Check for aalib
 672 AC_MSG_CHECKING(aalib)
 673 AC_CHECK_LIB(aa, aa_init, HAVE_LIBAA=yes, HAVE_LIBAA=no, )
 674 AC_CHECK_HEADER(aalib.h, :, HAVE_LIBAA=no)
 675
 676 dnl Check for quicktime
 677 AC_MSG_CHECKING(openquicktime)
 678 AC_CHECK_LIB(openquicktime, quicktime_init, HAVE_LIBOPENQUICKTIME=yes, HAVE_LIBOPENQUICKTIME=no, )
 679 AC_CHECK_HEADER(openquicktime/openquicktime.h, :, HAVE_LIBOPENQUICKTIME=no)
 680
 681 dnl Check for libdvdread
 682 AC_MSG_CHECKING(libdvdread)
 683 AC_CHECK_LIB(dvdread, DVDOpen, HAVE_LIBDVDREAD=yes, HAVE_LIBDVDREAD=no, )
 684 AC_CHECK_HEADER(dvdread/dvd_reader.h, :, HAVE_LIBDVDREAD=no)
 685
 686 dnl Check for SDL library
 687 dnl this bit is taken from vlc's configure.in and modified accordingly
 688
 689 AM_PATH_SDL(1.1.0, HAVE_LIBSDL=yes, HAVE_LIBSDL=no)
 690
 691 if test "x$HAVE_LIBSDL" = "xno"; then
 692   AC_MSG_WARN(
 693 ***** NOTE: These plugins won't be built: sdlvideosink
 694 )
 695 fi
 696
 697 dnl Check for linux/cdrom.h
 698 AC_CHECK_HEADER(linux/cdrom.h,
 699   HAVE_LINUX_CDROM=yes, HAVE_LINUX_CDROM=no
 700 )
 701
 702 dnl Check for linux/videodev.h
 703 AC_CHECK_HEADER(linux/videodev.h,
 704   HAVE_LINUX_VIDEODEV=yes, HAVE_LINUX_VIDEODEV=no
 705 )
 706
 707
 708 dnl ######################################################################
 709 dnl # Check command line parameters, and set shell variables accordingly #
 710 dnl ######################################################################
 711
 712 AC_ARG_ENABLE(libmmx,
 713 [  --enable-libmmx              use libmmx, if available],
 714 [case "${enableval}" in
 715   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 716   no)  USE_LIBMMX=no ;;
 717   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 718 esac],
 719 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 720
 721 AC_ARG_ENABLE(atomic,
 722 [  --enable-atomic              use atomic reference counting header],
 723 [case "${enableval}" in
 724   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 725   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 726   no)  USE_ATOMIC_H=no;;
 727   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 728 esac],
 729 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 730
 731 AC_ARG_ENABLE(plugin-builddir,
 732 [  --enable-plugin-builddir     allow tests/demos to use non-installed plugins ],
 733 [case "${enableval}" in
 734   yes) PLUGINS_USE_BUILDDIR=yes ;;
 735   no)  PLUGINS_USE_BUILDDIR=no ;;
 736   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-builddir) ;;
 737 esac],
 738 [PLUGINS_USE_BUILDDIR=no]) dnl Default value
 739
 740 AC_ARG_ENABLE(debug,
 741 [  --enable-debug               compile with -g debugging info],
 742 [case "${enableval}" in
 743   yes) USE_DEBUG=yes ;;
 744   no)  USE_DEBUG=no ;;
 745   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 746 esac],
 747 [USE_DEBUG=no]) dnl Default value
 748
 749 AC_ARG_ENABLE(DEBUG,
 750 [  --enable-DEBUG               compiles in a large number of debugging messages],
 751 [case "${enableval}" in
 752   yes) ENABLE_DEBUG=yes ;;
 753   no)  ENABLE_DEBUG=no ;;
 754   *) AC_MSG_ERROR(bad value ${enableval} for --enable-DEBUG) ;;
 755 esac],
 756 [ENABLE_DEBUG=no]) dnl Default value
 757 if test x$ENABLE_DEBUG = xyes; then
 758   AC_DEFINE(GST_DEBUG_ENABLED, 1, [Define if DEBUG statements should be compiled in])
 759 fi
 760
 761 AC_ARG_ENABLE(INFO,
 762 [  --disable-INFO               disables compilation of informational messages],
 763 [case "${enableval}" in
 764   yes) ENABLE_INFO=yes ;;
 765   no)  ENABLE_INFO=no ;;
 766   *) AC_MSG_ERROR(bad value ${enableval} for --enable-INFO) ;;
 767 esac],
 768 [ENABLE_INFO=yes]) dnl Default value
 769 if test x$ENABLE_INFO = xyes; then
 770   AC_DEFINE(GST_INFO_ENABLED, 1, [Define if INFO statements should be compiled in])
 771 fi
 772
 773 AC_ARG_ENABLE(debug-color,
 774 [  --disable-debug-color        disables color output of DEBUG and INFO output],
 775 [case "${enableval}" in
 776   yes) ENABLE_DEBUG_COLOR=yes ;;
 777   no)  ENABLE_DEBUG_COLOR=no ;;
 778   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug-color) ;;
 779 esac],
 780 [ENABLE_DEBUG_COLOR=yes]) dnl Default value
 781 if test "x$ENABLE_DEBUG_COLOR" = xyes; then
 782   AC_DEFINE(GST_DEBUG_COLOR, 1, [Define if debugging messages should be colorized])
 783 fi
 784
 785 AC_ARG_ENABLE(profiling,
 786 [  --enable-profiling           adds -pg to compiler commandline, for profiling],
 787 [case "${enableval}" in
 788   yes) USE_PROFILING=yes ;;
 789   no)  UES_PROFILING=no ;;
 790   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 791 esac],
 792 [USE_PROFILING=no]) dnl Default value
 793
 794 dnl default to building registry in the source tree if we are enabling plugin build dir
 795 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 796   GST_CONFIG_DIR=$builddir
 797 else
 798   GST_CONFIG_DIR=/etc/gstreamer
 799 fi
 800 AC_ARG_WITH(configdir,
 801 [  --with-configdir             specify path to use for configdir],
 802 [case "${withval}" in
 803   yes) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 804   no) AC_MSG_ERROR(bad value ${withval} for --with-configdir) ;;
 805   *) GST_CONFIG_DIR="${withval}" ;;
 806 esac],
 807 [:]) dnl Default value
 808
 809 dnl Default value
 810 GST_WIN32_LIBDIR="/usr/lib/win32"
 811 AC_ARG_WITH(win32_libdir,
 812 [  --with-win32-libdir          specify location for win32 DLLs],
 813 [case "${withval}" in
 814   yes) AC_MSG_ERROR(bad value ${withval} for --with-win32-libdir) ;;
 815   no) AC_MSG_ERROR(bad value ${withval} for --with-win32-libdir) ;;
 816   *) GST_WIN32_LIBDIR="${withval}" ;;
 817 esac],
 818 [:]) dnl Default value
 819
 820 AC_ARG_ENABLE(docs-build,
 821 [  --enable-docs-build          enable building of documentation],
 822 [case "${enableval}" in
 823   yes) BUILD_DOCS=yes ;;
 824   no)  BUILD_DOCS=no ;;
 825   *) AC_MSG_ERROR(bad value ${enableval} for --enable-docs-build) ;;
 826 esac],
 827 [BUILD_DOCS=no]) dnl Default value
 828
 829 AC_ARG_ENABLE(plugin-docs,
 830 [  --enable-plugin-docs         enable the building of plugin documentation
 831                                (this is currently broken, so off by default)],
 832 [case "${enableval}" in
 833   yes) BUILD_PLUGIN_DOCS=yes ;;
 834   no)  BUILD_PLUGIN_DOCS=no ;;
 835   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-docs) ;;
 836 esac],
 837 [BUILD_PLUGIN_DOCS=no]) dnl Default value
 838
 839 AC_ARG_ENABLE(tests,
 840 [  --disable-tests              disable building test apps],
 841 [case "${enableval}" in
 842   yes) BUILD_TESTS=yes ;;
 843   no)  BUILD_TESTS=no ;;
 844   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 845 esac],
 846 [BUILD_TESTS=yes]) dnl Default value
 847
 848 AC_ARG_ENABLE(examples,
 849 [  --disable-examples           disable building examples],
 850 [case "${enableval}" in
 851   yes) BUILD_EXAMPLES=yes ;;
 852   no)  BUILD_EXAMPLES=no ;;
 853   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 854 esac],
 855 [BUILD_EXAMPLES=yes]) dnl Default value
 856
 857 dnl Next, check for the optional components:
 858 dnl ========================================
 859
 860
 861 AC_DEFUN(GST_SUBSYSTEM_DISABLE,
 862 [dnl
 863 dnl Add a subsystem --disable flag and all the necessary symbols and substitions
 864 dnl
 865 AC_ARG_ENABLE(translit([$1], A-Z, a-z),
 866 [  ]builtin(format, --disable-%-17s  disable %s, translit([$1], A-Z, a-z), $2),
 867 [ case "${enableval}" in
 868     yes) GST_DISABLE_[$1]=no ;;
 869     no) GST_DISABLE_[$1]=yes ;;
 870     *) AC_MSG_ERROR(bad value ${enableval} for --enable-translit([$1], A-Z, a-z)) ;;
 871   esac],
 872 [GST_DISABLE_[$1]=no]) dnl Default value
 873 if test x$GST_DISABLE_[$1] = xyes; then
 874   AC_DEFINE(GST_DISABLE_[$1], 1, [Disable $2])
 875   GST_DISABLE_[$1]_DEFINE=-DGST_DISABLE_[$1]
 876 fi
 877 AM_CONDITIONAL(GST_DISABLE_[$1], test x$GST_DISABLE_[$1] = xyes)
 878 AC_SUBST(GST_DISABLE_[$1]_DEFINE)
 879 GST_SUBSYSTEM_DISABLE_DEFINES="$GST_SUBSYTEM_DISABLE_DEFINES $GST_DISABLE_[$1]_DEFINE"
 880 ])
 881
 882 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_LOADSAVE, true)
 883 GST_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
 884 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TYPEFIND, true)
 885 GST_SUBSYSTEM_DISABLE(TYPEFIND,[typefind plugin],)
 886 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_AUTOPLUG, true)
 887 GST_SUBSYSTEM_DISABLE(AUTOPLUG,[autoplugger subsystem])
 888 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_PARSE, true)
 889 GST_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
 890 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TRACE, true)
 891 GST_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 892 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_REGISTRY, true)
 893 GST_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 894
 895 GST_CFLAGS="$GST_CFLAGS $GST_SUBSYSTEM_DISABLE_DEFINES"
 896
 897
 898 dnl ################################################
 899 dnl # Set defines according to variables set above #
 900 dnl ################################################
 901
 902
 903 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 904 dnl HAVE_ and it is likely to be easier to stick with the old name
 905 if test "x$USE_LIBGHTTP" = xyes; then
 906   AC_DEFINE(HAVE_LIBGHTTP, 1, [Define if ghttp library is available])
 907 fi
 908
 909 if test "x$USE_LIBMMX" = xyes; then
 910   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
 911 fi
 912
 913 if test "x$USE_ATOMIC_H" = xyes; then
 914   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 915 fi
 916
 917 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 918   AC_DEFINE(PLUGINS_USE_BUILDDIR, 1, [Define if plugins should be loaded from the build tree - only developers should use this])
 919 fi
 920
 921 dnl if test "x$USE_DEBUG" = xyes; then
 922 dnl   CFLAGS="$CFLAGS -g"
 923 dnl fi
 924
 925 if test "x$USE_PROFILING" = xyes; then
 926 dnl  CFLAGS="$CFLAGS -pg -fprofile-arcs"
 927   FOMIT_FRAME_POINTER=""
 928 else
 929   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 930 fi
 931
 932 dnl
 933 dnl AC_SUBST(FOMIT_FRAME_POINTER)
 934 dnl
 935
 936 if test "x$HAVE_LIBXV" = xyes; then
 937   AC_DEFINE(HAVE_LIBXV)
 938 fi
 939
 940 if test "x$HAVE_OSS" = xyes; then
 941   AC_DEFINE(HAVE_OSS)
 942 fi
 943
 944 if test "x$HAVE_XAUDIO" = xyes; then
 945   AC_DEFINE(HAVE_XAUDIO)
 946 fi
 947
 948 if test "x$HAVE_LIBMAD" = xyes; then
 949   AC_DEFINE(HAVE_LIBMAD)
 950 fi
 951
 952 if test "x$HAVE_LIBMIKMOD" = xyes; then
 953   AC_DEFINE(HAVE_LIBMIKMOD)
 954 fi
 955
 956 if test "x$HAVE_VORBIS" = xyes; then
 957   AC_DEFINE(HAVE_VORBIS)
 958 fi
 959
 960 if test "x$HAVE_LIBJPEG" = xyes; then
 961   AC_DEFINE(HAVE_LIBJPEG)
 962 fi
 963
 964 if test "x$HAVE_LIBSDL" = xyes; then
 965   AC_DEFINE(HAVE_LIBSDL)
 966 fi
 967
 968 if test "x$HAVE_LIBHERMES" = "xyes"; then
 969   AC_DEFINE(HAVE_LIBHERMES)
 970 fi
 971
 972 if test "x$HAVE_LIBDVDREAD" = xyes; then
 973   AC_DEFINE(HAVE_LIBDVDREAD)
 974 fi
 975
 976 if test "x$HAVE_LINUX_CDROM" = xyes; then
 977   AC_DEFINE(HAVE_LINUX_CDROM)
 978 fi
 979
 980 if test "x$HAVE_LINUX_VIDEODEV" = xyes; then
 981   AC_DEFINE(HAVE_LINUX_VIDEODEV)
 982 fi
 983
 984 if test "x$HAVE_MPEG2DEC" = xyes; then
 985   AC_DEFINE(HAVE_MPEG2DEC)
 986 fi
 987
 988 if test "x$HAVE_A52DEC" = xyes; then
 989   AC_DEFINE(HAVE_A52DEC)
 990 fi
 991
 992 if test "x$HAVE_FLACLIB" = xyes; then
 993   AC_DEFINE(HAVE_FLACLIB)
 994 fi
 995
 996 if test "x$HAVE_LIBGSM" = xyes; then
 997   AC_DEFINE(HAVE_LIBGSM)
 998 fi
 999
1000 dnl #############################
1001 dnl # Set automake conditionals #
1002 dnl #############################
1003
1004 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
1005 dnl HAVE_ and it is likely to be easier to stick with the old name
1006 AM_CONDITIONAL(HAVE_CPU_I386,       test "x$HAVE_CPU_I386" = "xyes")
1007 AM_CONDITIONAL(HAVE_CPU_PPC,        test "x$HAVE_CPU_PPC" = "xyes")
1008 AM_CONDITIONAL(HAVE_CPU_ALPHA,      test "x$HAVE_CPU_ALPHA" = "xyes")
1009 AM_CONDITIONAL(HAVE_CPU_ARM,        test "x$HAVE_CPU_ARM" = "xyes")
1010 AM_CONDITIONAL(HAVE_CPU_SPARC,      test "x$HAVE_CPU_SPARC" = "xyes")
1011 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
1012 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
1013 AM_CONDITIONAL(HAVE_OSS,            test "x$HAVE_OSS" = "xyes")
1014 AM_CONDITIONAL(HAVE_XAUDIO,         test "x$HAVE_XAUDIO" = "xyes")
1015 AM_CONDITIONAL(HAVE_LIBMAD,         test "x$HAVE_LIBMAD" = "xyes")
1016 AM_CONDITIONAL(HAVE_LIBMIKMOD,      test "x$HAVE_LIBMIKMOD" = "xyes")
1017 AM_CONDITIONAL(HAVE_LINUX_CDROM,    test "x$HAVE_LINUX_CDROM" = "xyes")
1018 AM_CONDITIONAL(HAVE_LINUX_VIDEODEV, test "x$HAVE_LINUX_VIDEODEV" = "xyes")
1019 AM_CONDITIONAL(HAVE_LIBDVDREAD,     test "x$HAVE_LIBDVDREAD" = "xyes")
1020 AM_CONDITIONAL(HAVE_VORBIS,         test "x$HAVE_VORBIS" = "xyes")
1021 AM_CONDITIONAL(HAVE_LIBJPEG,        test "x$HAVE_LIBJPEG" = "xyes")
1022 AM_CONDITIONAL(HAVE_LIBSDL,         test "x$HAVE_LIBSDL" = "xyes")
1023 AM_CONDITIONAL(HAVE_LIBHERMES,      test "x$HAVE_LIBHERMES" = "xyes")
1024 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
1025 AM_CONDITIONAL(HAVE_LIBGLADE_GNOME, test "x$HAVE_LIBGLADE_GNOME" = "xyes")
1026 AM_CONDITIONAL(HAVE_GNOME,          test "x$HAVE_GNOME" = "xyes")
1027 AM_CONDITIONAL(HAVE_LIBXV,          test "x$HAVE_LIBXV" = "xyes")
1028 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
1029 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
1030 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
1031 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
1032 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
1033 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
1034 AM_CONDITIONAL(HAVE_DB2HTML,        $HAVE_DB2HTML)
1035 AM_CONDITIONAL(HAVE_DB2PS,          $HAVE_DB2PS)
1036 AM_CONDITIONAL(HAVE_PS2PDF,         $HAVE_PS2PDF)
1037 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
1038 AM_CONDITIONAL(HAVE_FIG2DEV_EPS,    $HAVE_FIG2DEV_EPS)
1039 AM_CONDITIONAL(HAVE_CDPARANOIA,     test "x$HAVE_CDPARANOIA" = "xyes")
1040 AM_CONDITIONAL(HAVE_LIBLAME,        test "x$HAVE_LIBLAME" = "xyes")
1041 AM_CONDITIONAL(HAVE_LIBSHOUT,       test "x$HAVE_LIBSHOUT" = "xyes")
1042 AM_CONDITIONAL(HAVE_MPEG2DEC,       test "x$HAVE_MPEG2DEC" = "xyes")
1043 AM_CONDITIONAL(HAVE_A52DEC,         test "x$HAVE_A52DEC" = "xyes")
1044 dnl thomas : the next line gives errors, this is how it is in CVS
1045 dnl AM_CONDITIONAL(HAVE_FLAC,               test "x$HAVE_FLAC" = "xyes")
1046 dnl thomas : the next line gives errors as well, I commented it
1047 dnl AM_CONDITIONAL(HAVE_LAC,                test "x$HAVE_FAC" = "xyes")
1048 dnl thomas: the next line doesn't give errors
1049 AM_CONDITIONAL(HAVE_FLACLIB,        test "x$HAVE_FLACLIB" = "xyes")
1050 AM_CONDITIONAL(HAVE_LIBRTP,         test "x$HAVE_LIBRTP" = "xyes")
1051 AM_CONDITIONAL(HAVE_ARTS,           test "x$HAVE_ARTS" = "xyes")
1052 AM_CONDITIONAL(HAVE_XMMS,           test "x$HAVE_XMMS" = "xyes")
1053 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
1054 AM_CONDITIONAL(HAVE_LIBDV,          test "x$HAVE_LIBDV" = "xyes")
1055 AM_CONDITIONAL(HAVE_LIBAA,          test "x$HAVE_LIBAA" = "xyes")
1056 AM_CONDITIONAL(HAVE_GNOME_VFS,      test "x$HAVE_GNOME_VFS" = "xyes")
1057 AM_CONDITIONAL(HAVE_AVIFILE,        test "x$HAVE_AVIFILE" = "xyes")
1058 AM_CONDITIONAL(HAVE_LIBOPENQUICKTIME, test "x$HAVE_LIBOPENQUICKTIME" = "xyes")
1059 AM_CONDITIONAL(HAVE_LIBGSM,         test "x$HAVE_LIBGSM" = "xyes")
1060 AM_CONDITIONAL(PLUGINS_USE_BUILDDIR,  test "x$PLUGINS_USE_BUILDDIR" = "xyes")
1061 AM_CONDITIONAL(HAVE_SIDPLAY,        test "x$have_sidplay" = "xyes")
1062
1063
1064 dnl ############################
1065 dnl # Set up some more defines #
1066 dnl ############################
1067
1068 dnl Set location of configuration dir.
1069 dnl AC_DEFINE_UNQUOTED(GST_CONFIG_DIR,"$GST_CONFIG_DIR")
1070 AC_SUBST(GST_CONFIG_DIR)
1071
1072 dnl Set location of windows dll dir.
1073 AC_DEFINE_UNQUOTED(GST_WIN32_LIBDIR,"$GST_WIN32_LIBDIR")
1074 AC_SUBST(GST_WIN32_LIBDIR)
1075
1076 dnl Set location of plugin directory
1077 if test "x${prefix}" = "xNONE"; then
1078   PLUGINS_DIR=${ac_default_prefix}/lib/gst
1079 else
1080   PLUGINS_DIR=${prefix}/lib/gst
1081 fi
1082 AC_DEFINE_UNQUOTED(PLUGINS_DIR,"$PLUGINS_DIR")
1083 AC_SUBST(PLUGINS_DIR)
1084
1085 dnl Set location of uninstalled plugin directory
1086 PLUGINS_BUILDDIR=${builddir}
1087 AC_DEFINE_UNQUOTED(PLUGINS_BUILDDIR,"$PLUGINS_BUILDDIR")
1088 AC_SUBST(PLUGINS_BUILDDIR)
1089
1090 dnl Vars for everyone else
1091 GST_LIBS="\$(top_builddir)/gst/libgst.la"
1092 GST_CFLAGS="-I\$(top_srcdir) -I\$(top_srcdir)/include"
1093 AC_SUBST(GST_LIBS)
1094 AC_SUBST(GST_CFLAGS)
1095
1096 dnl Private vars for libgst only
1097 LIBGST_CFLAGS="$GST_CFLAGS"
1098 AC_SUBST(LIBGST_LIBS)
1099 AC_SUBST(LIBGST_CFLAGS)
1100
1101 AC_SUBST(GST_CFLAGS)
1102
1103 dnl #############################
1104 dnl # Configure the subpackages #
1105 dnl #############################
1106
1107 dnl AC_CONFIG_SUBDIRS(gist)
1108 dnl AC_CONFIG_SUBDIRS(plugins/mp3decode/xing/libxing)
1109
1110 dnl ##################################################
1111 dnl # Prepare informative messages to display at end #
1112 dnl ##################################################
1113
1114 infomessages=
1115
1116 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
1117   infomessages="$infomessages
1118 *** Warning: You have configured using the --enable-plugin-builddir option.
1119
1120 This option is for development purposes only: binaries built with
1121 it should be used with code in the build tree only.  To build an
1122 installable version, use ./configure without the --enable-plugin-builddir
1123 option.  Note that the autogen.sh script supplies the plugin builddir
1124 option automatically - it cannot be used to configure installable builds.
1125
1126 "
1127 fi
1128
1129 dnl #########################
1130 dnl # Make the output files #
1131 dnl #########################
1132
1133 dnl until ffmpeg is handled by configure plugins/ffmpeg/Makefile
1134 dnl components/bonobo-gstmediaplay/Makefile
1135 dnl FIXME someone should fix this test/misc/Makefile
1136 dnl FIXME wtay fix this: testsuite/threads/Makefile
1137 dnl FIXME testsuite/refcounting/Makefile
1138
1139 AC_OUTPUT(
1140 Makefile
1141 include/Makefile
1142 gst/Makefile
1143 gst/gstversion.h
1144 gst/types/Makefile
1145 gst/elements/Makefile
1146 gst/autoplug/Makefile
1147 gst/schedulers/Makefile
1148 libs/Makefile
1149 libs/riff/Makefile
1150 libs/getbits/Makefile
1151 libs/putbits/Makefile
1152 libs/idct/Makefile
1153 libs/audio/Makefile
1154 libs/bytestream/Makefile
1155 libs/control/Makefile
1156 libs/resample/Makefile
1157 plugins/Makefile
1158 plugins/a52dec/Makefile
1159 plugins/aasink/Makefile
1160 plugins/alsa/Makefile
1161 plugins/au/Makefile
1162 plugins/audiofile/Makefile
1163 plugins/audioscale/Makefile
1164 plugins/avi/Makefile
1165 plugins/avi/wincodec/Makefile
1166 plugins/avi/winaudio/Makefile
1167 plugins/flx/Makefile
1168 plugins/festival/Makefile
1169 plugins/flac/Makefile
1170 plugins/jpeg/Makefile
1171 plugins/mp3decode/Makefile
1172 plugins/mp3decode/types/Makefile
1173 plugins/mp3decode/xa/Makefile
1174 plugins/mp3decode/mpg123/Makefile
1175 plugins/mp3decode/mad/Makefile
1176 plugins/mp3decode/parse/Makefile
1177 plugins/mp3encode/Makefile
1178 plugins/mp3encode/lame/Makefile
1179 plugins/mikmod/Makefile
1180 plugins/mpeg2/Makefile
1181 plugins/mpeg2/parse/Makefile
1182 plugins/mpeg2/ac3parse/Makefile
1183 plugins/mpeg2/ac3dec/Makefile
1184 plugins/mpeg2/video/Makefile
1185 plugins/mpeg2/mpeg2enc/Makefile
1186 plugins/mpeg2/mpeg2dec/Makefile
1187 plugins/mpeg2/subtitles/Makefile
1188 plugins/mpeg2/videoparse/Makefile
1189 plugins/mpeg2/mpegtypes/Makefile
1190 plugins/mpeg1/Makefile
1191 plugins/mpeg1/mpegtypes/Makefile
1192 plugins/mpeg1/mpeg_play/Makefile
1193 plugins/mpeg1/mpegaudio/Makefile
1194 plugins/mpeg1/parse/Makefile
1195 plugins/mpeg1/system_encode/Makefile
1196 plugins/mpeg1/mpeg1encoder/Makefile
1197 plugins/mpeg1video/Makefile
1198 plugins/mpeg1video/parse/Makefile
1199 plugins/oss/Makefile
1200 plugins/rtp/Makefile
1201 plugins/mulaw/Makefile
1202 plugins/alaw/Makefile
1203 plugins/filters/Makefile
1204 plugins/filters/smooth/Makefile
1205 plugins/filters/median/Makefile
1206 plugins/filters/ladspa/Makefile
1207 plugins/filters/stereo2mono/Makefile
1208 plugins/filters/mono2stereo/Makefile
1209 plugins/filters/intfloatconvert/Makefile
1210 plugins/filters/passthrough/Makefile
1211 plugins/filters/adder/Makefile
1212 plugins/filters/colorspace/Makefile
1213 plugins/filters/volenv/Makefile
1214 plugins/filters/level/Makefile
1215 plugins/filters/lav/Makefile
1216 plugins/filters/cutter/Makefile
1217 plugins/filters/deinterlace/Makefile
1218 plugins/filters/volume/Makefile
1219 plugins/filters/speed/Makefile
1220 plugins/filters/playondemand/Makefile
1221 plugins/gnomevfs/Makefile
1222 plugins/icecast/Makefile
1223 plugins/icecast/icecastsend/Makefile
1224 plugins/effects/Makefile
1225 plugins/effects/stereo/Makefile
1226 plugins/effects/volume/Makefile
1227 plugins/udp/Makefile
1228 plugins/visualization/Makefile
1229 plugins/visualization/spectrum/Makefile
1230 plugins/visualization/vumeter/Makefile
1231 plugins/visualization/synaesthesia/Makefile
1232 plugins/visualization/smoothwave/Makefile
1233 plugins/visualization/chart/Makefile
1234 plugins/videoscale/Makefile
1235 plugins/xvideosink/Makefile
1236 plugins/wav/Makefile
1237 plugins/dvdsrc/Makefile
1238 plugins/vcdsrc/Makefile
1239 plugins/rtjpeg/Makefile
1240 plugins/SID/Makefile
1241 plugins/vorbis/Makefile
1242 plugins/capture/Makefile
1243 plugins/capture/v4l/Makefile
1244 plugins/capture/qcam/Makefile
1245 plugins/cdparanoia/Makefile
1246 plugins/esd/Makefile
1247 plugins/esd/esdsink/Makefile
1248 plugins/artsd/Makefile
1249 plugins/quicktime/Makefile
1250 plugins/xmms/Makefile
1251 plugins/arts/Makefile
1252 plugins/gsm/Makefile
1253 plugins/1394/Makefile
1254 plugins/sdlsink/Makefile
1255 plugins/dv/Makefile
1256 plugins/synthesis/Makefile
1257 plugins/synthesis/sinesrc/Makefile
1258 plugins/silence/Makefile
1259 gstplay/Makefile
1260 test/Makefile
1261 test/xml/Makefile
1262 test/bindings/Makefile
1263 test/memchunk/Makefile
1264 test/events/Makefile
1265 tests/Makefile
1266 tests/sched/Makefile
1267 tests/eos/Makefile
1268 tests/muxing/Makefile
1269 testsuite/Makefile
1270 testsuite/bytestream/Makefile
1271 testsuite/capsnego/Makefile
1272 testsuite/plugin/Makefile
1273 tests/nego/Makefile
1274 examples/Makefile
1275 examples/autoplug/Makefile
1276 examples/helloworld/Makefile
1277 examples/helloworld2/Makefile
1278 examples/launch/Makefile
1279 examples/queue/Makefile
1280 examples/queue2/Makefile
1281 examples/queue3/Makefile
1282 examples/queue4/Makefile
1283 examples/thread/Makefile
1284 examples/mixer/Makefile
1285 examples/cutter/Makefile
1286 examples/launch/Makefile
1287 examples/xml/Makefile
1288 examples/plugins/Makefile
1289 examples/typefind/Makefile
1290 examples/mixer/Makefile
1291 editor/Makefile
1292 editor/pixmaps/Makefile
1293 tools/Makefile
1294 docs/Makefile
1295 docs/gst/Makefile
1296 docs/gst/gstreamer.types
1297 docs/libs/Makefile
1298 docs/plugins/Makefile
1299 docs/plugins/gstreamer-plugins.types
1300 docs/manual/Makefile
1301 docs/fwg/Makefile
1302 debian/Makefile
1303 stamp.h
1304 gstreamer-config
1305 gstreamer.pc
1306 gstreamer-uninstalled.pc
1307 gstreamer.spec,
1308 chmod +x gstreamer-config
1309 echo "$infomessages", infomessages="$infomessages"
1310 )