configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 AC_ARG_ENABLE(as-accelerator-for,
 288 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 289                 [build as offload target compiler.
 290                 Specify offload host triple by ARG])])
 291
 292 AC_ARG_ENABLE(offload-targets,
 293 [AS_HELP_STRING([--enable-offload-targets=LIST],
 294                 [enable offloading to devices from comma-separated LIST of
 295                 TARGET[=DIR]. Use optional path to find offload target compiler
 296                 during the build])],
 297 [
 298   if test x"$enable_offload_targets" = x; then
 299     AC_MSG_ERROR([no offload targets specified])
 300   fi
 301 ], [enable_offload_targets=])
 302
 303 # Handle --enable-gold, --enable-ld.
 304 # --disable-gold [--enable-ld]
 305 #     Build only ld.  Default option.
 306 # --enable-gold [--enable-ld]
 307 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 308 #     as "ld.bfd" and "ld".
 309 # --enable-gold=default [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 311 #     install ld as "ld.bfd".
 312 # --enable-gold[=default] --disable-ld
 313 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 314 # --enable-gold --enable-ld=default
 315 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 316 #     and ld.bfd).
 317 #     In other words, ld is default
 318 # --enable-gold=default --enable-ld=default
 319 #     Error.
 320
 321 default_ld=
 322 AC_ARG_ENABLE(gold,
 323 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 324                 [build gold @<:@ARG={default,yes,no}@:>@])],
 325 ENABLE_GOLD=$enableval,
 326 ENABLE_GOLD=no)
 327 case "${ENABLE_GOLD}" in
 328   yes|default)
 329     # Check for ELF target.
 330     is_elf=no
 331     case "${target}" in
 332       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 333       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 334       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 335       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 336         case "${target}" in
 337           *-*-linux*aout* | *-*-linux*oldld*)
 338             ;;
 339           *)
 340             is_elf=yes
 341             ;;
 342         esac
 343     esac
 344
 345     if test "$is_elf" = "yes"; then
 346       # Check for target supported by gold.
 347       case "${target}" in
 348         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 349         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 350           configdirs="$configdirs gold"
 351           if test x${ENABLE_GOLD} = xdefault; then
 352             default_ld=gold
 353           fi
 354           ENABLE_GOLD=yes
 355           ;;
 356       esac
 357     fi
 358     ;;
 359   no)
 360     ;;
 361   *)
 362     AC_MSG_ERROR([invalid --enable-gold argument])
 363     ;;
 364 esac
 365
 366 AC_ARG_ENABLE(ld,
 367 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 368                 [build ld @<:@ARG={default,yes,no}@:>@])],
 369 ENABLE_LD=$enableval,
 370 ENABLE_LD=yes)
 371
 372 case "${ENABLE_LD}" in
 373   default)
 374     if test x${default_ld} != x; then
 375       AC_MSG_ERROR([either gold or ld can be the default ld])
 376     fi
 377     ;;
 378   yes)
 379     ;;
 380   no)
 381     if test x${ENABLE_GOLD} != xyes; then
 382       AC_MSG_WARN([neither ld nor gold are enabled])
 383     fi
 384     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 385     ;;
 386   *)
 387     AC_MSG_ERROR([invalid --enable-ld argument])
 388     ;;
 389 esac
 390
 391 # PR gas/19109
 392 # Decide the default method for compressing debug sections.
 393 # Provide a configure time option to override our default.
 394 AC_ARG_ENABLE(compressed_debug_sections,
 395 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 396                 [Enable compressed debug sections for gas, gold or ld by
 397                  default])],
 398 [
 399   if test x"$enable_compressed_debug_sections" = xyes; then
 400     AC_MSG_ERROR([no program with compressed debug sections specified])
 401   fi
 402 ], [enable_compressed_debug_sections=])
 403
 404 # Configure extra directories which are host specific
 405
 406 case "${host}" in
 407   *-cygwin*)
 408     configdirs="$configdirs libtermcap" ;;
 409 esac
 410
 411 # A target can indicate whether a language isn't supported for some reason.
 412 # Only spaces may be used in this macro; not newlines or tabs.
 413 unsupported_languages=
 414
 415 # Remove more programs from consideration, based on the host or
 416 # target this usually means that a port of the program doesn't
 417 # exist yet.
 418
 419 case "${host}" in
 420   i[[3456789]]86-*-msdosdjgpp*)
 421     noconfigdirs="$noconfigdirs tcl tk itcl"
 422     ;;
 423 esac
 424
 425
 426 AC_ARG_ENABLE(libquadmath,
 427 AS_HELP_STRING([--disable-libquadmath],
 428   [do not build libquadmath directory]),
 429 ENABLE_LIBQUADMATH=$enableval,
 430 ENABLE_LIBQUADMATH=yes)
 431 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 432   noconfigdirs="$noconfigdirs target-libquadmath"
 433 fi
 434
 435
 436 AC_ARG_ENABLE(libquadmath-support,
 437 AS_HELP_STRING([--disable-libquadmath-support],
 438   [disable libquadmath support for Fortran]),
 439 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 440 ENABLE_LIBQUADMATH_SUPPORT=yes)
 441 enable_libquadmath_support=
 442 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 443   enable_libquadmath_support=no
 444 fi
 445
 446
 447 AC_ARG_ENABLE(libada,
 448 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 449 ENABLE_LIBADA=$enableval,
 450 ENABLE_LIBADA=yes)
 451 if test "${ENABLE_LIBADA}" != "yes" ; then
 452   noconfigdirs="$noconfigdirs gnattools"
 453 fi
 454
 455 AC_ARG_ENABLE(libssp,
 456 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 457 ENABLE_LIBSSP=$enableval,
 458 ENABLE_LIBSSP=yes)
 459
 460 AC_ARG_ENABLE(libstdcxx,
 461 AS_HELP_STRING([--disable-libstdcxx],
 462   [do not build libstdc++-v3 directory]),
 463 ENABLE_LIBSTDCXX=$enableval,
 464 ENABLE_LIBSTDCXX=default)
 465 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 466   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 467 fi]
 468
 469 # If this is accelerator compiler and its target is intelmic we enable
 470 # target liboffloadmic by default.  If this is compiler with offloading
 471 # for intelmic we enable host liboffloadmic by default.  Otherwise
 472 # liboffloadmic is disabled by default.
 473 AC_ARG_ENABLE([liboffloadmic],
 474 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 475                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 476 [case "$enableval" in
 477   no | host | target)
 478     enable_liboffloadmic=$enableval ;;
 479   *)
 480     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 481 esac],
 482 [if test x"$enable_as_accelerator_for" != x; then
 483   case "${target}" in
 484     *-intelmic-* | *-intelmicemul-*)
 485       enable_liboffloadmic=target
 486       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 487       ;;
 488     *)
 489       enable_liboffloadmic=no
 490       ;;
 491   esac
 492 else
 493   case "${enable_offload_targets}" in
 494     *-intelmic-* | *-intelmicemul-*)
 495       enable_liboffloadmic=host
 496       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 497       ;;
 498     *)
 499       enable_liboffloadmic=no
 500       ;;
 501     esac
 502 fi])
 503 AC_SUBST(extra_liboffloadmic_configure_flags)
 504
 505 # Enable libgomp by default on hosted POSIX systems, and a few others.
 506 if test x$enable_libgomp = x ; then
 507     case "${target}" in
 508     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 509         ;;
 510     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 511         ;;
 512     *-*-solaris2* | *-*-hpux11*)
 513         ;;
 514     *-*-darwin* | *-*-aix*)
 515         ;;
 516     nvptx*-*-* | amdgcn*-*-*)
 517         ;;
 518     *)
 519         noconfigdirs="$noconfigdirs target-libgomp"
 520         ;;
 521     esac
 522 fi
 523
 524 # Disable libatomic on unsupported systems.
 525 if test -d ${srcdir}/libatomic; then
 526     if test x$enable_libatomic = x; then
 527         AC_MSG_CHECKING([for libatomic support])
 528         if (srcdir=${srcdir}/libatomic; \
 529                 . ${srcdir}/configure.tgt; \
 530                 test -n "$UNSUPPORTED")
 531         then
 532             AC_MSG_RESULT([no])
 533             noconfigdirs="$noconfigdirs target-libatomic"
 534         else
 535             AC_MSG_RESULT([yes])
 536         fi
 537     fi
 538 fi
 539
 540 # Disable liboffloadmic on unsupported systems.
 541 if test -d ${srcdir}/liboffloadmic; then
 542     if test x$enable_liboffloadmic != xno; then
 543         AC_MSG_CHECKING([for liboffloadmic support])
 544         if (srcdir=${srcdir}/liboffloadmic; \
 545                 . ${srcdir}/configure.tgt; \
 546                 test -n "$UNSUPPORTED")
 547         then
 548             AC_MSG_RESULT([no])
 549             noconfigdirs="$noconfigdirs target-liboffloadmic"
 550         else
 551             AC_MSG_RESULT([yes])
 552         fi
 553     fi
 554 fi
 555
 556 # Disable libitm on unsupported systems.
 557 if test -d ${srcdir}/libitm; then
 558     if test x$enable_libitm = x; then
 559         AC_MSG_CHECKING([for libitm support])
 560         if (srcdir=${srcdir}/libitm; \
 561                 . ${srcdir}/configure.tgt; \
 562                 test -n "$UNSUPPORTED")
 563         then
 564             AC_MSG_RESULT([no])
 565             noconfigdirs="$noconfigdirs target-libitm"
 566         else
 567             AC_MSG_RESULT([yes])
 568         fi
 569     fi
 570 fi
 571
 572 # Disable libsanitizer on unsupported systems.
 573 if test -d ${srcdir}/libsanitizer; then
 574     if test x$enable_libsanitizer = x; then
 575         AC_MSG_CHECKING([for libsanitizer support])
 576         if (srcdir=${srcdir}/libsanitizer; \
 577                 . ${srcdir}/configure.tgt; \
 578                 test -n "$UNSUPPORTED")
 579         then
 580             AC_MSG_RESULT([no])
 581             noconfigdirs="$noconfigdirs target-libsanitizer"
 582         else
 583             AC_MSG_RESULT([yes])
 584         fi
 585     fi
 586 fi
 587
 588 # Disable libvtv on unsupported systems.
 589 if test -d ${srcdir}/libvtv; then
 590     if test x$enable_libvtv = x; then
 591         AC_MSG_CHECKING([for libvtv support])
 592         if (srcdir=${srcdir}/libvtv; \
 593                 . ${srcdir}/configure.tgt; \
 594                 test "$VTV_SUPPORTED" != "yes")
 595         then
 596             AC_MSG_RESULT([no])
 597             noconfigdirs="$noconfigdirs target-libvtv"
 598         else
 599             AC_MSG_RESULT([yes])
 600         fi
 601     fi
 602 fi
 603
 604
 605 # Disable libhsail-rt on unsupported systems.
 606 if test -d ${srcdir}/libhsail-rt; then
 607     if test x$enable_libhsail_rt = x; then
 608         AC_MSG_CHECKING([for libhsail-rt support])
 609         if (srcdir=${srcdir}/libhsail-rt; \
 610                 . ${srcdir}/configure.tgt; \
 611                 test -n "$UNSUPPORTED")
 612         then
 613             AC_MSG_RESULT([no])
 614             unsupported_languages="$unsupported_languages brig"
 615             # This implicitly disables also target-libhsail-rt as it won't
 616             # get added to the build without BRIG FE.
 617         else
 618             AC_MSG_RESULT([yes])
 619         fi
 620     fi
 621 fi
 622
 623
 624 # Disable libquadmath for some systems.
 625 case "${target}" in
 626   avr-*-*)
 627     noconfigdirs="$noconfigdirs target-libquadmath"
 628     ;;
 629   # libquadmath is unused on AIX and libquadmath build process use of
 630   # LD_LIBRARY_PATH can break AIX bootstrap.
 631   powerpc-*-aix* | rs6000-*-aix*)
 632     noconfigdirs="$noconfigdirs target-libquadmath"
 633     ;;
 634 esac
 635
 636 # Disable libssp for some systems.
 637 case "${target}" in
 638   avr-*-*)
 639     # No hosted I/O support.
 640     noconfigdirs="$noconfigdirs target-libssp"
 641     ;;
 642   bpf-*-*)
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   powerpc-*-aix* | rs6000-*-aix*)
 646     noconfigdirs="$noconfigdirs target-libssp"
 647     ;;
 648   pru-*-*)
 649     # No hosted I/O support.
 650     noconfigdirs="$noconfigdirs target-libssp"
 651     ;;
 652   rl78-*-*)
 653     # libssp uses a misaligned load to trigger a fault, but the RL78
 654     # doesn't fault for those - instead, it gives a build-time error
 655     # for explicit misaligned loads.
 656     noconfigdirs="$noconfigdirs target-libssp"
 657     ;;
 658   visium-*-*)
 659     # No hosted I/O support.
 660     noconfigdirs="$noconfigdirs target-libssp"
 661     ;;
 662 esac
 663
 664 # Disable libstdc++-v3 for some systems.
 665 # Allow user to override this if they pass --enable-libstdc++-v3
 666 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 667   case "${target}" in
 668     *-*-vxworks*)
 669       # VxWorks uses the Dinkumware C++ library.
 670       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 671       ;;
 672     amdgcn*-*-*)
 673       # Not ported/fails to build when using newlib.
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676     arm*-wince-pe*)
 677       # the C++ libraries don't build on top of CE's C libraries
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680     avr-*-*)
 681       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 682       ;;
 683     bpf-*-*)
 684       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 685       ;;
 686     ft32-*-*)
 687       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 688       ;;
 689   esac
 690 fi
 691
 692 # Disable C++ on systems where it is known to not work.
 693 # For testing, you can override this with --enable-languages=c++.
 694 case ,${enable_languages}, in
 695   *,c++,*)
 696     ;;
 697   *)
 698       case "${target}" in
 699         bpf-*-*)
 700           unsupported_languages="$unsupported_languages c++"
 701           ;;
 702       esac
 703       ;;
 704 esac
 705
 706 # Disable Objc on systems where it is known to not work.
 707 # For testing, you can override this with --enable-languages=objc.
 708 case ,${enable_languages}, in
 709   *,objc,*)
 710     ;;
 711   *)
 712       case "${target}" in
 713         bpf-*-*)
 714           unsupported_languages="$unsupported_languages objc"
 715           ;;
 716       esac
 717       ;;
 718 esac
 719
 720 # Disable D on systems where it is known to not work.
 721 # For testing, you can override this with --enable-languages=d.
 722 case ,${enable_languages}, in
 723   *,d,*)
 724     ;;
 725   *)
 726     case "${target}" in
 727       *-*-darwin*)
 728         unsupported_languages="$unsupported_languages d"
 729         ;;
 730       bpf-*-*)
 731         unsupported_languages="$unsupported_languages d"
 732         ;;
 733     esac
 734     ;;
 735 esac
 736
 737 # Disable libphobos on unsupported systems.
 738 # For testing, you can override this with --enable-libphobos.
 739 if test -d ${srcdir}/libphobos; then
 740     if test x$enable_libphobos = x; then
 741         AC_MSG_CHECKING([for libphobos support])
 742         if (srcdir=${srcdir}/libphobos; \
 743                 . ${srcdir}/configure.tgt; \
 744                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 745         then
 746             AC_MSG_RESULT([no])
 747             noconfigdirs="$noconfigdirs target-libphobos"
 748         else
 749             AC_MSG_RESULT([yes])
 750         fi
 751     fi
 752 fi
 753
 754 # Disable Fortran for some systems.
 755 case "${target}" in
 756   mmix-*-*)
 757     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 758     unsupported_languages="$unsupported_languages fortran"
 759     ;;
 760   bpf-*-*)
 761     unsupported_languages="$unsupported_languages fortran"
 762     ;;
 763 esac
 764
 765 # Disable libffi for some systems.
 766 case "${target}" in
 767   powerpc-*-darwin*)
 768     ;;
 769   i[[3456789]]86-*-darwin*)
 770     ;;
 771   x86_64-*-darwin[[912]]*)
 772     ;;
 773   *-*-darwin*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   *-*-netware*)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   *-*-phoenix*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   *-*-rtems*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   *-*-tpf*)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   *-*-uclinux*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   *-*-vxworks*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794   aarch64*-*-freebsd*)
 795     noconfigdirs="$noconfigdirs target-libffi"
 796     ;;
 797   alpha*-*-*vms*)
 798     noconfigdirs="$noconfigdirs target-libffi"
 799     ;;
 800   arm*-*-freebsd*)
 801     noconfigdirs="$noconfigdirs target-libffi"
 802     ;;
 803   arm-wince-pe)
 804     noconfigdirs="$noconfigdirs target-libffi"
 805     ;;
 806   arm*-*-symbianelf*)
 807     noconfigdirs="$noconfigdirs target-libffi"
 808     ;;
 809   bpf-*-*)
 810     noconfigdirs="$noconfigdirs target-libffi"
 811     ;;
 812   cris-*-* | crisv32-*-*)
 813     case "${target}" in
 814       *-*-linux*)
 815         ;;
 816       *) # See PR46792 regarding target-libffi.
 817         noconfigdirs="$noconfigdirs target-libffi";;
 818     esac
 819     ;;
 820   hppa*64*-*-hpux*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   hppa*-hp-hpux11*)
 824     ;;
 825   hppa*-*-hpux*)
 826     noconfigdirs="$noconfigdirs target-libffi"
 827     ;;
 828   ia64*-*-*vms*)
 829     noconfigdirs="$noconfigdirs target-libffi"
 830     ;;
 831   i[[3456789]]86-w64-mingw*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   i[[3456789]]86-*-mingw*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837   x86_64-*-mingw*)
 838     noconfigdirs="$noconfigdirs target-libffi"
 839     ;;
 840   mmix-*-*)
 841     noconfigdirs="$noconfigdirs target-libffi"
 842     ;;
 843   powerpc-*-aix*)
 844     ;;
 845   rs6000-*-aix*)
 846     ;;
 847   ft32-*-*)
 848     noconfigdirs="$noconfigdirs target-libffi"
 849     ;;
 850   *-*-lynxos*)
 851     noconfigdirs="$noconfigdirs target-libffi"
 852     ;;
 853 esac
 854
 855 # Disable the go frontend on systems where it is known to not work. Please keep
 856 # this in sync with contrib/config-list.mk.
 857 case "${target}" in
 858 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 859     unsupported_languages="$unsupported_languages go"
 860     ;;
 861 esac
 862
 863 # Only allow gdbserver on some systems.
 864 if test -d ${srcdir}/gdbserver; then
 865     if test x$enable_gdbserver = x; then
 866         AC_MSG_CHECKING([for gdbserver support])
 867         if (srcdir=${srcdir}/gdbserver; \
 868                 . ${srcdir}/configure.srv; \
 869                 test -n "$UNSUPPORTED")
 870         then
 871             AC_MSG_RESULT([no])
 872             noconfigdirs="$noconfigdirs gdbserver"
 873         else
 874             AC_MSG_RESULT([yes])
 875         fi
 876     fi
 877 fi
 878
 879 # Disable libgo for some systems where it is known to not work.
 880 # For testing, you can easily override this with --enable-libgo.
 881 if test x$enable_libgo = x; then
 882     case "${target}" in
 883     *-*-darwin*)
 884         # PR 46986
 885         noconfigdirs="$noconfigdirs target-libgo"
 886         ;;
 887     *-*-cygwin* | *-*-mingw*)
 888         noconfigdirs="$noconfigdirs target-libgo"
 889         ;;
 890     bpf-*-*)
 891         noconfigdirs="$noconfigdirs target-libgo"
 892         ;;
 893     esac
 894 fi
 895
 896 # Default libgloss CPU subdirectory.
 897 libgloss_dir="$target_cpu"
 898
 899 case "${target}" in
 900   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 901     libgloss_dir=wince
 902     ;;
 903   aarch64*-*-* )
 904     libgloss_dir=aarch64
 905     ;;
 906   arm*-*-*)
 907     libgloss_dir=arm
 908     ;;
 909   cris-*-* | crisv32-*-*)
 910     libgloss_dir=cris
 911     ;;
 912   hppa*-*-*)
 913     libgloss_dir=pa
 914     ;;
 915   i[[3456789]]86-*-*)
 916     libgloss_dir=i386
 917     ;;
 918   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 919     libgloss_dir=m68hc11
 920     ;;
 921   m68*-*-* | fido-*-*)
 922     libgloss_dir=m68k
 923     ;;
 924   mips*-*-*)
 925     libgloss_dir=mips
 926     ;;
 927   powerpc*-*-*)
 928     libgloss_dir=rs6000
 929     ;;
 930   pru-*-*)
 931     libgloss_dir=pru
 932     ;;
 933   sparc*-*-*)
 934     libgloss_dir=sparc
 935     ;;
 936 esac
 937
 938 # Disable newlib and libgloss for various target OSes.
 939 case "${target}" in
 940   alpha*-dec-osf*)
 941     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 942     ;;
 943   i[[3456789]]86-*-linux*)
 944     # This section makes it possible to build newlib natively on linux.
 945     # If we are using a cross compiler then don't configure newlib.
 946     if test x${is_cross_compiler} != xno ; then
 947       noconfigdirs="$noconfigdirs target-newlib"
 948     fi
 949     noconfigdirs="$noconfigdirs target-libgloss"
 950     # If we are not using a cross compiler, do configure newlib.
 951     # Note however, that newlib will only be configured in this situation
 952     # if the --with-newlib option has been given, because otherwise
 953     # 'target-newlib' will appear in skipdirs.
 954     ;;
 955   i[[3456789]]86-*-rdos*)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   sparc-*-sunos4*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   bpf-*-*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-aix*)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-beos*)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-chorusos)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-dragonfly*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-freebsd*)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 983     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     ;;
 985   *-*-lynxos*)
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   *-*-mingw*)
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   *-*-netbsd*)
 992     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 993     ;;
 994   *-*-netware*)
 995     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 996     ;;
 997   *-*-tpf*)
 998     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 999     ;;
