configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl ------------------------------------------------
   4 dnl Initialization and Versioning
   5 dnl ------------------------------------------------
   6
   7
   8 AC_INIT([libvorbis],[1.2.3],[vorbis-dev@xiph.org])
   9
  10 AC_CONFIG_SRCDIR([lib/mdct.c])
  11
  12 AC_CANONICAL_TARGET([])
  13
  14 AM_INIT_AUTOMAKE($PACKAGE_NAME,$PACKAGE_VERSION)
  15 AM_MAINTAINER_MODE
  16 AM_CONFIG_HEADER([config.h])
  17
  18 dnl Add parameters for aclocal
  19 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4")
  20
  21 dnl Library versioning
  22 dnl - library source changed -> increment REVISION
  23 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  24 dnl - interfaces added -> increment AGE
  25 dnl - interfaces removed -> AGE = 0
  26
  27 V_LIB_CURRENT=4
  28 V_LIB_REVISION=3
  29 V_LIB_AGE=4
  30
  31 VF_LIB_CURRENT=6
  32 VF_LIB_REVISION=2
  33 VF_LIB_AGE=3
  34
  35 VE_LIB_CURRENT=2
  36 VE_LIB_REVISION=6
  37 VE_LIB_AGE=0
  38
  39 AC_SUBST(V_LIB_CURRENT)
  40 AC_SUBST(V_LIB_REVISION)
  41 AC_SUBST(V_LIB_AGE)
  42 AC_SUBST(VF_LIB_CURRENT)
  43 AC_SUBST(VF_LIB_REVISION)
  44 AC_SUBST(VF_LIB_AGE)
  45 AC_SUBST(VE_LIB_CURRENT)
  46 AC_SUBST(VE_LIB_REVISION)
  47 AC_SUBST(VE_LIB_AGE)
  48
  49 dnl --------------------------------------------------
  50 dnl Check for programs
  51 dnl --------------------------------------------------
  52
  53 dnl save $CFLAGS since AC_PROG_CC likes to insert "-g -O2"
  54 dnl if $CFLAGS is blank
  55 cflags_save="$CFLAGS"
  56 AC_PROG_CC
  57 AC_PROG_CPP
  58 CFLAGS="$cflags_save"
  59
  60 AC_C_INLINE
  61
  62 AC_LIBTOOL_WIN32_DLL
  63 AC_PROG_LIBTOOL
  64 AM_PROG_CC_C_O
  65
  66 dnl latex tools for the specification document
  67 AC_ARG_ENABLE(docs,
  68         AC_HELP_STRING([--enable-docs], [build the documentation]))
  69
  70 if test "x$enable_docs" = xyes; then
  71   AC_CHECK_PROGS([PDFLATEX], pdflatex, [/bin/false])
  72   AC_CHECK_PROGS([HTLATEX], htlatex, [/bin/false])
  73   if test "x$PDFLATEX" = x/bin/false || test "x$HTLATEX" = x/bin/false; then
  74     enable_docs=no
  75     AC_MSG_WARN([Documentation will not be built!])
  76   fi
  77 fi
  78
  79 AM_CONDITIONAL(BUILD_DOCS, [test "x$enable_docs" = xyes])
  80
  81 dnl --------------------------------------------------
  82 dnl Set build flags based on environment
  83 dnl --------------------------------------------------
  84
  85 dnl Set some target options
  86
  87 cflags_save="$CFLAGS"
  88 if test -z "$GCC"; then
  89         case $host in
  90         *-*-irix*)
  91                 dnl If we're on IRIX, we wanna use cc even if gcc
  92                 dnl is there (unless the user has overriden us)...
  93                 if test -z "$CC"; then
  94                         CC=cc
  95                 fi
  96                 DEBUG="-g -signed"
  97                 CFLAGS="-O2 -w -signed"
  98                 PROFILE="-p -g3 -O2 -signed" ;;
  99         sparc-sun-solaris*)
 100                 DEBUG="-v -g"
 101                 CFLAGS="-xO4 -fast -w -fsimple -native -xcg92"
 102                 PROFILE="-v -xpg -g -xO4 -fast -native -fsimple -xcg92 -Dsuncc" ;;
 103         *)
 104                 DEBUG="-g"
 105                 CFLAGS="-O"
 106                 PROFILE="-g -p" ;;
 107         esac
 108 else
 109
 110         AC_MSG_CHECKING([GCC version])
 111         GCC_VERSION=`$CC -dumpversion`
 112         AC_MSG_RESULT([$GCC_VERSION])
 113         case $host in
 114         *86-*-linux*)
 115                 DEBUG="-g -Wall -Wextra -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 116                 CFLAGS="-O20 -ffast-math -mno-ieee-fp -D_REENTRANT -fsigned-char"
 117 #               PROFILE="-Wall -Wextra -pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char -fno-inline -static"
 118                 PROFILE="-Wall -Wextra -pg -g -O20 -ffast-math -mno-ieee-fp -D_REENTRANT -fsigned-char -fno-inline"
 119
 120                 # glibc < 2.1.3 has a serious FP bug in the math inline header
 121                 # that will cripple Vorbis.  Look to see if the magic FP stack
 122                 # clobber is missing in the mathinline header, thus indicating
 123                 # the buggy version
 124
 125                 AC_EGREP_CPP(log10.*fldlg2.*fxch,[
 126                                 #define __LIBC_INTERNAL_MATH_INLINES 1
 127                                 #define __OPTIMIZE__
 128                                 #include <math.h>
 129                                 ],bad=maybe,bad=no)
 130                 if test ${bad} = "maybe" ;then
 131                       AC_EGREP_CPP(log10.*fldlg2.*fxch.*st\([[0123456789]]*\),
 132                                         [
 133                                         #define __LIBC_INTERNAL_MATH_INLINES 1
 134                                         #define __OPTIMIZE__
 135                                         #include <math.h>
 136                                         ],bad=no,bad=yes)
 137                 fi
 138                 if test ${bad} = "yes" ;then
 139  AC_MSG_WARN([                                                        ])
 140  AC_MSG_WARN([********************************************************])
 141  AC_MSG_WARN([* The glibc headers on this machine have a serious bug *])
 142  AC_MSG_WARN([* in /usr/include/bits/mathinline.h  This bug affects  *])
 143  AC_MSG_WARN([* all floating point code, not just Ogg, built on this *])
 144  AC_MSG_WARN([* machine.  Upgrading to glibc 2.1.3 is strongly urged *])
 145  AC_MSG_WARN([* to correct the problem.  Note that upgrading glibc   *])
 146  AC_MSG_WARN([* will not fix any previously built programs; this is  *])
 147  AC_MSG_WARN([* a compile-time time bug.                             *])
 148  AC_MSG_WARN([* To work around the problem for this build of Ogg,    *])
 149  AC_MSG_WARN([* autoconf is disabling all math inlining.  This will  *])
 150  AC_MSG_WARN([* hurt Ogg performace but is necessary for an Ogg that *])
 151  AC_MSG_WARN([* will actually work.  Once glibc is upgraded, rerun   *])
 152  AC_MSG_WARN([* configure and make to build with inlining.           *])
 153  AC_MSG_WARN([********************************************************])
 154  AC_MSG_WARN([                                                        ])
 155
 156                 CFLAGS=${OPT}" -D__NO_MATH_INLINES"
 157                 PROFILE=${PROFILE}" -D__NO_MATH_INLINES"
 158                 fi;;
 159         powerpc-*-linux*)
 160                 DEBUG="-g -Wall -Wextra -D_REENTRANT -D__NO_MATH_INLINES"
 161                 CFLAGS="-O3 -Wall -Wextra -ffast-math -mfused-madd -mcpu=750 -D_REENTRANT"
 162                 PROFILE="-pg -g -O3 -ffast-math -mfused-madd -mcpu=750 -D_REENTRANT";;
 163         *-*-linux*)
 164                 DEBUG="-g -Wall -Wextra -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 165                 CFLAGS="-O20 -Wall -Wextra -ffast-math -D_REENTRANT -fsigned-char"
 166                 PROFILE="-pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char";;
 167         sparc-sun-*)
 168                 sparc_cpu=""
 169                 AC_MSG_CHECKING([if gcc supports -mv8])
 170                 old_cflags="$CFLAGS"
 171                 CFLAGS="$CFLAGS -mv8"
 172                 AC_TRY_COMPILE(, [return 0;], [
 173                         AC_MSG_RESULT([yes])
 174                         sparc_cpu="-mv8"
 175                 ])
 176                 CFLAGS="$old_cflags"
 177                 DEBUG="-g -Wall -Wextra -D__NO_MATH_INLINES -fsigned-char $sparc_cpu"
 178                 CFLAGS="-O20 -Wall -Wextra -ffast-math -D__NO_MATH_INLINES -fsigned-char $sparc_cpu"
 179                 PROFILE="-pg -g -O20 -D__NO_MATH_INLINES -fsigned-char $sparc_cpu" ;;
 180         *-*-darwin*)
 181                 DEBUG="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -O0 -fsigned-char"
 182                 CFLAGS="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -O4 -ffast-math -fsigned-char"
 183                 PROFILE="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -pg -O4 -ffast-math -fsigned-char";;
 184         *-*-os2*)
 185                 # Use -W instead of -Wextra because gcc on OS/2 is an old version.
 186                 DEBUG="-g -Wall -W -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 187                 CFLAGS="-O20 -Wall -W -ffast-math -D_REENTRANT -fsigned-char"
 188                 PROFILE="-pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char";;
 189         *)
 190                 DEBUG="-g -Wall -Wextra -D__NO_MATH_INLINES -fsigned-char"
 191                 CFLAGS="-O20 -Wall -Wextra -D__NO_MATH_INLINES -fsigned-char"
 192                 PROFILE="-O20 -g -pg -D__NO_MATH_INLINES -fsigned-char" ;;
 193         esac
 194
 195         AC_ADD_CFLAGS([-Wdeclaration-after-statement])
 196 fi
 197 CFLAGS="$CFLAGS $cflags_save"
 198
 199 dnl --------------------------------------------------
 200 dnl Check for headers
 201 dnl --------------------------------------------------
 202
 203 AC_CHECK_HEADER(memory.h,CFLAGS="$CFLAGS -DUSE_MEMORY_H",:)
 204
 205 dnl --------------------------------------------------
 206 dnl Check for typedefs, structures, etc
 207 dnl --------------------------------------------------
 208
 209 dnl none
 210
 211 dnl --------------------------------------------------
 212 dnl Check for libraries
 213 dnl --------------------------------------------------
 214
 215 AC_CHECK_LIB(m, cos, VORBIS_LIBS="-lm", VORBIS_LIBS="")
 216 AC_CHECK_LIB(pthread, pthread_create, pthread_lib="-lpthread", :)
 217
 218 PKG_PROG_PKG_CONFIG
 219
 220 HAVE_OGG=no
 221 if test "x$PKG_CONFIG" != "x"
 222 then
 223   PKG_CHECK_MODULES(OGG, ogg >= 1.0, HAVE_OGG=yes, HAVE_OGG=no)
 224 fi
 225 if test "x$HAVE_OGG" = "xno"
 226 then
 227   dnl fall back to the old school test
 228   XIPH_PATH_OGG(, AC_MSG_ERROR(must have Ogg installed!))
 229   libs_save=$LIBS
 230   LIBS="$OGG_LIBS $VORBIS_LIBS"
 231   AC_CHECK_FUNC(oggpack_writealign, , AC_MSG_ERROR(Ogg >= 1.0 required !))
 232   LIBS=$libs_save
 233 fi
 234
 235 dnl --------------------------------------------------
 236 dnl Check for library functions
 237 dnl --------------------------------------------------
 238
 239 AC_FUNC_ALLOCA
 240 AC_FUNC_MEMCMP
 241
 242 dnl --------------------------------------------------
 243 dnl Do substitutions
 244 dnl --------------------------------------------------
 245
 246 AC_SUBST(VORBIS_LIBS)
 247 AC_SUBST(DEBUG)
 248 AC_SUBST(PROFILE)
 249 AC_SUBST(pthread_lib)
 250
 251 dnl The following line causes the libtool distributed with the source
 252 dnl to be replaced if the build system has a more recent version.
 253 AC_SUBST(LIBTOOL_DEPS)
 254
 255 AC_OUTPUT([
 256 Makefile
 257 m4/Makefile
 258 lib/Makefile
 259 lib/modes/Makefile
 260 lib/books/Makefile
 261 lib/books/coupled/Makefile
 262 lib/books/uncoupled/Makefile
 263 lib/books/floor/Makefile
 264 doc/Makefile doc/vorbisfile/Makefile doc/vorbisenc/Makefile
 265 include/Makefile include/vorbis/Makefile
 266 examples/Makefile
 267 test/Makefile
 268 vq/Makefile
 269 libvorbis.spec
 270 vorbis.pc
 271 vorbisenc.pc
 272 vorbisfile.pc
 273 vorbis-uninstalled.pc
 274 vorbisenc-uninstalled.pc
 275 vorbisfile-uninstalled.pc
 276 ])