configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 # get rid of that stupid cache mechanism
   4 rm -f config.cache
   5
   6 AC_INIT([expedite], [1.7.8], [enlightenment-devel@lists.sourceforge.net])
   7 AC_PREREQ([2.52])
   8 AC_CONFIG_SRCDIR([configure.ac])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CANONICAL_BUILD
  11 AC_CANONICAL_HOST
  12
  13 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  14 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  15
  16 PKG_PROG_PKG_CONFIG
  17
  18
  19 ### Additional options to configure
  20
  21 ## Simple X11 build/link
  22
  23 ## Evas engines
  24
  25 AC_ARG_ENABLE(simple-x11,
  26    [AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking])],
  27    [want_evas_simple_x11=$enableval]
  28 )
  29
  30 # Software X11
  31 have_software_xlib="no"
  32 have_software_xcb="no"
  33 EXPEDITE_CHECK_ENGINE([software-x11], [Software X11], "yes")
  34
  35 if test "x${have_software_x11}" = "xyes" ; then
  36    have_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
  37    if test "x${have_software_xlib}" = "xstatic" ; then
  38       have_software_xlib="yes"
  39    fi
  40    if test "x${have_software_xlib}" = "xyes" ; then
  41       AC_DEFINE(HAVE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
  42    fi
  43    have_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
  44    if test "x${have_software_xcb}" = "xstatic" ; then
  45       have_software_xcb="yes"
  46    fi
  47    if test "x${have_software_xcb}" = "xyes" ; then
  48       AC_DEFINE(HAVE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
  49    fi
  50 fi
  51
  52 AM_CONDITIONAL([BUILD_SOFTWARE_XLIB], [test "x${have_software_xlib}" = "xyes"])
  53 AM_CONDITIONAL([BUILD_SOFTWARE_XCB], [test "x${have_software_xcb}" = "xyes"])
  54
  55 # XRender X11
  56 EXPEDITE_CHECK_ENGINE([xrender-x11], [XRender X11], "yes")
  57
  58 # OpenGL X11
  59 EXPEDITE_CHECK_ENGINE([opengl-x11], [OpenGL X11], "yes")
  60
  61 # XRender XCB
  62 EXPEDITE_CHECK_ENGINE([xrender-xcb], [XRender XCB], "yes")
  63
  64 # GDI
  65 EXPEDITE_CHECK_ENGINE([software-gdi], [Software GDI], "yes", [gdi_libs="-lgdi32"])
  66 AC_SUBST(gdi_libs)
  67
  68 # DirectDraw
  69 EXPEDITE_CHECK_ENGINE([software-ddraw], [Software DirectDraw], "yes", [ddraw_libs="-lddraw -ldxguid -lgdi32"])
  70 AC_SUBST(ddraw_libs)
  71
  72 # Direct3D
  73 EXPEDITE_CHECK_ENGINE([direct3d], [Direct3D], "yes", [d3d_libs="-ld3d9 -ld3dx9d -lgdi32"])
  74 AC_SUBST(d3d_libs)
  75
  76 # PSL1GHT
  77 EXPEDITE_CHECK_ENGINE([psl1ght], [PSL1GHT], "yes")
  78
  79 # GL SDL
  80 EXPEDITE_CHECK_ENGINE([opengl-sdl], [OpenGL SDL], "yes")
  81
  82 # FB
  83 EXPEDITE_CHECK_ENGINE([fb], [Framebuffer], "yes")
  84
  85 # DIRECTFB
  86 EXPEDITE_CHECK_ENGINE([directfb], [DirectFB], "yes")
  87
  88 # GL Cocoa
  89 EXPEDITE_CHECK_ENGINE([opengl-cocoa], [OpenGL Cocoa], "yes", [gl_cocoa_libs="-framework Cocoa"])
  90 AC_SUBST(gl_cocoa_libs)
  91
  92 # Software 16bit X11
  93 EXPEDITE_CHECK_ENGINE([software-16-x11], [Software 16 bits X11], "yes")
  94
  95 # 16bit WinCE
  96 EXPEDITE_CHECK_ENGINE([software-16-wince], [Software 16 bits WinCE], "yes", [wince_16_libs="-laygshell"])
  97 AC_SUBST(wince_16_libs)
  98
  99 ### Checks for programs
 100
 101 AC_ISC_POSIX
 102 m4_ifdef([AC_PROG_OBJC],
 103    [
 104     AC_PROG_OBJC
 105     _AM_DEPENDENCIES(OBJC)
 106    ],
 107    [
 108     AC_CHECK_TOOL([OBJC], [gcc])
 109     AC_SUBST([OBJC])
 110     AC_SUBST([OBJCFLAGS])
 111    ]
 112 )
 113 AC_PROG_CXX
 114 AC_PROG_CC
 115
 116 LT_PROG_RC
 117
 118
 119
 120 ### Checks for libraries
 121
 122 # Evil library for compilation on Windows
 123
 124 case "$host_os" in
 125    mingw32*)
 126       PKG_CHECK_MODULES([EVIL], [evil >= 1.7.8])
 127       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 128       ;;
 129 esac
 130
 131 # Eina
 132
 133 PKG_CHECK_MODULES([EINA], eina >= 1.7.8)
 134
 135 # Evas
 136
 137 PKG_CHECK_MODULES([EVAS], evas >= 1.7.8 eet >= 1.7.8)
 138
 139 # Xlib
 140
 141 if test "x$have_software_xlib" = "xyes" -o "x$have_software_16_x11" = "xyes" -o "x$have_xrender_x11" = "xyes" -o "x$have_opengl_x11" = "xyes"; then
 142    AC_PATH_XTRA
 143    AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h],
 144       [have_xlib="yes"],
 145       [have_xlib="no"])
 146    if test "x$want_evas_simple_x11" = "xyes"; then
 147       x_libs="${x_libs} -lX11"
 148    else
 149       x_dir=${x_dir:-/usr/X11R6}
 150       x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 151       x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11"
 152    fi
 153 fi
 154 AM_CONDITIONAL(BUILD_X11, [test "x$have_xlib" = "xyes"])
 155
 156 AC_SUBST(x_cflags)
 157 AC_SUBST(x_libs)
 158
 159 # XCB
 160
 161 if test "x$have_software_xcb" = "xyes"; then
 162    PKG_CHECK_MODULES([XCB], [xcb xcb-keysyms], [have_xcb="yes"], [have_xcb="no"])
 163 fi
 164 AM_CONDITIONAL(BUILD_XCB, test "x$have_xcb" = "xyes")
 165 if test "x$have_xcb" = "xyes"; then
 166    AC_DEFINE(BUILD_XCB, 1, [build xcb support])
 167 fi
 168
 169 # SDL
 170
 171 PKG_CHECK_MODULES([SDL], [sdl], [have_sdl="yes"], [have_sdl="no"])
 172 AM_CONDITIONAL(BUILD_SDL, test "x$have_sdl" = "xyes")
 173 if test "x$have_sdl" = "xyes"; then
 174    AC_DEFINE(BUILD_SDL, 1, [build sdl support])
 175 fi
 176
 177 # PSL1GHT
 178 AM_CONDITIONAL(BUILD_PSL1GHT, test "x$have_psl1ght" = "xyes")
 179
 180 # DirectFB
 181
 182 if test "x$have_directfb" = "xyes"; then
 183    PKG_CHECK_MODULES([DIRECTFB], [directfb], [have_directfb="yes"], [have_directfb="no"])
 184 fi
 185 AM_CONDITIONAL(BUILD_DIRECTFB, test "x$have_directfb" = "xyes")
 186
 187
 188 ### Checks for header files
 189
 190
 191 ### Checks for types
 192
 193
 194 ### Checks for structures
 195
 196
 197 ### Checks for compiler characteristics
 198
 199 AM_PROG_CC_STDC
 200 AC_HEADER_STDC
 201 AC_C_CONST
 202 AM_PROG_CC_C_O
 203 AC_C___ATTRIBUTE__
 204
 205 WIN32_CFLAGS=""
 206 case "$host_os" in
 207    cegcc*)
 208       WIN32_CFLAGS="-mwin32"
 209       ;;
 210 esac
 211 AC_SUBST(WIN32_CFLAGS)
 212
 213 EXPEDITE_CXXFLAGS=""
 214 AC_LANG_PUSH([C++])
 215 CXXFLAGS_save="${CXXFLAGS}"
 216 CXXFLAGS="${CXXFLAGS} -fno-rtti -fno-exceptions"
 217 AC_LINK_IFELSE(
 218    [AC_LANG_PROGRAM([[]])],
 219    [have_cxx_flags="yes"],
 220    [have_cxx_flags="no"])
 221 AC_MSG_CHECKING([whether the compiler supports -fno-rtti -fno-exceptions])
 222 AC_MSG_RESULT([${have_cxx_flags}])
 223 CXXFLAGS="${CXXFLAGS_save}"
 224 if test "x${have_cxx_flags}" = "xyes" ; then
 225    EXPEDITE_CXXFLAGS="-fno-rtti -fno-exceptions"
 226 fi
 227 AC_LANG_POP([C++])
 228 AC_SUBST(EXPEDITE_CXXFLAGS)
 229
 230
 231 ### Checks for linker characteristics
 232
 233 lt_enable_auto_import=""
 234 case "$host_os" in
 235    mingw* | cegcc*)
 236       lt_enable_auto_import="-Wl,--enable-auto-import"
 237       ;;
 238 esac
 239 AC_SUBST(lt_enable_auto_import)
 240
 241
 242 ### Checks for library functions
 243
 244 AC_CHECK_FUNCS([sync])
 245
 246
 247 AC_OUTPUT([
 248 Makefile
 249 expedite.spec
 250 src/Makefile
 251 src/bin/Makefile
 252 data/Makefile
 253 ])
 254
 255 echo
 256 echo "  $PACKAGE $VERSION"
 257 echo
 258 echo "  Engines:"
 259 echo "    Software X11.................: ${have_software_x11} (Xlib: ${have_software_xlib}) (XCB: ${have_software_xcb})"
 260 echo "    X Render X11.................: ${have_xrender_x11}"
 261 echo "    Open GL X11..................: ${have_opengl_x11}"
 262 echo "    X Render XCB.................: ${have_xrender_xcb}"
 263 echo "    Software GDI.................: ${have_software_gdi}"
 264 echo "    Software DirectDraw..........: ${have_software_ddraw}"
 265 echo "    Direct3D.....................: ${have_direct3d}"
 266 echo "    Software SDL.................: ${have_software_sdl}"
 267 echo "    Open GL SDL..................: ${have_opengl_sdl}"
 268 echo "    Open GL Cocoa................: ${have_opengl_cocoa}"
 269 echo "    FB...........................: ${have_fb}"
 270 echo "    DirectFB.....................: ${have_directfb}"
 271 echo "    PSL1GHT......................: ${have_psl1ght}"
 272 echo "    Software X11 16 bits.........: ${have_software_16_x11}"
 273 echo "    Software WinCE 16 bits.......: ${have_software_16_wince}"
 274 echo
 275 echo "  Installation:"
 276 echo "    prefix.......................: ${prefix}"
 277 echo