configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.14.2,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.23
  51 GSTPB_REQ=0.10.23
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 120 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 121
 122 dnl check for gconftool-2
 123 dnl this macro defines an am conditional, so it needs to be run always
 124 AM_GCONF_SOURCE_2
 125
 126 dnl check for documentation tools
 127 GTK_DOC_CHECK([1.3])
 128 AS_PATH_PYTHON([2.1])
 129 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 AC_CHECK_LIBM
 135 AC_SUBST(LIBM)
 136
 137 dnl *** checks for header files ***
 138
 139 dnl check if we have ANSI C header files
 140 AC_HEADER_STDC
 141
 142 dnl used by ext/wavpack
 143 AX_CREATE_STDINT_H
 144
 145 dnl used in gst/rtp/gstasteriskh263.c
 146 AC_CHECK_HEADERS([netinet/in.h])
 147 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 148 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 149
 150 dnl used in gst/udp
 151 AC_CHECK_HEADERS([sys/time.h])
 152
 153 dnl *** checks for types/defines ***
 154
 155 dnl Check for FIONREAD ioctl declaration.  This check is needed
 156 dnl for the UDP plugin to build on Solaris
 157 GST_CHECK_FIONREAD
 158
 159 dnl *** checks for structures ***
 160
 161 dnl *** checks for compiler characteristics ***
 162
 163 dnl check if we have GCC inline-asm
 164 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 165 if test x$HAVE_GCC_ASM = xyes ; then
 166   AC_DEFINE(HAVE_GCC_ASM, 1,
 167     [Define if compiler supports gcc inline assembly])
 168 fi
 169 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 170
 171 dnl *** checks for library functions ***
 172
 173 LIBS_SAVE=$LIBS
 174 LIBS="$LIBS $LIBM"
 175 AC_CHECK_FUNCS(rint sinh cosh asinh)
 176 LIBS=$LIBS_SAVE
 177
 178 dnl Check for mmap (needed by electricfence plugin)
 179 AC_FUNC_MMAP
 180 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 181
 182 dnl Check for mmap (needed by electricfence plugin)
 183
 184 AC_CHECK_TYPE([struct ip_mreqn], [
 185               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 186               [#include <netinet/in.h>])
 187
 188 dnl *** checks for dependency libraries ***
 189
 190 dnl GLib is required
 191 AG_GST_GLIB_CHECK([2.12])
 192
 193 dnl liboil is required
 194 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 195 if test "x$HAVE_LIBOIL" != "xyes"; then
 196   AC_ERROR([liboil-0.3.8 or later is required])
 197 fi
 198
 199 dnl checks for gstreamer
 200 dnl uninstalled is selected preferentially -- see pkg-config(1)
 201 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 202 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 203 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 204 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 205 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 206 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 207
 208 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 209 if test -z $GST_TOOLS_DIR; then
 210   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 211 fi
 212 AC_SUBST(GST_TOOLS_DIR)
 213
 214 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 215 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 216
 217 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 218
 219 dnl Check for documentation xrefs
 220 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 221 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 222 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 223 AC_SUBST(GLIB_PREFIX)
 224 AC_SUBST(GST_PREFIX)
 225 AC_SUBST(GSTPB_PREFIX)
 226
 227 dnl GTK is optional and used in examples
 228 if test "x$BUILD_EXAMPLES" = "xyes"; then
 229   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
 230   AC_SUBST(GTK_LIBS)
 231   AC_SUBST(GTK_CFLAGS)
 232 fi
 233 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 234
 235 dnl should we install schemas ?
 236 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 237 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 238   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 239   if test x$GCONFTOOL = xno; then
 240     AC_MSG_WARN(Not installing GConf schemas)
 241     HAVE_GCONFTOOL="no"
 242   else
 243     HAVE_GCONFTOOL="yes"
 244   fi
 245   AC_SUBST(HAVE_GCONFTOOL)
 246 ])
 247
 248 dnl *** set variables based on configure arguments ***
 249
 250 dnl set license and copyright notice
 251 GST_LICENSE="LGPL"
 252 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 253 AC_SUBST(GST_LICENSE)
 254
 255 dnl set location of plugin directory
 256 AG_GST_SET_PLUGINDIR
 257
 258 dnl define an ERROR_CFLAGS Makefile variable
 259 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 260
 261 dnl define an ERROR_CXXFLAGS Makefile variable
 262 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 263
 264 dnl define correct level for debugging messages
 265 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 266
 267 dnl used in examples
 268 AG_GST_DEFAULT_ELEMENTS
 269
 270 dnl *** plug-ins to include ***
 271
 272 dnl these are all the gst plug-ins, compilable without additional libs
 273 dnl videofilter is at the top because others depend on it
 274 AG_GST_CHECK_PLUGIN(videofilter)
 275 AG_GST_CHECK_PLUGIN(alpha)
 276 AG_GST_CHECK_PLUGIN(apetag)
 277 AG_GST_CHECK_PLUGIN(audiofx)
 278 AG_GST_CHECK_PLUGIN(auparse)
 279 AG_GST_CHECK_PLUGIN(autodetect)
 280 AG_GST_CHECK_PLUGIN(avi)
 281 AG_GST_CHECK_PLUGIN(cutter)
 282 AG_GST_CHECK_PLUGIN(debugutils)
 283 AG_GST_CHECK_PLUGIN(effectv)
 284 AG_GST_CHECK_PLUGIN(equalizer)
 285 AG_GST_CHECK_PLUGIN(id3demux)
 286 AG_GST_CHECK_PLUGIN(icydemux)
 287 AG_GST_CHECK_PLUGIN(interleave)
 288 AG_GST_CHECK_PLUGIN(flx)
 289 AG_GST_CHECK_PLUGIN(goom)
 290 AG_GST_CHECK_PLUGIN(goom2k1)
 291 AG_GST_CHECK_PLUGIN(law)
 292 AG_GST_CHECK_PLUGIN(level)
 293 AG_GST_CHECK_PLUGIN(matroska)
 294 AG_GST_CHECK_PLUGIN(monoscope)
 295 AG_GST_CHECK_PLUGIN(multifile)
 296 AG_GST_CHECK_PLUGIN(multipart)
 297 AG_GST_CHECK_PLUGIN(qtdemux)
 298 AG_GST_CHECK_PLUGIN(replaygain)
 299 AG_GST_CHECK_PLUGIN(rtp)
 300 AG_GST_CHECK_PLUGIN(rtsp)
 301 AG_GST_CHECK_PLUGIN(smpte)
 302 AG_GST_CHECK_PLUGIN(spectrum)
 303 AG_GST_CHECK_PLUGIN(udp)
 304 AG_GST_CHECK_PLUGIN(videobox)
 305 AG_GST_CHECK_PLUGIN(videocrop)
 306 AG_GST_CHECK_PLUGIN(videomixer)
 307 AG_GST_CHECK_PLUGIN(wavenc)
 308 AG_GST_CHECK_PLUGIN(wavparse)
 309
 310 dnl *** checks for socket and nsl libraries ***
 311 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 312
 313 dnl disable gst plugins we might not be able to build on this
 314 dnl platform: udp and rtsp (ugly but minimally invasive)
 315 dnl FIXME: maybe move to sys
 316 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 317 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 318
 319 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 320   AG_GST_DISABLE_PLUGIN(udp)
 321   AG_GST_DISABLE_PLUGIN(rtsp)
 322 fi
 323
 324 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 325   WIN32_LIBS="-lws2_32"
 326   AC_SUBST(WIN32_LIBS)
 327 fi
 328
 329 dnl disable experimental plug-ins
 330 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 331   AG_GST_DISABLE_PLUGIN(monoscope)
 332 fi
 333
 334 dnl *** sys plug-ins ***
 335
 336 echo
 337 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 338 echo
 339
 340 dnl DirectDraw
 341 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 342 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 343   HAVE_DIRECTDRAW="no"
 344   save_CFLAGS="$CFLAGS"
 345   save_LDFLAGS="$LDFLAGS"
 346   save_LIBS="$LIBS"
 347   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 348   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 349   LIBS="$LIBS -lddraw -lgdi32"
 350   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 351   AC_LINK_IFELSE([
 352 #include <windows.h>
 353 #include <ddraw.h>
 354
 355 int main ()
 356 {
 357   GetStockObject(0);
 358   DirectDrawCreate(NULL, NULL, NULL);
 359
 360   return 0;
 361 }
 362 ],
 363     [HAVE_DIRECTDRAW="yes"],
 364     [HAVE_DIRECTDRAW="no"])
 365   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 366   CFLAGS=$save_CFLAGS
 367   LDFLAGS=$save_LDFLAGS
 368   LIBS=$save_LIBS
 369
 370   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 371     dnl this is much more than we want
 372     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 373     AC_SUBST(DIRECTDRAW_CFLAGS)
 374     AC_SUBST(DIRECTDRAW_LDFLAGS)
 375     AC_SUBST(DIRECTDRAW_LIBS)
 376   fi
 377   AC_SUBST(HAVE_DIRECTDRAW)
 378 ])
 379
 380 dnl DirectSound
 381 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 382 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 383   HAVE_DIRECTSOUND="no"
 384   save_CFLAGS="$CFLAGS"
 385   save_LDFLAGS="$LDFLAGS"
 386   save_LIBS="$LIBS"
 387   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 388   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 389   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 390   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 391   AC_LINK_IFELSE([
 392 #include <windows.h>
 393 #include <dxerr9.h>
 394 #include <dsound.h>
 395
 396 int main ()
 397 {
 398   DXGetErrorString9 (0);
 399   DirectSoundCreate(NULL, NULL, NULL);
 400
 401   return 0;
 402 }
 403 ],
 404     [HAVE_DIRECTSOUND="yes"],
 405     [HAVE_DIRECTSOUND="no"])
 406   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 407   CFLAGS=$save_CFLAGS
 408   LDFLAGS=$save_LDFLAGS
 409   LIBS=$save_LIBS
 410
 411   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 412     dnl this is much more than we want
 413     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 414     AC_SUBST(DIRECTSOUND_CFLAGS)
 415     AC_SUBST(DIRECTSOUND_LDFLAGS)
 416     AC_SUBST(DIRECTSOUND_LIBS)
 417   fi
 418   AC_SUBST(HAVE_DIRECTSOUND)
 419 ])
 420
 421 dnl *** OSS audio *** (Linux, *BSD)
 422 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 423 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 424  HAVE_OSS="yes"
 425 dnl Linux and newer BSD versions :
 426  AC_CHECK_HEADER(sys/soundcard.h, [
 427    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 428    ] , [
 429 dnl Some old BSD versions and also newer OpenBSD versions :
 430    AC_CHECK_HEADER(soundcard.h, [
 431      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 432      ], [
 433   dnl Some old BSD versions :
 434      AC_CHECK_HEADER(machine/soundcard.h, [
 435        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 436          [Define if OSS includes are in /machine/])
 437        ], [
 438        HAVE_OSS="no"
 439      ])
 440    ])
 441  ])
 442 ])
 443
 444 dnl *** Sun Audio ***
 445 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 446 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 447   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 448 ])
 449
 450 dnl *** OSX Audio ***
 451 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 452 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 453   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 454 ])
 455
 456 dnl *** OS X video ***
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 458 HAVE_OSX_VIDEO="no"
 459 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 460   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 461 ])
 462 dnl in case header OpenGL/gl.h is found on other platforms
 463 case "$host" in
 464   *-*darwin*)
 465     dnl do nothing
 466     ;;
 467   *)
 468     HAVE_OSX_VIDEO="no"
 469     ;;
 470 esac
 471
 472
 473 dnl *** Video 4 Linux 2 ***
 474 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 475 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 476 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 477 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 478   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 479   AC_TRY_COMPILE([
 480 #include <sys/types.h>
 481 #ifdef __sun /* Solaris */
 482 #include <sys/types.h>
 483 #include <sys/videodev2.h>
 484 #else /* Linux */
 485 #include <linux/types.h>
 486 #define _LINUX_TIME_H
 487 #define __user
 488 #include <linux/videodev2.h>
 489 #endif
 490 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 491 #error too early v4l2 version or no v4l2 at all
 492 #endif
 493     ], [
 494 return 0;
 495     ], [
 496       HAVE_GST_V4L2="yes"
 497       AC_MSG_RESULT(yes)
 498     ], [
 499       HAVE_GST_V4L2="no"
 500       AC_MSG_RESULT(no)
 501
 502       HAVE_VIDEODEV=no
 503       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 504       [
 505         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 506       ])
 507
 508       if test "x$HAVE_VIDEODEV" = "xyes"; then
 509         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 510         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 511       else
 512         AC_MSG_WARN([video4linux2 was not found])
 513       fi
 514     ])
 515
 516   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 517     dnl check for missing v4l2_buffer declaration (see #135919)
 518     MISSING_DECL=0
 519     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 520     AC_TRY_COMPILE([
 521 #include <sys/types.h>
 522 #ifdef __sun /* Solaris */
 523 #include <sys/types.h>
 524 #include <sys/videodev2.h>
 525 #else /* Linux */
 526 #include <linux/types.h>
 527 #define _LINUX_TIME_H
 528 #define __user
 529 #include <linux/videodev2.h>
 530 #endif
 531     ],[
 532 struct v4l2_buffer buf;
 533 buf.index = 0;
 534 return 0;
 535     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 536     if [ test x$MISSING_DECL = x1 ]; then
 537       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 538     fi
 539
 540     dnl check for XOverlay libraries
 541     AG_GST_CHECK_XV
 542   fi
 543 ])
 544
 545 # Make libv4l2 non-automagic
 546 AC_ARG_WITH([libv4l2],
 547   AC_HELP_STRING([--with-libv4l2],
 548     [support video buffer conversion using libv4l2]),
 549   [],
 550   [with_libv4l2=check])
 551 if test x$HAVE_GST_V4L2 = xyes; then
 552   if test x$with_libv4l2 != xno; then
 553       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 554           [ have_libv4l2=yes
 555             AC_DEFINE(HAVE_LIBV4L2, 1,
 556                 [Whether libv4l2 is available for video buffer conversion])
 557           ], [
 558           have_libv4l2=no
 559           ])
 560   else
 561     have_libv4l2=no
 562   fi
 563 fi
 564
 565 dnl Check for X11
 566 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 567 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 568                   [ximagesrc], [
 569   AC_PATH_XTRA
 570
 571   dnl now try to find the HEADER
 572   ac_cflags_save="$CFLAGS"
 573   ac_cppflags_save="$CPPFLAGS"
 574   CFLAGS="$CFLAGS $X_CFLAGS"
 575   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 576   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 577
 578   if test "x$HAVE_X" = "xno"
 579   then
 580     AC_MSG_NOTICE([cannot find X11 development files])
 581   else
 582     dnl this is much more than we want
 583     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 584     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 585     dnl it does not add the libs; therefore we add them here
 586     X_LIBS="$X_LIBS -lX11"
 587     AC_SUBST(X_CFLAGS)
 588     AC_SUBST(X_LIBS)
 589
 590     dnl check for Xfixes
 591     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 592     if test "x$HAVE_XFIXES" = "xyes"
 593     then
 594         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 595     fi
 596     AC_SUBST(XFIXES_LIBS)
 597     AC_SUBST(XFIXES_CFLAGS)
 598
 599     dnl check for Xdamage
 600     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 601     if test "x$HAVE_XDAMAGE" = "xyes"
 602     then
 603         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 604     fi
 605     AC_SUBST(XDAMAGE_LIBS)
 606     AC_SUBST(XDAMAGE_CFLAGS)
 607   fi
 608   AC_SUBST(HAVE_X)
 609   CFLAGS="$ac_cflags_save"
 610   CPPFLAGS="$ac_cppflags_save"
 611 ])
 612
 613 dnl FIXME: this should be rolled into the test above, it's just an additional
 614 dnl feature of the ximagesrc plug-in
 615 dnl This is the same as in gst-plugins-base
 616 dnl check for X Shm
 617 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 618 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 619   if test x$HAVE_X = xyes; then
 620     AC_CHECK_LIB(Xext, XShmAttach,
 621                  HAVE_XSHM="yes", HAVE_XSHM="no",
 622                  $X_LIBS)
 623     if test "x$HAVE_XSHM" = "xyes"; then
 624       XSHM_LIBS="-lXext"
 625     else
 626       dnl On AIX, it is in XextSam instead, but we still need -lXext
 627       AC_CHECK_LIB(XextSam, XShmAttach,
 628                    HAVE_XSHM="yes", HAVE_XSHM="no",
 629                    $X_LIBS)
 630       if test "x$HAVE_XSHM" = "xyes"; then
 631         XSHM_LIBS="-lXext -lXextSam"
 632       fi
 633     fi
 634   fi
 635 ], ,[
 636   AC_SUBST(HAVE_XSHM)
 637   AC_SUBST(XSHM_LIBS)
 638 ])
 639
 640 dnl for V4L2, we also need to know if we have XVIDEO
 641 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 642 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 643                   [], [
 644   AG_GST_CHECK_XV
 645 ])
 646
 647 dnl *** ext plug-ins ***
 648 dnl keep this list sorted alphabetically !
 649
 650 if test "x$BUILD_EXTERNAL" = "xyes"; then
 651
 652 echo
 653 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 654 echo
 655
 656 dnl *** aalib ***
 657 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 658 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 659   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 660   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 661 ])
 662
 663 dnl *** annodex ***
 664 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 665 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 666   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 667 ])
 668
 669 dnl *** cairo ***
 670 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 671 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 672   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 673 ])
 674
 675 dnl **** ESound ****
 676 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 677 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 678   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 679   if test $HAVE_ESD = no
 680   then
 681     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 682     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 683   fi
 684 ])
 685
 686 dnl *** FLAC ***
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 688 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 689   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 690 ])
 691
 692 dnl *** GConf ***
 693 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 694 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 695   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 696 ])
 697
 698 dnl *** GDK pixbuf ***
 699 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 700 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 701   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 702 ])
 703
 704 dnl *** HAL ***
 705 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 706 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 707   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 708 ])
 709
 710 dnl *** jpeg ***
 711 dnl FIXME: we could use header checks here as well IMO
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 713 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 714   AC_ARG_WITH(jpeg-mmx,
 715     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 716   OLD_LIBS="$LIBS"
 717   if test x$with_jpeg_mmx != x; then
 718     LIBS="$LIBS -L$with_jpeg_mmx"
 719   fi
 720   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 721   JPEG_LIBS="$LIBS -ljpeg-mmx"
 722   LIBS="$OLD_LIBS"
 723   if test x$HAVE_JPEG != xyes; then
 724     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 725     JPEG_LIBS="-ljpeg"
 726   fi
 727   AC_SUBST(JPEG_LIBS)
 728 ])
 729
 730 dnl *** libcaca ***
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 732 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 733   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 734   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 735   if test "x$HAVE_LIBCACA" != "xyes"; then
 736     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 737     dnl see if it compilation works too, might not if we are cross-compiling
 738     if test "x$HAVE_LIBCACA" = "xyes"; then
 739       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 740                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 741     fi
 742   fi
 743 ])
 744
 745 dnl *** libdv ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 747 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 748   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 749 ])
 750
 751 dnl *** libpng ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 753 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 754   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 755 ])
 756
 757 dnl *** pulseaudio ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 759 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 760   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.8)
 761   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 762   if test x$HAVE_PULSE_0_9_11 = xyes; then
 763     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 764   fi
 765   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 766   if test x$HAVE_PULSE_0_9_12 = xyes; then
 767     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 768   fi
 769   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 770   if test x$HAVE_PULSE_0_9_13 = xyes; then
 771     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 772   fi
 773 ])
 774
 775 dnl *** dv1394 ***
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 777 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 778   dnl first test for libraw1394 >= 1.2.1
 779   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 780   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 781   dnl now see how far we got
 782   if test x$HAVE_RAW1394 = xyes && \
 783      test x$HAVE_LIBIEC61883 = xyes; then
 784        AG_GST_CHECK_LIBHEADER(AVC1394,
 785         avc1394, avc1394_send_command, $RAW1394_LIBS,
 786         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 787        AG_GST_CHECK_LIBHEADER(ROM1394,
 788         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 789         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 790        if test x$HAVE_AVC1394 = xyes && \
 791           test x$HAVE_AVC1394 = xyes && \
 792           test x$HAVE_ROM1394 = xyes; then
 793           HAVE_DV1394=yes
 794           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 795           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 796           AC_SUBST(DV1394_CFLAGS)
 797           AC_SUBST(DV1394_LIBS)
 798         fi
 799   else
 800        if test x$HAVE_RAW1394 = xno; then
 801           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 802           AG_GST_CHECK_LIBHEADER(AVC1394,
 803            avc1394, avc1394_send_command, $RAW1394_LIBS,
 804            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 805           AG_GST_CHECK_LIBHEADER(ROM1394,
 806            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 807            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 808           if test x$HAVE_RAW1394 = xyes && \
 809              test x$HAVE_AVC1394 = xyes && \
 810              test x$HAVE_ROM1394 = xyes; then
 811              HAVE_DV1394=yes
 812              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 813              DV1394_CFLAGS="$RAW1394_CFLAGS"
 814              if test x$HAVE_LIBIEC61883 = xyes; then
 815                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 816                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 817              fi
 818              AC_SUBST(DV1394_CFLAGS)
 819              AC_SUBST(DV1394_LIBS)
 820            fi
 821          fi
 822   fi
 823 ])
 824
 825 dnl *** shout2 ***
 826 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 827 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 828   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 829   if test $HAVE_SHOUT2 = no
 830   then
 831     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 832     AC_SUBST(SHOUT2_CFLAGS)
 833     AC_SUBST(SHOUT2_LIBS)
 834   fi
 835 ])
 836
 837 dnl *** soup ***
 838 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 839 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 840   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 841     HAVE_SOUP="yes"
 842     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 843   ],[
 844     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.3.2, HAVE_SOUP="yes", [
 845       HAVE_SOUP="no"
 846       AC_MSG_RESULT(no)
 847     ])
 848   ])
 849   AC_SUBST(SOUP_CFLAGS)
 850   AC_SUBST(SOUP_LIBS)
 851 ])
 852
 853 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 854 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 855 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 856 dnl   speex_jitter.h is 1.1.x only
 857 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 858 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 859   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 860   if test $HAVE_SPEEX = no
 861   then
 862     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 863       AC_CHECK_HEADER(speex/speex_jitter.h, [
 864         dnl speex 1.1.x :
 865         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 866           dnl speex 1.1.5 or + :
 867           HAVE_SPEEX="yes"
 868           SPEEX_LIBS="-lspeex"
 869           AC_SUBST(SPEEX_CFLAGS)
 870           AC_SUBST(SPEEX_LIBS)
 871         ],[
 872           HAVE_SPEEX="no"
 873         ])
 874       ],[
 875         dnl speex 1.0.x :
 876           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 877             dnl speex 1.0.4
 878             HAVE_SPEEX="yes"
 879             SPEEX_LIBS="-lspeex"
 880             AC_SUBST(SPEEX_CFLAGS)
 881             AC_SUBST(SPEEX_LIBS)
 882
 883             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 884               [defined if speex 1.0.x API detected])
 885         ],[
 886             HAVE_SPEEX="no"
 887             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 888         ], [
 889 #include <speex/speex.h>
 890         ])
 891       ])
 892     ])
 893   fi
 894 ])
 895
 896 dnl *** taglib ***
 897 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 898 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 899   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 900   if test "x$HAVE_CXX" != "xyes"; then
 901     USE_TAGLIB=false
 902     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 903   else
 904     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 905     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 906         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 907       ], [
 908         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 909     ])
 910     AC_SUBST(TAGLIB_CXXFLAGS)
 911   fi
 912 ])
 913
 914 dnl *** wavpack ***
 915 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 916 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 917   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 918     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 919       HAVE_WAVPACK=yes
 920       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 921     ],[
 922       HAVE_WAVPACK=no
 923       AC_MSG_RESULT(no)
 924     ])
 925   ])
 926   AC_SUBST(WAVPACK_CFLAGS)
 927   AC_SUBST(WAVPACK_LIBS)
 928 ])
 929
 930 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 931 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 932 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 933   AG_GST_CHECK_LIBHEADER(ZLIB,
 934     z, uncompress,, zlib.h, [
 935     HAVE_ZLIB="yes"
 936     ZLIB_LIBS="-lz"
 937     AC_SUBST(ZLIB_LIBS)
 938   ])
 939 ])
 940
 941 dnl *** matroska prefers to have bz2 ***
 942 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 943 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 944   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 945   AC_SUBST(BZ2_LIBS)
 946 ])
 947
 948 else
 949
 950 dnl not building plugins with external dependencies,
 951 dnl but we still need to set the conditionals
 952 AM_CONDITIONAL(USE_AALIB, false)
 953 AM_CONDITIONAL(USE_ANNODEX, false)
 954 AM_CONDITIONAL(USE_BZ2, false)
 955 AM_CONDITIONAL(USE_CAIRO, false)
 956 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 957 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 958 AM_CONDITIONAL(USE_DV1394, false)
 959 AM_CONDITIONAL(USE_ESD, false)
 960 AM_CONDITIONAL(USE_FLAC, false)
 961 AM_CONDITIONAL(USE_GCONF, false)
 962 AM_CONDITIONAL(USE_GCONFTOOL, false)
 963 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 964 AM_CONDITIONAL(USE_GST_V4L2, false)
 965 AM_CONDITIONAL(USE_HAL, false)
 966 AM_CONDITIONAL(USE_JPEG, false)
 967 AM_CONDITIONAL(USE_LIBCACA, false)
 968 AM_CONDITIONAL(USE_LIBDV, false)
 969 AM_CONDITIONAL(USE_LIBPNG, false)
 970 AM_CONDITIONAL(USE_OSS, false)
 971 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 972 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 973 AM_CONDITIONAL(USE_PULSE, false)
 974 AM_CONDITIONAL(USE_SHOUT2, false)
 975 AM_CONDITIONAL(USE_SOUP, false)
 976 AM_CONDITIONAL(USE_SPEEX, false)
 977 AM_CONDITIONAL(USE_SUNAUDIO, false)
 978 AM_CONDITIONAL(USE_TAGLIB, false)
 979 AM_CONDITIONAL(USE_WAVPACK, false)
 980 AM_CONDITIONAL(USE_X, false)
 981 AM_CONDITIONAL(USE_XSHM, false)
 982 AM_CONDITIONAL(USE_XVIDEO, false)
 983 AM_CONDITIONAL(USE_ZLIB, false)
 984
 985 fi dnl of EXT plugins
 986
 987 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 988
 989 dnl Overview:
 990 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 991 dnl GST_*:              flags shared by all built objects
 992 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 993 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 994 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 995 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 996
 997 dnl GST_OPTION_CFLAGS
 998 if test "x$USE_DEBUG" = xyes; then
 999    PROFILE_CFLAGS="-g"
