configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991, 1993-2011 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.62])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11.1 dist-xz color-tests parallel-tests])
  36 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  37
  38 AC_PROG_CC_STDC
  39 AM_PROG_CC_C_O
  40 AC_PROG_CPP
  41 AC_PROG_GCC_TRADITIONAL
  42 AC_PROG_RANLIB
  43 AC_PROG_LN_S
  44 gl_EARLY
  45 gl_INIT
  46 coreutils_MACROS
  47
  48 AC_ARG_ENABLE([gcc-warnings],
  49   [AS_HELP_STRING([--enable-gcc-warnings],
  50                   [turn on lots of GCC warnings (for developers)])],
  51   [case $enableval in
  52      yes|no) ;;
  53      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  54    esac
  55    gl_gcc_warnings=$enableval],
  56   [gl_gcc_warnings=no]
  57 )
  58
  59 if test "$gl_gcc_warnings" = yes; then
  60   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  61   AC_SUBST([WERROR_CFLAGS])
  62
  63   nw=
  64   # This, $nw, is the list of warnings we disable.
  65   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  66   nw="$nw -Waggregate-return"       # anachronistic
  67   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
  68   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  69   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  70   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  71   nw="$nw -Wcast-qual"              # Too many warnings for now
  72   nw="$nw -Wconversion"             # Too many warnings for now
  73   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  74   nw="$nw -Wsign-conversion"        # Too many warnings for now
  75   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  76   nw="$nw -Wunreachable-code"       # Too many warnings for now
  77   nw="$nw -Wpadded"                 # Our structs are not padded
  78   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  79   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  80   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
  81   nw="$nw -Wvla"                    # warnings in gettext.h
  82   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
  83   nw="$nw -Wswitch-enum"            # Too many warnings for now
  84   nw="$nw -Wswitch-default"         # Too many warnings for now
  85   nw="$nw -Wstack-protector"        # not worth working around
  86   # things I might fix soon:
  87   nw="$nw -Wfloat-equal"            # sort.c, seq.c
  88   nw="$nw -Wmissing-format-attribute" # copy.c
  89   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
  90   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
  91
  92   # Using -Wstrict-overflow is a pain, but the alternative is worse.
  93   # For an example, see the code that provoked this report:
  94   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=33498
  95   # Code like that still infloops with gcc-4.6.0 and -O2.  Scary indeed.
  96
  97   gl_MANYWARN_ALL_GCC([ws])
  98   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  99   for w in $ws; do
 100     gl_WARN_ADD([$w])
 101   done
 102   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 103   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 104
 105   # In spite of excluding -Wlogical-op above, it is enabled, as of
 106   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 107   gl_WARN_ADD([-Wno-logical-op])
 108
 109   gl_WARN_ADD([-fdiagnostics-show-option])
 110   gl_WARN_ADD([-funit-at-a-time])
 111
 112   AC_SUBST([WARN_CFLAGS])
 113
 114   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 115   AC_DEFINE([_FORTIFY_SOURCE], [2],
 116     [enable compile-time and run-time bounds-checking, and some warnings])
 117   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 118
 119   # We use a slightly smaller set of warning options for lib/.
 120   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 121   nw=
 122   nw="$nw -Wstrict-overflow"
 123   nw="$nw -Wuninitialized"
 124   nw="$nw -Wunused-macros"
 125   nw="$nw -Wmissing-prototypes"
 126   nw="$nw -Wold-style-definition"
 127   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 128   AC_SUBST([GNULIB_WARN_CFLAGS])
 129
 130   # For gnulib-tests, the set is slightly smaller still.
 131   nw=
 132   nw="$nw -Wstrict-prototypes"
 133   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 134                          [$GNULIB_WARN_CFLAGS], [$nw])
 135   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 136 fi
 137
 138 AC_FUNC_FORK
 139
 140 optional_bin_progs=
 141 AC_CHECK_FUNCS([chroot],
 142         gl_ADD_PROG([optional_bin_progs], [chroot]))
 143 AC_CHECK_FUNCS([gethostid],
 144         gl_ADD_PROG([optional_bin_progs], [hostid]))
 145
 146 gl_WINSIZE_IN_PTEM
 147
 148 AC_MSG_CHECKING([whether localtime caches TZ])
 149 AC_CACHE_VAL([utils_cv_localtime_cache],
 150 [if test x$ac_cv_func_tzset = xyes; then
 151 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 152 #if STDC_HEADERS
 153 # include <stdlib.h>
 154 #endif
 155 extern char **environ;
 156 void unset_TZ (void)
 157 {
 158   char **from, **to;
 159   for (to = from = environ; (*to = *from); from++)
 160     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 161       to++;
 162 }
 163 int main()
 164 {
 165   time_t now = time ((time_t *) 0);
 166   int hour_GMT0, hour_unset;
 167   if (putenv ("TZ=GMT0") != 0)
 168     return 1;
 169   hour_GMT0 = localtime (&now)->tm_hour;
 170   unset_TZ ();
 171   hour_unset = localtime (&now)->tm_hour;
 172   if (putenv ("TZ=PST8") != 0)
 173     return 1;
 174   if (localtime (&now)->tm_hour == hour_GMT0)
 175     return 1;
 176   unset_TZ ();
 177   if (localtime (&now)->tm_hour != hour_unset)
 178     return 1;
 179   return 0;
 180 }]])],
 181 [utils_cv_localtime_cache=no],
 182 [utils_cv_localtime_cache=yes],
 183 [# If we have tzset, assume the worst when cross-compiling.
 184 utils_cv_localtime_cache=yes])
 185 else
 186         # If we lack tzset, report that localtime does not cache TZ,
 187         # since we can't invalidate the cache if we don't have tzset.
 188         utils_cv_localtime_cache=no
 189 fi])dnl
 190 AC_MSG_RESULT([$utils_cv_localtime_cache])
 191 if test $utils_cv_localtime_cache = yes; then
 192   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 193 fi
 194
 195 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 196 AC_CHECK_FUNCS([initgroups])
 197 if test $ac_cv_func_initgroups = no; then
 198   AC_CHECK_LIB([os], [initgroups])
 199 fi
 200
 201 AC_CHECK_FUNCS([syslog])
 202 if test $ac_cv_func_syslog = no; then
 203   # syslog is not in the default libraries.  See if it's in some other.
 204   for lib in bsd socket inet; do
 205     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 206       LIBS="$LIBS -l$lib"; break])
 207   done
 208 fi
 209
 210 AC_CACHE_CHECK([for 3-argument setpriority function],
 211   [utils_cv_func_setpriority],
 212   [AC_LINK_IFELSE(
 213     [AC_LANG_PROGRAM(
 214        [[#include <sys/time.h>
 215          #include <sys/resource.h>
 216        ]],
 217        [[setpriority (0, 0, 0);]])],
 218     [utils_cv_func_setpriority=yes],
 219     [utils_cv_func_setpriority=no])])
 220 if test $utils_cv_func_setpriority = no; then
 221   AC_CHECK_FUNCS([nice])
 222 fi
 223 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 224 *yes*)
 225   gl_ADD_PROG([optional_bin_progs], [nice])
 226 esac
 227
 228 AC_DEFUN([coreutils_DUMMY_1],
 229 [
 230   AC_REQUIRE([gl_READUTMP])
 231   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 232     gl_ADD_PROG([optional_bin_progs], [who])
 233     gl_ADD_PROG([optional_bin_progs], [users])
 234     gl_ADD_PROG([optional_bin_progs], [pinky])
 235   fi
 236 ])
 237 coreutils_DUMMY_1
 238
 239 AC_MSG_CHECKING([ut_host in struct utmp])
 240 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 241 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 242 #include <utmp.h>]], [[struct utmp ut; return !sizeof ut.ut_host;]])],
 243   [su_cv_func_ut_host_in_utmp=yes],
 244   [su_cv_func_ut_host_in_utmp=no])])
 245 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 246 if test $su_cv_func_ut_host_in_utmp = yes; then
 247   have_ut_host=1
 248   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 249 fi
 250
 251 if test -z "$have_ut_host"; then
 252   AC_MSG_CHECKING([ut_host in struct utmpx])
 253   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 254   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 255 #include <utmpx.h>]], [[struct utmpx ut; return !sizeof ut.ut_host;]])],
 256     [su_cv_func_ut_host_in_utmpx=yes],
 257     [su_cv_func_ut_host_in_utmpx=no])])
 258   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 259   if test $su_cv_func_ut_host_in_utmpx = yes; then
 260     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 261     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 262   fi
 263 fi
 264
 265 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 266
 267 AC_SYS_POSIX_TERMIOS()
 268 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 269
 270 if test $ac_cv_sys_posix_termios = yes; then
 271   gl_ADD_PROG([optional_bin_progs], [stty])
 272
 273   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 274   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 275   [AC_EGREP_CPP([yes], [#include <termios.h>
 276 #ifdef IUCLC
 277 yes
 278 #endif], su_cv_sys_termios_needs_xopen_source=no,
 279    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 280 #include <termios.h>
 281 #ifdef IUCLC
 282 yes
 283 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 284    su_cv_sys_termios_needs_xopen_source=no))])
 285   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 286   test $su_cv_sys_termios_needs_xopen_source = yes &&
 287     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 288
 289   AC_MSG_CHECKING([c_line in struct termios])
 290   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 291   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 292 #define _XOPEN_SOURCE
 293 #endif
 294 #include <sys/types.h>
 295 #include <termios.h>]], [[struct termios t; return !sizeof t.c_line;]])],
 296     [su_cv_sys_c_line_in_termios=yes],
 297     [su_cv_sys_c_line_in_termios=no])])
 298   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 299   test $su_cv_sys_c_line_in_termios = yes \
 300     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 301 fi
 302
 303 # FIXME: note that this macro appears above, too.
 304 # I'm leaving it here for now.  This whole thing needs to be modernized...
 305 gl_WINSIZE_IN_PTEM
 306
 307 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 308
 309 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 310    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 311   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 312   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 313   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 314 #ifdef WINSIZE_IN_PTEM
 315 # include <sys/stream.h>
 316 # include <sys/ptem.h>
 317 #endif
 318 #include <sys/ioctl.h>
 319 #include <sys/tty.h>
 320 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 321     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 322     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 323   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 324
 325   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 326       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 327                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 328 fi
 329
 330 # For src/kill.c.
 331 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 332   [AC_INCLUDES_DEFAULT
 333 #include <signal.h>])
 334
 335 cu_LIB_CHECK
 336 cu_GMP
 337
 338 # Build df only if there's a point to it.
 339 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 340   gl_ADD_PROG([optional_bin_progs], [df])
 341 fi
 342
 343 # Limit stdbuf to ELF systems with GCC
 344 AC_MSG_CHECKING([whether this is an ELF system])
 345 AC_EGREP_CPP([yes], [#if __ELF__
 346 yes
 347 #endif], [elf_sys=yes], [elf_sys=no])
 348 AC_MSG_RESULT([$elf_sys])
 349 if test "$elf_sys" = "yes" && \
 350    test "$GCC" = "yes"; then
 351   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 352 fi
 353
 354 ############################################################################
 355 mk="$srcdir/src/Makefile.am"
 356 # Extract all literal names from the definition of $(EXTRA_PROGRAMS)
 357 # in $mk but don't expand the variable references.
 358 # Append each literal name to $optional_bin_progs.
 359 v=EXTRA_PROGRAMS
 360 for gl_i in `sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 361     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 362     | tr -s '\\015\\012\\\\' '   '`; do
 363   gl_ADD_PROG([optional_bin_progs], $gl_i)
 364 done
 365
 366 # As above, extract literal names from the definition of $(no_install__progs)
 367 # in $mk but don't expand the variable references.
 368 v=no_install__progs
 369 t=`sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 370     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 371     | tr -s '\\015\\012\\\\' '   '`
 372 # Remove any trailing space.
 373 no_install_progs_default=`echo "$t"|sed 's/ $//'`
 374
 375 # Unfortunately, due to the way autoconf's AS_HELP_STRING works, the list
 376 # of default-not-installed programs, "arch hostname su", must appear in two
 377 # places: in this file below, and in $mk.  Using "$no_install_progs_default"
 378 # below cannot work.  And we can't substitute the names into $mk because
 379 # automake needs the literals, too.
 380 # The compromise is to ensure that the space-separated list extracted
 381 # above matches the literal 2nd argument below.
 382 c="$srcdir/configure.ac"
 383 re='^g''l_INCLUDE_EXCLUDE_PROG(.* [\[\(.*\)\]])'
 384 t=`sed -n '/'"$re"'/{s/'"$re"'/\1/;s/,/ /gp
 385 }' $c`
 386 case $t in
 387   $no_install_progs_default) ;;
 388   *) AC_MSG_ERROR([[internal error: g'l_INCLUDE_EXCLUDE_PROG's 2nd arg, $t,
 389                    does not match the list of default-not-installed programs
 390                    ($no_install_progs_default) also recorded in $mk]],
 391                    1) ;;
 392 esac
 393
 394 # Given the name of a variable containing a space-separated list of
 395 # install-by-default programs and the actual list do-not-install-by-default
 396 # programs, modify the former variable to reflect any "do-install" and
 397 # "don't-install" requests.
 398 # I.e., add any program name specified via --enable-install-program=..., and
 399 # remove any program name specified via --enable-no-install-program=...
 400 # Note how the second argument below is a literal, with "," separators.
 401 # That is required due to the way the macro works, and since the
 402 # corresponding ./configure option argument is comma-separated on input.
 403 gl_INCLUDE_EXCLUDE_PROG([optional_bin_progs], [arch,hostname,su])
 404
 405 # Now that we know which programs will actually be built up, figure out
 406 # which optional helper progs should be compiled.
 407 optional_pkglib_progs=
 408 case " $optional_bin_progs " in
 409   *' stdbuf '*) gl_ADD_PROG([optional_pkglib_progs], [libstdbuf.so]) ;;
 410 esac
 411
 412 # Set INSTALL_SU if su installation has been requested via
 413 # --enable-install-program=su.
 414 AC_SUBST([INSTALL_SU])
 415 case " $optional_bin_progs " in
 416   *' su '*) INSTALL_SU=yes ;;
 417   *)        INSTALL_SU=no ;;
 418 esac
 419
 420 MAN=`echo "$optional_bin_progs "|sed 's/ /.1 /g;s/ $//'|tr -d '\\015\\012'`
 421
 422 # Change ginstall.1 to "install.h" in $MAN.
 423 MAN=`for m in $MAN; do test $m = ginstall.1 && m=install.1; echo $m; done \
 424   | tr '\015\012' '  '; echo`
 425
 426 # Remove [.1, since writing a portable rule for it in man/Makefile.am
 427 # is not practical.  The sed LHS below uses the autoconf quadrigraph
 428 # representing '['.
 429 MAN=`echo "$MAN"|sed 's/\@<:@\.1//'`
 430
 431 OPTIONAL_BIN_PROGS=`echo "$optional_bin_progs "|sed 's/ /\$(EXEEXT) /g;s/ $//'`
 432 AC_SUBST([OPTIONAL_BIN_PROGS])
 433 OPTIONAL_PKGLIB_PROGS=`echo "$optional_pkglib_progs " | sed 's/ $//'`
 434 AC_SUBST([OPTIONAL_PKGLIB_PROGS])
 435 NO_INSTALL_PROGS_DEFAULT=$no_install_progs_default
 436 AC_SUBST([NO_INSTALL_PROGS_DEFAULT])
 437
 438 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 439
 440 # Arrange to rerun configure whenever the file, src/Makefile.am,
 441 # containing the list of program names changes.
 442 CONFIG_STATUS_DEPENDENCIES='$(top_srcdir)/src/Makefile.am'
 443 AC_SUBST([CONFIG_STATUS_DEPENDENCIES])
 444 ############################################################################
 445
 446 # As long as "grep 'PRI[diouxX]' po/*.pot" reports matches in
 447 # translatable strings, we must use need-formatstring-macros here.
 448 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 449 AM_GNU_GETTEXT_VERSION([0.17])
 450
 451 # For a test of uniq: it uses the $LOCALE_FR envvar.
 452 gt_LOCALE_FR
 453
 454 AC_CONFIG_FILES(
 455   Makefile
 456   doc/Makefile
 457   lib/Makefile
 458   man/Makefile
 459   po/Makefile.in
 460   src/Makefile
 461   tests/Makefile
 462   gnulib-tests/Makefile
 463   )
 464 AC_OUTPUT