configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.10.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_CVS="no", GST_CVS="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl our libraries and install dirs use major.minor as a version
  32 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  33 dnl we override it here for release candidates for a new series
  34 GST_MAJORMINOR=0.10
  35 AC_SUBST(GST_MAJORMINOR)
  36 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  37   [library major.minor version])
  38
  39 dnl CURRENT, REVISION, AGE
  40 dnl - library source changed -> increment REVISION
  41 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  42 dnl - interfaces added -> increment AGE
  43 dnl - interfaces removed -> AGE = 0
  44 dnl sets GST_LT_LDFLAGS
  45 AS_LIBTOOL(GST, 9, 0, 9)
  46
  47 dnl FIXME: this macro doesn't actually work;
  48 dnl the generated libtool script has no support for the listed tags.
  49 dnl So this needs to be fixed first if we want to use this
  50 dnl AS_LIBTOOL_TAGS
  51
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  61
  62 dnl set up gettext
  63 dnl the version check needs to stay here because autopoint greps for it
  64 AM_GNU_GETTEXT_VERSION([0.11.5])
  65 AM_GNU_GETTEXT([external])
  66 GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  67
  68 dnl *** check for arguments to configure ***
  69
  70 dnl subsystems - can influence other decisions so needs to be high up
  71 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  72 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  73 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  74 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  75 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  76 dnl define a substitution to use in docs/gst/gstreamer.types
  77 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  78 then
  79   GST_LOADSAVE_DOC_TYPES="%"
  80 else
  81   GST_LOADSAVE_DOC_TYPES=
  82 fi
  83 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  84 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  85 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  86 if test "x$GST_DISABLE_PARSE" = xyes; then
  87   AC_DEFINE(GST_DISABLE_PARSE, 1,
  88     [Define if pipeline parsing code is disabled])
  89 fi
  90 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  91 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  92 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  93 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  94 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  95 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  96 dnl define a substitution to use in docs/gst/gstreamer.types
  97 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  98 then
  99   GST_REGISTRY_DOC_TYPES="%"
 100 else
 101   GST_REGISTRY_DOC_TYPES=
 102 fi
 103 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 104 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 105 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 106 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 107 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 108 GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 109 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 110 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 111 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 112 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 113 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 114
 115 GST_ARG_DEBUG
 116 GST_ARG_PROFILING
 117 GST_ARG_VALGRIND
 118 GST_ARG_GCOV
 119
 120 GST_ARG_EXAMPLES
 121
 122 GST_ARG_WITH_PKG_CONFIG_PATH
 123 GST_ARG_WITH_PACKAGE_NAME
 124 GST_ARG_WITH_PACKAGE_ORIGIN
 125
 126 dnl use a cache dir for storing element registry info.
 127 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 128
 129 AC_ARG_WITH(cachedir,
 130   AC_HELP_STRING([--with-cachedir],
 131     [specify path to use for plugin and command completion registries]),
 132   [
 133     case "${withval}" in
 134       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 135       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 136       *)   GST_CACHE_DIR="${withval}" ;;
 137     esac
 138   ],
 139   [:]) dnl Default value
 140
 141 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 142 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 143 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 144
 145 dnl building of tests
 146 AC_ARG_ENABLE(tests,
 147   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 148   [
 149     case "${enableval}" in
 150       yes) BUILD_TESTS=yes ;;
 151       no)  BUILD_TESTS=no ;;
 152       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 153     esac
 154   ],
 155 [BUILD_TESTS=yes]) dnl Default value
 156 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 157
 158 dnl tests known to fail
 159 AC_ARG_ENABLE(failing-tests,
 160   AC_HELP_STRING([--disable-failing-tests],
 161     [disable building tests known to fail]),
 162   [
 163     case "${enableval}" in
 164       yes) BUILD_FAILING_TESTS=yes ;;
 165       no)  BUILD_FAILING_TESTS=no ;;
 166       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 167     esac
 168   ],
 169   [BUILD_FAILING_TESTS=no]) dnl Default value
 170 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 171 if test x$BUILD_FAILING_TESTS = xyes; then
 172   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 173 else
 174   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 175 fi
 176
 177 dnl poison destroyed objects
 178 AC_ARG_ENABLE(poisoning,
 179   AC_HELP_STRING([--enable-poisoning],
 180     [enable poisoning of deallocated objects]),
 181   [
 182     case "${enableval}" in
 183       yes) USE_POISONING=yes ;;
 184       no)  USE_POISONING=no ;;
 185       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 186     esac
 187   ],
 188   [USE_POISONING=no]) dnl Default value
 189 if test "x$USE_POISONING" = xyes; then
 190   AC_DEFINE(USE_POISONING, 1,
 191     [Define if we should poison deallocated memory])
 192 fi
 193
 194 dnl *** checks for platform ***
 195
 196 dnl * hardware/architecture *
 197
 198 dnl common/m4/gst-arch.m4
 199 dnl check CPU type
 200 GST_ARCH
 201 dnl substitution for win32/common/config.h
 202 HOST_CPU=$host_cpu
 203 AC_SUBST(HOST_CPU)
 204
 205 dnl common/m4/gst-arch.m4
 206 dnl check for unaligned access
 207 GST_UNALIGNED_ACCESS
 208 dnl create a configure variable for gst/gstconfig.h
 209 if test x${as_cv_unaligned_access} = xyes ; then
 210   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 211 else
 212   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 213 fi
 214 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 215
 216 dnl * software *
 217
 218 dnl check for large file support
 219 dnl affected plugins must include config.h
 220 AC_SYS_LARGEFILE
 221
 222 dnl HAVE_WIN32 currently means "disable POSIXisms".
 223 case "$host" in
 224   *-*-mingw*)
 225     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 226     ;;
 227   *)
 228     ;;
 229 esac
 230
 231 dnl *** checks for programs ***
 232
 233 dnl find a compiler
 234 AC_PROG_CC
 235
 236 dnl find an assembler
 237 AM_PROG_AS
 238
 239 dnl Perl is used in building documentation and in the version checks
 240 AC_PATH_PROG(PERL_PATH, perl, no)
 241 if test x$PERL_PATH = xno; then
 242   AC_MSG_ERROR(Could not find perl)
 243 fi
 244
 245 dnl we require flex and bison for building the parser
 246 GST_BISON_CHECK
 247 GST_FLEX_CHECK
 248
 249 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 250 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 251
 252 dnl check for documentation tools
 253 GST_DOCBOOK_CHECK
 254 GTK_DOC_CHECK([1.3])
 255 AS_PATH_PYTHON([2.1])
 256 GST_PLUGIN_DOCS([1.3],[2.1])
 257
 258 dnl *** checks for libraries ***
 259
 260 dnl For interactive UNIX (a Sun thing)
 261 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 262 AC_ISC_POSIX
 263
 264 dnl *** checks for header files ***
 265
 266 dnl check if we have ANSI C header files
 267 AC_HEADER_STDC
 268
 269 dnl Check for ucontext.h
 270 AC_CHECK_HEADERS([ucontext.h])
 271 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 272 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 273 AC_CHECK_HEADERS([process.h])
 274
 275 dnl *** checks for types/defines ***
 276
 277 dnl *** checks for structures ***
 278
 279 dnl *** checks for compiler characteristics ***
 280
 281 dnl make sure we can use "inline" from C code
 282 AC_C_INLINE
 283
 284 OPT_CFLAGS=
 285 dnl Check for some compiler flags that optimize our code.
 286 if test "x$GCC" = xyes; then
 287   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 288 fi
 289
 290 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 291 dnl flag
 292 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 293 dnl symbolic register names in inline asm
 294 if test x$HAVE_CPU_PPC = xyes ; then
 295   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 296     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 297 fi
 298
 299 dnl *** checks for library functions ***
 300
 301 AC_CHECK_FUNCS([sigaction])
 302
 303 dnl we use fork in the registry code
 304 AC_CHECK_FUNCS([fork])
 305
 306 dnl check for fseeko()
 307 AC_FUNC_FSEEKO
 308 dnl check for ftello()
 309 AC_CHECK_FUNCS([ftello])
 310
 311 AC_CHECK_FUNCS([fgetpos])
 312 AC_CHECK_FUNCS([fsetpos])
 313
 314 dnl check for mmap()
 315 AC_FUNC_MMAP
 316 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 317
 318 dnl Check for a way to display the function name in debug output
 319 GST_CHECK_FUNCTION
 320
 321 dnl test for register_printf_function
 322 AC_CHECK_FUNC(register_printf_function,
 323   [
 324     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 325     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 326     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 327     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 328       [Defined if we have register_printf_function ()])
 329   ], [
 330     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 331     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 332     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 333   ]
 334 )
 335 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 336 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 337 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 338
 339 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 340 save_cflags="$CFLAGS"
 341 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 342 AC_CHECK_LIB(dl, dladdr,
 343    AC_DEFINE(HAVE_DLADDR, 1,
 344              [Defined if we have dladdr ()]))
 345 CFLAGS="$save_cflags"
 346
 347 dnl check for inet_aton()
 348 save_libs="$LIBS"
 349 AC_CHECK_FUNC(inet_aton, ,
 350    AC_CHECK_LIB(nsl, inet_aton, ,
 351       AC_CHECK_LIB(socket, inet_aton, ,
 352          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 353 INET_ATON_LIBS=$LIBS
 354 AC_SUBST(INET_ATON_LIBS)
 355 LIBS="$save_libs"
 356
 357 dnl *** checks for dependancy libraries ***
 358
 359 dnl GLib
 360
 361 GST_GLIB_CHECK([2.8])
 362
 363 dnl Guess we need to keep this around until 0.11
 364 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 365 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 366
 367 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 368 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 369
 370 dnl libxml 2, which is/should be optional (FIXME)
 371 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 372    test "x$GST_DISABLE_REGISTRY" = "xyes"
 373 then
 374   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 375 else
 376   dnl check for libxml2 with minimum req version
 377   GST_LIBXML2_CHECK(2.4.9)
 378 fi
 379
 380 dnl check for "check", unit testing library/header
 381 AM_PATH_CHECK(0.9.2,
 382     [
 383         HAVE_CHECK=yes
 384         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 385         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 386     ],
 387     HAVE_CHECK=no)
 388 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 389
 390 dnl *** set variables based on configure arguments
 391
 392 dnl set license and copyright notice
 393 GST_LICENSE="LGPL"
 394 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 395 AC_SUBST(GST_LICENSE)
 396
 397 dnl define LIBDIR so we can inform people where we live
 398 AS_AC_EXPAND(LIBDIR, $libdir)
 399 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 400
 401 dnl set location of plugin directory
 402 GST_SET_PLUGINDIR
 403
 404 dnl FIXME: add LIBXML_PKG here
 405 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 406 AC_SUBST(GST_PKG_DEPS)
 407
 408 dnl define an ERROR_CFLAGS Makefile variable
 409 GST_SET_ERROR_CFLAGS($GST_CVS)
 410
 411 dnl define correct level for debugging messages
 412 GST_SET_LEVEL_DEFAULT($GST_CVS)
 413
 414 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 415
 416 dnl Overview:
 417 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 418 dnl GST_ALL_*:          vars shared by all built objects
 419 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 420 dnl GST_OBJ_*:          additional vars to link to the core library
 421 dnl                     include GST_ALL_*
 422 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 423 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 424
 425 dnl GST_OPTION_CFLAGS
 426 if test "x$USE_DEBUG" = xyes; then
 427    PROFILE_CFLAGS="-g"
 428 fi
 429 AC_SUBST(PROFILE_CFLAGS)
 430
 431 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 432 # functionality from the API that gstreamer uses
 433 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 434 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 435 AC_SUBST(DEPRECATED_CFLAGS)
 436
 437 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 438 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 439 AC_SUBST(GST_OPTION_CFLAGS)
 440
 441 dnl GST_ALL_*
 442 dnl vars common to for all internal objects (core libs, elements, applications)
 443 dnl CFLAGS:
 444 dnl - XML needs to be added because xmlPtr is used in core
 445 dnl - src and build dirs need to be added because every piece that gets built
 446 dnl   will need the GStreamer source and generated headers
 447 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 448 dnl       from LibXML except for in the core library
 449 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 450 dnl FIXME: check if LTLIBINTL is needed everywhere
 451 dnl I presume it is given that it contains the symbols that _() stuff maps to
 452 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 453 dnl LDFLAGS really should only contain flags, not libs - they get added before
 454 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 455 GST_ALL_LDFLAGS="-no-undefined"
 456
 457 AC_SUBST(GST_ALL_CFLAGS)
 458 AC_SUBST(GST_ALL_LIBS)
 459 AC_SUBST(GST_ALL_LDFLAGS)
 460
 461 dnl GST_LIB_LDFLAGS
 462 dnl linker flags shared by all libraries
 463 dnl LDFLAGS modifier defining exported symbols from built libraries
 464 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 465 AC_SUBST(GST_LIB_LDFLAGS)
 466
 467 dnl GST_OBJ_*
 468 dnl default vars for all internal objects built on libgstreamer
 469 dnl includes GST_ALL_*
 470 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 471 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 472 AC_SUBST(GST_OBJ_CFLAGS)
 473 AC_SUBST(GST_OBJ_LIBS)
 474
 475 dnl GST_PLUGIN_LDFLAGS
 476 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 477 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 478 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 479
 480 AC_CONFIG_FILES(
 481 Makefile
 482 gst/Makefile
 483 gst/gstconfig.h
 484 gst/gstversion.h
 485 gst/parse/Makefile
 486 libs/Makefile
 487 libs/gst/Makefile
 488 libs/gst/base/Makefile
 489 libs/gst/check/Makefile
 490 libs/gst/controller/Makefile
 491 libs/gst/dataprotocol/Makefile
 492 libs/gst/net/Makefile
 493 plugins/Makefile
 494 plugins/indexers/Makefile
 495 plugins/elements/Makefile
 496 po/Makefile.in
 497 tests/Makefile
 498 tests/benchmarks/Makefile
 499 tests/check/Makefile
 500 tests/misc/Makefile
 501 tests/examples/Makefile
 502 tests/examples/adapter/Makefile
 503 tests/examples/controller/Makefile
 504 tests/examples/helloworld/Makefile
 505 tests/examples/launch/Makefile
 506 tests/examples/manual/Makefile
 507 tests/examples/metadata/Makefile
 508 tests/examples/queue/Makefile
 509 tests/examples/typefind/Makefile
 510 tests/examples/xml/Makefile
 511 tools/Makefile
 512 common/Makefile
 513 common/m4/Makefile
 514 docs/Makefile
 515 docs/design/Makefile
 516 docs/faq/Makefile
 517 docs/gst/Makefile
 518 docs/gst/gstreamer.types
 519 docs/libs/Makefile
 520 docs/plugins/Makefile
 521 docs/manual/Makefile
 522 docs/pwg/Makefile
 523 docs/slides/Makefile
 524 docs/xsl/Makefile
 525 docs/version.entities
 526 win32/common/config.h
 527 pkgconfig/Makefile
 528 stamp.h
 529 pkgconfig/gstreamer.pc
 530 pkgconfig/gstreamer-uninstalled.pc
 531 pkgconfig/gstreamer-base.pc
 532 pkgconfig/gstreamer-base-uninstalled.pc
 533 pkgconfig/gstreamer-check.pc
 534 pkgconfig/gstreamer-check-uninstalled.pc
 535 pkgconfig/gstreamer-controller.pc
 536 pkgconfig/gstreamer-controller-uninstalled.pc
 537 pkgconfig/gstreamer-dataprotocol.pc
 538 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 539 pkgconfig/gstreamer-net.pc
 540 pkgconfig/gstreamer-net-uninstalled.pc
 541 gst-element-check.m4
 542 gstreamer.spec
 543 )
 544
 545 AC_OUTPUT