configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer Bad Plug-ins, 0.10.6.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-plugins-bad)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_CVS="no", GST_CVS="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([docs/plugins/gst-plugins-bad-plugins-docs.sgml])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl our libraries and install dirs use major.minor as a version
  34 GST_MAJORMINOR=$GST_PLUGINS_BAD_VERSION_MAJOR.$GST_PLUGINS_BAD_VERSION_MINOR
  35 dnl we override it here if we need to for the release candidate of new series
  36 GST_MAJORMINOR=0.10
  37 AC_SUBST(GST_MAJORMINOR)
  38
  39 dnl FIXME: this macro doesn't actually work;
  40 dnl the generated libtool script has no support for the listed tags.
  41 dnl So this needs to be fixed first if we want to use this
  42 dnl AS_LIBTOOL_TAGS([CXX])
  43
  44 AM_PROG_LIBTOOL
  45
  46 dnl *** required versions of GStreamer stuff ***
  47 dnl *** remove rtpmanager stuff below when this is updated
  48 GST_REQ=0.10.17
  49 GSTPB_REQ=0.10.17
  50
  51 dnl *** autotools stuff ****
  52
  53 dnl allow for different autotools
  54 AS_AUTOTOOLS_ALTERNATE
  55
  56 dnl Add parameters for aclocal
  57 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  58
  59 dnl set up gettext
  60 dnl the version check needs to stay here because autopoint greps for it
  61 AM_GNU_GETTEXT_VERSION([0.11.5])
  62 AM_GNU_GETTEXT([external])
  63 AG_GST_GETTEXT([gst-plugins-bad-$GST_MAJORMINOR])
  64
  65 dnl *** check for arguments to configure ***
  66
  67 AG_GST_ARG_DEBUG
  68 AG_GST_ARG_PROFILING
  69 AG_GST_ARG_VALGRIND
  70 AG_GST_ARG_GCOV
  71
  72 AG_GST_ARG_EXAMPLES
  73
  74 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  75 AG_GST_ARG_WITH_PACKAGE_NAME
  76 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  77
  78 AG_GST_ARG_EXAMPLES
  79
  80 dnl these are all the gst plug-ins, compilable without additional libs
  81 GST_PLUGINS_ALL="\
  82   app \
  83   bayer \
  84   cdxaparse \
  85   deinterlace \
  86   dvdspu \
  87   festival \
  88   filter \
  89   flv \
  90   freeze \
  91   h264parse \
  92   interleave \
  93   librfb \
  94   modplug \
  95   mpegtsparse \
  96   mpeg4videoparse \
  97   mpegvideoparse \
  98   mve \
  99   nsf \
 100   nuvdemux \
 101   rawparse \
 102   real \
 103   replaygain \
 104   rtpmanager \
 105   sdp \
 106   selector \
 107   speexresample \
 108   speed \
 109   stereo \
 110   tta \
 111   videosignal \
 112   vmnc \
 113   y4m \
 114   "
 115
 116 AC_SUBST(GST_PLUGINS_ALL)
 117
 118 AG_GST_ARG_WITH_PLUGINS
 119
 120 AG_GST_ARG_ENABLE_EXTERNAL
 121
 122 AG_GST_ARG_ENABLE_EXPERIMENTAL
 123
 124 dnl *** checks for platform ***
 125
 126 dnl * hardware/architecture *
 127
 128 dnl common/m4/gst-arch.m4
 129 dnl check CPU type
 130 AG_GST_ARCH
 131
 132 dnl Determine endianness
 133 AC_C_BIGENDIAN
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139
 140 dnl determine c++ compiler
 141 AC_PROG_CXX
 142 dnl determine if c++ is available on this system
 143 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 144
 145 AS_PROG_OBJC
 146
 147 dnl check if the compiler supports '-c' and '-o' options
 148 AM_PROG_CC_C_O
 149
 150 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 151 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 152
 153 dnl check for documentation tools
 154 GTK_DOC_CHECK([1.3])
 155 AS_PATH_PYTHON([2.1])
 156 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 157
 158 dnl *** checks for libraries ***
 159
 160 dnl check for libm, for sin() etc.
 161 AC_CHECK_LIBM
 162 AC_SUBST(LIBM)
 163
 164 dnl *** checks for header files ***
 165
 166 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 167 AM_CONDITIONAL(HAVE_UNISTD_H, test "x$HAVE_UNISTD_H" = "xyes")
 168
 169 if test "x$HAVE_UNISTD_H" != "xyes"; then
 170   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/festival//`
 171 fi
 172
 173 dnl used by ext/dts
 174 AX_CREATE_STDINT_H
 175
 176 dnl *** checks for types/defines ***
 177
 178 dnl *** checks for structures ***
 179
 180 dnl *** checks for compiler characteristics ***
 181
 182 dnl *** checks for library functions ***
 183
 184 dnl *** checks for dependency libraries ***
 185
 186 dnl GLib is required
 187 AG_GST_GLIB_CHECK([2.6])
 188
 189 dnl liboil is required
 190 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 191 if test "x${HAVE_LIBOIL}" != xyes ; then
 192   AC_ERROR([liboil-0.3.8 or later is required])
 193 fi
 194
 195 dnl checks for gstreamer
 196 dnl uninstalled is selected preferentially -- see pkg-config(1)
 197 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 198 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 199 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 200 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 201 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 202 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], no)
 203 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 204
 205 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_MAJORMINOR --variable pluginsdir`
 206 AC_SUBST(GSTPB_PLUGINS_DIR)
 207 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 208
 209 dnl Check for documentation xrefs
 210 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 211 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 212 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 213 AC_SUBST(GLIB_PREFIX)
 214 AC_SUBST(GST_PREFIX)
 215 AC_SUBST(GSTPB_PREFIX)
 216
 217 dnl GTK is optional and used in examples
 218 HAVE_GTK=NO
 219 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 220 if test "x$HAVE_GTK_22" = "xyes"; then
 221   HAVE_GTK=yes
 222   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 223   AC_SUBST(GTK_VERSION)
 224   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 225   AC_SUBST(GTK_BASE_DIR)
 226   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 227   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 228   AC_SUBST(GTK_BASE_DIR)
 229 else
 230   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 231 fi
 232 if test "x$HAVE_GTK_20" = "xyes"; then
 233   HAVE_GTK=yes
 234 fi
 235 GTK_CFLAGS=$GTK2_CFLAGS
 236 GTK_LIBS=$GTK2_LIBS
 237 AC_SUBST(GTK_LIBS)
 238 AC_SUBST(GTK_CFLAGS)
 239 AC_SUBST(HAVE_GTK)
 240 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 241
 242 dnl libglade is optional and only used in examples
 243 HAVE_GLADE=NO
 244 PKG_CHECK_MODULES(GLADE, libglade-2.0 >= 2.6.0, HAVE_GLADE=yes, HAVE_GLADE=no)
 245 AC_SUBST(GLADE_LIBS)
 246 AC_SUBST(GLADE_CFLAGS)
 247 AC_SUBST(HAVE_GLADE)
 248 AM_CONDITIONAL(HAVE_GLADE, test "x$HAVE_GLADE" = "xyes")
 249
 250 dnl set license and copyright notice
 251 GST_LICENSE="LGPL"
 252 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 253 AC_SUBST(GST_LICENSE)
 254
 255 dnl set location of plugin directory
 256 AG_GST_SET_PLUGINDIR
 257
 258 dnl define an ERROR_CFLAGS Makefile variable
 259 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 260
 261 dnl define correct level for debugging messages
 262 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 263
 264 dnl *** plug-ins to exclude ***
 265
 266 dnl see if we can build C++ plug-ins
 267 if test "x$HAVE_CXX" != "xyes"; then
 268   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 269   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | sed 's/modplug//g'`
 270 fi
 271
 272 dnl real plugin only works on i386 and x86_64 for the time being.
 273 if test "x$HAVE_CPU_I386" != "xyes" && test "x$HAVE_CPU_X86_64" != "xyes"; then
 274   AC_MSG_WARN([Not building real plugin, only works on 32bit and 64bit x86 platforms])
 275   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | sed 's/real//g'`
 276 fi
 277
 278 dnl disable gst plugins we might not be able to build on this
 279 dnl platform: librfb (ugly but minimally invasive)
 280 dnl FIXME: maybe move to sys, or make work with winsock2
 281 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 282 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 283
 284 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 285   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/librfb//`
 286 fi
 287
 288 AC_SUBST(GST_PLUGINS_SELECTED)
 289
 290 dnl *** sys plug-ins ***
 291
 292 dnl check for QuickTime
 293 translit(dnm, m, l) AM_CONDITIONAL(USE_QUICKTIME, true)
 294 AG_GST_CHECK_FEATURE(QUICKTIME, [QuickTime wrapper], qtwrapper, [
 295   AC_CHECK_HEADER(QuickTime/Movies.h, HAVE_QUICKTIME="yes", HAVE_QUICKTIME="no")
 296 ])
 297
 298 dnl check for Video CD
 299 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 300 AG_GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 301   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 302 ])
 303
 304 dnl *** ext plug-ins ***
 305 dnl keep this list sorted alphabetically !
 306
 307 if test "x$BUILD_EXTERNAL" = "xyes"; then
 308
 309 dnl *** alsa ***
 310 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 311 AG_GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 312   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 313     HAVE_ALSA="yes"
 314     AC_SUBST(ALSA_CFLAGS)
 315     AC_SUBST(ALSA_LIBS)
 316   ], [
 317     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 318   ])
 319 ])
 320
 321 dnl *** amrwb ***
 322 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 323 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwb, [
 324   AG_GST_CHECK_LIBHEADER(AMRWB, amrwb,
 325                         GP3D_IF_decode, ,
 326                         amrwb/dec.h,
 327                         AMRWB_LIBS="-lamrwb"
 328                         AC_SUBST(AMRWB_LIBS))
 329 ])
 330
 331 dnl *** BZ2 ***
 332 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 333 AG_GST_CHECK_FEATURE(BZ2, [bz2 library], bz2, [
 334   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 335   AC_SUBST(BZ2_LIBS)
 336 ])
 337
 338 #dnl *** cairo ***
 339 #translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 340 #AG_GST_CHECK_FEATURE(CAIRO, [cairo plug-in], cairo, [
 341 #  PKG_CHECK_MODULES(CAIRO, cairo >= 1.0 glitz-glx, HAVE_CAIRO=yes, [
 342 #    HAVE_CAIRO=no
 343 #    AC_MSG_RESULT(no)
 344 #  ])
 345 #  AC_SUBST(CAIRO_CFLAGS)
 346 #  AC_SUBST(CAIRO_LIBS)
 347 #])
 348
 349 dnl *** cdaudio ***
 350 translit(dnm, m, l) AM_CONDITIONAL(USE_CDAUDIO, true)
 351 AG_GST_CHECK_FEATURE(CDAUDIO, [cdaudio], cdaudio, [
 352   AG_GST_CHECK_CONFIGPROG(CDAUDIO, libcdaudio-config)
 353   AC_SUBST(CDAUDIO_CFLAGS)
 354   AC_SUBST(CDAUDIO_LIBS)
 355 ])
 356
 357
 358 dnl *** dc1394  ***
 359 translit(dnm, m, l) AM_CONDITIONAL(USE_DC1394, true)
 360 AG_GST_CHECK_FEATURE(DC1394, [libdc1394], dc1394, [
 361    PKG_CHECK_MODULES(LIBDC1394, libdc1394-2 == 2.0.0-rc5, HAVE_DC1394="yes", [
 362         HAVE_DC1394="no"
 363         AC_MSG_RESULT(no)
 364    ])
 365    AC_SUBST(LIBDC1394_CFLAGS)
 366    AC_SUBST(LIBDC1394_LIBS)
 367 ])
 368
 369
 370 dnl **** DirectFB ****
 371 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTFB, true)
 372 AG_GST_CHECK_FEATURE(DIRECTFB, [directfb], dfbvideosink , [
 373   PKG_CHECK_MODULES(DIRECTFB, directfb >= 0.9.24, HAVE_DIRECTFB="yes", [
 374     HAVE_DIRECTFB="no"
 375     AC_MSG_RESULT(no)
 376   ])
 377 ])
 378
 379 dnl *** DTS ***
 380 translit(dnm, m, l) AM_CONDITIONAL(USE_DTS, true)
 381 AG_GST_CHECK_FEATURE(DTS, [dts library], dtsdec, [
 382   HAVE_DTS="yes"
 383   AG_GST_CHECK_LIBHEADER(DTS, dts_pic, dts_init, -lm, dts.h,
 384     DTS_LIBS="-ldts_pic -lm", HAVE_DTS="no")
 385   if test $HAVE_DTS = "no"; then
 386     AG_GST_CHECK_LIBHEADER(DTS, dca, dca_init, -lm, dts.h,
 387       DTS_LIBS="-ldca -lm")
 388   fi
 389   AC_SUBST(DTS_LIBS)
 390 ])
 391
 392 dnl *** DIVX ***
 393 translit(dnm, m, l) AM_CONDITIONAL(USE_DIVX, true)
 394 AG_GST_CHECK_FEATURE(DIVX, [divx plugins], divx, [
 395   HAVE_DIVX=yes
 396   AC_CHECK_HEADER(encore2.h, , [
 397     AC_MSG_WARN([Divx4linux encore headers not found])
 398     HAVE_DIVX=no
 399   ])
 400   if [ test x$HAVE_DIVX = xyes ]; then
 401     AC_MSG_CHECKING([Checking for valid divx4linux encore version])
 402     AC_TRY_COMPILE([
 403 #include <encore2.h>
 404 #if ENCORE_VERSION != 20021024
 405 #error Wrong version of divx encore libraries
 406 #endif
 407     ], [
 408 return 0;
 409     ], [
 410       HAVE_DIVX=yes
 411       AC_MSG_RESULT(yes)
 412     ], [
 413       HAVE_DIVX=no
 414       AC_MSG_RESULT(no)
 415       AC_MSG_WARN([Wrong version of divx4linux installed])
 416     ])
 417   fi
 418   if [ test x$HAVE_DIVX = xyes ]; then
 419     AC_CHECK_HEADER(decore.h, , [
 420       AC_MSG_WARN([Divx4linux decoder headers not found])
 421       HAVE_DIVX=no
 422     ])
 423   fi
 424   if [ test x$HAVE_DIVX = xyes ]; then
 425     AC_MSG_CHECKING([Checking for valid divx4linux decore version])
 426     AC_TRY_COMPILE([
 427 #include <decore.h>
 428 #if DECORE_VERSION != 20021112
 429 #error Wrong version of divx decore libraries
 430 #endif
 431     ], [
 432 return 0;
 433     ], [
 434       HAVE_DIVX=yes
 435       AC_MSG_RESULT(yes)
 436     ], [
 437       HAVE_DIVX=no
 438       AC_MSG_RESULT(no)
 439       AC_MSG_WARN([Wrong version of divx4linux installed])
 440     ])
 441   fi
 442   LIBS="-lm"
 443   if test x$HAVE_DIVX = xyes; then
 444     AC_CHECK_LIB(divxencore, encore, , [
 445       AC_MSG_WARN([Divx4linux encore libs not found])
 446       HAVE_DIVX=no
 447     ])
 448   fi
 449   if test x$HAVE_DIVX = xyes; then
 450     AC_CHECK_LIB(divxdecore, decore, , [
 451       AC_MSG_WARN([Divx4linux decore libs not found])
 452       HAVE_DIVX=no
 453   ])
 454   fi
 455   if test x$HAVE_DIVX = xyes; then
 456     DIVXENC_LIBS="-ldivxencore -lm"
 457     DIVXDEC_LIBS="-ldivxdecore -lm"
 458     AC_SUBST(DIVXENC_LIBS)
 459     AC_SUBST(DIVXDEC_LIBS)
 460   fi
 461 ])
 462
 463 dnl *** METADATA ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_METADATA, true)
 465 AG_GST_CHECK_FEATURE(METADATA, [METADATA muxer and demuxer], metadata, [
 466   HAVE_METADATA="no"
 467   PKG_CHECK_MODULES(EXIF, libexif >= 0.6.16, HAVE_EXIF="yes", [
 468     HAVE_EXIF="no"
 469   ])
 470   PKG_CHECK_MODULES(IPTC, libiptcdata >= 1.0.2, HAVE_IPTC="yes", [
 471     HAVE_IPTC="no"
 472   ])
 473   PKG_CHECK_MODULES(XMP, exempi-2.0, HAVE_XMP="yes", [
 474     HAVE_XMP="no"
 475   ])
 476   PKG_CHECK_MODULES(XMP_1_99_5, exempi-2.0 >= 1.99.5, XMP_CFLAGS="-DXMP_1_99_5 $XMP_CFLAGS", AC_MSG_RESULT(no))
 477   if test x$HAVE_EXIF = xyes; then
 478     METADATA_CFLAGS="-DHAVE_EXIF $EXIF_CFLAGS $METADATA_CFLAGS"
 479     METADATA_LIBS="$EXIF_LIBS $METADATA_LIBS -lm"
 480     HAVE_METADATA="yes"
 481   fi
 482   if test x$HAVE_IPTC = xyes; then
 483     METADATA_CFLAGS="-DHAVE_IPTC $IPTC_CFLAGS $METADATA_CFLAGS"
 484     METADATA_LIBS="$IPTC_LIBS $METADATA_LIBS"
 485     HAVE_METADATA="yes"
 486   fi
 487   if test x$HAVE_XMP = xyes; then
 488     METADATA_CFLAGS="-DHAVE_XMP $XMP_CFLAGS $METADATA_CFLAGS"
 489     METADATA_LIBS="$XMP_LIBS $METADATA_LIBS"
 490     HAVE_METADATA="yes"
 491   fi
 492   if test x$HAVE_METADATA = xno; then
 493     AC_MSG_WARN(no of metadata libraries (exif, iptc or xmp) found)
 494   fi
 495   dnl metadata plugin will parse whole chunks anyway
 496   HAVE_METADATA="yes"
 497   AC_SUBST(METADATA_CFLAGS)
 498   AC_SUBST(METADATA_LIBS)
 499 ])
 500
 501 dnl **** Free AAC Encoder (FAAC) ****
 502 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAC, true)
 503 AG_GST_CHECK_FEATURE(FAAC, [AAC encoder plug-in], faac, [
 504   AG_GST_CHECK_LIBHEADER(FAAC, faac, faacEncOpen, -lm, faac.h,
 505     FAAC_LIBS="-lfaac -lm")
 506   AS_SCRUB_INCLUDE(FAAC_CFLAGS)
 507   AC_SUBST(FAAC_LIBS)
 508 ])
 509
 510 dnl **** Free AAC Decoder (FAAD) ****
 511 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 512 AG_GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 513   HAVE_FAAD="yes"
 514   AG_GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h,
 515     FAAD_LIBS="-lfaad -lm", HAVE_FAAD="no")
 516   if test $HAVE_FAAD = "no"; then
 517     AG_GST_CHECK_LIBHEADER(FAAD, faad, NeAACDecOpen, -lm, neaacdec.h,
 518       [ FAAD_LIBS="-lfaad -lm"
 519                 AC_DEFINE(FAAD_IS_NEAAC, 1, [Define if AAC is using new api prefix])
 520           ],
 521           HAVE_FAAD="no",)
 522   fi
 523   if test $HAVE_FAAD = "yes"; then
 524     AC_MSG_CHECKING([Checking for FAAD >= 2.0])
 525     AC_TRY_COMPILE([#include <faad.h>], [
 526         #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 527         #error Not faad2
 528         #else
 529         /* Release candidate of 2.0 is not good enough for us. This field
 530          * was added only in 2.0 final and does not exist in 2.0-RC3 */
 531         faacDecConfiguration conf; conf.dontUpSampleImplicitSBR = 1;
 532         #endif
 533     ], [
 534       HAVE_FAAD="yes"
 535       AC_MSG_RESULT(yes)
 536     ], [
 537       HAVE_FAAD="no"
 538       AC_MSG_RESULT(no)
 539     ])
 540   fi
 541   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 542   AC_SUBST(FAAD_LIBS)
 543   AC_SUBST(FAAD_IS_NEAAC)
 544 ])
 545
 546 dnl *** fbdev ***
 547 translit(dnm, m, l) AM_CONDITIONAL(USE_FBDEV, true)
 548 AG_GST_CHECK_FEATURE(FBDEV, [linux framebuffer], fbdevsink, [
 549   if test "x$HAVE_FBDEV" != "xyes"; then
 550     AC_CHECK_HEADER([linux/fb.h], HAVE_FBDEV=yes, HAVE_FBDEV=no)
 551   fi
 552 ])
 553
 554 dnl *** gsm ***
 555 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 556 AG_GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 557   AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 558   if test $HAVE_GSM != "yes"; then
 559     AG_GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
 560     if test $HAVE_GSM = "yes"; then
 561       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
 562     fi
 563   fi
 564   AC_SUBST(GSM_LIBS)
 565 ])
 566
 567 dnl *** ivorbis ***
 568 dnl AM_PATH_IVORBIS only takes two options
 569 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 570 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 571   IVORBIS_LIBS=
 572   IVORBIS_CFLAGS=
 573   AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 574     [IVORBIS_LIBS=-lvorbisidec
 575      HAVE_IVORBIS=yes
 576      case $host in
 577      arm-*-*)
 578        IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 579      esac
 580     ],
 581     HAVE_IVORBIS=no)
 582   AC_SUBST(IVORBIS_LIBS)
 583   AC_SUBST(IVORBIS_CFLAGS)
 584 ])
 585
 586 dnl *** Jack ***
 587 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 588 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 589   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 590   AC_SUBST(JACK_CFLAGS)
 591   AC_SUBST(JACK_LIBS)
 592 ])
 593
 594 dnl *** ladspa ***
 595 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 596 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 597   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 598 ])
 599
 600 dnl *** libmms ***
 601 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBMMS, true)
 602 AG_GST_CHECK_FEATURE(LIBMMS, [mms protocol library], libmms, [
 603   dnl check with pkg-config first
 604   PKG_CHECK_MODULES(LIBMMS, libmms >= 0.2, HAVE_LIBMMS="yes", [
 605     HAVE_LIBMMS="no"
 606     AC_MSG_RESULT(no)
 607   ])
 608 ])
 609 AC_SUBST(LIBMMS_LIBS)
 610
 611 dnl *** mjpegtools version info ***
 612 dnl some may prefer older version (given quirks above)
 613 dnl hm, no version info seems available within mjpegtools headers
 614
 615 PKG_CHECK_EXISTS(mjpegtools >= 1.9.0 mjpegtools < 1.10.0, [
 616   AC_DEFINE(GST_MJPEGTOOLS_19x, 1, [mjpegtools >= 1.9.0 is used])
 617   have_mpjegtools_19x=yes
 618   ], [
 619   have_mpjegtools_19x=no])
 620
 621 PKG_CHECK_EXISTS(mjpegtools >= 1.8.0, [
 622   AC_DEFINE(GST_MJPEGTOOLS_18x, 1, [mjpegtools >= 1.8.0 is used])
 623   have_mpjegtools_18x=yes
 624   ], [
 625   have_mpjegtools_18x=no])
 626
 627 dnl *** mpeg2enc ***
 628 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2ENC, true)
 629 AG_GST_CHECK_FEATURE(MPEG2ENC, [mpeg2enc], mpeg2enc, [
 630   HAVE_MPEG2ENC="no"
 631   dnl we require a c++ compiler for this one
 632   if [ test x$HAVE_CXX = xyes ]; then
 633     dnl libmpeg2enc was first included in mjpegtools-1.6.2-rc3 (1.6.1.92)
 634     dnl since many distros include mjpegtools specifically without mplex
 635     dnl and mpeg2enc, we check for mpeg2enc on its own, too.
 636     PKG_CHECK_MODULES(MPEG2ENC, mjpegtools >= 1.6.1.93, [
 637       dnl HACK because mpeg2enc 1.8.0 header files have a spurious 'include config.h'
 638       touch config.h
 639       dnl switch over to c++ to test things
 640       AC_LANG_CPLUSPLUS
 641       OLD_CPPFLAGS="$CPPFLAGS"
 642       dnl HACK as above
 643       CPPFLAGS_GOOD="$CPPFLAGS $MPEG2ENC_CFLAGS"
 644       CPPFLAGS="$CPPFLAGS_GOOD -I."
 645       dnl check headers
 646       mpeg2enc_headers_ok=no
 647       AC_CHECK_HEADER([mpeg2encoder.hh], [
 648         MPEG2ENC_LIBS="$MPEG2ENC_LIBS -lmpeg2encpp -lm -lpthread"
 649         OLD_LIBS="$LIBS"
 650         LIBS="$LIBS $MPEG2ENC_LIBS"
 651         AC_MSG_CHECKING([for valid mpeg2enc objects])
 652         AC_TRY_RUN([
 653           #include <mpeg2encoder.hh>
 654           #include <mpeg2encoptions.hh>
 655
 656           int
 657           main (int   argc,
 658                 char *argv[])
 659           {
 660             MPEG2EncOptions *options = new MPEG2EncOptions ();
 661             MPEG2Encoder *encoder = new MPEG2Encoder (*options);
 662             return 0;
 663           }
 664         ],[
 665           AC_MSG_RESULT(yes)
 666           dnl so far so good, let's check more things:
 667           dnl mjpegtools-1.8.0 does not install the required
 668           dnl mpeg2syntaxcodes.h header by default, and a new release
 669           dnl is not in sight, so check for this oversight in case
 670           dnl distros or folks have fixed this themselves
 671           if test "x$have_mpjegtools_18x" = "xyes"; then
 672             AC_CHECK_HEADER([mpeg2syntaxcodes.h], [
 673                 mpeg2enc_headers_ok=yes
 674               ], [
 675                 mpeg2enc_headers_ok=no
 676               ])
 677           else
 678             mpeg2enc_headers_ok=yes
 679           fi
 680
 681           if test "x$mpeg2enc_headers_ok" = "xyes"; then
 682             HAVE_MPEG2ENC="yes"
 683           fi
 684           CPP_FLAGS="$CPPFLAGS_GOOD"
 685           AC_SUBST(MPEG2ENC_CFLAGS)
 686           AC_SUBST(MPEG2ENC_LIBS)
 687         ], [
 688           AC_MSG_RESULT(no)
 689         ])
 690         LIBS="$OLD_LIBS"
 691       ])
 692
 693       CPPFLAGS="$OLD_CPPFLAGS"
 694       AC_LANG_C
 695     ], [
 696       HAVE_MPEG2ENC="no"
 697     ])
 698   fi
 699 ])
 700
 701 dnl *** musepack ***
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSEPACK, true)
 703 AG_GST_CHECK_FEATURE(MUSEPACK, [musepackdec], musepack, [
 704   AC_LANG_CPLUSPLUS
 705   AC_CHECK_HEADER([mpcdec/mpcdec.h], [
 706     HAVE_MUSEPACK="yes"
 707     MUSEPACK_LIBS="-lmpcdec"
 708     AC_SUBST(MUSEPACK_LIBS)
 709     ], [HAVE_MUSEPACK="no"])
 710   AC_LANG_C
 711 ])
 712
 713 dnl *** musicbrainz ***
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSICBRAINZ, true)
 715 AG_GST_CHECK_FEATURE(MUSICBRAINZ, [musicbrainz tag generation], musicbrainz, [
 716   PKG_CHECK_MODULES(MUSICBRAINZ, libmusicbrainz >= 2.1.0, HAVE_MUSICBRAINZ="yes", HAVE_MUSICBRAINZ="no")
 717   AC_SUBST(MUSICBRAINZ_CFLAGS)
 718   AC_SUBST(MUSICBRAINZ_LIBS)
 719 ])
 720
 721 dnl *** MythTV ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_MYTHTV, true)
 723 AG_GST_CHECK_FEATURE(MYTHTV, [MythTV client plugins], mythtvsrc, [
 724   PKG_CHECK_MODULES(GMYTH, gmyth >= 0.4 gmyth <= 0.7.99, HAVE_MYTHTV="yes", [
 725     HAVE_MYTHTV="no"
 726     AC_MSG_RESULT(no)
 727   ])
 728   AC_SUBST(GMYTH_CFLAGS)
 729   AC_SUBST(GMYTH_LIBS)
 730 ])
 731
 732 dnl *** nas ***
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_NAS, true)
 734 AG_GST_CHECK_FEATURE(NAS, [nas plug-in], nassink, [
 735   HAVE_NAS="no"
 736   AG_GST_CHECK_X
 737   if test "x$HAVE_X" = "xyes"; then
 738     save_cppflags=$CFLAGS
 739     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 740     AG_GST_CHECK_LIBHEADER(NAS, audio, AuOpenServer, $X_LIBS, audio/audiolib.h,
 741       NAS_LIBS="$X_LIBS -laudio" NAS_CFLAGS="$X_CFLAGS")
 742     CPPFLAGS="$save_cppflags"
 743   fi
 744   AC_SUBST(NAS_CFLAGS)
 745   AC_SUBST(NAS_LIBS)
 746 ])
 747
 748 dnl *** neon ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_NEON, true)
 750 AG_GST_CHECK_FEATURE(NEON, [neon http client plugins], neonhttpsrc, [
 751   PKG_CHECK_MODULES(NEON, neon >= 0.26.0  neon <= 0.27.99, HAVE_NEON="yes", [
 752     HAVE_NEON="no"
 753     AC_MSG_RESULT(no)
 754   ])
 755   AC_SUBST(NEON_CFLAGS)
 756   AC_SUBST(NEON_LIBS)
 757 ])
 758
 759 dnl *** soup ***
 760 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 761 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 762   PKG_CHECK_MODULES(SOUP, libsoup-2.4, HAVE_SOUP="yes", [
 763     HAVE_SOUP="no"
 764     AC_MSG_RESULT(no)
 765   ])
 766   AC_SUBST(SOUP_CFLAGS)
 767   AC_SUBST(SOUP_LIBS)
 768 ])
 769
 770 dnl *** timidity ***
 771 translit(dnm, m, l) AM_CONDITIONAL(USE_TIMIDITY, true)
 772 AG_GST_CHECK_FEATURE(TIMIDITY, [timidity midi soft synth plugin], timidity, [
 773   PKG_CHECK_MODULES(TIMIDITY, libtimidity, [
 774     HAVE_TIMIDITY="yes",
 775         AC_MSG_CHECKING([for timidity.cfg])
 776         timidity_cfg=""
 777         if test -r /etc/timidity.cfg; then
 778           timidity_cfg=/etc/timidity.cfg
 779         elif test -r /etc/timidity/timidity.cfg; then
 780           timidity_cfg=/etc/timidity/timidity.cfg
 781         elif test -r /usr/share/timidity/timidity.cfg; then
 782           timidity_cfg=/usr/share/timidity/timidity.cfg
 783         elif test -r /usr/local/share/timidity/timidity.cfg; then
 784           timidity_cfg=/usr/local/share/timidity/timidity.cfg
 785         fi
 786         if test "x$timidity_cfg" != "x"; then
 787           AC_MSG_RESULT($timidity_cfg)
 788       AC_DEFINE_UNQUOTED(TIMIDITY_CFG, "$timidity_cfg", [Define location of timidity.cfg])
 789         else
 790           AC_MSG_RESULT([not found])
 791         fi
 792   ], [
 793     HAVE_TIMIDITY="no"
 794     AC_MSG_RESULT(no)
 795   ])
 796   AC_SUBST(TIMIDITY_CFLAGS)
 797   AC_SUBST(TIMIDITY_LIBS)
 798 ])
 799
 800 dnl *** wildmidi ***
 801 translit(dnm, m, l) AM_CONDITIONAL(USE_WILDMIDI, true)
 802 AG_GST_CHECK_FEATURE(WILDMIDI, [wildmidi midi soft synth plugin], wildmidi, [
 803   AC_CHECK_HEADER([wildmidi_lib.h],HAVE_WILDMIDI=yes, HAVE_WILDMIDI=no)
 804   if test "x$HAVE_WILDMIDI" = "xyes"; then
 805          WILDMIDI_CFLAGS=
 806          WILDMIDI_LIBS=-lWildMidi
 807          AC_MSG_NOTICE(compiling gstWildMidi)
 808   else
 809          WILDMIDI_CFLAGS=
 810          WILDMIDI_LIBS=
 811          AC_MSG_WARN(no WildMidi library found (libWildMidi))
 812   fi
 813   AC_SUBST(WILDMIDI_CFLAGS)
 814   AC_SUBST(WILDMIDI_LIBS)
 815 ])
 816
 817 dnl *** SDL ***
 818 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
 819 AG_GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink sdlaudiosink, [
 820     AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
 821 ])
 822
 823 dnl *** sndfile ***
 824 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
 825 AG_GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
 826   PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.16, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
 827   AC_SUBST(SNDFILE_CFLAGS)
 828   AC_SUBST(SNDFILE_LIBS)
 829 ])
 830
 831 dnl *** soundtouch ***
 832 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUNDTOUCH, true)
 833 AG_GST_CHECK_FEATURE(SOUNDTOUCH, [soundtouch plug-in], soundtouch, [
 834   PKG_CHECK_MODULES(SOUNDTOUCH, soundtouch-1.0,
 835     HAVE_SOUNDTOUCH=yes,
 836     [PKG_CHECK_MODULES(SOUNDTOUCH, libSoundTouch,
 837       HAVE_SOUNDTOUCH=yes,
 838       HAVE_SOUNDTOUCH=no)])
 839   AC_SUBST(SOUNDTOUCH_CFLAGS)
 840   AC_SUBST(SOUNDTOUCH_LIBS)
 841   if test "x$HAVE_CXX" != "xyes"; then
 842     USE_SOUNDTOUCH=false
 843     AC_MSG_NOTICE([Not building soundtouch plugin: no C++ compiler found])
 844   fi
 845 ])
 846
 847 dnl *** spc ***
 848 translit(dnm, m, l) AM_CONDITIONAL(USE_SPC, true)
 849 AG_GST_CHECK_FEATURE(SPC, [spc decoder], spc, [
 850   AC_CHECK_HEADER(openspc.h, [
 851     AC_CHECK_LIB(openspc, OSPC_Init, [
 852       SPC_LIBS="-lopenspc"
 853       AC_SUBST(SPC_LIBS)
 854       HAVE_SPC=yes
 855     ], [
 856       HAVE_SPC=no
 857     ])
 858   ], [
 859     HAVE_SPC=no
 860   ])
 861 ])
 862
 863 dnl *** swfdec ***
 864 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
 865 AG_GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
 866   PKG_CHECK_MODULES(SWFDEC, swfdec-0.3 >= 0.3.6, HAVE_SWFDEC=yes, [
 867     HAVE_SWFDEC=no
 868     AC_MSG_RESULT(no)
 869   ])
 870   AC_SUBST(SWFDEC_CFLAGS)
 871   AC_SUBST(SWFDEC_LIBS)
 872 ])
 873
 874 dnl *** theora ***
 875 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORADEC, true)
 876 AG_GST_CHECK_FEATURE(THEORADEC, [ogg theora codec], theoraexpdec, [
 877   PKG_CHECK_MODULES(THEORADEC, theoradec, HAVE_THEORADEC="yes", [
 878     HAVE_THEORADEC="no"
 879     AC_MSG_RESULT(no)
 880   ])
 881   AC_SUBST(THEORADEC_LIBS)
 882   AC_SUBST(THEORADEC_CFLAGS)
 883 ])
 884
 885 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 886 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 887 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 888   AG_GST_CHECK_LIBHEADER(X264, x264, x264_nal_encode, -lm, x264.h,
 889       X264_LIBS="$LDFLAGS -lx264 -lm"
 890       X264_CFLAGS="$CFLAGS"
 891       AC_SUBST(X264_LIBS)
 892       AC_SUBST(X264_CFLAGS))
 893 ])
 894
 895 dnl *** XVID ***
 896 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
 897 AG_GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
 898   HAVE_XVID=no
 899   AC_CHECK_HEADER(xvid.h, [
 900     OLD_LIBS="$LIBS"
 901     LIBS="-lm"
 902     AC_CHECK_LIB(xvidcore, xvid_encore, [
 903       AC_CHECK_LIB(xvidcore, xvid_decore, [
 904         AC_CHECK_LIB(xvidcore, xvid_global, [
 905           AC_MSG_CHECKING([for uptodate XviD API version])
 906           AC_TRY_COMPILE([#include <xvid.h>], [
 907               #if XVID_API_MAJOR(XVID_API) != 4
 908               #error "Incompatible XviD API version"
 909               #endif
 910           ],[ AC_MSG_RESULT(yes)
 911             XVID_LIBS="-lxvidcore -lm"
 912             AC_SUBST(XVID_LIBS)
 913             HAVE_XVID=yes
 914           ], AC_MSG_RESULT(no) )
 915         ], )
 916       ], )
 917     ], )
 918     LIBS="$OLD_LIBS"
 919   ], )
 920 ])
 921
 922 dnl *** dvb ***
 923 translit(dnm, m, l) AM_CONDITIONAL(USE_DVB, true)
 924 AG_GST_CHECK_FEATURE(DVB, [DVB Source], dvb, [
 925   AC_MSG_CHECKING([Checking for up to date dvb installation])
 926   AC_CHECK_HEADER(linux/dvb/frontend.h, [HAVE_DVB="yes"], [HAVE_DVB="no"])
 927 ])
 928
 929 else
 930
 931 dnl not building plugins with external dependencies,
 932 dnl but we still need to set the conditionals
 933
 934 AM_CONDITIONAL(USE_QUICKTIME, false)
 935 AM_CONDITIONAL(USE_VCD, false)
 936 AM_CONDITIONAL(USE_ALSA, false)
 937 AM_CONDITIONAL(USE_AMRWB, false)
 938 AM_CONDITIONAL(USE_BZ2, false)
 939 AM_CONDITIONAL(USE_CDAUDIO, false)
 940 AM_CONDITIONAL(USE_DIRECTFB, false)
 941 AM_CONDITIONAL(USE_DTS, false)
 942 AM_CONDITIONAL(USE_DIVX, false)
 943 AM_CONDITIONAL(USE_FAAC, false)
 944 AM_CONDITIONAL(USE_FAAD, false)
 945 AM_CONDITIONAL(USE_FBDEV, false)
 946 AM_CONDITIONAL(USE_GSM, false)
 947 AM_CONDITIONAL(USE_IVORBIS, false)
 948 AM_CONDITIONAL(USE_JACK, false)
 949 AM_CONDITIONAL(USE_LADSPA, false)
 950 AM_CONDITIONAL(USE_LIBMMS, false)
 951 AM_CONDITIONAL(USE_MPEG2ENC, false)
 952 AM_CONDITIONAL(USE_MUSEPACK, false)
 953 AM_CONDITIONAL(USE_MUSICBRAINZ, false)
 954 AM_CONDITIONAL(USE_MYTHTV, false)
 955 AM_CONDITIONAL(USE_NAS, false)
 956 AM_CONDITIONAL(USE_NEON, false)
 957 AM_CONDITIONAL(USE_SOUP, false)
 958 AM_CONDITIONAL(USE_SDL, false)
 959 AM_CONDITIONAL(USE_SNDFILE, false)
 960 AM_CONDITIONAL(USE_SOUNDTOUCH, false)
 961 AM_CONDITIONAL(USE_SPC, false)
 962 AM_CONDITIONAL(USE_SWFDEC, false)
 963 AM_CONDITIONAL(USE_THEORADEC, false)
 964 AM_CONDITIONAL(USE_TIMIDITY, false)
 965 AM_CONDITIONAL(USE_X264, false)
 966 AM_CONDITIONAL(USE_XVID, false)
 967 AM_CONDITIONAL(USE_WILDMIDI, false)
 968 AM_CONDITIONAL(USE_DVB, false)
 969
 970 fi dnl of EXT plugins
 971
 972 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 973
 974 dnl Overview:
 975 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 976 dnl GST_*:              flags shared by built objects to link against GStreamer
 977 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 978 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 979 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 980 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 981
 982 dnl GST_OPTION_CFLAGS
 983 if test "x$USE_DEBUG" = xyes; then
 984    PROFILE_CFLAGS="-g"
 985 fi
 986 AC_SUBST(PROFILE_CFLAGS)
 987
 988 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 989   dnl Define _only_ during CVS (not pre-releases or releases)
 990   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 991 else
 992   DEPRECATED_CFLAGS=""
 993 fi
 994 AC_SUBST(DEPRECATED_CFLAGS)
 995
 996 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 997 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 998 AC_SUBST(GST_OPTION_CFLAGS)
 999
