configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [35])
  34 m4_define([glib_micro_version], [5])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153
 154     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 155     ;;
 156   *)
 157     glib_native_win32=no
 158     glib_pid_type=int
 159     ;;
 160 esac
 161 case $host in
 162   *-*-linux*)
 163     glib_os_linux=yes
 164     ;;
 165 esac
 166
 167 AC_MSG_RESULT([$glib_native_win32])
 168
 169 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 170
 171 glib_have_carbon=no
 172 AC_MSG_CHECKING([for Mac OS X Carbon support])
 173 AC_TRY_CPP([
 174 #include <Carbon/Carbon.h>
 175 #include <CoreServices/CoreServices.h>
 176 ], glib_have_carbon=yes)
 177
 178 AC_MSG_RESULT([$glib_have_carbon])
 179
 180 glib_have_cocoa=no
 181 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 182 AC_TRY_CPP([
 183 #include <Cocoa/Cocoa.h>
 184 #ifdef GNUSTEP_BASE_VERSION
 185 #error "Detected GNUstep, not Cocoa"
 186 #endif
 187 ], glib_have_cocoa=yes)
 188
 189 AC_MSG_RESULT([$glib_have_cocoa])
 190
 191 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 192 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 193 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 194 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 195 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 196 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 197
 198 AS_IF([test "$glib_native_win32" = "yes"], [
 199   AC_CHECK_TOOL(WINDRES, windres, no)
 200   if test "$WINDRES" = no; then
 201     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 202   fi
 203   AC_CHECK_TOOL(NM, nm, no)
 204   if test "$NM" = no; then
 205     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 206   fi
 207   AC_CHECK_TOOL(RANLIB, ranlib, :)
 208   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 209   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 210 ])
 211 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 212
 213 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 214   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 215   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 216 ])
 217
 218 if test "x$glib_have_cocoa" = "xyes"; then
 219   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 220   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 221 fi
 222
 223 gl_GLIBC21
 224 AS_IF([test "x$GLIBC21" = "xyes"], [
 225   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 226 ])
 227
 228 dnl declare --enable-* args and collect ac_help strings
 229 AC_ARG_ENABLE(debug,
 230               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 231                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 232               enable_debug=glib_debug_default)
 233
 234 AC_ARG_ENABLE(gc_friendly,
 235               [AS_HELP_STRING([--enable-gc-friendly],
 236                               [turn on garbage collector friendliness [default=no]])],,
 237               [enable_gc_friendly=no])
 238 AC_ARG_ENABLE(mem_pools,
 239               [AS_HELP_STRING([--disable-mem-pools],
 240                               [disable all glib memory pools])],,
 241               [disable_mem_pools=no])
 242 AC_ARG_ENABLE(rebuilds,
 243               [AS_HELP_STRING([--disable-rebuilds],
 244                               [disable all source autogeneration rules])],,
 245               [enable_rebuilds=yes])
 246 AC_ARG_ENABLE(modular_tests,
 247               AS_HELP_STRING([--disable-modular-tests],
 248                              [Disable build of test programs (default: no)]),,
 249               [enable_modular_tests=yes])
 250 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 251
 252 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 253 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 254   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 255   AC_MSG_RESULT([yes])
 256 ], [ AC_MSG_RESULT([no]) ])
 257
 258 AC_MSG_CHECKING([whether to disable memory pools])
 259 AS_IF([test "x$disable_mem_pools" = "xno"], [
 260   AC_MSG_RESULT([no])
 261 ], [
 262   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 263   AC_MSG_RESULT([yes])
 264 ])
 265
 266 dnl location to install runtime libraries, e.g. ../../lib to install
 267 dnl to /lib if libdir is /usr/lib
 268 AC_ARG_WITH(runtime-libdir,
 269            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 270                            [install runtime libraries relative to libdir])],
 271            [],
 272            [with_runtime_libdir=""])
 273 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 274 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 275 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 276 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 277 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 278
 279 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 280 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 281 AC_LANG_SAVE
 282 AC_LANG_CPLUSPLUS
 283 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 284 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 285 AC_LANG_RESTORE
 286
 287 AM_PROG_CC_C_O
 288 AC_PROG_INSTALL
 289
 290 AC_SYS_LARGEFILE
 291
 292 PKG_PROG_PKG_CONFIG(0.16)
 293
 294 if test "x$enable_debug" = "xyes"; then
 295   if test x$cflags_set != xset ; then
 296       case " $CFLAGS " in
 297       *[[\ \    ]]-g[[\ \       ]]*) ;;
 298       *) CFLAGS="$CFLAGS -g" ;;
 299       esac
 300   fi
 301   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 302 else
 303   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 304
 305   if test "x$enable_debug" = "xno"; then
 306     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 307   fi
 308 fi
 309
 310 # Ensure MSVC-compatible struct packing convention is used when
 311 # compiling for Win32 with gcc.
 312 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 313 # gcc2 uses "-fnative-struct".
 314 if test x"$glib_native_win32" = xyes; then
 315   if test x"$GCC" = xyes; then
 316     msnative_struct=''
 317     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 318     if test -z "$ac_cv_prog_CC"; then
 319       our_gcc="$CC"
 320     else
 321       our_gcc="$ac_cv_prog_CC"
 322     fi
 323     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 324       2.)
 325         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 326           msnative_struct='-fnative-struct'
 327         fi
 328         ;;
 329       *)
 330         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 331           msnative_struct='-mms-bitfields'
 332         fi
 333         ;;
 334     esac
 335     if test x"$msnative_struct" = x ; then
 336       AC_MSG_RESULT([no way])
 337       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 338     else
 339       CFLAGS="$CFLAGS $msnative_struct"
 340       AC_MSG_RESULT([${msnative_struct}])
 341     fi
 342   fi
 343 fi
 344 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 345 AC_SUBST(GLIB_EXTRA_CFLAGS)
 346
 347 AC_EXEEXT
 348
 349 # define a MAINT-like variable REBUILD which is set if Perl
 350 # and awk are found, so autogenerated sources can be rebuilt
 351 AC_PROG_AWK
 352 AC_CHECK_PROGS(PERL, [perl5 perl])
 353 # We would like indent, but don't require it.
 354 AC_CHECK_PROG(INDENT, indent, indent)
 355 REBUILD=\#
 356 if test "x$enable_rebuilds" = "xyes" && \
 357      test -n "$PERL" && \
 358      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 359      test -n "$AWK" ; then
 360   REBUILD=
 361 fi
 362 AC_SUBST(REBUILD)
 363
 364 # Need full path to Perl for glib-mkenums
 365 #
 366 if test "x$PERL" != x ; then
 367   AC_PATH_PROG(PERL_PATH, [$PERL])
 368 fi
 369 if test "x$PERL_PATH" = x ; then
 370   PERL_PATH="/usr/bin/env perl"
 371 fi
 372 AC_SUBST(PERL_PATH)
 373
 374 # option to specify python interpreter to use; this just sets $PYTHON, so that
 375 # we will fallback to reading $PYTHON if --with-python is not given, and
 376 # python.m4 will get the expected input
 377 AC_ARG_WITH(python,
 378             AS_HELP_STRING([--with-python=PATH],
 379                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 380             [PYTHON="$withval"], [])
 381 if test x"$PYTHON" = xyes; then
 382   AC_MSG_ERROR([--with-python option requires a path or program argument])
 383 fi
 384 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 385
 386
 387 dnl ***********************
 388 dnl *** Tests for iconv ***
 389 dnl ***********************
 390 dnl
 391 dnl We do this before the gettext checks, to avoid distortion
 392
 393 dnl On Windows we use a native implementation
 394
 395 AS_IF([ test x"$glib_native_win32" = xyes], [
 396   with_libiconv=native
 397 ], [
 398   AC_ARG_WITH(libiconv,
 399               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 400                               [use the libiconv library])],,
 401               [with_libiconv=maybe])
 402
 403   found_iconv=no
 404   case $with_libiconv in
 405     maybe)
 406       # Check in the C library first
 407       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 408       # Check if we have GNU libiconv
 409       if test $found_iconv = "no"; then
 410         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 411       fi
 412       # Check if we have a iconv in -liconv, possibly from vendor
 413       if test $found_iconv = "no"; then
 414         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 415       fi
 416       ;;
 417     no)
 418       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 419       ;;
 420     gnu|yes)
 421       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 422       ;;
 423     native)
 424       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 425       ;;
 426   esac
 427
 428   if test "x$found_iconv" = "xno" ; then
 429      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 430   fi
 431 ])
 432
 433 AC_ARG_ENABLE(iconv-cache,
 434               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 435                               [cache iconv descriptors [default=auto]])],,
 436               [enable_iconv_cache=auto])
 437
 438 AC_MSG_CHECKING([whether to cache iconv descriptors])
 439 case $enable_iconv_cache in
 440   auto)
 441     if test $ac_cv_gnu_library_2_1 = yes; then
 442       enable_iconv_cache=no
 443     else
 444       enable_iconv_cache=yes
 445     fi
 446   ;;
 447   yes|no)
 448   ;;
 449   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 450   ;;
 451 esac
 452
 453 if test $enable_iconv_cache = yes; then
 454    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 455 fi
 456
 457 AC_MSG_RESULT($enable_iconv_cache)
 458
 459
 460 dnl
 461 dnl zlib support
 462 dnl
 463 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 464 AS_IF([test "x$found_zlib" = "xno"], [
 465   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 466   if test "x$found_zlib" = "xno" ; then
 467     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 468   fi
 469   ZLIB_LIBS='-lz'
 470   AC_SUBST(ZLIB_LIBS)
 471 ])
 472
 473 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 474 AC_SUBST(LIBFFI_CFLAGS)
 475 AC_SUBST(LIBFFI_LIBS)
 476
 477 dnl
 478 dnl gettext support
 479 dnl
 480
 481 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 482 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 483 GLIB_GNU_GETTEXT
 484
 485 if test "$gt_cv_have_gettext" != "yes" ; then
 486   AC_MSG_ERROR([
 487 *** You must have either have gettext support in your C library, or use the
 488 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 489 ])
 490 fi
 491
 492 LIBS="$INTLLIBS $LIBS"
 493
 494 GETTEXT_PACKAGE=glib20
 495 AC_SUBST(GETTEXT_PACKAGE)
 496 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 497   [Define the gettext package to be used])
 498
 499 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 500
 501 dnl
 502 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 503 dnl
 504
 505 AS_IF([test x"$glib_native_win32" != xyes], [
 506   if test x$with_libiconv != xno ; then
 507     case " $INTLLIBS " in
 508     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 509     *) ICONV_LIBS="-liconv" ;;
 510     esac
 511   fi
 512 ])
 513 AC_SUBST(ICONV_LIBS)
 514
 515 case $with_libiconv in
 516   gnu)
 517     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 518     ;;
 519   native)
 520     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 521     ;;
 522 esac
 523
 524 dnl Initialize libtool
 525 LT_PREREQ([2.2])
 526 LT_INIT([disable-static win32-dll])
 527 dnl when using libtool 2.x create libtool early, because it's used in configure
 528 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 529
 530
 531 AS_IF([test "$glib_native_win32" = "yes"], [
 532   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 533     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 534   fi
 535   if test x$enable_static = xyes; then
 536     glib_win32_static_compilation=yes
 537     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 538 #define GOBJECT_STATIC_COMPILATION 1"
 539     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 540   fi
 541 ])
 542 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 543
 544 dnl
 545 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 546 dnl
 547 AS_IF([test $cross_compiling != yes], [
 548     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 549     glib_save_LIBS=$LIBS
 550     LIBS="$LIBS -lm"
 551     AC_TRY_RUN([#include <math.h>
 552                  int main (void) { return (log(1) != log(1.)); }],
 553          AC_MSG_RESULT(none needed),
 554          glib_save_CFLAGS=$CFLAGS
 555          CFLAGS="$CFLAGS -std1"
 556          AC_TRY_RUN([#include <math.h>
 557                      int main (void) { return (log(1) != log(1.)); }],
 558              AC_MSG_RESULT(-std1),
 559              AC_MSG_RESULT()
 560              CFLAGS=$glib_save_CFLAGS
 561              AC_MSG_WARN(
 562                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 563          )
 564     )
 565     LIBS=$glib_save_LIBS
 566 ])
 567
 568 dnl NeXTStep cc seems to need this
 569 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 570 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 571   AC_MSG_RESULT(none needed),
 572   glib_save_CFLAGS=$CFLAGS
 573   CFLAGS="$CFLAGS -posix"
 574   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 575     AC_MSG_RESULT(-posix),
 576     AC_MSG_RESULT()
 577     CFLAGS=$glib_save_CFLAGS
 578     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 579
 580 # Checks for library functions.
 581 AC_FUNC_VPRINTF
 582 AC_FUNC_ALLOCA
 583 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 584 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 585
 586 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 587   [AC_TRY_LINK([#include <unistd.h>
 588     extern int __libc_enable_secure;],
 589     [return __libc_enable_secure;],
 590    glib_cv_have_libc_enable_secure=yes,
 591    glib_cv_have_libc_enable_secure=no)])
 592 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 593    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 594      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 595 ])
 596
 597 AC_CHECK_SIZEOF(char)
 598 AC_CHECK_SIZEOF(short)
 599 AC_CHECK_SIZEOF(long)
 600 AC_CHECK_SIZEOF(int)
 601 AC_CHECK_SIZEOF(void *)
 602 AC_CHECK_SIZEOF(long long)
 603 AC_CHECK_SIZEOF(__int64)
 604
 605 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 606   [AC_TRY_LINK([#include <signal.h>
 607      #include <sys/types.h>
 608      sig_atomic_t val = 42;],
 609     [return val == 42 ? 0 : 1],
 610    ac_cv_type_sig_atomic_t=yes,
 611    ac_cv_type_sig_atomic_t=no)])
 612 if test x$ac_cv_type_sig_atomic_t = xyes; then
 613    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 614      [Define if you have the 'sig_atomic_t' type.])
 615 fi
 616
 617 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 618   :
 619 else
 620   AC_MSG_ERROR([
 621 *** GLib requires a 64 bit type. You might want to consider
 622 *** using the GNU C compiler.
 623 ])
 624 fi
 625
 626 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 627         # long long is a 64 bit integer.
 628         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 629         AC_CACHE_VAL(glib_cv_long_long_format,[
 630                 for format in ll q I64; do
 631                   AC_TRY_RUN([#include <stdio.h>
 632                         int main()
 633                         {
 634                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 635                           char buffer[1000];
 636                           sprintf (buffer, "%${format}u", a);
 637                           sscanf (buffer, "%${format}u", &b);
 638                           exit (b!=a);
 639                         }
 640                         ],
 641                         [glib_cv_long_long_format=${format}
 642                         break],
 643                         [],[:])
 644                 done])
 645         AS_IF([ test -n "$glib_cv_long_long_format"], [
 646           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 647           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 648           if test x"$glib_cv_long_long_format" = xI64; then
 649             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 650           fi
 651         ], [AC_MSG_RESULT(none)])
 652 ],[ test x$ac_cv_sizeof___int64 = x8], [
 653         # __int64 is a 64 bit integer.
 654         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 655         # We know this is MSVCRT.DLL, and what the formats are
 656         glib_cv_long_long_format=I64
 657         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 660 ])
 661
 662 AC_C_CONST
 663
 664 dnl ok, here we try to check whether the systems prototypes for
 665 dnl malloc and friends actually match the prototypes provided
 666 dnl by gmem.h (keep in sync). i currently only know how to check
 667 dnl this reliably with gcc (-Werror), improvements for other
 668 dnl compilers are apprechiated.
 669 SANE_MALLOC_PROTOS=no
 670 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 671 glib_save_CFLAGS=$CFLAGS
 672 AS_IF([test "x$GCC" = "xyes"], [
 673   CFLAGS="$CFLAGS -Werror"
 674   AC_TRY_COMPILE([#include <stdlib.h>], [
 675     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 676     void* (*my_malloc_p)  (size_t)         = malloc;
 677     void  (*my_free_p)    (void*)          = free;
 678     void* (*my_realloc_p) (void*, size_t)  = realloc;
 679     my_calloc_p = 0;
 680     my_malloc_p = 0;
 681     my_free_p = 0;
 682     my_realloc_p = 0;
 683   ],
 684     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 685       [Define if you have correct malloc prototypes])
 686     SANE_MALLOC_PROTOS=yes)
 687 ])
 688 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 689 CFLAGS=$glib_save_CFLAGS
 690
 691 dnl
 692 dnl check in which direction the stack grows
 693 dnl
 694 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 695         AC_TRY_RUN([
 696         volatile int *a = 0, *b = 0;
 697         void foo (void);
 698         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 699         void foo (void) { volatile int x = 5; b = &x; }
 700         ],
 701         glib_cv_stack_grows=no
 702         ,
 703         glib_cv_stack_grows=yes
 704         ,)
 705 ])
 706
 707 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 708 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 709 dnl actually supported.
 710 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 711         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 712         __inline int foo () { return 0; }
 713         int main () { return foo (); }
 714         ]])],
 715         glib_cv_has__inline=yes
 716         ,
 717         glib_cv_has__inline=no
 718         ,)
 719 ])
 720 case x$glib_cv_has__inline in
 721 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 722 esac
 723 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 724         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 725         __inline__ int foo () { return 0; }
 726         int main () { return foo (); }
 727         ]])],
 728         glib_cv_has__inline__=yes
 729         ,
 730         glib_cv_has__inline__=no
 731         ,)
 732 ])
 733 case x$glib_cv_has__inline__ in
 734 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 735 esac
 736 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 737         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 738         #undef inline
 739         inline int foo () { return 0; }
 740         int main () { return foo (); }
 741         ]])],
 742         glib_cv_hasinline=yes
 743         ,
 744         glib_cv_hasinline=no
 745         ,)
 746 ])
 747 case x$glib_cv_hasinline in
 748 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 749 esac
 750
 751 # if we can use inline functions in headers
 752 AC_MSG_CHECKING(if inline functions in headers work)
 753 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 754 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 755 #  undef inline
 756 #  define inline __inline__
 757 #elif !defined (G_HAVE_INLINE)
 758 #  undef inline
 759 #  if defined (G_HAVE___INLINE__)
 760 #    define inline __inline__
 761 #  elif defined (G_HAVE___INLINE)
 762 #    define inline __inline
 763 #  endif
 764 #endif
 765
 766 int glib_test_func2 (int);
 767
 768 static inline int
 769 glib_test_func1 (void) {
 770   return glib_test_func2 (1);
 771 }
 772
 773 int
 774 main (void) {
 775   int i = 1;
 776 }]])],[g_can_inline=yes],[g_can_inline=no])
 777 AC_MSG_RESULT($g_can_inline)
 778
 779 dnl *** check for working do while(0) macros ***
 780 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 781         AC_TRY_COMPILE([],[
 782         #define STMT_START do
 783         #define STMT_END while(0)
 784         #define STMT_TEST STMT_START { i = 0; } STMT_END
 785         int main(void) { int i = 1; STMT_TEST; return i; }],
 786         [g_cv_support_dowhile_macros=yes],
 787         [g_cv_support_dowhile_macros=no],
 788         [g_cv_support_dowhile_macros=yes])
 789 ])
 790 if test x$g_cv_support_dowhile_macros = xyes; then
 791   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 792 fi
 793
 794 # check for flavours of varargs macros
 795 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 796 AC_TRY_COMPILE([],[
 797 int a(int p1, int p2, int p3);
 798 #define call_a(...) a(1,__VA_ARGS__)
 799 call_a(2,3);
 800 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 801 AC_MSG_RESULT($g_have_iso_c_varargs)
 802
 803 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 804 AS_IF([test "$CXX" = ""], [
 805 dnl No C++ compiler
 806   g_have_iso_cxx_varargs=no
 807 else
 808   AC_LANG_CPLUSPLUS
 809   AC_TRY_COMPILE([],[
 810 int a(int p1, int p2, int p3);
 811 #define call_a(...) a(1,__VA_ARGS__)
 812 call_a(2,3);
 813 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 814   AC_LANG_C
 815 ])
 816 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 817
 818 AC_MSG_CHECKING(for GNUC varargs macros)
 819 AC_TRY_COMPILE([],[
 820 int a(int p1, int p2, int p3);
 821 #define call_a(params...) a(1,params)
 822 call_a(2,3);
 823 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 824 AC_MSG_RESULT($g_have_gnuc_varargs)
 825
 826 # check for GNUC visibility support
 827 AC_MSG_CHECKING(for GNUC visibility attribute)
 828 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 829 void
 830 __attribute__ ((visibility ("hidden")))
 831      f_hidden (void)
 832 {
 833 }
 834 void
 835 __attribute__ ((visibility ("internal")))
 836      f_internal (void)
 837 {
 838 }
 839 void
 840 __attribute__ ((visibility ("protected")))
 841      f_protected (void)
 842 {
 843 }
 844 void
 845 __attribute__ ((visibility ("default")))
 846      f_default (void)
 847 {
 848 }
 849 int main (void)
 850 {
 851         f_hidden();
 852         f_internal();
 853         f_protected();
 854         f_default();
 855         return 0;
 856 }
 857 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 858 AC_MSG_RESULT($g_have_gnuc_visibility)
 859 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 860
 861 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 862 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 863 #else
 864 # include "error: this is not Sun Studio."
 865 #endif
 866 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 867 AC_MSG_RESULT($g_have_sunstudio_visibility)
 868 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 869
 870 # check for bytesex stuff
 871 AC_C_BIGENDIAN
 872 if test x$ac_cv_c_bigendian = xuniversal ; then
 873 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 874 #else
 875 #error Not a big endian.
 876 #endif],
 877     ac_cv_c_bigendian=yes
 878     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 879 #else
 880 #error Not a little endian.
 881 #endif],
 882     ac_cv_c_bigendian=no
 883     ,AC_MSG_WARN([Could not determine endianness.])))
 884 fi
 885
 886
 887 # check for header files
 888 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 889 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 890 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 891 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 892 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 893 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 894 AC_CHECK_HEADERS([linux/magic.h])
 895 AC_CHECK_HEADERS([sys/prctl.h])
 896 AC_CHECK_HEADERS([sys/ioctl.h])
 897
 898 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 899 [#if HAVE_SYS_PARAM_H
 900  #include <sys/param.h>
 901  #endif
 902 ])
 903 AC_CHECK_FUNCS(sysctlbyname)
 904
 905 AC_CHECK_HEADERS([xlocale.h])
 906
 907 # check for structure fields
 908 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 909 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 910 #include <sys/stat.h>
 911 #include <unistd.h>
 912 #ifdef HAVE_SYS_STATFS_H
 913 #include <sys/statfs.h>
 914 #endif
 915 #ifdef HAVE_SYS_PARAM_H
 916 #include <sys/param.h>
 917 #endif
 918 #ifdef HAVE_SYS_MOUNT_H
 919 #include <sys/mount.h>
 920 #endif])
 921 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 922 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 923 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 924 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 925
 926 AC_STRUCT_DIRENT_D_TYPE
 927
 928 # Checks for libcharset
 929 AM_LANGINFO_CODESET
 930 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 931 AC_CHECK_FUNCS(setlocale)
 932
 933 # check additional type sizes
 934 AC_CHECK_SIZEOF(size_t)
 935
 936 dnl Try to figure out whether gsize, gssize should be long or int
 937 AC_MSG_CHECKING([for the appropriate definition for size_t])
 938
 939 case $ac_cv_sizeof_size_t in
 940   $ac_cv_sizeof_short)
 941       glib_size_type=short
 942       ;;
 943   $ac_cv_sizeof_int)
 944       glib_size_type=int
 945       ;;
 946   $ac_cv_sizeof_long)
 947       glib_size_type=long
 948       ;;
 949   $ac_cv_sizeof_long_long)
 950       glib_size_type='long long'
 951       ;;
 952   $ac_cv_sizeof__int64)
 953       glib_size_type='__int64'
 954       ;;
 955   *)  AC_MSG_ERROR([No type matching size_t in size])
 956       ;;
 957 esac
 958
 959 dnl If int/long are the same size, we see which one produces
 960 dnl warnings when used in the location as size_t. (This matters
 961 dnl on AIX with xlc)
 962 dnl
 963 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 964        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 965   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 966 #if defined(_AIX) && !defined(__GNUC__)
 967 #pragma options langlvl=stdc89
 968 #endif
 969 #include <stddef.h>
 970 int main ()
 971 {
 972   size_t s = 1;
 973   unsigned int *size_int = &s;
 974   return (int)*size_int;
 975 }
 976     ]])],glib_size_type=int,
 977       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 978 #if defined(_AIX) && !defined(__GNUC__)
 979 #pragma options langlvl=stdc89
 980 #endif
 981 #include <stddef.h>
 982 int main ()
 983 {
 984    size_t s = 1;
 985    unsigned long *size_long = &s;
 986    return (int)*size_long;
 987 }
 988         ]])],glib_size_type=long)])
 989 ])
 990
 991 AC_MSG_RESULT(unsigned $glib_size_type)
 992
 993 # Check for some functions
 994 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 995 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
 996 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 997 # Check for high-resolution sleep functions
 998 AC_CHECK_FUNCS(splice)
 999 AC_CHECK_FUNCS(prlimit)