1000 fi
1001 AC_SUBST(PROFILE_CFLAGS)
1002
1003 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1004   dnl Define _only_ during CVS (not pre-releases or releases)
1005   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1006 else
1007   DEPRECATED_CFLAGS=""
1008 fi
1009 AC_SUBST(DEPRECATED_CFLAGS)
1010
1011 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1012 dnl at make time with e.g. make ERROR_CFLAGS=""
1013 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1014 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1015 AC_SUBST(GST_OPTION_CFLAGS)
1016 AC_SUBST(GST_OPTION_CXXFLAGS)
1017
1018 dnl our libraries need to be versioned correctly
1019 AC_SUBST(GST_LT_LDFLAGS)
1020
1021 dnl FIXME: do we want to rename to GST_ALL_* ?
1022 dnl prefer internal headers to already installed ones
1023 dnl also add builddir include for enumtypes and marshal
1024 dnl add ERROR_CFLAGS, but overridable
1025 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1026 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
1027 AC_SUBST(GST_CFLAGS)
1028 AC_SUBST(GST_CXXFLAGS)
1029 AC_SUBST(GST_LIBS)
1030
1031 dnl LDFLAGS really should only contain flags, not libs - they get added before
1032 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1033 GST_ALL_LDFLAGS="-no-undefined"
1034 AC_SUBST(GST_ALL_LDFLAGS)
1035
1036 dnl this really should only contain flags, not libs - they get added before
1037 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1038 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1039 AC_SUBST(GST_PLUGIN_LDFLAGS)
1040
1041 SHAVE_INIT([common],[enable])
1042 dnl *** output files ***
1043
1044 dnl keep this alphabetic per directory, please
1045 AC_CONFIG_FILES(
1046 Makefile
1047 common/shave
1048 common/shave-libtool
1049 gst/Makefile
1050 gst/alpha/Makefile
1051 gst/apetag/Makefile
1052 gst/audiofx/Makefile
1053 gst/auparse/Makefile
1054 gst/autodetect/Makefile
1055 gst/avi/Makefile
1056 gst/cutter/Makefile
1057 gst/debugutils/Makefile
1058 gst/effectv/Makefile
1059 gst/equalizer/Makefile
1060 gst/id3demux/Makefile
1061 gst/icydemux/Makefile
1062 gst/interleave/Makefile
1063 gst/goom/Makefile
1064 gst/goom2k1/Makefile
1065 gst/law/Makefile
1066 gst/level/Makefile
1067 gst/matroska/Makefile
1068 gst/monoscope/Makefile
1069 gst/multifile/Makefile
1070 gst/multipart/Makefile
1071 gst/qtdemux/Makefile
1072 gst/replaygain/Makefile
1073 gst/rtp/Makefile
1074 gst/rtsp/Makefile
1075 gst/smpte/Makefile
1076 gst/spectrum/Makefile
1077 gst/udp/Makefile
1078 gst/videobox/Makefile
1079 gst/videocrop/Makefile
1080 gst/videofilter/Makefile
1081 gst/videomixer/Makefile
1082 gst/wavenc/Makefile
1083 gst/wavparse/Makefile
1084 gst/flx/Makefile
1085 ext/jpeg/Makefile
1086 ext/Makefile
1087 ext/aalib/Makefile
1088 ext/annodex/Makefile
1089 ext/cairo/Makefile
1090 ext/dv/Makefile
1091 ext/esd/Makefile
1092 ext/flac/Makefile
1093 ext/gconf/Makefile
1094 ext/gdk_pixbuf/Makefile
1095 ext/hal/Makefile
1096 ext/ladspa/Makefile
1097 ext/libcaca/Makefile
1098 ext/libpng/Makefile
1099 ext/pulse/Makefile
1100 ext/raw1394/Makefile
1101 ext/shout2/Makefile
1102 ext/soup/Makefile
1103 ext/speex/Makefile
1104 ext/taglib/Makefile
1105 ext/wavpack/Makefile
1106 sys/Makefile
1107 sys/directdraw/Makefile
1108 sys/directsound/Makefile
1109 sys/oss/Makefile
1110 sys/sunaudio/Makefile
1111 sys/osxaudio/Makefile
1112 sys/osxvideo/Makefile
1113 sys/v4l2/Makefile
1114 sys/waveform/Makefile
1115 sys/ximage/Makefile
1116 po/Makefile.in
1117 tests/Makefile
1118 tests/check/Makefile
1119 tests/examples/Makefile
1120 tests/examples/audiofx/Makefile
1121 tests/examples/equalizer/Makefile
1122 tests/examples/level/Makefile
1123 tests/examples/rtp/Makefile
1124 tests/examples/spectrum/Makefile
1125 tests/files/Makefile
1126 tests/icles/Makefile
1127 gconf/Makefile
1128 gconf/gstreamer.schemas
1129 common/Makefile
1130 common/m4/Makefile
1131 m4/Makefile
1132 docs/Makefile
1133 docs/plugins/Makefile
1134 docs/version.entities
1135 pkgconfig/Makefile
1136 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1137 gst-plugins-good.spec
1138 )
1139
1140 dnl Create the config.h file for Visual Studio builds
1141 dnl Beware of spaces and /'s in some of the shell variable contents.
1142 sed \
1143     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1144     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1145     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1146     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1147     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1148     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1149     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1150     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1151     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1152     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1153     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1154     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1155     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1156     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1157     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1158     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1159     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1160     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1161     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1162     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1163     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1164     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1165     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1166     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1167     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1168     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1169     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1170     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1171     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1172     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1173     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1174     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1175     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1176     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1177     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1178     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1179     config.h.in >win32/common/config.h-new
1180
1181 AC_OUTPUT
1182
1183 AG_GST_OUTPUT_PLUGINS