configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 2, 0, 2)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.1.0
  50 GSTPB_REQ=1.1.0
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.16])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 dnl *** set variables based on configure arguments ***
 254
 255 dnl set license and copyright notice
 256 GST_LICENSE="LGPL"
 257 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 258 AC_SUBST(GST_LICENSE)
 259
 260 dnl set location of plugin directory
 261 AG_GST_SET_PLUGINDIR
 262
 263 dnl set release date/time
 264 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 265   ["${srcdir}/gst-plugins-good.doap"],
 266   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 267
 268 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 269 dnl make sure it doesn't complain about unused variables if debugging is disabled
 270 NO_WARNINGS=""
 271 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 272
 273 dnl define an ERROR_CFLAGS Makefile variable
 274 dnl -Wundef: too many broken headers
 275 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 276       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 277       -Wwrite-strings -Wold-style-definition -Waggregate-return
 278       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 279       -Wnested-externs $NO_WARNINGS])
 280
 281 dnl define an ERROR_CXXFLAGS Makefile variable
 282 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 283         -Wmissing-declarations -Wredundant-decls
 284         -Wwrite-strings
 285         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 286         $NO_WARNINGS])
 287
 288 dnl define an ERROR_OBJCFLAGS Makefile variable
 289 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 290       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 291       -Wwrite-strings -Wold-style-definition
 292       -Winit-self -Wmissing-include-dirs -Wno-multichar
 293       -Wnested-externs $NO_WARNINGS])
 294
 295 dnl define correct level for debugging messages
 296 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 297
 298 dnl used in examples
 299 AG_GST_DEFAULT_ELEMENTS
 300
 301 dnl *** plug-ins to include ***
 302
 303 dnl Non ported plugins (non-dependant, then dependant)
 304 dnl Make sure you have a space before and after all plugins
 305 GST_PLUGINS_NONPORTED="osx_audio "
 306 AC_SUBST(GST_PLUGINS_NONPORTED)
 307
 308 dnl these are all the gst plug-ins, compilable without additional libs
 309 dnl videofilter is at the top because others depend on it
 310 AG_GST_CHECK_PLUGIN(alpha)
 311 AG_GST_CHECK_PLUGIN(apetag)
 312 AG_GST_CHECK_PLUGIN(audiofx)
 313 AG_GST_CHECK_PLUGIN(audioparsers)
 314 AG_GST_CHECK_PLUGIN(auparse)
 315 AG_GST_CHECK_PLUGIN(autodetect)
 316 AG_GST_CHECK_PLUGIN(avi)
 317 AG_GST_CHECK_PLUGIN(cutter)
 318 AG_GST_CHECK_PLUGIN(debugutils)
 319 AG_GST_CHECK_PLUGIN(deinterlace)
 320 AG_GST_CHECK_PLUGIN(effectv)
 321 AG_GST_CHECK_PLUGIN(equalizer)
 322 AG_GST_CHECK_PLUGIN(flv)
 323 AG_GST_CHECK_PLUGIN(flx)
 324 AG_GST_CHECK_PLUGIN(goom)
 325 AG_GST_CHECK_PLUGIN(goom2k1)
 326 AG_GST_CHECK_PLUGIN(icydemux)
 327 AG_GST_CHECK_PLUGIN(id3demux)
 328 AG_GST_CHECK_PLUGIN(imagefreeze)
 329 AG_GST_CHECK_PLUGIN(interleave)
 330 AG_GST_CHECK_PLUGIN(isomp4)
 331 AG_GST_CHECK_PLUGIN(law)
 332 AG_GST_CHECK_PLUGIN(level)
 333 AG_GST_CHECK_PLUGIN(matroska)
 334 AG_GST_CHECK_PLUGIN(monoscope)
 335 AG_GST_CHECK_PLUGIN(multifile)
 336 AG_GST_CHECK_PLUGIN(multipart)
 337 AG_GST_CHECK_PLUGIN(replaygain)
 338 AG_GST_CHECK_PLUGIN(rtp)
 339 AG_GST_CHECK_PLUGIN(rtpmanager)
 340 AG_GST_CHECK_PLUGIN(rtsp)
 341 AG_GST_CHECK_PLUGIN(shapewipe)
 342 AG_GST_CHECK_PLUGIN(smpte)
 343 AG_GST_CHECK_PLUGIN(spectrum)
 344 AG_GST_CHECK_PLUGIN(udp)
 345 AG_GST_CHECK_PLUGIN(videobox)
 346 AG_GST_CHECK_PLUGIN(videocrop)
 347 AG_GST_CHECK_PLUGIN(videofilter)
 348 AG_GST_CHECK_PLUGIN(videomixer)
 349 AG_GST_CHECK_PLUGIN(wavenc)
 350 AG_GST_CHECK_PLUGIN(wavparse)
 351 AG_GST_CHECK_PLUGIN(y4m)
 352
 353 dnl disable experimental plug-ins
 354 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 355   AG_GST_DISABLE_PLUGIN(monoscope)
 356 fi
 357
 358 dnl *** sys plug-ins ***
 359
 360 echo
 361 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 362 echo
 363
 364 dnl DirectSound
 365 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 366 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 367   HAVE_DIRECTSOUND="no"
 368   save_CFLAGS="$CFLAGS"
 369   save_LDFLAGS="$LDFLAGS"
 370   save_LIBS="$LIBS"
 371   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 372   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 373   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 374   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 375   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 376 #include <windows.h>
 377 #include <dxerr9.h>
 378 #include <dsound.h>
 379 ]], [[
 380   DXGetErrorString9 (0);
 381   DirectSoundCreate(NULL, NULL, NULL);
 382 ]])
 383 ],
 384     [HAVE_DIRECTSOUND="yes"],
 385     [HAVE_DIRECTSOUND="no"])
 386   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 387   CFLAGS=$save_CFLAGS
 388   LDFLAGS=$save_LDFLAGS
 389   LIBS=$save_LIBS
 390
 391   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 392     dnl this is much more than we want
 393     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 394     AC_SUBST(DIRECTSOUND_CFLAGS)
 395     AC_SUBST(DIRECTSOUND_LDFLAGS)
 396     AC_SUBST(DIRECTSOUND_LIBS)
 397   fi
 398   AC_SUBST(HAVE_DIRECTSOUND)
 399 ])
 400
 401 dnl *** Win32 WaveOut ***
 402 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 403 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 404   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 405 ])
 406
 407 dnl *** OSS audio *** (Linux, *BSD)
 408 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 409 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 410  HAVE_OSS="yes"
 411 dnl Linux and newer BSD versions :
 412  AC_CHECK_HEADER(sys/soundcard.h, [
 413    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 414    ] , [
 415 dnl Some old BSD versions and also newer OpenBSD versions :
 416    AC_CHECK_HEADER(soundcard.h, [
 417      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 418      ], [
 419   dnl Some old BSD versions :
 420      AC_CHECK_HEADER(machine/soundcard.h, [
 421        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 422          [Define if OSS includes are in /machine/])
 423        ], [
 424        HAVE_OSS="no"
 425      ])
 426    ])
 427  ])
 428 ])
 429
 430 dnl *** oss4 ***
 431 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 432 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 433   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 434   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 435       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 436       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 437 ])
 438
 439 dnl *** Sun Audio ***
 440 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 441 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 442   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 443 ])
 444
 445 dnl *** OSX Audio ***
 446 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 447 have_ios="no"
 448 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 449   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 450     HAVE_OSX_AUDIO="yes",
 451     dnl *** Check for the iOS headers ***
 452     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 453       [HAVE_OSX_AUDIO="YES";have_ios="yes"], HAVE_OSX_AUDIO="no"
 454     )])
 455 ])
 456 if test "x$have_ios" = "xyes"; then
 457   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 458 fi
 459 AM_CONDITIONAL(HAVE_IOS, test "x$have_ios" = "xyes")
 460
 461 dnl *** OS X video ***
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 463 HAVE_OSX_VIDEO="no"
 464 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 465   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 466 ])
 467 dnl in case header OpenGL/gl.h is found on other platforms
 468 case "$host" in
 469   *-*darwin*)
 470     dnl do nothing
 471     ;;
 472   *)
 473     HAVE_OSX_VIDEO="no"
 474     ;;
 475 esac
 476
 477
 478 dnl *** Video 4 Linux 2 ***
 479 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 480 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 481 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 482 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 483   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 484   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 485 #include <sys/types.h>
 486 #ifdef __sun /* Solaris */
 487 #include <sys/types.h>
 488 #include <sys/videodev2.h>
 489 #elif __FreeBSD__
 490 #include <linux/videodev2.h>
 491 #else /* Linux */
 492 #include <linux/types.h>
 493 #define _LINUX_TIME_H
 494 #define __user
 495 #include <linux/videodev2.h>
 496 #endif
 497 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 498 #error too early v4l2 version or no v4l2 at all
 499 #endif
 500     ]], [[
 501 return 0;
 502     ]])],[
 503       HAVE_GST_V4L2="yes"
 504       AC_MSG_RESULT(yes)
 505     ],[
 506       HAVE_GST_V4L2="no"
 507       AC_MSG_RESULT(no)
 508
 509       HAVE_VIDEODEV=no
 510       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 511       [
 512         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 513       ])
 514
 515       if test "x$HAVE_VIDEODEV" = "xyes"; then
 516         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 517         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 518       else
 519         AC_MSG_WARN([video4linux2 was not found])
 520       fi
 521     ])
 522
 523   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 524     dnl check for missing v4l2_buffer declaration (see #135919)
 525     MISSING_DECL=0
 526     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 527     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 528 #include <sys/types.h>
 529 #ifdef __sun /* Solaris */
 530 #include <sys/types.h>
 531 #include <sys/videodev2.h>
 532 #elif __FreeBSD__
 533 #include <linux/videodev2.h>
 534 #else /* Linux */
 535 #include <linux/types.h>
 536 #define _LINUX_TIME_H
 537 #define __user
 538 #include <linux/videodev2.h>
 539 #endif
 540     ]], [[
 541 struct v4l2_buffer buf;
 542 buf.index = 0;
 543 return 0;
 544     ]])],[ AC_MSG_RESULT(yes) ],[ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 545     if [ test x$MISSING_DECL = x1 ]; then
 546       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 547     fi
 548
 549     dnl check for XOverlay libraries
 550     AG_GST_CHECK_XV
 551   fi
 552 ])
 553
 554 # Optional gudev for device probing
 555 AC_ARG_WITH([gudev],
 556   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 557   [],
 558   [with_gudev=check])
 559 if test x$HAVE_GST_V4L2 = xyes; then
 560   if test x$with_gudev != xno; then
 561       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 562           [ have_gudev=yes
 563             AC_DEFINE(HAVE_GUDEV, 1,
 564                [Whether gudev is available for device detection])
 565             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 566           ], [
 567           have_gudev=no
 568           ])
 569   else
 570     have_gudev=no
 571   fi
 572 fi
 573 AC_SUBST(GUDEV_CFLAGS)
 574 AC_SUBST(GUDEV_LIBS)
 575
 576 # Make libv4l2 non-automagic
 577 AC_ARG_WITH([libv4l2],
 578   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 579   [],
 580   [with_libv4l2=check])
 581 if test x$HAVE_GST_V4L2 = xyes; then
 582   if test x$with_libv4l2 != xno; then
 583       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 584           [ have_libv4l2=yes
 585             AC_DEFINE(HAVE_LIBV4L2, 1,
 586                 [Whether libv4l2 is available for video buffer conversion])
 587           ], [
 588           have_libv4l2=no
 589           ])
 590   else
 591     have_libv4l2=no
 592   fi
 593 fi
 594
 595 # Check if v4l2 support dmabuf
 596 if test x$HAVE_GST_V4L2 = xyes; then
 597         AC_CHECK_DECLS(V4L2_MEMORY_DMABUF,,,[
 598                                         #include <sys/types.h>
 599                                         #ifdef __sun /* Solaris */
 600                                         #include <sys/types.h>
 601                                         #include <sys/videodev2.h>
 602                                         #elif __FreeBSD__
 603                                         #include <linux/videodev2.h>
 604                                         #else /* Linux */
 605                                         #include <linux/types.h>
 606                                         #define _LINUX_TIME_H
 607                                         #define __user
 608                                         #include <linux/videodev2.h>
 609                                         #endif
 610                                         ])
 611 fi
 612
 613 dnl Check for X11
 614 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 615 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 616                   [ximagesrc], [
 617   AC_PATH_XTRA
 618
 619   dnl now try to find the HEADER
 620   ac_cflags_save="$CFLAGS"
 621   ac_cppflags_save="$CPPFLAGS"
 622   CFLAGS="$CFLAGS $X_CFLAGS"
 623   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 624   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 625
 626   if test "x$HAVE_X" = "xno"
 627   then
 628     AC_MSG_NOTICE([cannot find X11 development files])
 629   else
 630     dnl this is much more than we want
 631     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 632     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 633     dnl it does not add the libs; therefore we add them here
 634     X_LIBS="$X_LIBS -lX11"
 635     AC_SUBST(X_CFLAGS)
 636     AC_SUBST(X_LIBS)
 637
 638     dnl check for Xfixes
 639     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 640     if test "x$HAVE_XFIXES" = "xyes"
 641     then
 642         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 643     fi
 644     AC_SUBST(XFIXES_LIBS)
 645     AC_SUBST(XFIXES_CFLAGS)
 646
 647     dnl check for Xdamage
 648     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 649     if test "x$HAVE_XDAMAGE" = "xyes"
 650     then
 651         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 652     fi
 653     AC_SUBST(XDAMAGE_LIBS)
 654     AC_SUBST(XDAMAGE_CFLAGS)
 655   fi
 656   AC_SUBST(HAVE_X)
 657   CFLAGS="$ac_cflags_save"
 658   CPPFLAGS="$ac_cppflags_save"
 659 ])
 660
 661 dnl FIXME: this should be rolled into the test above, it's just an additional
 662 dnl feature of the ximagesrc plug-in
 663 dnl This is the same as in gst-plugins-base
 664 dnl check for X Shm
 665 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 666 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 667   if test x$HAVE_X = xyes; then
 668     AC_CHECK_LIB(Xext, XShmAttach,
 669                  HAVE_XSHM="yes", HAVE_XSHM="no",
 670                  $X_LIBS)
 671     if test "x$HAVE_XSHM" = "xyes"; then
 672       XSHM_LIBS="-lXext"
 673     else
 674       dnl On AIX, it is in XextSam instead, but we still need -lXext
 675       AC_CHECK_LIB(XextSam, XShmAttach,
 676                    HAVE_XSHM="yes", HAVE_XSHM="no",
 677                    $X_LIBS)
 678       if test "x$HAVE_XSHM" = "xyes"; then
 679         XSHM_LIBS="-lXext -lXextSam"
 680       fi
 681     fi
 682   fi
 683 ], ,[
 684   AC_SUBST(HAVE_XSHM)
 685   AC_SUBST(XSHM_LIBS)
 686 ])
 687
 688 dnl for V4L2, we also need to know if we have XVIDEO
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 690 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 691                   [], [
 692   AG_GST_CHECK_XV
 693 ])
 694
 695 dnl *** ext plug-ins ***
 696 dnl keep this list sorted alphabetically !
 697
 698 if test "x$BUILD_EXTERNAL" = "xyes"; then
 699
 700 echo
 701 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 702 echo
 703
 704 dnl *** aalib ***
 705 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 706 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 707   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 708   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 709 ])
 710
 711 dnl *** cairo ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 713 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 714   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 715 ])
 716
 717 dnl *** FLAC ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 719 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 720   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 721 ])
 722
 723 dnl *** GDK pixbuf ***
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 725 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 726   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 727 ])
 728
 729 dnl *** Jack ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 731 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 732   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 733   AC_SUBST(JACK_CFLAGS)
 734   AC_SUBST(JACK_LIBS)
 735
 736   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 737   if test x$HAVE_JACK_0_120_1 = xyes; then
 738     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 739   fi
 740   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 741   if test x$HAVE_JACK_1_9_7 = xyes; then
 742     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 743   fi
 744
 745 ])
 746
 747 dnl *** jpeg ***
 748 dnl FIXME: we could use header checks here as well IMO
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 750 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 751   AC_ARG_WITH(jpeg-mmx,
 752     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 753   OLD_LIBS="$LIBS"
 754   if test x$with_jpeg_mmx != x; then
 755     LIBS="$LIBS -L$with_jpeg_mmx"
 756   fi
 757   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 758   JPEG_LIBS="$LIBS -ljpeg-mmx"
 759   LIBS="$OLD_LIBS"
 760   if test x$HAVE_JPEG != xyes; then
 761     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 762     JPEG_LIBS="-ljpeg"
 763   fi
 764   AC_SUBST(JPEG_LIBS)
 765 ])
 766
 767 dnl *** libcaca ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 769 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 770   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 771 ])
 772
 773 dnl *** libdv ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 775 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 776   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 777 ])
 778
 779 dnl *** libpng ***
 780 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 781 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 782   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 783 ])
 784
 785 dnl *** pulseaudio ***
 786 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 787 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 788
 789   dnl used in ext/pulse/pulseutil.c
 790   AC_CHECK_HEADERS([process.h])
 791
 792   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 793 ])
 794
 795 dnl *** dv1394 ***
 796 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 797 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 798   dnl first test for libraw1394 >= 2.0.0
 799   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 800   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 801   dnl now see how far we got
 802   if test x$HAVE_RAW1394 = xyes && \
 803      test x$HAVE_LIBIEC61883 = xyes; then
 804        AG_GST_CHECK_LIBHEADER(AVC1394,
 805         avc1394, avc1394_send_command, $RAW1394_LIBS,
 806         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 807        AG_GST_CHECK_LIBHEADER(ROM1394,
 808         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 809         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 810        if test x$HAVE_AVC1394 = xyes && \
 811           test x$HAVE_AVC1394 = xyes && \
 812           test x$HAVE_ROM1394 = xyes; then
 813           HAVE_DV1394=yes
 814           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 815           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 816           AC_SUBST(DV1394_CFLAGS)
 817           AC_SUBST(DV1394_LIBS)
 818         fi
 819   else
 820        if test x$HAVE_RAW1394 = xno; then
 821           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 822           AG_GST_CHECK_LIBHEADER(AVC1394,
 823            avc1394, avc1394_send_command, $RAW1394_LIBS,
 824            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 825           AG_GST_CHECK_LIBHEADER(ROM1394,
 826            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 827            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 828           if test x$HAVE_RAW1394 = xyes && \
 829              test x$HAVE_AVC1394 = xyes && \
 830              test x$HAVE_ROM1394 = xyes; then
 831              HAVE_DV1394=yes
 832              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 833              DV1394_CFLAGS="$RAW1394_CFLAGS"
 834              if test x$HAVE_LIBIEC61883 = xyes; then
 835                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 836                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 837              fi
 838              AC_SUBST(DV1394_CFLAGS)
 839              AC_SUBST(DV1394_LIBS)
 840            fi
 841          fi
 842   fi
 843 ])
 844 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 845
 846 dnl *** shout2 ***
 847 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 848 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 849   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 850 ])
 851
 852 dnl *** soup ***
 853 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 854 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 855   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26.1, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 856   AC_SUBST(SOUP_CFLAGS)
 857   AC_SUBST(SOUP_LIBS)
 858 ])
 859
 860 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 861 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 862 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 863 dnl   speex_jitter.h is 1.1.x only
 864 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 865 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 866   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 867   if test $HAVE_SPEEX = no
 868   then
 869     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 870       AC_CHECK_HEADER(speex/speex_jitter.h, [
 871         dnl speex 1.1.x :
 872         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 873           dnl speex 1.1.5 or + :
 874           HAVE_SPEEX="yes"
 875           SPEEX_LIBS="-lspeex"
 876           AC_SUBST(SPEEX_CFLAGS)
 877           AC_SUBST(SPEEX_LIBS)
 878         ],[
 879           HAVE_SPEEX="no"
 880         ])
 881       ],[
 882         dnl speex 1.0.x :
 883           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 884             dnl speex 1.0.4
 885             HAVE_SPEEX="yes"
 886             SPEEX_LIBS="-lspeex"
 887             AC_SUBST(SPEEX_CFLAGS)
 888             AC_SUBST(SPEEX_LIBS)
 889
 890             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 891               [defined if speex 1.0.x API detected])
 892         ],[
 893             HAVE_SPEEX="no"
 894             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 895         ], [
 896 #include <speex/speex.h>
 897         ])
 898       ])
 899     ])
 900   fi
 901 ])
 902
 903 dnl *** taglib ***
 904 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 905 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 906   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 907   if test "x$HAVE_CXX" != "xyes"; then
 908     USE_TAGLIB=false
 909     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 910   else
 911     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 912     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 913         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 914       ], [
 915         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 916     ])
 917     AC_SUBST(TAGLIB_CXXFLAGS)
 918   fi
 919 ])
 920
 921 dnl *** vpx ***
 922 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 923 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 924   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 925
 926   if test $HAVE_VPX = "yes"; then
 927     OLD_LIBS="$LIBS"
 928     OLD_CFLAGS="$CFLAGS"
 929     CFLAGS="$CFLAGS $VPX_CFLAGS"
 930     LIBS="$LIBS $VPX_LIBS"
 931     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 932       HAVE_VP8=yes
 933       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 934     ])
 935     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 936       HAVE_VP8=yes
 937       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 938     ])
 939     LIBS="$OLD_LIBS"
 940     CFLAGS="$OLD_CFLAGS"
 941   fi
 942   AC_SUBST(VPX_LIBS)
 943   AC_SUBST(VPX_CFLAGS)
 944 ])
 945
 946 dnl *** wavpack ***
 947 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 948 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 949   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 950     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 951       HAVE_WAVPACK=yes
 952       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 953     ],[
 954       HAVE_WAVPACK=no
 955     ])
 956   ])
 957   AC_SUBST(WAVPACK_CFLAGS)
 958   AC_SUBST(WAVPACK_LIBS)
 959 ])
 960
 961 dnl *** qtdemux & matroska prefer to have zlib ***
 962 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 963 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 964   AG_GST_CHECK_LIBHEADER(ZLIB,
 965     z, uncompress,, zlib.h, [
 966     HAVE_ZLIB="yes"
 967     ZLIB_LIBS="-lz"
 968     AC_SUBST(ZLIB_LIBS)
 969   ])
 970 ])
 971
 972 dnl *** matroska prefers to have bz2 ***
 973 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 974 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 975   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 976   AC_SUBST(BZ2_LIBS)
 977 ])
 978
 979 else
 980
 981 dnl not building plugins with external dependencies,
 982 dnl but we still need to set the conditionals
 983 AM_CONDITIONAL(USE_AALIB, false)
 984 AM_CONDITIONAL(USE_BZ2, false)
 985 AM_CONDITIONAL(USE_CAIRO, false)
 986 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 987 AM_CONDITIONAL(USE_DV1394, false)
 988 AM_CONDITIONAL(USE_FLAC, false)
 989 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 990 AM_CONDITIONAL(USE_GST_V4L2, false)
 991 AM_CONDITIONAL(USE_JACK, false)
 992 AM_CONDITIONAL(USE_JPEG, false)
 993 AM_CONDITIONAL(USE_LIBCACA, false)
 994 AM_CONDITIONAL(USE_LIBDV, false)
 995 AM_CONDITIONAL(USE_LIBIEC61883, false)
 996 AM_CONDITIONAL(USE_LIBPNG, false)
 997 AM_CONDITIONAL(USE_OSS, false)
 998 AM_CONDITIONAL(USE_OSS4, false)
 999 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1000 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1001 AM_CONDITIONAL(USE_PULSE, false)
