configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 # 2004, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_INIT([GNU Automake], [1.11a], [bug-automake@gnu.org])
  20
  21 m4_ifndef([AC_PACKAGE_URL],
  22           [AC_SUBST([PACKAGE_URL], [http://www.gnu.org/software/automake/])])
  23
  24 AC_CONFIG_SRCDIR(automake.in)
  25 AC_CONFIG_AUX_DIR(lib)
  26
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by `missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 AM_INIT_AUTOMAKE([1.10a dist-bzip2 filename-length-max=99 color-tests
  40                   parallel-tests silent-rules])
  41
  42 # The API version is the base version.  We must guarantee
  43 # compatibility for all releases with the same API version.
  44 # Our current rule is that:
  45 # * All releases, including the prereleases, in an X.Y series
  46 #   are compatible.  So 1.5.1c is compatible with 1.5.
  47 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  48 #   aren't the same.
  49 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  50 AC_SUBST([APIVERSION])
  51
  52 # A versioned directory, defined here for convenience.
  53 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  54
  55 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  56 # hence `.' is really what we want for perllibdir, libdir, and acdir.
  57 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  58 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  59
  60 AC_PATH_PROG(PERL, perl)
  61 if test -z "$PERL"; then
  62    AC_MSG_ERROR([perl not found])
  63 fi
  64 $PERL -e 'require 5.006;' || {
  65    AC_MSG_ERROR(
  66 [perl 5.6 or better is required; perl 5.8.2 or better
  67 is recommended.  If you have several perl versions
  68 installed, select the one Automake should use using
  69   ./configure PERL=/path/to/perl])
  70 }
  71
  72 # We require ithreads support, and version 5.7.2 for CLONE.
  73 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  74 [if $PERL -e '
  75     require 5.007_002;
  76     use Config;
  77     if ($Config{useithreads})
  78       {
  79         require threads;
  80         import threads;
  81         require Thread::Queue;
  82         import Thread::Queue;
  83         exit 0;
  84       }
  85     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  86 then
  87   am_cv_prog_PERL_ithreads=yes
  88 else
  89   am_cv_prog_PERL_ithreads=no
  90 fi])
  91 if test $am_cv_prog_PERL_ithreads = yes; then
  92   PERL_THREADS=1;
  93 else
  94   PERL_THREADS=0;
  95 fi
  96 AC_SUBST([PERL_THREADS])
  97
  98 # The test suite will skip some tests if tex is absent.
  99 AC_CHECK_PROG([TEX], [tex], [tex])
 100
 101 # Generate man pages.
 102 AM_MISSING_PROG([HELP2MAN], [help2man])
 103
 104 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 105 # deletion of any files created (such as those added to
 106 # autom4te.cache).  We used to perform only the last of the three
 107 # following tests, but some users were unable to figure out that their
 108 # installation was broken since --version appeared to work.
 109
 110 required_autoconf_version=2.62
 111 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 112 [if AM_RUN_LOG([eval $am_AUTOCONF --version]);
 113 then
 114   am_cv_autoconf_installed=yes
 115 else
 116   am_cv_autoconf_installed=no
 117 fi])
 118 if test "$am_cv_autoconf_installed" = no; then
 119   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 120     Please make sure it is installed and in your PATH.])
 121 fi
 122
 123 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 124 [mkdir conftest
 125 echo 'AC''_INIT' > conftest/conftest.ac
 126 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
 127 then
 128   am_cv_autoconf_works=yes
 129 else
 130   am_cv_autoconf_works=no
 131 fi
 132 rm -rf conftest])
 133 if test "$am_cv_autoconf_works" = no; then
 134   AC_MSG_ERROR([The installed version of autoconf does not work.
 135     Please check config.log for error messages before this one.])
 136 fi
 137
 138 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 139 [mkdir conftest
 140 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 141 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 142 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
 143 then
 144   am_cv_autoconf_version=yes
 145 else
 146   am_cv_autoconf_version=no
 147 fi
 148 rm -rf conftest])
 149 if test "$am_cv_autoconf_version" = no; then
 150   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 151 fi
 152
 153 # Test for ln.  We need use it to install the versioned binaries.
 154 AC_MSG_CHECKING([whether ln works])
 155 AC_CACHE_VAL([am_cv_prog_ln], [
 156 rm -f conftest conftest.file
 157 : >conftest.file
 158 if ln conftest.file conftest 2>/dev/null; then
 159   am_cv_prog_ln=ln
 160 else
 161   am_cv_prog_ln='cp -p'
 162 fi
 163 rm -f conftest conftest.file])
 164 AC_SUBST([LN], [$am_cv_prog_ln])
 165 result=no
 166 test "x$am_cv_prog_ln" = xln && result=yes
 167 AC_MSG_RESULT([$result])
 168
 169 # The amount we should wait after modifying files depends on the platform.
 170 # On Windows '95, '98 and ME, files modifications have 2-seconds
 171 # granularity and can be up to 3 seconds in the future w.r.t. the
 172 # system clock.  When it is important to ensure one file is older
 173 # than another we wait at least 5 seconds between creations.
 174 case $build in
 175   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 176   *)               MODIFICATION_DELAY=2;;
 177 esac
 178 AC_SUBST([MODIFICATION_DELAY])
 179
 180 # Test for things needed by the test suite.
 181 AC_PROG_EGREP
 182 AC_PROG_FGREP
 183
 184 AC_CACHE_CHECK([whether /bin/sh has working 'set -e' with exit trap],
 185 [am_cv_sh_errexit_works],
 186 [if /bin/sh -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 187 then
 188   am_cv_sh_errexit_works=yes
 189 else
 190   am_cv_sh_errexit_works=no
 191 fi
 192 ])
 193 if test $am_cv_sh_errexit_works = no; then
 194   AC_MSG_WARN([`${MAKE-make} check' will leave leftover directories tests/*.dir])
 195   AC_MSG_WARN([you can clean them up manually using `${MAKE-make} clean' or])
 196   AC_MSG_WARN([`cd tests && ${MAKE-make} clean-local-check'])
 197   dnl restore font-lock: `
 198 fi
 199 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 200
 201 AC_CONFIG_FILES([
 202   Makefile
 203   doc/Makefile
 204   lib/Automake/Makefile
 205   lib/Automake/tests/Makefile
 206   lib/Makefile
 207   lib/am/Makefile
 208   m4/Makefile
 209   tests/Makefile
 210   tests/defs-static
 211 ])
 212 AC_CONFIG_LINKS([tests/defs:tests/defs])
 213 AC_CONFIG_FILES([tests/aclocal-${APIVERSION}:tests/aclocal.in],
 214                 [chmod +x tests/aclocal-${APIVERSION}],
 215                 [APIVERSION=$APIVERSION])
 216 AC_CONFIG_FILES([tests/automake-${APIVERSION}:tests/automake.in],
 217                 [chmod +x tests/automake-${APIVERSION}])
 218
 219 AC_OUTPUT