configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([harfbuzz],
   3         [0.3],
   4         [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
   5         [harfbuzz],
   6         [http://freedesktop.org/wiki/Software/harfbuzz])
   7
   8 AC_CONFIG_SRCDIR([harfbuzz.pc.in])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AM_INIT_AUTOMAKE([1.11.1 gnu dist-bzip2 no-dist-gzip -Wall no-define])
  13
  14 AM_SILENT_RULES([yes])
  15
  16 # Check for programs
  17 AC_PROG_CC
  18 AM_PROG_CC_C_O
  19 AC_PROG_CXX
  20
  21 # Initialize libtool
  22 LT_PREREQ([2.2])
  23 LT_INIT([win32-dll])
  24
  25 AC_CHECK_FUNCS(mprotect sysconf getpagesize)
  26 AC_CHECK_HEADERS(unistd.h sys/mman.h)
  27
  28 # Make sure we don't link to libstdc++
  29 if test "x$GCC" = "xyes"; then
  30         CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
  31 fi
  32
  33 dnl ==========================================================================
  34
  35 PKG_CHECK_MODULES(GLIB, glib-2.0, have_glib=true, have_glib=false)
  36 if $have_glib; then
  37         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
  38 fi
  39 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
  40
  41 PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
  42         AC_CHECK_PROG([have_icu], [icu-config], [true], [false])
  43         if $have_icu; then
  44                 icu_cflags=`icu-config --cppflags`
  45                 icu_libs=`icu-config --ldflags-libsonly`
  46                 AC_SUBST(ICU_CFLAGS, [$icu_cflags])
  47                 AC_SUBST(ICU_LIBS, [$icu_libs])
  48         fi
  49 ])
  50 if $have_icu; then
  51         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
  52 fi
  53 AM_CONDITIONAL(HAVE_ICU, $have_icu)
  54
  55 PKG_CHECK_MODULES(FREETYPE, freetype2, have_freetype=true, have_freetype=false)
  56 if $have_freetype; then
  57         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
  58         _save_libs="$LIBS"
  59         _save_cflags="$CFLAGS"
  60         LIBS="$LIBS $FREETYPE_LIBS"
  61         CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
  62         AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
  63         LIBS="$_save_libs"
  64         CFLAGS="$_save_cflags"
  65 fi
  66 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
  67
  68 dnl ==========================================================================
  69
  70 AC_CONFIG_FILES([
  71 harfbuzz.pc
  72 Makefile
  73 src/Makefile
  74 ])
  75
  76 AC_OUTPUT