configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [Install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286
 287   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 288 else
 289   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 290
 291   if test "x$enable_debug" = "xno"; then
 292     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 293   fi
 294 fi
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$glib_native_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 331 AC_SUBST(GLIB_EXTRA_CFLAGS)
 332
 333 AC_EXEEXT
 334
 335 # define a MAINT-like variable REBUILD which is set if Perl
 336 # and awk are found, so autogenerated sources can be rebuilt
 337 AC_PROG_AWK
 338 AC_CHECK_PROGS(PERL, [perl5 perl])
 339 # We would like indent, but don't require it.
 340 AC_CHECK_PROG(INDENT, indent, indent)
 341 REBUILD=\#
 342 if test "x$enable_rebuilds" = "xyes" && \
 343      test -n "$PERL" && \
 344      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 345      test -n "$AWK" ; then
 346   REBUILD=
 347 fi
 348 AC_SUBST(REBUILD)
 349
 350 # Need full path to Perl for glib-mkenums
 351 #
 352 if test "x$PERL" != x ; then
 353   AC_PATH_PROG(PERL_PATH, [$PERL])
 354 fi
 355 if test "x$PERL_PATH" = x ; then
 356   PERL_PATH="/usr/bin/env perl"
 357 fi
 358 AC_SUBST(PERL_PATH)
 359
 360 # Need suitable python path for greport
 361 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 362
 363
 364 dnl ***********************
 365 dnl *** Tests for iconv ***
 366 dnl ***********************
 367 dnl
 368 dnl We do this before the gettext checks, to avoid distortion
 369
 370 dnl On Windows we use a native implementation
 371
 372 if test x"$glib_native_win32" = xyes; then
 373   with_libiconv=native
 374 else
 375   AC_ARG_WITH(libiconv,
 376               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 377                               [use the libiconv library])],,
 378               [with_libiconv=maybe])
 379
 380   found_iconv=no
 381   case $with_libiconv in
 382     maybe)
 383       # Check in the C library first
 384       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385       # Check if we have GNU libiconv
 386       if test $found_iconv = "no"; then
 387         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388       fi
 389       # Check if we have a iconv in -liconv, possibly from vendor
 390       if test $found_iconv = "no"; then
 391         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 392       fi
 393       ;;
 394     no)
 395       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 396       ;;
 397     gnu|yes)
 398       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 399       ;;
 400     native)
 401       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 402       ;;
 403   esac
 404
 405   if test "x$found_iconv" = "xno" ; then
 406      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 407   fi
 408 fi
 409
 410 AC_ARG_ENABLE(iconv-cache,
 411               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 412                               [cache iconv descriptors [default=auto]])],,
 413               [enable_iconv_cache=auto])
 414
 415 AC_MSG_CHECKING([whether to cache iconv descriptors])
 416 case $enable_iconv_cache in
 417   auto)
 418     if test $ac_cv_gnu_library_2_1 = yes; then
 419       enable_iconv_cache=no
 420     else
 421       enable_iconv_cache=yes
 422     fi
 423   ;;
 424   yes|no)
 425   ;;
 426   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 427   ;;
 428 esac
 429
 430 if test $enable_iconv_cache = yes; then
 431    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 432 fi
 433
 434 AC_MSG_RESULT($enable_iconv_cache)
 435
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 if test "x$found_zlib" = "xno" ; then
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 fi
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 if test x"$glib_native_win32" != xyes; then
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 fi
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 if test "x$GCC" = "xyes"; then
 509   case " $CFLAGS " in
 510   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 511   *) CFLAGS="$CFLAGS -Wall" ;;
 512   esac
 513 fi
 514
 515 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 516
 517 if test "$glib_native_win32" = "yes"; then
 518   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 519     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 520   fi
 521   if test x$enable_static = xyes; then
 522     glib_win32_static_compilation=yes
 523     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 524 #define GOBJECT_STATIC_COMPILATION 1"
 525     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 526   fi
 527 fi
 528 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 529
 530 dnl
 531 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 532 dnl
 533 if test $cross_compiling != yes ; then
 534     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 535     glib_save_LIBS=$LIBS
 536     LIBS="$LIBS -lm"
 537     AC_TRY_RUN([#include <math.h>
 538                  int main (void) { return (log(1) != log(1.)); }],
 539          AC_MSG_RESULT(none needed),
 540          glib_save_CFLAGS=$CFLAGS
 541          CFLAGS="$CFLAGS -std1"
 542          AC_TRY_RUN([#include <math.h>
 543                      int main (void) { return (log(1) != log(1.)); }],
 544              AC_MSG_RESULT(-std1),
 545              AC_MSG_RESULT()
 546              CFLAGS=$glib_save_CFLAGS
 547              AC_MSG_WARN(
 548                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 549          )
 550     )
 551     LIBS=$glib_save_LIBS
 552 fi
 553
 554 dnl NeXTStep cc seems to need this
 555 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 556 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557   AC_MSG_RESULT(none needed),
 558   glib_save_CFLAGS=$CFLAGS
 559   CFLAGS="$CFLAGS -posix"
 560   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 561     AC_MSG_RESULT(-posix),
 562     AC_MSG_RESULT()
 563     CFLAGS=$glib_save_CFLAGS
 564     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 565
 566 # Checks for header files.
 567 AC_HEADER_STDC
 568
 569 # Checks for library functions.
 570 AC_FUNC_VPRINTF
 571 AC_FUNC_ALLOCA
 572 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 573 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 574
 575 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 576 dnl be automatically defined, which we don't want to do
 577 dnl until we have checked this function is actually usable
 578 AC_CHECK_FUNC([qsort_r])
 579
 580 # BSD has a qsort_r with wrong argument order
 581 if test x$ac_cv_func_qsort_r = xyes ; then
 582   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 583   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 584   #define _GNU_SOURCE
 585   #include <stdlib.h>
 586
 587   static int
 588   cmp (const void *a, const void *b, void *c)
 589   {
 590     const int *ia = a;
 591     const int *ib = b;
 592
 593     if (*ia < *ib)
 594       return -1;
 595     else if (*ia > *ib)
 596       return 1;
 597     else
 598       return 0;
 599   }
 600
 601   int
 602   main (int argc, char **argv)
 603   {
 604     int arr[3] = { 1, 2, 0 };
 605     int d = 3;
 606
 607     qsort_r (arr, 3, sizeof (int), cmp, &d);
 608
 609     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 610       return 0;
 611     else
 612       return 1;
 613   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 614 fi
 615
 616 if test x$glib_cv_have_qsort_r = xyes ; then
 617   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 618 fi
 619
 620 AC_CHECK_SIZEOF(char)
 621 AC_CHECK_SIZEOF(short)
 622 AC_CHECK_SIZEOF(long)
 623 AC_CHECK_SIZEOF(int)
 624 AC_CHECK_SIZEOF(void *)
 625 AC_CHECK_SIZEOF(long long)
 626 AC_CHECK_SIZEOF(__int64)
 627
 628 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 629   :
 630 else
 631   AC_MSG_ERROR([
 632 *** GLib requires a 64 bit type. You might want to consider
 633 *** using the GNU C compiler.
 634 ])
 635 fi
 636
 637 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 638         # long long is a 64 bit integer.
 639         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 640         AC_CACHE_VAL(glib_cv_long_long_format,[
 641                 for format in ll q I64; do
 642                   AC_TRY_RUN([#include <stdio.h>
 643                         int main()
 644                         {
 645                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 646                           char buffer[1000];
 647                           sprintf (buffer, "%${format}u", a);
 648                           sscanf (buffer, "%${format}u", &b);
 649                           exit (b!=a);
 650                         }
 651                         ],
 652                         [glib_cv_long_long_format=${format}
 653                         break],
 654                         [],[:])
 655                 done])
 656         if test -n "$glib_cv_long_long_format"; then
 657           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659           if test x"$glib_cv_long_long_format" = xI64; then
 660             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 661           fi
 662         else
 663           AC_MSG_RESULT(none)
 664         fi
 665 elif test x$ac_cv_sizeof___int64 = x8; then
 666         # __int64 is a 64 bit integer.
 667         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 668         # We know this is MSVCRT.DLL, and what the formats are
 669         glib_cv_long_long_format=I64
 670         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 671         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 672         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 673 fi
 674
 675 dnl long doubles were not used, and a portability problem
 676 dnl AC_C_LONG_DOUBLE
 677 AC_C_CONST
 678
 679 dnl ok, here we try to check whether the systems prototypes for
 680 dnl malloc and friends actually match the prototypes provided
 681 dnl by gmem.h (keep in sync). i currently only know how to check
 682 dnl this reliably with gcc (-Werror), improvements for other
 683 dnl compilers are apprechiated.
 684 SANE_MALLOC_PROTOS=no
 685 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 686 glib_save_CFLAGS=$CFLAGS
 687 if test "x$GCC" = "xyes"; then
 688   CFLAGS="$CFLAGS -Werror"
 689   AC_TRY_COMPILE([#include <stdlib.h>], [
 690     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 691     void* (*my_malloc_p)  (size_t)         = malloc;
 692     void  (*my_free_p)    (void*)          = free;
 693     void* (*my_realloc_p) (void*, size_t)  = realloc;
 694     my_calloc_p = 0;
 695     my_malloc_p = 0;
 696     my_free_p = 0;
 697     my_realloc_p = 0;
 698   ],
 699     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 700       [Define if you have correct malloc prototypes])
 701     SANE_MALLOC_PROTOS=yes)
 702 fi
 703 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 704 CFLAGS=$glib_save_CFLAGS
 705
 706 dnl
 707 dnl check in which direction the stack grows
 708 dnl
 709 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 710         AC_TRY_RUN([
 711         volatile int *a = 0, *b = 0;
 712         void foo (void);
 713         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 714         void foo (void) { volatile int x = 5; b = &x; }
 715         ],
 716         glib_cv_stack_grows=no
 717         ,
 718         glib_cv_stack_grows=yes
 719         ,)
 720 ])
 721
 722 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 723 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 724 dnl actually supported.
 725 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 726         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 727         __inline int foo () { return 0; }
 728         int main () { return foo (); }
 729         ]])],
 730         glib_cv_has__inline=yes
 731         ,
 732         glib_cv_has__inline=no
 733         ,)
 734 ])
 735 case x$glib_cv_has__inline in
 736 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 737 esac
 738 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 739         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 740         __inline__ int foo () { return 0; }
 741         int main () { return foo (); }
 742         ]])],
 743         glib_cv_has__inline__=yes
 744         ,
 745         glib_cv_has__inline__=no
 746         ,)
 747 ])
 748 case x$glib_cv_has__inline__ in
 749 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 750 esac
 751 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 752         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 753         #undef inline
 754         inline int foo () { return 0; }
 755         int main () { return foo (); }
 756         ]])],
 757         glib_cv_hasinline=yes
 758         ,
 759         glib_cv_hasinline=no
 760         ,)
 761 ])
 762 case x$glib_cv_hasinline in
 763 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 764 esac
 765
 766 # if we can use inline functions in headers
 767 AC_MSG_CHECKING(if inline functions in headers work)
 768 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 769 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 770 #  undef inline
 771 #  define inline __inline__
 772 #elif !defined (G_HAVE_INLINE)
 773 #  undef inline
 774 #  if defined (G_HAVE___INLINE__)
 775 #    define inline __inline__
 776 #  elif defined (G_HAVE___INLINE)
 777 #    define inline __inline
 778 #  endif
 779 #endif
 780
 781 int glib_test_func2 (int);
 782
 783 static inline int
 784 glib_test_func1 (void) {
 785   return glib_test_func2 (1);
 786 }
 787
 788 int
 789 main (void) {
 790   int i = 1;
 791 }]])],[g_can_inline=yes],[g_can_inline=no])
 792 AC_MSG_RESULT($g_can_inline)
 793
 794 dnl *** check for working do while(0) macros ***
 795 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 796         AC_TRY_COMPILE([],[
 797         #define STMT_START do
 798         #define STMT_END while(0)
 799         #define STMT_TEST STMT_START { i = 0; } STMT_END
 800         int main(void) { int i = 1; STMT_TEST; return i; }],
 801         [g_cv_support_dowhile_macros=yes],
 802         [g_cv_support_dowhile_macros=no],
 803         [g_cv_support_dowhile_macros=yes])
 804 ])
 805 if test x$g_cv_support_dowhile_macros = xyes; then
 806   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 807 fi
 808
 809 # check for flavours of varargs macros
 810 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 811 AC_TRY_COMPILE([],[
 812 int a(int p1, int p2, int p3);
 813 #define call_a(...) a(1,__VA_ARGS__)
 814 call_a(2,3);
 815 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 816 AC_MSG_RESULT($g_have_iso_c_varargs)
 817
 818 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 819 if test "$CXX" = ""; then
 820 dnl No C++ compiler
 821   g_have_iso_cxx_varargs=no
 822 else
 823   AC_LANG_CPLUSPLUS
 824   AC_TRY_COMPILE([],[
 825 int a(int p1, int p2, int p3);
 826 #define call_a(...) a(1,__VA_ARGS__)
 827 call_a(2,3);
 828 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 829   AC_LANG_C
 830 fi
 831 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 832
 833 AC_MSG_CHECKING(for GNUC varargs macros)
 834 AC_TRY_COMPILE([],[
 835 int a(int p1, int p2, int p3);
 836 #define call_a(params...) a(1,params)
 837 call_a(2,3);
 838 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 839 AC_MSG_RESULT($g_have_gnuc_varargs)
 840
 841 # check for GNUC visibility support
 842 AC_MSG_CHECKING(for GNUC visibility attribute)
 843 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 844 void
 845 __attribute__ ((visibility ("hidden")))
 846      f_hidden (void)
 847 {
 848 }
 849 void
 850 __attribute__ ((visibility ("internal")))
 851      f_internal (void)
 852 {
 853 }
 854 void
 855 __attribute__ ((visibility ("protected")))
 856      f_protected (void)
 857 {
 858 }
 859 void
 860 __attribute__ ((visibility ("default")))
 861      f_default (void)
 862 {
 863 }
 864 int main (int argc, char **argv)
 865 {
 866         f_hidden();
 867         f_internal();
 868         f_protected();
 869         f_default();
 870         return 0;
 871 }
 872 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 873 AC_MSG_RESULT($g_have_gnuc_visibility)
 874 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 875
 876 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 877 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 878 #else
 879 # include "error: this is not Sun Studio."
 880 #endif
 881 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 882 AC_MSG_RESULT($g_have_sunstudio_visibility)
 883 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 884
 885 # check for bytesex stuff
 886 AC_C_BIGENDIAN
 887 if test x$ac_cv_c_bigendian = xuniversal ; then
 888 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 889 #else
 890 #error Not a big endian.
 891 #endif],
 892     ac_cv_c_bigendian=yes
 893     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 894 #else
 895 #error Not a little endian.
 896 #endif],
 897     ac_cv_c_bigendian=no
 898     ,AC_MSG_WARN([Could not determine endianness.])))
 899 fi
 900
 901
 902 # check for header files
 903 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 904 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 905 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 906 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 907 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 908 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 909 AC_CHECK_HEADERS([linux/magic.h])
 910
 911 # check for structure fields
 912 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 913 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 914 #include <sys/stat.h>
 915 #include <unistd.h>
 916 #ifdef HAVE_SYS_STATFS_H
 917 #include <sys/statfs.h>
 918 #endif
 919 #ifdef HAVE_SYS_PARAM_H
 920 #include <sys/param.h>
 921 #endif
 922 #ifdef HAVE_SYS_MOUNT_H
 923 #include <sys/mount.h>
 924 #endif])
 925 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 926 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 927 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 928 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 929
 930 # Checks for libcharset
 931 AM_LANGINFO_CODESET
 932 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 933 AC_CHECK_FUNCS(setlocale)
 934
 935 # check additional type sizes
 936 AC_CHECK_SIZEOF(size_t)
 937
 938 dnl Try to figure out whether gsize, gssize should be long or int
 939 AC_MSG_CHECKING([for the appropriate definition for size_t])
 940
 941 case $ac_cv_sizeof_size_t in
 942   $ac_cv_sizeof_short)
 943       glib_size_type=short
 944       ;;
 945   $ac_cv_sizeof_int)
 946       glib_size_type=int
 947       ;;
 948   $ac_cv_sizeof_long)
 949       glib_size_type=long
 950       ;;
 951   $ac_cv_sizeof_long_long)
 952       glib_size_type='long long'
 953       ;;
 954   $ac_cv_sizeof__int64)
 955       glib_size_type='__int64'
 956       ;;
 957   *)  AC_MSG_ERROR([No type matching size_t in size])
 958       ;;
 959 esac
 960
 961 dnl If int/long are the same size, we see which one produces
 962 dnl warnings when used in the location as size_t. (This matters
 963 dnl on AIX with xlc)
 964 dnl
 965 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 966    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 967   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 968 #if defined(_AIX) && !defined(__GNUC__)
 969 #pragma options langlvl=stdc89
 970 #endif
 971 #include <stddef.h>
 972 int main ()
 973 {
 974   size_t s = 1;
 975   unsigned int *size_int = &s;
 976   return (int)*size_int;
 977 }
 978     ]])],glib_size_type=int,
 979       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 980 #if defined(_AIX) && !defined(__GNUC__)
 981 #pragma options langlvl=stdc89
 982 #endif
 983 #include <stddef.h>
 984 int main ()
 985 {
 986    size_t s = 1;
 987    unsigned long *size_long = &s;
 988    return (int)*size_long;
 989 }
 990         ]])],glib_size_type=long)])
 991 fi
 992
 993 AC_MSG_RESULT(unsigned $glib_size_type)
 994
 995 # Check for some functions
 996 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 997 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 998 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 999 # Check for high-resolution sleep functions
