configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.27.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.32
  58 GSTPB_REQ=0.10.32
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for gconftool-2
 134 dnl this macro defines an am conditional, so it needs to be run always
 135 AM_GCONF_SOURCE_2
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl check for libm, for sin()
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used by ext/wavpack
 154 AX_CREATE_STDINT_H
 155
 156 dnl used in gst/rtp/gstasteriskh263.c
 157 AC_CHECK_HEADERS([netinet/in.h])
 158 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 159 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 160
 161 dnl used in gst/udp
 162 AC_CHECK_HEADERS([sys/time.h])
 163
 164 dnl *** checks for types/defines ***
 165
 166 dnl Check for FIONREAD ioctl declaration.  This check is needed
 167 dnl for the UDP plugin to build on Solaris
 168 GST_CHECK_FIONREAD
 169
 170 dnl *** checks for structures ***
 171
 172 dnl *** checks for compiler characteristics ***
 173
 174 dnl check if we have GCC inline-asm
 175 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 176 if test x$HAVE_GCC_ASM = xyes ; then
 177   AC_DEFINE(HAVE_GCC_ASM, 1,
 178     [Define if compiler supports gcc inline assembly])
 179 fi
 180 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 181
 182 dnl *** checks for library functions ***
 183
 184 LIBS_SAVE=$LIBS
 185 LIBS="$LIBS $LIBM"
 186 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 187 LIBS=$LIBS_SAVE
 188
 189 dnl Check whether isinf() is defined by math.h
 190 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 191     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 192 if test "$ac_cv_have_isinf" = "yes"
 193 then
 194     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 195 fi
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198 AC_FUNC_MMAP
 199 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 200
 201 dnl Check for mmap (needed by electricfence plugin)
 202
 203 AC_CHECK_TYPE([struct ip_mreqn], [
 204               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 205               [#include <netinet/in.h>])
 206
 207 dnl *** checks for dependency libraries ***
 208
 209 dnl GLib is required
 210 AG_GST_GLIB_CHECK([2.20])
 211
 212 dnl Orc
 213 ORC_CHECK([0.4.11])
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 HAVE_GTK=no
 245 GTK2_REQ=2.14.0
 246 GTK3_REQ=2.91.3
 247 if test "x$BUILD_EXAMPLES" = "xyes"; then
 248   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 249   AC_ARG_WITH([gtk],
 250     AC_HELP_STRING([--with-gtk=3.0|2.0],
 251                    [which gtk+ version to compile against (default: 2.0)]),
 252     [case "$with_gtk" in
 253         2.0) GTK_REQ=$GTK2_REQ ;;
 254         3.0) GTK_REQ=$GTK3_REQ ;;
 255         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 256     esac],
 257     [with_gtk=2.0
 258      GTK_REQ=$GTK2_REQ])
 259   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 260   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 261   AC_SUBST(GTK_LIBS)
 262   AC_SUBST(GTK_CFLAGS)
 263 fi
 264 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 265
 266 dnl should we install schemas ?
 267 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 268 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 269   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 270   if test x$GCONFTOOL = xno; then
 271     AC_MSG_WARN(Not installing GConf schemas)
 272     HAVE_GCONFTOOL="no"
 273   else
 274     HAVE_GCONFTOOL="yes"
 275   fi
 276   AC_SUBST(HAVE_GCONFTOOL)
 277 ])
 278
 279 dnl *** set variables based on configure arguments ***
 280
 281 dnl set license and copyright notice
 282 GST_LICENSE="LGPL"
 283 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 284 AC_SUBST(GST_LICENSE)
 285
 286 dnl set location of plugin directory
 287 AG_GST_SET_PLUGINDIR
 288
 289 dnl set release date/time
 290 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 291   ["${srcdir}/gst-plugins-good.doap"],
 292   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 293
 294 dnl define an ERROR_CFLAGS Makefile variable
 295 dnl -Wundef: too many broken headers
 296 dnl -Waggregate-return: causes problems with ObjC code like in osxvideosink
 297 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 298         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 299         -Wwrite-strings -Wold-style-definition
 300         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 301         -Wnested-externs ])
 302
 303 dnl define an ERROR_CXXFLAGS Makefile variable
 304 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 305         -Wmissing-declarations -Wredundant-decls
 306         -Wwrite-strings
 307         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 308
 309 dnl define correct level for debugging messages
 310 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 311
 312 dnl used in examples
 313 AG_GST_DEFAULT_ELEMENTS
 314
 315 dnl *** plug-ins to include ***
 316
 317 dnl these are all the gst plug-ins, compilable without additional libs
 318 dnl videofilter is at the top because others depend on it
 319 AG_GST_CHECK_PLUGIN(videofilter)
 320 AG_GST_CHECK_PLUGIN(alpha)
 321 AG_GST_CHECK_PLUGIN(apetag)
 322 AG_GST_CHECK_PLUGIN(audiofx)
 323 AG_GST_CHECK_PLUGIN(auparse)
 324 AG_GST_CHECK_PLUGIN(autodetect)
 325 AG_GST_CHECK_PLUGIN(avi)
 326 AG_GST_CHECK_PLUGIN(cutter)
 327 AG_GST_CHECK_PLUGIN(debugutils)
 328 AG_GST_CHECK_PLUGIN(deinterlace)
 329 AG_GST_CHECK_PLUGIN(effectv)
 330 AG_GST_CHECK_PLUGIN(equalizer)
 331 AG_GST_CHECK_PLUGIN(flv)
 332 AG_GST_CHECK_PLUGIN(id3demux)
 333 AG_GST_CHECK_PLUGIN(icydemux)
 334 AG_GST_CHECK_PLUGIN(interleave)
 335 AG_GST_CHECK_PLUGIN(flx)
 336 AG_GST_CHECK_PLUGIN(goom)
 337 AG_GST_CHECK_PLUGIN(goom2k1)
 338 AG_GST_CHECK_PLUGIN(imagefreeze)
 339 AG_GST_CHECK_PLUGIN(law)
 340 AG_GST_CHECK_PLUGIN(level)
 341 AG_GST_CHECK_PLUGIN(matroska)
 342 AG_GST_CHECK_PLUGIN(monoscope)
 343 AG_GST_CHECK_PLUGIN(multifile)
 344 AG_GST_CHECK_PLUGIN(multipart)
 345 AG_GST_CHECK_PLUGIN(qtdemux)
 346 AG_GST_CHECK_PLUGIN(replaygain)
 347 AG_GST_CHECK_PLUGIN(rtp)
 348 AG_GST_CHECK_PLUGIN(rtpmanager)
 349 AG_GST_CHECK_PLUGIN(rtsp)
 350 AG_GST_CHECK_PLUGIN(shapewipe)
 351 AG_GST_CHECK_PLUGIN(smpte)
 352 AG_GST_CHECK_PLUGIN(spectrum)
 353 AG_GST_CHECK_PLUGIN(udp)
 354 AG_GST_CHECK_PLUGIN(videobox)
 355 AG_GST_CHECK_PLUGIN(videocrop)
 356 AG_GST_CHECK_PLUGIN(videomixer)
 357 AG_GST_CHECK_PLUGIN(wavenc)
 358 AG_GST_CHECK_PLUGIN(wavparse)
 359 AG_GST_CHECK_PLUGIN(y4m)
 360
 361 dnl *** checks for socket and nsl libraries ***
 362 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 363
 364 dnl disable gst plugins we might not be able to build on this
 365 dnl platform: udp and rtsp (ugly but minimally invasive)
 366 dnl FIXME: maybe move to sys
 367 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 368 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 369
 370 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 371   AG_GST_DISABLE_PLUGIN(udp)
 372   AG_GST_DISABLE_PLUGIN(rtsp)
 373 fi
 374
 375 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 376   WIN32_LIBS="-lws2_32"
 377   AC_SUBST(WIN32_LIBS)
 378 fi
 379
 380 dnl disable experimental plug-ins
 381 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 382   AG_GST_DISABLE_PLUGIN(monoscope)
 383 fi
 384
 385 dnl *** sys plug-ins ***
 386
 387 echo
 388 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 389 echo
 390
 391 dnl DirectSound
 392 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 393 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 394   HAVE_DIRECTSOUND="no"
 395   save_CFLAGS="$CFLAGS"
 396   save_LDFLAGS="$LDFLAGS"
 397   save_LIBS="$LIBS"
 398   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 399   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 400   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 401   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 402   AC_LINK_IFELSE([
 403 #include <windows.h>
 404 #include <dxerr9.h>
 405 #include <dsound.h>
 406
 407 int main ()
 408 {
 409   DXGetErrorString9 (0);
 410   DirectSoundCreate(NULL, NULL, NULL);
 411
 412   return 0;
 413 }
 414 ],
 415     [HAVE_DIRECTSOUND="yes"],
 416     [HAVE_DIRECTSOUND="no"])
 417   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 418   CFLAGS=$save_CFLAGS
 419   LDFLAGS=$save_LDFLAGS
 420   LIBS=$save_LIBS
 421
 422   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 423     dnl this is much more than we want
 424     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 425     AC_SUBST(DIRECTSOUND_CFLAGS)
 426     AC_SUBST(DIRECTSOUND_LDFLAGS)
 427     AC_SUBST(DIRECTSOUND_LIBS)
 428   fi
 429   AC_SUBST(HAVE_DIRECTSOUND)
 430 ])
 431
 432 dnl *** OSS audio *** (Linux, *BSD)
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 434 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 435  HAVE_OSS="yes"
 436 dnl Linux and newer BSD versions :
 437  AC_CHECK_HEADER(sys/soundcard.h, [
 438    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 439    ] , [
 440 dnl Some old BSD versions and also newer OpenBSD versions :
 441    AC_CHECK_HEADER(soundcard.h, [
 442      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 443      ], [
 444   dnl Some old BSD versions :
 445      AC_CHECK_HEADER(machine/soundcard.h, [
 446        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 447          [Define if OSS includes are in /machine/])
 448        ], [
 449        HAVE_OSS="no"
 450      ])
 451    ])
 452  ])
 453 ])
 454
 455 dnl *** oss4 ***
 456 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 457 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 458   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 459   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 460       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 461       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 462 ])
 463
 464 dnl *** Sun Audio ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 466 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 467   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 468 ])
 469
 470 dnl *** OSX Audio ***
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 472 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 473   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 474 ])
 475
 476 dnl *** OS X video ***
 477 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 478 HAVE_OSX_VIDEO="no"
 479 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 480   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 481 ])
 482 dnl in case header OpenGL/gl.h is found on other platforms
 483 case "$host" in
 484   *-*darwin*)
 485     dnl do nothing
 486     ;;
 487   *)
 488     HAVE_OSX_VIDEO="no"
 489     ;;
 490 esac
 491
 492
 493 dnl *** Video 4 Linux 2 ***
 494 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 495 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 496 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 497 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 498   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 499   AC_TRY_COMPILE([
 500 #include <sys/types.h>
 501 #ifdef __sun /* Solaris */
 502 #include <sys/types.h>
 503 #include <sys/videodev2.h>
 504 #else /* Linux */
 505 #include <linux/types.h>
 506 #define _LINUX_TIME_H
 507 #define __user
 508 #include <linux/videodev2.h>
 509 #endif
 510 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 511 #error too early v4l2 version or no v4l2 at all
 512 #endif
 513     ], [
 514 return 0;
 515     ], [
 516       HAVE_GST_V4L2="yes"
 517       AC_MSG_RESULT(yes)
 518     ], [
 519       HAVE_GST_V4L2="no"
 520       AC_MSG_RESULT(no)
 521
 522       HAVE_VIDEODEV=no
 523       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 524       [
 525         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 526       ])
 527
 528       if test "x$HAVE_VIDEODEV" = "xyes"; then
 529         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 530         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 531       else
 532         AC_MSG_WARN([video4linux2 was not found])
 533       fi
 534     ])
 535
 536   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 537     dnl check for missing v4l2_buffer declaration (see #135919)
 538     MISSING_DECL=0
 539     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 540     AC_TRY_COMPILE([
 541 #include <sys/types.h>
 542 #ifdef __sun /* Solaris */
 543 #include <sys/types.h>
 544 #include <sys/videodev2.h>
 545 #else /* Linux */
 546 #include <linux/types.h>
 547 #define _LINUX_TIME_H
 548 #define __user
 549 #include <linux/videodev2.h>
 550 #endif
 551     ],[
 552 struct v4l2_buffer buf;
 553 buf.index = 0;
 554 return 0;
 555     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 556     if [ test x$MISSING_DECL = x1 ]; then
 557       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 558     fi
 559
 560     dnl check for XOverlay libraries
 561     AG_GST_CHECK_XV
 562   fi
 563 ])
 564
 565 # Optional gudev for device probing
 566 AC_ARG_WITH([gudev],
 567   AC_HELP_STRING([--with-gudev],
 568     [device detection with gudev]),
 569   [],
 570   [with_gudev=check])
 571 if test x$HAVE_GST_V4L2 = xyes; then
 572   if test x$with_gudev != xno; then
 573       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 574           [ have_gudev=yes
 575             AC_DEFINE(HAVE_GUDEV, 1,
 576                [Whether gudev is available for device detection])
 577             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 578           ], [
 579           have_gudev=no
 580           ])
 581   else
 582     have_gudev=no
 583   fi
 584 fi
 585 AC_SUBST(GUDEV_CFLAGS)
 586 AC_SUBST(GUDEV_LIBS)
 587
 588 # Make libv4l2 non-automagic
 589 AC_ARG_WITH([libv4l2],
 590   AC_HELP_STRING([--with-libv4l2],
 591     [support video buffer conversion using libv4l2]),
 592   [],
 593   [with_libv4l2=check])
 594 if test x$HAVE_GST_V4L2 = xyes; then
 595   if test x$with_libv4l2 != xno; then
 596       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 597           [ have_libv4l2=yes
 598             AC_DEFINE(HAVE_LIBV4L2, 1,
 599                 [Whether libv4l2 is available for video buffer conversion])
 600           ], [
 601           have_libv4l2=no
 602           ])
 603   else
 604     have_libv4l2=no
 605   fi
 606 fi
 607
 608 dnl Check for X11
 609 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 610 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 611                   [ximagesrc], [
 612   AC_PATH_XTRA
 613
 614   dnl now try to find the HEADER
 615   ac_cflags_save="$CFLAGS"
 616   ac_cppflags_save="$CPPFLAGS"
 617   CFLAGS="$CFLAGS $X_CFLAGS"
 618   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 619   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 620
 621   if test "x$HAVE_X" = "xno"
 622   then
 623     AC_MSG_NOTICE([cannot find X11 development files])
 624   else
 625     dnl this is much more than we want
 626     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 627     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 628     dnl it does not add the libs; therefore we add them here
 629     X_LIBS="$X_LIBS -lX11"
 630     AC_SUBST(X_CFLAGS)
 631     AC_SUBST(X_LIBS)
 632
 633     dnl check for Xfixes
 634     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 635     if test "x$HAVE_XFIXES" = "xyes"
 636     then
 637         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 638     fi
 639     AC_SUBST(XFIXES_LIBS)
 640     AC_SUBST(XFIXES_CFLAGS)
 641
 642     dnl check for Xdamage
 643     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 644     if test "x$HAVE_XDAMAGE" = "xyes"
 645     then
 646         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 647     fi
 648     AC_SUBST(XDAMAGE_LIBS)
 649     AC_SUBST(XDAMAGE_CFLAGS)
 650   fi
 651   AC_SUBST(HAVE_X)
 652   CFLAGS="$ac_cflags_save"
 653   CPPFLAGS="$ac_cppflags_save"
 654 ])
 655
 656 dnl FIXME: this should be rolled into the test above, it's just an additional
 657 dnl feature of the ximagesrc plug-in
 658 dnl This is the same as in gst-plugins-base
 659 dnl check for X Shm
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 661 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 662   if test x$HAVE_X = xyes; then
 663     AC_CHECK_LIB(Xext, XShmAttach,
 664                  HAVE_XSHM="yes", HAVE_XSHM="no",
 665                  $X_LIBS)
 666     if test "x$HAVE_XSHM" = "xyes"; then
 667       XSHM_LIBS="-lXext"
 668     else
 669       dnl On AIX, it is in XextSam instead, but we still need -lXext
 670       AC_CHECK_LIB(XextSam, XShmAttach,
 671                    HAVE_XSHM="yes", HAVE_XSHM="no",
 672                    $X_LIBS)
 673       if test "x$HAVE_XSHM" = "xyes"; then
 674         XSHM_LIBS="-lXext -lXextSam"
 675       fi
 676     fi
 677   fi
 678 ], ,[
 679   AC_SUBST(HAVE_XSHM)
 680   AC_SUBST(XSHM_LIBS)
 681 ])
 682
 683 dnl for V4L2, we also need to know if we have XVIDEO
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 685 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 686                   [], [
 687   AG_GST_CHECK_XV
 688 ])
 689
 690 dnl *** ext plug-ins ***
 691 dnl keep this list sorted alphabetically !
 692
 693 if test "x$BUILD_EXTERNAL" = "xyes"; then
 694
 695 echo
 696 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 697 echo
 698
 699 dnl *** aalib ***
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 701 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 702   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 703   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 704 ])
 705
 706 dnl *** annodex ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 708 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 709   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 710 ])
 711
 712 dnl *** cairo ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 714 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 715   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 716 ])
 717
 718 dnl *** cairo-gobject ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 720 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 721   [Cairo graphics rendering gobject bindings], cairooverlay, [
 722   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 723 ])
 724
 725 dnl **** ESound ****
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 727 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 728   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 729   if test $HAVE_ESD = no
 730   then
 731     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 732     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 733   fi
 734 ])
 735
 736 dnl *** FLAC ***
 737 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 738 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 739   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 740 ])
 741
 742 dnl *** GConf ***
 743 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 744 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 745   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 746 ])
 747
 748 dnl *** GDK pixbuf ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 750 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 751   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 752 ])
 753
 754 dnl *** HAL ***
 755 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 756 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 757   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 758 ])
 759
 760 dnl *** Jack ***
 761 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 762 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 763   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 764   AC_SUBST(JACK_CFLAGS)
 765   AC_SUBST(JACK_LIBS)
 766 ])
 767
 768 dnl *** jpeg ***
 769 dnl FIXME: we could use header checks here as well IMO
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 771 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 772   AC_ARG_WITH(jpeg-mmx,
 773     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 774   OLD_LIBS="$LIBS"
 775   if test x$with_jpeg_mmx != x; then
 776     LIBS="$LIBS -L$with_jpeg_mmx"
 777   fi
 778   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 779   JPEG_LIBS="$LIBS -ljpeg-mmx"
 780   LIBS="$OLD_LIBS"
 781   if test x$HAVE_JPEG != xyes; then
 782     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 783     JPEG_LIBS="-ljpeg"
 784   fi
 785   AC_SUBST(JPEG_LIBS)
 786 ])
 787
 788 dnl *** libcaca ***
 789 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 790 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 791   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 792   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 793   if test "x$HAVE_LIBCACA" != "xyes"; then
 794     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 795     dnl see if it compilation works too, might not if we are cross-compiling
 796     if test "x$HAVE_LIBCACA" = "xyes"; then
 797       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 798                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 799     fi
 800   fi
 801 ])
 802
 803 dnl *** libdv ***
 804 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 805 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 806   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 807 ])
 808
 809 dnl *** libpng ***
 810 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 811 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 812   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 813 ])
 814
 815 dnl *** pulseaudio ***
 816 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 817 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 818
 819   dnl used in ext/pulse/pulseutil.c
 820   AC_CHECK_HEADERS([process.h])
 821
 822   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 823   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 824   if test x$HAVE_PULSE_0_9_11 = xyes; then
 825     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 826   fi
 827   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 828   if test x$HAVE_PULSE_0_9_12 = xyes; then
 829     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 830   fi
 831   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 832   if test x$HAVE_PULSE_0_9_13 = xyes; then
 833     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 834   fi
 835   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 836   if test x$HAVE_PULSE_0_9_15 = xyes; then
 837     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 838   fi
 839   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 840   if test x$HAVE_PULSE_0_9_16 = xyes; then
 841     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 842   fi
 843   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 844   if test x$HAVE_PULSE_0_9_20 = xyes; then
 845     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 846   fi
 847 ])
 848
 849 dnl *** dv1394 ***
 850 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 851 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 852   dnl first test for libraw1394 >= 2.0.0
 853   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 854   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 855   dnl now see how far we got
 856   if test x$HAVE_RAW1394 = xyes && \
 857      test x$HAVE_LIBIEC61883 = xyes; then
 858        AG_GST_CHECK_LIBHEADER(AVC1394,
 859         avc1394, avc1394_send_command, $RAW1394_LIBS,
 860         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 861        AG_GST_CHECK_LIBHEADER(ROM1394,
 862         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 863         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 864        if test x$HAVE_AVC1394 = xyes && \
 865           test x$HAVE_AVC1394 = xyes && \
 866           test x$HAVE_ROM1394 = xyes; then
 867           HAVE_DV1394=yes
 868           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 869           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 870           AC_SUBST(DV1394_CFLAGS)
 871           AC_SUBST(DV1394_LIBS)
 872         fi
 873   else
 874        if test x$HAVE_RAW1394 = xno; then
 875           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 876           AG_GST_CHECK_LIBHEADER(AVC1394,
 877            avc1394, avc1394_send_command, $RAW1394_LIBS,
 878            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 879           AG_GST_CHECK_LIBHEADER(ROM1394,
 880            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 881            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 882           if test x$HAVE_RAW1394 = xyes && \
 883              test x$HAVE_AVC1394 = xyes && \
 884              test x$HAVE_ROM1394 = xyes; then
 885              HAVE_DV1394=yes
 886              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 887              DV1394_CFLAGS="$RAW1394_CFLAGS"
 888              if test x$HAVE_LIBIEC61883 = xyes; then
 889                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 890                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 891              fi
 892              AC_SUBST(DV1394_CFLAGS)
 893              AC_SUBST(DV1394_LIBS)
 894            fi
 895          fi
 896   fi
 897 ])
 898 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 899
 900 dnl *** shout2 ***
 901 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 902 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 903   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 904   if test $HAVE_SHOUT2 = no
 905   then
 906     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 907     AC_SUBST(SHOUT2_CFLAGS)
 908     AC_SUBST(SHOUT2_LIBS)
 909   fi
 910 ])
 911
 912 dnl *** soup ***
 913 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 914 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 915   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 916     HAVE_SOUP="yes"
 917     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 918   ],[
 919     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 920       HAVE_SOUP="no"
 921       AC_MSG_RESULT(no)
 922     ])
 923   ])
 924   AC_SUBST(SOUP_CFLAGS)
 925   AC_SUBST(SOUP_LIBS)
 926 ])
 927
 928 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 929 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 930 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 931 dnl   speex_jitter.h is 1.1.x only
 932 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 933 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 934   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 935   if test $HAVE_SPEEX = no
 936   then
 937     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 938       AC_CHECK_HEADER(speex/speex_jitter.h, [
 939         dnl speex 1.1.x :
 940         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 941           dnl speex 1.1.5 or + :
 942           HAVE_SPEEX="yes"
 943           SPEEX_LIBS="-lspeex"
 944           AC_SUBST(SPEEX_CFLAGS)
 945           AC_SUBST(SPEEX_LIBS)
 946         ],[
 947           HAVE_SPEEX="no"
 948         ])
 949       ],[
 950         dnl speex 1.0.x :
 951           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 952             dnl speex 1.0.4
 953             HAVE_SPEEX="yes"
 954             SPEEX_LIBS="-lspeex"
 955             AC_SUBST(SPEEX_CFLAGS)
 956             AC_SUBST(SPEEX_LIBS)
 957
 958             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 959               [defined if speex 1.0.x API detected])
 960         ],[
 961             HAVE_SPEEX="no"
 962             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 963         ], [
 964 #include <speex/speex.h>
 965         ])
 966       ])
 967     ])
 968   fi
 969 ])
 970
 971 dnl *** taglib ***
 972 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 973 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 974   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 975   if test "x$HAVE_CXX" != "xyes"; then
 976     USE_TAGLIB=false
 977     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 978   else
 979     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 980     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 981         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 982       ], [
 983         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 984     ])
 985     AC_SUBST(TAGLIB_CXXFLAGS)
 986   fi
 987 ])
 988
 989 dnl *** wavpack ***
 990 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 991 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 992   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 993     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 994       HAVE_WAVPACK=yes
 995       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 996     ],[
 997       HAVE_WAVPACK=no
 998       AC_MSG_RESULT(no)
 999     ])
