configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 AC_ARG_WITH(system-zlib,
 242 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 243 # Make sure we don't let ZLIB be added if we didn't want it.
 244 if test x$with_system_zlib = xyes ; then
 245   use_included_zlib=no
 246   noconfigdirs="$noconfigdirs zlib"
 247 fi
 248
 249 # some tools are so dependent upon X11 that if we're not building with X,
 250 # it's not even worth trying to configure, much less build, that tool.
 251
 252 case ${with_x} in
 253   yes | "") ;; # the default value for this tree is that X11 is available
 254   no)
 255     skipdirs="${skipdirs} tk itcl libgui"
 256     # We won't be able to build gdbtk without X.
 257     enable_gdbtk=no
 258     ;;
 259   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 260 esac
 261
 262 # Some are only suitable for cross toolchains.
 263 # Remove these if host=target.
 264 cross_only="target-libgloss target-newlib target-opcodes"
 265
 266 case $is_cross_compiler in
 267   no) skipdirs="${skipdirs} ${cross_only}" ;;
 268 esac
 269
 270 # If both --with-headers and --with-libs are specified, default to
 271 # --without-newlib.
 272 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 273    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 274   if test x"${with_newlib}" = x ; then
 275     with_newlib=no
 276   fi
 277 fi
 278
 279 # Recognize --with-newlib/--without-newlib.
 280 case ${with_newlib} in
 281   no) skipdirs="${skipdirs} target-newlib" ;;
 282   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 283 esac
 284
 285 AC_ARG_ENABLE(as-accelerator-for,
 286 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 287                 [build as offload target compiler.
 288                 Specify offload host triple by ARG])])
 289
 290 AC_ARG_ENABLE(offload-targets,
 291 [AS_HELP_STRING([--enable-offload-targets=LIST],
 292                 [enable offloading to devices from comma-separated LIST of
 293                 TARGET[=DIR]. Use optional path to find offload target compiler
 294                 during the build])],
 295 [
 296   if test x"$enable_offload_targets" = x; then
 297     AC_MSG_ERROR([no offload targets specified])
 298   fi
 299 ], [enable_offload_targets=])
 300
 301 # Handle --enable-gold, --enable-ld.
 302 # --disable-gold [--enable-ld]
 303 #     Build only ld.  Default option.
 304 # --enable-gold [--enable-ld]
 305 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 306 #     as "ld.bfd" and "ld".
 307 # --enable-gold=default [--enable-ld]
 308 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 309 #     install ld as "ld.bfd".
 310 # --enable-gold[=default] --disable-ld
 311 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 312 # --enable-gold --enable-ld=default
 313 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 314 #     and ld.bfd).
 315 #     In other words, ld is default
 316 # --enable-gold=default --enable-ld=default
 317 #     Error.
 318
 319 default_ld=
 320 AC_ARG_ENABLE(gold,
 321 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 322                 [build gold @<:@ARG={default,yes,no}@:>@])],
 323 ENABLE_GOLD=$enableval,
 324 ENABLE_GOLD=no)
 325 case "${ENABLE_GOLD}" in
 326   yes|default)
 327     # Check for ELF target.
 328     is_elf=no
 329     case "${target}" in
 330       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 331       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 332       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 333       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 334         case "${target}" in
 335           *-*-linux*aout* | *-*-linux*oldld*)
 336             ;;
 337           *)
 338             is_elf=yes
 339             ;;
 340         esac
 341     esac
 342
 343     if test "$is_elf" = "yes"; then
 344       # Check for target supported by gold.
 345       case "${target}" in
 346         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 347         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 348           configdirs="$configdirs gold"
 349           if test x${ENABLE_GOLD} = xdefault; then
 350             default_ld=gold
 351           fi
 352           ENABLE_GOLD=yes
 353           ;;
 354       esac
 355     fi
 356     ;;
 357   no)
 358     ;;
 359   *)
 360     AC_MSG_ERROR([invalid --enable-gold argument])
 361     ;;
 362 esac
 363
 364 AC_ARG_ENABLE(ld,
 365 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 366                 [build ld @<:@ARG={default,yes,no}@:>@])],
 367 ENABLE_LD=$enableval,
 368 ENABLE_LD=yes)
 369
 370 case "${ENABLE_LD}" in
 371   default)
 372     if test x${default_ld} != x; then
 373       AC_MSG_ERROR([either gold or ld can be the default ld])
 374     fi
 375     ;;
 376   yes)
 377     ;;
 378   no)
 379     if test x${ENABLE_GOLD} != xyes; then
 380       AC_MSG_WARN([neither ld nor gold are enabled])
 381     fi
 382     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 383     ;;
 384   *)
 385     AC_MSG_ERROR([invalid --enable-ld argument])
 386     ;;
 387 esac
 388
 389 # PR gas/19109
 390 # Decide the default method for compressing debug sections.
 391 # Provide a configure time option to override our default.
 392 AC_ARG_ENABLE(compressed_debug_sections,
 393 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 394                 [Enable compressed debug sections for gas, gold or ld by
 395                  default])],
 396 [
 397   if test x"$enable_compressed_debug_sections" = xyes; then
 398     AC_MSG_ERROR([no program with compressed debug sections specified])
 399   fi
 400 ], [enable_compressed_debug_sections=])
 401
 402 # Configure extra directories which are host specific
 403
 404 case "${host}" in
 405   *-cygwin*)
 406     configdirs="$configdirs libtermcap" ;;
 407 esac
 408
 409 # A target can indicate whether a language isn't supported for some reason.
 410 # Only spaces may be used in this macro; not newlines or tabs.
 411 unsupported_languages=
 412
 413 # Remove more programs from consideration, based on the host or
 414 # target this usually means that a port of the program doesn't
 415 # exist yet.
 416
 417 case "${host}" in
 418   i[[3456789]]86-*-msdosdjgpp*)
 419     noconfigdirs="$noconfigdirs tcl tk itcl"
 420     ;;
 421 esac
 422
 423
 424 AC_ARG_ENABLE(libquadmath,
 425 AS_HELP_STRING([--disable-libquadmath],
 426   [do not build libquadmath directory]),
 427 ENABLE_LIBQUADMATH=$enableval,
 428 ENABLE_LIBQUADMATH=yes)
 429 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 430   noconfigdirs="$noconfigdirs target-libquadmath"
 431 fi
 432
 433
 434 AC_ARG_ENABLE(libquadmath-support,
 435 AS_HELP_STRING([--disable-libquadmath-support],
 436   [disable libquadmath support for Fortran]),
 437 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 438 ENABLE_LIBQUADMATH_SUPPORT=yes)
 439 enable_libquadmath_support=
 440 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 441   enable_libquadmath_support=no
 442 fi
 443
 444
 445 AC_ARG_ENABLE(libada,
 446 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 447 ENABLE_LIBADA=$enableval,
 448 ENABLE_LIBADA=yes)
 449 if test "${ENABLE_LIBADA}" != "yes" ; then
 450   noconfigdirs="$noconfigdirs gnattools"
 451 fi
 452
 453 AC_ARG_ENABLE(libssp,
 454 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 455 ENABLE_LIBSSP=$enableval,
 456 ENABLE_LIBSSP=yes)
 457
 458 AC_ARG_ENABLE(libstdcxx,
 459 AS_HELP_STRING([--disable-libstdcxx],
 460   [do not build libstdc++-v3 directory]),
 461 ENABLE_LIBSTDCXX=$enableval,
 462 ENABLE_LIBSTDCXX=default)
 463 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 464   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 465 fi]
 466
 467 # If this is accelerator compiler and its target is intelmic we enable
 468 # target liboffloadmic by default.  If this is compiler with offloading
 469 # for intelmic we enable host liboffloadmic by default.  Otherwise
 470 # liboffloadmic is disabled by default.
 471 AC_ARG_ENABLE([liboffloadmic],
 472 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 473                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 474 [case "$enableval" in
 475   no | host | target)
 476     enable_liboffloadmic=$enableval ;;
 477   *)
 478     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 479 esac],
 480 [if test x"$enable_as_accelerator_for" != x; then
 481   case "${target}" in
 482     *-intelmic-* | *-intelmicemul-*)
 483       enable_liboffloadmic=target
 484       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 485       ;;
 486     *)
 487       enable_liboffloadmic=no
 488       ;;
 489   esac
 490 else
 491   case "${enable_offload_targets}" in
 492     *-intelmic-* | *-intelmicemul-*)
 493       enable_liboffloadmic=host
 494       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 495       ;;
 496     *)
 497       enable_liboffloadmic=no
 498       ;;
 499     esac
 500 fi])
 501 AC_SUBST(extra_liboffloadmic_configure_flags)
 502
 503 # Enable libgomp by default on hosted POSIX systems, and a few others.
 504 if test x$enable_libgomp = x ; then
 505     case "${target}" in
 506     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 507         ;;
 508     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 509         ;;
 510     *-*-solaris2* | *-*-hpux11*)
 511         ;;
 512     *-*-darwin* | *-*-aix*)
 513         ;;
 514     nvptx*-*-*)
 515         ;;
 516     *)
 517         noconfigdirs="$noconfigdirs target-libgomp"
 518         ;;
 519     esac
 520 fi
 521
 522 # Disable libatomic on unsupported systems.
 523 if test -d ${srcdir}/libatomic; then
 524     if test x$enable_libatomic = x; then
 525         AC_MSG_CHECKING([for libatomic support])
 526         if (srcdir=${srcdir}/libatomic; \
 527                 . ${srcdir}/configure.tgt; \
 528                 test -n "$UNSUPPORTED")
 529         then
 530             AC_MSG_RESULT([no])
 531             noconfigdirs="$noconfigdirs target-libatomic"
 532         else
 533             AC_MSG_RESULT([yes])
 534         fi
 535     fi
 536 fi
 537
 538 # Disable liboffloadmic on unsupported systems.
 539 if test -d ${srcdir}/liboffloadmic; then
 540     if test x$enable_liboffloadmic != xno; then
 541         AC_MSG_CHECKING([for liboffloadmic support])
 542         if (srcdir=${srcdir}/liboffloadmic; \
 543                 . ${srcdir}/configure.tgt; \
 544                 test -n "$UNSUPPORTED")
 545         then
 546             AC_MSG_RESULT([no])
 547             noconfigdirs="$noconfigdirs target-liboffloadmic"
 548         else
 549             AC_MSG_RESULT([yes])
 550         fi
 551     fi
 552 fi
 553
 554 # Disable libitm on unsupported systems.
 555 if test -d ${srcdir}/libitm; then
 556     if test x$enable_libitm = x; then
 557         AC_MSG_CHECKING([for libitm support])
 558         if (srcdir=${srcdir}/libitm; \
 559                 . ${srcdir}/configure.tgt; \
 560                 test -n "$UNSUPPORTED")
 561         then
 562             AC_MSG_RESULT([no])
 563             noconfigdirs="$noconfigdirs target-libitm"
 564         else
 565             AC_MSG_RESULT([yes])
 566         fi
 567     fi
 568 fi
 569
 570 # Disable libsanitizer on unsupported systems.
 571 if test -d ${srcdir}/libsanitizer; then
 572     if test x$enable_libsanitizer = x; then
 573         AC_MSG_CHECKING([for libsanitizer support])
 574         if (srcdir=${srcdir}/libsanitizer; \
 575                 . ${srcdir}/configure.tgt; \
 576                 test -n "$UNSUPPORTED")
 577         then
 578             AC_MSG_RESULT([no])
 579             noconfigdirs="$noconfigdirs target-libsanitizer"
 580         else
 581             AC_MSG_RESULT([yes])
 582         fi
 583     fi
 584 fi
 585
 586 # Disable libvtv on unsupported systems.
 587 if test -d ${srcdir}/libvtv; then
 588     if test x$enable_libvtv = x; then
 589         AC_MSG_CHECKING([for libvtv support])
 590         if (srcdir=${srcdir}/libvtv; \
 591                 . ${srcdir}/configure.tgt; \
 592                 test "$VTV_SUPPORTED" != "yes")
 593         then
 594             AC_MSG_RESULT([no])
 595             noconfigdirs="$noconfigdirs target-libvtv"
 596         else
 597             AC_MSG_RESULT([yes])
 598         fi
 599     fi
 600 fi
 601
 602
 603 # Disable libhsail-rt on unsupported systems.
 604 if test -d ${srcdir}/libhsail-rt; then
 605     if test x$enable_libhsail_rt = x; then
 606         AC_MSG_CHECKING([for libhsail-rt support])
 607         if (srcdir=${srcdir}/libhsail-rt; \
 608                 . ${srcdir}/configure.tgt; \
 609                 test -n "$UNSUPPORTED")
 610         then
 611             AC_MSG_RESULT([no])
 612             unsupported_languages="$unsupported_languages brig"
 613             # This implicitly disables also target-libhsail-rt as it won't
 614             # get added to the build without BRIG FE.
 615         else
 616             AC_MSG_RESULT([yes])
 617         fi
 618     fi
 619 fi
 620
 621
 622 # Disable libquadmath for some systems.
 623 case "${target}" in
 624   avr-*-*)
 625     noconfigdirs="$noconfigdirs target-libquadmath"
 626     ;;
 627   # libquadmath is unused on AIX and libquadmath build process use of
 628   # LD_LIBRARY_PATH can break AIX bootstrap.
 629   powerpc-*-aix* | rs6000-*-aix*)
 630     noconfigdirs="$noconfigdirs target-libquadmath"
 631     ;;
 632 esac
 633
 634 # Disable libssp for some systems.
 635 case "${target}" in
 636   avr-*-*)
 637     # No hosted I/O support.
 638     noconfigdirs="$noconfigdirs target-libssp"
 639     ;;
 640   powerpc-*-aix* | rs6000-*-aix*)
 641     noconfigdirs="$noconfigdirs target-libssp"
 642     ;;
 643   rl78-*-*)
 644     # libssp uses a misaligned load to trigger a fault, but the RL78
 645     # doesn't fault for those - instead, it gives a build-time error
 646     # for explicit misaligned loads.
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649   visium-*-*)
 650     # No hosted I/O support.
 651     noconfigdirs="$noconfigdirs target-libssp"
 652     ;;
 653 esac
 654
 655 # Disable libstdc++-v3 for some systems.
 656 # Allow user to override this if they pass --enable-libstdc++-v3
 657 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 658   case "${target}" in
 659     *-*-vxworks*)
 660       # VxWorks uses the Dinkumware C++ library.
 661       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 662       ;;
 663     arm*-wince-pe*)
 664       # the C++ libraries don't build on top of CE's C libraries
 665       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 666       ;;
 667     avr-*-*)
 668       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 669       ;;
 670     ft32-*-*)
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673   esac
 674 fi
 675
 676 # Disable Fortran for some systems.
 677 case "${target}" in
 678   mmix-*-*)
 679     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 680     unsupported_languages="$unsupported_languages fortran"
 681     ;;
 682 esac
 683
 684 # Disable libffi for some systems.
 685 case "${target}" in
 686   powerpc-*-darwin*)
 687     ;;
 688   i[[3456789]]86-*-darwin*)
 689     ;;
 690   x86_64-*-darwin[[912]]*)
 691     ;;
 692   *-*-darwin*)
 693     noconfigdirs="$noconfigdirs target-libffi"
 694     ;;
 695   *-*-netware*)
 696     noconfigdirs="$noconfigdirs target-libffi"
 697     ;;
 698   *-*-phoenix*)
 699     noconfigdirs="$noconfigdirs target-libffi"
 700     ;;
 701   *-*-rtems*)
 702     noconfigdirs="$noconfigdirs target-libffi"
 703     ;;
 704   *-*-tpf*)
 705     noconfigdirs="$noconfigdirs target-libffi"
 706     ;;
 707   *-*-uclinux*)
 708     noconfigdirs="$noconfigdirs target-libffi"
 709     ;;
 710   *-*-vxworks*)
 711     noconfigdirs="$noconfigdirs target-libffi"
 712     ;;
 713   aarch64*-*-freebsd*)
 714     noconfigdirs="$noconfigdirs target-libffi"
 715     ;;
 716   alpha*-*-*vms*)
 717     noconfigdirs="$noconfigdirs target-libffi"
 718     ;;
 719   arm*-*-freebsd*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   arm-wince-pe)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   arm*-*-symbianelf*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   cris-*-* | crisv32-*-*)
 729     case "${target}" in
 730       *-*-linux*)
 731         ;;
 732       *) # See PR46792 regarding target-libffi.
 733         noconfigdirs="$noconfigdirs target-libffi";;
 734     esac
 735     ;;
 736   hppa*64*-*-hpux*)
 737     noconfigdirs="$noconfigdirs target-libffi"
 738     ;;
 739   hppa*-hp-hpux11*)
 740     ;;
 741   hppa*-*-hpux*)
 742     noconfigdirs="$noconfigdirs target-libffi"
 743     ;;
 744   ia64*-*-*vms*)
 745     noconfigdirs="$noconfigdirs target-libffi"
 746     ;;
 747   i[[3456789]]86-w64-mingw*)
 748     noconfigdirs="$noconfigdirs target-libffi"
 749     ;;
 750   i[[3456789]]86-*-mingw*)
 751     noconfigdirs="$noconfigdirs target-libffi"
 752     ;;
 753   x86_64-*-mingw*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   mmix-*-*)
 757     noconfigdirs="$noconfigdirs target-libffi"
 758     ;;
 759   powerpc-*-aix*)
 760     ;;
 761   rs6000-*-aix*)
 762     ;;
 763   ft32-*-*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   *-*-lynxos*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769 esac
 770
 771 # Disable the go frontend on systems where it is known to not work. Please keep
 772 # this in sync with contrib/config-list.mk.
 773 case "${target}" in
 774 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 775     unsupported_languages="$unsupported_languages go"
 776     ;;
 777 esac
 778
 779 # Disable libgo for some systems where it is known to not work.
 780 # For testing, you can easily override this with --enable-libgo.
 781 if test x$enable_libgo = x; then
 782     case "${target}" in
 783     *-*-darwin*)
 784         # PR 46986
 785         noconfigdirs="$noconfigdirs target-libgo"
 786         ;;
 787     *-*-cygwin* | *-*-mingw*)
 788         noconfigdirs="$noconfigdirs target-libgo"
 789         ;;
 790     esac
 791 fi
 792
 793 # Default libgloss CPU subdirectory.
 794 libgloss_dir="$target_cpu"
 795
 796 case "${target}" in
 797   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 798     libgloss_dir=wince
 799     ;;
 800   aarch64*-*-* )
 801     libgloss_dir=aarch64
 802     ;;
 803   arm*-*-*)
 804     libgloss_dir=arm
 805     ;;
 806   cris-*-* | crisv32-*-*)
 807     libgloss_dir=cris
 808     ;;
 809   hppa*-*-*)
 810     libgloss_dir=pa
 811     ;;
 812   i[[3456789]]86-*-*)
 813     libgloss_dir=i386
 814     ;;
 815   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 816     libgloss_dir=m68hc11
 817     ;;
 818   m68*-*-* | fido-*-*)
 819     libgloss_dir=m68k
 820     ;;
 821   mips*-*-*)
 822     libgloss_dir=mips
 823     ;;
 824   powerpc*-*-*)
 825     libgloss_dir=rs6000
 826     ;;
 827   sparc*-*-*)
 828     libgloss_dir=sparc
 829     ;;
 830 esac
 831
 832 # Disable newlib and libgloss for various target OSes.
 833 case "${target}" in
 834   alpha*-dec-osf*)
 835     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 836     ;;
 837   i[[3456789]]86-*-linux*)
 838     # This section makes it possible to build newlib natively on linux.
 839     # If we are using a cross compiler then don't configure newlib.
 840     if test x${is_cross_compiler} != xno ; then
 841       noconfigdirs="$noconfigdirs target-newlib"
 842     fi
 843     noconfigdirs="$noconfigdirs target-libgloss"
 844     # If we are not using a cross compiler, do configure newlib.
 845     # Note however, that newlib will only be configured in this situation
 846     # if the --with-newlib option has been given, because otherwise
 847     # 'target-newlib' will appear in skipdirs.
 848     ;;
 849   i[[3456789]]86-*-rdos*)
 850     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 851     ;;
 852   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 853     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 854     ;;
 855   sparc-*-sunos4*)
 856     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 857     ;;
 858   *-*-aix*)
 859     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 860     ;;
 861   *-*-beos*)
 862     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 863     ;;
 864   *-*-chorusos)
 865     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 866     ;;
 867   *-*-dragonfly*)
 868     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 869     ;;
 870   *-*-freebsd*)
 871     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 872     ;;
 873   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 874     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 875     ;;
 876   *-*-lynxos*)
 877     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 878     ;;
 879   *-*-mingw*)
 880     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 881     ;;
 882   *-*-netbsd*)
 883     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 884     ;;
 885   *-*-netware*)
 886     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 887     ;;
 888   *-*-tpf*)
 889     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 890     ;;
 891   *-*-uclinux*)
 892     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 893     ;;
 894   *-*-vxworks*)
 895     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 896     ;;
 897 esac
 898
 899 case "${target}" in
 900   *-*-chorusos)
 901     ;;
 902   aarch64-*-darwin*)
 903     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 904     noconfigdirs="$noconfigdirs sim target-rda"
 905     ;;
 906   arm-*-darwin*)
 907     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 908     noconfigdirs="$noconfigdirs sim target-rda"
 909     ;;
 910   powerpc-*-darwin*)
 911     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 912     noconfigdirs="$noconfigdirs sim target-rda"
 913     ;;
 914   i[[3456789]]86-*-darwin*)
 915     noconfigdirs="$noconfigdirs ld gprof"
 916     noconfigdirs="$noconfigdirs sim target-rda"
 917     ;;
 918   x86_64-*-darwin[[912]]*)
 919     noconfigdirs="$noconfigdirs ld gas gprof"
 920     noconfigdirs="$noconfigdirs sim target-rda"
 921     ;;
 922   *-*-darwin*)
 923     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 924     noconfigdirs="$noconfigdirs sim target-rda"
 925     ;;
 926   *-*-dragonfly*)
 927     ;;
 928   *-*-freebsd*)
 929     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 930         && test -f /usr/local/include/gmp.h; then
 931       with_gmp=/usr/local
 932     fi
 933     ;;
 934   *-*-kaos*)
 935     # Remove unsupported stuff on all kaOS configurations.
 936     noconfigdirs="$noconfigdirs target-libgloss"
 937     ;;
 938   *-*-netbsd*)
 939     ;;
 940   *-*-netware*)
 941     ;;
 942   *-*-phoenix*)
 943     noconfigdirs="$noconfigdirs target-libgloss"
 944     ;;
 945   *-*-rtems*)
 946     noconfigdirs="$noconfigdirs target-libgloss"
 947     ;;
 948     # The tpf target doesn't support gdb yet.
 949   *-*-tpf*)
 950     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 951     ;;
 952   *-*-uclinux*)
 953     noconfigdirs="$noconfigdirs target-rda"
 954     ;;
 955   *-*-vxworks*)
 956     ;;
 957   alpha*-dec-osf*)
 958     # ld works, but does not support shared libraries.
 959     # gas doesn't generate exception information.
 960     noconfigdirs="$noconfigdirs gas ld"
 961     ;;
 962   alpha*-*-*vms*)
 963     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 964     ;;
 965   alpha*-*-*)
 966     # newlib is not 64 bit ready
 967     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 968     ;;
 969   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 970     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 971     ;;
 972   arc*-*-*)
 973     noconfigdirs="$noconfigdirs sim"
 974     ;;
 975   arm-*-pe*)
 976     noconfigdirs="$noconfigdirs target-libgloss"
 977     ;;
 978   arm-*-riscix*)
 979     noconfigdirs="$noconfigdirs ld target-libgloss"
 980     ;;
 981   avr-*-*)
 982     if test x${with_avrlibc} != xno; then
 983       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     fi
 985     ;;
 986   c4x-*-* | tic4x-*-*)
 987     noconfigdirs="$noconfigdirs target-libgloss"
 988     ;;
 989   tic54x-*-*)
 990     noconfigdirs="$noconfigdirs target-libgloss gdb"
 991     ;;
 992   d10v-*-*)
 993     noconfigdirs="$noconfigdirs target-libgloss"
 994     ;;
 995   d30v-*-*)
 996     noconfigdirs="$noconfigdirs gdb"
 997     ;;
 998   fr30-*-elf*)
 999     noconfigdirs="$noconfigdirs gdb"
