configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.21.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.28.1
  56 GSTPB_REQ=0.10.28.1
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AS_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for gconftool-2
 131 dnl this macro defines an am conditional, so it needs to be run always
 132 AM_GCONF_SOURCE_2
 133
 134 dnl check for documentation tools
 135 GTK_DOC_CHECK([1.3])
 136 AS_PATH_PYTHON([2.1])
 137 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 138
 139 dnl *** checks for libraries ***
 140
 141 dnl check for libm, for sin()
 142 AC_CHECK_LIBM
 143 AC_SUBST(LIBM)
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/rtp/gstasteriskh263.c
 154 AC_CHECK_HEADERS([netinet/in.h])
 155 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 156 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 157
 158 dnl used in gst/udp
 159 AC_CHECK_HEADERS([sys/time.h])
 160
 161 dnl *** checks for types/defines ***
 162
 163 dnl Check for FIONREAD ioctl declaration.  This check is needed
 164 dnl for the UDP plugin to build on Solaris
 165 GST_CHECK_FIONREAD
 166
 167 dnl *** checks for structures ***
 168
 169 dnl *** checks for compiler characteristics ***
 170
 171 dnl check if we have GCC inline-asm
 172 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 173 if test x$HAVE_GCC_ASM = xyes ; then
 174   AC_DEFINE(HAVE_GCC_ASM, 1,
 175     [Define if compiler supports gcc inline assembly])
 176 fi
 177 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 178
 179 dnl *** checks for library functions ***
 180
 181 LIBS_SAVE=$LIBS
 182 LIBS="$LIBS $LIBM"
 183 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 184 LIBS=$LIBS_SAVE
 185
 186 dnl Check whether isinf() is defined by math.h
 187 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 189 if test "$ac_cv_have_isinf" = "yes"
 190 then
 191     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 192 fi
 193
 194 dnl Check for mmap (needed by electricfence plugin)
 195 AC_FUNC_MMAP
 196 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199
 200 AC_CHECK_TYPE([struct ip_mreqn], [
 201               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 202               [#include <netinet/in.h>])
 203
 204 dnl *** checks for dependency libraries ***
 205
 206 dnl GLib is required
 207 AG_GST_GLIB_CHECK([2.18])
 208
 209 dnl liboil is required
 210 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 211 if test "x$HAVE_LIBOIL" != "xyes"; then
 212   AC_ERROR([liboil-0.3.8 or later is required])
 213 fi
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 if test "x$BUILD_EXAMPLES" = "xyes"; then
 245   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
 246   AC_SUBST(GTK_LIBS)
 247   AC_SUBST(GTK_CFLAGS)
 248 fi
 249 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 250
 251 dnl should we install schemas ?
 252 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 253 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 254   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 255   if test x$GCONFTOOL = xno; then
 256     AC_MSG_WARN(Not installing GConf schemas)
 257     HAVE_GCONFTOOL="no"
 258   else
 259     HAVE_GCONFTOOL="yes"
 260   fi
 261   AC_SUBST(HAVE_GCONFTOOL)
 262 ])
 263
 264 dnl *** set variables based on configure arguments ***
 265
 266 dnl set license and copyright notice
 267 GST_LICENSE="LGPL"
 268 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 269 AC_SUBST(GST_LICENSE)
 270
 271 dnl set location of plugin directory
 272 AG_GST_SET_PLUGINDIR
 273
 274 dnl define an ERROR_CFLAGS Makefile variable
 275 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 276         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 277         -Wwrite-strings -Wold-style-definition -Wcast-align
 278         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 279         -Waggregate-return -Wnested-externs ])
 280
 281 dnl define an ERROR_CXXFLAGS Makefile variable
 282 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 283         -Wmissing-declarations -Wredundant-decls -Wundef
 284         -Wwrite-strings -Wcast-align
 285         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 286
 287 dnl define correct level for debugging messages
 288 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 289
 290 dnl used in examples
 291 AG_GST_DEFAULT_ELEMENTS
 292
 293 dnl *** plug-ins to include ***
 294
 295 dnl these are all the gst plug-ins, compilable without additional libs
 296 dnl videofilter is at the top because others depend on it
 297 AG_GST_CHECK_PLUGIN(videofilter)
 298 AG_GST_CHECK_PLUGIN(alpha)
 299 AG_GST_CHECK_PLUGIN(apetag)
 300 AG_GST_CHECK_PLUGIN(audiofx)
 301 AG_GST_CHECK_PLUGIN(auparse)
 302 AG_GST_CHECK_PLUGIN(autodetect)
 303 AG_GST_CHECK_PLUGIN(avi)
 304 AG_GST_CHECK_PLUGIN(cutter)
 305 AG_GST_CHECK_PLUGIN(debugutils)
 306 AG_GST_CHECK_PLUGIN(deinterlace)
 307 AG_GST_CHECK_PLUGIN(effectv)
 308 AG_GST_CHECK_PLUGIN(equalizer)
 309 AG_GST_CHECK_PLUGIN(flv)
 310 AG_GST_CHECK_PLUGIN(id3demux)
 311 AG_GST_CHECK_PLUGIN(icydemux)
 312 AG_GST_CHECK_PLUGIN(interleave)
 313 AG_GST_CHECK_PLUGIN(flx)
 314 AG_GST_CHECK_PLUGIN(goom)
 315 AG_GST_CHECK_PLUGIN(goom2k1)
 316 AG_GST_CHECK_PLUGIN(law)
 317 AG_GST_CHECK_PLUGIN(level)
 318 AG_GST_CHECK_PLUGIN(matroska)
 319 AG_GST_CHECK_PLUGIN(monoscope)
 320 AG_GST_CHECK_PLUGIN(multifile)
 321 AG_GST_CHECK_PLUGIN(multipart)
 322 AG_GST_CHECK_PLUGIN(qtdemux)
 323 AG_GST_CHECK_PLUGIN(replaygain)
 324 AG_GST_CHECK_PLUGIN(rtp)
 325 AG_GST_CHECK_PLUGIN(rtpmanager)
 326 AG_GST_CHECK_PLUGIN(rtsp)
 327 AG_GST_CHECK_PLUGIN(shapewipe)
 328 AG_GST_CHECK_PLUGIN(smpte)
 329 AG_GST_CHECK_PLUGIN(spectrum)
 330 AG_GST_CHECK_PLUGIN(udp)
 331 AG_GST_CHECK_PLUGIN(videobox)
 332 AG_GST_CHECK_PLUGIN(videocrop)
 333 AG_GST_CHECK_PLUGIN(videomixer)
 334 AG_GST_CHECK_PLUGIN(wavenc)
 335 AG_GST_CHECK_PLUGIN(wavparse)
 336 AG_GST_CHECK_PLUGIN(y4m)
 337
 338 dnl *** checks for socket and nsl libraries ***
 339 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 340
 341 dnl disable gst plugins we might not be able to build on this
 342 dnl platform: udp and rtsp (ugly but minimally invasive)
 343 dnl FIXME: maybe move to sys
 344 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 345 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 346
 347 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 348   AG_GST_DISABLE_PLUGIN(udp)
 349   AG_GST_DISABLE_PLUGIN(rtsp)
 350 fi
 351
 352 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 353   WIN32_LIBS="-lws2_32"
 354   AC_SUBST(WIN32_LIBS)
 355 fi
 356
 357 dnl disable experimental plug-ins
 358 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 359   AG_GST_DISABLE_PLUGIN(monoscope)
 360 fi
 361
 362 dnl *** sys plug-ins ***
 363
 364 echo
 365 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 366 echo
 367
 368 dnl DirectSound
 369 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 370 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 371   HAVE_DIRECTSOUND="no"
 372   save_CFLAGS="$CFLAGS"
 373   save_LDFLAGS="$LDFLAGS"
 374   save_LIBS="$LIBS"
 375   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 376   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 377   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 378   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 379   AC_LINK_IFELSE([
 380 #include <windows.h>
 381 #include <dxerr9.h>
 382 #include <dsound.h>
 383
 384 int main ()
 385 {
 386   DXGetErrorString9 (0);
 387   DirectSoundCreate(NULL, NULL, NULL);
 388
 389   return 0;
 390 }
 391 ],
 392     [HAVE_DIRECTSOUND="yes"],
 393     [HAVE_DIRECTSOUND="no"])
 394   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 395   CFLAGS=$save_CFLAGS
 396   LDFLAGS=$save_LDFLAGS
 397   LIBS=$save_LIBS
 398
 399   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 400     dnl this is much more than we want
 401     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 402     AC_SUBST(DIRECTSOUND_CFLAGS)
 403     AC_SUBST(DIRECTSOUND_LDFLAGS)
 404     AC_SUBST(DIRECTSOUND_LIBS)
 405   fi
 406   AC_SUBST(HAVE_DIRECTSOUND)
 407 ])
 408
 409 dnl *** OSS audio *** (Linux, *BSD)
 410 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 411 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 412  HAVE_OSS="yes"
 413 dnl Linux and newer BSD versions :
 414  AC_CHECK_HEADER(sys/soundcard.h, [
 415    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 416    ] , [
 417 dnl Some old BSD versions and also newer OpenBSD versions :
 418    AC_CHECK_HEADER(soundcard.h, [
 419      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 420      ], [
 421   dnl Some old BSD versions :
 422      AC_CHECK_HEADER(machine/soundcard.h, [
 423        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 424          [Define if OSS includes are in /machine/])
 425        ], [
 426        HAVE_OSS="no"
 427      ])
 428    ])
 429  ])
 430 ])
 431
 432 dnl *** Sun Audio ***
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 434 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 435   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 436 ])
 437
 438 dnl *** OSX Audio ***
 439 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 440 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 441   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 442 ])
 443
 444 dnl *** OS X video ***
 445 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 446 HAVE_OSX_VIDEO="no"
 447 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 448   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 449 ])
 450 dnl in case header OpenGL/gl.h is found on other platforms
 451 case "$host" in
 452   *-*darwin*)
 453     dnl do nothing
 454     ;;
 455   *)
 456     HAVE_OSX_VIDEO="no"
 457     ;;
 458 esac
 459
 460
 461 dnl *** Video 4 Linux 2 ***
 462 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 463 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 465 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 466   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 467   AC_TRY_COMPILE([
 468 #include <sys/types.h>
 469 #ifdef __sun /* Solaris */
 470 #include <sys/types.h>
 471 #include <sys/videodev2.h>
 472 #else /* Linux */
 473 #include <linux/types.h>
 474 #define _LINUX_TIME_H
 475 #define __user
 476 #include <linux/videodev2.h>
 477 #endif
 478 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 479 #error too early v4l2 version or no v4l2 at all
 480 #endif
 481     ], [
 482 return 0;
 483     ], [
 484       HAVE_GST_V4L2="yes"
 485       AC_MSG_RESULT(yes)
 486     ], [
 487       HAVE_GST_V4L2="no"
 488       AC_MSG_RESULT(no)
 489
 490       HAVE_VIDEODEV=no
 491       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 492       [
 493         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 494       ])
 495
 496       if test "x$HAVE_VIDEODEV" = "xyes"; then
 497         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 498         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 499       else
 500         AC_MSG_WARN([video4linux2 was not found])
 501       fi
 502     ])
 503
 504   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 505     dnl check for missing v4l2_buffer declaration (see #135919)
 506     MISSING_DECL=0
 507     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 508     AC_TRY_COMPILE([
 509 #include <sys/types.h>
 510 #ifdef __sun /* Solaris */
 511 #include <sys/types.h>
 512 #include <sys/videodev2.h>
 513 #else /* Linux */
 514 #include <linux/types.h>
 515 #define _LINUX_TIME_H
 516 #define __user
 517 #include <linux/videodev2.h>
 518 #endif
 519     ],[
 520 struct v4l2_buffer buf;
 521 buf.index = 0;
 522 return 0;
 523     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 524     if [ test x$MISSING_DECL = x1 ]; then
 525       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 526     fi
 527
 528     dnl check for XOverlay libraries
 529     AG_GST_CHECK_XV
 530   fi
 531 ])
 532
 533 # Optional gudev for device probing
 534 AC_ARG_WITH([gudev],
 535   AC_HELP_STRING([--with-gudev],
 536     [device detection with gudev]),
 537   [],
 538   [with_gudev=check])
 539 if test x$HAVE_GST_V4L2 = xyes; then
 540   if test x$with_gudev != xno; then
 541       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 542           [ have_gudev=yes
 543             AC_DEFINE(HAVE_GUDEV, 1,
 544                [Whether gudev is available for device detection])
 545             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 546           ], [
 547           have_gudev=no
 548           ])
 549   else
 550     have_gudev=no
 551   fi
 552 fi
 553 AC_SUBST(GUDEV_CFLAGS)
 554 AC_SUBST(GUDEV_LIBS)
 555
 556 # Make libv4l2 non-automagic
 557 AC_ARG_WITH([libv4l2],
 558   AC_HELP_STRING([--with-libv4l2],
 559     [support video buffer conversion using libv4l2]),
 560   [],
 561   [with_libv4l2=check])
 562 if test x$HAVE_GST_V4L2 = xyes; then
 563   if test x$with_libv4l2 != xno; then
 564       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 565           [ have_libv4l2=yes
 566             AC_DEFINE(HAVE_LIBV4L2, 1,
 567                 [Whether libv4l2 is available for video buffer conversion])
 568           ], [
 569           have_libv4l2=no
 570           ])
 571   else
 572     have_libv4l2=no
 573   fi
 574 fi
 575
 576 dnl Check for X11
 577 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 578 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 579                   [ximagesrc], [
 580   AC_PATH_XTRA
 581
 582   dnl now try to find the HEADER
 583   ac_cflags_save="$CFLAGS"
 584   ac_cppflags_save="$CPPFLAGS"
 585   CFLAGS="$CFLAGS $X_CFLAGS"
 586   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 587   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 588
 589   if test "x$HAVE_X" = "xno"
 590   then
 591     AC_MSG_NOTICE([cannot find X11 development files])
 592   else
 593     dnl this is much more than we want
 594     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 595     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 596     dnl it does not add the libs; therefore we add them here
 597     X_LIBS="$X_LIBS -lX11"
 598     AC_SUBST(X_CFLAGS)
 599     AC_SUBST(X_LIBS)
 600
 601     dnl check for Xfixes
 602     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 603     if test "x$HAVE_XFIXES" = "xyes"
 604     then
 605         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 606     fi
 607     AC_SUBST(XFIXES_LIBS)
 608     AC_SUBST(XFIXES_CFLAGS)
 609
 610     dnl check for Xdamage
 611     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 612     if test "x$HAVE_XDAMAGE" = "xyes"
 613     then
 614         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 615     fi
 616     AC_SUBST(XDAMAGE_LIBS)
 617     AC_SUBST(XDAMAGE_CFLAGS)
 618   fi
 619   AC_SUBST(HAVE_X)
 620   CFLAGS="$ac_cflags_save"
 621   CPPFLAGS="$ac_cppflags_save"
 622 ])
 623
 624 dnl FIXME: this should be rolled into the test above, it's just an additional
 625 dnl feature of the ximagesrc plug-in
 626 dnl This is the same as in gst-plugins-base
 627 dnl check for X Shm
 628 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 629 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 630   if test x$HAVE_X = xyes; then
 631     AC_CHECK_LIB(Xext, XShmAttach,
 632                  HAVE_XSHM="yes", HAVE_XSHM="no",
 633                  $X_LIBS)
 634     if test "x$HAVE_XSHM" = "xyes"; then
 635       XSHM_LIBS="-lXext"
 636     else
 637       dnl On AIX, it is in XextSam instead, but we still need -lXext
 638       AC_CHECK_LIB(XextSam, XShmAttach,
 639                    HAVE_XSHM="yes", HAVE_XSHM="no",
 640                    $X_LIBS)
 641       if test "x$HAVE_XSHM" = "xyes"; then
 642         XSHM_LIBS="-lXext -lXextSam"
 643       fi
 644     fi
 645   fi
 646 ], ,[
 647   AC_SUBST(HAVE_XSHM)
 648   AC_SUBST(XSHM_LIBS)
 649 ])
 650
 651 dnl for V4L2, we also need to know if we have XVIDEO
 652 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 653 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 654                   [], [
 655   AG_GST_CHECK_XV
 656 ])
 657
 658 dnl *** ext plug-ins ***
 659 dnl keep this list sorted alphabetically !
 660
 661 if test "x$BUILD_EXTERNAL" = "xyes"; then
 662
 663 echo
 664 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 665 echo
 666
 667 dnl *** aalib ***
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 669 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 670   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 671   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 672 ])
 673
 674 dnl *** annodex ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 676 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 677   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 678 ])
 679
 680 dnl *** cairo ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 682 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 683   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 684 ])
 685
 686 dnl **** ESound ****
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 688 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 689   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 690   if test $HAVE_ESD = no
 691   then
 692     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 693     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 694   fi
 695 ])
 696
 697 dnl *** FLAC ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 699 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 700   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 701 ])
 702
 703 dnl *** GConf ***
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 705 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 706   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 707 ])
 708
 709 dnl *** GDK pixbuf ***
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 711 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 712   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 713 ])
 714
 715 dnl *** HAL ***
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 717 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 718   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 719 ])
 720
 721 dnl *** jpeg ***
 722 dnl FIXME: we could use header checks here as well IMO
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 724 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 725   AC_ARG_WITH(jpeg-mmx,
 726     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 727   OLD_LIBS="$LIBS"
 728   if test x$with_jpeg_mmx != x; then
 729     LIBS="$LIBS -L$with_jpeg_mmx"
 730   fi
 731   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 732   JPEG_LIBS="$LIBS -ljpeg-mmx"
 733   LIBS="$OLD_LIBS"
 734   if test x$HAVE_JPEG != xyes; then
 735     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 736     JPEG_LIBS="-ljpeg"
 737   fi
 738   AC_SUBST(JPEG_LIBS)
 739 ])
 740
 741 dnl *** libcaca ***
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 743 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 744   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 745   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 746   if test "x$HAVE_LIBCACA" != "xyes"; then
 747     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 748     dnl see if it compilation works too, might not if we are cross-compiling
 749     if test "x$HAVE_LIBCACA" = "xyes"; then
 750       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 751                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 752     fi
 753   fi
 754 ])
 755
 756 dnl *** libdv ***
 757 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 758 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 759   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 760 ])
 761
 762 dnl *** libpng ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 764 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 765   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 766 ])
 767
 768 dnl *** pulseaudio ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 770 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 771   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 772   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 773   if test x$HAVE_PULSE_0_9_11 = xyes; then
 774     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 775   fi
 776   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 777   if test x$HAVE_PULSE_0_9_12 = xyes; then
 778     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 779   fi
 780   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 781   if test x$HAVE_PULSE_0_9_13 = xyes; then
 782     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 783   fi
 784   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 785   if test x$HAVE_PULSE_0_9_15 = xyes; then
 786     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 787   fi
 788   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 789   if test x$HAVE_PULSE_0_9_20 = xyes; then
 790     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 791   fi
 792 ])
 793
 794 dnl *** dv1394 ***
 795 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 796 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 797   dnl first test for libraw1394 >= 1.2.1
 798   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 799   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 800   dnl now see how far we got
 801   if test x$HAVE_RAW1394 = xyes && \
 802      test x$HAVE_LIBIEC61883 = xyes; then
 803        AG_GST_CHECK_LIBHEADER(AVC1394,
 804         avc1394, avc1394_send_command, $RAW1394_LIBS,
 805         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 806        AG_GST_CHECK_LIBHEADER(ROM1394,
 807         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 808         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 809        if test x$HAVE_AVC1394 = xyes && \
 810           test x$HAVE_AVC1394 = xyes && \
 811           test x$HAVE_ROM1394 = xyes; then
 812           HAVE_DV1394=yes
 813           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 814           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 815           AC_SUBST(DV1394_CFLAGS)
 816           AC_SUBST(DV1394_LIBS)
 817         fi
 818   else
 819        if test x$HAVE_RAW1394 = xno; then
 820           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 821           AG_GST_CHECK_LIBHEADER(AVC1394,
 822            avc1394, avc1394_send_command, $RAW1394_LIBS,
 823            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 824           AG_GST_CHECK_LIBHEADER(ROM1394,
 825            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 826            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 827           if test x$HAVE_RAW1394 = xyes && \
 828              test x$HAVE_AVC1394 = xyes && \
 829              test x$HAVE_ROM1394 = xyes; then
 830              HAVE_DV1394=yes
 831              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 832              DV1394_CFLAGS="$RAW1394_CFLAGS"
 833              if test x$HAVE_LIBIEC61883 = xyes; then
 834                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 835                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 836              fi
 837              AC_SUBST(DV1394_CFLAGS)
 838              AC_SUBST(DV1394_LIBS)
 839            fi
 840          fi
 841   fi
 842 ])
 843
 844 dnl *** shout2 ***
 845 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 846 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 847   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 848   if test $HAVE_SHOUT2 = no
 849   then
 850     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 851     AC_SUBST(SHOUT2_CFLAGS)
 852     AC_SUBST(SHOUT2_LIBS)
 853   fi
 854 ])
 855
 856 dnl *** soup ***
 857 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 858 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 859   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 860     HAVE_SOUP="yes"
 861     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 862   ],[
 863     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 864       HAVE_SOUP="no"
 865       AC_MSG_RESULT(no)
 866     ])
 867   ])
 868   AC_SUBST(SOUP_CFLAGS)
 869   AC_SUBST(SOUP_LIBS)
 870 ])
 871
 872 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 873 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 874 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 875 dnl   speex_jitter.h is 1.1.x only
 876 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 877 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 878   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 879   if test $HAVE_SPEEX = no
 880   then
 881     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 882       AC_CHECK_HEADER(speex/speex_jitter.h, [
 883         dnl speex 1.1.x :
 884         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 885           dnl speex 1.1.5 or + :
 886           HAVE_SPEEX="yes"
 887           SPEEX_LIBS="-lspeex"
 888           AC_SUBST(SPEEX_CFLAGS)
 889           AC_SUBST(SPEEX_LIBS)
 890         ],[
 891           HAVE_SPEEX="no"
 892         ])
 893       ],[
 894         dnl speex 1.0.x :
 895           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 896             dnl speex 1.0.4
 897             HAVE_SPEEX="yes"
 898             SPEEX_LIBS="-lspeex"
 899             AC_SUBST(SPEEX_CFLAGS)
 900             AC_SUBST(SPEEX_LIBS)
 901
 902             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 903               [defined if speex 1.0.x API detected])
 904         ],[
 905             HAVE_SPEEX="no"
 906             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 907         ], [
 908 #include <speex/speex.h>
 909         ])
 910       ])
 911     ])
 912   fi
 913 ])
 914
 915 dnl *** taglib ***
 916 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 917 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 918   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 919   if test "x$HAVE_CXX" != "xyes"; then
 920     USE_TAGLIB=false
 921     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 922   else
 923     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 924     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 925         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 926       ], [
 927         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 928     ])
 929     AC_SUBST(TAGLIB_CXXFLAGS)
 930   fi
 931 ])
 932
 933 dnl *** wavpack ***
 934 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 935 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 936   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 937     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 938       HAVE_WAVPACK=yes
 939       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 940     ],[
 941       HAVE_WAVPACK=no
 942       AC_MSG_RESULT(no)
 943     ])
 944   ])
 945   AC_SUBST(WAVPACK_CFLAGS)
 946   AC_SUBST(WAVPACK_LIBS)
 947 ])
 948
 949 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 950 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 951 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 952   AG_GST_CHECK_LIBHEADER(ZLIB,
 953     z, uncompress,, zlib.h, [
 954     HAVE_ZLIB="yes"
 955     ZLIB_LIBS="-lz"
 956     AC_SUBST(ZLIB_LIBS)
 957   ])
 958 ])
 959
 960 dnl *** matroska prefers to have bz2 ***
 961 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 962 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 963   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 964   AC_SUBST(BZ2_LIBS)
 965 ])
 966
 967 else
 968
 969 dnl not building plugins with external dependencies,
 970 dnl but we still need to set the conditionals
 971 AM_CONDITIONAL(USE_AALIB, false)
 972 AM_CONDITIONAL(USE_ANNODEX, false)
 973 AM_CONDITIONAL(USE_BZ2, false)
 974 AM_CONDITIONAL(USE_CAIRO, false)
 975 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 976 AM_CONDITIONAL(USE_DV1394, false)
 977 AM_CONDITIONAL(USE_ESD, false)
 978 AM_CONDITIONAL(USE_FLAC, false)
 979 AM_CONDITIONAL(USE_GCONF, false)
 980 AM_CONDITIONAL(USE_GCONFTOOL, false)
 981 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 982 AM_CONDITIONAL(USE_GST_V4L2, false)
 983 AM_CONDITIONAL(USE_HAL, false)
 984 AM_CONDITIONAL(USE_JPEG, false)
 985 AM_CONDITIONAL(USE_LIBCACA, false)
 986 AM_CONDITIONAL(USE_LIBDV, false)
 987 AM_CONDITIONAL(USE_LIBPNG, false)
 988 AM_CONDITIONAL(USE_OSS, false)
 989 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 990 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 991 AM_CONDITIONAL(USE_PULSE, false)
 992 AM_CONDITIONAL(USE_SHOUT2, false)
 993 AM_CONDITIONAL(USE_SOUP, false)
 994 AM_CONDITIONAL(USE_SPEEX, false)
 995 AM_CONDITIONAL(USE_SUNAUDIO, false)
 996 AM_CONDITIONAL(USE_TAGLIB, false)
 997 AM_CONDITIONAL(USE_WAVPACK, false)
 998 AM_CONDITIONAL(USE_X, false)
 999 AM_CONDITIONAL(USE_XSHM, false)
