configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.0
  58 GSTPB_REQ=0.11.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for documentation tools
 134 GTK_DOC_CHECK([1.3])
 135 AS_PATH_PYTHON([2.1])
 136 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl check for libm, for sin()
 141 AC_CHECK_LIBM
 142 AC_SUBST(LIBM)
 143
 144 dnl *** checks for header files ***
 145
 146 dnl check if we have ANSI C header files
 147 AC_HEADER_STDC
 148
 149 dnl used by ext/wavpack
 150 AX_CREATE_STDINT_H
 151
 152 dnl used in gst/rtp/gstasteriskh263.c
 153 AC_CHECK_HEADERS([netinet/in.h])
 154 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 155 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 156
 157 dnl used in gst/udp
 158 AC_CHECK_HEADERS([sys/time.h])
 159
 160 dnl *** checks for types/defines ***
 161
 162 dnl Check for FIONREAD ioctl declaration.  This check is needed
 163 dnl for the UDP plugin to build on Solaris
 164 GST_CHECK_FIONREAD
 165
 166 dnl *** checks for structures ***
 167
 168 dnl *** checks for compiler characteristics ***
 169
 170 dnl check if we have GCC inline-asm
 171 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 172 if test x$HAVE_GCC_ASM = xyes ; then
 173   AC_DEFINE(HAVE_GCC_ASM, 1,
 174     [Define if compiler supports gcc inline assembly])
 175 fi
 176 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 177
 178 dnl *** checks for library functions ***
 179
 180 LIBS_SAVE=$LIBS
 181 LIBS="$LIBS $LIBM"
 182 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 183 LIBS=$LIBS_SAVE
 184
 185 dnl Check whether isinf() is defined by math.h
 186 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 188 if test "$ac_cv_have_isinf" = "yes"
 189 then
 190     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 191 fi
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194 AC_FUNC_MMAP
 195 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198
 199 AC_CHECK_TYPE([struct ip_mreqn], [
 200               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 201               [#include <netinet/in.h>])
 202
 203 dnl *** checks for dependency libraries ***
 204
 205 dnl GLib is required
 206 AG_GST_GLIB_CHECK([2.20])
 207
 208 dnl Orc
 209 ORC_CHECK([0.4.11])
 210
 211 dnl checks for gstreamer
 212 dnl uninstalled is selected preferentially -- see pkg-config(1)
 213 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 214 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK2_REQ=2.14.0
 243 GTK3_REQ=2.91.3
 244 if test "x$BUILD_EXAMPLES" = "xyes"; then
 245   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 246   AC_ARG_WITH([gtk],
 247     AC_HELP_STRING([--with-gtk=3.0|2.0],
 248                    [which gtk+ version to compile against (default: 2.0)]),
 249     [case "$with_gtk" in
 250         2.0) GTK_REQ=$GTK2_REQ ;;
 251         3.0) GTK_REQ=$GTK3_REQ ;;
 252         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 253     esac],
 254     [with_gtk=2.0
 255      GTK_REQ=$GTK2_REQ])
 256   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 257   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 258   dnl some examples need gtk+-x11
 259   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 260   AC_SUBST(GTK_LIBS)
 261   AC_SUBST(GTK_CFLAGS)
 262 fi
 263 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 264 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 265
 266 dnl *** set variables based on configure arguments ***
 267
 268 dnl set license and copyright notice
 269 GST_LICENSE="LGPL"
 270 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 271 AC_SUBST(GST_LICENSE)
 272
 273 dnl set location of plugin directory
 274 AG_GST_SET_PLUGINDIR
 275
 276 dnl set release date/time
 277 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 278   ["${srcdir}/gst-plugins-good.doap"],
 279   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 280
 281 dnl define an ERROR_CFLAGS Makefile variable
 282 dnl -Wundef: too many broken headers
 283 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 284   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 285         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 286         -Wwrite-strings -Wold-style-definition -Waggregate-return
 287         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 288         -Wnested-externs ])
 289 else
 290   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 291   dnl doesn't understand all warning flags that the C compiler knows about
 292   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 293   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 294         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 295         -Wwrite-strings -Wold-style-definition
 296         -Winit-self -Wmissing-include-dirs -Wno-multichar
 297         -Wnested-externs ])
 298 fi
 299
 300 dnl define an ERROR_CXXFLAGS Makefile variable
 301 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 302         -Wmissing-declarations -Wredundant-decls
 303         -Wwrite-strings
 304         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 305
 306 dnl define correct level for debugging messages
 307 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 308
 309 dnl used in examples
 310 AG_GST_DEFAULT_ELEMENTS
 311
 312 dnl *** plug-ins to include ***
 313
 314 dnl Non ported plugins (non-dependant, then dependant)
 315 dnl Make sure you have a space before and after all plugins
 316 GST_PLUGINS_NONPORTED="deinterlace flx goom2k1 \
 317  imagefreeze interleave matroska monoscope smpte \
 318  videobox videomixer \
 319  cairo cairo_gobject dv1394 gdk_pixbuf libdv libpng \
 320  oss oss4 shout2 \
 321  taglib wavpack "
 322 AC_SUBST(GST_PLUGINS_NONPORTED)
 323
 324 dnl these are all the gst plug-ins, compilable without additional libs
 325 dnl videofilter is at the top because others depend on it
 326 AG_GST_CHECK_PLUGIN(alpha)
 327 AG_GST_CHECK_PLUGIN(apetag)
 328 AG_GST_CHECK_PLUGIN(audiofx)
 329 AG_GST_CHECK_PLUGIN(audioparsers)
 330 AG_GST_CHECK_PLUGIN(auparse)
 331 AG_GST_CHECK_PLUGIN(autodetect)
 332 AG_GST_CHECK_PLUGIN(avi)
 333 AG_GST_CHECK_PLUGIN(cutter)
 334 AG_GST_CHECK_PLUGIN(debugutils)
 335 AG_GST_CHECK_PLUGIN(deinterlace)
 336 AG_GST_CHECK_PLUGIN(effectv)
 337 AG_GST_CHECK_PLUGIN(equalizer)
 338 AG_GST_CHECK_PLUGIN(flv)
 339 AG_GST_CHECK_PLUGIN(flx)
 340 AG_GST_CHECK_PLUGIN(goom)
 341 AG_GST_CHECK_PLUGIN(goom2k1)
 342 AG_GST_CHECK_PLUGIN(icydemux)
 343 AG_GST_CHECK_PLUGIN(id3demux)
 344 AG_GST_CHECK_PLUGIN(imagefreeze)
 345 AG_GST_CHECK_PLUGIN(interleave)
 346 AG_GST_CHECK_PLUGIN(isomp4)
 347 AG_GST_CHECK_PLUGIN(law)
 348 AG_GST_CHECK_PLUGIN(level)
 349 AG_GST_CHECK_PLUGIN(matroska)
 350 AG_GST_CHECK_PLUGIN(monoscope)
 351 AG_GST_CHECK_PLUGIN(multifile)
 352 AG_GST_CHECK_PLUGIN(multipart)
 353 AG_GST_CHECK_PLUGIN(replaygain)
 354 AG_GST_CHECK_PLUGIN(rtp)
 355 AG_GST_CHECK_PLUGIN(rtpmanager)
 356 AG_GST_CHECK_PLUGIN(rtsp)
 357 AG_GST_CHECK_PLUGIN(shapewipe)
 358 AG_GST_CHECK_PLUGIN(smpte)
 359 AG_GST_CHECK_PLUGIN(spectrum)
 360 AG_GST_CHECK_PLUGIN(udp)
 361 AG_GST_CHECK_PLUGIN(videobox)
 362 AG_GST_CHECK_PLUGIN(videocrop)
 363 AG_GST_CHECK_PLUGIN(videofilter)
 364 AG_GST_CHECK_PLUGIN(videomixer)
 365 AG_GST_CHECK_PLUGIN(wavenc)
 366 AG_GST_CHECK_PLUGIN(wavparse)
 367 AG_GST_CHECK_PLUGIN(y4m)
 368
 369 dnl *** checks for socket and nsl libraries ***
 370 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 371
 372 dnl disable gst plugins we might not be able to build on this
 373 dnl platform: udp and rtsp (ugly but minimally invasive)
 374 dnl FIXME: maybe move to sys
 375 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 376 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 377
 378 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 379   AG_GST_DISABLE_PLUGIN(udp)
 380   AG_GST_DISABLE_PLUGIN(rtsp)
 381 fi
 382
 383 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 384   WIN32_LIBS="-lws2_32"
 385   AC_SUBST(WIN32_LIBS)
 386 fi
 387
 388 dnl disable experimental plug-ins
 389 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 390   AG_GST_DISABLE_PLUGIN(monoscope)
 391 fi
 392
 393 dnl *** sys plug-ins ***
 394
 395 echo
 396 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 397 echo
 398
 399 dnl DirectSound
 400 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 401 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 402   HAVE_DIRECTSOUND="no"
 403   save_CFLAGS="$CFLAGS"
 404   save_LDFLAGS="$LDFLAGS"
 405   save_LIBS="$LIBS"
 406   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 407   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 408   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 409   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 410   AC_LINK_IFELSE([
 411 #include <windows.h>
 412 #include <dxerr9.h>
 413 #include <dsound.h>
 414
 415 int main ()
 416 {
 417   DXGetErrorString9 (0);
 418   DirectSoundCreate(NULL, NULL, NULL);
 419
 420   return 0;
 421 }
 422 ],
 423     [HAVE_DIRECTSOUND="yes"],
 424     [HAVE_DIRECTSOUND="no"])
 425   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 426   CFLAGS=$save_CFLAGS
 427   LDFLAGS=$save_LDFLAGS
 428   LIBS=$save_LIBS
 429
 430   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 431     dnl this is much more than we want
 432     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 433     AC_SUBST(DIRECTSOUND_CFLAGS)
 434     AC_SUBST(DIRECTSOUND_LDFLAGS)
 435     AC_SUBST(DIRECTSOUND_LIBS)
 436   fi
 437   AC_SUBST(HAVE_DIRECTSOUND)
 438 ])
 439
 440 dnl *** OSS audio *** (Linux, *BSD)
 441 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 442 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 443  HAVE_OSS="yes"
 444 dnl Linux and newer BSD versions :
 445  AC_CHECK_HEADER(sys/soundcard.h, [
 446    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 447    ] , [
 448 dnl Some old BSD versions and also newer OpenBSD versions :
 449    AC_CHECK_HEADER(soundcard.h, [
 450      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 451      ], [
 452   dnl Some old BSD versions :
 453      AC_CHECK_HEADER(machine/soundcard.h, [
 454        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 455          [Define if OSS includes are in /machine/])
 456        ], [
 457        HAVE_OSS="no"
 458      ])
 459    ])
 460  ])
 461 ])
 462
 463 dnl *** oss4 ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 465 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 466   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 467   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 468       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 469       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 470 ])
 471
 472 dnl *** Sun Audio ***
 473 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 474 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 475   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 476 ])
 477
 478 dnl *** OSX Audio ***
 479 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 480 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 481   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 482 ])
 483
 484 dnl *** OS X video ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 486 HAVE_OSX_VIDEO="no"
 487 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 488   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 489 ])
 490 dnl in case header OpenGL/gl.h is found on other platforms
 491 case "$host" in
 492   *-*darwin*)
 493     dnl do nothing
 494     ;;
 495   *)
 496     HAVE_OSX_VIDEO="no"
 497     ;;
 498 esac
 499
 500
 501 dnl *** Video 4 Linux 2 ***
 502 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 503 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 504 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 505 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 506   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 507   AC_TRY_COMPILE([
 508 #include <sys/types.h>
 509 #ifdef __sun /* Solaris */
 510 #include <sys/types.h>
 511 #include <sys/videodev2.h>
 512 #else /* Linux */
 513 #include <linux/types.h>
 514 #define _LINUX_TIME_H
 515 #define __user
 516 #include <linux/videodev2.h>
 517 #endif
 518 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 519 #error too early v4l2 version or no v4l2 at all
 520 #endif
 521     ], [
 522 return 0;
 523     ], [
 524       HAVE_GST_V4L2="yes"
 525       AC_MSG_RESULT(yes)
 526     ], [
 527       HAVE_GST_V4L2="no"
 528       AC_MSG_RESULT(no)
 529
 530       HAVE_VIDEODEV=no
 531       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 532       [
 533         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 534       ])
 535
 536       if test "x$HAVE_VIDEODEV" = "xyes"; then
 537         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 538         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 539       else
 540         AC_MSG_WARN([video4linux2 was not found])
 541       fi
 542     ])
 543
 544   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 545     dnl check for missing v4l2_buffer declaration (see #135919)
 546     MISSING_DECL=0
 547     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 548     AC_TRY_COMPILE([
 549 #include <sys/types.h>
 550 #ifdef __sun /* Solaris */
 551 #include <sys/types.h>
 552 #include <sys/videodev2.h>
 553 #else /* Linux */
 554 #include <linux/types.h>
 555 #define _LINUX_TIME_H
 556 #define __user
 557 #include <linux/videodev2.h>
 558 #endif
 559     ],[
 560 struct v4l2_buffer buf;
 561 buf.index = 0;
 562 return 0;
 563     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 564     if [ test x$MISSING_DECL = x1 ]; then
 565       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 566     fi
 567
 568     dnl check for XOverlay libraries
 569     AG_GST_CHECK_XV
 570   fi
 571 ])
 572
 573 # Optional gudev for device probing
 574 AC_ARG_WITH([gudev],
 575   AC_HELP_STRING([--with-gudev],
 576     [device detection with gudev]),
 577   [],
 578   [with_gudev=check])
 579 if test x$HAVE_GST_V4L2 = xyes; then
 580   if test x$with_gudev != xno; then
 581       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 582           [ have_gudev=yes
 583             AC_DEFINE(HAVE_GUDEV, 1,
 584                [Whether gudev is available for device detection])
 585             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 586           ], [
 587           have_gudev=no
 588           ])
 589   else
 590     have_gudev=no
 591   fi
 592 fi
 593 AC_SUBST(GUDEV_CFLAGS)
 594 AC_SUBST(GUDEV_LIBS)
 595
 596 # Make libv4l2 non-automagic
 597 AC_ARG_WITH([libv4l2],
 598   AC_HELP_STRING([--with-libv4l2],
 599     [support video buffer conversion using libv4l2]),
 600   [],
 601   [with_libv4l2=check])
 602 if test x$HAVE_GST_V4L2 = xyes; then
 603   if test x$with_libv4l2 != xno; then
 604       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 605           [ have_libv4l2=yes
 606             AC_DEFINE(HAVE_LIBV4L2, 1,
 607                 [Whether libv4l2 is available for video buffer conversion])
 608           ], [
 609           have_libv4l2=no
 610           ])
 611   else
 612     have_libv4l2=no
 613   fi
 614 fi
 615
 616 dnl Check for X11
 617 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 618 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 619                   [ximagesrc], [
 620   AC_PATH_XTRA
 621
 622   dnl now try to find the HEADER
 623   ac_cflags_save="$CFLAGS"
 624   ac_cppflags_save="$CPPFLAGS"
 625   CFLAGS="$CFLAGS $X_CFLAGS"
 626   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 627   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 628
 629   if test "x$HAVE_X" = "xno"
 630   then
 631     AC_MSG_NOTICE([cannot find X11 development files])
 632   else
 633     dnl this is much more than we want
 634     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 635     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 636     dnl it does not add the libs; therefore we add them here
 637     X_LIBS="$X_LIBS -lX11"
 638     AC_SUBST(X_CFLAGS)
 639     AC_SUBST(X_LIBS)
 640
 641     dnl check for Xfixes
 642     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 643     if test "x$HAVE_XFIXES" = "xyes"
 644     then
 645         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 646     fi
 647     AC_SUBST(XFIXES_LIBS)
 648     AC_SUBST(XFIXES_CFLAGS)
 649
 650     dnl check for Xdamage
 651     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 652     if test "x$HAVE_XDAMAGE" = "xyes"
 653     then
 654         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 655     fi
 656     AC_SUBST(XDAMAGE_LIBS)
 657     AC_SUBST(XDAMAGE_CFLAGS)
 658   fi
 659   AC_SUBST(HAVE_X)
 660   CFLAGS="$ac_cflags_save"
 661   CPPFLAGS="$ac_cppflags_save"
 662 ])
 663
 664 dnl FIXME: this should be rolled into the test above, it's just an additional
 665 dnl feature of the ximagesrc plug-in
 666 dnl This is the same as in gst-plugins-base
 667 dnl check for X Shm
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 669 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 670   if test x$HAVE_X = xyes; then
 671     AC_CHECK_LIB(Xext, XShmAttach,
 672                  HAVE_XSHM="yes", HAVE_XSHM="no",
 673                  $X_LIBS)
 674     if test "x$HAVE_XSHM" = "xyes"; then
 675       XSHM_LIBS="-lXext"
 676     else
 677       dnl On AIX, it is in XextSam instead, but we still need -lXext
 678       AC_CHECK_LIB(XextSam, XShmAttach,
 679                    HAVE_XSHM="yes", HAVE_XSHM="no",
 680                    $X_LIBS)
 681       if test "x$HAVE_XSHM" = "xyes"; then
 682         XSHM_LIBS="-lXext -lXextSam"
 683       fi
 684     fi
 685   fi
 686 ], ,[
 687   AC_SUBST(HAVE_XSHM)
 688   AC_SUBST(XSHM_LIBS)
 689 ])
 690
 691 dnl for V4L2, we also need to know if we have XVIDEO
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 693 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 694                   [], [
 695   AG_GST_CHECK_XV
 696 ])
 697
 698 dnl *** ext plug-ins ***
 699 dnl keep this list sorted alphabetically !
 700
 701 if test "x$BUILD_EXTERNAL" = "xyes"; then
 702
 703 echo
 704 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 705 echo
 706
 707 dnl *** aalib ***
 708 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 709 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 710   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 711   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 712 ])
 713
 714 dnl *** annodex ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 716 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 717   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 718 ])
 719
 720 dnl *** cairo ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 722 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 723   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 724 ])
 725
 726 dnl *** cairo-gobject ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 728 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 729   [Cairo graphics rendering gobject bindings], cairooverlay, [
 730   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 731 ])
 732
 733 dnl *** FLAC ***
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 735 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 736   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 737 ])
 738
 739 dnl *** GDK pixbuf ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 741 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 742   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 743 ])
 744
 745 dnl *** Jack ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 747 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 748   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 749   AC_SUBST(JACK_CFLAGS)
 750   AC_SUBST(JACK_LIBS)
 751
 752   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 753   if test x$HAVE_JACK_0_120_1 = xyes; then
 754     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 755   fi
 756   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 757   if test x$HAVE_JACK_1_9_7 = xyes; then
 758     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 759   fi
 760
 761 ])
 762
 763 dnl *** jpeg ***
 764 dnl FIXME: we could use header checks here as well IMO
 765 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 766 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 767   AC_ARG_WITH(jpeg-mmx,
 768     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 769   OLD_LIBS="$LIBS"
 770   if test x$with_jpeg_mmx != x; then
 771     LIBS="$LIBS -L$with_jpeg_mmx"
 772   fi
 773   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 774   JPEG_LIBS="$LIBS -ljpeg-mmx"
 775   LIBS="$OLD_LIBS"
 776   if test x$HAVE_JPEG != xyes; then
 777     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 778     JPEG_LIBS="-ljpeg"
 779   fi
 780   AC_SUBST(JPEG_LIBS)
 781 ])
 782
 783 dnl *** libcaca ***
 784 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 785 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 786   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 787 ])
 788
 789 dnl *** libdv ***
 790 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 791 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 792   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 793 ])
 794
 795 dnl *** libpng ***
 796 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 797 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 798   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 799 ])
 800
 801 dnl *** pulseaudio ***
 802 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 803 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 804
 805   dnl used in ext/pulse/pulseutil.c
 806   AC_CHECK_HEADERS([process.h])
 807
 808   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.16)
 809   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 810   if test x$HAVE_PULSE_0_9_20 = xyes; then
 811     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 812   fi
 813   AG_GST_PKG_CHECK_MODULES(PULSE_1_0, libpulse >= 0.98)
 814   if test x$HAVE_PULSE_1_0 = xyes; then
 815     AC_DEFINE(HAVE_PULSE_1_0, 1, [defined if pulseaudio >= 1.0 is available])
 816   fi
 817 ])
 818
 819 dnl *** dv1394 ***
 820 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 821 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 822   dnl first test for libraw1394 >= 2.0.0
 823   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 824   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 825   dnl now see how far we got
 826   if test x$HAVE_RAW1394 = xyes && \
 827      test x$HAVE_LIBIEC61883 = xyes; then
 828        AG_GST_CHECK_LIBHEADER(AVC1394,
 829         avc1394, avc1394_send_command, $RAW1394_LIBS,
 830         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 831        AG_GST_CHECK_LIBHEADER(ROM1394,
 832         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 833         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 834        if test x$HAVE_AVC1394 = xyes && \
 835           test x$HAVE_AVC1394 = xyes && \
 836           test x$HAVE_ROM1394 = xyes; then
 837           HAVE_DV1394=yes
 838           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 839           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 840           AC_SUBST(DV1394_CFLAGS)
 841           AC_SUBST(DV1394_LIBS)
 842         fi
 843   else
 844        if test x$HAVE_RAW1394 = xno; then
 845           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 846           AG_GST_CHECK_LIBHEADER(AVC1394,
 847            avc1394, avc1394_send_command, $RAW1394_LIBS,
 848            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 849           AG_GST_CHECK_LIBHEADER(ROM1394,
 850            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 851            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 852           if test x$HAVE_RAW1394 = xyes && \
 853              test x$HAVE_AVC1394 = xyes && \
 854              test x$HAVE_ROM1394 = xyes; then
 855              HAVE_DV1394=yes
 856              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 857              DV1394_CFLAGS="$RAW1394_CFLAGS"
 858              if test x$HAVE_LIBIEC61883 = xyes; then
 859                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 860                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 861              fi
 862              AC_SUBST(DV1394_CFLAGS)
 863              AC_SUBST(DV1394_LIBS)
 864            fi
 865          fi
 866   fi
 867 ])
 868 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 869
 870 dnl *** shout2 ***
 871 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 872 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 873   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 874 ])
 875
 876 dnl *** soup ***
 877 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 878 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 879   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 880     HAVE_SOUP="yes"
 881     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 882   ],[
 883     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 884       HAVE_SOUP="no"
 885     ])
 886   ])
 887   AC_SUBST(SOUP_CFLAGS)
 888   AC_SUBST(SOUP_LIBS)
 889 ])
 890
 891 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 892 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 893 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 894 dnl   speex_jitter.h is 1.1.x only
 895 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 896 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 897   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 898   if test $HAVE_SPEEX = no
 899   then
 900     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 901       AC_CHECK_HEADER(speex/speex_jitter.h, [
 902         dnl speex 1.1.x :
 903         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 904           dnl speex 1.1.5 or + :
 905           HAVE_SPEEX="yes"
 906           SPEEX_LIBS="-lspeex"
 907           AC_SUBST(SPEEX_CFLAGS)
 908           AC_SUBST(SPEEX_LIBS)
 909         ],[
 910           HAVE_SPEEX="no"
 911         ])
 912       ],[
 913         dnl speex 1.0.x :
 914           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 915             dnl speex 1.0.4
 916             HAVE_SPEEX="yes"
 917             SPEEX_LIBS="-lspeex"
 918             AC_SUBST(SPEEX_CFLAGS)
 919             AC_SUBST(SPEEX_LIBS)
 920
 921             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 922               [defined if speex 1.0.x API detected])
 923         ],[
 924             HAVE_SPEEX="no"
 925             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 926         ], [
 927 #include <speex/speex.h>
 928         ])
 929       ])
 930     ])
 931   fi
 932 ])
 933
 934 dnl *** taglib ***
 935 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 936 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 937   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 938   if test "x$HAVE_CXX" != "xyes"; then
 939     USE_TAGLIB=false
 940     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 941   else
 942     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 943     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 944         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 945       ], [
 946         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 947     ])
 948     AC_SUBST(TAGLIB_CXXFLAGS)
 949   fi
 950 ])
 951
 952 dnl *** wavpack ***
 953 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 954 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 955   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 956     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 957       HAVE_WAVPACK=yes
 958       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 959     ],[
 960       HAVE_WAVPACK=no
 961     ])
 962   ])
 963   AC_SUBST(WAVPACK_CFLAGS)
 964   AC_SUBST(WAVPACK_LIBS)
 965 ])
 966
 967 dnl *** qtdemux & matroska prefer to have zlib ***
 968 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 969 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 970   AG_GST_CHECK_LIBHEADER(ZLIB,
 971     z, uncompress,, zlib.h, [
 972     HAVE_ZLIB="yes"
 973     ZLIB_LIBS="-lz"
 974     AC_SUBST(ZLIB_LIBS)
 975   ])
 976 ])
 977
 978 dnl *** matroska prefers to have bz2 ***
 979 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 980 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 981   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 982   AC_SUBST(BZ2_LIBS)
 983 ])
 984
 985 else
 986
 987 dnl not building plugins with external dependencies,
 988 dnl but we still need to set the conditionals
 989 AM_CONDITIONAL(USE_AALIB, false)
 990 AM_CONDITIONAL(USE_ANNODEX, false)
 991 AM_CONDITIONAL(USE_BZ2, false)
 992 AM_CONDITIONAL(USE_CAIRO, false)
 993 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 994 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 995 AM_CONDITIONAL(USE_DV1394, false)
 996 AM_CONDITIONAL(USE_FLAC, false)
 997 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 998 AM_CONDITIONAL(USE_GST_V4L2, false)
 999 AM_CONDITIONAL(USE_JACK, false)
