configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [35])
  34 m4_define([glib_micro_version], [7])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153
 154     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 155     ;;
 156   *)
 157     glib_native_win32=no
 158     glib_pid_type=int
 159     ;;
 160 esac
 161 case $host in
 162   *-*-linux*)
 163     glib_os_linux=yes
 164     ;;
 165 esac
 166
 167 AC_MSG_RESULT([$glib_native_win32])
 168
 169 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 170
 171 glib_have_carbon=no
 172 AC_MSG_CHECKING([for Mac OS X Carbon support])
 173 AC_TRY_CPP([
 174 #include <Carbon/Carbon.h>
 175 #include <CoreServices/CoreServices.h>
 176 ], glib_have_carbon=yes)
 177
 178 AC_MSG_RESULT([$glib_have_carbon])
 179
 180 glib_have_cocoa=no
 181 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 182 AC_TRY_CPP([
 183 #include <Cocoa/Cocoa.h>
 184 #ifdef GNUSTEP_BASE_VERSION
 185 #error "Detected GNUstep, not Cocoa"
 186 #endif
 187 ], glib_have_cocoa=yes)
 188
 189 AC_MSG_RESULT([$glib_have_cocoa])
 190
 191 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 192 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 193 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 194 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 195 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 196 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 197
 198 AS_IF([test "$glib_native_win32" = "yes"], [
 199   AC_CHECK_TOOL(WINDRES, windres, no)
 200   if test "$WINDRES" = no; then
 201     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 202   fi
 203   AC_CHECK_TOOL(NM, nm, no)
 204   if test "$NM" = no; then
 205     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 206   fi
 207   AC_CHECK_TOOL(RANLIB, ranlib, :)
 208   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 209   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 210 ])
 211 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 212
 213 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 214   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 215   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 216 ])
 217
 218 if test "x$glib_have_cocoa" = "xyes"; then
 219   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 220   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 221 fi
 222
 223 gl_GLIBC21
 224 AS_IF([test "x$GLIBC21" = "xyes"], [
 225   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 226 ])
 227
 228 dnl declare --enable-* args and collect ac_help strings
 229 AC_ARG_ENABLE(debug,
 230               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 231                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 232               enable_debug=glib_debug_default)
 233
 234 AC_ARG_ENABLE(gc_friendly,
 235               [AS_HELP_STRING([--enable-gc-friendly],
 236                               [turn on garbage collector friendliness [default=no]])],,
 237               [enable_gc_friendly=no])
 238 AC_ARG_ENABLE(mem_pools,
 239               [AS_HELP_STRING([--disable-mem-pools],
 240                               [disable all glib memory pools])],,
 241               [disable_mem_pools=no])
 242 AC_ARG_ENABLE(rebuilds,
 243               [AS_HELP_STRING([--disable-rebuilds],
 244                               [disable all source autogeneration rules])],,
 245               [enable_rebuilds=yes])
 246 AC_ARG_ENABLE(modular_tests,
 247               AS_HELP_STRING([--disable-modular-tests],
 248                              [Disable build of test programs (default: no)]),,
 249               [enable_modular_tests=yes])
 250 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 251
 252 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 253 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 254   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 255   AC_MSG_RESULT([yes])
 256 ], [ AC_MSG_RESULT([no]) ])
 257
 258 AC_MSG_CHECKING([whether to disable memory pools])
 259 AS_IF([test "x$disable_mem_pools" = "xno"], [
 260   AC_MSG_RESULT([no])
 261 ], [
 262   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 263   AC_MSG_RESULT([yes])
 264 ])
 265
 266 dnl location to install runtime libraries, e.g. ../../lib to install
 267 dnl to /lib if libdir is /usr/lib
 268 AC_ARG_WITH(runtime-libdir,
 269            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 270                            [install runtime libraries relative to libdir])],
 271            [],
 272            [with_runtime_libdir=""])
 273 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 274 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 275 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 276 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 277 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 278
 279 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 280 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 281 AC_LANG_SAVE
 282 AC_LANG_CPLUSPLUS
 283 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 284 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 285 AC_LANG_RESTORE
 286
 287 AM_PROG_CC_C_O
 288 AC_PROG_INSTALL
 289
 290 AC_SYS_LARGEFILE
 291
 292 PKG_PROG_PKG_CONFIG(0.16)
 293
 294 if test "x$enable_debug" = "xyes"; then
 295   if test x$cflags_set != xset ; then
 296       case " $CFLAGS " in
 297       *[[\ \    ]]-g[[\ \       ]]*) ;;
 298       *) CFLAGS="$CFLAGS -g" ;;
 299       esac
 300   fi
 301   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 302 else
 303   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 304
 305   if test "x$enable_debug" = "xno"; then
 306     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 307   fi
 308 fi
 309
 310 # Ensure MSVC-compatible struct packing convention is used when
 311 # compiling for Win32 with gcc.
 312 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 313 # gcc2 uses "-fnative-struct".
 314 if test x"$glib_native_win32" = xyes; then
 315   if test x"$GCC" = xyes; then
 316     msnative_struct=''
 317     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 318     if test -z "$ac_cv_prog_CC"; then
 319       our_gcc="$CC"
 320     else
 321       our_gcc="$ac_cv_prog_CC"
 322     fi
 323     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 324       2.)
 325         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 326           msnative_struct='-fnative-struct'
 327         fi
 328         ;;
 329       *)
 330         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 331           msnative_struct='-mms-bitfields'
 332         fi
 333         ;;
 334     esac
 335     if test x"$msnative_struct" = x ; then
 336       AC_MSG_RESULT([no way])
 337       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 338     else
 339       CFLAGS="$CFLAGS $msnative_struct"
 340       AC_MSG_RESULT([${msnative_struct}])
 341     fi
 342   fi
 343 fi
 344 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 345 AC_SUBST(GLIB_EXTRA_CFLAGS)
 346
 347 AC_EXEEXT
 348
 349 # define a MAINT-like variable REBUILD which is set if Perl
 350 # and awk are found, so autogenerated sources can be rebuilt
 351 AC_PROG_AWK
 352 AC_CHECK_PROGS(PERL, [perl5 perl])
 353 # We would like indent, but don't require it.
 354 AC_CHECK_PROG(INDENT, indent, indent)
 355 REBUILD=\#
 356 if test "x$enable_rebuilds" = "xyes" && \
 357      test -n "$PERL" && \
 358      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 359      test -n "$AWK" ; then
 360   REBUILD=
 361 fi
 362 AC_SUBST(REBUILD)
 363
 364 # Need full path to Perl for glib-mkenums
 365 #
 366 if test "x$PERL" != x ; then
 367   AC_PATH_PROG(PERL_PATH, [$PERL])
 368 fi
 369 if test "x$PERL_PATH" = x ; then
 370   PERL_PATH="/usr/bin/env perl"
 371 fi
 372 AC_SUBST(PERL_PATH)
 373
 374 # option to specify python interpreter to use; this just sets $PYTHON, so that
 375 # we will fallback to reading $PYTHON if --with-python is not given, and
 376 # python.m4 will get the expected input
 377 AC_ARG_WITH(python,
 378             AS_HELP_STRING([--with-python=PATH],
 379                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 380             [PYTHON="$withval"], [])
 381 if test x"$PYTHON" = xyes; then
 382   AC_MSG_ERROR([--with-python option requires a path or program argument])
 383 fi
 384 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 385
 386
 387 dnl ***********************
 388 dnl *** Tests for iconv ***
 389 dnl ***********************
 390 dnl
 391 dnl We do this before the gettext checks, to avoid distortion
 392
 393 dnl On Windows we use a native implementation
 394
 395 AS_IF([ test x"$glib_native_win32" = xyes], [
 396   with_libiconv=native
 397 ], [
 398   AC_ARG_WITH(libiconv,
 399               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 400                               [use the libiconv library])],,
 401               [with_libiconv=maybe])
 402
 403   found_iconv=no
 404   case $with_libiconv in
 405     maybe)
 406       # Check in the C library first
 407       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 408       # Check if we have GNU libiconv
 409       if test $found_iconv = "no"; then
 410         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 411       fi
 412       # Check if we have a iconv in -liconv, possibly from vendor
 413       if test $found_iconv = "no"; then
 414         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 415       fi
 416       ;;
 417     no)
 418       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 419       ;;
 420     gnu|yes)
 421       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 422       ;;
 423     native)
 424       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 425       ;;
 426   esac
 427
 428   if test "x$found_iconv" = "xno" ; then
 429      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 430   fi
 431 ])
 432
 433 AC_ARG_ENABLE(iconv-cache,
 434               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 435                               [cache iconv descriptors [default=auto]])],,
 436               [enable_iconv_cache=auto])
 437
 438 AC_MSG_CHECKING([whether to cache iconv descriptors])
 439 case $enable_iconv_cache in
 440   auto)
 441     if test $ac_cv_gnu_library_2_1 = yes; then
 442       enable_iconv_cache=no
 443     else
 444       enable_iconv_cache=yes
 445     fi
 446   ;;
 447   yes|no)
 448   ;;
 449   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 450   ;;
 451 esac
 452
 453 if test $enable_iconv_cache = yes; then
 454    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 455 fi
 456
 457 AC_MSG_RESULT($enable_iconv_cache)
 458
 459
 460 dnl
 461 dnl zlib support
 462 dnl
 463 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 464 AS_IF([test "x$found_zlib" = "xno"], [
 465   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 466   if test "x$found_zlib" = "xno" ; then
 467     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 468   fi
 469   ZLIB_LIBS='-lz'
 470   AC_SUBST(ZLIB_LIBS)
 471 ])
 472
 473 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 474 AC_SUBST(LIBFFI_CFLAGS)
 475 AC_SUBST(LIBFFI_LIBS)
 476
 477 dnl
 478 dnl gettext support
 479 dnl
 480
 481 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 482 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 483 GLIB_GNU_GETTEXT
 484
 485 if test "$gt_cv_have_gettext" != "yes" ; then
 486   AC_MSG_ERROR([
 487 *** You must have either have gettext support in your C library, or use the
 488 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 489 ])
 490 fi
 491
 492 LIBS="$INTLLIBS $LIBS"
 493
 494 GETTEXT_PACKAGE=glib20
 495 AC_SUBST(GETTEXT_PACKAGE)
 496 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 497   [Define the gettext package to be used])
 498
 499 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 500
 501 dnl
 502 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 503 dnl
 504
 505 AS_IF([test x"$glib_native_win32" != xyes], [
 506   if test x$with_libiconv != xno ; then
 507     case " $INTLLIBS " in
 508     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 509     *) ICONV_LIBS="-liconv" ;;
 510     esac
 511   fi
 512 ])
 513 AC_SUBST(ICONV_LIBS)
 514
 515 case $with_libiconv in
 516   gnu)
 517     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 518     ;;
 519   native)
 520     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 521     ;;
 522 esac
 523
 524 dnl Initialize libtool
 525 LT_PREREQ([2.2])
 526 LT_INIT([disable-static win32-dll])
 527 dnl when using libtool 2.x create libtool early, because it's used in configure
 528 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 529
 530
 531 AS_IF([test "$glib_native_win32" = "yes"], [
 532   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 533     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 534   fi
 535   if test x$enable_static = xyes; then
 536     glib_win32_static_compilation=yes
 537     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 538 #define GOBJECT_STATIC_COMPILATION 1"
 539     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 540   fi
 541 ])
 542 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 543
 544 dnl
 545 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 546 dnl
 547 AS_IF([test $cross_compiling != yes], [
 548     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 549     glib_save_LIBS=$LIBS
 550     LIBS="$LIBS -lm"
 551     AC_TRY_RUN([#include <math.h>
 552                  int main (void) { return (log(1) != log(1.)); }],
 553          AC_MSG_RESULT(none needed),
 554          glib_save_CFLAGS=$CFLAGS
 555          CFLAGS="$CFLAGS -std1"
 556          AC_TRY_RUN([#include <math.h>
 557                      int main (void) { return (log(1) != log(1.)); }],
 558              AC_MSG_RESULT(-std1),
 559              AC_MSG_RESULT()
 560              CFLAGS=$glib_save_CFLAGS
 561              AC_MSG_WARN(
 562                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 563          )
 564     )
 565     LIBS=$glib_save_LIBS
 566 ])
 567
 568 dnl NeXTStep cc seems to need this
 569 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 570 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 571   AC_MSG_RESULT(none needed),
 572   glib_save_CFLAGS=$CFLAGS
 573   CFLAGS="$CFLAGS -posix"
 574   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 575     AC_MSG_RESULT(-posix),
 576     AC_MSG_RESULT()
 577     CFLAGS=$glib_save_CFLAGS
 578     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 579
 580 # Checks for library functions.
 581 AC_FUNC_VPRINTF
 582 AC_FUNC_ALLOCA
 583 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 584 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 585
 586 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 587   [AC_TRY_LINK([#include <unistd.h>
 588     extern int __libc_enable_secure;],
 589     [return __libc_enable_secure;],
 590    glib_cv_have_libc_enable_secure=yes,
 591    glib_cv_have_libc_enable_secure=no)])
 592 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 593    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 594      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 595 ])
 596
 597 AC_CHECK_SIZEOF(char)
 598 AC_CHECK_SIZEOF(short)
 599 AC_CHECK_SIZEOF(long)
 600 AC_CHECK_SIZEOF(int)
 601 AC_CHECK_SIZEOF(void *)
 602 AC_CHECK_SIZEOF(long long)
 603 AC_CHECK_SIZEOF(__int64)
 604
 605 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 606   [AC_TRY_LINK([#include <signal.h>
 607      #include <sys/types.h>
 608      sig_atomic_t val = 42;],
 609     [return val == 42 ? 0 : 1],
 610    ac_cv_type_sig_atomic_t=yes,
 611    ac_cv_type_sig_atomic_t=no)])
 612 if test x$ac_cv_type_sig_atomic_t = xyes; then
 613    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 614      [Define if you have the 'sig_atomic_t' type.])
 615 fi
 616
 617 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 618   :
 619 else
 620   AC_MSG_ERROR([
 621 *** GLib requires a 64 bit type. You might want to consider
 622 *** using the GNU C compiler.
 623 ])
 624 fi
 625
 626 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 627         # long long is a 64 bit integer.
 628         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 629         AC_CACHE_VAL(glib_cv_long_long_format,[
 630                 for format in ll q I64; do
 631                   AC_TRY_RUN([#include <stdio.h>
 632                         int main()
 633                         {
 634                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 635                           char buffer[1000];
 636                           sprintf (buffer, "%${format}u", a);
 637                           sscanf (buffer, "%${format}u", &b);
 638                           exit (b!=a);
 639                         }
 640                         ],
 641                         [glib_cv_long_long_format=${format}
 642                         break],
 643                         [],[:])
 644                 done])
 645         AS_IF([ test -n "$glib_cv_long_long_format"], [
 646           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 647           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 648           if test x"$glib_cv_long_long_format" = xI64; then
 649             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 650           fi
 651         ], [AC_MSG_RESULT(none)])
 652 ],[ test x$ac_cv_sizeof___int64 = x8], [
 653         # __int64 is a 64 bit integer.
 654         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 655         # We know this is MSVCRT.DLL, and what the formats are
 656         glib_cv_long_long_format=I64
 657         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 660 ])
 661
 662 AC_C_CONST
 663
 664 dnl ok, here we try to check whether the systems prototypes for
 665 dnl malloc and friends actually match the prototypes provided
 666 dnl by gmem.h (keep in sync). i currently only know how to check
 667 dnl this reliably with gcc (-Werror), improvements for other
 668 dnl compilers are apprechiated.
 669 SANE_MALLOC_PROTOS=no
 670 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 671 glib_save_CFLAGS=$CFLAGS
 672 AS_IF([test "x$GCC" = "xyes"], [
 673   CFLAGS="$CFLAGS -Werror"
 674   AC_TRY_COMPILE([#include <stdlib.h>], [
 675     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 676     void* (*my_malloc_p)  (size_t)         = malloc;
 677     void  (*my_free_p)    (void*)          = free;
 678     void* (*my_realloc_p) (void*, size_t)  = realloc;
 679     my_calloc_p = 0;
 680     my_malloc_p = 0;
 681     my_free_p = 0;
 682     my_realloc_p = 0;
 683   ],
 684     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 685       [Define if you have correct malloc prototypes])
 686     SANE_MALLOC_PROTOS=yes)
 687 ])
 688 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 689 CFLAGS=$glib_save_CFLAGS
 690
 691 dnl
 692 dnl check in which direction the stack grows
 693 dnl
 694 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 695         AC_TRY_RUN([
 696         volatile int *a = 0, *b = 0;
 697         void foo (void);
 698         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 699         void foo (void) { volatile int x = 5; b = &x; }
 700         ],
 701         glib_cv_stack_grows=no
 702         ,
 703         glib_cv_stack_grows=yes
 704         ,)
 705 ])
 706
 707 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 708 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 709 dnl actually supported.
 710 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 711         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 712         __inline int foo () { return 0; }
 713         int main () { return foo (); }
 714         ]])],
 715         glib_cv_has__inline=yes
 716         ,
 717         glib_cv_has__inline=no
 718         ,)
 719 ])
 720 case x$glib_cv_has__inline in
 721 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 722 esac
 723 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 724         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 725         __inline__ int foo () { return 0; }
 726         int main () { return foo (); }
 727         ]])],
 728         glib_cv_has__inline__=yes
 729         ,
 730         glib_cv_has__inline__=no
 731         ,)
 732 ])
 733 case x$glib_cv_has__inline__ in
 734 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 735 esac
 736 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 737         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 738         #undef inline
 739         inline int foo () { return 0; }
 740         int main () { return foo (); }
 741         ]])],
 742         glib_cv_hasinline=yes
 743         ,
 744         glib_cv_hasinline=no
 745         ,)
 746 ])
 747 case x$glib_cv_hasinline in
 748 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 749 esac
 750
 751 # if we can use inline functions in headers
 752 AC_MSG_CHECKING(if inline functions in headers work)
 753 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 754 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 755 #  undef inline
 756 #  define inline __inline__
 757 #elif !defined (G_HAVE_INLINE)
 758 #  undef inline
 759 #  if defined (G_HAVE___INLINE__)
 760 #    define inline __inline__
 761 #  elif defined (G_HAVE___INLINE)
 762 #    define inline __inline
 763 #  endif
 764 #endif
 765
 766 int glib_test_func2 (int);
 767
 768 static inline int
 769 glib_test_func1 (void) {
 770   return glib_test_func2 (1);
 771 }
 772
 773 int
 774 main (void) {
 775   int i = 1;
 776 }]])],[g_can_inline=yes],[g_can_inline=no])
 777 AC_MSG_RESULT($g_can_inline)
 778
 779 dnl *** check for working do while(0) macros ***
 780 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 781         AC_TRY_COMPILE([],[
 782         #define STMT_START do
 783         #define STMT_END while(0)
 784         #define STMT_TEST STMT_START { i = 0; } STMT_END
 785         int main(void) { int i = 1; STMT_TEST; return i; }],
 786         [g_cv_support_dowhile_macros=yes],
 787         [g_cv_support_dowhile_macros=no],
 788         [g_cv_support_dowhile_macros=yes])
 789 ])
 790 if test x$g_cv_support_dowhile_macros = xyes; then
 791   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 792 fi
 793
 794 # check for flavours of varargs macros
 795 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 796 AC_TRY_COMPILE([],[
 797 int a(int p1, int p2, int p3);
 798 #define call_a(...) a(1,__VA_ARGS__)
 799 call_a(2,3);
 800 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 801 AC_MSG_RESULT($g_have_iso_c_varargs)
 802
 803 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 804 AS_IF([test "$CXX" = ""], [
 805 dnl No C++ compiler
 806   g_have_iso_cxx_varargs=no
 807 else
 808   AC_LANG_CPLUSPLUS
 809   AC_TRY_COMPILE([],[
 810 int a(int p1, int p2, int p3);
 811 #define call_a(...) a(1,__VA_ARGS__)
 812 call_a(2,3);
 813 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 814   AC_LANG_C
 815 ])
 816 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 817
 818 AC_MSG_CHECKING(for GNUC varargs macros)
 819 AC_TRY_COMPILE([],[
 820 int a(int p1, int p2, int p3);
 821 #define call_a(params...) a(1,params)
 822 call_a(2,3);
 823 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 824 AC_MSG_RESULT($g_have_gnuc_varargs)
 825
 826 # check for GNUC visibility support
 827 AC_MSG_CHECKING(for GNUC visibility attribute)
 828 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 829 void
 830 __attribute__ ((visibility ("hidden")))
 831      f_hidden (void)
 832 {
 833 }
 834 void
 835 __attribute__ ((visibility ("internal")))
 836      f_internal (void)
 837 {
 838 }
 839 void
 840 __attribute__ ((visibility ("protected")))
 841      f_protected (void)
 842 {
 843 }
 844 void
 845 __attribute__ ((visibility ("default")))
 846      f_default (void)
 847 {
 848 }
 849 int main (void)
 850 {
 851         f_hidden();
 852         f_internal();
 853         f_protected();
 854         f_default();
 855         return 0;
 856 }
 857 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 858 AC_MSG_RESULT($g_have_gnuc_visibility)
 859 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 860
 861 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 862 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 863 #else
 864 # include "error: this is not Sun Studio."
 865 #endif
 866 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 867 AC_MSG_RESULT($g_have_sunstudio_visibility)
 868 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 869
 870 # check for bytesex stuff
 871 AC_C_BIGENDIAN
 872 if test x$ac_cv_c_bigendian = xuniversal ; then
 873 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 874 #else
 875 #error Not a big endian.
 876 #endif],
 877     ac_cv_c_bigendian=yes
 878     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 879 #else
 880 #error Not a little endian.
 881 #endif],
 882     ac_cv_c_bigendian=no
 883     ,AC_MSG_WARN([Could not determine endianness.])))
 884 fi
 885
 886
 887 # check for header files
 888 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 889 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 890 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 891 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 892 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 893 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 894 AC_CHECK_HEADERS([linux/magic.h])
 895 AC_CHECK_HEADERS([sys/prctl.h])
 896 AC_CHECK_HEADERS([sys/ioctl.h])
 897
 898 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 899 [#if HAVE_SYS_PARAM_H
 900  #include <sys/param.h>
 901  #endif
 902 ])
 903 AC_CHECK_FUNCS(sysctlbyname)
 904
 905 AC_CHECK_HEADERS([xlocale.h])
 906
 907 # check for structure fields
 908 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 909 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 910 #include <sys/stat.h>
 911 #include <unistd.h>
 912 #ifdef HAVE_SYS_STATFS_H
 913 #include <sys/statfs.h>
 914 #endif
 915 #ifdef HAVE_SYS_PARAM_H
 916 #include <sys/param.h>
 917 #endif
 918 #ifdef HAVE_SYS_MOUNT_H
 919 #include <sys/mount.h>
 920 #endif])
 921 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 922 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 923 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 924 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 925
 926 AC_STRUCT_DIRENT_D_TYPE
 927
 928 # Checks for libcharset
 929 AM_LANGINFO_CODESET
 930 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 931 AC_CHECK_FUNCS(setlocale)
 932
 933 # check additional type sizes
 934 AC_CHECK_SIZEOF(size_t)
 935
 936 dnl Try to figure out whether gsize, gssize should be long or int
 937 AC_MSG_CHECKING([for the appropriate definition for size_t])
 938
 939 case $ac_cv_sizeof_size_t in
 940   $ac_cv_sizeof_short)
 941       glib_size_type=short
 942       ;;
 943   $ac_cv_sizeof_int)
 944       glib_size_type=int
 945       ;;
 946   $ac_cv_sizeof_long)
 947       glib_size_type=long
 948       ;;
 949   $ac_cv_sizeof_long_long)
 950       glib_size_type='long long'
 951       ;;
 952   $ac_cv_sizeof__int64)
 953       glib_size_type='__int64'
 954       ;;
 955   *)  AC_MSG_ERROR([No type matching size_t in size])
 956       ;;
 957 esac
 958
 959 dnl If int/long are the same size, we see which one produces
 960 dnl warnings when used in the location as size_t. (This matters
 961 dnl on AIX with xlc)
 962 dnl
 963 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 964        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 965   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 966 #if defined(_AIX) && !defined(__GNUC__)
 967 #pragma options langlvl=stdc89
 968 #endif
 969 #include <stddef.h>
 970 int main ()
 971 {
 972   size_t s = 1;
 973   unsigned int *size_int = &s;
 974   return (int)*size_int;
 975 }
 976     ]])],glib_size_type=int,
 977       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 978 #if defined(_AIX) && !defined(__GNUC__)
 979 #pragma options langlvl=stdc89
 980 #endif
 981 #include <stddef.h>
 982 int main ()
 983 {
 984    size_t s = 1;
 985    unsigned long *size_long = &s;
 986    return (int)*size_long;
 987 }
 988         ]])],glib_size_type=long)])
 989 ])
 990
 991 AC_MSG_RESULT(unsigned $glib_size_type)
 992
 993 # Check for some functions
 994 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 995 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
 996 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 997 # Check for high-resolution sleep functions
 998 AC_CHECK_FUNCS(splice)
 999 AC_CHECK_FUNCS(prlimit)