1000 AC_CHECK_FUNCS(splice)
1001
1002 # To avoid finding a compatibility unusable statfs, which typically
1003 # successfully compiles, but warns to use the newer statvfs interface:
1004 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1005 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1006
1007 AC_MSG_CHECKING([whether to use statfs or statvfs])
1008 # Some systems have both statfs and statvfs, pick the most "native" for these
1009 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1010    [
1011    # on solaris and irix, statfs doesn't even have the f_bavail field
1012    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1013       [ac_cv_func_statfs=no],
1014    # else, at least on linux, statfs is the actual syscall
1015       [ac_cv_func_statvfs=no])
1016    ])
1017
1018 AS_IF([test x$ac_cv_func_statfs = xyes],
1019       [
1020          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1021          AC_MSG_RESULT([statfs])
1022       ],
1023       [test x$ac_cv_func_statvfs = xyes],
1024       [
1025          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1026          AC_MSG_RESULT([statvfs])
1027       ],
1028       [  AC_MSG_RESULT([neither])])
1029
1030 AC_CHECK_HEADERS(crt_externs.h)
1031 AC_CHECK_FUNCS(_NSGetEnviron)
1032
1033 AC_FUNC_VSNPRINTF_C99
1034 AC_FUNC_PRINTF_UNIX98
1035
1036 # Internet address families
1037 if test $glib_native_win32 = yes; then
1038   glib_inet_includes=["
1039 #include <winsock2.h>
1040   "]
1041 else
1042   glib_inet_includes=["
1043 #include <sys/types.h>
1044 #include <sys/socket.h>
1045   "]
1046 fi
1047
1048 glib_failed=false
1049 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1050 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1051 # winsock defines this even though it doesn't support it
1052 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1053 if $glib_failed ; then
1054   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1055 fi
1056
1057 glib_failed=false
1058 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1059 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1061 if $glib_failed ; then
1062   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1063 fi
1064
1065 AC_CHECK_FUNCS(getprotobyname_r endservent)
1066 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1067
1068 # For gio/libasyncns
1069 if test $glib_native_win32 = no; then
1070   AC_CHECK_FUNCS(strndup setresuid setreuid)
1071   AC_CHECK_HEADERS(sys/prctl.h)
1072
1073   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1074   NETWORK_LIBS=""
1075   AC_MSG_CHECKING([for res_query])
1076   AC_TRY_LINK([#include <sys/types.h>
1077                #include <netinet/in.h>
1078                #include <arpa/nameser.h>
1079                #include <resolv.h>
1080               ],[
1081                res_query("test", 0, 0, (void *)0, 0);
1082               ],[AC_MSG_RESULT([yes])],
1083               [save_libs="$LIBS"
1084                LIBS="-lresolv $LIBS"
1085                AC_TRY_LINK([#include <sys/types.h>
1086                             #include <netinet/in.h>
1087                             #include <arpa/nameser.h>
1088                             #include <resolv.h>
1089                            ],[
1090                             res_query("test", 0, 0, (void *)0, 0);
1091                            ],[AC_MSG_RESULT([in -lresolv])
1092                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1093                            [LIBS="-lbind $save_libs"
1094                             AC_TRY_LINK([#include <resolv.h>],
1095                                         [res_query("test", 0, 0, (void *)0, 0);],
1096                                         [AC_MSG_RESULT([in -lbind])
1097                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1098                                         [AC_MSG_ERROR(not found)])])
1099                LIBS="$save_libs"])
1100   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1101                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1102                                         [AC_MSG_ERROR(Could not find socket())]))
1103 fi
1104 AC_SUBST(NETWORK_LIBS)
1105
1106 case $host in
1107   *-*-solaris* )
1108      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1111      ;;
1112 esac
1113
1114 dnl
1115 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1116 dnl
1117 if test "$ac_cv_func_statfs" = yes ; then
1118   AC_MSG_CHECKING([number of arguments to statfs()])
1119   AC_TRY_COMPILE([#include <unistd.h>
1120   #ifdef HAVE_SYS_PARAM_H
1121   #include <sys/param.h>
1122   #endif
1123   #ifdef HAVE_SYS_VFS_H
1124   #include <sys/vfs.h>
1125   #endif
1126   #ifdef HAVE_SYS_MOUNT_H
1127   #include <sys/mount.h>
1128   #endif
1129   #ifdef HAVE_SYS_STATFS_H
1130   #include <sys/statfs.h>
1131   #endif], [struct statfs st;
1132   statfs(NULL, &st);],[
1133     AC_MSG_RESULT([2])
1134     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1135     AC_TRY_COMPILE([#include <unistd.h>
1136   #ifdef HAVE_SYS_PARAM_H
1137   #include <sys/param.h>
1138   #endif
1139   #ifdef HAVE_SYS_VFS_H
1140   #include <sys/vfs.h>
1141   #endif
1142   #ifdef HAVE_SYS_MOUNT_H
1143   #include <sys/mount.h>
1144   #endif
1145   #ifdef HAVE_SYS_STATFS_H
1146   #include <sys/statfs.h>
1147   #endif], [struct statfs st;
1148   statfs(NULL, &st, sizeof (st), 0);],[
1149       AC_MSG_RESULT([4])
1150       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1151       AC_MSG_RESULT(unknown)
1152       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1153 fi
1154
1155 #
1156 # Check whether to use an included printf
1157 #
1158
1159 AC_ARG_ENABLE(included-printf,
1160               [AC_HELP_STRING([--enable-included-printf],
1161                               [use included printf [default=auto]])],
1162               enable_included_printf="$enableval")
1163
1164 need_included_printf=no
1165 if test "x$enable_included_printf" = "xyes" ; then
1166   need_included_printf=yes
1167 fi
1168 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1169   need_included_printf=yes
1170 fi
1171 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1175    test -z "$glib_cv_long_long_format" ; then
1176   need_included_printf=yes
1177 fi
1178
1179 if test "x$enable_included_printf" = "xno" &&
1180    test "x$need_included_printf" = "xyes" ; then
1181   AC_MSG_ERROR([
1182 *** Your C library's printf doesn't appear to have the features that
1183 *** GLib needs, but you specified --enable-included-printf=no.])
1184 fi
1185
1186 enable_included_printf=$need_included_printf
1187
1188 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1189 if test "$enable_included_printf" != "yes" ; then
1190   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1191 else
1192   if test -z "$glib_cv_long_long_format" ; then
1193     glib_cv_long_long_format="ll"
1194   fi
1195   AC_DEFINE(HAVE_VASPRINTF,1)
1196 fi
1197
1198 # Checks needed for gnulib vasnprintf
1199 bh_C_SIGNED
1200 jm_AC_TYPE_LONG_LONG
1201 gt_TYPE_LONGDOUBLE
1202 gt_TYPE_WCHAR_T
1203 gt_TYPE_WINT_T
1204 AC_TYPE_SIZE_T
1205 AC_CHECK_TYPES(ptrdiff_t)
1206 jm_AC_TYPE_INTMAX_T
1207 AC_CHECK_FUNCS([snprintf wcslen])
1208 AC_FUNC_SNPRINTF_C99
1209
1210 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1211 # The check is borrowed from the PERL Configure script.
1212 if test "$ac_cv_func_memmove" != "yes"; then
1213   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1214     glib_cv_working_bcopy,[AC_TRY_RUN([
1215       int main() {
1216         char buf[128], abc[128], *b;
1217         int len, off, align;
1218         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1219         for (align = 7; align >= 0; align--) {
1220           for (len = 36; len; len--) {
1221             b = buf+align; bcopy(abc, b, len);
1222             for (off = 1; off <= len; off++) {
1223               bcopy(b, b+off, len); bcopy(b+off, b, len);
1224                 if (bcmp(b, abc, len)) return(1);
1225             }
1226           }
1227         }
1228         return(0);
1229       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1230
1231   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1232   if test "$glib_cv_working_bcopy" = "yes"; then
1233     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1234   fi
1235 fi
1236
1237 # Check for sys_errlist
1238 AC_MSG_CHECKING(for sys_errlist)
1239 AC_TRY_LINK(, [
1240 extern char *sys_errlist[];
1241 extern int sys_nerr;
1242 sys_errlist[sys_nerr-1][0] = 0;
1243 ], glib_ok=yes, glib_ok=no)
1244 AC_MSG_RESULT($glib_ok)
1245 if test "$glib_ok" = "no"; then
1246     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1247 fi
1248
1249 # Check for sys_siglist
1250 AC_MSG_CHECKING(for sys_siglist)
1251 AC_TRY_LINK(, [
1252 extern char *sys_siglist[];
1253 exit (sys_siglist[0]);
1254 ], glib_ok=yes, glib_ok=no)
1255 AC_MSG_RESULT($glib_ok)
1256 if test "$glib_ok" = "no"; then
1257     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1258 fi
1259
1260 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1261 AC_MSG_CHECKING(for sys_siglist declaration)
1262 AC_TRY_COMPILE([#include <signal.h>], [
1263 strlen (sys_siglist[0]);
1264 ], glib_ok=yes, glib_ok=no)
1265 AC_MSG_RESULT($glib_ok)
1266 if test "$glib_ok" = "no"; then
1267     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1268 fi
1269
1270 # Check if <sys/select.h> needs to be included for fd_set
1271 AC_MSG_CHECKING([for fd_set])
1272 AC_TRY_COMPILE([#include <sys/types.h>],
1273         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1274 if test "$gtk_ok" = "yes"; then
1275     AC_MSG_RESULT([yes, found in sys/types.h])
1276 else
1277     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1278     if test "$gtk_ok" = "yes"; then
1279         # *** FIXME: give it a different name
1280         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1281         AC_MSG_RESULT([yes, found in sys/select.h])
1282     else
1283         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1284         AC_MSG_RESULT(no)
1285     fi
1286 fi
1287
1288 dnl *** check for sane realloc() ***
1289 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1290         AC_TRY_RUN([#include <stdlib.h>
1291         int main() {
1292           return realloc (0, sizeof (int)) == 0;
1293         }],
1294         [glib_cv_sane_realloc=yes],
1295         [glib_cv_sane_realloc=no],
1296         [glib_cv_sane_realloc=yes])
1297 ])
1298 if test x$glib_cv_sane_realloc = xyes; then
1299   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1300 fi
1301
1302 dnl Check for nl_langinfo and CODESET
1303 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1304         AC_TRY_COMPILE([#include <langinfo.h>],
1305                 [char *codeset = nl_langinfo (CODESET);],
1306                 [glib_cv_langinfo_codeset=yes],
1307                 [glib_cv_langinfo_codeset=no])])
1308 if test x$glib_cv_langinfo_codeset = xyes; then
1309   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1310 fi
1311
1312 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1313 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1314         AC_TRY_COMPILE([#include <langinfo.h>],
1315                 [char *str;
1316                  str = nl_langinfo (PM_STR);
1317                  str = nl_langinfo (D_T_FMT);
1318                  str = nl_langinfo (D_FMT);
1319                  str = nl_langinfo (T_FMT);
1320                  str = nl_langinfo (T_FMT_AMPM);
1321                  str = nl_langinfo (MON_1);
1322                  str = nl_langinfo (ABMON_12);
1323                  str = nl_langinfo (DAY_1);
1324                  str = nl_langinfo (ABDAY_7);],
1325                 [glib_cv_langinfo_time=yes],
1326                 [glib_cv_langinfo_time=no])])
1327 if test x$glib_cv_langinfo_time = xyes; then
1328   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1329 fi
1330
1331 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1332 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1333         AC_TRY_COMPILE([#include <langinfo.h>],
1334                 [char *str;
1335                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1336                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1337                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1338                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1339                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1340                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1341                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1342                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1343                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1344                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1345                 [glib_cv_langinfo_outdigit=yes],
1346                 [glib_cv_langinfo_outdigit=no])])
1347 if test x$glib_cv_langinfo_outdigit = xyes; then
1348   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1349 fi
1350
1351 dnl ****************************************
1352 dnl *** posix_memalign                   ***
1353 dnl ****************************************
1354 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1355 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1356     glib_cv_compliant_posix_memalign=0
1357     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1358         AC_TRY_RUN([
1359                 #define _XOPEN_SOURCE 600
1360                 #include <stdlib.h> /* posix_memalign() should be defined here */
1361                 /* some systems break if #include <malloc.h> used */
1362                 static void test_memalign (size_t boundary, size_t size) {
1363                     void *mem = 0;
1364                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1365                         exit (1);
1366                     else
1367                       free (mem);
1368                 }
1369                 int main() {
1370                     test_memalign (  128,   128 - 2 * sizeof (void*));
1371                     test_memalign (  256,   256 - 2 * sizeof (void*));
1372                     test_memalign (  512,   512 - 2 * sizeof (void*));
1373                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1374                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1375                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1376                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1377                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1378                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1379                     exit (0); /* success */
1380                 }
1381                 ],
1382             [glib_cv_compliant_posix_memalign=1], [], [:])
1383       :
1384     fi
1385     ])
1386 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1387     AC_MSG_RESULT(yes)
1388     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1389 else
1390     AC_MSG_RESULT(no)
1391 fi
1392
1393
1394 dnl ****************************************
1395 dnl *** strlcpy/strlcat                  ***
1396 dnl ****************************************
1397 # Check for strlcpy
1398 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1399 AC_TRY_RUN([#include <stdlib.h>
1400 #include <string.h>
1401 int main() {
1402   char p[10];
1403   (void) strlcpy (p, "hi", 10);
1404   if (strlcat (p, "bye", 0) != 3)
1405     return 1;
1406   return 0;
1407 }], glib_cv_have_strlcpy=yes,
1408     glib_cv_have_strlcpy=no,
1409     glib_cv_have_strlcpy=no)])
1410 if test "$glib_cv_have_strlcpy" = "yes"; then
1411     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1412 fi
1413
1414
1415 dnl **********************
1416 dnl *** va_copy checks ***
1417 dnl **********************
1418 dnl we currently check for all three va_copy possibilities, so we get
1419 dnl all results in config.log for bug reports.
1420 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1421         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1422 #include <stdlib.h>
1423         void f (int i, ...) {
1424         va_list args1, args2;
1425         va_start (args1, i);
1426         va_copy (args2, args1);
1427         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1428           exit (1);
1429         va_end (args1); va_end (args2);
1430         }
1431         int main() {
1432           f (0, 42);
1433           return 0;
1434         }]])],
1435         [glib_cv_va_copy=yes],
1436         [glib_cv_va_copy=no])
1437 ])
1438 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1439         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1440 #include <stdlib.h>
1441         void f (int i, ...) {
1442         va_list args1, args2;
1443         va_start (args1, i);
1444         __va_copy (args2, args1);
1445         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1446           exit (1);
1447         va_end (args1); va_end (args2);
1448         }
1449         int main() {
1450           f (0, 42);
1451           return 0;
1452         }]])],
1453         [glib_cv___va_copy=yes],
1454         [glib_cv___va_copy=no])
1455 ])
1456
1457 if test "x$glib_cv_va_copy" = "xyes"; then
1458   g_va_copy_func=va_copy
1459 else if test "x$glib_cv___va_copy" = "xyes"; then
1460   g_va_copy_func=__va_copy
1461 fi
1462 fi
1463
1464 if test -n "$g_va_copy_func"; then
1465   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1466 fi
1467
1468 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1469         AC_TRY_RUN([#include <stdarg.h>
1470 #include <stdlib.h>
1471         void f (int i, ...) {
1472         va_list args1, args2;
1473         va_start (args1, i);
1474         args2 = args1;
1475         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1476           exit (1);
1477         va_end (args1); va_end (args2);
1478         }
1479         int main() {
1480           f (0, 42);
1481           return 0;
1482         }],
1483         [glib_cv_va_val_copy=yes],
1484         [glib_cv_va_val_copy=no],
1485         [glib_cv_va_val_copy=yes])
1486 ])
1487
1488 if test "x$glib_cv_va_val_copy" = "xno"; then
1489   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1490 fi
1491
1492 dnl ***********************
1493 dnl *** g_module checks ***
1494 dnl ***********************
1495 G_MODULE_LIBS=
1496 G_MODULE_LIBS_EXTRA=
1497 G_MODULE_PLUGIN_LIBS=
1498 if test x"$glib_native_win32" = xyes; then
1499   dnl No use for this on Win32
1500   G_MODULE_LDFLAGS=
1501 else
1502   export SED
1503   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1504 fi
1505 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1506 G_MODULE_NEED_USCORE=0
1507 G_MODULE_BROKEN_RTLD_GLOBAL=0
1508 G_MODULE_HAVE_DLERROR=0
1509 dnl *** force native WIN32 shared lib loader
1510 if test -z "$G_MODULE_IMPL"; then
1511   case "$host" in
1512   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1513   esac
1514 fi
1515 dnl *** force native AIX library loader
1516 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1517 if test -z "$G_MODULE_IMPL"; then
1518   case "$host" in
1519   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1520   esac
1521 fi
1522 dnl *** dlopen() and dlsym() in system libraries
1523 if test -z "$G_MODULE_IMPL"; then
1524         AC_CHECK_FUNC(dlopen,
1525                       [AC_CHECK_FUNC(dlsym,
1526                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1527                       [])
1528 fi
1529 dnl *** load_image (BeOS)
1530 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1531   AC_CHECK_LIB(root, load_image,
1532       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1533       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1534       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1535       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1536       [])
1537 fi
1538 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1539 if test -z "$G_MODULE_IMPL"; then
1540         AC_CHECK_FUNC(NSLinkModule,
1541                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1542                        G_MODULE_NEED_USCORE=1],
1543                       [])
1544 fi
1545 dnl *** dlopen() and dlsym() in libdl
1546 if test -z "$G_MODULE_IMPL"; then
1547         AC_CHECK_LIB(dl, dlopen,
1548                      [AC_CHECK_LIB(dl, dlsym,
1549                                    [G_MODULE_LIBS=-ldl
1550                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1551                      [])
1552 fi
1553 dnl *** shl_load() in libdld (HP-UX)
1554 if test -z "$G_MODULE_IMPL"; then
1555         AC_CHECK_LIB(dld, shl_load,
1556                 [G_MODULE_LIBS=-ldld
1557                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1558                 [])
1559 fi
1560 dnl *** additional checks for G_MODULE_IMPL_DL
1561 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1562         LIBS_orig="$LIBS"
1563         LDFLAGS_orig="$LDFLAGS"
1564         LIBS="$G_MODULE_LIBS $LIBS"
1565         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1566 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1567         echo "void glib_plugin_test(void) { }" > plugin.c
1568         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1569                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1570         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1571                 glib_cv_rtldglobal_broken,[
1572                 AC_TRY_RUN([
1573 #include <dlfcn.h>
1574 #ifndef RTLD_GLOBAL
1575 #  define RTLD_GLOBAL 0
1576 #endif
1577 #ifndef RTLD_LAZY
1578 #  define RTLD_LAZY 0
1579 #endif
1580 int glib_plugin_test;
1581 int main () {
1582     void *handle, *global, *local;
1583     global = &glib_plugin_test;
1584     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1585     if (!handle) return 0;
1586     local = dlsym (handle, "glib_plugin_test");
1587     return global == local;
1588 }                       ],
1589                         [glib_cv_rtldglobal_broken=no],
1590                         [glib_cv_rtldglobal_broken=yes],
1591                         [glib_cv_rtldglobal_broken=no])
1592                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1593                 rmdir .libs 2>/dev/null
1594         ])
1595         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1596                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1597         else
1598                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1599         fi
1600 dnl *** check whether we need preceeding underscores
1601         AC_CACHE_CHECK([for preceeding underscore in symbols],
1602                 glib_cv_uscore,[
1603                 AC_TRY_RUN([#include <dlfcn.h>
1604                 int glib_underscore_test (void) { return 42; }
1605                 int main() {
1606                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1607                   handle = dlopen ((void*)0, 0);
1608                   if (handle) {
1609                     f1 = dlsym (handle, "glib_underscore_test");
1610                     f2 = dlsym (handle, "_glib_underscore_test");
1611                   } return (!f2 || f1);
1612                 }],
1613                         [glib_cv_uscore=yes],
1614                         [glib_cv_uscore=no],
1615                         [])
1616                 rm -f plugin.c plugin.$ac_objext plugin.lo
1617         ])
1618         GLIB_ASSERT_SET(glib_cv_uscore)
1619         if test "x$glib_cv_uscore" = "xyes"; then
1620                 G_MODULE_NEED_USCORE=1
1621         else
1622                 G_MODULE_NEED_USCORE=0
1623         fi
1624
1625         LDFLAGS="$LDFLAGS_orig"
1626 dnl *** check for having dlerror()
1627         AC_CHECK_FUNC(dlerror,
1628                 [G_MODULE_HAVE_DLERROR=1],
1629                 [G_MODULE_HAVE_DLERROR=0])
1630         LIBS="$LIBS_orig"
1631 fi
1632 dnl *** done, have we got an implementation?
1633 if test -z "$G_MODULE_IMPL"; then
1634         G_MODULE_IMPL=0
1635         G_MODULE_SUPPORTED=false
1636 else
1637         G_MODULE_SUPPORTED=true
1638 fi
1639
1640 AC_MSG_CHECKING(for the suffix of module shared libraries)
1641 export SED
1642 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1643 eval $shrext_cmds
1644 module=yes eval std_shrext=$shrext_cmds
1645 # chop the initial dot
1646 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1647 AC_MSG_RESULT(.$glib_gmodule_suffix)
1648 # any reason it may fail?
1649 if test "x$glib_gmodule_suffix" = x; then
1650         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1651 fi
1652
1653 AC_SUBST(G_MODULE_SUPPORTED)
1654 AC_SUBST(G_MODULE_IMPL)
1655 AC_SUBST(G_MODULE_LIBS)
1656 AC_SUBST(G_MODULE_LIBS_EXTRA)
1657 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1658 AC_SUBST(G_MODULE_LDFLAGS)
1659 AC_SUBST(G_MODULE_HAVE_DLERROR)
1660 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1661 AC_SUBST(G_MODULE_NEED_USCORE)
1662 AC_SUBST(GLIB_DEBUG_FLAGS)
1663
1664 dnl **********************
1665 dnl *** g_spawn checks ***
1666 dnl **********************
1667
1668 AC_MSG_CHECKING(for gspawn implementation)
1669 case "$host" in
1670   *-*-mingw*)
1671     GSPAWN=gspawn-win32.lo
1672     ;;
1673   *)
1674     GSPAWN=gspawn.lo
1675     ;;
1676 esac
1677 AC_MSG_RESULT($GSPAWN)
1678 AC_SUBST(GSPAWN)
1679
1680 dnl *************************
1681 dnl *** GIOChannel checks ***
1682 dnl *************************
1683
1684 AC_MSG_CHECKING(for GIOChannel implementation)
1685 case "$host" in
1686   *-*-mingw*)
1687     GIO=giowin32.lo
1688     ;;
1689   *)
1690     GIO=giounix.lo
1691     ;;
1692 esac
1693 AC_MSG_RESULT($GIO)
1694 AC_SUBST(GIO)
1695
1696 dnl *********************************
1697 dnl *** Directory for GIO modules ***
1698 dnl *********************************
1699
1700 AC_ARG_WITH(gio-module-dir,
1701            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1702                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1703            [],
1704            [with_gio_module_dir='${libdir}/gio/modules'])
1705 GIO_MODULE_DIR=$with_gio_module_dir
1706 AC_SUBST(GIO_MODULE_DIR)
1707
1708 dnl **********************************
1709 dnl *** Check for libselinux (GIO) ***
1710 dnl **********************************
1711 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1712 msg_selinux=no
1713 SELINUX_LIBS=
1714 if test "x$enable_selinux" != "xno"; then
1715
1716  AC_CHECK_LIB(selinux, is_selinux_enabled,
1717    [AC_CHECK_HEADERS(selinux/selinux.h,
1718      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1719        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1720         SELINUX_LIBS="-lselinux"
1721         msg_selinux=yes])
1722      ])
1723    ])
1724 fi
1725 AC_SUBST(SELINUX_LIBS)
1726
1727 dnl *****************************
1728 dnl ** Check for inotify (GIO) **
1729 dnl *****************************
1730 inotify_support=no
1731 AC_CHECK_HEADERS([sys/inotify.h],
1732 [
1733         inotify_support=yes
1734         AC_CHECK_FUNCS(inotify_init1)
1735 ])
1736
1737 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1738
1739 dnl *********************************
1740 dnl ** Check for Solaris FEN (GIO) **
1741 dnl *********************************
1742 fen_support=no
1743 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1744 #include <port.h>
1745 #ifndef PORT_SOURCE_FILE
1746 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1747 #endif
1748 int main() { return 0; } ]])],
1749 [
1750         fen_support=yes
1751 ],)
1752
1753 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1754
1755 dnl ****************************
1756 dnl *** Checks for FAM (GIO) ***
1757 dnl ****************************
1758
1759 should_disable_fam=no
1760
1761 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1762                          [
1763                                 if test "x$enable_fam" = "xno"; then
1764                                         should_disable_fam=yes
1765                                         echo "Not building FAM support"
1766                                 fi
1767                          ]
1768                          )
1769 fam_support=no
1770 FAM_LIBS=
1771 if test "x$should_disable_fam" = "xno"; then
1772 AC_CHECK_LIB(fam, FAMOpen,
1773   [AC_CHECK_HEADERS(fam.h,
1774     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1775      AC_CHECK_LIB(fam, FAMNoExists,
1776                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1777      FAM_LIBS="-lfam"]
1778      fam_support=yes,
1779     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1780   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1781 AC_SUBST(FAM_LIBS)
1782 fi
1783 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1784
1785
1786 dnl *****************************
1787 dnl *** Check for xattr (GIO) ***
1788 dnl *****************************
1789 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1790 msg_xattr=no
1791 XATTR_LIBS=
1792 if test "x$enable_xattr" != "xno"; then
1793
1794 dnl either glibc or libattr can provide xattr support
1795
1796 dnl for both of them, we check for getxattr being in
1797 dnl the library and a valid xattr header.
1798
1799 dnl try glibc
1800  AC_CHECK_LIB(c, getxattr,
1801    [AC_CHECK_HEADERS(sys/xattr.h,
1802      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1803       msg_xattr=yes])
1804    ])
1805
1806   if test "x$msg_xattr" != "xyes"; then
1807 dnl   failure. try libattr
1808    AC_CHECK_LIB(attr, getxattr,
1809       [AC_CHECK_HEADERS(attr/xattr.h,
1810        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1811         XATTR_LIBS="-lattr"
1812         msg_xattr=yes])
1813       ])
1814   fi
1815
1816   if test "x$msg_xattr" = "xyes"; then
1817     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1818     AC_TRY_COMPILE([
1819       #include <stdio.h>
1820       #ifdef HAVE_SYS_TYPES_H
1821       #include <sys/types.h>
1822       #endif
1823       #ifdef HAVE_SYS_XATTR_H
1824       #include <sys/xattr.h>
1825       #elif HAVE_ATTR_XATTR_H
1826       #include <attr/xattr.h>
1827       #endif
1828     ],
1829     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1830     [
1831       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1832       AC_MSG_RESULT([yes])
1833     ],
1834     [AC_MSG_RESULT([no])]
1835     )
1836   fi
1837
1838 fi
1839 AC_SUBST(XATTR_LIBS)
1840
1841 dnl ****************************************
1842 dnl *** platform dependent source checks ***
1843 dnl ****************************************
1844
1845 AC_MSG_CHECKING(for platform-dependent source)
1846 case "$host" in
1847   *-*-cygwin*|*-*-mingw*)
1848     PLATFORMDEP=gwin32.lo
1849     ;;
1850   *)
1851     PLATFORMDEP=
1852     ;;
1853 esac
1854 AC_MSG_RESULT($PLATFORMDEP)
1855 AC_SUBST(PLATFORMDEP)
1856
1857 AC_MSG_CHECKING([whether to compile timeloop])
1858 case "$host" in
1859   *-*-cygwin*|*-*-mingw*|*-*-minix)
1860     enable_timeloop=no
1861     ;;
1862   *)
1863     enable_timeloop=yes
1864     ;;
1865 esac
1866 AC_MSG_RESULT($enable_timeloop)
1867 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1868
1869 AC_MSG_CHECKING([if building for some Win32 platform])
1870 case "$host" in
1871   *-*-mingw*|*-*-cygwin*)
1872     platform_win32=yes
1873     ;;
1874   *)
1875     platform_win32=no
1876     ;;
1877 esac
1878 AC_MSG_RESULT($platform_win32)
1879 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1880
1881 dnl ***********************
1882 dnl *** g_thread checks ***
1883 dnl ***********************
1884
1885 AC_ARG_WITH(threads,
1886            [AC_HELP_STRING([--with-threads=@<:@posix/dce/win32@:>@],
1887                            [specify a thread implementation to use])],
1888            [if test "x$with_threads" = x; then
1889                 want_threads=yes
1890             else
1891                 want_threads=$with_threads
1892             fi],
1893            [want_threads=yes])
1894
1895 dnl error and warning message
1896 dnl *************************
1897
1898 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1899                 computer."
1900
1901 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1902                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1903                 compilation now, but then your programs might not work.
1904                 Please provide information on how it is done on your system."
1905
1906 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1907                 "
1908
1909 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1910                 provide information on your thread implementation."
1911
1912 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1913                 functions will not be MT-safe during their first call because
1914                 there is no working 'getpwuid_r' on your system."
1915
1916 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1917                 because there is no 'localtime_r' on your system."
1918
1919 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1920                 crude surrogate will be used. If you happen to know a
1921                 yield function for your system, please inform the GLib
1922                 developers."
1923
1924 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1925                 threads on your system. Thus threads can only have the default
1926                 priority. If you happen to know these main/max
1927                 priorities, please inform the GLib developers."
1928
1929 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1930                 linking threaded applications. As GLib cannot do that
1931                 automatically, you will get an linkg error everytime you are
1932                 not using the right compiler. In that case you have to relink
1933                 with the right compiler. Ususally just '_r' is appended
1934                 to the compiler name."
1935
1936 dnl determination of thread implementation
1937 dnl ***************************************
1938
1939 have_threads=no
1940 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1941                                 || test "x$want_threads" = xdce; then
1942         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1943         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1944         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1945         glib_save_CPPFLAGS="$CPPFLAGS"
1946         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1947         if test "x$have_threads" = xno; then
1948                 AC_TRY_COMPILE([#include <pthread.h>],
1949                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1950                         have_threads=posix)
1951         fi
1952         if test "x$have_threads" = xno; then
1953                 AC_TRY_COMPILE([#include <pthread.h>],
1954                         [pthread_mutex_t m;
1955                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1956                         have_threads=dce)
1957         fi
1958         # Tru64Unix requires -pthread to find pthread.h. See #103020
1959         CPPFLAGS="$CPPFLAGS -pthread"
1960         if test "x$have_threads" = xno; then
1961         AC_TRY_COMPILE([#include <pthread.h>],
1962                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1963                        have_threads=posix)
1964         fi
1965         CPPFLAGS="$glib_save_CPPFLAGS"
1966 fi
1967 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1968         case $host in
1969                 *-*-mingw*)
1970                 have_threads=win32
1971                 ;;
1972         esac
1973 fi
1974
1975 AC_MSG_CHECKING(for thread implementation)
1976
1977 if test "x$have_threads" = xno; then
1978         AC_MSG_RESULT(none available)
1979         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1980 else
1981         AC_MSG_RESULT($have_threads)
1982 fi
1983
1984
1985 dnl determination of G_THREAD_CFLAGS
1986 dnl ********************************
1987
1988 G_THREAD_LIBS=
1989 G_THREAD_LIBS_EXTRA=
1990 G_THREAD_CFLAGS=
1991
1992 dnl
1993 dnl Test program for basic POSIX threads functionality
1994 dnl
1995 m4_define([glib_thread_test],[
1996 #include <pthread.h>
1997 int check_me = 0;
1998 void* func(void* data) {check_me = 42; return &check_me;}
1999 int main()
2000  { pthread_t t;
2001    void *ret;
2002    pthread_create (&t, $1, func, 0);
2003    pthread_join (t, &ret);
2004    return (check_me != 42 || ret != &check_me);
2005 }])
2006
2007 dnl
2008 dnl Test program for sched_get_priority_min()
2009 dnl
2010 m4_define([glib_sched_priority_test],[
2011 #include <sched.h>
2012 #include <errno.h>
2013 int main() {
2014     errno = 0;
2015     return sched_get_priority_min(SCHED_OTHER)==-1
2016            && errno != 0;
2017 }])
2018
2019 if test x"$have_threads" = xposix; then
2020   # First we test for posix, whether -pthread or -pthreads do the trick as
2021   # both CPPFLAG and LIBS.
2022   # One of them does for most gcc versions and some other platforms/compilers
2023   # too and could be considered as the canonical way to go.
2024   case $host in
2025     *-*-cygwin*|*-*-darwin*)
2026        # skip cygwin and darwin -pthread or -pthreads test
2027        ;;
2028     *-solaris*)
2029       # These compiler/linker flags work with both Sun Studio and gcc
2030       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2031       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2032       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2033       G_THREAD_LIBS="-lpthread -lthread"
2034       ;;
2035     *)
2036       for flag in pthread pthreads mt; do
2037         glib_save_CFLAGS="$CFLAGS"
2038         CFLAGS="$CFLAGS -$flag"
2039         AC_TRY_RUN(glib_thread_test(0),
2040                    glib_flag_works=yes,
2041                    glib_flag_works=no,
2042                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2043                                    glib_flag_works=yes,
2044                                    glib_flag_works=no)])
2045         CFLAGS="$glib_save_CFLAGS"
2046         if test $glib_flag_works = yes ; then
2047            G_THREAD_CFLAGS=-$flag
2048         G_THREAD_LIBS=-$flag
2049         break;
2050         fi
2051       done
2052        ;;
2053   esac
2054 fi
2055
2056 if test x"$G_THREAD_CFLAGS" = x; then
2057
2058   # The canonical -pthread[s] does not work. Try something different.
2059
2060   case $host in
2061         *-aix*)
2062                 if test x"$GCC" = xyes; then
2063                         # GCC 3.0 and above needs -pthread.
2064                         # Should be coverd by the case above.
2065                         # GCC 2.x and below needs -mthreads
2066                         G_THREAD_CFLAGS="-mthreads"
2067                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2068                 else
2069                         # We are probably using the aix compiler. Normaly a
2070                         # program would have to be compiled with the _r variant
2071                         # of the corresponding compiler, but we as GLib cannot
2072                         # do that: but the good news is that for compiling the
2073                         # only difference is the added -D_THREAD_SAFE compile
2074                         # option. This is according to the "C for AIX User's
2075                         # Guide".
2076                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2077                 fi
2078                 ;;
2079         *-dg-dgux*)  # DG/UX
2080                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2081                 ;;
2082         *-osf*)
2083                 # So we are using dce threads. posix threads are already
2084                 # catched above.
2085                 G_THREAD_CFLAGS="-threads"
2086                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2087                 ;;
2088         *-sysv5uw7*) # UnixWare 7
2089                 # We are not using gcc with -pthread. Catched above.
2090                 G_THREAD_CFLAGS="-Kthread"
2091                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2092                 ;;
2093         *-mingw*)
2094                 # No flag needed when using MSVCRT.DLL
2095                 G_THREAD_CFLAGS=""
2096                 ;;
2097         *)
2098                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2099                 ;;
2100   esac
2101
2102 fi
2103
2104 # if we are not finding the localtime_r function, then we probably are
2105 # not using the proper multithread flag
2106
2107 glib_save_CPPFLAGS="$CPPFLAGS"
2108 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2109
2110 # First we test, whether localtime_r is declared in time.h
2111 # directly. Then we test whether a macro localtime_r exists, in
2112 # which case localtime_r in the test program is replaced and thus
2113 # if we still find localtime_r in the output, it is not defined as
2114 # a macro.
2115
2116 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2117   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2118                                                            localtime_r(a,b)],
2119                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2120
2121 CPPFLAGS="$glib_save_CPPFLAGS"
2122
2123 AC_MSG_CHECKING(thread related cflags)
2124 AC_MSG_RESULT($G_THREAD_CFLAGS)
2125 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2126
2127 dnl determination of G_THREAD_LIBS
2128 dnl ******************************
2129
2130 mutex_has_default=no
2131 case $have_threads in
2132         posix|dce)
2133           glib_save_CPPFLAGS="$CPPFLAGS"
2134           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2135           if test x"$G_THREAD_LIBS" = x; then
2136             case $host in
2137               *-aix*)
2138                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2139                 # probably using the aix compiler.
2140                 AC_MSG_WARN($AIX_COMPILE_INFO)
2141                 ;;
2142               *)
2143                 G_THREAD_LIBS=error
2144                 glib_save_LIBS="$LIBS"
2145                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2146                         if test x"$thread_lib" = x; then
2147                                 add_thread_lib=""
2148                                 IN=""
2149                         else
2150                                 add_thread_lib="-l$thread_lib"
2151                                 IN=" in -l$thread_lib"
2152                         fi
2153                         if test x"$have_threads" = xposix; then
2154                                 defattr=0
2155                         else
2156                                 defattr=pthread_attr_default
2157                         fi
2158
2159                         LIBS="$add_thread_lib $glib_save_LIBS"
2160
2161                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2162                         AC_TRY_RUN(glib_thread_test($defattr),
2163                                    glib_result=yes,
2164                                    glib_result=no,
2165                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2166                                                    glib_result=yes,
2167                                                    glib_result=no)])
2168                         AC_MSG_RESULT($glib_result)
2169
2170                         if test "$glib_result" = "yes" ; then
2171                           G_THREAD_LIBS="$add_thread_lib"
2172                           break
2173                         fi
2174                 done
2175                 if test "x$G_THREAD_LIBS" = xerror; then
2176                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2177                 fi
2178                 LIBS="$glib_save_LIBS"
2179                 ;;
2180             esac
2181           fi
2182
2183           glib_save_LIBS="$LIBS"
2184           for thread_lib in "" rt rte; do
2185             if test x"$thread_lib" = x; then
2186               add_thread_lib=""
2187               IN=""
2188             else
2189               add_thread_lib="-l$thread_lib"
2190               IN=" in -l$thread_lib"
2191             fi
2192             LIBS="$add_thread_lib $glib_save_LIBS"
2193
2194             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2195             AC_TRY_RUN(glib_sched_priority_test,
2196                        glib_result=yes,
2197                        glib_result=no,
2198                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2199                                        glib_result=yes,
2200                                        glib_result=no)])
2201             AC_MSG_RESULT($glib_result)
2202
2203             if test "$glib_result" = "yes" ; then
2204                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2205                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2206                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2207                break
2208             fi
2209           done
2210           LIBS="$glib_save_LIBS"
2211           mutex_has_default=yes
2212           mutex_default_type='pthread_mutex_t'
2213           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2214           mutex_header_file='pthread.h'
2215           if test "x$have_threads" = "xposix"; then
2216             g_threads_impl="POSIX"
2217           else
2218             g_threads_impl="DCE"
2219             have_threads="posix"
2220           fi
2221           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2222           CPPFLAGS="$glib_save_CPPFLAGS"
2223           ;;
2224         win32)
2225            g_threads_impl="WIN32"
2226            ;;
2227         *)
2228            g_threads_impl="NONE"
2229            G_THREAD_LIBS=error
2230            ;;
2231 esac
2232
2233 if test "x$G_THREAD_LIBS" = xerror; then
2234         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2235 fi
2236
2237 case $host in
2238   *-*-beos*)
2239     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2240     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2241     ;;
2242   *)
2243     ;;
2244 esac
2245
2246 AC_MSG_CHECKING(thread related libraries)
2247 AC_MSG_RESULT($G_THREAD_LIBS)
2248
2249 dnl check for mt safe function variants and some posix functions
2250 dnl ************************************************************
2251
2252 glib_save_LIBS="$LIBS"
2253 # we are not doing the following for now, as this might require glib
2254 # to always be linked with the thread libs on some platforms.
2255 # LIBS="$LIBS $G_THREAD_LIBS"
2256 AC_CHECK_FUNCS(localtime_r gmtime_r)
2257 if test "$ac_cv_header_pwd_h" = "yes"; then
2258         AC_CACHE_CHECK([for posix getpwuid_r],
2259                 ac_cv_func_posix_getpwuid_r,
2260                 [AC_TRY_RUN([
2261 #include <errno.h>
2262 #include <pwd.h>
2263 int main () {
2264     char buffer[10000];
2265     struct passwd pwd, *pwptr = &pwd;
2266     int error;
2267     errno = 0;
2268     error = getpwuid_r (0, &pwd, buffer,
2269                         sizeof (buffer), &pwptr);
2270    return (error < 0 && errno == ENOSYS)
2271            || error == ENOSYS;
2272 }                               ],
2273                         [ac_cv_func_posix_getpwuid_r=yes],
2274                         [ac_cv_func_posix_getpwuid_r=no])])
2275         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2276         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2277                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2278                         [Have POSIX function getpwuid_r])
2279         else
2280                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2281                         ac_cv_func_nonposix_getpwuid_r,
2282                         [AC_TRY_LINK([#include <pwd.h>],
2283                                 [char buffer[10000];
2284                                 struct passwd pwd;
2285                                 getpwuid_r (0, &pwd, buffer,
2286                                                 sizeof (buffer));],
2287                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2288                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2289                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2290                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2291                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2292                                 [Have non-POSIX function getpwuid_r])
2293                 fi
2294         fi
2295 fi
2296 if test "$ac_cv_header_grp_h" = "yes"; then
2297         AC_CACHE_CHECK([for posix getgrgid_r],
2298                 ac_cv_func_posix_getgrgid_r,
2299                 [AC_TRY_RUN([
2300 #include <errno.h>
2301 #include <grp.h>
2302 int main () {
2303     char buffer[10000];
2304     struct group grp, *grpptr = &grp;
2305     int error;
2306     errno = 0;
2307     error = getgrgid_r (0, &grp, buffer,
2308                         sizeof (buffer), &grpptr);
2309    return (error < 0 && errno == ENOSYS)
2310            || error == ENOSYS;
2311 }                              ],
2312                        [ac_cv_func_posix_getgrgid_r=yes],
2313                        [ac_cv_func_posix_getgrgid_r=no])])
2314         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2315         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2316                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2317                         [Have POSIX function getgrgid_r])
2318         else
2319                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2320                         ac_cv_func_nonposix_getgrgid_r,
2321                         [AC_TRY_LINK([#include <grp.h>],
2322                                 [char buffer[10000];
2323                                 struct group grp;
2324                                 getgrgid_r (0, &grp, buffer,
2325                                 sizeof (buffer));],
2326                         [ac_cv_func_nonposix_getgrgid_r=yes],
2327                         [ac_cv_func_nonposix_getgrgid_r=no])])
2328                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2329                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2330                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2331                                 [Have non-POSIX function getgrgid_r])
2332                 fi
2333         fi
2334 fi
2335 LIBS="$G_THREAD_LIBS $LIBS"
2336 if test x"$have_threads" = xposix; then
2337         glib_save_CPPFLAGS="$CPPFLAGS"
2338         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2339         dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2340         GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2341         # This is not AC_CHECK_FUNC to also work with function
2342         # name mangling in header files.
2343         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2344         AC_TRY_LINK([#include <pthread.h>],
2345                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2346                 [AC_MSG_RESULT(yes)
2347                 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2348                           [Have function pthread_attr_setstacksize])],
2349                 [AC_MSG_RESULT(no)])
2350         AC_MSG_CHECKING(for minimal/maximal thread priority)
2351         if test x"$posix_priority_min" = x; then
2352                 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2353                         PX_PRIO_MIN],,[
2354                         posix_priority_min=PX_PRIO_MIN
2355                         posix_priority_max=PX_PRIO_MAX])
2356         fi
2357         if test x"$posix_priority_min" = x; then
2358                 # AIX
2359                 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2360                         PTHREAD_PRIO_MIN],,[
2361                         posix_priority_min=PTHREAD_PRIO_MIN
2362                         posix_priority_max=PTHREAD_PRIO_MAX])
2363         fi
2364         if test x"$posix_priority_min" = x; then
2365                 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2366                         PRI_OTHER_MIN],,[
2367                         posix_priority_min=PRI_OTHER_MIN
2368                         posix_priority_max=PRI_OTHER_MAX])
2369         fi
2370         if test x"$posix_priority_min" = x; then
2371                 AC_MSG_RESULT(none found)
2372                 AC_MSG_WARN($POSIX_NO_PRIORITIES)
2373                 posix_priority_min=-1
2374                 posix_priority_max=-1
2375         else
2376                 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2377                 AC_MSG_CHECKING(for pthread_setschedparam)
2378                 AC_TRY_LINK([#include <pthread.h>],
2379                   [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2380                   [AC_MSG_RESULT(yes)
2381                 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2382                    AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2383                   [AC_MSG_RESULT(no)
2384                    AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2385         fi
2386         posix_yield_func=none
2387         AC_MSG_CHECKING(for posix yield function)
2388         for yield_func in sched_yield pthread_yield_np pthread_yield \
2389                                                 thr_yield; do
2390                 AC_TRY_LINK([#include <pthread.h>],
2391                         [$yield_func()],
2392                         [posix_yield_func="$yield_func"
2393                         break])
2394         done
2395         if test x"$posix_yield_func" = xnone; then
2396                 AC_MSG_RESULT(none found)
2397                 AC_MSG_WARN($POSIX_NO_YIELD)
2398                 posix_yield_func="g_usleep(1000)"
2399         else
2400                 AC_MSG_RESULT($posix_yield_func)
2401                 posix_yield_func="$posix_yield_func()"
2402         fi
2403         AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2404         CPPFLAGS="$glib_save_CPPFLAGS"
2405
2406 elif test x"$have_threads" = xwin32; then
2407         # It's a pointer to a private struct
2408         GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2409 fi
2410
2411 LIBS="$glib_save_LIBS"
2412
2413 # now spit out all the warnings.
2414 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2415    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2416         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2417 fi
2418 if test "$ac_cv_func_localtime_r" != "yes"; then
2419         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2420 fi
2421
2422 if test x"$glib_cv_sizeof_system_thread" = x; then
2423    # use a pointer as a fallback.
2424    GLIB_SIZEOF(,void *, system_thread)
2425 fi
2426
2427 #
2428 # Hack to deal with:
2429 #
2430 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2431 #     building shared libraries with linux.
2432 #  b) FreeBSD doesn't do this either.
2433 #
2434 case $host in
2435   *-*-freebsd*|*-*-linux*)
2436     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2437     ;;
2438   *)
2439     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2440     ;;
2441 esac
2442
2443 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2444                    [Source file containing thread implementation])
2445 AC_SUBST(G_THREAD_CFLAGS)
2446 AC_SUBST(G_THREAD_LIBS)
2447 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2448 AC_SUBST(G_THREAD_LIBS_EXTRA)
2449
2450 dnl **********************************************
2451 dnl *** GDefaultMutex setup and initialization ***
2452 dnl **********************************************
2453 dnl
2454 dnl if mutex_has_default = yes, we also got
2455 dnl mutex_default_type, mutex_default_init and mutex_header_file
2456 if test $mutex_has_default = yes ; then
2457         glib_save_CPPFLAGS="$CPPFLAGS"
2458         glib_save_LIBS="$LIBS"
2459         LIBS="$G_THREAD_LIBS $LIBS"
2460         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2461         GLIB_SIZEOF([#include <$mutex_header_file>],
2462                     $mutex_default_type,
2463                     gmutex)
2464         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2465                            $mutex_default_type,
2466                            gmutex,
2467                            $glib_cv_sizeof_gmutex,
2468                            $mutex_default_init)
2469         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2470                 mutex_has_default=no
2471         fi
2472         CPPFLAGS="$glib_save_CPPFLAGS"
2473         LIBS="$glib_save_LIBS"
2474 fi
2475
2476 AC_CHECK_FUNCS(clock_gettime, [], [
2477   AC_CHECK_LIB(rt, clock_gettime, [
2478     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2479     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2480     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2481     GLIB_RT_LIBS="-lrt"
2482   ])
2483 ])
2484 AC_SUBST(GLIB_RT_LIBS)
2485
2486 AC_CACHE_CHECK(for monotonic clocks,
2487     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2488 #include <time.h>
2489 #include <unistd.h>
2490 int main() {
2491 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2492         #error No monotonic clock
2493 #endif
2494         return 0;
2495 }
2496 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2497 if test "$glib_cv_monotonic_clock" = "yes"; then
2498   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2499 fi
2500
2501
2502 dnl ************************
2503 dnl *** g_atomic_* tests ***
2504 dnl ************************
2505
2506 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2507     case $host_cpu in
2508       i386)
2509         AC_MSG_RESULT([none])
2510         glib_memory_barrier_needed=no
2511         ;;
2512       i?86)
2513         AC_MSG_RESULT([i486])
2514         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2515                            [i486 atomic implementation])
2516         glib_memory_barrier_needed=no
2517         ;;
2518       sparc*)
2519         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2520                          when you are using a sparc with v9 instruction set (most
2521                          sparcs nowadays). This will make the code for atomic
2522                          operations much faster. The resulting code will not run
2523                          on very old sparcs though."
2524
2525         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2526           main ()
2527           {
2528             int tmp1, tmp2, tmp3;
2529             __asm__ __volatile__("casx [%2], %0, %1"
2530                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2531           }]])],
2532           AC_MSG_RESULT([sparcv9])
2533           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2534                              [sparcv9 atomic implementation]),
2535           AC_MSG_RESULT([no])
2536           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2537         glib_memory_barrier_needed=yes
2538         ;;
2539       alpha*)
2540         AC_MSG_RESULT([alpha])
2541         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2542                            [alpha atomic implementation])
2543         glib_memory_barrier_needed=yes
2544         ;;
2545       x86_64)
2546         AC_MSG_RESULT([x86_64])
2547         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2548                            [x86_64 atomic implementation])
2549         glib_memory_barrier_needed=no
2550        ;;
2551       powerpc*)
2552         AC_MSG_RESULT([powerpc])
2553         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2554                            [powerpc atomic implementation])
2555         glib_memory_barrier_needed=yes
2556         AC_MSG_CHECKING([whether asm supports numbered local labels])
2557         AC_TRY_COMPILE(
2558                        ,[
2559                        __asm__ __volatile__ ("1:       nop\n"
2560                                "         bne-    1b")
2561                        ],[
2562                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2563                        AC_MSG_RESULT([yes])
2564                        ],[
2565                        AC_MSG_RESULT([no])
2566                        ])
2567         ;;
2568       ia64)
2569         AC_MSG_RESULT([ia64])
2570         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2571                            [ia64 atomic implementation])
2572         glib_memory_barrier_needed=yes
2573         ;;
2574       s390|s390x)
2575         AC_MSG_RESULT([s390])
2576         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2577                            [s390 atomic implementation])
2578         glib_memory_barrier_needed=no
2579         ;;
2580       arm*)
2581         AC_MSG_RESULT([arm])
2582         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2583                            [arm atomic implementation])
2584         glib_memory_barrier_needed=no
2585         ;;
2586       crisv32*|etraxfs*)
2587         AC_MSG_RESULT([crisv32])
2588         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2589                            [crisv32 atomic implementation])
2590         glib_memory_barrier_needed=no
2591         ;;
2592       cris*|etrax*)
2593         AC_MSG_RESULT([cris])
2594         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2595                            [cris atomic implementation])
2596         glib_memory_barrier_needed=no
2597         ;;
2598       *)
2599         AC_MSG_RESULT([none])
2600         glib_memory_barrier_needed=yes
2601         ;;
2602     esac
2603
2604 glib_cv_gcc_has_builtin_atomic_operations=no
2605 if test x"$GCC" = xyes; then
2606   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2607   AC_TRY_LINK([],
2608               [int i;
2609                __sync_synchronize ();
2610                __sync_bool_compare_and_swap (&i, 0, 1);
2611                __sync_fetch_and_add (&i, 1);
2612               ],
2613               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2614               [glib_cv_gcc_has_builtin_atomic_operations=no])
2615
2616   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2617 fi
2618 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2619                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2620
2621 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2622 glib_cv_has_win32_atomic_operations=no
2623 AC_TRY_LINK([],
2624         [int i; _InterlockedExchangeAdd (&i, 0);],
2625         [glib_cv_has_win32_atomic_operations=yes],
2626         [glib_cv_has_win32_atomic_operations=no])
2627 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2628 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2629         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2630 fi
2631
2632 dnl ************************
2633 dnl ** Check for futex(2) **
2634 dnl ************************
2635 AC_CACHE_CHECK(for futex(2) system call,
2636     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2637 #include <linux/futex.h>
2638 #include <sys/syscall.h>
2639 #include <unistd.h>
2640 ],[
2641 int
2642 main (void)
2643 {
2644   /* it is not like this actually runs or anything... */
2645   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2646   return 0;
2647 }
2648 ])],glib_cv_futex=yes,glib_cv_futex=no))
2649 if test x"$glib_cv_futex" = xyes; then
2650   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2651 fi
2652
2653 AC_CACHE_CHECK(for eventfd(2) system call,
2654     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2655 #include <sys/eventfd.h>
2656 #include <unistd.h>
2657 ],[
2658 int
2659 main (void)
2660 {
2661   eventfd (0, EFD_CLOEXEC);
2662   return 0;
2663 }
2664 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2665 if test x"$glib_cv_eventfd" = x"yes"; then
2666   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2667 fi
2668 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2669
2670 dnl ****************************************
2671 dnl *** GLib POLL* compatibility defines ***
2672 dnl ****************************************
2673
2674 glib_poll_includes=["
2675 #include <sys/types.h>
2676 #include <sys/poll.h>
2677 "]
2678
2679 if test $ac_cv_header_sys_types_h = yes &&
2680    test $ac_cv_header_sys_poll_h = yes ; then
2681   glib_failed=false
2682   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2683   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2684   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2685   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2686   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2687   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2688   if $glib_failed ; then
2689     AC_MSG_ERROR([Could not determine values for POLL* constants])
2690   fi
2691 else
2692   glib_cv_value_POLLIN=1
2693   glib_cv_value_POLLOUT=4
2694   glib_cv_value_POLLPRI=2
2695   glib_cv_value_POLLERR=8
2696   glib_cv_value_POLLHUP=16
2697   glib_cv_value_POLLNVAL=32
2698 fi
2699
2700 AC_MSG_CHECKING([for broken poll])
2701 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2702         #include <stdlib.h>
2703         #include <fcntl.h>
2704         #include <poll.h>
2705         #ifdef HAVE_SYS_POLL_H
2706         #include <sys/poll.h>
2707         #endif
2708         int main(void) {
2709           struct pollfd fds[1];
2710           int fd;
2711           fd = open("/dev/null", 1);
2712           fds[0].fd = fd;
2713           fds[0].events = POLLIN;
2714           fds[0].revents = 0;
2715           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2716                 exit(1);  /* Does not work for devices -- fail */
2717           }
2718           exit(0);
2719         }]])],
2720   [broken_poll=no],
2721   [broken_poll=yes
2722    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2723   [broken_poll="no (cross compiling)"])
2724 AC_MSG_RESULT($broken_poll)
2725
2726 dnl *********************
2727 dnl *** GRegex checks ***
2728 dnl *********************
2729 PCRE_REQUIRED_VERSION=8.11
2730
2731 # Check if we should compile GRegex
2732 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2733               [disable the compilation of GRegex]),
2734 [case "${enableval}" in
2735   yes) enable_regex=true ;;
2736   no)  enable_regex=false ;;
2737   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2738 esac],
2739 [enable_regex=true])
2740
2741 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2742
2743 if test x$enable_regex = xtrue; then
2744   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2745   # Check if we should use the internal or the system-supplied pcre
2746   AC_ARG_WITH(pcre,
2747              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2748                              [specify whether to use the internal or the
2749                               system-supplied PCRE library])])
2750
2751   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2752
2753   if test "x$with_pcre" = xsystem; then
2754     PKG_CHECK_MODULES(PCRE,
2755                       libpcre >= $PCRE_REQUIRED_VERSION)
2756     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2757                    glib_save_CFLAGS="$CFLAGS"
2758                    glib_save_LIBS="$LIBS"
2759                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2760                    AC_TRY_RUN([#include <pcre.h>
2761                                int main () {
2762                                  int support;
2763                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2764                                  if (!support)
2765                                    return 1;
2766                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2767                                  if (!support)
2768                                    return 1;
2769                                  return 0;
2770                                }],
2771                    glib_cv_pcre_has_unicode=yes,
2772                    glib_cv_pcre_has_unicode=no,
2773                    glib_cv_pcre_has_unicode=yes)
2774                    CFLAGS="$glib_save_CFLAGS"
2775                    LIBS="$glib_save_LIBS"
2776         ])
2777     if test "$glib_cv_pcre_has_unicode" = "no"; then
2778       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2779     fi
2780     AC_SUBST(PCRE_CFLAGS)
2781     AC_SUBST(PCRE_LIBS)
2782     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2783     PCRE_REQUIRES=libpcre
2784     AC_SUBST(PCRE_REQUIRES)
2785   else
2786     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2787     if test x"$GCC" = xyes; then
2788       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2789       save_CFLAGS="$CFLAGS"
2790       CFLAGS="$CFLAGS -Wno-pointer-sign"
2791       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2792                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2793       CFLAGS="$save_CFLAGS"
2794     fi
2795   fi
2796   AC_SUBST(PCRE_WARN_CFLAGS)
2797 else
2798   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2799 fi
2800
2801 dnl **********************
2802 dnl *** Win32 API libs ***
2803 dnl **********************
2804
2805 case $host in
2806   *-*-cygwin*)
2807         G_LIBS_EXTRA="-luser32 -lkernel32"
2808     ;;
2809   *-*-mingw*)
2810         G_LIBS_EXTRA="-lws2_32 -lole32"
2811     ;;
2812   *)
2813         G_LIBS_EXTRA=""
2814     ;;
2815 esac
2816 AC_SUBST(G_LIBS_EXTRA)
2817
2818 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2819 dnl since we need it for g_iconv()
2820
2821 AC_MSG_CHECKING([for EILSEQ])
2822 AC_TRY_COMPILE([
2823 #include <errno.h>
2824 ],
2825 [
2826 int error = EILSEQ;
2827 ], have_eilseq=yes, have_eilseq=no);
2828 AC_MSG_RESULT($have_eilseq)
2829
2830 dnl ******************************************************************
2831 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2832 dnl *** glib-compile-schemas in PATH                               ***
2833 dnl ******************************************************************
2834
2835 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2836
2837 if test $cross_compiling = yes; then
2838   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2839   if test x$GLIB_GENMARSHAL = xno; then
2840     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2841   fi
2842
2843   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2844   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2845     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2846   fi
2847 fi
2848
2849 dnl **************************
2850 dnl *** Checks for gtk-doc ***
2851 dnl **************************
2852
2853 GTK_DOC_CHECK([1.15])
2854
2855 AC_ARG_ENABLE(man,
2856               [AC_HELP_STRING([--enable-man],
2857                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2858               enable_man=no)
2859
2860 if test "${enable_man}" != no; then
2861 dnl
2862 dnl Check for xsltproc
2863 dnl
2864 AC_PATH_PROG([XSLTPROC], [xsltproc])
2865   if test -z "$XSLTPROC"; then
2866     enable_man=no
2867   fi
2868
2869   dnl check for DocBook DTD and stylesheets in the local catalog.
2870   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2871      [DocBook XML DTD V4.1.2],,enable_man=no)
2872   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2873      [DocBook XSL Stylesheets],,enable_man=no)
2874 fi
2875
2876 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2877
2878 dnl
2879 dnl Tracing
2880 dnl
2881
2882 AC_ARG_ENABLE([dtrace],
2883              [AS_HELP_STRING([--enable-dtrace],
2884                               [Enable inclusion of dtrace trace support])])
2885 have_dtrace=no
2886 AC_MSG_CHECKING([whether to include dtrace tracing support])
2887 if test "x$enable_dtrace" != xno; then
2888   if test x$glib_have_carbon = xyes; then
2889     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2890   else
2891     AC_MSG_RESULT([yes])
2892     AC_CHECK_PROGS(DTRACE, dtrace)
2893     if test -z "$DTRACE"; then
2894       if test "x$enable_dtrace" = xyes; then
2895         AC_MSG_ERROR([dtrace not found])
2896       fi
2897     else
2898       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2899                       [if test "x$enable_dtrace" = xyes; then
2900                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2901                        fi])
2902     fi
2903   fi
2904 else
2905   AC_MSG_RESULT([no])
2906 fi
2907 if test "x$have_dtrace" = xyes; then
2908   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2909 fi
2910 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2911
2912 AC_MSG_CHECKING([whether to include systemtap tracing support])
2913 AC_ARG_ENABLE([systemtap],
2914              [AS_HELP_STRING([--enable-systemtap],
2915                               [Enable inclusion of systemtap trace support])])
2916 have_systemtap=no
2917 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2918   have_systemtap=yes
2919 fi
2920 AC_MSG_RESULT(${have_systemtap})
2921
2922 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2923
2924 AC_ARG_WITH([tapset-install-dir],
2925             [AS_HELP_STRING([--with-tapset-install-dir],
2926             [The absolute path where the systemtap tapsets will be installed])],
2927             [if test "x${withval}" = x; then
2928                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2929              else
2930                ABS_TAPSET_DIR="${withval}"
2931               fi],
2932             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2933 AC_SUBST(ABS_TAPSET_DIR)
2934
2935 dnl ************************************
2936 dnl *** Enable lcov coverage reports ***
2937 dnl ************************************
2938
2939 AC_ARG_ENABLE(gcov,
2940   AS_HELP_STRING([--enable-gcov],
2941                  [Enable gcov]),
2942   [use_gcov=$enableval], [use_gcov=no])
2943
2944 if test "x$use_gcov" = "xyes"; then
2945   dnl we need gcc:
2946   if test "$GCC" != "yes"; then
2947     AC_MSG_ERROR([GCC is required for --enable-gcov])
2948   fi
2949
2950   dnl Check if ccache is being used
2951   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2952   case `$SHTOOL path $CC` in
2953     *ccache*[)] gcc_ccache=yes;;
2954     *[)] gcc_ccache=no;;
2955   esac
2956
2957   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2958     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2959   fi
2960
2961   ltp_version_list="1.6 1.7 1.8 1.9"
2962   AC_CHECK_PROG(LTP, lcov, lcov)
2963   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2964
2965   if test "$LTP"; then
2966     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2967       glib_cv_ltp_version=invalid
2968       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2969       for ltp_check_version in $ltp_version_list; do
2970         if test "$ltp_version" = "$ltp_check_version"; then
2971           glib_cv_ltp_version="$ltp_check_version (ok)"
2972         fi
2973       done
2974     ])
2975   else
2976     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2977     AC_MSG_ERROR([$ltp_msg])
2978   fi
2979
2980   case $glib_cv_ltp_version in
2981     ""|invalid[)]
2982       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2983       AC_MSG_ERROR([$ltp_msg])
2984       LTP="exit 0;"
2985       ;;
2986   esac
2987
2988   if test -z "$LTP_GENHTML"; then
2989     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2990   fi
2991
2992   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2993
2994   dnl Remove all optimization flags from CFLAGS
2995   changequote({,})
2996   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2997   changequote([,])
2998
2999   dnl Add the special gcc flags
3000   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
3001   LDFLAGS="$LDFLAGS -lgcov"
3002 fi
3003
3004 dnl ******************************
3005 dnl *** output the whole stuff ***
3006 dnl ******************************
3007
3008 dnl this section will only be run if config.status is invoked with no
3009 dnl arguments, or with "glib/glibconfig.h" as an argument.
3010 AC_CONFIG_COMMANDS([glib/glibconfig.h],
3011 [
3012         outfile=glib/glibconfig.h-tmp
3013         cat > $outfile <<\_______EOF
3014 /* glibconfig.h
3015  *
3016  * This is a generated file.  Please modify 'configure.ac'
3017  */
3018
3019 #ifndef __G_LIBCONFIG_H__
3020 #define __G_LIBCONFIG_H__
3021
3022 #include <glib/gmacros.h>
3023
3024 _______EOF
3025
3026         if test x$glib_limits_h = xyes; then
3027           echo '#include <limits.h>' >> $outfile
3028         fi
3029         if test x$glib_float_h = xyes; then
3030           echo '#include <float.h>' >> $outfile
3031         fi
3032         if test x$glib_values_h = xyes; then
3033           echo '#include <values.h>' >> $outfile
3034         fi
3035         if test "$glib_header_alloca_h" = "yes"; then
3036           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
3037         fi
3038         if test x$glib_sys_poll_h = xyes; then
3039           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
3040         fi
3041         if test x$glib_included_printf != xyes; then
3042           echo "
3043 /* Specifies that GLib's g_print*() functions wrap the
3044  * system printf functions.  This is useful to know, for example,
3045  * when using glibc's register_printf_function().
3046  */" >> $outfile
3047           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
3048         fi
3049
3050         cat >> $outfile <<_______EOF
3051
3052 G_BEGIN_DECLS
3053
3054 #define G_MINFLOAT      $glib_mf
3055 #define G_MAXFLOAT      $glib_Mf
3056 #define G_MINDOUBLE     $glib_md
3057 #define G_MAXDOUBLE     $glib_Md
3058 #define G_MINSHORT      $glib_ms
3059 #define G_MAXSHORT      $glib_Ms
3060 #define G_MAXUSHORT     $glib_Mus
3061 #define G_MININT        $glib_mi
3062 #define G_MAXINT        $glib_Mi
3063 #define G_MAXUINT       $glib_Mui
3064 #define G_MINLONG       $glib_ml
3065 #define G_MAXLONG       $glib_Ml
3066 #define G_MAXULONG      $glib_Mul
3067
3068 _______EOF
3069
3070
3071         ### this should always be true in a modern C/C++ compiler
3072         cat >>$outfile <<_______EOF
3073 typedef signed char gint8;
3074 typedef unsigned char guint8;
3075 _______EOF
3076
3077
3078         if test -n "$gint16"; then
3079           cat >>$outfile <<_______EOF
3080 typedef signed $gint16 gint16;
3081 typedef unsigned $gint16 guint16;
3082 #define G_GINT16_MODIFIER $gint16_modifier
3083 #define G_GINT16_FORMAT $gint16_format
3084 #define G_GUINT16_FORMAT $guint16_format
3085 _______EOF
3086         fi
3087
3088
3089         if test -n "$gint32"; then
3090           cat >>$outfile <<_______EOF
3091 typedef signed $gint32 gint32;
3092 typedef unsigned $gint32 guint32;
3093 #define G_GINT32_MODIFIER $gint32_modifier
3094 #define G_GINT32_FORMAT $gint32_format
3095 #define G_GUINT32_FORMAT $guint32_format
3096 _______EOF
3097         fi
3098
3099         cat >>$outfile <<_______EOF
3100 #define G_HAVE_GINT64 1          /* deprecated, always true */
3101
3102 ${glib_extension}typedef signed $gint64 gint64;
3103 ${glib_extension}typedef unsigned $gint64 guint64;
3104
3105 #define G_GINT64_CONSTANT(val)  $gint64_constant
3106 #define G_GUINT64_CONSTANT(val) $guint64_constant
3107 _______EOF
3108
3109         if test x$gint64_format != x ; then
3110           cat >>$outfile <<_______EOF
3111 #define G_GINT64_MODIFIER $gint64_modifier
3112 #define G_GINT64_FORMAT $gint64_format
3113 #define G_GUINT64_FORMAT $guint64_format
3114 _______EOF
3115         else
3116           cat >>$outfile <<_______EOF
3117 #undef G_GINT64_MODIFIER
3118 #undef G_GINT64_FORMAT
3119 #undef G_GUINT64_FORMAT
3120 _______EOF
3121         fi
3122
3123         cat >>$outfile <<_______EOF
3124
3125 #define GLIB_SIZEOF_VOID_P $glib_void_p
3126 #define GLIB_SIZEOF_LONG   $glib_long
3127 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3128
3129 _______EOF
3130
3131         cat >>$outfile <<_______EOF
3132 typedef signed $glib_size_type_define gssize;
3133 typedef unsigned $glib_size_type_define gsize;
3134 #define G_GSIZE_MODIFIER $gsize_modifier
3135 #define G_GSSIZE_FORMAT $gssize_format
3136 #define G_GSIZE_FORMAT $gsize_format
3137
3138 #define G_MAXSIZE       G_MAXU$glib_msize_type
3139 #define G_MINSSIZE      G_MIN$glib_msize_type
3140 #define G_MAXSSIZE      G_MAX$glib_msize_type
3141
3142 typedef gint64 goffset;
3143 #define G_MINOFFSET     G_MININT64
3144 #define G_MAXOFFSET     G_MAXINT64
3145
3146 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3147 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3148 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3149
3150 _______EOF
3151
3152         if test -z "$glib_unknown_void_p"; then
3153           cat >>$outfile <<_______EOF
3154
3155 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3156 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3157
3158 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3159 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3160
3161 typedef signed $glib_intptr_type_define gintptr;
3162 typedef unsigned $glib_intptr_type_define guintptr;
3163
3164 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3165 #define G_GINTPTR_FORMAT        $gintptr_format
3166 #define G_GUINTPTR_FORMAT       $guintptr_format
3167 _______EOF
3168         else
3169           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3170         fi
3171
3172
3173
3174         cat >>$outfile <<_______EOF
3175 $glib_atexit
3176 $glib_memmove
3177 $glib_defines
3178 $glib_os
3179 $glib_static_compilation
3180
3181 $glib_vacopy
3182
3183 #ifdef  __cplusplus
3184 #define G_HAVE_INLINE   1
3185 #else   /* !__cplusplus */
3186 $glib_inline
3187 #endif  /* !__cplusplus */
3188
3189 #ifdef  __cplusplus
3190 #define G_CAN_INLINE    1
3191 _______EOF
3192
3193         if test x$g_can_inline = xyes ; then
3194                 cat >>$outfile <<_______EOF
3195 #else   /* !__cplusplus */
3196 #define G_CAN_INLINE    1
3197 _______EOF
3198         fi
3199
3200         cat >>$outfile <<_______EOF
3201 #endif
3202
3203 _______EOF
3204
3205         if test x$g_have_iso_c_varargs = xyes ; then
3206                 cat >>$outfile <<_______EOF
3207 #ifndef __cplusplus
3208 # define G_HAVE_ISO_VARARGS 1
3209 #endif
3210 _______EOF
3211         fi
3212         if test x$g_have_iso_cxx_varargs = xyes ; then
3213                 cat >>$outfile <<_______EOF
3214 #ifdef __cplusplus
3215 # define G_HAVE_ISO_VARARGS 1
3216 #endif
3217 _______EOF
3218         fi
3219         if test x$g_have_gnuc_varargs = xyes ; then
3220                 cat >>$outfile <<_______EOF
3221
3222 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3223  * is passed ISO vararg support is turned off, and there is no work
3224  * around to turn it on, so we unconditionally turn it off.
3225  */
3226 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3227 #  undef G_HAVE_ISO_VARARGS
3228 #endif
3229
3230 #define G_HAVE_GNUC_VARARGS 1
3231 _______EOF
3232         fi
3233
3234         case x$g_stack_grows in
3235         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3236         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3237         esac
3238
3239
3240         echo >>$outfile
3241         if test x$g_have_eilseq = xno; then
3242                 cat >>$outfile <<_______EOF
3243 #ifndef EILSEQ
3244 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3245  * The correspondence between this and the corresponding definition
3246  * in libiconv is essential.
3247  */
3248 #  define EILSEQ ENOENT
3249 #endif
3250 _______EOF
3251
3252         fi
3253
3254         if test x$g_have_gnuc_visibility = xyes; then
3255                 cat >>$outfile <<_______EOF
3256 #define G_HAVE_GNUC_VISIBILITY 1
3257 _______EOF
3258         fi
3259                 cat >>$outfile <<_______EOF
3260 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3261 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3262 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3263 #define G_GNUC_INTERNAL __hidden
3264 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3265 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3266 #else
3267 #define G_GNUC_INTERNAL
3268 #endif
3269 _______EOF
3270
3271
3272         echo >>$outfile
3273         if test x$g_mutex_has_default = xyes; then
3274                 cat >>$outfile <<_______EOF
3275 #define G_THREADS_ENABLED
3276 #define G_THREADS_IMPL_$g_threads_impl_def
3277 typedef struct _GStaticMutex GStaticMutex;
3278 struct _GStaticMutex
3279 {
3280   struct _GMutex *runtime_mutex;
3281   union {
3282     char   pad[[$g_mutex_sizeof]];
3283     double dummy_double;
3284     void  *dummy_pointer;
3285     long   dummy_long;
3286   } static_mutex;
3287 };
3288 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3289 #define g_static_mutex_get_mutex(mutex) \\
3290   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3291    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3292 _______EOF
3293         else
3294                 cat >>$outfile <<_______EOF
3295 #define G_THREADS_ENABLED
3296 #define G_THREADS_IMPL_$g_threads_impl_def
3297 typedef struct _GMutex* GStaticMutex;
3298 #define G_STATIC_MUTEX_INIT NULL
3299 #define g_static_mutex_get_mutex(mutex) \\
3300   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3301 _______EOF
3302         fi
3303
3304         cat >>$outfile <<_______EOF
3305 /* This represents a system thread as used by the implementation. An
3306  * alien implementaion, as loaded by g_thread_init can only count on
3307  * "sizeof (gpointer)" bytes to store their info. We however need more
3308  * for some of our native implementations. */
3309 typedef union _GSystemThread GSystemThread;
3310 union _GSystemThread
3311 {
3312   char   data[[$g_system_thread_sizeof]];
3313   double dummy_double;
3314   void  *dummy_pointer;
3315   long   dummy_long;
3316 };
3317 _______EOF
3318         if test x"$g_memory_barrier_needed" != xno; then
3319           echo >>$outfile
3320           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3321         fi
3322         if test x"$g_gcc_atomic_ops" != xno; then
3323           echo >>$outfile
3324           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3325         fi
3326         echo >>$outfile
3327         g_bit_sizes="16 32 64"
3328         for bits in $g_bit_sizes; do
3329           cat >>$outfile <<_______EOF
3330 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3331 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3332 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3333 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3334 _______EOF
3335         done
3336
3337         cat >>$outfile <<_______EOF
3338 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3339 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3340 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3341 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3342 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3343 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3344 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3345 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3346 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3347 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3348 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3349 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3350 #define G_BYTE_ORDER $g_byte_order
3351
3352 #define GLIB_SYSDEF_POLLIN =$g_pollin
3353 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3354 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3355 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3356 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3357 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3358
3359 #define G_MODULE_SUFFIX "$g_module_suffix"
3360
3361 /* A GPid is an abstraction for a process "handle". It is *not* an
3362  * abstraction for a process identifier in general. GPid is used in
3363  * GLib only for descendant processes spawned with the g_spawn*
3364  * functions. On POSIX there is no "process handle" concept as such,
3365  * but on Windows a GPid is a handle to a process, a kind of pointer,
3366  * not a process identifier.
3367  */
3368 typedef $g_pid_type GPid;
3369
3370 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3371 #define GLIB_SYSDEF_AF_INET $g_af_inet
3372 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3373
3374 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3375 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3376 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3377
3378 G_END_DECLS
3379
3380 #endif /* GLIBCONFIG_H */
3381 _______EOF
3382
3383
3384         if cmp -s $outfile glib/glibconfig.h; then
3385           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3386           rm -f $outfile
3387         else
3388           mv $outfile glib/glibconfig.h
3389         fi
3390 ],[
3391
3392 # Note that if two cases are the same, case goes with the first one.
3393 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3394 # on variable expansion in case labels.  Look at the generated config.status
3395 # for a hint.
3396
3397 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3398   glib_header_alloca_h="$ac_cv_working_alloca_h"
3399 else
3400   glib_header_alloca_h="$ac_cv_header_alloca_h"
3401 fi
3402
3403 case xyes in
3404 x$ac_cv_header_float_h)
3405   glib_float_h=yes
3406   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3407   glib_md=DBL_MIN glib_Md=DBL_MAX
3408   ;;
3409 x$ac_cv_header_values_h)
3410   glib_values_h=yes
3411   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3412   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3413   ;;
3414 esac
3415
3416 case xyes in
3417 x$ac_cv_header_limits_h)
3418   glib_limits_h=yes
3419   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3420   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3421   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3422   ;;
3423 x$ac_cv_header_values_h)
3424   glib_values_h=yes
3425   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3426   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3427   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3428   ;;
3429 esac
3430
3431 if test x$ac_cv_header_sys_poll_h = xyes ; then
3432   glib_sys_poll_h=yes
3433 fi
3434
3435 if test x$enable_included_printf = xyes ; then
3436   glib_included_printf=yes
3437 fi
3438
3439 case 2 in
3440 $ac_cv_sizeof_short)
3441   gint16=short
3442   gint16_modifier='"h"'
3443   gint16_format='"hi"'
3444   guint16_format='"hu"'
3445   ;;
3446 $ac_cv_sizeof_int)
3447   gint16=int
3448   gint16_modifier='""'
3449   gint16_format='"i"'
3450   guint16_format='"u"'
3451   ;;
3452 esac
3453 case 4 in
3454 $ac_cv_sizeof_short)
3455   gint32=short
3456   gint32_modifier='"h"'
3457   gint32_format='"hi"'
3458   guint32_format='"hu"'
3459   ;;
3460 $ac_cv_sizeof_int)
3461   gint32=int
3462   gint32_modifier='""'
3463   gint32_format='"i"'
3464   guint32_format='"u"'
3465   ;;
3466 $ac_cv_sizeof_long)
3467   gint32=long
3468   gint32_modifier='"l"'
3469   gint32_format='"li"'
3470   guint32_format='"lu"'
3471   ;;
3472 esac
3473 case 8 in
3474 $ac_cv_sizeof_int)
3475   gint64=int
3476   gint64_modifier='""'
3477   gint64_format='"i"'
3478   guint64_format='"u"'
3479   glib_extension=
3480   gint64_constant='(val)'
3481   guint64_constant='(val)'
3482   ;;
3483 $ac_cv_sizeof_long)
3484   gint64=long
3485   gint64_modifier='"l"'
3486   gint64_format='"li"'
3487   guint64_format='"lu"'
3488   glib_extension=
3489   gint64_constant='(val##L)'
3490   guint64_constant='(val##UL)'
3491   ;;
3492 $ac_cv_sizeof_long_long)
3493   gint64='long long'
3494   if test -n "$glib_cv_long_long_format"; then
3495     gint64_modifier='"'$glib_cv_long_long_format'"'
3496     gint64_format='"'$glib_cv_long_long_format'i"'
3497     guint64_format='"'$glib_cv_long_long_format'u"'
3498   fi
3499   glib_extension='G_GNUC_EXTENSION '
3500   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3501   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3502   ;;
3503 $ac_cv_sizeof___int64)
3504   gint64='__int64'
3505   if test -n "$glib_cv_long_long_format"; then
3506     gint64_modifier='"'$glib_cv_long_long_format'"'
3507     gint64_format='"'$glib_cv_long_long_format'i"'
3508     guint64_format='"'$glib_cv_long_long_format'u"'
3509   fi
3510   glib_extension=
3511   gint64_constant='(val##i64)'
3512   guint64_constant='(val##ui64)'
3513   ;;
3514 esac
3515 glib_size_t=$ac_cv_sizeof_size_t
3516 glib_size_type_define="$glib_size_type"
3517 glib_void_p=$ac_cv_sizeof_void_p
3518 glib_long=$ac_cv_sizeof_long
3519
3520 case "$glib_size_type" in
3521 short)
3522   gsize_modifier='"h"'
3523   gsize_format='"hu"'
3524   gssize_format='"hi"'
3525   glib_msize_type='SHRT'
3526   ;;
3527 int)
3528   gsize_modifier='""'
3529   gsize_format='"u"'
3530   gssize_format='"i"'
3531   glib_msize_type='INT'
3532   ;;
3533 long)
3534   gsize_modifier='"l"'
3535   gsize_format='"lu"'
3536   gssize_format='"li"'
3537   glib_msize_type='LONG'
3538   ;;
3539 "long long"|__int64)
3540   gsize_modifier='"I64"'
3541   gsize_format='"I64u"'
3542   gssize_format='"I64i"'
3543   glib_msize_type='INT64'
3544   ;;
3545 esac
3546
3547 gintbits=`expr $ac_cv_sizeof_int \* 8`
3548 glongbits=`expr $ac_cv_sizeof_long \* 8`
3549 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3550
3551 case $ac_cv_sizeof_void_p in
3552 $ac_cv_sizeof_int)
3553   glib_intptr_type_define=int
3554   gintptr_modifier='""'
3555   gintptr_format='"i"'
3556   guintptr_format='"u"'
3557   glib_gpi_cast=''
3558   glib_gpui_cast=''
3559   ;;
3560 $ac_cv_sizeof_long)
3561   glib_intptr_type_define=long
3562   gintptr_modifier='"l"'
3563   gintptr_format='"li"'
3564   guintptr_format='"lu"'
3565   glib_gpi_cast='(glong)'
3566   glib_gpui_cast='(gulong)'
3567   ;;
3568 $ac_cv_sizeof_long_long)
3569   glib_intptr_type_define='long long'
3570   gintptr_modifier='"I64"'
3571   gintptr_format='"I64i"'
3572   guintptr_format='"I64u"'
3573   glib_gpi_cast='(gint64)'
3574   glib_gpui_cast='(guint64)'
3575   ;;
3576 $ac_cv_sizeof___int64)
3577   glib_intptr_type_define=__int64
3578   gintptr_modifier='"I64"'
3579   gintptr_format='"I64i"'
3580   guintptr_format='"I64u"'
3581   glib_gpi_cast='(gint64)'
3582   glib_gpui_cast='(guint64)'
3583   ;;
3584 *)
3585   glib_unknown_void_p=yes
3586   ;;
3587 esac
3588
3589
3590 case xyes in
3591 x$ac_cv_func_atexit)
3592   glib_atexit="
3593 #ifdef NeXT /* @#%@! NeXTStep */
3594 # define g_ATEXIT(proc) (!atexit (proc))
3595 #else
3596 # define g_ATEXIT(proc) (atexit (proc))
3597 #endif"
3598   ;;
3599 x$ac_cv_func_on_exit)
3600   glib_atexit="
3601 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3602   ;;
3603 esac
3604
3605 case xyes in
3606 x$ac_cv_func_memmove)
3607   glib_memmove='
3608 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3609   ;;
3610 x$glib_cv_working_bcopy)
3611   glib_memmove="
3612 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3613 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3614   ;;
3615 *)
3616   glib_memmove="
3617 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3618  * so we have to roll our own copy routine. */
3619 void g_memmove (void* dest, const void * src, unsigned long len);"
3620   ;;
3621 esac
3622
3623 glib_defines="
3624 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3625 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3626 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3627 "
3628
3629 case xyes in
3630 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3631 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3632 *)                      glib_vacopy=''
3633 esac
3634
3635 if test x$glib_cv_va_val_copy = xno; then
3636   glib_vacopy="\$glib_vacopy
3637 #define G_VA_COPY_AS_ARRAY 1"
3638 fi
3639
3640 if test x$glib_cv_hasinline = xyes; then
3641     glib_inline='#define G_HAVE_INLINE 1'
3642 fi
3643 if test x$glib_cv_has__inline = xyes; then
3644     glib_inline="\$glib_inline
3645 #define G_HAVE___INLINE 1"
3646 fi
3647 if test x$glib_cv_has__inline__ = xyes; then
3648     glib_inline="\$glib_inline
3649 #define G_HAVE___INLINE__ 1"
3650 fi
3651
3652 g_have_gnuc_varargs=$g_have_gnuc_varargs
3653 g_have_iso_c_varargs=$g_have_iso_c_varargs
3654 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3655
3656 g_can_inline=$g_can_inline
3657 g_have_gnuc_visibility=$g_have_gnuc_visibility
3658 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3659
3660 if test x$ac_cv_c_bigendian = xyes; then
3661   g_byte_order=G_BIG_ENDIAN
3662   g_bs_native=BE
3663   g_bs_alien=LE
3664 else
3665   g_byte_order=G_LITTLE_ENDIAN
3666   g_bs_native=LE
3667   g_bs_alien=BE
3668 fi
3669
3670 g_pollin=$glib_cv_value_POLLIN
3671 g_pollout=$glib_cv_value_POLLOUT
3672 g_pollpri=$glib_cv_value_POLLPRI
3673 g_pollhup=$glib_cv_value_POLLHUP
3674 g_pollerr=$glib_cv_value_POLLERR
3675 g_pollnval=$glib_cv_value_POLLNVAL
3676
3677 g_af_unix=$glib_cv_value_AF_UNIX
3678 g_af_inet=$glib_cv_value_AF_INET
3679 g_af_inet6=$glib_cv_value_AF_INET6
3680
3681 g_msg_peek=$glib_cv_value_MSG_PEEK
3682 g_msg_oob=$glib_cv_value_MSG_OOB
3683 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3684
3685 g_stack_grows=$glib_cv_stack_grows
3686
3687 g_have_eilseq=$have_eilseq
3688
3689 g_threads_impl_def=$g_threads_impl
3690
3691 g_mutex_has_default="$mutex_has_default"
3692 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3693 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3694 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3695
3696 g_memory_barrier_needed="$glib_memory_barrier_needed"
3697 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3698
3699 g_module_suffix="$glib_gmodule_suffix"
3700
3701 g_pid_type="$glib_pid_type"
3702 case $host in
3703   *-*-beos*)
3704     glib_os="#define G_OS_BEOS"
3705     ;;
3706   *-*-cygwin*)
3707     glib_os="#define G_OS_UNIX
3708 #define G_PLATFORM_WIN32
3709 #define G_WITH_CYGWIN"
3710     ;;
3711   *-*-mingw*)
3712     glib_os="#define G_OS_WIN32
3713 #define G_PLATFORM_WIN32"
3714     ;;
3715   *)
3716     glib_os="#define G_OS_UNIX"
3717     ;;
3718 esac
3719 glib_static_compilation=""
3720 if test x$glib_win32_static_compilation = xyes; then
3721   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3722 #define GOBJECT_STATIC_COMPILATION 1"
3723 fi
3724 ])
3725
3726 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3727 #
3728 # 1.2.14 required for dbus_message_set_serial
3729 PKG_CHECK_MODULES(DBUS1,
3730                   dbus-1 >= 1.2.14,
3731                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3732                   have_dbus1=no)
3733 AC_SUBST(DBUS1_CFLAGS)
3734 AC_SUBST(DBUS1_LIBS)
3735 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3736
3737 dnl
3738 dnl Check for -Bsymbolic-functions linker flag used to avoid
3739 dnl intra-library PLT jumps, if available.
3740 dnl
3741
3742 AC_ARG_ENABLE(Bsymbolic,
3743               [AC_HELP_STRING([--disable-Bsymbolic],
3744                               [avoid linking with -Bsymbolic])],,
3745               [SAVED_LDFLAGS="${LDFLAGS}"
3746                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3747                LDFLAGS=-Wl,-Bsymbolic-functions
3748                AC_TRY_LINK([], [int main (void) { return 0; }],
3749                            AC_MSG_RESULT(yes)
3750                            enable_Bsymbolic=yes,
3751                            AC_MSG_RESULT(no)
3752                            enable_Bsymbolic=no)
3753                LDFLAGS="${SAVED_LDFLAGS}"])
3754
3755 if test "x${enable_Bsymbolic}" == "xyes"; then
3756   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3757 fi
3758
3759 AC_SUBST(GLIB_LINK_FLAGS)
3760
3761 #
3762 # Define variables corresponding to the correct include paths to use for
3763 # in-tree building.
3764 #
3765
3766 # for config.h:
3767 config_h_INCLUDES='-I$(top_builddir)'
3768 AC_SUBST(config_h_INCLUDES)
3769
3770 # glib:
3771 #   config.h
3772 #   $(top_builddir)/glib: for glibconfig.h
3773 #   $(top_srcdir)/glib:   for glib.h
3774 #   $(top_srcdir):        for everything
3775 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3776 AC_SUBST(glib_INCLUDES)
3777
3778 # gthread:
3779 #   same as glib
3780 gthread_INCLUDES='$(glib_INCLUDES)'
3781 AC_SUBST(gthread_INCLUDES)
3782
3783 # gobject:
3784 #   same as gthread
3785 gobject_INCLUDES='$(gthread_INCLUDES)'
3786 AC_SUBST(gobject_INCLUDES)
3787
3788 # gmodule:
3789 #   glib includes
3790 #   $(top_srcdir)/gmodule: for gmodule.h
3791 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3792 AC_SUBST(gmodule_INCLUDES)
3793
3794 # gio:
3795 #   same as gmodule
3796 gio_INCLUDES='$(gmodule_INCLUDES)'
3797 AC_SUBST(gio_INCLUDES)
3798
3799
3800 AC_CONFIG_FILES([
3801 glib-2.0.pc
3802 glib-2.0-uninstalled.pc
3803 gmodule-2.0.pc
3804 gmodule-export-2.0.pc
3805 gmodule-no-export-2.0.pc
3806 gmodule-2.0-uninstalled.pc
3807 gmodule-no-export-2.0-uninstalled.pc
3808 gthread-2.0.pc
3809 gthread-2.0-uninstalled.pc
3810 gobject-2.0.pc
3811 gobject-2.0-uninstalled.pc
3812 gio-2.0.pc
3813 gio-unix-2.0.pc
3814 gio-windows-2.0.pc
3815 gio-2.0-uninstalled.pc
3816 gio-unix-2.0-uninstalled.pc
3817 glib-zip
3818 glib-gettextize
3819 Makefile
3820 build/Makefile
3821 build/win32/Makefile
3822 build/win32/dirent/Makefile
3823 build/win32/vs9/Makefile
3824 build/win32/vs10/Makefile
3825 glib/Makefile
3826 glib/glib.stp
3827 glib/libcharset/Makefile
3828 glib/gnulib/Makefile
3829 glib/pcre/Makefile
3830 glib/update-pcre/Makefile
3831 glib/tests/Makefile
3832 gmodule/Makefile
3833 gmodule/gmoduleconf.h
3834 gobject/Makefile
3835 gobject/gobject.stp
3836 gobject/glib-mkenums
3837 gobject/tests/Makefile
3838 gthread/Makefile
3839 gthread/tests/Makefile
3840 gio/Makefile
3841 gio/gdbus-2.0/codegen/Makefile
3842 gio/gdbus-2.0/codegen/config.py
3843 gio/xdgmime/Makefile
3844 gio/inotify/Makefile
3845 gio/libasyncns/Makefile
3846 gio/fen/Makefile
3847 gio/fam/Makefile
3848 gio/win32/Makefile
3849 gio/tests/Makefile
3850 gio/tests/gdbus-object-manager-example/Makefile
3851 po/Makefile.in
3852 docs/Makefile
3853 docs/reference/Makefile
3854 docs/reference/glib/Makefile
3855 docs/reference/glib/version.xml
3856 docs/reference/gobject/Makefile
3857 docs/reference/gobject/version.xml
3858 docs/reference/gio/Makefile
3859 docs/reference/gio/gdbus-object-manager-example/Makefile
3860 docs/reference/gio/version.xml
3861 tests/Makefile
3862 tests/gobject/Makefile
3863 tests/refcount/Makefile
3864 m4macros/Makefile
3865 ])
3866
3867 AC_CONFIG_COMMANDS([chmod-scripts],
3868 [chmod 0755 glib-zip
3869 chmod 0755 glib-gettextize
3870 chmod 0755 gobject/glib-mkenums])
3871
3872 # we want to invoke this macro solely so that the config.status script
3873 # and automake generated makefiles know about these generated files.
3874 # They are only needed to distcheck the package
3875 if false; then
3876   AC_CONFIG_FILES([
3877     INSTALL
3878     README
3879     config.h.win32
3880     glib/glibconfig.h.win32
3881     glib/makefile.msc
3882     glib/glib.rc
3883     gmodule/makefile.msc
3884     gmodule/gmodule.rc
3885     gobject/makefile.msc
3886     gobject/gobject.rc
3887     gthread/makefile.msc
3888     gthread/gthread.rc
3889     gio/gio.rc
3890     tests/makefile.msc
3891   ])
3892 fi
3893
3894 AC_OUTPUT