configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32 m4_include([config/cloog.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_PREREQ(2.64)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl cloog libelf libiconv"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 145
 146 # libgcj represents the runtime libraries only used by gcj.
 147 libgcj="target-libffi \
 148         target-zlib \
 149         target-libjava"
 150
 151 # these libraries are built for the target environment, and are built after
 152 # the host libraries and the host tools (which may be a cross compiler)
 153 # Note that libiberty is not a target library.
 154 target_libraries="target-libgcc \
 155                 target-libbacktrace \
 156                 target-libgloss \
 157                 target-newlib \
 158                 target-libgomp \
 159                 target-libatomic \
 160                 target-libitm \
 161                 target-libstdc++-v3 \
 162                 target-libmudflap \
 163                 target-libsanitizer \
 164                 target-libssp \
 165                 target-libquadmath \
 166                 target-libgfortran \
 167                 target-boehm-gc \
 168                 ${libgcj} \
 169                 target-libobjc \
 170                 target-libada \
 171                 target-libgo"
 172
 173 # these tools are built using the target libraries, and are intended to
 174 # run only in the target environment
 175 #
 176 # note: any program that *uses* libraries that are in the "target_libraries"
 177 # list belongs in this list.
 178 #
 179 target_tools="target-rda"
 180
 181 ################################################################################
 182
 183 ## All tools belong in one of the four categories, and are assigned above
 184 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 185 ## is important because configure will choke if they ever get through.
 186 ## ${configdirs} is directories we build using the host tools.
 187 ## ${target_configdirs} is directories we build using the target tools.
 188 configdirs=`echo ${host_libs} ${host_tools}`
 189 target_configdirs=`echo ${target_libraries} ${target_tools}`
 190 build_configdirs=`echo ${build_libs} ${build_tools}`
 191
 192 m4_divert_text([PARSE_ARGS],
 193 [case $srcdir in
 194   *" "*)
 195 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 196     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 197 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 198     ;;
 199 esac
 200 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 201 ])
 202
 203 ################################################################################
 204
 205 srcname="gnu development package"
 206
 207 # This gets set non-empty for some net releases of packages.
 208 appdirs=""
 209
 210 # Define is_cross_compiler to save on calls to 'test'.
 211 is_cross_compiler=
 212 if test x"${host}" = x"${target}" ; then
 213   is_cross_compiler=no
 214 else
 215   is_cross_compiler=yes
 216 fi
 217
 218 # Find the build and target subdir names.
 219 GCC_TOPLEV_SUBDIRS
 220 # Be sure to cover against remnants of an in-tree build.
 221 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 222   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 223 Use a pristine source tree when building in a separate tree])
 224 fi
 225
 226 # Skipdirs are removed silently.
 227 skipdirs=
 228 # Noconfigdirs are removed loudly.
 229 noconfigdirs=""
 230
 231 use_gnu_ld=
 232 # Make sure we don't let GNU ld be added if we didn't want it.
 233 if test x$with_gnu_ld = xno ; then
 234   use_gnu_ld=no
 235   noconfigdirs="$noconfigdirs ld gold"
 236 fi
 237
 238 use_gnu_as=
 239 # Make sure we don't let GNU as be added if we didn't want it.
 240 if test x$with_gnu_as = xno ; then
 241   use_gnu_as=no
 242   noconfigdirs="$noconfigdirs gas"
 243 fi
 244
 245 use_included_zlib=
 246 # Make sure we don't let ZLIB be added if we didn't want it.
 247 if test x$with_system_zlib = xyes ; then
 248   use_included_zlib=no
 249   noconfigdirs="$noconfigdirs zlib"
 250 fi
 251
 252 # some tools are so dependent upon X11 that if we're not building with X,
 253 # it's not even worth trying to configure, much less build, that tool.
 254
 255 case ${with_x} in
 256   yes | "") ;; # the default value for this tree is that X11 is available
 257   no)
 258     skipdirs="${skipdirs} tk itcl libgui"
 259     # We won't be able to build gdbtk without X.
 260     enable_gdbtk=no
 261     ;;
 262   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 263 esac
 264
 265 # Some are only suitable for cross toolchains.
 266 # Remove these if host=target.
 267 cross_only="target-libgloss target-newlib target-opcodes"
 268
 269 case $is_cross_compiler in
 270   no) skipdirs="${skipdirs} ${cross_only}" ;;
 271 esac
 272
 273 # If both --with-headers and --with-libs are specified, default to
 274 # --without-newlib.
 275 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 276    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 277   if test x"${with_newlib}" = x ; then
 278     with_newlib=no
 279   fi
 280 fi
 281
 282 # Recognize --with-newlib/--without-newlib.
 283 case ${with_newlib} in
 284   no) skipdirs="${skipdirs} target-newlib" ;;
 285   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 286 esac
 287
 288 # Handle --enable-gold, --enable-ld.
 289 # --disable-gold [--enable-ld]
 290 #     Build only ld.  Default option.
 291 # --enable-gold [--enable-ld]
 292 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 293 #     as "ld.bfd" and "ld".
 294 # --enable-gold=default [--enable-ld]
 295 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 296 #     install ld as "ld.bfd".
 297 # --enable-gold[=default] --disable-ld
 298 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 299 # --enable-gold --enable-ld=default
 300 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 301 #     and ld.bfd).
 302 #     In other words, ld is default
 303 # --enable-gold=default --enable-ld=default
 304 #     Error.
 305
 306 default_ld=
 307 AC_ARG_ENABLE(gold,
 308 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 309                 [build gold @<:@ARG={default,yes,no}@:>@])],
 310 ENABLE_GOLD=$enableval,
 311 ENABLE_GOLD=no)
 312 case "${ENABLE_GOLD}" in
 313   yes|default)
 314     # Check for ELF target.
 315     is_elf=no
 316     case "${target}" in
 317       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 318       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 319       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 320       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 321         case "${target}" in
 322           *-*-linux*aout* | *-*-linux*oldld*)
 323             ;;
 324           *)
 325             is_elf=yes
 326             ;;
 327         esac
 328     esac
 329
 330     if test "$is_elf" = "yes"; then
 331       # Check for target supported by gold.
 332       case "${target}" in
 333         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* | tilegx*-*-*)
 334           configdirs="$configdirs gold"
 335           if test x${ENABLE_GOLD} = xdefault; then
 336             default_ld=gold
 337           fi
 338           ENABLE_GOLD=yes
 339           ;;
 340       esac
 341     fi
 342     ;;
 343   no)
 344     ;;
 345   *)
 346     AC_MSG_ERROR([invalid --enable-gold argument])
 347     ;;
 348 esac
 349
 350 AC_ARG_ENABLE(ld,
 351 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 352                 [build ld @<:@ARG={default,yes,no}@:>@])],
 353 ENABLE_LD=$enableval,
 354 ENABLE_LD=yes)
 355
 356 case "${ENABLE_LD}" in
 357   default)
 358     if test x${default_ld} != x; then
 359       AC_MSG_ERROR([either gold or ld can be the default ld])
 360     fi
 361     ;;
 362   yes)
 363     ;;
 364   no)
 365     if test x${ENABLE_GOLD} != xyes; then
 366       AC_MSG_WARN([neither ld nor gold are enabled])
 367     fi
 368     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 369     ;;
 370   *)
 371     AC_MSG_ERROR([invalid --enable-ld argument])
 372     ;;
 373 esac
 374
 375 # Configure extra directories which are host specific
 376
 377 case "${host}" in
 378   *-cygwin*)
 379     configdirs="$configdirs libtermcap" ;;
 380 esac
 381
 382 # A target can indicate whether a language isn't supported for some reason.
 383 # Only spaces may be used in this macro; not newlines or tabs.
 384 unsupported_languages=
 385
 386 # Remove more programs from consideration, based on the host or
 387 # target this usually means that a port of the program doesn't
 388 # exist yet.
 389
 390 case "${host}" in
 391   i[[3456789]]86-*-msdosdjgpp*)
 392     noconfigdirs="$noconfigdirs tcl tk itcl"
 393     ;;
 394 esac
 395
 396
 397 AC_ARG_ENABLE(libquadmath,
 398 AS_HELP_STRING([--disable-libquadmath],
 399   [do not build libquadmath directory]),
 400 ENABLE_LIBQUADMATH=$enableval,
 401 ENABLE_LIBQUADMATH=yes)
 402 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 403   noconfigdirs="$noconfigdirs target-libquadmath"
 404 fi
 405
 406
 407 AC_ARG_ENABLE(libquadmath-support,
 408 AS_HELP_STRING([--disable-libquadmath-support],
 409   [disable libquadmath support for Fortran]),
 410 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 411 ENABLE_LIBQUADMATH_SUPPORT=yes)
 412 enable_libquadmath_support=
 413 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 414   enable_libquadmath_support=no
 415 fi
 416
 417
 418 AC_ARG_ENABLE(libada,
 419 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 420 ENABLE_LIBADA=$enableval,
 421 ENABLE_LIBADA=yes)
 422 if test "${ENABLE_LIBADA}" != "yes" ; then
 423   noconfigdirs="$noconfigdirs gnattools"
 424 fi
 425
 426 AC_ARG_ENABLE(libssp,
 427 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 428 ENABLE_LIBSSP=$enableval,
 429 ENABLE_LIBSSP=yes)
 430
 431 AC_ARG_ENABLE(libstdcxx,
 432 AS_HELP_STRING([--disable-libstdcxx],
 433   [do not build libstdc++-v3 directory]),
 434 ENABLE_LIBSTDCXX=$enableval,
 435 ENABLE_LIBSTDCXX=default)
 436 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 437   noconfigdirs="$noconfigdirs libstdc++-v3"
 438 fi]
 439
 440 # Save it here so that, even in case of --enable-libgcj, if the Java
 441 # front-end isn't enabled, we still get libgcj disabled.
 442 libgcj_saved=$libgcj
 443 case $enable_libgcj in
 444 yes)
 445   # If we reset it here, it won't get added to noconfigdirs in the
 446   # target-specific build rules, so it will be forcibly enabled
 447   # (unless the Java language itself isn't enabled).
 448   libgcj=
 449   ;;
 450 no)
 451   # Make sure we get it printed in the list of not supported target libs.
 452   # Don't disable libffi, though, other languages use it.
 453   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 454   # Clear libgcj_saved so that even if java is enabled libffi won't be
 455   # built.
 456   libgcj_saved=
 457   ;;
 458 esac
 459
 460 AC_ARG_ENABLE(static-libjava,
 461 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 462                 [build static libjava @<:@default=no@:>@])],
 463 ENABLE_STATIC_LIBJAVA=$enableval,
 464 ENABLE_STATIC_LIBJAVA=no)
 465 enable_static_libjava=
 466 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 467   enable_static_libjava=yes
 468 fi
 469
 470 if test x$enable_static_libjava != xyes ; then
 471   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 472 fi
 473 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 474
 475 # Disable libmudflap on some systems.
 476 if test x$enable_libmudflap = x ; then
 477     case "${target}" in
 478     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 479         # Enable libmudflap by default in GNU and friends.
 480         ;;
 481     *-*-freebsd*)
 482         # Enable libmudflap by default in FreeBSD.
 483         ;;
 484     *)
 485         # Disable it by default everywhere else.
 486         noconfigdirs="$noconfigdirs target-libmudflap"
 487         ;;
 488     esac
 489 fi
 490
 491 # Disable libgomp on non POSIX hosted systems.
 492 if test x$enable_libgomp = x ; then
 493     # Enable libgomp by default on hosted POSIX systems.
 494     case "${target}" in
 495     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 496         ;;
 497     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 498         ;;
 499     *-*-solaris2* | *-*-hpux11*)
 500         ;;
 501     *-*-darwin* | *-*-aix*)
 502         ;;
 503     *)
 504         noconfigdirs="$noconfigdirs target-libgomp"
 505         ;;
 506     esac
 507 fi
 508
 509 # Disable libatomic on unsupported systems.
 510 if test -d ${srcdir}/libatomic; then
 511     if test x$enable_libatomic = x; then
 512         AC_MSG_CHECKING([for libatomic support])
 513         if (srcdir=${srcdir}/libatomic; \
 514                 . ${srcdir}/configure.tgt; \
 515                 test -n "$UNSUPPORTED")
 516         then
 517             AC_MSG_RESULT([no])
 518             noconfigdirs="$noconfigdirs target-libatomic"
 519         else
 520             AC_MSG_RESULT([yes])
 521         fi
 522     fi
 523 fi
 524
 525 # Disable libitm on unsupported systems.
 526 if test -d ${srcdir}/libitm; then
 527     if test x$enable_libitm = x; then
 528         AC_MSG_CHECKING([for libitm support])
 529         if (srcdir=${srcdir}/libitm; \
 530                 . ${srcdir}/configure.tgt; \
 531                 test -n "$UNSUPPORTED")
 532         then
 533             AC_MSG_RESULT([no])
 534             noconfigdirs="$noconfigdirs target-libitm"
 535         else
 536             AC_MSG_RESULT([yes])
 537         fi
 538     fi
 539 fi
 540
 541 # Disable libsanitizer on unsupported systems.
 542 if test -d ${srcdir}/libsanitizer; then
 543     if test x$enable_libsanitizer = x; then
 544         AC_MSG_CHECKING([for libsanitizer support])
 545         if (srcdir=${srcdir}/libsanitizer; \
 546                 . ${srcdir}/configure.tgt; \
 547                 test -n "$UNSUPPORTED")
 548         then
 549             AC_MSG_RESULT([no])
 550             noconfigdirs="$noconfigdirs target-libsanitizer"
 551         else
 552             AC_MSG_RESULT([yes])
 553         fi
 554     fi
 555 fi
 556
 557 # Disable libquadmath for some systems.
 558 case "${target}" in
 559   avr-*-*)
 560     noconfigdirs="$noconfigdirs target-libquadmath"
 561     ;;
 562   # libquadmath is unused on AIX and libquadmath build process use of
 563   # LD_LIBRARY_PATH can break AIX bootstrap.
 564   powerpc-*-aix* | rs6000-*-aix*)
 565     noconfigdirs="$noconfigdirs target-libquadmath"
 566     ;;
 567 esac
 568
 569 # Disable libssp for some systems.
 570 case "${target}" in
 571   avr-*-*)
 572     # No hosted I/O support.
 573     noconfigdirs="$noconfigdirs target-libssp"
 574     ;;
 575   powerpc-*-aix* | rs6000-*-aix*)
 576     noconfigdirs="$noconfigdirs target-libssp"
 577     ;;
 578   rl78-*-*)
 579     # libssp uses a misaligned load to trigger a fault, but the RL78
 580     # doesn't fault for those - instead, it gives a build-time error
 581     # for explicit misaligned loads.
 582     noconfigdirs="$noconfigdirs target-libssp"
 583     ;;
 584 esac
 585
 586 # Disable libstdc++-v3 for some systems.
 587 # Allow user to override this if they pass --enable-libstdc++-v3
 588 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 589   case "${target}" in
 590     *-*-vxworks*)
 591       # VxWorks uses the Dinkumware C++ library.
 592       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 593       ;;
 594     arm*-wince-pe*)
 595       # the C++ libraries don't build on top of CE's C libraries
 596       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 597       ;;
 598     avr-*-*)
 599       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 600       ;;
 601   esac
 602 fi
 603
 604 # Disable Fortran for some systems.
 605 case "${target}" in
 606   mmix-*-*)
 607     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 608     unsupported_languages="$unsupported_languages fortran"
 609     ;;
 610 esac
 611
 612 # Disable Java if libffi is not supported.
 613 case "${target}" in
 614   alpha*-*-*)
 615     ;;
 616   arm*-*-*)
 617     ;;
 618   cris-*-*)
 619     ;;
 620   frv-*-*)
 621     ;;
 622   hppa*-*-linux*)
 623     ;;
 624   hppa*-*-hpux*)
 625     ;;
 626   i?86-*-*)
 627     ;;
 628   ia64*-*-*)
 629     ;;
 630   m32r*-*-*)
 631     ;;
 632   m68k-*-*)
 633     ;;
 634   mips*-*-rtems*)
 635     ;;
 636   mips*-*-linux*)
 637     ;;
 638   powerpc*-*-linux*)
 639     ;;
 640   powerpc-*-darwin*)
 641     ;;
 642   powerpc-*-aix* | rs6000-*-aix*)
 643     ;;
 644   powerpc-*-freebsd*)
 645     ;;
 646   powerpc64-*-freebsd*)
 647     ;;
 648   powerpc*-*-rtems*)
 649     ;;
 650   s390-*-* | s390x-*-*)
 651     ;;
 652   sh-*-* | sh[[34]]*-*-*)
 653     ;;
 654   sh64-*-* | sh5*-*-*)
 655     ;;
 656   sparc*-*-*)
 657     ;;
 658   x86_64-*-*)
 659     ;;
 660   *-*-*)
 661     unsupported_languages="$unsupported_languages java"
 662     ;;
 663 esac
 664
 665 # Disable Java, libgcj or related libraries for some systems.
 666 case "${target}" in
 667   powerpc-*-darwin*)
 668     ;;
 669   i[[3456789]]86-*-darwin*)
 670     ;;
 671   x86_64-*-darwin[[912]]*)
 672     ;;
 673   *-*-darwin*)
 674     noconfigdirs="$noconfigdirs ${libgcj}"
 675     ;;
 676   *-*-netware*)
 677     noconfigdirs="$noconfigdirs ${libgcj}"
 678     ;;
 679   *-*-rtems*)
 680     noconfigdirs="$noconfigdirs ${libgcj}"
 681     ;;
 682   *-*-tpf*)
 683     noconfigdirs="$noconfigdirs ${libgcj}"
 684     ;;
 685   *-*-uclinux*)
 686     noconfigdirs="$noconfigdirs ${libgcj}"
 687     ;;
 688   *-*-vxworks*)
 689     noconfigdirs="$noconfigdirs ${libgcj}"
 690     ;;
 691   alpha*-*-*vms*)
 692     noconfigdirs="$noconfigdirs ${libgcj}"
 693     ;;
 694   arm-wince-pe)
 695     noconfigdirs="$noconfigdirs ${libgcj}"
 696     ;;
 697   arm*-*-symbianelf*)
 698     noconfigdirs="$noconfigdirs ${libgcj}"
 699     ;;
 700   bfin-*-*)
 701     noconfigdirs="$noconfigdirs target-boehm-gc"
 702     ;;
 703   cris-*-* | crisv32-*-*)
 704     unsupported_languages="$unsupported_languages java"
 705     case "${target}" in
 706       *-*-linux*)
 707         ;;
 708       *) # See PR46792 regarding target-libffi.
 709         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 710     esac
 711     ;;
 712   hppa*64*-*-linux*)
 713     # In this case, it's because the hppa64-linux target is for
 714     # the kernel only at this point and has no libc, and thus no
 715     # headers, crt*.o, etc., all of which are needed by these.
 716     unsupported_languages="$unsupported_languages java"
 717     ;;
 718   hppa*64*-*-hpux*)
 719     noconfigdirs="$noconfigdirs ${libgcj}"
 720     ;;
 721   hppa*-hp-hpux11*)
 722     ;;
 723   hppa*-*-hpux*)
 724     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 725     # build on HP-UX 10.20.
 726     noconfigdirs="$noconfigdirs ${libgcj}"
 727     ;;
 728   ia64*-*-*vms*)
 729     noconfigdirs="$noconfigdirs ${libgcj}"
 730     ;;
 731   i[[3456789]]86-w64-mingw*)
 732     noconfigdirs="$noconfigdirs ${libgcj}"
 733     ;;
 734   i[[3456789]]86-*-mingw*)
 735     noconfigdirs="$noconfigdirs ${libgcj}"
 736     ;;
 737   x86_64-*-mingw*)
 738     noconfigdirs="$noconfigdirs ${libgcj}"
 739     ;;
 740   mmix-*-*)
 741     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 742     ;;
 743   powerpc-*-aix*)
 744     # copied from rs6000-*-* entry
 745     noconfigdirs="$noconfigdirs ${libgcj}"
 746     ;;
 747   rs6000-*-aix*)
 748     noconfigdirs="$noconfigdirs ${libgcj}"
 749     ;;
 750   *-*-lynxos*)
 751     noconfigdirs="$noconfigdirs ${libgcj}"
 752     ;;
 753 esac
 754
 755 # Disable libgo for some systems where it is known to not work.
 756 # For testing, you can easily override this with --enable-libgo.
 757 if test x$enable_libgo = x; then
 758     case "${target}" in
 759     *-*-darwin*)
 760         # PR 46986
 761         noconfigdirs="$noconfigdirs target-libgo"
 762         ;;
 763     *-*-cygwin* | *-*-mingw*)
 764         noconfigdirs="$noconfigdirs target-libgo"
 765         ;;
 766     *-*-aix*)
 767         noconfigdirs="$noconfigdirs target-libgo"
 768         ;;
 769     esac
 770 fi
 771
 772 # Default libgloss CPU subdirectory.
 773 libgloss_dir="$target_cpu"
 774
 775 case "${target}" in
 776   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 777     libgloss_dir=wince
 778     ;;
 779   aarch64*-*-* )
 780     libgloss_dir=aarch64
 781     ;;
 782   arm*-*-*)
 783     libgloss_dir=arm
 784     ;;
 785   cris-*-* | crisv32-*-*)
 786     libgloss_dir=cris
 787     ;;
 788   hppa*-*-*)
 789     libgloss_dir=pa
 790     ;;
 791   i[[3456789]]86-*-*)
 792     libgloss_dir=i386
 793     ;;
 794   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 795     libgloss_dir=m68hc11
 796     ;;
 797   m68*-*-* | fido-*-*)
 798     libgloss_dir=m68k
 799     ;;
 800   mips*-*-*)
 801     libgloss_dir=mips
 802     ;;
 803   powerpc*-*-*)
 804     libgloss_dir=rs6000
 805     ;;
 806   sparc*-*-*)
 807     libgloss_dir=sparc
 808     ;;
 809 esac
 810
 811 # Disable newlib and libgloss for various target OSes.
 812 case "${target}" in
 813   alpha*-dec-osf*)
 814     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 815     ;;
 816   i[[3456789]]86-*-linux*)
 817     # This section makes it possible to build newlib natively on linux.
 818     # If we are using a cross compiler then don't configure newlib.
 819     if test x${is_cross_compiler} != xno ; then
 820       noconfigdirs="$noconfigdirs target-newlib"
 821     fi
 822     noconfigdirs="$noconfigdirs target-libgloss"
 823     # If we are not using a cross compiler, do configure newlib.
 824     # Note however, that newlib will only be configured in this situation
 825     # if the --with-newlib option has been given, because otherwise
 826     # 'target-newlib' will appear in skipdirs.
 827     ;;
 828   i[[3456789]]86-*-rdos*)
 829     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 830     ;;
 831   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 832     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 833     ;;
 834   sparc-*-sunos4*)
 835     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 836     ;;
 837   *-*-aix*)
 838     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 839     ;;
 840   *-*-beos*)
 841     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 842     ;;
 843   *-*-chorusos)
 844     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 845     ;;
 846   *-*-dragonfly*)
 847     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 848     ;;
 849   *-*-freebsd*)
 850     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 851     ;;
 852   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 853     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 854     ;;
 855   *-*-lynxos*)
 856     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 857     ;;
 858   *-*-mingw*)
 859     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 860     ;;
 861   *-*-netbsd*)
 862     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 863     ;;
 864   *-*-netware*)
 865     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 866     ;;
 867   *-*-tpf*)
 868     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 869     ;;
 870   *-*-uclinux*)
 871     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 872     ;;
 873   *-*-vxworks*)
 874     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 875     ;;
 876 esac
 877
 878 case "${target}" in
 879   *-*-chorusos)
 880     ;;
 881   powerpc-*-darwin*)
 882     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 883     noconfigdirs="$noconfigdirs sim target-rda"
 884     ;;
 885   i[[3456789]]86-*-darwin*)
 886     noconfigdirs="$noconfigdirs ld gprof"
 887     noconfigdirs="$noconfigdirs sim target-rda"
 888     ;;
 889   x86_64-*-darwin[[912]]*)
 890     noconfigdirs="$noconfigdirs ld gas gprof"
 891     noconfigdirs="$noconfigdirs sim target-rda"
 892     ;;
 893   *-*-darwin*)
 894     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 895     noconfigdirs="$noconfigdirs sim target-rda"
 896     ;;
 897   *-*-dragonfly*)
 898     ;;
 899   *-*-freebsd*)
 900     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 901         && test -f /usr/local/include/gmp.h; then
 902       with_gmp=/usr/local
 903     fi
 904     ;;
 905   *-*-kaos*)
 906     # Remove unsupported stuff on all kaOS configurations.
 907     noconfigdirs="$noconfigdirs target-libgloss"
 908     ;;
 909   *-*-netbsd*)
 910     ;;
 911   *-*-netware*)
 912     ;;
 913   *-*-rtems*)
 914     noconfigdirs="$noconfigdirs target-libgloss"
 915     ;;
 916     # The tpf target doesn't support gdb yet.
 917   *-*-tpf*)
 918     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 919     ;;
 920   *-*-uclinux*)
 921     noconfigdirs="$noconfigdirs target-rda"
 922     ;;
 923   *-*-vxworks*)
 924     ;;
 925   alpha*-dec-osf*)
 926     # ld works, but does not support shared libraries.
 927     # gas doesn't generate exception information.
 928     noconfigdirs="$noconfigdirs gas ld"
 929     ;;
 930   alpha*-*-*vms*)
 931     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 932     ;;
 933   alpha*-*-*)
 934     # newlib is not 64 bit ready
 935     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 936     ;;
 937   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 938     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 939     ;;
 940   arc-*-*)
 941     noconfigdirs="$noconfigdirs target-libgloss"
 942     ;;
 943   arm-*-pe*)
 944     noconfigdirs="$noconfigdirs target-libgloss"
 945     ;;
 946   arm-*-riscix*)
 947     noconfigdirs="$noconfigdirs ld target-libgloss"
 948     ;;
 949   avr-*-rtems*)
 950     ;;
 951   avr-*-*)
 952     if test x${with_avrlibc} != xno; then
 953       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 954     fi
 955     ;;
 956   c4x-*-* | tic4x-*-*)
 957     noconfigdirs="$noconfigdirs target-libgloss"
 958     ;;
 959   tic54x-*-*)
 960     noconfigdirs="$noconfigdirs target-libgloss gdb"
 961     ;;
 962   d10v-*-*)
 963     noconfigdirs="$noconfigdirs target-libgloss"
 964     ;;
 965   d30v-*-*)
 966     noconfigdirs="$noconfigdirs gdb"
 967     ;;
 968   fr30-*-elf*)
 969     noconfigdirs="$noconfigdirs gdb"
 970     ;;
 971   moxie-*-*)
 972     noconfigdirs="$noconfigdirs gprof"
 973     ;;
 974   h8300*-*-*)
 975     noconfigdirs="$noconfigdirs target-libgloss"
 976     ;;
 977   h8500-*-*)
 978     noconfigdirs="$noconfigdirs target-libgloss"
 979     ;;
 980   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 981     ;;
 982   hppa*64*-*-linux*)
 983     ;;
 984   hppa*-*-linux*)
 985     ;;
 986   hppa*-*-*elf* | \
 987   hppa*-*-lites* | \
 988   hppa*-*-openbsd* | \
 989   hppa*64*-*-*)
 990     ;;
 991   hppa*-hp-hpux11*)
 992     noconfigdirs="$noconfigdirs ld"
 993     ;;
 994   hppa*-*-pro*)
 995     ;;
 996   hppa*-*-*)
 997     noconfigdirs="$noconfigdirs ld"
 998     ;;
 999   i960-*-*)
