configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.38
  32 LIBDRM_INTEL_REQUIRED=2.4.37
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  35 DRI2PROTO_REQUIRED=2.6
  36 GLPROTO_REQUIRED=1.4.14
  37 LIBDRM_XORG_REQUIRED=2.4.24
  38 LIBKMS_XORG_REQUIRED=1.0.0
  39
  40 dnl Check for progs
  41 AC_PROG_CPP
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44 AM_PROG_CC_C_O
  45 AM_PROG_AS
  46 AC_CHECK_PROGS([MAKE], [gmake make])
  47 AC_CHECK_PROGS([PYTHON2], [python2 python])
  48 AC_PROG_SED
  49 AC_PROG_MKDIR_P
  50 AC_PATH_PROG([MKDEP], [makedepend])
  51
  52 if test "x$MKDEP" = "x"; then
  53     AC_MSG_ERROR([makedepend is required to build Mesa])
  54 fi
  55
  56 AC_PROG_YACC
  57 AC_PATH_PROG([YACC_INST], $YACC)
  58 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  59     if test -z "$YACC_INST"; then
  60         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  61     fi
  62 fi
  63 AC_PROG_LEX
  64
  65 AC_PATH_PROG([PERL], [perl])
  66
  67 AC_CHECK_PROG(INDENT, indent, indent, cat)
  68 if test "x$INDENT" != "xcat"; then
  69     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  70 fi
  71
  72 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  73 dnl configuration in that case.
  74 AC_PROG_INSTALL
  75 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122
 123 MKDEP_OPTIONS=-fdepend
 124 dnl Ask gcc where it's keeping its secret headers
 125 if test "x$GCC" = xyes; then
 126     for dir in include include-fixed; do
 127         GCC_INCLUDES=`$CC -print-file-name=$dir`
 128         if test "x$GCC_INCLUDES" != x && \
 129            test "$GCC_INCLUDES" != "$dir" && \
 130            test -d "$GCC_INCLUDES"; then
 131             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 132         fi
 133     done
 134 fi
 135 AC_SUBST([MKDEP_OPTIONS])
 136
 137 dnl Make sure the pkg-config macros are defined
 138 m4_ifndef([PKG_PROG_PKG_CONFIG],
 139     [m4_fatal([Could not locate the pkg-config autoconf macros.
 140   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 141   are in a different location, try setting the environment variable
 142   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 143 PKG_PROG_PKG_CONFIG()
 144
 145 dnl LIB_DIR - library basename
 146 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 147 AC_SUBST([LIB_DIR])
 148
 149 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 150 _SAVE_LDFLAGS="$LDFLAGS"
 151 _SAVE_CPPFLAGS="$CPPFLAGS"
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DPTHREADS"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     CFLAGS="$CFLAGS -Wall -std=c99"
 171
 172     # Enable -Werror=implicit-function-declaration and
 173     # -Werror=missing-prototypes, if available, or otherwise, just
 174     # -Wmissing-prototypes.  This is particularly useful to avoid
 175     # generating a loadable driver module that has undefined symbols.
 176     save_CFLAGS="$CFLAGS"
 177     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 178     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 179     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 180     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 181                    AC_MSG_RESULT([yes]),
 182                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 183                     AC_MSG_RESULT([no])]);
 184
 185     # Enable -fvisibility=hidden if using a gcc that supports it
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 188     VISIBILITY_CFLAGS="-fvisibility=hidden"
 189     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 191                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 192
 193     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 194     CFLAGS=$save_CFLAGS
 195
 196     # Work around aliasing bugs - developers should comment this out
 197     CFLAGS="$CFLAGS -fno-strict-aliasing"
 198
 199     # gcc's builtin memcmp is slower than glibc's
 200     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 201     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 202 fi
 203 if test "x$GXX" = xyes; then
 204     CXXFLAGS="$CXXFLAGS -Wall"
 205
 206     # Enable -fvisibility=hidden if using a gcc that supports it
 207     save_CXXFLAGS="$CXXFLAGS"
 208     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 209     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 210     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 211     AC_LANG_PUSH([C++])
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 213                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 214     AC_LANG_POP([C++])
 215
 216     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 217     CXXFLAGS=$save_CXXFLAGS
 218
 219     # Work around aliasing bugs - developers should comment this out
 220     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 221
 222     # gcc's builtin memcmp is slower than glibc's
 223     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 224     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 225 fi
 226
 227 dnl even if the compiler appears to support it, using visibility attributes isn't
 228 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 229 case "$host_os" in
 230 cygwin*)
 231     VISIBILITY_CFLAGS=""
 232     VISIBILITY_CXXFLAGS=""
 233     ;;
 234 esac
 235
 236 AC_SUBST([VISIBILITY_CFLAGS])
 237 AC_SUBST([VISIBILITY_CXXFLAGS])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 dnl
 287 dnl mklib options
 288 dnl
 289 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 290 if test "$enable_static" = yes; then
 291     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 292 fi
 293 AC_SUBST([MKLIB_OPTIONS])
 294
 295 dnl
 296 dnl other compiler options
 297 dnl
 298 AC_ARG_ENABLE([debug],
 299     [AS_HELP_STRING([--enable-debug],
 300         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 301     [enable_debug="$enableval"],
 302     [enable_debug=no]
 303 )
 304 if test "x$enable_debug" = xyes; then
 305     DEFINES="$DEFINES -DDEBUG"
 306     if test "x$GCC" = xyes; then
 307         CFLAGS="$CFLAGS -g"
 308     fi
 309     if test "x$GXX" = xyes; then
 310         CXXFLAGS="$CXXFLAGS -g"
 311     fi
 312 fi
 313
 314 dnl
 315 dnl library names
 316 dnl
 317 LIB_PREFIX_GLOB='lib'
 318 LIB_VERSION_SEPARATOR='.'
 319 if test "$enable_static" = yes; then
 320     LIB_EXTENSION='a'
 321 else
 322     case "$host_os" in
 323     darwin* )
 324         LIB_EXTENSION='dylib' ;;
 325     cygwin* )
 326         dnl prefix can be 'cyg' or 'lib'
 327         LIB_PREFIX_GLOB='???'
 328         LIB_VERSION_SEPARATOR='-'
 329         LIB_EXTENSION='dll' ;;
 330     aix* )
 331         LIB_EXTENSION='a' ;;
 332     * )
 333         LIB_EXTENSION='so' ;;
 334     esac
 335 fi
 336 AC_ARG_WITH([gl-lib-name],
 337   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 338     [specify GL library name @<:@default=GL@:>@])],
 339   [GL_LIB=$withval],
 340   [GL_LIB=GL])
 341 AC_ARG_WITH([glu-lib-name],
 342   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 343     [specify GLU library name @<:@default=GLU@:>@])],
 344   [GLU_LIB=$withval],
 345   [GLU_LIB=GLU])
 346 AC_ARG_WITH([osmesa-lib-name],
 347   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 348     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 349   [OSMESA_LIB=$withval],
 350   [OSMESA_LIB=OSMesa])
 351 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 352 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 353 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 354
 355 dnl
 356 dnl Mangled Mesa support
 357 dnl
 358 AC_ARG_ENABLE([mangling],
 359   [AS_HELP_STRING([--enable-mangling],
 360     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 361   [enable_mangling="${enableval}"],
 362   [enable_mangling=no]
 363 )
 364 if test "x${enable_mangling}" = "xyes" ; then
 365   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 366   GL_LIB="Mangled${GL_LIB}"
 367   GLU_LIB="Mangled${GLU_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([GLU_LIB])
 372 AC_SUBST([OSMESA_LIB])
 373
 374 dnl
 375 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 376 dnl
 377 AC_ARG_ENABLE([texture-float],
 378     [AS_HELP_STRING([--enable-texture-float],
 379         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 380     [enable_texture_float="$enableval"],
 381     [enable_texture_float=no]
 382 )
 383 if test "x$enable_texture_float" = xyes; then
 384     AC_MSG_WARN([Floating-point textures enabled.])
 385     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 386     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 387 fi
 388
 389 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 390 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 391 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 392 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 393 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 394 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 395 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 396 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 397
 398 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406
 407 AC_SUBST([GL_LIB_NAME])
 408 AC_SUBST([GLU_LIB_NAME])
 409 AC_SUBST([OSMESA_LIB_NAME])
 410 AC_SUBST([EGL_LIB_NAME])
 411 AC_SUBST([GLESv1_CM_LIB_NAME])
 412 AC_SUBST([GLESv2_LIB_NAME])
 413 AC_SUBST([VG_LIB_NAME])
 414 AC_SUBST([GLAPI_LIB_NAME])
 415
 416 AC_SUBST([GL_LIB_GLOB])
 417 AC_SUBST([GLU_LIB_GLOB])
 418 AC_SUBST([EGL_LIB_GLOB])
 419 AC_SUBST([GLESv1_CM_LIB_GLOB])
 420 AC_SUBST([GLESv2_LIB_GLOB])
 421 AC_SUBST([VG_LIB_GLOB])
 422 AC_SUBST([GLAPI_LIB_GLOB])
 423
 424 dnl
 425 dnl Arch/platform-specific settings
 426 dnl
 427 AC_ARG_ENABLE([asm],
 428     [AS_HELP_STRING([--disable-asm],
 429         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 430     [enable_asm="$enableval"],
 431     [enable_asm=yes]
 432 )
 433 asm_arch=""
 434 MESA_ASM_FILES=""
 435 AC_MSG_CHECKING([whether to enable assembly])
 436 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 437 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 438 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 439     case "$host_cpu" in
 440     i?86 | x86_64)
 441         enable_asm=no
 442         AC_MSG_RESULT([no, cross compiling])
 443         ;;
 444     esac
 445 fi
 446 # check for supported arches
 447 if test "x$enable_asm" = xyes; then
 448     case "$host_cpu" in
 449     i?86)
 450         case "$host_os" in
 451         linux* | *freebsd* | dragonfly* | *netbsd*)
 452             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 453             ;;
 454         esac
 455         ;;
 456     x86_64)
 457         case "$host_os" in
 458         linux* | *freebsd* | dragonfly* | *netbsd*)
 459             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 460             ;;
 461         esac
 462         ;;
 463     sparc*)
 464         case "$host_os" in
 465         linux*)
 466             asm_arch=sparc
 467             ;;
 468         esac
 469         ;;
 470     esac
 471
 472     case "$asm_arch" in
 473     x86)
 474         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 475         MESA_ASM_FILES='$(X86_FILES)'
 476         AC_MSG_RESULT([yes, x86])
 477         ;;
 478     x86_64)
 479         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 480         MESA_ASM_FILES='$(X86_64_FILES)'
 481         AC_MSG_RESULT([yes, x86_64])
 482         ;;
 483     sparc)
 484         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 485         MESA_ASM_FILES='$(SPARC_FILES)'
 486         AC_MSG_RESULT([yes, sparc])
 487         ;;
 488     *)
 489         AC_MSG_RESULT([no, platform not supported])
 490         ;;
 491     esac
 492 fi
 493 AC_SUBST([MESA_ASM_FILES])
 494
 495 dnl PIC code macro
 496 MESA_PIC_FLAGS
 497
 498 dnl Check to see if dlopen is in default libraries (like Solaris, which
 499 dnl has it in libc), or if libdl is needed to get it.
 500 AC_CHECK_FUNC([dlopen], [],
 501     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 502 AC_SUBST([DLOPEN_LIBS])
 503
 504 dnl See if posix_memalign is available
 505 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 506
 507 dnl SELinux awareness.
 508 AC_ARG_ENABLE([selinux],
 509     [AS_HELP_STRING([--enable-selinux],
 510         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 511     [MESA_SELINUX="$enableval"],
 512     [MESA_SELINUX=no])
 513 if test "x$enable_selinux" = "xyes"; then
 514     AC_CHECK_HEADER([selinux/selinux.h],[],
 515                     [AC_MSG_ERROR([SELinux headers not found])])
 516     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 517                  [AC_MSG_ERROR([SELinux library not found])])
 518     SELINUX_LIBS="-lselinux"
 519     DEFINES="$DEFINES -DMESA_SELINUX"
 520 fi
 521
 522 dnl Options for APIs
 523 AC_ARG_ENABLE([opengl],
 524     [AS_HELP_STRING([--disable-opengl],
 525         [disable support for standard OpenGL API @<:@default=no@:>@])],
 526     [enable_opengl="$enableval"],
 527     [enable_opengl=yes])
 528 AC_ARG_ENABLE([gles1],
 529     [AS_HELP_STRING([--enable-gles1],
 530         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 531     [enable_gles1="$enableval"],
 532     [enable_gles1=no])
 533 AC_ARG_ENABLE([gles2],
 534     [AS_HELP_STRING([--enable-gles2],
 535         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 536     [enable_gles2="$enableval"],
 537     [enable_gles2=no])
 538 AC_ARG_ENABLE([openvg],
 539     [AS_HELP_STRING([--enable-openvg],
 540         [enable support for OpenVG API @<:@default=no@:>@])],
 541     [enable_openvg="$enableval"],
 542     [enable_openvg=no])
 543
 544 AC_ARG_ENABLE([dri],
 545     [AS_HELP_STRING([--enable-dri],
 546         [enable DRI modules @<:@default=enabled@:>@])],
 547     [enable_dri="$enableval"],
 548     [enable_dri=yes])
 549 AC_ARG_ENABLE([glx],
 550     [AS_HELP_STRING([--enable-glx],
 551         [enable GLX library @<:@default=enabled@:>@])],
 552     [enable_glx="$enableval"],
 553     [enable_glx=yes])
 554 AC_ARG_ENABLE([osmesa],
 555     [AS_HELP_STRING([--enable-osmesa],
 556         [enable OSMesa library @<:@default=disabled@:>@])],
 557     [enable_osmesa="$enableval"],
 558     [enable_osmesa=no])
 559 AC_ARG_ENABLE([egl],
 560     [AS_HELP_STRING([--disable-egl],
 561         [disable EGL library @<:@default=enabled@:>@])],
 562     [enable_egl="$enableval"],
 563     [enable_egl=yes])
 564
 565 AC_ARG_ENABLE([xorg],
 566     [AS_HELP_STRING([--enable-xorg],
 567         [enable support for X.Org DDX API @<:@default=no@:>@])],
 568     [enable_xorg="$enableval"],
 569     [enable_xorg=no])
 570 AC_ARG_ENABLE([xa],
 571     [AS_HELP_STRING([--enable-xa],
 572         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 573     [enable_xa="$enableval"],
 574     [enable_xa=no])
 575 AC_ARG_ENABLE([d3d1x],
 576     [AS_HELP_STRING([--enable-d3d1x],
 577         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 578     [enable_d3d1x="$enableval"],
 579     [enable_d3d1x=no])
 580 AC_ARG_ENABLE([gbm],
 581    [AS_HELP_STRING([--enable-gbm],
 582          [enable gbm library @<:@default=auto@:>@])],
 583    [enable_gbm="$enableval"],
 584    [enable_gbm=auto])
 585
 586 AC_ARG_ENABLE([xvmc],
 587    [AS_HELP_STRING([--enable-xvmc],
 588          [enable xvmc library @<:@default=auto@:>@])],
 589    [enable_xvmc="$enableval"],
 590    [enable_xvmc=auto])
 591 AC_ARG_ENABLE([vdpau],
 592    [AS_HELP_STRING([--enable-vdpau],
 593          [enable vdpau library @<:@default=auto@:>@])],
 594    [enable_vdpau="$enableval"],
 595    [enable_vdpau=auto])
 596 AC_ARG_ENABLE([va],
 597    [AS_HELP_STRING([--enable-va],
 598          [enable va library @<:@default=auto@:>@])],
 599    [enable_va="$enableval"],
 600    [enable_va=auto])
 601 AC_ARG_ENABLE([opencl],
 602    [AS_HELP_STRING([--enable-opencl],
 603          [enable OpenCL library @<:@default=no@:>@])],
 604    [enable_opencl="$enableval"],
 605    [enable_opencl=no])
 606 AC_ARG_ENABLE([xlib_glx],
 607     [AS_HELP_STRING([--enable-xlib-glx],
 608         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 609     [enable_xlib_glx="$enableval"],
 610     [enable_xlib_glx=no])
 611 AC_ARG_ENABLE([gallium_egl],
 612     [AS_HELP_STRING([--enable-gallium-egl],
 613         [enable optional EGL state tracker (not required
 614          for EGL support in Gallium with OpenGL and OpenGL ES)
 615          @<:@default=disable@:>@])],
 616     [enable_gallium_egl="$enableval"],
 617     [enable_gallium_egl=no])
 618 AC_ARG_ENABLE([gallium_gbm],
 619     [AS_HELP_STRING([--enable-gallium-gbm],
 620         [enable optional gbm state tracker (not required for
 621          gbm support in Gallium)
 622          @<:@default=auto@:>@])],
 623     [enable_gallium_gbm="$enableval"],
 624     [enable_gallium_gbm=auto])
 625
 626 AC_ARG_ENABLE([r600-llvm-compiler],
 627     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 628         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 629     [enable_r600_llvm="$enableval"],
 630     [enable_r600_llvm=no])
 631
 632 AC_ARG_ENABLE([gallium_tests],
 633     [AS_HELP_STRING([--enable-gallium-tests],
 634         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 635     [enable_gallium_tests="$enableval"],
 636     [enable_gallium_tests=no])
 637
 638 # Option for Gallium drivers
 639 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 640
 641 AC_ARG_WITH([gallium-drivers],
 642     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 643         [comma delimited Gallium drivers list, e.g.
 644         "i915,nouveau,r300,r600,svga,swrast"
 645         @<:@default=r300,r600,swrast@:>@])],
 646     [with_gallium_drivers="$withval"],
 647     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 648
 649 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 650 # here so that the script doesn't choke on an unknown driver name later.
 651 case "$with_gallium_drivers" in
 652     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 653     no) with_gallium_drivers='' ;;
 654 esac
 655
 656 if test "x$enable_opengl" = xno -a \
 657         "x$enable_gles1" = xno -a \
 658         "x$enable_gles2" = xno -a \
 659         "x$enable_openvg" = xno -a \
 660         "x$enable_xorg" = xno -a \
 661         "x$enable_xa" = xno -a \
 662         "x$enable_d3d1x" = xno -a \
 663         "x$enable_xvmc" = xno -a \
 664         "x$enable_vdpau" = xno -a \
 665         "x$enable_va" = xno -a \
 666         "x$enable_opencl" = xno; then
 667     AC_MSG_ERROR([at least one API should be enabled])
 668 fi
 669
 670 API_DEFINES=""
 671 if test "x$enable_opengl" = xno; then
 672     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 673 else
 674     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 675 fi
 676 if test "x$enable_gles1" = xyes; then
 677     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 678 fi
 679 if test "x$enable_gles2" = xyes; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 681 fi
 682 AC_SUBST([API_DEFINES])
 683
 684 if test "x$enable_glx" = xno; then
 685     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 686     enable_xlib_glx=no
 687 fi
 688
 689 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 690     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 691 fi
 692
 693 # Disable GLX if DRI and Xlib-GLX are not enabled
 694 if test "x$enable_glx" = xyes -a \
 695         "x$enable_dri" = xno -a \
 696         "x$enable_xlib_glx" = xno; then
 697     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 698     enable_glx=no
 699 fi
 700
 701 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 702
 703 AC_ARG_ENABLE([shared-glapi],
 704     [AS_HELP_STRING([--enable-shared-glapi],
 705         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 706     [enable_shared_glapi="$enableval"],
 707     [enable_shared_glapi="$enable_dri"])
 708
 709 # Shared GLAPI is only useful for DRI
 710 if test "x$enable_dri" = xno; then
 711     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 712     enable_shared_glapi=no
 713 fi
 714
 715 # TODO: Get rid of SHARED_GLAPI variable
 716 SHARED_GLAPI="0"
 717 if test "x$enable_shared_glapi" = xyes; then
 718     SHARED_GLAPI="1"
 719     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 720     # the remap table)
 721     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 722     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 723 fi
 724 AC_SUBST([SHARED_GLAPI])
 725 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 726
 727 dnl
 728 dnl Driver specific build directories
 729 dnl
 730
 731 dnl this variable will be prepended to SRC_DIRS and is not exported
 732 CORE_DIRS=""
 733
 734 SRC_DIRS="gtest"
 735 GLU_DIRS="sgi"
 736 GALLIUM_DIRS="auxiliary drivers state_trackers"
 737 GALLIUM_TARGET_DIRS=""
 738 GALLIUM_WINSYS_DIRS="sw"
 739 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 740 GALLIUM_STATE_TRACKERS_DIRS=""
 741
 742 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 743 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 744 x*yes*)
 745     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 746     ;;
 747 esac
 748
 749 # build glapi if OpenGL is enabled
 750 if test "x$enable_opengl" = xyes; then
 751     CORE_DIRS="$CORE_DIRS mapi/glapi"
 752 fi
 753
 754 # build es1api if OpenGL ES 1.x is enabled
 755 if test "x$enable_gles1" = xyes; then
 756     CORE_DIRS="$CORE_DIRS mapi/es1api"
 757 fi
 758
 759 # build es2api if OpenGL ES 2.x is enabled
 760 if test "x$enable_gles2" = xyes; then
 761     CORE_DIRS="$CORE_DIRS mapi/es2api"
 762 fi
 763
 764 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 765 case "x$enable_opengl$enable_gles1$enable_gles2" in
 766 x*yes*)
 767     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 768     ;;
 769 esac
 770
 771 case "x$enable_glx$enable_xlib_glx" in
 772 xyesyes)
 773     DRIVER_DIRS="$DRIVER_DIRS x11"
 774     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 775     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 776     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 777     HAVE_WINSYS_XLIB="yes"
 778     ;;
 779 xyesno)
 780     # DRI-based GLX
 781     SRC_DIRS="$SRC_DIRS glx"
 782     ;;
 783 esac
 784
 785 if test "x$enable_dri" = xyes; then
 786     DRIVER_DIRS="$DRIVER_DIRS dri"
 787
 788     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 789     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 790     HAVE_ST_DRI="yes"
 791 fi
 792
 793 if test "x$enable_osmesa" = xyes; then
 794     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 795 fi
 796
 797 AC_SUBST([SRC_DIRS])
 798 AC_SUBST([GLU_DIRS])
 799 AC_SUBST([DRIVER_DIRS])
 800 AC_SUBST([GALLIUM_DIRS])
 801 AC_SUBST([GALLIUM_TARGET_DIRS])
 802 AC_SUBST([GALLIUM_WINSYS_DIRS])
 803 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 804 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 805 AC_SUBST([MESA_LLVM])
 806
 807 # Check for libdrm
 808 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 809                   [have_libdrm=yes], [have_libdrm=no])
 810
 811 if test "x$enable_dri" = xyes; then
 812     # DRI must be shared, I think
 813     if test "$enable_static" = yes; then
 814         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 815     fi
 816
 817     # not a hard requirement as swrast does not depend on it
 818     if test "x$have_libdrm" = xyes; then
 819         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 820     fi
 821 fi
 822
 823 dnl Find out if X is available.
 824 PKG_CHECK_MODULES([X11], [x11])
 825
 826 dnl Try to tell the user that the --x-* options are only used when
 827 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 828 m4_divert_once([HELP_BEGIN],
 829 [These options are only used when the X libraries cannot be found by the
 830 pkg-config utility.])
 831
 832 dnl We need X for xlib and dri, so bomb now if it's not found
 833 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 834     AC_MSG_ERROR([X11 development libraries needed for GLX])
 835 fi
 836
 837 if test "x$enable_glx" = xyes; then
 838     DEFINES="$DEFINES -DUSE_XCB"
 839 fi
 840
 841 dnl Direct rendering or just indirect rendering
 842 case "$host_os" in
 843 gnu*)
 844     dnl Disable by default on GNU/Hurd
 845     driglx_direct_default="no"
 846     ;;
 847 cygwin*)
 848     dnl Disable by default on cygwin
 849     driglx_direct_default="no"
 850     ;;
 851 *)
 852     driglx_direct_default="yes"
 853     ;;
 854 esac
 855 AC_ARG_ENABLE([driglx-direct],
 856     [AS_HELP_STRING([--disable-driglx-direct],
 857         [enable direct rendering in GLX and EGL for DRI \
 858             @<:@default=auto@:>@])],
 859     [driglx_direct="$enableval"],
 860     [driglx_direct="$driglx_direct_default"])
 861
 862 dnl
 863 dnl libGL configuration per driver
 864 dnl
 865 case "x$enable_glx$enable_xlib_glx" in
 866 xyesyes)
 867     # Xlib-based GLX
 868     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 869     GL_PC_REQ_PRIV="x11 xext"
 870     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 871     GL_LIB_DEPS="$XLIBGL_LIBS"
 872     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 873     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 874     ;;
 875 xyesno)
 876     # DRI-based GLX
 877     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 878     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 879     if test x"$driglx_direct" = xyes; then
 880         if test "x$have_libdrm" != xyes; then
 881             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 882         fi
 883         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 884         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 885     fi
 886
 887     # find the DRI deps for libGL
 888     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 889
 890     # add xf86vidmode if available
 891     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 892     if test "$HAVE_XF86VIDMODE" = yes ; then
 893         dri_modules="$dri_modules xxf86vm"
 894     fi
 895
 896     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 897     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 898     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 899     GL_LIB_DEPS="$DRIGL_LIBS"
 900
 901     # need DRM libs, -lpthread, etc.
 902     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 903     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 904     ;;
 905 esac
 906
 907 # This is outside the case (above) so that it is invoked even for non-GLX
 908 # builds.
 909 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 910
 911 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 912 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 913 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 914 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 915
 916 AC_SUBST([GL_LIB_DEPS])
 917 AC_SUBST([GL_PC_REQ_PRIV])
 918 AC_SUBST([GL_PC_LIB_PRIV])
 919 AC_SUBST([GL_PC_CFLAGS])
 920 AC_SUBST([DRI_PC_REQ_PRIV])
 921 AC_SUBST([GLESv1_CM_LIB_DEPS])
 922 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 923 AC_SUBST([GLESv2_LIB_DEPS])
 924 AC_SUBST([GLESv2_PC_LIB_PRIV])
 925
 926 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
 927 AC_SUBST([GLAPI_LIB_DEPS])
 928
 929
 930 dnl dri libraries are linking with mesa
 931 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.la'
 932 GALLIUM_DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
 933
 934 dnl ... or dricore?
 935 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
 936     DRI_LIB_DEPS="\$(TOP)/src/mesa/libdricore/libdricore${VERSION}.la"
 937     GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
 938     HAVE_DRICORE=yes
 939 fi
 940 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
 941
 942 AC_SUBST([HAVE_XF86VIDMODE])
 943
 944 dnl
 945 dnl More GLX setup
 946 dnl
 947 case "x$enable_glx$enable_xlib_glx" in
 948 xyesyes)
 949     DEFINES="$DEFINES -DUSE_XSHM"
 950     ;;
 951 xyesno)
 952     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 953     if test "x$driglx_direct" = xyes; then
 954         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 955     fi
 956     ;;
 957 esac
 958
 959 dnl
 960 dnl TLS detection
 961 dnl
 962
 963 AC_ARG_ENABLE([glx-tls],
 964     [AS_HELP_STRING([--enable-glx-tls],
 965         [enable TLS support in GLX @<:@default=disabled@:>@])],
 966     [GLX_USE_TLS="$enableval"],
 967     [GLX_USE_TLS=no])
 968 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 969
 970 AS_IF([test "x$GLX_USE_TLS" = xyes],
 971       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
 972
 973 dnl
 974 dnl More DRI setup
 975 dnl
 976 dnl Directory for DRI drivers
 977 AC_ARG_WITH([dri-driverdir],
 978     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 979         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 980     [DRI_DRIVER_INSTALL_DIR="$withval"],
 981     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 982 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 983 dnl Extra search path for DRI drivers
 984 AC_ARG_WITH([dri-searchpath],
 985     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 986         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 987     [DRI_DRIVER_SEARCH_DIR="$withval"],
 988     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 989 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 990 dnl Which drivers to build - default is chosen by platform
 991 AC_ARG_WITH([dri-drivers],
 992     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 993         [comma delimited DRI drivers list, e.g.
 994         "swrast,i965,radeon" @<:@default=auto@:>@])],
 995     [with_dri_drivers="$withval"],
 996     [with_dri_drivers=yes])
 997 if test "x$with_dri_drivers" = x; then
 998     with_dri_drivers=no
 999 fi
1000
1001 dnl If $with_dri_drivers is yes, directories will be added through
1002 dnl platform checks
1003 DRI_DIRS=""
1004 case "$with_dri_drivers" in
1005 no) ;;
1006 yes)
1007     # classic DRI drivers require FEATURE_GL to build
1008     if test "x$enable_opengl" = xyes; then
1009         DRI_DIRS="yes"
1010     fi
1011     ;;
1012 *)
1013     # verify the requested driver directories exist
1014     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1015     for driver in $dri_drivers; do
1016         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1017             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1018     done
1019     DRI_DIRS="$dri_drivers"
1020     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1021         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1022     fi
1023     ;;
1024 esac
1025
1026 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1027 if test "x$enable_dri" = xyes; then
1028     # Platform specific settings and drivers to build
1029     case "$host_os" in
1030     linux*)
1031         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1032         DEFINES="$DEFINES -DHAVE_ALIAS"
1033
1034         case "$host_cpu" in
1035         x86_64)
1036             if test "x$DRI_DIRS" = "xyes"; then
1037                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1038             fi
1039             ;;
1040         powerpc*)
1041             # Build only the drivers for cards that exist on PowerPC.
1042             if test "x$DRI_DIRS" = "xyes"; then
1043                 DRI_DIRS="r200 radeon swrast"
1044             fi
1045             ;;
1046         sparc*)
1047             # Build only the drivers for cards that exist on sparc
1048             if test "x$DRI_DIRS" = "xyes"; then
1049                 DRI_DIRS="r200 radeon swrast"
1050             fi
1051             ;;
1052         esac
1053         ;;
1054     freebsd* | dragonfly* | *netbsd*)
1055         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1056         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1057
1058         if test "x$DRI_DIRS" = "xyes"; then
1059             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1060         fi
1061         ;;
1062     gnu*)
1063         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1064         DEFINES="$DEFINES -DHAVE_ALIAS"
1065         ;;
1066     solaris*)
1067         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1068         ;;
1069     cygwin*)
1070         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1071         if test "x$DRI_DIRS" = "xyes"; then
1072             DRI_DIRS="swrast"
1073         fi
1074         ;;
1075     esac
1076
1077     # default drivers
1078     if test "x$DRI_DIRS" = "xyes"; then
1079         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1080     fi
1081
1082     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1083
1084     # Check for expat
1085     if test "x$enable_dri" = xyes; then
1086         EXPAT_INCLUDES=""
1087         EXPAT_LIB=-lexpat
1088         AC_ARG_WITH([expat],
1089             [AS_HELP_STRING([--with-expat=DIR],
1090                 [expat install directory])],[
1091             EXPAT_INCLUDES="-I$withval/include"
1092             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1093             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1094             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1095             ])
1096         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1097         save_LIBS="$LIBS"
1098         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1099             [AC_MSG_ERROR([Expat required for DRI.])])
1100         LIBS="$save_LIBS"
1101     fi
1102
1103     # if we are building any dri driver other than swrast ...
1104     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1105         # ... libdrm is required
1106         if test "x$have_libdrm" != xyes; then
1107             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1108         fi
1109         # ... and build dricommon
1110         HAVE_COMMON_DRI=yes
1111     fi
1112
1113     # put all the necessary libs together
1114     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1115     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1116 fi
1117 AC_SUBST([DRI_DIRS])
1118 AC_SUBST([EXPAT_INCLUDES])
1119 AC_SUBST([DRI_LIB_DEPS])
1120 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1121
1122 case $DRI_DIRS in
1123 *i915*|*i965*)
1124     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1125
1126     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1127         case $d in
1128         i915)
1129             HAVE_I915_DRI=yes;
1130             ;;
1131         i965)
1132             HAVE_I965_DRI=yes;
1133             ;;
1134         esac
1135     done
1136
1137     ;;
1138 esac
1139
1140 case $DRI_DIRS in
1141 *nouveau*)
1142     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1143     HAVE_NOUVEAU_DRI=yes;
1144     ;;
1145 esac
1146
1147 case $DRI_DIRS in
1148 *radeon*|*r200*)
1149     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1150
1151     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1152         case $d in
1153         radeon)
1154             HAVE_RADEON_DRI=yes;
1155             ;;
1156         r200)
1157             HAVE_R200_DRI=yes;
1158             ;;
1159         esac
1160     done
1161
1162     ;;
1163 esac
1164
1165 case $DRI_DIRS in
1166 *swrast*)
1167     HAVE_SWRAST_DRI=yes;
1168     ;;
1169 esac
1170
1171 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1172 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1173 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1174 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1175 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1176 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1177 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1178
1179 dnl
1180 dnl OSMesa configuration
1181 dnl
1182
1183 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1184 AC_ARG_WITH([osmesa-bits],
1185     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1186         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1187     [osmesa_bits="$withval"],
1188     [osmesa_bits=8])
1189 if test "x$osmesa_bits" != x8; then
1190     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1191         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1192         osmesa_bits=8
1193     fi
1194 fi
1195 case "x$osmesa_bits" in
1196 x8)
1197     OSMESA_LIB="${OSMESA_LIB}"
1198     ;;
1199 x16|x32)
1200     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1201     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1202     ;;
1203 *)
1204     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1205     ;;
1206 esac
1207
1208 if test "x$enable_osmesa" = xyes; then
1209     # only link libraries with osmesa if shared
1210     if test "$enable_static" = no; then
1211         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1212     else
1213         OSMESA_LIB_DEPS=""
1214     fi
1215     OSMESA_MESA_DEPS=""
1216     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1217 fi
1218
1219 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1220
1221 AC_SUBST([OSMESA_LIB_DEPS])
1222 AC_SUBST([OSMESA_MESA_DEPS])
1223 AC_SUBST([OSMESA_PC_REQ])
1224 AC_SUBST([OSMESA_PC_LIB_PRIV])
1225 AC_SUBST([OSMESA_VERSION])
1226
1227 dnl
1228 dnl gbm configuration
1229 dnl
1230 if test "x$enable_gbm" = xauto; then
1231     case "$with_egl_platforms" in
1232         *drm*)
1233             enable_gbm=yes ;;
1234          *)
1235             enable_gbm=no ;;
1236     esac
1237 fi
1238 if test "x$enable_gbm" = xyes; then
1239     SRC_DIRS="$SRC_DIRS gbm"
1240
1241     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1242                       AC_MSG_ERROR([gbm needs udev]))
1243
1244     if test "x$enable_dri" = xyes; then
1245         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1246         if test "x$enable_shared_glapi" = xno; then
1247             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1248         fi
1249     fi
1250 fi
1251 GBM_PC_REQ_PRIV="libudev"
1252 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1253 AC_SUBST([GBM_PC_REQ_PRIV])
1254 AC_SUBST([GBM_PC_LIB_PRIV])
1255
1256 dnl
1257 dnl EGL configuration
1258 dnl
1259 EGL_CLIENT_APIS=""
1260
1261 if test "x$enable_egl" = xyes; then
1262     SRC_DIRS="$SRC_DIRS egl"
1263     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1264
1265     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1266
1267     if test "$enable_static" != yes; then
1268         # build egl_glx when libGL is built
1269         if test "x$enable_glx" = xyes; then
1270             HAVE_EGL_DRIVER_GLX=1
1271         fi
1272
1273         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1274                           [have_libudev=yes],[have_libudev=no])
1275         if test "$have_libudev" = yes; then
1276             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1277         fi
1278
1279         if test "x$enable_dri" = xyes; then
1280             HAVE_EGL_DRIVER_DRI2=1
1281         fi
1282
1283     fi
1284 fi
1285 AC_SUBST([EGL_LIB_DEPS])
1286
1287 dnl
1288 dnl EGL Gallium configuration
1289 dnl
1290 if test "x$enable_gallium_egl" = xyes; then
1291     if test "x$with_gallium_drivers" = x; then
1292         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1293     fi
1294     if test "x$enable_egl" = xno; then
1295         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1296     fi
1297     if test "x$have_libdrm" != xyes; then
1298         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1299     fi
1300
1301     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1302     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1303     HAVE_ST_EGL="yes"
1304 fi
1305
1306 dnl
1307 dnl gbm Gallium configuration
1308 dnl
1309 if test "x$enable_gallium_gbm" = xauto; then
1310     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1311         yesyesyes*drm*)
1312             enable_gallium_gbm=yes ;;
1313          *)
1314             enable_gallium_gbm=no ;;
1315     esac
1316 fi
1317 if test "x$enable_gallium_gbm" = xyes; then
1318     if test "x$with_gallium_drivers" = x; then
1319         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1320     fi
1321     if test "x$enable_gbm" = xno; then
1322         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1323     fi
1324     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1325     if test "x$enable_dri" = xno; then
1326         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1327     fi
1328
1329     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1330     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1331     HAVE_ST_GBM="yes"
1332     enable_gallium_loader=yes
1333 fi
1334
1335 dnl
1336 dnl X.Org DDX configuration
1337 dnl
1338 if test "x$enable_xorg" = xyes; then
1339     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1340     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1341     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1342     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1343         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1344         HAVE_XEXTPROTO_71="no")
1345     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1346     HAVE_ST_XORG=yes
1347 fi
1348
1349 dnl
1350 dnl XA configuration
1351 dnl
1352 if test "x$enable_xa" = xyes; then
1353 AC_PROG_AWK
1354 AC_PROG_GREP
1355 AC_CHECK_PROG(NM, nm, "nm")
1356 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1357 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1358 enable_xa=no
1359 fi
1360 fi
1361 if test "x$enable_xa" = xyes; then
1362     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1363     HAVE_ST_XA=yes
1364     AC_SUBST(AWK)
1365     AC_SUBST(GREP)
1366     AC_SUBST(NM)
1367 fi
1368
1369 dnl
1370 dnl OpenVG configuration
1371 dnl
1372 VG_LIB_DEPS=""
1373
1374 if test "x$enable_openvg" = xyes; then
1375     if test "x$enable_egl" = xno; then
1376         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1377     fi
1378     if test "x$with_gallium_drivers" = x; then
1379         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1380     fi
1381     if test "x$enable_gallium_egl" = xno; then
1382         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1383     fi
1384
1385     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1386     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1387     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1388     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1389     HAVE_ST_VEGA=yes
1390 fi
1391
1392 dnl
1393 dnl D3D1X configuration
1394 dnl
1395
1396 if test "x$enable_d3d1x" = xyes; then
1397     if test "x$with_gallium_drivers" = x; then
1398         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1399     fi
1400
1401     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1402     HAVE_ST_D3D1X=yes
1403 fi
1404
1405 dnl
1406 dnl Gallium G3DVL configuration
1407 dnl
1408 AC_ARG_ENABLE([gallium-g3dvl],
1409     [AS_HELP_STRING([--enable-gallium-g3dvl],
1410         [build gallium g3dvl @<:@default=disabled@:>@])],
1411     [enable_gallium_g3dvl="$enableval"],
1412     [enable_gallium_g3dvl=no])
1413 if test "x$enable_gallium_g3dvl" = xyes; then
1414     if test "x$with_gallium_drivers" = x; then
1415         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1416     fi
1417
1418     if test "x$enable_xvmc" = xauto; then
1419         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1420     fi
1421
1422     if test "x$enable_vdpau" = xauto; then
1423         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1424     fi
1425
1426     if test "x$enable_va" = xauto; then
1427         #don't enable vaapi state tracker even if package exists
1428         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1429         enable_va=no
1430     fi
1431 fi
1432
1433 if test "x$enable_xvmc" = xyes; then
1434     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1435     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1436     HAVE_ST_XVMC="yes"
1437 fi
1438
1439 if test "x$enable_vdpau" = xyes; then
1440     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1441     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1442     HAVE_ST_VDPAU="yes"
1443 fi
1444
1445 if test "x$enable_va" = xyes; then
1446     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1447     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1448     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1449     HAVE_ST_VA="yes"
1450 fi
1451
1452 dnl
1453 dnl OpenCL configuration
1454 dnl
1455
1456 AC_ARG_WITH([libclc-path],
1457    [AS_HELP_STRING([--with-libclc-path],
1458          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1459    [LIBCLC_PATH="$withval"],
1460    [LIBCLC_PATH=""])
1461
1462 AC_ARG_WITH([clang-libdir],
1463    [AS_HELP_STRING([--with-clang-libdir],
1464          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1465    [CLANG_LIBDIR="$withval"],
1466    [CLANG_LIBDIR=""])
1467
1468 AC_SUBST([LIBCLC_PATH])
1469
1470 if test "x$enable_opencl" = xyes; then
1471     if test "x$with_gallium_drivers" = x; then
1472         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1473     fi
1474
1475     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1476         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1477     fi
1478
1479     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1480     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1481     enable_gallium_loader=yes
1482 fi
1483
1484 dnl
1485 dnl GLU configuration
1486 dnl
1487 AC_ARG_ENABLE([glu],
1488     [AS_HELP_STRING([--disable-glu],
1489         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1490     [enable_glu="$enableval"],
1491     [enable_glu=yes])
1492
1493 if test "x$enable_glu" = xyes; then
1494     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1495         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1496         enable_glu=no
1497     fi
1498 fi
1499
1500 if test "x$enable_glu" = xyes; then
1501     SRC_DIRS="$SRC_DIRS glu"
1502
1503     if test "x$enable_glx" = xno; then
1504         # Link libGLU to libOSMesa instead of libGL
1505         GLU_LIB_DEPS=""
1506         GLU_PC_REQ="osmesa"
1507         if test "$enable_static" = no; then
1508             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1509         else
1510             GLU_MESA_DEPS=""
1511         fi
1512     else
1513         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1514         GLU_PC_REQ="gl"
1515         GLU_PC_LIB_PRIV="-lm"
1516         if test "$enable_static" = no; then
1517             GLU_LIB_DEPS="-lm"
1518             GLU_MESA_DEPS='-l$(GL_LIB)'
1519         else
1520             GLU_LIB_DEPS=""
1521             GLU_MESA_DEPS=""
1522         fi
1523     fi
1524 fi
1525 if test "$enable_static" = no; then
1526     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1527 fi
1528 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1529 AC_SUBST([GLU_LIB_DEPS])
1530 AC_SUBST([GLU_MESA_DEPS])
1531 AC_SUBST([GLU_PC_REQ])
1532 AC_SUBST([GLU_PC_REQ_PRIV])
1533 AC_SUBST([GLU_PC_LIB_PRIV])
1534 AC_SUBST([GLU_PC_CFLAGS])
1535
1536 AC_SUBST([PROGRAM_DIRS])
1537
1538 dnl
1539 dnl Gallium configuration
1540 dnl
1541 if test "x$with_gallium_drivers" != x; then
1542     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1543 fi
1544
1545 AC_SUBST([LLVM_BINDIR])
1546 AC_SUBST([LLVM_CFLAGS])
1547 AC_SUBST([LLVM_CPPFLAGS])
1548 AC_SUBST([LLVM_CXXFLAGS])
1549 AC_SUBST([LLVM_LIBDIR])
1550 AC_SUBST([LLVM_LIBS])
1551 AC_SUBST([LLVM_LDFLAGS])
1552 AC_SUBST([LLVM_INCLUDEDIR])
1553 AC_SUBST([LLVM_VERSION])
1554 AC_SUBST([CLANG_RESOURCE_DIR])
1555
1556 case "x$enable_opengl$enable_gles1$enable_gles2" in
1557 x*yes*)
1558     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1559     ;;
1560 esac
1561
1562 AC_SUBST([VG_LIB_DEPS])
1563 AC_SUBST([EGL_CLIENT_APIS])
1564
1565 dnl
1566 dnl EGL Platforms configuration
1567 dnl
1568 AC_ARG_WITH([egl-platforms],
1569     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1570         [comma delimited native platforms libEGL supports, e.g.
1571         "x11,drm" @<:@default=auto@:>@])],
1572     [with_egl_platforms="$withval"],
1573     [if test "x$enable_egl" = xyes; then
1574         with_egl_platforms="x11"
1575     else
1576         with_egl_platforms=""
1577     fi])
1578
1579 EGL_PLATFORMS=""
1580
1581 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1582     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1583 fi
1584
1585 # Do per-EGL platform setups and checks
1586 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1587 for plat in $egl_platforms; do
1588         case "$plat" in
1589         fbdev|null)
1590                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1591                 ;;
1592
1593         wayland)
1594                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1595                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1596                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1597
1598                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1599                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1600                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1601                 ;;
1602
1603         x11)
1604                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1605                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1606                 save_LIBS="$LIBS"
1607                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1608                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1609                 LIBS="$save_LIBS"
1610                 ;;
1611
1612         drm)
1613                 test "x$enable_gbm" = "xno" &&
1614                         AC_MSG_ERROR([EGL platform drm needs gbm])
1615                 ;;
1616
1617         android|gdi)
1618                 ;;
1619
1620         *)
1621                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1622                 ;;
1623         esac
1624
1625         case "$plat$have_libudev" in
1626                 waylandno|drmno)
1627                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1628         esac
1629 done
1630
1631 # libEGL wants to default to the first platform specified in
1632 # ./configure.  parse that here.
1633 if test "x$egl_platforms" != "x"; then
1634     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1635     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1636 else
1637     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1638 fi
1639
1640 EGL_PLATFORMS="$egl_platforms"
1641
1642 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1643 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1644 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1645 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1646 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1647
1648 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1649 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1650
1651 AC_SUBST([EGL_NATIVE_PLATFORM])
1652 AC_SUBST([EGL_PLATFORMS])
1653 AC_SUBST([EGL_CFLAGS])
1654
1655 AC_ARG_WITH([egl-driver-dir],
1656     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1657                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1658     [EGL_DRIVER_INSTALL_DIR="$withval"],
1659     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1660 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1661
1662 AC_ARG_WITH([xorg-driver-dir],
1663     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1664                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1665     [XORG_DRIVER_INSTALL_DIR="$withval"],
1666     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1667 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1668
1669 AC_ARG_WITH([max-width],
1670     [AS_HELP_STRING([--with-max-width=N],
1671                     [Maximum framebuffer width (4096)])],
1672     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1673      AS_IF([test "${withval}" -gt "4096"],
1674            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1675 )
1676 AC_ARG_WITH([max-height],
1677     [AS_HELP_STRING([--with-max-height=N],
1678                     [Maximum framebuffer height (4096)])],
1679     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1680      AS_IF([test "${withval}" -gt "4096"],
1681            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1682 )
1683
1684 dnl
1685 dnl Gallium LLVM
1686 dnl
1687 AC_ARG_ENABLE([gallium-llvm],
1688     [AS_HELP_STRING([--enable-gallium-llvm],
1689         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1690     [enable_gallium_llvm="$enableval"],
1691     [enable_gallium_llvm=auto])
1692
1693 AC_ARG_WITH([llvm-shared-libs],
1694     [AS_HELP_STRING([--with-llvm-shared-libs],
1695         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1696     [with_llvm_shared_libs=yes],
1697     [with_llvm_shared_libs=no])
1698
1699 AC_ARG_WITH([llvm-prefix],
1700     [AS_HELP_STRING([--with-llvm-prefix],
1701         [Prefix for LLVM installations in non-standard locations])],
1702     [llvm_prefix="$withval"],
1703     [llvm_prefix=""])
1704
1705
1706 if test "x$with_gallium_drivers" = x; then
1707     enable_gallium_llvm=no
1708 fi
1709 if test "x$enable_gallium_llvm" = xauto; then
1710     case "$host_cpu" in
1711     i*86|x86_64) enable_gallium_llvm=yes;;
1712     esac
1713 fi
1714 if test "x$enable_gallium_llvm" = xyes; then
1715     if test "x$llvm_prefix" != x; then
1716         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1717     else
1718         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1719     fi
1720
1721     if test "x$LLVM_CONFIG" != xno; then
1722         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1723         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1724         if test "x$with_llvm_shared_libs" = xyes; then
1725             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1726             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1727         else
1728             LLVM_COMPONENTS="engine bitwriter"
1729             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1730                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1731             fi
1732             if test "x$enable_opencl" = xyes; then
1733                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1734             fi
1735             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1736         fi
1737         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1738         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1739         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1740         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1741         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1742         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1743         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1744         MESA_LLVM=1
1745
1746         dnl Check for Clang interanl headers
1747         if test "x$enable_opencl" = xyes; then
1748             if test "x$CLANG_LIBDIR" = x; then
1749                 CLANG_LIBDIR=${LLVM_LIBDIR}
1750             fi
1751             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1752             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1753                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1754         fi
1755     else
1756         MESA_LLVM=0
1757     fi
1758 else
1759     MESA_LLVM=0
1760 fi
1761
1762 dnl Directory for XVMC libs
1763 AC_ARG_WITH([xvmc-libdir],
1764     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1765         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1766     [XVMC_LIB_INSTALL_DIR="$withval"],
1767     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1768 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1769
1770 dnl
1771 dnl Gallium Tests
1772 dnl
1773 if test "x$enable_gallium_tests" = xyes; then
1774     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1775     enable_gallium_loader=yes
1776 fi
1777
1778 dnl Directory for VDPAU libs
1779 AC_ARG_WITH([vdpau-libdir],
1780     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1781         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1782     [VDPAU_LIB_INSTALL_DIR="$withval"],
1783     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1784 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1785
1786 dnl Directory for VA libs
1787 AC_ARG_WITH([va-libdir],
1788     [AS_HELP_STRING([--with-va-libdir=DIR],
1789         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1790     [VA_LIB_INSTALL_DIR="$withval"],
1791     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1792 AC_SUBST([VA_LIB_INSTALL_DIR])
1793
1794 dnl Directory for OpenCL libs
1795 AC_ARG_WITH([opencl-libdir],
1796     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1797         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1798     [OPENCL_LIB_INSTALL_DIR="$withval"],
1799     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1800 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1801
1802 dnl
1803 dnl Gallium helper functions
1804 dnl
1805 gallium_check_st() {
1806     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1807          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1808          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1809          if test "x$have_libdrm" != xyes; then
1810             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1811          fi
1812          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1813     fi
1814     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1815          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1816     fi
1817     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1818          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1819     fi
1820     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1821          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1822     fi
1823     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1824          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1825     fi
1826     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1827          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1828     fi
1829     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1830          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1831     fi
1832 }
1833
1834 gallium_require_llvm() {
1835     if test "x$MESA_LLVM" = x0; then
1836         case "$host_cpu" in
1837         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1838         esac
1839     fi
1840 }
1841
1842 gallium_require_drm_loader() {
1843     if test "x$enable_gallium_loader" = xyes; then
1844         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1845                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1846         if test "x$have_libdrm" != xyes; then
1847             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1848         fi
1849         enable_gallium_drm_loader=yes
1850     fi
1851 }
1852
1853 dnl Gallium drivers
1854 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1855 if test "x$with_gallium_drivers" != x; then
1856     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1857     for driver in $gallium_drivers; do
1858         case "x$driver" in
1859         xsvga)
1860             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1861             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1862             ;;
1863         xi915)
1864             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1865             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1866             if test "x$MESA_LLVM" = x1; then
1867                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1868             fi
1869             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1870             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1871             ;;
1872         xr300)
1873             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1874             gallium_require_llvm "Gallium R300"
1875             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1876             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1877             ;;
1878         xr600)
1879             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1880             gallium_require_drm_loader
1881             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1882             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1883                 if test "x$LLVM_VERSION" != "x3.1"; then
1884                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1885                 fi
1886                 NEED_RADEON_GALLIUM=yes;
1887             fi
1888             if test "x$enable_r600_llvm" = xyes; then
1889                 USE_R600_LLVM_COMPILER=yes;
1890             fi
1891             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1892                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1893             fi
1894             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1895             ;;
1896         xradeonsi)
1897             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1898             gallium_require_drm_loader
1899             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1900             if test "x$LLVM_VERSION" != "x3.1"; then
1901                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1902             fi
1903             NEED_RADEON_GALLIUM=yes;
1904             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1905             ;;
1906         xnouveau)
1907             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1908             gallium_require_drm_loader
1909             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1910             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1911             ;;
1912         xswrast)
1913             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1914             if test "x$MESA_LLVM" = x1; then
1915                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1916             fi
1917
1918             if test "x$HAVE_ST_DRI" = xyes; then
1919                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1920             fi
1921             if test "x$HAVE_ST_VDPAU" = xyes; then
1922                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1923             fi
1924             if test "x$HAVE_ST_XVMC" = xyes; then
1925                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1926             fi
1927             if test "x$HAVE_ST_VA" = xyes; then
1928                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1929             fi
1930             if test "x$HAVE_ST_VDPAU" = xyes ||
1931                test "x$HAVE_ST_XVMC" = xyes ||
1932                test "x$HAVE_ST_VA" = xyes; then
1933                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1934                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1935                fi
1936             fi
1937             ;;
1938         *)
1939             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1940             ;;
1941         esac
1942     done
1943 fi
1944
1945 if test "x$enable_gallium_loader" = xyes; then
1946     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1947     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1948     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1949     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1950
1951     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1952         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1953         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1954     fi
1955
1956     if test "x$enable_gallium_drm_loader" = xyes; then
1957         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1958         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1959                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1960         if test "x$pipe_loader_have_xcb" = xyes; then
1961             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1962             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1963         fi
1964     fi
1965
1966     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1967     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1968 fi
1969
1970 dnl Tell Automake which drivers to build
1971 for driver in $GALLIUM_DRIVERS_DIRS; do
1972     case "x$driver" in
1973         xgalahad)
1974             HAVE_GALAHAD_GALLIUM=yes;
1975             ;;
1976         xidentity)
1977             HAVE_IDENTITY_GALLIUM=yes;
1978             ;;
1979         xnoop)
1980             HAVE_NOOP_GALLIUM=yes;
1981             ;;
1982         *)
1983             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1984             ;;
1985     esac
1986 done
1987
1988 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1989 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1990 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1991 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1992 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1993 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1994 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1995 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1996 AC_SUBST([GALLIUM_MAKE_DIRS])
1997
1998 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1999 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
2000
2001 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2002 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2003 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2004
2005 dnl prepend CORE_DIRS to SRC_DIRS
2006 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2007
2008 dnl Restore LDFLAGS and CPPFLAGS
2009 LDFLAGS="$_SAVE_LDFLAGS"
2010 CPPFLAGS="$_SAVE_CPPFLAGS"
2011
2012 dnl Add user CFLAGS and CXXFLAGS
2013 CFLAGS="$CFLAGS $USER_CFLAGS"
2014 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2015
2016 dnl Substitute the config
2017 AC_CONFIG_FILES([configs/current
2018                 Makefile
2019                 src/Makefile
2020                 src/gallium/Makefile
2021                 src/gallium/auxiliary/pipe-loader/Makefile
2022                 src/gallium/state_trackers/clover/Makefile
2023                 src/gallium/drivers/Makefile
2024                 src/gallium/drivers/r300/Makefile
2025                 src/gallium/drivers/r600/Makefile
2026                 src/gallium/targets/opencl/Makefile
2027                 src/gbm/Makefile
2028                 src/gbm/main/gbm.pc
2029                 src/egl/drivers/Makefile
2030                 src/egl/drivers/dri2/Makefile
2031                 src/egl/drivers/glx/Makefile
2032                 src/egl/Makefile
2033                 src/egl/main/Makefile
2034                 src/egl/main/egl.pc
2035                 src/egl/wayland/Makefile
2036                 src/egl/wayland/wayland-egl/Makefile
2037                 src/egl/wayland/wayland-egl/wayland-egl.pc
2038                 src/egl/wayland/wayland-drm/Makefile
2039                 src/glsl/Makefile
2040                 src/glsl/glcpp/Makefile
2041                 src/glsl/tests/Makefile
2042                 src/glx/Makefile
2043                 src/glx/tests/Makefile
2044                 src/mapi/glapi/Makefile
2045                 src/mapi/glapi/gen/Makefile
2046                 src/mapi/shared-glapi/Makefile
2047                 src/mapi/glapi/tests/Makefile
2048                 src/mapi/shared-glapi/tests/Makefile
2049                 src/gtest/Makefile
2050                 src/mesa/Makefile
2051                 src/mesa/libdricore/Makefile
2052                 src/mesa/main/tests/Makefile
2053                 src/mesa/x86/Makefile
2054                 src/mesa/x86-64/Makefile
2055                 src/mesa/drivers/Makefile
2056                 src/mesa/drivers/dri/dri.pc
2057                 src/mesa/drivers/dri/Makefile
2058                 src/mesa/drivers/dri/common/Makefile
2059                 src/mesa/drivers/dri/i915/Makefile
2060                 src/mesa/drivers/dri/i965/Makefile
2061                 src/mesa/drivers/dri/nouveau/Makefile
2062                 src/mesa/drivers/dri/r200/Makefile
2063                 src/mesa/drivers/dri/radeon/Makefile
2064                 src/mesa/drivers/dri/swrast/Makefile
2065                 src/mesa/drivers/osmesa/Makefile
2066                 src/mesa/drivers/x11/Makefile
2067                 src/mesa/gl.pc
2068                 src/mesa/drivers/osmesa/osmesa.pc])
2069
2070 dnl Sort the dirs alphabetically
2071 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2072 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2073 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2074 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2075 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2076
2077 AC_OUTPUT
2078
2079 dnl
2080 dnl Output some configuration info for the user
2081 dnl
2082 echo ""
2083 echo "        prefix:          $prefix"
2084 echo "        exec_prefix:     $exec_prefix"
2085 echo "        libdir:          $libdir"
2086 echo "        includedir:      $includedir"
2087
2088 dnl API info
2089 echo ""
2090 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2091 echo "        OpenVG:          $enable_openvg"
2092
2093 dnl Driver info
2094 echo ""
2095 if test "x$enable_osmesa" != xno; then
2096         echo "        OSMesa:          lib$OSMESA_LIB"
2097 else
2098         echo "        OSMesa:          no"
2099 fi
2100
2101 if test "x$enable_dri" != xno; then
2102         # cleanup the drivers var
2103         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2104         if test "x$DRI_DIRS" = x; then
2105             echo "        DRI drivers:     no"
2106         else
2107             echo "        DRI drivers:     $dri_dirs"
2108         fi
2109         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2110 fi
2111
2112 case "x$enable_glx$enable_xlib_glx" in
2113 xyesyes)
2114     echo "        GLX:             Xlib-based"
2115     ;;
2116 xyesno)
2117     echo "        GLX:             DRI-based"
2118     ;;
2119 *)
2120     echo "        GLX:             $enable_glx"
2121     ;;
2122 esac
2123
2124 echo ""
2125 echo "        GLU:             $enable_glu"
2126
2127 dnl EGL
2128 echo ""
2129 echo "        EGL:             $enable_egl"
2130 if test "$enable_egl" = yes; then
2131     echo "        EGL platforms:   $EGL_PLATFORMS"
2132
2133     egl_drivers=""
2134     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2135         egl_drivers="$egl_drivers builtin:egl_glx"
2136     fi
2137     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2138         egl_drivers="$egl_drivers builtin:egl_dri2"
2139     fi
2140
2141     if test "x$HAVE_ST_EGL" = xyes; then
2142         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2143         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2144     else
2145         echo "        EGL drivers:    $egl_drivers"
2146     fi
2147 fi
2148
2149 echo ""
2150 if test "x$MESA_LLVM" = x1; then
2151     echo "        llvm:            yes"
2152     echo "        llvm-config:     $LLVM_CONFIG"
2153     echo "        llvm-version:    $LLVM_VERSION"
2154 else
2155     echo "        llvm:            no"
2156 fi
2157
2158 echo ""
2159 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2160     echo "        Gallium:         yes"
2161     echo "        Gallium dirs:    $GALLIUM_DIRS"
2162     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2163     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2164     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2165     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2166 else
2167     echo "        Gallium:         no"
2168 fi
2169
2170
2171 dnl Libraries
2172 echo ""
2173 echo "        Shared libs:     $enable_shared"
2174 echo "        Static libs:     $enable_static"
2175 echo "        Shared-glapi:    $enable_shared_glapi"
2176
2177 dnl Compiler options
2178 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2179 cflags=`echo $CFLAGS $PIC_FLAGS | \
2180     $SED 's/^ *//;s/  */ /;s/ *$//'`
2181 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2182     $SED 's/^ *//;s/  */ /;s/ *$//'`
2183 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2184 echo ""
2185 echo "        CFLAGS:          $cflags"
2186 echo "        CXXFLAGS:        $cxxflags"
2187 echo "        Macros:          $defines"
2188 echo ""
2189 echo "        PYTHON2:         $PYTHON2"
2190
2191 echo ""
2192 echo "        Run '${MAKE-make}' to build Mesa"
2193 echo ""