configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.28.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl our libraries and install dirs use major.minor as a version
  38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  39 dnl we override it here for release candidates for a new series
  40 GST_MAJORMINOR=0.10
  41 AC_SUBST(GST_MAJORMINOR)
  42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  43   [library major.minor version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 24, 1, 24)
  52
  53 dnl FIXME: this macro doesn't actually work;
  54 dnl the generated libtool script has no support for the listed tags.
  55 dnl So this needs to be fixed first if we want to use this
  56 dnl AS_LIBTOOL_TAGS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AM_PROG_LIBTOOL
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4 -I .")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 dnl subsystems - can influence other decisions so needs to be high up
  78 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  79 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  80 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  81 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  82 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  83 dnl define a substitution to use in docs/gst/gstreamer.types
  84 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  85 then
  86   GST_LOADSAVE_DOC_TYPES="%"
  87 else
  88   GST_LOADSAVE_DOC_TYPES=
  89 fi
  90 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 121
 122 AG_GST_ARG_DEBUG
 123 AG_GST_ARG_PROFILING
 124 AG_GST_ARG_VALGRIND
 125 AG_GST_ARG_GCOV
 126
 127 AG_GST_ARG_EXAMPLES
 128
 129 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 130 AG_GST_ARG_WITH_PACKAGE_NAME
 131 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 132
 133 dnl building of tests
 134 AC_ARG_ENABLE(tests,
 135   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 136   [
 137     case "${enableval}" in
 138       yes) BUILD_TESTS=yes ;;
 139       no)  BUILD_TESTS=no ;;
 140       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 141     esac
 142   ],
 143 [BUILD_TESTS=yes]) dnl Default value
 144 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 145
 146 dnl tests known to fail
 147 AC_ARG_ENABLE(failing-tests,
 148   AC_HELP_STRING([--disable-failing-tests],
 149     [disable building tests known to fail]),
 150   [
 151     case "${enableval}" in
 152       yes) BUILD_FAILING_TESTS=yes ;;
 153       no)  BUILD_FAILING_TESTS=no ;;
 154       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 155     esac
 156   ],
 157   [BUILD_FAILING_TESTS=no]) dnl Default value
 158 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 159 if test x$BUILD_FAILING_TESTS = xyes; then
 160   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 161 else
 162   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 163 fi
 164
 165 dnl poison destroyed objects
 166 AC_ARG_ENABLE(poisoning,
 167   AC_HELP_STRING([--enable-poisoning],
 168     [enable poisoning of deallocated objects]),
 169   [
 170     case "${enableval}" in
 171       yes) USE_POISONING=yes ;;
 172       no)  USE_POISONING=no ;;
 173       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 174     esac
 175   ],
 176   [USE_POISONING=no]) dnl Default value
 177 if test "x$USE_POISONING" = xyes; then
 178   AC_DEFINE(USE_POISONING, 1,
 179     [Define if we should poison deallocated memory])
 180 fi
 181
 182 dnl *** checks for platform ***
 183
 184 dnl * hardware/architecture *
 185
 186 dnl common/m4/gst-arch.m4
 187 dnl check CPU type
 188 AG_GST_ARCH
 189 dnl substitution for win32/common/config.h
 190 HOST_CPU=$host_cpu
 191 AC_SUBST(HOST_CPU)
 192
 193 dnl common/m4/gst-arch.m4
 194 dnl check for unaligned access
 195 AG_GST_UNALIGNED_ACCESS
 196 dnl create a configure variable for gst/gstconfig.h
 197 if test x${as_cv_unaligned_access} = xyes ; then
 198   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 199 else
 200   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 201 fi
 202 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 203
 204 dnl check for platform specific settings
 205 AG_GST_PLATFORM
 206
 207 dnl * software *
 208
 209 dnl check for large file support
 210 dnl affected plugins must include config.h
 211 AC_SYS_LARGEFILE
 212
 213 dnl *** checks for programs ***
 214
 215 dnl find a compiler
 216 AC_PROG_CC
 217
 218 dnl check if the compiler supports '-c' and '-o' options
 219 AM_PROG_CC_C_O
 220
 221 dnl find an assembler
 222 AM_PROG_AS
 223
 224 dnl Perl is used in building documentation and in the version checks
 225 AC_PATH_PROG(PERL_PATH, perl, no)
 226 if test x$PERL_PATH = xno; then
 227   AC_MSG_ERROR(Could not find perl)
 228 fi
 229
 230 dnl we require flex and bison for building the parser
 231 if test "x$GST_DISABLE_PARSE" != xyes; then
 232   AG_GST_BISON_CHECK
 233   AG_GST_FLEX_CHECK
 234 fi
 235
 236 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 237 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 238
 239 dnl check for gobject-introspection
 240 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 241
 242 dnl check for documentation tools
 243 AG_GST_DOCBOOK_CHECK
 244 GTK_DOC_CHECK([1.3])
 245 AS_PATH_PYTHON([2.1])
 246 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 247
 248 dnl *** checks for libraries ***
 249
 250 dnl check for libm, for sin()
 251 AC_CHECK_LIBM
 252 AC_SUBST(LIBM)
 253
 254 dnl *** checks for header files ***
 255
 256 dnl check if we have ANSI C header files
 257 AC_HEADER_STDC
 258
 259 dnl Check for ucontext.h
 260 AC_CHECK_HEADERS([ucontext.h])
 261
 262 dnl Check for sys/socket.h
 263 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 264 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 265
 266 dnl check for sys/times.h for tests/examples/adapter/
 267 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 268 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 269 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 270
 271 dnl Check for process.h for getpid() on win32
 272 AC_CHECK_HEADERS([process.h])
 273
 274 dnl Check for sys/utsname.h for uname
 275 AC_CHECK_HEADERS([sys/utsname.h])
 276
 277 dnl Check for stdio_ext.f for __fbufsize
 278 AC_CHECK_HEADERS([stdio_ext.h])
 279
 280 dnl check for pthreads
 281 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 282 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 283
 284 dnl Check for valgrind.h
 285 dnl separate from HAVE_VALGRIND because you can have the program, but not
 286 dnl the dev package
 287 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 288
 289 dnl used in gst/gstpoll.c
 290 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 291 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 292 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 293   WIN32_LIBS="-lws2_32"
 294   AC_SUBST(WIN32_LIBS)
 295 fi
 296
 297 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 298 if test "x$BUILD_TESTS" = "xyes"; then
 299   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 300                          __gmpz_init_set_d, ,
 301                          gmp.h,
 302                          GMP_LIBS="-lgmp"
 303                          AC_SUBST(GMP_LIBS)
 304                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 305   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 306                          gsl_rng_uniform_int, -lgslcblas,
 307                          gsl/gsl_rng.h,
 308                          GSL_LIBS="-lgsl -lgslcblas"
 309                          AC_SUBST(GSL_LIBS)
 310                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 311 fi
 312
 313 dnl *** checks for types/defines ***
 314
 315 dnl *** checks for structures ***
 316
 317 dnl *** checks for compiler characteristics ***
 318
 319 dnl check if the compiler supports __uint128_t (gcc)
 320 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 321     AC_TRY_COMPILE([ ], [
 322       unsigned long long v1 = 1024ULL;
 323       unsigned long long v2 = 0x8000000000000000ULL;
 324       __uint128_t u = ((__uint128_t)v1)*((__uint128_t)v2);
 325
 326       return 0;
 327     ], [
 328       gst_cv_uint128_t=yes
 329     ], [
 330       gst_cv_uint128_t=no
 331     ])
 332 )
 333 if test x$gst_cv_uint128_t = xyes; then
 334   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 335 fi
 336
 337 OPT_CFLAGS=
 338 dnl Check for some compiler flags that optimize our code.
 339 if test "x$GCC" = xyes; then
 340   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 341 fi
 342
 343 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 344 dnl flag
 345 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 346 dnl symbolic register names in inline asm
 347 if test x$HAVE_CPU_PPC = xyes ; then
 348   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 349     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 350 fi
 351
 352 dnl *** checks for library functions ***
 353
 354 AC_CHECK_FUNCS([sigaction])
 355
 356 dnl check for fseeko()
 357 AC_FUNC_FSEEKO
 358 dnl check for ftello()
 359 AC_CHECK_FUNCS([ftello])
 360
 361 AC_CHECK_FUNCS([fgetpos])
 362 AC_CHECK_FUNCS([fsetpos])
 363
 364 dnl check for poll(), ppoll() and pselect()
 365 AC_CHECK_FUNCS([poll])
 366 AC_CHECK_FUNCS([ppoll])
 367 AC_CHECK_FUNCS([pselect])
 368
 369 dnl ****************************************
 370 dnl *** GLib POLL* compatibility defines ***
 371 dnl ****************************************
 372
 373 AC_MSG_CHECKING([for broken poll])
 374 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 375         #include <stdlib.h>
 376         #include <fcntl.h>
 377         #include <poll.h>
 378         #ifdef HAVE_SYS_POLL_H
 379         #include <sys/poll.h>
 380         #endif
 381         int main(void) {
 382           struct pollfd fds[1];
 383           int fd;
 384           fd = open("/dev/null", 1);
 385           fds[0].fd = fd;
 386           fds[0].events = POLLIN;
 387           fds[0].revents = 0;
 388           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 389                 exit(1);  /* Does not work for devices -- fail */
 390           }
 391           exit(0);
 392         }]])],
 393   [broken_poll=no],
 394   [broken_poll=yes
 395    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 396   [broken_poll="no (cross compiling)"])
 397 AC_MSG_RESULT($broken_poll)
 398
 399 dnl check for mmap()
 400 AC_FUNC_MMAP
 401 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 402
 403 dnl Check for POSIX timers
 404 AC_CHECK_FUNCS(clock_gettime, [], [
 405   AC_CHECK_LIB(rt, clock_gettime, [
 406     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 407     LIBS="$LIBS -lrt"
 408   ])
 409 ])
 410
 411 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 412     AC_TRY_COMPILE([
 413 #include <time.h>
 414 #ifdef HAVE_UNISTD_H
 415 #include <unistd.h>
 416 #endif
 417     ], [
 418 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 419 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 420 #endif
 421       return 0;
 422     ], [
 423       gst_cv_posix_timers=yes
 424     ], [
 425       gst_cv_posix_timers=no
 426     ])
 427 )
 428
 429 if test "$gst_cv_posix_timers" = "yes"; then
 430   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 431   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 432 else
 433   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 434 fi
 435 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 436 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 437
 438 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 439     AC_TRY_COMPILE([
 440 #include <time.h>
 441 #ifdef HAVE_UNISTD_H
 442 #include <unistd.h>
 443 #endif
 444     ], [
 445 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 446 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 447 #endif
 448       return 0;
 449     ], [
 450       gst_cv_monotonic_clock=yes
 451     ], [
 452       gst_cv_monotonic_clock=no
 453     ])
 454 )
 455
 456 if test "$gst_cv_monotonic_clock" = "yes"; then
 457   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 458   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 459 else
 460   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 461 fi
 462 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 463 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 464
 465 dnl Check for a way to display the function name in debug output
 466 AG_GST_CHECK_FUNCTION
 467
 468 dnl test for register_printf_specifier or register_printf_function
 469 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 470     [HAVE_PRINTF_EXTENSION=yes])
 471
 472 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 473   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 474   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 475   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 476   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 477       [Defined if we have printf specifier extensions available])
 478 else
 479     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 480     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 481     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 482 fi
 483 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 484 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 485 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 486
 487 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 488 save_cflags="$CFLAGS"
 489 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 490 AC_CHECK_LIB(dl, dladdr,
 491    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 492    LIBS="$LIBS -ldl")
 493 CFLAGS="$save_cflags"
 494
 495 dnl *** checks for socket and nsl libraries ***
 496 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 497 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 498
 499 dnl check for inet_aton()
 500 save_libs="$LIBS"
 501 AC_CHECK_FUNC(inet_aton, ,
 502    AC_CHECK_LIB(nsl, inet_aton, ,
 503       AC_CHECK_LIB(socket, inet_aton, ,
 504          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 505 INET_ATON_LIBS=$LIBS
 506 AC_SUBST(INET_ATON_LIBS)
 507 LIBS="$save_libs"
 508
 509 dnl *** checks for dependency libraries ***
 510
 511 dnl GLib
 512 GLIB_REQ=2.18
 513
 514 AG_GST_GLIB_CHECK([$GLIB_REQ])
 515
 516 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 517 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 518 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 519
 520 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 521 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 522
 523 dnl Check for documentation xrefs
 524 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 525 AC_SUBST(GLIB_PREFIX)
 526
 527 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 528 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 529 then
 530   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 531   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 532 else
 533   dnl check for libxml2 with minimum req version
 534   AG_GST_LIBXML2_CHECK(2.4.9)
 535   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 536 fi
 537 AC_SUBST(GST_DISABLE_XML_DEFINE)
 538
 539 dnl building of unit test libraries
 540 AC_ARG_ENABLE(check,
 541   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 542   [
 543     case "${enableval}" in
 544       yes) BUILD_CHECK=yes ;;
 545       no)  BUILD_CHECK=no ;;
 546       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 547     esac
 548   ], [
 549     dnl Default value
 550     case $host_os in
 551       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 552       *) BUILD_CHECK=yes ;;
 553     esac
 554 ])
 555 dnl bit of a misnomer, but keep the conditional named like this so we don't
 556 dnl have to change too much elsewhere
 557 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 558
 559
 560 dnl *** set variables based on configure arguments
 561
 562 dnl set license and copyright notice
 563 GST_LICENSE="LGPL"
 564 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 565 AC_SUBST(GST_LICENSE)
 566
 567 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 568 AS_AC_EXPAND(LIBDIR, $libdir)
 569 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 570 AS_AC_EXPAND(DATADIR, $datadir)
 571 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 572
 573 dnl set location of plugin directory
 574 AG_GST_SET_PLUGINDIR
 575
 576 dnl FIXME: add LIBXML_PKG here if we use it
 577 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 578 AC_SUBST(GST_PKG_DEPS)
 579
 580 dnl define an ERROR_CFLAGS Makefile variable
 581 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wredundant-decls])
 582
 583 dnl define correct level for debugging messages
 584 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 585
 586 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 587
 588 dnl Overview:
 589 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 590 dnl GST_ALL_*:          vars shared by all built objects
 591 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 592 dnl GST_OBJ_*:          additional vars to link to the core library
 593 dnl                     include GST_ALL_*
 594 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 595 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 596
 597 dnl GST_OPTION_CFLAGS
 598 if test "x$USE_DEBUG" = xyes; then
 599    PROFILE_CFLAGS="-g"
 600 fi
 601 AC_SUBST(PROFILE_CFLAGS)
 602
 603 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 604 # functionality from the API that gstreamer uses
 605 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 606 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 607   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 608   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 609 else
 610   DEPRECATED_CFLAGS=""
 611 fi
 612 AC_SUBST(DEPRECATED_CFLAGS)
 613
 614 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 615 dnl make DEPRECATED_CFLAGS=''
 616 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 617 AC_SUBST(GST_OPTION_CFLAGS)
 618
 619 dnl GST_ALL_*
 620 dnl vars common to for all internal objects (core libs, elements, applications)
 621 dnl CFLAGS:
 622 dnl - XML needs to be added because xmlPtr is used in core
 623 dnl - src and build dirs need to be added because every piece that gets built
 624 dnl   will need the GStreamer source and generated headers
 625 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 626 dnl       from LibXML except for in the core library
 627 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS) -DG_THREADS_MANDATORY"
 628
 629 dnl FIXME: check if LTLIBINTL is needed everywhere
 630 dnl I presume it is given that it contains the symbols that _() stuff maps to
 631 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 632
 633 dnl LDFLAGS really should only contain flags, not libs - they get added before
 634 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 635 GST_ALL_LDFLAGS="-no-undefined"
 636
 637 AC_SUBST(GST_ALL_CFLAGS)
 638 AC_SUBST(GST_ALL_LIBS)
 639 AC_SUBST(GST_ALL_LDFLAGS)
 640
 641 dnl GST_LIB_LDFLAGS
 642 dnl linker flags shared by all libraries
 643 dnl LDFLAGS modifier defining exported symbols from built libraries
 644 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 645 AC_SUBST(GST_LIB_LDFLAGS)
 646
 647 dnl GST_OBJ_*
 648 dnl default vars for all internal objects built on libgstreamer
 649 dnl includes GST_ALL_*
 650 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 651 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 652 AC_SUBST(GST_OBJ_CFLAGS)
 653 AC_SUBST(GST_OBJ_LIBS)
 654
 655 dnl GST_PLUGIN_LDFLAGS
 656 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 657 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 658 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 659
 660 dnl plugin scanner locations
 661 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 662 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 663     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 664 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 665
 666 dnl things for our internal libcheck (must be called even if building
 667 dnl libcheck is disabled because it defines conditionals)
 668 AG_GST_CHECK_CHECKS()
 669
 670 AC_CONFIG_FILES(
 671 Makefile
 672 gst/Makefile
 673 gst/gstconfig.h
 674 gst/gstversion.h
 675 gst/parse/Makefile
 676 libs/Makefile
 677 libs/gst/Makefile
 678 libs/gst/base/Makefile
 679 libs/gst/check/Makefile
 680 libs/gst/check/libcheck/Makefile
 681 libs/gst/check/libcheck/check.h
 682 libs/gst/controller/Makefile
 683 libs/gst/dataprotocol/Makefile
 684 libs/gst/helpers/Makefile
 685 libs/gst/net/Makefile
 686 plugins/Makefile
 687 plugins/indexers/Makefile
 688 plugins/elements/Makefile
 689 po/Makefile.in
 690 tests/Makefile
 691 tests/benchmarks/Makefile
 692 tests/check/Makefile
 693 tests/misc/Makefile
 694 tests/examples/Makefile
 695 tests/examples/adapter/Makefile
 696 tests/examples/controller/Makefile
 697 tests/examples/stepping/Makefile
 698 tests/examples/helloworld/Makefile
 699 tests/examples/launch/Makefile
 700 tests/examples/manual/Makefile
 701 tests/examples/metadata/Makefile
 702 tests/examples/queue/Makefile
 703 tests/examples/streams/Makefile
 704 tests/examples/typefind/Makefile
 705 tests/examples/xml/Makefile
 706 tools/Makefile
 707 common/Makefile
 708 common/m4/Makefile
 709 docs/Makefile
 710 docs/design/Makefile
 711 docs/faq/Makefile
 712 docs/gst/Makefile
 713 docs/gst/gstreamer.types
 714 docs/libs/Makefile
 715 docs/plugins/Makefile
 716 docs/manual/Makefile
 717 docs/pwg/Makefile
 718 docs/slides/Makefile
 719 docs/xsl/Makefile
 720 docs/version.entities
 721 pkgconfig/Makefile
 722 stamp.h
 723 pkgconfig/gstreamer.pc
 724 pkgconfig/gstreamer-uninstalled.pc
 725 pkgconfig/gstreamer-base.pc
 726 pkgconfig/gstreamer-base-uninstalled.pc
 727 pkgconfig/gstreamer-check.pc
 728 pkgconfig/gstreamer-check-uninstalled.pc
 729 pkgconfig/gstreamer-controller.pc
 730 pkgconfig/gstreamer-controller-uninstalled.pc
 731 pkgconfig/gstreamer-dataprotocol.pc
 732 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 733 pkgconfig/gstreamer-net.pc
 734 pkgconfig/gstreamer-net-uninstalled.pc
 735 gst-element-check.m4
 736 gstreamer.spec
 737 )
 738
 739 dnl Create the config.h file for Visual Studio builds
 740 dnl Beware of spaces and /'s in some of the shell variable contents.
 741 sed \
 742     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 743     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 744     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 745     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 746     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 747     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 748     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 749     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 750     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 751     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 752     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 753     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 754     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 755     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 756     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 757     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 758     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 759     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 760     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 761     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 762     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 763     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 764     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 765     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 766     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 767     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 768     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 769     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 770     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 771     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 772     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 773     config.h.in >win32/common/config.h-new
 774
 775 AC_OUTPUT
 776
 777 dnl negate for output
 778 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 779 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 780 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 781 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 782 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 783 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 784 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 785 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 786 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 787
 788 echo "
 789
 790 Configuration
 791         Version                    : ${VERSION}
 792         Source code location       : ${srcdir}
 793         Prefix                     : ${prefix}
 794         Compiler                   : ${CC}
 795         Package name               : ${GST_PACKAGE_NAME}
 796         Package origin             : ${GST_PACKAGE_ORIGIN}
 797
 798         Documentation (manuals)    : ${enable_docbook}
 799         Documentation (API)        : ${enable_gtk_doc}
 800
 801         Debug Logging              : ${enable_gst_debug}
 802         Pipeline XML load/save     : ${enable_loadsave}
 803         Command-line parser        : ${enable_parse}
 804         Option parsing in gst_init : ${enable_option_parsing}
 805         Tracing subsystem          : ${enable_trace}
 806         Allocation tracing         : ${enable_alloc_trace}
 807         Plugin registry            : ${enable_registry}
 808         Plugin support             : ${enable_plugin}
 809         Network support            : ${enable_net}
 810         Unit testing support       : ${BUILD_CHECK}
 811
 812         Debug                      : ${USE_DEBUG}
 813         Profiling                  : ${USE_PROFILING}
 814
 815         Building examples          : ${BUILD_EXAMPLES}
 816         Building test apps         : ${BUILD_TESTS}
 817         Building tests that fail   : ${BUILD_FAILING_TESTS}
 818 "