1000     noconfigdirs="$noconfigdirs gdb"
1001     ;;
1002   ia64*-*-elf*)
1003     # No gdb support yet.
1004     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1005     ;;
1006   ia64*-**-hpux*)
1007     # No ld support yet.
1008     noconfigdirs="$noconfigdirs libgui itcl ld"
1009     ;;
1010   ia64*-*-*vms*)
1011     # No ld support yet.
1012     noconfigdirs="$noconfigdirs libgui itcl ld"
1013     ;;
1014   i[[3456789]]86-w64-mingw*)
1015     ;;
1016   i[[3456789]]86-*-mingw*)
1017     target_configdirs="$target_configdirs target-winsup"
1018     ;;
1019   *-*-cygwin*)
1020     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1021     noconfigdirs="$noconfigdirs target-libgloss"
1022     # always build newlib if winsup directory is present.
1023     if test -d "$srcdir/winsup/cygwin"; then
1024       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1025     elif test -d "$srcdir/newlib"; then
1026       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1027     fi
1028     ;;
1029   i[[3456789]]86-*-pe)
1030     noconfigdirs="$noconfigdirs target-libgloss"
1031     ;;
1032   i[[3456789]]86-*-sco3.2v5*)
1033     # The linker does not yet know about weak symbols in COFF,
1034     # and is not configured to handle mixed ELF and COFF.
1035     noconfigdirs="$noconfigdirs ld target-libgloss"
1036     ;;
1037   i[[3456789]]86-*-sco*)
1038     noconfigdirs="$noconfigdirs gprof target-libgloss"
1039     ;;
1040   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1041     noconfigdirs="$noconfigdirs target-libgloss"
1042     ;;
1043   i[[3456789]]86-*-sysv4*)
1044     noconfigdirs="$noconfigdirs target-libgloss"
1045     ;;
1046   i[[3456789]]86-*-beos*)
1047     noconfigdirs="$noconfigdirs gdb"
1048     ;;
1049   i[[3456789]]86-*-rdos*)
1050     noconfigdirs="$noconfigdirs gdb"
1051     ;;
1052   mmix-*-*)
1053     noconfigdirs="$noconfigdirs gdb"
1054     ;;
1055   mt-*-*)
1056     noconfigdirs="$noconfigdirs sim"
1057     ;;
1058   powerpc-*-aix*)
1059     # copied from rs6000-*-* entry
1060     noconfigdirs="$noconfigdirs gprof"
1061     ;;
1062   powerpc*-*-winnt* | powerpc*-*-pe*)
1063     target_configdirs="$target_configdirs target-winsup"
1064     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1065     # always build newlib.
1066     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1067     ;;
1068     # This is temporary until we can link against shared libraries
1069   powerpcle-*-solaris*)
1070     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1071     ;;
1072   powerpc-*-beos*)
1073     noconfigdirs="$noconfigdirs gdb"
1074     ;;
1075   rs6000-*-lynxos*)
1076     noconfigdirs="$noconfigdirs gprof"
1077     ;;
1078   rs6000-*-aix*)
1079     noconfigdirs="$noconfigdirs gprof"
1080     ;;
1081   rs6000-*-*)
1082     noconfigdirs="$noconfigdirs gprof"
1083     ;;
1084   m68k-apollo-*)
1085     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1086     ;;
1087   microblaze*)
1088     noconfigdirs="$noconfigdirs gprof"
1089     ;;
1090   mips*-sde-elf* | mips*-mti-elf*)
1091     if test x$with_newlib = xyes; then
1092       noconfigdirs="$noconfigdirs gprof"
1093     fi
1094     ;;
1095   mips*-*-irix5*)
1096     noconfigdirs="$noconfigdirs gprof target-libgloss"
1097     ;;
1098   mips*-*-irix6*)
1099     noconfigdirs="$noconfigdirs gprof target-libgloss"
1100     ;;
1101   mips*-*-bsd*)
1102     noconfigdirs="$noconfigdirs gprof target-libgloss"
1103     ;;
1104   mips*-*-linux*)
1105     ;;
1106   mips*-*-*)
1107     noconfigdirs="$noconfigdirs gprof"
1108     ;;
1109   sh-*-* | sh64-*-*)
1110     case "${target}" in
1111       sh*-*-elf)
1112          ;;
1113       *)
1114          noconfigdirs="$noconfigdirs target-libgloss" ;;
1115     esac
1116     ;;
1117   sparc-*-sunos4*)
1118     if test x${is_cross_compiler} = xno ; then
1119            use_gnu_ld=no
1120     fi
1121     ;;
1122   tic6x-*-*)
1123     noconfigdirs="$noconfigdirs sim"
1124     ;;
1125   tilepro-*-* | tilegx-*-*)
1126     noconfigdirs="$noconfigdirs sim"
1127     ;;
1128   v810-*-*)
1129     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1130     ;;
1131   vax-*-*)
1132     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1133     ;;
1134 esac
1135
1136 # If we aren't building newlib, then don't build libgloss, since libgloss
1137 # depends upon some newlib header files.
1138 case "${noconfigdirs}" in
1139   *target-libgloss*) ;;
1140   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1141 esac
1142
1143 # Work in distributions that contain no compiler tools, like Autoconf.
1144 host_makefile_frag=/dev/null
1145 if test -d ${srcdir}/config ; then
1146 case "${host}" in
1147   i[[3456789]]86-*-msdosdjgpp*)
1148     host_makefile_frag="config/mh-djgpp"
1149     ;;
1150   *-cygwin*)
1151     ACX_CHECK_CYGWIN_CAT_WORKS
1152     host_makefile_frag="config/mh-cygwin"
1153     ;;
1154   *-mingw*)
1155     host_makefile_frag="config/mh-mingw"
1156     ;;
1157   hppa*-hp-hpux10*)
1158     host_makefile_frag="config/mh-pa-hpux10"
1159     ;;
1160   hppa*-hp-hpux*)
1161     host_makefile_frag="config/mh-pa"
1162     ;;
1163   hppa*-*)
1164     host_makefile_frag="config/mh-pa"
1165     ;;
1166   *-*-darwin*)
1167     host_makefile_frag="config/mh-darwin"
1168     ;;
1169   powerpc-*-aix*)
1170     host_makefile_frag="config/mh-ppc-aix"
1171     ;;
1172   rs6000-*-aix*)
1173     host_makefile_frag="config/mh-ppc-aix"
1174     ;;
1175 esac
1176 fi
1177
1178 if test "${build}" != "${host}" ; then
1179   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1180   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1181   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1182   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1183   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1184   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1185   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1186   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1187   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1188   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1189   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1190   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1191   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1192 else
1193   AR_FOR_BUILD="\$(AR)"
1194   AS_FOR_BUILD="\$(AS)"
1195   CC_FOR_BUILD="\$(CC)"
1196   CXX_FOR_BUILD="\$(CXX)"
1197   GCJ_FOR_BUILD="\$(GCJ)"
1198   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1199   GOC_FOR_BUILD="\$(GOC)"
1200   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1201   LD_FOR_BUILD="\$(LD)"
1202   NM_FOR_BUILD="\$(NM)"
1203   RANLIB_FOR_BUILD="\$(RANLIB)"
1204   WINDRES_FOR_BUILD="\$(WINDRES)"
1205   WINDMC_FOR_BUILD="\$(WINDMC)"
1206 fi
1207
1208 AC_PROG_CC
1209 AC_PROG_CXX
1210
1211 # We must set the default linker to the linker used by gcc for the correct
1212 # operation of libtool.  If LD is not defined and we are using gcc, try to
1213 # set the LD default to the ld used by gcc.
1214 if test -z "$LD"; then
1215   if test "$GCC" = yes; then
1216     case $build in
1217     *-*-mingw*)
1218       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1219     *)
1220       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1221     esac
1222     case $gcc_prog_ld in
1223     # Accept absolute paths.
1224     [[\\/]* | [A-Za-z]:[\\/]*)]
1225       LD="$gcc_prog_ld" ;;
1226     esac
1227   fi
1228 fi
1229
1230 # Check whether -static-libstdc++ -static-libgcc is supported.
1231 have_static_libs=no
1232 if test "$GCC" = yes; then
1233   saved_LDFLAGS="$LDFLAGS"
1234
1235   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1236   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1237   AC_LANG_PUSH(C++)
1238   AC_LINK_IFELSE([
1239 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1240 #error -static-libstdc++ not implemented
1241 #endif
1242 int main() {}],
1243     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1244     [AC_MSG_RESULT([no])])
1245   AC_LANG_POP(C++)
1246
1247   LDFLAGS="$saved_LDFLAGS"
1248 fi
1249
1250 ACX_PROG_GNAT
1251 ACX_PROG_CMP_IGNORE_INITIAL
1252
1253 AC_ARG_ENABLE([bootstrap],
1254 [AS_HELP_STRING([--enable-bootstrap],
1255                 [enable bootstrapping @<:@yes if native build@:>@])],,
1256 enable_bootstrap=default)
1257
1258 # Issue errors and warnings for invalid/strange bootstrap combinations.
1259 if test -r $srcdir/gcc/configure; then
1260   have_compiler=yes
1261 else
1262   have_compiler=no
1263 fi
1264
1265 case "$have_compiler:$host:$target:$enable_bootstrap" in
1266   *:*:*:no) ;;
1267
1268   # Default behavior.  Enable bootstrap if we have a compiler
1269   # and we are in a native configuration.
1270   yes:$build:$build:default)
1271     enable_bootstrap=yes ;;
1272
1273   *:*:*:default)
1274     enable_bootstrap=no ;;
1275
1276   # We have a compiler and we are in a native configuration, bootstrap is ok
1277   yes:$build:$build:yes)
1278     ;;
1279
1280   # Other configurations, but we have a compiler.  Assume the user knows
1281   # what he's doing.
1282   yes:*:*:yes)
1283     AC_MSG_WARN([trying to bootstrap a cross compiler])
1284     ;;
1285
1286   # No compiler: if they passed --enable-bootstrap explicitly, fail
1287   no:*:*:yes)
1288     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1289
1290   # Fail if wrong command line
1291   *)
1292     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1293     ;;
1294 esac
1295
1296 # Used for setting $lt_cv_objdir
1297 _LT_CHECK_OBJDIR
1298
1299 # Check for GMP, MPFR and MPC
1300 gmplibs="-lmpc -lmpfr -lgmp"
1301 gmpinc=
1302 have_gmp=no
1303
1304 # Specify a location for mpc
1305 # check for this first so it ends up on the link line before mpfr.
1306 AC_ARG_WITH(mpc,
1307 [AS_HELP_STRING([--with-mpc=PATH],
1308                 [specify prefix directory for installed MPC package.
1309                  Equivalent to --with-mpc-include=PATH/include
1310                  plus --with-mpc-lib=PATH/lib])])
1311 AC_ARG_WITH(mpc-include,
1312 [AS_HELP_STRING([--with-mpc-include=PATH],
1313                 [specify directory for installed MPC include files])])
1314 AC_ARG_WITH(mpc-lib,
1315 [AS_HELP_STRING([--with-mpc-lib=PATH],
1316                 [specify directory for the installed MPC library])])
1317
1318 if test "x$with_mpc" != x; then
1319   gmplibs="-L$with_mpc/lib $gmplibs"
1320   gmpinc="-I$with_mpc/include $gmpinc"
1321 fi
1322 if test "x$with_mpc_include" != x; then
1323   gmpinc="-I$with_mpc_include $gmpinc"
1324 fi
1325 if test "x$with_mpc_lib" != x; then
1326   gmplibs="-L$with_mpc_lib $gmplibs"
1327 fi
1328 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1329   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1330   gmpinc='-I$$s/mpc/src '"$gmpinc"
1331   # Do not test the mpc version.  Assume that it is sufficient, since
1332   # it is in the source tree, and the library has not been built yet
1333   # but it would be included on the link line in the version check below
1334   # hence making the test fail.
1335   have_gmp=yes
1336 fi
1337
1338 # Specify a location for mpfr
1339 # check for this first so it ends up on the link line before gmp.
1340 AC_ARG_WITH(mpfr-dir,
1341 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1342 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1343 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1344
1345 AC_ARG_WITH(mpfr,
1346 [AS_HELP_STRING([--with-mpfr=PATH],
1347                 [specify prefix directory for installed MPFR package.
1348                  Equivalent to --with-mpfr-include=PATH/include
1349                  plus --with-mpfr-lib=PATH/lib])])
1350 AC_ARG_WITH(mpfr-include,
1351 [AS_HELP_STRING([--with-mpfr-include=PATH],
1352                 [specify directory for installed MPFR include files])])
1353 AC_ARG_WITH(mpfr-lib,
1354 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1355                 [specify directory for the installed MPFR library])])
1356
1357 if test "x$with_mpfr" != x; then
1358   gmplibs="-L$with_mpfr/lib $gmplibs"
1359   gmpinc="-I$with_mpfr/include $gmpinc"
1360 fi
1361 if test "x$with_mpfr_include" != x; then
1362   gmpinc="-I$with_mpfr_include $gmpinc"
1363 fi
1364 if test "x$with_mpfr_lib" != x; then
1365   gmplibs="-L$with_mpfr_lib $gmplibs"
1366 fi
1367 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1368   # MPFR v3.1.0 moved the sources into a src sub-directory.
1369   if test -d ${srcdir}/mpfr/src; then
1370     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1371     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1372     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1373   else
1374     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1375     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1376     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1377   fi
1378   # Do not test the mpfr version.  Assume that it is sufficient, since
1379   # it is in the source tree, and the library has not been built yet
1380   # but it would be included on the link line in the version check below
1381   # hence making the test fail.
1382   have_gmp=yes
1383 fi
1384
1385 # Specify a location for gmp
1386 AC_ARG_WITH(gmp-dir,
1387 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1388 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1389 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1390
1391 AC_ARG_WITH(gmp,
1392 [AS_HELP_STRING([--with-gmp=PATH],
1393                 [specify prefix directory for the installed GMP package.
1394                  Equivalent to --with-gmp-include=PATH/include
1395                  plus --with-gmp-lib=PATH/lib])])
1396 AC_ARG_WITH(gmp-include,
1397 [AS_HELP_STRING([--with-gmp-include=PATH],
1398                 [specify directory for installed GMP include files])])
1399 AC_ARG_WITH(gmp-lib,
1400 [AS_HELP_STRING([--with-gmp-lib=PATH],
1401                 [specify directory for the installed GMP library])])
1402
1403
1404 if test "x$with_gmp" != x; then
1405   gmplibs="-L$with_gmp/lib $gmplibs"
1406   gmpinc="-I$with_gmp/include $gmpinc"
1407 fi
1408 if test "x$with_gmp_include" != x; then
1409   gmpinc="-I$with_gmp_include $gmpinc"
1410 fi
1411 if test "x$with_gmp_lib" != x; then
1412   gmplibs="-L$with_gmp_lib $gmplibs"
1413 fi
1414 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1415   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1416   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1417   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1418   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1419   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1420   # Do not test the gmp version.  Assume that it is sufficient, since
1421   # it is in the source tree, and the library has not been built yet
1422   # but it would be included on the link line in the version check below
1423   # hence making the test fail.
1424   have_gmp=yes
1425 fi
1426
1427 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1428   have_gmp=yes
1429   saved_CFLAGS="$CFLAGS"
1430   CFLAGS="$CFLAGS $gmpinc"
1431   # Check for the recommended and required versions of GMP.
1432   AC_MSG_CHECKING([for the correct version of gmp.h])
1433   AC_TRY_COMPILE([#include "gmp.h"],[
1434   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1435   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1436   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1437   choke me
1438   #endif
1439   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1440   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1441   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1442   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1443   choke me
1444   #endif
1445   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1446    [AC_MSG_RESULT([no]); have_gmp=no])
1447
1448   # If we have GMP, check the MPFR version.
1449   if test x"$have_gmp" = xyes; then
1450     # Check for the recommended and required versions of MPFR.
1451     AC_MSG_CHECKING([for the correct version of mpfr.h])
1452     AC_TRY_COMPILE([#include <gmp.h>
1453     #include <mpfr.h>],[
1454     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1455     choke me
1456     #endif
1457     ], [AC_TRY_COMPILE([#include <gmp.h>
1458     #include <mpfr.h>],[
1459     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1460     choke me
1461     #endif
1462     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1463      [AC_MSG_RESULT([no]); have_gmp=no])
1464   fi
1465
1466   # Check for the MPC header version.
1467   if test x"$have_gmp" = xyes ; then
1468     # Check for the recommended and required versions of MPC.
1469     AC_MSG_CHECKING([for the correct version of mpc.h])
1470     AC_TRY_COMPILE([#include <mpc.h>],[
1471     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1472     choke me
1473     #endif
1474     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1475     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1476     choke me
1477     #endif
1478     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1479      [AC_MSG_RESULT([no]); have_gmp=no])
1480   fi
1481
1482   # Now check the MPFR library.
1483   if test x"$have_gmp" = xyes; then
1484     saved_LIBS="$LIBS"
1485     LIBS="$LIBS $gmplibs"
1486     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1487     AC_TRY_LINK([#include <mpc.h>],[
1488     mpfr_t n;
1489     mpfr_t x;
1490     mpc_t c;
1491     int t;
1492     mpfr_init (n);
1493     mpfr_init (x);
1494     mpfr_atan2 (n, n, x, GMP_RNDN);
1495     mpfr_erfc (n, x, GMP_RNDN);
1496     mpfr_subnormalize (x, t, GMP_RNDN);
1497     mpfr_clear(n);
1498     mpfr_clear(x);
1499     mpc_init2 (c, 53);
1500     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1501     mpc_cosh (c, c, MPC_RNDNN);
1502     mpc_pow (c, c, c, MPC_RNDNN);
1503     mpc_acosh (c, c, MPC_RNDNN);
1504     mpc_clear (c);
1505     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1506     LIBS="$saved_LIBS"
1507   fi
1508
1509   CFLAGS="$saved_CFLAGS"
1510
1511 # The library versions listed in the error message below should match
1512 # the HARD-minimums enforced above.
1513   if test x$have_gmp != xyes; then
1514     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1515 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1516 their locations.  Source code for these libraries can be found at
1517 their respective hosting sites as well as at
1518 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1519 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1520 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1521 make sure that you have installed both the libraries and the header
1522 files.  They may be located in separate packages.])
1523   fi
1524 fi
1525
1526 # Flags needed for both GMP, MPFR and/or MPC.
1527 AC_SUBST(gmplibs)
1528 AC_SUBST(gmpinc)
1529 AC_SUBST(extra_mpfr_configure_flags)
1530 AC_SUBST(extra_mpc_gmp_configure_flags)
1531 AC_SUBST(extra_mpc_mpfr_configure_flags)
1532 AC_SUBST(extra_isl_gmp_configure_flags)
1533
1534 # Allow host libstdc++ to be specified for static linking with PPL.
1535 AC_ARG_WITH(host-libstdcxx,
1536 [AS_HELP_STRING([--with-host-libstdcxx=L],
1537                 [use linker arguments L to link with libstdc++
1538                  when linking with PPL])])
1539
1540 case $with_host_libstdcxx in
1541   no|yes)
1542     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1543     ;;
1544 esac
1545
1546 # Libraries to use for stage1 or when not bootstrapping.
1547 AC_ARG_WITH(stage1-libs,
1548 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1549 [if test "$withval" = "no" -o "$withval" = "yes"; then
1550    stage1_libs=
1551  else
1552    stage1_libs=$withval
1553  fi],
1554 [stage1_libs=$with_host_libstdcxx])
1555 AC_SUBST(stage1_libs)
1556
1557 # Linker flags to use for stage1 or when not bootstrapping.
1558 AC_ARG_WITH(stage1-ldflags,
1559 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1560 [if test "$withval" = "no" -o "$withval" = "yes"; then
1561    stage1_ldflags=
1562  else
1563    stage1_ldflags=$withval
1564  fi],
1565 [stage1_ldflags=
1566  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1567  # if supported.  But if the user explicitly specified the libraries to use,
1568  # trust that they are doing what they want.
1569  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1570    stage1_ldflags="-static-libstdc++ -static-libgcc"
1571  fi])
1572 AC_SUBST(stage1_ldflags)
1573
1574 # Libraries to use for stage2 and later builds.  This defaults to the
1575 # argument passed to --with-host-libstdcxx.
1576 AC_ARG_WITH(boot-libs,
1577 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1578 [if test "$withval" = "no" -o "$withval" = "yes"; then
1579    poststage1_libs=
1580  else
1581    poststage1_libs=$withval
1582  fi],
1583 [poststage1_libs=$with_host_libstdcxx])
1584 AC_SUBST(poststage1_libs)
1585
1586 # Linker flags to use for stage2 and later builds.
1587 AC_ARG_WITH(boot-ldflags,
1588 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1589                 [linker flags for stage2 and later])],
1590 [if test "$withval" = "no" -o "$withval" = "yes"; then
1591    poststage1_ldflags=
1592  else
1593    poststage1_ldflags=$withval
1594  fi],
1595 [poststage1_ldflags=
1596  # In stages 2 and 3, default to linking libstdc++ and libgcc
1597  # statically.  But if the user explicitly specified the libraries to
1598  # use, trust that they are doing what they want.
1599  if test "$poststage1_libs" = ""; then
1600    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1601  fi])
1602 AC_SUBST(poststage1_ldflags)
1603
1604 # GCC GRAPHITE dependences, ISL and CLOOG which in turn requires ISL.
1605 # Basic setup is inlined here, actual checks are in config/cloog.m4 and
1606 # config/isl.m4
1607
1608 AC_ARG_WITH(cloog,
1609   [AS_HELP_STRING(
1610     [--with-cloog=PATH],
1611     [Specify prefix directory for the installed CLooG-ISL package.
1612      Equivalent to --with-cloog-include=PATH/include
1613      plus --with-cloog-lib=PATH/lib])])
1614 AC_ARG_WITH(isl,
1615   [AS_HELP_STRING(
1616    [--with-isl=PATH],
1617    [Specify prefix directory for the installed ISL package.
1618     Equivalent to --with-isl-include=PATH/include
1619     plus --with-isl-lib=PATH/lib])])
1620
1621 # Treat either --without-cloog or --without-isl as a request to disable
1622 # GRAPHITE support and skip all following checks.
1623 if test "x$with_isl" != "xno" &&
1624    test "x$with_cloog" != "xno"; then
1625   # Check for ISL
1626   dnl Provide configure switches and initialize islinc & isllibs
1627   dnl with user input.
1628   ISL_INIT_FLAGS
1629   dnl The versions of ISL that work for Graphite
1630   ISL_CHECK_VERSION(0,10)
1631   if test "${gcc_cv_isl}" = no ; then
1632     ISL_CHECK_VERSION(0,11)
1633   fi
1634   dnl Only execute fail-action, if ISL has been requested.
1635   ISL_IF_FAILED([
1636     AC_MSG_ERROR([Unable to find a usable ISL.  See config.log for details.])])
1637
1638   if test "x$gcc_cv_isl" != "xno"; then
1639     # Check for CLOOG
1640     dnl Provide configure switches and initialize clooginc & clooglibs
1641     dnl with user input.
1642     CLOOG_INIT_FLAGS
1643     dnl The versions of CLooG that work for Graphite.
1644     CLOOG_CHECK_VERSION(0,17,0)
1645     if test "${gcc_cv_cloog}" = no ; then
1646       CLOOG_CHECK_VERSION(0,18,0)
1647     fi
1648
1649     dnl Only execute fail-action, if CLooG has been requested.
1650     CLOOG_IF_FAILED([
1651       AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1652   fi
1653 fi
1654
1655 # If either the ISL or the CLooG check failed, disable builds of in-tree
1656 # variants of both
1657 if test "x$with_isl" = xno ||
1658    test "x$with_cloog" = xno ||
1659    test "x$gcc_cv_cloog" = xno ||
1660    test "x$gcc_cv_isl" = xno; then
1661   noconfigdirs="$noconfigdirs cloog isl"
1662   islinc=
1663   clooginc=
1664   clooglibs=
1665 fi
1666
1667 AC_SUBST(islinc)
1668 AC_SUBST(clooglibs)
1669 AC_SUBST(clooginc)
1670
1671
1672 # Check for LTO support.
1673 AC_ARG_ENABLE(lto,
1674 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1675 enable_lto=$enableval,
1676 enable_lto=yes; default_enable_lto=yes)
1677
1678 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1679   build_lto_plugin=yes
1680 ],[if test x"$default_enable_lto" = x"yes" ; then
1681     case $target in
1682       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1683       # On other non-ELF platforms, LTO has yet to be validated.
1684       *) enable_lto=no ;;
1685     esac
1686   else
1687   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1688   # It would also be nice to check the binutils support, but we don't
1689   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1690   # warn during gcc/ subconfigure; unless you're bootstrapping with
1691   # -flto it won't be needed until after installation anyway.
1692     case $target in
1693       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1694       *) if test x"$enable_lto" = x"yes"; then
1695         AC_MSG_ERROR([LTO support is not enabled for this target.])
1696         fi
1697       ;;
1698     esac
1699   fi
1700   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1701   # Build it unless LTO was explicitly disabled.
1702   case $target in
1703     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1704     *) ;;
1705   esac
1706 ])
1707
1708
1709 # By default, C and C++ are the only stage 1 languages.
1710 stage1_languages=,c,
1711
1712 # Target libraries that we bootstrap.
1713 bootstrap_target_libs=,target-libgcc,
1714
1715 # Figure out what language subdirectories are present.
1716 # Look if the user specified --enable-languages="..."; if not, use
1717 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1718 # go away some day.
1719 # NB:  embedded tabs in this IF block -- do not untabify
1720 if test -d ${srcdir}/gcc; then
1721   if test x"${enable_languages+set}" != xset; then
1722     if test x"${LANGUAGES+set}" = xset; then
1723       enable_languages="${LANGUAGES}"
1724         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1725     else
1726       enable_languages=all
1727     fi
1728   else
1729     if test x"${enable_languages}" = x ||
1730        test x"${enable_languages}" = xyes;
1731        then
1732       echo configure.in: --enable-languages needs at least one language argument 1>&2
1733       exit 1
1734     fi
1735   fi
1736   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1737
1738   # 'f95' is the old name for the 'fortran' language. We issue a warning
1739   # and make the substitution.
1740   case ,${enable_languages}, in
1741     *,f95,*)
1742       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1743       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1744       ;;
1745   esac
1746
1747   # If bootstrapping, C++ must be enabled.
1748   case ",$enable_languages,:$enable_bootstrap" in
1749     *,c++,*:*) ;;
1750     *:yes)
1751       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1752         enable_languages="${enable_languages},c++"
1753       else
1754         AC_MSG_ERROR([bootstrapping requires c++ sources])
1755       fi
1756       ;;
1757   esac
1758
1759   # First scan to see if an enabled language requires some other language.
1760   # We assume that a given config-lang.in will list all the language
1761   # front ends it requires, even if some are required indirectly.
1762   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1763     case ${lang_frag} in
1764       ..) ;;
1765       # The odd quoting in the next line works around
1766       # an apparent bug in bash 1.12 on linux.
1767       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1768       *)
1769         # From the config-lang.in, get $language, $lang_requires, and
1770         # $lang_requires_boot_languages.
1771         language=
1772         lang_requires=
1773         lang_requires_boot_languages=
1774         . ${lang_frag}
1775         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1776           case ,${enable_languages}, in
1777             *,$other,*) ;;
1778             *,all,*) ;;
1779             *,$language,*)
1780               echo " \`$other' language required by \`$language'; enabling" 1>&2
1781               enable_languages="${enable_languages},${other}"
1782               ;;
1783           esac
1784         done
1785         for other in ${lang_requires_boot_languages} ; do
1786           if test "$other" != "c"; then
1787             case ,${enable_stage1_languages}, in
1788               *,$other,*) ;;
1789               *,all,*) ;;
1790               *)
1791                 case ,${enable_languages}, in
1792                   *,$language,*)
1793                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1794                     enable_stage1_languages="$enable_stage1_languages,${other}"
1795                     ;;
1796                 esac
1797                 ;;
1798             esac
1799           fi
1800         done
1801         ;;
1802     esac
1803   done
1804
1805   new_enable_languages=,c,
1806
1807   # If LTO is enabled, add the LTO front end.
1808   extra_host_libiberty_configure_flags=
1809   if test "$enable_lto" = "yes" ; then
1810     case ,${enable_languages}, in
1811       *,lto,*) ;;
1812       *) enable_languages="${enable_languages},lto" ;;
1813     esac
1814     if test "${build_lto_plugin}" = "yes" ; then
1815       configdirs="$configdirs lto-plugin"
1816       extra_host_libiberty_configure_flags=--enable-shared
1817     fi
1818   fi
1819   AC_SUBST(extra_host_libiberty_configure_flags)
1820
1821   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1822   potential_languages=,c,
1823
1824   enabled_target_libs=
1825   disabled_target_libs=
1826
1827   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1828     case ${lang_frag} in
1829       ..) ;;
1830       # The odd quoting in the next line works around
1831       # an apparent bug in bash 1.12 on linux.
1832       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1833       *)
1834         # From the config-lang.in, get $language, $target_libs,
1835         # $lang_dirs, $boot_language, and $build_by_default
1836         language=
1837         target_libs=
1838         lang_dirs=
1839         subdir_requires=
1840         boot_language=no
1841         build_by_default=yes
1842         . ${lang_frag}
1843         if test x${language} = x; then
1844           echo "${lang_frag} doesn't set \$language." 1>&2
1845           exit 1
1846         fi
1847
1848         if test "$language" = "c++"; then
1849           boot_language=yes
1850         fi
1851
1852         add_this_lang=no
1853         case ,${enable_languages}, in
1854           *,${language},*)
1855             # Language was explicitly selected; include it
1856             # unless it is C, which is enabled by default.
1857             if test "$language" != "c"; then
1858               add_this_lang=yes
1859             fi
1860             ;;
1861           *,all,*)
1862             # 'all' was selected, select it if it is a default language
1863             if test "$language" != "c"; then
1864               add_this_lang=${build_by_default}
1865             fi
1866             ;;
1867         esac
1868
1869         # Disable languages that need other directories if these aren't available.
1870         for i in $subdir_requires; do
1871           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1872           case ,${enable_languages}, in
1873             *,${language},*)
1874               # Specifically requested language; tell them.
1875               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1876               ;;
1877             *)
1878               # Silently disable.
1879               add_this_lang=unsupported
1880               ;;
1881           esac
1882         done
1883
1884         # Disable Ada if no preexisting GNAT is available.
1885         case ,${enable_languages},:${language}:${have_gnat} in
1886           *,${language},*:ada:no)
1887             # Specifically requested language; tell them.
1888             AC_MSG_ERROR([GNAT is required to build $language])
1889             ;;
1890           *:ada:no)
1891             # Silently disable.
1892             add_this_lang=unsupported
1893             ;;
1894         esac
1895
1896         # Disable a language that is unsupported by the target.
1897         case " $unsupported_languages " in
1898           *" $language "*)
1899             add_this_lang=unsupported
1900             ;;
1901         esac
1902
1903         case $add_this_lang in
1904           unsupported)
1905             # Remove language-dependent dirs.
1906             disabled_target_libs="$disabled_target_libs $target_libs"
1907             noconfigdirs="$noconfigdirs $lang_dirs"
1908             ;;
1909           no)
1910             # Remove language-dependent dirs; still show language as supported.
1911             disabled_target_libs="$disabled_target_libs $target_libs"
1912             noconfigdirs="$noconfigdirs $lang_dirs"
1913             potential_languages="${potential_languages}${language},"
1914             ;;
1915           yes)
1916             new_enable_languages="${new_enable_languages}${language},"
1917             potential_languages="${potential_languages}${language},"
1918             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1919             enabled_target_libs="$enabled_target_libs $target_libs"
1920             case "${boot_language}:,$enable_stage1_languages," in
1921               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1922                 # Add to (comma-separated) list of stage 1 languages.
1923                 case ",$stage1_languages," in
1924                   *,$language,* | ,yes, | ,all,) ;;
1925                   *) stage1_languages="${stage1_languages}${language}," ;;
1926                 esac
1927                 # We need to bootstrap any supporting libraries.
1928                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1929                 ;;
1930             esac
1931             ;;
1932         esac
1933         ;;
1934     esac
1935   done
1936
1937   # Add target libraries which are only needed for disabled languages
1938   # to noconfigdirs.
1939   if test -n "$disabled_target_libs"; then
1940     for dir in $disabled_target_libs; do
1941       case " $enabled_target_libs " in
1942       *" ${dir} "*) ;;
1943       *) noconfigdirs="$noconfigdirs $dir" ;;
1944       esac
1945     done
1946   fi
1947
1948   AC_ARG_ENABLE(stage1-languages,
1949   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1950                   [choose additional languages to build during
1951                   stage1.  Mostly useful for compiler development])],
1952   [case ,${enable_stage1_languages}, in
1953     ,no,|,,)
1954       # Set it to something that will have no effect in the loop below
1955       enable_stage1_languages=c ;;
1956     ,yes,)
1957       enable_stage1_languages=`echo $new_enable_languages | \
1958         sed -e "s/^,//" -e "s/,$//" ` ;;
1959     *,all,*)
1960       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1961         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1962   esac
1963
1964   # Add "good" languages from enable_stage1_languages to stage1_languages,
1965   # while "bad" languages go in missing_languages.  Leave no duplicates.
1966   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1967     case $potential_languages in
1968       *,$i,*)
1969         case $stage1_languages in
1970           *,$i,*) ;;
1971           *) stage1_languages="$stage1_languages$i," ;;
1972         esac ;;
1973       *)
1974         case $missing_languages in
1975           *,$i,*) ;;
1976           *) missing_languages="$missing_languages$i," ;;
1977         esac ;;
1978      esac
1979   done])
1980
1981   # Remove leading/trailing commas that were added for simplicity
1982   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1983   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1984   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1985   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1986
1987   if test "x$missing_languages" != x; then
1988     AC_MSG_ERROR([
1989 The following requested languages could not be built: ${missing_languages}
1990 Supported languages are: ${potential_languages}])
1991   fi
1992   if test "x$new_enable_languages" != "x$enable_languages"; then
1993     echo The following languages will be built: ${new_enable_languages}
1994     enable_languages="$new_enable_languages"
1995   fi
1996
1997   AC_SUBST(stage1_languages)
1998   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1999 fi
2000
2001 # Handle --disable-<component> generically.
2002 for dir in $configdirs $build_configdirs $target_configdirs ; do
2003   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2004   varname=`echo $dirname | sed -e s/+/_/g`
2005   if eval test x\${enable_${varname}} "=" xno ; then
2006     noconfigdirs="$noconfigdirs $dir"
2007   fi
2008 done
2009
2010 # Check for Boehm's garbage collector
2011 AC_ARG_ENABLE(objc-gc,
2012 [AS_HELP_STRING([--enable-objc-gc],
2013                 [enable use of Boehm's garbage collector with the
2014                  GNU Objective-C runtime])],
2015 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
2016   *,objc,*:*:yes:*target-boehm-gc*)
2017     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
2018     ;;
2019 esac])
2020
2021 # Make sure we only build Boehm's garbage collector if required.
2022 case ,${enable_languages},:${enable_objc_gc} in
2023   *,objc,*:yes)
2024     # Keep target-boehm-gc if requested for Objective-C.
2025     ;;
2026   *)
2027     # Otherwise remove target-boehm-gc depending on target-libjava.
2028     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
2029       noconfigdirs="$noconfigdirs target-boehm-gc"
2030     fi
2031     ;;
2032 esac
2033
2034 # Disable libitm and libsanitizer if we're not building C++
2035 case ,${enable_languages}, in
2036   *,c++,*) ;;
2037   *)
2038     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2039     ;;
2040 esac
2041
2042 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2043 # $build_configdirs and $target_configdirs.
2044 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2045
2046 notsupp=""
2047 for dir in . $skipdirs $noconfigdirs ; do
2048   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2049   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2050     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2051     if test -r $srcdir/$dirname/configure ; then
2052       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2053         true
2054       else
2055         notsupp="$notsupp $dir"
2056       fi
2057     fi
2058   fi
2059   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2060     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2061     if test -r $srcdir/$dirname/configure ; then
2062       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2063         true
2064       else
2065         notsupp="$notsupp $dir"
2066       fi
2067     fi
2068   fi
2069   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2070     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2071     if test -r $srcdir/$dirname/configure ; then
2072       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2073         true
2074       else
2075         notsupp="$notsupp $dir"
2076       fi
2077     fi
2078   fi
2079 done
2080
2081 # Quietly strip out all directories which aren't configurable in this tree.
2082 # This relies on all configurable subdirectories being autoconfiscated, which
2083 # is now the case.
2084 build_configdirs_all="$build_configdirs"
2085 build_configdirs=
2086 for i in ${build_configdirs_all} ; do
2087   j=`echo $i | sed -e s/build-//g`
2088   if test -f ${srcdir}/$j/configure ; then
2089     build_configdirs="${build_configdirs} $i"
2090   fi
2091 done
2092
2093 configdirs_all="$configdirs"
2094 configdirs=
2095 for i in ${configdirs_all} ; do
2096   if test -f ${srcdir}/$i/configure ; then
2097     configdirs="${configdirs} $i"
2098   fi
2099 done
2100
2101 target_configdirs_all="$target_configdirs"
2102 target_configdirs=
2103 for i in ${target_configdirs_all} ; do
2104   j=`echo $i | sed -e s/target-//g`
2105   if test -f ${srcdir}/$j/configure ; then
2106     target_configdirs="${target_configdirs} $i"
2107   fi
2108 done
2109
2110 # Produce a warning message for the subdirs we can't configure.
2111 # This isn't especially interesting in the Cygnus tree, but in the individual
2112 # FSF releases, it's important to let people know when their machine isn't
2113 # supported by the one or two programs in a package.
2114
2115 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2116   # If $appdirs is non-empty, at least one of those directories must still
2117   # be configured, or we error out.  (E.g., if the gas release supports a
2118   # specified target in some subdirs but not the gas subdir, we shouldn't
2119   # pretend that all is well.)
2120   if test -n "$appdirs" ; then
2121     for dir in $appdirs ; do
2122       if test -r $dir/Makefile.in ; then
2123         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2124           appdirs=""
2125           break
2126         fi
2127         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2128           appdirs=""
2129           break
2130         fi
2131       fi
2132     done
2133     if test -n "$appdirs" ; then
2134       echo "*** This configuration is not supported by this package." 1>&2
2135       exit 1
2136     fi
2137   fi
2138   # Okay, some application will build, or we don't care to check.  Still
2139   # notify of subdirs not getting built.
2140   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2141   echo "    ${notsupp}" 1>&2
2142   echo "    (Any other directories should still work fine.)" 1>&2
2143 fi
2144
2145 case "$host" in
2146   *msdosdjgpp*)
2147     enable_gdbtk=no ;;
2148 esac
2149
2150 # To find our prefix, in gcc_cv_tool_prefix.
2151 ACX_TOOL_DIRS
2152
2153 copy_dirs=
2154
2155 AC_ARG_WITH([build-sysroot],
2156   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2157                   [use sysroot as the system root during the build])],
2158   [if test x"$withval" != x ; then
2159      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2160    fi],
2161   [SYSROOT_CFLAGS_FOR_TARGET=])
2162 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2163
2164 AC_ARG_WITH([debug-prefix-map],
2165   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2166                   [map A to B, C to D ... in debug information])],
2167   [if test x"$withval" != x; then
2168      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2169      for debug_map in $withval; do
2170        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2171      done
2172    fi],
2173   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2174 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2175
2176 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2177 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2178 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2179 # We want to ensure that TARGET libraries (which we know are built with
2180 # gcc) are built with "-O2 -g", so include those options when setting
2181 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2182 if test "x$CFLAGS_FOR_TARGET" = x; then
2183   CFLAGS_FOR_TARGET=$CFLAGS
2184   case " $CFLAGS " in
2185     *" -O2 "*) ;;
2186     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2187   esac
2188   case " $CFLAGS " in
2189     *" -g "* | *" -g3 "*) ;;
2190     *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2191   esac
2192 fi
2193 AC_SUBST(CFLAGS_FOR_TARGET)
2194
2195 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2196   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2197   case " $CXXFLAGS " in
2198     *" -O2 "*) ;;
2199     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2200   esac
2201   case " $CXXFLAGS " in
2202     *" -g "* | *" -g3 "*) ;;
2203     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2204   esac
2205 fi
2206 AC_SUBST(CXXFLAGS_FOR_TARGET)
2207
2208 AC_SUBST(LDFLAGS_FOR_TARGET)
2209
2210 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2211 # the named directory are copied to $(tooldir)/sys-include.
2212 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2213   if test x${is_cross_compiler} = xno ; then
2214     echo 1>&2 '***' --with-headers is only supported when cross compiling
2215     exit 1
2216   fi
2217   if test x"${with_headers}" != xyes ; then
2218     x=${gcc_cv_tool_prefix}
2219     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2220   fi
2221 fi
2222
2223 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2224 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2225 # are permitted.
2226 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2227   if test x${is_cross_compiler} = xno ; then
2228     echo 1>&2 '***' --with-libs is only supported when cross compiling
2229     exit 1
2230   fi
2231   if test x"${with_libs}" != xyes ; then
2232     # Copy the libraries in reverse order, so that files in the first named
2233     # library override files in subsequent libraries.
2234     x=${gcc_cv_tool_prefix}
2235     for l in ${with_libs}; do
2236       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2237     done
2238   fi
2239 fi
2240
2241 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2242 #
2243 # This is done by determining whether or not the appropriate directory
2244 # is available, and by checking whether or not specific configurations
2245 # have requested that this magic not happen.
2246 #
2247 # The command line options always override the explicit settings in
2248 # configure.in, and the settings in configure.in override this magic.
2249 #
2250 # If the default for a toolchain is to use GNU as and ld, and you don't
2251 # want to do that, then you should use the --without-gnu-as and
2252 # --without-gnu-ld options for the configure script.  Similarly, if
2253 # the default is to use the included zlib and you don't want to do that,
2254 # you should use the --with-system-zlib option for the configure script.
2255
2256 if test x${use_gnu_as} = x &&
2257    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2258   with_gnu_as=yes
2259   extra_host_args="$extra_host_args --with-gnu-as"
2260 fi
2261
2262 if test x${use_gnu_ld} = x &&
2263    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2264   with_gnu_ld=yes
2265   extra_host_args="$extra_host_args --with-gnu-ld"
2266 fi
2267
2268 if test x${use_included_zlib} = x &&
2269    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2270   :
2271 else
2272   with_system_zlib=yes
2273   extra_host_args="$extra_host_args --with-system-zlib"
2274 fi
2275
2276 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2277 # can detect this case.
2278
2279 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2280   with_newlib=yes
2281   extra_host_args="$extra_host_args --with-newlib"
2282 fi
2283
2284 # Handle ${copy_dirs}
2285 set fnord ${copy_dirs}
2286 shift
2287 while test $# != 0 ; do
2288   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2289     :
2290   else
2291     echo Copying $1 to $2
2292
2293     # Use the install script to create the directory and all required
2294     # parent directories.
2295     if test -d $2 ; then
2296       :
2297     else
2298       echo >config.temp
2299       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2300     fi
2301
2302     # Copy the directory, assuming we have tar.
2303     # FIXME: Should we use B in the second tar?  Not all systems support it.
2304     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2305
2306     # It is the responsibility of the user to correctly adjust all
2307     # symlinks.  If somebody can figure out how to handle them correctly
2308     # here, feel free to add the code.
2309
2310     echo $1 > $2/COPIED
2311   fi
2312   shift; shift
2313 done
2314
2315 # Determine a target-dependent exec_prefix that the installed
2316 # gcc will search in.  Keep this list sorted by triplet, with
2317 # the *-*-osname triplets last.
2318 md_exec_prefix=
2319 case "${target}" in
2320   i[[34567]]86-pc-msdosdjgpp*)
2321     md_exec_prefix=/dev/env/DJDIR/bin
2322     ;;
2323   *-*-hpux* | \
2324   *-*-nto-qnx* | \
2325   *-*-solaris2*)
2326     md_exec_prefix=/usr/ccs/bin
2327     ;;
2328 esac
2329
2330 extra_arflags_for_target=
2331 extra_nmflags_for_target=
2332 extra_ranlibflags_for_target=
2333 target_makefile_frag=/dev/null
2334 case "${target}" in
2335   spu-*-*)
2336     target_makefile_frag="config/mt-spu"
2337     ;;
2338   mips*-sde-elf* | mips*-mti-elf*)
2339     target_makefile_frag="config/mt-sde"
2340     ;;
2341   mipsisa*-*-elfoabi*)
2342     target_makefile_frag="config/mt-mips-elfoabi"
2343     ;;
2344   mips*-*-*linux* | mips*-*-gnu*)
2345     target_makefile_frag="config/mt-mips-gnu"
2346     ;;
2347   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2348     target_makefile_frag="config/mt-gnu"
2349     ;;
2350   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2351     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2352     # commands to handle both 32-bit and 64-bit objects.  These flags are
2353     # harmless if we're using GNU nm or ar.
2354     extra_arflags_for_target=" -X32_64"
2355     extra_nmflags_for_target=" -B -X32_64"
2356     ;;
2357 esac
2358
2359 alphaieee_frag=/dev/null
2360 case $target in
2361   alpha*-*-*)
2362     # This just makes sure to use the -mieee option to build target libs.
2363     # This should probably be set individually by each library.
2364     alphaieee_frag="config/mt-alphaieee"
2365     ;;
2366 esac
2367
2368 # If --enable-target-optspace always use -Os instead of -O2 to build
2369 # the target libraries, similarly if it is not specified, use -Os
2370 # on selected platforms.
2371 ospace_frag=/dev/null
2372 case "${enable_target_optspace}:${target}" in
2373   yes:*)
2374     ospace_frag="config/mt-ospace"
2375     ;;
2376   :d30v-*)
2377     ospace_frag="config/mt-d30v"
2378     ;;
2379   :m32r-* | :d10v-* | :fr30-*)
2380     ospace_frag="config/mt-ospace"
2381     ;;
2382   no:* | :*)
2383     ;;
2384   *)
2385     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2386     ;;
2387 esac
2388
2389 # Some systems (e.g., one of the i386-aix systems the gas testers are
2390 # using) don't handle "\$" correctly, so don't use it here.
2391 tooldir='${exec_prefix}'/${target_noncanonical}
2392 build_tooldir=${tooldir}
2393
2394 # Create a .gdbinit file which runs the one in srcdir
2395 # and tells GDB to look there for source files.
2396
2397 if test -r ${srcdir}/.gdbinit ; then
2398   case ${srcdir} in
2399     .) ;;
2400     *) cat > ./.gdbinit <<EOF
2401 # ${NO_EDIT}
2402 dir ${srcdir}
2403 dir .
2404 source ${srcdir}/.gdbinit
2405 EOF
2406     ;;
2407   esac
2408 fi
2409
2410 # Make sure that the compiler is able to generate an executable.  If it
2411 # can't, we are probably in trouble.  We don't care whether we can run the
2412 # executable--we might be using a cross compiler--we only care whether it
2413 # can be created.  At this point the main configure script has set CC.
2414 we_are_ok=no
2415 echo "int main () { return 0; }" > conftest.c
2416 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2417 if test $? = 0 ; then
2418   if test -s conftest || test -s conftest.exe ; then
2419     we_are_ok=yes
2420   fi
2421 fi
2422 case $we_are_ok in
2423   no)
2424     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2425     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2426     rm -f conftest*
2427     exit 1
2428     ;;
2429 esac
2430 rm -f conftest*
2431
2432 # Decide which environment variable is used to find dynamic libraries.
2433 case "${host}" in
2434   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2435   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2436   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2437   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2438 esac
2439
2440 # On systems where the dynamic library environment variable is PATH,
2441 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2442 # built executables to PATH.
2443 if test "$RPATH_ENVVAR" = PATH; then
2444   GCC_SHLIB_SUBDIR=/shlib
2445 else
2446   GCC_SHLIB_SUBDIR=
2447 fi
2448
2449 # Record target_configdirs and the configure arguments for target and
2450 # build configuration in Makefile.
2451 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2452 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2453
2454 # If we are building libgomp, bootstrap it.
2455 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2456   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2457 fi
2458
2459 # If we are building libsanitizer, bootstrap it.
2460 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1 ; then
2461   bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2462 fi
2463
2464 # Determine whether gdb needs tk/tcl or not.
2465 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2466 # and in that case we want gdb to be built without tk.  Ugh!
2467 # In fact I believe gdb is the *only* package directly dependent on tk,
2468 # so we should be able to put the 'maybe's in unconditionally and
2469 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2470 # 100% sure that that's safe though.
2471
2472 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2473 case "$enable_gdbtk" in
2474   no)
2475     GDB_TK="" ;;
2476   yes)
2477     GDB_TK="${gdb_tk}" ;;
2478   *)
2479     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2480     # distro.  Eventually someone will fix this and move Insight, nee
2481     # gdbtk to a separate directory.
2482     if test -d ${srcdir}/gdb/gdbtk ; then
2483       GDB_TK="${gdb_tk}"
2484     else
2485       GDB_TK=""
2486     fi
2487     ;;
2488 esac
2489 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2490 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2491
2492 # Strip out unwanted targets.
2493
2494 # While at that, we remove Makefiles if we were started for recursive
2495 # configuration, so that the top-level Makefile reconfigures them,
2496 # like we used to do when configure itself was recursive.
2497
2498 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2499 # but now we're fixing up the Makefile ourselves with the additional
2500 # commands passed to AC_CONFIG_FILES.  Use separate variables
2501 # extrasub-{build,host,target} not because there is any reason to split
2502 # the substitutions up that way, but only to remain below the limit of
2503 # 99 commands in a script, for HP-UX sed.
2504 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2505
2506 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2507   yes:yes:*\ gold\ *:*,c++,*) ;;
2508   yes:yes:*\ gold\ *:*)
2509     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2510     ;;
2511 esac
2512
2513 # Adjust the toplevel makefile according to whether bootstrap was selected.
2514 case $enable_bootstrap in
2515   yes)
2516     bootstrap_suffix=bootstrap
2517     BUILD_CONFIG=bootstrap-debug
2518     ;;
2519   no)
2520     bootstrap_suffix=no-bootstrap
2521     BUILD_CONFIG=
2522     ;;
2523 esac
2524
2525 AC_MSG_CHECKING(for default BUILD_CONFIG)
2526
2527 AC_ARG_WITH([build-config],
2528   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2529                   [use config/NAME.mk build configuration])],
2530   [case $with_build_config in
2531    yes) with_build_config= ;;
2532    no) with_build_config= BUILD_CONFIG= ;;
2533    esac])
2534
2535 if test "x${with_build_config}" != x; then
2536   BUILD_CONFIG=$with_build_config
2537 else
2538   case $BUILD_CONFIG in
2539   bootstrap-debug)
2540     if echo "int f (void) { return 0; }" > conftest.c &&
2541        ${CC} -c conftest.c &&
2542        mv conftest.o conftest.o.g0 &&
2543        ${CC} -c -g conftest.c &&
2544        mv conftest.o conftest.o.g &&
2545        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2546       :
2547     else
2548       BUILD_CONFIG=
2549     fi
2550     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2551     ;;
2552   esac
2553 fi
2554 AC_MSG_RESULT($BUILD_CONFIG)
2555 AC_SUBST(BUILD_CONFIG)
2556
2557 extrasub_build=
2558 for module in ${build_configdirs} ; do
2559   if test -z "${no_recursion}" \
2560      && test -f ${build_subdir}/${module}/Makefile; then
2561     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2562     rm -f ${build_subdir}/${module}/Makefile
2563   fi
2564   extrasub_build="$extrasub_build
2565 /^@if build-$module\$/d
2566 /^@endif build-$module\$/d
2567 /^@if build-$module-$bootstrap_suffix\$/d
2568 /^@endif build-$module-$bootstrap_suffix\$/d"
2569 done
2570 extrasub_host=
2571 for module in ${configdirs} ; do
2572   if test -z "${no_recursion}"; then
2573     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2574       if test -f ${file}; then
2575         echo 1>&2 "*** removing ${file} to force reconfigure"
2576         rm -f ${file}
2577       fi
2578     done
2579   fi
2580   extrasub_host="$extrasub_host
2581 /^@if $module\$/d
2582 /^@endif $module\$/d
2583 /^@if $module-$bootstrap_suffix\$/d
2584 /^@endif $module-$bootstrap_suffix\$/d"
2585 done
2586 extrasub_target=
2587 for module in ${target_configdirs} ; do
2588   if test -z "${no_recursion}" \
2589      && test -f ${target_subdir}/${module}/Makefile; then
2590     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2591     rm -f ${target_subdir}/${module}/Makefile
2592   fi
2593
2594   # We only bootstrap target libraries listed in bootstrap_target_libs.
2595   case $bootstrap_target_libs in
2596     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2597     *) target_bootstrap_suffix=no-bootstrap ;;
2598   esac
2599
2600   extrasub_target="$extrasub_target
2601 /^@if target-$module\$/d
2602 /^@endif target-$module\$/d
2603 /^@if target-$module-$target_bootstrap_suffix\$/d
2604 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2605 done
2606
2607 # Do the final fixup along with target modules.
2608 extrasub_target="$extrasub_target
2609 /^@if /,/^@endif /d"
2610
2611 # Create the serialization dependencies.  This uses a temporary file.
2612
2613 AC_ARG_ENABLE([serial-configure],
2614 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2615                 [force sequential configuration of
2616                  sub-packages for the host, target or build
2617                  machine, or all sub-packages])])
2618
2619 case ${enable_serial_configure} in
2620   yes)
2621     enable_serial_build_configure=yes
2622     enable_serial_host_configure=yes
2623     enable_serial_target_configure=yes
2624     ;;
2625 esac
2626
2627 # These force 'configure's to be done one at a time, to avoid problems
2628 # with contention over a shared config.cache.
2629 rm -f serdep.tmp
2630 echo '# serdep.tmp' > serdep.tmp
2631 olditem=
2632 test "x${enable_serial_build_configure}" = xyes &&
2633 for item in ${build_configdirs} ; do
2634   case ${olditem} in
2635     "") ;;
2636     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2637   esac
2638   olditem=${item}
2639 done
2640 olditem=
2641 test "x${enable_serial_host_configure}" = xyes &&
2642 for item in ${configdirs} ; do
2643   case ${olditem} in
2644     "") ;;
2645     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2646   esac
2647   olditem=${item}
2648 done
2649 olditem=
2650 test "x${enable_serial_target_configure}" = xyes &&
2651 for item in ${target_configdirs} ; do
2652   case ${olditem} in
2653     "") ;;
2654     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2655   esac
2656   olditem=${item}
2657 done
2658 serialization_dependencies=serdep.tmp
2659 AC_SUBST_FILE(serialization_dependencies)
2660
2661 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2662 # target, nonopt, and variable assignments.  These are the ones we
2663 # might not want to pass down to subconfigures.  The exception being
2664 # --cache-file=/dev/null, which is used to turn off the use of cache
2665 # files altogether, and which should be passed on to subconfigures.
2666 # Also strip program-prefix, program-suffix, and program-transform-name,
2667 # so that we can pass down a consistent program-transform-name.
2668 baseargs=
2669 tbaseargs=
2670 keep_next=no
2671 skip_next=no
2672 eval "set -- $ac_configure_args"
2673 for ac_arg
2674 do
2675   if test X"$skip_next" = X"yes"; then
2676     skip_next=no
2677     continue
2678   fi
2679   if test X"$keep_next" = X"yes"; then
2680     case $ac_arg in
2681       *\'*)
2682         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2683     esac
2684     baseargs="$baseargs '$ac_arg'"
2685     tbaseargs="$tbaseargs '$ac_arg'"
2686     keep_next=no
2687     continue
2688   fi
2689
2690   # Handle separated arguments.  Based on the logic generated by
2691   # autoconf 2.59.
2692   case $ac_arg in
2693     *=* | --config-cache | -C | -disable-* | --disable-* \
2694       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2695       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2696       | -with-* | --with-* | -without-* | --without-* | --x)
2697       separate_arg=no
2698       ;;
2699     -*)
2700       separate_arg=yes
2701       ;;
2702     *)
2703       separate_arg=no
2704       ;;
2705   esac
2706
2707   skip_targ=no
2708   case $ac_arg in
2709 changequote(,)
2710   --with-* | --without-*)
2711     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2712
2713     case $libopt in
2714     *[-_]include)
2715       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2716       ;;
2717     *[-_]lib)
2718       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2719       ;;
2720     *)
2721       lib=$libopt
2722       ;;
2723     esac
2724 changequote([,])
2725
2726     case $lib in
2727     mpc | mpfr | gmp | cloog)
2728       # If we're processing --with-$lib, --with-$lib-include or
2729       # --with-$lib-lib, for one of the libs above, and target is
2730       # different from host, don't pass the current argument to any
2731       # target library's configure.
2732       if test x$is_cross_compiler = xyes; then
2733         skip_targ=yes
2734       fi
2735       ;;
2736     esac
2737     ;;
2738   esac
2739
2740   case "$ac_arg" in
2741     --cache-file=/dev/null | \
2742     -cache-file=/dev/null )
2743       # Handled here to avoid the test to skip args below.
2744       baseargs="$baseargs '$ac_arg'"
2745       tbaseargs="$tbaseargs '$ac_arg'"
2746       # Assert: $separate_arg should always be no.
2747       keep_next=$separate_arg
2748       ;;
2749     --no*)
2750       continue
2751       ;;
2752     --c* | \
2753     --sr* | \
2754     --ho* | \
2755     --bu* | \
2756     --t* | \
2757     --program-* | \
2758     -cache_file* | \
2759     -srcdir* | \
2760     -host* | \
2761     -build* | \
2762     -target* | \
2763     -program-prefix* | \
2764     -program-suffix* | \
2765     -program-transform-name* )
2766       skip_next=$separate_arg
2767       continue
2768       ;;
2769     -*)
2770       # An option.  Add it.
2771       case $ac_arg in
2772         *\'*)
2773           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2774       esac
2775       baseargs="$baseargs '$ac_arg'"
2776       if test X"$skip_targ" = Xno; then
2777         tbaseargs="$tbaseargs '$ac_arg'"
2778       fi
2779       keep_next=$separate_arg
2780       ;;
2781     *)
2782       # Either a variable assignment, or a nonopt (triplet).  Don't
2783       # pass it down; let the Makefile handle this.
2784       continue
2785       ;;
2786   esac
2787 done
2788 # Remove the initial space we just introduced and, as these will be
2789 # expanded by make, quote '$'.
2790 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2791
2792 # Add in --program-transform-name, after --program-prefix and
2793 # --program-suffix have been applied to it.  Autoconf has already
2794 # doubled dollar signs and backslashes in program_transform_name; we want
2795 # the backslashes un-doubled, and then the entire thing wrapped in single
2796 # quotes, because this will be expanded first by make and then by the shell.
2797 # Also, because we want to override the logic in subdir configure scripts to
2798 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2799 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2800 ${program_transform_name}
2801 EOF_SED
2802 gcc_transform_name=`cat conftestsed.out`
2803 rm -f conftestsed.out
2804 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2805 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2806 if test "$silent" = yes; then
2807   baseargs="$baseargs --silent"
2808   tbaseargs="$tbaseargs --silent"
2809 fi
2810 baseargs="$baseargs --disable-option-checking"
2811 tbaseargs="$tbaseargs --disable-option-checking"
2812
2813 # Record and document user additions to sub configure arguments.
2814 AC_ARG_VAR([build_configargs],
2815            [additional configure arguments for build directories])
2816 AC_ARG_VAR([host_configargs],
2817            [additional configure arguments for host directories])
2818 AC_ARG_VAR([target_configargs],
2819            [additional configure arguments for target directories])
2820
2821 # For the build-side libraries, we just need to pretend we're native,
2822 # and not use the same cache file.  Multilibs are neither needed nor
2823 # desired.
2824 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2825
2826 # For host modules, accept cache file option, or specification as blank.
2827 case "${cache_file}" in
2828 "") # empty
2829   cache_file_option="" ;;
2830 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2831   cache_file_option="--cache-file=${cache_file}" ;;
2832 *) # relative path
2833   cache_file_option="--cache-file=../${cache_file}" ;;
2834 esac
2835
2836 # Host dirs don't like to share a cache file either, horribly enough.
2837 # This seems to be due to autoconf 2.5x stupidity.
2838 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2839
2840 target_configargs="$target_configargs ${tbaseargs}"
2841
2842 # Passing a --with-cross-host argument lets the target libraries know
2843 # whether they are being built with a cross-compiler or being built
2844 # native.  However, it would be better to use other mechanisms to make the
2845 # sorts of decisions they want to make on this basis.  Please consider
2846 # this option to be deprecated.  FIXME.
2847 if test x${is_cross_compiler} = xyes ; then
2848   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2849 fi
2850
2851 # Default to --enable-multilib.
2852 if test x${enable_multilib} = x ; then
2853   target_configargs="--enable-multilib ${target_configargs}"
2854 fi
2855
2856 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2857 # changed from the earlier setting of with_newlib.
2858 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2859   target_configargs="--with-newlib ${target_configargs}"
2860 fi
2861
2862 # Different target subdirs use different values of certain variables
2863 # (notably CXX).  Worse, multilibs use *lots* of different values.
2864 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2865 # it doesn't automatically accept command-line overrides of them.
2866 # This means it's not safe for target subdirs to share a cache file,
2867 # which is disgusting, but there you have it.  Hopefully this can be
2868 # fixed in future.  It's still worthwhile to use a cache file for each
2869 # directory.  I think.
2870
2871 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2872 # We need to pass --target, as newer autoconf's requires consistency
2873 # for target_alias and gcc doesn't manage it consistently.
2874 target_configargs="--cache-file=./config.cache ${target_configargs}"
2875
2876 FLAGS_FOR_TARGET=
2877 case " $target_configdirs " in
2878  *" newlib "*)
2879   case " $target_configargs " in
2880   *" --with-newlib "*)
2881    case "$target" in
2882     *-cygwin*)
2883       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
2884       ;;
2885    esac
2886
2887    # If we're not building GCC, don't discard standard headers.
2888    if test -d ${srcdir}/gcc; then
2889      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2890
2891      if test "${build}" != "${host}"; then
2892        # On Canadian crosses, CC_FOR_TARGET will have already been set
2893        # by `configure', so we won't have an opportunity to add -Bgcc/
2894        # to it.  This is right: we don't want to search that directory
2895        # for binaries, but we want the header files in there, so add
2896        # them explicitly.
2897        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2898
2899        # Someone might think of using the pre-installed headers on
2900        # Canadian crosses, in case the installed compiler is not fully
2901        # compatible with the compiler being built.  In this case, it
2902        # would be better to flag an error than risking having
2903        # incompatible object files being constructed.  We can't
2904        # guarantee that an error will be flagged, but let's hope the
2905        # compiler will do it, when presented with incompatible header
2906        # files.
2907      fi
2908    fi
2909
2910    case "${target}-${is_cross_compiler}" in
2911    i[[3456789]]86-*-linux*-no)
2912       # Here host == target, so we don't need to build gcc,
2913       # so we don't want to discard standard headers.
2914       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2915       ;;
2916    *)
2917       # If we're building newlib, use its generic headers last, but search
2918       # for any libc-related directories first (so make it the last -B
2919       # switch).
2920       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2921
2922       # If we're building libgloss, find the startup file, simulator library
2923       # and linker script.
2924       case " $target_configdirs " in
2925         *" libgloss "*)
2926         # Look for startup file, simulator library and maybe linker script.
2927         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2928         # Look for libnosys.a in case the target needs it.
2929         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2930         # Most targets have the linker script in the source directory.
2931         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2932         ;;
2933       esac
2934       ;;
2935    esac
2936    ;;
2937   esac
2938   ;;
2939 esac
2940
2941 case "$target" in
2942   x86_64-*mingw* | *-w64-mingw*)
2943   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2944   # however, use a symlink named 'mingw' in ${prefix} .
2945     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2946     ;;
2947   *-mingw*)
2948   # MinGW can't be handled as Cygwin above since it does not use newlib.
2949     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2950     ;;
2951 esac
2952
2953 # Allow the user to override the flags for
2954 # our build compiler if desired.
2955 if test x"${build}" = x"${host}" ; then
2956   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2957   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2958   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2959 fi
2960
2961 # On Canadian crosses, we'll be searching the right directories for
2962 # the previously-installed cross compiler, so don't bother to add
2963 # flags for directories within the install tree of the compiler
2964 # being built; programs in there won't even run.
2965 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2966   # Search for pre-installed headers if nothing else fits.
2967   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2968 fi
2969
2970 if test "x${use_gnu_ld}" = x &&
2971    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2972   # Arrange for us to find uninstalled linker scripts.
2973   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2974 fi
2975
2976 # Search for other target-specific linker scripts and such.
2977 case "${target}" in
2978   mep*)
2979     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2980     ;;
2981 esac
2982
2983 # Makefile fragments.
2984 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2985 do
2986   eval fragval=\$$frag
2987   if test $fragval != /dev/null; then
2988     eval $frag=${srcdir}/$fragval
2989   fi
2990 done
2991 AC_SUBST_FILE(host_makefile_frag)
2992 AC_SUBST_FILE(target_makefile_frag)
2993 AC_SUBST_FILE(alphaieee_frag)
2994 AC_SUBST_FILE(ospace_frag)
2995
2996 # Miscellanea: directories, flags, etc.
2997 AC_SUBST(RPATH_ENVVAR)
2998 AC_SUBST(GCC_SHLIB_SUBDIR)
2999 AC_SUBST(tooldir)
3000 AC_SUBST(build_tooldir)
3001 AC_SUBST(CONFIGURE_GDB_TK)
3002 AC_SUBST(GDB_TK)
3003 AC_SUBST(INSTALL_GDB_TK)
3004
3005 # Build module lists & subconfigure args.
3006 AC_SUBST(build_configargs)
3007 AC_SUBST(build_configdirs)
3008
3009 # Host module lists & subconfigure args.
3010 AC_SUBST(host_configargs)
3011 AC_SUBST(configdirs)
3012 AC_SUBST(target_configdirs)
3013
3014 # Target module lists & subconfigure args.
3015 AC_SUBST(target_configargs)
3016
3017
3018 # Build tools.
3019 AC_SUBST(AR_FOR_BUILD)
3020 AC_SUBST(AS_FOR_BUILD)
3021 AC_SUBST(CC_FOR_BUILD)
3022 AC_SUBST(CFLAGS_FOR_BUILD)
3023 AC_SUBST(CXXFLAGS_FOR_BUILD)
3024 AC_SUBST(CXX_FOR_BUILD)
3025 AC_SUBST(DLLTOOL_FOR_BUILD)
3026 AC_SUBST(GCJ_FOR_BUILD)
3027 AC_SUBST(GFORTRAN_FOR_BUILD)
3028 AC_SUBST(GOC_FOR_BUILD)
3029 AC_SUBST(LDFLAGS_FOR_BUILD)
3030 AC_SUBST(LD_FOR_BUILD)
3031 AC_SUBST(NM_FOR_BUILD)
3032 AC_SUBST(RANLIB_FOR_BUILD)
3033 AC_SUBST(WINDMC_FOR_BUILD)
3034 AC_SUBST(WINDRES_FOR_BUILD)
3035
3036 # Generate default definitions for YACC, M4, LEX and other programs that run
3037 # on the build machine.  These are used if the Makefile can't locate these
3038 # programs in objdir.
3039 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3040
3041 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3042 case " $build_configdirs " in
3043   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3044 esac
3045
3046 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3047 case " $build_configdirs " in
3048   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3049 esac
3050
3051 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3052 case " $build_configdirs " in
3053   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3054 esac
3055
3056 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3057 case " $build_configdirs " in
3058   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3059   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3060 esac
3061
3062 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3063 case " $build_configdirs " in
3064   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3065 esac
3066
3067 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3068 case " $build_configdirs " in
3069   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3070   *)
3071 changequote(,)
3072     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3073     # higher, else we use the "missing" dummy.
3074     if ${MAKEINFO} --version \
3075        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3076       :
3077     else
3078       MAKEINFO="$MISSING makeinfo"
3079     fi
3080     ;;
3081 changequote([,])
3082 esac
3083
3084 # FIXME: expect and dejagnu may become build tools?
3085
3086 AC_CHECK_PROGS(EXPECT, expect, expect)
3087 case " $configdirs " in
3088   *" expect "*)
3089     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3090     ;;
3091 esac
3092
3093 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3094 case " $configdirs " in
3095   *" dejagnu "*)
3096     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3097     ;;
3098 esac
3099
3100
3101 # Host tools.
3102 NCN_STRICT_CHECK_TOOLS(AR, ar)
3103 NCN_STRICT_CHECK_TOOLS(AS, as)
3104 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3105 NCN_STRICT_CHECK_TOOLS(LD, ld)
3106 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3107 NCN_STRICT_CHECK_TOOLS(NM, nm)
3108 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3109 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3110 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3111 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3112 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3113 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3114 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3115 AC_SUBST(CC)
3116 AC_SUBST(CXX)
3117 AC_SUBST(CFLAGS)
3118 AC_SUBST(CXXFLAGS)
3119
3120 # Target tools.
3121 AC_ARG_WITH([build-time-tools],
3122   [AS_HELP_STRING([--with-build-time-tools=PATH],
3123                   [use given path to find target tools during the build])],
3124   [case x"$withval" in
3125      x/*) ;;
3126      *)
3127        with_build_time_tools=
3128        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3129        ;;
3130    esac],
3131   [with_build_time_tools=])
3132
3133 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3134 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3135 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3136 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3137 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3138 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3139
3140 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3141 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3142 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3143 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3144 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3145 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3146 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3147 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3148 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3149 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3150 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3151 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3152
3153 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3154
3155 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3156 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3157 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3158 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3159 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3160                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3161                 c++)
3162 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3163                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3164                 c++)
3165 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3166 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3167 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3168                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3169 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3170                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3171 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3172                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3173 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3174 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3175 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3176 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3177 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3178 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3179 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3180 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3181 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3182
3183 AC_SUBST(FLAGS_FOR_TARGET)
3184 AC_SUBST(RAW_CXX_FOR_TARGET)
3185
3186 # Certain tools may need extra flags.
3187 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3188 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3189 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3190
3191 # When building target libraries, except in a Canadian cross, we use
3192 # the same toolchain as the compiler we just built.
3193 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3194 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3195 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3196 if test $host = $build; then
3197   case " $configdirs " in
3198     *" gcc "*)
3199       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3200       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3201       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3202       ;;
3203   esac
3204 fi
3205
3206 AC_SUBST(COMPILER_AS_FOR_TARGET)
3207 AC_SUBST(COMPILER_LD_FOR_TARGET)
3208 AC_SUBST(COMPILER_NM_FOR_TARGET)
3209
3210 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3211 AC_ARG_ENABLE(maintainer-mode,
3212 [AS_HELP_STRING([--enable-maintainer-mode],
3213                 [enable make rules and dependencies not useful
3214                  (and sometimes confusing) to the casual installer])],
3215       USE_MAINTAINER_MODE=$enableval,
3216       USE_MAINTAINER_MODE=no)
3217 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3218 AC_SUBST(MAINTAINER_MODE_TRUE)
3219 AC_SUBST(MAINTAINER_MODE_FALSE)
3220 if test "$USE_MAINTAINER_MODE" = yes; then
3221   MAINTAINER_MODE_TRUE=
3222   MAINTAINER_MODE_FALSE='#'
3223 else
3224   MAINTAINER_MODE_TRUE='#'
3225   MAINTAINER_MODE_FALSE=
3226 fi
3227 MAINT=$MAINTAINER_MODE_TRUE
3228 AC_SUBST(MAINT)dnl
3229
3230 # ---------------------
3231 # GCC bootstrap support
3232 # ---------------------
3233
3234 # Stage specific cflags for build.
3235 stage1_cflags="-g"
3236 case $build in
3237   vax-*-*)
3238     case ${GCC} in
3239       yes) stage1_cflags="-g -Wa,-J" ;;
3240       *) stage1_cflags="-g -J" ;;
3241     esac ;;
3242 esac
3243
3244 AC_SUBST(stage1_cflags)
3245
3246 # Enable --enable-checking in stage1 of the compiler.
3247 AC_ARG_ENABLE(stage1-checking,
3248 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3249                 [choose additional checking for stage1 of the compiler])],
3250 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3251 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3252   stage1_checking=--enable-checking=yes,types
3253 else
3254   stage1_checking=--enable-checking=$enable_checking,types
3255 fi])
3256 AC_SUBST(stage1_checking)
3257
3258 # Enable -Werror in bootstrap stage2 and later.
3259 AC_ARG_ENABLE(werror,
3260 [AS_HELP_STRING([--enable-werror],
3261                 [enable -Werror in bootstrap stage2 and later])], [],
3262 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3263   enable_werror=yes
3264 else
3265   enable_werror=no
3266 fi])
3267 case ${enable_werror} in
3268   yes) stage2_werror_flag="--enable-werror-always" ;;
3269   *) stage2_werror_flag="" ;;
3270 esac
3271 AC_SUBST(stage2_werror_flag)
3272
3273 # Specify what files to not compare during bootstrap.
3274
3275 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3276 case "$target" in
3277   hppa*64*-*-hpux*) ;;
3278   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3279   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3280 esac
3281 AC_SUBST(compare_exclusions)
3282
3283 AC_CONFIG_FILES([Makefile],
3284   [sed "$extrasub_build" Makefile |
3285    sed "$extrasub_host" |
3286    sed "$extrasub_target" > mf$$
3287    mv -f mf$$ Makefile],
3288   [extrasub_build="$extrasub_build"
3289    extrasub_host="$extrasub_host"
3290    extrasub_target="$extrasub_target"])
3291 AC_OUTPUT