configure.ac

   1 dnl *******************************************
   2 dnl *** Initialize automake and set version ***
   3 dnl *******************************************
   4
   5 AC_PREREQ(2.63)
   6 AC_INIT([libsoup],[2.39.3],[http://bugzilla.gnome.org/enter_bug.cgi?product=libsoup])
   7 AC_CONFIG_SRCDIR([libsoup-2.4.pc.in])
   8 AC_CONFIG_MACRO_DIR([m4])
   9
  10 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz -Wno-portability])
  11 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  12
  13 AC_PROG_MAKE_SET
  14
  15 SOUP_API_VERSION=2.4
  16 AC_SUBST(SOUP_API_VERSION)
  17
  18 # Increment on interface addition. Reset on removal.
  19 SOUP_AGE=5
  20
  21 # Increment on interface add, remove, or change.
  22 SOUP_CURRENT=6
  23
  24 # Increment on source change. Reset when CURRENT changes.
  25 SOUP_REVISION=0
  26
  27 AC_SUBST(SOUP_CURRENT)
  28 AC_SUBST(SOUP_REVISION)
  29 AC_SUBST(SOUP_AGE)
  30
  31 dnl ***************************
  32 dnl *** Set debugging flags ***
  33 dnl ***************************
  34
  35 debug_default=minimum
  36
  37 # Declare --enable-* args and collect ac_help strings
  38 AC_ARG_ENABLE(debug,
  39               AS_HELP_STRING([--enable-debug=[no/minimum/yes]],
  40                              [turn on debugging (default=$debug_default)]),,
  41               enable_debug=$debug_default)
  42
  43 # Set the debug flags
  44 if test "x$enable_debug" = "xyes"; then
  45         test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  46         SOUP_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
  47 else
  48         if test "x$enable_debug" = "xno"; then
  49                 SOUP_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
  50         fi
  51 fi
  52
  53 AC_SUBST(SOUP_DEBUG_FLAGS)
  54
  55 # Set the maintainer flags
  56 #if test -d .git; then
  57 #       SOUP_MAINTAINER_FLAGS="-DG_DISABLE_DEPRECATED"
  58 #fi
  59 AC_SUBST(SOUP_MAINTAINER_FLAGS)
  60
  61 dnl ***************************
  62 dnl *** Checks for programs ***
  63 dnl ***************************
  64
  65 AC_PROG_CC
  66 AC_PROG_INSTALL
  67
  68 # Initialize libtool
  69 LT_INIT([win32-dll])
  70
  71 dnl ***********************
  72 dnl *** Checks for glib ***
  73 dnl ***********************
  74
  75 GLIB_REQUIRED=2.33.1
  76 AM_PATH_GLIB_2_0($GLIB_REQUIRED,,,gobject gio)
  77 if test "$GLIB_LIBS" = ""; then
  78    AC_MSG_ERROR(GLIB $GLIB_REQUIRED or later is required to build libsoup)
  79 fi
  80 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_34"
  81
  82 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
  83 AC_SUBST(GLIB_MAKEFILE)
  84
  85 PKG_CHECK_MODULES(XML, libxml-2.0)
  86 AC_SUBST(XML_CFLAGS)
  87 AC_SUBST(XML_LIBS)
  88
  89 dnl ***********************
  90 dnl *** Check for Win32 ***
  91 dnl ***********************
  92
  93 AC_MSG_CHECKING([for Win32])
  94 case "$host" in
  95   *-*-mingw*)
  96     os_win32=yes
  97     CFLAGS="$CFLAGS -D_REENTRANT"
  98     ;;
  99   *)
 100     os_win32=no
 101     ;;
 102 esac
 103 AC_MSG_RESULT([$os_win32])
 104 AM_CONDITIONAL(OS_WIN32, [test $os_win32 = yes])
 105
 106 dnl ************************
 107 dnl *** gettext/intltool ***
 108 dnl ************************
 109 IT_PROG_INTLTOOL([0.35.0])
 110 GETTEXT_PACKAGE=libsoup
 111 AC_SUBST([GETTEXT_PACKAGE])
 112 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[The gettext domain name])
 113 AM_GLIB_GNU_GETTEXT
 114
 115 dnl *******************
 116 dnl *** Misc checks ***
 117 dnl *******************
 118 AC_CHECK_FUNCS(gmtime_r)
 119 AC_CHECK_FUNCS(mmap)
 120 AC_CHECK_FUNC(socket, , AC_CHECK_LIB(socket, socket))
 121
 122 dnl *********************
 123 dnl *** GNOME support ***
 124 dnl *********************
 125 AC_MSG_CHECKING(whether to build libsoup-gnome)
 126 AC_ARG_WITH(gnome,
 127             AS_HELP_STRING([--without-gnome], [Do not build libsoup-gnome]),
 128             :, [if test $os_win32 = yes; then with_gnome=no; else with_gnome=yes; fi])
 129 AC_MSG_RESULT($with_gnome)
 130
 131 if test $with_gnome != no -a $os_win32 != yes; then
 132         PKG_CHECK_MODULES(GNOME_KEYRING, gnome-keyring-1, :,
 133                           AC_MSG_ERROR(
 134 [Could not find gnome-keyring devel files.
 135 Configure with --without-gnome if you wish to build only libsoup
 136 without GNOME-specific features.]))
 137 fi
 138 AC_SUBST(GNOME_KEYRING_CFLAGS)
 139 AC_SUBST(GNOME_KEYRING_LIBS)
 140
 141 AM_CONDITIONAL(BUILD_LIBSOUP_GNOME, test $with_gnome != no)
 142
 143 if test $with_gnome != no; then
 144         AC_DEFINE(HAVE_GNOME, 1, [Defined if GNOME support is enabled])
 145
 146         PKG_CHECK_MODULES(SQLITE, sqlite3, :, [AC_MSG_ERROR(dnl
 147 [Could not find sqlite3 devel files:
 148
 149 $SQLITE_PKG_ERRORS
 150
 151 Pass "--without-gnome" to configure if you want to build libsoup
 152 without GNOME support.])])
 153 fi
 154 AC_SUBST(HAVE_GNOME)
 155 AC_SUBST(SQLITE_CFLAGS)
 156 AC_SUBST(SQLITE_LIBS)
 157
 158 dnl *****************************
 159 dnl *** gobject-introspection ***
 160 dnl *****************************
 161 GOBJECT_INTROSPECTION_CHECK([0.9.5])
 162
 163 AC_MSG_CHECKING([for glib-networking (glib TLS implementation)])
 164 save_CFLAGS="$CFLAGS"
 165 save_LIBS="$LIBS"
 166 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 167 LIBS="$LIBS $GLIB_LIBS"
 168 AC_RUN_IFELSE([AC_LANG_PROGRAM([#include <gio/gio.h>],
 169                                [g_type_init (); return !g_tls_backend_supports_tls (g_tls_backend_get_default ());])],
 170               [have_glib_networking=yes],
 171               [have_glib_networking=no],
 172               [have_glib_networking="unknown (cross-compiling)"])
 173 CFLAGS="$save_CFLAGS"
 174 LIBS="$save_LIBS"
 175 AC_MSG_RESULT($have_glib_networking)
 176
 177 AC_ARG_ENABLE(tls-check,
 178               AS_HELP_STRING([--disable-tls-check], [Don't error out if glib-networking is unavailable]))
 179 if test "$enable_tls_check" != "no" -a "$have_glib_networking" = "no"; then
 180         AC_MSG_ERROR([libsoup requires glib-networking for TLS support.
 181
 182 If you are building a package, you can pass --disable-tls-check to
 183 allow building libsoup anyway (since glib-networking is not actually
 184 required at compile time), but you should be sure to add a runtime
 185 dependency on it.])
 186 fi
 187
 188 dnl ******************************
 189 dnl *** Stuff for regression tests
 190 dnl ******************************
 191 AC_MSG_NOTICE([checking for programs needed for regression tests])
 192 MISSING_REGRESSION_TEST_PACKAGES=""
 193
 194 if test "$have_glib_networking" = "no"; then
 195         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES glib-networking"
 196 fi
 197
 198 AC_ARG_WITH(apache-httpd,
 199             AS_HELP_STRING([--with-apache-httpd], [Path to apache httpd (for tests)]),
 200             APACHE_HTTPD="$withval",
 201             [AC_PATH_PROGS(APACHE_HTTPD, httpd2 httpd apache2 apache, no, ${PATH}:/usr/sbin)])
 202 if test "$APACHE_HTTPD" != "no"; then
 203     AC_MSG_CHECKING([Apache version])
 204     apache_version=`$APACHE_HTTPD -v 2>/dev/null | sed -ne 's/Server version: Apache\///p'`
 205     case $apache_version in
 206     2.2.*)
 207         AC_MSG_RESULT([$apache_version (ok)])
 208         ;;
 209     *)
 210         AC_MSG_RESULT([$apache_version (ignoring)])
 211         APACHE_HTTPD="no"
 212         ;;
 213     esac
 214 fi
 215 AC_SUBST(APACHE_HTTPD)
 216 AC_DEFINE_UNQUOTED(APACHE_HTTPD, "$APACHE_HTTPD", [Apache httpd])
 217
 218 if test "$APACHE_HTTPD" != "no"; then
 219     AC_MSG_CHECKING([for Apache module directory])
 220     AC_ARG_WITH(apache-module-dir,
 221                 AS_HELP_STRING([--with-apache-module-dir], [Apache modules dirs (for tests)]),
 222                 apache_module_dirs="$withval",
 223                 [apache_prefix=`dirname \`dirname $APACHE_HTTPD\``
 224                 mpm=`$APACHE_HTTPD -V | sed -ne 's/^Server MPM: */-/p' | tr 'A-Z' 'a-z'`
 225                 # This only works with bash, but should fail harmlessly in sh
 226                 apache_module_dirs=`echo $apache_prefix/lib{64,}/{apache,apache2,http,http2,httpd}{$mpm,}{/modules,}`])
 227     for dir in $apache_module_dirs; do
 228         if test -f $dir/mod_auth_digest.so; then
 229             APACHE_MODULE_DIR="$dir"
 230         fi
 231         if test -f $dir/mod_ssl.so; then
 232             APACHE_SSL_MODULE_DIR="$dir"
 233             IF_HAVE_APACHE_SSL=""
 234         fi
 235         if test -f $dir/mod_php5.so; then
 236             APACHE_PHP_MODULE_DIR="$dir"
 237             APACHE_PHP_MODULE=mod_php5.so
 238         fi
 239         if test -f $dir/libphp5.so; then
 240             APACHE_PHP_MODULE_DIR="$dir"
 241             APACHE_PHP_MODULE=libphp5.so
 242         fi
 243     done
 244     AC_MSG_RESULT($APACHE_MODULE_DIR)
 245     AC_SUBST(APACHE_MODULE_DIR)
 246     AC_SUBST(APACHE_SSL_MODULE_DIR)
 247     AC_SUBST(APACHE_PHP_MODULE_DIR)
 248     AC_SUBST(APACHE_PHP_MODULE)
 249 fi
 250
 251 if test "$APACHE_HTTPD" != "no" -a -n "$APACHE_MODULE_DIR" -a -n "$APACHE_SSL_MODULE_DIR"; then
 252     AC_DEFINE(HAVE_APACHE, 1, [Whether or not apache can be used for tests])
 253     have_apache=1
 254     if test -z "$APACHE_PHP_MODULE_DIR"; then
 255         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES mod_php5"
 256     fi
 257 else
 258     have_apache=0
 259     if test "$APACHE_HTTPD" = "no" -o -z "$APACHE_MODULE_DIR"; then
 260         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES apache"
 261     else
 262         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES mod_ssl"
 263     fi
 264 fi
 265 AM_CONDITIONAL(HAVE_APACHE, test $have_apache = 1)
 266
 267 if test "$have_apache" = 1; then
 268     AC_CHECK_PROGS(PHP, php php5)
 269
 270     AC_MSG_CHECKING([for Apache PHP module])
 271     if test -f $APACHE_PHP_MODULE_DIR/$APACHE_PHP_MODULE; then
 272         have_php=yes
 273         IF_HAVE_PHP=""
 274     else
 275         have_php=no
 276         IF_HAVE_PHP="#"
 277         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES php5"
 278     fi
 279     AC_MSG_RESULT($have_php)
 280
 281     if test "$have_php" = yes; then
 282         AC_MSG_CHECKING([for xmlrpc-epi-php])
 283         if $PHP --rf xmlrpc_server_create | grep -q "does not exist"; then
 284             have_xmlrpc_epi_php=no
 285             MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES php-xmlrpc"
 286         else
 287             have_xmlrpc_epi_php=yes
 288         fi
 289         AC_MSG_RESULT($have_xmlrpc_epi_php)
 290     fi
 291 fi
 292
 293 AC_SUBST(IF_HAVE_PHP)
 294 AM_CONDITIONAL(HAVE_XMLRPC_EPI_PHP, test "$have_xmlrpc_epi_php" = yes)
 295
 296 AC_PATH_PROG(CURL, curl, no)
 297 if test "$CURL" != no; then
 298     AC_DEFINE(HAVE_CURL, 1, [Whether or not curl can be used for tests])
 299 else
 300     MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES curl"
 301 fi
 302 AM_CONDITIONAL(HAVE_CURL, test "$CURL" != no)
 303
 304 AC_SUBST(MISSING_REGRESSION_TEST_PACKAGES)
 305 AM_CONDITIONAL(MISSING_REGRESSION_TEST_PACKAGES, test -n "$MISSING_REGRESSION_TEST_PACKAGES")
 306
 307 dnl **********************************************************
 308 dnl *** path of NTLM single-sign-on helper ntlm_auth
 309 dnl **********************************************************
 310 AC_ARG_WITH(ntlm-auth,
 311             AC_HELP_STRING([--with-ntlm-auth=PATH],[Where to look for ntlm_auth, path points to ntlm_auth installation (default: /usr/bin/ntlm_auth)]),
 312             ntlm_auth="$withval",
 313             [if test $os_win32 = yes; then ntlm_auth="no"; else ntlm_auth="/usr/bin/ntlm_auth"; fi])
 314 if test "$ntlm_auth" != "no"; then
 315     AC_DEFINE(USE_NTLM_AUTH, 1, [Whether or not use Samba's 'winbind' daemon helper 'ntlm_auth' for NTLM single-sign-on])
 316     if test "$ntlm_auth" = "yes"; then
 317         dnl --with-ntlm-auth (without path) used, use default path
 318         ntlm_auth="/usr/bin/ntlm_auth"
 319     fi
 320 fi
 321 AC_SUBST(ntlm_auth)
 322 AC_DEFINE_UNQUOTED(NTLM_AUTH, "$ntlm_auth", [Samba's 'winbind' daemon helper 'ntlm_auth' which can be used for NTLM single-sign-on])
 323
 324 dnl ****************************************************
 325 dnl *** Warnings to show if using GCC                ***
 326 dnl *** (do this last so -Werror won't mess up tests ***
 327 dnl ****************************************************
 328
 329 AC_ARG_ENABLE(more-warnings,
 330               AS_HELP_STRING([--disable-more-warnings], [Inhibit compiler warnings]),
 331               set_more_warnings=no)
 332
 333 if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 334         CFLAGS="$CFLAGS \
 335                 -Wall -Wstrict-prototypes -Werror=missing-prototypes \
 336                 -Werror=implicit-function-declaration \
 337                 -Werror=pointer-arith -Werror=init-self -Werror=format=2 \
 338                 -Werror=missing-include-dirs -Werror=aggregate-return \
 339                 -Werror=declaration-after-statement"
 340 fi
 341
 342 dnl *************************
 343 dnl *** Output Everything ***
 344 dnl *************************
 345
 346 AC_CONFIG_HEADERS([config.h])
 347 AC_CONFIG_FILES([
 348         libsoup-2.4.pc
 349         libsoup-gnome-2.4.pc
 350         Makefile
 351         libsoup-zip
 352         libsoup/Makefile
 353         po/Makefile.in
 354         po/Makefile
 355         tests/Makefile
 356         tests/httpd.conf
 357         docs/Makefile
 358         docs/reference/Makefile
 359         ])
 360 AC_OUTPUT
 361
 362 if test -n "$MISSING_REGRESSION_TEST_PACKAGES"; then
 363     echo ""
 364     echo Some regression tests will not be run due to missing packages:
 365     echo $MISSING_REGRESSION_TEST_PACKAGES
 366     echo ""
 367 fi