configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.28,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 19, 2, 19)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.28
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130 AC_PROG_CXX
 131
 132 dnl determine if c++ is available on this system
 133 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 134
 135 dnl determine c++ preprocessor
 136 dnl FIXME: do we need this ?
 137 AC_PROG_CXXCPP
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 143 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 144
 145 dnl check for gobject-introspection
 146 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 147
 148 dnl check for documentation tools
 149 GTK_DOC_CHECK([1.3])
 150 AS_PATH_PYTHON([2.1])
 151 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 152
 153 dnl *** checks for libraries ***
 154
 155 dnl libm, for sin() etc.
 156 AC_CHECK_LIBM
 157 AC_SUBST(LIBM)
 158
 159 dnl *** checks for header files ***
 160
 161 dnl check if we have ANSI C header files
 162 AC_HEADER_STDC
 163
 164 dnl used in gst/ffmpegcolorspace/mem.c
 165 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 166 AC_CHECK_HEADERS([malloc.h])
 167
 168 ac_cppflags_save="$CPPFLAGS"
 169 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 170 AC_COMPILE_IFELSE(
 171   AC_LANG_PROGRAM([
 172 #include <libxml/HTMLparser.h>
 173                      ],[
 174 #ifndef LIBXML_HTML_ENABLED
 175 #error libxml2 has no HTML support
 176 #endif /* LIBXML_HTML_ENABLED */
 177                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 178 CPPFLAGS="$ac_cppflags_save"
 179 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 180
 181 dnl used in gst/tcp
 182 AC_CHECK_HEADERS([sys/socket.h],
 183   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 184 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 185
 186 dnl used in gst-libs/gst/rtsp
 187 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 188 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 189   WIN32_LIBS="-lws2_32"
 190   AC_SUBST(WIN32_LIBS)
 191 fi
 192
 193 dnl check for hstrerror, for gst-libs/gst/rtsp
 194 save_libs="$LIBS"
 195 AC_CHECK_FUNC(hstrerror, ,
 196     AC_CHECK_LIB(resolv, hstrerror, ,
 197         [AC_DEFINE(NO_HSTRERROR, 1,
 198              [Define if you have no native hstrerror() function.])]))
 199 HSTRERROR_LIBS=$LIBS
 200 AC_SUBST(HSTRERROR_LIBS)
 201 LIBS="$save_libs"
 202
 203 dnl used in gst-libs/gst/pbutils and associated unit test
 204 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 205
 206 dnl ffmpegcolorspace includes _stdint.h
 207 dnl also, Windows does not have long long
 208 AX_CREATE_STDINT_H
 209
 210 dnl *** checks for functions ***
 211 AC_CHECK_FUNCS([localtime_r gmtime_r])
 212
 213 dnl *** checks for math functions ***
 214 LIBS_SAVE=$LIBS
 215 LIBS="$LIBS $LIBM"
 216 AC_CHECK_FUNCS(cbrt)
 217 LIBS=$LIBS_SAVE
 218
 219 dnl *** checks for types/defines ***
 220
 221 dnl Check for FIONREAD ioctl declaration
 222 dnl used in gst/tcp
 223 GST_CHECK_FIONREAD
 224
 225 dnl *** checks for structures ***
 226
 227 dnl *** checks for compiler characteristics ***
 228
 229 dnl *** checks for library functions ***
 230
 231 dnl check for fseeko()
 232 AC_FUNC_FSEEKO
 233
 234 dnl Check for fast float to int casting as defined in C99
 235 dnl used in gst-libs/gst/floatcast/floatcast.h
 236 save_libs=$LIBS
 237 LIBS="$LIBS $LIBM"
 238 AC_C99_FUNC_LRINT
 239 AC_C99_FUNC_LRINTF
 240 LIBS=$save_libs
 241
 242 dnl Check for a way to display the function name in debug output
 243 AG_GST_CHECK_FUNCTION
 244
 245 dnl *** checks for socket and nsl libraries ***
 246 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 247 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 248
 249 dnl *** checks for dependency libraries ***
 250
 251 dnl GLib is required
 252 AG_GST_GLIB_CHECK([2.18])
 253
 254 dnl liboil is required
 255 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 256 if test "x$HAVE_LIBOIL" != "xyes"; then
 257   AC_ERROR([liboil-0.3.14 or later is required])
 258 fi
 259
 260 dnl checks for gstreamer
 261 dnl uninstalled is selected preferentially -- see pkg-config(1)
 262 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 263 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 264 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 265 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 266 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 267 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 268
 269 dnl Check for documentation xrefs
 270 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 271 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 272 AC_SUBST(GLIB_PREFIX)
 273 AC_SUBST(GST_PREFIX)
 274
 275 dnl GTK is optional and only used in examples
 276 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.14.0, HAVE_GTK=yes, HAVE_GTK=no)
 277 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 278
 279 dnl some examples need gtk+-x11
 280 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.14.0,
 281     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 282 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 283
 284 dnl QT is optional and only used in examples
 285 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 286   HAVE_QT_GV=yes
 287   HAVE_QT=yes
 288 ], [
 289   HAVE_QT_GV=no
 290   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 291 ])
 292 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 293 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 294
 295 dnl *** set variables based on configure arguments ***
 296
 297 dnl set license and copyright notice
 298 GST_LICENSE="LGPL"
 299 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 300 AC_SUBST(GST_LICENSE)
 301
 302 dnl set location of plugin directory
 303 AG_GST_SET_PLUGINDIR
 304
 305 dnl define an ERROR_CFLAGS Makefile variable
 306 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 307
 308 dnl define an ERROR_CXXFLAGS Makefile variable
 309 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT)
 310
 311 dnl define correct level for debugging messages
 312 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 313
 314 dnl used in examples
 315 AG_GST_DEFAULT_ELEMENTS
 316
 317 dnl behaviour of speex based audio resampler
 318 AC_MSG_CHECKING(which audio resample format to use for integer)
 319 AC_ARG_WITH([audioresample_format],
 320         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 321         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 322 AC_MSG_RESULT($ac_cv_audioresample_format)
 323 case $ac_cv_audioresample_format in
 324   int)
 325     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 326     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 327   ;;
 328   float)
 329     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 330     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 331   ;;
 332   auto)
 333     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 334     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 335 esac
 336 AM_CONDITIONAL(AUDIORESAMPLE_NEEDS_LIBOIL, test "$ac_cv_audioresample_format" = "auto")
 337
 338 dnl *** plug-ins to include ***
 339
 340 dnl these are all the gst plug-ins, compilable without additional libs
 341 AG_GST_CHECK_PLUGIN(adder)
 342 AG_GST_CHECK_PLUGIN(app)
 343 AG_GST_CHECK_PLUGIN(audioconvert)
 344 AG_GST_CHECK_PLUGIN(audiorate)
 345 AG_GST_CHECK_PLUGIN(audiotestsrc)
 346 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 347 AG_GST_CHECK_PLUGIN(gdp)
 348 AG_GST_CHECK_PLUGIN(playback)
 349 AG_GST_CHECK_PLUGIN(audioresample)
 350 AG_GST_CHECK_PLUGIN(subparse)
 351 AG_GST_CHECK_PLUGIN(tcp)
 352 AG_GST_CHECK_PLUGIN(typefind)
 353 AG_GST_CHECK_PLUGIN(videotestsrc)
 354 AG_GST_CHECK_PLUGIN(videorate)
 355 AG_GST_CHECK_PLUGIN(videoscale)
 356 AG_GST_CHECK_PLUGIN(volume)
 357
 358 dnl check for gstreamer core features (subsystems)
 359 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 360 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 361 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 362
 363 dnl disable plug-ins that require libxml2's HTML support if it is not available
 364 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 365   AG_GST_DISABLE_PLUGIN(subparse)
 366 fi
 367
 368 dnl disable plug-ins that require sys/socket.h if it is not available
 369 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 370   AG_GST_DISABLE_PLUGIN(tcp)
 371 fi
 372
 373 dnl iso-codes is optional, used by libgsttag
 374 AC_ARG_ENABLE(iso-codes,
 375 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 376 [case "${enableval}" in
 377   yes) enable_iso_codes=yes ;;
 378   no)  enable_iso_codes=no ;;
 379   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 380 esac
 381 ],
 382 [enable_iso_codes=yes]) dnl Default value
 383
 384 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 385 if test "x$enable_iso_codes" = "xyes"; then
 386   AC_MSG_RESULT([yes])
 387   have_iso_codes=no
 388   AC_MSG_CHECKING([whether iso-codes are available on this system])
 389   if $PKG_CONFIG iso-codes; then
 390     AC_MSG_RESULT([yes])
 391     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 392     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 393       AC_MSG_RESULT([yes])
 394       AC_MSG_CHECKING([for iso-codes prefix])
 395       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 396       if test -d "$ISO_CODES_PREFIX"; then
 397         AC_MSG_RESULT([yes])
 398         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 399         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 400         ISO_639_DOMAIN="iso_639"
 401         AC_MSG_CHECKING([ISO_639_DOMAIN])
 402         AC_MSG_RESULT([$ISO_639_DOMAIN])
 403         have_iso_codes=yes
 404         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 405         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 406         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 407         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 408       else
 409         AC_MSG_RESULT([no])
 410       fi
 411     else
 412       AC_MSG_RESULT([no])
 413     fi
 414   else
 415     AC_MSG_RESULT([no])
 416   fi
 417   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 418 else
 419   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 420   AM_CONDITIONAL(USE_ISO_CODES, false)
 421 fi
 422
 423 dnl *** sys plug-ins ***
 424
 425 echo
 426 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 427 echo
 428
 429 dnl *** X11 ***
 430 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 431 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 432                   [ximagesink], [
 433   AC_PATH_XTRA
 434   ac_cflags_save="$CFLAGS"
 435   ac_cppflags_save="$CPPFLAGS"
 436   CFLAGS="$CFLAGS $X_CFLAGS"
 437   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 438
 439   dnl now try to find the HEADER
 440   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 441
 442   if test "x$HAVE_X" = "xno"
 443   then
 444     AC_MSG_NOTICE([cannot find X11 development files])
 445   else
 446     dnl this is much more than we want
 447     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 448     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 449     dnl it does not add the libs; therefore we add them here
 450     X_LIBS="$X_LIBS -lX11"
 451     AC_SUBST(X_CFLAGS)
 452     AC_SUBST(X_LIBS)
 453   fi
 454   AC_SUBST(HAVE_X)
 455   CFLAGS="$ac_cflags_save"
 456   CPPFLAGS="$ac_cppflags_save"
 457 ])
 458
 459 dnl Check for Xv extension
 460 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 461 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 462                   [xvimagesink], [
 463   AG_GST_CHECK_XV
 464 ])
 465
 466 dnl check for X Shm
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 468 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 469   if test x$HAVE_X = xyes; then
 470     AC_CHECK_LIB(Xext, XShmAttach,
 471                  HAVE_XSHM="yes", HAVE_XSHM="no",
 472                  $X_LIBS)
 473     if test "x$HAVE_XSHM" = "xyes"; then
 474       XSHM_LIBS="-lXext"
 475     else
 476       dnl On AIX, it is in XextSam instead, but we still need -lXext
 477       AC_CHECK_LIB(XextSam, XShmAttach,
 478                    HAVE_XSHM="yes", HAVE_XSHM="no",
 479                    $X_LIBS)
 480       if test "x$HAVE_XSHM" = "xyes"; then
 481         XSHM_LIBS="-lXext -lXextSam"
 482       fi
 483     fi
 484   fi
 485 ], , [
 486   AC_SUBST(HAVE_XSHM)
 487   AC_SUBST(XSHM_LIBS)
 488 ])
 489
 490 dnl v4l/v4l2 checks have been moved down because they require X
 491
 492 dnl *** Video 4 Linux ***
 493 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 494 dnl renamed to GST_V4L in accordance with V4L2 below
 495 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 496 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 497   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 498 #include <sys/types.h>
 499 #define _LINUX_TIME_H
 500 #define __user
 501 #include <linux/videodev.h>
 502   ])
 503
 504   dnl we can build v4l without Xv, but then we won't have XOverlay support
 505   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 506   then
 507     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 508     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 509   fi
 510 ])
 511
 512 # Optional gudev for device probing
 513 AC_ARG_WITH([gudev],
 514   AC_HELP_STRING([--with-gudev],
 515     [device detection with gudev]),
 516   [],
 517   [with_gudev=check])
 518 if test x$HAVE_GST_V4L = xyes; then
 519   if test x$with_gudev != xno; then
 520       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 521           [ have_gudev=yes
 522             AC_DEFINE(HAVE_GUDEV, 1,
 523                [Whether gudev is available for device detection])
 524             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 525           ], [
 526           have_gudev=no
 527           ])
 528   else
 529     have_gudev=no
 530   fi
 531 fi
 532 AC_SUBST(GUDEV_CFLAGS)
 533 AC_SUBST(GUDEV_LIBS)
 534
 535 dnl *** ext plug-ins ***
 536 dnl keep this list sorted alphabetically !
 537
 538 if test "x$BUILD_EXTERNAL" = "xyes"; then
 539
 540 echo
 541 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 542 echo
 543
 544 dnl *** alsa ***
 545 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 546 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 547   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 548     HAVE_ALSA="yes"
 549     AC_SUBST(ALSA_CFLAGS)
 550     AC_SUBST(ALSA_LIBS)
 551   ], [
 552     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 553   ])
 554 ])
 555
 556 dnl *** CDParanoia ***
 557 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 558 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 559   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 560                       cdda_open, -lm,
 561                       cdda_interface.h,
 562                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 563                       HEADER_DIR="no"
 564                       FOUND_CDPARANOIA="yes")
 565   if test "x$FOUND_CDPARANOIA" != "xyes";
 566   then
 567     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 568                         cdda_open, -lm,
 569                         cdda/cdda_interface.h,
 570                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 571                         HEADER_DIR="yes"
 572                         FOUND_CDPARANOIA="yes")
 573   fi
 574   if test "x$HEADER_DIR" = "xyes";
 575   then
 576     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 577                        defined if cdda headers are in a cdda/ directory)
 578   fi
 579   if test "x$FOUND_CDPARANOIA" = "xyes";
 580   then
 581     AC_CHECK_LIB(cdda_paranoia,
 582                  paranoia_cachemodel_size,
 583                  : ,
 584                  HAVE_CDPARANOIA=no)
 585   fi
 586
 587   AC_SUBST(CDPARANOIA_LIBS)
 588 ])
 589 dnl FIXME : add second check somehow if that is necessary
 590 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 591 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 592
 593 dnl *** GNOME VFS ***
 594 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 595 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 596   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 597       HAVE_GNOME_VFS="yes"
 598       AC_SUBST(GNOME_VFS_CFLAGS)
 599       AC_SUBST(GNOME_VFS_LIBS)
 600       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 601       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 602              [The GnomeVFS modules directory.])
 603     ],[
 604       HAVE_GNOME_VFS="no"
 605     ]
 606     )
 607 ])
 608
 609 dnl *** ivorbis ***
 610 dnl AM_PATH_IVORBIS only takes two options
 611 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 612 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 613   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 614   if test $HAVE_IVORBIS = no
 615   then
 616     IVORBIS_LIBS=
 617     IVORBIS_CFLAGS=
 618     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 619       [IVORBIS_LIBS=-lvorbisidec
 620       HAVE_IVORBIS=yes
 621       case $host in
 622       arm-*-*)
 623         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 624       esac
 625       ],
 626       HAVE_IVORBIS=no)
 627     AC_SUBST(IVORBIS_LIBS)
 628     AC_SUBST(IVORBIS_CFLAGS)
 629   fi
 630 ])
 631
 632 dnl *** libgio ***
 633 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 634 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 635   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 636     HAVE_GIO="yes"
 637     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 638     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 639            [The GIO modules directory.])
 640     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 641     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 642            [The GIO library directory.])
 643   ], [
 644     HAVE_GIO="no"
 645     AC_MSG_RESULT(no)
 646   ])
 647   AC_SUBST(GIO_CFLAGS)
 648   AC_SUBST(GIO_LIBS)
 649   AC_SUBST(GIO_LDFLAGS)
 650 ])
 651
 652 dnl *** libvisual ***
 653 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 654 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 655   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 656   if test $HAVE_LIBVISUAL = no
 657   then
 658     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 659     if test x$HAVE_LIBVISUAL == xyes; then
 660       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 661     fi
 662   else
 663     if test x$HAVE_LIBVISUAL == xyes; then
 664       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 665     fi
 666   fi
 667   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 668   if test x$LIBVIS_PLUGINSDIR != x; then
 669     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 670         "$LIBVIS_PLUGINSDIR",
 671         [directory in which the detected libvisual's plugins are located])
 672   fi
 673 ])
 674
 675 dnl *** ogg ***
 676 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 677 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 678   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 679   if test $HAVE_OGG = no
 680   then
 681     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 682     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 683   fi
 684 ])
 685
 686 dnl *** pango ***
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 688 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 689   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 690 ])
 691
 692 dnl *** theora ***
 693 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 694 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 695   dnl theora uses pkg-config version incorrectly, for pkg-config:
 696   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 697   dnl theoraenc and theoradec appeared in 1.0beta3
 698
 699   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 700 ])
 701
 702 dnl *** vorbis ***
 703 dnl AM_PATH_VORBIS only takes two options
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 705 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 706   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 707   if test $HAVE_VORBIS = no
 708   then
 709     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 710     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 711   fi
 712 ])
 713
 714 if test "x$HAVE_VORBIS" = "xyes"; then
 715   ac_cflags_save="$CFLAGS"
 716   AC_COMPILE_IFELSE(
 717     AC_LANG_PROGRAM([
 718 #include <vorbis/codec.h>
 719                      ],[
 720 vorbis_dsp_state *v;
 721
 722 vorbis_synthesis_restart (v);
 723                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 724   if test "x$HAVE_VSR" = "xyes"; then
 725     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 726                        [defined if vorbis_synthesis_restart is present])
 727   fi
 728   CFLAGS="$ac_cflags_save"
 729 fi
 730
 731 else
 732
 733 dnl not building plugins with external dependencies,
 734 dnl but we still need to set the conditionals
 735 AM_CONDITIONAL(USE_ALSA, false)
 736 AM_CONDITIONAL(USE_CDPARANOIA, false)
 737 AM_CONDITIONAL(USE_GNOME_VFS, false)
 738 AM_CONDITIONAL(USE_GIO, false)
 739 AM_CONDITIONAL(USE_LIBVISUAL, false)
 740 AM_CONDITIONAL(USE_OGG, false)
 741 AM_CONDITIONAL(USE_PANGO, false)
 742 AM_CONDITIONAL(USE_THEORA, false)
 743 AM_CONDITIONAL(USE_VORBIS, false)
 744
 745 fi dnl of EXT plugins
 746
 747 dnl seeking needs freetype, so check for it here
 748 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 749   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 750 ])
 751 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 752 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 753 AC_SUBST(FT2_CFLAGS)
 754 AC_SUBST(FT2_LIBS)
 755
 756 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 757
 758 dnl Overview:
 759 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 760 dnl GST_*:              flags shared by built objects to link against GStreamer
 761 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 762 dnl                          (compare to other modules) or for i18n
 763 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 764 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 765 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 766 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 767
 768 dnl GST_OPTION_CFLAGS
 769 if test "x$USE_DEBUG" = xyes; then
 770    PROFILE_CFLAGS="-g"
 771 fi
 772 AC_SUBST(PROFILE_CFLAGS)
 773
 774 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 775   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 776   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 777 else
 778   DEPRECATED_CFLAGS=""
 779 fi
 780 AC_SUBST(DEPRECATED_CFLAGS)
 781
 782 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 783 dnl at make time with e.g. make ERROR_CFLAGS=""
 784 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 785 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 786 AC_SUBST(GST_OPTION_CFLAGS)
 787 AC_SUBST(GST_OPTION_CXXFLAGS)
 788
 789 dnl our libraries need to be versioned correctly
 790 AC_SUBST(GST_LT_LDFLAGS)
 791
 792 dnl GST_PLUGINS_BASE_CFLAGS
 793 dnl prefer internal headers to already installed ones
 794 dnl also add builddir include for enumtypes and marshal
 795 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 796 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 797
 798 dnl FIXME: do we want to rename to GST_ALL_* ?
 799 dnl add GST_OPTION_CFLAGS, but overridable
 800 GST_CXXFLAGS="$GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 801 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 802 AC_SUBST(GST_CFLAGS)
 803 AC_SUBST(GST_CXXFLAGS)
 804 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 805 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 806 AC_SUBST(GST_LIBS)
 807
 808 dnl LDFLAGS really should only contain flags, not libs - they get added before
 809 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 810 GST_ALL_LDFLAGS="-no-undefined"
 811 AC_SUBST(GST_ALL_LDFLAGS)
 812
 813 dnl GST_LIB_LDFLAGS
 814 dnl linker flags shared by all libraries
 815 dnl LDFLAGS modifier defining exported symbols from built libraries
 816 dnl (export _gst_foo but not __gst_foo)
 817 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 818 AC_SUBST(GST_LIB_LDFLAGS)
 819
 820 dnl this really should only contain flags, not libs - they get added before
 821 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 822 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 823 AC_SUBST(GST_PLUGIN_LDFLAGS)
 824
 825 SHAVE_INIT([common],[enable])
 826
 827 dnl *** output files ***
 828
 829 AC_CONFIG_FILES(
 830 Makefile
 831 common/shave
 832 common/shave-libtool
 833 gst-plugins-base.spec
 834 gst/Makefile
 835 gst/adder/Makefile
 836 gst/app/Makefile
 837 gst/audioconvert/Makefile
 838 gst/audiorate/Makefile
 839 gst/audiotestsrc/Makefile
 840 gst/ffmpegcolorspace/Makefile
 841 gst/gdp/Makefile
 842 gst/playback/Makefile
 843 gst/audioresample/Makefile
 844 gst/subparse/Makefile
 845 gst/tcp/Makefile
 846 gst/typefind/Makefile
 847 gst/videotestsrc/Makefile
 848 gst/videorate/Makefile
 849 gst/videoscale/Makefile
 850 gst/volume/Makefile
 851 sys/Makefile
 852 sys/ximage/Makefile
 853 sys/xvimage/Makefile
 854 sys/v4l/Makefile
 855 ext/Makefile
 856 ext/alsa/Makefile
 857 ext/cdparanoia/Makefile
 858 ext/gnomevfs/Makefile
 859 ext/gio/Makefile
 860 ext/libvisual/Makefile
 861 ext/ogg/Makefile
 862 ext/pango/Makefile
 863 ext/theora/Makefile
 864 ext/vorbis/Makefile
 865 gst-libs/Makefile
 866 gst-libs/gst/Makefile
 867 gst-libs/gst/audio/Makefile
 868 gst-libs/gst/app/Makefile
 869 gst-libs/gst/cdda/Makefile
 870 gst-libs/gst/fft/Makefile
 871 gst-libs/gst/floatcast/Makefile
 872 gst-libs/gst/interfaces/Makefile
 873 gst-libs/gst/netbuffer/Makefile
 874 gst-libs/gst/riff/Makefile
 875 gst-libs/gst/rtp/Makefile
 876 gst-libs/gst/rtsp/Makefile
 877 gst-libs/gst/sdp/Makefile
 878 gst-libs/gst/tag/Makefile
 879 gst-libs/gst/pbutils/Makefile
 880 gst-libs/gst/video/Makefile
 881 tools/Makefile
 882 pkgconfig/Makefile
 883 pkgconfig/gstreamer-audio.pc
 884 pkgconfig/gstreamer-audio-uninstalled.pc
 885 pkgconfig/gstreamer-app.pc
 886 pkgconfig/gstreamer-app-uninstalled.pc
 887 pkgconfig/gstreamer-cdda.pc
 888 pkgconfig/gstreamer-cdda-uninstalled.pc
 889 pkgconfig/gstreamer-fft.pc
 890 pkgconfig/gstreamer-fft-uninstalled.pc
 891 pkgconfig/gstreamer-floatcast.pc
 892 pkgconfig/gstreamer-floatcast-uninstalled.pc
 893 pkgconfig/gstreamer-interfaces.pc
 894 pkgconfig/gstreamer-interfaces-uninstalled.pc
 895 pkgconfig/gstreamer-netbuffer.pc
 896 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 897 pkgconfig/gstreamer-pbutils.pc
 898 pkgconfig/gstreamer-pbutils-uninstalled.pc
 899 pkgconfig/gstreamer-riff.pc
 900 pkgconfig/gstreamer-riff-uninstalled.pc
 901 pkgconfig/gstreamer-rtp.pc
 902 pkgconfig/gstreamer-rtp-uninstalled.pc
 903 pkgconfig/gstreamer-rtsp.pc
 904 pkgconfig/gstreamer-rtsp-uninstalled.pc
 905 pkgconfig/gstreamer-sdp.pc
 906 pkgconfig/gstreamer-sdp-uninstalled.pc
 907 pkgconfig/gstreamer-tag.pc
 908 pkgconfig/gstreamer-tag-uninstalled.pc
 909 pkgconfig/gstreamer-video.pc
 910 pkgconfig/gstreamer-video-uninstalled.pc
 911 pkgconfig/gstreamer-plugins-base.pc
 912 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 913 tests/Makefile
 914 tests/check/Makefile
 915 tests/examples/Makefile
 916 tests/examples/app/Makefile
 917 tests/examples/dynamic/Makefile
 918 tests/examples/overlay/Makefile
 919 tests/examples/seek/Makefile
 920 tests/examples/volume/Makefile
 921 tests/examples/snapshot/Makefile
 922 tests/examples/gio/Makefile
 923 tests/examples/v4l/Makefile
 924 tests/icles/Makefile
 925 docs/Makefile
 926 docs/design/Makefile
 927 docs/libs/Makefile
 928 docs/plugins/Makefile
 929 docs/version.entities
 930 po/Makefile.in
 931 common/Makefile
 932 common/m4/Makefile
 933 m4/Makefile
 934 )
 935
 936 dnl Create the config.h file for Visual Studio builds
 937 dnl Beware of spaces and /'s in some of the shell variable contents.
 938 sed \
 939     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 940     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 941     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 942     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 943     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 944     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 945     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 946     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 947     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 948     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 949     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 950     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 951     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 952     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 953     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 954     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 955     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 956     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 957     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 958     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 959     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 960     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 961     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 962     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 963     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 964     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 965     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 966     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 967     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 968     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 969     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 970     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 971     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 972     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 973     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 974     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
 975     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 976     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 977     config.h.in >win32/common/config.h-new
 978
 979
 980
 981 AC_OUTPUT
 982
 983 AG_GST_OUTPUT_PLUGINS