configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [6])
   6 m4_define([dbus_micro_version], [255])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=10
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=2
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=7
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 154 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 155 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 156 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 157 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 158 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 159 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 160
 161 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 162 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 163 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 164 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 165 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 166 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 167 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 168 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 169 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 170 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 171 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 172
 173 AC_ARG_ENABLE([embedded-tests],
 174   AS_HELP_STRING([--enable-embedded-tests],
 175     [enable unit test code in the library and binaries]),
 176   [], [enable_embedded_tests=$enable_developer])
 177 AC_ARG_ENABLE([modular-tests],
 178   AS_HELP_STRING([--enable-modular-tests],
 179     [enable modular regression tests (requires GLib)]),
 180   [], [enable_modular_tests=auto])
 181 # --enable-tests overrides both --enable-embedded-tests and
 182 # --enable-modular-tests
 183 AC_ARG_ENABLE([tests],
 184   AS_HELP_STRING([--enable-tests],
 185     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 186   [
 187   if test "x$enableval" = xyes; then
 188     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 189     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 190   fi
 191   enable_embedded_tests=$enableval
 192   enable_modular_tests=$enableval
 193   ],
 194   [])
 195
 196 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 197 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 198 # name for this.
 199 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 200 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 201   [test "x$enable_embedded_tests" = xyes])
 202 if test "x$enable_embedded_tests" = xyes; then
 203     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 204       [Define to build test code into the library and binaries])
 205     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 206       [Define to build test code into the library and binaries])
 207 fi
 208
 209 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 210 # These use GTest, from GLib, because life's too short. They're enabled by
 211 # default (unless you don't have GLib), because they don't bloat the library
 212 # or binaries.
 213
 214 with_glib=yes
 215
 216 if test "x$enable_modular_tests" != xno; then
 217   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 218     [],
 219     [if test "x$enable_modular_tests" = xyes; then
 220       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 221       AC_MSG_ERROR([$GLIB_ERRORS])
 222     else # assumed to be "auto"
 223       with_glib=no
 224     fi])
 225   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 226   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 227     [],
 228     [if test "x$enable_modular_tests" = xyes; then
 229       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 230       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 231     else # assumed to be "auto"
 232       with_glib=no
 233     fi])
 234 fi
 235 if test "x$enable_modular_tests" != xno; then
 236   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 237     [Define to build independent test binaries])
 238 fi
 239 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 240   [test "x$enable_modular_tests" != xno])
 241
 242 if test "x$with_glib" != xno; then
 243   AC_DEFINE([DBUS_WITH_GLIB], [1],
 244     [Define if GLib, GObject, GIO are available])
 245 fi
 246 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 247
 248 AC_ARG_ENABLE([installed-tests],
 249   AS_HELP_STRING([--enable-installed-tests],
 250     [enable unit test code in the library and binaries]),
 251   [], [enable_installed_tests=no])
 252 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 253   [test "x$enable_installed_tests" = xyes])
 254
 255 if test "x$enable_tests" = xyes; then
 256   # full test coverage is required, Python is a hard dependency
 257   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 258   AM_PATH_PYTHON([2.6])
 259   AC_MSG_CHECKING([for Python modules for full test coverage])
 260   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 261     AC_MSG_RESULT([yes])
 262   else
 263     AC_MSG_RESULT([no])
 264     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 265   fi
 266 else
 267   # --enable-tests not given: do not abort if Python is missing
 268   AM_PATH_PYTHON([2.6], [], [:])
 269 fi
 270
 271 if test x$enable_verbose_mode = xyes; then
 272     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 273 fi
 274
 275 if test x$enable_asserts = xno; then
 276     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 277     DISABLE_UNUSED_WARNINGS="unused-label"
 278     R_DYNAMIC_LDFLAG=""
 279 else
 280     # -rdynamic is needed for glibc's backtrace_symbols to work.
 281     # No clue how much overhead this adds, but it's useful
 282     # to do this on any assertion failure,
 283     # so for now it's enabled anytime asserts are (currently not
 284     # in production builds).
 285
 286     # To get -rdynamic you pass -export-dynamic to libtool.
 287     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 288     R_DYNAMIC_LDFLAG=-export-dynamic
 289 fi
 290 AC_SUBST(R_DYNAMIC_LDFLAG)
 291
 292 if test x$enable_checks = xno; then
 293     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 294     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 295     DISABLE_UNUSED_WARNINGS="unused-label"
 296 fi
 297
 298 if test x$enable_userdb_cache = xyes; then
 299     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 300 fi
 301
 302 if test x$enable_compiler_coverage = xyes; then
 303      ## so that config.h changes when you toggle gcov support
 304      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 305 fi
 306
 307 # glibc21.m4 serial 3
 308 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 309 dnl This file is free software; the Free Software Foundation
 310 dnl gives unlimited permission to copy and/or distribute it,
 311 dnl with or without modifications, as long as this notice is preserved.
 312
 313 # Test for the GNU C Library, version 2.1 or newer.
 314 # From Bruno Haible.
 315
 316 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 317   ac_cv_gnu_library_2_1,
 318   [AC_EGREP_CPP([Lucky GNU user],
 319     [
 320 #include <features.h>
 321 #ifdef __GNU_LIBRARY__
 322  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 323   Lucky GNU user
 324  #endif
 325 #endif
 326     ],
 327     ac_cv_gnu_library_2_1=yes,
 328     ac_cv_gnu_library_2_1=no)
 329   ]
 330 )
 331
 332 #### Integer sizes
 333
 334 AC_CHECK_SIZEOF(char)
 335 AC_CHECK_SIZEOF(short)
 336 AC_CHECK_SIZEOF(long)
 337 AC_CHECK_SIZEOF(int)
 338 AC_CHECK_SIZEOF(void *)
 339 AC_CHECK_SIZEOF(long long)
 340 AC_CHECK_SIZEOF(__int64)
 341
 342 AC_ARG_WITH([64-bit],
 343   [AS_HELP_STRING([--without-64-bit],
 344     [If you have to use this option, please report it as a bug])],
 345   [],
 346   [with_64_bit=yes])
 347
 348 ### See what our 64 bit type is called
 349 AC_MSG_CHECKING([64-bit integer type])
 350
 351 case 8 in
 352 $ac_cv_sizeof_int)
 353   dbusint64=int
 354   dbusint64_constant='(val)'
 355   dbusuint64_constant='(val)'
 356   dbusint64_printf_modifier='""'
 357   ;;
 358 $ac_cv_sizeof_long)
 359   dbusint64=long
 360   dbusint64_constant='(val##L)'
 361   dbusuint64_constant='(val##UL)'
 362   dbusint64_printf_modifier='"l"'
 363   ;;
 364 $ac_cv_sizeof_long_long)
 365   dbusint64='long long'
 366   dbusint64_constant='(val##LL)'
 367   dbusuint64_constant='(val##ULL)'
 368   # Ideally we discover what the format is, but this is
 369   # only used in verbose mode, so eh...
 370   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 371     dbusint64_printf_modifier='"ll"'
 372   fi
 373   ;;
 374 $ac_cv_sizeof___int64)
 375   dbusint64=__int64
 376   dbusint64_constant='(val##i64)'
 377   dbusuint64_constant='(val##ui64)'
 378   # See above case
 379   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 380     dbusint64_printf_modifier='"ll"'
 381   fi
 382   ;;
 383 esac
 384
 385 AS_IF(
 386   [test "x$with_64_bit" = xno],
 387   [
 388         DBUS_INT64_TYPE="no_int64_type_detected"
 389         DBUS_HAVE_INT64=0
 390         DBUS_INT64_CONSTANT=
 391         DBUS_UINT64_CONSTANT=
 392         AC_MSG_RESULT([disabled via --without-64-bit])
 393   ],
 394   dnl else if
 395   [test -z "$dbusint64"],
 396   [AC_MSG_RESULT([not found])
 397   AC_MSG_ERROR([Could not find a 64-bit integer type.
 398
 399 Please report a bug here with details of your platform and compiler:
 400
 401     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 402
 403 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 404 the option "--without-64-bit".
 405
 406 This option is likely to be removed in future, unless you report that your
 407 platform needs it.])
 408   ],
 409   dnl else
 410   [
 411         DBUS_INT64_TYPE="$dbusint64"
 412         DBUS_HAVE_INT64=1
 413         DBUS_INT64_CONSTANT="$dbusint64_constant"
 414         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 415         if test x"$dbusint64_printf_modifier" != x; then
 416                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 417         fi
 418         AC_MSG_RESULT($DBUS_INT64_TYPE)
 419   ])
 420
 421 AC_SUBST(DBUS_INT64_TYPE)
 422 AC_SUBST(DBUS_INT64_CONSTANT)
 423 AC_SUBST(DBUS_UINT64_CONSTANT)
 424 AC_SUBST(DBUS_HAVE_INT64)
 425
 426 ### see what 32-bit int is called
 427 AC_MSG_CHECKING([32-bit integer type])
 428
 429 case 4 in
 430 $ac_cv_sizeof_short)
 431   dbusint32=short
 432   ;;
 433 $ac_cv_sizeof_int)
 434   dbusint32=int
 435   ;;
 436 $ac_cv_sizeof_long)
 437   dbusint32=long
 438   ;;
 439 esac
 440
 441 if test -z "$dbusint32" ; then
 442         DBUS_INT32_TYPE="no_int32_type_detected"
 443         AC_MSG_ERROR([No 32-bit integer type found])
 444 else
 445         DBUS_INT32_TYPE="$dbusint32"
 446         AC_MSG_RESULT($DBUS_INT32_TYPE)
 447 fi
 448
 449 AC_SUBST(DBUS_INT32_TYPE)
 450
 451 ### see what 16-bit int is called
 452 AC_MSG_CHECKING([16-bit integer type])
 453
 454 case 2 in
 455 $ac_cv_sizeof_short)
 456   dbusint16=short
 457   ;;
 458 $ac_cv_sizeof_int)
 459   dbusint16=int
 460   ;;
 461 esac
 462
 463 if test -z "$dbusint16" ; then
 464         DBUS_INT16_TYPE="no_int16_type_detected"
 465         AC_MSG_ERROR([No 16-bit integer type found])
 466 else
 467         DBUS_INT16_TYPE="$dbusint16"
 468         AC_MSG_RESULT($DBUS_INT16_TYPE)
 469 fi
 470
 471 AC_SUBST(DBUS_INT16_TYPE)
 472
 473 ## byte order
 474 case $host_os in
 475         darwin*)
 476                 # check at compile-time, so that it is possible to build universal
 477                 # (with multiple architectures at once on the compile line)
 478                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 479                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 480                         #if defined(__BIG_ENDIAN__)
 481                         #define WORDS_BIGENDIAN 1
 482                         #endif
 483                 ])
 484                 ;;
 485         *)
 486                 AC_C_BIGENDIAN
 487                 ;;
 488 esac
 489
 490 dnl **********************************
 491 dnl *** va_copy checks (from GLib) ***
 492 dnl **********************************
 493 dnl we currently check for all three va_copy possibilities, so we get
 494 dnl all results in config.log for bug reports.
 495 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 496         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 497 #include <stdlib.h>
 498         static void f (int i, ...) {
 499         va_list args1, args2;
 500         va_start (args1, i);
 501         va_copy (args2, args1);
 502         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 503           exit (1);
 504         va_end (args1); va_end (args2);
 505         }
 506         int main() {
 507           f (0, 42);
 508           return 0;
 509         }])],
 510         [dbus_cv_va_copy=yes],
 511         [dbus_cv_va_copy=no])
 512 ])
 513 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 514         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 515 #include <stdlib.h>
 516         static void f (int i, ...) {
 517         va_list args1, args2;
 518         va_start (args1, i);
 519         __va_copy (args2, args1);
 520         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 521           exit (1);
 522         va_end (args1); va_end (args2);
 523         }
 524         int main() {
 525           f (0, 42);
 526           return 0;
 527         }])],
 528         [dbus_cv___va_copy=yes],
 529         [dbus_cv___va_copy=no])
 530 ])
 531
 532 if test "x$dbus_cv_va_copy" = "xyes"; then
 533   dbus_va_copy_func=va_copy
 534 else if test "x$dbus_cv___va_copy" = "xyes"; then
 535   dbus_va_copy_func=__va_copy
 536 fi
 537 fi
 538
 539 if test -n "$dbus_va_copy_func"; then
 540   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 541 fi
 542
 543 AC_LANG_PUSH(C)
 544 AC_CACHE_CHECK([whether va_lists can be copied by value],
 545         dbus_cv_va_val_copy,
 546         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 547 [[
 548         #include <stdarg.h>
 549         #include <stdlib.h>
 550 ]],
 551 [[
 552         static void f (int i, ...) {
 553         va_list args1, args2;
 554         va_start (args1, i);
 555         args2 = args1;
 556         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 557           exit (1);
 558         va_end (args1); va_end (args2);
 559         }
 560         int main() {
 561           f (0, 42);
 562           return 0;
 563         }
 564 ]])],
 565         [dbus_cv_va_val_copy=yes],
 566         [dbus_cv_va_val_copy=no],
 567         [dbus_cv_va_val_copy=yes])
 568 ])
 569 AC_LANG_POP(C)
 570
 571 if test "x$dbus_cv_va_val_copy" = "xno"; then
 572   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 573 fi
 574
 575
 576 #### Atomic integers
 577
 578 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 579   dbus_cv_sync_sub_and_fetch,
 580   [AC_LINK_IFELSE([
 581      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 582      [dbus_cv_sync_sub_and_fetch=yes],
 583      [dbus_cv_sync_sub_and_fetch=no])
 584   ])
 585
 586 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 587    have_sync=1
 588 else
 589    have_sync=0
 590 fi
 591
 592 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 593
 594 #### Various functions
 595 AC_SEARCH_LIBS(socket,[socket network])
 596 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 597
 598 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid)
 599
 600 AC_CHECK_HEADERS([syslog.h])
 601 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 602   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 603 fi
 604
 605 #### Check for broken poll; taken from Glib's configure
 606
 607 AC_MSG_CHECKING([for broken poll])
 608 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 609     #include <stdlib.h>
 610     #include <fcntl.h>
 611     #include <poll.h>
 612     #ifdef HAVE_SYS_POLL_H
 613     #include <sys/poll.h>
 614     #endif
 615     int main(void) {
 616       struct pollfd fds[1];
 617       int fd;
 618       fd = open("/dev/null", 1);
 619       fds[0].fd = fd;
 620       fds[0].events = POLLIN;
 621       fds[0].revents = 0;
 622       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 623             exit(1);  /* Does not work for devices -- fail */
 624       }
 625       exit(0);
 626     }]])],
 627   [broken_poll=no],
 628   [broken_poll=yes
 629    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 630   [broken_poll="no (cross compiling)"])
 631 AC_MSG_RESULT($broken_poll)
 632
 633 AC_MSG_CHECKING(for dirfd)
 634 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 635 #include <sys/types.h>
 636 #include <dirent.h>
 637 ]], [[
 638 DIR *dirp;
 639 dirp = opendir(".");
 640 dirfd(dirp);
 641 closedir(dirp);
 642 ]])],
 643 [dbus_have_dirfd=yes],
 644 [dbus_have_dirfd=no])
 645 AC_MSG_RESULT($dbus_have_dirfd)
 646 if test "$dbus_have_dirfd" = yes; then
 647         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 648 else
 649         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 650         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 651 #include <sys/types.h>
 652 #include <dirent.h>
 653         ]], [[
 654 DIR *dirp;
 655 int fd;
 656 dirp = opendir(".");
 657 fd = dirp->dd_fd;
 658 closedir(dirp);
 659         ]])],
 660         [dbus_have_ddfd=yes],
 661         [dbus_have_ddfd=no])
 662         AC_MSG_RESULT($dbus_have_ddfd)
 663         if test "$dbus_have_ddfd" = yes; then
 664                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 665         fi
 666 fi
 667
 668 AC_CHECK_HEADERS(sys/resource.h)
 669
 670 AC_CHECK_HEADERS(dirent.h)
 671
 672 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 673
 674 AC_CHECK_HEADERS(errno.h)
 675
 676 AC_CHECK_HEADERS(signal.h)
 677
 678 AC_CHECK_HEADERS(locale.h)
 679
 680 AC_CHECK_HEADERS(byteswap.h)
 681
 682 AC_CHECK_HEADERS(unistd.h)
 683
 684 AC_CHECK_HEADERS(ws2tcpip.h)
 685
 686 AC_CHECK_HEADERS(wspiapi.h)
 687
 688 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 689 #
 690 case $host_os in
 691     solaris*)
 692        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 693 esac
 694
 695 # checking for a posix version of getpwnam_r
 696 # if we are cross compiling and can not run the test
 697 # assume getpwnam_r is the posix version
 698 # it is up to the person cross compiling to change
 699 # this behavior if desired
 700 AC_LANG_PUSH(C)
 701 AC_CACHE_CHECK([for posix getpwnam_r],
 702                 ac_cv_func_posix_getpwnam_r,
 703                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 704 [[
 705 #include <errno.h>
 706 #include <pwd.h>
 707 ]],
 708 [[
 709     char buffer[10000];
 710     struct passwd pwd, *pwptr = &pwd;
 711     int error;
 712     errno = 0;
 713     error = getpwnam_r ("", &pwd, buffer,
 714                         sizeof (buffer), &pwptr);
 715    return (error < 0 && errno == ENOSYS)
 716            || error == ENOSYS;
 717 ]])],
 718         [ac_cv_func_posix_getpwnam_r=yes],
 719         [ac_cv_func_posix_getpwnam_r=no],
 720         [ac_cv_func_posix_getpwnam_r=yes]
 721 )])
 722 AC_LANG_POP(C)
 723
 724 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 725         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 726                 [Have POSIX function getpwnam_r])
 727 else
 728         AC_CACHE_CHECK([for nonposix getpwnam_r],
 729                 ac_cv_func_nonposix_getpwnam_r,
 730                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 731                         struct passwd pwd;
 732                         getpwnam_r ("", &pwd, buffer,
 733                                         sizeof (buffer));]])],
 734                         [ac_cv_func_nonposix_getpwnam_r=yes],
 735                         [ac_cv_func_nonposix_getpwnam_r=no])])
 736                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 737                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 738                         [Have non-POSIX function getpwnam_r])
 739         fi
 740 fi
 741
 742 dnl check for socklen_t
 743 AC_MSG_CHECKING(whether socklen_t is defined)
 744 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 745 #include <sys/types.h>
 746 #include <sys/socket.h>
 747 #include <netdb.h>
 748 ]], [[
 749 socklen_t foo;
 750 foo = 1;
 751 ]])],
 752 [dbus_have_socklen_t=yes],
 753 [dbus_have_socklen_t=no])
 754 AC_MSG_RESULT($dbus_have_socklen_t)
 755
 756 if test "x$dbus_have_socklen_t" = "xyes"; then
 757     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 758 fi
 759
 760 dnl check for writev header and writev function so we're
 761 dnl good to go if HAVE_WRITEV gets defined.
 762 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 763
 764 dnl needed on darwin for NAME_MAX
 765 AC_CHECK_HEADERS(sys/syslimits.h)
 766
 767 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 768 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 769 #include <sys/socket.h> ]])
 770
 771 dnl check for flavours of varargs macros (test from GLib)
 772 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 773 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 774 int a(int p1, int p2, int p3);
 775 #define call_a(...) a(1,__VA_ARGS__)
 776 call_a(2,3);
 777 ]])],
 778 [dbus_have_iso_c_varargs=yes],
 779 [dbus_have_iso_c_varargs=no])
 780 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 781
 782 AC_MSG_CHECKING(for GNUC varargs macros)
 783 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 784 int a(int p1, int p2, int p3);
 785 #define call_a(params...) a(1,params)
 786 call_a(2,3);
 787 ]])],
 788 [dbus_have_gnuc_varargs=yes],
 789 [dbus_have_gnuc_varargs=no])
 790 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 791
 792 dnl Output varargs tests
 793 if test x$dbus_have_iso_c_varargs = xyes; then
 794     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 795 fi
 796 if test x$dbus_have_gnuc_varargs = xyes; then
 797     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 798 fi
 799
 800 dnl Check for various credentials.
 801 AC_MSG_CHECKING(for struct cmsgcred)
 802 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 803 #include <sys/types.h>
 804 #include <sys/socket.h>
 805 ]], [[
 806 struct cmsgcred cred;
 807
 808 cred.cmcred_pid = 0;
 809 ]])],
 810 [dbus_have_struct_cmsgcred=yes],
 811 [dbus_have_struct_cmsgcred=no])
 812 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 813
 814 if test x$dbus_have_struct_cmsgcred = xyes; then
 815     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 816 fi
 817
 818 AC_CHECK_FUNCS(getpeerucred getpeereid)
 819
 820 AC_CHECK_FUNCS(pipe2 accept4)
 821
 822 #### Abstract sockets
 823
 824 if test x$enable_abstract_sockets = xauto; then
 825 AC_LANG_PUSH(C)
 826 warn_on_xcompile=no
 827 AC_CACHE_CHECK([abstract socket namespace],
 828                 ac_cv_have_abstract_sockets,
 829                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 830 [[
 831 #include <sys/types.h>
 832 #include <stdlib.h>
 833 #include <string.h>
 834 #include <stdio.h>
 835 #include <sys/socket.h>
 836 #include <sys/un.h>
 837 #include <errno.h>
 838 ]],
 839 [[
 840   size_t slen;
 841   int listen_fd;
 842   struct sockaddr_un addr;
 843
 844   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 845
 846   if (listen_fd < 0)
 847     {
 848       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 849       exit (1);
 850     }
 851
 852   memset (&addr, '\0', sizeof (addr));
 853   addr.sun_family = AF_UNIX;
 854   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 855   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 856    * beginning.
 857    */
 858   slen = SUN_LEN(&addr);
 859   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 860
 861   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 862     {
 863        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 864                 strerror (errno));
 865        exit (1);
 866     }
 867   else
 868     exit (0);
 869 ]])],
 870               [ac_cv_have_abstract_sockets=yes],
 871               [ac_cv_have_abstract_sockets=no],
 872               [
 873                 ac_cv_have_abstract_sockets=no
 874                 warn_on_xcompile=yes
 875               ]
 876 )])
 877 if test x$warn_on_xcompile = xyes ; then
 878   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 879 fi
 880 AC_LANG_POP(C)
 881 fi
 882
 883 if test x$enable_abstract_sockets = xyes; then
 884     if test x$ac_cv_have_abstract_sockets = xno; then
 885         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 886     fi
 887 fi
 888
 889 if test x$enable_abstract_sockets = xno; then
 890    ac_cv_have_abstract_sockets=no;
 891 fi
 892
 893 if test x$ac_cv_have_abstract_sockets = xyes ; then
 894    DBUS_PATH_OR_ABSTRACT=abstract
 895    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 896 else
 897    DBUS_PATH_OR_ABSTRACT=path
 898 fi
 899
 900 # this is used in addresses to prefer abstract, e.g.
 901 # unix:path=/foo or unix:abstract=/foo
 902 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 903
 904 PKG_PROG_PKG_CONFIG
 905
 906 #### Sort out XML library
 907
 908 # see what we have
 909 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 910              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 911              have_expat=false)
 912
 913 # see what we want to use
 914 dbus_use_libxml=false
 915 dbus_use_expat=false
 916 if test x$with_xml = xexpat; then
 917         if ! $have_expat ; then
 918            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 919         fi
 920         dbus_use_expat=true
 921 elif test x$with_xml = xlibxml; then
 922         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 923         if ! $have_libxml ; then
 924            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 925         fi
 926         dbus_use_libxml=true
 927 else
 928         ### expat is the default because libxml can't currently survive
 929         ### our brutal OOM-handling unit test setup.
 930         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 931         if test x$have_expat = xfalse; then
 932                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 933         fi
 934         ### By default, only use Expat since it's tested and known to work.  If you're a
 935         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 936         ### if your OS is built around libxml, that's another case.
 937         dbus_use_expat=true
 938 fi
 939
 940 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 941 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 942
 943 if $dbus_use_expat; then
 944    XML_LIBS=-lexpat
 945    XML_CFLAGS=
 946 fi
 947 if $dbus_use_libxml; then
 948    XML_LIBS=$LIBXML_LIBS
 949    XML_CFLAGS=$LIBXML_CFLAGS
 950 fi
 951 AC_SUBST([XML_CFLAGS])
 952 AC_SUBST([XML_LIBS])
 953
 954 # Thread lib detection
 955 AC_ARG_VAR([THREAD_LIBS])
 956 save_libs="$LIBS"
 957 LIBS="$LIBS $THREAD_LIBS"
 958
 959 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 960
 961 # Don't do these automatic checks if the user set THREAD_LIBS on the
 962 # configure command-line. If they did, we assume they're right.
 963 #
 964 # We also don't do these checks on Windows, because you don't need magical
 965 # linker flags to have threading support there.
 966 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 967   [
 968     # Mandatory pthread functions. In principle, some of these could be made
 969     # optional if there are platforms that don't have them.
 970     #
 971     # Currently, we only look in -lpthread.
 972     # In principle we might need to look in -lpthreads, -lthreads, ...
 973     # as well - please file a bug if your platform needs this.
 974     AC_SEARCH_LIBS([pthread_cond_timedwait],
 975         [pthread],
 976         [THREAD_LIBS="$LIBS"],
 977         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 978         [])
 979     AC_SEARCH_LIBS([pthread_mutexattr_init],
 980         [pthread],
 981         [THREAD_LIBS="$LIBS"],
 982         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 983         [])
 984     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 985         [pthread],
 986         [THREAD_LIBS="$LIBS"],
 987         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 988         [])
 989
 990     # Optional, for monotonic clocks. Because it's optional, this check
 991     # is non-fatal if we don't find it.
 992     AC_SEARCH_LIBS([pthread_condattr_setclock],
 993         [pthread],
 994         [THREAD_LIBS="$LIBS"])
 995
 996     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 997       [
 998         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 999         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1000         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1001 [[#include <time.h>
1002 #include <pthread.h>
1003 ]], [[
1004 struct timespec monotonic_timer;
1005 pthread_condattr_t attr;
1006 pthread_condattr_init (&attr);
1007 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
1008 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
1009 ]])],
1010             [have_clock_monotonic=true],
1011             [have_clock_monotonic=false])
1012         AS_IF([test x$have_clock_monotonic = xtrue],
1013           [
1014             AC_MSG_RESULT([found])
1015             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
1016           ],
1017           [AC_MSG_RESULT([not found])])
1018       ]) dnl have pthread_condattr_setclock
1019   ]) dnl on Unix
1020
1021 LIBS="$save_libs"
1022
1023 AC_SUBST([THREAD_LIBS])
1024
1025 # SELinux detection
1026 if test x$enable_selinux = xno ; then
1027     have_selinux=no;
1028 else
1029     # See if we have SELinux library
1030     AC_CHECK_LIB(selinux, is_selinux_enabled,
1031                  have_selinux=yes, have_selinux=no)
1032
1033     # see if we have the SELinux header with the new D-Bus stuff in it
1034     if test x$have_selinux = xyes ; then
1035         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
1036         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
1037                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
1038                             #else
1039                             #error DBUS__ACQUIRE_SVC not defined
1040                             #endif]])],
1041                           [have_selinux=yes],
1042                           [have_selinux=no])
1043         AC_MSG_RESULT($have_selinux)
1044     fi
1045
1046     if test x$enable_selinux = xauto ; then
1047         if test x$have_selinux = xno ; then
1048                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1049         fi
1050     else
1051         if test x$have_selinux = xno ; then
1052                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1053         fi
1054     fi
1055 fi
1056
1057 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1058
1059 if test x$have_selinux = xyes ; then
1060     # the selinux code creates threads
1061     # which requires libpthread even on linux
1062     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1063                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1064
1065     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1066     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1067 else
1068     SELINUX_LIBS=
1069 fi
1070
1071 # inotify checks
1072 if test x$enable_inotify = xno ; then
1073     have_inotify=no;
1074 else
1075     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1076 fi
1077
1078 dnl check if inotify backend is enabled
1079 if test x$have_inotify = xyes; then
1080    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1081    AC_CHECK_FUNCS(inotify_init1)
1082 fi
1083
1084 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1085
1086 # dnotify checks
1087 if test x$enable_dnotify = xno ; then
1088     have_dnotify=no;
1089 else
1090     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1091         have_dnotify=yes;
1092     else
1093         have_dnotify=no;
1094     fi
1095 fi
1096
1097 dnl check if dnotify backend is enabled
1098 if test x$have_dnotify = xyes; then
1099    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1100 fi
1101
1102 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1103
1104 # For simplicity, we require the userland API for epoll_create1 at
1105 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1106 # not to have it at runtime.
1107 AC_ARG_ENABLE([epoll],
1108               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1109               [enable_epoll=$enableval], [enable_epoll=auto])
1110 if test x$enable_epoll = xno; then
1111     have_linux_epoll=no
1112 else
1113     AC_MSG_CHECKING([for Linux epoll(4)])
1114     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1115         [
1116         #ifndef __linux__
1117         #error This is not Linux
1118         #endif
1119         #include <sys/epoll.h>
1120         ],
1121         [epoll_create1 (EPOLL_CLOEXEC);])],
1122         [have_linux_epoll=yes],
1123         [have_linux_epoll=no])
1124     AC_MSG_RESULT([$have_linux_epoll])
1125 fi
1126 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1127     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1128 fi
1129 if test x$have_linux_epoll = xyes; then
1130   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1131 fi
1132 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1133
1134 # kqueue checks
1135 if test x$enable_kqueue = xno ; then
1136     have_kqueue=no
1137 else
1138     have_kqueue=yes
1139     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1140     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1141
1142     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1143         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1144     fi
1145 fi
1146
1147 dnl check if kqueue backend is enabled
1148 if test x$have_kqueue = xyes; then
1149    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1150 fi
1151
1152 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1153
1154 # launchd checks
1155 if test x$enable_launchd = xno ; then
1156     have_launchd=no
1157 else
1158     have_launchd=yes
1159     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1160     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1161     if test "x$LAUNCHCTL" = "x"; then
1162         have_launchd=no
1163     fi
1164
1165     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1166         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1167     fi
1168 fi
1169
1170 dnl check if launchd is enabled
1171 if test x$have_launchd = xyes; then
1172     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1173 fi
1174
1175 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1176
1177 #### Directory to place launchd agent file
1178 if test "x$with_launchd_agent_dir" = "x"; then
1179    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1180 else
1181    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1182 fi
1183
1184 AC_SUBST(LAUNCHD_AGENT_DIR)
1185
1186 dnl console owner file
1187 if test x$enable_console_owner_file = xno ; then
1188     have_console_owner_file=no;
1189 else
1190     case $host_os in
1191     solaris*)
1192         have_console_owner_file=yes;
1193         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1194         ;;
1195     *)
1196         have_console_owner_file=no;;
1197     esac
1198 fi
1199
1200 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1201
1202 dnl systemd detection
1203 if test x$enable_systemd = xno ; then
1204     have_systemd=no;
1205 else
1206     PKG_CHECK_MODULES(SYSTEMD,
1207         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1208         have_systemd=yes,
1209         have_systemd=no)
1210 fi
1211
1212 if test x$have_systemd = xyes; then
1213     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1214 fi
1215
1216 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1217     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1218 fi
1219
1220 # libaudit detection
1221 if test x$enable_libaudit = xno ; then
1222     have_libaudit=no;
1223 else
1224     # See if we have audit daemon & capabilities library
1225     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1226                  have_libaudit=yes, have_libaudit=no)
1227     if test x$have_libaudit = xyes ; then
1228         AC_CHECK_LIB(cap-ng, capng_clear,
1229                  have_libaudit=yes, have_libaudit=no)
1230     fi
1231 fi
1232
1233 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1234
1235 if test x$have_libaudit = xyes ; then
1236     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1237     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1238 fi
1239
1240 AC_SUBST([SELINUX_LIBS])
1241
1242 # Check for ADT API (Solaris Basic Security Mode auditing)
1243 AC_MSG_CHECKING(for ADT API)
1244 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1245 #include <bsm/adt.h>
1246 adt_user_context = ADT_USER;
1247 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1248
1249 if test ${check_adt_audit} = yes
1250 then
1251    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1252    ADT_LIBS="-lbsm"
1253    LIBS="-lbsm $LIBS"
1254    AC_MSG_RESULT(yes)
1255 else
1256    AC_MSG_RESULT(no)
1257 fi
1258 AC_SUBST([ADT_LIBS])
1259
1260 # Check for SCM_RIGHTS
1261 AC_MSG_CHECKING([for SCM_RIGHTS])
1262 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1263 #include <sys/types.h>
1264 #include <sys/socket.h>
1265 #include <sys/un.h>
1266 static int x = SCM_RIGHTS;
1267 ]], [[]])],
1268 [ AC_MSG_RESULT([supported])
1269   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1270 [ AC_MSG_RESULT([not supported]) ])
1271
1272 NETWORK_libs=
1273 if test x$dbus_win = xyes ; then
1274   if test x$dbus_wince = xyes ; then
1275     NETWORK_libs="-lws2"
1276   else
1277     NETWORK_libs="-lws2_32"
1278   fi
1279 fi
1280
1281 AC_SUBST([NETWORK_libs])
1282
1283 AC_ARG_WITH([valgrind],
1284   [AS_HELP_STRING([--with-valgrind],
1285      [Add instrumentation to help valgrind to understand our allocator])],
1286   [],
1287   [with_valgrind=no])
1288
1289 if test x$with_valgrind != xno; then
1290   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1291   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1292 fi
1293
1294 #### Set up final flags
1295 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1296 AC_SUBST([LIBDBUS_LIBS])
1297
1298 ### X11 detection
1299 DBUS_X_LIBS=
1300 DBUS_X_CFLAGS=
1301
1302 AC_ARG_ENABLE([x11-autolaunch],
1303   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1304   [], [enable_x11_autolaunch=auto])
1305
1306 if test "x$dbus_win" = xyes; then
1307     if test "x$enable_x11_autolaunch" = xyes; then
1308         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1309     fi
1310
1311     enable_x11_autolaunch=no
1312     have_x11=no
1313 else
1314     AC_PATH_XTRA
1315
1316     if test "x$no_x" = xyes; then
1317         have_x11=no
1318     else
1319         have_x11=yes
1320         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1321         DBUS_X_CFLAGS="$X_CFLAGS"
1322     fi
1323 fi
1324
1325 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1326     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1327 else
1328     # move from "auto" to "yes" or "no" if necessary
1329     if test "x$enable_x11_autolaunch" != xno; then
1330         enable_x11_autolaunch="$have_x11"
1331     fi
1332 fi
1333
1334 if test "x$have_x11" = xyes ; then
1335    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1336 fi
1337
1338 if test "x$enable_x11_autolaunch" = xyes ; then
1339    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1340 fi
1341
1342 AC_SUBST([DBUS_X_CFLAGS])
1343 AC_SUBST([DBUS_X_LIBS])
1344
1345 #### gcc warning flags
1346
1347 cc_supports_flag() {
1348   AC_MSG_CHECKING(whether $CC supports "$*")
1349   save_CFLAGS="$CFLAGS"
1350   CFLAGS="$*"
1351   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1352   CFLAGS="$save_CFLAGS"
1353   AC_MSG_RESULT([$rc])
1354   test "x$rc" = xyes
1355 }
1356
1357 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1358   dnl Use -Werror by default if:
1359   dnl - we're not on Windows (too many warnings), and
1360   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1361   dnl Override with --enable-Werror or --disable-Werror
1362   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1363
1364   dnl Enable these warnings if possible:
1365   [all \
1366    extra \
1367    char-subscripts \
1368    missing-declarations \
1369    missing-prototypes \
1370    nested-externs \
1371    pointer-arith \
1372    cast-align \
1373    no-address \
1374    float-equal \
1375    declaration-after-statement \
1376   ],
1377
1378   dnl Disable these warnings if possible, make them non-fatal if possible,
1379   dnl and don't enable -Werror unless we succeeded.
1380   dnl
1381   dnl Intentional:
1382   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1383   dnl   checking or not asserting
1384   dnl - missing field initializers being 0 is a C feature, not a bug
1385   dnl - unused-parameter is to make writing callbacks less annoying
1386   dnl
1387   dnl To be fixed one day:
1388   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1389   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1390   dnl   is better than nothing
1391   [$DISABLE_UNUSED_WARNINGS \
1392    missing-field-initializers \
1393    unused-parameter \
1394    sign-compare \
1395    pointer-sign \
1396    type-limits \
1397   ])
1398
1399 if test "x$GCC" = "xyes"; then
1400   # We're treating -fno-common like a warning: it makes the linker more
1401   # strict, because on some systems the linker is *always* this strict
1402   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1403
1404   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1405   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1406
1407   if test "x$enable_ansi" = "xyes"; then
1408     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1409       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1410   fi
1411 fi
1412
1413 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1414 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1415 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1416 dnl is the next best thing
1417 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1418
1419 case $host_os in
1420     solaris*)
1421         # Solaris' C library apparently needs these runes to be threadsafe...
1422         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1423         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1424         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1425         # ... and this opt-in to get file descriptor passing support
1426         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1427         ;;
1428 esac
1429
1430 ### Doxygen Documentation
1431
1432 AC_PATH_PROG(DOXYGEN, doxygen, no)
1433
1434 AC_MSG_CHECKING([whether to build Doxygen documentation])
1435
1436 if test x$DOXYGEN = xno ; then
1437     have_doxygen=no
1438 else
1439     have_doxygen=yes
1440 fi
1441
1442 if test x$enable_doxygen_docs = xauto ; then
1443     if test x$have_doxygen = xno ; then
1444         enable_doxygen_docs=no
1445     else
1446         enable_doxygen_docs=yes
1447     fi
1448 fi
1449
1450 if test x$enable_doxygen_docs = xyes; then
1451     if test x$have_doxygen = xno; then
1452         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1453     fi
1454 fi
1455
1456 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1457 AC_MSG_RESULT($enable_doxygen_docs)
1458
1459 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1460 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1461
1462 ### XML Documentation
1463
1464 AC_PATH_PROG(XMLTO, xmlto, no)
1465
1466 AC_MSG_CHECKING([whether to build XML documentation])
1467
1468 if test x$XMLTO = xno ; then
1469     have_xmlto=no
1470 else
1471     have_xmlto=yes
1472 fi
1473
1474 if test x$enable_xml_docs = xauto ; then
1475     if test x$have_xmlto = xno ; then
1476         enable_xml_docs=no
1477     else
1478         enable_xml_docs=yes
1479     fi
1480 fi
1481
1482 if test x$enable_xml_docs = xyes; then
1483     if test x$have_xmlto = xno; then
1484         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1485     fi
1486 fi
1487
1488 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1489 AC_MSG_RESULT($enable_xml_docs)
1490
1491 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1492     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes])
1493
1494 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1495
1496 #### find the actual value for $prefix that we'll end up with
1497 ##   (I know this is broken and should be done in the Makefile, but
1498 ##    that's a major pain and almost nobody actually seems to care)
1499 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1500 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1501 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1502 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1503 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1504 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1505 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1506
1507 #### Check our operating system
1508 operating_system=unknown
1509 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1510    operating_system=redhat
1511 fi
1512
1513 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1514    operating_system=slackware
1515 fi
1516
1517 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1518    operating_system=cygwin
1519 fi
1520
1521 #### Sort out init scripts
1522
1523 if test x$with_init_scripts = x; then
1524     case x$operating_system in
1525         xredhat)        with_init_scripts=redhat ;;
1526         xslackware)     with_init_scripts=slackware ;;
1527         xcygwin)        with_init_scripts=cygwin ;;
1528         *)                      with_init_scripts=none ;;
1529     esac
1530 fi
1531
1532 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1533 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1534 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1535
1536 ##### systemd unit files
1537 AC_ARG_WITH([systemdsystemunitdir],
1538 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1539     [],
1540     [
1541     PKG_CHECK_EXISTS([systemd],
1542       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1543       [with_systemdsystemunitdir=no])
1544     ])
1545 if test "x$with_systemdsystemunitdir" != xno; then
1546    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1547 fi
1548 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1549
1550 ##### Set up location for system bus socket
1551 if ! test -z "$with_system_socket"; then
1552    DBUS_SYSTEM_SOCKET=$with_system_socket
1553 else
1554    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1555 fi
1556
1557 AC_SUBST(DBUS_SYSTEM_SOCKET)
1558 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1559
1560 ## System bus only listens on local domain sockets, and never
1561 ## on an abstract socket (so only root can create the socket).
1562 ##
1563 ## This won't work on Windows. It's not meant to - the system bus is
1564 ## meaningless on Windows anyway.
1565 ##
1566 ## This has to be suitable for hard-coding in client libraries as well as
1567 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1568 ## and also to connect to. If this ever changes, it'll need to be split into
1569 ## two variables, one for the listening address and one for the connecting
1570 ## address.
1571 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1572 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1573 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1574
1575 #### Set up the pid file
1576 if ! test -z "$with_system_pid_file"; then
1577    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1578 elif test x$with_init_scripts = xredhat ; then
1579    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1580 else
1581    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1582 fi
1583
1584 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1585
1586 #### Directory to check for console ownership
1587 if ! test -z "$with_console_auth_dir"; then
1588    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1589 else
1590    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1591 fi
1592
1593 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1594 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1595
1596 #### File to check for console ownership
1597 if test x$have_console_owner_file = xyes; then
1598    if ! test -z "$with_console_owner_file"; then
1599       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1600    else
1601       DBUS_CONSOLE_OWNER_FILE=/dev/console
1602    fi
1603 else
1604   DBUS_CONSOLE_OWNER_FILE=
1605 fi
1606
1607 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1608 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1609
1610 #### User to start the system bus as
1611 if test -z "$with_dbus_user" ; then
1612     DBUS_USER=messagebus
1613 else
1614     DBUS_USER=$with_dbus_user
1615 fi
1616 AC_SUBST(DBUS_USER)
1617 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1618
1619 #### Prefix to install into
1620 DBUS_PREFIX=$EXPANDED_PREFIX
1621 AC_SUBST(DBUS_PREFIX)
1622 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1623
1624 #### Direcotry to install data files into
1625 DBUS_DATADIR=$EXPANDED_DATADIR
1626 AC_SUBST(DBUS_DATADIR)
1627 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1628
1629 #### Directory to install dbus-daemon
1630 if test -z "$with_dbus_daemondir" ; then
1631     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1632 else
1633     DBUS_DAEMONDIR=$with_dbus_daemondir
1634 fi
1635 AC_SUBST(DBUS_DAEMONDIR)
1636 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1637
1638 #### Directory to install the other binaries
1639 DBUS_BINDIR="$EXPANDED_BINDIR"
1640 AC_SUBST(DBUS_BINDIR)
1641 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1642
1643 #### Directory to install the libexec binaries
1644 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1645 AC_SUBST(DBUS_LIBEXECDIR)
1646 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1647
1648 #### Tell tests where to find certain stuff in builddir
1649
1650 DBUS_PWD=`pwd`
1651 # Useful in a cross-compilation environment, where the tests are run on the host system.
1652 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1653                            DBUS_PWD=$withval)
1654
1655 DBUS_TEST_EXEC="$DBUS_PWD/test"
1656 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1657
1658 AC_SUBST([DBUS_TEST_DATA])
1659 AC_SUBST([DBUS_TEST_EXEC])
1660
1661 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1662                    [Full path to the daemon in the builddir])
1663 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1664                    [Extension for executables, typically empty or .exe])
1665
1666 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1667                    [Full path to the daemon in the builddir])
1668 AC_SUBST(TEST_BUS_BINARY)
1669
1670 ## Export the non-setuid external helper
1671 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1672 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1673 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1674                    [Full path to the launch helper test program in the builddir])
1675
1676 #### Find socket directories
1677 if ! test -z "$TMPDIR" ; then
1678    DEFAULT_SOCKET_DIR=$TMPDIR
1679 elif ! test -z "$TEMP" ; then
1680    DEFAULT_SOCKET_DIR=$TEMP
1681 elif ! test -z "$TMP" ; then
1682    DEFAULT_SOCKET_DIR=$TMP
1683 else
1684    DEFAULT_SOCKET_DIR=/tmp
1685 fi
1686
1687 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1688
1689 if ! test -z "$with_test_socket_dir" ; then
1690    TEST_SOCKET_DIR="$with_test_socket_dir"
1691 else
1692    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1693 fi
1694 AC_SUBST(TEST_SOCKET_DIR)
1695 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1696
1697 if test "x$dbus_unix" = xyes; then
1698   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1699 else
1700   TEST_LISTEN="tcp:host=localhost"
1701 fi
1702 AC_SUBST([TEST_LISTEN])
1703 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1704   [Listening address for regression tests])
1705
1706 if ! test -z "$with_session_socket_dir" ; then
1707    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1708 else
1709    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1710 fi
1711 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1712 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1713
1714 # This must be a listening address. It doesn't necessarily need to be an
1715 # address you can connect to - it can be something vague like
1716 # "nonce-tcp:".
1717 #
1718 # The default varies by platform.
1719 AC_ARG_WITH([dbus_session_bus_listen_address],
1720             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1721                            [default address for a session bus to listen on (see configure.ac)]),
1722             [with_dbus_session_bus_listen_address=$withval],
1723             [with_dbus_session_bus_listen_address=])
1724
1725 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1726         # the user specified something, trust them
1727         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1728 elif test x$dbus_win = xyes; then
1729         # On Windows, you can (and should) listen on autolaunch addresses,
1730         # because autolaunching is different.
1731         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1732         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1733 elif test x$have_launchd = xyes; then
1734         # Mac OS X default is to use launchd
1735         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1736 else
1737         # The default on all other Unix platforms (notably Linux)
1738         # is to create a randomly named socket in /tmp or similar
1739         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1740 fi
1741 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1742
1743 # This must be an address you can connect to. It doesn't necessarily
1744 # need to be an address you can listen on - it can be "autolaunch:",
1745 # even on Unix.
1746 #
1747 # The default varies by platform.
1748 AC_ARG_WITH([dbus_session_bus_connect_address],
1749             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1750                            [fallback address for a session bus client to connect to (see configure.ac)]),
1751             [with_dbus_session_bus_connect_address=$withval],
1752             [with_dbus_session_bus_connect_address=])
1753
1754 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1755         # the user specified something, trust them
1756         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1757 elif test x$dbus_win = xyes; then
1758         # Windows autolaunching is a bit different; leaving it in its own
1759         # branch of the conditional because the default might conceivably
1760         # change (see #38201)
1761         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1762 else
1763         # The default on all other Unix platforms (notably Linux)
1764         # is to use auto-launching - this works a bit differently on Mac OS X
1765         # but comes out basically the same in the end
1766         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1767 fi
1768 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1769 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1770   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1771   [Fallback address for session bus clients])
1772
1773 # darwin needs this to initialize the environment
1774 AC_CHECK_HEADERS(crt_externs.h)
1775 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1776 AH_VERBATIM(_DARWIN_ENVIRON,
1777 [
1778 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1779 # include <sys/time.h>
1780 # include <crt_externs.h>
1781 # define environ (*_NSGetEnviron())
1782 #endif
1783 ])
1784
1785 AC_ARG_ENABLE([stats],
1786   [AS_HELP_STRING([--enable-stats],
1787     [enable bus daemon usage statistics])],
1788   [], [enable_stats=no])
1789 if test "x$enable_stats" = xyes; then
1790   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1791     [Define to enable bus daemon usage statistics])
1792 fi
1793
1794 AC_CONFIG_FILES([
1795 Doxyfile
1796 dbus/versioninfo.rc
1797 dbus/dbus-arch-deps.h
1798 bus/system.conf
1799 bus/session.conf
1800 bus/messagebus
1801 bus/messagebus-config
1802 bus/org.freedesktop.dbus-session.plist
1803 bus/rc.messagebus
1804 bus/dbus.service
1805 bus/dbus.socket
1806 Makefile
1807 dbus/Makefile
1808 bus/Makefile
1809 tools/Makefile
1810 test/Makefile
1811 test/name-test/Makefile
1812 doc/Makefile
1813 doc/dbus-daemon.1.xml
1814 dbus-1.pc
1815 dbus-1-uninstalled.pc
1816 test/data/valid-config-files/debug-allow-all.conf
1817 test/data/valid-config-files/debug-allow-all-sha1.conf
1818 test/data/valid-config-files-system/debug-allow-all-pass.conf
1819 test/data/valid-config-files-system/debug-allow-all-fail.conf
1820 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1821 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1822 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1823 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1824 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1825 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1826 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1827 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1828 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1829 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1830 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1831 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1832 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1833 ])
1834 AC_OUTPUT
1835
1836 dnl ==========================================================================
1837 echo "
1838                     D-Bus $VERSION
1839                   ==============
1840
1841         prefix:                   ${EXPANDED_PREFIX}
1842         exec_prefix:              ${exec_prefix}
1843         libdir:                   ${EXPANDED_LIBDIR}
1844         libexecdir:               ${EXPANDED_LIBEXECDIR}
1845         bindir:                   ${EXPANDED_BINDIR}
1846         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1847         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1848         datadir:                  ${EXPANDED_DATADIR}
1849         source code location:     ${srcdir}
1850         compiler:                 ${CC}
1851         cflags:                   ${CFLAGS}
1852         cppflags:                 ${CPPFLAGS}
1853         cxxflags:                 ${CXXFLAGS}
1854         64-bit int:               ${DBUS_INT64_TYPE}
1855         32-bit int:               ${DBUS_INT32_TYPE}
1856         16-bit int:               ${DBUS_INT16_TYPE}
1857         Doxygen:                  ${DOXYGEN:-not found}
1858         xmlto:                    ${XMLTO:-not found}"
1859
1860 echo "
1861         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1862         gcc coverage profiling:   ${enable_compiler_coverage}
1863         Building embedded tests:  ${enable_embedded_tests}
1864         Building modular tests:   ${enable_modular_tests}
1865             - with GLib:          ${with_glib}
1866         Building verbose mode:    ${enable_verbose_mode}
1867         Building assertions:      ${enable_asserts}
1868         Building checks:          ${enable_checks}
1869         Building bus stats API:   ${enable_stats}
1870         Building SELinux support: ${have_selinux}
1871         Building inotify support: ${have_inotify}
1872         Building dnotify support: ${have_dnotify}
1873         Building kqueue support:  ${have_kqueue}
1874         Building systemd support: ${have_systemd}
1875         Building X11 code:        ${enable_x11}
1876         Building Doxygen docs:    ${enable_doxygen_docs}
1877         Building XML docs:        ${enable_xml_docs}
1878         Building cache support:   ${enable_userdb_cache}
1879         Building launchd support: ${have_launchd}
1880         Using XML parser:         ${with_xml}
1881         Init scripts style:       ${with_init_scripts}
1882         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1883         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1884         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1885         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1886         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1887         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1888         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1889         Console owner file:       ${have_console_owner_file}
1890         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1891         System bus user:          ${DBUS_USER}
1892         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1893         'make check' socket dir:  ${TEST_SOCKET_DIR}
1894 "
1895 if test x$have_launchd = xyes; then
1896         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1897 fi
1898 echo
1899
1900 if test x$enable_embedded_tests = xyes; then
1901         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1902 fi
1903 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1904         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1905 fi
1906 if test x$enable_compiler_coverage = xyes; then
1907         echo "NOTE: building with coverage profiling is definitely for developers only."
1908 fi
1909 if test x$enable_verbose_mode = xyes; then
1910         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1911 fi
1912 if test x$enable_asserts = xyes; then
1913         echo "NOTE: building with assertions increases library size and decreases performance."
1914 fi
1915 if test x$enable_checks = xno; then
1916         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1917 fi
1918 if test x$dbus_use_libxml = xtrue; then
1919         echo
1920         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1921 fi
1922
1923 if test "x$DBUS_HAVE_INT64" = x0; then
1924   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1925
1926   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1927   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1928   used if your compiler lacks support for 64-bit integers. Please report a bug
1929   with details of your platform and compiler.
1930
1931   This option is likely to be removed in future, unless the D-Bus developers
1932   receive reports that it is still needed.
1933   ])
1934 fi