configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT.
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusb],[LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC],[libusb-devel@lists.sourceforge.net],[libusb],[http://libusb.info])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_CONFIG_SRCDIR([libusb/core.c])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AC_CONFIG_HEADERS([config.h])
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36
  37 AC_PREREQ([2.50])
  38 AC_PROG_CC
  39 LT_INIT
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48
  49 dnl on linux-android platform, some functions are in different places
  50 case $host in
  51 *-linux-android*)
  52         AC_MSG_RESULT([This is a Linux-Android system])
  53         is_backend_android="yes"
  54         ;;
  55 *)
  56         is_backend_android="no"
  57 esac
  58
  59 case $host in
  60 *-linux* | *-uclinux*)
  61         AC_MSG_RESULT([Linux])
  62         backend="linux"
  63         threads="posix"
  64         ;;
  65 *-darwin*)
  66         AC_MSG_RESULT([Darwin/Mac OS X])
  67         backend="darwin"
  68         threads="posix"
  69         ;;
  70 *-openbsd*)
  71         AC_MSG_RESULT([OpenBSD])
  72         backend="openbsd"
  73         threads="posix"
  74         ;;
  75 *-netbsd*)
  76         AC_MSG_RESULT([NetBSD])
  77         backend="netbsd"
  78         threads="posix"
  79         ;;
  80 *-mingw*)
  81         AC_MSG_RESULT([Windows])
  82         backend="windows"
  83         threads="windows"
  84         create_import_lib="yes"
  85         AM_CFLAGS="${AM_CFLAGS} -fno-omit-frame-pointer"
  86         ;;
  87 *-cygwin*)
  88         AC_MSG_RESULT([Cygwin (using Windows backend)])
  89         backend="windows"
  90         threads="posix"
  91         ;;
  92 *-haiku*)
  93         AC_MSG_RESULT([Haiku])
  94         AC_CONFIG_SUBDIRS([libusb/os/haiku])
  95         backend="haiku"
  96         threads="posix"
  97         ;;
  98 *)
  99         AC_MSG_ERROR([unsupported operating system])
 100 esac
 101
 102 case $backend in
 103 linux)
 104         AC_DEFINE(OS_LINUX, 1, [Linux backend])
 105         AC_SUBST(OS_LINUX)
 106         AC_SEARCH_LIBS(clock_gettime, rt, [], [], -pthread)
 107         AC_ARG_ENABLE([udev],
 108                 [AC_HELP_STRING([--enable-udev], [use udev for device enumeration and hotplug support (recommended) [default=yes]])],
 109                 [], [enable_udev="yes"])
 110                 if test "x$enable_udev" = "xyes" ; then
 111                         # system has udev. use it or fail!
 112                         AC_CHECK_HEADERS([libudev.h],[],[AC_ERROR(["udev support requested but libudev not installed"])])
 113                         AC_CHECK_LIB([udev], [udev_new], [], [AC_ERROR(["udev support requested but libudev not installed"])])
 114                         AC_DEFINE(USE_UDEV, 1, [Use udev for device enumeration/hotplug])
 115                 else
 116                         AC_CHECK_HEADERS([asm/types.h sys/socket.h], [], [])
 117                         AC_CHECK_HEADERS([linux/netlink.h linux/filter.h], [], [AC_ERROR(["Linux netlink headers not found"])], [
 118 #ifdef HAVE_ASM_TYPES_H
 119 #include <asm/types.h>
 120 #endif
 121 #ifdef HAVE_SYS_SOCKET_H
 122 #include <sys/socket.h>
 123 #endif
 124 ])
 125                 fi
 126                 AC_SUBST(USE_UDEV)
 127
 128 case $is_backend_android in
 129 yes)
 130         dnl some pthread functions is in libc
 131         THREAD_CFLAGS="-c"
 132         LIBS="${LIBS} -c"
 133         dnl there are gettimeofday function but configure doesn't seem to be able to find it.
 134         AC_DEFINE([HAVE_GETTIMEOFDAY], [1], [Define if you have gettimeofday])
 135         ;;
 136 *)
 137         THREAD_CFLAGS="-pthread"
 138         LIBS="${LIBS} -pthread"
 139 esac
 140
 141         AC_CHECK_HEADERS([poll.h])
 142         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 143         ;;
 144 darwin)
 145         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
 146         AC_SUBST(OS_DARWIN)
 147         LIBS="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
 148         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
 149         AC_CHECK_HEADERS([poll.h])
 150         AC_CHECK_TYPE([nfds_t],
 151                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
 152                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
 153                 [#include <poll.h>])
 154         ;;
 155 openbsd)
 156         AC_DEFINE(OS_OPENBSD, 1, [OpenBSD backend])
 157         AC_SUBST(OS_OPENBSD)
 158         THREAD_CFLAGS="-pthread"
 159         LIBS="-pthread"
 160         AC_CHECK_HEADERS([poll.h])
 161         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 162         ;;
 163 netbsd)
 164         AC_DEFINE(OS_NETBSD, 1, [NetBSD backend])
 165         AC_SUBST(OS_NETBSD)
 166         THREAD_CFLAGS="-pthread"
 167         LIBS="-pthread"
 168         AC_CHECK_HEADERS([poll.h])
 169         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 170         ;;
 171 windows)
 172         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
 173         AC_SUBST(OS_WINDOWS)
 174         LIBS=""
 175         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 176         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
 177         AC_DEFINE([WINVER], 0x0501, [Oldest Windows version supported])
 178         ;;
 179 haiku)
 180         AC_DEFINE(OS_HAIKU, 1, [Haiku backend])
 181         AC_SUBST(OS_HAIKU)
 182         LIBS="${LIBS} -lbe"
 183         AC_CHECK_HEADERS([poll.h])
 184         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 185         ;;
 186 esac
 187
 188 AC_SUBST(LIBS)
 189
 190 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 191 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 192 AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xopenbsd)
 193 AM_CONDITIONAL(OS_NETBSD, test "x$backend" = xnetbsd)
 194 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 195 AM_CONDITIONAL(OS_HAIKU, test "x$backend" = xhaiku)
 196 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 197 AM_CONDITIONAL(CREATE_IMPORT_LIB, test "x$create_import_lib" = "xyes")
 198 AM_CONDITIONAL(USE_UDEV, test "x$enable_udev" = xyes)
 199 if test "$threads" = posix; then
 200         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 201 fi
 202
 203 # timerfd
 204 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 205 AC_ARG_ENABLE([timerfd],
 206         [AS_HELP_STRING([--enable-timerfd],
 207                 [use timerfd for timing [default=auto]])],
 208         [use_timerfd=$enableval], [use_timerfd='auto'])
 209
 210 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 211         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 212 fi
 213
 214 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 215 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 216         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 217 fi
 218
 219 AC_MSG_CHECKING([whether to use timerfd for timing])
 220 if test "x$use_timerfd" = "xno"; then
 221         AC_MSG_RESULT([no (disabled by user)])
 222 else
 223         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 224                 AC_MSG_RESULT([yes])
 225                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 226         else
 227                 AC_MSG_RESULT([no (header not available)])
 228         fi
 229 fi
 230
 231 AC_CHECK_TYPES(struct timespec)
 232
 233 # Message logging
 234 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 235         [log_enabled=$enableval],
 236         [log_enabled='yes'])
 237 if test "x$log_enabled" != "xno"; then
 238         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 239 fi
 240
 241 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 242         [start with debug message logging enabled [default=no]])],
 243         [debug_log_enabled=$enableval],
 244         [debug_log_enabled='no'])
 245 if test "x$debug_log_enabled" != "xno"; then
 246         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Start with debug message logging enabled])
 247 fi
 248
 249 AC_ARG_ENABLE([system-log], [AS_HELP_STRING([--enable-system-log],
 250         [output logging messages to system wide log, if supported by the OS [default=no]])],
 251         [system_log_enabled=$enableval],
 252         [system_log_enabled='no'])
 253 if test "x$system_log_enabled" != "xno"; then
 254         AC_DEFINE([USE_SYSTEM_LOGGING_FACILITY], 1, [Enable output to system log])
 255 fi
 256
 257 # Check if syslog is available in standard C library
 258 AC_CHECK_HEADERS(syslog.h)
 259 AC_CHECK_FUNC([syslog], [have_syslog=yes], [have_syslog=no])
 260 if test "x$have_syslog" != "xno"; then
 261         AC_DEFINE([HAVE_SYSLOG_FUNC], 1, [syslog() function available])
 262 fi
 263
 264 # Examples build
 265 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 266         [build example applications [default=no]])],
 267         [build_examples=$enableval],
 268         [build_examples='no'])
 269 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 270
 271 # Tests build
 272 AC_ARG_ENABLE([tests-build], [AS_HELP_STRING([--enable-tests-build],
 273         [build test applications [default=no]])],
 274         [build_tests=$enableval],
 275         [build_tests='no'])
 276 AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != "xno"])
 277
 278 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 279 saved_cflags="$CFLAGS"
 280 # -Werror required for cygwin
 281 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 282 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 283         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 284          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 285         [ VISIBILITY_CFLAGS=""
 286          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 287         ])
 288 CFLAGS="$saved_cflags"
 289
 290 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 291 saved_cflags="$CFLAGS"
 292 CFLAGS="$CFLAGS -Wno-pointer-sign"
 293 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 294         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 295 CFLAGS="$saved_cflags"
 296
 297 # sigaction not available on MinGW
 298 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 299 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 300
 301 # headers not available on all platforms but required on others
 302 AC_CHECK_HEADERS([sys/time.h])
 303 AC_CHECK_FUNCS(gettimeofday)
 304 AC_CHECK_HEADERS([signal.h])
 305
 306 # check for -std=gnu99 compiler support
 307 saved_cflags="$CFLAGS"
 308 CFLAGS="-std=gnu99"
 309 AC_MSG_CHECKING([whether CC supports -std=gnu99])
 310 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 311     [AC_MSG_RESULT([yes])]
 312     [AM_CFLAGS="${AM_CFLAGS} -std=gnu99"],
 313     [AC_MSG_RESULT([no])]
 314 )
 315 CFLAGS="$saved_cflags"
 316
 317 AM_CFLAGS="${AM_CFLAGS} -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow ${THREAD_CFLAGS} ${VISIBILITY_CFLAGS}"
 318
 319 AC_SUBST(AM_CFLAGS)
 320 AC_SUBST(LTLDFLAGS)
 321
 322 AC_CONFIG_FILES([libusb-1.0.pc])
 323 AC_CONFIG_FILES([Makefile])
 324 AC_CONFIG_FILES([libusb/Makefile])
 325 AC_CONFIG_FILES([examples/Makefile])
 326 AC_CONFIG_FILES([tests/Makefile])
 327 AC_CONFIG_FILES([doc/Makefile])
 328 AC_CONFIG_FILES([doc/doxygen.cfg])
 329 AC_OUTPUT