configure.ac

   1 AC_INIT([libgee], [0.7.3], [ptitjes@free.fr], [libgee])
   2 AC_CONFIG_SRCDIR([Makefile.am])
   3 AC_CONFIG_HEADERS(config.h)
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AM_INIT_AUTOMAKE([check-news dist-bzip2])
   6 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   7
   8 # Checks for programs.
   9 AC_PROG_CC
  10 AM_PROG_CC_C_O
  11 AC_DISABLE_STATIC
  12 AC_PROG_LIBTOOL
  13
  14 LIBGEE_LT_VERSION="0:0:0"
  15 AC_SUBST(LIBGEE_LT_VERSION)
  16
  17 AM_PROG_VALAC([0.17.5])
  18 AC_SUBST(VALAC)
  19
  20 AC_SUBST(VALAFLAGS)
  21
  22 AC_ARG_ENABLE(doc, AS_HELP_STRING([--enable-doc], [Enable documentation generation]), enable_doc=$enableval, enable_doc=no)
  23 AM_CONDITIONAL(ENABLE_DOC, test x$enable_doc = xyes)
  24
  25 AS_IF([test "x$enable_doc" != xno],
  26         [AC_PATH_PROG(VALADOC, valadoc, :)
  27          AC_SUBST(VALADOC)
  28          AS_IF([test "$VALADOC" = :],
  29                 [AC_MSG_ERROR([valadoc not found])])])
  30
  31 AC_ARG_ENABLE(coverage,
  32         AS_HELP_STRING([--enable-coverage],
  33         [compile with coverage profiling and debug (gcc only)]),
  34         enable_coverage=$enableval,enable_coverage=no)
  35 AM_CONDITIONAL(ENABLE_COVERAGE, test x$enable_coverage != xno)
  36
  37 AS_IF([test "x$enable_coverage" != xno],
  38         [COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
  39          COVERAGE_VALAFLAGS="-g"
  40          COVERAGE_LIBS="-lgcov"
  41          AC_SUBST(COVERAGE_CFLAGS)
  42          AC_SUBST(COVERAGE_VALAFLAGS)
  43          AC_SUBST(COVERAGE_LIBS)
  44
  45          AC_PATH_PROG(LCOV, lcov, :)
  46          AC_SUBST(LCOV)
  47          AS_IF([test "$LCOV" = :],
  48                 [AC_MSG_ERROR([lcov is necessary for testing code coverage (http://ltp.sourceforge.net/coverage/lcov.php)])])])
  49
  50 AC_ARG_ENABLE(benchmark, AS_HELP_STRING([--enable-benchmark], [Enable benchmark]), enable_benchmark=$enableval, enable_benchmark=no)
  51 AM_CONDITIONAL(ENABLE_BENCHMARK, test x$enable_benchmark = xyes)
  52
  53 GLIB_REQUIRED=2.12.0
  54
  55 PKG_CHECK_MODULES(GLIB, glib-2.0 >= $GLIB_REQUIRED gobject-2.0 >= $GLIB_REQUIRED)
  56 AC_SUBST(GLIB_CFLAGS)
  57 AC_SUBST(GLIB_LIBS)
  58
  59 GOBJECT_INTROSPECTION_CHECK([0.9.0])
  60
  61 AC_OUTPUT([Makefile
  62            gee-0.8.pc
  63            benchmark/Makefile
  64            doc/Makefile
  65            gee/Makefile
  66            tests/Makefile])