1002 AM_CONDITIONAL(USE_SHOUT2, false)
1003 AM_CONDITIONAL(USE_SOUP, false)
1004 AM_CONDITIONAL(USE_SPEEX, false)
1005 AM_CONDITIONAL(USE_SUNAUDIO, false)
1006 AM_CONDITIONAL(USE_TAGLIB, false)
1007 AM_CONDITIONAL(USE_VPX, false)
1008 AM_CONDITIONAL(USE_WAVEFORM, false)
1009 AM_CONDITIONAL(USE_WAVPACK, false)
1010 AM_CONDITIONAL(USE_X, false)
1011 AM_CONDITIONAL(USE_XSHM, false)
1012 AM_CONDITIONAL(USE_XVIDEO, false)
1013 AM_CONDITIONAL(USE_ZLIB, false)
1014
1015 fi dnl of EXT plugins
1016
1017 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1018
1019 dnl Overview:
1020 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1021 dnl GST_*:              flags shared by all built objects
1022 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1023 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1024 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1025 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1026
1027 dnl GST_OPTION_CFLAGS
1028 if test "x$USE_DEBUG" = xyes; then
1029    PROFILE_CFLAGS="-g"
1030 fi
1031 AC_SUBST(PROFILE_CFLAGS)
1032
1033 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1034   dnl Define _only_ for git (not pre-releases or releases)
1035   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1036 else
1037   DEPRECATED_CFLAGS=""
1038 fi
1039 AC_SUBST(DEPRECATED_CFLAGS)
1040
1041 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1042 dnl at make time with e.g. make ERROR_CFLAGS=""
1043 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1044 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1045 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1046 AC_SUBST(GST_OPTION_CFLAGS)
1047 AC_SUBST(GST_OPTION_CXXFLAGS)
1048 AC_SUBST(GST_OPTION_OBJCFLAGS)
1049
1050 dnl our libraries need to be versioned correctly
1051 AC_SUBST(GST_LT_LDFLAGS)
1052
1053 dnl FIXME: do we want to rename to GST_ALL_* ?
1054 dnl prefer internal headers to already installed ones
1055 dnl also add builddir include for enumtypes and marshal
1056 dnl add ERROR_CFLAGS, but overridable
1057 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1058 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1059 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1060 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1061 AC_SUBST(GST_CFLAGS)
1062 AC_SUBST(GST_CXXFLAGS)
1063 AC_SUBST(GST_OBJCFLAGS)
1064 AC_SUBST(GST_LIBS)
1065
1066 dnl LDFLAGS really should only contain flags, not libs - they get added before
1067 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1068 GST_ALL_LDFLAGS="-no-undefined"
1069 AC_SUBST(GST_ALL_LDFLAGS)
1070
1071 dnl this really should only contain flags, not libs - they get added before
1072 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1073 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1074 AC_SUBST(GST_PLUGIN_LDFLAGS)
1075
1076 dnl *** output files ***
1077
1078 dnl keep this alphabetic per directory, please
1079 AC_CONFIG_FILES(
1080 Makefile
1081 gst/Makefile
1082 gst/alpha/Makefile
1083 gst/apetag/Makefile
1084 gst/audiofx/Makefile
1085 gst/audioparsers/Makefile
1086 gst/auparse/Makefile
1087 gst/autodetect/Makefile
1088 gst/avi/Makefile
1089 gst/cutter/Makefile
1090 gst/deinterlace/Makefile
1091 gst/debugutils/Makefile
1092 gst/effectv/Makefile
1093 gst/equalizer/Makefile
1094 gst/flv/Makefile
1095 gst/goom/Makefile
1096 gst/goom2k1/Makefile
1097 gst/id3demux/Makefile
1098 gst/icydemux/Makefile
1099 gst/imagefreeze/Makefile
1100 gst/interleave/Makefile
1101 gst/isomp4/Makefile
1102 gst/law/Makefile
1103 gst/level/Makefile
1104 gst/matroska/Makefile
1105 gst/monoscope/Makefile
1106 gst/multifile/Makefile
1107 gst/multipart/Makefile
1108 gst/replaygain/Makefile
1109 gst/rtp/Makefile
1110 gst/rtpmanager/Makefile
1111 gst/rtsp/Makefile
1112 gst/shapewipe/Makefile
1113 gst/smpte/Makefile
1114 gst/spectrum/Makefile
1115 gst/udp/Makefile
1116 gst/videobox/Makefile
1117 gst/videocrop/Makefile
1118 gst/videofilter/Makefile
1119 gst/videomixer/Makefile
1120 gst/wavenc/Makefile
1121 gst/wavparse/Makefile
1122 gst/flx/Makefile
1123 gst/y4m/Makefile
1124 ext/Makefile
1125 ext/aalib/Makefile
1126 ext/cairo/Makefile
1127 ext/dv/Makefile
1128 ext/flac/Makefile
1129 ext/gdk_pixbuf/Makefile
1130 ext/jack/Makefile
1131 ext/jpeg/Makefile
1132 ext/libcaca/Makefile
1133 ext/libpng/Makefile
1134 ext/pulse/Makefile
1135 ext/raw1394/Makefile
1136 ext/shout2/Makefile
1137 ext/soup/Makefile
1138 ext/speex/Makefile
1139 ext/taglib/Makefile
1140 ext/vpx/Makefile
1141 ext/wavpack/Makefile
1142 sys/Makefile
1143 sys/directsound/Makefile
1144 sys/oss/Makefile
1145 sys/oss4/Makefile
1146 sys/osxaudio/Makefile
1147 sys/osxvideo/Makefile
1148 sys/sunaudio/Makefile
1149 sys/v4l2/Makefile
1150 sys/waveform/Makefile
1151 sys/ximage/Makefile
1152 po/Makefile.in
1153 tests/Makefile
1154 tests/check/Makefile
1155 tests/examples/Makefile
1156 tests/examples/audiofx/Makefile
1157 tests/examples/cairo/Makefile
1158 tests/examples/equalizer/Makefile
1159 tests/examples/jack/Makefile
1160 tests/examples/level/Makefile
1161 tests/examples/pulse/Makefile
1162 tests/examples/rtp/Makefile
1163 tests/examples/shapewipe/Makefile
1164 tests/examples/spectrum/Makefile
1165 tests/examples/v4l2/Makefile
1166 tests/files/Makefile
1167 tests/icles/Makefile
1168 common/Makefile
1169 common/m4/Makefile
1170 m4/Makefile
1171 docs/Makefile
1172 docs/plugins/Makefile
1173 docs/version.entities
1174 pkgconfig/Makefile
1175 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1176 gst-plugins-good.spec
1177 )
1178
1179 dnl Create the config.h file for Visual Studio builds
1180 dnl Beware of spaces and /'s in some of the shell variable contents.
1181 sed \
1182     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1183     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1184     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1185     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1186     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1187     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1188     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1189     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1190     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1191     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1192     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1193     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1194     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1195     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1196     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1197     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1198     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1199     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1200     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1201     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1202     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1203     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1204     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1205     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1206     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1207     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1208     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1209     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1210     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1211     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1212     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1213     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1214     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1215     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1216     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1217     config.h.in >win32/common/config.h-new
1218
1219 AC_OUTPUT
1220
1221 AG_GST_OUTPUT_PLUGINS
1222 ORC_OUTPUT
1223