1000
1001 # To avoid finding a compatibility unusable statfs, which typically
1002 # successfully compiles, but warns to use the newer statvfs interface:
1003 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1004 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1005
1006 AC_MSG_CHECKING([whether to use statfs or statvfs])
1007 # Some systems have both statfs and statvfs, pick the most "native" for these
1008 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1009    [
1010    # on solaris and irix, statfs doesn't even have the f_bavail field
1011    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1012       [ac_cv_func_statfs=no],
1013    # else, at least on linux, statfs is the actual syscall
1014       [ac_cv_func_statvfs=no])
1015    ])
1016
1017 AS_IF([test x$ac_cv_func_statfs = xyes],
1018       [
1019          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1020          AC_MSG_RESULT([statfs])
1021       ],
1022       [test x$ac_cv_func_statvfs = xyes],
1023       [
1024          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1025          AC_MSG_RESULT([statvfs])
1026       ],
1027       [  AC_MSG_RESULT([neither])])
1028
1029 AC_CHECK_HEADERS(crt_externs.h)
1030 AC_CHECK_FUNCS(_NSGetEnviron)
1031
1032 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1033
1034 AC_FUNC_VSNPRINTF_C99
1035 AC_FUNC_PRINTF_UNIX98
1036
1037 # Internet address families
1038 if test $glib_native_win32 = yes; then
1039   glib_inet_includes=["
1040 #include <winsock2.h>
1041   "]
1042 else
1043   glib_inet_includes=["
1044 #include <sys/types.h>
1045 #include <sys/socket.h>
1046   "]
1047 fi
1048
1049 glib_failed=false
1050 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1051 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1052 # winsock defines this even though it doesn't support it
1053 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1054 if $glib_failed ; then
1055   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1056 fi
1057
1058 glib_failed=false
1059 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1061 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1062 if $glib_failed ; then
1063   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1064 fi
1065
1066 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1067
1068 AS_IF([test $glib_native_win32 = yes], [
1069   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1070   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1071   # they aren't present at run-time (on Windows 2000).
1072   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1073   AC_SUBST(WSPIAPI_INCLUDE)
1074 ], [
1075   AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1076   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1077                                       #include <arpa/nameser.h>],
1078                                      [int qclass = C_IN;])],
1079                     [AC_MSG_RESULT([no])],
1080                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1081                                                          #include <arpa/nameser.h>
1082                                                          #include <arpa/nameser_compat.h>],
1083                                                         [int qclass = C_IN;])],
1084                                        [AC_MSG_RESULT([yes])
1085                                         NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1086                                        [AC_MSG_ERROR([could not compile test program either way])])])
1087   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1088
1089   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1090   NETWORK_LIBS=""
1091   AC_MSG_CHECKING([for res_query])
1092   AC_TRY_LINK([#include <sys/types.h>
1093                #include <netinet/in.h>
1094                #include <arpa/nameser.h>
1095                #include <resolv.h>
1096               ],[
1097                res_query("test", 0, 0, (void *)0, 0);
1098               ],[AC_MSG_RESULT([yes])],
1099               [save_libs="$LIBS"
1100                LIBS="-lresolv $LIBS"
1101                AC_TRY_LINK([#include <sys/types.h>
1102                             #include <netinet/in.h>
1103                             #include <arpa/nameser.h>
1104                             #include <resolv.h>
1105                            ],[
1106                             res_query("test", 0, 0, (void *)0, 0);
1107                            ],[AC_MSG_RESULT([in -lresolv])
1108                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1109                            [LIBS="-lbind $save_libs"
1110                             AC_TRY_LINK([#include <resolv.h>],
1111                                         [res_query("test", 0, 0, (void *)0, 0);],
1112                                         [AC_MSG_RESULT([in -lbind])
1113                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1114                                         [AC_MSG_ERROR(not found)])])
1115                LIBS="$save_libs"])
1116   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1117                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1118                                         [AC_MSG_ERROR(Could not find socket())]))
1119 ])
1120 AC_SUBST(NETWORK_LIBS)
1121
1122 AC_CHECK_HEADER([linux/netlink.h],
1123                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1124                 [#include <sys/socket.h>])
1125 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1126
1127 AC_CHECK_TYPE([struct ip_mreqn], [
1128               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1129               [#include <netinet/in.h>])
1130
1131 case $host in
1132   *-*-solaris* )
1133      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1134      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1135      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1136      ;;
1137 esac
1138
1139 dnl
1140 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1141 dnl
1142 AS_IF([test "$ac_cv_func_statfs" = yes], [
1143   AC_MSG_CHECKING([number of arguments to statfs()])
1144   AC_TRY_COMPILE([#include <unistd.h>
1145   #ifdef HAVE_SYS_PARAM_H
1146   #include <sys/param.h>
1147   #endif
1148   #ifdef HAVE_SYS_VFS_H
1149   #include <sys/vfs.h>
1150   #endif
1151   #ifdef HAVE_SYS_MOUNT_H
1152   #include <sys/mount.h>
1153   #endif
1154   #ifdef HAVE_SYS_STATFS_H
1155   #include <sys/statfs.h>
1156   #endif], [struct statfs st;
1157   statfs(NULL, &st);],[
1158     AC_MSG_RESULT([2])
1159     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1160     AC_TRY_COMPILE([#include <unistd.h>
1161   #ifdef HAVE_SYS_PARAM_H
1162   #include <sys/param.h>
1163   #endif
1164   #ifdef HAVE_SYS_VFS_H
1165   #include <sys/vfs.h>
1166   #endif
1167   #ifdef HAVE_SYS_MOUNT_H
1168   #include <sys/mount.h>
1169   #endif
1170   #ifdef HAVE_SYS_STATFS_H
1171   #include <sys/statfs.h>
1172   #endif], [struct statfs st;
1173   statfs(NULL, &st, sizeof (st), 0);],[
1174       AC_MSG_RESULT([4])
1175       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1176       AC_MSG_RESULT(unknown)
1177       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1178 ])
1179
1180 #
1181 # Check whether to use an included printf
1182 #
1183
1184 AC_ARG_ENABLE(included-printf,
1185               [AS_HELP_STRING([--enable-included-printf],
1186                               [use included printf [default=auto]])],
1187               enable_included_printf="$enableval")
1188
1189 need_included_printf=no
1190 if test "x$enable_included_printf" = "xyes" ; then
1191   need_included_printf=yes
1192 fi
1193 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1194   need_included_printf=yes
1195 fi
1196 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1197   need_included_printf=yes
1198 fi
1199 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1200    test -z "$glib_cv_long_long_format" ; then
1201   need_included_printf=yes
1202 fi
1203
1204 if test "x$enable_included_printf" = "xno" &&
1205    test "x$need_included_printf" = "xyes" ; then
1206   AC_MSG_ERROR([
1207 *** Your C library's printf doesn't appear to have the features that
1208 *** GLib needs, but you specified --enable-included-printf=no.])
1209 fi
1210
1211 enable_included_printf=$need_included_printf
1212
1213 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1214 AS_IF([test "$enable_included_printf" != "yes"], [
1215   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1216 ], [
1217   if test -z "$glib_cv_long_long_format" ; then
1218     glib_cv_long_long_format="ll"
1219   fi
1220   AC_DEFINE(HAVE_VASPRINTF,1)
1221 ])
1222
1223 # Checks needed for gnulib vasnprintf
1224 bh_C_SIGNED
1225 jm_AC_TYPE_LONG_LONG
1226 gt_TYPE_LONGDOUBLE
1227 gt_TYPE_WCHAR_T
1228 gt_TYPE_WINT_T
1229 AC_TYPE_SIZE_T
1230 AC_CHECK_TYPES(ptrdiff_t)
1231 jm_AC_TYPE_INTMAX_T
1232 AC_CHECK_FUNCS([snprintf wcslen])
1233 AC_FUNC_SNPRINTF_C99
1234
1235 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1236 # The check is borrowed from the PERL Configure script.
1237 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1238   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1239     glib_cv_working_bcopy,[AC_TRY_RUN([
1240       int main() {
1241         char buf[128], abc[128], *b;
1242         int len, off, align;
1243         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1244         for (align = 7; align >= 0; align--) {
1245           for (len = 36; len; len--) {
1246             b = buf+align; bcopy(abc, b, len);
1247             for (off = 1; off <= len; off++) {
1248               bcopy(b, b+off, len); bcopy(b+off, b, len);
1249                 if (bcmp(b, abc, len)) return(1);
1250             }
1251           }
1252         }
1253         return(0);
1254       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1255
1256   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1257   if test "$glib_cv_working_bcopy" = "yes"; then
1258     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1259   fi
1260 ])
1261
1262 # Check if <sys/select.h> needs to be included for fd_set
1263 AC_MSG_CHECKING([for fd_set])
1264 AC_TRY_COMPILE([#include <sys/types.h>],
1265         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1266 AS_IF([test "$gtk_ok" = "yes"], [
1267     AC_MSG_RESULT([yes, found in sys/types.h])
1268 ], [
1269     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1270     if test "$gtk_ok" = "yes"; then
1271         # *** FIXME: give it a different name
1272         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1273         AC_MSG_RESULT([yes, found in sys/select.h])
1274     else
1275         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1276         AC_MSG_RESULT(no)
1277     fi
1278 ])
1279
1280 dnl *** check for sane realloc() ***
1281 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1282         AC_TRY_RUN([#include <stdlib.h>
1283         int main() {
1284           return realloc (0, sizeof (int)) == 0;
1285         }],
1286         [glib_cv_sane_realloc=yes],
1287         [glib_cv_sane_realloc=no],
1288         [glib_cv_sane_realloc=yes])
1289 ])
1290 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1291   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1292 ])
1293
1294 dnl Check for nl_langinfo and CODESET
1295 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1296         AC_TRY_COMPILE([#include <langinfo.h>],
1297                 [char *codeset = nl_langinfo (CODESET);],
1298                 [glib_cv_langinfo_codeset=yes],
1299                 [glib_cv_langinfo_codeset=no])])
1300 if test x$glib_cv_langinfo_codeset = xyes; then
1301   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1302 fi
1303
1304 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1305 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1306         AC_TRY_COMPILE([#include <langinfo.h>],
1307                 [char *str;
1308                  str = nl_langinfo (PM_STR);
1309                  str = nl_langinfo (D_T_FMT);
1310                  str = nl_langinfo (D_FMT);
1311                  str = nl_langinfo (T_FMT);
1312                  str = nl_langinfo (T_FMT_AMPM);
1313                  str = nl_langinfo (MON_1);
1314                  str = nl_langinfo (ABMON_12);
1315                  str = nl_langinfo (DAY_1);
1316                  str = nl_langinfo (ABDAY_7);],
1317                 [glib_cv_langinfo_time=yes],
1318                 [glib_cv_langinfo_time=no])])
1319 if test x$glib_cv_langinfo_time = xyes; then
1320   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1321 fi
1322
1323 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1324 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1325         AC_TRY_COMPILE([#include <langinfo.h>],
1326                 [char *str;
1327                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1328                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1329                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1330                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1331                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1332                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1333                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1334                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1335                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1336                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1337                 [glib_cv_langinfo_outdigit=yes],
1338                 [glib_cv_langinfo_outdigit=no])])
1339 if test x$glib_cv_langinfo_outdigit = xyes; then
1340   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1341 fi
1342
1343 dnl ****************************************
1344 dnl *** posix_memalign                   ***
1345 dnl ****************************************
1346 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1347 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1348     glib_cv_compliant_posix_memalign=0
1349     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1350         AC_TRY_RUN([
1351                 #define _XOPEN_SOURCE 600
1352                 #include <stdlib.h> /* posix_memalign() should be defined here */
1353                 /* some systems break if #include <malloc.h> used */
1354                 static void test_memalign (size_t boundary, size_t size) {
1355                     void *mem = 0;
1356                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1357                         exit (1);
1358                     else
1359                       free (mem);
1360                 }
1361                 int main() {
1362                     test_memalign (  128,   128 - 2 * sizeof (void*));
1363                     test_memalign (  256,   256 - 2 * sizeof (void*));
1364                     test_memalign (  512,   512 - 2 * sizeof (void*));
1365                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1366                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1367                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1368                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1369                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1370                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1371                     exit (0); /* success */
1372                 }
1373                 ],
1374             [glib_cv_compliant_posix_memalign=1], [], [:])
1375       :
1376     fi
1377     ])
1378 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1379     AC_MSG_RESULT(yes)
1380     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1381 ], [
1382     AC_MSG_RESULT(no)
1383 ])
1384
1385
1386 dnl ****************************************
1387 dnl *** strlcpy/strlcat                  ***
1388 dnl ****************************************
1389 # Check for strlcpy
1390 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1391 AC_TRY_RUN([#include <stdlib.h>
1392 #include <string.h>
1393 int main() {
1394   char p[10];
1395   (void) strlcpy (p, "hi", 10);
1396   if (strlcat (p, "bye", 0) != 3)
1397     return 1;
1398   return 0;
1399 }], glib_cv_have_strlcpy=yes,
1400     glib_cv_have_strlcpy=no,
1401     glib_cv_have_strlcpy=no)])
1402 if test "$glib_cv_have_strlcpy" = "yes"; then
1403     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1404 fi
1405
1406
1407 dnl **********************
1408 dnl *** va_copy checks ***
1409 dnl **********************
1410 dnl we currently check for all three va_copy possibilities, so we get
1411 dnl all results in config.log for bug reports.
1412 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1413         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1414 #include <stdlib.h>
1415         void f (int i, ...) {
1416         va_list args1, args2;
1417         va_start (args1, i);
1418         va_copy (args2, args1);
1419         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1420           exit (1);
1421         va_end (args1); va_end (args2);
1422         }
1423         int main() {
1424           f (0, 42);
1425           return 0;
1426         }]])],
1427         [glib_cv_va_copy=yes],
1428         [glib_cv_va_copy=no])
1429 ])
1430 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1431         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1432 #include <stdlib.h>
1433         void f (int i, ...) {
1434         va_list args1, args2;
1435         va_start (args1, i);
1436         __va_copy (args2, args1);
1437         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1438           exit (1);
1439         va_end (args1); va_end (args2);
1440         }
1441         int main() {
1442           f (0, 42);
1443           return 0;
1444         }]])],
1445         [glib_cv___va_copy=yes],
1446         [glib_cv___va_copy=no])
1447 ])
1448
1449 if test "x$glib_cv_va_copy" = "xyes"; then
1450   g_va_copy_func=va_copy
1451 else if test "x$glib_cv___va_copy" = "xyes"; then
1452   g_va_copy_func=__va_copy
1453 fi
1454 fi
1455
1456 if test -n "$g_va_copy_func"; then
1457   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1458 fi
1459
1460 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1461         AC_TRY_RUN([#include <stdarg.h>
1462 #include <stdlib.h>
1463         void f (int i, ...) {
1464         va_list args1, args2;
1465         va_start (args1, i);
1466         args2 = args1;
1467         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1468           exit (1);
1469         va_end (args1); va_end (args2);
1470         }
1471         int main() {
1472           f (0, 42);
1473           return 0;
1474         }],
1475         [glib_cv_va_val_copy=yes],
1476         [glib_cv_va_val_copy=no],
1477         [glib_cv_va_val_copy=yes])
1478 ])
1479
1480 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1481   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1482 ])
1483
1484 dnl ***********************
1485 dnl *** g_module checks ***
1486 dnl ***********************
1487 G_MODULE_LIBS=
1488 G_MODULE_LIBS_EXTRA=
1489 G_MODULE_PLUGIN_LIBS=
1490 if test x"$glib_native_win32" = xyes; then
1491   dnl No use for this on Win32
1492   G_MODULE_LDFLAGS=
1493 else
1494   export SED
1495   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1496 fi
1497 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1498 G_MODULE_NEED_USCORE=0
1499 G_MODULE_BROKEN_RTLD_GLOBAL=0
1500 G_MODULE_HAVE_DLERROR=0
1501 dnl *** force native WIN32 shared lib loader
1502 if test -z "$G_MODULE_IMPL"; then
1503   case "$host" in
1504   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1505   esac
1506 fi
1507 dnl *** force native AIX library loader
1508 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1509 if test -z "$G_MODULE_IMPL"; then
1510   case "$host" in
1511   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1512   esac
1513 fi
1514 dnl *** dlopen() and dlsym() in system libraries
1515 AS_IF([ test -z "$G_MODULE_IMPL"], [
1516         AC_CHECK_FUNC(dlopen,
1517                       [AC_CHECK_FUNC(dlsym,
1518                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1519                       [])
1520 ])
1521 dnl *** load_image (BeOS)
1522 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1523   AC_CHECK_LIB(root, load_image,
1524       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1525       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1526       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1527       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1528       [])
1529 ])
1530 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1531 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1532         AC_CHECK_FUNC(NSLinkModule,
1533                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1534                        G_MODULE_NEED_USCORE=1],
1535                       [])
1536 ])
1537 dnl *** dlopen() and dlsym() in libdl
1538 AS_IF([ test -z "$G_MODULE_IMPL"], [
1539         AC_CHECK_LIB(dl, dlopen,
1540                      [AC_CHECK_LIB(dl, dlsym,
1541                                    [G_MODULE_LIBS=-ldl
1542                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1543                      [])
1544 ])
1545 dnl *** shl_load() in libdld (HP-UX)
1546 AS_IF([ test -z "$G_MODULE_IMPL"], [
1547         AC_CHECK_LIB(dld, shl_load,
1548                 [G_MODULE_LIBS=-ldld
1549                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1550                 [])
1551 ])
1552 dnl *** additional checks for G_MODULE_IMPL_DL
1553 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1554         LIBS_orig="$LIBS"
1555         LDFLAGS_orig="$LDFLAGS"
1556         LIBS="$G_MODULE_LIBS $LIBS"
1557         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1558 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1559         echo "void glib_plugin_test(void) { }" > plugin.c
1560         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1561                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1562         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1563                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1564                 -shrext ".o" -avoid-version plugin.lo \
1565                 -rpath /dont/care >/dev/null 2>&1
1566         eval `./libtool --config | grep ^objdir`
1567         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1568                 glib_cv_rtldglobal_broken,[
1569                 AC_TRY_RUN([
1570 #include <dlfcn.h>
1571 #ifndef RTLD_GLOBAL
1572 #  define RTLD_GLOBAL 0
1573 #endif
1574 #ifndef RTLD_LAZY
1575 #  define RTLD_LAZY 0
1576 #endif
1577 int glib_plugin_test;
1578 int main () {
1579     void *handle, *global, *local;
1580     global = &glib_plugin_test;
1581     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1582     if (!handle) return 0;
1583     local = dlsym (handle, "glib_plugin_test");
1584     return global == local;
1585 }                       ],
1586                         [glib_cv_rtldglobal_broken=no],
1587                         [glib_cv_rtldglobal_broken=yes],
1588                         [glib_cv_rtldglobal_broken=no])
1589                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1590                 rmdir ${objdir} 2>/dev/null
1591         ])
1592         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1593                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1594         else
1595                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1596         fi
1597 dnl *** check whether we need preceeding underscores
1598         AC_CACHE_CHECK([for preceeding underscore in symbols],
1599                 glib_cv_uscore,[
1600                 AC_TRY_RUN([#include <dlfcn.h>
1601                 int glib_underscore_test (void) { return 42; }
1602                 int main() {
1603                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1604                   handle = dlopen ((void*)0, 0);
1605                   if (handle) {
1606                     f1 = dlsym (handle, "glib_underscore_test");
1607                     f2 = dlsym (handle, "_glib_underscore_test");
1608                   } return (!f2 || f1);
1609                 }],
1610                         [glib_cv_uscore=yes],
1611                         [glib_cv_uscore=no],
1612                         [])
1613                 rm -f plugin.c plugin.$ac_objext plugin.lo
1614         ])
1615         GLIB_ASSERT_SET(glib_cv_uscore)
1616         if test "x$glib_cv_uscore" = "xyes"; then
1617                 G_MODULE_NEED_USCORE=1
1618         else
1619                 G_MODULE_NEED_USCORE=0
1620         fi
1621
1622         LDFLAGS="$LDFLAGS_orig"
1623 dnl *** check for having dlerror()
1624         AC_CHECK_FUNC(dlerror,
1625                 [G_MODULE_HAVE_DLERROR=1],
1626                 [G_MODULE_HAVE_DLERROR=0])
1627         LIBS="$LIBS_orig"
1628 ])
1629 dnl *** done, have we got an implementation?
1630 if test -z "$G_MODULE_IMPL"; then
1631         G_MODULE_IMPL=0
1632         G_MODULE_SUPPORTED=false
1633 else
1634         G_MODULE_SUPPORTED=true
1635 fi
1636
1637 AC_MSG_CHECKING(for the suffix of module shared libraries)
1638 export SED
1639 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1640 eval $shrext_cmds
1641 module=yes eval std_shrext=$shrext_cmds
1642 # chop the initial dot
1643 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1644 AC_MSG_RESULT(.$glib_gmodule_suffix)
1645 # any reason it may fail?
1646 if test "x$glib_gmodule_suffix" = x; then
1647         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1648 fi
1649
1650 AC_SUBST(G_MODULE_SUPPORTED)
1651 AC_SUBST(G_MODULE_IMPL)
1652 AC_SUBST(G_MODULE_LIBS)
1653 AC_SUBST(G_MODULE_LIBS_EXTRA)
1654 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1655 AC_SUBST(G_MODULE_LDFLAGS)
1656 AC_SUBST(G_MODULE_HAVE_DLERROR)
1657 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1658 AC_SUBST(G_MODULE_NEED_USCORE)
1659 AC_SUBST(GLIB_DEBUG_FLAGS)
1660
1661 dnl **********************
1662 dnl *** g_spawn checks ***
1663 dnl **********************
1664
1665 AC_MSG_CHECKING(for gspawn implementation)
1666 case "$host" in
1667   *-*-mingw*)
1668     GSPAWN=gspawn-win32.lo
1669     ;;
1670   *)
1671     GSPAWN=gspawn.lo
1672     ;;
1673 esac
1674 AC_MSG_RESULT($GSPAWN)
1675 AC_SUBST(GSPAWN)
1676
1677 dnl *************************
1678 dnl *** GIOChannel checks ***
1679 dnl *************************
1680
1681 AC_MSG_CHECKING(for GIOChannel implementation)
1682 case "$host" in
1683   *-*-mingw*)
1684     GIO=giowin32.lo
1685     ;;
1686   *)
1687     GIO=giounix.lo
1688     ;;
1689 esac
1690 AC_MSG_RESULT($GIO)
1691 AC_SUBST(GIO)
1692
1693 dnl *********************************
1694 dnl *** Directory for GIO modules ***
1695 dnl *********************************
1696
1697 AC_ARG_WITH(gio-module-dir,
1698            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1699                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1700            [],
1701            [with_gio_module_dir='${libdir}/gio/modules'])
1702 GIO_MODULE_DIR=$with_gio_module_dir
1703 AC_SUBST(GIO_MODULE_DIR)
1704
1705 dnl **********************************
1706 dnl *** Check for libselinux (GIO) ***
1707 dnl **********************************
1708 AC_ARG_ENABLE(selinux,
1709               AS_HELP_STRING([--disable-selinux],
1710                              [build without selinux support]))
1711 msg_selinux=no
1712 SELINUX_LIBS=
1713 AS_IF([ test "x$enable_selinux" != "xno"], [
1714
1715  AC_CHECK_LIB(selinux, is_selinux_enabled,
1716    [AC_CHECK_HEADERS(selinux/selinux.h,
1717      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1718        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1719         SELINUX_LIBS="-lselinux"
1720         msg_selinux=yes])
1721      ])
1722    ])
1723 ])
1724 AC_SUBST(SELINUX_LIBS)
1725
1726 dnl *****************************
1727 dnl ** Check for inotify (GIO) **
1728 dnl *****************************
1729 inotify_support=no
1730 AC_CHECK_HEADERS([sys/inotify.h],
1731 [
1732         inotify_support=yes
1733         AC_CHECK_FUNCS(inotify_init1)
1734 ])
1735
1736 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1737
1738 dnl ****************************
1739 dnl ** Check for kqueue (GIO) **
1740 dnl ****************************
1741 kqueue_support=no
1742 AC_CHECK_HEADERS([sys/event.h],
1743 [
1744         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1745 ])
1746
1747 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1748
1749 dnl *********************************
1750 dnl ** Check for Solaris FEN (GIO) **
1751 dnl *********************************
1752 fen_support=no
1753 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1754 #include <port.h>
1755 #ifndef PORT_SOURCE_FILE
1756 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1757 #endif
1758 int main() { return 0; } ]])],
1759 [
1760         fen_support=yes
1761 ],)
1762
1763 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1764
1765 dnl ****************************
1766 dnl *** Checks for FAM (GIO) ***
1767 dnl ****************************
1768
1769 should_disable_fam=no
1770
1771 AC_ARG_ENABLE(fam,
1772               AS_HELP_STRING([--disable-fam],
1773                              [don't use fam for file system monitoring]),
1774                          [
1775                                 if test "x$enable_fam" = "xno"; then
1776                                         should_disable_fam=yes
1777                                 fi
1778                          ]
1779                          )
1780 fam_support=no
1781 FAM_LIBS=
1782 if test "x$should_disable_fam" = "xno"; then
1783 AC_CHECK_LIB(fam, FAMOpen,
1784   [AC_CHECK_HEADERS(fam.h,
1785     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1786      AC_CHECK_LIB(fam, FAMNoExists,
1787                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1788      FAM_LIBS="-lfam"]
1789      fam_support=yes,
1790     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1791   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1792 AC_SUBST(FAM_LIBS)
1793 fi
1794 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1795
1796
1797 dnl *****************************
1798 dnl *** Check for xattr (GIO) ***
1799 dnl *****************************
1800 AC_ARG_ENABLE(xattr,
1801               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1802 msg_xattr=no
1803 XATTR_LIBS=
1804 AS_IF([ test "x$enable_xattr" != "xno"], [
1805
1806 dnl either glibc or libattr can provide xattr support
1807
1808 dnl for both of them, we check for getxattr being in
1809 dnl the library and a valid xattr header.
1810
1811 dnl try glibc
1812  AC_CHECK_LIB(c, getxattr,
1813    [AC_CHECK_HEADERS(sys/xattr.h,
1814      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1815       msg_xattr=yes])
1816    ])
1817
1818   AS_IF([ test "x$msg_xattr" != "xyes"], [
1819 dnl   failure. try libattr
1820    AC_CHECK_LIB(attr, getxattr,
1821       [AC_CHECK_HEADERS(attr/xattr.h,
1822        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1823         XATTR_LIBS="-lattr"
1824         msg_xattr=yes])
1825       ])
1826   ])
1827
1828   AS_IF([ test "x$msg_xattr" = "xyes"], [
1829     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1830     AC_TRY_COMPILE([
1831       #include <stdio.h>
1832       #ifdef HAVE_SYS_TYPES_H
1833       #include <sys/types.h>
1834       #endif
1835       #ifdef HAVE_SYS_XATTR_H
1836       #include <sys/xattr.h>
1837       #elif HAVE_ATTR_XATTR_H
1838       #include <attr/xattr.h>
1839       #endif
1840     ],
1841     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1842     [
1843       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1844       AC_MSG_RESULT([yes])
1845     ],
1846     [AC_MSG_RESULT([no])]
1847     )
1848   ])
1849 ])
1850 AC_SUBST(XATTR_LIBS)
1851
1852 dnl ************************
1853 dnl *** check for libelf ***
1854 dnl ************************
1855 AC_ARG_ENABLE(libelf,
1856               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1857 AS_IF([ test "x$enable_libelf" != "xno"],[
1858 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1859 AS_IF([ test $have_libelf = maybe ], [
1860   glib_save_LIBS=$LIBS
1861   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1862   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1863   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1864   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1865   LIBS=$glib_save_LIBS
1866
1867   if test $have_libelf != no; then
1868     LIBELF_LIBS=-lelf
1869     have_libelf=yes
1870   fi
1871 ])
1872 ])
1873
1874 if test x$have_libelf = xyes; then
1875   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1876 fi
1877
1878 dnl ****************************************
1879 dnl *** platform dependent source checks ***
1880 dnl ****************************************
1881
1882 AC_MSG_CHECKING(for platform-dependent source)
1883 case "$host" in
1884   *-*-cygwin*|*-*-mingw*)
1885     PLATFORMDEP=gwin32.lo
1886     ;;
1887   *)
1888     PLATFORMDEP=
1889     ;;
1890 esac
1891 AC_MSG_RESULT($PLATFORMDEP)
1892 AC_SUBST(PLATFORMDEP)
1893
1894 AC_MSG_CHECKING([whether to compile timeloop])
1895 case "$host" in
1896   *-*-cygwin*|*-*-mingw*|*-*-minix)
1897     enable_timeloop=no
1898     ;;
1899   *)
1900     enable_timeloop=yes
1901     ;;
1902 esac
1903 AC_MSG_RESULT($enable_timeloop)
1904 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1905
1906 AC_MSG_CHECKING([if building for some Win32 platform])
1907 case "$host" in
1908   *-*-mingw*|*-*-cygwin*)
1909     platform_win32=yes
1910     ;;
1911   *)
1912     platform_win32=no
1913     ;;
1914 esac
1915 AC_MSG_RESULT($platform_win32)
1916 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1917
1918 dnl ***********************
1919 dnl *** g_thread checks ***
1920 dnl ***********************
1921
1922 AC_ARG_WITH(threads,
1923            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1924                            [specify a thread implementation to use])],
1925            [],
1926            [with_threads=yes])
1927
1928 dnl error and warning message
1929 dnl *************************
1930
1931 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1932
1933 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1934                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1935                 compilation now, but then your programs might not work.
1936                 Please provide information on how it is done on your system."
1937
1938 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1939                  "
1940
1941 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1942                   provide information on your thread implementation."
1943
1944 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1945                 functions will not be MT-safe during their first call because
1946                 there is no working 'getpwuid_r' on your system."
1947
1948 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1949                 because there is no 'localtime_r' on your system."
1950
1951 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1952                 linking threaded applications. As GLib cannot do that
1953                 automatically, you will get an linkg error everytime you are
1954                 not using the right compiler. In that case you have to relink
1955                 with the right compiler. Ususally just '_r' is appended
1956                 to the compiler name."
1957
1958 dnl determination of thread implementation
1959 dnl ***************************************
1960
1961 AC_MSG_CHECKING(for thread implementation)
1962
1963 have_threads=no
1964 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1965         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1966         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1967         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1968         glib_save_CPPFLAGS="$CPPFLAGS"
1969         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1970         AS_IF([ test "x$have_threads" = xno], [
1971                 AC_TRY_COMPILE([#include <pthread.h>],
1972                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1973                         have_threads=posix)
1974         ])
1975         # Tru64Unix requires -pthread to find pthread.h. See #103020
1976         CPPFLAGS="$CPPFLAGS -pthread"
1977         if test "x$have_threads" = xno; then
1978         AC_TRY_COMPILE([#include <pthread.h>],
1979                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1980                        have_threads=posix)
1981         fi
1982         CPPFLAGS="$glib_save_CPPFLAGS"
1983 ])
1984 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1985         case $host in
1986                 *-*-mingw*)
1987                 have_threads=win32
1988                 ;;
1989         esac
1990 fi
1991
1992 if test "x$have_threads" = xno; then
1993         AC_MSG_RESULT(none available)
1994         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1995 else
1996         AC_MSG_RESULT($have_threads)
1997 fi
1998
1999
2000 dnl determination of G_THREAD_CFLAGS
2001 dnl ********************************
2002
2003 G_THREAD_LIBS=
2004 G_THREAD_LIBS_EXTRA=
2005 G_THREAD_CFLAGS=
2006
2007 dnl
2008 dnl Test program for basic POSIX threads functionality
2009 dnl
2010 m4_define([glib_thread_test],[
2011 #include <pthread.h>
2012 int check_me = 0;
2013 void* func(void* data) {check_me = 42; return &check_me;}
2014 int main()
2015  { pthread_t t;
2016    void *ret;
2017    pthread_create (&t, $1, func, 0);
2018    pthread_join (t, &ret);
2019    return (check_me != 42 || ret != &check_me);
2020 }])
2021
2022 AS_IF([ test x"$have_threads" = xposix], [
2023   # First we test for posix, whether -pthread or -pthreads do the trick as
2024   # both CPPFLAG and LIBS.
2025   # One of them does for most gcc versions and some other platforms/compilers
2026   # too and could be considered as the canonical way to go.
2027   case $host in
2028     *-*-cygwin*|*-*-darwin*)
2029        # skip cygwin and darwin -pthread or -pthreads test
2030        ;;
2031     *-solaris*)
2032       # These compiler/linker flags work with both Sun Studio and gcc
2033       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2034       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2035       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2036       G_THREAD_LIBS="-lpthread -lthread"
2037       ;;
2038     *)
2039       for flag in pthread pthreads mt; do
2040         glib_save_CFLAGS="$CFLAGS"
2041         CFLAGS="$CFLAGS -$flag"
2042         AC_TRY_RUN(glib_thread_test(0),
2043                    glib_flag_works=yes,
2044                    glib_flag_works=no,
2045                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2046                                    glib_flag_works=yes,
2047                                    glib_flag_works=no)])
2048         CFLAGS="$glib_save_CFLAGS"
2049         if test $glib_flag_works = yes ; then
2050            G_THREAD_CFLAGS=-$flag
2051         G_THREAD_LIBS=-$flag
2052         break;
2053         fi
2054       done
2055        ;;
2056   esac
2057 ])
2058
2059 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2060
2061   # The canonical -pthread[s] does not work. Try something different.
2062
2063   case $host in
2064         *-aix*)
2065                 if test x"$GCC" = xyes; then
2066                         # GCC 3.0 and above needs -pthread.
2067                         # Should be coverd by the case above.
2068                         # GCC 2.x and below needs -mthreads
2069                         G_THREAD_CFLAGS="-mthreads"
2070                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2071                 else
2072                         # We are probably using the aix compiler. Normaly a
2073                         # program would have to be compiled with the _r variant
2074                         # of the corresponding compiler, but we as GLib cannot
2075                         # do that: but the good news is that for compiling the
2076                         # only difference is the added -D_THREAD_SAFE compile
2077                         # option. This is according to the "C for AIX User's
2078                         # Guide".
2079                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2080                 fi
2081                 ;;
2082         *-dg-dgux*)  # DG/UX
2083                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2084                 ;;
2085         *-sysv5uw7*) # UnixWare 7
2086                 # We are not using gcc with -pthread. Catched above.
2087                 G_THREAD_CFLAGS="-Kthread"
2088                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2089                 ;;
2090         *-mingw*)
2091                 # No flag needed when using MSVCRT.DLL
2092                 G_THREAD_CFLAGS=""
2093                 ;;
2094         *)
2095                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2096                 ;;
2097   esac
2098 ])
2099
2100 # if we are not finding the localtime_r function, then we probably are
2101 # not using the proper multithread flag
2102
2103 glib_save_CPPFLAGS="$CPPFLAGS"
2104 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2105
2106 # First we test, whether localtime_r is declared in time.h
2107 # directly. Then we test whether a macro localtime_r exists, in
2108 # which case localtime_r in the test program is replaced and thus
2109 # if we still find localtime_r in the output, it is not defined as
2110 # a macro.
2111
2112 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2113   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2114                                                            localtime_r(a,b)],
2115                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2116
2117 CPPFLAGS="$glib_save_CPPFLAGS"
2118
2119 AC_MSG_CHECKING(thread related cflags)
2120 AC_MSG_RESULT($G_THREAD_CFLAGS)
2121 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2122
2123 dnl determination of G_THREAD_LIBS
2124 dnl ******************************
2125
2126 AS_IF([test x$have_threads = xposix], [
2127           glib_save_CPPFLAGS="$CPPFLAGS"
2128           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2129           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2130             case $host in
2131               *-aix*)
2132                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2133                 # probably using the aix compiler.
2134                 AC_MSG_WARN($AIX_COMPILE_INFO)
2135                 ;;
2136               *)
2137                 G_THREAD_LIBS=error
2138                 glib_save_LIBS="$LIBS"
2139                 for thread_lib in "" pthread pthread32 pthreads thread; do
2140                         if test x"$thread_lib" = x; then
2141                                 add_thread_lib=""
2142                                 IN=""
2143                         else
2144                                 add_thread_lib="-l$thread_lib"
2145                                 IN=" in -l$thread_lib"
2146                         fi
2147                         if test x"$have_threads" = xposix; then
2148                                 defattr=0
2149                         else
2150                                 defattr=pthread_attr_default
2151                         fi
2152
2153                         LIBS="$add_thread_lib $glib_save_LIBS"
2154
2155                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2156                         AC_TRY_RUN(glib_thread_test($defattr),
2157                                    glib_result=yes,
2158                                    glib_result=no,
2159                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2160                                                    glib_result=yes,
2161                                                    glib_result=no)])
2162                         AC_MSG_RESULT($glib_result)
2163
2164                         if test "$glib_result" = "yes" ; then
2165                           G_THREAD_LIBS="$add_thread_lib"
2166                           break
2167                         fi
2168                 done
2169                 if test "x$G_THREAD_LIBS" = xerror; then
2170                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2171                 fi
2172                 LIBS="$glib_save_LIBS"
2173                 ;;
2174             esac
2175           ])
2176
2177           g_threads_impl="POSIX"
2178           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2179           CPPFLAGS="$glib_save_CPPFLAGS"
2180 ], [test x$have_threads = xwin32], [
2181            g_threads_impl="WIN32"
2182 ], [
2183            g_threads_impl="NONE"
2184            G_THREAD_LIBS=error
2185 ])
2186
2187 if test "x$G_THREAD_LIBS" = xerror; then
2188         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2189 fi
2190
2191 case $host in
2192   *-*-beos*)
2193     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2194     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2195     ;;
2196   *)
2197     ;;
2198 esac
2199
2200 AC_MSG_CHECKING(thread related libraries)
2201 AC_MSG_RESULT($G_THREAD_LIBS)
2202
2203 dnl check for mt safe function variants and some posix functions
2204 dnl ************************************************************
2205
2206 glib_save_LIBS="$LIBS"
2207 # we are not doing the following for now, as this might require glib
2208 # to always be linked with the thread libs on some platforms.
2209 # LIBS="$LIBS $G_THREAD_LIBS"
2210 AC_CHECK_FUNCS(localtime_r gmtime_r)
2211 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2212         AC_CACHE_CHECK([for posix getpwuid_r],
2213                 ac_cv_func_posix_getpwuid_r,
2214                 [AC_TRY_RUN([
2215 #include <errno.h>
2216 #include <pwd.h>
2217 int main () {
2218     char buffer[10000];
2219     struct passwd pwd, *pwptr = &pwd;
2220     int error;
2221     errno = 0;
2222     error = getpwuid_r (0, &pwd, buffer,
2223                         sizeof (buffer), &pwptr);
2224    return (error < 0 && errno == ENOSYS)
2225            || error == ENOSYS;
2226 }                               ],
2227                         [ac_cv_func_posix_getpwuid_r=yes],
2228                         [ac_cv_func_posix_getpwuid_r=no])])
2229         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2230         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2231                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2232                         [Have POSIX function getpwuid_r])
2233         else
2234                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2235                         ac_cv_func_nonposix_getpwuid_r,
2236                         [AC_TRY_LINK([#include <pwd.h>],
2237                                 [char buffer[10000];
2238                                 struct passwd pwd;
2239                                 getpwuid_r (0, &pwd, buffer,
2240                                                 sizeof (buffer));],
2241                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2242                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2243                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2244                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2245                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2246                                 [Have non-POSIX function getpwuid_r])
2247                 fi
2248         fi
2249 ])
2250 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2251         AC_CACHE_CHECK([for posix getgrgid_r],
2252                 ac_cv_func_posix_getgrgid_r,
2253                 [AC_TRY_RUN([
2254 #include <errno.h>
2255 #include <grp.h>
2256 int main () {
2257     char buffer[10000];
2258     struct group grp, *grpptr = &grp;
2259     int error;
2260     errno = 0;
2261     error = getgrgid_r (0, &grp, buffer,
2262                         sizeof (buffer), &grpptr);
2263    return (error < 0 && errno == ENOSYS)
2264            || error == ENOSYS;
2265 }                              ],
2266                        [ac_cv_func_posix_getgrgid_r=yes],
2267                        [ac_cv_func_posix_getgrgid_r=no])])
2268         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2269         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2270                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2271                         [Have POSIX function getgrgid_r])
2272         ], [
2273                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2274                         ac_cv_func_nonposix_getgrgid_r,
2275                         [AC_TRY_LINK([#include <grp.h>],
2276                                 [char buffer[10000];
2277                                 struct group grp;
2278                                 getgrgid_r (0, &grp, buffer,
2279                                 sizeof (buffer));],
2280                         [ac_cv_func_nonposix_getgrgid_r=yes],
2281                         [ac_cv_func_nonposix_getgrgid_r=no])])
2282                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2283                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2284                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2285                                 [Have non-POSIX function getgrgid_r])
2286                 fi
2287         ])
2288 ])
2289 LIBS="$G_THREAD_LIBS $LIBS"
2290 AS_IF([ test x"$have_threads" = xposix], [
2291         glib_save_CPPFLAGS="$CPPFLAGS"
2292         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2293         # This is not AC_CHECK_FUNC to also work with function
2294         # name mangling in header files.
2295         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2296         AC_LINK_IFELSE(
2297             [AC_LANG_PROGRAM(
2298                 [#include <pthread.h>],
2299                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2300             [AC_MSG_RESULT(yes)
2301              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2302                 [Have function pthread_attr_setstacksize])],
2303             [AC_MSG_RESULT(no)])
2304         AC_MSG_CHECKING(for pthread_condattr_setclock)
2305         AC_LINK_IFELSE(
2306             [AC_LANG_PROGRAM(
2307                 [#include <pthread.h>],
2308                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2309             [AC_MSG_RESULT(yes)
2310              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2311                 [Have function pthread_condattr_setclock])],
2312             [AC_MSG_RESULT(no)])
2313         CPPFLAGS="$glib_save_CPPFLAGS"
2314 ])
2315
2316 LIBS="$glib_save_LIBS"
2317
2318 # now spit out all the warnings.
2319 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2320    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2321         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2322 fi
2323 if test "$ac_cv_func_localtime_r" != "yes"; then
2324         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2325 fi
2326
2327 #
2328 # Hack to deal with:
2329 #
2330 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2331 #     building shared libraries with linux.
2332 #  b) FreeBSD doesn't do this either.
2333 #
2334 case $host in
2335   *-*-freebsd*|*-*-linux*)
2336     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2337     ;;
2338   *-*-openbsd*)
2339     LDFLAGS="$LDFLAGS -pthread"
2340     ;;
2341   *)
2342     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2343     ;;
2344 esac
2345
2346 AC_SUBST(G_THREAD_CFLAGS)
2347 AC_SUBST(G_THREAD_LIBS)
2348 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2349 AC_SUBST(G_THREAD_LIBS_EXTRA)
2350
2351 AC_CHECK_FUNCS(clock_gettime, [], [
2352   AC_CHECK_LIB(rt, clock_gettime, [
2353     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2354     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2355     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2356   ])
2357 ])
2358
2359
2360 dnl ************************
2361 dnl *** g_atomic_* tests ***
2362 dnl ************************
2363
2364 dnl We need to decide at configure time if GLib will use real atomic
2365 dnl operations ("lock free") or emulated ones with a mutex.  This is
2366 dnl because we must put this information in glibconfig.h so we know if
2367 dnl it is safe or not to inline using compiler intrinsics directly from
2368 dnl the header.
2369 dnl
2370 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2371 dnl user is interested in knowing if they can use the atomic ops across
2372 dnl processes.
2373 dnl
2374 dnl We can currently support the atomic ops natively when building GLib
2375 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2376 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2377 dnl we are using GCC.
2378 dnl
2379 dnl Note that the atomic ops are only available with GCC on x86 when
2380 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2381 dnl not available but would be available given the right flags, we want
2382 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2383 dnl that then to silently fall back on emulated atomic ops just because
2384 dnl the user had the wrong build environment.
2385
2386 dnl We may add other compilers here in the future...
2387
2388 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2389   AC_TRY_COMPILE([],
2390                  [volatile int atomic = 2;\
2391                   __sync_bool_compare_and_swap (&atomic, 2, 3);],
2392                  [glib_cv_g_atomic_lock_free=yes],
2393                  [glib_cv_g_atomic_lock_free=no])])
2394
2395 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2396   SAVE_CFLAGS="${CFLAGS}"
2397   CFLAGS="-march=i486"
2398   AC_TRY_COMPILE([],
2399                  [volatile int atomic = 2;\
2400                   __sync_bool_compare_and_swap (&atomic, 2, 3);],
2401                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2402                  [])
2403   CFLAGS="${SAVE_CFLAGS}"
2404 fi
2405
2406 # Some compilers support atomic operations but do not define
2407 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2408 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2409   AC_TRY_COMPILE([],
2410                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2411                  [],
2412                  [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2413 fi
2414
2415 dnl We need a more robust approach here...
2416 case $host_cpu in
2417   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2418     glib_memory_barrier_needed=no
2419     ;;
2420   sparc*|alpha*|powerpc*|ia64)
2421     glib_memory_barrier_needed=yes
2422     ;;
2423   *)
2424     glib_memory_barrier_needed=yes
2425     ;;
2426 esac
2427
2428 dnl ************************
2429 dnl ** Check for futex(2) **
2430 dnl ************************
2431 AC_CACHE_CHECK(for futex(2) system call,
2432     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2433 #include <linux/futex.h>
2434 #include <sys/syscall.h>
2435 #include <unistd.h>
2436 ],[
2437 int
2438 main (void)
2439 {
2440   /* it is not like this actually runs or anything... */
2441   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2442   return 0;
2443 }
2444 ])],glib_cv_futex=yes,glib_cv_futex=no))
2445 if test x"$glib_cv_futex" = xyes; then
2446   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2447 fi
2448
2449 AC_CACHE_CHECK(for eventfd(2) system call,
2450     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2451 #include <sys/eventfd.h>
2452 #include <unistd.h>
2453 ],[
2454 int
2455 main (void)
2456 {
2457   eventfd (0, EFD_CLOEXEC);
2458   return 0;
2459 }
2460 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2461 if test x"$glib_cv_eventfd" = x"yes"; then
2462   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2463 fi
2464 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2465
2466 dnl ****************************************
2467 dnl *** GLib POLL* compatibility defines ***
2468 dnl ****************************************
2469
2470 glib_poll_includes=["
2471 #include <sys/types.h>
2472 #include <sys/poll.h>
2473 "]
2474
2475 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2476    test $ac_cv_header_sys_poll_h = yes ], [
2477   glib_failed=false
2478   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2479   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2480   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2481   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2482   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2483   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2484   if $glib_failed ; then
2485     AC_MSG_ERROR([Could not determine values for POLL* constants])
2486   fi
2487 ], [
2488   glib_cv_value_POLLIN=1
2489   glib_cv_value_POLLOUT=4
2490   glib_cv_value_POLLPRI=2
2491   glib_cv_value_POLLERR=8
2492   glib_cv_value_POLLHUP=16
2493   glib_cv_value_POLLNVAL=32
2494 ])
2495
2496 AC_MSG_CHECKING([for broken poll])
2497 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2498         #include <stdlib.h>
2499         #include <fcntl.h>
2500         #include <poll.h>
2501         #ifdef HAVE_SYS_POLL_H
2502         #include <sys/poll.h>
2503         #endif
2504         int main(void) {
2505           struct pollfd fds[1];
2506           int fd;
2507           fd = open("/dev/null", 1);
2508           fds[0].fd = fd;
2509           fds[0].events = POLLIN;
2510           fds[0].revents = 0;
2511           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2512                 exit(1);  /* Does not work for devices -- fail */
2513           }
2514           exit(0);
2515         }]])],
2516   [broken_poll=no],
2517   [broken_poll=yes
2518    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2519   [broken_poll="no (cross compiling)"])
2520 AC_MSG_RESULT($broken_poll)
2521
2522 dnl *********************
2523 dnl *** GRegex checks ***
2524 dnl *********************
2525
2526 PCRE_REQUIRED_VERSION=8.13
2527
2528 # Check if we should use the internal or the system-supplied pcre
2529 AC_ARG_WITH(pcre,
2530             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2531                             [whether to use system PCRE [default=internal]])])
2532
2533 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2534
2535 AS_IF([ test "x$with_pcre" = xsystem], [
2536   PKG_CHECK_MODULES(PCRE,
2537                     libpcre >= $PCRE_REQUIRED_VERSION)
2538   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2539                   glib_save_CFLAGS="$CFLAGS"
2540                   glib_save_LIBS="$LIBS"
2541                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2542                   AC_TRY_RUN([#include <pcre.h>
2543                               int main () {
2544                                 int support;
2545                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2546                                 if (!support)
2547                                   return 1;
2548                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2549                                 if (!support)
2550                                   return 1;
2551                                 return 0;
2552                               }],
2553                   glib_cv_pcre_has_unicode=yes,
2554                   glib_cv_pcre_has_unicode=no,
2555                   glib_cv_pcre_has_unicode=yes)
2556                   CFLAGS="$glib_save_CFLAGS"
2557                   LIBS="$glib_save_LIBS"
2558       ])
2559   if test "$glib_cv_pcre_has_unicode" = "no"; then
2560     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2561   fi
2562   AC_SUBST(PCRE_CFLAGS)
2563   AC_SUBST(PCRE_LIBS)
2564   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2565   PCRE_REQUIRES=libpcre
2566   AC_SUBST(PCRE_REQUIRES)
2567 ], [
2568   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2569   AS_IF([ test x"$GCC" = xyes], [
2570     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2571     save_CFLAGS="$CFLAGS"
2572     CFLAGS="$CFLAGS -Wno-pointer-sign"
2573     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2574                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2575     CFLAGS="$save_CFLAGS"
2576   ])
2577 ])
2578 AC_SUBST(PCRE_WARN_CFLAGS)
2579
2580 dnl **********************
2581 dnl *** Win32 API libs ***
2582 dnl **********************
2583
2584 case $host in
2585   *-*-cygwin*)
2586         G_LIBS_EXTRA="-luser32 -lkernel32"
2587     ;;
2588   *-*-mingw*)
2589         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2590     ;;
2591   *)
2592         G_LIBS_EXTRA=""
2593     ;;
2594 esac
2595 AC_SUBST(G_LIBS_EXTRA)
2596
2597 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2598 dnl since we need it for g_iconv()
2599
2600 AC_MSG_CHECKING([for EILSEQ])
2601 AC_TRY_COMPILE([
2602 #include <errno.h>
2603 ],
2604 [
2605 int error = EILSEQ;
2606 ], have_eilseq=yes, have_eilseq=no);
2607 AC_MSG_RESULT($have_eilseq)
2608
2609 dnl ******************************************************************
2610 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2611 dnl *** glib-compile-schemas in PATH                               ***
2612 dnl ******************************************************************
2613
2614 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2615
2616 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2617   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2618   if test x$GLIB_GENMARSHAL = xno; then
2619     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2620   fi
2621
2622   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2623   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2624     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2625   fi
2626
2627   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2628   if test x$GLIB_COMPILE_RESOURCES = xno; then
2629     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2630   fi
2631 ])
2632
2633 dnl **************************
2634 dnl *** Checks for gtk-doc ***
2635 dnl **************************
2636 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2637 # it on it's own line.
2638 m4_ifdef([GTK_DOC_CHECK], [
2639 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2640 ],[
2641 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2642 ])
2643
2644 AC_ARG_ENABLE(man,
2645               [AS_HELP_STRING([--enable-man],
2646                               [generate man pages [default=auto]])],,
2647               enable_man=maybe)
2648
2649 AS_IF([test "$enable_man" != no], [
2650   AC_PATH_PROG([XSLTPROC], [xsltproc])
2651   AS_IF([test -z "$XSLTPROC"], [
2652     AS_IF([test "$enable_man" = yes], [
2653       AC_MSG_ERROR([xsltproc is required for --enable-man])
2654     ])
2655     enable_man=no
2656   ])
2657 ])
2658
2659 AS_IF([ test "$enable_man" != no ], [
2660   dnl check for DocBook DTD in the local catalog
2661   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2662      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2663   AS_IF([test "$have_docbook_dtd" != yes], [
2664     AS_IF([test "$enable_man" = yes ], [
2665       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2666     ])
2667     enable_man=no
2668   ])
2669 ])
2670
2671 AS_IF([test "$enable_man" != no], [
2672   dnl check for DocBook XSL stylesheets in the local catalog
2673   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2674      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2675   AS_IF([ test "$have_docbook_dtd" != yes ], [
2676     AS_IF([ test "$enable_man" = yes ], [
2677       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2678     ])
2679     enable_man=no
2680   ])
2681 ])
2682
2683 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2684
2685 AC_MSG_CHECKING([whether to generate man pages])
2686 AS_IF([ test "$enable_man" != no ], [
2687   AC_MSG_RESULT([yes])
2688 ], [
2689   AC_MSG_RESULT([no])
2690 ])
2691
2692 dnl
2693 dnl Tracing
2694 dnl
2695
2696 AC_ARG_ENABLE([dtrace],
2697              [AS_HELP_STRING([--enable-dtrace],
2698                               [include tracing support for dtrace])])
2699 have_dtrace=no
2700 AC_MSG_CHECKING([whether to include dtrace tracing support])
2701 AS_IF([ test "x$enable_dtrace" != xno], [
2702   if test x$glib_have_carbon = xyes; then
2703     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2704   else
2705     AC_MSG_RESULT([yes])
2706     AC_CHECK_PROGS(DTRACE, dtrace)
2707     if test -z "$DTRACE"; then
2708       if test "x$enable_dtrace" = xyes; then
2709         AC_MSG_ERROR([dtrace not found])
2710       fi
2711     else
2712       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2713                       [if test "x$enable_dtrace" = xyes; then
2714                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2715                        fi])
2716     fi
2717   fi
2718 ], [
2719   AC_MSG_RESULT([no])
2720 ])
2721 if test "x$have_dtrace" = xyes; then
2722   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2723 fi
2724 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2725
2726 AC_MSG_CHECKING([whether to include systemtap tracing support])
2727 AC_ARG_ENABLE([systemtap],
2728              [AS_HELP_STRING([--enable-systemtap],
2729                               [include tracing support for systemtap])])
2730 have_systemtap=no
2731 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2732   have_systemtap=yes
2733 fi
2734 AC_MSG_RESULT(${have_systemtap})
2735
2736 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2737
2738 AC_ARG_WITH([tapset-install-dir],
2739             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2740                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2741             [if test "x${withval}" = x; then
2742                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2743              else
2744                ABS_TAPSET_DIR="${withval}"
2745               fi],
2746             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2747 AC_SUBST(ABS_TAPSET_DIR)
2748
2749 dnl ************************************
2750 dnl *** Enable lcov coverage reports ***
2751 dnl ************************************
2752
2753 AC_ARG_ENABLE(gcov,
2754   AS_HELP_STRING([--enable-gcov],
2755                  [enable coverage testing with gcov]),
2756   [use_gcov=$enableval], [use_gcov=no])
2757
2758 AS_IF([ test "x$use_gcov" = "xyes"], [
2759   dnl we need gcc:
2760   if test "$GCC" != "yes"; then
2761     AC_MSG_ERROR([GCC is required for --enable-gcov])
2762   fi
2763
2764   dnl Check if ccache is being used
2765   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2766   case `$SHTOOL path $CC` in
2767     *ccache*[)] gcc_ccache=yes;;
2768     *[)] gcc_ccache=no;;
2769   esac
2770
2771   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2772     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2773   fi
2774
2775   ltp_version_list="1.6 1.7 1.8 1.9"
2776   AC_CHECK_PROG(LTP, lcov, lcov)
2777   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2778
2779   AS_IF([ test "$LTP" ], [
2780     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2781       glib_cv_ltp_version=invalid
2782       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2783       for ltp_check_version in $ltp_version_list; do
2784         if test "$ltp_version" = "$ltp_check_version"; then
2785           glib_cv_ltp_version="$ltp_check_version (ok)"
2786         fi
2787       done
2788     ])
2789   ], [
2790     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2791     AC_MSG_ERROR([$ltp_msg])
2792   ])
2793
2794   case $glib_cv_ltp_version in
2795     ""|invalid[)]
2796       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2797       AC_MSG_ERROR([$ltp_msg])
2798       LTP="exit 0;"
2799       ;;
2800   esac
2801
2802   if test -z "$LTP_GENHTML"; then
2803     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2804   fi
2805
2806   dnl Remove all optimization flags from CFLAGS
2807   changequote({,})
2808   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2809   changequote([,])
2810
2811   dnl Add the special gcc flags
2812   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2813   LDFLAGS="$LDFLAGS -lgcov"
2814 ])
2815
2816 dnl ******************************
2817 dnl *** output the whole stuff ***
2818 dnl ******************************
2819
2820 dnl this section will only be run if config.status is invoked with no
2821 dnl arguments, or with "glib/glibconfig.h" as an argument.
2822 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2823 [
2824         outfile=glib/glibconfig.h-tmp
2825         cat > $outfile <<\_______EOF
2826 /* glibconfig.h
2827  *
2828  * This is a generated file.  Please modify 'configure.ac'
2829  */
2830
2831 #ifndef __GLIBCONFIG_H__
2832 #define __GLIBCONFIG_H__
2833
2834 #include <glib/gmacros.h>
2835
2836 _______EOF
2837
2838         if test x$glib_limits_h = xyes; then
2839           echo '#include <limits.h>' >> $outfile
2840         fi
2841         if test x$glib_float_h = xyes; then
2842           echo '#include <float.h>' >> $outfile
2843         fi
2844         if test x$glib_values_h = xyes; then
2845           echo '#include <values.h>' >> $outfile
2846         fi
2847         if test "$glib_header_alloca_h" = "yes"; then
2848           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2849         fi
2850         if test x$glib_sys_poll_h = xyes; then
2851           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2852         fi
2853         if test x$glib_included_printf != xyes; then
2854           echo "
2855 /* Specifies that GLib's g_print*() functions wrap the
2856  * system printf functions.  This is useful to know, for example,
2857  * when using glibc's register_printf_function().
2858  */" >> $outfile
2859           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2860         fi
2861
2862         cat >> $outfile <<_______EOF
2863
2864 G_BEGIN_DECLS
2865
2866 #define G_MINFLOAT      $glib_mf
2867 #define G_MAXFLOAT      $glib_Mf
2868 #define G_MINDOUBLE     $glib_md
2869 #define G_MAXDOUBLE     $glib_Md
2870 #define G_MINSHORT      $glib_ms
2871 #define G_MAXSHORT      $glib_Ms
2872 #define G_MAXUSHORT     $glib_Mus
2873 #define G_MININT        $glib_mi
2874 #define G_MAXINT        $glib_Mi
2875 #define G_MAXUINT       $glib_Mui
2876 #define G_MINLONG       $glib_ml
2877 #define G_MAXLONG       $glib_Ml
2878 #define G_MAXULONG      $glib_Mul
2879
2880 _______EOF
2881
2882
2883         ### this should always be true in a modern C/C++ compiler
2884         cat >>$outfile <<_______EOF
2885 typedef signed char gint8;
2886 typedef unsigned char guint8;
2887 _______EOF
2888
2889
2890         if test -n "$gint16"; then
2891           cat >>$outfile <<_______EOF
2892 typedef signed $gint16 gint16;
2893 typedef unsigned $gint16 guint16;
2894 #define G_GINT16_MODIFIER $gint16_modifier
2895 #define G_GINT16_FORMAT $gint16_format
2896 #define G_GUINT16_FORMAT $guint16_format
2897 _______EOF
2898         fi
2899
2900
2901         if test -n "$gint32"; then
2902           cat >>$outfile <<_______EOF
2903 typedef signed $gint32 gint32;
2904 typedef unsigned $gint32 guint32;
2905 #define G_GINT32_MODIFIER $gint32_modifier
2906 #define G_GINT32_FORMAT $gint32_format
2907 #define G_GUINT32_FORMAT $guint32_format
2908 _______EOF
2909         fi
2910
2911         cat >>$outfile <<_______EOF
2912 #define G_HAVE_GINT64 1          /* deprecated, always true */
2913
2914 ${glib_extension}typedef signed $gint64 gint64;
2915 ${glib_extension}typedef unsigned $gint64 guint64;
2916
2917 #define G_GINT64_CONSTANT(val)  $gint64_constant
2918 #define G_GUINT64_CONSTANT(val) $guint64_constant
2919 _______EOF
2920
2921         if test x$gint64_format != x ; then
2922           cat >>$outfile <<_______EOF
2923 #define G_GINT64_MODIFIER $gint64_modifier
2924 #define G_GINT64_FORMAT $gint64_format
2925 #define G_GUINT64_FORMAT $guint64_format
2926 _______EOF
2927         else
2928           cat >>$outfile <<_______EOF
2929 #undef G_GINT64_MODIFIER
2930 #undef G_GINT64_FORMAT
2931 #undef G_GUINT64_FORMAT
2932 _______EOF
2933         fi
2934
2935         cat >>$outfile <<_______EOF
2936
2937 #define GLIB_SIZEOF_VOID_P $glib_void_p
2938 #define GLIB_SIZEOF_LONG   $glib_long
2939 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2940
2941 _______EOF
2942
2943         cat >>$outfile <<_______EOF
2944 typedef signed $glib_size_type_define gssize;
2945 typedef unsigned $glib_size_type_define gsize;
2946 #define G_GSIZE_MODIFIER $gsize_modifier
2947 #define G_GSSIZE_FORMAT $gssize_format
2948 #define G_GSIZE_FORMAT $gsize_format
2949
2950 #define G_MAXSIZE       G_MAXU$glib_msize_type
2951 #define G_MINSSIZE      G_MIN$glib_msize_type
2952 #define G_MAXSSIZE      G_MAX$glib_msize_type
2953
2954 typedef gint64 goffset;
2955 #define G_MINOFFSET     G_MININT64
2956 #define G_MAXOFFSET     G_MAXINT64
2957
2958 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2959 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2960 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2961
2962 _______EOF
2963
2964         if test -z "$glib_unknown_void_p"; then
2965           cat >>$outfile <<_______EOF
2966
2967 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2968 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2969
2970 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2971 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2972
2973 typedef signed $glib_intptr_type_define gintptr;
2974 typedef unsigned $glib_intptr_type_define guintptr;
2975
2976 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2977 #define G_GINTPTR_FORMAT        $gintptr_format
2978 #define G_GUINTPTR_FORMAT       $guintptr_format
2979 _______EOF
2980         else
2981           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2982         fi
2983
2984
2985
2986         cat >>$outfile <<_______EOF
2987 $glib_atexit
2988 $glib_memmove
2989 $glib_defines
2990 $glib_os
2991 $glib_static_compilation
2992
2993 $glib_vacopy
2994
2995 #ifdef  __cplusplus
2996 #define G_HAVE_INLINE   1
2997 #else   /* !__cplusplus */
2998 $glib_inline
2999 #endif  /* !__cplusplus */
3000
3001 #ifdef  __cplusplus
3002 #define G_CAN_INLINE    1
3003 _______EOF
3004
3005         if test x$g_can_inline = xyes ; then
3006                 cat >>$outfile <<_______EOF
3007 #else   /* !__cplusplus */
3008 #define G_CAN_INLINE    1
3009 _______EOF
3010         fi
3011
3012         cat >>$outfile <<_______EOF
3013 #endif
3014
3015 _______EOF
3016
3017         if test x$g_have_iso_c_varargs = xyes ; then
3018                 cat >>$outfile <<_______EOF
3019 #ifndef __cplusplus
3020 # define G_HAVE_ISO_VARARGS 1
3021 #endif
3022 _______EOF
3023         fi
3024         if test x$g_have_iso_cxx_varargs = xyes ; then
3025                 cat >>$outfile <<_______EOF
3026 #ifdef __cplusplus
3027 # define G_HAVE_ISO_VARARGS 1
3028 #endif
3029 _______EOF
3030         fi
3031         if test x$g_have_gnuc_varargs = xyes ; then
3032                 cat >>$outfile <<_______EOF
3033
3034 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3035  * is passed ISO vararg support is turned off, and there is no work
3036  * around to turn it on, so we unconditionally turn it off.
3037  */
3038 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3039 #  undef G_HAVE_ISO_VARARGS
3040 #endif
3041
3042 #define G_HAVE_GNUC_VARARGS 1
3043 _______EOF
3044         fi
3045
3046         case x$g_stack_grows in
3047         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3048         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3049         esac
3050
3051
3052         echo >>$outfile
3053         if test x$g_have_eilseq = xno; then
3054                 cat >>$outfile <<_______EOF
3055 #ifndef EILSEQ
3056 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3057  * The correspondence between this and the corresponding definition
3058  * in libiconv is essential.
3059  */
3060 #  define EILSEQ ENOENT
3061 #endif
3062 _______EOF
3063
3064         fi
3065
3066         if test x$g_have_gnuc_visibility = xyes; then
3067                 cat >>$outfile <<_______EOF
3068 #define G_HAVE_GNUC_VISIBILITY 1
3069 _______EOF
3070         fi
3071                 cat >>$outfile <<_______EOF
3072 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3073 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3074 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3075 #define G_GNUC_INTERNAL __hidden
3076 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3077 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3078 #else
3079 #define G_GNUC_INTERNAL
3080 #endif
3081 _______EOF
3082
3083         echo >>$outfile
3084         cat >>$outfile <<_______EOF
3085 #define G_THREADS_ENABLED
3086 #define G_THREADS_IMPL_$g_threads_impl_def
3087 _______EOF
3088
3089         if test x"$g_memory_barrier_needed" != xno; then
3090           echo >>$outfile
3091           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3092         fi
3093         if test x"$g_atomic_lock_free" = xyes; then
3094           echo >>$outfile
3095           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3096         fi
3097         echo >>$outfile
3098         g_bit_sizes="16 32 64"
3099         for bits in $g_bit_sizes; do
3100           cat >>$outfile <<_______EOF
3101 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3102 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3103 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3104 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3105 _______EOF
3106         done
3107
3108         cat >>$outfile <<_______EOF
3109 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3110 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3111 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3112 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3113 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3114 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3115 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3116 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3117 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3118 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3119 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3120 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3121 #define G_BYTE_ORDER $g_byte_order
3122
3123 #define GLIB_SYSDEF_POLLIN =$g_pollin
3124 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3125 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3126 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3127 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3128 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3129
3130 #define G_MODULE_SUFFIX "$g_module_suffix"
3131
3132 typedef $g_pid_type GPid;
3133
3134 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3135 #define GLIB_SYSDEF_AF_INET $g_af_inet
3136 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3137
3138 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3139 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3140 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3141
3142 G_END_DECLS
3143
3144 #endif /* __GLIBCONFIG_H__ */
3145 _______EOF
3146
3147
3148         if cmp -s $outfile glib/glibconfig.h; then
3149           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3150           rm -f $outfile
3151         else
3152           mv $outfile glib/glibconfig.h
3153         fi
3154 ],[
3155
3156 # Note that if two cases are the same, case goes with the first one.
3157 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3158 # on variable expansion in case labels.  Look at the generated config.status
3159 # for a hint.
3160
3161 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3162   glib_header_alloca_h="$ac_cv_working_alloca_h"
3163 else
3164   glib_header_alloca_h="$ac_cv_header_alloca_h"
3165 fi
3166
3167 case xyes in
3168 x$ac_cv_header_float_h)
3169   glib_float_h=yes
3170   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3171   glib_md=DBL_MIN glib_Md=DBL_MAX
3172   ;;
3173 x$ac_cv_header_values_h)
3174   glib_values_h=yes
3175   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3176   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3177   ;;
3178 esac
3179
3180 case xyes in
3181 x$ac_cv_header_limits_h)
3182   glib_limits_h=yes
3183   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3184   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3185   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3186   ;;
3187 x$ac_cv_header_values_h)
3188   glib_values_h=yes
3189   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3190   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3191   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3192   ;;
3193 esac
3194
3195 if test x$ac_cv_header_sys_poll_h = xyes ; then
3196   glib_sys_poll_h=yes
3197 fi
3198
3199 if test x$enable_included_printf = xyes ; then
3200   glib_included_printf=yes
3201 fi
3202
3203 case 2 in
3204 $ac_cv_sizeof_short)
3205   gint16=short
3206   gint16_modifier='"h"'
3207   gint16_format='"hi"'
3208   guint16_format='"hu"'
3209   ;;
3210 $ac_cv_sizeof_int)
3211   gint16=int
3212   gint16_modifier='""'
3213   gint16_format='"i"'
3214   guint16_format='"u"'
3215   ;;
3216 esac
3217 case 4 in
3218 $ac_cv_sizeof_short)
3219   gint32=short
3220   gint32_modifier='"h"'
3221   gint32_format='"hi"'
3222   guint32_format='"hu"'
3223   ;;
3224 $ac_cv_sizeof_int)
3225   gint32=int
3226   gint32_modifier='""'
3227   gint32_format='"i"'
3228   guint32_format='"u"'
3229   ;;
3230 $ac_cv_sizeof_long)
3231   gint32=long
3232   gint32_modifier='"l"'
3233   gint32_format='"li"'
3234   guint32_format='"lu"'
3235   ;;
3236 esac
3237 case 8 in
3238 $ac_cv_sizeof_int)
3239   gint64=int
3240   gint64_modifier='""'
3241   gint64_format='"i"'
3242   guint64_format='"u"'
3243   glib_extension=
3244   gint64_constant='(val)'
3245   guint64_constant='(val)'
3246   ;;
3247 $ac_cv_sizeof_long)
3248   gint64=long
3249   gint64_modifier='"l"'
3250   gint64_format='"li"'
3251   guint64_format='"lu"'
3252   glib_extension=
3253   gint64_constant='(val##L)'
3254   guint64_constant='(val##UL)'
3255   ;;
3256 $ac_cv_sizeof_long_long)
3257   gint64='long long'
3258   if test -n "$glib_cv_long_long_format"; then
3259     gint64_modifier='"'$glib_cv_long_long_format'"'
3260     gint64_format='"'$glib_cv_long_long_format'i"'
3261     guint64_format='"'$glib_cv_long_long_format'u"'
3262   fi
3263   glib_extension='G_GNUC_EXTENSION '
3264   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3265   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3266   ;;
3267 $ac_cv_sizeof___int64)
3268   gint64='__int64'
3269   if test -n "$glib_cv_long_long_format"; then
3270     gint64_modifier='"'$glib_cv_long_long_format'"'
3271     gint64_format='"'$glib_cv_long_long_format'i"'
3272     guint64_format='"'$glib_cv_long_long_format'u"'
3273   fi
3274   glib_extension=
3275   gint64_constant='(val##i64)'
3276   guint64_constant='(val##ui64)'
3277   ;;
3278 esac
3279 glib_size_t=$ac_cv_sizeof_size_t
3280 glib_size_type_define="$glib_size_type"
3281 glib_void_p=$ac_cv_sizeof_void_p
3282 glib_long=$ac_cv_sizeof_long
3283
3284 case "$glib_size_type" in
3285 short)
3286   gsize_modifier='"h"'
3287   gsize_format='"hu"'
3288   gssize_format='"hi"'
3289   glib_msize_type='SHRT'
3290   ;;
3291 int)
3292   gsize_modifier='""'
3293   gsize_format='"u"'
3294   gssize_format='"i"'
3295   glib_msize_type='INT'
3296   ;;
3297 long)
3298   gsize_modifier='"l"'
3299   gsize_format='"lu"'
3300   gssize_format='"li"'
3301   glib_msize_type='LONG'
3302   ;;
3303 "long long"|__int64)
3304   gsize_modifier='"I64"'
3305   gsize_format='"I64u"'
3306   gssize_format='"I64i"'
3307   glib_msize_type='INT64'
3308   ;;
3309 esac
3310
3311 gintbits=`expr $ac_cv_sizeof_int \* 8`
3312 glongbits=`expr $ac_cv_sizeof_long \* 8`
3313 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3314
3315 case $ac_cv_sizeof_void_p in
3316 $ac_cv_sizeof_int)
3317   glib_intptr_type_define=int
3318   gintptr_modifier='""'
3319   gintptr_format='"i"'
3320   guintptr_format='"u"'
3321   glib_gpi_cast='(gint)'
3322   glib_gpui_cast='(guint)'
3323   ;;
3324 $ac_cv_sizeof_long)
3325   glib_intptr_type_define=long
3326   gintptr_modifier='"l"'
3327   gintptr_format='"li"'
3328   guintptr_format='"lu"'
3329   glib_gpi_cast='(glong)'
3330   glib_gpui_cast='(gulong)'
3331   ;;
3332 $ac_cv_sizeof_long_long)
3333   glib_intptr_type_define='long long'
3334   gintptr_modifier='"I64"'
3335   gintptr_format='"I64i"'
3336   guintptr_format='"I64u"'
3337   glib_gpi_cast='(gint64)'
3338   glib_gpui_cast='(guint64)'
3339   ;;
3340 $ac_cv_sizeof___int64)
3341   glib_intptr_type_define=__int64
3342   gintptr_modifier='"I64"'
3343   gintptr_format='"I64i"'
3344   guintptr_format='"I64u"'
3345   glib_gpi_cast='(gint64)'
3346   glib_gpui_cast='(guint64)'
3347   ;;
3348 *)
3349   glib_unknown_void_p=yes
3350   ;;
3351 esac
3352
3353
3354 case xyes in
3355 x$ac_cv_func_atexit)
3356   glib_atexit="
3357 #ifdef NeXT /* @#%@! NeXTStep */
3358 # define g_ATEXIT(proc) (!atexit (proc))
3359 #else
3360 # define g_ATEXIT(proc) (atexit (proc))
3361 #endif"
3362   ;;
3363 x$ac_cv_func_on_exit)
3364   glib_atexit="
3365 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3366   ;;
3367 esac
3368
3369 case xyes in
3370 x$ac_cv_func_memmove)
3371   glib_memmove='
3372 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3373   ;;
3374 x$glib_cv_working_bcopy)
3375   glib_memmove="
3376 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3377 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3378   ;;
3379 *)
3380   glib_memmove="
3381 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3382  * so we have to roll our own copy routine. */
3383 void g_memmove (void* dest, const void * src, unsigned long len);"
3384   ;;
3385 esac
3386
3387 glib_defines="
3388 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3389 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3390 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3391 "
3392
3393 case xyes in
3394 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3395 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3396 *)                      glib_vacopy=''
3397 esac
3398
3399 if test x$glib_cv_va_val_copy = xno; then
3400   glib_vacopy="\$glib_vacopy
3401 #define G_VA_COPY_AS_ARRAY 1"
3402 fi
3403
3404 if test x$glib_cv_hasinline = xyes; then
3405     glib_inline='#define G_HAVE_INLINE 1'
3406 fi
3407 if test x$glib_cv_has__inline = xyes; then
3408     glib_inline="\$glib_inline
3409 #define G_HAVE___INLINE 1"
3410 fi
3411 if test x$glib_cv_has__inline__ = xyes; then
3412     glib_inline="\$glib_inline
3413 #define G_HAVE___INLINE__ 1"
3414 fi
3415
3416 g_have_gnuc_varargs=$g_have_gnuc_varargs
3417 g_have_iso_c_varargs=$g_have_iso_c_varargs
3418 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3419
3420 g_can_inline=$g_can_inline
3421 g_have_gnuc_visibility=$g_have_gnuc_visibility
3422 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3423
3424 if test x$ac_cv_c_bigendian = xyes; then
3425   g_byte_order=G_BIG_ENDIAN
3426   g_bs_native=BE
3427   g_bs_alien=LE
3428 else
3429   g_byte_order=G_LITTLE_ENDIAN
3430   g_bs_native=LE
3431   g_bs_alien=BE
3432 fi
3433
3434 g_pollin=$glib_cv_value_POLLIN
3435 g_pollout=$glib_cv_value_POLLOUT
3436 g_pollpri=$glib_cv_value_POLLPRI
3437 g_pollhup=$glib_cv_value_POLLHUP
3438 g_pollerr=$glib_cv_value_POLLERR
3439 g_pollnval=$glib_cv_value_POLLNVAL
3440
3441 # If a family is not found on the system, define that family to
3442 # a negative value, picking a different one for each undefined
3443 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3444 # This is needed because glib-mkenums doesn't handle optional
3445 # values in enums, and thus we have to have all existing values
3446 # defined in the enum.
3447 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3448   g_af_unix=$glib_cv_value_AF_UNIX
3449 else
3450   g_af_unix=-1
3451 fi
3452 g_af_inet=$glib_cv_value_AF_INET
3453 g_af_inet6=$glib_cv_value_AF_INET6
3454
3455 g_msg_peek=$glib_cv_value_MSG_PEEK
3456 g_msg_oob=$glib_cv_value_MSG_OOB
3457 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3458
3459 g_stack_grows=$glib_cv_stack_grows
3460
3461 g_have_eilseq=$have_eilseq
3462
3463 g_threads_impl_def=$g_threads_impl
3464
3465 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3466 g_memory_barrier_needed="$glib_memory_barrier_needed"
3467 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3468
3469 g_module_suffix="$glib_gmodule_suffix"
3470
3471 g_pid_type="$glib_pid_type"
3472 case $host in
3473   *-*-beos*)
3474     glib_os="#define G_OS_BEOS"
3475     ;;
3476   *-*-cygwin*)
3477     glib_os="#define G_OS_UNIX
3478 #define G_PLATFORM_WIN32
3479 #define G_WITH_CYGWIN"
3480     ;;
3481   *-*-mingw*)
3482     glib_os="#define G_OS_WIN32
3483 #define G_PLATFORM_WIN32"
3484     ;;
3485   *)
3486     glib_os="#define G_OS_UNIX"
3487     ;;
3488 esac
3489 glib_static_compilation=""
3490 if test x$glib_win32_static_compilation = xyes; then
3491   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3492 #define GOBJECT_STATIC_COMPILATION 1"
3493 fi
3494 ])
3495
3496 # Redo enough to get guint32 and guint64 for the alignment checks below
3497 case 4 in
3498 $ac_cv_sizeof_short)
3499   gint32=short
3500   ;;
3501 $ac_cv_sizeof_int)
3502   gint32=int
3503   ;;
3504 $ac_cv_sizeof_long)
3505   gint32=long
3506   ;;
3507 esac
3508 case 8 in
3509 $ac_cv_sizeof_int)
3510   gint64=int
3511   ;;
3512 $ac_cv_sizeof_long)
3513   gint64=long
3514   ;;
3515 $ac_cv_sizeof_long_long)
3516   gint64='long long'
3517   ;;
3518 $ac_cv_sizeof___int64)
3519   gint64='__int64'
3520   ;;
3521 esac
3522
3523 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3524 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3525 typedef unsigned $gint32 guint32;])
3526 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3527 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3528 typedef unsigned $gint64 guint64;])
3529 AC_CHECK_TYPE([unsigned long])
3530 AC_CHECK_ALIGNOF([unsigned long])
3531
3532 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3533 #
3534 # 1.2.14 required for dbus_message_set_serial
3535 AS_IF([ test x$enable_modular_tests = xyes], [
3536    PKG_CHECK_MODULES(DBUS1,
3537                      dbus-1 >= 1.2.14,
3538                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3539                      have_dbus1=no)
3540    AC_SUBST(DBUS1_CFLAGS)
3541    AC_SUBST(DBUS1_LIBS)
3542 ])
3543 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3544
3545 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3546 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3547
3548 dnl
3549 dnl Check for -Bsymbolic-functions linker flag used to avoid
3550 dnl intra-library PLT jumps, if available.
3551 dnl
3552
3553 AC_ARG_ENABLE(Bsymbolic,
3554               [AS_HELP_STRING([--disable-Bsymbolic],
3555                               [avoid linking with -Bsymbolic])],,
3556               [SAVED_LDFLAGS="${LDFLAGS}"
3557                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3558                LDFLAGS=-Wl,-Bsymbolic-functions
3559                AC_TRY_LINK([], [int main (void) { return 0; }],
3560                            AC_MSG_RESULT(yes)
3561                            enable_Bsymbolic=yes,
3562                            AC_MSG_RESULT(no)
3563                            enable_Bsymbolic=no)
3564                LDFLAGS="${SAVED_LDFLAGS}"])
3565
3566 if test "x${enable_Bsymbolic}" = "xyes"; then
3567   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3568 fi
3569
3570 AC_SUBST(GLIB_LINK_FLAGS)
3571
3572 dnl
3573 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3574 dnl visibility attributes for symbol export control
3575 dnl
3576 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3577 case "$host" in
3578   *-*-mingw*)
3579     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3580     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3581               [defines how to decorate public symbols while building])
3582     CFLAGS="${CFLAGS} -fvisibility=hidden"
3583     ;;
3584   *)
3585     dnl on other compilers, check if we can do -fvisibility=hidden
3586     SAVED_CFLAGS="${CFLAGS}"
3587     CFLAGS="-fvisibility=hidden"
3588     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3589     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3590                    AC_MSG_RESULT(yes)
3591                    enable_fvisibility_hidden=yes,
3592                    AC_MSG_RESULT(no)
3593                    enable_fvisibility_hidden=no)
3594     CFLAGS="${SAVED_CFLAGS}"
3595
3596     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3597       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3598                 [defines how to decorate public symbols while building])
3599       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3600     ])
3601     ;;
3602 esac
3603 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3604
3605 dnl Compiler flags; macro originates from systemd
3606 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3607 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
3608    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3609    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3610    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3611    -Werror=format=2 -Werror=missing-include-dirs])
3612 CFLAGS="$with_cflags $CFLAGS"
3613
3614 #
3615 # Define variables corresponding to the correct include paths to use for
3616 # in-tree building.
3617 #
3618
3619 # for config.h:
3620 config_h_INCLUDES='-I$(top_builddir)'
3621 AC_SUBST(config_h_INCLUDES)
3622
3623 # glib:
3624 #   config.h
3625 #   $(top_builddir)/glib: for glibconfig.h
3626 #   $(top_srcdir)/glib:   for glib.h
3627 #   $(top_srcdir):        for everything
3628 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3629 AC_SUBST(glib_INCLUDES)
3630
3631 # gobject:
3632 #   same as glib
3633 gobject_INCLUDES='$(glib_INCLUDES)'
3634 AC_SUBST(gobject_INCLUDES)
3635
3636 # gmodule:
3637 #   glib includes
3638 #   $(top_srcdir)/gmodule: for gmodule.h
3639 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3640 AC_SUBST(gmodule_INCLUDES)
3641
3642 # gio:
3643 #   same as gmodule
3644 gio_INCLUDES='$(gmodule_INCLUDES)'
3645 AC_SUBST(gio_INCLUDES)
3646
3647
3648 AC_CONFIG_FILES([
3649 glib-2.0.pc
3650 gmodule-2.0.pc
3651 gmodule-export-2.0.pc
3652 gmodule-no-export-2.0.pc
3653 gthread-2.0.pc
3654 gobject-2.0.pc
3655 gio-2.0.pc
3656 gio-unix-2.0.pc
3657 gio-windows-2.0.pc
3658 glib-zip
3659 glib-gettextize
3660 Makefile
3661 build/Makefile
3662 build/win32/Makefile
3663 build/win32/dirent/Makefile
3664 build/win32/vs9/Makefile
3665 build/win32/vs10/Makefile
3666 build/win32/vs11/Makefile
3667 glib/Makefile
3668 glib/glib.stp
3669 glib/libcharset/Makefile
3670 glib/gnulib/Makefile
3671 glib/pcre/Makefile
3672 glib/update-pcre/Makefile
3673 glib/tests/Makefile
3674 gmodule/Makefile
3675 gmodule/gmoduleconf.h
3676 gobject/Makefile
3677 gobject/gobject.stp
3678 gobject/glib-mkenums
3679 gobject/tests/Makefile
3680 gthread/Makefile
3681 gio/Makefile
3682 gio/gdbus-2.0/codegen/Makefile
3683 gio/gdbus-2.0/codegen/config.py
3684 gio/gnetworking.h
3685 gio/xdgmime/Makefile
3686 gio/inotify/Makefile
3687 gio/kqueue/Makefile
3688 gio/fen/Makefile
3689 gio/fam/Makefile
3690 gio/win32/Makefile
3691 gio/tests/Makefile
3692 gio/tests/gdbus-object-manager-example/Makefile
3693 gio/tests/services/Makefile
3694 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3695 po/Makefile.in
3696 docs/Makefile
3697 docs/reference/Makefile
3698 docs/reference/glib/Makefile
3699 docs/reference/glib/version.xml
3700 docs/reference/gobject/Makefile
3701 docs/reference/gobject/version.xml
3702 docs/reference/gio/Makefile
3703 docs/reference/gio/gdbus-object-manager-example/Makefile
3704 docs/reference/gio/version.xml
3705 tests/Makefile
3706 tests/gobject/Makefile
3707 tests/refcount/Makefile
3708 m4macros/Makefile
3709 ])
3710
3711 AC_CONFIG_COMMANDS([chmod-scripts],
3712 [chmod 0755 glib-zip
3713 chmod 0755 glib-gettextize
3714 chmod 0755 gobject/glib-mkenums])
3715
3716 # we want to invoke this macro solely so that the config.status script
3717 # and automake generated makefiles know about these generated files.
3718 # They are only needed to distcheck the package
3719 if false; then
3720   AC_CONFIG_FILES([
3721     INSTALL
3722     README
3723     config.h.win32
3724     glib/glibconfig.h.win32
3725     glib/makefile.msc
3726     glib/glib.rc
3727     gmodule/makefile.msc
3728     gmodule/gmodule.rc
3729     gobject/makefile.msc
3730     gobject/gobject.rc
3731     gthread/makefile.msc
3732     gthread/gthread.rc
3733     gio/gio.rc
3734     tests/makefile.msc
3735   ])
3736 fi
3737
3738 AC_OUTPUT