1000 dnl FIXME: do we want to rename to GST_ALL_* ?
1001 dnl prefer internal headers to already installed ones
1002 dnl also add builddir include for enumtypes and marshal
1003 dnl add GST_OPTION_CFLAGS, but overridable
1004 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1005 AC_SUBST(GST_CFLAGS)
1006 AC_SUBST(GST_LIBS)
1007
1008 dnl LDFLAGS really should only contain flags, not libs - they get added before
1009 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1010 GST_ALL_LDFLAGS="-no-undefined"
1011 AC_SUBST(GST_ALL_LDFLAGS)
1012
1013 dnl this really should only contain flags, not libs - they get added before
1014 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1015 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1016 AC_SUBST(GST_PLUGIN_LDFLAGS)
1017
1018 dnl *** output files ***
1019
1020 dnl po/Makefile.in
1021
1022
1023 AC_CONFIG_FILES(
1024 Makefile
1025 gst-plugins-bad.spec
1026 gst/Makefile
1027 gst/app/Makefile
1028 gst/bayer/Makefile
1029 gst/cdxaparse/Makefile
1030 gst/deinterlace/Makefile
1031 gst/dvdspu/Makefile
1032 gst/festival/Makefile
1033 gst/filter/Makefile
1034 gst/flv/Makefile
1035 gst/freeze/Makefile
1036 gst/h264parse/Makefile
1037 gst/interleave/Makefile
1038 gst/librfb/Makefile
1039 gst/modplug/Makefile
1040 gst/modplug/libmodplug/Makefile
1041 gst/mpegtsparse/Makefile
1042 gst/mpeg4videoparse/Makefile
1043 gst/mpegvideoparse/Makefile
1044 gst/mve/Makefile
1045 gst/nsf/Makefile
1046 gst/nuvdemux/Makefile
1047 gst/rawparse/Makefile
1048 gst/replaygain/Makefile
1049 gst/rtpmanager/Makefile
1050 gst/sdp/Makefile
1051 gst/selector/Makefile
1052 gst/speed/Makefile
1053 gst/speexresample/Makefile
1054 gst/stereo/Makefile
1055 gst/tta/Makefile
1056 gst/videosignal/Makefile
1057 gst/vmnc/Makefile
1058 gst/real/Makefile
1059 gst/y4m/Makefile
1060 gst-libs/Makefile
1061 gst-libs/gst/Makefile
1062 gst-libs/gst/app/Makefile
1063 gst-libs/gst/dshow/Makefile
1064 sys/Makefile
1065 sys/dshowdecwrapper/Makefile
1066 sys/dshowsrcwrapper/Makefile
1067 sys/fbdev/Makefile
1068 sys/dvb/Makefile
1069 sys/qtwrapper/Makefile
1070 sys/vcd/Makefile
1071 examples/Makefile
1072 examples/app/Makefile
1073 examples/directfb/Makefile
1074 examples/switch/Makefile
1075 ext/amrwb/Makefile
1076 ext/alsaspdif/Makefile
1077 ext/bz2/Makefile
1078 ext/cdaudio/Makefile
1079 ext/dc1394/Makefile
1080 ext/directfb/Makefile
1081 ext/divx/Makefile
1082 ext/dts/Makefile
1083 ext/metadata/Makefile
1084 ext/faac/Makefile
1085 ext/faad/Makefile
1086 ext/gsm/Makefile
1087 ext/ivorbis/Makefile
1088 ext/jack/Makefile
1089 ext/ladspa/Makefile
1090 ext/libmms/Makefile
1091 ext/Makefile
1092 ext/nas/Makefile
1093 ext/mpeg2enc/Makefile
1094 ext/musepack/Makefile
1095 ext/musicbrainz/Makefile
1096 ext/mythtv/Makefile
1097 ext/neon/Makefile
1098 ext/soup/Makefile
1099 ext/sdl/Makefile
1100 ext/sndfile/Makefile
1101 ext/soundtouch/Makefile
1102 ext/spc/Makefile
1103 ext/swfdec/Makefile
1104 ext/theora/Makefile
1105 ext/timidity/Makefile
1106 ext/x264/Makefile
1107 ext/xvid/Makefile
1108 po/Makefile.in
1109 docs/Makefile
1110 docs/plugins/Makefile
1111 docs/version.entities
1112 common/Makefile
1113 common/m4/Makefile
1114 m4/Makefile
1115 tests/Makefile
1116 tests/check/Makefile
1117 tests/icles/Makefile
1118 win32/common/config.h
1119 )
1120 AC_OUTPUT
1121
1122 AG_GST_OUTPUT_PLUGINS