configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [5])
   6 m4_define([dbus_micro_version], [1])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22  ## must come before we use the $USE_MAINTAINER_MODE variable later
  23 AM_MAINTAINER_MODE
  24
  25 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  26
  27 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  28
  29 # libtool versioning - this applies to libdbus
  30 #
  31 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  32 #
  33
  34 ## increment if the interface has additions, changes, removals.
  35 LT_CURRENT=9
  36
  37 ## increment any time the source changes; set to
  38 ##  0 if you increment CURRENT
  39 LT_REVISION=0
  40
  41 ## increment if any interfaces have been added; set to 0
  42 ## if any interfaces have been changed or removed. removal has
  43 ## precedence over adding, so set to 0 if both happened.
  44 LT_AGE=6
  45
  46 AC_SUBST(LT_CURRENT)
  47 AC_SUBST(LT_REVISION)
  48 AC_SUBST(LT_AGE)
  49
  50 DBUS_MAJOR_VERSION=dbus_major_version
  51 DBUS_MINOR_VERSION=dbus_minor_version
  52 DBUS_MICRO_VERSION=dbus_micro_version
  53 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  54
  55 AC_SUBST(DBUS_MAJOR_VERSION)
  56 AC_SUBST(DBUS_MINOR_VERSION)
  57 AC_SUBST(DBUS_MICRO_VERSION)
  58 AC_SUBST(DBUS_VERSION)
  59
  60 AC_PROG_CC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_USE_SYSTEM_EXTENSIONS
  64 AC_ISC_POSIX
  65 AC_HEADER_STDC
  66 AC_C_INLINE
  67 AM_PROG_LIBTOOL
  68 AC_PROG_MKDIR_P
  69 COMPILER_COVERAGE
  70 COMPILER_OPTIMISATIONS
  71
  72 # Initialize libtool
  73 LT_INIT([win32-dll])
  74 LT_LANG([Windows Resource])
  75
  76 # Set some internal variables depending on the platform for later use.
  77 dbus_win=no
  78 dbus_cygwin=no
  79 dbus_unix=no
  80 case "${host}" in
  81     *-mingw32ce*)
  82         dbus_win=yes
  83         dbus_wince=yes
  84         ;;
  85     *-mingw32*)
  86         dbus_win=yes
  87         ;;
  88     *-cygwin*)
  89         dbus_cygwin=yes
  90         dbus_unix=yes
  91         ;;
  92     *)
  93         dbus_unix=yes
  94        ;;
  95 esac
  96
  97 # Special defines for certain platforms
  98 if test "$dbus_win" = yes; then
  99     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 100     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 101     AC_SUBST(BUILD_TIMESTAMP)
 102     # Assume DBUS_VERSION is always three numbers
 103     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 104     AC_SUBST(BUILD_FILEVERSION)
 105     AC_CHECK_TOOL(WINDRES, windres, no)
 106     if test "$WINDRES" = no; then
 107       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 108     fi
 109     if test "$dbus_wince" = yes; then
 110       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 111       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 112     fi
 113 else
 114     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 115 fi
 116 if test "$dbus_cygwin" = yes; then
 117     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 118 fi
 119
 120 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 121 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 122 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 123 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 124
 125 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests],[enable unit test code in the library and binaries]),enable_tests=$enableval,enable_tests=$USE_MAINTAINER_MODE)
 126 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 127 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)
 128 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$USE_MAINTAINER_MODE)
 129 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 130 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 131 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 132 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 133 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 134 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 135 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 136 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 137 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 138 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 139 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 140 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 141
 142 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 143 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 144 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 145 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 146 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 147 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 148 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 149 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 150 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 151 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 152 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 153
 154 dnl DBUS_BUILD_TESTS controls unit tests built in to .c files
 155 dnl and also some stuff in the test/ subdir
 156 AM_CONDITIONAL(DBUS_BUILD_TESTS, test x$enable_tests = xyes)
 157 if test x$enable_tests = xyes; then
 158     AC_DEFINE(DBUS_BUILD_TESTS,1,[Build test code])
 159 fi
 160
 161 if test x$enable_verbose_mode = xyes; then
 162     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 163 fi
 164
 165 if test x$enable_asserts = xno; then
 166     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 167     AC_DEFINE(G_DISABLE_ASSERT,1,[Disable GLib assertion macros])
 168     R_DYNAMIC_LDFLAG=""
 169 else
 170     # -rdynamic is needed for glibc's backtrace_symbols to work.
 171     # No clue how much overhead this adds, but it's useful
 172     # to do this on any assertion failure,
 173     # so for now it's enabled anytime asserts are (currently not
 174     # in production builds).
 175
 176     # To get -rdynamic you pass -export-dynamic to libtool.
 177     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 178     R_DYNAMIC_LDFLAG=-export-dynamic
 179 fi
 180 AC_SUBST(R_DYNAMIC_LDFLAG)
 181
 182 if test x$enable_checks = xno; then
 183     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 184     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 185 fi
 186
 187 if test x$enable_userdb_cache = xyes; then
 188     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 189 fi
 190
 191 if test x$enable_compiler_coverage = xyes; then
 192      ## so that config.h changes when you toggle gcov support
 193      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 194 fi
 195
 196 # glibc21.m4 serial 3
 197 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 198 dnl This file is free software; the Free Software Foundation
 199 dnl gives unlimited permission to copy and/or distribute it,
 200 dnl with or without modifications, as long as this notice is preserved.
 201
 202 # Test for the GNU C Library, version 2.1 or newer.
 203 # From Bruno Haible.
 204
 205 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 206   ac_cv_gnu_library_2_1,
 207   [AC_EGREP_CPP([Lucky GNU user],
 208     [
 209 #include <features.h>
 210 #ifdef __GNU_LIBRARY__
 211  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 212   Lucky GNU user
 213  #endif
 214 #endif
 215     ],
 216     ac_cv_gnu_library_2_1=yes,
 217     ac_cv_gnu_library_2_1=no)
 218   ]
 219 )
 220
 221 #### Integer sizes
 222
 223 AC_CHECK_SIZEOF(char)
 224 AC_CHECK_SIZEOF(short)
 225 AC_CHECK_SIZEOF(long)
 226 AC_CHECK_SIZEOF(int)
 227 AC_CHECK_SIZEOF(void *)
 228 AC_CHECK_SIZEOF(long long)
 229 AC_CHECK_SIZEOF(__int64)
 230
 231 AC_ARG_WITH([64-bit],
 232   [AS_HELP_STRING([--without-64-bit],
 233     [If you have to use this option, please report it as a bug])],
 234   [],
 235   [with_64_bit=yes])
 236
 237 ### See what our 64 bit type is called
 238 AC_MSG_CHECKING([64-bit integer type])
 239
 240 case 8 in
 241 $ac_cv_sizeof_int)
 242   dbusint64=int
 243   dbusint64_constant='(val)'
 244   dbusuint64_constant='(val)'
 245   dbusint64_printf_modifier='""'
 246   ;;
 247 $ac_cv_sizeof_long)
 248   dbusint64=long
 249   dbusint64_constant='(val##L)'
 250   dbusuint64_constant='(val##UL)'
 251   dbusint64_printf_modifier='"l"'
 252   ;;
 253 $ac_cv_sizeof_long_long)
 254   dbusint64='long long'
 255   dbusint64_constant='(val##LL)'
 256   dbusuint64_constant='(val##ULL)'
 257   # Ideally we discover what the format is, but this is
 258   # only used in verbose mode, so eh...
 259   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 260     dbusint64_printf_modifier='"ll"'
 261   fi
 262   ;;
 263 $ac_cv_sizeof___int64)
 264   dbusint64=__int64
 265   dbusint64_constant='(val##i64)'
 266   dbusuint64_constant='(val##ui64)'
 267   # See above case
 268   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 269     dbusint64_printf_modifier='"ll"'
 270   fi
 271   ;;
 272 esac
 273
 274 AS_IF(
 275   [test "x$with_64_bit" = xno],
 276   [
 277         DBUS_INT64_TYPE="no_int64_type_detected"
 278         DBUS_HAVE_INT64=0
 279         DBUS_INT64_CONSTANT=
 280         DBUS_UINT64_CONSTANT=
 281         AC_MSG_RESULT([disabled via --without-64-bit])
 282   ],
 283   dnl else if
 284   [test -z "$dbusint64"],
 285   [AC_MSG_RESULT([not found])
 286   AC_MSG_ERROR([Could not find a 64-bit integer type.
 287
 288 Please report a bug here with details of your platform and compiler:
 289
 290     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 291
 292 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 293 the option "--without-64-bit".
 294
 295 This option is likely to be removed in future, unless you report that your
 296 platform needs it.])
 297   ],
 298   dnl else
 299   [
 300         DBUS_INT64_TYPE="$dbusint64"
 301         DBUS_HAVE_INT64=1
 302         DBUS_INT64_CONSTANT="$dbusint64_constant"
 303         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 304         if test x"$dbusint64_printf_modifier" != x; then
 305                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 306         fi
 307         AC_MSG_RESULT($DBUS_INT64_TYPE)
 308   ])
 309
 310 AC_SUBST(DBUS_INT64_TYPE)
 311 AC_SUBST(DBUS_INT64_CONSTANT)
 312 AC_SUBST(DBUS_UINT64_CONSTANT)
 313 AC_SUBST(DBUS_HAVE_INT64)
 314
 315 ### see what 32-bit int is called
 316 AC_MSG_CHECKING([32-bit integer type])
 317
 318 case 4 in
 319 $ac_cv_sizeof_short)
 320   dbusint32=short
 321   ;;
 322 $ac_cv_sizeof_int)
 323   dbusint32=int
 324   ;;
 325 $ac_cv_sizeof_long)
 326   dbusint32=long
 327   ;;
 328 esac
 329
 330 if test -z "$dbusint32" ; then
 331         DBUS_INT32_TYPE="no_int32_type_detected"
 332         AC_MSG_ERROR([No 32-bit integer type found])
 333 else
 334         DBUS_INT32_TYPE="$dbusint32"
 335         AC_MSG_RESULT($DBUS_INT32_TYPE)
 336 fi
 337
 338 AC_SUBST(DBUS_INT32_TYPE)
 339
 340 ### see what 16-bit int is called
 341 AC_MSG_CHECKING([16-bit integer type])
 342
 343 case 2 in
 344 $ac_cv_sizeof_short)
 345   dbusint16=short
 346   ;;
 347 $ac_cv_sizeof_int)
 348   dbusint16=int
 349   ;;
 350 esac
 351
 352 if test -z "$dbusint16" ; then
 353         DBUS_INT16_TYPE="no_int16_type_detected"
 354         AC_MSG_ERROR([No 16-bit integer type found])
 355 else
 356         DBUS_INT16_TYPE="$dbusint16"
 357         AC_MSG_RESULT($DBUS_INT16_TYPE)
 358 fi
 359
 360 AC_SUBST(DBUS_INT16_TYPE)
 361
 362 ## byte order
 363 case $host_os in
 364         darwin*)
 365                 # check at compile-time, so that it is possible to build universal
 366                 # (with multiple architectures at once on the compile line)
 367                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 368                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 369                         #if defined(__BIG_ENDIAN__)
 370                         #define WORDS_BIGENDIAN 1
 371                         #endif
 372                 ])
 373                 ;;
 374         *)
 375                 AC_C_BIGENDIAN
 376                 ;;
 377 esac
 378
 379 dnl **********************************
 380 dnl *** va_copy checks (from GLib) ***
 381 dnl **********************************
 382 dnl we currently check for all three va_copy possibilities, so we get
 383 dnl all results in config.log for bug reports.
 384 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 385         AC_LINK_IFELSE([#include <stdarg.h>
 386 #include <stdlib.h>
 387         static void f (int i, ...) {
 388         va_list args1, args2;
 389         va_start (args1, i);
 390         va_copy (args2, args1);
 391         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 392           exit (1);
 393         va_end (args1); va_end (args2);
 394         }
 395         int main() {
 396           f (0, 42);
 397           return 0;
 398         }],
 399         [dbus_cv_va_copy=yes],
 400         [dbus_cv_va_copy=no])
 401 ])
 402 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 403         AC_LINK_IFELSE([#include <stdarg.h>
 404 #include <stdlib.h>
 405         static void f (int i, ...) {
 406         va_list args1, args2;
 407         va_start (args1, i);
 408         __va_copy (args2, args1);
 409         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 410           exit (1);
 411         va_end (args1); va_end (args2);
 412         }
 413         int main() {
 414           f (0, 42);
 415           return 0;
 416         }],
 417         [dbus_cv___va_copy=yes],
 418         [dbus_cv___va_copy=no])
 419 ])
 420
 421 if test "x$dbus_cv_va_copy" = "xyes"; then
 422   dbus_va_copy_func=va_copy
 423 else if test "x$dbus_cv___va_copy" = "xyes"; then
 424   dbus_va_copy_func=__va_copy
 425 fi
 426 fi
 427
 428 if test -n "$dbus_va_copy_func"; then
 429   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 430 fi
 431
 432 AC_LANG_PUSH(C)
 433 AC_CACHE_CHECK([whether va_lists can be copied by value],
 434         dbus_cv_va_val_copy,
 435         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 436 [[
 437         #include <stdarg.h>
 438         #include <stdlib.h>
 439 ]],
 440 [[
 441         static void f (int i, ...) {
 442         va_list args1, args2;
 443         va_start (args1, i);
 444         args2 = args1;
 445         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 446           exit (1);
 447         va_end (args1); va_end (args2);
 448         }
 449         int main() {
 450           f (0, 42);
 451           return 0;
 452         }
 453 ]])],
 454         [dbus_cv_va_val_copy=yes],
 455         [dbus_cv_va_val_copy=no],
 456         [dbus_cv_va_val_copy=yes])
 457 ])
 458 AC_LANG_POP(C)
 459
 460 if test "x$dbus_cv_va_val_copy" = "xno"; then
 461   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 462 fi
 463
 464
 465 #### Atomic integers
 466
 467 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 468   dbus_cv_sync_sub_and_fetch,
 469   [AC_LINK_IFELSE(
 470      AC_LANG_PROGRAM([], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]]),
 471      [dbus_cv_sync_sub_and_fetch=yes],
 472      [dbus_cv_sync_sub_and_fetch=no])
 473   ])
 474
 475 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 476    have_sync=1
 477 else
 478    have_sync=0
 479 fi
 480
 481 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 482
 483 #### Various functions
 484 AC_SEARCH_LIBS(socket,[socket network])
 485 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 486
 487 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 488
 489 #### Check for broken poll; taken from Glib's configure
 490
 491 AC_MSG_CHECKING([for broken poll])
 492 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 493     #include <stdlib.h>
 494     #include <fcntl.h>
 495     #include <poll.h>
 496     #ifdef HAVE_SYS_POLL_H
 497     #include <sys/poll.h>
 498     #endif
 499     int main(void) {
 500       struct pollfd fds[1];
 501       int fd;
 502       fd = open("/dev/null", 1);
 503       fds[0].fd = fd;
 504       fds[0].events = POLLIN;
 505       fds[0].revents = 0;
 506       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 507             exit(1);  /* Does not work for devices -- fail */
 508       }
 509       exit(0);
 510     }]])],
 511   [broken_poll=no],
 512   [broken_poll=yes
 513    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 514   [broken_poll="no (cross compiling)"])
 515 AC_MSG_RESULT($broken_poll)
 516
 517 AC_MSG_CHECKING(for dirfd)
 518 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 519 #include <sys/types.h>
 520 #include <dirent.h>
 521 ]], [[
 522 DIR *dirp;
 523 dirp = opendir(".");
 524 dirfd(dirp);
 525 closedir(dirp);
 526 ]])],
 527 [dbus_have_dirfd=yes],
 528 [dbus_have_dirfd=no])
 529 AC_MSG_RESULT($dbus_have_dirfd)
 530 if test "$dbus_have_dirfd" = yes; then
 531         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 532 else
 533         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 534         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 535 #include <sys/types.h>
 536 #include <dirent.h>
 537         ]], [[
 538 DIR *dirp;
 539 int fd;
 540 dirp = opendir(".");
 541 fd = dirp->dd_fd;
 542 closedir(dirp);
 543         ]])],
 544         [dbus_have_ddfd=yes],
 545         [dbus_have_ddfd=no])
 546         AC_MSG_RESULT($dbus_have_ddfd)
 547         if test "$dbus_have_ddfd" = yes; then
 548                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 549         fi
 550 fi
 551
 552 AC_CHECK_HEADERS(sys/resource.h)
 553
 554 AC_CHECK_HEADERS(dirent.h)
 555
 556 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 557
 558 AC_CHECK_HEADERS(errno.h)
 559
 560 AC_CHECK_HEADERS(signal.h)
 561
 562 AC_CHECK_HEADERS(locale.h)
 563
 564 AC_CHECK_HEADERS(byteswap.h)
 565
 566 AC_CHECK_HEADERS(unistd.h)
 567
 568 AC_CHECK_HEADERS(ws2tcpip.h)
 569
 570 AC_CHECK_HEADERS(wspiapi.h)
 571
 572 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 573 #
 574 case $host_os in
 575     solaris*)
 576        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 577 esac
 578
 579 # checking for a posix version of getpwnam_r
 580 # if we are cross compiling and can not run the test
 581 # assume getpwnam_r is the posix version
 582 # it is up to the person cross compiling to change
 583 # this behavior if desired
 584 AC_LANG_PUSH(C)
 585 AC_CACHE_CHECK([for posix getpwnam_r],
 586                 ac_cv_func_posix_getpwnam_r,
 587                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 588 [[
 589 #include <errno.h>
 590 #include <pwd.h>
 591 ]],
 592 [[
 593     char buffer[10000];
 594     struct passwd pwd, *pwptr = &pwd;
 595     int error;
 596     errno = 0;
 597     error = getpwnam_r ("", &pwd, buffer,
 598                         sizeof (buffer), &pwptr);
 599    return (error < 0 && errno == ENOSYS)
 600            || error == ENOSYS;
 601 ]])],
 602         [ac_cv_func_posix_getpwnam_r=yes],
 603         [ac_cv_func_posix_getpwnam_r=no],
 604         [ac_cv_func_posix_getpwnam_r=yes]
 605 )])
 606 AC_LANG_POP(C)
 607
 608 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 609         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 610                 [Have POSIX function getpwnam_r])
 611 else
 612         AC_CACHE_CHECK([for nonposix getpwnam_r],
 613                 ac_cv_func_nonposix_getpwnam_r,
 614                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 615                         struct passwd pwd;
 616                         getpwnam_r ("", &pwd, buffer,
 617                                         sizeof (buffer));]])],
 618                         [ac_cv_func_nonposix_getpwnam_r=yes],
 619                         [ac_cv_func_nonposix_getpwnam_r=no])])
 620                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 621                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 622                         [Have non-POSIX function getpwnam_r])
 623         fi
 624 fi
 625
 626 dnl check for socklen_t
 627 AC_MSG_CHECKING(whether socklen_t is defined)
 628 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 629 #include <sys/types.h>
 630 #include <sys/socket.h>
 631 #include <netdb.h>
 632 ]], [[
 633 socklen_t foo;
 634 foo = 1;
 635 ]])],
 636 [dbus_have_socklen_t=yes],
 637 [dbus_have_socklen_t=no])
 638 AC_MSG_RESULT($dbus_have_socklen_t)
 639
 640 if test "x$dbus_have_socklen_t" = "xyes"; then
 641     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 642 fi
 643
 644 dnl check for writev header and writev function so we're
 645 dnl good to go if HAVE_WRITEV gets defined.
 646 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 647
 648 dnl needed on darwin for NAME_MAX
 649 AC_CHECK_HEADERS(sys/syslimits.h)
 650
 651 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 652 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 653
 654 dnl check for flavours of varargs macros (test from GLib)
 655 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 656 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 657 int a(int p1, int p2, int p3);
 658 #define call_a(...) a(1,__VA_ARGS__)
 659 call_a(2,3);
 660 ]])],
 661 [dbus_have_iso_c_varargs=yes],
 662 [dbus_have_iso_c_varargs=no])
 663 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 664
 665 AC_MSG_CHECKING(for GNUC varargs macros)
 666 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 667 int a(int p1, int p2, int p3);
 668 #define call_a(params...) a(1,params)
 669 call_a(2,3);
 670 ]])],
 671 [dbus_have_gnuc_varargs=yes],
 672 [dbus_have_gnuc_varargs=no])
 673 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 674
 675 dnl Output varargs tests
 676 if test x$dbus_have_iso_c_varargs = xyes; then
 677     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 678 fi
 679 if test x$dbus_have_gnuc_varargs = xyes; then
 680     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 681 fi
 682
 683 dnl Check for various credentials.
 684 AC_MSG_CHECKING(for struct cmsgcred)
 685 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 686 #include <sys/types.h>
 687 #include <sys/socket.h>
 688 ]], [[
 689 struct cmsgcred cred;
 690
 691 cred.cmcred_pid = 0;
 692 ]])],
 693 [dbus_have_struct_cmsgcred=yes],
 694 [dbus_have_struct_cmsgcred=no])
 695 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 696
 697 if test x$dbus_have_struct_cmsgcred = xyes; then
 698     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 699 fi
 700
 701 AC_CHECK_FUNCS(getpeerucred getpeereid)
 702
 703 AC_CHECK_FUNCS(pipe2 accept4)
 704
 705 #### Abstract sockets
 706
 707 if test x$enable_abstract_sockets = xauto; then
 708 AC_LANG_PUSH(C)
 709 warn_on_xcompile=no
 710 AC_CACHE_CHECK([abstract socket namespace],
 711                 ac_cv_have_abstract_sockets,
 712                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 713 [[
 714 #include <sys/types.h>
 715 #include <stdlib.h>
 716 #include <string.h>
 717 #include <stdio.h>
 718 #include <sys/socket.h>
 719 #include <sys/un.h>
 720 #include <errno.h>
 721 ]],
 722 [[
 723   size_t slen;
 724   int listen_fd;
 725   struct sockaddr_un addr;
 726
 727   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 728
 729   if (listen_fd < 0)
 730     {
 731       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 732       exit (1);
 733     }
 734
 735   memset (&addr, '\0', sizeof (addr));
 736   addr.sun_family = AF_UNIX;
 737   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 738   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 739    * beginning.
 740    */
 741   slen = SUN_LEN(&addr);
 742   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 743
 744   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 745     {
 746        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 747                 strerror (errno));
 748        exit (1);
 749     }
 750   else
 751     exit (0);
 752 ]])],
 753               [ac_cv_have_abstract_sockets=yes],
 754               [ac_cv_have_abstract_sockets=no],
 755               [
 756                 ac_cv_have_abstract_sockets=no
 757                 warn_on_xcompile=yes
 758               ]
 759 )])
 760 if test x$warn_on_xcompile = xyes ; then
 761   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 762 fi
 763 AC_LANG_POP(C)
 764 fi
 765
 766 if test x$enable_abstract_sockets = xyes; then
 767     if test x$ac_cv_have_abstract_sockets = xno; then
 768         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 769     fi
 770 fi
 771
 772 if test x$enable_abstract_sockets = xno; then
 773    ac_cv_have_abstract_sockets=no;
 774 fi
 775
 776 if test x$ac_cv_have_abstract_sockets = xyes ; then
 777    DBUS_PATH_OR_ABSTRACT=abstract
 778    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 779 else
 780    DBUS_PATH_OR_ABSTRACT=path
 781 fi
 782
 783 # this is used in addresses to prefer abstract, e.g.
 784 # unix:path=/foo or unix:abstract=/foo
 785 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 786
 787 PKG_PROG_PKG_CONFIG
 788
 789 #### Sort out XML library
 790
 791 # see what we have
 792 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 793              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 794              have_expat=false)
 795
 796 # see what we want to use
 797 dbus_use_libxml=false
 798 dbus_use_expat=false
 799 if test x$with_xml = xexpat; then
 800         if ! $have_expat ; then
 801            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 802         fi
 803         dbus_use_expat=true
 804 elif test x$with_xml = xlibxml; then
 805         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 806         if ! $have_libxml ; then
 807            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 808         fi
 809         dbus_use_libxml=true
 810 else
 811         ### expat is the default because libxml can't currently survive
 812         ### our brutal OOM-handling unit test setup.
 813         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 814         if test x$have_expat = xfalse; then
 815                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 816         fi
 817         ### By default, only use Expat since it's tested and known to work.  If you're a
 818         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 819         ### if your OS is built around libxml, that's another case.
 820         dbus_use_expat=true
 821 fi
 822
 823 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 824 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 825
 826 if $dbus_use_expat; then
 827    XML_LIBS=-lexpat
 828    XML_CFLAGS=
 829 fi
 830 if $dbus_use_libxml; then
 831    XML_LIBS=$LIBXML_LIBS
 832    XML_CFLAGS=$LIBXML_CFLAGS
 833 fi
 834
 835 # Thread lib detection
 836 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 837                                                     [THREAD_LIBS="-lpthread"])])
 838 save_libs="$LIBS"
 839 LIBS="$LIBS $THREAD_LIBS"
 840 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 841 if test x$have_pthread_condattr_setclock = xtrue; then
 842     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 843     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 844     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 845 #include <pthread.h>
 846 ]], [[
 847 struct timespec monotonic_timer;
 848 pthread_condattr_t attr;
 849 pthread_condattr_init (&attr);
 850 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 851 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 852 ]])],
 853 [have_clock_monotonic=true],
 854 [have_clock_monotonic=false])
 855 if test x$have_clock_monotonic = xtrue; then
 856     AC_MSG_RESULT([found])
 857     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 858 else
 859     AC_MSG_RESULT([not found])
 860 fi
 861 fi
 862 LIBS="$save_libs"
 863
 864 # SELinux detection
 865 if test x$enable_selinux = xno ; then
 866     have_selinux=no;
 867 else
 868     # See if we have SELinux library
 869     AC_CHECK_LIB(selinux, is_selinux_enabled,
 870                  have_selinux=yes, have_selinux=no)
 871
 872     # see if we have the SELinux header with the new D-Bus stuff in it
 873     if test x$have_selinux = xyes ; then
 874         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 875         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 876                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 877                             #else
 878                             #error DBUS__ACQUIRE_SVC not defined
 879                             #endif]])],
 880                           [have_selinux=yes],
 881                           [have_selinux=no])
 882         AC_MSG_RESULT($have_selinux)
 883     fi
 884
 885     if test x$enable_selinux = xauto ; then
 886         if test x$have_selinux = xno ; then
 887                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 888         fi
 889     else
 890         if test x$have_selinux = xno ; then
 891                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 892         fi
 893     fi
 894 fi
 895
 896 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 897
 898 if test x$have_selinux = xyes ; then
 899     # the selinux code creates threads
 900     # which requires libpthread even on linux
 901     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
 902                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
 903
 904     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
 905     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
 906 else
 907     SELINUX_LIBS=
 908 fi
 909
 910 # inotify checks
 911 if test x$enable_inotify = xno ; then
 912     have_inotify=no;
 913 else
 914     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
 915 fi
 916
 917 dnl check if inotify backend is enabled
 918 if test x$have_inotify = xyes; then
 919    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
 920    AC_CHECK_FUNCS(inotify_init1)
 921 fi
 922
 923 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
 924
 925 # dnotify checks
 926 if test x$enable_dnotify = xno ; then
 927     have_dnotify=no;
 928 else
 929     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
 930         have_dnotify=yes;
 931     else
 932         have_dnotify=no;
 933     fi
 934 fi
 935
 936 dnl check if dnotify backend is enabled
 937 if test x$have_dnotify = xyes; then
 938    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
 939 fi
 940
 941 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
 942
 943 # kqueue checks
 944 if test x$enable_kqueue = xno ; then
 945     have_kqueue=no
 946 else
 947     have_kqueue=yes
 948     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
 949     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
 950
 951     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
 952         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
 953     fi
 954 fi
 955
 956 dnl check if kqueue backend is enabled
 957 if test x$have_kqueue = xyes; then
 958    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
 959 fi
 960
 961 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
 962
 963 # launchd checks
 964 if test x$enable_launchd = xno ; then
 965     have_launchd=no
 966 else
 967     have_launchd=yes
 968     AC_CHECK_HEADER([launch.h], , have_launchd=no)
 969     AC_PATH_PROG([LAUNCHCTL], [launchctl])
 970     if test "x$LAUNCHCTL" = "x"; then
 971         have_launchd=no
 972     fi
 973
 974     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
 975         AC_MSG_ERROR([launchd support explicitly enabled but not available])
 976     fi
 977 fi
 978
 979 dnl check if launchd is enabled
 980 if test x$have_launchd = xyes; then
 981     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
 982 fi
 983
 984 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
 985
 986 #### Directory to place launchd agent file
 987 if test "x$with_launchd_agent_dir" = "x"; then
 988    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
 989 else
 990    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
 991 fi
 992
 993 AC_SUBST(LAUNCHD_AGENT_DIR)
 994
 995 dnl console owner file
 996 if test x$enable_console_owner_file = xno ; then
 997     have_console_owner_file=no;
 998 else
 999     case $host_os in