1000     ;;
1001   ft32-*-*)
1002     noconfigdirs="$noconfigdirs target-rda gprof"
1003     ;;
1004   moxie-*-*)
1005     noconfigdirs="$noconfigdirs"
1006     ;;
1007   h8300*-*-*)
1008     noconfigdirs="$noconfigdirs target-libgloss"
1009     ;;
1010   h8500-*-*)
1011     noconfigdirs="$noconfigdirs target-libgloss"
1012     ;;
1013   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1014     ;;
1015   hppa*64*-*-hpux*)
1016     noconfigdirs="$noconfigdirs gdb"
1017     ;;
1018   hppa*-*-hpux11*)
1019     noconfigdirs="$noconfigdirs gdb ld"
1020     ;;
1021   hppa*64*-*-linux*)
1022     ;;
1023   hppa*-*-linux*)
1024     ;;
1025   hppa*-*-*elf* | \
1026   hppa*-*-lites* | \
1027   hppa*-*-openbsd* | \
1028   hppa*64*-*-*)
1029     ;;
1030   hppa*-*-pro*)
1031     ;;
1032   hppa*-*-*)
1033     noconfigdirs="$noconfigdirs ld"
1034     ;;
1035   i960-*-*)
1036     noconfigdirs="$noconfigdirs gdb"
1037     ;;
1038   ia64*-*-elf*)
1039     # No gdb support yet.
1040     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1041     ;;
1042   ia64*-**-hpux*)
1043     # No ld support yet.
1044     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1045     ;;
1046   ia64*-*-*vms*)
1047     # No ld support yet.
1048     noconfigdirs="$noconfigdirs libgui itcl ld"
1049     ;;
1050   i[[3456789]]86-w64-mingw*)
1051     ;;
1052   i[[3456789]]86-*-mingw*)
1053     target_configdirs="$target_configdirs target-winsup"
1054     ;;
1055   *-*-cygwin*)
1056     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1057     noconfigdirs="$noconfigdirs target-libgloss"
1058     # always build newlib if winsup directory is present.
1059     if test -d "$srcdir/winsup/cygwin"; then
1060       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1061     elif test -d "$srcdir/newlib"; then
1062       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1063     fi
1064     ;;
1065   i[[3456789]]86-*-pe)
1066     noconfigdirs="$noconfigdirs target-libgloss"
1067     ;;
1068   i[[3456789]]86-*-sco3.2v5*)
1069     # The linker does not yet know about weak symbols in COFF,
1070     # and is not configured to handle mixed ELF and COFF.
1071     noconfigdirs="$noconfigdirs ld target-libgloss"
1072     ;;
1073   i[[3456789]]86-*-sco*)
1074     noconfigdirs="$noconfigdirs gprof target-libgloss"
1075     ;;
1076   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1077     noconfigdirs="$noconfigdirs target-libgloss"
1078     ;;
1079   i[[3456789]]86-*-sysv4*)
1080     noconfigdirs="$noconfigdirs target-libgloss"
1081     ;;
1082   i[[3456789]]86-*-beos*)
1083     noconfigdirs="$noconfigdirs gdb"
1084     ;;
1085   i[[3456789]]86-*-rdos*)
1086     noconfigdirs="$noconfigdirs gdb"
1087     ;;
1088   mmix-*-*)
1089     noconfigdirs="$noconfigdirs gdb"
1090     ;;
1091   mt-*-*)
1092     noconfigdirs="$noconfigdirs sim"
1093     ;;
1094   nfp-*-*)
1095     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1096     noconfigdirs="$noconfigdirs $target_libraries"
1097     ;;
1098   powerpc-*-aix*)
1099     # copied from rs6000-*-* entry
1100     noconfigdirs="$noconfigdirs gprof"
1101     ;;
1102   powerpc*-*-winnt* | powerpc*-*-pe*)
1103     target_configdirs="$target_configdirs target-winsup"
1104     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1105     # always build newlib.
1106     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1107     ;;
1108     # This is temporary until we can link against shared libraries
1109   powerpcle-*-solaris*)
1110     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1111     ;;
1112   powerpc-*-beos*)
1113     noconfigdirs="$noconfigdirs gdb"
1114     ;;
1115   rs6000-*-lynxos*)
1116     noconfigdirs="$noconfigdirs gprof"
1117     ;;
1118   rs6000-*-aix*)
1119     noconfigdirs="$noconfigdirs gprof"
1120     ;;
1121   rs6000-*-*)
1122     noconfigdirs="$noconfigdirs gprof"
1123     ;;
1124   m68k-apollo-*)
1125     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1126     ;;
1127   microblaze*)
1128     noconfigdirs="$noconfigdirs gprof"
1129     ;;
1130   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1131     if test x$with_newlib = xyes; then
1132       noconfigdirs="$noconfigdirs gprof"
1133     fi
1134     ;;
1135   mips*-*-irix5*)
1136     noconfigdirs="$noconfigdirs gprof target-libgloss"
1137     ;;
1138   mips*-*-irix6*)
1139     noconfigdirs="$noconfigdirs gprof target-libgloss"
1140     ;;
1141   mips*-*-bsd*)
1142     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1143     ;;
1144   mips*-*-linux*)
1145     ;;
1146   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1147   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1148     noconfigdirs="$noconfigdirs ld gas gprof"
1149     ;;
1150   mips*-*-*)
1151     noconfigdirs="$noconfigdirs gprof"
1152     ;;
1153   nvptx*-*-*)
1154     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1155     ;;
1156   sh-*-*)
1157     case "${target}" in
1158       sh*-*-elf)
1159          ;;
1160       *)
1161          noconfigdirs="$noconfigdirs target-libgloss" ;;
1162     esac
1163     ;;
1164   sparc-*-sunos4*)
1165     if test x${is_cross_compiler} = xno ; then
1166            use_gnu_ld=no
1167     fi
1168     ;;
1169   tic6x-*-*)
1170     noconfigdirs="$noconfigdirs sim"
1171     ;;
1172   tilepro*-*-* | tilegx*-*-*)
1173     noconfigdirs="$noconfigdirs sim"
1174     ;;
1175   v810-*-*)
1176     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1177     ;;
1178   vax-*-*)
1179     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1180     ;;
1181   wasm32-*-*)
1182     noconfigdirs="$noconfigdirs ld"
1183     ;;
1184 esac
1185
1186 # If we aren't building newlib, then don't build libgloss, since libgloss
1187 # depends upon some newlib header files.
1188 case "${noconfigdirs}" in
1189   *target-libgloss*) ;;
1190   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1191 esac
1192
1193 # Work in distributions that contain no compiler tools, like Autoconf.
1194 host_makefile_frag=/dev/null
1195 if test -d ${srcdir}/config ; then
1196 case "${host}" in
1197   i[[3456789]]86-*-msdosdjgpp*)
1198     host_makefile_frag="config/mh-djgpp"
1199     ;;
1200   *-cygwin*)
1201     ACX_CHECK_CYGWIN_CAT_WORKS
1202     host_makefile_frag="config/mh-cygwin"
1203     ;;
1204   *-mingw*)
1205     host_makefile_frag="config/mh-mingw"
1206     ;;
1207   alpha*-linux*)
1208     host_makefile_frag="config/mh-alpha-linux"
1209     ;;
1210   hppa*-hp-hpux10*)
1211     host_makefile_frag="config/mh-pa-hpux10"
1212     ;;
1213   hppa*-hp-hpux*)
1214     host_makefile_frag="config/mh-pa"
1215     ;;
1216   hppa*-*)
1217     host_makefile_frag="config/mh-pa"
1218     ;;
1219   *-*-darwin*)
1220     host_makefile_frag="config/mh-darwin"
1221     ;;
1222   powerpc-*-aix*)
1223     host_makefile_frag="config/mh-ppc-aix"
1224     ;;
1225   rs6000-*-aix*)
1226     host_makefile_frag="config/mh-ppc-aix"
1227     ;;
1228 esac
1229 fi
1230
1231 if test "${build}" != "${host}" ; then
1232   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1233   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1234   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1235   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1236   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1237   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1238   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1239   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1240   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1241   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1242   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1243   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1244 else
1245   AR_FOR_BUILD="\$(AR)"
1246   AS_FOR_BUILD="\$(AS)"
1247   CC_FOR_BUILD="\$(CC)"
1248   CXX_FOR_BUILD="\$(CXX)"
1249   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1250   GOC_FOR_BUILD="\$(GOC)"
1251   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1252   LD_FOR_BUILD="\$(LD)"
1253   NM_FOR_BUILD="\$(NM)"
1254   RANLIB_FOR_BUILD="\$(RANLIB)"
1255   WINDRES_FOR_BUILD="\$(WINDRES)"
1256   WINDMC_FOR_BUILD="\$(WINDMC)"
1257 fi
1258
1259 AC_PROG_CC
1260 AC_PROG_CXX
1261
1262 # We must set the default linker to the linker used by gcc for the correct
1263 # operation of libtool.  If LD is not defined and we are using gcc, try to
1264 # set the LD default to the ld used by gcc.
1265 if test -z "$LD"; then
1266   if test "$GCC" = yes; then
1267     case $build in
1268     *-*-mingw*)
1269       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1270     *)
1271       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1272     esac
1273     case $gcc_prog_ld in
1274     # Accept absolute paths.
1275     [[\\/]* | [A-Za-z]:[\\/]*)]
1276       LD="$gcc_prog_ld" ;;
1277     esac
1278   fi
1279 fi
1280
1281 # Check whether -static-libstdc++ -static-libgcc is supported.
1282 have_static_libs=no
1283 if test "$GCC" = yes; then
1284   saved_LDFLAGS="$LDFLAGS"
1285
1286   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1287   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1288   AC_LANG_PUSH(C++)
1289   AC_LINK_IFELSE([
1290 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1291 #error -static-libstdc++ not implemented
1292 #endif
1293 int main() {}],
1294     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1295     [AC_MSG_RESULT([no])])
1296   AC_LANG_POP(C++)
1297
1298   LDFLAGS="$saved_LDFLAGS"
1299 fi
1300
1301 ACX_PROG_GNAT
1302 ACX_PROG_CMP_IGNORE_INITIAL
1303
1304 AC_ARG_ENABLE([bootstrap],
1305 [AS_HELP_STRING([--enable-bootstrap],
1306                 [enable bootstrapping @<:@yes if native build@:>@])],,
1307 enable_bootstrap=default)
1308
1309 # Issue errors and warnings for invalid/strange bootstrap combinations.
1310 if test -r $srcdir/gcc/configure; then
1311   have_compiler=yes
1312 else
1313   have_compiler=no
1314 fi
1315
1316 case "$have_compiler:$host:$target:$enable_bootstrap" in
1317   *:*:*:no) ;;
1318
1319   # Default behavior.  Enable bootstrap if we have a compiler
1320   # and we are in a native configuration.
1321   yes:$build:$build:default)
1322     enable_bootstrap=yes ;;
1323
1324   *:*:*:default)
1325     enable_bootstrap=no ;;
1326
1327   # We have a compiler and we are in a native configuration, bootstrap is ok
1328   yes:$build:$build:yes)
1329     ;;
1330
1331   # Other configurations, but we have a compiler.  Assume the user knows
1332   # what he's doing.
1333   yes:*:*:yes)
1334     AC_MSG_WARN([trying to bootstrap a cross compiler])
1335     ;;
1336
1337   # No compiler: if they passed --enable-bootstrap explicitly, fail
1338   no:*:*:yes)
1339     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1340
1341   # Fail if wrong command line
1342   *)
1343     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1344     ;;
1345 esac
1346
1347 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1348 # C++98 compiler can still start the bootstrap.
1349 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1350   CXX="$CXX -std=gnu++98"
1351 fi
1352
1353 # Used for setting $lt_cv_objdir
1354 _LT_CHECK_OBJDIR
1355
1356 # Check for GMP, MPFR and MPC
1357 gmplibs="-lmpc -lmpfr -lgmp"
1358 gmpinc=
1359 have_gmp=no
1360
1361 # Specify a location for mpc
1362 # check for this first so it ends up on the link line before mpfr.
1363 AC_ARG_WITH(mpc,
1364 [AS_HELP_STRING([--with-mpc=PATH],
1365                 [specify prefix directory for installed MPC package.
1366                  Equivalent to --with-mpc-include=PATH/include
1367                  plus --with-mpc-lib=PATH/lib])])
1368 AC_ARG_WITH(mpc-include,
1369 [AS_HELP_STRING([--with-mpc-include=PATH],
1370                 [specify directory for installed MPC include files])])
1371 AC_ARG_WITH(mpc-lib,
1372 [AS_HELP_STRING([--with-mpc-lib=PATH],
1373                 [specify directory for the installed MPC library])])
1374
1375 if test "x$with_mpc" != x; then
1376   gmplibs="-L$with_mpc/lib $gmplibs"
1377   gmpinc="-I$with_mpc/include $gmpinc"
1378 fi
1379 if test "x$with_mpc_include" != x; then
1380   gmpinc="-I$with_mpc_include $gmpinc"
1381 fi
1382 if test "x$with_mpc_lib" != x; then
1383   gmplibs="-L$with_mpc_lib $gmplibs"
1384 fi
1385 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1386   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1387   gmpinc='-I$$s/mpc/src '"$gmpinc"
1388   # Do not test the mpc version.  Assume that it is sufficient, since
1389   # it is in the source tree, and the library has not been built yet
1390   # but it would be included on the link line in the version check below
1391   # hence making the test fail.
1392   have_gmp=yes
1393 fi
1394
1395 # Specify a location for mpfr
1396 # check for this first so it ends up on the link line before gmp.
1397 AC_ARG_WITH(mpfr-dir,
1398 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1399 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1400 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1401
1402 AC_ARG_WITH(mpfr,
1403 [AS_HELP_STRING([--with-mpfr=PATH],
1404                 [specify prefix directory for installed MPFR package.
1405                  Equivalent to --with-mpfr-include=PATH/include
1406                  plus --with-mpfr-lib=PATH/lib])])
1407 AC_ARG_WITH(mpfr-include,
1408 [AS_HELP_STRING([--with-mpfr-include=PATH],
1409                 [specify directory for installed MPFR include files])])
1410 AC_ARG_WITH(mpfr-lib,
1411 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1412                 [specify directory for the installed MPFR library])])
1413
1414 if test "x$with_mpfr" != x; then
1415   gmplibs="-L$with_mpfr/lib $gmplibs"
1416   gmpinc="-I$with_mpfr/include $gmpinc"
1417 fi
1418 if test "x$with_mpfr_include" != x; then
1419   gmpinc="-I$with_mpfr_include $gmpinc"
1420 fi
1421 if test "x$with_mpfr_lib" != x; then
1422   gmplibs="-L$with_mpfr_lib $gmplibs"
1423 fi
1424 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1425   # MPFR v3.1.0 moved the sources into a src sub-directory.
1426   if ! test -d ${srcdir}/mpfr/src; then
1427     AC_MSG_ERROR([dnl
1428 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1429   fi
1430   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1431   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1432   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1433   # Do not test the mpfr version.  Assume that it is sufficient, since
1434   # it is in the source tree, and the library has not been built yet
1435   # but it would be included on the link line in the version check below
1436   # hence making the test fail.
1437   have_gmp=yes
1438 fi
1439
1440 # Specify a location for gmp
1441 AC_ARG_WITH(gmp-dir,
1442 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1443 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1444 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1445
1446 AC_ARG_WITH(gmp,
1447 [AS_HELP_STRING([--with-gmp=PATH],
1448                 [specify prefix directory for the installed GMP package.
1449                  Equivalent to --with-gmp-include=PATH/include
1450                  plus --with-gmp-lib=PATH/lib])])
1451 AC_ARG_WITH(gmp-include,
1452 [AS_HELP_STRING([--with-gmp-include=PATH],
1453                 [specify directory for installed GMP include files])])
1454 AC_ARG_WITH(gmp-lib,
1455 [AS_HELP_STRING([--with-gmp-lib=PATH],
1456                 [specify directory for the installed GMP library])])
1457
1458
1459 if test "x$with_gmp" != x; then
1460   gmplibs="-L$with_gmp/lib $gmplibs"
1461   gmpinc="-I$with_gmp/include $gmpinc"
1462 fi
1463 if test "x$with_gmp_include" != x; then
1464   gmpinc="-I$with_gmp_include $gmpinc"
1465 fi
1466 if test "x$with_gmp_lib" != x; then
1467   gmplibs="-L$with_gmp_lib $gmplibs"
1468 fi
1469 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1470   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1471   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1472   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1473   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1474   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1475   # Do not test the gmp version.  Assume that it is sufficient, since
1476   # it is in the source tree, and the library has not been built yet
1477   # but it would be included on the link line in the version check below
1478   # hence making the test fail.
1479   have_gmp=yes
1480 fi
1481
1482 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1483   have_gmp=yes
1484   saved_CFLAGS="$CFLAGS"
1485   CFLAGS="$CFLAGS $gmpinc"
1486   # Check for the recommended and required versions of GMP.
1487   AC_MSG_CHECKING([for the correct version of gmp.h])
1488   AC_TRY_COMPILE([#include "gmp.h"],[
1489   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1490   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1491   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1492   choke me
1493   #endif
1494   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1495   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1496   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1497   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1498   choke me
1499   #endif
1500   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1501    [AC_MSG_RESULT([no]); have_gmp=no])
1502
1503   # If we have GMP, check the MPFR version.
1504   if test x"$have_gmp" = xyes; then
1505     # Check for the recommended and required versions of MPFR.
1506     AC_MSG_CHECKING([for the correct version of mpfr.h])
1507     AC_TRY_COMPILE([#include <gmp.h>
1508     #include <mpfr.h>],[
1509     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1510     choke me
1511     #endif
1512     ], [AC_TRY_COMPILE([#include <gmp.h>
1513     #include <mpfr.h>],[
1514     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1515     choke me
1516     #endif
1517     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1518      [AC_MSG_RESULT([no]); have_gmp=no])
1519   fi
1520
1521   # Check for the MPC header version.
1522   if test x"$have_gmp" = xyes ; then
1523     # Check for the recommended and required versions of MPC.
1524     AC_MSG_CHECKING([for the correct version of mpc.h])
1525     AC_TRY_COMPILE([#include <mpc.h>],[
1526     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1527     choke me
1528     #endif
1529     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1530     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1531     choke me
1532     #endif
1533     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1534      [AC_MSG_RESULT([no]); have_gmp=no])
1535   fi
1536
1537   # Now check the MPFR library.
1538   if test x"$have_gmp" = xyes; then
1539     saved_LIBS="$LIBS"
1540     LIBS="$LIBS $gmplibs"
1541     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1542     AC_TRY_LINK([#include <mpc.h>],[
1543     mpfr_t n;
1544     mpfr_t x;
1545     mpc_t c;
1546     int t;
1547     mpfr_init (n);
1548     mpfr_init (x);
1549     mpfr_atan2 (n, n, x, GMP_RNDN);
1550     mpfr_erfc (n, x, GMP_RNDN);
1551     mpfr_subnormalize (x, t, GMP_RNDN);
1552     mpfr_clear(n);
1553     mpfr_clear(x);
1554     mpc_init2 (c, 53);
1555     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1556     mpc_cosh (c, c, MPC_RNDNN);
1557     mpc_pow (c, c, c, MPC_RNDNN);
1558     mpc_acosh (c, c, MPC_RNDNN);
1559     mpc_clear (c);
1560     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1561     LIBS="$saved_LIBS"
1562   fi
1563
1564   CFLAGS="$saved_CFLAGS"
1565
1566 # The library versions listed in the error message below should match
1567 # the HARD-minimums enforced above.
1568   if test x$have_gmp != xyes; then
1569     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1570 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1571 their locations.  Source code for these libraries can be found at
1572 their respective hosting sites as well as at
1573 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1574 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1575 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1576 make sure that you have installed both the libraries and the header
1577 files.  They may be located in separate packages.])
1578   fi
1579 fi
1580
1581 # Flags needed for both GMP, MPFR and/or MPC.
1582 AC_SUBST(gmplibs)
1583 AC_SUBST(gmpinc)
1584 AC_SUBST(extra_mpfr_configure_flags)
1585 AC_SUBST(extra_mpc_gmp_configure_flags)
1586 AC_SUBST(extra_mpc_mpfr_configure_flags)
1587 AC_SUBST(extra_isl_gmp_configure_flags)
1588
1589 # Libraries to use for stage1 or when not bootstrapping.
1590 AC_ARG_WITH(stage1-libs,
1591 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1592 [if test "$withval" = "no" -o "$withval" = "yes"; then
1593    stage1_libs=
1594  else
1595    stage1_libs=$withval
1596  fi],
1597 [stage1_libs=])
1598 AC_SUBST(stage1_libs)
1599
1600 # Linker flags to use for stage1 or when not bootstrapping.
1601 AC_ARG_WITH(stage1-ldflags,
1602 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1603 [if test "$withval" = "no" -o "$withval" = "yes"; then
1604    stage1_ldflags=
1605  else
1606    stage1_ldflags=$withval
1607  fi],
1608 [stage1_ldflags=
1609  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1610  # if supported.  But if the user explicitly specified the libraries to use,
1611  # trust that they are doing what they want.
1612  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1613    stage1_ldflags="-static-libstdc++ -static-libgcc"
1614  fi])
1615 AC_SUBST(stage1_ldflags)
1616
1617 # Libraries to use for stage2 and later builds.
1618 AC_ARG_WITH(boot-libs,
1619 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1620 [if test "$withval" = "no" -o "$withval" = "yes"; then
1621    poststage1_libs=
1622  else
1623    poststage1_libs=$withval
1624  fi],
1625 [poststage1_libs=])
1626 AC_SUBST(poststage1_libs)
1627
1628 # Linker flags to use for stage2 and later builds.
1629 AC_ARG_WITH(boot-ldflags,
1630 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1631                 [linker flags for stage2 and later])],
1632 [if test "$withval" = "no" -o "$withval" = "yes"; then
1633    poststage1_ldflags=
1634  else
1635    poststage1_ldflags=$withval
1636  fi],
1637 [poststage1_ldflags=
1638  # In stages 2 and 3, default to linking libstdc++ and libgcc
1639  # statically.  But if the user explicitly specified the libraries to
1640  # use, trust that they are doing what they want.
1641  if test "$poststage1_libs" = ""; then
1642    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1643  fi])
1644 AC_SUBST(poststage1_ldflags)
1645
1646 # GCC GRAPHITE dependency isl.
1647 # Basic setup is inlined here, actual checks are in config/isl.m4
1648
1649 AC_ARG_WITH(isl,
1650   [AS_HELP_STRING(
1651    [--with-isl=PATH],
1652    [Specify prefix directory for the installed isl package.
1653     Equivalent to --with-isl-include=PATH/include
1654     plus --with-isl-lib=PATH/lib])])
1655
1656 # Treat --without-isl as a request to disable
1657 # GRAPHITE support and skip all following checks.
1658 if test "x$with_isl" != "xno"; then
1659   # Check for isl
1660   dnl Provide configure switches and initialize islinc & isllibs
1661   dnl with user input.
1662   ISL_INIT_FLAGS
1663   dnl The versions of isl that work for Graphite
1664   ISL_CHECK_VERSION()
1665   dnl Only execute fail-action, if isl has been requested.
1666   ISL_IF_FAILED([
1667     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1668 fi
1669
1670 # If the isl check failed, disable builds of in-tree variant of isl
1671 if test "x$with_isl" = xno ||
1672    test "x$gcc_cv_isl" = xno; then
1673   noconfigdirs="$noconfigdirs isl"
1674   islinc=
1675 fi
1676
1677 AC_SUBST(isllibs)
1678 AC_SUBST(islinc)
1679
1680 # Check for LTO support.
1681 AC_ARG_ENABLE(lto,
1682 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1683 enable_lto=$enableval,
1684 enable_lto=yes; default_enable_lto=yes)
1685
1686 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1687   build_lto_plugin=yes
1688 ],[if test x"$default_enable_lto" = x"yes" ; then
1689     case $target in
1690       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1691       # On other non-ELF platforms, LTO has yet to be validated.
1692       *) enable_lto=no ;;
1693     esac
1694   else
1695   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1696   # It would also be nice to check the binutils support, but we don't
1697   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1698   # warn during gcc/ subconfigure; unless you're bootstrapping with
1699   # -flto it won't be needed until after installation anyway.
1700     case $target in
1701       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1702       *) if test x"$enable_lto" = x"yes"; then
1703         AC_MSG_ERROR([LTO support is not enabled for this target.])
1704         fi
1705       ;;
1706     esac
1707   fi
1708   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1709   # Build it unless LTO was explicitly disabled.
1710   case $target in
1711     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1712     *) ;;
1713   esac
1714 ])
1715
1716 AC_ARG_ENABLE(linker-plugin-configure-flags,
1717   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1718     [additional flags for configuring linker plugins @<:@none@:>@])],
1719   extra_linker_plugin_configure_flags=$enableval,
1720   extra_linker_plugin_configure_flags=)
1721 AC_SUBST(extra_linker_plugin_configure_flags)
1722 AC_ARG_ENABLE(linker-plugin-flags,
1723   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1724     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1725   extra_linker_plugin_flags=$enableval,
1726   extra_linker_plugin_flags=)
1727 AC_SUBST(extra_linker_plugin_flags)
1728
1729 # Enable --enable-host-shared.
1730 # Checked early to determine whether jit is an 'all' language
1731 AC_ARG_ENABLE(host-shared,
1732 [AS_HELP_STRING([--enable-host-shared],
1733                 [build host code as shared libraries])],
1734 [host_shared=$enableval], [host_shared=no])
1735 AC_SUBST(host_shared)
1736
1737 # By default, C and C++ are the only stage 1 languages.
1738 stage1_languages=,c,
1739
1740 # Target libraries that we bootstrap.
1741 bootstrap_target_libs=,target-libgcc,
1742
1743 # Figure out what language subdirectories are present.
1744 # Look if the user specified --enable-languages="..."; if not, use
1745 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1746 # go away some day.
1747 # NB:  embedded tabs in this IF block -- do not untabify
1748 if test -d ${srcdir}/gcc; then
1749   if test x"${enable_languages+set}" != xset; then
1750     if test x"${LANGUAGES+set}" = xset; then
1751       enable_languages="${LANGUAGES}"
1752         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1753     else
1754       enable_languages=default
1755     fi
1756   else
1757     if test x"${enable_languages}" = x ||
1758        test x"${enable_languages}" = xyes;
1759        then
1760       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1761       exit 1
1762     fi
1763   fi
1764   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1765
1766   # 'f95' is the old name for the 'fortran' language. We issue a warning
1767   # and make the substitution.
1768   case ,${enable_languages}, in
1769     *,f95,*)
1770       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1771       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1772       ;;
1773   esac
1774
1775   # If bootstrapping, C++ must be enabled.
1776   case ",$enable_languages,:$enable_bootstrap" in
1777     *,c++,*:*) ;;
1778     *:yes)
1779       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1780         enable_languages="${enable_languages},c++"
1781       else
1782         AC_MSG_ERROR([bootstrapping requires c++ sources])
1783       fi
1784       ;;
1785   esac
1786
1787   # First scan to see if an enabled language requires some other language.
1788   # We assume that a given config-lang.in will list all the language
1789   # front ends it requires, even if some are required indirectly.
1790   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1791     case ${lang_frag} in
1792       ..) ;;
1793       # The odd quoting in the next line works around
1794       # an apparent bug in bash 1.12 on linux.
1795       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1796       *)
1797         # From the config-lang.in, get $language, $lang_requires, and
1798         # $lang_requires_boot_languages.
1799         language=
1800         lang_requires=
1801         lang_requires_boot_languages=
1802         # set srcdir during sourcing lang_frag to the gcc dir.
1803         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1804         # polutes this shell
1805         saved_srcdir=${srcdir}
1806         srcdir=${srcdir}/gcc . ${lang_frag}
1807         srcdir=${saved_srcdir}
1808         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1809           case ,${enable_languages}, in
1810             *,$other,*) ;;
1811             *,default,*) ;;
1812             *,all,*) ;;
1813             *,$language,*)
1814               echo " \`$other' language required by \`$language'; enabling" 1>&2
1815               enable_languages="${enable_languages},${other}"
1816               ;;
1817           esac
1818         done
1819         for other in ${lang_requires_boot_languages} ; do
1820           if test "$other" != "c"; then
1821             case ,${enable_stage1_languages}, in
1822               *,$other,*) ;;
1823               *,default,*) ;;
1824               *,all,*) ;;
1825               *)
1826                 case ,${enable_languages}, in
1827                   *,$language,*)
1828                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1829                     enable_stage1_languages="$enable_stage1_languages,${other}"
1830                     ;;
1831                 esac
1832                 ;;
1833             esac
1834           fi
1835         done
1836         ;;
1837     esac
1838   done
1839
1840   new_enable_languages=,c,
1841
1842   # If LTO is enabled, add the LTO front end.
1843   if test "$enable_lto" = "yes" ; then
1844     case ,${enable_languages}, in
1845       *,lto,*) ;;
1846       *) enable_languages="${enable_languages},lto" ;;
1847     esac
1848     if test "${build_lto_plugin}" = "yes" ; then
1849       configdirs="$configdirs lto-plugin"
1850     fi
1851   fi
1852
1853   # If we're building an offloading compiler, add the LTO front end.
1854   if test x"$enable_as_accelerator_for" != x ; then
1855     case ,${enable_languages}, in
1856       *,lto,*) ;;
1857       *) enable_languages="${enable_languages},lto" ;;
1858     esac
1859   fi
1860
1861   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1862   potential_languages=,c,
1863
1864   enabled_target_libs=
1865   disabled_target_libs=
1866
1867   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1868     case ${lang_frag} in
1869       ..) ;;
1870       # The odd quoting in the next line works around
1871       # an apparent bug in bash 1.12 on linux.
1872       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1873       *)
1874         # From the config-lang.in, get $language, $target_libs,
1875         # $lang_dirs, $boot_language, and $build_by_default
1876         language=
1877         target_libs=
1878         lang_dirs=
1879         subdir_requires=
1880         boot_language=no
1881         build_by_default=yes
1882         # set srcdir during sourcing.  See above about save & restore
1883         saved_srcdir=${srcdir}
1884         srcdir=${srcdir}/gcc . ${lang_frag}
1885         srcdir=${saved_srcdir}
1886         if test x${language} = x; then
1887           echo "${lang_frag} doesn't set \$language." 1>&2
1888           exit 1
1889         fi
1890
1891         if test "$language" = "c++"; then
1892           boot_language=yes
1893         fi
1894
1895         add_this_lang=no
1896         # C is always enabled, so no need to add it again
1897         if test "$language" != "c"; then
1898           case ,${enable_languages}, in
1899             *,${language},*)
1900               # Language was explicitly selected; include it
1901               add_this_lang=yes
1902               ;;
1903             *,all,*)
1904               # All languages are enabled
1905               add_this_lang=all
1906               ;;
1907             *,default,*)
1908               # 'default' was selected, select it if it is a default language
1909               add_this_lang=${build_by_default}
1910               ;;
1911           esac
1912         fi
1913
1914         # Disable languages that need other directories if these aren't available.
1915         for i in $subdir_requires; do
1916           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1917           case ${add_this_lang} in
1918             yes)
1919               # Specifically requested language; tell them.
1920               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1921               ;;
1922             all)
1923               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1924               add_this_lang=unsupported
1925               ;;
1926             *)
1927               # Silently disable.
1928               add_this_lang=unsupported
1929               ;;
1930           esac
1931         done
1932
1933         # Disable Ada if no preexisting GNAT is available.
1934         case ${add_this_lang}:${language}:${have_gnat} in
1935           yes:ada:no)
1936             # Specifically requested language; tell them.
1937             AC_MSG_ERROR([GNAT is required to build $language])
1938             ;;
1939           all:ada:no)
1940             AC_MSG_WARN([GNAT is required to build $language])
1941             add_this_lang=unsupported
1942             ;;
1943           *:ada:no)
1944             # Silently disable.
1945             add_this_lang=unsupported
1946             ;;
1947         esac
1948
1949         # Disable jit if -enable-host-shared not specified
1950         case ${add_this_lang}:${language}:${host_shared} in
1951           yes:jit:no)
1952             # PR jit/64780: explicitly specify --enable-host-shared
1953             AC_MSG_ERROR([
1954 Enabling language "jit" requires --enable-host-shared.
1955
1956 --enable-host-shared typically slows the rest of the compiler down by
1957 a few %, so you must explicitly enable it.
1958
1959 If you want to build both the jit and the regular compiler, it is often
1960 best to do this via two separate configure/builds, in separate
1961 directories, to avoid imposing the performance cost of
1962 --enable-host-shared on the regular compiler.])
1963             ;;
1964           all:jit:no)
1965             AC_MSG_WARN([--enable-host-shared required to build $language])
1966             add_this_lang=unsupported
1967             ;;
1968           *:jit:no)
1969             # Silently disable.
1970             add_this_lang=unsupported
1971             ;;
1972         esac
1973
1974         # Disable a language that is unsupported by the target.
1975         case "${add_this_lang}: $unsupported_languages " in
1976           no:*) ;;
1977           unsupported:*) ;;
1978           *:*" $language "*)
1979             AC_MSG_WARN([${language} not supported for this target])
1980             add_this_lang=unsupported
1981             ;;
1982         esac
1983
1984         case $add_this_lang in
1985           unsupported)
1986             # Remove language-dependent dirs.
1987             disabled_target_libs="$disabled_target_libs $target_libs"
1988             noconfigdirs="$noconfigdirs $lang_dirs"
1989             ;;
1990           no)
1991             # Remove language-dependent dirs; still show language as supported.
1992             disabled_target_libs="$disabled_target_libs $target_libs"
1993             noconfigdirs="$noconfigdirs $lang_dirs"
1994             potential_languages="${potential_languages}${language},"
1995             ;;
1996           all|yes)
1997             new_enable_languages="${new_enable_languages}${language},"
1998             potential_languages="${potential_languages}${language},"
1999             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2000             enabled_target_libs="$enabled_target_libs $target_libs"
2001             case "${boot_language}:,$enable_stage1_languages," in
2002               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2003                 # Add to (comma-separated) list of stage 1 languages.
2004                 case ",$stage1_languages," in
2005                   *,$language,* | ,yes, | ,all,) ;;
2006                   *) stage1_languages="${stage1_languages}${language}," ;;
2007                 esac
2008                 # We need to bootstrap any supporting libraries.
2009                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2010                 ;;
2011             esac
2012             ;;
2013         esac
2014         ;;
2015     esac
2016   done
2017
2018   # Add target libraries which are only needed for disabled languages
2019   # to noconfigdirs.
2020   if test -n "$disabled_target_libs"; then
2021     for dir in $disabled_target_libs; do
2022       case " $enabled_target_libs " in
2023       *" ${dir} "*) ;;
2024       *) noconfigdirs="$noconfigdirs $dir" ;;
2025       esac
2026     done
2027   fi
2028
2029   AC_ARG_ENABLE(stage1-languages,
2030   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2031                   [choose additional languages to build during
2032                   stage1.  Mostly useful for compiler development])],
2033   [case ,${enable_stage1_languages}, in
2034     ,no,|,,)
2035       # Set it to something that will have no effect in the loop below
2036       enable_stage1_languages=c ;;
2037     ,yes,)
2038       enable_stage1_languages=`echo $new_enable_languages | \
2039         sed -e "s/^,//" -e "s/,$//" ` ;;
2040     *,all,*)
2041       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2042         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2043   esac
2044
2045   # Add "good" languages from enable_stage1_languages to stage1_languages,
2046   # while "bad" languages go in missing_languages.  Leave no duplicates.
2047   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2048     case $potential_languages in
2049       *,$i,*)
2050         case $stage1_languages in
2051           *,$i,*) ;;
2052           *) stage1_languages="$stage1_languages$i," ;;
2053         esac ;;
2054       *)
2055         case $missing_languages in
2056           *,$i,*) ;;
2057           *) missing_languages="$missing_languages$i," ;;
2058         esac ;;
2059      esac
2060   done])
2061
2062   # Remove leading/trailing commas that were added for simplicity
2063   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2064   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2065   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2066   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2067
2068   if test "x$missing_languages" != x; then
2069     AC_MSG_ERROR([
2070 The following requested languages could not be built: ${missing_languages}
2071 Supported languages are: ${potential_languages}])
2072   fi
2073   if test "x$new_enable_languages" != "x$enable_languages"; then
2074     echo The following languages will be built: ${new_enable_languages}
2075     enable_languages="$new_enable_languages"
2076   fi
2077
2078   AC_SUBST(stage1_languages)
2079   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2080 fi
2081
2082 # Handle --disable-<component> generically.
2083 for dir in $configdirs $build_configdirs $target_configdirs ; do
2084   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2085   varname=`echo $dirname | sed -e s/+/_/g`
2086   if eval test x\${enable_${varname}} "=" xno ; then
2087     noconfigdirs="$noconfigdirs $dir"
2088   fi
2089 done
2090
2091 # Check for Boehm's garbage collector
2092 AC_ARG_ENABLE(objc-gc,
2093 [AS_HELP_STRING([--enable-objc-gc],
2094                 [enable use of Boehm's garbage collector with the
2095                  GNU Objective-C runtime])])
2096 AC_ARG_WITH([target-bdw-gc],
2097 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2098                 [specify prefix directory for installed bdw-gc package.
2099                  Equivalent to --with-target-bdw-gc-include=PATH/include
2100                  plus --with-target-bdw-gc-lib=PATH/lib])])
2101 AC_ARG_WITH([target-bdw-gc-include],
2102 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2103                 [specify directories for installed bdw-gc include files])])
2104 AC_ARG_WITH([target-bdw-gc-lib],
2105 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2106                 [specify directories for installed bdw-gc library])])
2107
2108 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2109   AC_MSG_CHECKING([for bdw garbage collector])
2110   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2111     dnl no bdw-gw options, assume default locations
2112     AC_MSG_RESULT([using bdw-gc in default locations])
2113   else
2114     dnl bdw-gw options, first error checking, complete checking in libobjc
2115     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2116       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2117     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2118       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2119     else
2120       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2121     fi
2122   fi
2123 esac
2124
2125 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2126 case ,${enable_languages}, in
2127   *,c++,*)
2128     # Disable libitm, libsanitizer if we're not building libstdc++
2129     case "${noconfigdirs}" in
2130       *target-libstdc++-v3*)
2131         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2132         ;;
2133       *) ;;
2134     esac
2135     ;;
2136   *)
2137     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2138     ;;
2139 esac
2140
2141 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2142 # $build_configdirs and $target_configdirs.
2143 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2144
2145 notsupp=""
2146 for dir in . $skipdirs $noconfigdirs ; do
2147   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2148   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2149     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2150     if test -r $srcdir/$dirname/configure ; then
2151       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2152         true
2153       else
2154         notsupp="$notsupp $dir"
2155       fi
2156     fi
2157   fi
2158   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2159     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2160     if test -r $srcdir/$dirname/configure ; then
2161       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2162         true
2163       else
2164         notsupp="$notsupp $dir"
2165       fi
2166     fi
2167   fi
2168   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2169     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2170     if test -r $srcdir/$dirname/configure ; then
2171       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2172         true
2173       else
2174         notsupp="$notsupp $dir"
2175       fi
2176     fi
2177   fi
2178 done
2179
2180 # Quietly strip out all directories which aren't configurable in this tree.
2181 # This relies on all configurable subdirectories being autoconfiscated, which
2182 # is now the case.
2183 build_configdirs_all="$build_configdirs"
2184 build_configdirs=
2185 for i in ${build_configdirs_all} ; do
2186   j=`echo $i | sed -e s/build-//g`
2187   if test -f ${srcdir}/$j/configure ; then
2188     build_configdirs="${build_configdirs} $i"
2189   fi
2190 done
2191
2192 configdirs_all="$configdirs"
2193 configdirs=
2194 for i in ${configdirs_all} ; do
2195   if test -f ${srcdir}/$i/configure ; then
2196     configdirs="${configdirs} $i"
2197   fi
2198 done
2199
2200 target_configdirs_all="$target_configdirs"
2201 target_configdirs=
2202 for i in ${target_configdirs_all} ; do
2203   j=`echo $i | sed -e s/target-//g`
2204   if test -f ${srcdir}/$j/configure ; then
2205     target_configdirs="${target_configdirs} $i"
2206   fi
2207 done
2208
2209 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2210 # so we have to add it after the preceding checks.
2211 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2212 then
2213   case " $configdirs " in
2214     *" libiberty "*)
2215       # If we can build libiberty, we can also build libiberty-linker-plugin.
2216       configdirs="$configdirs libiberty-linker-plugin"
2217       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2218         --with-libiberty=../libiberty-linker-plugin";;
2219     *)
2220       AC_MSG_ERROR([libiberty missing]);;
2221   esac
2222 fi
2223
2224 # Sometimes we have special requirements for the host libiberty.
2225 extra_host_libiberty_configure_flags=
2226 extra_host_zlib_configure_flags=
2227 case " $configdirs " in
2228   *" lto-plugin "* | *" libcc1 "*)
2229     # When these are to be built as shared libraries, the same applies to
2230     # libiberty.
2231     extra_host_libiberty_configure_flags=--enable-shared
2232     ;;
2233   *" bfd "*)
2234     # When bfd is to be built as a shared library, the same applies to
2235     # zlib.
2236     if test "$enable_shared" = "yes"; then
2237       extra_host_zlib_configure_flags=--enable-host-shared
2238     fi
2239     ;;
2240 esac
2241 AC_SUBST(extra_host_libiberty_configure_flags)
2242 AC_SUBST(extra_host_zlib_configure_flags)
2243
2244 # Produce a warning message for the subdirs we can't configure.
2245 # This isn't especially interesting in the Cygnus tree, but in the individual
2246 # FSF releases, it's important to let people know when their machine isn't
2247 # supported by the one or two programs in a package.
2248
2249 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2250   # If $appdirs is non-empty, at least one of those directories must still
2251   # be configured, or we error out.  (E.g., if the gas release supports a
2252   # specified target in some subdirs but not the gas subdir, we shouldn't
2253   # pretend that all is well.)
2254   if test -n "$appdirs" ; then
2255     for dir in $appdirs ; do
2256       if test -r $dir/Makefile.in ; then
2257         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2258           appdirs=""
2259           break
2260         fi
2261         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2262           appdirs=""
2263           break
2264         fi
2265       fi
2266     done
2267     if test -n "$appdirs" ; then
2268       echo "*** This configuration is not supported by this package." 1>&2
2269       exit 1
2270     fi
2271   fi
2272   # Okay, some application will build, or we don't care to check.  Still
2273   # notify of subdirs not getting built.
2274   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2275   echo "    ${notsupp}" 1>&2
2276   echo "    (Any other directories should still work fine.)" 1>&2
2277 fi
2278
2279 case "$host" in
2280   *msdosdjgpp*)
2281     enable_gdbtk=no ;;
2282 esac
2283
2284 # To find our prefix, in gcc_cv_tool_prefix.
2285 ACX_TOOL_DIRS
2286
2287 copy_dirs=
2288
2289 AC_ARG_WITH([build-sysroot],
2290   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2291                   [use sysroot as the system root during the build])],
2292   [if test x"$withval" != x ; then
2293      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2294    fi],
2295   [SYSROOT_CFLAGS_FOR_TARGET=])
2296 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2297
2298 AC_ARG_WITH([debug-prefix-map],
2299   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2300                   [map A to B, C to D ... in debug information])],
2301   [if test x"$withval" != x; then
2302      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2303      for debug_map in $withval; do
2304        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2305      done
2306    fi],
2307   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2308 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2309
2310 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2311 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2312 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2313 # We want to ensure that TARGET libraries (which we know are built with
2314 # gcc) are built with "-O2 -g", so include those options when setting
2315 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2316 if test "x$CFLAGS_FOR_TARGET" = x; then
2317   if test "x${is_cross_compiler}" = xyes; then
2318     CFLAGS_FOR_TARGET="-g -O2"
2319   else
2320     CFLAGS_FOR_TARGET=$CFLAGS
2321     case " $CFLAGS " in
2322       *" -O2 "*) ;;
2323       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2324     esac
2325     case " $CFLAGS " in
2326       *" -g "* | *" -g3 "*) ;;
2327       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2328     esac
2329   fi
2330 fi
2331 AC_SUBST(CFLAGS_FOR_TARGET)
2332
2333 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2334   if test "x${is_cross_compiler}" = xyes; then
2335     CXXFLAGS_FOR_TARGET="-g -O2"
2336   else
2337     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2338     case " $CXXFLAGS " in
2339       *" -O2 "*) ;;
2340       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2341     esac
2342     case " $CXXFLAGS " in
2343       *" -g "* | *" -g3 "*) ;;
2344       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2345     esac
2346   fi
2347 fi
2348 AC_SUBST(CXXFLAGS_FOR_TARGET)
2349
2350 AC_SUBST(LDFLAGS_FOR_TARGET)
2351
2352 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2353 # the named directory are copied to $(tooldir)/sys-include.
2354 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2355   if test x${is_cross_compiler} = xno ; then
2356     echo 1>&2 '***' --with-headers is only supported when cross compiling
2357     exit 1
2358   fi
2359   if test x"${with_headers}" != xyes ; then
2360     x=${gcc_cv_tool_prefix}
2361     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2362   fi
2363 fi
2364
2365 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2366 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2367 # are permitted.
2368 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2369   if test x${is_cross_compiler} = xno ; then
2370     echo 1>&2 '***' --with-libs is only supported when cross compiling
2371     exit 1
2372   fi
2373   if test x"${with_libs}" != xyes ; then
2374     # Copy the libraries in reverse order, so that files in the first named
2375     # library override files in subsequent libraries.
2376     x=${gcc_cv_tool_prefix}
2377     for l in ${with_libs}; do
2378       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2379     done
2380   fi
2381 fi
2382
2383 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2384 #
2385 # This is done by determining whether or not the appropriate directory
2386 # is available, and by checking whether or not specific configurations
2387 # have requested that this magic not happen.
2388 #
2389 # The command line options always override the explicit settings in
2390 # configure.ac, and the settings in configure.ac override this magic.
2391 #
2392 # If the default for a toolchain is to use GNU as and ld, and you don't
2393 # want to do that, then you should use the --without-gnu-as and
2394 # --without-gnu-ld options for the configure script.  Similarly, if
2395 # the default is to use the included zlib and you don't want to do that,
2396 # you should use the --with-system-zlib option for the configure script.
2397
2398 if test x${use_gnu_as} = x &&
2399    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2400   with_gnu_as=yes
2401   extra_host_args="$extra_host_args --with-gnu-as"
2402 fi
2403
2404 if test x${use_gnu_ld} = x &&
2405    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2406   with_gnu_ld=yes
2407   extra_host_args="$extra_host_args --with-gnu-ld"
2408 fi
2409
2410 if test x${use_included_zlib} = x &&
2411    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2412   :
2413 else
2414   with_system_zlib=yes
2415   extra_host_args="$extra_host_args --with-system-zlib"
2416 fi
2417
2418 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2419 # can detect this case.
2420
2421 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2422   with_newlib=yes
2423   extra_host_args="$extra_host_args --with-newlib"
2424 fi
2425
2426 # Handle ${copy_dirs}
2427 set fnord ${copy_dirs}
2428 shift
2429 while test $# != 0 ; do
2430   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2431     :
2432   else
2433     echo Copying $1 to $2
2434
2435     # Use the install script to create the directory and all required
2436     # parent directories.
2437     if test -d $2 ; then
2438       :
2439     else
2440       echo >config.temp
2441       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2442     fi
2443
2444     # Copy the directory, assuming we have tar.
2445     # FIXME: Should we use B in the second tar?  Not all systems support it.
2446     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2447
2448     # It is the responsibility of the user to correctly adjust all
2449     # symlinks.  If somebody can figure out how to handle them correctly
2450     # here, feel free to add the code.
2451
2452     echo $1 > $2/COPIED
2453   fi
2454   shift; shift
2455 done
2456
2457 # Determine a target-dependent exec_prefix that the installed
2458 # gcc will search in.  Keep this list sorted by triplet, with
2459 # the *-*-osname triplets last.
2460 md_exec_prefix=
2461 case "${target}" in
2462   i[[34567]]86-pc-msdosdjgpp*)
2463     md_exec_prefix=/dev/env/DJDIR/bin
2464     ;;
2465   *-*-hpux* | \
2466   *-*-nto-qnx* | \
2467   *-*-solaris2*)
2468     md_exec_prefix=/usr/ccs/bin
2469     ;;
2470 esac
2471
2472 extra_arflags_for_target=
2473 extra_nmflags_for_target=
2474 extra_ranlibflags_for_target=
2475 target_makefile_frag=/dev/null
2476 case "${target}" in
2477   spu-*-*)
2478     target_makefile_frag="config/mt-spu"
2479     ;;
2480   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2481     target_makefile_frag="config/mt-sde"
2482     ;;
2483   mipsisa*-*-elfoabi*)
2484     target_makefile_frag="config/mt-mips-elfoabi"
2485     ;;
2486   mips*-*-*linux* | mips*-*-gnu*)
2487     target_makefile_frag="config/mt-mips-gnu"
2488     ;;
2489   nios2-*-elf*)
2490     target_makefile_frag="config/mt-nios2-elf"
2491     ;;
2492   *-*-linux-android*)
2493     target_makefile_frag="config/mt-android"
2494     ;;
2495   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2496     target_makefile_frag="config/mt-gnu"
2497     ;;
2498   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2499     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2500     # commands to handle both 32-bit and 64-bit objects.  These flags are
2501     # harmless if we're using GNU nm or ar.
2502     extra_arflags_for_target=" -X32_64"
2503     extra_nmflags_for_target=" -B -X32_64"
2504     ;;
2505 esac
2506
2507 alphaieee_frag=/dev/null
2508 case $target in
2509   alpha*-*-*)
2510     # This just makes sure to use the -mieee option to build target libs.
2511     # This should probably be set individually by each library.
2512     alphaieee_frag="config/mt-alphaieee"
2513     ;;
2514 esac
2515
2516 # If --enable-target-optspace always use -Os instead of -O2 to build
2517 # the target libraries, similarly if it is not specified, use -Os
2518 # on selected platforms.
2519 ospace_frag=/dev/null
2520 case "${enable_target_optspace}:${target}" in
2521   yes:*)
2522     ospace_frag="config/mt-ospace"
2523     ;;
2524   :d30v-*)
2525     ospace_frag="config/mt-d30v"
2526     ;;
2527   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2528     ospace_frag="config/mt-ospace"
2529     ;;
2530   no:* | :*)
2531     ;;
2532   *)
2533     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2534     ;;
2535 esac
2536
2537 # Some systems (e.g., one of the i386-aix systems the gas testers are
2538 # using) don't handle "\$" correctly, so don't use it here.
2539 tooldir='${exec_prefix}'/${target_noncanonical}
2540 build_tooldir=${tooldir}
2541
2542 # Create a .gdbinit file which runs the one in srcdir
2543 # and tells GDB to look there for source files.
2544
2545 if test -r ${srcdir}/.gdbinit ; then
2546   case ${srcdir} in
2547     .) ;;
2548     *) cat > ./.gdbinit <<EOF
2549 # ${NO_EDIT}
2550 dir ${srcdir}
2551 dir .
2552 source ${srcdir}/.gdbinit
2553 EOF
2554     ;;
2555   esac
2556 fi
2557
2558 # Make sure that the compiler is able to generate an executable.  If it
2559 # can't, we are probably in trouble.  We don't care whether we can run the
2560 # executable--we might be using a cross compiler--we only care whether it
2561 # can be created.  At this point the main configure script has set CC.
2562 we_are_ok=no
2563 echo "int main () { return 0; }" > conftest.c
2564 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2565 if test $? = 0 ; then
2566   if test -s conftest || test -s conftest.exe ; then
2567     we_are_ok=yes
2568   fi
2569 fi
2570 case $we_are_ok in
2571   no)
2572     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2573     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2574     rm -f conftest*
2575     exit 1
2576     ;;
2577 esac
2578 rm -f conftest*
2579
2580 # Decide which environment variable is used to find dynamic libraries.
2581 case "${host}" in
2582   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2583   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2584   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2585   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2586 esac
2587
2588 # On systems where the dynamic library environment variable is PATH,
2589 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2590 # built executables to PATH.
2591 if test "$RPATH_ENVVAR" = PATH; then
2592   GCC_SHLIB_SUBDIR=/shlib
2593 else
2594   GCC_SHLIB_SUBDIR=
2595 fi
2596
2597 # Adjust the toplevel makefile according to whether bootstrap was selected.
2598 case $enable_bootstrap in
2599   yes)
2600     bootstrap_suffix=bootstrap
2601     BUILD_CONFIG=bootstrap-debug
2602     ;;
2603   no)
2604     bootstrap_suffix=no-bootstrap
2605     BUILD_CONFIG=
2606     ;;
2607 esac
2608
2609 AC_MSG_CHECKING(for default BUILD_CONFIG)
2610
2611 AC_ARG_WITH([build-config],
2612   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2613                   [use config/NAME.mk build configuration])],
2614   [case $with_build_config in
2615    yes) with_build_config= ;;
2616    no) with_build_config= BUILD_CONFIG= ;;
2617    esac])
2618
2619 if test "x${with_build_config}" != x; then
2620   BUILD_CONFIG=$with_build_config
2621 else
2622   case $BUILD_CONFIG in
2623   bootstrap-debug)
2624     if echo "int f (void) { return 0; }" > conftest.c &&
2625        ${CC} -c conftest.c &&
2626        mv conftest.o conftest.o.g0 &&
2627        ${CC} -c -g conftest.c &&
2628        mv conftest.o conftest.o.g &&
2629        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2630       :
2631     else
2632       BUILD_CONFIG=
2633     fi
2634     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2635     ;;
2636   esac
2637 fi
2638 AC_MSG_RESULT($BUILD_CONFIG)
2639 AC_SUBST(BUILD_CONFIG)
2640
2641 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2642 AC_MSG_CHECKING([for --enable-vtable-verify])
2643 AC_ARG_ENABLE(vtable-verify,
2644 [AS_HELP_STRING([--enable-vtable-verify],
2645                 [Enable vtable verification feature])],
2646 [case "$enableval" in
2647  yes) enable_vtable_verify=yes ;;
2648  no)  enable_vtable_verify=no ;;
2649  *)   enable_vtable_verify=no;;
2650  esac],
2651 [enable_vtable_verify=no])
2652 AC_MSG_RESULT($enable_vtable_verify)
2653
2654 # Record target_configdirs and the configure arguments for target and
2655 # build configuration in Makefile.
2656 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2657 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2658 bootstrap_fixincludes=no
2659
2660 # If we are building libgomp, bootstrap it.
2661 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2662   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2663 fi
2664
2665 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2666 # or bootstrap-ubsan, bootstrap it.
2667 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2668   case "$BUILD_CONFIG" in
2669     *bootstrap-asan* | *bootstrap-ubsan* )
2670       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2671       bootstrap_fixincludes=yes
2672       ;;
2673   esac
2674 fi
2675
2676 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2677 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2678    test "$enable_vtable_verify" != no; then
2679   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2680 fi
2681
2682 # Determine whether gdb needs tk/tcl or not.
2683 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2684 # and in that case we want gdb to be built without tk.  Ugh!
2685 # In fact I believe gdb is the *only* package directly dependent on tk,
2686 # so we should be able to put the 'maybe's in unconditionally and
2687 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2688 # 100% sure that that's safe though.
2689
2690 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2691 case "$enable_gdbtk" in
2692   no)
2693     GDB_TK="" ;;
2694   yes)
2695     GDB_TK="${gdb_tk}" ;;
2696   *)
2697     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2698     # distro.  Eventually someone will fix this and move Insight, nee
2699     # gdbtk to a separate directory.
2700     if test -d ${srcdir}/gdb/gdbtk ; then
2701       GDB_TK="${gdb_tk}"
2702     else
2703       GDB_TK=""
2704     fi
2705     ;;
2706 esac
2707 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2708 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2709
2710 # Strip out unwanted targets.
2711
2712 # While at that, we remove Makefiles if we were started for recursive
2713 # configuration, so that the top-level Makefile reconfigures them,
2714 # like we used to do when configure itself was recursive.
2715
2716 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2717 # but now we're fixing up the Makefile ourselves with the additional
2718 # commands passed to AC_CONFIG_FILES.  Use separate variables
2719 # extrasub-{build,host,target} not because there is any reason to split
2720 # the substitutions up that way, but only to remain below the limit of
2721 # 99 commands in a script, for HP-UX sed.
2722 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2723
2724 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2725   yes:yes:*\ gold\ *:*,c++,*) ;;
2726   yes:yes:*\ gold\ *:*)
2727     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2728     ;;
2729 esac
2730
2731 extrasub_build=
2732 for module in ${build_configdirs} ; do
2733   if test -z "${no_recursion}" \
2734      && test -f ${build_subdir}/${module}/Makefile; then
2735     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2736     rm -f ${build_subdir}/${module}/Makefile
2737   fi
2738   extrasub_build="$extrasub_build
2739 /^@if build-$module\$/d
2740 /^@endif build-$module\$/d
2741 /^@if build-$module-$bootstrap_suffix\$/d
2742 /^@endif build-$module-$bootstrap_suffix\$/d"
2743 done
2744 extrasub_host=
2745 for module in ${configdirs} ; do
2746   if test -z "${no_recursion}"; then
2747     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2748       if test -f ${file}; then
2749         echo 1>&2 "*** removing ${file} to force reconfigure"
2750         rm -f ${file}
2751       fi
2752     done
2753   fi
2754   case ${module},${bootstrap_fixincludes} in
2755     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2756     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2757   esac
2758   extrasub_host="$extrasub_host
2759 /^@if $module\$/d
2760 /^@endif $module\$/d
2761 /^@if $module-$host_bootstrap_suffix\$/d
2762 /^@endif $module-$host_bootstrap_suffix\$/d"
2763 done
2764 extrasub_target=
2765 for module in ${target_configdirs} ; do
2766   if test -z "${no_recursion}" \
2767      && test -f ${target_subdir}/${module}/Makefile; then
2768     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2769     rm -f ${target_subdir}/${module}/Makefile
2770   fi
2771
2772   # We only bootstrap target libraries listed in bootstrap_target_libs.
2773   case $bootstrap_target_libs in
2774     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2775     *) target_bootstrap_suffix=no-bootstrap ;;
2776   esac
2777
2778   extrasub_target="$extrasub_target
2779 /^@if target-$module\$/d
2780 /^@endif target-$module\$/d
2781 /^@if target-$module-$target_bootstrap_suffix\$/d
2782 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2783 done
2784
2785 # Do the final fixup along with target modules.
2786 extrasub_target="$extrasub_target
2787 /^@if /,/^@endif /d"
2788
2789 # Create the serialization dependencies.  This uses a temporary file.
2790
2791 AC_ARG_ENABLE([serial-configure],
2792 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2793                 [force sequential configuration of
2794                  sub-packages for the host, target or build
2795                  machine, or all sub-packages])])
2796
2797 case ${enable_serial_configure} in
2798   yes)
2799     enable_serial_build_configure=yes
2800     enable_serial_host_configure=yes
2801     enable_serial_target_configure=yes
2802     ;;
2803 esac
2804
2805 # These force 'configure's to be done one at a time, to avoid problems
2806 # with contention over a shared config.cache.
2807 rm -f serdep.tmp
2808 echo '# serdep.tmp' > serdep.tmp
2809 olditem=
2810 test "x${enable_serial_build_configure}" = xyes &&
2811 for item in ${build_configdirs} ; do
2812   case ${olditem} in
2813     "") ;;
2814     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2815   esac
2816   olditem=${item}
2817 done
2818 olditem=
2819 test "x${enable_serial_host_configure}" = xyes &&
2820 for item in ${configdirs} ; do
2821   case ${olditem} in
2822     "") ;;
2823     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2824   esac
2825   olditem=${item}
2826 done
2827 olditem=
2828 test "x${enable_serial_target_configure}" = xyes &&
2829 for item in ${target_configdirs} ; do
2830   case ${olditem} in
2831     "") ;;
2832     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2833   esac
2834   olditem=${item}
2835 done
2836 serialization_dependencies=serdep.tmp
2837 AC_SUBST_FILE(serialization_dependencies)
2838
2839 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2840 # target, nonopt, and variable assignments.  These are the ones we
2841 # might not want to pass down to subconfigures.  The exception being
2842 # --cache-file=/dev/null, which is used to turn off the use of cache
2843 # files altogether, and which should be passed on to subconfigures.
2844 # Also strip program-prefix, program-suffix, and program-transform-name,
2845 # so that we can pass down a consistent program-transform-name.
2846 baseargs=
2847 tbaseargs=
2848 keep_next=no
2849 skip_next=no
2850 eval "set -- $ac_configure_args"
2851 for ac_arg
2852 do
2853   if test X"$skip_next" = X"yes"; then
2854     skip_next=no
2855     continue
2856   fi
2857   if test X"$keep_next" = X"yes"; then
2858     case $ac_arg in
2859       *\'*)
2860         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2861     esac
2862     baseargs="$baseargs '$ac_arg'"
2863     tbaseargs="$tbaseargs '$ac_arg'"
2864     keep_next=no
2865     continue
2866   fi
2867
2868   # Handle separated arguments.  Based on the logic generated by
2869   # autoconf 2.59.
2870   case $ac_arg in
2871     *=* | --config-cache | -C | -disable-* | --disable-* \
2872       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2873       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2874       | -with-* | --with-* | -without-* | --without-* | --x)
2875       separate_arg=no
2876       ;;
2877     -*)
2878       separate_arg=yes
2879       ;;
2880     *)
2881       separate_arg=no
2882       ;;
2883   esac
2884
2885   skip_targ=no
2886   case $ac_arg in
2887 changequote(,)
2888   --with-* | --without-*)
2889     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2890
2891     case $libopt in
2892     *[-_]include)
2893       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2894       ;;
2895     *[-_]lib)
2896       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2897       ;;
2898     *)
2899       lib=$libopt
2900       ;;
2901     esac
2902 changequote([,])
2903
2904     case $lib in
2905     mpc | mpfr | gmp | isl)
2906       # If we're processing --with-$lib, --with-$lib-include or
2907       # --with-$lib-lib, for one of the libs above, and target is
2908       # different from host, don't pass the current argument to any
2909       # target library's configure.
2910       if test x$is_cross_compiler = xyes; then
2911         skip_targ=yes
2912       fi
2913       ;;
2914     esac
2915     ;;
2916   esac
2917
2918   case "$ac_arg" in
2919     --cache-file=/dev/null | \
2920     -cache-file=/dev/null )
2921       # Handled here to avoid the test to skip args below.
2922       baseargs="$baseargs '$ac_arg'"
2923       tbaseargs="$tbaseargs '$ac_arg'"
2924       # Assert: $separate_arg should always be no.
2925       keep_next=$separate_arg
2926       ;;
2927     --no*)
2928       continue
2929       ;;
2930     --c* | \
2931     --sr* | \
2932     --ho* | \
2933     --bu* | \
2934     --t* | \
2935     --program-* | \
2936     -cache_file* | \
2937     -srcdir* | \
2938     -host* | \
2939     -build* | \
2940     -target* | \
2941     -program-prefix* | \
2942     -program-suffix* | \
2943     -program-transform-name* )
2944       skip_next=$separate_arg
2945       continue
2946       ;;
2947     -*)
2948       # An option.  Add it.
2949       case $ac_arg in
2950         *\'*)
2951           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2952       esac
2953       baseargs="$baseargs '$ac_arg'"
2954       if test X"$skip_targ" = Xno; then
2955         tbaseargs="$tbaseargs '$ac_arg'"
2956       fi
2957       keep_next=$separate_arg
2958       ;;
2959     *)
2960       # Either a variable assignment, or a nonopt (triplet).  Don't
2961       # pass it down; let the Makefile handle this.
2962       continue
2963       ;;
2964   esac
2965 done
2966 # Remove the initial space we just introduced and, as these will be
2967 # expanded by make, quote '$'.
2968 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2969
2970 # Add in --program-transform-name, after --program-prefix and
2971 # --program-suffix have been applied to it.  Autoconf has already
2972 # doubled dollar signs and backslashes in program_transform_name; we want
2973 # the backslashes un-doubled, and then the entire thing wrapped in single
2974 # quotes, because this will be expanded first by make and then by the shell.
2975 # Also, because we want to override the logic in subdir configure scripts to
2976 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2977 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2978 ${program_transform_name}
2979 EOF_SED
2980 gcc_transform_name=`cat conftestsed.out`
2981 rm -f conftestsed.out
2982 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2983 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2984 if test "$silent" = yes; then
2985   baseargs="$baseargs --silent"
2986   tbaseargs="$tbaseargs --silent"
2987 fi
2988 baseargs="$baseargs --disable-option-checking"
2989 tbaseargs="$tbaseargs --disable-option-checking"
2990
2991 # Record and document user additions to sub configure arguments.
2992 AC_ARG_VAR([build_configargs],
2993            [additional configure arguments for build directories])
2994 AC_ARG_VAR([host_configargs],
2995            [additional configure arguments for host directories])
2996 AC_ARG_VAR([target_configargs],
2997            [additional configure arguments for target directories])
2998
2999 # For the build-side libraries, we just need to pretend we're native,
3000 # and not use the same cache file.  Multilibs are neither needed nor
3001 # desired.  We can't even use the same cache file for all build-side
3002 # libraries, as they're compiled differently; some with C, some with
3003 # C++ or with different feature-enabling options.
3004 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3005
3006 # For host modules, accept cache file option, or specification as blank.
3007 case "${cache_file}" in
3008 "") # empty
3009   cache_file_option="" ;;
3010 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3011   cache_file_option="--cache-file=${cache_file}" ;;
3012 *) # relative path
3013   cache_file_option="--cache-file=../${cache_file}" ;;
3014 esac
3015
3016 # Host dirs don't like to share a cache file either, horribly enough.
3017 # This seems to be due to autoconf 2.5x stupidity.
3018 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3019
3020 target_configargs="$target_configargs ${tbaseargs}"
3021
3022 # Passing a --with-cross-host argument lets the target libraries know
3023 # whether they are being built with a cross-compiler or being built
3024 # native.  However, it would be better to use other mechanisms to make the
3025 # sorts of decisions they want to make on this basis.  Please consider
3026 # this option to be deprecated.  FIXME.
3027 if test x${is_cross_compiler} = xyes ; then
3028   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3029 fi
3030
3031 # Special user-friendly check for native x86_64-linux build, if
3032 # multilib is not explicitly enabled.
3033 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3034   x86_64-*linux*:yes:$build:$build:)
3035     # Make sure we have a development environment that handles 32-bit
3036     dev64=no
3037     echo "int main () { return 0; }" > conftest.c
3038     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3039     if test $? = 0 ; then
3040       if test -s conftest || test -s conftest.exe ; then
3041         dev64=yes
3042       fi
3043     fi
3044     rm -f conftest*
3045     if test x${dev64} != xyes ; then
3046       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3047     fi
3048     ;;
3049 esac
3050
3051 # Default to --enable-multilib.
3052 if test x${enable_multilib} = x ; then
3053   target_configargs="--enable-multilib ${target_configargs}"
3054 fi
3055
3056 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3057 # changed from the earlier setting of with_newlib.
3058 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3059   target_configargs="--with-newlib ${target_configargs}"
3060 fi
3061
3062 # Different target subdirs use different values of certain variables
3063 # (notably CXX).  Worse, multilibs use *lots* of different values.
3064 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3065 # it doesn't automatically accept command-line overrides of them.
3066 # This means it's not safe for target subdirs to share a cache file,
3067 # which is disgusting, but there you have it.  Hopefully this can be
3068 # fixed in future.  It's still worthwhile to use a cache file for each
3069 # directory.  I think.
3070
3071 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3072 # We need to pass --target, as newer autoconf's requires consistency
3073 # for target_alias and gcc doesn't manage it consistently.
3074 target_configargs="--cache-file=./config.cache ${target_configargs}"
3075
3076 FLAGS_FOR_TARGET=
3077 case " $target_configdirs " in
3078  *" newlib "*)
3079   case " $target_configargs " in
3080   *" --with-newlib "*)
3081    case "$target" in
3082     *-cygwin*)
3083       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3084       ;;
3085    esac
3086
3087    # If we're not building GCC, don't discard standard headers.
3088    if test -d ${srcdir}/gcc; then
3089      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3090
3091      if test "${build}" != "${host}"; then
3092        # On Canadian crosses, CC_FOR_TARGET will have already been set
3093        # by `configure', so we won't have an opportunity to add -Bgcc/
3094        # to it.  This is right: we don't want to search that directory
3095        # for binaries, but we want the header files in there, so add
3096        # them explicitly.
3097        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3098
3099        # Someone might think of using the pre-installed headers on
3100        # Canadian crosses, in case the installed compiler is not fully
3101        # compatible with the compiler being built.  In this case, it
3102        # would be better to flag an error than risking having
3103        # incompatible object files being constructed.  We can't
3104        # guarantee that an error will be flagged, but let's hope the
3105        # compiler will do it, when presented with incompatible header
3106        # files.
3107      fi
3108    fi
3109
3110    case "${target}-${is_cross_compiler}" in
3111    i[[3456789]]86-*-linux*-no)
3112       # Here host == target, so we don't need to build gcc,
3113       # so we don't want to discard standard headers.
3114       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3115       ;;
3116    *)
3117       # If we're building newlib, use its generic headers last, but search
3118       # for any libc-related directories first (so make it the last -B
3119       # switch).
3120       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3121
3122       # If we're building libgloss, find the startup file, simulator library
3123       # and linker script.
3124       case " $target_configdirs " in
3125         *" libgloss "*)
3126         # Look for startup file, simulator library and maybe linker script.
3127         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3128         # Look for libnosys.a in case the target needs it.
3129         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3130         # Most targets have the linker script in the source directory.
3131         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3132         ;;
3133       esac
3134       ;;
3135    esac
3136    ;;
3137   esac
3138   ;;
3139 esac
3140
3141 case "$target" in
3142   x86_64-*mingw* | *-w64-mingw*)
3143   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3144   # however, use a symlink named 'mingw' in ${prefix} .
3145     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3146     ;;
3147   *-mingw*)
3148   # MinGW can't be handled as Cygwin above since it does not use newlib.
3149     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3150     ;;
3151 esac
3152
3153 # Allow the user to override the flags for
3154 # our build compiler if desired.
3155 if test x"${build}" = x"${host}" ; then
3156   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3157   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3158   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3159 fi
3160
3161 # On Canadian crosses, we'll be searching the right directories for
3162 # the previously-installed cross compiler, so don't bother to add
3163 # flags for directories within the install tree of the compiler
3164 # being built; programs in there won't even run.
3165 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3166   # Search for pre-installed headers if nothing else fits.
3167   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3168 fi
3169
3170 if test "x${use_gnu_ld}" = x &&
3171    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3172   # Arrange for us to find uninstalled linker scripts.
3173   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3174 fi
3175
3176 # Search for other target-specific linker scripts and such.
3177 case "${target}" in
3178   mep*)
3179     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3180     ;;
3181 esac
3182
3183 # Makefile fragments.
3184 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3185 do
3186   eval fragval=\$$frag
3187   if test $fragval != /dev/null; then
3188     eval $frag=${srcdir}/$fragval
3189   fi
3190 done
3191 AC_SUBST_FILE(host_makefile_frag)
3192 AC_SUBST_FILE(target_makefile_frag)
3193 AC_SUBST_FILE(alphaieee_frag)
3194 AC_SUBST_FILE(ospace_frag)
3195
3196 # Miscellanea: directories, flags, etc.
3197 AC_SUBST(RPATH_ENVVAR)
3198 AC_SUBST(GCC_SHLIB_SUBDIR)
3199 AC_SUBST(tooldir)
3200 AC_SUBST(build_tooldir)
3201 AC_SUBST(CONFIGURE_GDB_TK)
3202 AC_SUBST(GDB_TK)
3203 AC_SUBST(INSTALL_GDB_TK)
3204
3205 # Build module lists & subconfigure args.
3206 AC_SUBST(build_configargs)
3207 AC_SUBST(build_configdirs)
3208
3209 # Host module lists & subconfigure args.
3210 AC_SUBST(host_configargs)
3211 AC_SUBST(configdirs)
3212 AC_SUBST(target_configdirs)
3213
3214 # Target module lists & subconfigure args.
3215 AC_SUBST(target_configargs)
3216
3217
3218 # Build tools.
3219 AC_SUBST(AR_FOR_BUILD)
3220 AC_SUBST(AS_FOR_BUILD)
3221 AC_SUBST(CC_FOR_BUILD)
3222 AC_SUBST(CFLAGS_FOR_BUILD)
3223 AC_SUBST(CXXFLAGS_FOR_BUILD)
3224 AC_SUBST(CXX_FOR_BUILD)
3225 AC_SUBST(DLLTOOL_FOR_BUILD)
3226 AC_SUBST(GFORTRAN_FOR_BUILD)
3227 AC_SUBST(GOC_FOR_BUILD)
3228 AC_SUBST(LDFLAGS_FOR_BUILD)
3229 AC_SUBST(LD_FOR_BUILD)
3230 AC_SUBST(NM_FOR_BUILD)
3231 AC_SUBST(RANLIB_FOR_BUILD)
3232 AC_SUBST(WINDMC_FOR_BUILD)
3233 AC_SUBST(WINDRES_FOR_BUILD)
3234
3235 # Generate default definitions for YACC, M4, LEX and other programs that run
3236 # on the build machine.  These are used if the Makefile can't locate these
3237 # programs in objdir.
3238 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3239
3240 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3241 case " $build_configdirs " in
3242   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3243 esac
3244
3245 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3246 case " $build_configdirs " in
3247   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3248 esac
3249
3250 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3251 case " $build_configdirs " in
3252   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3253 esac
3254
3255 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3256 case " $build_configdirs " in
3257   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3258   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3259 esac
3260
3261 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3262 case " $build_configdirs " in
3263   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3264 esac
3265
3266 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3267 case " $build_configdirs " in
3268   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3269   *)
3270 changequote(,)
3271     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3272     # higher, else we use the "missing" dummy.
3273     if ${MAKEINFO} --version \
3274        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3275       :
3276     else
3277       MAKEINFO="$MISSING makeinfo"
3278     fi
3279     ;;
3280 changequote([,])
3281 esac
3282
3283 # FIXME: expect and dejagnu may become build tools?
3284
3285 AC_CHECK_PROGS(EXPECT, expect, expect)
3286 case " $configdirs " in
3287   *" expect "*)
3288     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3289     ;;
3290 esac
3291
3292 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3293 case " $configdirs " in
3294   *" dejagnu "*)
3295     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3296     ;;
3297 esac
3298
3299
3300 # Host tools.
3301 NCN_STRICT_CHECK_TOOLS(AR, ar)
3302 NCN_STRICT_CHECK_TOOLS(AS, as)
3303 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3304 NCN_STRICT_CHECK_TOOLS(LD, ld)
3305 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3306 NCN_STRICT_CHECK_TOOLS(NM, nm)
3307 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3308 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3309 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3310 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3311 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3312 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3313 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3314 AC_SUBST(CC)
3315 AC_SUBST(CXX)
3316 AC_SUBST(CFLAGS)
3317 AC_SUBST(CXXFLAGS)
3318
3319 # Target tools.
3320 AC_ARG_WITH([build-time-tools],
3321   [AS_HELP_STRING([--with-build-time-tools=PATH],
3322                   [use given path to find target tools during the build])],
3323   [case x"$withval" in
3324      x/*) ;;
3325      *)
3326        with_build_time_tools=
3327        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3328        ;;
3329    esac],
3330   [with_build_time_tools=])
3331
3332 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3333 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3334 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3335 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3336 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3337
3338 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3339 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3340 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3341 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3342 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3343 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3344 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3345 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3346 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3347 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3348 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3349 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3350 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3351
3352 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3353
3354 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3355 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3356 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3357 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3358 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3359                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3360                 c++)
3361 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3362                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3363                 c++)
3364 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3365 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3366 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3367                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3368 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3369                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3370 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3371 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3372 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3373 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3374 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3375 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3376 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3377 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3378 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3379 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3380
3381 AC_SUBST(FLAGS_FOR_TARGET)
3382 AC_SUBST(RAW_CXX_FOR_TARGET)
3383
3384 # Certain tools may need extra flags.
3385 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3386 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3387 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3388
3389 # When building target libraries, except in a Canadian cross, we use
3390 # the same toolchain as the compiler we just built.
3391 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3392 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3393 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3394 if test $host = $build; then
3395   case " $configdirs " in
3396     *" gcc "*)
3397       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3398       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3399       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3400       ;;
3401   esac
3402 fi
3403
3404 AC_SUBST(COMPILER_AS_FOR_TARGET)
3405 AC_SUBST(COMPILER_LD_FOR_TARGET)
3406 AC_SUBST(COMPILER_NM_FOR_TARGET)
3407
3408 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3409 AC_ARG_ENABLE(maintainer-mode,
3410 [AS_HELP_STRING([--enable-maintainer-mode],
3411                 [enable make rules and dependencies not useful
3412                  (and sometimes confusing) to the casual installer])],
3413       USE_MAINTAINER_MODE=$enableval,
3414       USE_MAINTAINER_MODE=no)
3415 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3416 AC_SUBST(MAINTAINER_MODE_TRUE)
3417 AC_SUBST(MAINTAINER_MODE_FALSE)
3418 if test "$USE_MAINTAINER_MODE" = yes; then
3419   MAINTAINER_MODE_TRUE=
3420   MAINTAINER_MODE_FALSE='#'
3421 else
3422   MAINTAINER_MODE_TRUE='#'
3423   MAINTAINER_MODE_FALSE=
3424 fi
3425 MAINT=$MAINTAINER_MODE_TRUE
3426 AC_SUBST(MAINT)dnl
3427
3428 # ---------------------
3429 # GCC bootstrap support
3430 # ---------------------
3431
3432 # Stage specific cflags for build.
3433 stage1_cflags="-g"
3434 case $build in
3435   vax-*-*)
3436     case ${GCC} in
3437       yes) stage1_cflags="-g -Wa,-J" ;;
3438       *) stage1_cflags="-g -J" ;;
3439     esac ;;
3440 esac
3441
3442 AC_SUBST(stage1_cflags)
3443
3444 # Enable --enable-checking in stage1 of the compiler.
3445 AC_ARG_ENABLE(stage1-checking,
3446 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3447                 [choose additional checking for stage1 of the compiler])],
3448 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3449 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3450   # For --disable-checking or implicit --enable-checking=release, avoid
3451   # setting --enable-checking=gc in the default stage1 checking for LTO
3452   # bootstraps.  See PR62077.
3453   case $BUILD_CONFIG in
3454     *lto*)
3455       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3456     *)
3457       stage1_checking=--enable-checking=yes,types;;
3458   esac
3459   if test "x$enable_checking" = x && \
3460      test -d ${srcdir}/gcc && \
3461      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3462     stage1_checking=--enable-checking=yes,types,extra
3463   fi
3464 else
3465   stage1_checking=--enable-checking=$enable_checking,types
3466 fi])
3467 AC_SUBST(stage1_checking)
3468
3469 # Enable -Werror in bootstrap stage2 and later.
3470 AC_ARG_ENABLE(werror,
3471 [AS_HELP_STRING([--enable-werror],
3472                 [enable -Werror in bootstrap stage2 and later])],
3473 [
3474 case ${enable_werror} in
3475   yes) stage2_werror_flag="--enable-werror-always" ;;
3476   *) stage2_werror_flag="" ;;
3477 esac
3478 ],
3479 [
3480 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3481   case $BUILD_CONFIG in
3482   bootstrap-debug)
3483       stage2_werror_flag="--enable-werror-always" ;;
3484   "")
3485       stage2_werror_flag="--enable-werror-always" ;;
3486   esac
3487 fi
3488 ])
3489
3490 AC_SUBST(stage2_werror_flag)
3491
3492 # Specify what files to not compare during bootstrap.
3493
3494 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3495 case "$target" in
3496   hppa*64*-*-hpux*) ;;
3497   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3498   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3499 esac
3500 AC_SUBST(compare_exclusions)
3501
3502 AC_CONFIG_FILES([Makefile],
3503   [sed "$extrasub_build" Makefile |
3504    sed "$extrasub_host" |
3505    sed "$extrasub_target" > mf$$
3506    mv -f mf$$ Makefile],
3507   [extrasub_build="$extrasub_build"
3508    extrasub_host="$extrasub_host"
3509    extrasub_target="$extrasub_target"])
3510 AC_OUTPUT