1000
1001 # To avoid finding a compatibility unusable statfs, which typically
1002 # successfully compiles, but warns to use the newer statvfs interface:
1003 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1004 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1005
1006 AC_MSG_CHECKING([whether to use statfs or statvfs])
1007 # Some systems have both statfs and statvfs, pick the most "native" for these
1008 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1009    [
1010    # on solaris and irix, statfs doesn't even have the f_bavail field
1011    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1012       [ac_cv_func_statfs=no],
1013    # else, at least on linux, statfs is the actual syscall
1014       [ac_cv_func_statvfs=no])
1015    ])
1016
1017 AS_IF([test x$ac_cv_func_statfs = xyes],
1018       [
1019          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1020          AC_MSG_RESULT([statfs])
1021       ],
1022       [test x$ac_cv_func_statvfs = xyes],
1023       [
1024          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1025          AC_MSG_RESULT([statvfs])
1026       ],
1027       [  AC_MSG_RESULT([neither])])
1028
1029 AC_CHECK_HEADERS(crt_externs.h)
1030 AC_CHECK_FUNCS(_NSGetEnviron)
1031
1032 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1033
1034 AC_FUNC_VSNPRINTF_C99
1035 AC_FUNC_PRINTF_UNIX98
1036
1037 # Internet address families
1038 if test $glib_native_win32 = yes; then
1039   glib_inet_includes=["
1040 #include <winsock2.h>
1041   "]
1042 else
1043   glib_inet_includes=["
1044 #include <sys/types.h>
1045 #include <sys/socket.h>
1046   "]
1047 fi
1048
1049 glib_failed=false
1050 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1051 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1052 # winsock defines this even though it doesn't support it
1053 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1054 if $glib_failed ; then
1055   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1056 fi
1057
1058 glib_failed=false
1059 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1061 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1062 if $glib_failed ; then
1063   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1064 fi
1065
1066 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1067
1068 AS_IF([test $glib_native_win32 = yes], [
1069   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1070   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1071   # they aren't present at run-time (on Windows 2000).
1072   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1073   AC_SUBST(WSPIAPI_INCLUDE)
1074 ], [
1075   AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1076   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <arpa/nameser.h>],
1077                                      [int qclass = C_IN;])],
1078                     [AC_MSG_RESULT([no])],
1079                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <arpa/nameser.h>
1080                                                          #include <arpa/nameser_compat.h>],
1081                                                         [int qclass = C_IN;])],
1082                                        [AC_MSG_RESULT([yes])
1083                                         NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1084                                        [AC_MSG_ERROR([could not compile test program either way])])])
1085   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1086
1087   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1088   NETWORK_LIBS=""
1089   AC_MSG_CHECKING([for res_query])
1090   AC_TRY_LINK([#include <sys/types.h>
1091                #include <netinet/in.h>
1092                #include <arpa/nameser.h>
1093                #include <resolv.h>
1094               ],[
1095                res_query("test", 0, 0, (void *)0, 0);
1096               ],[AC_MSG_RESULT([yes])],
1097               [save_libs="$LIBS"
1098                LIBS="-lresolv $LIBS"
1099                AC_TRY_LINK([#include <sys/types.h>
1100                             #include <netinet/in.h>
1101                             #include <arpa/nameser.h>
1102                             #include <resolv.h>
1103                            ],[
1104                             res_query("test", 0, 0, (void *)0, 0);
1105                            ],[AC_MSG_RESULT([in -lresolv])
1106                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1107                            [LIBS="-lbind $save_libs"
1108                             AC_TRY_LINK([#include <resolv.h>],
1109                                         [res_query("test", 0, 0, (void *)0, 0);],
1110                                         [AC_MSG_RESULT([in -lbind])
1111                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1112                                         [AC_MSG_ERROR(not found)])])
1113                LIBS="$save_libs"])
1114   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1115                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1116                                         [AC_MSG_ERROR(Could not find socket())]))
1117 ])
1118 AC_SUBST(NETWORK_LIBS)
1119
1120 AC_CHECK_HEADER([linux/netlink.h],
1121                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1122                 [#include <sys/socket.h>])
1123 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1124
1125 AC_CHECK_TYPE([struct ip_mreqn], [
1126               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1127               [#include <netinet/in.h>])
1128
1129 case $host in
1130   *-*-solaris* )
1131      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1132      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1133      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1134      ;;
1135 esac
1136
1137 dnl
1138 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1139 dnl
1140 AS_IF([test "$ac_cv_func_statfs" = yes], [
1141   AC_MSG_CHECKING([number of arguments to statfs()])
1142   AC_TRY_COMPILE([#include <unistd.h>
1143   #ifdef HAVE_SYS_PARAM_H
1144   #include <sys/param.h>
1145   #endif
1146   #ifdef HAVE_SYS_VFS_H
1147   #include <sys/vfs.h>
1148   #endif
1149   #ifdef HAVE_SYS_MOUNT_H
1150   #include <sys/mount.h>
1151   #endif
1152   #ifdef HAVE_SYS_STATFS_H
1153   #include <sys/statfs.h>
1154   #endif], [struct statfs st;
1155   statfs(NULL, &st);],[
1156     AC_MSG_RESULT([2])
1157     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1158     AC_TRY_COMPILE([#include <unistd.h>
1159   #ifdef HAVE_SYS_PARAM_H
1160   #include <sys/param.h>
1161   #endif
1162   #ifdef HAVE_SYS_VFS_H
1163   #include <sys/vfs.h>
1164   #endif
1165   #ifdef HAVE_SYS_MOUNT_H
1166   #include <sys/mount.h>
1167   #endif
1168   #ifdef HAVE_SYS_STATFS_H
1169   #include <sys/statfs.h>
1170   #endif], [struct statfs st;
1171   statfs(NULL, &st, sizeof (st), 0);],[
1172       AC_MSG_RESULT([4])
1173       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1174       AC_MSG_RESULT(unknown)
1175       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1176 ])
1177
1178 #
1179 # Check whether to use an included printf
1180 #
1181
1182 AC_ARG_ENABLE(included-printf,
1183               [AS_HELP_STRING([--enable-included-printf],
1184                               [use included printf [default=auto]])],
1185               enable_included_printf="$enableval")
1186
1187 need_included_printf=no
1188 if test "x$enable_included_printf" = "xyes" ; then
1189   need_included_printf=yes
1190 fi
1191 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1192   need_included_printf=yes
1193 fi
1194 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1195   need_included_printf=yes
1196 fi
1197 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1198    test -z "$glib_cv_long_long_format" ; then
1199   need_included_printf=yes
1200 fi
1201
1202 if test "x$enable_included_printf" = "xno" &&
1203    test "x$need_included_printf" = "xyes" ; then
1204   AC_MSG_ERROR([
1205 *** Your C library's printf doesn't appear to have the features that
1206 *** GLib needs, but you specified --enable-included-printf=no.])
1207 fi
1208
1209 enable_included_printf=$need_included_printf
1210
1211 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1212 AS_IF([test "$enable_included_printf" != "yes"], [
1213   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1214 ], [
1215   if test -z "$glib_cv_long_long_format" ; then
1216     glib_cv_long_long_format="ll"
1217   fi
1218   AC_DEFINE(HAVE_VASPRINTF,1)
1219 ])
1220
1221 # Checks needed for gnulib vasnprintf
1222 bh_C_SIGNED
1223 jm_AC_TYPE_LONG_LONG
1224 gt_TYPE_LONGDOUBLE
1225 gt_TYPE_WCHAR_T
1226 gt_TYPE_WINT_T
1227 AC_TYPE_SIZE_T
1228 AC_CHECK_TYPES(ptrdiff_t)
1229 jm_AC_TYPE_INTMAX_T
1230 AC_CHECK_FUNCS([snprintf wcslen])
1231 AC_FUNC_SNPRINTF_C99
1232
1233 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1234 # The check is borrowed from the PERL Configure script.
1235 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1236   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1237     glib_cv_working_bcopy,[AC_TRY_RUN([
1238       int main() {
1239         char buf[128], abc[128], *b;
1240         int len, off, align;
1241         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1242         for (align = 7; align >= 0; align--) {
1243           for (len = 36; len; len--) {
1244             b = buf+align; bcopy(abc, b, len);
1245             for (off = 1; off <= len; off++) {
1246               bcopy(b, b+off, len); bcopy(b+off, b, len);
1247                 if (bcmp(b, abc, len)) return(1);
1248             }
1249           }
1250         }
1251         return(0);
1252       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1253
1254   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1255   if test "$glib_cv_working_bcopy" = "yes"; then
1256     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1257   fi
1258 ])
1259
1260 # Check if <sys/select.h> needs to be included for fd_set
1261 AC_MSG_CHECKING([for fd_set])
1262 AC_TRY_COMPILE([#include <sys/types.h>],
1263         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1264 AS_IF([test "$gtk_ok" = "yes"], [
1265     AC_MSG_RESULT([yes, found in sys/types.h])
1266 ], [
1267     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1268     if test "$gtk_ok" = "yes"; then
1269         # *** FIXME: give it a different name
1270         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1271         AC_MSG_RESULT([yes, found in sys/select.h])
1272     else
1273         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1274         AC_MSG_RESULT(no)
1275     fi
1276 ])
1277
1278 dnl *** check for sane realloc() ***
1279 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1280         AC_TRY_RUN([#include <stdlib.h>
1281         int main() {
1282           return realloc (0, sizeof (int)) == 0;
1283         }],
1284         [glib_cv_sane_realloc=yes],
1285         [glib_cv_sane_realloc=no],
1286         [glib_cv_sane_realloc=yes])
1287 ])
1288 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1289   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1290 ])
1291
1292 dnl Check for nl_langinfo and CODESET
1293 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1294         AC_TRY_COMPILE([#include <langinfo.h>],
1295                 [char *codeset = nl_langinfo (CODESET);],
1296                 [glib_cv_langinfo_codeset=yes],
1297                 [glib_cv_langinfo_codeset=no])])
1298 if test x$glib_cv_langinfo_codeset = xyes; then
1299   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1300 fi
1301
1302 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1303 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1304         AC_TRY_COMPILE([#include <langinfo.h>],
1305                 [char *str;
1306                  str = nl_langinfo (PM_STR);
1307                  str = nl_langinfo (D_T_FMT);
1308                  str = nl_langinfo (D_FMT);
1309                  str = nl_langinfo (T_FMT);
1310                  str = nl_langinfo (T_FMT_AMPM);
1311                  str = nl_langinfo (MON_1);
1312                  str = nl_langinfo (ABMON_12);
1313                  str = nl_langinfo (DAY_1);
1314                  str = nl_langinfo (ABDAY_7);],
1315                 [glib_cv_langinfo_time=yes],
1316                 [glib_cv_langinfo_time=no])])
1317 if test x$glib_cv_langinfo_time = xyes; then
1318   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1319 fi
1320
1321 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1322 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1323         AC_TRY_COMPILE([#include <langinfo.h>],
1324                 [char *str;
1325                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1326                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1327                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1328                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1329                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1330                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1331                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1332                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1333                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1334                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1335                 [glib_cv_langinfo_outdigit=yes],
1336                 [glib_cv_langinfo_outdigit=no])])
1337 if test x$glib_cv_langinfo_outdigit = xyes; then
1338   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1339 fi
1340
1341 dnl ****************************************
1342 dnl *** posix_memalign                   ***
1343 dnl ****************************************
1344 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1345 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1346     glib_cv_compliant_posix_memalign=0
1347     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1348         AC_TRY_RUN([
1349                 #define _XOPEN_SOURCE 600
1350                 #include <stdlib.h> /* posix_memalign() should be defined here */
1351                 /* some systems break if #include <malloc.h> used */
1352                 static void test_memalign (size_t boundary, size_t size) {
1353                     void *mem = 0;
1354                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1355                         exit (1);
1356                     else
1357                       free (mem);
1358                 }
1359                 int main() {
1360                     test_memalign (  128,   128 - 2 * sizeof (void*));
1361                     test_memalign (  256,   256 - 2 * sizeof (void*));
1362                     test_memalign (  512,   512 - 2 * sizeof (void*));
1363                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1364                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1365                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1366                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1367                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1368                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1369                     exit (0); /* success */
1370                 }
1371                 ],
1372             [glib_cv_compliant_posix_memalign=1], [], [:])
1373       :
1374     fi
1375     ])
1376 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1377     AC_MSG_RESULT(yes)
1378     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1379 ], [
1380     AC_MSG_RESULT(no)
1381 ])
1382
1383
1384 dnl ****************************************
1385 dnl *** strlcpy/strlcat                  ***
1386 dnl ****************************************
1387 # Check for strlcpy
1388 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1389 AC_TRY_RUN([#include <stdlib.h>
1390 #include <string.h>
1391 int main() {
1392   char p[10];
1393   (void) strlcpy (p, "hi", 10);
1394   if (strlcat (p, "bye", 0) != 3)
1395     return 1;
1396   return 0;
1397 }], glib_cv_have_strlcpy=yes,
1398     glib_cv_have_strlcpy=no,
1399     glib_cv_have_strlcpy=no)])
1400 if test "$glib_cv_have_strlcpy" = "yes"; then
1401     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1402 fi
1403
1404
1405 dnl **********************
1406 dnl *** va_copy checks ***
1407 dnl **********************
1408 dnl we currently check for all three va_copy possibilities, so we get
1409 dnl all results in config.log for bug reports.
1410 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1411         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1412 #include <stdlib.h>
1413         void f (int i, ...) {
1414         va_list args1, args2;
1415         va_start (args1, i);
1416         va_copy (args2, args1);
1417         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1418           exit (1);
1419         va_end (args1); va_end (args2);
1420         }
1421         int main() {
1422           f (0, 42);
1423           return 0;
1424         }]])],
1425         [glib_cv_va_copy=yes],
1426         [glib_cv_va_copy=no])
1427 ])
1428 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1429         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1430 #include <stdlib.h>
1431         void f (int i, ...) {
1432         va_list args1, args2;
1433         va_start (args1, i);
1434         __va_copy (args2, args1);
1435         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1436           exit (1);
1437         va_end (args1); va_end (args2);
1438         }
1439         int main() {
1440           f (0, 42);
1441           return 0;
1442         }]])],
1443         [glib_cv___va_copy=yes],
1444         [glib_cv___va_copy=no])
1445 ])
1446
1447 if test "x$glib_cv_va_copy" = "xyes"; then
1448   g_va_copy_func=va_copy
1449 else if test "x$glib_cv___va_copy" = "xyes"; then
1450   g_va_copy_func=__va_copy
1451 fi
1452 fi
1453
1454 if test -n "$g_va_copy_func"; then
1455   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1456 fi
1457
1458 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1459         AC_TRY_RUN([#include <stdarg.h>
1460 #include <stdlib.h>
1461         void f (int i, ...) {
1462         va_list args1, args2;
1463         va_start (args1, i);
1464         args2 = args1;
1465         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1466           exit (1);
1467         va_end (args1); va_end (args2);
1468         }
1469         int main() {
1470           f (0, 42);
1471           return 0;
1472         }],
1473         [glib_cv_va_val_copy=yes],
1474         [glib_cv_va_val_copy=no],
1475         [glib_cv_va_val_copy=yes])
1476 ])
1477
1478 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1479   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1480 ])
1481
1482 dnl ***********************
1483 dnl *** g_module checks ***
1484 dnl ***********************
1485 G_MODULE_LIBS=
1486 G_MODULE_LIBS_EXTRA=
1487 G_MODULE_PLUGIN_LIBS=
1488 if test x"$glib_native_win32" = xyes; then
1489   dnl No use for this on Win32
1490   G_MODULE_LDFLAGS=
1491 else
1492   export SED
1493   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1494 fi
1495 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1496 G_MODULE_NEED_USCORE=0
1497 G_MODULE_BROKEN_RTLD_GLOBAL=0
1498 G_MODULE_HAVE_DLERROR=0
1499 dnl *** force native WIN32 shared lib loader
1500 if test -z "$G_MODULE_IMPL"; then
1501   case "$host" in
1502   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1503   esac
1504 fi
1505 dnl *** force native AIX library loader
1506 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1507 if test -z "$G_MODULE_IMPL"; then
1508   case "$host" in
1509   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1510   esac
1511 fi
1512 dnl *** dlopen() and dlsym() in system libraries
1513 AS_IF([ test -z "$G_MODULE_IMPL"], [
1514         AC_CHECK_FUNC(dlopen,
1515                       [AC_CHECK_FUNC(dlsym,
1516                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1517                       [])
1518 ])
1519 dnl *** load_image (BeOS)
1520 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1521   AC_CHECK_LIB(root, load_image,
1522       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1523       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1524       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1525       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1526       [])
1527 ])
1528 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1529 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1530         AC_CHECK_FUNC(NSLinkModule,
1531                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1532                        G_MODULE_NEED_USCORE=1],
1533                       [])
1534 ])
1535 dnl *** dlopen() and dlsym() in libdl
1536 AS_IF([ test -z "$G_MODULE_IMPL"], [
1537         AC_CHECK_LIB(dl, dlopen,
1538                      [AC_CHECK_LIB(dl, dlsym,
1539                                    [G_MODULE_LIBS=-ldl
1540                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1541                      [])
1542 ])
1543 dnl *** shl_load() in libdld (HP-UX)
1544 AS_IF([ test -z "$G_MODULE_IMPL"], [
1545         AC_CHECK_LIB(dld, shl_load,
1546                 [G_MODULE_LIBS=-ldld
1547                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1548                 [])
1549 ])
1550 dnl *** additional checks for G_MODULE_IMPL_DL
1551 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1552         LIBS_orig="$LIBS"
1553         LDFLAGS_orig="$LDFLAGS"
1554         LIBS="$G_MODULE_LIBS $LIBS"
1555         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1556 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1557         echo "void glib_plugin_test(void) { }" > plugin.c
1558         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1559                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1560         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1561                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1562                 -shrext ".o" -avoid-version plugin.lo \
1563                 -rpath /dont/care >/dev/null 2>&1
1564         eval `./libtool --config | grep ^objdir`
1565         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1566                 glib_cv_rtldglobal_broken,[
1567                 AC_TRY_RUN([
1568 #include <dlfcn.h>
1569 #ifndef RTLD_GLOBAL
1570 #  define RTLD_GLOBAL 0
1571 #endif
1572 #ifndef RTLD_LAZY
1573 #  define RTLD_LAZY 0
1574 #endif
1575 int glib_plugin_test;
1576 int main () {
1577     void *handle, *global, *local;
1578     global = &glib_plugin_test;
1579     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1580     if (!handle) return 0;
1581     local = dlsym (handle, "glib_plugin_test");
1582     return global == local;
1583 }                       ],
1584                         [glib_cv_rtldglobal_broken=no],
1585                         [glib_cv_rtldglobal_broken=yes],
1586                         [glib_cv_rtldglobal_broken=no])
1587                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1588                 rmdir ${objdir} 2>/dev/null
1589         ])
1590         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1591                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1592         else
1593                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1594         fi
1595 dnl *** check whether we need preceeding underscores
1596         AC_CACHE_CHECK([for preceeding underscore in symbols],
1597                 glib_cv_uscore,[
1598                 AC_TRY_RUN([#include <dlfcn.h>
1599                 int glib_underscore_test (void) { return 42; }
1600                 int main() {
1601                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1602                   handle = dlopen ((void*)0, 0);
1603                   if (handle) {
1604                     f1 = dlsym (handle, "glib_underscore_test");
1605                     f2 = dlsym (handle, "_glib_underscore_test");
1606                   } return (!f2 || f1);
1607                 }],
1608                         [glib_cv_uscore=yes],
1609                         [glib_cv_uscore=no],
1610                         [])
1611                 rm -f plugin.c plugin.$ac_objext plugin.lo
1612         ])
1613         GLIB_ASSERT_SET(glib_cv_uscore)
1614         if test "x$glib_cv_uscore" = "xyes"; then
1615                 G_MODULE_NEED_USCORE=1
1616         else
1617                 G_MODULE_NEED_USCORE=0
1618         fi
1619
1620         LDFLAGS="$LDFLAGS_orig"
1621 dnl *** check for having dlerror()
1622         AC_CHECK_FUNC(dlerror,
1623                 [G_MODULE_HAVE_DLERROR=1],
1624                 [G_MODULE_HAVE_DLERROR=0])
1625         LIBS="$LIBS_orig"
1626 ])
1627 dnl *** done, have we got an implementation?
1628 if test -z "$G_MODULE_IMPL"; then
1629         G_MODULE_IMPL=0
1630         G_MODULE_SUPPORTED=false
1631 else
1632         G_MODULE_SUPPORTED=true
1633 fi
1634
1635 AC_MSG_CHECKING(for the suffix of module shared libraries)
1636 export SED
1637 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1638 eval $shrext_cmds
1639 module=yes eval std_shrext=$shrext_cmds
1640 # chop the initial dot
1641 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1642 AC_MSG_RESULT(.$glib_gmodule_suffix)
1643 # any reason it may fail?
1644 if test "x$glib_gmodule_suffix" = x; then
1645         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1646 fi
1647
1648 AC_SUBST(G_MODULE_SUPPORTED)
1649 AC_SUBST(G_MODULE_IMPL)
1650 AC_SUBST(G_MODULE_LIBS)
1651 AC_SUBST(G_MODULE_LIBS_EXTRA)
1652 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1653 AC_SUBST(G_MODULE_LDFLAGS)
1654 AC_SUBST(G_MODULE_HAVE_DLERROR)
1655 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1656 AC_SUBST(G_MODULE_NEED_USCORE)
1657 AC_SUBST(GLIB_DEBUG_FLAGS)
1658
1659 dnl **********************
1660 dnl *** g_spawn checks ***
1661 dnl **********************
1662
1663 AC_MSG_CHECKING(for gspawn implementation)
1664 case "$host" in
1665   *-*-mingw*)
1666     GSPAWN=gspawn-win32.lo
1667     ;;
1668   *)
1669     GSPAWN=gspawn.lo
1670     ;;
1671 esac
1672 AC_MSG_RESULT($GSPAWN)
1673 AC_SUBST(GSPAWN)
1674
1675 dnl *************************
1676 dnl *** GIOChannel checks ***
1677 dnl *************************
1678
1679 AC_MSG_CHECKING(for GIOChannel implementation)
1680 case "$host" in
1681   *-*-mingw*)
1682     GIO=giowin32.lo
1683     ;;
1684   *)
1685     GIO=giounix.lo
1686     ;;
1687 esac
1688 AC_MSG_RESULT($GIO)
1689 AC_SUBST(GIO)
1690
1691 dnl *********************************
1692 dnl *** Directory for GIO modules ***
1693 dnl *********************************
1694
1695 AC_ARG_WITH(gio-module-dir,
1696            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1697                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1698            [],
1699            [with_gio_module_dir='${libdir}/gio/modules'])
1700 GIO_MODULE_DIR=$with_gio_module_dir
1701 AC_SUBST(GIO_MODULE_DIR)
1702
1703 dnl **********************************
1704 dnl *** Check for libselinux (GIO) ***
1705 dnl **********************************
1706 AC_ARG_ENABLE(selinux,
1707               AS_HELP_STRING([--disable-selinux],
1708                              [build without selinux support]))
1709 msg_selinux=no
1710 SELINUX_LIBS=
1711 AS_IF([ test "x$enable_selinux" != "xno"], [
1712
1713  AC_CHECK_LIB(selinux, is_selinux_enabled,
1714    [AC_CHECK_HEADERS(selinux/selinux.h,
1715      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1716        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1717         SELINUX_LIBS="-lselinux"
1718         msg_selinux=yes])
1719      ])
1720    ])
1721 ])
1722 AC_SUBST(SELINUX_LIBS)
1723
1724 dnl *****************************
1725 dnl ** Check for inotify (GIO) **
1726 dnl *****************************
1727 inotify_support=no
1728 AC_CHECK_HEADERS([sys/inotify.h],
1729 [
1730         inotify_support=yes
1731         AC_CHECK_FUNCS(inotify_init1)
1732 ])
1733
1734 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1735
1736 dnl ****************************
1737 dnl ** Check for kqueue (GIO) **
1738 dnl ****************************
1739 kqueue_support=no
1740 AC_CHECK_HEADERS([sys/event.h],
1741 [
1742         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1743 ])
1744
1745 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1746
1747 dnl *********************************
1748 dnl ** Check for Solaris FEN (GIO) **
1749 dnl *********************************
1750 fen_support=no
1751 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1752 #include <port.h>
1753 #ifndef PORT_SOURCE_FILE
1754 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1755 #endif
1756 int main() { return 0; } ]])],
1757 [
1758         fen_support=yes
1759 ],)
1760
1761 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1762
1763 dnl ****************************
1764 dnl *** Checks for FAM (GIO) ***
1765 dnl ****************************
1766
1767 should_disable_fam=no
1768
1769 AC_ARG_ENABLE(fam,
1770               AS_HELP_STRING([--disable-fam],
1771                              [don't use fam for file system monitoring]),
1772                          [
1773                                 if test "x$enable_fam" = "xno"; then
1774                                         should_disable_fam=yes
1775                                 fi
1776                          ]
1777                          )
1778 fam_support=no
1779 FAM_LIBS=
1780 if test "x$should_disable_fam" = "xno"; then
1781 AC_CHECK_LIB(fam, FAMOpen,
1782   [AC_CHECK_HEADERS(fam.h,
1783     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1784      AC_CHECK_LIB(fam, FAMNoExists,
1785                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1786      FAM_LIBS="-lfam"]
1787      fam_support=yes,
1788     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1789   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1790 AC_SUBST(FAM_LIBS)
1791 fi
1792 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1793
1794
1795 dnl *****************************
1796 dnl *** Check for xattr (GIO) ***
1797 dnl *****************************
1798 AC_ARG_ENABLE(xattr,
1799               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1800 msg_xattr=no
1801 XATTR_LIBS=
1802 AS_IF([ test "x$enable_xattr" != "xno"], [
1803
1804 dnl either glibc or libattr can provide xattr support
1805
1806 dnl for both of them, we check for getxattr being in
1807 dnl the library and a valid xattr header.
1808
1809 dnl try glibc
1810  AC_CHECK_LIB(c, getxattr,
1811    [AC_CHECK_HEADERS(sys/xattr.h,
1812      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1813       msg_xattr=yes])
1814    ])
1815
1816   AS_IF([ test "x$msg_xattr" != "xyes"], [
1817 dnl   failure. try libattr
1818    AC_CHECK_LIB(attr, getxattr,
1819       [AC_CHECK_HEADERS(attr/xattr.h,
1820        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1821         XATTR_LIBS="-lattr"
1822         msg_xattr=yes])
1823       ])
1824   ])
1825
1826   AS_IF([ test "x$msg_xattr" = "xyes"], [
1827     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1828     AC_TRY_COMPILE([
1829       #include <stdio.h>
1830       #ifdef HAVE_SYS_TYPES_H
1831       #include <sys/types.h>
1832       #endif
1833       #ifdef HAVE_SYS_XATTR_H
1834       #include <sys/xattr.h>
1835       #elif HAVE_ATTR_XATTR_H
1836       #include <attr/xattr.h>
1837       #endif
1838     ],
1839     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1840     [
1841       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1842       AC_MSG_RESULT([yes])
1843     ],
1844     [AC_MSG_RESULT([no])]
1845     )
1846   ])
1847 ])
1848 AC_SUBST(XATTR_LIBS)
1849
1850 dnl ************************
1851 dnl *** check for libelf ***
1852 dnl ************************
1853 AC_ARG_ENABLE(libelf,
1854               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1855 AS_IF([ test "x$enable_libelf" != "xno"],[
1856 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1857 AS_IF([ test $have_libelf = maybe ], [
1858   glib_save_LIBS=$LIBS
1859   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1860   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1861   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1862   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1863   LIBS=$glib_save_LIBS
1864
1865   if test $have_libelf != no; then
1866     LIBELF_LIBS=-lelf
1867     have_libelf=yes
1868   fi
1869 ])
1870 ])
1871
1872 if test x$have_libelf = xyes; then
1873   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1874 fi
1875
1876 dnl ****************************************
1877 dnl *** platform dependent source checks ***
1878 dnl ****************************************
1879
1880 AC_MSG_CHECKING(for platform-dependent source)
1881 case "$host" in
1882   *-*-cygwin*|*-*-mingw*)
1883     PLATFORMDEP=gwin32.lo
1884     ;;
1885   *)
1886     PLATFORMDEP=
1887     ;;
1888 esac
1889 AC_MSG_RESULT($PLATFORMDEP)
1890 AC_SUBST(PLATFORMDEP)
1891
1892 AC_MSG_CHECKING([whether to compile timeloop])
1893 case "$host" in
1894   *-*-cygwin*|*-*-mingw*|*-*-minix)
1895     enable_timeloop=no
1896     ;;
1897   *)
1898     enable_timeloop=yes
1899     ;;
1900 esac
1901 AC_MSG_RESULT($enable_timeloop)
1902 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1903
1904 AC_MSG_CHECKING([if building for some Win32 platform])
1905 case "$host" in
1906   *-*-mingw*|*-*-cygwin*)
1907     platform_win32=yes
1908     ;;
1909   *)
1910     platform_win32=no
1911     ;;
1912 esac
1913 AC_MSG_RESULT($platform_win32)
1914 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1915
1916 dnl ***********************
1917 dnl *** g_thread checks ***
1918 dnl ***********************
1919
1920 AC_ARG_WITH(threads,
1921            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1922                            [specify a thread implementation to use])],
1923            [],
1924            [with_threads=yes])
1925
1926 dnl error and warning message
1927 dnl *************************
1928
1929 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1930
1931 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1932                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1933                 compilation now, but then your programs might not work.
1934                 Please provide information on how it is done on your system."
1935
1936 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1937                  "
1938
1939 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1940                   provide information on your thread implementation."
1941
1942 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1943                 functions will not be MT-safe during their first call because
1944                 there is no working 'getpwuid_r' on your system."
1945
1946 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1947                 because there is no 'localtime_r' on your system."
1948
1949 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1950                 linking threaded applications. As GLib cannot do that
1951                 automatically, you will get an linkg error everytime you are
1952                 not using the right compiler. In that case you have to relink
1953                 with the right compiler. Ususally just '_r' is appended
1954                 to the compiler name."
1955
1956 dnl determination of thread implementation
1957 dnl ***************************************
1958
1959 AC_MSG_CHECKING(for thread implementation)
1960
1961 have_threads=no
1962 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1963         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1964         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1965         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1966         glib_save_CPPFLAGS="$CPPFLAGS"
1967         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1968         AS_IF([ test "x$have_threads" = xno], [
1969                 AC_TRY_COMPILE([#include <pthread.h>],
1970                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1971                         have_threads=posix)
1972         ])
1973         # Tru64Unix requires -pthread to find pthread.h. See #103020
1974         CPPFLAGS="$CPPFLAGS -pthread"
1975         if test "x$have_threads" = xno; then
1976         AC_TRY_COMPILE([#include <pthread.h>],
1977                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1978                        have_threads=posix)
1979         fi
1980         CPPFLAGS="$glib_save_CPPFLAGS"
1981 ])
1982 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1983         case $host in
1984                 *-*-mingw*)
1985                 have_threads=win32
1986                 ;;
1987         esac
1988 fi
1989
1990 if test "x$have_threads" = xno; then
1991         AC_MSG_RESULT(none available)
1992         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1993 else
1994         AC_MSG_RESULT($have_threads)
1995 fi
1996
1997
1998 dnl determination of G_THREAD_CFLAGS
1999 dnl ********************************
2000
2001 G_THREAD_LIBS=
2002 G_THREAD_LIBS_EXTRA=
2003 G_THREAD_CFLAGS=
2004
2005 dnl
2006 dnl Test program for basic POSIX threads functionality
2007 dnl
2008 m4_define([glib_thread_test],[
2009 #include <pthread.h>
2010 int check_me = 0;
2011 void* func(void* data) {check_me = 42; return &check_me;}
2012 int main()
2013  { pthread_t t;
2014    void *ret;
2015    pthread_create (&t, $1, func, 0);
2016    pthread_join (t, &ret);
2017    return (check_me != 42 || ret != &check_me);
2018 }])
2019
2020 AS_IF([ test x"$have_threads" = xposix], [
2021   # First we test for posix, whether -pthread or -pthreads do the trick as
2022   # both CPPFLAG and LIBS.
2023   # One of them does for most gcc versions and some other platforms/compilers
2024   # too and could be considered as the canonical way to go.
2025   case $host in
2026     *-*-cygwin*|*-*-darwin*)
2027        # skip cygwin and darwin -pthread or -pthreads test
2028        ;;
2029     *-solaris*)
2030       # These compiler/linker flags work with both Sun Studio and gcc
2031       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2032       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2033       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2034       G_THREAD_LIBS="-lpthread -lthread"
2035       ;;
2036     *)
2037       for flag in pthread pthreads mt; do
2038         glib_save_CFLAGS="$CFLAGS"
2039         CFLAGS="$CFLAGS -$flag"
2040         AC_TRY_RUN(glib_thread_test(0),
2041                    glib_flag_works=yes,
2042                    glib_flag_works=no,
2043                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2044                                    glib_flag_works=yes,
2045                                    glib_flag_works=no)])
2046         CFLAGS="$glib_save_CFLAGS"
2047         if test $glib_flag_works = yes ; then
2048            G_THREAD_CFLAGS=-$flag
2049         G_THREAD_LIBS=-$flag
2050         break;
2051         fi
2052       done
2053        ;;
2054   esac
2055 ])
2056
2057 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2058
2059   # The canonical -pthread[s] does not work. Try something different.
2060
2061   case $host in
2062         *-aix*)
2063                 if test x"$GCC" = xyes; then
2064                         # GCC 3.0 and above needs -pthread.
2065                         # Should be coverd by the case above.
2066                         # GCC 2.x and below needs -mthreads
2067                         G_THREAD_CFLAGS="-mthreads"
2068                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2069                 else
2070                         # We are probably using the aix compiler. Normaly a
2071                         # program would have to be compiled with the _r variant
2072                         # of the corresponding compiler, but we as GLib cannot
2073                         # do that: but the good news is that for compiling the
2074                         # only difference is the added -D_THREAD_SAFE compile
2075                         # option. This is according to the "C for AIX User's
2076                         # Guide".
2077                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2078                 fi
2079                 ;;
2080         *-dg-dgux*)  # DG/UX
2081                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2082                 ;;
2083         *-sysv5uw7*) # UnixWare 7
2084                 # We are not using gcc with -pthread. Catched above.
2085                 G_THREAD_CFLAGS="-Kthread"
2086                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2087                 ;;
2088         *-mingw*)
2089                 # No flag needed when using MSVCRT.DLL
2090                 G_THREAD_CFLAGS=""
2091                 ;;
2092         *)
2093                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2094                 ;;
2095   esac
2096 ])
2097
2098 # if we are not finding the localtime_r function, then we probably are
2099 # not using the proper multithread flag
2100
2101 glib_save_CPPFLAGS="$CPPFLAGS"
2102 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2103
2104 # First we test, whether localtime_r is declared in time.h
2105 # directly. Then we test whether a macro localtime_r exists, in
2106 # which case localtime_r in the test program is replaced and thus
2107 # if we still find localtime_r in the output, it is not defined as
2108 # a macro.
2109
2110 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2111   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2112                                                            localtime_r(a,b)],
2113                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2114
2115 CPPFLAGS="$glib_save_CPPFLAGS"
2116
2117 AC_MSG_CHECKING(thread related cflags)
2118 AC_MSG_RESULT($G_THREAD_CFLAGS)
2119 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2120
2121 dnl determination of G_THREAD_LIBS
2122 dnl ******************************
2123
2124 AS_IF([test x$have_threads = xposix], [
2125           glib_save_CPPFLAGS="$CPPFLAGS"
2126           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2127           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2128             case $host in
2129               *-aix*)
2130                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2131                 # probably using the aix compiler.
2132                 AC_MSG_WARN($AIX_COMPILE_INFO)
2133                 ;;
2134               *)
2135                 G_THREAD_LIBS=error
2136                 glib_save_LIBS="$LIBS"
2137                 for thread_lib in "" pthread pthread32 pthreads thread; do
2138                         if test x"$thread_lib" = x; then
2139                                 add_thread_lib=""
2140                                 IN=""
2141                         else
2142                                 add_thread_lib="-l$thread_lib"
2143                                 IN=" in -l$thread_lib"
2144                         fi
2145                         if test x"$have_threads" = xposix; then
2146                                 defattr=0
2147                         else
2148                                 defattr=pthread_attr_default
2149                         fi
2150
2151                         LIBS="$add_thread_lib $glib_save_LIBS"
2152
2153                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2154                         AC_TRY_RUN(glib_thread_test($defattr),
2155                                    glib_result=yes,
2156                                    glib_result=no,
2157                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2158                                                    glib_result=yes,
2159                                                    glib_result=no)])
2160                         AC_MSG_RESULT($glib_result)
2161
2162                         if test "$glib_result" = "yes" ; then
2163                           G_THREAD_LIBS="$add_thread_lib"
2164                           break
2165                         fi
2166                 done
2167                 if test "x$G_THREAD_LIBS" = xerror; then
2168                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2169                 fi
2170                 LIBS="$glib_save_LIBS"
2171                 ;;
2172             esac
2173           ])
2174
2175           g_threads_impl="POSIX"
2176           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2177           CPPFLAGS="$glib_save_CPPFLAGS"
2178 ], [test x$have_threads = xwin32], [
2179            g_threads_impl="WIN32"
2180 ], [
2181            g_threads_impl="NONE"
2182            G_THREAD_LIBS=error
2183 ])
2184
2185 if test "x$G_THREAD_LIBS" = xerror; then
2186         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2187 fi
2188
2189 case $host in
2190   *-*-beos*)
2191     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2192     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2193     ;;
2194   *)
2195     ;;
2196 esac
2197
2198 AC_MSG_CHECKING(thread related libraries)
2199 AC_MSG_RESULT($G_THREAD_LIBS)
2200
2201 dnl check for mt safe function variants and some posix functions
2202 dnl ************************************************************
2203
2204 glib_save_LIBS="$LIBS"
2205 # we are not doing the following for now, as this might require glib
2206 # to always be linked with the thread libs on some platforms.
2207 # LIBS="$LIBS $G_THREAD_LIBS"
2208 AC_CHECK_FUNCS(localtime_r gmtime_r)
2209 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2210         AC_CACHE_CHECK([for posix getpwuid_r],
2211                 ac_cv_func_posix_getpwuid_r,
2212                 [AC_TRY_RUN([
2213 #include <errno.h>
2214 #include <pwd.h>
2215 int main () {
2216     char buffer[10000];
2217     struct passwd pwd, *pwptr = &pwd;
2218     int error;
2219     errno = 0;
2220     error = getpwuid_r (0, &pwd, buffer,
2221                         sizeof (buffer), &pwptr);
2222    return (error < 0 && errno == ENOSYS)
2223            || error == ENOSYS;
2224 }                               ],
2225                         [ac_cv_func_posix_getpwuid_r=yes],
2226                         [ac_cv_func_posix_getpwuid_r=no])])
2227         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2228         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2229                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2230                         [Have POSIX function getpwuid_r])
2231         else
2232                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2233                         ac_cv_func_nonposix_getpwuid_r,
2234                         [AC_TRY_LINK([#include <pwd.h>],
2235                                 [char buffer[10000];
2236                                 struct passwd pwd;
2237                                 getpwuid_r (0, &pwd, buffer,
2238                                                 sizeof (buffer));],
2239                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2240                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2241                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2242                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2243                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2244                                 [Have non-POSIX function getpwuid_r])
2245                 fi
2246         fi
2247 ])
2248 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2249         AC_CACHE_CHECK([for posix getgrgid_r],
2250                 ac_cv_func_posix_getgrgid_r,
2251                 [AC_TRY_RUN([
2252 #include <errno.h>
2253 #include <grp.h>
2254 int main () {
2255     char buffer[10000];
2256     struct group grp, *grpptr = &grp;
2257     int error;
2258     errno = 0;
2259     error = getgrgid_r (0, &grp, buffer,
2260                         sizeof (buffer), &grpptr);
2261    return (error < 0 && errno == ENOSYS)
2262            || error == ENOSYS;
2263 }                              ],
2264                        [ac_cv_func_posix_getgrgid_r=yes],
2265                        [ac_cv_func_posix_getgrgid_r=no])])
2266         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2267         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2268                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2269                         [Have POSIX function getgrgid_r])
2270         ], [
2271                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2272                         ac_cv_func_nonposix_getgrgid_r,
2273                         [AC_TRY_LINK([#include <grp.h>],
2274                                 [char buffer[10000];
2275                                 struct group grp;
2276                                 getgrgid_r (0, &grp, buffer,
2277                                 sizeof (buffer));],
2278                         [ac_cv_func_nonposix_getgrgid_r=yes],
2279                         [ac_cv_func_nonposix_getgrgid_r=no])])
2280                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2281                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2282                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2283                                 [Have non-POSIX function getgrgid_r])
2284                 fi
2285         ])
2286 ])
2287 LIBS="$G_THREAD_LIBS $LIBS"
2288 AS_IF([ test x"$have_threads" = xposix], [
2289         glib_save_CPPFLAGS="$CPPFLAGS"
2290         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2291         # This is not AC_CHECK_FUNC to also work with function
2292         # name mangling in header files.
2293         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2294         AC_LINK_IFELSE(
2295             [AC_LANG_PROGRAM(
2296                 [#include <pthread.h>],
2297                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2298             [AC_MSG_RESULT(yes)
2299              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2300                 [Have function pthread_attr_setstacksize])],
2301             [AC_MSG_RESULT(no)])
2302         AC_MSG_CHECKING(for pthread_condattr_setclock)
2303         AC_LINK_IFELSE(
2304             [AC_LANG_PROGRAM(
2305                 [#include <pthread.h>],
2306                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2307             [AC_MSG_RESULT(yes)
2308              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2309                 [Have function pthread_condattr_setclock])],
2310             [AC_MSG_RESULT(no)])
2311         CPPFLAGS="$glib_save_CPPFLAGS"
2312 ])
2313
2314 LIBS="$glib_save_LIBS"
2315
2316 # now spit out all the warnings.
2317 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2318    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2319         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2320 fi
2321 if test "$ac_cv_func_localtime_r" != "yes"; then
2322         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2323 fi
2324
2325 #
2326 # Hack to deal with:
2327 #
2328 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2329 #     building shared libraries with linux.
2330 #  b) FreeBSD doesn't do this either.
2331 #
2332 case $host in
2333   *-*-freebsd*|*-*-linux*)
2334     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2335     ;;
2336   *-*-openbsd*)
2337     LDFLAGS="$LDFLAGS -pthread"
2338     ;;
2339   *)
2340     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2341     ;;
2342 esac
2343
2344 AC_SUBST(G_THREAD_CFLAGS)
2345 AC_SUBST(G_THREAD_LIBS)
2346 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2347 AC_SUBST(G_THREAD_LIBS_EXTRA)
2348
2349 AC_CHECK_FUNCS(clock_gettime, [], [
2350   AC_CHECK_LIB(rt, clock_gettime, [
2351     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2352     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2353     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2354   ])
2355 ])
2356
2357
2358 dnl ************************
2359 dnl *** g_atomic_* tests ***
2360 dnl ************************
2361
2362 dnl We need to decide at configure time if GLib will use real atomic
2363 dnl operations ("lock free") or emulated ones with a mutex.  This is
2364 dnl because we must put this information in glibconfig.h so we know if
2365 dnl it is safe or not to inline using compiler intrinsics directly from
2366 dnl the header.
2367 dnl
2368 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2369 dnl user is interested in knowing if they can use the atomic ops across
2370 dnl processes.
2371 dnl
2372 dnl We can currently support the atomic ops natively when building GLib
2373 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2374 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2375 dnl we are using GCC.
2376 dnl
2377 dnl Note that the atomic ops are only available with GCC on x86 when
2378 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2379 dnl not available but would be available given the right flags, we want
2380 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2381 dnl that then to silently fall back on emulated atomic ops just because
2382 dnl the user had the wrong build environment.
2383
2384 dnl We may add other compilers here in the future...
2385
2386 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2387   AC_TRY_COMPILE([],
2388                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2389                  [glib_cv_g_atomic_lock_free=yes],
2390                  [glib_cv_g_atomic_lock_free=no])])
2391
2392 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2393   SAVE_CFLAGS="${CFLAGS}"
2394   CFLAGS="-march=i486"
2395   AC_TRY_COMPILE([],
2396                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2397                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2398                  [])
2399   CFLAGS="${SAVE_CFLAGS}"
2400 fi
2401
2402 dnl We need a more robust approach here...
2403 case $host_cpu in
2404   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2405     glib_memory_barrier_needed=no
2406     ;;
2407   sparc*|alpha*|powerpc*|ia64)
2408     glib_memory_barrier_needed=yes
2409     ;;
2410   *)
2411     glib_memory_barrier_needed=yes
2412     ;;
2413 esac
2414
2415 dnl ************************
2416 dnl ** Check for futex(2) **
2417 dnl ************************
2418 AC_CACHE_CHECK(for futex(2) system call,
2419     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2420 #include <linux/futex.h>
2421 #include <sys/syscall.h>
2422 #include <unistd.h>
2423 ],[
2424 int
2425 main (void)
2426 {
2427   /* it is not like this actually runs or anything... */
2428   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2429   return 0;
2430 }
2431 ])],glib_cv_futex=yes,glib_cv_futex=no))
2432 if test x"$glib_cv_futex" = xyes; then
2433   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2434 fi
2435
2436 AC_CACHE_CHECK(for eventfd(2) system call,
2437     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2438 #include <sys/eventfd.h>
2439 #include <unistd.h>
2440 ],[
2441 int
2442 main (void)
2443 {
2444   eventfd (0, EFD_CLOEXEC);
2445   return 0;
2446 }
2447 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2448 if test x"$glib_cv_eventfd" = x"yes"; then
2449   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2450 fi
2451 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2452
2453 dnl ****************************************
2454 dnl *** GLib POLL* compatibility defines ***
2455 dnl ****************************************
2456
2457 glib_poll_includes=["
2458 #include <sys/types.h>
2459 #include <sys/poll.h>
2460 "]
2461
2462 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2463    test $ac_cv_header_sys_poll_h = yes ], [
2464   glib_failed=false
2465   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2466   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2467   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2468   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2469   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2470   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2471   if $glib_failed ; then
2472     AC_MSG_ERROR([Could not determine values for POLL* constants])
2473   fi
2474 ], [
2475   glib_cv_value_POLLIN=1
2476   glib_cv_value_POLLOUT=4
2477   glib_cv_value_POLLPRI=2
2478   glib_cv_value_POLLERR=8
2479   glib_cv_value_POLLHUP=16
2480   glib_cv_value_POLLNVAL=32
2481 ])
2482
2483 AC_MSG_CHECKING([for broken poll])
2484 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2485         #include <stdlib.h>
2486         #include <fcntl.h>
2487         #include <poll.h>
2488         #ifdef HAVE_SYS_POLL_H
2489         #include <sys/poll.h>
2490         #endif
2491         int main(void) {
2492           struct pollfd fds[1];
2493           int fd;
2494           fd = open("/dev/null", 1);
2495           fds[0].fd = fd;
2496           fds[0].events = POLLIN;
2497           fds[0].revents = 0;
2498           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2499                 exit(1);  /* Does not work for devices -- fail */
2500           }
2501           exit(0);
2502         }]])],
2503   [broken_poll=no],
2504   [broken_poll=yes
2505    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2506   [broken_poll="no (cross compiling)"])
2507 AC_MSG_RESULT($broken_poll)
2508
2509 dnl *********************
2510 dnl *** GRegex checks ***
2511 dnl *********************
2512
2513 PCRE_REQUIRED_VERSION=8.13
2514
2515 # Check if we should use the internal or the system-supplied pcre
2516 AC_ARG_WITH(pcre,
2517             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2518                             [whether to use system PCRE [default=internal]])])
2519
2520 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2521
2522 AS_IF([ test "x$with_pcre" = xsystem], [
2523   PKG_CHECK_MODULES(PCRE,
2524                     libpcre >= $PCRE_REQUIRED_VERSION)
2525   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2526                   glib_save_CFLAGS="$CFLAGS"
2527                   glib_save_LIBS="$LIBS"
2528                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2529                   AC_TRY_RUN([#include <pcre.h>
2530                               int main () {
2531                                 int support;
2532                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2533                                 if (!support)
2534                                   return 1;
2535                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2536                                 if (!support)
2537                                   return 1;
2538                                 return 0;
2539                               }],
2540                   glib_cv_pcre_has_unicode=yes,
2541                   glib_cv_pcre_has_unicode=no,
2542                   glib_cv_pcre_has_unicode=yes)
2543                   CFLAGS="$glib_save_CFLAGS"
2544                   LIBS="$glib_save_LIBS"
2545       ])
2546   if test "$glib_cv_pcre_has_unicode" = "no"; then
2547     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2548   fi
2549   AC_SUBST(PCRE_CFLAGS)
2550   AC_SUBST(PCRE_LIBS)
2551   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2552   PCRE_REQUIRES=libpcre
2553   AC_SUBST(PCRE_REQUIRES)
2554 ], [
2555   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2556   AS_IF([ test x"$GCC" = xyes], [
2557     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2558     save_CFLAGS="$CFLAGS"
2559     CFLAGS="$CFLAGS -Wno-pointer-sign"
2560     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2561                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2562     CFLAGS="$save_CFLAGS"
2563   ])
2564 ])
2565 AC_SUBST(PCRE_WARN_CFLAGS)
2566
2567 dnl **********************
2568 dnl *** Win32 API libs ***
2569 dnl **********************
2570
2571 case $host in
2572   *-*-cygwin*)
2573         G_LIBS_EXTRA="-luser32 -lkernel32"
2574     ;;
2575   *-*-mingw*)
2576         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2577     ;;
2578   *)
2579         G_LIBS_EXTRA=""
2580     ;;
2581 esac
2582 AC_SUBST(G_LIBS_EXTRA)
2583
2584 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2585 dnl since we need it for g_iconv()
2586
2587 AC_MSG_CHECKING([for EILSEQ])
2588 AC_TRY_COMPILE([
2589 #include <errno.h>
2590 ],
2591 [
2592 int error = EILSEQ;
2593 ], have_eilseq=yes, have_eilseq=no);
2594 AC_MSG_RESULT($have_eilseq)
2595
2596 dnl ******************************************************************
2597 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2598 dnl *** glib-compile-schemas in PATH                               ***
2599 dnl ******************************************************************
2600
2601 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2602
2603 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2604   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2605   if test x$GLIB_GENMARSHAL = xno; then
2606     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2607   fi
2608
2609   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2610   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2611     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2612   fi
2613
2614   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2615   if test x$GLIB_COMPILE_RESOURCES = xno; then
2616     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2617   fi
2618 ])
2619
2620 dnl **************************
2621 dnl *** Checks for gtk-doc ***
2622 dnl **************************
2623 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2624 # it on it's own line.
2625 m4_ifdef([GTK_DOC_CHECK], [
2626 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2627 ],[
2628 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2629 ])
2630
2631 AC_ARG_ENABLE(man,
2632               [AS_HELP_STRING([--enable-man],
2633                               [generate man pages [default=auto]])],,
2634               enable_man=maybe)
2635
2636 AS_IF([test "$enable_man" != no], [
2637   AC_PATH_PROG([XSLTPROC], [xsltproc])
2638   AS_IF([test -z "$XSLTPROC"], [
2639     AS_IF([test "$enable_man" = yes], [
2640       AC_MSG_ERROR([xsltproc is required for --enable-man])
2641     ])
2642     enable_man=no
2643   ])
2644 ])
2645
2646 AS_IF([ test "$enable_man" != no ], [
2647   dnl check for DocBook DTD in the local catalog
2648   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2649      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2650   AS_IF([test "$have_docbook_dtd" != yes], [
2651     AS_IF([test "$enable_man" = yes ], [
2652       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2653     ])
2654     enable_man=no
2655   ])
2656 ])
2657
2658 AS_IF([test "$enable_man" != no], [
2659   dnl check for DocBook XSL stylesheets in the local catalog
2660   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2661      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2662   AS_IF([ test "$have_docbook_dtd" != yes ], [
2663     AS_IF([ test "$enable_man" = yes ], [
2664       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2665     ])
2666     enable_man=no
2667   ])
2668 ])
2669
2670 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2671
2672 AC_MSG_CHECKING([whether to generate man pages])
2673 AS_IF([ test "$enable_man" != no ], [
2674   AC_MSG_RESULT([yes])
2675 ], [
2676   AC_MSG_RESULT([no])
2677 ])
2678
2679 dnl
2680 dnl Tracing
2681 dnl
2682
2683 AC_ARG_ENABLE([dtrace],
2684              [AS_HELP_STRING([--enable-dtrace],
2685                               [include tracing support for dtrace])])
2686 have_dtrace=no
2687 AC_MSG_CHECKING([whether to include dtrace tracing support])
2688 AS_IF([ test "x$enable_dtrace" != xno], [
2689   if test x$glib_have_carbon = xyes; then
2690     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2691   else
2692     AC_MSG_RESULT([yes])
2693     AC_CHECK_PROGS(DTRACE, dtrace)
2694     if test -z "$DTRACE"; then
2695       if test "x$enable_dtrace" = xyes; then
2696         AC_MSG_ERROR([dtrace not found])
2697       fi
2698     else
2699       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2700                       [if test "x$enable_dtrace" = xyes; then
2701                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2702                        fi])
2703     fi
2704   fi
2705 ], [
2706   AC_MSG_RESULT([no])
2707 ])
2708 if test "x$have_dtrace" = xyes; then
2709   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2710 fi
2711 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2712
2713 AC_MSG_CHECKING([whether to include systemtap tracing support])
2714 AC_ARG_ENABLE([systemtap],
2715              [AS_HELP_STRING([--enable-systemtap],
2716                               [include tracing support for systemtap])])
2717 have_systemtap=no
2718 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2719   have_systemtap=yes
2720 fi
2721 AC_MSG_RESULT(${have_systemtap})
2722
2723 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2724
2725 AC_ARG_WITH([tapset-install-dir],
2726             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2727                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2728             [if test "x${withval}" = x; then
2729                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2730              else
2731                ABS_TAPSET_DIR="${withval}"
2732               fi],
2733             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2734 AC_SUBST(ABS_TAPSET_DIR)
2735
2736 dnl ************************************
2737 dnl *** Enable lcov coverage reports ***
2738 dnl ************************************
2739
2740 AC_ARG_ENABLE(gcov,
2741   AS_HELP_STRING([--enable-gcov],
2742                  [enable coverage testing with gcov]),
2743   [use_gcov=$enableval], [use_gcov=no])
2744
2745 AS_IF([ test "x$use_gcov" = "xyes"], [
2746   dnl we need gcc:
2747   if test "$GCC" != "yes"; then
2748     AC_MSG_ERROR([GCC is required for --enable-gcov])
2749   fi
2750
2751   dnl Check if ccache is being used
2752   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2753   case `$SHTOOL path $CC` in
2754     *ccache*[)] gcc_ccache=yes;;
2755     *[)] gcc_ccache=no;;
2756   esac
2757
2758   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2759     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2760   fi
2761
2762   ltp_version_list="1.6 1.7 1.8 1.9"
2763   AC_CHECK_PROG(LTP, lcov, lcov)
2764   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2765
2766   AS_IF([ test "$LTP" ], [
2767     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2768       glib_cv_ltp_version=invalid
2769       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2770       for ltp_check_version in $ltp_version_list; do
2771         if test "$ltp_version" = "$ltp_check_version"; then
2772           glib_cv_ltp_version="$ltp_check_version (ok)"
2773         fi
2774       done
2775     ])
2776   ], [
2777     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2778     AC_MSG_ERROR([$ltp_msg])
2779   ])
2780
2781   case $glib_cv_ltp_version in
2782     ""|invalid[)]
2783       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2784       AC_MSG_ERROR([$ltp_msg])
2785       LTP="exit 0;"
2786       ;;
2787   esac
2788
2789   if test -z "$LTP_GENHTML"; then
2790     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2791   fi
2792
2793   dnl Remove all optimization flags from CFLAGS
2794   changequote({,})
2795   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2796   changequote([,])
2797
2798   dnl Add the special gcc flags
2799   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2800   LDFLAGS="$LDFLAGS -lgcov"
2801 ])
2802
2803 dnl ******************************
2804 dnl *** output the whole stuff ***
2805 dnl ******************************
2806
2807 dnl this section will only be run if config.status is invoked with no
2808 dnl arguments, or with "glib/glibconfig.h" as an argument.
2809 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2810 [
2811         outfile=glib/glibconfig.h-tmp
2812         cat > $outfile <<\_______EOF
2813 /* glibconfig.h
2814  *
2815  * This is a generated file.  Please modify 'configure.ac'
2816  */
2817
2818 #ifndef __GLIBCONFIG_H__
2819 #define __GLIBCONFIG_H__
2820
2821 #include <glib/gmacros.h>
2822
2823 _______EOF
2824
2825         if test x$glib_limits_h = xyes; then
2826           echo '#include <limits.h>' >> $outfile
2827         fi
2828         if test x$glib_float_h = xyes; then
2829           echo '#include <float.h>' >> $outfile
2830         fi
2831         if test x$glib_values_h = xyes; then
2832           echo '#include <values.h>' >> $outfile
2833         fi
2834         if test "$glib_header_alloca_h" = "yes"; then
2835           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2836         fi
2837         if test x$glib_sys_poll_h = xyes; then
2838           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2839         fi
2840         if test x$glib_included_printf != xyes; then
2841           echo "
2842 /* Specifies that GLib's g_print*() functions wrap the
2843  * system printf functions.  This is useful to know, for example,
2844  * when using glibc's register_printf_function().
2845  */" >> $outfile
2846           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2847         fi
2848
2849         cat >> $outfile <<_______EOF
2850
2851 G_BEGIN_DECLS
2852
2853 #define G_MINFLOAT      $glib_mf
2854 #define G_MAXFLOAT      $glib_Mf
2855 #define G_MINDOUBLE     $glib_md
2856 #define G_MAXDOUBLE     $glib_Md
2857 #define G_MINSHORT      $glib_ms
2858 #define G_MAXSHORT      $glib_Ms
2859 #define G_MAXUSHORT     $glib_Mus
2860 #define G_MININT        $glib_mi
2861 #define G_MAXINT        $glib_Mi
2862 #define G_MAXUINT       $glib_Mui
2863 #define G_MINLONG       $glib_ml
2864 #define G_MAXLONG       $glib_Ml
2865 #define G_MAXULONG      $glib_Mul
2866
2867 _______EOF
2868
2869
2870         ### this should always be true in a modern C/C++ compiler
2871         cat >>$outfile <<_______EOF
2872 typedef signed char gint8;
2873 typedef unsigned char guint8;
2874 _______EOF
2875
2876
2877         if test -n "$gint16"; then
2878           cat >>$outfile <<_______EOF
2879 typedef signed $gint16 gint16;
2880 typedef unsigned $gint16 guint16;
2881 #define G_GINT16_MODIFIER $gint16_modifier
2882 #define G_GINT16_FORMAT $gint16_format
2883 #define G_GUINT16_FORMAT $guint16_format
2884 _______EOF
2885         fi
2886
2887
2888         if test -n "$gint32"; then
2889           cat >>$outfile <<_______EOF
2890 typedef signed $gint32 gint32;
2891 typedef unsigned $gint32 guint32;
2892 #define G_GINT32_MODIFIER $gint32_modifier
2893 #define G_GINT32_FORMAT $gint32_format
2894 #define G_GUINT32_FORMAT $guint32_format
2895 _______EOF
2896         fi
2897
2898         cat >>$outfile <<_______EOF
2899 #define G_HAVE_GINT64 1          /* deprecated, always true */
2900
2901 ${glib_extension}typedef signed $gint64 gint64;
2902 ${glib_extension}typedef unsigned $gint64 guint64;
2903
2904 #define G_GINT64_CONSTANT(val)  $gint64_constant
2905 #define G_GUINT64_CONSTANT(val) $guint64_constant
2906 _______EOF
2907
2908         if test x$gint64_format != x ; then
2909           cat >>$outfile <<_______EOF
2910 #define G_GINT64_MODIFIER $gint64_modifier
2911 #define G_GINT64_FORMAT $gint64_format
2912 #define G_GUINT64_FORMAT $guint64_format
2913 _______EOF
2914         else
2915           cat >>$outfile <<_______EOF
2916 #undef G_GINT64_MODIFIER
2917 #undef G_GINT64_FORMAT
2918 #undef G_GUINT64_FORMAT
2919 _______EOF
2920         fi
2921
2922         cat >>$outfile <<_______EOF
2923
2924 #define GLIB_SIZEOF_VOID_P $glib_void_p
2925 #define GLIB_SIZEOF_LONG   $glib_long
2926 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2927
2928 _______EOF
2929
2930         cat >>$outfile <<_______EOF
2931 typedef signed $glib_size_type_define gssize;
2932 typedef unsigned $glib_size_type_define gsize;
2933 #define G_GSIZE_MODIFIER $gsize_modifier
2934 #define G_GSSIZE_FORMAT $gssize_format
2935 #define G_GSIZE_FORMAT $gsize_format
2936
2937 #define G_MAXSIZE       G_MAXU$glib_msize_type
2938 #define G_MINSSIZE      G_MIN$glib_msize_type
2939 #define G_MAXSSIZE      G_MAX$glib_msize_type
2940
2941 typedef gint64 goffset;
2942 #define G_MINOFFSET     G_MININT64
2943 #define G_MAXOFFSET     G_MAXINT64
2944
2945 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2946 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2947 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2948
2949 _______EOF
2950
2951         if test -z "$glib_unknown_void_p"; then
2952           cat >>$outfile <<_______EOF
2953
2954 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2955 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2956
2957 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2958 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2959
2960 typedef signed $glib_intptr_type_define gintptr;
2961 typedef unsigned $glib_intptr_type_define guintptr;
2962
2963 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2964 #define G_GINTPTR_FORMAT        $gintptr_format
2965 #define G_GUINTPTR_FORMAT       $guintptr_format
2966 _______EOF
2967         else
2968           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2969         fi
2970
2971
2972
2973         cat >>$outfile <<_______EOF
2974 $glib_atexit
2975 $glib_memmove
2976 $glib_defines
2977 $glib_os
2978 $glib_static_compilation
2979
2980 $glib_vacopy
2981
2982 #ifdef  __cplusplus
2983 #define G_HAVE_INLINE   1
2984 #else   /* !__cplusplus */
2985 $glib_inline
2986 #endif  /* !__cplusplus */
2987
2988 #ifdef  __cplusplus
2989 #define G_CAN_INLINE    1
2990 _______EOF
2991
2992         if test x$g_can_inline = xyes ; then
2993                 cat >>$outfile <<_______EOF
2994 #else   /* !__cplusplus */
2995 #define G_CAN_INLINE    1
2996 _______EOF
2997         fi
2998
2999         cat >>$outfile <<_______EOF
3000 #endif
3001
3002 _______EOF
3003
3004         if test x$g_have_iso_c_varargs = xyes ; then
3005                 cat >>$outfile <<_______EOF
3006 #ifndef __cplusplus
3007 # define G_HAVE_ISO_VARARGS 1
3008 #endif
3009 _______EOF
3010         fi
3011         if test x$g_have_iso_cxx_varargs = xyes ; then
3012                 cat >>$outfile <<_______EOF
3013 #ifdef __cplusplus
3014 # define G_HAVE_ISO_VARARGS 1
3015 #endif
3016 _______EOF
3017         fi
3018         if test x$g_have_gnuc_varargs = xyes ; then
3019                 cat >>$outfile <<_______EOF
3020
3021 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3022  * is passed ISO vararg support is turned off, and there is no work
3023  * around to turn it on, so we unconditionally turn it off.
3024  */
3025 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3026 #  undef G_HAVE_ISO_VARARGS
3027 #endif
3028
3029 #define G_HAVE_GNUC_VARARGS 1
3030 _______EOF
3031         fi
3032
3033         case x$g_stack_grows in
3034         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3035         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3036         esac
3037
3038
3039         echo >>$outfile
3040         if test x$g_have_eilseq = xno; then
3041                 cat >>$outfile <<_______EOF
3042 #ifndef EILSEQ
3043 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3044  * The correspondence between this and the corresponding definition
3045  * in libiconv is essential.
3046  */
3047 #  define EILSEQ ENOENT
3048 #endif
3049 _______EOF
3050
3051         fi
3052
3053         if test x$g_have_gnuc_visibility = xyes; then
3054                 cat >>$outfile <<_______EOF
3055 #define G_HAVE_GNUC_VISIBILITY 1
3056 _______EOF
3057         fi
3058                 cat >>$outfile <<_______EOF
3059 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3060 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3061 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3062 #define G_GNUC_INTERNAL __hidden
3063 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3064 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3065 #else
3066 #define G_GNUC_INTERNAL
3067 #endif
3068 _______EOF
3069
3070         echo >>$outfile
3071         cat >>$outfile <<_______EOF
3072 #define G_THREADS_ENABLED
3073 #define G_THREADS_IMPL_$g_threads_impl_def
3074 _______EOF
3075
3076         if test x"$g_memory_barrier_needed" != xno; then
3077           echo >>$outfile
3078           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3079         fi
3080         if test x"$g_atomic_lock_free" = xyes; then
3081           echo >>$outfile
3082           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3083         fi
3084         echo >>$outfile
3085         g_bit_sizes="16 32 64"
3086         for bits in $g_bit_sizes; do
3087           cat >>$outfile <<_______EOF
3088 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3089 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3090 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3091 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3092 _______EOF
3093         done
3094
3095         cat >>$outfile <<_______EOF
3096 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3097 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3098 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3099 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3100 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3101 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3102 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3103 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3104 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3105 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3106 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3107 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3108 #define G_BYTE_ORDER $g_byte_order
3109
3110 #define GLIB_SYSDEF_POLLIN =$g_pollin
3111 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3112 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3113 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3114 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3115 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3116
3117 #define G_MODULE_SUFFIX "$g_module_suffix"
3118
3119 typedef $g_pid_type GPid;
3120
3121 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3122 #define GLIB_SYSDEF_AF_INET $g_af_inet
3123 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3124
3125 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3126 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3127 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3128
3129 G_END_DECLS
3130
3131 #endif /* __GLIBCONFIG_H__ */
3132 _______EOF
3133
3134
3135         if cmp -s $outfile glib/glibconfig.h; then
3136           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3137           rm -f $outfile
3138         else
3139           mv $outfile glib/glibconfig.h
3140         fi
3141 ],[
3142
3143 # Note that if two cases are the same, case goes with the first one.
3144 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3145 # on variable expansion in case labels.  Look at the generated config.status
3146 # for a hint.
3147
3148 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3149   glib_header_alloca_h="$ac_cv_working_alloca_h"
3150 else
3151   glib_header_alloca_h="$ac_cv_header_alloca_h"
3152 fi
3153
3154 case xyes in
3155 x$ac_cv_header_float_h)
3156   glib_float_h=yes
3157   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3158   glib_md=DBL_MIN glib_Md=DBL_MAX
3159   ;;
3160 x$ac_cv_header_values_h)
3161   glib_values_h=yes
3162   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3163   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3164   ;;
3165 esac
3166
3167 case xyes in
3168 x$ac_cv_header_limits_h)
3169   glib_limits_h=yes
3170   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3171   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3172   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3173   ;;
3174 x$ac_cv_header_values_h)
3175   glib_values_h=yes
3176   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3177   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3178   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3179   ;;
3180 esac
3181
3182 if test x$ac_cv_header_sys_poll_h = xyes ; then
3183   glib_sys_poll_h=yes
3184 fi
3185
3186 if test x$enable_included_printf = xyes ; then
3187   glib_included_printf=yes
3188 fi
3189
3190 case 2 in
3191 $ac_cv_sizeof_short)
3192   gint16=short
3193   gint16_modifier='"h"'
3194   gint16_format='"hi"'
3195   guint16_format='"hu"'
3196   ;;
3197 $ac_cv_sizeof_int)
3198   gint16=int
3199   gint16_modifier='""'
3200   gint16_format='"i"'
3201   guint16_format='"u"'
3202   ;;
3203 esac
3204 case 4 in
3205 $ac_cv_sizeof_short)
3206   gint32=short
3207   gint32_modifier='"h"'
3208   gint32_format='"hi"'
3209   guint32_format='"hu"'
3210   ;;
3211 $ac_cv_sizeof_int)
3212   gint32=int
3213   gint32_modifier='""'
3214   gint32_format='"i"'
3215   guint32_format='"u"'
3216   ;;
3217 $ac_cv_sizeof_long)
3218   gint32=long
3219   gint32_modifier='"l"'
3220   gint32_format='"li"'
3221   guint32_format='"lu"'
3222   ;;
3223 esac
3224 case 8 in
3225 $ac_cv_sizeof_int)
3226   gint64=int
3227   gint64_modifier='""'
3228   gint64_format='"i"'
3229   guint64_format='"u"'
3230   glib_extension=
3231   gint64_constant='(val)'
3232   guint64_constant='(val)'
3233   ;;
3234 $ac_cv_sizeof_long)
3235   gint64=long
3236   gint64_modifier='"l"'
3237   gint64_format='"li"'
3238   guint64_format='"lu"'
3239   glib_extension=
3240   gint64_constant='(val##L)'
3241   guint64_constant='(val##UL)'
3242   ;;
3243 $ac_cv_sizeof_long_long)
3244   gint64='long long'
3245   if test -n "$glib_cv_long_long_format"; then
3246     gint64_modifier='"'$glib_cv_long_long_format'"'
3247     gint64_format='"'$glib_cv_long_long_format'i"'
3248     guint64_format='"'$glib_cv_long_long_format'u"'
3249   fi
3250   glib_extension='G_GNUC_EXTENSION '
3251   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3252   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3253   ;;
3254 $ac_cv_sizeof___int64)
3255   gint64='__int64'
3256   if test -n "$glib_cv_long_long_format"; then
3257     gint64_modifier='"'$glib_cv_long_long_format'"'
3258     gint64_format='"'$glib_cv_long_long_format'i"'
3259     guint64_format='"'$glib_cv_long_long_format'u"'
3260   fi
3261   glib_extension=
3262   gint64_constant='(val##i64)'
3263   guint64_constant='(val##ui64)'
3264   ;;
3265 esac
3266 glib_size_t=$ac_cv_sizeof_size_t
3267 glib_size_type_define="$glib_size_type"
3268 glib_void_p=$ac_cv_sizeof_void_p
3269 glib_long=$ac_cv_sizeof_long
3270
3271 case "$glib_size_type" in
3272 short)
3273   gsize_modifier='"h"'
3274   gsize_format='"hu"'
3275   gssize_format='"hi"'
3276   glib_msize_type='SHRT'
3277   ;;
3278 int)
3279   gsize_modifier='""'
3280   gsize_format='"u"'
3281   gssize_format='"i"'
3282   glib_msize_type='INT'
3283   ;;
3284 long)
3285   gsize_modifier='"l"'
3286   gsize_format='"lu"'
3287   gssize_format='"li"'
3288   glib_msize_type='LONG'
3289   ;;
3290 "long long"|__int64)
3291   gsize_modifier='"I64"'
3292   gsize_format='"I64u"'
3293   gssize_format='"I64i"'
3294   glib_msize_type='INT64'
3295   ;;
3296 esac
3297
3298 gintbits=`expr $ac_cv_sizeof_int \* 8`
3299 glongbits=`expr $ac_cv_sizeof_long \* 8`
3300 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3301
3302 case $ac_cv_sizeof_void_p in
3303 $ac_cv_sizeof_int)
3304   glib_intptr_type_define=int
3305   gintptr_modifier='""'
3306   gintptr_format='"i"'
3307   guintptr_format='"u"'
3308   glib_gpi_cast='(gint)'
3309   glib_gpui_cast='(guint)'
3310   ;;
3311 $ac_cv_sizeof_long)
3312   glib_intptr_type_define=long
3313   gintptr_modifier='"l"'
3314   gintptr_format='"li"'
3315   guintptr_format='"lu"'
3316   glib_gpi_cast='(glong)'
3317   glib_gpui_cast='(gulong)'
3318   ;;
3319 $ac_cv_sizeof_long_long)
3320   glib_intptr_type_define='long long'
3321   gintptr_modifier='"I64"'
3322   gintptr_format='"I64i"'
3323   guintptr_format='"I64u"'
3324   glib_gpi_cast='(gint64)'
3325   glib_gpui_cast='(guint64)'
3326   ;;
3327 $ac_cv_sizeof___int64)
3328   glib_intptr_type_define=__int64
3329   gintptr_modifier='"I64"'
3330   gintptr_format='"I64i"'
3331   guintptr_format='"I64u"'
3332   glib_gpi_cast='(gint64)'
3333   glib_gpui_cast='(guint64)'
3334   ;;
3335 *)
3336   glib_unknown_void_p=yes
3337   ;;
3338 esac
3339
3340
3341 case xyes in
3342 x$ac_cv_func_atexit)
3343   glib_atexit="
3344 #ifdef NeXT /* @#%@! NeXTStep */
3345 # define g_ATEXIT(proc) (!atexit (proc))
3346 #else
3347 # define g_ATEXIT(proc) (atexit (proc))
3348 #endif"
3349   ;;
3350 x$ac_cv_func_on_exit)
3351   glib_atexit="
3352 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3353   ;;
3354 esac
3355
3356 case xyes in
3357 x$ac_cv_func_memmove)
3358   glib_memmove='
3359 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3360   ;;
3361 x$glib_cv_working_bcopy)
3362   glib_memmove="
3363 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3364 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3365   ;;
3366 *)
3367   glib_memmove="
3368 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3369  * so we have to roll our own copy routine. */
3370 void g_memmove (void* dest, const void * src, unsigned long len);"
3371   ;;
3372 esac
3373
3374 glib_defines="
3375 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3376 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3377 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3378 "
3379
3380 case xyes in
3381 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3382 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3383 *)                      glib_vacopy=''
3384 esac
3385
3386 if test x$glib_cv_va_val_copy = xno; then
3387   glib_vacopy="\$glib_vacopy
3388 #define G_VA_COPY_AS_ARRAY 1"
3389 fi
3390
3391 if test x$glib_cv_hasinline = xyes; then
3392     glib_inline='#define G_HAVE_INLINE 1'
3393 fi
3394 if test x$glib_cv_has__inline = xyes; then
3395     glib_inline="\$glib_inline
3396 #define G_HAVE___INLINE 1"
3397 fi
3398 if test x$glib_cv_has__inline__ = xyes; then
3399     glib_inline="\$glib_inline
3400 #define G_HAVE___INLINE__ 1"
3401 fi
3402
3403 g_have_gnuc_varargs=$g_have_gnuc_varargs
3404 g_have_iso_c_varargs=$g_have_iso_c_varargs
3405 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3406
3407 g_can_inline=$g_can_inline
3408 g_have_gnuc_visibility=$g_have_gnuc_visibility
3409 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3410
3411 if test x$ac_cv_c_bigendian = xyes; then
3412   g_byte_order=G_BIG_ENDIAN
3413   g_bs_native=BE
3414   g_bs_alien=LE
3415 else
3416   g_byte_order=G_LITTLE_ENDIAN
3417   g_bs_native=LE
3418   g_bs_alien=BE
3419 fi
3420
3421 g_pollin=$glib_cv_value_POLLIN
3422 g_pollout=$glib_cv_value_POLLOUT
3423 g_pollpri=$glib_cv_value_POLLPRI
3424 g_pollhup=$glib_cv_value_POLLHUP
3425 g_pollerr=$glib_cv_value_POLLERR
3426 g_pollnval=$glib_cv_value_POLLNVAL
3427
3428 # If a family is not found on the system, define that family to
3429 # a negative value, picking a different one for each undefined
3430 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3431 # This is needed because glib-mkenums doesn't handle optional
3432 # values in enums, and thus we have to have all existing values
3433 # defined in the enum.
3434 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3435   g_af_unix=$glib_cv_value_AF_UNIX
3436 else
3437   g_af_unix=-1
3438 fi
3439 g_af_inet=$glib_cv_value_AF_INET
3440 g_af_inet6=$glib_cv_value_AF_INET6
3441
3442 g_msg_peek=$glib_cv_value_MSG_PEEK
3443 g_msg_oob=$glib_cv_value_MSG_OOB
3444 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3445
3446 g_stack_grows=$glib_cv_stack_grows
3447
3448 g_have_eilseq=$have_eilseq
3449
3450 g_threads_impl_def=$g_threads_impl
3451
3452 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3453 g_memory_barrier_needed="$glib_memory_barrier_needed"
3454 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3455
3456 g_module_suffix="$glib_gmodule_suffix"
3457
3458 g_pid_type="$glib_pid_type"
3459 case $host in
3460   *-*-beos*)
3461     glib_os="#define G_OS_BEOS"
3462     ;;
3463   *-*-cygwin*)
3464     glib_os="#define G_OS_UNIX
3465 #define G_PLATFORM_WIN32
3466 #define G_WITH_CYGWIN"
3467     ;;
3468   *-*-mingw*)
3469     glib_os="#define G_OS_WIN32
3470 #define G_PLATFORM_WIN32"
3471     ;;
3472   *)
3473     glib_os="#define G_OS_UNIX"
3474     ;;
3475 esac
3476 glib_static_compilation=""
3477 if test x$glib_win32_static_compilation = xyes; then
3478   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3479 #define GOBJECT_STATIC_COMPILATION 1"
3480 fi
3481 ])
3482
3483 # Redo enough to get guint32 and guint64 for the alignment checks below
3484 case 4 in
3485 $ac_cv_sizeof_short)
3486   gint32=short
3487   ;;
3488 $ac_cv_sizeof_int)
3489   gint32=int
3490   ;;
3491 $ac_cv_sizeof_long)
3492   gint32=long
3493   ;;
3494 esac
3495 case 8 in
3496 $ac_cv_sizeof_int)
3497   gint64=int
3498   ;;
3499 $ac_cv_sizeof_long)
3500   gint64=long
3501   ;;
3502 $ac_cv_sizeof_long_long)
3503   gint64='long long'
3504   ;;
3505 $ac_cv_sizeof___int64)
3506   gint64='__int64'
3507   ;;
3508 esac
3509
3510 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3511 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3512 typedef unsigned $gint32 guint32;])
3513 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3514 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3515 typedef unsigned $gint64 guint64;])
3516 AC_CHECK_TYPE([unsigned long])
3517 AC_CHECK_ALIGNOF([unsigned long])
3518
3519 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3520 #
3521 # 1.2.14 required for dbus_message_set_serial
3522 AS_IF([ test x$enable_modular_tests = xyes], [
3523    PKG_CHECK_MODULES(DBUS1,
3524                      dbus-1 >= 1.2.14,
3525                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3526                      have_dbus1=no)
3527    AC_SUBST(DBUS1_CFLAGS)
3528    AC_SUBST(DBUS1_LIBS)
3529 ])
3530 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3531
3532 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3533 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3534
3535 dnl
3536 dnl Check for -Bsymbolic-functions linker flag used to avoid
3537 dnl intra-library PLT jumps, if available.
3538 dnl
3539
3540 AC_ARG_ENABLE(Bsymbolic,
3541               [AS_HELP_STRING([--disable-Bsymbolic],
3542                               [avoid linking with -Bsymbolic])],,
3543               [SAVED_LDFLAGS="${LDFLAGS}"
3544                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3545                LDFLAGS=-Wl,-Bsymbolic-functions
3546                AC_TRY_LINK([], [int main (void) { return 0; }],
3547                            AC_MSG_RESULT(yes)
3548                            enable_Bsymbolic=yes,
3549                            AC_MSG_RESULT(no)
3550                            enable_Bsymbolic=no)
3551                LDFLAGS="${SAVED_LDFLAGS}"])
3552
3553 if test "x${enable_Bsymbolic}" = "xyes"; then
3554   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3555 fi
3556
3557 AC_SUBST(GLIB_LINK_FLAGS)
3558
3559 dnl
3560 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3561 dnl visibility attributes for symbol export control
3562 dnl
3563 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3564 case "$host" in
3565   *-*-mingw*)
3566     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3567     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3568               [defines how to decorate public symbols while building])
3569     CFLAGS="${CFLAGS} -fvisibility=hidden"
3570     ;;
3571   *)
3572     dnl on other compilers, check if we can do -fvisibility=hidden
3573     SAVED_CFLAGS="${CFLAGS}"
3574     CFLAGS="-fvisibility=hidden"
3575     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3576     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3577                    AC_MSG_RESULT(yes)
3578                    enable_fvisibility_hidden=yes,
3579                    AC_MSG_RESULT(no)
3580                    enable_fvisibility_hidden=no)
3581     CFLAGS="${SAVED_CFLAGS}"
3582
3583     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3584       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3585                 [defines how to decorate public symbols while building])
3586       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3587     ])
3588     ;;
3589 esac
3590 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3591
3592 dnl Compiler flags; macro originates from systemd
3593 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3594 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
3595    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3596    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3597    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3598    -Werror=format=2 -Werror=missing-include-dirs])
3599 CFLAGS="$with_cflags $CFLAGS"
3600
3601 #
3602 # Define variables corresponding to the correct include paths to use for
3603 # in-tree building.
3604 #
3605
3606 # for config.h:
3607 config_h_INCLUDES='-I$(top_builddir)'
3608 AC_SUBST(config_h_INCLUDES)
3609
3610 # glib:
3611 #   config.h
3612 #   $(top_builddir)/glib: for glibconfig.h
3613 #   $(top_srcdir)/glib:   for glib.h
3614 #   $(top_srcdir):        for everything
3615 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3616 AC_SUBST(glib_INCLUDES)
3617
3618 # gobject:
3619 #   same as glib
3620 gobject_INCLUDES='$(glib_INCLUDES)'
3621 AC_SUBST(gobject_INCLUDES)
3622
3623 # gmodule:
3624 #   glib includes
3625 #   $(top_srcdir)/gmodule: for gmodule.h
3626 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3627 AC_SUBST(gmodule_INCLUDES)
3628
3629 # gio:
3630 #   same as gmodule
3631 gio_INCLUDES='$(gmodule_INCLUDES)'
3632 AC_SUBST(gio_INCLUDES)
3633
3634
3635 AC_CONFIG_FILES([
3636 glib-2.0.pc
3637 gmodule-2.0.pc
3638 gmodule-export-2.0.pc
3639 gmodule-no-export-2.0.pc
3640 gthread-2.0.pc
3641 gobject-2.0.pc
3642 gio-2.0.pc
3643 gio-unix-2.0.pc
3644 gio-windows-2.0.pc
3645 glib-zip
3646 glib-gettextize
3647 Makefile
3648 build/Makefile
3649 build/win32/Makefile
3650 build/win32/dirent/Makefile
3651 build/win32/vs9/Makefile
3652 build/win32/vs10/Makefile
3653 build/win32/vs11/Makefile
3654 glib/Makefile
3655 glib/glib.stp
3656 glib/libcharset/Makefile
3657 glib/gnulib/Makefile
3658 glib/pcre/Makefile
3659 glib/update-pcre/Makefile
3660 glib/tests/Makefile
3661 gmodule/Makefile
3662 gmodule/gmoduleconf.h
3663 gobject/Makefile
3664 gobject/gobject.stp
3665 gobject/glib-mkenums
3666 gobject/tests/Makefile
3667 gthread/Makefile
3668 gio/Makefile
3669 gio/gdbus-2.0/codegen/Makefile
3670 gio/gdbus-2.0/codegen/config.py
3671 gio/gnetworking.h
3672 gio/xdgmime/Makefile
3673 gio/inotify/Makefile
3674 gio/kqueue/Makefile
3675 gio/fen/Makefile
3676 gio/fam/Makefile
3677 gio/win32/Makefile
3678 gio/tests/Makefile
3679 gio/tests/gdbus-object-manager-example/Makefile
3680 gio/tests/services/Makefile
3681 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3682 po/Makefile.in
3683 docs/Makefile
3684 docs/reference/Makefile
3685 docs/reference/glib/Makefile
3686 docs/reference/glib/version.xml
3687 docs/reference/gobject/Makefile
3688 docs/reference/gobject/version.xml
3689 docs/reference/gio/Makefile
3690 docs/reference/gio/gdbus-object-manager-example/Makefile
3691 docs/reference/gio/version.xml
3692 tests/Makefile
3693 tests/gobject/Makefile
3694 tests/refcount/Makefile
3695 m4macros/Makefile
3696 ])
3697
3698 AC_CONFIG_COMMANDS([chmod-scripts],
3699 [chmod 0755 glib-zip
3700 chmod 0755 glib-gettextize
3701 chmod 0755 gobject/glib-mkenums])
3702
3703 # we want to invoke this macro solely so that the config.status script
3704 # and automake generated makefiles know about these generated files.
3705 # They are only needed to distcheck the package
3706 if false; then
3707   AC_CONFIG_FILES([
3708     INSTALL
3709     README
3710     config.h.win32
3711     glib/glibconfig.h.win32
3712     glib/makefile.msc
3713     glib/glib.rc
3714     gmodule/makefile.msc
3715     gmodule/gmodule.rc
3716     gobject/makefile.msc
3717     gobject/gobject.rc
3718     gthread/makefile.msc
3719     gthread/gthread.rc
3720     gio/gio.rc
3721     tests/makefile.msc
3722   ])
3723 fi
3724
3725 AC_OUTPUT