1000 AM_CONDITIONAL(USE_XVIDEO, false)
1001 AM_CONDITIONAL(USE_ZLIB, false)
1002
1003 fi dnl of EXT plugins
1004
1005 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1006
1007 dnl Overview:
1008 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1009 dnl GST_*:              flags shared by all built objects
1010 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1011 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1012 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1013 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1014
1015 dnl GST_OPTION_CFLAGS
1016 if test "x$USE_DEBUG" = xyes; then
1017    PROFILE_CFLAGS="-g"
1018 fi
1019 AC_SUBST(PROFILE_CFLAGS)
1020
1021 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1022   dnl Define _only_ for git (not pre-releases or releases)
1023   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1024 else
1025   DEPRECATED_CFLAGS=""
1026 fi
1027 AC_SUBST(DEPRECATED_CFLAGS)
1028
1029 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1030 dnl at make time with e.g. make ERROR_CFLAGS=""
1031 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1032 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1033 AC_SUBST(GST_OPTION_CFLAGS)
1034 AC_SUBST(GST_OPTION_CXXFLAGS)
1035
1036 dnl our libraries need to be versioned correctly
1037 AC_SUBST(GST_LT_LDFLAGS)
1038
1039 dnl FIXME: do we want to rename to GST_ALL_* ?
1040 dnl prefer internal headers to already installed ones
1041 dnl also add builddir include for enumtypes and marshal
1042 dnl add ERROR_CFLAGS, but overridable
1043 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1044 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1045 AC_SUBST(GST_CFLAGS)
1046 AC_SUBST(GST_CXXFLAGS)
1047 AC_SUBST(GST_LIBS)
1048
1049 dnl LDFLAGS really should only contain flags, not libs - they get added before
1050 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1051 GST_ALL_LDFLAGS="-no-undefined"
1052 AC_SUBST(GST_ALL_LDFLAGS)
1053
1054 dnl this really should only contain flags, not libs - they get added before
1055 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1056 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1057 AC_SUBST(GST_PLUGIN_LDFLAGS)
1058
1059 dnl *** output files ***
1060
1061 dnl keep this alphabetic per directory, please
1062 AC_CONFIG_FILES(
1063 Makefile
1064 gst/Makefile
1065 gst/alpha/Makefile
1066 gst/apetag/Makefile
1067 gst/audiofx/Makefile
1068 gst/auparse/Makefile
1069 gst/autodetect/Makefile
1070 gst/avi/Makefile
1071 gst/cutter/Makefile
1072 gst/deinterlace/Makefile
1073 gst/debugutils/Makefile
1074 gst/effectv/Makefile
1075 gst/equalizer/Makefile
1076 gst/flv/Makefile
1077 gst/id3demux/Makefile
1078 gst/icydemux/Makefile
1079 gst/interleave/Makefile
1080 gst/goom/Makefile
1081 gst/goom2k1/Makefile
1082 gst/law/Makefile
1083 gst/level/Makefile
1084 gst/matroska/Makefile
1085 gst/monoscope/Makefile
1086 gst/multifile/Makefile
1087 gst/multipart/Makefile
1088 gst/qtdemux/Makefile
1089 gst/replaygain/Makefile
1090 gst/rtp/Makefile
1091 gst/rtpmanager/Makefile
1092 gst/rtsp/Makefile
1093 gst/shapewipe/Makefile
1094 gst/smpte/Makefile
1095 gst/spectrum/Makefile
1096 gst/udp/Makefile
1097 gst/videobox/Makefile
1098 gst/videocrop/Makefile
1099 gst/videofilter/Makefile
1100 gst/videomixer/Makefile
1101 gst/wavenc/Makefile
1102 gst/wavparse/Makefile
1103 gst/flx/Makefile
1104 gst/y4m/Makefile
1105 ext/jpeg/Makefile
1106 ext/Makefile
1107 ext/aalib/Makefile
1108 ext/annodex/Makefile
1109 ext/cairo/Makefile
1110 ext/dv/Makefile
1111 ext/esd/Makefile
1112 ext/flac/Makefile
1113 ext/gconf/Makefile
1114 ext/gdk_pixbuf/Makefile
1115 ext/hal/Makefile
1116 ext/libcaca/Makefile
1117 ext/libpng/Makefile
1118 ext/pulse/Makefile
1119 ext/raw1394/Makefile
1120 ext/shout2/Makefile
1121 ext/soup/Makefile
1122 ext/speex/Makefile
1123 ext/taglib/Makefile
1124 ext/wavpack/Makefile
1125 sys/Makefile
1126 sys/directsound/Makefile
1127 sys/oss/Makefile
1128 sys/sunaudio/Makefile
1129 sys/osxaudio/Makefile
1130 sys/osxvideo/Makefile
1131 sys/v4l2/Makefile
1132 sys/waveform/Makefile
1133 sys/ximage/Makefile
1134 po/Makefile.in
1135 tests/Makefile
1136 tests/check/Makefile
1137 tests/examples/Makefile
1138 tests/examples/audiofx/Makefile
1139 tests/examples/equalizer/Makefile
1140 tests/examples/level/Makefile
1141 tests/examples/rtp/Makefile
1142 tests/examples/shapewipe/Makefile
1143 tests/examples/spectrum/Makefile
1144 tests/examples/v4l2/Makefile
1145 tests/files/Makefile
1146 tests/icles/Makefile
1147 gconf/Makefile
1148 gconf/gstreamer.schemas
1149 common/Makefile
1150 common/m4/Makefile
1151 m4/Makefile
1152 docs/Makefile
1153 docs/plugins/Makefile
1154 docs/version.entities
1155 pkgconfig/Makefile
1156 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1157 gst-plugins-good.spec
1158 )
1159
1160 dnl Create the config.h file for Visual Studio builds
1161 dnl Beware of spaces and /'s in some of the shell variable contents.
1162 sed \
1163     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1164     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1165     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1166     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1167     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1168     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1169     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1170     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1171     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1172     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1173     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1174     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1175     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1176     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1177     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1178     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1179     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1180     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1181     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1182     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1183     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1184     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1185     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1186     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1187     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1188     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1189     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1190     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1191     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1192     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1193     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1194     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1195     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1196     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1197     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1198     config.h.in >win32/common/config.h-new
1199
1200 AC_OUTPUT
1201
1202 AG_GST_OUTPUT_PLUGINS