configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.93.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 AG_GST_LIBTOOL_PREPARE
  48 AS_LIBTOOL(GST, 0, 0, 0)
  49
  50 dnl *** required versions of GStreamer stuff ***
  51 GST_REQ=0.11.93
  52 GSTPB_REQ=0.11.93
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  61
  62 dnl set up gettext
  63 dnl the version check needs to stay here because autopoint greps for it
  64 AM_GNU_GETTEXT_VERSION([0.17])
  65 AM_GNU_GETTEXT([external])
  66 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  67
  68 dnl *** check for arguments to configure ***
  69
  70 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  71
  72 AG_GST_ARG_DEBUG
  73 AG_GST_ARG_PROFILING
  74 AG_GST_ARG_VALGRIND
  75 AG_GST_ARG_GCOV
  76
  77 AG_GST_ARG_EXAMPLES
  78
  79 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  80 AG_GST_ARG_WITH_PACKAGE_NAME
  81 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  82
  83 AG_GST_ARG_WITH_PLUGINS
  84
  85 AG_GST_ARG_ENABLE_EXTERNAL
  86
  87 AG_GST_ARG_ENABLE_EXPERIMENTAL
  88
  89 dnl *** checks for platform ***
  90
  91 dnl * hardware/architecture *
  92
  93 dnl common/m4/gst-arch.m4
  94 dnl check CPU type
  95 AG_GST_ARCH
  96
  97 dnl Determine endianness
  98 AC_C_BIGENDIAN
  99
 100 dnl *** checks for programs ***
 101
 102 dnl find a compiler
 103 AC_PROG_CC
 104 AC_PROG_CC_STDC
 105
 106 dnl determine c++ compiler
 107 AC_PROG_CXX
 108 dnl determine if c++ is available on this system
 109 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 110
 111 dnl determine c++ preprocessor
 112 dnl FIXME: do we need this ?
 113 AC_PROG_CXXCPP
 114
 115 AC_PROG_OBJC
 116
 117 dnl check if the compiler supports '-c' and '-o' options
 118 AM_PROG_CC_C_O
 119
 120 dnl find an assembler
 121 AM_PROG_AS
 122
 123 dnl check if the compiler supports do while(0) macros
 124 AG_GST_CHECK_DOWHILE_MACROS
 125
 126 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 127 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 128
 129 dnl check for documentation tools
 130 GTK_DOC_CHECK([1.3])
 131 AS_PATH_PYTHON([2.1])
 132 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 dnl *** checks for header files ***
 141
 142 dnl check if we have ANSI C header files
 143 AC_HEADER_STDC
 144
 145 dnl used by ext/wavpack
 146 AX_CREATE_STDINT_H
 147
 148 dnl used in gst/udp
 149 AC_CHECK_HEADERS([sys/time.h])
 150
 151 dnl used in gst/udp
 152 AC_CHECK_HEADERS([sys/socket.h])
 153
 154 dnl *** checks for types/defines ***
 155
 156 dnl Check for FIONREAD ioctl declaration.  This check is needed
 157 dnl for the UDP plugin to build on Solaris
 158 GST_CHECK_FIONREAD
 159
 160 dnl *** checks for structures ***
 161
 162 dnl *** checks for compiler characteristics ***
 163
 164 dnl check if we have GCC inline-asm
 165 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 166 if test x$HAVE_GCC_ASM = xyes ; then
 167   AC_DEFINE(HAVE_GCC_ASM, 1,
 168     [Define if compiler supports gcc inline assembly])
 169 fi
 170 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 171
 172 dnl *** checks for library functions ***
 173
 174 LIBS_SAVE=$LIBS
 175 LIBS="$LIBS $LIBM"
 176 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 177 LIBS=$LIBS_SAVE
 178
 179 dnl Check whether isinf() is defined by math.h
 180 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 181     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 182 if test "$ac_cv_have_isinf" = "yes"
 183 then
 184     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 185 fi
 186
 187 dnl Check for mmap (needed by electricfence plugin)
 188 AC_FUNC_MMAP
 189 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 190
 191 dnl Check for mmap (needed by electricfence plugin)
 192
 193 AC_CHECK_TYPE([struct ip_mreqn], [
 194               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 195               [#include <netinet/in.h>])
 196
 197 dnl *** checks for dependency libraries ***
 198
 199
 200 dnl GLib
 201 GLIB_REQ=2.32.0
 202 AG_GST_GLIB_CHECK([$GLIB_REQ])
 203
 204 dnl Orc
 205 ORC_CHECK([0.4.16])
 206
 207 dnl checks for gstreamer
 208 dnl uninstalled is selected preferentially -- see pkg-config(1)
 209 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 210 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 211 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 212 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 213 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 214 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 215
 216 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 217 if test -z $GST_TOOLS_DIR; then
 218   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 219 fi
 220 AC_SUBST(GST_TOOLS_DIR)
 221
 222 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 223 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 224
 225 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 226
 227 dnl Check for documentation xrefs
 228 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 229 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 230 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 231 AC_SUBST(GLIB_PREFIX)
 232 AC_SUBST(GST_PREFIX)
 233 AC_SUBST(GSTPB_PREFIX)
 234
 235 dnl GTK is optional and used in examples
 236 HAVE_GTK=no
 237 GT_REQ=3.0.0
 238 if test "x$BUILD_EXAMPLES" = "xyes"; then
 239   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 240   dnl some examples need gtk+-x11
 241   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 242   AC_SUBST(GTK_LIBS)
 243   AC_SUBST(GTK_CFLAGS)
 244 fi
 245 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 246 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 247
 248 dnl *** set variables based on configure arguments ***
 249
 250 dnl set license and copyright notice
 251 GST_LICENSE="LGPL"
 252 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 253 AC_SUBST(GST_LICENSE)
 254
 255 dnl set location of plugin directory
 256 AG_GST_SET_PLUGINDIR
 257
 258 dnl set release date/time
 259 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 260   ["${srcdir}/gst-plugins-good.doap"],
 261   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 262
 263 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 264 dnl make sure it doesn't complain about unused variables if debugging is disabled
 265 NO_WARNINGS=""
 266 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 267
 268 dnl define an ERROR_CFLAGS Makefile variable
 269 dnl -Wundef: too many broken headers
 270 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 271       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 272       -Wwrite-strings -Wold-style-definition -Waggregate-return
 273       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 274       -Wnested-externs $NO_WARNINGS])
 275
 276 dnl define an ERROR_CXXFLAGS Makefile variable
 277 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 278         -Wmissing-declarations -Wredundant-decls
 279         -Wwrite-strings
 280         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 281         $NO_WARNINGS])
 282
 283 dnl define an ERROR_OBJCFLAGS Makefile variable
 284 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 285       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 286       -Wwrite-strings -Wold-style-definition
 287       -Winit-self -Wmissing-include-dirs -Wno-multichar
 288       -Wnested-externs $NO_WARNINGS])
 289
 290 dnl define correct level for debugging messages
 291 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 292
 293 dnl used in examples
 294 AG_GST_DEFAULT_ELEMENTS
 295
 296 dnl *** plug-ins to include ***
 297
 298 dnl Non ported plugins (non-dependant, then dependant)
 299 dnl Make sure you have a space before and after all plugins
 300 GST_PLUGINS_NONPORTED="cairo cairo_gobject gdk_pixbuf osx_audio "
 301 AC_SUBST(GST_PLUGINS_NONPORTED)
 302
 303 dnl these are all the gst plug-ins, compilable without additional libs
 304 dnl videofilter is at the top because others depend on it
 305 AG_GST_CHECK_PLUGIN(alpha)
 306 AG_GST_CHECK_PLUGIN(apetag)
 307 AG_GST_CHECK_PLUGIN(audiofx)
 308 AG_GST_CHECK_PLUGIN(audioparsers)
 309 AG_GST_CHECK_PLUGIN(auparse)
 310 AG_GST_CHECK_PLUGIN(autodetect)
 311 AG_GST_CHECK_PLUGIN(avi)
 312 AG_GST_CHECK_PLUGIN(cutter)
 313 AG_GST_CHECK_PLUGIN(debugutils)
 314 AG_GST_CHECK_PLUGIN(deinterlace)
 315 AG_GST_CHECK_PLUGIN(effectv)
 316 AG_GST_CHECK_PLUGIN(equalizer)
 317 AG_GST_CHECK_PLUGIN(flv)
 318 AG_GST_CHECK_PLUGIN(flx)
 319 AG_GST_CHECK_PLUGIN(goom)
 320 AG_GST_CHECK_PLUGIN(goom2k1)
 321 AG_GST_CHECK_PLUGIN(icydemux)
 322 AG_GST_CHECK_PLUGIN(id3demux)
 323 AG_GST_CHECK_PLUGIN(imagefreeze)
 324 AG_GST_CHECK_PLUGIN(interleave)
 325 AG_GST_CHECK_PLUGIN(isomp4)
 326 AG_GST_CHECK_PLUGIN(law)
 327 AG_GST_CHECK_PLUGIN(level)
 328 AG_GST_CHECK_PLUGIN(matroska)
 329 AG_GST_CHECK_PLUGIN(monoscope)
 330 AG_GST_CHECK_PLUGIN(multifile)
 331 AG_GST_CHECK_PLUGIN(multipart)
 332 AG_GST_CHECK_PLUGIN(replaygain)
 333 AG_GST_CHECK_PLUGIN(rtp)
 334 AG_GST_CHECK_PLUGIN(rtpmanager)
 335 AG_GST_CHECK_PLUGIN(rtsp)
 336 AG_GST_CHECK_PLUGIN(shapewipe)
 337 AG_GST_CHECK_PLUGIN(smpte)
 338 AG_GST_CHECK_PLUGIN(spectrum)
 339 AG_GST_CHECK_PLUGIN(udp)
 340 AG_GST_CHECK_PLUGIN(videobox)
 341 AG_GST_CHECK_PLUGIN(videocrop)
 342 AG_GST_CHECK_PLUGIN(videofilter)
 343 AG_GST_CHECK_PLUGIN(videomixer)
 344 AG_GST_CHECK_PLUGIN(wavenc)
 345 AG_GST_CHECK_PLUGIN(wavparse)
 346 AG_GST_CHECK_PLUGIN(y4m)
 347
 348 dnl disable experimental plug-ins
 349 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 350   AG_GST_DISABLE_PLUGIN(monoscope)
 351 fi
 352
 353 dnl *** sys plug-ins ***
 354
 355 echo
 356 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 357 echo
 358
 359 dnl DirectSound
 360 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 361 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 362   HAVE_DIRECTSOUND="no"
 363   save_CFLAGS="$CFLAGS"
 364   save_LDFLAGS="$LDFLAGS"
 365   save_LIBS="$LIBS"
 366   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 367   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 368   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 369   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 370   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 371 #include <windows.h>
 372 #include <dxerr9.h>
 373 #include <dsound.h>
 374 ]], [[
 375   DXGetErrorString9 (0);
 376   DirectSoundCreate(NULL, NULL, NULL);
 377 ]])
 378 ],
 379     [HAVE_DIRECTSOUND="yes"],
 380     [HAVE_DIRECTSOUND="no"])
 381   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 382   CFLAGS=$save_CFLAGS
 383   LDFLAGS=$save_LDFLAGS
 384   LIBS=$save_LIBS
 385
 386   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 387     dnl this is much more than we want
 388     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 389     AC_SUBST(DIRECTSOUND_CFLAGS)
 390     AC_SUBST(DIRECTSOUND_LDFLAGS)
 391     AC_SUBST(DIRECTSOUND_LIBS)
 392   fi
 393   AC_SUBST(HAVE_DIRECTSOUND)
 394 ])
 395
 396 dnl *** Win32 WaveOut ***
 397 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 398 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 399   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 400 ])
 401
 402 dnl *** OSS audio *** (Linux, *BSD)
 403 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 404 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 405  HAVE_OSS="yes"
 406 dnl Linux and newer BSD versions :
 407  AC_CHECK_HEADER(sys/soundcard.h, [
 408    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 409    ] , [
 410 dnl Some old BSD versions and also newer OpenBSD versions :
 411    AC_CHECK_HEADER(soundcard.h, [
 412      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 413      ], [
 414   dnl Some old BSD versions :
 415      AC_CHECK_HEADER(machine/soundcard.h, [
 416        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 417          [Define if OSS includes are in /machine/])
 418        ], [
 419        HAVE_OSS="no"
 420      ])
 421    ])
 422  ])
 423 ])
 424
 425 dnl *** oss4 ***
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 427 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 428   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 429   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 430       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 431       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 432 ])
 433
 434 dnl *** Sun Audio ***
 435 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 436 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 437   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 438 ])
 439
 440 dnl *** OSX Audio ***
 441 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 442 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 443   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 444 ])
 445
 446 dnl *** OS X video ***
 447 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 448 HAVE_OSX_VIDEO="no"
 449 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 450   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 451 ])
 452 dnl in case header OpenGL/gl.h is found on other platforms
 453 case "$host" in
 454   *-*darwin*)
 455     dnl do nothing
 456     ;;
 457   *)
 458     HAVE_OSX_VIDEO="no"
 459     ;;
 460 esac
 461
 462
 463 dnl *** Video 4 Linux 2 ***
 464 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 465 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 467 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 468   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 469   AC_TRY_COMPILE([
 470 #include <sys/types.h>
 471 #ifdef __sun /* Solaris */
 472 #include <sys/types.h>
 473 #include <sys/videodev2.h>
 474 #else /* Linux */
 475 #include <linux/types.h>
 476 #define _LINUX_TIME_H
 477 #define __user
 478 #include <linux/videodev2.h>
 479 #endif
 480 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 481 #error too early v4l2 version or no v4l2 at all
 482 #endif
 483     ], [
 484 return 0;
 485     ], [
 486       HAVE_GST_V4L2="yes"
 487       AC_MSG_RESULT(yes)
 488     ], [
 489       HAVE_GST_V4L2="no"
 490       AC_MSG_RESULT(no)
 491
 492       HAVE_VIDEODEV=no
 493       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 494       [
 495         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 496       ])
 497
 498       if test "x$HAVE_VIDEODEV" = "xyes"; then
 499         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 500         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 501       else
 502         AC_MSG_WARN([video4linux2 was not found])
 503       fi
 504     ])
 505
 506   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 507     dnl check for missing v4l2_buffer declaration (see #135919)
 508     MISSING_DECL=0
 509     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 510     AC_TRY_COMPILE([
 511 #include <sys/types.h>
 512 #ifdef __sun /* Solaris */
 513 #include <sys/types.h>
 514 #include <sys/videodev2.h>
 515 #else /* Linux */
 516 #include <linux/types.h>
 517 #define _LINUX_TIME_H
 518 #define __user
 519 #include <linux/videodev2.h>
 520 #endif
 521     ],[
 522 struct v4l2_buffer buf;
 523 buf.index = 0;
 524 return 0;
 525     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 526     if [ test x$MISSING_DECL = x1 ]; then
 527       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 528     fi
 529
 530     dnl check for XOverlay libraries
 531     AG_GST_CHECK_XV
 532   fi
 533 ])
 534
 535 # Optional gudev for device probing
 536 AC_ARG_WITH([gudev],
 537   AC_HELP_STRING([--with-gudev],
 538     [device detection with gudev]),
 539   [],
 540   [with_gudev=check])
 541 if test x$HAVE_GST_V4L2 = xyes; then
 542   if test x$with_gudev != xno; then
 543       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 544           [ have_gudev=yes
 545             AC_DEFINE(HAVE_GUDEV, 1,
 546                [Whether gudev is available for device detection])
 547             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 548           ], [
 549           have_gudev=no
 550           ])
 551   else
 552     have_gudev=no
 553   fi
 554 fi
 555 AC_SUBST(GUDEV_CFLAGS)
 556 AC_SUBST(GUDEV_LIBS)
 557
 558 # Make libv4l2 non-automagic
 559 AC_ARG_WITH([libv4l2],
 560   AC_HELP_STRING([--with-libv4l2],
 561     [support video buffer conversion using libv4l2]),
 562   [],
 563   [with_libv4l2=check])
 564 if test x$HAVE_GST_V4L2 = xyes; then
 565   if test x$with_libv4l2 != xno; then
 566       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 567           [ have_libv4l2=yes
 568             AC_DEFINE(HAVE_LIBV4L2, 1,
 569                 [Whether libv4l2 is available for video buffer conversion])
 570           ], [
 571           have_libv4l2=no
 572           ])
 573   else
 574     have_libv4l2=no
 575   fi
 576 fi
 577
 578 dnl Check for X11
 579 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 580 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 581                   [ximagesrc], [
 582   AC_PATH_XTRA
 583
 584   dnl now try to find the HEADER
 585   ac_cflags_save="$CFLAGS"
 586   ac_cppflags_save="$CPPFLAGS"
 587   CFLAGS="$CFLAGS $X_CFLAGS"
 588   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 589   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 590
 591   if test "x$HAVE_X" = "xno"
 592   then
 593     AC_MSG_NOTICE([cannot find X11 development files])
 594   else
 595     dnl this is much more than we want
 596     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 597     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 598     dnl it does not add the libs; therefore we add them here
 599     X_LIBS="$X_LIBS -lX11"
 600     AC_SUBST(X_CFLAGS)
 601     AC_SUBST(X_LIBS)
 602
 603     dnl check for Xfixes
 604     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 605     if test "x$HAVE_XFIXES" = "xyes"
 606     then
 607         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 608     fi
 609     AC_SUBST(XFIXES_LIBS)
 610     AC_SUBST(XFIXES_CFLAGS)
 611
 612     dnl check for Xdamage
 613     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 614     if test "x$HAVE_XDAMAGE" = "xyes"
 615     then
 616         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 617     fi
 618     AC_SUBST(XDAMAGE_LIBS)
 619     AC_SUBST(XDAMAGE_CFLAGS)
 620   fi
 621   AC_SUBST(HAVE_X)
 622   CFLAGS="$ac_cflags_save"
 623   CPPFLAGS="$ac_cppflags_save"
 624 ])
 625
 626 dnl FIXME: this should be rolled into the test above, it's just an additional
 627 dnl feature of the ximagesrc plug-in
 628 dnl This is the same as in gst-plugins-base
 629 dnl check for X Shm
 630 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 631 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 632   if test x$HAVE_X = xyes; then
 633     AC_CHECK_LIB(Xext, XShmAttach,
 634                  HAVE_XSHM="yes", HAVE_XSHM="no",
 635                  $X_LIBS)
 636     if test "x$HAVE_XSHM" = "xyes"; then
 637       XSHM_LIBS="-lXext"
 638     else
 639       dnl On AIX, it is in XextSam instead, but we still need -lXext
 640       AC_CHECK_LIB(XextSam, XShmAttach,
 641                    HAVE_XSHM="yes", HAVE_XSHM="no",
 642                    $X_LIBS)
 643       if test "x$HAVE_XSHM" = "xyes"; then
 644         XSHM_LIBS="-lXext -lXextSam"
 645       fi
 646     fi
 647   fi
 648 ], ,[
 649   AC_SUBST(HAVE_XSHM)
 650   AC_SUBST(XSHM_LIBS)
 651 ])
 652
 653 dnl for V4L2, we also need to know if we have XVIDEO
 654 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 655 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 656                   [], [
 657   AG_GST_CHECK_XV
 658 ])
 659
 660 dnl *** ext plug-ins ***
 661 dnl keep this list sorted alphabetically !
 662
 663 if test "x$BUILD_EXTERNAL" = "xyes"; then
 664
 665 echo
 666 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 667 echo
 668
 669 dnl *** aalib ***
 670 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 671 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 672   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 673   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 674 ])
 675
 676 dnl *** cairo ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 678 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 679   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 680 ])
 681
 682 dnl *** cairo-gobject ***
 683 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 684 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 685   [Cairo graphics rendering gobject bindings], cairooverlay, [
 686   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 687 ])
 688
 689 dnl *** FLAC ***
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 691 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 692   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 693 ])
 694
 695 dnl *** GDK pixbuf ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 697 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 698   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 699 ])
 700
 701 dnl *** Jack ***
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 703 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 704   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 705   AC_SUBST(JACK_CFLAGS)
 706   AC_SUBST(JACK_LIBS)
 707
 708   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 709   if test x$HAVE_JACK_0_120_1 = xyes; then
 710     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 711   fi
 712   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 713   if test x$HAVE_JACK_1_9_7 = xyes; then
 714     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 715   fi
 716
 717 ])
 718
 719 dnl *** jpeg ***
 720 dnl FIXME: we could use header checks here as well IMO
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 722 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 723   AC_ARG_WITH(jpeg-mmx,
 724     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 725   OLD_LIBS="$LIBS"
 726   if test x$with_jpeg_mmx != x; then
 727     LIBS="$LIBS -L$with_jpeg_mmx"
 728   fi
 729   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 730   JPEG_LIBS="$LIBS -ljpeg-mmx"
 731   LIBS="$OLD_LIBS"
 732   if test x$HAVE_JPEG != xyes; then
 733     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 734     JPEG_LIBS="-ljpeg"
 735   fi
 736   AC_SUBST(JPEG_LIBS)
 737 ])
 738
 739 dnl *** libcaca ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 741 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 742   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 743 ])
 744
 745 dnl *** libdv ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 747 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 748   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 749 ])
 750
 751 dnl *** libpng ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 753 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 754   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 755 ])
 756
 757 dnl *** pulseaudio ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 759 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 760
 761   dnl used in ext/pulse/pulseutil.c
 762   AC_CHECK_HEADERS([process.h])
 763
 764   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 765 ])
 766
 767 dnl *** dv1394 ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 769 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 770   dnl first test for libraw1394 >= 2.0.0
 771   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 772   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 773   dnl now see how far we got
 774   if test x$HAVE_RAW1394 = xyes && \
 775      test x$HAVE_LIBIEC61883 = xyes; then
 776        AG_GST_CHECK_LIBHEADER(AVC1394,
 777         avc1394, avc1394_send_command, $RAW1394_LIBS,
 778         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 779        AG_GST_CHECK_LIBHEADER(ROM1394,
 780         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 781         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 782        if test x$HAVE_AVC1394 = xyes && \
 783           test x$HAVE_AVC1394 = xyes && \
 784           test x$HAVE_ROM1394 = xyes; then
 785           HAVE_DV1394=yes
 786           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 787           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 788           AC_SUBST(DV1394_CFLAGS)
 789           AC_SUBST(DV1394_LIBS)
 790         fi
 791   else
 792        if test x$HAVE_RAW1394 = xno; then
 793           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 794           AG_GST_CHECK_LIBHEADER(AVC1394,
 795            avc1394, avc1394_send_command, $RAW1394_LIBS,
 796            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 797           AG_GST_CHECK_LIBHEADER(ROM1394,
 798            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 799            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 800           if test x$HAVE_RAW1394 = xyes && \
 801              test x$HAVE_AVC1394 = xyes && \
 802              test x$HAVE_ROM1394 = xyes; then
 803              HAVE_DV1394=yes
 804              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 805              DV1394_CFLAGS="$RAW1394_CFLAGS"
 806              if test x$HAVE_LIBIEC61883 = xyes; then
 807                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 808                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 809              fi
 810              AC_SUBST(DV1394_CFLAGS)
 811              AC_SUBST(DV1394_LIBS)
 812            fi
 813          fi
 814   fi
 815 ])
 816 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 817
 818 dnl *** shout2 ***
 819 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 820 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 821   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 822 ])
 823
 824 dnl *** soup ***
 825 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 826 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 827   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 828     HAVE_SOUP="yes"
 829     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 830   ],[
 831     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26.1, HAVE_SOUP="yes", [
 832       HAVE_SOUP="no"
 833     ])
 834   ])
 835   AC_SUBST(SOUP_CFLAGS)
 836   AC_SUBST(SOUP_LIBS)
 837 ])
 838
 839 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 840 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 841 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 842 dnl   speex_jitter.h is 1.1.x only
 843 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 844 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 845   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 846   if test $HAVE_SPEEX = no
 847   then
 848     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 849       AC_CHECK_HEADER(speex/speex_jitter.h, [
 850         dnl speex 1.1.x :
 851         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 852           dnl speex 1.1.5 or + :
 853           HAVE_SPEEX="yes"
 854           SPEEX_LIBS="-lspeex"
 855           AC_SUBST(SPEEX_CFLAGS)
 856           AC_SUBST(SPEEX_LIBS)
 857         ],[
 858           HAVE_SPEEX="no"
 859         ])
 860       ],[
 861         dnl speex 1.0.x :
 862           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 863             dnl speex 1.0.4
 864             HAVE_SPEEX="yes"
 865             SPEEX_LIBS="-lspeex"
 866             AC_SUBST(SPEEX_CFLAGS)
 867             AC_SUBST(SPEEX_LIBS)
 868
 869             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 870               [defined if speex 1.0.x API detected])
 871         ],[
 872             HAVE_SPEEX="no"
 873             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 874         ], [
 875 #include <speex/speex.h>
 876         ])
 877       ])
 878     ])
 879   fi
 880 ])
 881
 882 dnl *** taglib ***
 883 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 884 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 885   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 886   if test "x$HAVE_CXX" != "xyes"; then
 887     USE_TAGLIB=false
 888     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 889   else
 890     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 891     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 892         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 893       ], [
 894         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 895     ])
 896     AC_SUBST(TAGLIB_CXXFLAGS)
 897   fi
 898 ])
 899
 900 dnl *** wavpack ***
 901 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 902 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 903   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 904     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 905       HAVE_WAVPACK=yes
 906       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 907     ],[
 908       HAVE_WAVPACK=no
 909     ])
 910   ])
 911   AC_SUBST(WAVPACK_CFLAGS)
 912   AC_SUBST(WAVPACK_LIBS)
 913 ])
 914
 915 dnl *** qtdemux & matroska prefer to have zlib ***
 916 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 917 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 918   AG_GST_CHECK_LIBHEADER(ZLIB,
 919     z, uncompress,, zlib.h, [
 920     HAVE_ZLIB="yes"
 921     ZLIB_LIBS="-lz"
 922     AC_SUBST(ZLIB_LIBS)
 923   ])
 924 ])
 925
 926 dnl *** matroska prefers to have bz2 ***
 927 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 928 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 929   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 930   AC_SUBST(BZ2_LIBS)
 931 ])
 932
 933 else
 934
 935 dnl not building plugins with external dependencies,
 936 dnl but we still need to set the conditionals
 937 AM_CONDITIONAL(USE_AALIB, false)
 938 AM_CONDITIONAL(USE_BZ2, false)
 939 AM_CONDITIONAL(USE_CAIRO, false)
 940 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 941 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 942 AM_CONDITIONAL(USE_DV1394, false)
 943 AM_CONDITIONAL(USE_FLAC, false)
 944 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 945 AM_CONDITIONAL(USE_GST_V4L2, false)
 946 AM_CONDITIONAL(USE_JACK, false)
 947 AM_CONDITIONAL(USE_JPEG, false)
 948 AM_CONDITIONAL(USE_LIBCACA, false)
 949 AM_CONDITIONAL(USE_LIBDV, false)
 950 AM_CONDITIONAL(USE_LIBIEC61883, false)
 951 AM_CONDITIONAL(USE_LIBPNG, false)
 952 AM_CONDITIONAL(USE_OSS, false)
 953 AM_CONDITIONAL(USE_OSS4, false)
 954 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 955 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 956 AM_CONDITIONAL(USE_PULSE, false)
 957 AM_CONDITIONAL(USE_SHOUT2, false)
 958 AM_CONDITIONAL(USE_SOUP, false)
 959 AM_CONDITIONAL(USE_SPEEX, false)
 960 AM_CONDITIONAL(USE_SUNAUDIO, false)
 961 AM_CONDITIONAL(USE_TAGLIB, false)
 962 AM_CONDITIONAL(USE_WAVEFORM, false)
 963 AM_CONDITIONAL(USE_WAVPACK, false)
 964 AM_CONDITIONAL(USE_X, false)
 965 AM_CONDITIONAL(USE_XSHM, false)
 966 AM_CONDITIONAL(USE_XVIDEO, false)
 967 AM_CONDITIONAL(USE_ZLIB, false)
 968
 969 fi dnl of EXT plugins
 970
 971 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 972
 973 dnl Overview:
 974 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 975 dnl GST_*:              flags shared by all built objects
 976 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 977 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 978 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 979 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 980
 981 dnl GST_OPTION_CFLAGS
 982 if test "x$USE_DEBUG" = xyes; then
 983    PROFILE_CFLAGS="-g"
 984 fi
 985 AC_SUBST(PROFILE_CFLAGS)
 986
 987 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 988   dnl Define _only_ for git (not pre-releases or releases)
 989   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 990 else
 991   DEPRECATED_CFLAGS=""
 992 fi
 993 AC_SUBST(DEPRECATED_CFLAGS)
 994
 995 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 996 dnl at make time with e.g. make ERROR_CFLAGS=""
 997 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 998 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 999 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1000 AC_SUBST(GST_OPTION_CFLAGS)