1000     solaris*)
1001         have_console_owner_file=yes;
1002         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1003         ;;
1004     *)
1005         have_console_owner_file=no;;
1006     esac
1007 fi
1008
1009 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1010
1011 # libaudit detection
1012 if test x$enable_libaudit = xno ; then
1013     have_libaudit=no;
1014 else
1015     # See if we have audit daemon & capabilities library
1016     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1017                  have_libaudit=yes, have_libaudit=no)
1018     if test x$have_libaudit = xyes ; then
1019         AC_CHECK_LIB(cap-ng, capng_clear,
1020                  have_libaudit=yes, have_libaudit=no)
1021     fi
1022 fi
1023
1024 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1025
1026 if test x$have_libaudit = xyes ; then
1027     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1028     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1029 fi
1030
1031 # Check for ADT API
1032 AC_MSG_CHECKING(for ADT API)
1033 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1034 #include <bsm/adt.h>
1035 adt_user_context = ADT_USER;
1036 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1037
1038 if test ${check_adt_audit} = yes
1039 then
1040    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1041    ADT_LIBS="-lbsm"
1042    LIBS="-lbsm $LIBS"
1043    AC_MSG_RESULT(yes)
1044 else
1045    AC_MSG_RESULT(no)
1046 fi
1047
1048 # Check for SCM_RIGHTS
1049 AC_MSG_CHECKING([for SCM_RIGHTS])
1050 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1051 #include <sys/socket.h>
1052 #include <sys/un.h>
1053 static int x = SCM_RIGHTS;
1054 ]], [[]])],
1055 [ AC_MSG_RESULT([supported])
1056   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1057 [ AC_MSG_RESULT([not supported]) ])
1058
1059 NETWORK_libs=
1060 if test x$dbus_win = xyes ; then
1061   if test x$dbus_wince = xyes ; then
1062     NETWORK_libs="-lws2"
1063   else
1064     NETWORK_libs="-lws2_32"
1065   fi
1066 fi
1067
1068 #### Set up final flags
1069 DBUS_CLIENT_CFLAGS=
1070 DBUS_CLIENT_LIBS="$THREAD_LIBS $NETWORK_libs"
1071 AC_SUBST(DBUS_CLIENT_CFLAGS)
1072 AC_SUBST(DBUS_CLIENT_LIBS)
1073
1074 DBUS_BUS_CFLAGS="$XML_CFLAGS"
1075 DBUS_BUS_LIBS="$XML_LIBS $SELINUX_LIBS $THREAD_LIBS $ADT_LIBS $NETWORK_libs"
1076 AC_SUBST(DBUS_BUS_CFLAGS)
1077 AC_SUBST(DBUS_BUS_LIBS)
1078
1079 DBUS_LAUNCHER_CFLAGS="$XML_CFLAGS"
1080 DBUS_LAUNCHER_LIBS="$XML_LIBS $THREAD_LIBS $NETWORK_libs"
1081 AC_SUBST(DBUS_LAUNCHER_CFLAGS)
1082 AC_SUBST(DBUS_LAUNCHER_LIBS)
1083
1084 DBUS_TEST_CFLAGS=
1085 DBUS_TEST_LIBS="$THREAD_LIBS $NETWORK_libs"
1086 AC_SUBST(DBUS_TEST_CFLAGS)
1087 AC_SUBST(DBUS_TEST_LIBS)
1088
1089 ### X11 detection
1090 DBUS_X_LIBS=
1091 DBUS_X_CFLAGS=
1092
1093 AC_ARG_ENABLE([x11-autolaunch],
1094   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1095   [], [enable_x11_autolaunch=auto])
1096
1097 if test "x$dbus_win" = xyes; then
1098     if test "x$enable_x11_autolaunch" = xyes; then
1099         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1100     fi
1101
1102     enable_x11_autolaunch=no
1103 fi
1104
1105 if test "x$enable_x11_autolaunch" = xno; then
1106     have_x11=no
1107 else
1108     AC_PATH_XTRA
1109
1110     if test "x$no_x" = xyes; then
1111         have_x11=no
1112     else
1113         have_x11=yes
1114         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1115         DBUS_X_CFLAGS="$X_CFLAGS"
1116     fi
1117 fi
1118
1119 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1120     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1121 else
1122     # move from "auto" to "yes" or "no" if necessary
1123     enable_x11_autolaunch="$have_x11"
1124 fi
1125
1126 if test "x$enable_x11_autolaunch" = xyes ; then
1127    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to enable X11 auto-launch])
1128 fi
1129
1130 AC_SUBST([DBUS_X_CFLAGS])
1131 AC_SUBST([DBUS_X_LIBS])
1132
1133 #### gcc warning flags
1134
1135 cc_supports_flag() {
1136   AC_MSG_CHECKING(whether $CC supports "$*")
1137   save_CFLAGS="$CFLAGS"
1138   CFLAGS="$*"
1139   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1140   CFLAGS="$save_CFLAGS"
1141   AC_MSG_RESULT([$rc])
1142   test "x$rc" = xyes
1143 }
1144
1145 # Don't bother with -Werror on Windows for now, too many warnings
1146 if test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$USE_MAINTAINER_MODE = xyes; then
1147   if cc_supports_flag "-Werror"; then
1148     CFLAGS="$CFLAGS -Werror"
1149   fi
1150 fi
1151
1152 dnl This whole "if" block is in m4 quotes ([]) because it uses them
1153 dnl for character ranges internally. m4 macros cannot be used inside this
1154 dnl block.
1155 [if test "x$GCC" = "xyes"; then
1156   case " $CFLAGS " in
1157   *[\ \ ]-Wall[\ \      ]*) ;;
1158   *) CFLAGS="$CFLAGS -Wall" ;;
1159   esac
1160
1161   case " $CFLAGS " in
1162   *[\ \ ]-Wchar-subscripts[\ \  ]*) ;;
1163   *) CFLAGS="$CFLAGS -Wchar-subscripts" ;;
1164   esac
1165
1166   case " $CFLAGS " in
1167   *[\ \ ]-Wmissing-declarations[\ \     ]*) ;;
1168   *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
1169   esac
1170
1171   case " $CFLAGS " in
1172   *[\ \ ]-Wmissing-prototypes[\ \       ]*) ;;
1173   *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
1174   esac
1175
1176   case " $CFLAGS " in
1177   *[\ \ ]-Wnested-externs[\ \   ]*) ;;
1178   *) CFLAGS="$CFLAGS -Wnested-externs" ;;
1179   esac
1180
1181   case " $CFLAGS " in
1182   *[\ \ ]-Wpointer-arith[\ \    ]*) ;;
1183   *) CFLAGS="$CFLAGS -Wpointer-arith" ;;
1184   esac
1185
1186   case " $CFLAGS " in
1187   *[\ \ ]-Wcast-align[\ \       ]*) ;;
1188   *) CFLAGS="$CFLAGS -Wcast-align" ;;
1189   esac
1190
1191   case " $CFLAGS " in
1192   *[\ \ ]-Wno-address[\ \       ]*) ;;
1193   *) CFLAGS="$CFLAGS -Wno-address" ;;
1194   esac
1195
1196   case " $CFLAGS " in
1197   *[\ \ ]-Wfloat-equal[\ \      ]*) ;;
1198   *) if cc_supports_flag -Wfloat-equal; then
1199         CFLAGS="$CFLAGS -Wfloat-equal"
1200      fi
1201      ;;
1202   esac
1203
1204   case " $CFLAGS " in
1205   *[\ \ ]-Wdeclaration-after-statement[\ \      ]*) ;;
1206   *) if cc_supports_flag -Wdeclaration-after-statement; then
1207         CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1208      fi
1209      ;;
1210   esac
1211
1212   case " $CFLAGS " in
1213   *[\ \ ]-fno-common[\ \        ]*) ;;
1214   *) if cc_supports_flag -fno-common; then
1215         CFLAGS="$CFLAGS -fno-common"
1216      fi
1217      ;;
1218   esac
1219
1220   ### Disabled warnings, and compiler flag overrides
1221
1222   # Let's just ignore unused for now
1223   case " $CFLAGS " in
1224   *[\ \ ]-Wno-unused[\ \        ]*) ;;
1225   *) CFLAGS="$CFLAGS -Wno-unused" ;;
1226   esac
1227
1228   # This group is for warnings we currently don't pass.
1229   # We would like to, however.  Please fix.
1230
1231   # http://bugs.freedesktop.org/show_bug.cgi?id=17433
1232   case " $CFLAGS " in
1233   *[\ \ ]-Wno-sign-compare[\ \  ]*) ;;
1234   *) CFLAGS="$CFLAGS -Wno-sign-compare" ;;
1235   esac
1236   case " $CFLAGS " in
1237   *[\ \ ]-Wno-pointer-sign[\ \  ]*) ;;
1238   *) if cc_supports_flag -Wno-pointer-sign; then
1239         CFLAGS="$CFLAGS -Wno-pointer-sign"
1240      fi
1241      ;;
1242   esac
1243
1244   # This one is special - it's not a warning override.
1245   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1246   case " $CFLAGS " in
1247   *[\ \ ]-fno-strict-aliasing[\ \       ]*) ;;
1248   *) CFLAGS="$CFLAGS -fno-strict-aliasing" ;;
1249   esac
1250   ### End disabled warnings
1251
1252   if test "x$enable_ansi" = "xyes"; then
1253     case " $CFLAGS " in
1254     *[\ \       ]-ansi[\ \      ]*) ;;
1255     *) CFLAGS="$CFLAGS -ansi" ;;
1256     esac
1257
1258     case " $CFLAGS " in
1259     *[\ \       ]-D_POSIX_C_SOURCE*) ;;
1260     *) CFLAGS="$CFLAGS -D_POSIX_C_SOURCE=199309L" ;;
1261     esac
1262
1263     case " $CFLAGS " in
1264     *[\ \       ]-D_BSD_SOURCE[\ \      ]*) ;;
1265     *) CFLAGS="$CFLAGS -D_BSD_SOURCE" ;;
1266     esac
1267
1268     case " $CFLAGS " in
1269     *[\ \       ]-pedantic[\ \  ]*) ;;
1270     *) CFLAGS="$CFLAGS -pedantic" ;;
1271     esac
1272   fi
1273 fi]
1274
1275 # Disabling gc-sections makes our binaries bigger, but some toolchains
1276 # have known-broken support for it which discards sections that are needed.
1277 # See https://bugs.freedesktop.org/show_bug.cgi?id=33466
1278 SECTION_LDFLAGS=
1279 AC_ARG_ENABLE([gc-sections],
1280   [AS_HELP_STRING([--disable-gc-sections],
1281     [disable --gc-sections to work around broken toolchains])],
1282   [enable_gc_sections=$enableval],
1283   [enable_gc_sections=yes])
1284 if test "x$GCC,$enable_gc_sections,$dbus_win" = xyes,yes,no; then
1285   save_CFLAGS="$CFLAGS"
1286   save_LDFLAGS="$LDFLAGS"
1287   AC_MSG_CHECKING([for ability to link with --gc-sections])
1288   CFLAGS="-ffunction-sections -fdata-sections"
1289   LDFLAGS="-Wl,--gc-sections"
1290   AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1291     [rc=yes],
1292     [rc=no])
1293   AC_MSG_RESULT([$rc])
1294   CFLAGS="$save_CFLAGS"
1295   LDFLAGS="$save_LDFLAGS"
1296   if test "x$rc" = xyes; then
1297     SECTION_LDFLAGS="-Wl,--gc-sections"
1298     CFLAGS="-ffunction-sections -fdata-sections $CFLAGS"
1299   fi
1300 fi
1301 AC_SUBST([SECTION_LDFLAGS])
1302
1303 case $host_os in
1304     solaris*)
1305         # Solaris' C library apparently needs these runes to be threadsafe...
1306         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1307 esac
1308
1309 ### Doxygen Documentation
1310
1311 AC_PATH_PROG(DOXYGEN, doxygen, no)
1312
1313 AC_MSG_CHECKING([whether to build Doxygen documentation])
1314
1315 if test x$DOXYGEN = xno ; then
1316     have_doxygen=no
1317 else
1318     have_doxygen=yes
1319 fi
1320
1321 if test x$enable_doxygen_docs = xauto ; then
1322     if test x$have_doxygen = xno ; then
1323         enable_doxygen_docs=no
1324     else
1325         enable_doxygen_docs=yes
1326     fi
1327 fi
1328
1329 if test x$enable_doxygen_docs = xyes; then
1330     if test x$have_doxygen = xno; then
1331         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1332     fi
1333 fi
1334
1335 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1336 AC_MSG_RESULT($enable_doxygen_docs)
1337
1338 XSLTPROC=false
1339 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1340 AM_CONDITIONAL(DBUS_HAVE_XSLTPROC, test "$XSLTPROC" != false)
1341
1342 ### XML Documentation
1343
1344 AC_PATH_PROG(XMLTO, xmlto, no)
1345
1346 AC_MSG_CHECKING([whether to build XML documentation])
1347
1348 if test x$XMLTO = xno ; then
1349     have_xmlto=no
1350 else
1351     have_xmlto=yes
1352 fi
1353
1354 if test x$enable_xml_docs = xauto ; then
1355     if test x$have_xmlto = xno ; then
1356         enable_xml_docs=no
1357     else
1358         enable_xml_docs=yes
1359     fi
1360 fi
1361
1362 if test x$enable_xml_docs = xyes; then
1363     if test x$have_xmlto = xno; then
1364         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1365     fi
1366 fi
1367
1368 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1369 AC_MSG_RESULT($enable_xml_docs)
1370
1371 AC_PATH_PROG([MAN2HTML], [man2html])
1372 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1373 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1374
1375 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1376     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1377          x$MAN2HTML != x)
1378
1379 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1380
1381 #### find the actual value for $prefix that we'll end up with
1382 ##   (I know this is broken and should be done in the Makefile, but
1383 ##    that's a major pain and almost nobody actually seems to care)
1384 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1385 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1386 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1387 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1388 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1389 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1390 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1391
1392 #### Check our operating system
1393 operating_system=unknown
1394 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1395    operating_system=redhat
1396 fi
1397
1398 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1399    operating_system=slackware
1400 fi
1401
1402 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1403    operating_system=cygwin
1404 fi
1405
1406 #### Sort out init scripts
1407
1408 if test x$with_init_scripts = x; then
1409     case x$operating_system in
1410         xredhat)        with_init_scripts=redhat ;;
1411         xslackware)     with_init_scripts=slackware ;;
1412         xcygwin)        with_init_scripts=cygwin ;;
1413         *)                      with_init_scripts=none ;;
1414     esac
1415 fi
1416
1417 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1418 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1419 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1420
1421 ##### systemd unit files
1422 AC_ARG_WITH([systemdsystemunitdir],
1423 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1424         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
1425 if test "x$with_systemdsystemunitdir" != xno; then
1426    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1427 fi
1428 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1429
1430 ##### Set up location for system bus socket
1431 if ! test -z "$with_system_socket"; then
1432    DBUS_SYSTEM_SOCKET=$with_system_socket
1433 else
1434    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1435 fi
1436
1437 AC_SUBST(DBUS_SYSTEM_SOCKET)
1438 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1439
1440 ## system bus only listens on local domain sockets, and never
1441 ## on an abstract socket (so only root can create the socket)
1442 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1443 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1444 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1445
1446 #### Set up the pid file
1447 if ! test -z "$with_system_pid_file"; then
1448    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1449 elif test x$with_init_scripts = xredhat ; then
1450    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1451 else
1452    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1453 fi
1454
1455 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1456
1457 #### Directory to check for console ownership
1458 if ! test -z "$with_console_auth_dir"; then
1459    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1460 else
1461    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1462 fi
1463
1464 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1465 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1466
1467 #### File to check for console ownership
1468 if test x$have_console_owner_file = xyes; then
1469    if ! test -z "$with_console_owner_file"; then
1470       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1471    else
1472       DBUS_CONSOLE_OWNER_FILE=/dev/console
1473    fi
1474 else
1475   DBUS_CONSOLE_OWNER_FILE=
1476 fi
1477
1478 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1479 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1480
1481 #### User to start the system bus as
1482 if test -z "$with_dbus_user" ; then
1483     DBUS_USER=messagebus
1484 else
1485     DBUS_USER=$with_dbus_user
1486 fi
1487 AC_SUBST(DBUS_USER)
1488 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1489
1490 #### Prefix to install into
1491 DBUS_PREFIX=$EXPANDED_PREFIX
1492 AC_SUBST(DBUS_PREFIX)
1493 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1494
1495 #### Direcotry to install data files into
1496 DBUS_DATADIR=$EXPANDED_DATADIR
1497 AC_SUBST(DBUS_DATADIR)
1498 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1499
1500 #### Directory to install dbus-daemon
1501 if test -z "$with_dbus_daemondir" ; then
1502     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1503 else
1504     DBUS_DAEMONDIR=$with_dbus_daemondir
1505 fi
1506 AC_SUBST(DBUS_DAEMONDIR)
1507 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1508
1509 #### Directory to install the other binaries
1510 DBUS_BINDIR="$EXPANDED_BINDIR"
1511 AC_SUBST(DBUS_BINDIR)
1512 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1513
1514 #### Directory to install the libexec binaries
1515 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1516 AC_SUBST(DBUS_LIBEXECDIR)
1517 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1518
1519 #### Tell tests where to find certain stuff in builddir
1520
1521 DBUS_PWD=`pwd`
1522 # Useful in a cross-compilation environment, where the tests are run on the host system.
1523 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1524                            DBUS_PWD=$withval)
1525 AC_DEFUN([TEST_PATH], [
1526 TEST_$1=${DBUS_PWD}/test/$2
1527 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1",
1528                    [Full path to test file test/$2 in builddir])
1529 AC_SUBST(TEST_$1)
1530 ])
1531 AC_DEFUN([TEST_PROG], [
1532 TEST_$1=${DBUS_PWD}/test/$2
1533 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1$EXEEXT",
1534                    [Full path to test file test/$2 in builddir])
1535 AC_SUBST(TEST_$1)
1536 ])
1537
1538 TEST_PATH(VALID_SERVICE_DIR, data/valid-service-files)
1539 TEST_PATH(INVALID_SERVICE_DIR, data/invalid-service-files)
1540 TEST_PATH(VALID_SERVICE_SYSTEM_DIR, data/valid-service-files-system)
1541 TEST_PATH(INVALID_SERVICE_SYSTEM_DIR, data/invalid-service-files-system)
1542 TEST_PROG(SERVICE_BINARY, test-service)
1543 TEST_PROG(SHELL_SERVICE_BINARY, test-shell-service)
1544 TEST_PROG(EXIT_BINARY, test-exit)
1545 TEST_PROG(SEGFAULT_BINARY, test-segfault)
1546 TEST_PROG(SLEEP_FOREVER_BINARY, test-sleep-forever)
1547 TEST_PROG(PRIVSERVER_BINARY, name-test/test-privserver)
1548
1549 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, "$DBUS_PWD/bus/dbus-daemon$EXEEXT",
1550                    [Full path to the daemon in the builddir])
1551 AC_SUBST(TEST_BUS_BINARY)
1552
1553 ## Export the non-setuid external helper
1554 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1555 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1556 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1557                    [Full path to the launch helper test program in the builddir])
1558
1559 #### Find socket directories
1560 if ! test -z "$TMPDIR" ; then
1561    DEFAULT_SOCKET_DIR=$TMPDIR
1562 elif ! test -z "$TEMP" ; then
1563    DEFAULT_SOCKET_DIR=$TEMP
1564 elif ! test -z "$TMP" ; then
1565    DEFAULT_SOCKET_DIR=$TMP
1566 else
1567    DEFAULT_SOCKET_DIR=/tmp
1568 fi
1569
1570 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1571
1572 if ! test -z "$with_test_socket_dir" ; then
1573    TEST_SOCKET_DIR="$with_test_socket_dir"
1574 else
1575    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1576 fi
1577 AC_SUBST(TEST_SOCKET_DIR)
1578 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1579
1580 if ! test -z "$with_session_socket_dir" ; then
1581    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1582 else
1583    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1584 fi
1585 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1586 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1587
1588 if test x$dbus_win = xyes; then
1589         DBUS_SESSION_BUS_DEFAULT_ADDRESS="nonce-tcp:"
1590 elif test x$have_launchd = xyes; then
1591         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1592 else
1593         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1594 fi
1595 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1596
1597 # darwin needs this to initialize the environment
1598 AC_CHECK_HEADERS(crt_externs.h)
1599 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1600 AH_VERBATIM(_DARWIN_ENVIRON,
1601 [
1602 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1603 # include <sys/time.h>
1604 # include <crt_externs.h>
1605 # define environ (*_NSGetEnviron())
1606 #endif
1607 ])
1608
1609 AC_CONFIG_FILES([
1610 Doxyfile
1611 dbus/versioninfo.rc
1612 dbus/dbus-arch-deps.h
1613 bus/system.conf
1614 bus/session.conf
1615 bus/messagebus
1616 bus/messagebus-config
1617 bus/org.freedesktop.dbus-session.plist
1618 bus/rc.messagebus
1619 bus/dbus.service
1620 bus/dbus.socket
1621 Makefile
1622 dbus/Makefile
1623 bus/Makefile
1624 tools/Makefile
1625 test/Makefile
1626 test/name-test/Makefile
1627 doc/Makefile
1628 doc/dbus-daemon.1
1629 dbus-1.pc
1630 dbus-1-uninstalled.pc
1631 test/data/valid-config-files/debug-allow-all.conf
1632 test/data/valid-config-files/debug-allow-all-sha1.conf
1633 test/data/valid-config-files-system/debug-allow-all-pass.conf
1634 test/data/valid-config-files-system/debug-allow-all-fail.conf
1635 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1636 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1637 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1638 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1639 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1640 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1641 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1642 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1643 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1644 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1645 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1646 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1647 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1648 ])
1649 AC_OUTPUT
1650
1651 dnl ==========================================================================
1652 echo "
1653                     D-Bus $VERSION
1654                   ==============
1655
1656         prefix:                   ${EXPANDED_PREFIX}
1657         exec_prefix:              ${exec_prefix}
1658         libdir:                   ${EXPANDED_LIBDIR}
1659         libexecdir:               ${EXPANDED_LIBEXECDIR}
1660         bindir:                   ${EXPANDED_BINDIR}
1661         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1662         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1663         datadir:                  ${EXPANDED_DATADIR}
1664         source code location:     ${srcdir}
1665         compiler:                 ${CC}
1666         cflags:                   ${CFLAGS}
1667         cppflags:                 ${CPPFLAGS}
1668         cxxflags:                 ${CXXFLAGS}
1669         64-bit int:               ${DBUS_INT64_TYPE}
1670         32-bit int:               ${DBUS_INT32_TYPE}
1671         16-bit int:               ${DBUS_INT16_TYPE}
1672         Doxygen:                  ${DOXYGEN:-not found}
1673         xmlto:                    ${XMLTO:-not found}
1674         man2html:                 ${MAN2HTML:-not found}"
1675
1676 echo "
1677         Maintainer mode:          ${USE_MAINTAINER_MODE}
1678         gcc coverage profiling:   ${enable_compiler_coverage}
1679         Building unit tests:      ${enable_tests}
1680         Building verbose mode:    ${enable_verbose_mode}
1681         Building assertions:      ${enable_asserts}
1682         Building checks:          ${enable_checks}
1683         Building SELinux support: ${have_selinux}
1684         Building inotify support: ${have_inotify}
1685         Building dnotify support: ${have_dnotify}
1686         Building kqueue support:  ${have_kqueue}
1687         Building X11 code:        ${enable_x11}
1688         Building Doxygen docs:    ${enable_doxygen_docs}
1689         Building XML docs:        ${enable_xml_docs}
1690         Building cache support:   ${enable_userdb_cache}
1691         Building launchd support: ${have_launchd}
1692         Using XML parser:         ${with_xml}
1693         Init scripts style:       ${with_init_scripts}
1694         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1695         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1696         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1697         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1698         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1699         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1700         Console owner file:       ${have_console_owner_file}
1701         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1702         System bus user:          ${DBUS_USER}
1703         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1704         'make check' socket dir:  ${TEST_SOCKET_DIR}
1705 "
1706 if test x$have_launchd = xyes; then
1707         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1708 fi
1709 echo
1710
1711 if test x$enable_tests = xyes; then
1712         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1713 fi
1714 if test x$enable_tests = xyes -a x$enable_asserts = xno; then
1715         echo "NOTE: building with unit tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1716 fi
1717 if test x$enable_compiler_coverage = xyes; then
1718         echo "NOTE: building with coverage profiling is definitely for developers only."
1719 fi
1720 if test x$enable_verbose_mode = xyes; then
1721         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1722 fi
1723 if test x$enable_asserts = xyes; then
1724         echo "NOTE: building with assertions increases library size and decreases performance."
1725 fi
1726 if test x$enable_checks = xno; then
1727         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1728 fi
1729 if test x$dbus_use_libxml = xtrue; then
1730         echo
1731         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1732 fi
1733
1734 if test "x$DBUS_HAVE_INT64" = x0; then
1735   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1736
1737   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1738   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1739   used if your compiler lacks support for 64-bit integers. Please report a bug
1740   with details of your platform and compiler.
1741
1742   This option is likely to be removed in future, unless the D-Bus developers
1743   receive reports that it is still needed.
1744   ])
1745 fi