1000 AM_CONDITIONAL(USE_JPEG, false)
1001 AM_CONDITIONAL(USE_LIBCACA, false)
1002 AM_CONDITIONAL(USE_LIBDV, false)
1003 AM_CONDITIONAL(USE_LIBIEC61883, false)
1004 AM_CONDITIONAL(USE_LIBPNG, false)
1005 AM_CONDITIONAL(USE_OSS, false)
1006 AM_CONDITIONAL(USE_OSS4, false)
1007 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1008 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1009 AM_CONDITIONAL(USE_PULSE, false)
1010 AM_CONDITIONAL(USE_SHOUT2, false)
1011 AM_CONDITIONAL(USE_SOUP, false)
1012 AM_CONDITIONAL(USE_SPEEX, false)
1013 AM_CONDITIONAL(USE_SUNAUDIO, false)
1014 AM_CONDITIONAL(USE_TAGLIB, false)
1015 AM_CONDITIONAL(USE_WAVPACK, false)
1016 AM_CONDITIONAL(USE_X, false)
1017 AM_CONDITIONAL(USE_XSHM, false)
1018 AM_CONDITIONAL(USE_XVIDEO, false)
1019 AM_CONDITIONAL(USE_ZLIB, false)
1020
1021 fi dnl of EXT plugins
1022
1023 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1024
1025 dnl Overview:
1026 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1027 dnl GST_*:              flags shared by all built objects
1028 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1029 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1030 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1031 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1032
1033 dnl GST_OPTION_CFLAGS
1034 if test "x$USE_DEBUG" = xyes; then
1035    PROFILE_CFLAGS="-g"
1036 fi
1037 AC_SUBST(PROFILE_CFLAGS)
1038
1039 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1040   dnl Define _only_ for git (not pre-releases or releases)
1041   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1042 else
1043   DEPRECATED_CFLAGS=""
1044 fi
1045 AC_SUBST(DEPRECATED_CFLAGS)
1046
1047 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1048 dnl at make time with e.g. make ERROR_CFLAGS=""
1049 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1050 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1051 AC_SUBST(GST_OPTION_CFLAGS)
1052 AC_SUBST(GST_OPTION_CXXFLAGS)
1053
1054 dnl our libraries need to be versioned correctly
1055 AC_SUBST(GST_LT_LDFLAGS)
1056
1057 dnl FIXME: do we want to rename to GST_ALL_* ?
1058 dnl prefer internal headers to already installed ones
1059 dnl also add builddir include for enumtypes and marshal
1060 dnl add ERROR_CFLAGS, but overridable
1061 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1062 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1063 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1064 AC_SUBST(GST_CFLAGS)
1065 AC_SUBST(GST_CXXFLAGS)
1066 AC_SUBST(GST_LIBS)
1067
1068 dnl LDFLAGS really should only contain flags, not libs - they get added before
1069 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1070 GST_ALL_LDFLAGS="-no-undefined"
1071 AC_SUBST(GST_ALL_LDFLAGS)
1072
1073 dnl this really should only contain flags, not libs - they get added before
1074 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1075 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1076 AC_SUBST(GST_PLUGIN_LDFLAGS)
1077
1078 dnl *** output files ***
1079
1080 dnl keep this alphabetic per directory, please
1081 AC_CONFIG_FILES(
1082 Makefile
1083 gst/Makefile
1084 gst/alpha/Makefile
1085 gst/apetag/Makefile
1086 gst/audiofx/Makefile
1087 gst/audioparsers/Makefile
1088 gst/auparse/Makefile
1089 gst/autodetect/Makefile
1090 gst/avi/Makefile
1091 gst/cutter/Makefile
1092 gst/deinterlace/Makefile
1093 gst/debugutils/Makefile
1094 gst/effectv/Makefile
1095 gst/equalizer/Makefile
1096 gst/flv/Makefile
1097 gst/goom/Makefile
1098 gst/goom2k1/Makefile
1099 gst/id3demux/Makefile
1100 gst/icydemux/Makefile
1101 gst/imagefreeze/Makefile
1102 gst/interleave/Makefile
1103 gst/isomp4/Makefile
1104 gst/law/Makefile
1105 gst/level/Makefile
1106 gst/matroska/Makefile
1107 gst/monoscope/Makefile
1108 gst/multifile/Makefile
1109 gst/multipart/Makefile
1110 gst/replaygain/Makefile
1111 gst/rtp/Makefile
1112 gst/rtpmanager/Makefile
1113 gst/rtsp/Makefile
1114 gst/shapewipe/Makefile
1115 gst/smpte/Makefile
1116 gst/spectrum/Makefile
1117 gst/udp/Makefile
1118 gst/videobox/Makefile
1119 gst/videocrop/Makefile
1120 gst/videofilter/Makefile
1121 gst/videomixer/Makefile
1122 gst/wavenc/Makefile
1123 gst/wavparse/Makefile
1124 gst/flx/Makefile
1125 gst/y4m/Makefile
1126 ext/Makefile
1127 ext/aalib/Makefile
1128 ext/annodex/Makefile
1129 ext/cairo/Makefile
1130 ext/dv/Makefile
1131 ext/flac/Makefile
1132 ext/gdk_pixbuf/Makefile
1133 ext/jack/Makefile
1134 ext/jpeg/Makefile
1135 ext/libcaca/Makefile
1136 ext/libpng/Makefile
1137 ext/pulse/Makefile
1138 ext/raw1394/Makefile
1139 ext/shout2/Makefile
1140 ext/soup/Makefile
1141 ext/speex/Makefile
1142 ext/taglib/Makefile
1143 ext/wavpack/Makefile
1144 sys/Makefile
1145 sys/directsound/Makefile
1146 sys/oss/Makefile
1147 sys/oss4/Makefile
1148 sys/osxaudio/Makefile
1149 sys/osxvideo/Makefile
1150 sys/sunaudio/Makefile
1151 sys/v4l2/Makefile
1152 sys/waveform/Makefile
1153 sys/ximage/Makefile
1154 po/Makefile.in
1155 tests/Makefile
1156 tests/check/Makefile
1157 tests/examples/Makefile
1158 tests/examples/audiofx/Makefile
1159 tests/examples/cairo/Makefile
1160 tests/examples/equalizer/Makefile
1161 tests/examples/jack/Makefile
1162 tests/examples/level/Makefile
1163 tests/examples/pulse/Makefile
1164 tests/examples/rtp/Makefile
1165 tests/examples/shapewipe/Makefile
1166 tests/examples/spectrum/Makefile
1167 tests/examples/v4l2/Makefile
1168 tests/files/Makefile
1169 tests/icles/Makefile
1170 common/Makefile
1171 common/m4/Makefile
1172 m4/Makefile
1173 docs/Makefile
1174 docs/plugins/Makefile
1175 docs/version.entities
1176 pkgconfig/Makefile
1177 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1178 gst-plugins-good.spec
1179 )
1180
1181 dnl Create the config.h file for Visual Studio builds
1182 dnl Beware of spaces and /'s in some of the shell variable contents.
1183 sed \
1184     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1185     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1186     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1187     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1188     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1189     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1190     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1191     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1192     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1193     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1194     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1195     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1196     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1197     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1198     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1199     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1200     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1201     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1202     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1203     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1204     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1205     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1206     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1207     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1208     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1209     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1210     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1211     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1212     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1213     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1214     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1215     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1216     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1217     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1218     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1219     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1220     config.h.in >win32/common/config.h-new
1221
1222 AC_OUTPUT
1223
1224 AG_GST_OUTPUT_PLUGINS
1225 ORC_OUTPUT
1226