configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67
  68 dnl Versions for external dependencies
  69 LIBDRM_REQUIRED=2.4.38
  70 LIBDRM_RADEON_REQUIRED=2.4.56
  71 LIBDRM_INTEL_REQUIRED=2.4.60
  72 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  73 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  74 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  75 DRI2PROTO_REQUIRED=2.6
  76 DRI3PROTO_REQUIRED=1.0
  77 PRESENTPROTO_REQUIRED=1.0
  78 LIBUDEV_REQUIRED=151
  79 GLPROTO_REQUIRED=1.4.14
  80 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  81 LIBVA_REQUIRED=0.35.0
  82 VDPAU_REQUIRED=0.4.1
  83 WAYLAND_REQUIRED=1.2.0
  84 XCB_REQUIRED=1.9.3
  85 XCBDRI2_REQUIRED=1.8
  86 XCBGLX_REQUIRED=1.8.1
  87 XSHMFENCE_REQUIRED=1.1
  88 XVMC_REQUIRED=1.0.6
  89 PYTHON_MAKO_REQUIRED=0.3.4
  90
  91 dnl Check for progs
  92 AC_PROG_CPP
  93 AC_PROG_CC
  94 AC_PROG_CXX
  95 AM_PROG_CC_C_O
  96 AM_PROG_AS
  97 AX_CHECK_GNU_MAKE
  98 AC_CHECK_PROGS([PYTHON2], [python2 python])
  99 AC_PROG_SED
 100 AC_PROG_MKDIR_P
 101
 102 AC_SYS_LARGEFILE
 103
 104 LT_PREREQ([2.2])
 105 LT_INIT([disable-static])
 106
 107 AX_PROG_BISON([],
 108               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 109                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 110 AX_PROG_FLEX([],
 111              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 112                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 113
 114 AC_CHECK_PROG(INDENT, indent, indent, cat)
 115 if test "x$INDENT" != "xcat"; then
 116     # Only GNU indent is supported
 117     INDENT_VERSION=`indent --version | grep GNU`
 118     if test $? -eq 0; then
 119        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 120     else
 121        INDENT="cat"
 122     fi
 123 fi
 124
 125 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 126
 127 if test -z "$PYTHON2"; then
 128     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 129         AC_MSG_ERROR([Python not found - unable to generate sources])
 130     fi
 131 else
 132     if test "x$acv_mako_found" = xno; then
 133         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 134             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 135         fi
 136     fi
 137 fi
 138
 139 AC_PROG_INSTALL
 140
 141 dnl We need a POSIX shell for parts of the build. Assume we have one
 142 dnl in most cases.
 143 case "$host_os" in
 144 solaris*)
 145     # Solaris /bin/sh is too old/non-POSIX compliant
 146     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 147     SHELL="$POSIX_SHELL"
 148     ;;
 149 esac
 150
 151 dnl clang is mostly GCC-compatible, but its version is much lower,
 152 dnl so we have to check for it.
 153 AC_MSG_CHECKING([if compiling with clang])
 154
 155 AC_COMPILE_IFELSE(
 156 [AC_LANG_PROGRAM([], [[
 157 #ifndef __clang__
 158        not clang
 159 #endif
 160 ]])],
 161 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 162
 163 AC_MSG_RESULT([$acv_mesa_CLANG])
 164
 165 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 166 dnl versions are explictly not supported.
 167 GEN_ASM_OFFSETS=no
 168 USE_GNU99=no
 169 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 170     AC_MSG_CHECKING([whether gcc version is sufficient])
 171     major=0
 172     minor=0
 173
 174     GCC_VERSION=`$CC -dumpversion`
 175     if test $? -eq 0; then
 176         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 177         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 178     fi
 179
 180     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 181         AC_MSG_RESULT([no])
 182         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 183     else
 184         AC_MSG_RESULT([yes])
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 188         USE_GNU99=yes
 189     fi
 190     if test "x$cross_compiling" = xyes; then
 191         GEN_ASM_OFFSETS=yes
 192     fi
 193 fi
 194
 195 dnl Check for compiler builtins
 196 AX_GCC_BUILTIN([__builtin_bswap32])
 197 AX_GCC_BUILTIN([__builtin_bswap64])
 198 AX_GCC_BUILTIN([__builtin_clz])
 199 AX_GCC_BUILTIN([__builtin_clzll])
 200 AX_GCC_BUILTIN([__builtin_ctz])
 201 AX_GCC_BUILTIN([__builtin_expect])
 202 AX_GCC_BUILTIN([__builtin_ffs])
 203 AX_GCC_BUILTIN([__builtin_ffsll])
 204 AX_GCC_BUILTIN([__builtin_popcount])
 205 AX_GCC_BUILTIN([__builtin_popcountll])
 206 AX_GCC_BUILTIN([__builtin_unreachable])
 207
 208 AX_GCC_FUNC_ATTRIBUTE([flatten])
 209 AX_GCC_FUNC_ATTRIBUTE([format])
 210 AX_GCC_FUNC_ATTRIBUTE([malloc])
 211 AX_GCC_FUNC_ATTRIBUTE([packed])
 212 AX_GCC_FUNC_ATTRIBUTE([unused])
 213
 214 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 215
 216 dnl Make sure the pkg-config macros are defined
 217 m4_ifndef([PKG_PROG_PKG_CONFIG],
 218     [m4_fatal([Could not locate the pkg-config autoconf macros.
 219   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 220   are in a different location, try setting the environment variable
 221   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 222 PKG_PROG_PKG_CONFIG()
 223
 224 dnl LIB_DIR - library basename
 225 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 226 AC_SUBST([LIB_DIR])
 227
 228 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 229 _SAVE_LDFLAGS="$LDFLAGS"
 230 _SAVE_CPPFLAGS="$CPPFLAGS"
 231
 232 dnl Compiler macros
 233 DEFINES=""
 234 AC_SUBST([DEFINES])
 235 case "$host_os" in
 236 linux*|*-gnu*|gnu*)
 237     DEFINES="$DEFINES -D_GNU_SOURCE"
 238     ;;
 239 solaris*)
 240     DEFINES="$DEFINES -DSVR4"
 241     ;;
 242 cygwin*)
 243     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 244     ;;
 245 esac
 246
 247 dnl Add flags for gcc and g++
 248 if test "x$GCC" = xyes; then
 249     CFLAGS="$CFLAGS -Wall"
 250
 251     if test "x$USE_GNU99" = xyes; then
 252         CFLAGS="$CFLAGS -std=gnu99"
 253     else
 254         CFLAGS="$CFLAGS -std=c99"
 255     fi
 256
 257     # Enable -Werror=implicit-function-declaration and
 258     # -Werror=missing-prototypes, if available, or otherwise, just
 259     # -Wmissing-prototypes.  This is particularly useful to avoid
 260     # generating a loadable driver module that has undefined symbols.
 261     save_CFLAGS="$CFLAGS"
 262     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 263     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 264     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 265     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 266                    AC_MSG_RESULT([yes]),
 267                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 268                     AC_MSG_RESULT([no])]);
 269
 270     # Enable -fvisibility=hidden if using a gcc that supports it
 271     save_CFLAGS="$CFLAGS"
 272     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 273     VISIBILITY_CFLAGS="-fvisibility=hidden"
 274     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 275     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 276                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 277
 278     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 279     CFLAGS=$save_CFLAGS
 280
 281     # Work around aliasing bugs - developers should comment this out
 282     CFLAGS="$CFLAGS -fno-strict-aliasing"
 283
 284     # gcc's builtin memcmp is slower than glibc's
 285     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 286     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 287
 288     # Flags to help ensure that certain portions of the code -- and only those
 289     # portions -- can be built with MSVC:
 290     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 291     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 292     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 293     #   supports most of C99)
 294     # - the rest has no compiler compiler restrictions
 295     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 296     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 297
 298     # Enable -Werror=vla if compiler supports it
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 301     CFLAGS="$CFLAGS -Werror=vla"
 302     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 303                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 304                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 305                     AC_MSG_RESULT([yes])],
 306                     AC_MSG_RESULT([no]));
 307     CFLAGS="$save_CFLAGS"
 308
 309     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 310     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 311 fi
 312 if test "x$GXX" = xyes; then
 313     CXXFLAGS="$CXXFLAGS -Wall"
 314
 315     # Enable -fvisibility=hidden if using a gcc that supports it
 316     save_CXXFLAGS="$CXXFLAGS"
 317     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 318     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 319     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 320     AC_LANG_PUSH([C++])
 321     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 322                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 323     AC_LANG_POP([C++])
 324
 325     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 326     CXXFLAGS=$save_CXXFLAGS
 327
 328     # Work around aliasing bugs - developers should comment this out
 329     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 330
 331     # gcc's builtin memcmp is slower than glibc's
 332     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 333     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 334 fi
 335
 336 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 337 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 338 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 339 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 340
 341 dnl even if the compiler appears to support it, using visibility attributes isn't
 342 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 343 case "$host_os" in
 344 cygwin*)
 345     VISIBILITY_CFLAGS=""
 346     VISIBILITY_CXXFLAGS=""
 347     ;;
 348 esac
 349
 350 AC_SUBST([VISIBILITY_CFLAGS])
 351 AC_SUBST([VISIBILITY_CXXFLAGS])
 352
 353 dnl
 354 dnl Optional flags, check for compiler support
 355 dnl
 356 SSE41_CFLAGS="-msse4.1"
 357 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 358 dnl stack, but on x86-32 such alignment is not guaranteed.
 359 case "$target_cpu" in
 360 i?86)
 361     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 362     ;;
 363 esac
 364 save_CFLAGS="$CFLAGS"
 365 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 366 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 367 #include <smmintrin.h>
 368 int main () {
 369     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 370     c = _mm_max_epu32(a, b);
 371     return 0;
 372 }]])], SSE41_SUPPORTED=1)
 373 CFLAGS="$save_CFLAGS"
 374 if test "x$SSE41_SUPPORTED" = x1; then
 375     DEFINES="$DEFINES -DUSE_SSE41"
 376 fi
 377 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 378 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 379
 380 dnl Can't have static and shared libraries, default to static if user
 381 dnl explicitly requested. If both disabled, set to static since shared
 382 dnl was explicitly requested.
 383 case "x$enable_static$enable_shared" in
 384 xyesyes)
 385     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 386     enable_shared=no
 387     ;;
 388 xnono)
 389     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 390     enable_shared=yes
 391     ;;
 392 esac
 393
 394 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 395
 396 dnl
 397 dnl other compiler options
 398 dnl
 399 AC_ARG_ENABLE([debug],
 400     [AS_HELP_STRING([--enable-debug],
 401         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 402     [enable_debug="$enableval"],
 403     [enable_debug=no]
 404 )
 405 if test "x$enable_debug" = xyes; then
 406     DEFINES="$DEFINES -DDEBUG"
 407     if test "x$GCC" = xyes; then
 408         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 409             CFLAGS="$CFLAGS -g"
 410         fi
 411         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 412             CFLAGS="$CFLAGS -O0"
 413         fi
 414     fi
 415     if test "x$GXX" = xyes; then
 416         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 417             CXXFLAGS="$CXXFLAGS -g"
 418         fi
 419         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 420             CXXFLAGS="$CXXFLAGS -O0"
 421         fi
 422     fi
 423 else
 424    DEFINES="$DEFINES -DNDEBUG"
 425 fi
 426
 427 dnl
 428 dnl Check if linker supports -Bsymbolic
 429 dnl
 430 save_LDFLAGS=$LDFLAGS
 431 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 432 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 433 AC_LINK_IFELSE(
 434     [AC_LANG_SOURCE([int main() { return 0;}])],
 435     [AC_MSG_RESULT([yes])
 436         BSYMBOLIC="-Wl,-Bsymbolic";],
 437     [AC_MSG_RESULT([no])
 438         BSYMBOLIC="";])
 439 LDFLAGS=$save_LDFLAGS
 440
 441 AC_SUBST([BSYMBOLIC])
 442
 443 dnl
 444 dnl Check if linker supports garbage collection
 445 dnl
 446 save_LDFLAGS=$LDFLAGS
 447 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 448 AC_MSG_CHECKING([whether ld supports --gc-sections])
 449 AC_LINK_IFELSE(
 450     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 451     [AC_MSG_RESULT([yes])
 452         GC_SECTIONS="-Wl,--gc-sections";],
 453     [AC_MSG_RESULT([no])
 454         GC_SECTIONS="";])
 455 LDFLAGS=$save_LDFLAGS
 456
 457 AC_SUBST([GC_SECTIONS])
 458
 459 dnl
 460 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 461 dnl so when these flags are passed to ld via libtool the checks will fail
 462 dnl
 463 case "$host_os" in
 464 openbsd* | darwin* )
 465     LD_NO_UNDEFINED="" ;;
 466 *)
 467     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 468 esac
 469
 470 AC_SUBST([LD_NO_UNDEFINED])
 471
 472 dnl
 473 dnl Check if linker supports version scripts
 474 dnl
 475 AC_MSG_CHECKING([if the linker supports version-scripts])
 476 save_LDFLAGS=$LDFLAGS
 477 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 478 cat > conftest.map <<EOF
 479 VERSION_1 {
 480      global:
 481          main;
 482
 483      local:
 484          *;
 485 };
 486 EOF
 487 AC_LINK_IFELSE(
 488     [AC_LANG_SOURCE([int main() { return 0;}])],
 489     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 490     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 491 LDFLAGS=$save_LDFLAGS
 492 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 493
 494 dnl
 495 dnl Check if linker supports dynamic list files
 496 dnl
 497 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 498 save_LDFLAGS=$LDFLAGS
 499 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 500 cat > conftest.dyn <<EOF
 501 {
 502         radeon_drm_winsys_create;
 503 };
 504 EOF
 505 AC_LINK_IFELSE(
 506     [AC_LANG_SOURCE([int main() { return 0;}])],
 507     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 508     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 509 LDFLAGS=$save_LDFLAGS
 510 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 511
 512 dnl
 513 dnl compatibility symlinks
 514 dnl
 515 case "$host_os" in
 516 linux* )
 517     HAVE_COMPAT_SYMLINKS=yes ;;
 518 * )
 519     HAVE_COMPAT_SYMLINKS=no ;;
 520 esac
 521
 522 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 523
 524 dnl
 525 dnl library names
 526 dnl
 527 case "$host_os" in
 528 darwin* )
 529     LIB_EXT='dylib' ;;
 530 cygwin* )
 531     LIB_EXT='dll' ;;
 532 aix* )
 533     LIB_EXT='a' ;;
 534 * )
 535     LIB_EXT='so' ;;
 536 esac
 537
 538 AC_SUBST([LIB_EXT])
 539
 540 AC_ARG_WITH([gl-lib-name],
 541   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 542     [specify GL library name @<:@default=GL@:>@])],
 543   [GL_LIB=$withval],
 544   [GL_LIB=GL])
 545 AC_ARG_WITH([osmesa-lib-name],
 546   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 547     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 548   [OSMESA_LIB=$withval],
 549   [OSMESA_LIB=OSMesa])
 550 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 551 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 552
 553 dnl
 554 dnl Mangled Mesa support
 555 dnl
 556 AC_ARG_ENABLE([mangling],
 557   [AS_HELP_STRING([--enable-mangling],
 558     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 559   [enable_mangling="${enableval}"],
 560   [enable_mangling=no]
 561 )
 562 if test "x${enable_mangling}" = "xyes" ; then
 563   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 564   GL_LIB="Mangled${GL_LIB}"
 565   OSMESA_LIB="Mangled${OSMESA_LIB}"
 566 fi
 567 AC_SUBST([GL_LIB])
 568 AC_SUBST([OSMESA_LIB])
 569
 570 dnl
 571 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 572 dnl
 573 AC_ARG_ENABLE([texture-float],
 574     [AS_HELP_STRING([--enable-texture-float],
 575         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 576     [enable_texture_float="$enableval"],
 577     [enable_texture_float=no]
 578 )
 579 if test "x$enable_texture_float" = xyes; then
 580     AC_MSG_WARN([Floating-point textures enabled.])
 581     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 582     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 583 fi
 584
 585 dnl
 586 dnl Arch/platform-specific settings
 587 dnl
 588 AC_ARG_ENABLE([asm],
 589     [AS_HELP_STRING([--disable-asm],
 590         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 591     [enable_asm="$enableval"],
 592     [enable_asm=yes]
 593 )
 594 asm_arch=""
 595 AC_MSG_CHECKING([whether to enable assembly])
 596 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 597 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 598 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 599     case "$host_cpu" in
 600     i?86 | x86_64 | amd64)
 601         enable_asm=no
 602         AC_MSG_RESULT([no, cross compiling])
 603         ;;
 604     esac
 605 fi
 606 # check for supported arches
 607 if test "x$enable_asm" = xyes; then
 608     case "$host_cpu" in
 609     i?86)
 610         case "$host_os" in
 611         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 612             asm_arch=x86
 613             ;;
 614         esac
 615         ;;
 616     x86_64|amd64)
 617         case "$host_os" in
 618         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 619             asm_arch=x86_64
 620             ;;
 621         esac
 622         ;;
 623     sparc*)
 624         case "$host_os" in
 625         linux*)
 626             asm_arch=sparc
 627             ;;
 628         esac
 629         ;;
 630     esac
 631
 632     case "$asm_arch" in
 633     x86)
 634         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 635         AC_MSG_RESULT([yes, x86])
 636         ;;
 637     x86_64|amd64)
 638         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 639         AC_MSG_RESULT([yes, x86_64])
 640         ;;
 641     sparc)
 642         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 643         AC_MSG_RESULT([yes, sparc])
 644         ;;
 645     *)
 646         AC_MSG_RESULT([no, platform not supported])
 647         ;;
 648     esac
 649 fi
 650
 651 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 652 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 653 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 654
 655 dnl Check to see if dlopen is in default libraries (like Solaris, which
 656 dnl has it in libc), or if libdl is needed to get it.
 657 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 658     [AC_CHECK_LIB([dl], [dlopen],
 659        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 660 AC_SUBST([DLOPEN_LIBS])
 661
 662 dnl Check if that library also has dladdr
 663 save_LIBS="$LIBS"
 664 LIBS="$LIBS $DLOPEN_LIBS"
 665 AC_CHECK_FUNCS([dladdr])
 666 LIBS="$save_LIBS"
 667
 668 case "$host_os" in
 669 darwin*)
 670     ;;
 671 *)
 672     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 673                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 674                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 675     AC_SUBST([CLOCK_LIB])
 676     ;;
 677 esac
 678
 679 dnl See if posix_memalign is available
 680 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 681
 682 dnl Check for pthreads
 683 AX_PTHREAD
 684 if test "x$ax_pthread_ok" = xno; then
 685     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 686 fi
 687 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 688 dnl to -pthread, which causes problems if we need -lpthread to appear in
 689 dnl pkgconfig files.
 690 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 691
 692 dnl SELinux awareness.
 693 AC_ARG_ENABLE([selinux],
 694     [AS_HELP_STRING([--enable-selinux],
 695         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 696     [MESA_SELINUX="$enableval"],
 697     [MESA_SELINUX=no])
 698 if test "x$enable_selinux" = "xyes"; then
 699     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 700         [AC_CHECK_HEADER([selinux/selinux.h],[],
 701                          [AC_MSG_ERROR([SELinux headers not found])])
 702          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 703                       [AC_MSG_ERROR([SELinux library not found])])
 704          SELINUX_LIBS="-lselinux"])
 705     DEFINES="$DEFINES -DMESA_SELINUX"
 706 fi
 707 AC_SUBST([SELINUX_CFLAGS])
 708 AC_SUBST([SELINUX_LIBS])
 709
 710 dnl Options for APIs
 711 AC_ARG_ENABLE([opengl],
 712     [AS_HELP_STRING([--disable-opengl],
 713         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 714     [enable_opengl="$enableval"],
 715     [enable_opengl=yes])
 716 AC_ARG_ENABLE([gles1],
 717     [AS_HELP_STRING([--disable-gles1],
 718         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 719     [enable_gles1="$enableval"],
 720     [enable_gles1=yes])
 721 AC_ARG_ENABLE([gles2],
 722     [AS_HELP_STRING([--disable-gles2],
 723         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 724     [enable_gles2="$enableval"],
 725     [enable_gles2=yes])
 726
 727 AC_ARG_ENABLE([dri],
 728     [AS_HELP_STRING([--enable-dri],
 729         [enable DRI modules @<:@default=enabled@:>@])],
 730     [enable_dri="$enableval"],
 731     [enable_dri=yes])
 732
 733 case "$host_os" in
 734 linux*)
 735     dri3_default=yes
 736     ;;
 737 *)
 738     dri3_default=no
 739     ;;
 740 esac
 741 AC_ARG_ENABLE([dri3],
 742     [AS_HELP_STRING([--enable-dri3],
 743         [enable DRI3 @<:@default=auto@:>@])],
 744     [enable_dri3="$enableval"],
 745     [enable_dri3="$dri3_default"])
 746 AC_ARG_ENABLE([glx],
 747     [AS_HELP_STRING([--enable-glx],
 748         [enable GLX library @<:@default=enabled@:>@])],
 749     [enable_glx="$enableval"],
 750     [enable_glx=yes])
 751 AC_ARG_ENABLE([osmesa],
 752     [AS_HELP_STRING([--enable-osmesa],
 753         [enable OSMesa library @<:@default=disabled@:>@])],
 754     [enable_osmesa="$enableval"],
 755     [enable_osmesa=no])
 756 AC_ARG_ENABLE([gallium-osmesa],
 757     [AS_HELP_STRING([--enable-gallium-osmesa],
 758         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 759     [enable_gallium_osmesa="$enableval"],
 760     [enable_gallium_osmesa=no])
 761 AC_ARG_ENABLE([egl],
 762     [AS_HELP_STRING([--disable-egl],
 763         [disable EGL library @<:@default=enabled@:>@])],
 764     [enable_egl="$enableval"],
 765     [enable_egl=yes])
 766
 767 AC_ARG_ENABLE([xa],
 768     [AS_HELP_STRING([--enable-xa],
 769         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 770     [enable_xa="$enableval"],
 771     [enable_xa=no])
 772 AC_ARG_ENABLE([gbm],
 773    [AS_HELP_STRING([--enable-gbm],
 774          [enable gbm library @<:@default=auto@:>@])],
 775    [enable_gbm="$enableval"],
 776    [enable_gbm=auto])
 777 AC_ARG_ENABLE([nine],
 778     [AS_HELP_STRING([--enable-nine],
 779         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 780     [enable_nine="$enableval"],
 781     [enable_nine=no])
 782
 783 AC_ARG_ENABLE([xvmc],
 784    [AS_HELP_STRING([--enable-xvmc],
 785          [enable xvmc library @<:@default=auto@:>@])],
 786    [enable_xvmc="$enableval"],
 787    [enable_xvmc=auto])
 788 AC_ARG_ENABLE([vdpau],
 789    [AS_HELP_STRING([--enable-vdpau],
 790          [enable vdpau library @<:@default=auto@:>@])],
 791    [enable_vdpau="$enableval"],
 792    [enable_vdpau=auto])
 793 AC_ARG_ENABLE([omx],
 794    [AS_HELP_STRING([--enable-omx],
 795          [enable OpenMAX library @<:@default=disabled@:>@])],
 796    [enable_omx="$enableval"],
 797    [enable_omx=no])
 798 AC_ARG_ENABLE([va],
 799    [AS_HELP_STRING([--enable-va],
 800          [enable va library @<:@default=auto@:>@])],
 801    [enable_va="$enableval"],
 802    [enable_va=auto])
 803 AC_ARG_ENABLE([opencl],
 804    [AS_HELP_STRING([--enable-opencl],
 805          [enable OpenCL library @<:@default=disabled@:>@])],
 806    [enable_opencl="$enableval"],
 807    [enable_opencl=no])
 808 AC_ARG_ENABLE([opencl_icd],
 809    [AS_HELP_STRING([--enable-opencl-icd],
 810           [Build an OpenCL ICD library to be loaded by an ICD implementation
 811            @<:@default=disabled@:>@])],
 812     [enable_opencl_icd="$enableval"],
 813     [enable_opencl_icd=no])
 814 AC_ARG_ENABLE([xlib-glx],
 815     [AS_HELP_STRING([--enable-xlib-glx],
 816         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 817     [enable_xlib_glx="$enableval"],
 818     [enable_xlib_glx=no])
 819
 820 AC_ARG_ENABLE([r600-llvm-compiler],
 821     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 822         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 823     [enable_r600_llvm="$enableval"],
 824     [enable_r600_llvm=no])
 825
 826 AC_ARG_ENABLE([gallium-tests],
 827     [AS_HELP_STRING([--enable-gallium-tests],
 828         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 829     [enable_gallium_tests="$enableval"],
 830     [enable_gallium_tests=no])
 831
 832 # Option for Gallium drivers
 833
 834 # Keep this in sync with the --with-gallium-drivers help string default value
 835 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 836
 837 AC_ARG_WITH([gallium-drivers],
 838     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 839         [comma delimited Gallium drivers list, e.g.
 840         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 841         @<:@default=r300,r600,svga,swrast@:>@])],
 842     [with_gallium_drivers="$withval"],
 843     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 844
 845 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 846 # here so that the script doesn't choke on an unknown driver name later.
 847 case "$with_gallium_drivers" in
 848     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 849     no) with_gallium_drivers='' ;;
 850 esac
 851
 852 if test "x$enable_opengl" = xno -a \
 853         "x$enable_gles1" = xno -a \
 854         "x$enable_gles2" = xno -a \
 855         "x$enable_nine" = xno -a \
 856         "x$enable_xa" = xno -a \
 857         "x$enable_xvmc" = xno -a \
 858         "x$enable_vdpau" = xno -a \
 859         "x$enable_omx" = xno -a \
 860         "x$enable_va" = xno -a \
 861         "x$enable_opencl" = xno; then
 862     AC_MSG_ERROR([at least one API should be enabled])
 863 fi
 864
 865 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 866 if test "x$enable_opengl" = xno -a \
 867         "x$enable_gles1" = xyes; then
 868     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 869 fi
 870
 871 if test "x$enable_opengl" = xno -a \
 872         "x$enable_gles2" = xyes; then
 873     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 874 fi
 875
 876 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 877 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 878 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 879 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 880                                         "x$enable_gles1" = xyes -o \
 881                                         "x$enable_gles2" = xyes)
 882
 883 if test "x$enable_glx" = xno; then
 884     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 885     enable_xlib_glx=no
 886 fi
 887
 888 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 889     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 890 fi
 891
 892 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 893     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 894 fi
 895
 896 # Disable GLX if OpenGL is not enabled
 897 if test "x$enable_glx$enable_opengl" = xyesno; then
 898     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 899     enable_glx=no
 900 fi
 901
 902 # Disable GLX if DRI and Xlib-GLX are not enabled
 903 if test "x$enable_glx" = xyes -a \
 904         "x$enable_dri" = xno -a \
 905         "x$enable_xlib_glx" = xno; then
 906     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 907     enable_glx=no
 908 fi
 909
 910 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 911                                   "x$enable_dri" = xyes)
 912
 913 # Select which platform-dependent DRI code gets built
 914 case "$host_os" in
 915 darwin*)
 916     dri_platform='apple' ;;
 917 gnu*|cygwin*)
 918     dri_platform='none' ;;
 919 *)
 920     dri_platform='drm' ;;
 921 esac
 922
 923 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 924 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 925 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 926 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 927 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 928
 929 AC_ARG_ENABLE([shared-glapi],
 930     [AS_HELP_STRING([--enable-shared-glapi],
 931         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 932     [enable_shared_glapi="$enableval"],
 933     [enable_shared_glapi=yes])
 934
 935 case "x$enable_opengl$enable_gles1$enable_gles2" in
 936 x*yes*yes*)
 937     if test "x$enable_shared_glapi" = xno; then
 938         AC_MSG_ERROR([shared GLAPI required when building two or more of
 939                       the following APIs - opengl, gles1 gles2])
 940     fi
 941     ;;
 942 esac
 943
 944 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 945
 946 # Build the pipe-drivers as separate libraries/modules.
 947 # Do not touch this unless you know what you are doing.
 948 # XXX: Expose via configure option ?
 949 enable_shared_pipe_drivers=no
 950
 951 dnl
 952 dnl Driver specific build directories
 953 dnl
 954
 955 case "x$enable_glx$enable_xlib_glx" in
 956 xyesyes)
 957     NEED_WINSYS_XLIB="yes"
 958     ;;
 959 esac
 960
 961 if test "x$enable_dri" = xyes; then
 962     enable_gallium_loader="$enable_shared_pipe_drivers"
 963 fi
 964
 965 if test "x$enable_gallium_osmesa" = xyes; then
 966     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 967         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 968     fi
 969     if test "x$enable_osmesa" = xyes; then
 970         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 971     fi
 972 fi
 973
 974 AC_SUBST([MESA_LLVM])
 975
 976 # SHA1 hashing
 977 AC_ARG_WITH([sha1],
 978         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 979         [choose SHA1 implementation])])
 980 case "x$with_sha1" in
 981 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 982   ;;
 983 *)
 984         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 985 esac
 986
 987 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 988 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 989         with_sha1=libc
 990 fi
 991 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 992         AC_MSG_ERROR([sha1 in libc requested but not found])
 993 fi
 994 if test "x$with_sha1" = xlibc; then
 995         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 996                 [Use libc SHA1 functions])
 997         SHA1_LIBS=""
 998 fi
 999 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1000 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1001         with_sha1=CommonCrypto
1002 fi
1003 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1004         AC_MSG_ERROR([CommonCrypto requested but not found])
1005 fi
1006 if test "x$with_sha1" = xCommonCrypto; then
1007         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1008                 [Use CommonCrypto SHA1 functions])
1009         SHA1_LIBS=""
1010 fi
1011 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1012 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1013 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1014         with_sha1=CryptoAPI
1015 fi
1016 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1017         AC_MSG_ERROR([CryptoAPI requested but not found])
1018 fi
1019 if test "x$with_sha1" = xCryptoAPI; then
1020         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1021                 [Use CryptoAPI SHA1 functions])
1022         SHA1_LIBS=""
1023 fi
1024 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1025 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1026         with_sha1=libmd
1027 fi
1028 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1029         AC_MSG_ERROR([libmd requested but not found])
1030 fi
1031 if test "x$with_sha1" = xlibmd; then
1032         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1033                   [Use libmd SHA1 functions])
1034         SHA1_LIBS=-lmd
1035 fi
1036 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1037 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1038    with_sha1=libsha1
1039 fi
1040 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1041         AC_MSG_ERROR([libsha1 requested but not found])
1042 fi
1043 if test "x$with_sha1" = xlibsha1; then
1044         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1045                   [Use libsha1 for SHA1])
1046         SHA1_LIBS=-lsha1
1047 fi
1048 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1049 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1050         with_sha1=libnettle
1051 fi
1052 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1053         AC_MSG_ERROR([libnettle requested but not found])
1054 fi
1055 if test "x$with_sha1" = xlibnettle; then
1056         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1057                   [Use libnettle SHA1 functions])
1058         SHA1_LIBS=-lnettle
1059 fi
1060 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1061 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1062         with_sha1=libgcrypt
1063 fi
1064 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1065         AC_MSG_ERROR([libgcrypt requested but not found])
1066 fi
1067 if test "x$with_sha1" = xlibgcrypt; then
1068         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1069                   [Use libgcrypt SHA1 functions])
1070         SHA1_LIBS=-lgcrypt
1071 fi
1072 # We don't need all of the OpenSSL libraries, just libcrypto
1073 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1074 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1075                   [HAVE_OPENSSL_PKC=no])
1076 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1077         if test "x$with_sha1" = x; then
1078                 with_sha1=libcrypto
1079         fi
1080 else
1081         if test "x$with_sha1" = xlibcrypto; then
1082                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1083         fi
1084 fi
1085 if test "x$with_sha1" = xlibcrypto; then
1086         if test "x$HAVE_LIBCRYPTO" = xyes; then
1087                 SHA1_LIBS=-lcrypto
1088         else
1089                 SHA1_LIBS="$OPENSSL_LIBS"
1090                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1091         fi
1092 fi
1093 AC_MSG_CHECKING([for SHA1 implementation])
1094 AC_MSG_RESULT([$with_sha1])
1095 AC_SUBST(SHA1_LIBS)
1096 AC_SUBST(SHA1_CFLAGS)
1097
1098 # Allow user to configure out the shader-cache feature
1099 AC_ARG_ENABLE([shader-cache],
1100     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1101     [enable_shader_cache="$enableval"],
1102     [if test "x$with_sha1" != "x"; then
1103         enable_shader_cache=yes
1104      else
1105         enable_shader_cache=no
1106      fi])
1107 if test "x$with_sha1" = "x"; then
1108     if test "x$enable_shader_cache" = "xyes"; then
1109         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1110     fi
1111 fi
1112 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1113
1114 # Check for libdrm
1115 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1116                   [have_libdrm=yes], [have_libdrm=no])
1117 if test "x$have_libdrm" = xyes; then
1118         DEFINES="$DEFINES -DHAVE_LIBDRM"
1119 fi
1120
1121 case "$host_os" in
1122 linux*)
1123     need_pci_id=yes ;;
1124 *)
1125     need_pci_id=no ;;
1126 esac
1127
1128 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1129                   have_libudev=yes, have_libudev=no)
1130
1131 AC_ARG_ENABLE([sysfs],
1132     [AS_HELP_STRING([--enable-sysfs],
1133         [enable /sys PCI identification @<:@default=disabled@:>@])],
1134     [have_sysfs="$enableval"],
1135     [have_sysfs=no]
1136 )
1137
1138 if test "x$enable_dri" = xyes; then
1139     if test "$enable_static" = yes; then
1140         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1141     fi
1142
1143     # not a hard requirement as swrast does not depend on it
1144     if test "x$have_libdrm" = xyes; then
1145         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1146     fi
1147 fi
1148
1149 AC_ARG_ENABLE([driglx-direct],
1150     [AS_HELP_STRING([--disable-driglx-direct],
1151         [disable direct rendering in GLX and EGL for DRI \
1152             @<:@default=auto@:>@])],
1153     [driglx_direct="$enableval"],
1154     [driglx_direct="yes"])
1155
1156 # Check for libcaca
1157 PKG_CHECK_EXISTS([caca], [have_libcaca=yes], [have_libcaca=no])
1158 AM_CONDITIONAL([HAVE_LIBCACA], [test x$have_libcaca = xyes])
1159
1160 dnl
1161 dnl libGL configuration per driver
1162 dnl
1163 case "x$enable_glx$enable_xlib_glx" in
1164 xyesyes)
1165     # Xlib-based GLX
1166     dri_modules="x11 xext xcb"
1167     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1168     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1169     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1170     GL_LIB_DEPS="$XLIBGL_LIBS"
1171     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1172     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1173     ;;
1174 xyesno)
1175     # DRI-based GLX
1176     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1177
1178     # find the DRI deps for libGL
1179     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1180
1181     if test x"$driglx_direct" = xyes; then
1182         if test x"$dri_platform" = xdrm ; then
1183             DEFINES="$DEFINES -DGLX_USE_DRM"
1184             if test "x$have_libdrm" != xyes; then
1185                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1186             fi
1187
1188             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1189             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1190             if test x"$enable_dri3" = xyes; then
1191                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1192                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1193             fi
1194
1195             if test x"$enable_dri" = xyes; then
1196                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1197             fi
1198
1199             if test x"$enable_dri3" = xyes; then
1200                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1201                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1202             fi
1203         fi
1204         if test x"$dri_platform" = xapple ; then
1205             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1206         fi
1207     fi
1208
1209     # add xf86vidmode if available
1210     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1211     if test "$HAVE_XF86VIDMODE" = yes ; then
1212         dri_modules="$dri_modules xxf86vm"
1213     fi
1214
1215     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1216     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1217     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1218     GL_LIB_DEPS="$DRIGL_LIBS"
1219
1220     # need DRM libs, $PTHREAD_LIBS, etc.
1221     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1222     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1223     ;;
1224 esac
1225
1226 have_pci_id=no
1227 if test "$have_libudev" = yes; then
1228     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1229     have_pci_id=yes
1230 fi
1231
1232 if test "$have_sysfs" = yes; then
1233     DEFINES="$DEFINES -DHAVE_SYSFS"
1234     have_pci_id=yes
1235 fi
1236
1237 # This is outside the case (above) so that it is invoked even for non-GLX
1238 # builds.
1239 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1240
1241 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1242 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1243 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1244 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1245
1246 AC_SUBST([X11_INCLUDES])
1247 AC_SUBST([GL_LIB_DEPS])
1248 AC_SUBST([GL_PC_REQ_PRIV])
1249 AC_SUBST([GL_PC_LIB_PRIV])
1250 AC_SUBST([GL_PC_CFLAGS])
1251 AC_SUBST([DRI_PC_REQ_PRIV])
1252 AC_SUBST([GLESv1_CM_LIB_DEPS])
1253 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1254 AC_SUBST([GLESv2_LIB_DEPS])
1255 AC_SUBST([GLESv2_PC_LIB_PRIV])
1256
1257 AC_SUBST([HAVE_XF86VIDMODE])
1258
1259 dnl
1260 dnl More GLX setup
1261 dnl
1262 case "x$enable_glx$enable_xlib_glx" in
1263 xyesyes)
1264     DEFINES="$DEFINES -DUSE_XSHM"
1265     ;;
1266 xyesno)
1267     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1268     if test "x$driglx_direct" = xyes; then
1269         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1270     fi
1271     ;;
1272 esac
1273
1274 dnl
1275 dnl TLS detection
1276 dnl
1277
1278 AC_ARG_ENABLE([glx-tls],
1279     [AS_HELP_STRING([--enable-glx-tls],
1280         [enable TLS support in GLX @<:@default=disabled@:>@])],
1281     [GLX_USE_TLS="$enableval"],
1282     [GLX_USE_TLS=no])
1283 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1284
1285 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1286       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1287
1288 dnl
1289 dnl More DRI setup
1290 dnl
1291 dnl Directory for DRI drivers
1292 AC_ARG_WITH([dri-driverdir],
1293     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1294         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1295     [DRI_DRIVER_INSTALL_DIR="$withval"],
1296     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1297 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1298 dnl Extra search path for DRI drivers
1299 AC_ARG_WITH([dri-searchpath],
1300     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1301         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1302     [DRI_DRIVER_SEARCH_DIR="$withval"],
1303     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1304 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1305 dnl Which drivers to build - default is chosen by platform
1306 AC_ARG_WITH([dri-drivers],
1307     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1308         [comma delimited classic DRI drivers list, e.g.
1309         "swrast,i965,radeon" @<:@default=auto@:>@])],
1310     [with_dri_drivers="$withval"],
1311     [with_dri_drivers=auto])
1312
1313 if test "x$with_dri_drivers" = xauto; then
1314     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1315         with_dri_drivers="yes"
1316     else
1317         with_dri_drivers="no"
1318     fi
1319 fi
1320 if test "x$with_dri_drivers" = xno; then
1321     with_dri_drivers=''
1322 fi
1323
1324 dnl If $with_dri_drivers is yes, drivers will be added through
1325 dnl platform checks. Set DEFINES and LIB_DEPS
1326 if test "x$enable_dri" = xyes; then
1327     # Platform specific settings and drivers to build
1328     case "$host_os" in
1329     linux*)
1330         DEFINES="$DEFINES -DHAVE_ALIAS"
1331         if test "x$enable_dri3" = xyes; then
1332             DEFINES="$DEFINES -DHAVE_DRI3"
1333         fi
1334
1335         if test "x$have_pci_id" != xyes; then
1336             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1337         fi
1338
1339         case "$host_cpu" in
1340         powerpc* | sparc*)
1341             # Build only the drivers for cards that exist on PowerPC/sparc
1342             if test "x$with_dri_drivers" = "xyes"; then
1343                 with_dri_drivers="r200 radeon swrast"
1344             fi
1345             ;;
1346         esac
1347         ;;
1348     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1349         DEFINES="$DEFINES -DHAVE_ALIAS"
1350         ;;
1351     gnu*)
1352         DEFINES="$DEFINES -DHAVE_ALIAS"
1353         ;;
1354     cygwin*)
1355         if test "x$with_dri_drivers" = "xyes"; then
1356             with_dri_drivers="swrast"
1357         fi
1358         ;;
1359     darwin*)
1360         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1361         if test "x$with_dri_drivers" = "xyes"; then
1362             with_dri_drivers="swrast"
1363         fi
1364         ;;
1365     esac
1366
1367     # default drivers
1368     if test "x$with_dri_drivers" = "xyes"; then
1369         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1370     fi
1371
1372     # Check for expat
1373     PKG_CHECK_MODULES([EXPAT], [expat], [],
1374         # expat version 2.0 and earlier do not provide expat.pc
1375         [AC_CHECK_HEADER([expat.h],[],
1376                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1377          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1378                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1379          EXPAT_LIBS="-lexpat"])
1380
1381     DRICOMMON_NEED_LIBDRM=no
1382     # If we are building any DRI driver other than swrast.
1383     if test -n "$with_dri_drivers"; then
1384         if test "x$with_dri_drivers" != xswrast; then
1385             # ... libdrm is required
1386             if test "x$have_libdrm" != xyes; then
1387                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1388             fi
1389             DRICOMMON_NEED_LIBDRM=yes
1390         fi
1391     fi
1392
1393     # If we're building any gallium DRI driver other than swrast
1394     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1395         if test "x$with_gallium_drivers" != xswrast; then
1396             # ... build a libdrm aware dricommon
1397             DRICOMMON_NEED_LIBDRM=yes
1398         fi
1399     fi
1400
1401     # put all the necessary libs together
1402     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1403 fi
1404
1405 AC_SUBST([DRI_LIB_DEPS])
1406
1407 DRI_DIRS=''
1408 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1409 if test -n "$with_dri_drivers"; then
1410     if test "x$enable_opengl" != xyes; then
1411         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1412     fi
1413
1414     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1415     for driver in $dri_drivers; do
1416         DRI_DIRS="$DRI_DIRS $driver"
1417         case "x$driver" in
1418         xi915)
1419             HAVE_I915_DRI=yes;
1420             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1421             ;;
1422         xi965)
1423             HAVE_I965_DRI=yes;
1424             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1425             ;;
1426         xnouveau)
1427             HAVE_NOUVEAU_DRI=yes;
1428             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1429             ;;
1430         xradeon)
1431             HAVE_RADEON_DRI=yes;
1432             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1433             ;;
1434         xr200)
1435             HAVE_R200_DRI=yes;
1436             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1437             ;;
1438         xswrast)
1439             HAVE_SWRAST_DRI=yes;
1440             ;;
1441         *)
1442             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1443             ;;
1444         esac
1445     done
1446     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1447 fi
1448
1449 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1450 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1451                                   "x$enable_osmesa" = xyes -o \
1452                                   -n "$DRI_DIRS")
1453
1454 dnl
1455 dnl OSMesa configuration
1456 dnl
1457
1458 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1459 AC_ARG_WITH([osmesa-bits],
1460     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1461         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1462     [osmesa_bits="$withval"],
1463     [osmesa_bits=8])
1464 if test "x$osmesa_bits" != x8; then
1465     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1466         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1467         osmesa_bits=8
1468     fi
1469 fi
1470 case "x$osmesa_bits" in
1471 x8)
1472     OSMESA_LIB="${OSMESA_LIB}"
1473     ;;
1474 x16|x32)
1475     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1476     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1477     ;;
1478 *)
1479     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1480     ;;
1481 esac
1482
1483 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1484     # only link libraries with osmesa if shared
1485     if test "$enable_static" = no; then
1486         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1487     else
1488         OSMESA_LIB_DEPS=""
1489     fi
1490     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1491 fi
1492
1493 AC_SUBST([OSMESA_LIB_DEPS])
1494 AC_SUBST([OSMESA_PC_REQ])
1495 AC_SUBST([OSMESA_PC_LIB_PRIV])
1496
1497 dnl
1498 dnl gbm configuration
1499 dnl
1500 if test "x$enable_gbm" = xauto; then
1501     case "$with_egl_platforms" in
1502         *drm*)
1503             enable_gbm=yes ;;
1504          *)
1505             enable_gbm=no ;;
1506     esac
1507 fi
1508 if test "x$enable_gbm" = xyes; then
1509     if test "x$need_pci_id$have_pci_id" = xyesno; then
1510         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1511     fi
1512
1513     if test "x$enable_dri" = xyes; then
1514         if test "x$enable_shared_glapi" = xno; then
1515             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1516         fi
1517     else
1518         # Strictly speaking libgbm does not require --enable-dri, although
1519         # both of its backends do. Thus one can build libgbm without any
1520         # backends if --disable-dri is set.
1521         # To avoid unnecessary complexity of checking if at least one backend
1522         # is available when building, just mandate --enable-dri.
1523         AC_MSG_ERROR([gbm requires --enable-dri])
1524     fi
1525 fi
1526 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1527 if test "x$need_pci_id$have_libudev" = xyesyes; then
1528     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1529 else
1530     GBM_PC_REQ_PRIV=""
1531 fi
1532 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1533 AC_SUBST([GBM_PC_REQ_PRIV])
1534 AC_SUBST([GBM_PC_LIB_PRIV])
1535
1536 AM_CONDITIONAL(HAVE_VULKAN, true)
1537
1538 dnl
1539 dnl EGL configuration
1540 dnl
1541 EGL_CLIENT_APIS=""
1542
1543 if test "x$enable_egl" = xyes; then
1544     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1545
1546     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1547
1548     if test "$enable_static" != yes; then
1549         if test "x$enable_dri" = xyes; then
1550             HAVE_EGL_DRIVER_DRI2=1
1551             if test "x$enable_shared_glapi" = xno; then
1552                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1553             fi
1554         else
1555             # Avoid building an "empty" libEGL. Drop/update this
1556             # when other backends (haiku?) come along.
1557             AC_MSG_ERROR([egl requires --enable-dri])
1558         fi
1559
1560     fi
1561 fi
1562 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1563 AC_SUBST([EGL_LIB_DEPS])
1564
1565 dnl
1566 dnl XA configuration
1567 dnl
1568 if test "x$enable_xa" = xyes; then
1569     if test "x$with_gallium_drivers" = xswrast; then
1570        AC_MSG_ERROR([
1571           Building xa requires at least one non swrast gallium driver.
1572           If you are looking to use libxatracker.so with the VMware driver,
1573           make sure to include svga in the gallium drivers list, apart from
1574           enabling XA.
1575           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1576     fi
1577     enable_gallium_loader=$enable_shared_pipe_drivers
1578 fi
1579 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1580
1581 dnl
1582 dnl Gallium G3DVL configuration
1583 dnl
1584 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1585     if test "x$enable_xvmc" = xauto; then
1586         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1587     fi
1588
1589     if test "x$enable_vdpau" = xauto; then
1590         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1591     fi
1592
1593     if test "x$enable_omx" = xauto; then
1594         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1595     fi
1596
1597     if test "x$enable_va" = xauto; then
1598         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1599     fi
1600 fi
1601
1602 if test "x$enable_dri" = xyes -o \
1603         "x$enable_xvmc" = xyes -o \
1604         "x$enable_vdpau" = xyes -o \
1605         "x$enable_omx" = xyes -o \
1606         "x$enable_va" = xyes; then
1607     need_gallium_vl=yes
1608 fi
1609 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1610
1611 if test "x$enable_xvmc" = xyes -o \
1612         "x$enable_vdpau" = xyes -o \
1613         "x$enable_omx" = xyes -o \
1614         "x$enable_va" = xyes; then
1615     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1616     need_gallium_vl_winsys=yes
1617 fi
1618 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1619
1620 if test "x$enable_xvmc" = xyes; then
1621     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1622     enable_gallium_loader=$enable_shared_pipe_drivers
1623 fi
1624 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1625
1626 if test "x$enable_vdpau" = xyes; then
1627     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1628     enable_gallium_loader=$enable_shared_pipe_drivers
1629 fi
1630 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1631
1632 if test "x$enable_omx" = xyes; then
1633     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1634     enable_gallium_loader=$enable_shared_pipe_drivers
1635 fi
1636 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1637
1638 if test "x$enable_va" = xyes; then
1639     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1640     enable_gallium_loader=$enable_shared_pipe_drivers
1641 fi
1642 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1643
1644 dnl
1645 dnl Nine Direct3D9 configuration
1646 dnl
1647 if test "x$enable_nine" = xyes; then
1648     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1649         AC_MSG_ERROR([nine requires the gallium swrast driver])
1650     fi
1651     if test "x$with_gallium_drivers" = xswrast; then
1652         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1653     fi
1654     if test "x$enable_dri3" = xno; then
1655         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1656     fi
1657
1658     enable_gallium_loader=$enable_shared_pipe_drivers
1659 fi
1660 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1661
1662 dnl
1663 dnl OpenCL configuration
1664 dnl
1665
1666 AC_ARG_WITH([clang-libdir],
1667    [AS_HELP_STRING([--with-clang-libdir],
1668          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1669    [CLANG_LIBDIR="$withval"],
1670    [CLANG_LIBDIR=''])
1671
1672 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1673 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1674
1675 if test "x$enable_opencl" = xyes; then
1676     if test -z "$with_gallium_drivers"; then
1677         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1678     fi
1679
1680     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1681         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1682     fi
1683
1684     if test "x$have_libclc" = xno; then
1685         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1686                     Make sure the directory containing libclc.pc is specified in your
1687                     PKG_CONFIG_PATH environment variable.
1688                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1689     else
1690         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1691         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1692         AC_SUBST([LIBCLC_INCLUDEDIR])
1693         AC_SUBST([LIBCLC_LIBEXECDIR])
1694     fi
1695
1696     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1697     enable_gallium_loader=yes
1698
1699     if test "x$enable_opencl_icd" = xyes; then
1700         OPENCL_LIBNAME="MesaOpenCL"
1701     else
1702         OPENCL_LIBNAME="OpenCL"
1703     fi
1704
1705     if test "x$have_libelf" != xyes; then
1706        AC_MSG_ERROR([Clover requires libelf])
1707     fi
1708 fi
1709 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1710 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1711 AC_SUBST([OPENCL_LIBNAME])
1712
1713 dnl
1714 dnl Gallium configuration
1715 dnl
1716 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1717
1718 AC_SUBST([LLVM_BINDIR])
1719 AC_SUBST([LLVM_CFLAGS])
1720 AC_SUBST([LLVM_CPPFLAGS])
1721 AC_SUBST([LLVM_CXXFLAGS])
1722 AC_SUBST([LLVM_LIBDIR])
1723 AC_SUBST([LLVM_LIBS])
1724 AC_SUBST([LLVM_LDFLAGS])
1725 AC_SUBST([LLVM_INCLUDEDIR])
1726 AC_SUBST([LLVM_VERSION])
1727 AC_SUBST([CLANG_RESOURCE_DIR])
1728
1729 case "x$enable_opengl$enable_gles1$enable_gles2" in
1730 x*yes*)
1731     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1732     ;;
1733 esac
1734
1735 AC_SUBST([VG_LIB_DEPS])
1736 AC_SUBST([EGL_CLIENT_APIS])
1737
1738 dnl
1739 dnl EGL Platforms configuration
1740 dnl
1741 AC_ARG_WITH([egl-platforms],
1742     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1743         [comma delimited native platforms libEGL supports, e.g.
1744         "x11,drm" @<:@default=auto@:>@])],
1745     [with_egl_platforms="$withval"],
1746     [if test "x$enable_egl" = xyes; then
1747         with_egl_platforms="x11"
1748     else
1749         with_egl_platforms=""
1750     fi])
1751
1752 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1753     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1754 fi
1755
1756 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1757         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1758         WAYLAND_SCANNER='')
1759 if test "x$WAYLAND_SCANNER" = x; then
1760     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1761 fi
1762
1763 # Do per-EGL platform setups and checks
1764 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1765 for plat in $egl_platforms; do
1766         case "$plat" in
1767         wayland)
1768                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1769
1770                 if test "x$WAYLAND_SCANNER" = x; then
1771                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1772                 fi
1773                 ;;
1774
1775         x11)
1776                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1777                 ;;
1778
1779         drm)
1780                 test "x$enable_gbm" = "xno" &&
1781                         AC_MSG_ERROR([EGL platform drm needs gbm])
1782                 test "x$have_libdrm" != xyes &&
1783                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1784                 ;;
1785
1786         surfaceless)
1787                 test "x$have_libdrm" != xyes &&
1788                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1789                 ;;
1790
1791         android|gdi|null)
1792                 ;;
1793
1794         *)
1795                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1796                 ;;
1797         esac
1798
1799         case "$plat$need_pci_id$have_pci_id" in
1800                 waylandyesno|drmyesno)
1801                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1802         esac
1803 done
1804
1805 # libEGL wants to default to the first platform specified in
1806 # ./configure.  parse that here.
1807 if test "x$egl_platforms" != "x"; then
1808     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1809     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1810 else
1811     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1812 fi
1813
1814 if echo "$egl_platforms" | grep -q 'x11'; then
1815     NEED_WINSYS_XLIB=yes
1816 fi
1817 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1818 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1819 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1820 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1821 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1822
1823 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1824
1825 AC_SUBST([EGL_NATIVE_PLATFORM])
1826 AC_SUBST([EGL_CFLAGS])
1827
1828 # If we don't have the X11 platform, set this define so we don't try to include
1829 # the X11 headers.
1830 if ! echo "$egl_platforms" | grep -q 'x11'; then
1831     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1832     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1833 fi
1834
1835 dnl
1836 dnl Gallium LLVM
1837 dnl
1838 AC_ARG_ENABLE([gallium-llvm],
1839     [AS_HELP_STRING([--enable-gallium-llvm],
1840         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1841     [enable_gallium_llvm="$enableval"],
1842     [enable_gallium_llvm=auto])
1843
1844 AC_ARG_ENABLE([llvm-shared-libs],
1845     [AS_HELP_STRING([--enable-llvm-shared-libs],
1846         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1847     [enable_llvm_shared_libs="$enableval"],
1848     [enable_llvm_shared_libs=yes])
1849
1850 AC_ARG_WITH([llvm-prefix],
1851     [AS_HELP_STRING([--with-llvm-prefix],
1852         [Prefix for LLVM installations in non-standard locations])],
1853     [llvm_prefix="$withval"],
1854     [llvm_prefix=''])
1855
1856
1857 # Call this inside ` ` to get the return value.
1858 # $1 is the llvm-config command with arguments.
1859 strip_unwanted_llvm_flags() {
1860     # Use \> (marks the end of the word)
1861     echo `$1` | sed \
1862         -e 's/-DNDEBUG\>//g' \
1863         -e 's/-D_GNU_SOURCE\>//g' \
1864         -e 's/-pedantic\>//g' \
1865         -e 's/-Wcovered-switch-default\>//g' \
1866         -e 's/-O.\>//g' \
1867         -e 's/-g\>//g' \
1868         -e 's/-Wall\>//g' \
1869         -e 's/-Wcast-qual\>//g' \
1870         -e 's/-Woverloaded-virtual\>//g' \
1871         -e 's/-fcolor-diagnostics\>//g' \
1872         -e 's/-fdata-sections\>//g' \
1873         -e 's/-ffunction-sections\>//g' \
1874         -e 's/-fno-exceptions\>//g' \
1875         -e 's/-fomit-frame-pointer\>//g' \
1876         -e 's/-fvisibility-inlines-hidden\>//g' \
1877         -e 's/-fPIC\>//g' \
1878         -e 's/-fstack-protector-strong\>//g'
1879 }
1880
1881 llvm_check_version_for() {
1882     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1883         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1884     fi
1885 }
1886
1887
1888
1889 if test -z "$with_gallium_drivers"; then
1890     enable_gallium_llvm=no
1891 fi
1892 if test "x$enable_gallium_llvm" = xauto; then
1893     case "$host_cpu" in
1894     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1895     esac
1896 fi
1897 if test "x$enable_gallium_llvm" = xyes; then
1898     if test -n "$llvm_prefix"; then
1899         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1900     else
1901         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1902     fi
1903
1904     if test "x$LLVM_CONFIG" != xno; then
1905         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1906         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1907         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1908         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1909         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1910         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1911         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1912         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1913
1914         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1915             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1916         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1917             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1918
1919         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1920         if test -z "$LLVM_VERSION_PATCH"; then
1921             LLVM_VERSION_PATCH=0
1922         fi
1923
1924         if test -n "${LLVM_VERSION_MAJOR}"; then
1925             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1926         else
1927             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1928         fi
1929
1930         LLVM_REQUIRED_VERSION_MAJOR="3"
1931         LLVM_REQUIRED_VERSION_MINOR="3"
1932         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1933             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1934         fi
1935
1936         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1937
1938         if test "x$enable_opencl" = xyes; then
1939             llvm_check_version_for "3" "5" "0" "opencl"
1940
1941             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1942             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1943         fi
1944         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1945         MESA_LLVM=1
1946
1947         dnl Check for Clang internal headers
1948         if test "x$enable_opencl" = xyes; then
1949             if test -z "$CLANG_LIBDIR"; then
1950                 CLANG_LIBDIR=${LLVM_LIBDIR}
1951             fi
1952             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1953             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1954                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1955         fi
1956     else
1957         MESA_LLVM=0
1958         LLVM_VERSION_INT=0
1959     fi
1960 else
1961     MESA_LLVM=0
1962     LLVM_VERSION_INT=0
1963
1964     if test "x$enable_opencl" = xyes; then
1965         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1966     fi
1967 fi
1968
1969 dnl Directory for XVMC libs
1970 AC_ARG_WITH([xvmc-libdir],
1971     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1972         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1973     [XVMC_LIB_INSTALL_DIR="$withval"],
1974     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1975 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1976
1977 dnl
1978 dnl Gallium Tests
1979 dnl
1980 if test "x$enable_gallium_tests" = xyes; then
1981     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1982     enable_gallium_loader=yes
1983 fi
1984 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1985
1986 dnl Directory for VDPAU libs
1987 AC_ARG_WITH([vdpau-libdir],
1988     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1989         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1990     [VDPAU_LIB_INSTALL_DIR="$withval"],
1991     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1992 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1993
1994 dnl Directory for OMX libs
1995
1996 AC_ARG_WITH([omx-libdir],
1997     [AS_HELP_STRING([--with-omx-libdir=DIR],
1998         [directory for the OMX libraries])],
1999     [OMX_LIB_INSTALL_DIR="$withval"],
2000     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2001 AC_SUBST([OMX_LIB_INSTALL_DIR])
2002
2003 dnl Directory for VA libs
2004
2005 AC_ARG_WITH([va-libdir],
2006     [AS_HELP_STRING([--with-va-libdir=DIR],
2007         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2008     [VA_LIB_INSTALL_DIR="$withval"],
2009     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2010 AC_SUBST([VA_LIB_INSTALL_DIR])
2011
2012 AC_ARG_WITH([d3d-libdir],
2013     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2014         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2015     [D3D_DRIVER_INSTALL_DIR="$withval"],
2016     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2017 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2018
2019 dnl
2020 dnl Gallium helper functions
2021 dnl
2022 gallium_require_drm() {
2023     if test "x$have_libdrm" != xyes; then
2024        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2025     fi
2026 }
2027
2028 gallium_require_llvm() {
2029     if test "x$MESA_LLVM" = x0; then
2030         case "$host" in *gnux32) return;; esac
2031         case "$host_cpu" in
2032         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2033         esac
2034     fi
2035 }
2036
2037 gallium_require_drm_loader() {
2038     if test "x$enable_gallium_loader" = xyes; then
2039         if test "x$need_pci_id$have_pci_id" = xyesno; then
2040             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2041         fi
2042         enable_gallium_drm_loader=yes
2043     fi
2044     if test "x$enable_va" = xyes && test "x$7" != x; then
2045          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2046     fi
2047 }
2048
2049 require_egl_drm() {
2050     case "$with_egl_platforms" in
2051         *drm*)
2052             ;;
2053          *)
2054             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2055             ;;
2056     esac
2057     if test "x$enable_gbm" != xyes; then
2058             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2059     fi
2060 }
2061
2062 radeon_llvm_check() {
2063     if test ${LLVM_VERSION_INT} -lt 307; then
2064         amdgpu_llvm_target_name='r600'
2065     else
2066         amdgpu_llvm_target_name='amdgpu'
2067     fi
2068     if test "x$enable_gallium_llvm" != "xyes"; then
2069         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2070     fi
2071     llvm_check_version_for "3" "4" "2" $1
2072     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2073         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2074     fi
2075     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2076     NEED_RADEON_LLVM=yes
2077     if test "x$have_libelf" != xyes; then
2078        AC_MSG_ERROR([$1 requires libelf when using llvm])
2079     fi
2080 }
2081
2082 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2083 if test -n "$with_gallium_drivers"; then
2084     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2085     for driver in $gallium_drivers; do
2086         case "x$driver" in
2087         xsvga)
2088             HAVE_GALLIUM_SVGA=yes
2089             gallium_require_drm "svga"
2090             gallium_require_drm_loader
2091             ;;
2092         xi915)
2093             HAVE_GALLIUM_I915=yes
2094             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2095             gallium_require_drm "Gallium i915"
2096             gallium_require_drm_loader
2097             ;;
2098         xilo)
2099             HAVE_GALLIUM_ILO=yes
2100             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2101             gallium_require_drm "Gallium i965/ilo"
2102             gallium_require_drm_loader
2103             ;;
2104         xr300)
2105             HAVE_GALLIUM_R300=yes
2106             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2107             gallium_require_drm "Gallium R300"
2108             gallium_require_drm_loader
2109             gallium_require_llvm "Gallium R300"
2110             ;;
2111         xr600)
2112             HAVE_GALLIUM_R600=yes
2113             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2114             gallium_require_drm "Gallium R600"
2115             gallium_require_drm_loader
2116             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2117                 radeon_llvm_check "r600g"
2118                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2119             fi
2120             if test "x$enable_r600_llvm" = xyes; then
2121                 USE_R600_LLVM_COMPILER=yes;
2122             fi
2123             if test "x$enable_opencl" = xyes; then
2124                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2125             fi
2126             ;;
2127         xradeonsi)
2128             HAVE_GALLIUM_RADEONSI=yes
2129             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2130             gallium_require_drm "radeonsi"
2131             gallium_require_drm_loader
2132             radeon_llvm_check "radeonsi"
2133             require_egl_drm "radeonsi"
2134             ;;
2135         xnouveau)
2136             HAVE_GALLIUM_NOUVEAU=yes
2137             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2138             gallium_require_drm "nouveau"
2139             gallium_require_drm_loader
2140             ;;
2141         xfreedreno)
2142             HAVE_GALLIUM_FREEDRENO=yes
2143             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2144             gallium_require_drm "freedreno"
2145             gallium_require_drm_loader
2146             ;;
2147         xswrast)
2148             HAVE_GALLIUM_SOFTPIPE=yes
2149             if test "x$MESA_LLVM" = x1; then
2150                 HAVE_GALLIUM_LLVMPIPE=yes
2151             fi
2152             ;;
2153         xvc4)
2154             HAVE_GALLIUM_VC4=yes
2155             gallium_require_drm "vc4"
2156             gallium_require_drm_loader
2157
2158             case "$host_cpu" in
2159                 i?86 | x86_64 | amd64)
2160                 USE_VC4_SIMULATOR=yes
2161                 ;;
2162             esac
2163             ;;
2164         *)
2165             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2166             ;;
2167         esac
2168     done
2169 fi
2170
2171 dnl Set LLVM_LIBS - This is done after the driver configuration so
2172 dnl that drivers can add additional components to LLVM_COMPONENTS.
2173 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2174 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2175 dnl this was causing the same libraries to be appear multiple times
2176 dnl in LLVM_LIBS.
2177
2178 if test "x$MESA_LLVM" != x0; then
2179
2180     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2181
2182     if test "x$enable_llvm_shared_libs" = xyes; then
2183         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2184         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2185         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2186
2187         if test "x$llvm_have_one_so" = xyes; then
2188             dnl LLVM was built using auto*, so there is only one shared object.
2189             LLVM_LIBS="-l$LLVM_SO_NAME"
2190         else
2191             dnl If LLVM was built with CMake, there will be one shared object per
2192             dnl component.
2193             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2194                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2195         Please make sure you have built llvm with the --enable-shared option
2196         and that your llvm libraries are installed in $LLVM_LIBDIR
2197         If you have installed your llvm libraries to a different directory you
2198         can use the --with-llvm-prefix= configure flag to specify this directory.
2199         NOTE: Mesa is attempting to use llvm shared libraries by default.
2200         If you do not want to build with llvm shared libraries and instead want to
2201         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2202         invocation and rebuild.])])
2203
2204            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2205            dnl install uses a shared object for each component and we have
2206            dnl already added all of these objects to LLVM_LIBS.
2207         fi
2208     else
2209         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2210         dnl We need to link to llvm system libs when using static libs
2211         dnl However, only llvm 3.5+ provides --system-libs
2212         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2213             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2214         fi
2215     fi
2216 fi
2217
2218 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2219 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2220 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2221 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2222 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2223 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2224 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2225                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2226 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2227 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2228 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2229 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2230 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2231
2232 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2233
2234 # NOTE: anything using xcb or other client side libs ends up in separate
2235 #       _CLIENT variables.  The pipe loader is built in two variants,
2236 #       one that is standalone and does not link any x client libs (for
2237 #       use by XA tracker in particular, but could be used in any case
2238 #       where communication with xserver is not desired).
2239 if test "x$enable_gallium_loader" = xyes; then
2240     if test "x$NEED_WINSYS_XLIB" = xyes; then
2241         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2242     fi
2243
2244     if test "x$enable_dri" = xyes; then
2245         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2246     fi
2247
2248     if test "x$enable_gallium_drm_loader" = xyes; then
2249         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2250         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2251                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2252         if test "x$pipe_loader_have_xcb" = xyes; then
2253             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2254             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2255         fi
2256     fi
2257
2258     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2259     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2260
2261     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2262     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2263     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2264     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2265 fi
2266
2267 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2268 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2269 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2270 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2271 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2272 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2273
2274 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2275                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2276                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2277 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2278 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2279 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2280 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2281 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2282 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2283 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2284 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2285 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2286     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2287 fi
2288
2289 AC_SUBST([ELF_LIB])
2290
2291 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2292 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2293 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2294 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2295 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2296
2297 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2298 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2299 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2300
2301 AC_SUBST([NINE_MAJOR], 1)
2302 AC_SUBST([NINE_MINOR], 0)
2303 AC_SUBST([NINE_TINY], 0)
2304 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2305
2306 AC_SUBST([VDPAU_MAJOR], 1)
2307 AC_SUBST([VDPAU_MINOR], 0)
2308
2309 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2310 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2311 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2312 AC_SUBST([VA_MINOR], $VA_MINOR)
2313
2314 AC_SUBST([XVMC_MAJOR], 1)
2315 AC_SUBST([XVMC_MINOR], 0)
2316
2317 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2318 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2319 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2320 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2321
2322 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2323 AC_SUBST([XA_MINOR], $XA_MINOR)
2324 AC_SUBST([XA_TINY], $XA_TINY)
2325 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2326
2327 PKG_CHECK_MODULES(VALGRIND, [valgrind],
2328                   [have_valgrind=yes], [have_valgrind=no])
2329 if test "x$have_valgrind" = "xyes"; then
2330     AC_DEFINE([HAVE_VALGRIND], 1,
2331               [Use valgrind intrinsics to suppress false warnings])
2332 fi
2333
2334 dnl Restore LDFLAGS and CPPFLAGS
2335 LDFLAGS="$_SAVE_LDFLAGS"
2336 CPPFLAGS="$_SAVE_CPPFLAGS"
2337
2338 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2339 if test "x$acv_mesa_CLANG" = xyes; then
2340     CFLAGS="$CFLAGS -Qunused-arguments"
2341     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2342 fi
2343
2344 dnl Add user CFLAGS and CXXFLAGS
2345 CFLAGS="$CFLAGS $USER_CFLAGS"
2346 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2347
2348 dnl Substitute the config
2349 AC_CONFIG_FILES([Makefile
2350                 src/Makefile
2351                 src/egl/drivers/dri2/Makefile
2352                 src/egl/main/Makefile
2353                 src/egl/main/egl.pc
2354                 src/egl/wayland/wayland-drm/Makefile
2355                 src/egl/wayland/wayland-egl/Makefile
2356                 src/egl/wayland/wayland-egl/wayland-egl.pc
2357                 src/gallium/Makefile
2358                 src/gallium/auxiliary/Makefile
2359                 src/gallium/auxiliary/pipe-loader/Makefile
2360                 src/gallium/drivers/freedreno/Makefile
2361                 src/gallium/drivers/i915/Makefile
2362                 src/gallium/drivers/ilo/Makefile
2363                 src/gallium/drivers/llvmpipe/Makefile
2364                 src/gallium/drivers/noop/Makefile
2365                 src/gallium/drivers/nouveau/Makefile
2366                 src/gallium/drivers/r300/Makefile
2367                 src/gallium/drivers/r600/Makefile
2368                 src/gallium/drivers/radeon/Makefile
2369                 src/gallium/drivers/radeonsi/Makefile
2370                 src/gallium/drivers/rbug/Makefile
2371                 src/gallium/drivers/softpipe/Makefile
2372                 src/gallium/drivers/svga/Makefile
2373                 src/gallium/drivers/trace/Makefile
2374                 src/gallium/drivers/vc4/Makefile
2375                 src/gallium/state_trackers/clover/Makefile
2376                 src/gallium/state_trackers/dri/Makefile
2377                 src/gallium/state_trackers/glx/xlib/Makefile
2378                 src/gallium/state_trackers/nine/Makefile
2379                 src/gallium/state_trackers/omx/Makefile
2380                 src/gallium/state_trackers/osmesa/Makefile
2381                 src/gallium/state_trackers/va/Makefile
2382                 src/gallium/state_trackers/vdpau/Makefile
2383                 src/gallium/state_trackers/xa/Makefile
2384                 src/gallium/state_trackers/xvmc/Makefile
2385                 src/gallium/targets/d3dadapter9/Makefile
2386                 src/gallium/targets/d3dadapter9/d3d.pc
2387                 src/gallium/targets/dri/Makefile
2388                 src/gallium/targets/libgl-xlib/Makefile
2389                 src/gallium/targets/omx/Makefile
2390                 src/gallium/targets/opencl/Makefile
2391                 src/gallium/targets/osmesa/Makefile
2392                 src/gallium/targets/osmesa/osmesa.pc
2393                 src/gallium/targets/pipe-loader/Makefile
2394                 src/gallium/targets/va/Makefile
2395                 src/gallium/targets/vdpau/Makefile
2396                 src/gallium/targets/xa/Makefile
2397                 src/gallium/targets/xa/xatracker.pc
2398                 src/gallium/targets/xvmc/Makefile
2399                 src/gallium/tests/trivial/Makefile
2400                 src/gallium/tests/unit/Makefile
2401                 src/gallium/winsys/freedreno/drm/Makefile
2402                 src/gallium/winsys/i915/drm/Makefile
2403                 src/gallium/winsys/intel/drm/Makefile
2404                 src/gallium/winsys/nouveau/drm/Makefile
2405                 src/gallium/winsys/radeon/drm/Makefile
2406                 src/gallium/winsys/svga/drm/Makefile
2407                 src/gallium/winsys/sw/dri/Makefile
2408                 src/gallium/winsys/sw/kms-dri/Makefile
2409                 src/gallium/winsys/sw/null/Makefile
2410                 src/gallium/winsys/sw/wrapper/Makefile
2411                 src/gallium/winsys/sw/xlib/Makefile
2412                 src/gallium/winsys/vc4/drm/Makefile
2413                 src/gbm/Makefile
2414                 src/gbm/main/gbm.pc
2415                 src/glsl/Makefile
2416                 src/glx/Makefile
2417                 src/glx/apple/Makefile
2418                 src/glx/tests/Makefile
2419                 src/gtest/Makefile
2420                 src/loader/Makefile
2421                 src/mapi/Makefile
2422                 src/mapi/es1api/glesv1_cm.pc
2423                 src/mapi/es2api/glesv2.pc
2424                 src/mapi/glapi/gen/Makefile
2425                 src/mesa/Makefile
2426                 src/mesa/gl.pc
2427                 src/mesa/drivers/dri/dri.pc
2428                 src/mesa/drivers/dri/common/Makefile
2429                 src/mesa/drivers/dri/common/xmlpool/Makefile
2430                 src/mesa/drivers/dri/i915/Makefile
2431                 src/mesa/drivers/dri/i965/Makefile
2432                 src/mesa/drivers/dri/Makefile
2433                 src/mesa/drivers/dri/nouveau/Makefile
2434                 src/mesa/drivers/dri/r200/Makefile
2435                 src/mesa/drivers/dri/radeon/Makefile
2436                 src/mesa/drivers/dri/swrast/Makefile
2437                 src/mesa/drivers/osmesa/Makefile
2438                 src/mesa/drivers/osmesa/osmesa.pc
2439                 src/mesa/drivers/x11/Makefile
2440                 src/mesa/main/tests/Makefile
2441                 src/vulkan/Makefile
2442                 src/util/Makefile
2443                 src/util/tests/hash_table/Makefile])
2444
2445 AC_OUTPUT
2446
2447 dnl
2448 dnl Output some configuration info for the user
2449 dnl
2450 echo ""
2451 echo "        prefix:          $prefix"
2452 echo "        exec_prefix:     $exec_prefix"
2453 echo "        libdir:          $libdir"
2454 echo "        includedir:      $includedir"
2455
2456 dnl API info
2457 echo ""
2458 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2459
2460 dnl Driver info
2461 echo ""
2462 case "x$enable_osmesa$enable_gallium_osmesa" in
2463 xnoyes)
2464         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2465         ;;
2466 xyesno)
2467         echo "        OSMesa:          lib$OSMESA_LIB"
2468         ;;
2469 xnono)
2470         echo "        OSMesa:          no"
2471         ;;
2472 esac
2473
2474 echo ""
2475 if test "x$enable_dri" != xno; then
2476         echo "        DRI platform:    $dri_platform"
2477         if test -z "$DRI_DIRS"; then
2478             echo "        DRI drivers:     no"
2479         else
2480             echo "        DRI drivers:     $DRI_DIRS"
2481         fi
2482         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2483 fi
2484
2485 case "x$enable_glx$enable_xlib_glx" in
2486 xyesyes)
2487     echo "        GLX:             Xlib-based"
2488     ;;
2489 xyesno)
2490     echo "        GLX:             DRI-based"
2491     ;;
2492 *)
2493     echo "        GLX:             $enable_glx"
2494     ;;
2495 esac
2496
2497 dnl EGL
2498 echo ""
2499 echo "        EGL:             $enable_egl"
2500 if test "$enable_egl" = yes; then
2501     echo "        EGL platforms:   $egl_platforms"
2502
2503     egl_drivers=""
2504     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2505         egl_drivers="$egl_drivers builtin:egl_dri2"
2506     fi
2507
2508     echo "        EGL drivers:    $egl_drivers"
2509 fi
2510
2511 echo ""
2512 if test "x$MESA_LLVM" = x1; then
2513     echo "        llvm:            yes"
2514     echo "        llvm-config:     $LLVM_CONFIG"
2515     echo "        llvm-version:    $LLVM_VERSION"
2516 else
2517     echo "        llvm:            no"
2518 fi
2519
2520 echo ""
2521 if test -n "$with_gallium_drivers"; then
2522     echo "        Gallium:         yes"
2523 else
2524     echo "        Gallium:         no"
2525 fi
2526
2527 dnl Shader cache
2528 echo ""
2529 echo "        Shader cache:    $enable_shader_cache"
2530 if test "x$enable_shader_cache" = "xyes"; then
2531     echo "        With SHA1 from:  $with_sha1"
2532 fi
2533
2534 dnl Libraries
2535 echo ""
2536 echo "        Shared libs:     $enable_shared"
2537 echo "        Static libs:     $enable_static"
2538 echo "        Shared-glapi:    $enable_shared_glapi"
2539
2540 dnl Compiler options
2541 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2542 cflags=`echo $CFLAGS | \
2543     $SED 's/^ *//;s/  */ /;s/ *$//'`
2544 cxxflags=`echo $CXXFLAGS | \
2545     $SED 's/^ *//;s/  */ /;s/ *$//'`
2546 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2547 echo ""
2548 echo "        CFLAGS:          $cflags"
2549 echo "        CXXFLAGS:        $cxxflags"
2550 echo "        Macros:          $defines"
2551 echo ""
2552 if test "x$MESA_LLVM" = x1; then
2553     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2554     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2555     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2556     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2557     echo ""
2558 fi
2559 echo "        PYTHON2:         $PYTHON2"
2560
2561 echo ""
2562 echo "        Run '${MAKE-make}' to build Mesa"
2563 echo ""