configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.0.2],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 LT_PREREQ([2.2])
  28 LT_INIT([disable-static])
  29
  30 dnl Set internal versions
  31 OSMESA_VERSION=8
  32 AC_SUBST([OSMESA_VERSION])
  33
  34 dnl Versions for external dependencies
  35 LIBDRM_REQUIRED=2.4.24
  36 LIBDRM_RADEON_REQUIRED=2.4.39
  37 LIBDRM_INTEL_REQUIRED=2.4.38
  38 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  39 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  40 DRI2PROTO_REQUIRED=2.6
  41 GLPROTO_REQUIRED=1.4.14
  42 LIBDRM_XORG_REQUIRED=2.4.24
  43 LIBKMS_XORG_REQUIRED=1.0.0
  44
  45 dnl Check for progs
  46 AC_PROG_CPP
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AC_PROG_SED
  54 AC_PROG_MKDIR_P
  55 AC_PATH_PROG([MKDEP], [makedepend])
  56
  57 if test "x$MKDEP" = "x"; then
  58     AC_MSG_ERROR([makedepend is required to build Mesa])
  59 fi
  60
  61 AC_PROG_YACC
  62 AC_PATH_PROG([YACC_INST], $YACC)
  63 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
  64     if test -z "$YACC_INST"; then
  65         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  66     fi
  67 fi
  68 AC_PROG_LEX
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  75 fi
  76
  77 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  78 dnl configuration in that case.
  79 AC_PROG_INSTALL
  80 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  81
  82 dnl We need a POSIX shell for parts of the build. Assume we have one
  83 dnl in most cases.
  84 case "$host_os" in
  85 solaris*)
  86     # Solaris /bin/sh is too old/non-POSIX compliant
  87     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  88     SHELL="$POSIX_SHELL"
  89     ;;
  90 esac
  91
  92 dnl clang is mostly GCC-compatible, but its version is much lower,
  93 dnl so we have to check for it.
  94 AC_MSG_CHECKING([if compiling with clang])
  95
  96 AC_COMPILE_IFELSE(
  97 [AC_LANG_PROGRAM([], [[
  98 #ifndef __clang__
  99        not clang
 100 #endif
 101 ]])],
 102 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 103
 104 AC_MSG_RESULT([$acv_mesa_CLANG])
 105
 106 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 107 dnl versions are explictly not supported.
 108 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 109     AC_MSG_CHECKING([whether gcc version is sufficient])
 110     major=0
 111     minor=0
 112
 113     GCC_VERSION=`$CC -dumpversion`
 114     if test $? -eq 0; then
 115         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 116         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 117     fi
 118
 119     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 120         AC_MSG_RESULT([no])
 121         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 122     else
 123         AC_MSG_RESULT([yes])
 124     fi
 125 fi
 126
 127
 128 MKDEP_OPTIONS=-fdepend
 129 dnl Ask gcc where it's keeping its secret headers
 130 if test "x$GCC" = xyes; then
 131     for dir in include include-fixed; do
 132         GCC_INCLUDES=`$CC -print-file-name=$dir`
 133         if test "x$GCC_INCLUDES" != x && \
 134            test "$GCC_INCLUDES" != "$dir" && \
 135            test -d "$GCC_INCLUDES"; then
 136             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 137         fi
 138     done
 139 fi
 140 AC_SUBST([MKDEP_OPTIONS])
 141
 142 dnl Make sure the pkg-config macros are defined
 143 m4_ifndef([PKG_PROG_PKG_CONFIG],
 144     [m4_fatal([Could not locate the pkg-config autoconf macros.
 145   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 146   are in a different location, try setting the environment variable
 147   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 148 PKG_PROG_PKG_CONFIG()
 149
 150 dnl LIB_DIR - library basename
 151 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 152 AC_SUBST([LIB_DIR])
 153
 154 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 155 _SAVE_LDFLAGS="$LDFLAGS"
 156 _SAVE_CPPFLAGS="$CPPFLAGS"
 157
 158 dnl Compiler macros
 159 DEFINES=""
 160 AC_SUBST([DEFINES])
 161 case "$host_os" in
 162 linux*|*-gnu*|gnu*)
 163     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 164     ;;
 165 solaris*)
 166     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 167     ;;
 168 cygwin*)
 169     DEFINES="$DEFINES -DHAVE_PTHREAD"
 170     ;;
 171 esac
 172
 173 dnl Add flags for gcc and g++
 174 if test "x$GCC" = xyes; then
 175     CFLAGS="$CFLAGS -Wall -std=c99"
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Hacks to enable 32 or 64 bit build
 246 dnl
 247 AC_ARG_ENABLE([32-bit],
 248     [AS_HELP_STRING([--enable-32-bit],
 249         [build 32-bit libraries @<:@default=auto@:>@])],
 250     [enable_32bit="$enableval"],
 251     [enable_32bit=auto]
 252 )
 253 if test "x$enable_32bit" = xyes; then
 254     if test "x$GCC" = xyes; then
 255         CFLAGS="$CFLAGS -m32"
 256         CCASFLAGS="$CCASFLAGS -m32"
 257     fi
 258     if test "x$GXX" = xyes; then
 259         CXXFLAGS="$CXXFLAGS -m32"
 260     fi
 261 fi
 262 AC_ARG_ENABLE([64-bit],
 263     [AS_HELP_STRING([--enable-64-bit],
 264         [build 64-bit libraries @<:@default=auto@:>@])],
 265     [enable_64bit="$enableval"],
 266     [enable_64bit=auto]
 267 )
 268 if test "x$enable_64bit" = xyes; then
 269     if test "x$GCC" = xyes; then
 270         CFLAGS="$CFLAGS -m64"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m64"
 274     fi
 275 fi
 276
 277 dnl Can't have static and shared libraries, default to static if user
 278 dnl explicitly requested. If both disabled, set to static since shared
 279 dnl was explicitly requested.
 280 case "x$enable_static$enable_shared" in
 281 xyesyes )
 282     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 283     enable_shared=no
 284     ;;
 285 xnono )
 286     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 287     enable_static=yes
 288     ;;
 289 esac
 290
 291 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 292
 293 dnl
 294 dnl mklib options
 295 dnl
 296 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 297 if test "$enable_static" = yes; then
 298     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 299 fi
 300 AC_SUBST([MKLIB_OPTIONS])
 301
 302 dnl
 303 dnl other compiler options
 304 dnl
 305 AC_ARG_ENABLE([debug],
 306     [AS_HELP_STRING([--enable-debug],
 307         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 308     [enable_debug="$enableval"],
 309     [enable_debug=no]
 310 )
 311 if test "x$enable_debug" = xyes; then
 312     DEFINES="$DEFINES -DDEBUG"
 313     if test "x$GCC" = xyes; then
 314         CFLAGS="$CFLAGS -g"
 315     fi
 316     if test "x$GXX" = xyes; then
 317         CXXFLAGS="$CXXFLAGS -g"
 318     fi
 319 fi
 320
 321 dnl
 322 dnl library names
 323 dnl
 324 LIB_PREFIX_GLOB='lib'
 325 LIB_VERSION_SEPARATOR='.'
 326 if test "$enable_static" = yes; then
 327     LIB_EXTENSION='a'
 328 else
 329     case "$host_os" in
 330     darwin* )
 331         LIB_EXTENSION='dylib' ;;
 332     cygwin* )
 333         dnl prefix can be 'cyg' or 'lib'
 334         LIB_PREFIX_GLOB='???'
 335         LIB_VERSION_SEPARATOR='-'
 336         LIB_EXTENSION='dll' ;;
 337     aix* )
 338         LIB_EXTENSION='a' ;;
 339     * )
 340         LIB_EXTENSION='so' ;;
 341     esac
 342 fi
 343 AC_ARG_WITH([gl-lib-name],
 344   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 345     [specify GL library name @<:@default=GL@:>@])],
 346   [GL_LIB=$withval],
 347   [GL_LIB=GL])
 348 AC_ARG_WITH([osmesa-lib-name],
 349   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 350     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 351   [OSMESA_LIB=$withval],
 352   [OSMESA_LIB=OSMesa])
 353 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 354 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 355
 356 dnl
 357 dnl Mangled Mesa support
 358 dnl
 359 AC_ARG_ENABLE([mangling],
 360   [AS_HELP_STRING([--enable-mangling],
 361     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 362   [enable_mangling="${enableval}"],
 363   [enable_mangling=no]
 364 )
 365 if test "x${enable_mangling}" = "xyes" ; then
 366   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 367   GL_LIB="Mangled${GL_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([OSMESA_LIB])
 372
 373 dnl
 374 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 375 dnl
 376 AC_ARG_ENABLE([texture-float],
 377     [AS_HELP_STRING([--enable-texture-float],
 378         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 379     [enable_texture_float="$enableval"],
 380     [enable_texture_float=no]
 381 )
 382 if test "x$enable_texture_float" = xyes; then
 383     AC_MSG_WARN([Floating-point textures enabled.])
 384     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 385     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 386 fi
 387
 388 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 389 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 390 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 391 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 392 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 393 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 394 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 395
 396 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 397 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 398 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403
 404 AC_SUBST([GL_LIB_NAME])
 405 AC_SUBST([OSMESA_LIB_NAME])
 406 AC_SUBST([EGL_LIB_NAME])
 407 AC_SUBST([GLESv1_CM_LIB_NAME])
 408 AC_SUBST([GLESv2_LIB_NAME])
 409 AC_SUBST([VG_LIB_NAME])
 410 AC_SUBST([GLAPI_LIB_NAME])
 411
 412 AC_SUBST([GL_LIB_GLOB])
 413 AC_SUBST([EGL_LIB_GLOB])
 414 AC_SUBST([GLESv1_CM_LIB_GLOB])
 415 AC_SUBST([GLESv2_LIB_GLOB])
 416 AC_SUBST([VG_LIB_GLOB])
 417 AC_SUBST([GLAPI_LIB_GLOB])
 418
 419 dnl
 420 dnl Arch/platform-specific settings
 421 dnl
 422 AC_ARG_ENABLE([asm],
 423     [AS_HELP_STRING([--disable-asm],
 424         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 425     [enable_asm="$enableval"],
 426     [enable_asm=yes]
 427 )
 428 asm_arch=""
 429 MESA_ASM_FILES=""
 430 AC_MSG_CHECKING([whether to enable assembly])
 431 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 432 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 433 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 434     case "$host_cpu" in
 435     i?86 | x86_64)
 436         enable_asm=no
 437         AC_MSG_RESULT([no, cross compiling])
 438         ;;
 439     esac
 440 fi
 441 # check for supported arches
 442 if test "x$enable_asm" = xyes; then
 443     case "$host_cpu" in
 444     i?86)
 445         case "$host_os" in
 446         linux* | *freebsd* | dragonfly* | *netbsd*)
 447             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 448             ;;
 449         esac
 450         ;;
 451     x86_64)
 452         case "$host_os" in
 453         linux* | *freebsd* | dragonfly* | *netbsd*)
 454             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 455             ;;
 456         esac
 457         ;;
 458     sparc*)
 459         case "$host_os" in
 460         linux*)
 461             asm_arch=sparc
 462             ;;
 463         esac
 464         ;;
 465     esac
 466
 467     case "$asm_arch" in
 468     x86)
 469         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 470         MESA_ASM_FILES='$(X86_FILES)'
 471         AC_MSG_RESULT([yes, x86])
 472         ;;
 473     x86_64)
 474         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 475         MESA_ASM_FILES='$(X86_64_FILES)'
 476         AC_MSG_RESULT([yes, x86_64])
 477         ;;
 478     sparc)
 479         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 480         MESA_ASM_FILES='$(SPARC_FILES)'
 481         AC_MSG_RESULT([yes, sparc])
 482         ;;
 483     *)
 484         AC_MSG_RESULT([no, platform not supported])
 485         ;;
 486     esac
 487 fi
 488 AC_SUBST([MESA_ASM_FILES])
 489
 490 dnl PIC code macro
 491 MESA_PIC_FLAGS
 492
 493 dnl Check to see if dlopen is in default libraries (like Solaris, which
 494 dnl has it in libc), or if libdl is needed to get it.
 495 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 496     [AC_CHECK_LIB([dl], [dlopen],
 497        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 498 AC_SUBST([DLOPEN_LIBS])
 499
 500 dnl See if posix_memalign is available
 501 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 502
 503 dnl Check for pthreads
 504 AX_PTHREAD
 505 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 506 dnl to -pthread, which causes problems if we need -lpthread to appear in
 507 dnl pkgconfig files.
 508 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 509
 510 dnl SELinux awareness.
 511 AC_ARG_ENABLE([selinux],
 512     [AS_HELP_STRING([--enable-selinux],
 513         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 514     [MESA_SELINUX="$enableval"],
 515     [MESA_SELINUX=no])
 516 if test "x$enable_selinux" = "xyes"; then
 517     AC_CHECK_HEADER([selinux/selinux.h],[],
 518                     [AC_MSG_ERROR([SELinux headers not found])])
 519     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 520                  [AC_MSG_ERROR([SELinux library not found])])
 521     SELINUX_LIBS="-lselinux"
 522     DEFINES="$DEFINES -DMESA_SELINUX"
 523 fi
 524 AC_SUBST([SELINUX_LIBS])
 525
 526 dnl Options for APIs
 527 AC_ARG_ENABLE([opengl],
 528     [AS_HELP_STRING([--disable-opengl],
 529         [disable support for standard OpenGL API @<:@default=no@:>@])],
 530     [enable_opengl="$enableval"],
 531     [enable_opengl=yes])
 532 AC_ARG_ENABLE([gles1],
 533     [AS_HELP_STRING([--enable-gles1],
 534         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 535     [enable_gles1="$enableval"],
 536     [enable_gles1=no])
 537 AC_ARG_ENABLE([gles2],
 538     [AS_HELP_STRING([--enable-gles2],
 539         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 540     [enable_gles2="$enableval"],
 541     [enable_gles2=no])
 542 AC_ARG_ENABLE([openvg],
 543     [AS_HELP_STRING([--enable-openvg],
 544         [enable support for OpenVG API @<:@default=no@:>@])],
 545     [enable_openvg="$enableval"],
 546     [enable_openvg=no])
 547
 548 AC_ARG_ENABLE([dri],
 549     [AS_HELP_STRING([--enable-dri],
 550         [enable DRI modules @<:@default=enabled@:>@])],
 551     [enable_dri="$enableval"],
 552     [enable_dri=yes])
 553 AC_ARG_ENABLE([glx],
 554     [AS_HELP_STRING([--enable-glx],
 555         [enable GLX library @<:@default=enabled@:>@])],
 556     [enable_glx="$enableval"],
 557     [enable_glx=yes])
 558 AC_ARG_ENABLE([osmesa],
 559     [AS_HELP_STRING([--enable-osmesa],
 560         [enable OSMesa library @<:@default=disabled@:>@])],
 561     [enable_osmesa="$enableval"],
 562     [enable_osmesa=no])
 563 AC_ARG_ENABLE([egl],
 564     [AS_HELP_STRING([--disable-egl],
 565         [disable EGL library @<:@default=enabled@:>@])],
 566     [enable_egl="$enableval"],
 567     [enable_egl=yes])
 568
 569 AC_ARG_ENABLE([xorg],
 570     [AS_HELP_STRING([--enable-xorg],
 571         [enable support for X.Org DDX API @<:@default=no@:>@])],
 572     [enable_xorg="$enableval"],
 573     [enable_xorg=no])
 574 AC_ARG_ENABLE([xa],
 575     [AS_HELP_STRING([--enable-xa],
 576         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 577     [enable_xa="$enableval"],
 578     [enable_xa=no])
 579 AC_ARG_ENABLE([d3d1x],
 580     [AS_HELP_STRING([--enable-d3d1x],
 581         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 582     [enable_d3d1x="$enableval"],
 583     [enable_d3d1x=no])
 584 AC_ARG_ENABLE([gbm],
 585    [AS_HELP_STRING([--enable-gbm],
 586          [enable gbm library @<:@default=auto@:>@])],
 587    [enable_gbm="$enableval"],
 588    [enable_gbm=auto])
 589
 590 AC_ARG_ENABLE([xvmc],
 591    [AS_HELP_STRING([--enable-xvmc],
 592          [enable xvmc library @<:@default=auto@:>@])],
 593    [enable_xvmc="$enableval"],
 594    [enable_xvmc=auto])
 595 AC_ARG_ENABLE([vdpau],
 596    [AS_HELP_STRING([--enable-vdpau],
 597          [enable vdpau library @<:@default=auto@:>@])],
 598    [enable_vdpau="$enableval"],
 599    [enable_vdpau=auto])
 600 AC_ARG_ENABLE([va],
 601    [AS_HELP_STRING([--enable-va],
 602          [enable va library @<:@default=auto@:>@])],
 603    [enable_va="$enableval"],
 604    [enable_va=auto])
 605 AC_ARG_ENABLE([opencl],
 606    [AS_HELP_STRING([--enable-opencl],
 607          [enable OpenCL library @<:@default=no@:>@])],
 608    [enable_opencl="$enableval"],
 609    [enable_opencl=no])
 610 AC_ARG_ENABLE([xlib_glx],
 611     [AS_HELP_STRING([--enable-xlib-glx],
 612         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 613     [enable_xlib_glx="$enableval"],
 614     [enable_xlib_glx=no])
 615 AC_ARG_ENABLE([gallium_egl],
 616     [AS_HELP_STRING([--enable-gallium-egl],
 617         [enable optional EGL state tracker (not required
 618          for EGL support in Gallium with OpenGL and OpenGL ES)
 619          @<:@default=disable@:>@])],
 620     [enable_gallium_egl="$enableval"],
 621     [enable_gallium_egl=no])
 622 AC_ARG_ENABLE([gallium_gbm],
 623     [AS_HELP_STRING([--enable-gallium-gbm],
 624         [enable optional gbm state tracker (not required for
 625          gbm support in Gallium)
 626          @<:@default=auto@:>@])],
 627     [enable_gallium_gbm="$enableval"],
 628     [enable_gallium_gbm=auto])
 629
 630 AC_ARG_ENABLE([r600-llvm-compiler],
 631     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 632         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 633     [enable_r600_llvm="$enableval"],
 634     [enable_r600_llvm=no])
 635
 636 AC_ARG_ENABLE([gallium_tests],
 637     [AS_HELP_STRING([--enable-gallium-tests],
 638         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 639     [enable_gallium_tests="$enableval"],
 640     [enable_gallium_tests=no])
 641
 642 # Option for Gallium drivers
 643 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 644
 645 AC_ARG_WITH([gallium-drivers],
 646     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 647         [comma delimited Gallium drivers list, e.g.
 648         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 649         @<:@default=r300,r600,swrast@:>@])],
 650     [with_gallium_drivers="$withval"],
 651     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 652
 653 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 654 # here so that the script doesn't choke on an unknown driver name later.
 655 case "$with_gallium_drivers" in
 656     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 657     no) with_gallium_drivers='' ;;
 658 esac
 659
 660 if test "x$enable_opengl" = xno -a \
 661         "x$enable_gles1" = xno -a \
 662         "x$enable_gles2" = xno -a \
 663         "x$enable_openvg" = xno -a \
 664         "x$enable_xorg" = xno -a \
 665         "x$enable_xa" = xno -a \
 666         "x$enable_d3d1x" = xno -a \
 667         "x$enable_xvmc" = xno -a \
 668         "x$enable_vdpau" = xno -a \
 669         "x$enable_va" = xno -a \
 670         "x$enable_opencl" = xno; then
 671     AC_MSG_ERROR([at least one API should be enabled])
 672 fi
 673
 674 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 675 if test "x$enable_opengl" = xno -a \
 676         "x$enable_gles1" = xyes; then
 677     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 678 fi
 679
 680 if test "x$enable_opengl" = xno -a \
 681         "x$enable_gles2" = xyes; then
 682     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 683 fi
 684
 685 API_DEFINES=""
 686 if test "x$enable_opengl" = xno; then
 687     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 688 else
 689     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 690 fi
 691 if test "x$enable_gles1" = xyes; then
 692     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 693 fi
 694 if test "x$enable_gles2" = xyes; then
 695     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 696 fi
 697 AC_SUBST([API_DEFINES])
 698
 699 if test "x$enable_glx" = xno; then
 700     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 701     enable_xlib_glx=no
 702 fi
 703
 704 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 705     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 706 fi
 707
 708 # Disable GLX if DRI and Xlib-GLX are not enabled
 709 if test "x$enable_glx" = xyes -a \
 710         "x$enable_dri" = xno -a \
 711         "x$enable_xlib_glx" = xno; then
 712     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 713     enable_glx=no
 714 fi
 715
 716 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 717 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 718                                   "x$enable_osmesa" = xyes)
 719
 720 AC_ARG_ENABLE([shared-glapi],
 721     [AS_HELP_STRING([--enable-shared-glapi],
 722         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 723     [enable_shared_glapi="$enableval"],
 724     [enable_shared_glapi="$enable_dri"])
 725
 726 # Shared GLAPI is only useful for DRI
 727 if test "x$enable_dri" = xno; then
 728     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 729     enable_shared_glapi=no
 730 fi
 731
 732 # TODO: Get rid of SHARED_GLAPI variable
 733 SHARED_GLAPI="0"
 734 if test "x$enable_shared_glapi" = xyes; then
 735     SHARED_GLAPI="1"
 736     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 737     # the remap table)
 738     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 739     CORE_DIRS="mapi/shared-glapi"
 740 fi
 741 AC_SUBST([SHARED_GLAPI])
 742 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 743
 744 dnl
 745 dnl Driver specific build directories
 746 dnl
 747 SRC_DIRS="gtest"
 748 GALLIUM_DIRS="auxiliary drivers state_trackers"
 749 GALLIUM_TARGET_DIRS=""
 750 GALLIUM_WINSYS_DIRS="sw"
 751 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 752 GALLIUM_STATE_TRACKERS_DIRS=""
 753
 754 # build glapi if OpenGL is enabled
 755 if test "x$enable_opengl" = xyes; then
 756     CORE_DIRS="$CORE_DIRS mapi/glapi"
 757 fi
 758
 759 # build es1api if OpenGL ES 1.x is enabled
 760 if test "x$enable_gles1" = xyes; then
 761     CORE_DIRS="$CORE_DIRS mapi/es1api"
 762 fi
 763
 764 # build es2api if OpenGL ES 2.x is enabled
 765 if test "x$enable_gles2" = xyes; then
 766     CORE_DIRS="$CORE_DIRS mapi/es2api"
 767 fi
 768
 769 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 770 case "x$enable_opengl$enable_gles1$enable_gles2" in
 771 x*yes*)
 772     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 773     ;;
 774 esac
 775
 776 case "x$enable_glx$enable_xlib_glx" in
 777 xyesyes)
 778     DRIVER_DIRS="$DRIVER_DIRS x11"
 779     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 780     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 781     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 782     HAVE_WINSYS_XLIB="yes"
 783     ;;
 784 xyesno)
 785     # DRI-based GLX
 786     SRC_DIRS="$SRC_DIRS glx"
 787     ;;
 788 esac
 789
 790 if test "x$enable_dri" = xyes; then
 791     DRIVER_DIRS="$DRIVER_DIRS dri"
 792
 793     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 794     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 795     HAVE_ST_DRI="yes"
 796 fi
 797
 798 if test "x$enable_osmesa" = xyes; then
 799     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 800 fi
 801
 802 AC_SUBST([SRC_DIRS])
 803 AC_SUBST([DRIVER_DIRS])
 804 AC_SUBST([GALLIUM_DIRS])
 805 AC_SUBST([GALLIUM_TARGET_DIRS])
 806 AC_SUBST([GALLIUM_WINSYS_DIRS])
 807 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 808 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 809 AC_SUBST([MESA_LLVM])
 810
 811 # Check for libdrm
 812 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 813                   [have_libdrm=yes], [have_libdrm=no])
 814
 815 if test "x$enable_dri" = xyes; then
 816     # DRI must be shared, I think
 817     if test "$enable_static" = yes; then
 818         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 819     fi
 820
 821     # not a hard requirement as swrast does not depend on it
 822     if test "x$have_libdrm" = xyes; then
 823         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 824     fi
 825 fi
 826
 827 dnl Find out if X is available.
 828 PKG_CHECK_MODULES([X11], [x11])
 829
 830 dnl Try to tell the user that the --x-* options are only used when
 831 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 832 m4_divert_once([HELP_BEGIN],
 833 [These options are only used when the X libraries cannot be found by the
 834 pkg-config utility.])
 835
 836 dnl We need X for xlib and dri, so bomb now if it's not found
 837 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 838     AC_MSG_ERROR([X11 development libraries needed for GLX])
 839 fi
 840
 841 if test "x$enable_glx" = xyes; then
 842     DEFINES="$DEFINES -DUSE_XCB"
 843 fi
 844
 845 dnl Direct rendering or just indirect rendering
 846 case "$host_os" in
 847 gnu*)
 848     dnl Disable by default on GNU/Hurd
 849     driglx_direct_default="no"
 850     ;;
 851 cygwin*)
 852     dnl Disable by default on cygwin
 853     driglx_direct_default="no"
 854     ;;
 855 *)
 856     driglx_direct_default="yes"
 857     ;;
 858 esac
 859 AC_ARG_ENABLE([driglx-direct],
 860     [AS_HELP_STRING([--disable-driglx-direct],
 861         [enable direct rendering in GLX and EGL for DRI \
 862             @<:@default=auto@:>@])],
 863     [driglx_direct="$enableval"],
 864     [driglx_direct="$driglx_direct_default"])
 865
 866 dnl
 867 dnl libGL configuration per driver
 868 dnl
 869 case "x$enable_glx$enable_xlib_glx" in
 870 xyesyes)
 871     # Xlib-based GLX
 872     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 873     GL_PC_REQ_PRIV="x11 xext"
 874     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 875     GL_LIB_DEPS="$XLIBGL_LIBS"
 876     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 877     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 878     ;;
 879 xyesno)
 880     # DRI-based GLX
 881     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 882     if test x"$driglx_direct" = xyes; then
 883         if test "x$have_libdrm" != xyes; then
 884             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 885         fi
 886         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 887         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 888     fi
 889
 890     # find the DRI deps for libGL
 891     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 892
 893     # add xf86vidmode if available
 894     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 895     if test "$HAVE_XF86VIDMODE" = yes ; then
 896         dri_modules="$dri_modules xxf86vm"
 897     fi
 898
 899     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 900     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 901     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 902     GL_LIB_DEPS="$DRIGL_LIBS"
 903
 904     # need DRM libs, $PTHREAD_LIBS, etc.
 905     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 906     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 907     ;;
 908 esac
 909
 910 # This is outside the case (above) so that it is invoked even for non-GLX
 911 # builds.
 912 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 913
 914 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 915 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 916 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 917 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 918
 919 AC_SUBST([GL_LIB_DEPS])
 920 AC_SUBST([GL_PC_REQ_PRIV])
 921 AC_SUBST([GL_PC_LIB_PRIV])
 922 AC_SUBST([GL_PC_CFLAGS])
 923 AC_SUBST([DRI_PC_REQ_PRIV])
 924 AC_SUBST([GLESv1_CM_LIB_DEPS])
 925 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 926 AC_SUBST([GLESv2_LIB_DEPS])
 927 AC_SUBST([GLESv2_PC_LIB_PRIV])
 928
 929 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 930
 931 AC_SUBST([HAVE_XF86VIDMODE])
 932
 933 dnl
 934 dnl More GLX setup
 935 dnl
 936 case "x$enable_glx$enable_xlib_glx" in
 937 xyesyes)
 938     DEFINES="$DEFINES -DUSE_XSHM"
 939     ;;
 940 xyesno)
 941     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 942     if test "x$driglx_direct" = xyes; then
 943         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 944     fi
 945     ;;
 946 esac
 947
 948 dnl
 949 dnl TLS detection
 950 dnl
 951
 952 AC_ARG_ENABLE([glx-tls],
 953     [AS_HELP_STRING([--enable-glx-tls],
 954         [enable TLS support in GLX @<:@default=disabled@:>@])],
 955     [GLX_USE_TLS="$enableval"],
 956     [GLX_USE_TLS=no])
 957 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 958
 959 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 960       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 961
 962 dnl
 963 dnl More DRI setup
 964 dnl
 965 dnl Directory for DRI drivers
 966 AC_ARG_WITH([dri-driverdir],
 967     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 968         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 969     [DRI_DRIVER_INSTALL_DIR="$withval"],
 970     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 971 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 972 dnl Extra search path for DRI drivers
 973 AC_ARG_WITH([dri-searchpath],
 974     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 975         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 976     [DRI_DRIVER_SEARCH_DIR="$withval"],
 977     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 978 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 979 dnl Which drivers to build - default is chosen by platform
 980 AC_ARG_WITH([dri-drivers],
 981     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 982         [comma delimited DRI drivers list, e.g.
 983         "swrast,i965,radeon" @<:@default=auto@:>@])],
 984     [with_dri_drivers="$withval"],
 985     [with_dri_drivers=yes])
 986 if test "x$with_dri_drivers" = x; then
 987     with_dri_drivers=no
 988 fi
 989
 990 dnl If $with_dri_drivers is yes, directories will be added through
 991 dnl platform checks
 992 DRI_DIRS=""
 993 case "$with_dri_drivers" in
 994 no) ;;
 995 yes)
 996     # classic DRI drivers require FEATURE_GL to build
 997     if test "x$enable_opengl" = xyes; then
 998         DRI_DIRS="yes"
 999     fi
1000     ;;
1001 *)
1002     # verify the requested driver directories exist
1003     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1004     for driver in $dri_drivers; do
1005         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1006             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1007     done
1008     DRI_DIRS="$dri_drivers"
1009     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1010         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1011     fi
1012     ;;
1013 esac
1014
1015 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1016 if test "x$enable_dri" = xyes; then
1017     # Platform specific settings and drivers to build
1018     case "$host_os" in
1019     linux*)
1020         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1021         DEFINES="$DEFINES -DHAVE_ALIAS"
1022
1023         case "$host_cpu" in
1024         x86_64)
1025             if test "x$DRI_DIRS" = "xyes"; then
1026                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1027             fi
1028             ;;
1029         powerpc*)
1030             # Build only the drivers for cards that exist on PowerPC.
1031             if test "x$DRI_DIRS" = "xyes"; then
1032                 DRI_DIRS="r200 radeon swrast"
1033             fi
1034             ;;
1035         sparc*)
1036             # Build only the drivers for cards that exist on sparc
1037             if test "x$DRI_DIRS" = "xyes"; then
1038                 DRI_DIRS="r200 radeon swrast"
1039             fi
1040             ;;
1041         esac
1042         ;;
1043     freebsd* | dragonfly* | *netbsd*)
1044         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1045         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1046
1047         if test "x$DRI_DIRS" = "xyes"; then
1048             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1049         fi
1050         ;;
1051     gnu*)
1052         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1053         DEFINES="$DEFINES -DHAVE_ALIAS"
1054         ;;
1055     solaris*)
1056         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1057         ;;
1058     cygwin*)
1059         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1060         if test "x$DRI_DIRS" = "xyes"; then
1061             DRI_DIRS="swrast"
1062         fi
1063         ;;
1064     esac
1065
1066     # default drivers
1067     if test "x$DRI_DIRS" = "xyes"; then
1068         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1069     fi
1070
1071     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1072
1073     # Check for expat
1074     if test "x$enable_dri" = xyes; then
1075         EXPAT_INCLUDES=""
1076         EXPAT_LIB=-lexpat
1077         AC_ARG_WITH([expat],
1078             [AS_HELP_STRING([--with-expat=DIR],
1079                 [expat install directory])],[
1080             EXPAT_INCLUDES="-I$withval/include"
1081             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1082             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1083             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1084             ])
1085         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1086         save_LIBS="$LIBS"
1087         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1088             [AC_MSG_ERROR([Expat required for DRI.])])
1089         LIBS="$save_LIBS"
1090     fi
1091
1092     # if we are building any dri driver other than swrast ...
1093     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1094         # ... libdrm is required
1095         if test "x$have_libdrm" != xyes; then
1096             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1097         fi
1098         # ... and build dricommon
1099         HAVE_COMMON_DRI=yes
1100     fi
1101
1102     # put all the necessary libs together
1103     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1104     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1105 fi
1106 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1107 AC_SUBST([DRI_DIRS])
1108 AC_SUBST([EXPAT_INCLUDES])
1109 AC_SUBST([DRI_LIB_DEPS])
1110 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1111
1112 case $DRI_DIRS in
1113 *i915*|*i965*)
1114     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1115
1116     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1117         case $d in
1118         i915)
1119             HAVE_I915_DRI=yes;
1120             ;;
1121         i965)
1122             HAVE_I965_DRI=yes;
1123             ;;
1124         esac
1125     done
1126
1127     ;;
1128 esac
1129
1130 case $DRI_DIRS in
1131 *nouveau*)
1132     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1133     HAVE_NOUVEAU_DRI=yes;
1134     ;;
1135 esac
1136
1137 case $DRI_DIRS in
1138 *radeon*|*r200*)
1139     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1140
1141     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1142         case $d in
1143         radeon)
1144             HAVE_RADEON_DRI=yes;
1145             ;;
1146         r200)
1147             HAVE_R200_DRI=yes;
1148             ;;
1149         esac
1150     done
1151
1152     ;;
1153 esac
1154
1155 case $DRI_DIRS in
1156 *swrast*)
1157     HAVE_SWRAST_DRI=yes;
1158     ;;
1159 esac
1160
1161 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1162 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1163 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1164 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1165 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1166 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1167 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1168
1169 dnl
1170 dnl OSMesa configuration
1171 dnl
1172
1173 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1174 AC_ARG_WITH([osmesa-bits],
1175     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1176         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1177     [osmesa_bits="$withval"],
1178     [osmesa_bits=8])
1179 if test "x$osmesa_bits" != x8; then
1180     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1181         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1182         osmesa_bits=8
1183     fi
1184 fi
1185 case "x$osmesa_bits" in
1186 x8)
1187     OSMESA_LIB="${OSMESA_LIB}"
1188     ;;
1189 x16|x32)
1190     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1191     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1192     ;;
1193 *)
1194     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1195     ;;
1196 esac
1197
1198 if test "x$enable_osmesa" = xyes; then
1199     # only link libraries with osmesa if shared
1200     if test "$enable_static" = no; then
1201         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1202     else
1203         OSMESA_LIB_DEPS=""
1204     fi
1205     OSMESA_MESA_DEPS=""
1206     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1207 fi
1208
1209 AC_SUBST([OSMESA_LIB_DEPS])
1210 AC_SUBST([OSMESA_MESA_DEPS])
1211 AC_SUBST([OSMESA_PC_REQ])
1212 AC_SUBST([OSMESA_PC_LIB_PRIV])
1213
1214 dnl
1215 dnl gbm configuration
1216 dnl
1217 if test "x$enable_gbm" = xauto; then
1218     case "$with_egl_platforms" in
1219         *drm*)
1220             enable_gbm=yes ;;
1221          *)
1222             enable_gbm=no ;;
1223     esac
1224 fi
1225 if test "x$enable_gbm" = xyes; then
1226     SRC_DIRS="$SRC_DIRS gbm"
1227
1228     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1229                       AC_MSG_ERROR([gbm needs udev]))
1230
1231     if test "x$enable_dri" = xyes; then
1232         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1233         if test "x$enable_shared_glapi" = xno; then
1234             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1235         fi
1236     fi
1237 fi
1238 GBM_PC_REQ_PRIV="libudev"
1239 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1240 AC_SUBST([GBM_PC_REQ_PRIV])
1241 AC_SUBST([GBM_PC_LIB_PRIV])
1242
1243 dnl
1244 dnl EGL configuration
1245 dnl
1246 EGL_CLIENT_APIS=""
1247
1248 if test "x$enable_egl" = xyes; then
1249     SRC_DIRS="$SRC_DIRS egl"
1250     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1251
1252     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1253
1254     if test "$enable_static" != yes; then
1255         # build egl_glx when libGL is built
1256         if test "x$enable_glx" = xyes; then
1257             HAVE_EGL_DRIVER_GLX=1
1258         fi
1259
1260         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1261                           [have_libudev=yes],[have_libudev=no])
1262         if test "$have_libudev" = yes; then
1263             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1264         fi
1265
1266         if test "x$enable_dri" = xyes; then
1267             HAVE_EGL_DRIVER_DRI2=1
1268         fi
1269
1270     fi
1271 fi
1272 AC_SUBST([EGL_LIB_DEPS])
1273
1274 dnl
1275 dnl EGL Gallium configuration
1276 dnl
1277 if test "x$enable_gallium_egl" = xyes; then
1278     if test "x$with_gallium_drivers" = x; then
1279         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1280     fi
1281     if test "x$enable_egl" = xno; then
1282         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1283     fi
1284     if test "x$have_libdrm" != xyes; then
1285         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1286     fi
1287
1288     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1289     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1290     HAVE_ST_EGL="yes"
1291 fi
1292
1293 dnl
1294 dnl gbm Gallium configuration
1295 dnl
1296 if test "x$enable_gallium_gbm" = xauto; then
1297     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1298         yesyesyes*drm*)
1299             enable_gallium_gbm=yes ;;
1300          *)
1301             enable_gallium_gbm=no ;;
1302     esac
1303 fi
1304 if test "x$enable_gallium_gbm" = xyes; then
1305     if test "x$with_gallium_drivers" = x; then
1306         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1307     fi
1308     if test "x$enable_gbm" = xno; then
1309         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1310     fi
1311     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1312     if test "x$enable_dri" = xno; then
1313         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1314     fi
1315
1316     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1317     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1318     HAVE_ST_GBM="yes"
1319     enable_gallium_loader=yes
1320 fi
1321
1322 dnl
1323 dnl X.Org DDX configuration
1324 dnl
1325 if test "x$enable_xorg" = xyes; then
1326     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1327     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1328     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1329     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1330         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1331         HAVE_XEXTPROTO_71="no")
1332     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1333     HAVE_ST_XORG=yes
1334 fi
1335
1336 dnl
1337 dnl XA configuration
1338 dnl
1339 if test "x$enable_xa" = xyes; then
1340 AC_PROG_AWK
1341 AC_PROG_GREP
1342 AC_CHECK_PROG(NM, nm, "nm")
1343 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1344 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1345 enable_xa=no
1346 fi
1347 fi
1348 if test "x$enable_xa" = xyes; then
1349     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1350     HAVE_ST_XA=yes
1351     AC_SUBST(AWK)
1352     AC_SUBST(GREP)
1353     AC_SUBST(NM)
1354 fi
1355
1356 dnl
1357 dnl OpenVG configuration
1358 dnl
1359 VG_LIB_DEPS=""
1360
1361 if test "x$enable_openvg" = xyes; then
1362     if test "x$enable_egl" = xno; then
1363         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1364     fi
1365     if test "x$with_gallium_drivers" = x; then
1366         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1367     fi
1368     if test "x$enable_gallium_egl" = xno; then
1369         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1370     fi
1371
1372     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1373     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1374     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1375     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1376     HAVE_ST_VEGA=yes
1377     VG_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1378     AC_SUBST([VG_PC_LIB_PRIV])
1379 fi
1380
1381 dnl
1382 dnl D3D1X configuration
1383 dnl
1384
1385 if test "x$enable_d3d1x" = xyes; then
1386     if test "x$with_gallium_drivers" = x; then
1387         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1388     fi
1389
1390     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1391     HAVE_ST_D3D1X=yes
1392 fi
1393
1394 dnl
1395 dnl Gallium G3DVL configuration
1396 dnl
1397 AC_ARG_ENABLE([gallium-g3dvl],
1398     [AS_HELP_STRING([--enable-gallium-g3dvl],
1399         [build gallium g3dvl @<:@default=disabled@:>@])],
1400     [enable_gallium_g3dvl="$enableval"],
1401     [enable_gallium_g3dvl=no])
1402 if test "x$enable_gallium_g3dvl" = xyes; then
1403     if test "x$with_gallium_drivers" = x; then
1404         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1405     fi
1406
1407     if test "x$enable_xvmc" = xauto; then
1408         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1409     fi
1410
1411     if test "x$enable_vdpau" = xauto; then
1412         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1413     fi
1414
1415     if test "x$enable_va" = xauto; then
1416         #don't enable vaapi state tracker even if package exists
1417         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1418         enable_va=no
1419     fi
1420 fi
1421
1422 if test "x$enable_xvmc" = xyes; then
1423     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1424     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1425     HAVE_ST_XVMC="yes"
1426 fi
1427
1428 if test "x$enable_vdpau" = xyes; then
1429     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1430     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1431     HAVE_ST_VDPAU="yes"
1432 fi
1433
1434 if test "x$enable_va" = xyes; then
1435     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1436     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1437     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1438     HAVE_ST_VA="yes"
1439 fi
1440
1441 dnl
1442 dnl OpenCL configuration
1443 dnl
1444
1445 AC_ARG_WITH([libclc-path],
1446    [AS_HELP_STRING([--with-libclc-path],
1447          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1448    [LIBCLC_PATH="$withval"],
1449    [LIBCLC_PATH=""])
1450
1451 if test "x$LIBCLC_PATH" != x; then
1452    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1453                   Please review the updated build instructions for clover:
1454                   http://dri.freedesktop.org/wiki/GalliumCompute])
1455 fi
1456
1457
1458 AC_ARG_WITH([clang-libdir],
1459    [AS_HELP_STRING([--with-clang-libdir],
1460          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1461    [CLANG_LIBDIR="$withval"],
1462    [CLANG_LIBDIR=""])
1463
1464 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1465 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1466 AC_SUBST([LIBCLC_INCLUDEDIR])
1467 AC_SUBST([LIBCLC_LIBEXECDIR])
1468
1469 if test "x$enable_opencl" = xyes; then
1470     if test "x$with_gallium_drivers" = x; then
1471         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1472     fi
1473
1474     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1475         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1476     fi
1477
1478     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1479         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1480     fi
1481
1482     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1483     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1484     enable_gallium_loader=yes
1485 fi
1486
1487 dnl
1488 dnl Gallium configuration
1489 dnl
1490 if test "x$with_gallium_drivers" != x; then
1491     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1492 fi
1493 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1494
1495 AC_SUBST([LLVM_BINDIR])
1496 AC_SUBST([LLVM_CFLAGS])
1497 AC_SUBST([LLVM_CPPFLAGS])
1498 AC_SUBST([LLVM_CXXFLAGS])
1499 AC_SUBST([LLVM_LIBDIR])
1500 AC_SUBST([LLVM_LIBS])
1501 AC_SUBST([LLVM_LDFLAGS])
1502 AC_SUBST([LLVM_INCLUDEDIR])
1503 AC_SUBST([LLVM_VERSION])
1504 AC_SUBST([CLANG_RESOURCE_DIR])
1505
1506 case "x$enable_opengl$enable_gles1$enable_gles2" in
1507 x*yes*)
1508     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1509     ;;
1510 esac
1511
1512 AC_SUBST([VG_LIB_DEPS])
1513 AC_SUBST([EGL_CLIENT_APIS])
1514
1515 dnl
1516 dnl EGL Platforms configuration
1517 dnl
1518 AC_ARG_WITH([egl-platforms],
1519     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1520         [comma delimited native platforms libEGL supports, e.g.
1521         "x11,drm" @<:@default=auto@:>@])],
1522     [with_egl_platforms="$withval"],
1523     [if test "x$enable_egl" = xyes; then
1524         with_egl_platforms="x11"
1525     else
1526         with_egl_platforms=""
1527     fi])
1528
1529 EGL_PLATFORMS=""
1530
1531 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1532     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1533 fi
1534
1535 # Do per-EGL platform setups and checks
1536 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1537 for plat in $egl_platforms; do
1538         case "$plat" in
1539         fbdev|null)
1540                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1541                 ;;
1542
1543         wayland)
1544                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1545                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1546
1547                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1548                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1549                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1550                 ;;
1551
1552         x11)
1553                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1554                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1555                 save_LIBS="$LIBS"
1556                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1557                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1558                 LIBS="$save_LIBS"
1559                 ;;
1560
1561         drm)
1562                 test "x$enable_gbm" = "xno" &&
1563                         AC_MSG_ERROR([EGL platform drm needs gbm])
1564                 ;;
1565
1566         android|gdi)
1567                 ;;
1568
1569         *)
1570                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1571                 ;;
1572         esac
1573
1574         case "$plat$have_libudev" in
1575                 waylandno|drmno)
1576                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1577         esac
1578 done
1579
1580 # libEGL wants to default to the first platform specified in
1581 # ./configure.  parse that here.
1582 if test "x$egl_platforms" != "x"; then
1583     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1584     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1585 else
1586     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1587 fi
1588
1589 EGL_PLATFORMS="$egl_platforms"
1590
1591 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1592 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1593 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1594 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1595 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1596
1597 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1598 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1599
1600 AC_SUBST([EGL_NATIVE_PLATFORM])
1601 AC_SUBST([EGL_PLATFORMS])
1602 AC_SUBST([EGL_CFLAGS])
1603
1604 AC_ARG_WITH([egl-driver-dir],
1605     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1606                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1607     [EGL_DRIVER_INSTALL_DIR="$withval"],
1608     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1609 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1610
1611 AC_ARG_WITH([xorg-driver-dir],
1612     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1613                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1614     [XORG_DRIVER_INSTALL_DIR="$withval"],
1615     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1616 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1617
1618 AC_ARG_WITH([max-width],
1619     [AS_HELP_STRING([--with-max-width=N],
1620                     [Maximum framebuffer width (4096)])],
1621     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1622      AS_IF([test "${withval}" -gt "4096"],
1623            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1624 )
1625 AC_ARG_WITH([max-height],
1626     [AS_HELP_STRING([--with-max-height=N],
1627                     [Maximum framebuffer height (4096)])],
1628     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1629      AS_IF([test "${withval}" -gt "4096"],
1630            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1631 )
1632
1633 dnl
1634 dnl Gallium LLVM
1635 dnl
1636 AC_ARG_ENABLE([gallium-llvm],
1637     [AS_HELP_STRING([--enable-gallium-llvm],
1638         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1639     [enable_gallium_llvm="$enableval"],
1640     [enable_gallium_llvm=auto])
1641
1642 AC_ARG_WITH([llvm-shared-libs],
1643     [AS_HELP_STRING([--with-llvm-shared-libs],
1644         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1645     [with_llvm_shared_libs=yes],
1646     [with_llvm_shared_libs=no])
1647
1648 AC_ARG_WITH([llvm-prefix],
1649     [AS_HELP_STRING([--with-llvm-prefix],
1650         [Prefix for LLVM installations in non-standard locations])],
1651     [llvm_prefix="$withval"],
1652     [llvm_prefix=""])
1653
1654
1655 if test "x$with_gallium_drivers" = x; then
1656     enable_gallium_llvm=no
1657 fi
1658 if test "x$enable_gallium_llvm" = xauto; then
1659     case "$host_cpu" in
1660     i*86|x86_64) enable_gallium_llvm=yes;;
1661     esac
1662 fi
1663 if test "x$enable_gallium_llvm" = xyes; then
1664     if test "x$llvm_prefix" != x; then
1665         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1666     else
1667         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1668     fi
1669
1670     if test "x$LLVM_CONFIG" != xno; then
1671         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1672         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1673         if test "x$with_llvm_shared_libs" = xyes; then
1674             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1675             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1676         else
1677             LLVM_COMPONENTS="engine bitwriter"
1678             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1679                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1680             fi
1681             if test "x$enable_opencl" = xyes; then
1682                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1683             fi
1684             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1685         fi
1686         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1687         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1688         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1689         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1690         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1691         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1692         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1693         MESA_LLVM=1
1694
1695         dnl Check for Clang interanl headers
1696         if test "x$enable_opencl" = xyes; then
1697             if test "x$CLANG_LIBDIR" = x; then
1698                 CLANG_LIBDIR=${LLVM_LIBDIR}
1699             fi
1700             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1701             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1702                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1703         fi
1704     else
1705         MESA_LLVM=0
1706     fi
1707 else
1708     MESA_LLVM=0
1709 fi
1710
1711 dnl Directory for XVMC libs
1712 AC_ARG_WITH([xvmc-libdir],
1713     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1714         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1715     [XVMC_LIB_INSTALL_DIR="$withval"],
1716     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1717 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1718
1719 dnl
1720 dnl Gallium Tests
1721 dnl
1722 if test "x$enable_gallium_tests" = xyes; then
1723     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1724     enable_gallium_loader=yes
1725 fi
1726
1727 dnl Directory for VDPAU libs
1728 AC_ARG_WITH([vdpau-libdir],
1729     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1730         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1731     [VDPAU_LIB_INSTALL_DIR="$withval"],
1732     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1733 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1734
1735 dnl Directory for VA libs
1736 AC_ARG_WITH([va-libdir],
1737     [AS_HELP_STRING([--with-va-libdir=DIR],
1738         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1739     [VA_LIB_INSTALL_DIR="$withval"],
1740     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1741 AC_SUBST([VA_LIB_INSTALL_DIR])
1742
1743 dnl Directory for OpenCL libs
1744 AC_ARG_WITH([opencl-libdir],
1745     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1746         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1747     [OPENCL_LIB_INSTALL_DIR="$withval"],
1748     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1749 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1750
1751 dnl
1752 dnl Gallium helper functions
1753 dnl
1754 gallium_check_st() {
1755     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1756          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1757          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1758          if test "x$have_libdrm" != xyes; then
1759             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1760          fi
1761          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1762     fi
1763     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1764          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1765     fi
1766     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1767          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1768     fi
1769     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1770          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1771     fi
1772     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1773          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1774     fi
1775     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1776          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1777     fi
1778     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1779          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1780     fi
1781 }
1782
1783 gallium_require_llvm() {
1784     if test "x$MESA_LLVM" = x0; then
1785         case "$host_cpu" in
1786         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1787         esac
1788     fi
1789 }
1790
1791 gallium_require_drm_loader() {
1792     if test "x$enable_gallium_loader" = xyes; then
1793         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1794                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1795         if test "x$have_libdrm" != xyes; then
1796             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1797         fi
1798         enable_gallium_drm_loader=yes
1799     fi
1800 }
1801
1802 dnl Gallium drivers
1803 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1804 if test "x$with_gallium_drivers" != x; then
1805     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1806     for driver in $gallium_drivers; do
1807         case "x$driver" in
1808         xsvga)
1809             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1810             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1811             ;;
1812         xi915)
1813             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1814             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1815             if test "x$MESA_LLVM" = x1; then
1816                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1817             fi
1818             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1819             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1820             ;;
1821         xr300)
1822             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1823             gallium_require_llvm "Gallium R300"
1824             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1825             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1826             ;;
1827         xr600)
1828             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1829             gallium_require_drm_loader
1830             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1831             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1832                 if test "x$LLVM_VERSION" != "x3.1"; then
1833                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1834                 fi
1835                 NEED_RADEON_GALLIUM=yes;
1836             fi
1837             if test "x$enable_r600_llvm" = xyes; then
1838                 USE_R600_LLVM_COMPILER=yes;
1839             fi
1840             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1841                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1842             fi
1843             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1844             ;;
1845         xradeonsi)
1846             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1847             gallium_require_drm_loader
1848             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1849             if test "x$LLVM_VERSION" != "x3.1"; then
1850                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1851             fi
1852             NEED_RADEON_GALLIUM=yes;
1853             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1854             ;;
1855         xnouveau)
1856             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1857             gallium_require_drm_loader
1858             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1859             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1860             ;;
1861         xswrast)
1862             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1863             if test "x$MESA_LLVM" = x1; then
1864                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1865             fi
1866
1867             if test "x$HAVE_ST_DRI" = xyes; then
1868                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1869             fi
1870             if test "x$HAVE_ST_VDPAU" = xyes; then
1871                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1872             fi
1873             if test "x$HAVE_ST_XVMC" = xyes; then
1874                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1875             fi
1876             if test "x$HAVE_ST_VA" = xyes; then
1877                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1878             fi
1879             if test "x$HAVE_ST_VDPAU" = xyes ||
1880                test "x$HAVE_ST_XVMC" = xyes ||
1881                test "x$HAVE_ST_VA" = xyes; then
1882                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1883                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1884                fi
1885             fi
1886             ;;
1887         *)
1888             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1889             ;;
1890         esac
1891     done
1892 fi
1893
1894 if test "x$enable_gallium_loader" = xyes; then
1895     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1896     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1897     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1898     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1899
1900     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1901         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1902         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1903     fi
1904
1905     if test "x$enable_gallium_drm_loader" = xyes; then
1906         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1907         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1908                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1909         if test "x$pipe_loader_have_xcb" = xyes; then
1910             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1911             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1912         fi
1913     fi
1914
1915     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1916     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1917 fi
1918
1919 dnl Tell Automake which drivers to build
1920 for driver in $GALLIUM_DRIVERS_DIRS; do
1921     case "x$driver" in
1922         xgalahad)
1923             HAVE_GALAHAD_GALLIUM=yes;
1924             ;;
1925         xidentity)
1926             HAVE_IDENTITY_GALLIUM=yes;
1927             ;;
1928         xnoop)
1929             HAVE_NOOP_GALLIUM=yes;
1930             ;;
1931         *)
1932             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1933             ;;
1934     esac
1935 done
1936
1937 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1938 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1939 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1940 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1941 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1942 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1943 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1944 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1945 AC_SUBST([GALLIUM_MAKE_DIRS])
1946
1947 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1948
1949 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1950 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1951 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1952
1953 dnl prepend CORE_DIRS to SRC_DIRS
1954 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1955
1956 dnl Restore LDFLAGS and CPPFLAGS
1957 LDFLAGS="$_SAVE_LDFLAGS"
1958 CPPFLAGS="$_SAVE_CPPFLAGS"
1959
1960 dnl Add user CFLAGS and CXXFLAGS
1961 CFLAGS="$CFLAGS $USER_CFLAGS"
1962 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1963
1964 dnl Substitute the config
1965 AC_CONFIG_FILES([configs/current
1966                 Makefile
1967                 src/egl/Makefile
1968                 src/egl/drivers/Makefile
1969                 src/egl/drivers/dri2/Makefile
1970                 src/egl/drivers/glx/Makefile
1971                 src/egl/main/Makefile
1972                 src/egl/main/egl.pc
1973                 src/egl/wayland/Makefile
1974                 src/egl/wayland/wayland-drm/Makefile
1975                 src/egl/wayland/wayland-egl/Makefile
1976                 src/egl/wayland/wayland-egl/wayland-egl.pc
1977                 src/gallium/Makefile
1978                 src/gallium/auxiliary/pipe-loader/Makefile
1979                 src/gallium/drivers/Makefile
1980                 src/gallium/drivers/r300/Makefile
1981                 src/gallium/drivers/r600/Makefile
1982                 src/gallium/state_trackers/clover/Makefile
1983                 src/gallium/targets/opencl/Makefile
1984                 src/gbm/Makefile
1985                 src/gbm/main/gbm.pc
1986                 src/glsl/Makefile
1987                 src/glsl/glcpp/Makefile
1988                 src/glsl/tests/Makefile
1989                 src/glx/Makefile
1990                 src/glx/tests/Makefile
1991                 src/gtest/Makefile
1992                 src/Makefile
1993                 src/mapi/es1api/Makefile
1994                 src/mapi/es1api/glesv1_cm.pc
1995                 src/mapi/es2api/Makefile
1996                 src/mapi/es2api/glesv2.pc
1997                 src/mapi/glapi/Makefile
1998                 src/mapi/glapi/gen/Makefile
1999                 src/mapi/glapi/tests/Makefile
2000                 src/mapi/shared-glapi/Makefile
2001                 src/mapi/shared-glapi/tests/Makefile
2002                 src/mapi/vgapi/Makefile
2003                 src/mapi/vgapi/vg.pc
2004                 src/mesa/Makefile
2005                 src/mesa/gl.pc
2006                 src/mesa/drivers/Makefile
2007                 src/mesa/drivers/dri/dri.pc
2008                 src/mesa/drivers/dri/common/Makefile
2009                 src/mesa/drivers/dri/i915/Makefile
2010                 src/mesa/drivers/dri/i965/Makefile
2011                 src/mesa/drivers/dri/Makefile
2012                 src/mesa/drivers/dri/nouveau/Makefile
2013                 src/mesa/drivers/dri/r200/Makefile
2014                 src/mesa/drivers/dri/radeon/Makefile
2015                 src/mesa/drivers/dri/swrast/Makefile
2016                 src/mesa/drivers/osmesa/Makefile
2017                 src/mesa/drivers/osmesa/osmesa.pc
2018                 src/mesa/drivers/x11/Makefile
2019                 src/mesa/libdricore/Makefile
2020                 src/mesa/main/tests/Makefile
2021                 src/mesa/x86-64/Makefile
2022                 src/mesa/x86/Makefile])
2023
2024 dnl Sort the dirs alphabetically
2025 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2026 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2027 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2028 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2029 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2030
2031 AC_OUTPUT
2032
2033 dnl
2034 dnl Output some configuration info for the user
2035 dnl
2036 echo ""
2037 echo "        prefix:          $prefix"
2038 echo "        exec_prefix:     $exec_prefix"
2039 echo "        libdir:          $libdir"
2040 echo "        includedir:      $includedir"
2041
2042 dnl API info
2043 echo ""
2044 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2045 echo "        OpenVG:          $enable_openvg"
2046
2047 dnl Driver info
2048 echo ""
2049 if test "x$enable_osmesa" != xno; then
2050         echo "        OSMesa:          lib$OSMESA_LIB"
2051 else
2052         echo "        OSMesa:          no"
2053 fi
2054
2055 if test "x$enable_dri" != xno; then
2056         # cleanup the drivers var
2057         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2058         if test "x$DRI_DIRS" = x; then
2059             echo "        DRI drivers:     no"
2060         else
2061             echo "        DRI drivers:     $dri_dirs"
2062         fi
2063         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2064 fi
2065
2066 case "x$enable_glx$enable_xlib_glx" in
2067 xyesyes)
2068     echo "        GLX:             Xlib-based"
2069     ;;
2070 xyesno)
2071     echo "        GLX:             DRI-based"
2072     ;;
2073 *)
2074     echo "        GLX:             $enable_glx"
2075     ;;
2076 esac
2077
2078 dnl EGL
2079 echo ""
2080 echo "        EGL:             $enable_egl"
2081 if test "$enable_egl" = yes; then
2082     echo "        EGL platforms:   $EGL_PLATFORMS"
2083
2084     egl_drivers=""
2085     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2086         egl_drivers="$egl_drivers builtin:egl_glx"
2087     fi
2088     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2089         egl_drivers="$egl_drivers builtin:egl_dri2"
2090     fi
2091
2092     if test "x$HAVE_ST_EGL" = xyes; then
2093         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2094         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2095     else
2096         echo "        EGL drivers:    $egl_drivers"
2097     fi
2098 fi
2099
2100 echo ""
2101 if test "x$MESA_LLVM" = x1; then
2102     echo "        llvm:            yes"
2103     echo "        llvm-config:     $LLVM_CONFIG"
2104     echo "        llvm-version:    $LLVM_VERSION"
2105 else
2106     echo "        llvm:            no"
2107 fi
2108
2109 echo ""
2110 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2111     echo "        Gallium:         yes"
2112     echo "        Gallium dirs:    $GALLIUM_DIRS"
2113     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2114     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2115     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2116     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2117 else
2118     echo "        Gallium:         no"
2119 fi
2120
2121
2122 dnl Libraries
2123 echo ""
2124 echo "        Shared libs:     $enable_shared"
2125 echo "        Static libs:     $enable_static"
2126 echo "        Shared-glapi:    $enable_shared_glapi"
2127
2128 dnl Compiler options
2129 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2130 cflags=`echo $CFLAGS $PIC_FLAGS | \
2131     $SED 's/^ *//;s/  */ /;s/ *$//'`
2132 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2133     $SED 's/^ *//;s/  */ /;s/ *$//'`
2134 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2135 echo ""
2136 echo "        CFLAGS:          $cflags"
2137 echo "        CXXFLAGS:        $cxxflags"
2138 echo "        Macros:          $defines"
2139 echo ""
2140 echo "        PYTHON2:         $PYTHON2"
2141
2142 echo ""
2143 echo "        Run '${MAKE-make}' to build Mesa"
2144 echo ""