configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.24.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 21, 0, 21)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.17])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 113 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 dnl building of tests
 129 AC_ARG_ENABLE(tests,
 130   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 131   [
 132     case "${enableval}" in
 133       yes) BUILD_TESTS=yes ;;
 134       no)  BUILD_TESTS=no ;;
 135       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 136     esac
 137   ],
 138 [BUILD_TESTS=yes]) dnl Default value
 139 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 140
 141 dnl tests known to fail
 142 AC_ARG_ENABLE(failing-tests,
 143   AC_HELP_STRING([--disable-failing-tests],
 144     [disable building tests known to fail]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_FAILING_TESTS=yes ;;
 148       no)  BUILD_FAILING_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 150     esac
 151   ],
 152   [BUILD_FAILING_TESTS=no]) dnl Default value
 153 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 154 if test x$BUILD_FAILING_TESTS = xyes; then
 155   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 156 else
 157   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 158 fi
 159
 160 dnl poison destroyed objects
 161 AC_ARG_ENABLE(poisoning,
 162   AC_HELP_STRING([--enable-poisoning],
 163     [enable poisoning of deallocated objects]),
 164   [
 165     case "${enableval}" in
 166       yes) USE_POISONING=yes ;;
 167       no)  USE_POISONING=no ;;
 168       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 169     esac
 170   ],
 171   [USE_POISONING=no]) dnl Default value
 172 if test "x$USE_POISONING" = xyes; then
 173   AC_DEFINE(USE_POISONING, 1,
 174     [Define if we should poison deallocated memory])
 175 fi
 176
 177 dnl *** checks for platform ***
 178
 179 dnl * hardware/architecture *
 180
 181 dnl common/m4/gst-arch.m4
 182 dnl check CPU type
 183 AG_GST_ARCH
 184 dnl substitution for win32/common/config.h
 185 HOST_CPU=$host_cpu
 186 AC_SUBST(HOST_CPU)
 187
 188 dnl common/m4/gst-arch.m4
 189 dnl check for unaligned access
 190 AG_GST_UNALIGNED_ACCESS
 191 dnl create a configure variable for gst/gstconfig.h
 192 if test x${as_cv_unaligned_access} = xyes ; then
 193   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 194 else
 195   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 196 fi
 197 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 198
 199 dnl check for platform specific settings
 200 case $host_os in
 201      rhapsody*)
 202         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 203         ;;
 204      darwin*)
 205         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 206         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 207         ;;
 208      cygwin*)
 209         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 210         ;;
 211      mingw* | msvc* | mks*)
 212         dnl HAVE_WIN32 currently means "disable POSIXisms".
 213         AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 214
 215         dnl define __MSVCRT_VERSION__ version if not set already by the
 216         dnl compiler (ie. mostly for mingw). This is needed for things like
 217         dnl __stat64 to be available. If set by the compiler, ensure it's
 218         dnl new enough - we need at least WinXP SP2.
 219         AC_TRY_COMPILE([ ], [ return __MSVCRT_VERSION__; ], [
 220             AC_TRY_COMPILE([ ], [
 221               #if __MSVCRT_VERSION__ < 0x0601
 222               #error "MSVCRT too old"
 223               #endif
 224             ], [
 225               AC_MSG_NOTICE([MSVCRT version looks ok])
 226             ], [
 227               AC_MSG_ERROR([MSVCRT version too old, need at least WinXP SP2])
 228             ])
 229         ], [
 230           AC_MSG_NOTICE([Setting MSVCRT version to 0x0601])
 231           AC_DEFINE_UNQUOTED(__MSVCRT_VERSION__, 0x0601, [We need at least WinXP SP2 for __stat64])
 232         ])
 233         ;;
 234      *)
 235         ;;
 236 esac
 237
 238 dnl * software *
 239
 240 dnl check for large file support
 241 dnl affected plugins must include config.h
 242 AC_SYS_LARGEFILE
 243
 244 dnl *** checks for programs ***
 245
 246 dnl find a compiler
 247 AC_PROG_CC
 248
 249 dnl check if the compiler supports '-c' and '-o' options
 250 AM_PROG_CC_C_O
 251
 252 dnl find an assembler
 253 AM_PROG_AS
 254
 255 dnl Perl is used in building documentation and in the version checks
 256 AC_PATH_PROG(PERL_PATH, perl, no)
 257 if test x$PERL_PATH = xno; then
 258   AC_MSG_ERROR(Could not find perl)
 259 fi
 260
 261 dnl we require flex and bison for building the parser
 262 if test "x$GST_DISABLE_PARSE" != xyes; then
 263   AG_GST_BISON_CHECK
 264   AG_GST_FLEX_CHECK
 265 fi
 266
 267 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 268 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 269
 270 dnl check for documentation tools
 271 AG_GST_DOCBOOK_CHECK
 272 GTK_DOC_CHECK([1.3])
 273 AS_PATH_PYTHON([2.1])
 274 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 275
 276 dnl *** checks for libraries ***
 277
 278 dnl check for libm, for sin()
 279 AC_CHECK_LIBM
 280 AC_SUBST(LIBM)
 281
 282 dnl *** checks for header files ***
 283
 284 dnl check if we have ANSI C header files
 285 AC_HEADER_STDC
 286
 287 dnl Check for ucontext.h
 288 AC_CHECK_HEADERS([ucontext.h])
 289
 290 dnl Check for sys/socket.h
 291 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 292 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 293
 294 dnl check for sys/times.h for tests/examples/adapter/
 295 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 296 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 297 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 298
 299 dnl Check for process.h for getpid() on win32
 300 AC_CHECK_HEADERS([process.h])
 301
 302 dnl Check for sys/utsname.h for uname
 303 AC_CHECK_HEADERS([sys/utsname.h])
 304
 305 dnl Check for stdio_ext.f for __fbufsize
 306 AC_CHECK_HEADERS([stdio_ext.h])
 307
 308 dnl check for pthreads
 309 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 310 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 311
 312 dnl Check for valgrind.h
 313 dnl separate from HAVE_VALGRIND because you can have the program, but not
 314 dnl the dev package
 315 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 316
 317 dnl used in gst/gstpoll.c
 318 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 319 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 320 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 321   WIN32_LIBS="-lws2_32"
 322   AC_SUBST(WIN32_LIBS)
 323 fi
 324
 325 dnl *** checks for types/defines ***
 326
 327 dnl *** checks for structures ***
 328
 329 dnl *** checks for compiler characteristics ***
 330
 331 OPT_CFLAGS=
 332 dnl Check for some compiler flags that optimize our code.
 333 if test "x$GCC" = xyes; then
 334   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 335 fi
 336
 337 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 338 dnl flag
 339 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 340 dnl symbolic register names in inline asm
 341 if test x$HAVE_CPU_PPC = xyes ; then
 342   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 343     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 344 fi
 345
 346 dnl *** checks for library functions ***
 347
 348 AC_CHECK_FUNCS([sigaction])
 349
 350 dnl we use fork in the registry code
 351 AC_CHECK_FUNCS([fork])
 352
 353 dnl check for fseeko()
 354 AC_FUNC_FSEEKO
 355 dnl check for ftello()
 356 AC_CHECK_FUNCS([ftello])
 357
 358 AC_CHECK_FUNCS([fgetpos])
 359 AC_CHECK_FUNCS([fsetpos])
 360
 361 dnl check for poll(), ppoll() and pselect()
 362 AC_CHECK_FUNCS([poll])
 363 AC_CHECK_FUNCS([ppoll])
 364 AC_CHECK_FUNCS([pselect])
 365
 366 dnl check for mmap()
 367 AC_FUNC_MMAP
 368 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 369
 370 dnl Check for POSIX timers
 371 AC_CHECK_FUNCS(clock_gettime, [], [
 372   AC_CHECK_LIB(rt, clock_gettime, [
 373     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 374     LIBS="$LIBS -lrt"
 375   ])
 376 ])
 377
 378 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 379     AC_TRY_COMPILE([
 380 #include <time.h>
 381 #ifdef HAVE_UNISTD_H
 382 #include <unistd.h>
 383 #endif
 384     ], [
 385 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 386 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 387 #endif
 388       return 0;
 389     ], [
 390       gst_cv_posix_timers=yes
 391     ], [
 392       gst_cv_posix_timers=no
 393     ])
 394 )
 395
 396 if test "$gst_cv_posix_timers" = "yes"; then
 397   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 398   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 399 else
 400   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 401 fi
 402 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 403 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 404
 405 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 406     AC_TRY_COMPILE([
 407 #include <time.h>
 408 #ifdef HAVE_UNISTD_H
 409 #include <unistd.h>
 410 #endif
 411     ], [
 412 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 413 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 414 #endif
 415       return 0;
 416     ], [
 417       gst_cv_monotonic_clock=yes
 418     ], [
 419       gst_cv_monotonic_clock=no
 420     ])
 421 )
 422
 423 if test "$gst_cv_monotonic_clock" = "yes"; then
 424   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 425   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 426 else
 427   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 428 fi
 429 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 430 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 431
 432 dnl Check for a way to display the function name in debug output
 433 AG_GST_CHECK_FUNCTION
 434
 435 dnl test for register_printf_specifier or register_printf_function
 436 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 437     [HAVE_PRINTF_EXTENSION=yes])
 438
 439 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 440   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 441   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 442   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 443   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 444       [Defined if we have printf specifier extensions available])
 445 else
 446     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 447     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 448     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 449 fi
 450 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 451 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 452 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 453
 454 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 455 save_cflags="$CFLAGS"
 456 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 457 AC_CHECK_LIB(dl, dladdr,
 458    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 459    LIBS="$LIBS -ldl")
 460 CFLAGS="$save_cflags"
 461
 462 dnl *** checks for socket and nsl libraries ***
 463 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 464 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 465
 466 dnl check for inet_aton()
 467 save_libs="$LIBS"
 468 AC_CHECK_FUNC(inet_aton, ,
 469    AC_CHECK_LIB(nsl, inet_aton, ,
 470       AC_CHECK_LIB(socket, inet_aton, ,
 471          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 472 INET_ATON_LIBS=$LIBS
 473 AC_SUBST(INET_ATON_LIBS)
 474 LIBS="$save_libs"
 475
 476 dnl *** checks for dependency libraries ***
 477
 478 dnl GLib
 479 GLIB_REQ=2.16
 480
 481 AG_GST_GLIB_CHECK([$GLIB_REQ])
 482
 483 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 484 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 485 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 486
 487 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 488 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 489
 490 dnl Check for documentation xrefs
 491 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 492 AC_SUBST(GLIB_PREFIX)
 493
 494 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 495 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 496 then
 497   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 498   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 499 else
 500   dnl check for libxml2 with minimum req version
 501   AG_GST_LIBXML2_CHECK(2.4.9)
 502   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 503 fi
 504 AC_SUBST(GST_DISABLE_XML_DEFINE)
 505
 506 dnl check for "check", unit testing library/header
 507 if test "$cross_compiling" != yes; then
 508   AM_PATH_CHECK(0.9.2,
 509       HAVE_CHECK=yes,
 510       HAVE_CHECK=no)
 511 else
 512   HAVE_CHECK=no
 513 fi
 514 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 515
 516 dnl pkg-config check that for libcheck that works for cross-compiling
 517 dnl but not normal compilation on Fedora & Ubuntu:
 518 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 519 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 520 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 521 dnl )
 522
 523 dnl *** set variables based on configure arguments
 524
 525 dnl set license and copyright notice
 526 GST_LICENSE="LGPL"
 527 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 528 AC_SUBST(GST_LICENSE)
 529
 530 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 531 AS_AC_EXPAND(LIBDIR, $libdir)
 532 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 533 AS_AC_EXPAND(DATADIR, $datadir)
 534 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 535
 536 dnl set location of plugin directory
 537 AG_GST_SET_PLUGINDIR
 538
 539 dnl FIXME: add LIBXML_PKG here if we use it
 540 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 541 AC_SUBST(GST_PKG_DEPS)
 542
 543 dnl define an ERROR_CFLAGS Makefile variable
 544 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 545
 546 dnl define correct level for debugging messages
 547 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 548
 549 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 550
 551 dnl Overview:
 552 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 553 dnl GST_ALL_*:          vars shared by all built objects
 554 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 555 dnl GST_OBJ_*:          additional vars to link to the core library
 556 dnl                     include GST_ALL_*
 557 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 558 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 559
 560 dnl GST_OPTION_CFLAGS
 561 if test "x$USE_DEBUG" = xyes; then
 562    PROFILE_CFLAGS="-g"
 563 fi
 564 AC_SUBST(PROFILE_CFLAGS)
 565
 566 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 567 # functionality from the API that gstreamer uses
 568 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 569 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 570   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 571   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 572 else
 573   DEPRECATED_CFLAGS=""
 574 fi
 575 AC_SUBST(DEPRECATED_CFLAGS)
 576
 577 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 578 dnl make DEPRECATED_CFLAGS=''
 579 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 580 AC_SUBST(GST_OPTION_CFLAGS)
 581
 582 dnl GST_ALL_*
 583 dnl vars common to for all internal objects (core libs, elements, applications)
 584 dnl CFLAGS:
 585 dnl - XML needs to be added because xmlPtr is used in core
 586 dnl - src and build dirs need to be added because every piece that gets built
 587 dnl   will need the GStreamer source and generated headers
 588 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 589 dnl       from LibXML except for in the core library
 590 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 591
 592 dnl FIXME: check if LTLIBINTL is needed everywhere
 593 dnl I presume it is given that it contains the symbols that _() stuff maps to
 594 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 595
 596 dnl LDFLAGS really should only contain flags, not libs - they get added before
 597 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 598 GST_ALL_LDFLAGS="-no-undefined"
 599
 600 AC_SUBST(GST_ALL_CFLAGS)
 601 AC_SUBST(GST_ALL_LIBS)
 602 AC_SUBST(GST_ALL_LDFLAGS)
 603
 604 dnl GST_LIB_LDFLAGS
 605 dnl linker flags shared by all libraries
 606 dnl LDFLAGS modifier defining exported symbols from built libraries
 607 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 608 AC_SUBST(GST_LIB_LDFLAGS)
 609 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
 610 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
 611 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
 612 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
 613   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
 614 fi
 615 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
 616
 617 dnl GST_OBJ_*
 618 dnl default vars for all internal objects built on libgstreamer
 619 dnl includes GST_ALL_*
 620 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 621 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 622 AC_SUBST(GST_OBJ_CFLAGS)
 623 AC_SUBST(GST_OBJ_LIBS)
 624
 625 dnl GST_PLUGIN_LDFLAGS
 626 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 627 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 628 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 629
 630 SHAVE_INIT([common],[enable])
 631
 632 AC_CONFIG_FILES(
 633 Makefile
 634 common/shave
 635 common/shave-libtool
 636 gst/Makefile
 637 gst/gstconfig.h
 638 gst/gstversion.h
 639 gst/parse/Makefile
 640 libs/Makefile
 641 libs/gst/Makefile
 642 libs/gst/base/Makefile
 643 libs/gst/check/Makefile
 644 libs/gst/controller/Makefile
 645 libs/gst/dataprotocol/Makefile
 646 libs/gst/net/Makefile
 647 plugins/Makefile
 648 plugins/indexers/Makefile
 649 plugins/elements/Makefile
 650 po/Makefile.in
 651 tests/Makefile
 652 tests/benchmarks/Makefile
 653 tests/check/Makefile
 654 tests/misc/Makefile
 655 tests/examples/Makefile
 656 tests/examples/adapter/Makefile
 657 tests/examples/controller/Makefile
 658 tests/examples/stepping/Makefile
 659 tests/examples/helloworld/Makefile
 660 tests/examples/launch/Makefile
 661 tests/examples/manual/Makefile
 662 tests/examples/metadata/Makefile
 663 tests/examples/queue/Makefile
 664 tests/examples/streams/Makefile
 665 tests/examples/typefind/Makefile
 666 tests/examples/xml/Makefile
 667 tools/Makefile
 668 common/Makefile
 669 common/m4/Makefile
 670 docs/Makefile
 671 docs/design/Makefile
 672 docs/faq/Makefile
 673 docs/gst/Makefile
 674 docs/gst/gstreamer.types
 675 docs/libs/Makefile
 676 docs/plugins/Makefile
 677 docs/manual/Makefile
 678 docs/pwg/Makefile
 679 docs/slides/Makefile
 680 docs/xsl/Makefile
 681 docs/version.entities
 682 pkgconfig/Makefile
 683 stamp.h
 684 pkgconfig/gstreamer.pc
 685 pkgconfig/gstreamer-uninstalled.pc
 686 pkgconfig/gstreamer-base.pc
 687 pkgconfig/gstreamer-base-uninstalled.pc
 688 pkgconfig/gstreamer-check.pc
 689 pkgconfig/gstreamer-check-uninstalled.pc
 690 pkgconfig/gstreamer-controller.pc
 691 pkgconfig/gstreamer-controller-uninstalled.pc
 692 pkgconfig/gstreamer-dataprotocol.pc
 693 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 694 pkgconfig/gstreamer-net.pc
 695 pkgconfig/gstreamer-net-uninstalled.pc
 696 gst-element-check.m4
 697 gstreamer.spec
 698 )
 699
 700 dnl Create the config.h file for Visual Studio builds
 701 dnl Beware of spaces and /'s in some of the shell variable contents.
 702 sed \
 703     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 704     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 705     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 706     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 707     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 708     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 709     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 710     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 711     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 712     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 713     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 714     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 715     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 716     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 717     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 718     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 719     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 720     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 721     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 722     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 723     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 724     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 725     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 726     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 727     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 728     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 729     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 730     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 731     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 732     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 733     config.h.in >win32/common/config.h-new
 734
 735 AC_OUTPUT
 736
 737 dnl negate for output
 738 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 739 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 740 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 741 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 742 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 743 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 744 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 745 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 746 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 747
 748 echo "
 749
 750 Configuration
 751         Version                    : ${VERSION}
 752         Source code location       : ${srcdir}
 753         Prefix                     : ${prefix}
 754         Compiler                   : ${SHAVE_SAVED_CC}
 755         Package name               : ${GST_PACKAGE_NAME}
 756         Package origin             : ${GST_PACKAGE_ORIGIN}
 757
 758         Documentation (manuals)    : ${enable_docbook}
 759         Documentation (API)        : ${enable_gtk_doc}
 760
 761         Debug Logging              : ${enable_gst_debug}
 762         Pipeline XML load/save     : ${enable_loadsave}
 763         Command-line parser        : ${enable_parse}
 764         Option parsing in gst_init : ${enable_option_parsing}
 765         Tracing subsystem          : ${enable_trace}
 766         Allocation tracing         : ${enable_alloc_trace}
 767         Plugin registry            : ${enable_registry}
 768         Plugin support             : ${enable_plugin}
 769         Network support            : ${enable_net}
 770
 771         Debug                      : ${USE_DEBUG}
 772         Profiling                  : ${USE_PROFILING}
 773
 774         Building examples          : ${BUILD_EXAMPLES}
 775         Building test apps         : ${BUILD_TESTS}
 776         Building tests that fail   : ${BUILD_FAILING_TESTS}
 777 "