configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl we don't specify PACKAGE and VERSION because AS_VERSION puts it together
   5 AC_INIT
   6
   7 dnl when going to/from release please set the nano (fourth number) right !
   8 dnl releases only do Wall, cvs and prerelease does Werror too
   9 AS_VERSION(gst-plugins-base, GST_PLUGINS_BASE_VERSION, 0, 10, 4, 0,
  10     GST_CVS="no", GST_CVS="yes")
  11
  12 dnl can autoconf find the source ?
  13 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  14
  15 dnl define the output header for config
  16 AM_CONFIG_HEADER([config.h])
  17
  18 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  19 AM_MAINTAINER_MODE
  20
  21 dnl sets host_* variables
  22 AC_CANONICAL_HOST
  23
  24 dnl initialize automake
  25 dnl FIXME: this is deprecated use, we should move PACKAGE and VERSION to
  26 dnl AC_INIT, but then we need to parse the version to pass to AS_VERSION
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  28
  29 dnl our libraries and install dirs use major.minor as a version
  30 GST_MAJORMINOR=$GST_PLUGINS_BASE_VERSION_MAJOR.$GST_PLUGINS_BASE_VERSION_MINOR
  31 dnl we override it here if we need to for the release candidate of new series
  32 GST_MAJORMINOR=0.10
  33 AC_SUBST(GST_MAJORMINOR)
  34
  35 dnl CURRENT, REVISION, AGE
  36 dnl - library source changed -> increment REVISION
  37 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  38 dnl - interfaces added -> increment AGE
  39 dnl - interfaces removed -> AGE = 0
  40 dnl sets GST_LT_LDFLAGS
  41 AS_LIBTOOL(GST, 2, 0, 2)
  42 AS_LIBTOOL_TAGS
  43 AM_PROG_LIBTOOL
  44
  45 dnl *** required versions of GStreamer stuff ***
  46 GST_REQ=0.10.4
  47
  48 dnl *** autotools stuff ****
  49
  50 dnl allow for different autotools
  51 AS_AUTOTOOLS_ALTERNATE
  52
  53 dnl Add parameters for aclocal
  54 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  55
  56 dnl set up gettext
  57 dnl the version check needs to stay here because autopoint greps for it
  58 AM_GNU_GETTEXT_VERSION([0.11.5])
  59 AM_GNU_GETTEXT([external])
  60 GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  61
  62 dnl *** check for arguments to configure ***
  63
  64 GST_ARG_DEBUG
  65 GST_ARG_PROFILING
  66 GST_ARG_VALGRIND
  67 GST_ARG_GCOV
  68
  69 GST_ARG_EXAMPLES
  70
  71 GST_ARG_WITH_PKG_CONFIG_PATH
  72 GST_ARG_WITH_PACKAGE_NAME([GStreamer Base Plug-ins])
  73 GST_ARG_WITH_PACKAGE_ORIGIN
  74
  75 dnl these are all the gst plug-ins, compilable without additional libs
  76 GST_PLUGINS_ALL="\
  77         adder \
  78         audioconvert \
  79         audiorate \
  80         audioresample \
  81         audiotestsrc \
  82         ffmpegcolorspace \
  83         playback \
  84         typefind \
  85         videotestsrc \
  86         videorate \
  87         videoscale \
  88         volume \
  89         "
  90 AC_SUBST(GST_PLUGINS_ALL)
  91
  92 GST_PLUGINS_SELECTED=""
  93
  94 AC_ARG_WITH(plugins,
  95     AC_HELP_STRING([--with-plugins],
  96       [comma-separated list of plug-ins to compile]),
  97     [for i in `echo $withval | tr , ' '`; do
  98         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
  99         then
 100             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 101         else
 102             echo "plug-in $i not recognized, ignoring..."
 103         fi
 104     done],
 105     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 106
 107 AC_SUBST(GST_PLUGINS_SELECTED)
 108
 109 dnl ext plug-ins; plug-ins that have external dependencies
 110 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 111   [HAVE_EXTERNAL=yes], enabled,
 112   [
 113     AC_MSG_NOTICE(building external plug-ins)
 114     BUILD_EXTERNAL="yes"
 115   ],[
 116     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 117     BUILD_EXTERNAL="no"
 118   ])
 119 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 GST_ARCH
 128
 129 dnl *** checks for programs ***
 130
 131 dnl find a compiler
 132 AC_PROG_CC
 133
 134 dnl determine c++ compiler
 135 AC_PROG_CXX
 136 dnl determine if c++ is available on this system
 137 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 138
 139 dnl determine c++ preprocessor
 140 dnl FIXME: do we need this ?
 141 AC_PROG_CXXCPP
 142
 143 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 144 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 145
 146 dnl check for documentation tools
 147 GTK_DOC_CHECK([1.3])
 148 AS_PATH_PYTHON([2.1])
 149
 150 dnl *** checks for libraries ***
 151
 152 dnl For interactive UNIX (a Sun thing)
 153 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 154 AC_ISC_POSIX
 155
 156 dnl *** checks for header files ***
 157
 158 dnl check if we have ANSI C header files
 159 AC_HEADER_STDC
 160
 161 dnl used in gst/ffmpegcolorspace/mem.c
 162 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 163 AC_CHECK_HEADERS([malloc.h])
 164
 165 dnl used in gst/subparse/gstsubparse.c
 166 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 167 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 168
 169 dnl used in gst/tcp
 170 AC_CHECK_HEADERS([sys/socket.h],
 171   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 172 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 173
 174 dnl ffmpegcolorspace includes _stdint.h
 175 dnl also, Windows does not have long long
 176 AX_CREATE_STDINT_H
 177
 178 dnl *** checks for types/defines ***
 179
 180 dnl Check for FIONREAD ioctl declaration
 181 dnl used in gst/tcp
 182 GST_CHECK_FIONREAD
 183
 184 dnl *** checks for structures ***
 185
 186 dnl *** checks for compiler characteristics ***
 187
 188 dnl make sure we can use "inline" from C code
 189 AC_C_INLINE
 190
 191 dnl *** checks for library functions ***
 192
 193 dnl Check for fast float to int casting as defined in C99
 194 dnl used in gst-libs/gst/floatcast/floatcast.h
 195 AC_C99_FUNC_LRINT
 196 AC_C99_FUNC_LRINTF
 197
 198 dnl Check for a way to display the function name in debug output
 199 GST_CHECK_FUNCTION
 200
 201 dnl *** checks for dependancy libraries ***
 202
 203 dnl GLib is required
 204 GST_GLIB_CHECK([2.6])
 205
 206 dnl liboil is required
 207 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.6, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 208 if test "x${HAVE_LIBOIL}" != xyes ; then
 209   AC_ERROR([liboil-0.3.6 or later is required])
 210 fi
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 215 GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 216 GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 217 GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 218 GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 219
 220 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 221 dnl check for "check", unit testing library/header
 222 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 223 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 224
 225 dnl GTK is optional and used in examples
 226 HAVE_GTK=NO
 227 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 228 if test "x$HAVE_GTK_22" = "xyes"; then
 229   HAVE_GTK=yes
 230   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 231   AC_SUBST(GTK_VERSION)
 232   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 233   AC_SUBST(GTK_BASE_DIR)
 234 else
 235   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 236 fi
 237 if test "x$HAVE_GTK_20" = "xyes"; then
 238   HAVE_GTK=yes
 239 fi
 240 GTK_CFLAGS=$GTK2_CFLAGS
 241 GTK_LIBS=$GTK2_LIBS
 242 AC_SUBST(GTK_LIBS)
 243 AC_SUBST(GTK_CFLAGS)
 244 AC_SUBST(HAVE_GTK)
 245 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 246
 247 dnl *** set variables based on configure arguments ***
 248
 249 dnl set license and copyright notice
 250 GST_LICENSE="LGPL"
 251 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 252 AC_SUBST(GST_LICENSE)
 253
 254 dnl set location of plugin directory
 255 GST_SET_PLUGINDIR
 256
 257 dnl define an ERROR_CFLAGS Makefile variable
 258 GST_SET_ERROR_CFLAGS($GST_CVS)
 259
 260 dnl define correct level for debugging messages
 261 GST_SET_LEVEL_DEFAULT($GST_CVS)
 262
 263 dnl used in examples
 264 GST_DEFAULT_ELEMENTS
 265
 266 dnl *** sys plug-ins ***
 267
 268 echo
 269 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 270 echo
 271
 272 dnl *** X11 ***
 273 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 274 GST_CHECK_FEATURE(X, [X libraries and plugins],
 275                   [ximagesink], [
 276   AC_PATH_XTRA
 277   ac_cflags_save="$CFLAGS"
 278   ac_cppflags_save="$CPPFLAGS"
 279   CFLAGS="$CFLAGS $X_CFLAGS"
 280   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 281
 282   dnl now try to find the HEADER
 283   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 284
 285   if test "x$HAVE_X" = "xno"
 286   then
 287     AC_MSG_NOTICE([cannot find X11 development files])
 288   else
 289     dnl this is much more than we want
 290     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 291     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 292     dnl it does not add the libs; therefore we add them here
 293     X_LIBS="$X_LIBS -lX11"
 294     AC_SUBST(X_CFLAGS)
 295     AC_SUBST(X_LIBS)
 296   fi
 297   AC_SUBST(HAVE_X)
 298   CFLAGS="$ac_cflags_save"
 299   CPPFLAGS="$ac_cppflags_save"
 300 ])
 301
 302 dnl *** XVideo ***
 303 dnl Look for the PIC library first, Debian requires it.
 304 dnl Check debian-devel archives for gory details.
 305 dnl 20020110:
 306 dnl At the moment XFree86 doesn't distribute shared libXv due
 307 dnl to unstable API.  On many platforms you CAN NOT link a shared
 308 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 309 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 310 dnl version of the static lib for plug-ins to link to when it is
 311 dnl inappropriate to link the main application to libXv directly.
 312 dnl FIXME: add check if this platform can support linking to a
 313 dnl        non-PIC libXv, if not then don not use Xv.
 314 dnl FIXME: perhaps warn user if they have a shared libXv since
 315 dnl        this is an error until XFree86 starts shipping one
 316
 317 dnl Check for Xv extension
 318 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 319 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 320                   [xvimagesink], [
 321   if test x$HAVE_X = xyes; then
 322     AC_CHECK_LIB(Xv_pic, XvQueryExtension,
 323                  HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 324                  $X_LIBS -lXext)
 325
 326     if test x$HAVE_XVIDEO = xyes; then
 327       XVIDEO_LIBS="-lXv_pic -lXext"
 328       AC_SUBST(XVIDEO_LIBS)
 329     else
 330       dnl try again using something else if we didn't find it first
 331       if test x$HAVE_XVIDEO = xno; then
 332         AC_CHECK_LIB(Xv, XvQueryExtension,
 333                    HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 334                    $X_LIBS -lXext)
 335
 336         if test x$HAVE_XVIDEO = xyes; then
 337           XVIDEO_LIBS="-lXv -lXext"
 338           AC_SUBST(XVIDEO_LIBS)
 339         fi
 340       fi
 341     fi
 342   fi
 343 ])
 344
 345 dnl check for X Shm
 346 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 347 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 348   if test x$HAVE_X = xyes; then
 349     AC_CHECK_LIB(Xext, XShmAttach,
 350                  HAVE_XSHM="yes", HAVE_XSHM="no",
 351                  $X_LIBS)
 352     if test "x$HAVE_XSHM" = "xyes"; then
 353       XSHM_LIBS="-lXext"
 354     else
 355       dnl On AIX, it is in XextSam instead, but we still need -lXext
 356       AC_CHECK_LIB(XextSam, XShmAttach,
 357                    HAVE_XSHM="yes", HAVE_XSHM="no",
 358                    $X_LIBS)
 359       if test "x$HAVE_XSHM" = "xyes"; then
 360         XSHM_LIBS="-lXext -lXextSam"
 361       fi
 362     fi
 363   fi
 364 ], , [
 365   AC_SUBST(HAVE_XSHM)
 366   AC_SUBST(XSHM_LIBS)
 367 ] )
 368
 369 dnl v4l/v4l2 checks have been moved down because they require X
 370
 371 dnl *** Video 4 Linux ***
 372 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 373 dnl renamed to GST_V4L in accordance with V4L2 below
 374 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 375 GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 376   # first check X
 377   HAVE_GST_V4L="no"
 378   if test "$HAVE_X" = "yes"
 379   then
 380     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 381 #include <sys/types.h>
 382 #define _LINUX_TIME_H
 383 #define __user
 384 #include <linux/videodev.h>
 385     ])
 386   fi
 387 ])
 388
 389 dnl *** ext plug-ins ***
 390 dnl keep this list sorted alphabetically !
 391
 392 if test "x$BUILD_EXTERNAL" = "xyes"; then
 393
 394 echo
 395 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 396 echo
 397
 398 dnl *** alsa ***
 399 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 400 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 401   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 402     HAVE_ALSA="yes"
 403     AC_SUBST(ALSA_CFLAGS)
 404     AC_SUBST(ALSA_LIBS)
 405   ], [
 406     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 407   ])
 408 ])
 409
 410 dnl *** CDParanoia ***
 411 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 412 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 413   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 414                       cdda_open, -lm,
 415                       cdda_interface.h,
 416                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 417                       HEADER_DIR="no"
 418                       FOUND_CDPARANOIA="yes")
 419   if test "x$FOUND_CDPARANOIA" != "xyes";
 420   then
 421     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 422                         cdda_open, -lm,
 423                         cdda/cdda_interface.h,
 424                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 425                         HEADER_DIR="yes"
 426                         FOUND_CDPARANOIA="yes")
 427   fi
 428   if test "x$HEADER_DIR" = "xyes";
 429   then
 430     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 431                        defined if cdda headers are in a cdda/ directory)
 432   fi
 433   AC_SUBST(CDPARANOIA_LIBS)
 434 ])
 435 dnl FIXME : add second check somehow if that is necessary
 436 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 437 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 438 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 439   [HAVE_EXTERNAL=yes], enabled,
 440   [
 441     AC_MSG_NOTICE(building external plug-ins)
 442     BUILD_EXTERNAL="yes"
 443   ],[
 444     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 445     BUILD_EXTERNAL="no"
 446   ])
 447
 448
 449 dnl *** Gnome VFS ***
 450 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 451 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 452   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 453   AC_SUBST(GNOME_VFS_CFLAGS)
 454   AC_SUBST(GNOME_VFS_LIBS)
 455 ])
 456
 457 dnl *** libvisual ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 459 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
 460   PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
 461   AC_SUBST(LIBVISUAL_CFLAGS)
 462   AC_SUBST(LIBVISUAL_LIBS)
 463 ])
 464
 465 dnl *** ogg ***
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 467 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
 468   PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
 469     HAVE_OGG="yes"
 470     AC_SUBST(OGG_CFLAGS)
 471     AC_SUBST(OGG_LIBS)
 472   ], [
 473     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 474     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 475   ])
 476 ])
 477
 478 dnl *** pango ***
 479 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 480 GST_CHECK_FEATURE(PANGO, [pango], pango, [
 481   PKG_CHECK_MODULES(PANGO, pango pangoft2,
 482       HAVE_PANGO="yes", HAVE_PANGO="no")
 483   AC_SUBST(PANGO_CFLAGS)
 484   AC_SUBST(PANGO_LIBS)
 485 ])
 486
 487 dnl *** theora ***
 488 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 489 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec theoraenc, [
 490   PKG_CHECK_MODULES(THEORA, theora, [
 491     HAVE_THEORA="yes"
 492     AC_SUBST(THEORA_LIBS)
 493     AC_SUBST(THEORA_CFLAGS)
 494   ], [
 495     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 496     AC_SUBST(THEORA_LIBS)
 497   ])
 498 ])
 499
 500 dnl *** vorbis ***
 501 dnl AM_PATH_VORBIS only takes two options
 502 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 503 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
 504   PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
 505     HAVE_VORBIS="yes"
 506   ], [
 507     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 508     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 509   ])
 510 ])
 511 if test "x$HAVE_VORBIS" = "xyes"; then
 512   ac_cflags_save="$CFLAGS"
 513   dnl FIXME: does this work on non-gcc? -- Company
 514   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 515   CFLAGS="-Wall -Werror"
 516   AC_COMPILE_IFELSE(
 517     AC_LANG_PROGRAM([
 518 #include <vorbis/codec.h>
 519                      ],[
 520 vorbis_dsp_state *v;
 521
 522 vorbis_synthesis_restart (v);
 523                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 524   if test "x$HAVE_VSR" = "xyes"; then
 525     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 526                        [defined if vorbis_synthesis_restart is present])
 527   fi
 528   CFLAGS="$ac_cflags_save"
 529 fi
 530
 531 fi dnl of EXT plugins
 532
 533 dnl seeking needs freetype, so check for it here
 534 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 535   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 536 ])
 537 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 538 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 539 AC_SUBST(FT2_CFLAGS)
 540 AC_SUBST(FT2_LIBS)
 541
 542 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 543
 544 dnl Overview:
 545 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 546 dnl GST_*:              flags shared by built objects to link against GStreamer
 547 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 548 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 549 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 550 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 551
 552 dnl GST_OPTION_CFLAGS
 553 if test "x$USE_DEBUG" = xyes; then
 554    PROFILE_CFLAGS="-g"
 555 fi
 556 AC_SUBST(PROFILE_CFLAGS)
 557
 558 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 559 AC_SUBST(DEPRECATED_CFLAGS)
 560
 561 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 562 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 563 AC_SUBST(GST_OPTION_CFLAGS)
 564
 565 dnl our libraries need to be versioned correctly
 566 AC_SUBST(GST_LT_LDFLAGS)
 567
 568 dnl FIXME: do we want to rename to GST_ALL_* ?
 569 dnl prefer internal headers to already installed ones
 570 dnl also add builddir include for enumtypes and marshal
 571 dnl add GST_OPTION_CFLAGS, but overridable
 572 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 573 AC_SUBST(GST_CFLAGS)
 574 AC_SUBST(GST_LIBS)
 575
 576 dnl LDFLAGS really should only contain flags, not libs - they get added before
 577 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 578 GST_ALL_LDFLAGS="-no-undefined"
 579 AC_SUBST(GST_ALL_LDFLAGS)
 580
 581 dnl GST_LIB_LDFLAGS
 582 dnl linker flags shared by all libraries
 583 dnl LDFLAGS modifier defining exported symbols from built libraries
 584 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 585 AC_SUBST(GST_LIB_LDFLAGS)
 586
 587 dnl this really should only contain flags, not libs - they get added before
 588 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 589 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 590 AC_SUBST(GST_PLUGIN_LDFLAGS)
 591
 592 dnl *** output files ***
 593
 594 AC_CONFIG_FILES(
 595 Makefile
 596 gst-plugins-base.spec
 597 gst/Makefile
 598 gst/adder/Makefile
 599 gst/audioconvert/Makefile
 600 gst/audiorate/Makefile
 601 gst/audioresample/Makefile
 602 gst/audiotestsrc/Makefile
 603 gst/ffmpegcolorspace/Makefile
 604 gst/playback/Makefile
 605 gst/subparse/Makefile
 606 gst/tcp/Makefile
 607 gst/typefind/Makefile
 608 gst/videotestsrc/Makefile
 609 gst/videorate/Makefile
 610 gst/videoscale/Makefile
 611 gst/volume/Makefile
 612 sys/Makefile
 613 sys/ximage/Makefile
 614 sys/xvimage/Makefile
 615 sys/v4l/Makefile
 616 ext/Makefile
 617 ext/alsa/Makefile
 618 ext/cdparanoia/Makefile
 619 ext/gnomevfs/Makefile
 620 ext/libvisual/Makefile
 621 ext/ogg/Makefile
 622 ext/pango/Makefile
 623 ext/theora/Makefile
 624 ext/vorbis/Makefile
 625 gst-libs/Makefile
 626 gst-libs/gst/Makefile
 627 gst-libs/gst/audio/Makefile
 628 gst-libs/gst/cdda/Makefile
 629 gst-libs/gst/floatcast/Makefile
 630 gst-libs/gst/interfaces/Makefile
 631 gst-libs/gst/netbuffer/Makefile
 632 gst-libs/gst/riff/Makefile
 633 gst-libs/gst/rtp/Makefile
 634 gst-libs/gst/tag/Makefile
 635 gst-libs/gst/video/Makefile
 636 tools/Makefile
 637 win32/common/config.h
 638 pkgconfig/Makefile
 639 pkgconfig/gstreamer-plugins-base.pc
 640 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 641 tests/Makefile
 642 tests/check/Makefile
 643 tests/examples/Makefile
 644 tests/examples/seek/Makefile
 645 tests/examples/volume/Makefile
 646 tests/icles/Makefile
 647 docs/Makefile
 648 docs/libs/Makefile
 649 docs/plugins/Makefile
 650 docs/version.entities
 651 po/Makefile.in
 652 common/Makefile
 653 common/m4/Makefile
 654 m4/Makefile
 655 )
 656 AC_OUTPUT
 657
 658 echo "configure: *** Core plug-ins, always built:"
 659 ( for i in $GST_PLUGINS_ALL; do echo -e '\t'$i; done ) | sort
 660 echo
 661 echo -n "configure: *** Plug-ins relying on libraries that will be built:"
 662 echo -e "$GST_PLUGINS_YES" | sort
 663 echo
 664 echo -n "configure: *** Plug-ins relying on libraries that will NOT be built:"
 665 echo -e "$GST_PLUGINS_NO" | sort
 666 echo
 667 if test "x$BUILD_EXTERNAL" = "xno"; then
 668   echo "configure: *** No external plug-ins will be built"
 669 fi