1001 AC_SUBST(GST_OPTION_CXXFLAGS)
1002 AC_SUBST(GST_OPTION_OBJCFLAGS)
1003
1004 dnl our libraries need to be versioned correctly
1005 AC_SUBST(GST_LT_LDFLAGS)
1006
1007 dnl FIXME: do we want to rename to GST_ALL_* ?
1008 dnl prefer internal headers to already installed ones
1009 dnl also add builddir include for enumtypes and marshal
1010 dnl add ERROR_CFLAGS, but overridable
1011 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1012 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1013 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1014 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1015 AC_SUBST(GST_CFLAGS)
1016 AC_SUBST(GST_CXXFLAGS)
1017 AC_SUBST(GST_OBJCFLAGS)
1018 AC_SUBST(GST_LIBS)
1019
1020 dnl LDFLAGS really should only contain flags, not libs - they get added before
1021 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1022 GST_ALL_LDFLAGS="-no-undefined"
1023 AC_SUBST(GST_ALL_LDFLAGS)
1024
1025 dnl this really should only contain flags, not libs - they get added before
1026 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1027 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1028 AC_SUBST(GST_PLUGIN_LDFLAGS)
1029
1030 dnl *** output files ***
1031
1032 dnl keep this alphabetic per directory, please
1033 AC_CONFIG_FILES(
1034 Makefile
1035 gst/Makefile
1036 gst/alpha/Makefile
1037 gst/apetag/Makefile
1038 gst/audiofx/Makefile
1039 gst/audioparsers/Makefile
1040 gst/auparse/Makefile
1041 gst/autodetect/Makefile
1042 gst/avi/Makefile
1043 gst/cutter/Makefile
1044 gst/deinterlace/Makefile
1045 gst/debugutils/Makefile
1046 gst/effectv/Makefile
1047 gst/equalizer/Makefile
1048 gst/flv/Makefile
1049 gst/goom/Makefile
1050 gst/goom2k1/Makefile
1051 gst/id3demux/Makefile
1052 gst/icydemux/Makefile
1053 gst/imagefreeze/Makefile
1054 gst/interleave/Makefile
1055 gst/isomp4/Makefile
1056 gst/law/Makefile
1057 gst/level/Makefile
1058 gst/matroska/Makefile
1059 gst/monoscope/Makefile
1060 gst/multifile/Makefile
1061 gst/multipart/Makefile
1062 gst/replaygain/Makefile
1063 gst/rtp/Makefile
1064 gst/rtpmanager/Makefile
1065 gst/rtsp/Makefile
1066 gst/shapewipe/Makefile
1067 gst/smpte/Makefile
1068 gst/spectrum/Makefile
1069 gst/udp/Makefile
1070 gst/videobox/Makefile
1071 gst/videocrop/Makefile
1072 gst/videofilter/Makefile
1073 gst/videomixer/Makefile
1074 gst/wavenc/Makefile
1075 gst/wavparse/Makefile
1076 gst/flx/Makefile
1077 gst/y4m/Makefile
1078 ext/Makefile
1079 ext/aalib/Makefile
1080 ext/cairo/Makefile
1081 ext/dv/Makefile
1082 ext/flac/Makefile
1083 ext/gdk_pixbuf/Makefile
1084 ext/jack/Makefile
1085 ext/jpeg/Makefile
1086 ext/libcaca/Makefile
1087 ext/libpng/Makefile
1088 ext/pulse/Makefile
1089 ext/raw1394/Makefile
1090 ext/shout2/Makefile
1091 ext/soup/Makefile
1092 ext/speex/Makefile
1093 ext/taglib/Makefile
1094 ext/wavpack/Makefile
1095 sys/Makefile
1096 sys/directsound/Makefile
1097 sys/oss/Makefile
1098 sys/oss4/Makefile
1099 sys/osxaudio/Makefile
1100 sys/osxvideo/Makefile
1101 sys/sunaudio/Makefile
1102 sys/v4l2/Makefile
1103 sys/waveform/Makefile
1104 sys/ximage/Makefile
1105 po/Makefile.in
1106 tests/Makefile
1107 tests/check/Makefile
1108 tests/examples/Makefile
1109 tests/examples/audiofx/Makefile
1110 tests/examples/cairo/Makefile
1111 tests/examples/equalizer/Makefile
1112 tests/examples/jack/Makefile
1113 tests/examples/level/Makefile
1114 tests/examples/pulse/Makefile
1115 tests/examples/rtp/Makefile
1116 tests/examples/shapewipe/Makefile
1117 tests/examples/spectrum/Makefile
1118 tests/examples/v4l2/Makefile
1119 tests/files/Makefile
1120 tests/icles/Makefile
1121 common/Makefile
1122 common/m4/Makefile
1123 m4/Makefile
1124 docs/Makefile
1125 docs/plugins/Makefile
1126 docs/version.entities
1127 pkgconfig/Makefile
1128 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1129 gst-plugins-good.spec
1130 )
1131
1132 dnl Create the config.h file for Visual Studio builds
1133 dnl Beware of spaces and /'s in some of the shell variable contents.
1134 sed \
1135     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1136     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1137     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1138     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1139     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1140     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1141     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1142     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1143     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1144     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1145     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1146     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1147     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1148     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1149     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1150     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1151     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1152     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1153     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1154     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1155     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1156     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1157     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1158     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1159     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1160     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1161     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1162     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1163     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1164     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1165     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1166     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1167     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1168     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1169     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1170     config.h.in >win32/common/config.h-new
1171
1172 AC_OUTPUT
1173
1174 AG_GST_OUTPUT_PLUGINS
1175 ORC_OUTPUT
1176