1000   ])
1001   AC_SUBST(WAVPACK_CFLAGS)
1002   AC_SUBST(WAVPACK_LIBS)
1003 ])
1004
1005 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
1006 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
1007 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
1008   AG_GST_CHECK_LIBHEADER(ZLIB,
1009     z, uncompress,, zlib.h, [
1010     HAVE_ZLIB="yes"
1011     ZLIB_LIBS="-lz"
1012     AC_SUBST(ZLIB_LIBS)
1013   ])
1014 ])
1015
1016 dnl *** matroska prefers to have bz2 ***
1017 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1018 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1019   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
1020   AC_SUBST(BZ2_LIBS)
1021 ])
1022
1023 else
1024
1025 dnl not building plugins with external dependencies,
1026 dnl but we still need to set the conditionals
1027 AM_CONDITIONAL(USE_AALIB, false)
1028 AM_CONDITIONAL(USE_ANNODEX, false)
1029 AM_CONDITIONAL(USE_BZ2, false)
1030 AM_CONDITIONAL(USE_CAIRO, false)
1031 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1032 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1033 AM_CONDITIONAL(USE_DV1394, false)
1034 AM_CONDITIONAL(USE_ESD, false)
1035 AM_CONDITIONAL(USE_FLAC, false)
1036 AM_CONDITIONAL(USE_GCONF, false)
1037 AM_CONDITIONAL(USE_GCONFTOOL, false)
1038 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1039 AM_CONDITIONAL(USE_GST_V4L2, false)
1040 AM_CONDITIONAL(USE_HAL, false)
1041 AM_CONDITIONAL(USE_JACK, false)
1042 AM_CONDITIONAL(USE_JPEG, false)
1043 AM_CONDITIONAL(USE_LIBCACA, false)
1044 AM_CONDITIONAL(USE_LIBDV, false)
1045 AM_CONDITIONAL(USE_LIBIEC61883, false)
1046 AM_CONDITIONAL(USE_LIBPNG, false)
1047 AM_CONDITIONAL(USE_OSS, false)
1048 AM_CONDITIONAL(USE_OSS4, false)
1049 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1050 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1051 AM_CONDITIONAL(USE_PULSE, false)
1052 AM_CONDITIONAL(USE_SHOUT2, false)
1053 AM_CONDITIONAL(USE_SOUP, false)
1054 AM_CONDITIONAL(USE_SPEEX, false)
1055 AM_CONDITIONAL(USE_SUNAUDIO, false)
1056 AM_CONDITIONAL(USE_TAGLIB, false)
1057 AM_CONDITIONAL(USE_WAVPACK, false)
1058 AM_CONDITIONAL(USE_X, false)
1059 AM_CONDITIONAL(USE_XSHM, false)
1060 AM_CONDITIONAL(USE_XVIDEO, false)
1061 AM_CONDITIONAL(USE_ZLIB, false)
1062
1063 fi dnl of EXT plugins
1064
1065 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1066
1067 dnl Overview:
1068 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1069 dnl GST_*:              flags shared by all built objects
1070 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1071 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1072 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1073 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1074
1075 dnl GST_OPTION_CFLAGS
1076 if test "x$USE_DEBUG" = xyes; then
1077    PROFILE_CFLAGS="-g"
1078 fi
1079 AC_SUBST(PROFILE_CFLAGS)
1080
1081 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1082   dnl Define _only_ for git (not pre-releases or releases)
1083   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1084 else
1085   DEPRECATED_CFLAGS=""
1086 fi
1087 AC_SUBST(DEPRECATED_CFLAGS)
1088
1089 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1090 dnl at make time with e.g. make ERROR_CFLAGS=""
1091 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1092 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1093 AC_SUBST(GST_OPTION_CFLAGS)
1094 AC_SUBST(GST_OPTION_CXXFLAGS)
1095
1096 dnl our libraries need to be versioned correctly
1097 AC_SUBST(GST_LT_LDFLAGS)
1098
1099 dnl FIXME: do we want to rename to GST_ALL_* ?
1100 dnl prefer internal headers to already installed ones
1101 dnl also add builddir include for enumtypes and marshal
1102 dnl add ERROR_CFLAGS, but overridable
1103 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1104 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1105 AC_SUBST(GST_CFLAGS)
1106 AC_SUBST(GST_CXXFLAGS)
1107 AC_SUBST(GST_LIBS)
1108
1109 dnl LDFLAGS really should only contain flags, not libs - they get added before
1110 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1111 GST_ALL_LDFLAGS="-no-undefined"
1112 AC_SUBST(GST_ALL_LDFLAGS)
1113
1114 dnl this really should only contain flags, not libs - they get added before
1115 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1116 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1117 AC_SUBST(GST_PLUGIN_LDFLAGS)
1118
1119 dnl *** output files ***
1120
1121 dnl keep this alphabetic per directory, please
1122 AC_CONFIG_FILES(
1123 Makefile
1124 gst/Makefile
1125 gst/alpha/Makefile
1126 gst/apetag/Makefile
1127 gst/audiofx/Makefile
1128 gst/auparse/Makefile
1129 gst/autodetect/Makefile
1130 gst/avi/Makefile
1131 gst/cutter/Makefile
1132 gst/deinterlace/Makefile
1133 gst/debugutils/Makefile
1134 gst/effectv/Makefile
1135 gst/equalizer/Makefile
1136 gst/flv/Makefile
1137 gst/id3demux/Makefile
1138 gst/icydemux/Makefile
1139 gst/imagefreeze/Makefile
1140 gst/interleave/Makefile
1141 gst/goom/Makefile
1142 gst/goom2k1/Makefile
1143 gst/law/Makefile
1144 gst/level/Makefile
1145 gst/matroska/Makefile
1146 gst/monoscope/Makefile
1147 gst/multifile/Makefile
1148 gst/multipart/Makefile
1149 gst/qtdemux/Makefile
1150 gst/replaygain/Makefile
1151 gst/rtp/Makefile
1152 gst/rtpmanager/Makefile
1153 gst/rtsp/Makefile
1154 gst/shapewipe/Makefile
1155 gst/smpte/Makefile
1156 gst/spectrum/Makefile
1157 gst/udp/Makefile
1158 gst/videobox/Makefile
1159 gst/videocrop/Makefile
1160 gst/videofilter/Makefile
1161 gst/videomixer/Makefile
1162 gst/wavenc/Makefile
1163 gst/wavparse/Makefile
1164 gst/flx/Makefile
1165 gst/y4m/Makefile
1166 ext/Makefile
1167 ext/aalib/Makefile
1168 ext/annodex/Makefile
1169 ext/cairo/Makefile
1170 ext/dv/Makefile
1171 ext/esd/Makefile
1172 ext/flac/Makefile
1173 ext/gconf/Makefile
1174 ext/gdk_pixbuf/Makefile
1175 ext/hal/Makefile
1176 ext/jack/Makefile
1177 ext/jpeg/Makefile
1178 ext/libcaca/Makefile
1179 ext/libpng/Makefile
1180 ext/pulse/Makefile
1181 ext/raw1394/Makefile
1182 ext/shout2/Makefile
1183 ext/soup/Makefile
1184 ext/speex/Makefile
1185 ext/taglib/Makefile
1186 ext/wavpack/Makefile
1187 sys/Makefile
1188 sys/directsound/Makefile
1189 sys/oss/Makefile
1190 sys/oss4/Makefile
1191 sys/osxaudio/Makefile
1192 sys/osxvideo/Makefile
1193 sys/sunaudio/Makefile
1194 sys/v4l2/Makefile
1195 sys/waveform/Makefile
1196 sys/ximage/Makefile
1197 po/Makefile.in
1198 tests/Makefile
1199 tests/check/Makefile
1200 tests/examples/Makefile
1201 tests/examples/audiofx/Makefile
1202 tests/examples/cairo/Makefile
1203 tests/examples/equalizer/Makefile
1204 tests/examples/jack/Makefile
1205 tests/examples/level/Makefile
1206 tests/examples/pulse/Makefile
1207 tests/examples/rtp/Makefile
1208 tests/examples/shapewipe/Makefile
1209 tests/examples/spectrum/Makefile
1210 tests/examples/v4l2/Makefile
1211 tests/files/Makefile
1212 tests/icles/Makefile
1213 gconf/Makefile
1214 gconf/gstreamer.schemas
1215 common/Makefile
1216 common/m4/Makefile
1217 m4/Makefile
1218 docs/Makefile
1219 docs/plugins/Makefile
1220 docs/version.entities
1221 pkgconfig/Makefile
1222 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1223 gst-plugins-good.spec
1224 )
1225
1226 dnl Create the config.h file for Visual Studio builds
1227 dnl Beware of spaces and /'s in some of the shell variable contents.
1228 sed \
1229     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1230     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1231     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1232     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1233     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1234     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1235     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1236     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1237     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1238     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1239     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1240     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1241     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1242     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1243     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1244     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1245     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1246     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1247     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1248     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1249     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1250     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1251     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1252     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1253     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1254     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1255     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1256     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1257     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1258     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1259     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1260     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1261     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1262     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1263     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1264     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1265     config.h.in >win32/common/config.h-new
1266
1267 AC_OUTPUT
1268
1269 AG_GST_OUTPUT_PLUGINS
1270 ORC_OUTPUT
1271