1000   *-*-uclinux*)
1001     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1002     ;;
1003   *-*-vxworks*)
1004     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1005     ;;
1006 esac
1007
1008 case "${target}" in
1009   *-*-chorusos)
1010     ;;
1011   aarch64-*-darwin*)
1012     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1013     noconfigdirs="$noconfigdirs sim target-rda"
1014     ;;
1015   amdgcn*-*-*)
1016     ;;
1017   arm-*-darwin*)
1018     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1019     noconfigdirs="$noconfigdirs sim target-rda"
1020     ;;
1021   powerpc-*-darwin*)
1022     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1023     noconfigdirs="$noconfigdirs sim target-rda"
1024     ;;
1025   i[[3456789]]86-*-darwin*)
1026     noconfigdirs="$noconfigdirs ld gprof"
1027     noconfigdirs="$noconfigdirs sim target-rda"
1028     ;;
1029   x86_64-*-darwin[[912]]*)
1030     noconfigdirs="$noconfigdirs ld gas gprof"
1031     noconfigdirs="$noconfigdirs sim target-rda"
1032     ;;
1033   *-*-darwin*)
1034     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1035     noconfigdirs="$noconfigdirs sim target-rda"
1036     ;;
1037   *-*-dragonfly*)
1038     ;;
1039   *-*-freebsd*)
1040     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1041         && test -f /usr/local/include/gmp.h; then
1042       with_gmp=/usr/local
1043     fi
1044     ;;
1045   *-*-kaos*)
1046     # Remove unsupported stuff on all kaOS configurations.
1047     noconfigdirs="$noconfigdirs target-libgloss"
1048     ;;
1049   *-*-netbsd*)
1050     ;;
1051   *-*-netware*)
1052     ;;
1053   *-*-phoenix*)
1054     noconfigdirs="$noconfigdirs target-libgloss"
1055     ;;
1056   *-*-rtems*)
1057     noconfigdirs="$noconfigdirs target-libgloss"
1058     ;;
1059     # The tpf target doesn't support gdb yet.
1060   *-*-tpf*)
1061     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1062     ;;
1063   *-*-uclinux*)
1064     noconfigdirs="$noconfigdirs target-rda"
1065     ;;
1066   *-*-vxworks*)
1067     ;;
1068   alpha*-dec-osf*)
1069     # ld works, but does not support shared libraries.
1070     # gas doesn't generate exception information.
1071     noconfigdirs="$noconfigdirs gas ld"
1072     ;;
1073   alpha*-*-*vms*)
1074     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1075     ;;
1076   alpha*-*-*)
1077     # newlib is not 64 bit ready
1078     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1079     ;;
1080   bpf-*-*)
1081     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1082     ;;
1083   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1084     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1085     ;;
1086   arc*-*-*)
1087     noconfigdirs="$noconfigdirs sim"
1088     ;;
1089   arm-*-pe*)
1090     noconfigdirs="$noconfigdirs target-libgloss"
1091     ;;
1092   arm-*-riscix*)
1093     noconfigdirs="$noconfigdirs ld target-libgloss"
1094     ;;
1095   avr-*-*)
1096     if test x${with_avrlibc} != xno; then
1097       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1098     fi
1099     ;;
1100   c4x-*-* | tic4x-*-*)
1101     noconfigdirs="$noconfigdirs target-libgloss"
1102     ;;
1103   tic54x-*-*)
1104     noconfigdirs="$noconfigdirs target-libgloss gdb"
1105     ;;
1106   d10v-*-*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   d30v-*-*)
1110     noconfigdirs="$noconfigdirs gdb"
1111     ;;
1112   fr30-*-elf*)
1113     noconfigdirs="$noconfigdirs gdb"
1114     ;;
1115   ft32-*-*)
1116     noconfigdirs="$noconfigdirs target-rda gprof"
1117     ;;
1118   moxie-*-*)
1119     noconfigdirs="$noconfigdirs"
1120     ;;
1121   h8300*-*-*)
1122     noconfigdirs="$noconfigdirs target-libgloss"
1123     ;;
1124   h8500-*-*)
1125     noconfigdirs="$noconfigdirs target-libgloss"
1126     ;;
1127   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1128     ;;
1129   hppa*64*-*-hpux*)
1130     noconfigdirs="$noconfigdirs gdb"
1131     ;;
1132   hppa*-*-hpux11*)
1133     noconfigdirs="$noconfigdirs gdb ld"
1134     ;;
1135   hppa*64*-*-linux*)
1136     ;;
1137   hppa*-*-linux*)
1138     ;;
1139   hppa*-*-*elf* | \
1140   hppa*-*-lites* | \
1141   hppa*-*-openbsd* | \
1142   hppa*64*-*-*)
1143     ;;
1144   hppa*-*-pro*)
1145     ;;
1146   hppa*-*-*)
1147     noconfigdirs="$noconfigdirs ld"
1148     ;;
1149   i960-*-*)
1150     noconfigdirs="$noconfigdirs gdb"
1151     ;;
1152   ia64*-*-elf*)
1153     # No gdb support yet.
1154     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1155     ;;
1156   ia64*-**-hpux*)
1157     # No ld support yet.
1158     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1159     ;;
1160   ia64*-*-*vms*)
1161     # No ld support yet.
1162     noconfigdirs="$noconfigdirs libgui itcl ld"
1163     ;;
1164   i[[3456789]]86-w64-mingw*)
1165     ;;
1166   i[[3456789]]86-*-mingw*)
1167     target_configdirs="$target_configdirs target-winsup"
1168     ;;
1169   *-*-cygwin*)
1170     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1171     noconfigdirs="$noconfigdirs target-libgloss"
1172     # always build newlib if winsup directory is present.
1173     if test -d "$srcdir/winsup/cygwin"; then
1174       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1175     elif test -d "$srcdir/newlib"; then
1176       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1177     fi
1178     ;;
1179   i[[3456789]]86-*-pe)
1180     noconfigdirs="$noconfigdirs target-libgloss"
1181     ;;
1182   i[[3456789]]86-*-sco3.2v5*)
1183     # The linker does not yet know about weak symbols in COFF,
1184     # and is not configured to handle mixed ELF and COFF.
1185     noconfigdirs="$noconfigdirs ld target-libgloss"
1186     ;;
1187   i[[3456789]]86-*-sco*)
1188     noconfigdirs="$noconfigdirs gprof target-libgloss"
1189     ;;
1190   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1191     noconfigdirs="$noconfigdirs target-libgloss"
1192     ;;
1193   i[[3456789]]86-*-sysv4*)
1194     noconfigdirs="$noconfigdirs target-libgloss"
1195     ;;
1196   i[[3456789]]86-*-beos*)
1197     noconfigdirs="$noconfigdirs gdb"
1198     ;;
1199   i[[3456789]]86-*-rdos*)
1200     noconfigdirs="$noconfigdirs gdb"
1201     ;;
1202   mmix-*-*)
1203     noconfigdirs="$noconfigdirs gdb"
1204     ;;
1205   mt-*-*)
1206     noconfigdirs="$noconfigdirs sim"
1207     ;;
1208   nfp-*-*)
1209     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1210     noconfigdirs="$noconfigdirs $target_libraries"
1211     ;;
1212   pdp11-*-*)
1213     noconfigdirs="$noconfigdirs gdb gprof"
1214     ;;
1215   powerpc-*-aix*)
1216     # copied from rs6000-*-* entry
1217     noconfigdirs="$noconfigdirs gprof"
1218     ;;
1219   powerpc*-*-winnt* | powerpc*-*-pe*)
1220     target_configdirs="$target_configdirs target-winsup"
1221     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1222     # always build newlib.
1223     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1224     ;;
1225     # This is temporary until we can link against shared libraries
1226   powerpcle-*-solaris*)
1227     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1228     ;;
1229   powerpc-*-beos*)
1230     noconfigdirs="$noconfigdirs gdb"
1231     ;;
1232   rs6000-*-lynxos*)
1233     noconfigdirs="$noconfigdirs gprof"
1234     ;;
1235   rs6000-*-aix*)
1236     noconfigdirs="$noconfigdirs gprof"
1237     ;;
1238   rs6000-*-*)
1239     noconfigdirs="$noconfigdirs gprof"
1240     ;;
1241   m68k-apollo-*)
1242     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1243     ;;
1244   microblaze*)
1245     noconfigdirs="$noconfigdirs gprof"
1246     ;;
1247   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1248     if test x$with_newlib = xyes; then
1249       noconfigdirs="$noconfigdirs gprof"
1250     fi
1251     ;;
1252   mips*-*-irix5*)
1253     noconfigdirs="$noconfigdirs gprof target-libgloss"
1254     ;;
1255   mips*-*-irix6*)
1256     noconfigdirs="$noconfigdirs gprof target-libgloss"
1257     ;;
1258   mips*-*-bsd*)
1259     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1260     ;;
1261   mips*-*-linux*)
1262     ;;
1263   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1264   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1265     noconfigdirs="$noconfigdirs ld gas gprof"
1266     ;;
1267   mips*-*-*)
1268     noconfigdirs="$noconfigdirs gprof"
1269     ;;
1270   nvptx*-*-*)
1271     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1272     ;;
1273   sh-*-*)
1274     case "${target}" in
1275       sh*-*-elf)
1276          ;;
1277       *)
1278          noconfigdirs="$noconfigdirs target-libgloss" ;;
1279     esac
1280     ;;
1281   sparc-*-sunos4*)
1282     if test x${is_cross_compiler} = xno ; then
1283            use_gnu_ld=no
1284     fi
1285     ;;
1286   tic6x-*-*)
1287     noconfigdirs="$noconfigdirs sim"
1288     ;;
1289   tilepro*-*-* | tilegx*-*-*)
1290     noconfigdirs="$noconfigdirs sim"
1291     ;;
1292   v810-*-*)
1293     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1294     ;;
1295   vax-*-*)
1296     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1297     ;;
1298   wasm32-*-*)
1299     noconfigdirs="$noconfigdirs ld"
1300     ;;
1301 esac
1302
1303 # If we aren't building newlib, then don't build libgloss, since libgloss
1304 # depends upon some newlib header files.
1305 case "${noconfigdirs}" in
1306   *target-libgloss*) ;;
1307   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1308 esac
1309
1310 # Work in distributions that contain no compiler tools, like Autoconf.
1311 host_makefile_frag=/dev/null
1312 if test -d ${srcdir}/config ; then
1313 case "${host}" in
1314   i[[3456789]]86-*-msdosdjgpp*)
1315     host_makefile_frag="config/mh-djgpp"
1316     ;;
1317   *-cygwin*)
1318     ACX_CHECK_CYGWIN_CAT_WORKS
1319     host_makefile_frag="config/mh-cygwin"
1320     ;;
1321   *-mingw*)
1322     host_makefile_frag="config/mh-mingw"
1323     ;;
1324   alpha*-linux*)
1325     host_makefile_frag="config/mh-alpha-linux"
1326     ;;
1327   hppa*-hp-hpux10*)
1328     host_makefile_frag="config/mh-pa-hpux10"
1329     ;;
1330   hppa*-hp-hpux*)
1331     host_makefile_frag="config/mh-pa"
1332     ;;
1333   hppa*-*)
1334     host_makefile_frag="config/mh-pa"
1335     ;;
1336   *-*-darwin*)
1337     host_makefile_frag="config/mh-darwin"
1338     ;;
1339   powerpc-*-aix*)
1340     host_makefile_frag="config/mh-ppc-aix"
1341     ;;
1342   rs6000-*-aix*)
1343     host_makefile_frag="config/mh-ppc-aix"
1344     ;;
1345 esac
1346 fi
1347
1348 if test "${build}" != "${host}" ; then
1349   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1350   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1351   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1352   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1353   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1354   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1355   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1356   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1357   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1358   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1359   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1360   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1361   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1362 else
1363   AR_FOR_BUILD="\$(AR)"
1364   AS_FOR_BUILD="\$(AS)"
1365   CC_FOR_BUILD="\$(CC)"
1366   CXX_FOR_BUILD="\$(CXX)"
1367   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1368   GOC_FOR_BUILD="\$(GOC)"
1369   GDC_FOR_BUILD="\$(GDC)"
1370   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1371   LD_FOR_BUILD="\$(LD)"
1372   NM_FOR_BUILD="\$(NM)"
1373   RANLIB_FOR_BUILD="\$(RANLIB)"
1374   WINDRES_FOR_BUILD="\$(WINDRES)"
1375   WINDMC_FOR_BUILD="\$(WINDMC)"
1376 fi
1377
1378 AC_PROG_CC
1379 AC_PROG_CXX
1380
1381 # We must set the default linker to the linker used by gcc for the correct
1382 # operation of libtool.  If LD is not defined and we are using gcc, try to
1383 # set the LD default to the ld used by gcc.
1384 if test -z "$LD"; then
1385   if test "$GCC" = yes; then
1386     case $build in
1387     *-*-mingw*)
1388       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1389     *)
1390       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1391     esac
1392     case $gcc_prog_ld in
1393     # Accept absolute paths.
1394     [[\\/]* | [A-Za-z]:[\\/]*)]
1395       LD="$gcc_prog_ld" ;;
1396     esac
1397   fi
1398 fi
1399
1400 # Check whether -static-libstdc++ -static-libgcc is supported.
1401 have_static_libs=no
1402 if test "$GCC" = yes; then
1403   saved_LDFLAGS="$LDFLAGS"
1404
1405   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1406   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1407   AC_LANG_PUSH(C++)
1408   AC_LINK_IFELSE([AC_LANG_SOURCE([
1409 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1410 #error -static-libstdc++ not implemented
1411 #endif
1412 int main() {}])],
1413     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1414     [AC_MSG_RESULT([no])])
1415   AC_LANG_POP(C++)
1416
1417   LDFLAGS="$saved_LDFLAGS"
1418 fi
1419
1420 ACX_PROG_GNAT
1421 ACX_PROG_CMP_IGNORE_INITIAL
1422
1423 AC_ARG_ENABLE([bootstrap],
1424 [AS_HELP_STRING([--enable-bootstrap],
1425                 [enable bootstrapping @<:@yes if native build@:>@])],,
1426 enable_bootstrap=default)
1427
1428 # Issue errors and warnings for invalid/strange bootstrap combinations.
1429 if test -r $srcdir/gcc/configure; then
1430   have_compiler=yes
1431 else
1432   have_compiler=no
1433 fi
1434
1435 case "$have_compiler:$host:$target:$enable_bootstrap" in
1436   *:*:*:no) ;;
1437
1438   # Default behavior.  Enable bootstrap if we have a compiler
1439   # and we are in a native configuration.
1440   yes:$build:$build:default)
1441     enable_bootstrap=yes ;;
1442
1443   *:*:*:default)
1444     enable_bootstrap=no ;;
1445
1446   # We have a compiler and we are in a native configuration, bootstrap is ok
1447   yes:$build:$build:yes)
1448     ;;
1449
1450   # Other configurations, but we have a compiler.  Assume the user knows
1451   # what he's doing.
1452   yes:*:*:yes)
1453     AC_MSG_WARN([trying to bootstrap a cross compiler])
1454     ;;
1455
1456   # No compiler: if they passed --enable-bootstrap explicitly, fail
1457   no:*:*:yes)
1458     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1459
1460   # Fail if wrong command line
1461   *)
1462     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1463     ;;
1464 esac
1465
1466 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1467 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1468 # require C++11 (or higher).
1469 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1470   CXX="$CXX -std=c++11"
1471 elif test "$have_compiler" = yes; then
1472   AX_CXX_COMPILE_STDCXX(11)
1473
1474   if test "${build}" != "${host}"; then
1475     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1476   fi
1477 fi
1478
1479 # Used for setting $lt_cv_objdir
1480 _LT_CHECK_OBJDIR
1481
1482 # Check for GMP, MPFR and MPC
1483 gmplibs="-lmpc -lmpfr -lgmp"
1484 gmpinc=
1485 have_gmp=no
1486
1487 # Specify a location for mpc
1488 # check for this first so it ends up on the link line before mpfr.
1489 AC_ARG_WITH(mpc,
1490 [AS_HELP_STRING([--with-mpc=PATH],
1491                 [specify prefix directory for installed MPC package.
1492                  Equivalent to --with-mpc-include=PATH/include
1493                  plus --with-mpc-lib=PATH/lib])])
1494 AC_ARG_WITH(mpc-include,
1495 [AS_HELP_STRING([--with-mpc-include=PATH],
1496                 [specify directory for installed MPC include files])])
1497 AC_ARG_WITH(mpc-lib,
1498 [AS_HELP_STRING([--with-mpc-lib=PATH],
1499                 [specify directory for the installed MPC library])])
1500
1501 if test "x$with_mpc" != x; then
1502   gmplibs="-L$with_mpc/lib $gmplibs"
1503   gmpinc="-I$with_mpc/include $gmpinc"
1504 fi
1505 if test "x$with_mpc_include" != x; then
1506   gmpinc="-I$with_mpc_include $gmpinc"
1507 fi
1508 if test "x$with_mpc_lib" != x; then
1509   gmplibs="-L$with_mpc_lib $gmplibs"
1510 fi
1511 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1512   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1513   gmpinc='-I$$s/mpc/src '"$gmpinc"
1514   # Do not test the mpc version.  Assume that it is sufficient, since
1515   # it is in the source tree, and the library has not been built yet
1516   # but it would be included on the link line in the version check below
1517   # hence making the test fail.
1518   have_gmp=yes
1519 fi
1520
1521 # Specify a location for mpfr
1522 # check for this first so it ends up on the link line before gmp.
1523 AC_ARG_WITH(mpfr-dir,
1524 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1525 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1526 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1527
1528 AC_ARG_WITH(mpfr,
1529 [AS_HELP_STRING([--with-mpfr=PATH],
1530                 [specify prefix directory for installed MPFR package.
1531                  Equivalent to --with-mpfr-include=PATH/include
1532                  plus --with-mpfr-lib=PATH/lib])])
1533 AC_ARG_WITH(mpfr-include,
1534 [AS_HELP_STRING([--with-mpfr-include=PATH],
1535                 [specify directory for installed MPFR include files])])
1536 AC_ARG_WITH(mpfr-lib,
1537 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1538                 [specify directory for the installed MPFR library])])
1539
1540 if test "x$with_mpfr" != x; then
1541   gmplibs="-L$with_mpfr/lib $gmplibs"
1542   gmpinc="-I$with_mpfr/include $gmpinc"
1543 fi
1544 if test "x$with_mpfr_include" != x; then
1545   gmpinc="-I$with_mpfr_include $gmpinc"
1546 fi
1547 if test "x$with_mpfr_lib" != x; then
1548   gmplibs="-L$with_mpfr_lib $gmplibs"
1549 fi
1550 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1551   # MPFR v3.1.0 moved the sources into a src sub-directory.
1552   if ! test -d ${srcdir}/mpfr/src; then
1553     AC_MSG_ERROR([dnl
1554 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1555   fi
1556   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1557   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1558   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1559   # Do not test the mpfr version.  Assume that it is sufficient, since
1560   # it is in the source tree, and the library has not been built yet
1561   # but it would be included on the link line in the version check below
1562   # hence making the test fail.
1563   have_gmp=yes
1564 fi
1565
1566 # Specify a location for gmp
1567 AC_ARG_WITH(gmp-dir,
1568 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1569 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1570 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1571
1572 AC_ARG_WITH(gmp,
1573 [AS_HELP_STRING([--with-gmp=PATH],
1574                 [specify prefix directory for the installed GMP package.
1575                  Equivalent to --with-gmp-include=PATH/include
1576                  plus --with-gmp-lib=PATH/lib])])
1577 AC_ARG_WITH(gmp-include,
1578 [AS_HELP_STRING([--with-gmp-include=PATH],
1579                 [specify directory for installed GMP include files])])
1580 AC_ARG_WITH(gmp-lib,
1581 [AS_HELP_STRING([--with-gmp-lib=PATH],
1582                 [specify directory for the installed GMP library])])
1583
1584
1585 if test "x$with_gmp" != x; then
1586   gmplibs="-L$with_gmp/lib $gmplibs"
1587   gmpinc="-I$with_gmp/include $gmpinc"
1588 fi
1589 if test "x$with_gmp_include" != x; then
1590   gmpinc="-I$with_gmp_include $gmpinc"
1591 fi
1592 if test "x$with_gmp_lib" != x; then
1593   gmplibs="-L$with_gmp_lib $gmplibs"
1594 fi
1595 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1596   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1597   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1598   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1599   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1600   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1601   # Do not test the gmp version.  Assume that it is sufficient, since
1602   # it is in the source tree, and the library has not been built yet
1603   # but it would be included on the link line in the version check below
1604   # hence making the test fail.
1605   have_gmp=yes
1606 fi
1607
1608 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1609   have_gmp=yes
1610   saved_CFLAGS="$CFLAGS"
1611   CFLAGS="$CFLAGS $gmpinc"
1612   # Check for the recommended and required versions of GMP.
1613   AC_MSG_CHECKING([for the correct version of gmp.h])
1614   AC_TRY_COMPILE([#include "gmp.h"],[
1615   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1616   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1617   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1618   choke me
1619   #endif
1620   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1621   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1622   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1623   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1624   choke me
1625   #endif
1626   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1627    [AC_MSG_RESULT([no]); have_gmp=no])
1628
1629   # If we have GMP, check the MPFR version.
1630   if test x"$have_gmp" = xyes; then
1631     # Check for the recommended and required versions of MPFR.
1632     AC_MSG_CHECKING([for the correct version of mpfr.h])
1633     AC_TRY_COMPILE([#include <gmp.h>
1634     #include <mpfr.h>],[
1635     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1636     choke me
1637     #endif
1638     ], [AC_TRY_COMPILE([#include <gmp.h>
1639     #include <mpfr.h>],[
1640     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1641     choke me
1642     #endif
1643     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1644      [AC_MSG_RESULT([no]); have_gmp=no])
1645   fi
1646
1647   # Check for the MPC header version.
1648   if test x"$have_gmp" = xyes ; then
1649     # Check for the recommended and required versions of MPC.
1650     AC_MSG_CHECKING([for the correct version of mpc.h])
1651     AC_TRY_COMPILE([#include <mpc.h>],[
1652     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1653     choke me
1654     #endif
1655     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1656     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1657     choke me
1658     #endif
1659     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1660      [AC_MSG_RESULT([no]); have_gmp=no])
1661   fi
1662
1663   # Now check the MPFR library.
1664   if test x"$have_gmp" = xyes; then
1665     saved_LIBS="$LIBS"
1666     LIBS="$LIBS $gmplibs"
1667     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1668     AC_TRY_LINK([#include <mpc.h>],[
1669     mpfr_t n;
1670     mpfr_t x;
1671     mpc_t c;
1672     int t;
1673     mpfr_init (n);
1674     mpfr_init (x);
1675     mpfr_atan2 (n, n, x, MPFR_RNDN);
1676     mpfr_erfc (n, x, MPFR_RNDN);
1677     mpfr_subnormalize (x, t, MPFR_RNDN);
1678     mpfr_clear(n);
1679     mpfr_clear(x);
1680     mpc_init2 (c, 53);
1681     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1682     mpc_cosh (c, c, MPC_RNDNN);
1683     mpc_pow (c, c, c, MPC_RNDNN);
1684     mpc_acosh (c, c, MPC_RNDNN);
1685     mpc_clear (c);
1686     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1687     LIBS="$saved_LIBS"
1688   fi
1689
1690   CFLAGS="$saved_CFLAGS"
1691
1692 # The library versions listed in the error message below should match
1693 # the HARD-minimums enforced above.
1694   if test x$have_gmp != xyes; then
1695     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1696 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1697 their locations.  Source code for these libraries can be found at
1698 their respective hosting sites as well as at
1699 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1700 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1701 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1702 make sure that you have installed both the libraries and the header
1703 files.  They may be located in separate packages.])
1704   fi
1705 fi
1706
1707 # Flags needed for both GMP, MPFR and/or MPC.
1708 AC_SUBST(gmplibs)
1709 AC_SUBST(gmpinc)
1710 AC_SUBST(extra_mpfr_configure_flags)
1711 AC_SUBST(extra_mpc_gmp_configure_flags)
1712 AC_SUBST(extra_mpc_mpfr_configure_flags)
1713 AC_SUBST(extra_isl_gmp_configure_flags)
1714
1715 # Libraries to use for stage1 or when not bootstrapping.
1716 AC_ARG_WITH(stage1-libs,
1717 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1718 [if test "$withval" = "no" -o "$withval" = "yes"; then
1719    stage1_libs=
1720  else
1721    stage1_libs=$withval
1722  fi],
1723 [stage1_libs=])
1724 AC_SUBST(stage1_libs)
1725
1726 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1727 # default is yes if gcc is being built; no otherwise.  The reason for
1728 # this default is that gdb is sometimes linked against GNU Source
1729 # Highlight, which is a shared library that uses C++ exceptions.  In
1730 # this case, -static-libstdc++ will cause crashes.
1731 AC_ARG_WITH(static-standard-libraries,
1732 [AS_HELP_STRING([--with-static-standard-libraries],
1733                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1734 [], [with_static_standard_libraries=auto])
1735 if test "$with_static_standard_libraries" = auto; then
1736   with_static_standard_libraries=$have_compiler
1737 fi
1738
1739 # Linker flags to use for stage1 or when not bootstrapping.
1740 AC_ARG_WITH(stage1-ldflags,
1741 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1742 [if test "$withval" = "no" -o "$withval" = "yes"; then
1743    stage1_ldflags=
1744  else
1745    stage1_ldflags=$withval
1746  fi],
1747 [stage1_ldflags=
1748  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1749  # if supported.  But if the user explicitly specified the libraries to use,
1750  # trust that they are doing what they want.
1751  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1752      -a "$have_static_libs" = yes; then
1753    stage1_ldflags="-static-libstdc++ -static-libgcc"
1754  fi])
1755 AC_SUBST(stage1_ldflags)
1756
1757 # Libraries to use for stage2 and later builds.
1758 AC_ARG_WITH(boot-libs,
1759 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1760 [if test "$withval" = "no" -o "$withval" = "yes"; then
1761    poststage1_libs=
1762  else
1763    poststage1_libs=$withval
1764  fi],
1765 [poststage1_libs=])
1766 AC_SUBST(poststage1_libs)
1767
1768 # Linker flags to use for stage2 and later builds.
1769 AC_ARG_WITH(boot-ldflags,
1770 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1771                 [linker flags for stage2 and later])],
1772 [if test "$withval" = "no" -o "$withval" = "yes"; then
1773    poststage1_ldflags=
1774  else
1775    poststage1_ldflags=$withval
1776  fi],
1777 [poststage1_ldflags=
1778  # In stages 2 and 3, default to linking libstdc++ and libgcc
1779  # statically.  But if the user explicitly specified the libraries to
1780  # use, trust that they are doing what they want.
1781  if test "$poststage1_libs" = ""; then
1782    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1783  fi])
1784 AC_SUBST(poststage1_ldflags)
1785
1786 # GCC GRAPHITE dependency isl.
1787 # Basic setup is inlined here, actual checks are in config/isl.m4
1788
1789 AC_ARG_WITH(isl,
1790   [AS_HELP_STRING(
1791    [--with-isl=PATH],
1792    [Specify prefix directory for the installed isl package.
1793     Equivalent to --with-isl-include=PATH/include
1794     plus --with-isl-lib=PATH/lib])])
1795
1796 # Treat --without-isl as a request to disable
1797 # GRAPHITE support and skip all following checks.
1798 if test "x$with_isl" != "xno"; then
1799   # Check for isl
1800   dnl Provide configure switches and initialize islinc & isllibs
1801   dnl with user input.
1802   ISL_INIT_FLAGS
1803   dnl The versions of isl that work for Graphite
1804   ISL_CHECK_VERSION()
1805   dnl Only execute fail-action, if isl has been requested.
1806   ISL_IF_FAILED([
1807     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1808 fi
1809
1810 # If the isl check failed, disable builds of in-tree variant of isl
1811 if test "x$with_isl" = xno ||
1812    test "x$gcc_cv_isl" = xno; then
1813   noconfigdirs="$noconfigdirs isl"
1814   islinc=
1815 fi
1816
1817 AC_SUBST(isllibs)
1818 AC_SUBST(islinc)
1819
1820 # Check for LTO support.
1821 AC_ARG_ENABLE(lto,
1822 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1823 enable_lto=$enableval,
1824 enable_lto=yes; default_enable_lto=yes)
1825
1826 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1827   build_lto_plugin=yes
1828 ],[if test x"$default_enable_lto" = x"yes" ; then
1829     case $target in
1830       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1831       # On other non-ELF platforms, LTO has yet to be validated.
1832       *) enable_lto=no ;;
1833     esac
1834   else
1835   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1836   # It would also be nice to check the binutils support, but we don't
1837   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1838   # warn during gcc/ subconfigure; unless you're bootstrapping with
1839   # -flto it won't be needed until after installation anyway.
1840     case $target in
1841       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1842       *) if test x"$enable_lto" = x"yes"; then
1843         AC_MSG_ERROR([LTO support is not enabled for this target.])
1844         fi
1845       ;;
1846     esac
1847   fi
1848   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1849   # Build it unless LTO was explicitly disabled.
1850   case $target in
1851     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1852     *) ;;
1853   esac
1854 ])
1855
1856 AC_ARG_ENABLE(linker-plugin-configure-flags,
1857   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1858     [additional flags for configuring linker plugins @<:@none@:>@])],
1859   extra_linker_plugin_configure_flags=$enableval,
1860   extra_linker_plugin_configure_flags=)
1861 AC_SUBST(extra_linker_plugin_configure_flags)
1862 AC_ARG_ENABLE(linker-plugin-flags,
1863   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1864     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1865   extra_linker_plugin_flags=$enableval,
1866   extra_linker_plugin_flags=)
1867 AC_SUBST(extra_linker_plugin_flags)
1868
1869 # Enable --enable-host-shared.
1870 # Checked early to determine whether jit is an 'all' language
1871 AC_ARG_ENABLE(host-shared,
1872 [AS_HELP_STRING([--enable-host-shared],
1873                 [build host code as shared libraries])],
1874 [host_shared=$enableval], [host_shared=no])
1875 AC_SUBST(host_shared)
1876
1877 # By default, C and C++ are the only stage 1 languages.
1878 stage1_languages=,c,
1879
1880 # Target libraries that we bootstrap.
1881 bootstrap_target_libs=,target-libgcc,
1882
1883 # Figure out what language subdirectories are present.
1884 # Look if the user specified --enable-languages="..."; if not, use
1885 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1886 # go away some day.
1887 # NB:  embedded tabs in this IF block -- do not untabify
1888 if test -d ${srcdir}/gcc; then
1889   if test x"${enable_languages+set}" != xset; then
1890     if test x"${LANGUAGES+set}" = xset; then
1891       enable_languages="${LANGUAGES}"
1892         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1893     else
1894       enable_languages=default
1895     fi
1896   else
1897     if test x"${enable_languages}" = x ||
1898        test x"${enable_languages}" = xyes;
1899        then
1900       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1901       exit 1
1902     fi
1903   fi
1904   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1905
1906   # 'f95' is the old name for the 'fortran' language. We issue a warning
1907   # and make the substitution.
1908   case ,${enable_languages}, in
1909     *,f95,*)
1910       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1911       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1912       ;;
1913   esac
1914
1915   # If bootstrapping, C++ must be enabled.
1916   case ",$enable_languages,:$enable_bootstrap" in
1917     *,c++,*:*) ;;
1918     *:yes)
1919       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1920         enable_languages="${enable_languages},c++"
1921       else
1922         AC_MSG_ERROR([bootstrapping requires c++ sources])
1923       fi
1924       ;;
1925   esac
1926
1927   # First scan to see if an enabled language requires some other language.
1928   # We assume that a given config-lang.in will list all the language
1929   # front ends it requires, even if some are required indirectly.
1930   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1931     case ${lang_frag} in
1932       ..) ;;
1933       # The odd quoting in the next line works around
1934       # an apparent bug in bash 1.12 on linux.
1935       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1936       *)
1937         # From the config-lang.in, get $language, $lang_requires, and
1938         # $lang_requires_boot_languages.
1939         language=
1940         lang_requires=
1941         lang_requires_boot_languages=
1942         # set srcdir during sourcing lang_frag to the gcc dir.
1943         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1944         # polutes this shell
1945         saved_srcdir=${srcdir}
1946         srcdir=${srcdir}/gcc . ${lang_frag}
1947         srcdir=${saved_srcdir}
1948         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1949           case ,${enable_languages}, in
1950             *,$other,*) ;;
1951             *,default,*) ;;
1952             *,all,*) ;;
1953             *,$language,*)
1954               echo " \`$other' language required by \`$language'; enabling" 1>&2
1955               enable_languages="${enable_languages},${other}"
1956               ;;
1957           esac
1958         done
1959         for other in ${lang_requires_boot_languages} ; do
1960           if test "$other" != "c"; then
1961             case ,${enable_stage1_languages}, in
1962               *,$other,*) ;;
1963               *,default,*) ;;
1964               *,all,*) ;;
1965               *)
1966                 case ,${enable_languages}, in
1967                   *,$language,*)
1968                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1969                     enable_stage1_languages="$enable_stage1_languages,${other}"
1970                     ;;
1971                 esac
1972                 ;;
1973             esac
1974           fi
1975         done
1976         ;;
1977     esac
1978   done
1979
1980   new_enable_languages=,c,
1981
1982   # If LTO is enabled, add the LTO front end.
1983   if test "$enable_lto" = "yes" ; then
1984     case ,${enable_languages}, in
1985       *,lto,*) ;;
1986       *) enable_languages="${enable_languages},lto" ;;
1987     esac
1988     if test "${build_lto_plugin}" = "yes" ; then
1989       configdirs="$configdirs lto-plugin"
1990     fi
1991   fi
1992
1993   # If we're building an offloading compiler, add the LTO front end.
1994   if test x"$enable_as_accelerator_for" != x ; then
1995     case ,${enable_languages}, in
1996       *,lto,*) ;;
1997       *) enable_languages="${enable_languages},lto" ;;
1998     esac
1999   fi
2000
2001   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2002   potential_languages=,c,
2003
2004   enabled_target_libs=
2005   disabled_target_libs=
2006
2007   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2008     case ${lang_frag} in
2009       ..) ;;
2010       # The odd quoting in the next line works around
2011       # an apparent bug in bash 1.12 on linux.
2012       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2013       *)
2014         # From the config-lang.in, get $language, $target_libs,
2015         # $lang_dirs, $boot_language, and $build_by_default
2016         language=
2017         target_libs=
2018         lang_dirs=
2019         subdir_requires=
2020         boot_language=no
2021         build_by_default=yes
2022         # set srcdir during sourcing.  See above about save & restore
2023         saved_srcdir=${srcdir}
2024         srcdir=${srcdir}/gcc . ${lang_frag}
2025         srcdir=${saved_srcdir}
2026         if test x${language} = x; then
2027           echo "${lang_frag} doesn't set \$language." 1>&2
2028           exit 1
2029         fi
2030
2031         if test "$language" = "c++"; then
2032           boot_language=yes
2033         fi
2034
2035         add_this_lang=no
2036         # C is always enabled, so no need to add it again
2037         if test "$language" != "c"; then
2038           case ,${enable_languages}, in
2039             *,${language},*)
2040               # Language was explicitly selected; include it
2041               add_this_lang=yes
2042               ;;
2043             *,all,*)
2044               # All languages are enabled
2045               add_this_lang=all
2046               ;;
2047             *,default,*)
2048               # 'default' was selected, select it if it is a default language
2049               add_this_lang=${build_by_default}
2050               ;;
2051           esac
2052         fi
2053
2054         # Disable languages that need other directories if these aren't available.
2055         for i in $subdir_requires; do
2056           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2057           case ${add_this_lang} in
2058             yes)
2059               # Specifically requested language; tell them.
2060               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2061               ;;
2062             all)
2063               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2064               add_this_lang=unsupported
2065               ;;
2066             *)
2067               # Silently disable.
2068               add_this_lang=unsupported
2069               ;;
2070           esac
2071         done
2072
2073         # Disable Ada if no preexisting GNAT is available.
2074         case ${add_this_lang}:${language}:${have_gnat} in
2075           yes:ada:no)
2076             # Specifically requested language; tell them.
2077             AC_MSG_ERROR([GNAT is required to build $language])
2078             ;;
2079           all:ada:no)
2080             AC_MSG_WARN([GNAT is required to build $language])
2081             add_this_lang=unsupported
2082             ;;
2083           *:ada:no)
2084             # Silently disable.
2085             add_this_lang=unsupported
2086             ;;
2087         esac
2088
2089         # Disable jit if -enable-host-shared not specified
2090         # but not if building for Mingw. All code in Windows
2091         # is position independent code (PIC).
2092         case $target in
2093           *mingw*) ;;
2094           *)
2095           case ${add_this_lang}:${language}:${host_shared} in
2096             yes:jit:no)
2097                    # PR jit/64780: explicitly specify --enable-host-shared
2098             AC_MSG_ERROR([
2099 Enabling language "jit" requires --enable-host-shared.
2100
2101 --enable-host-shared typically slows the rest of the compiler down by
2102 a few %, so you must explicitly enable it.
2103
2104 If you want to build both the jit and the regular compiler, it is often
2105 best to do this via two separate configure/builds, in separate
2106 directories, to avoid imposing the performance cost of
2107 --enable-host-shared on the regular compiler.])
2108                     ;;
2109             all:jit:no)
2110               AC_MSG_WARN([--enable-host-shared required to build $language])
2111               add_this_lang=unsupported
2112               ;;
2113             *:jit:no)
2114               # Silently disable.
2115               add_this_lang=unsupported
2116               ;;
2117                 esac
2118           ;;
2119         esac
2120
2121         # Disable a language that is unsupported by the target.
2122         case "${add_this_lang}: $unsupported_languages " in
2123           no:*) ;;
2124           unsupported:*) ;;
2125           *:*" $language "*)
2126             AC_MSG_WARN([${language} not supported for this target])
2127             add_this_lang=unsupported
2128             ;;
2129         esac
2130
2131         case $add_this_lang in
2132           unsupported)
2133             # Remove language-dependent dirs.
2134             disabled_target_libs="$disabled_target_libs $target_libs"
2135             noconfigdirs="$noconfigdirs $lang_dirs"
2136             ;;
2137           no)
2138             # Remove language-dependent dirs; still show language as supported.
2139             disabled_target_libs="$disabled_target_libs $target_libs"
2140             noconfigdirs="$noconfigdirs $lang_dirs"
2141             potential_languages="${potential_languages}${language},"
2142             ;;
2143           all|yes)
2144             new_enable_languages="${new_enable_languages}${language},"
2145             potential_languages="${potential_languages}${language},"
2146             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2147             enabled_target_libs="$enabled_target_libs $target_libs"
2148             case "${boot_language}:,$enable_stage1_languages," in
2149               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2150                 # Add to (comma-separated) list of stage 1 languages.
2151                 case ",$stage1_languages," in
2152                   *,$language,* | ,yes, | ,all,) ;;
2153                   *) stage1_languages="${stage1_languages}${language}," ;;
2154                 esac
2155                 # We need to bootstrap any supporting libraries.
2156                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2157                 ;;
2158             esac
2159             ;;
2160         esac
2161         ;;
2162     esac
2163   done
2164
2165   # Add target libraries which are only needed for disabled languages
2166   # to noconfigdirs.
2167   if test -n "$disabled_target_libs"; then
2168     for dir in $disabled_target_libs; do
2169       case " $enabled_target_libs " in
2170       *" ${dir} "*) ;;
2171       *) noconfigdirs="$noconfigdirs $dir" ;;
2172       esac
2173     done
2174   fi
2175
2176   AC_ARG_ENABLE(stage1-languages,
2177   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2178                   [choose additional languages to build during
2179                   stage1.  Mostly useful for compiler development])],
2180   [case ,${enable_stage1_languages}, in
2181     ,no,|,,)
2182       # Set it to something that will have no effect in the loop below
2183       enable_stage1_languages=c ;;
2184     ,yes,)
2185       enable_stage1_languages=`echo $new_enable_languages | \
2186         sed -e "s/^,//" -e "s/,$//" ` ;;
2187     *,all,*)
2188       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2189         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2190   esac
2191
2192   # Add "good" languages from enable_stage1_languages to stage1_languages,
2193   # while "bad" languages go in missing_languages.  Leave no duplicates.
2194   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2195     case $potential_languages in
2196       *,$i,*)
2197         case $stage1_languages in
2198           *,$i,*) ;;
2199           *) stage1_languages="$stage1_languages$i," ;;
2200         esac ;;
2201       *)
2202         case $missing_languages in
2203           *,$i,*) ;;
2204           *) missing_languages="$missing_languages$i," ;;
2205         esac ;;
2206      esac
2207   done])
2208
2209   # Remove leading/trailing commas that were added for simplicity
2210   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2211   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2212   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2213   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2214
2215   if test "x$missing_languages" != x; then
2216     AC_MSG_ERROR([
2217 The following requested languages could not be built: ${missing_languages}
2218 Supported languages are: ${potential_languages}])
2219   fi
2220   if test "x$new_enable_languages" != "x$enable_languages"; then
2221     echo The following languages will be built: ${new_enable_languages}
2222     enable_languages="$new_enable_languages"
2223   fi
2224
2225   AC_SUBST(stage1_languages)
2226   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2227 fi
2228
2229 # Handle --disable-<component> generically.
2230 for dir in $configdirs $build_configdirs $target_configdirs ; do
2231   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2232   varname=`echo $dirname | sed -e s/+/_/g`
2233   if eval test x\${enable_${varname}} "=" xno ; then
2234     noconfigdirs="$noconfigdirs $dir"
2235   fi
2236 done
2237
2238 # Check for Boehm's garbage collector
2239 AC_ARG_ENABLE(objc-gc,
2240 [AS_HELP_STRING([--enable-objc-gc],
2241                 [enable use of Boehm's garbage collector with the
2242                  GNU Objective-C runtime])])
2243 AC_ARG_WITH([target-bdw-gc],
2244 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2245                 [specify prefix directory for installed bdw-gc package.
2246                  Equivalent to --with-target-bdw-gc-include=PATH/include
2247                  plus --with-target-bdw-gc-lib=PATH/lib])])
2248 AC_ARG_WITH([target-bdw-gc-include],
2249 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2250                 [specify directories for installed bdw-gc include files])])
2251 AC_ARG_WITH([target-bdw-gc-lib],
2252 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2253                 [specify directories for installed bdw-gc library])])
2254
2255 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2256   AC_MSG_CHECKING([for bdw garbage collector])
2257   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2258     dnl no bdw-gw options, assume default locations
2259     AC_MSG_RESULT([using bdw-gc in default locations])
2260   else
2261     dnl bdw-gw options, first error checking, complete checking in libobjc
2262     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2263       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2264     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2265       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2266     else
2267       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2268     fi
2269   fi
2270 esac
2271
2272 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2273 case ,${enable_languages}, in
2274   *,c++,*)
2275     # Disable libitm, libsanitizer if we're not building libstdc++
2276     case "${noconfigdirs}" in
2277       *target-libstdc++-v3*)
2278         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2279         ;;
2280       *) ;;
2281     esac
2282     ;;
2283   *)
2284     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2285     ;;
2286 esac
2287
2288 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2289 # $build_configdirs and $target_configdirs.
2290 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2291
2292 notsupp=""
2293 for dir in . $skipdirs $noconfigdirs ; do
2294   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2295   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2296     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2297     if test -r $srcdir/$dirname/configure ; then
2298       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2299         true
2300       else
2301         notsupp="$notsupp $dir"
2302       fi
2303     fi
2304   fi
2305   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2306     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2307     if test -r $srcdir/$dirname/configure ; then
2308       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2309         true
2310       else
2311         notsupp="$notsupp $dir"
2312       fi
2313     fi
2314   fi
2315   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2316     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2317     if test -r $srcdir/$dirname/configure ; then
2318       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2319         true
2320       else
2321         notsupp="$notsupp $dir"
2322       fi
2323     fi
2324   fi
2325 done
2326
2327 # Quietly strip out all directories which aren't configurable in this tree.
2328 # This relies on all configurable subdirectories being autoconfiscated, which
2329 # is now the case.
2330 build_configdirs_all="$build_configdirs"
2331 build_configdirs=
2332 for i in ${build_configdirs_all} ; do
2333   j=`echo $i | sed -e s/build-//g`
2334   if test -f ${srcdir}/$j/configure ; then
2335     build_configdirs="${build_configdirs} $i"
2336   fi
2337 done
2338
2339 configdirs_all="$configdirs"
2340 configdirs=
2341 for i in ${configdirs_all} ; do
2342   if test -f ${srcdir}/$i/configure ; then
2343     configdirs="${configdirs} $i"
2344   fi
2345 done
2346
2347 target_configdirs_all="$target_configdirs"
2348 target_configdirs=
2349 for i in ${target_configdirs_all} ; do
2350   j=`echo $i | sed -e s/target-//g`
2351   if test -f ${srcdir}/$j/configure ; then
2352     target_configdirs="${target_configdirs} $i"
2353   fi
2354 done
2355
2356 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2357 # so we have to add it after the preceding checks.
2358 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2359 then
2360   case " $configdirs " in
2361     *" libiberty "*)
2362       # If we can build libiberty, we can also build libiberty-linker-plugin.
2363       configdirs="$configdirs libiberty-linker-plugin"
2364       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2365         --with-libiberty=../libiberty-linker-plugin";;
2366     *)
2367       AC_MSG_ERROR([libiberty missing]);;
2368   esac
2369 fi
2370
2371 # Sometimes we have special requirements for the host libiberty.
2372 extra_host_libiberty_configure_flags=
2373 extra_host_zlib_configure_flags=
2374 case " $configdirs " in
2375   *" lto-plugin "* | *" libcc1 "*)
2376     # When these are to be built as shared libraries, the same applies to
2377     # libiberty.
2378     extra_host_libiberty_configure_flags=--enable-shared
2379     ;;
2380   *" bfd "*)
2381     # When bfd is to be built as a shared library, the same applies to
2382     # zlib.
2383     if test "$enable_shared" = "yes"; then
2384       extra_host_zlib_configure_flags=--enable-host-shared
2385     fi
2386     ;;
2387 esac
2388 AC_SUBST(extra_host_libiberty_configure_flags)
2389 AC_SUBST(extra_host_zlib_configure_flags)
2390
2391 # Produce a warning message for the subdirs we can't configure.
2392 # This isn't especially interesting in the Cygnus tree, but in the individual
2393 # FSF releases, it's important to let people know when their machine isn't
2394 # supported by the one or two programs in a package.
2395
2396 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2397   # If $appdirs is non-empty, at least one of those directories must still
2398   # be configured, or we error out.  (E.g., if the gas release supports a
2399   # specified target in some subdirs but not the gas subdir, we shouldn't
2400   # pretend that all is well.)
2401   if test -n "$appdirs" ; then
2402     for dir in $appdirs ; do
2403       if test -r $dir/Makefile.in ; then
2404         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2405           appdirs=""
2406           break
2407         fi
2408         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2409           appdirs=""
2410           break
2411         fi
2412       fi
2413     done
2414     if test -n "$appdirs" ; then
2415       echo "*** This configuration is not supported by this package." 1>&2
2416       exit 1
2417     fi
2418   fi
2419   # Okay, some application will build, or we don't care to check.  Still
2420   # notify of subdirs not getting built.
2421   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2422   echo "    ${notsupp}" 1>&2
2423   echo "    (Any other directories should still work fine.)" 1>&2
2424 fi
2425
2426 case "$host" in
2427   *msdosdjgpp*)
2428     enable_gdbtk=no ;;
2429 esac
2430
2431 # To find our prefix, in gcc_cv_tool_prefix.
2432 ACX_TOOL_DIRS
2433
2434 copy_dirs=
2435
2436 AC_ARG_WITH([build-sysroot],
2437   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2438                   [use sysroot as the system root during the build])],
2439   [if test x"$withval" != x ; then
2440      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2441    fi],
2442   [SYSROOT_CFLAGS_FOR_TARGET=])
2443 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2444
2445 AC_ARG_WITH([debug-prefix-map],
2446   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2447                   [map A to B, C to D ... in debug information])],
2448   [if test x"$withval" != x; then
2449      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2450      for debug_map in $withval; do
2451        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2452      done
2453    fi],
2454   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2455 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2456
2457 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2458 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2459 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2460 # We want to ensure that TARGET libraries (which we know are built with
2461 # gcc) are built with "-O2 -g", so include those options when setting
2462 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2463 if test "x$CFLAGS_FOR_TARGET" = x; then
2464   if test "x${is_cross_compiler}" = xyes; then
2465     CFLAGS_FOR_TARGET="-g -O2"
2466   else
2467     CFLAGS_FOR_TARGET=$CFLAGS
2468     case " $CFLAGS " in
2469       *" -O2 "*) ;;
2470       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2471     esac
2472     case " $CFLAGS " in
2473       *" -g "* | *" -g3 "*) ;;
2474       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2475     esac
2476   fi
2477 fi
2478 AC_SUBST(CFLAGS_FOR_TARGET)
2479
2480 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2481   if test "x${is_cross_compiler}" = xyes; then
2482     CXXFLAGS_FOR_TARGET="-g -O2"
2483   else
2484     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2485     case " $CXXFLAGS " in
2486       *" -O2 "*) ;;
2487       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2488     esac
2489     case " $CXXFLAGS " in
2490       *" -g "* | *" -g3 "*) ;;
2491       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2492     esac
2493   fi
2494 fi
2495 AC_SUBST(CXXFLAGS_FOR_TARGET)
2496
2497 AC_SUBST(LDFLAGS_FOR_TARGET)
2498
2499 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2500 # the named directory are copied to $(tooldir)/sys-include.
2501 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2502   if test x${is_cross_compiler} = xno ; then
2503     echo 1>&2 '***' --with-headers is only supported when cross compiling
2504     exit 1
2505   fi
2506   if test x"${with_headers}" != xyes ; then
2507     x=${gcc_cv_tool_prefix}
2508     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2509   fi
2510 fi
2511
2512 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2513 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2514 # are permitted.
2515 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2516   if test x${is_cross_compiler} = xno ; then
2517     echo 1>&2 '***' --with-libs is only supported when cross compiling
2518     exit 1
2519   fi
2520   if test x"${with_libs}" != xyes ; then
2521     # Copy the libraries in reverse order, so that files in the first named
2522     # library override files in subsequent libraries.
2523     x=${gcc_cv_tool_prefix}
2524     for l in ${with_libs}; do
2525       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2526     done
2527   fi
2528 fi
2529
2530 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2531 #
2532 # This is done by determining whether or not the appropriate directory
2533 # is available, and by checking whether or not specific configurations
2534 # have requested that this magic not happen.
2535 #
2536 # The command line options always override the explicit settings in
2537 # configure.ac, and the settings in configure.ac override this magic.
2538 #
2539 # If the default for a toolchain is to use GNU as and ld, and you don't
2540 # want to do that, then you should use the --without-gnu-as and
2541 # --without-gnu-ld options for the configure script.  Similarly, if
2542 # the default is to use the included zlib and you don't want to do that,
2543 # you should use the --with-system-zlib option for the configure script.
2544
2545 if test x${use_gnu_as} = x &&
2546    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2547   with_gnu_as=yes
2548   extra_host_args="$extra_host_args --with-gnu-as"
2549 fi
2550
2551 if test x${use_gnu_ld} = x &&
2552    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2553   with_gnu_ld=yes
2554   extra_host_args="$extra_host_args --with-gnu-ld"
2555 fi
2556
2557 if test x${use_included_zlib} = x &&
2558    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2559   :
2560 else
2561   with_system_zlib=yes
2562   extra_host_args="$extra_host_args --with-system-zlib"
2563 fi
2564
2565 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2566 # can detect this case.
2567
2568 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2569   with_newlib=yes
2570   extra_host_args="$extra_host_args --with-newlib"
2571 fi
2572
2573 # Handle ${copy_dirs}
2574 set fnord ${copy_dirs}
2575 shift
2576 while test $# != 0 ; do
2577   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2578     :
2579   else
2580     echo Copying $1 to $2
2581
2582     # Use the install script to create the directory and all required
2583     # parent directories.
2584     if test -d $2 ; then
2585       :
2586     else
2587       echo >config.temp
2588       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2589     fi
2590
2591     # Copy the directory, assuming we have tar.
2592     # FIXME: Should we use B in the second tar?  Not all systems support it.
2593     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2594
2595     # It is the responsibility of the user to correctly adjust all
2596     # symlinks.  If somebody can figure out how to handle them correctly
2597     # here, feel free to add the code.
2598
2599     echo $1 > $2/COPIED
2600   fi
2601   shift; shift
2602 done
2603
2604 # Determine a target-dependent exec_prefix that the installed
2605 # gcc will search in.  Keep this list sorted by triplet, with
2606 # the *-*-osname triplets last.
2607 md_exec_prefix=
2608 case "${target}" in
2609   i[[34567]]86-pc-msdosdjgpp*)
2610     md_exec_prefix=/dev/env/DJDIR/bin
2611     ;;
2612   *-*-hpux* | \
2613   *-*-nto-qnx* | \
2614   *-*-solaris2*)
2615     md_exec_prefix=/usr/ccs/bin
2616     ;;
2617 esac
2618
2619 extra_arflags_for_target=
2620 extra_nmflags_for_target=
2621 extra_ranlibflags_for_target=
2622 target_makefile_frag=/dev/null
2623 case "${target}" in
2624   spu-*-*)
2625     target_makefile_frag="config/mt-spu"
2626     ;;
2627   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2628     target_makefile_frag="config/mt-sde"
2629     ;;
2630   mipsisa*-*-elfoabi*)
2631     target_makefile_frag="config/mt-mips-elfoabi"
2632     ;;
2633   mips*-*-*linux* | mips*-*-gnu*)
2634     target_makefile_frag="config/mt-mips-gnu"
2635     ;;
2636   nios2-*-elf*)
2637     target_makefile_frag="config/mt-nios2-elf"
2638     ;;
2639   *-*-linux-android*)
2640     target_makefile_frag="config/mt-android"
2641     ;;
2642   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2643     target_makefile_frag="config/mt-gnu"
2644     ;;
2645   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2646     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2647     # commands to handle both 32-bit and 64-bit objects.  These flags are
2648     # harmless if we're using GNU nm or ar.
2649     extra_arflags_for_target=" -X32_64"
2650     extra_nmflags_for_target=" -B -X32_64"
2651     ;;
2652 esac
2653
2654 alphaieee_frag=/dev/null
2655 case $target in
2656   alpha*-*-*)
2657     # This just makes sure to use the -mieee option to build target libs.
2658     # This should probably be set individually by each library.
2659     alphaieee_frag="config/mt-alphaieee"
2660     ;;
2661 esac
2662
2663 # If --enable-target-optspace always use -Os instead of -O2 to build
2664 # the target libraries, similarly if it is not specified, use -Os
2665 # on selected platforms.
2666 ospace_frag=/dev/null
2667 case "${enable_target_optspace}:${target}" in
2668   yes:*)
2669     ospace_frag="config/mt-ospace"
2670     ;;
2671   :d30v-*)
2672     ospace_frag="config/mt-d30v"
2673     ;;
2674   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2675     ospace_frag="config/mt-ospace"
2676     ;;
2677   no:* | :*)
2678     ;;
2679   *)
2680     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2681     ;;
2682 esac
2683
2684 # Some systems (e.g., one of the i386-aix systems the gas testers are
2685 # using) don't handle "\$" correctly, so don't use it here.
2686 tooldir='${exec_prefix}'/${target_noncanonical}
2687 build_tooldir=${tooldir}
2688
2689 # Create a .gdbinit file which runs the one in srcdir
2690 # and tells GDB to look there for source files.
2691
2692 if test -r ${srcdir}/.gdbinit ; then
2693   case ${srcdir} in
2694     .) ;;
2695     *) cat > ./.gdbinit <<EOF
2696 # ${NO_EDIT}
2697 dir ${srcdir}
2698 dir .
2699 source ${srcdir}/.gdbinit
2700 EOF
2701     ;;
2702   esac
2703 fi
2704
2705 # Make sure that the compiler is able to generate an executable.  If it
2706 # can't, we are probably in trouble.  We don't care whether we can run the
2707 # executable--we might be using a cross compiler--we only care whether it
2708 # can be created.  At this point the main configure script has set CC.
2709 we_are_ok=no
2710 echo "int main () { return 0; }" > conftest.c
2711 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2712 if test $? = 0 ; then
2713   if test -s conftest || test -s conftest.exe ; then
2714     we_are_ok=yes
2715   fi
2716 fi
2717 case $we_are_ok in
2718   no)
2719     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2720     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2721     rm -f conftest*
2722     exit 1
2723     ;;
2724 esac
2725 rm -f conftest*
2726
2727 # Decide which environment variable is used to find dynamic libraries.
2728 case "${host}" in
2729   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2730   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2731   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2732   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2733 esac
2734
2735 # On systems where the dynamic library environment variable is PATH,
2736 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2737 # built executables to PATH.
2738 if test "$RPATH_ENVVAR" = PATH; then
2739   GCC_SHLIB_SUBDIR=/shlib
2740 else
2741   GCC_SHLIB_SUBDIR=
2742 fi
2743
2744 # Adjust the toplevel makefile according to whether bootstrap was selected.
2745 case $enable_bootstrap in
2746   yes)
2747     bootstrap_suffix=bootstrap
2748     BUILD_CONFIG=bootstrap-debug
2749     ;;
2750   no)
2751     bootstrap_suffix=no-bootstrap
2752     BUILD_CONFIG=
2753     ;;
2754 esac
2755
2756 AC_MSG_CHECKING(for default BUILD_CONFIG)
2757
2758 AC_ARG_WITH([build-config],
2759   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2760                   [use config/NAME.mk build configuration])],
2761   [case $with_build_config in
2762    yes) with_build_config= ;;
2763    no) with_build_config= BUILD_CONFIG= ;;
2764    esac])
2765
2766 if test "x${with_build_config}" != x; then
2767   BUILD_CONFIG=$with_build_config
2768 else
2769   case $BUILD_CONFIG in
2770   bootstrap-debug)
2771     if echo "int f (void) { return 0; }" > conftest.c &&
2772        ${CC} -c conftest.c &&
2773        mv conftest.o conftest.o.g0 &&
2774        ${CC} -c -g conftest.c &&
2775        mv conftest.o conftest.o.g &&
2776        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2777       :
2778     else
2779       BUILD_CONFIG=
2780     fi
2781     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2782     ;;
2783   esac
2784 fi
2785 AC_MSG_RESULT($BUILD_CONFIG)
2786 AC_SUBST(BUILD_CONFIG)
2787
2788 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2789 AC_MSG_CHECKING([for --enable-vtable-verify])
2790 AC_ARG_ENABLE(vtable-verify,
2791 [AS_HELP_STRING([--enable-vtable-verify],
2792                 [Enable vtable verification feature])],
2793 [case "$enableval" in
2794  yes) enable_vtable_verify=yes ;;
2795  no)  enable_vtable_verify=no ;;
2796  *)   enable_vtable_verify=no;;
2797  esac],
2798 [enable_vtable_verify=no])
2799 AC_MSG_RESULT($enable_vtable_verify)
2800
2801 # Record target_configdirs and the configure arguments for target and
2802 # build configuration in Makefile.
2803 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2804 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2805 bootstrap_fixincludes=no
2806
2807 # If we are building libgomp, bootstrap it.
2808 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2809   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2810 fi
2811
2812 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2813 # or bootstrap-ubsan, bootstrap it.
2814 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2815   case "$BUILD_CONFIG" in
2816     *bootstrap-asan* | *bootstrap-ubsan* )
2817       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2818       bootstrap_fixincludes=yes
2819       ;;
2820   esac
2821 fi
2822
2823 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2824 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2825    test "$enable_vtable_verify" != no; then
2826   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2827 fi
2828
2829 # Determine whether gdb needs tk/tcl or not.
2830 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2831 # and in that case we want gdb to be built without tk.  Ugh!
2832 # In fact I believe gdb is the *only* package directly dependent on tk,
2833 # so we should be able to put the 'maybe's in unconditionally and
2834 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2835 # 100% sure that that's safe though.
2836
2837 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2838 case "$enable_gdbtk" in
2839   no)
2840     GDB_TK="" ;;
2841   yes)
2842     GDB_TK="${gdb_tk}" ;;
2843   *)
2844     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2845     # distro.  Eventually someone will fix this and move Insight, nee
2846     # gdbtk to a separate directory.
2847     if test -d ${srcdir}/gdb/gdbtk ; then
2848       GDB_TK="${gdb_tk}"
2849     else
2850       GDB_TK=""
2851     fi
2852     ;;
2853 esac
2854 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2855 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2856
2857 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2858 # else does, only include them if one of these is built.  The Makefile
2859 # provides the ordering, so it's enough here to add to the list.
2860 case " ${configdirs} " in
2861   *\ gdb\ *)
2862     configdirs="${configdirs} gnulib gdbsupport"
2863     ;;
2864   *\ gdbserver\ *)
2865     configdirs="${configdirs} gnulib gdbsupport"
2866     ;;
2867 esac
2868
2869 # Strip out unwanted targets.
2870
2871 # While at that, we remove Makefiles if we were started for recursive
2872 # configuration, so that the top-level Makefile reconfigures them,
2873 # like we used to do when configure itself was recursive.
2874
2875 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2876 # but now we're fixing up the Makefile ourselves with the additional
2877 # commands passed to AC_CONFIG_FILES.  Use separate variables
2878 # extrasub-{build,host,target} not because there is any reason to split
2879 # the substitutions up that way, but only to remain below the limit of
2880 # 99 commands in a script, for HP-UX sed.
2881
2882 # Do not nest @if/@endif or @unless/@endunless pairs, because
2883 # configure will not warn you at all.
2884
2885 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2886   yes:yes:*\ gold\ *:*,c++,*) ;;
2887   yes:yes:*\ gold\ *:*)
2888     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2889     ;;
2890 esac
2891
2892 extrasub_build=
2893 for module in ${build_configdirs} ; do
2894   if test -z "${no_recursion}" \
2895      && test -f ${build_subdir}/${module}/Makefile; then
2896     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2897     rm -f ${build_subdir}/${module}/Makefile
2898   fi
2899   extrasub_build="$extrasub_build
2900 /^@if build-$module\$/d
2901 /^@endif build-$module\$/d
2902 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2903 /^@if build-$module-$bootstrap_suffix\$/d
2904 /^@endif build-$module-$bootstrap_suffix\$/d
2905 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2906 done
2907 extrasub_host=
2908 for module in ${configdirs} ; do
2909   if test -z "${no_recursion}"; then
2910     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2911       if test -f ${file}; then
2912         echo 1>&2 "*** removing ${file} to force reconfigure"
2913         rm -f ${file}
2914       fi
2915     done
2916   fi
2917   case ${module},${bootstrap_fixincludes} in
2918     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2919     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2920   esac
2921   extrasub_host="$extrasub_host
2922 /^@if $module\$/d
2923 /^@endif $module\$/d
2924 /^@unless $module\$/,/^@endunless $module\$/d
2925 /^@if $module-$host_bootstrap_suffix\$/d
2926 /^@endif $module-$host_bootstrap_suffix\$/d
2927 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2928 done
2929 extrasub_target=
2930 for module in ${target_configdirs} ; do
2931   if test -z "${no_recursion}" \
2932      && test -f ${target_subdir}/${module}/Makefile; then
2933     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2934     rm -f ${target_subdir}/${module}/Makefile
2935   fi
2936
2937   # We only bootstrap target libraries listed in bootstrap_target_libs.
2938   case $bootstrap_target_libs in
2939     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2940     *) target_bootstrap_suffix=no-bootstrap ;;
2941   esac
2942
2943   extrasub_target="$extrasub_target
2944 /^@if target-$module\$/d
2945 /^@endif target-$module\$/d
2946 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2947 /^@if target-$module-$target_bootstrap_suffix\$/d
2948 /^@endif target-$module-$target_bootstrap_suffix\$/d
2949 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2950 done
2951
2952 # Do the final fixup along with target modules.
2953 extrasub_target="$extrasub_target
2954 /^@if /,/^@endif /d
2955 /^@unless /d
2956 /^@endunless /d"
2957
2958 # Create the serialization dependencies.  This uses a temporary file.
2959
2960 AC_ARG_ENABLE([serial-configure],
2961 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2962                 [force sequential configuration of
2963                  sub-packages for the host, target or build
2964                  machine, or all sub-packages])])
2965
2966 case ${enable_serial_configure} in
2967   yes)
2968     enable_serial_build_configure=yes
2969     enable_serial_host_configure=yes
2970     enable_serial_target_configure=yes
2971     ;;
2972 esac
2973
2974 # These force 'configure's to be done one at a time, to avoid problems
2975 # with contention over a shared config.cache.
2976 rm -f serdep.tmp
2977 echo '# serdep.tmp' > serdep.tmp
2978 olditem=
2979 test "x${enable_serial_build_configure}" = xyes &&
2980 for item in ${build_configdirs} ; do
2981   case ${olditem} in
2982     "") ;;
2983     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2984   esac
2985   olditem=${item}
2986 done
2987 olditem=
2988 test "x${enable_serial_host_configure}" = xyes &&
2989 for item in ${configdirs} ; do
2990   case ${olditem} in
2991     "") ;;
2992     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2993   esac
2994   olditem=${item}
2995 done
2996 olditem=
2997 test "x${enable_serial_target_configure}" = xyes &&
2998 for item in ${target_configdirs} ; do
2999   case ${olditem} in
3000     "") ;;
3001     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3002   esac
3003   olditem=${item}
3004 done
3005 serialization_dependencies=serdep.tmp
3006 AC_SUBST_FILE(serialization_dependencies)
3007
3008 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3009 # target, nonopt, and variable assignments.  These are the ones we
3010 # might not want to pass down to subconfigures.  The exception being
3011 # --cache-file=/dev/null, which is used to turn off the use of cache
3012 # files altogether, and which should be passed on to subconfigures.
3013 # Also strip program-prefix, program-suffix, and program-transform-name,
3014 # so that we can pass down a consistent program-transform-name.
3015 baseargs=
3016 tbaseargs=
3017 keep_next=no
3018 skip_next=no
3019 eval "set -- $ac_configure_args"
3020 for ac_arg
3021 do
3022   if test X"$skip_next" = X"yes"; then
3023     skip_next=no
3024     continue
3025   fi
3026   if test X"$keep_next" = X"yes"; then
3027     case $ac_arg in
3028       *\'*)
3029         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3030     esac
3031     baseargs="$baseargs '$ac_arg'"
3032     tbaseargs="$tbaseargs '$ac_arg'"
3033     keep_next=no
3034     continue
3035   fi
3036
3037   # Handle separated arguments.  Based on the logic generated by
3038   # autoconf 2.59.
3039   case $ac_arg in
3040     *=* | --config-cache | -C | -disable-* | --disable-* \
3041       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3042       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3043       | -with-* | --with-* | -without-* | --without-* | --x)
3044       separate_arg=no
3045       ;;
3046     -*)
3047       separate_arg=yes
3048       ;;
3049     *)
3050       separate_arg=no
3051       ;;
3052   esac
3053
3054   skip_targ=no
3055   case $ac_arg in
3056 changequote(,)
3057   --with-* | --without-*)
3058     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3059
3060     case $libopt in
3061     *[-_]include)
3062       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3063       ;;
3064     *[-_]lib)
3065       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3066       ;;
3067     *)
3068       lib=$libopt
3069       ;;
3070     esac
3071 changequote([,])
3072
3073     case $lib in
3074     mpc | mpfr | gmp | isl)
3075       # If we're processing --with-$lib, --with-$lib-include or
3076       # --with-$lib-lib, for one of the libs above, and target is
3077       # different from host, don't pass the current argument to any
3078       # target library's configure.
3079       if test x$is_cross_compiler = xyes; then
3080         skip_targ=yes
3081       fi
3082       ;;
3083     esac
3084     ;;
3085   esac
3086
3087   case "$ac_arg" in
3088     --cache-file=/dev/null | \
3089     -cache-file=/dev/null )
3090       # Handled here to avoid the test to skip args below.
3091       baseargs="$baseargs '$ac_arg'"
3092       tbaseargs="$tbaseargs '$ac_arg'"
3093       # Assert: $separate_arg should always be no.
3094       keep_next=$separate_arg
3095       ;;
3096     --no*)
3097       continue
3098       ;;
3099     --c* | \
3100     --sr* | \
3101     --ho* | \
3102     --bu* | \
3103     --t* | \
3104     --program-* | \
3105     -cache_file* | \
3106     -srcdir* | \
3107     -host* | \
3108     -build* | \
3109     -target* | \
3110     -program-prefix* | \
3111     -program-suffix* | \
3112     -program-transform-name* )
3113       skip_next=$separate_arg
3114       continue
3115       ;;
3116     -*)
3117       # An option.  Add it.
3118       case $ac_arg in
3119         *\'*)
3120           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3121       esac
3122       baseargs="$baseargs '$ac_arg'"
3123       if test X"$skip_targ" = Xno; then
3124         tbaseargs="$tbaseargs '$ac_arg'"
3125       fi
3126       keep_next=$separate_arg
3127       ;;
3128     *)
3129       # Either a variable assignment, or a nonopt (triplet).  Don't
3130       # pass it down; let the Makefile handle this.
3131       continue
3132       ;;
3133   esac
3134 done
3135 # Remove the initial space we just introduced and, as these will be
3136 # expanded by make, quote '$'.
3137 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3138
3139 # Add in --program-transform-name, after --program-prefix and
3140 # --program-suffix have been applied to it.  Autoconf has already
3141 # doubled dollar signs and backslashes in program_transform_name; we want
3142 # the backslashes un-doubled, and then the entire thing wrapped in single
3143 # quotes, because this will be expanded first by make and then by the shell.
3144 # Also, because we want to override the logic in subdir configure scripts to
3145 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3146 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3147 ${program_transform_name}
3148 EOF_SED
3149 gcc_transform_name=`cat conftestsed.out`
3150 rm -f conftestsed.out
3151 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3152 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3153 if test "$silent" = yes; then
3154   baseargs="$baseargs --silent"
3155   tbaseargs="$tbaseargs --silent"
3156 fi
3157 baseargs="$baseargs --disable-option-checking"
3158 tbaseargs="$tbaseargs --disable-option-checking"
3159
3160 # Record and document user additions to sub configure arguments.
3161 AC_ARG_VAR([build_configargs],
3162            [additional configure arguments for build directories])
3163 AC_ARG_VAR([host_configargs],
3164            [additional configure arguments for host directories])
3165 AC_ARG_VAR([target_configargs],
3166            [additional configure arguments for target directories])
3167
3168 # For the build-side libraries, we just need to pretend we're native,
3169 # and not use the same cache file.  Multilibs are neither needed nor
3170 # desired.  We can't even use the same cache file for all build-side
3171 # libraries, as they're compiled differently; some with C, some with
3172 # C++ or with different feature-enabling options.
3173 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3174
3175 # For host modules, accept cache file option, or specification as blank.
3176 case "${cache_file}" in
3177 "") # empty
3178   cache_file_option="" ;;
3179 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3180   cache_file_option="--cache-file=${cache_file}" ;;
3181 *) # relative path
3182   cache_file_option="--cache-file=../${cache_file}" ;;
3183 esac
3184
3185 # Host dirs don't like to share a cache file either, horribly enough.
3186 # This seems to be due to autoconf 2.5x stupidity.
3187 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3188
3189 target_configargs="$target_configargs ${tbaseargs}"
3190
3191 # Passing a --with-cross-host argument lets the target libraries know
3192 # whether they are being built with a cross-compiler or being built
3193 # native.  However, it would be better to use other mechanisms to make the
3194 # sorts of decisions they want to make on this basis.  Please consider
3195 # this option to be deprecated.  FIXME.
3196 if test x${is_cross_compiler} = xyes ; then
3197   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3198 fi
3199
3200 # Special user-friendly check for native x86_64-linux build, if
3201 # multilib is not explicitly enabled.
3202 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3203   x86_64-*linux*:yes:$build:$build:)
3204     # Make sure we have a development environment that handles 32-bit
3205     dev64=no
3206     echo "int main () { return 0; }" > conftest.c
3207     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3208     if test $? = 0 ; then
3209       if test -s conftest || test -s conftest.exe ; then
3210         dev64=yes
3211       fi
3212     fi
3213     rm -f conftest*
3214     if test x${dev64} != xyes ; then
3215       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3216     fi
3217     ;;
3218 esac
3219
3220 # Default to --enable-multilib.
3221 if test x${enable_multilib} = x ; then
3222   target_configargs="--enable-multilib ${target_configargs}"
3223 fi
3224
3225 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3226 # changed from the earlier setting of with_newlib.
3227 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3228   target_configargs="--with-newlib ${target_configargs}"
3229 fi
3230
3231 # Different target subdirs use different values of certain variables
3232 # (notably CXX).  Worse, multilibs use *lots* of different values.
3233 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3234 # it doesn't automatically accept command-line overrides of them.
3235 # This means it's not safe for target subdirs to share a cache file,
3236 # which is disgusting, but there you have it.  Hopefully this can be
3237 # fixed in future.  It's still worthwhile to use a cache file for each
3238 # directory.  I think.
3239
3240 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3241 # We need to pass --target, as newer autoconf's requires consistency
3242 # for target_alias and gcc doesn't manage it consistently.
3243 target_configargs="--cache-file=./config.cache ${target_configargs}"
3244
3245 FLAGS_FOR_TARGET=
3246 case " $target_configdirs " in
3247  *" newlib "*)
3248   case " $target_configargs " in
3249   *" --with-newlib "*)
3250    case "$target" in
3251     *-cygwin*)
3252       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3253       ;;
3254    esac
3255
3256    # If we're not building GCC, don't discard standard headers.
3257    if test -d ${srcdir}/gcc; then
3258      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3259
3260      if test "${build}" != "${host}"; then
3261        # On Canadian crosses, CC_FOR_TARGET will have already been set
3262        # by `configure', so we won't have an opportunity to add -Bgcc/
3263        # to it.  This is right: we don't want to search that directory
3264        # for binaries, but we want the header files in there, so add
3265        # them explicitly.
3266        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3267
3268        # Someone might think of using the pre-installed headers on
3269        # Canadian crosses, in case the installed compiler is not fully
3270        # compatible with the compiler being built.  In this case, it
3271        # would be better to flag an error than risking having
3272        # incompatible object files being constructed.  We can't
3273        # guarantee that an error will be flagged, but let's hope the
3274        # compiler will do it, when presented with incompatible header
3275        # files.
3276      fi
3277    fi
3278
3279    case "${target}-${is_cross_compiler}" in
3280    i[[3456789]]86-*-linux*-no)
3281       # Here host == target, so we don't need to build gcc,
3282       # so we don't want to discard standard headers.
3283       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3284       ;;
3285    *)
3286       # If we're building newlib, use its generic headers last, but search
3287       # for any libc-related directories first (so make it the last -B
3288       # switch).
3289       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3290
3291       # If we're building libgloss, find the startup file, simulator library
3292       # and linker script.
3293       case " $target_configdirs " in
3294         *" libgloss "*)
3295         # Look for startup file, simulator library and maybe linker script.
3296         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3297         # Look for libnosys.a in case the target needs it.
3298         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3299         # Most targets have the linker script in the source directory.
3300         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3301         ;;
3302       esac
3303       ;;
3304    esac
3305    ;;
3306   esac
3307   ;;
3308 esac
3309
3310 case "$target" in
3311   x86_64-*mingw* | *-w64-mingw*)
3312   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3313   # however, use a symlink named 'mingw' in ${prefix} .
3314     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3315     ;;
3316   *-mingw*)
3317   # MinGW can't be handled as Cygwin above since it does not use newlib.
3318     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3319     ;;
3320 esac
3321
3322 # Allow the user to override the flags for
3323 # our build compiler if desired.
3324 if test x"${build}" = x"${host}" ; then
3325   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3326   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3327   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3328 fi
3329
3330 # On Canadian crosses, we'll be searching the right directories for
3331 # the previously-installed cross compiler, so don't bother to add
3332 # flags for directories within the install tree of the compiler
3333 # being built; programs in there won't even run.
3334 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3335   # Search for pre-installed headers if nothing else fits.
3336   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3337 fi
3338
3339 if test "x${use_gnu_ld}" = x &&
3340    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3341   # Arrange for us to find uninstalled linker scripts.
3342   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3343 fi
3344
3345 # Search for other target-specific linker scripts and such.
3346 case "${target}" in
3347   mep*)
3348     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3349     ;;
3350 esac
3351
3352 # Makefile fragments.
3353 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3354 do
3355   eval fragval=\$$frag
3356   if test $fragval != /dev/null; then
3357     eval $frag=${srcdir}/$fragval
3358   fi
3359 done
3360 AC_SUBST_FILE(host_makefile_frag)
3361 AC_SUBST_FILE(target_makefile_frag)
3362 AC_SUBST_FILE(alphaieee_frag)
3363 AC_SUBST_FILE(ospace_frag)
3364
3365 # Miscellanea: directories, flags, etc.
3366 AC_SUBST(RPATH_ENVVAR)
3367 AC_SUBST(GCC_SHLIB_SUBDIR)
3368 AC_SUBST(tooldir)
3369 AC_SUBST(build_tooldir)
3370 AC_SUBST(CONFIGURE_GDB_TK)
3371 AC_SUBST(GDB_TK)
3372 AC_SUBST(INSTALL_GDB_TK)
3373
3374 # Build module lists & subconfigure args.
3375 AC_SUBST(build_configargs)
3376 AC_SUBST(build_configdirs)
3377
3378 # Host module lists & subconfigure args.
3379 AC_SUBST(host_configargs)
3380 AC_SUBST(configdirs)
3381 AC_SUBST(target_configdirs)
3382
3383 # Target module lists & subconfigure args.
3384 AC_SUBST(target_configargs)
3385
3386
3387 # Build tools.
3388 AC_SUBST(AR_FOR_BUILD)
3389 AC_SUBST(AS_FOR_BUILD)
3390 AC_SUBST(CC_FOR_BUILD)
3391 AC_SUBST(CFLAGS_FOR_BUILD)
3392 AC_SUBST(CXXFLAGS_FOR_BUILD)
3393 AC_SUBST(CXX_FOR_BUILD)
3394 AC_SUBST(DLLTOOL_FOR_BUILD)
3395 AC_SUBST(GFORTRAN_FOR_BUILD)
3396 AC_SUBST(GOC_FOR_BUILD)
3397 AC_SUBST(GDC_FOR_BUILD)
3398 AC_SUBST(LDFLAGS_FOR_BUILD)
3399 AC_SUBST(LD_FOR_BUILD)
3400 AC_SUBST(NM_FOR_BUILD)
3401 AC_SUBST(RANLIB_FOR_BUILD)
3402 AC_SUBST(WINDMC_FOR_BUILD)
3403 AC_SUBST(WINDRES_FOR_BUILD)
3404
3405 # Generate default definitions for YACC, M4, LEX and other programs that run
3406 # on the build machine.  These are used if the Makefile can't locate these
3407 # programs in objdir.
3408 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3409
3410 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3411 case " $build_configdirs " in
3412   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3413 esac
3414
3415 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3416 case " $build_configdirs " in
3417   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3418 esac
3419
3420 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3421 case " $build_configdirs " in
3422   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3423 esac
3424
3425 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3426 case " $build_configdirs " in
3427   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3428   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3429 esac
3430
3431 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3432 case " $build_configdirs " in
3433   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3434 esac
3435
3436 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3437 case " $build_configdirs " in
3438   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3439   *)
3440 changequote(,)
3441     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3442     # higher, else we use the "missing" dummy.
3443     if ${MAKEINFO} --version \
3444        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3445       :
3446     else
3447       MAKEINFO="$MISSING makeinfo"
3448     fi
3449     ;;
3450 changequote([,])
3451 esac
3452
3453 # FIXME: expect and dejagnu may become build tools?
3454
3455 AC_CHECK_PROGS(EXPECT, expect, expect)
3456 case " $configdirs " in
3457   *" expect "*)
3458     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3459     ;;
3460 esac
3461
3462 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3463 case " $configdirs " in
3464   *" dejagnu "*)
3465     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3466     ;;
3467 esac
3468
3469
3470 # Host tools.
3471 NCN_STRICT_CHECK_TOOLS(AR, ar)
3472 NCN_STRICT_CHECK_TOOLS(AS, as)
3473 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3474 NCN_STRICT_CHECK_TOOLS(LD, ld)
3475 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3476 NCN_STRICT_CHECK_TOOLS(NM, nm)
3477 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3478 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3479 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3480 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3481 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3482 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3483 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3484 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3485 AC_SUBST(CC)
3486 AC_SUBST(CXX)
3487 AC_SUBST(CFLAGS)
3488 AC_SUBST(CXXFLAGS)
3489
3490 # Target tools.
3491 AC_ARG_WITH([build-time-tools],
3492   [AS_HELP_STRING([--with-build-time-tools=PATH],
3493                   [use given path to find target tools during the build])],
3494   [case x"$withval" in
3495      x/*) ;;
3496      *)
3497        with_build_time_tools=
3498        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3499        ;;
3500    esac],
3501   [with_build_time_tools=])
3502
3503 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3504 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3505 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3506 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3507 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3508 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3509
3510 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3511 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3512 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3513 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3514 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3515 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3516 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3517 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3518 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3519 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3520 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3521 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3522 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3523 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3524
3525 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3526
3527 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3528 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3529 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3530 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3531 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3532                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3533                 c++)
3534 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3535                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3536                 c++)
3537 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3538 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3539 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3540                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3541 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3542                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3543 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3544                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3545 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3546 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3547 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3548 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3549 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3550 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3551 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3552 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3553 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3554 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3555 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3556
3557 AC_SUBST(FLAGS_FOR_TARGET)
3558 AC_SUBST(RAW_CXX_FOR_TARGET)
3559
3560 # Certain tools may need extra flags.
3561 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3562 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3563 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3564
3565 # When building target libraries, except in a Canadian cross, we use
3566 # the same toolchain as the compiler we just built.
3567 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3568 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3569 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3570 if test $host = $build; then
3571   case " $configdirs " in
3572     *" gcc "*)
3573       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3574       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3575       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3576       ;;
3577   esac
3578 fi
3579
3580 AC_SUBST(COMPILER_AS_FOR_TARGET)
3581 AC_SUBST(COMPILER_LD_FOR_TARGET)
3582 AC_SUBST(COMPILER_NM_FOR_TARGET)
3583
3584 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3585 AC_ARG_ENABLE(maintainer-mode,
3586 [AS_HELP_STRING([--enable-maintainer-mode],
3587                 [enable make rules and dependencies not useful
3588                  (and sometimes confusing) to the casual installer])],
3589       USE_MAINTAINER_MODE=$enableval,
3590       USE_MAINTAINER_MODE=no)
3591 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3592 AC_SUBST(MAINTAINER_MODE_TRUE)
3593 AC_SUBST(MAINTAINER_MODE_FALSE)
3594 if test "$USE_MAINTAINER_MODE" = yes; then
3595   MAINTAINER_MODE_TRUE=
3596   MAINTAINER_MODE_FALSE='#'
3597 else
3598   MAINTAINER_MODE_TRUE='#'
3599   MAINTAINER_MODE_FALSE=
3600 fi
3601 MAINT=$MAINTAINER_MODE_TRUE
3602 AC_SUBST(MAINT)dnl
3603
3604 # ---------------------
3605 # GCC bootstrap support
3606 # ---------------------
3607
3608 # Stage specific cflags for build.
3609 stage1_cflags="-g"
3610 case $build in
3611   vax-*-*)
3612     case ${GCC} in
3613       yes) stage1_cflags="-g -Wa,-J" ;;
3614       *) stage1_cflags="-g -J" ;;
3615     esac ;;
3616 esac
3617
3618 AC_SUBST(stage1_cflags)
3619
3620 # Enable --enable-checking in stage1 of the compiler.
3621 AC_ARG_ENABLE(stage1-checking,
3622 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3623                 [choose additional checking for stage1 of the compiler])],
3624 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3625 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3626   # For --disable-checking or implicit --enable-checking=release, avoid
3627   # setting --enable-checking=gc in the default stage1 checking for LTO
3628   # bootstraps.  See PR62077.
3629   case $BUILD_CONFIG in
3630     *lto*)
3631       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3632     *)
3633       stage1_checking=--enable-checking=yes,types;;
3634   esac
3635   if test "x$enable_checking" = x && \
3636      test -d ${srcdir}/gcc && \
3637      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3638     stage1_checking=--enable-checking=yes,types,extra
3639   fi
3640 else
3641   stage1_checking=--enable-checking=$enable_checking,types
3642 fi])
3643 AC_SUBST(stage1_checking)
3644
3645 # Enable -Werror in bootstrap stage2 and later.
3646 AC_ARG_ENABLE(werror,
3647 [AS_HELP_STRING([--enable-werror],
3648                 [enable -Werror in bootstrap stage2 and later])],
3649 [
3650 case ${enable_werror} in
3651   yes) stage2_werror_flag="--enable-werror-always" ;;
3652   *) stage2_werror_flag="" ;;
3653 esac
3654 ],
3655 [
3656 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3657   case $BUILD_CONFIG in
3658   bootstrap-debug)
3659       stage2_werror_flag="--enable-werror-always" ;;
3660   "")
3661       stage2_werror_flag="--enable-werror-always" ;;
3662   esac
3663 fi
3664 ])
3665
3666 AC_SUBST(stage2_werror_flag)
3667
3668 # Specify what files to not compare during bootstrap.
3669
3670 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3671 case "$target" in
3672   hppa*64*-*-hpux*) ;;
3673   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3674   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3675 esac
3676 AC_SUBST(compare_exclusions)
3677
3678 AC_CONFIG_FILES([Makefile],
3679   [sed "$extrasub_build" Makefile |
3680    sed "$extrasub_host" |
3681    sed "$extrasub_target" > mf$$
3682    mv -f mf$$ Makefile],
3683   [extrasub_build="$extrasub_build"
3684    extrasub_host="$extrasub_host"
3685    extrasub_target="$extrasub_target"])
3686 AC_OUTPUT