configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [39])
  34 m4_define([glib_micro_version], [2])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_cv_stack_grows=no
 129     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 130     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 131     # (Sorry, I don't know exactly what is the problem, but it is related to
 132     # floating point formatting and decimal point vs. comma.)
 133     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 134     # rigorous enough to notice, though.
 135     # So preset the autoconf cache variables.
 136     ac_cv_func_vsnprintf_c99=no
 137     ac_cv_func_snprintf_c99=no
 138     case "$host" in
 139     x86_64-*-*)
 140       LIB_EXE_MACHINE_FLAG=X64
 141       ;;
 142     esac
 143
 144     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 145     ;;
 146   *)
 147     glib_native_win32=no
 148     glib_pid_type=int
 149     ;;
 150 esac
 151 case $host in
 152   *-*-linux*)
 153     glib_os_linux=yes
 154     ;;
 155 esac
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158
 159 AC_MSG_CHECKING([for the Android])
 160 case $host in
 161   *android*)
 162     glib_native_android="yes"
 163     ;;
 164   *)
 165     glib_native_android="no"
 166     ;;
 167 esac
 168 AC_MSG_RESULT([$glib_native_android])
 169
 170 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 171
 172 glib_have_carbon=no
 173 AC_MSG_CHECKING([for Mac OS X Carbon support])
 174 AC_TRY_CPP([
 175 #include <Carbon/Carbon.h>
 176 #include <CoreServices/CoreServices.h>
 177 ], glib_have_carbon=yes)
 178
 179 AC_MSG_RESULT([$glib_have_carbon])
 180
 181 glib_have_cocoa=no
 182 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 183 AC_TRY_CPP([
 184 #include <Cocoa/Cocoa.h>
 185 #ifdef GNUSTEP_BASE_VERSION
 186 #error "Detected GNUstep, not Cocoa"
 187 #endif
 188 ], glib_have_cocoa=yes)
 189
 190 AC_MSG_RESULT([$glib_have_cocoa])
 191
 192 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 193 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 194 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 195 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 196 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 197 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 198
 199 AS_IF([test "$glib_native_win32" = "yes"], [
 200   AC_CHECK_TOOL(WINDRES, windres, no)
 201   if test "$WINDRES" = no; then
 202     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 203   fi
 204   AC_CHECK_TOOL(NM, nm, no)
 205   if test "$NM" = no; then
 206     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 207   fi
 208   AC_CHECK_TOOL(RANLIB, ranlib, :)
 209   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 210   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 211 ])
 212 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 213
 214 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 215   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 216   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 217 ])
 218
 219 if test "x$glib_have_cocoa" = "xyes"; then
 220   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 221   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 222 fi
 223
 224 dnl declare --enable-* args and collect ac_help strings
 225 AC_ARG_ENABLE(debug,
 226               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 227                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 228               enable_debug=glib_debug_default)
 229
 230 AC_ARG_ENABLE(gc_friendly,
 231               [AS_HELP_STRING([--enable-gc-friendly],
 232                               [turn on garbage collector friendliness [default=no]])],,
 233               [enable_gc_friendly=no])
 234 AC_ARG_ENABLE(mem_pools,
 235               [AS_HELP_STRING([--disable-mem-pools],
 236                               [disable all glib memory pools])],,
 237               [disable_mem_pools=no])
 238 AC_ARG_ENABLE(rebuilds,
 239               [AS_HELP_STRING([--disable-rebuilds],
 240                               [disable all source autogeneration rules])],,
 241               [enable_rebuilds=yes])
 242
 243 GLIB_TESTS
 244
 245 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 246 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 247   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 248   AC_MSG_RESULT([yes])
 249 ], [ AC_MSG_RESULT([no]) ])
 250
 251 AC_MSG_CHECKING([whether to disable memory pools])
 252 AS_IF([test "x$disable_mem_pools" = "xno"], [
 253   AC_MSG_RESULT([no])
 254 ], [
 255   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 256   AC_MSG_RESULT([yes])
 257 ])
 258
 259 dnl location to install runtime libraries, e.g. ../../lib to install
 260 dnl to /lib if libdir is /usr/lib
 261 AC_ARG_WITH(runtime-libdir,
 262            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 263                            [install runtime libraries relative to libdir])],
 264            [],
 265            [with_runtime_libdir=""])
 266 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 267 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 268 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 269 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 270 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 271
 272 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 273 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 274 AC_LANG_SAVE
 275 AC_LANG_CPLUSPLUS
 276 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 277 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 278 AC_LANG_RESTORE
 279
 280 AM_PROG_CC_C_O
 281 AC_PROG_INSTALL
 282
 283 AC_SYS_LARGEFILE
 284
 285 PKG_PROG_PKG_CONFIG(0.16)
 286
 287 if test "x$enable_debug" = "xyes"; then
 288   if test x$cflags_set != xset ; then
 289       case " $CFLAGS " in
 290       *[[\ \    ]]-g[[\ \       ]]*) ;;
 291       *) CFLAGS="$CFLAGS -g" ;;
 292       esac
 293   fi
 294   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 295 else
 296   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 297
 298   if test "x$enable_debug" = "xno"; then
 299     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 300   fi
 301 fi
 302
 303 # Ensure MSVC-compatible struct packing convention is used when
 304 # compiling for Win32 with gcc.
 305 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 306 # gcc2 uses "-fnative-struct".
 307 if test x"$glib_native_win32" = xyes; then
 308   if test x"$GCC" = xyes; then
 309     msnative_struct=''
 310     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 311     if test -z "$ac_cv_prog_CC"; then
 312       our_gcc="$CC"
 313     else
 314       our_gcc="$ac_cv_prog_CC"
 315     fi
 316     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 317       2.)
 318         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 319           msnative_struct='-fnative-struct'
 320         fi
 321         ;;
 322       *)
 323         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 324           msnative_struct='-mms-bitfields'
 325         fi
 326         ;;
 327     esac
 328     if test x"$msnative_struct" = x ; then
 329       AC_MSG_RESULT([no way])
 330       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 331     else
 332       CFLAGS="$CFLAGS $msnative_struct"
 333       AC_MSG_RESULT([${msnative_struct}])
 334     fi
 335   fi
 336 fi
 337 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 338 AC_SUBST(GLIB_EXTRA_CFLAGS)
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 fi
 362 if test "x$PERL_PATH" = x ; then
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 # option to specify python interpreter to use; this just sets $PYTHON, so that
 368 # we will fallback to reading $PYTHON if --with-python is not given, and
 369 # python.m4 will get the expected input
 370 AC_ARG_WITH(python,
 371             AS_HELP_STRING([--with-python=PATH],
 372                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 373             [PYTHON="$withval"], [])
 374 if test x"$PYTHON" = xyes; then
 375   AC_MSG_ERROR([--with-python option requires a path or program argument])
 376 fi
 377 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 378
 379
 380 dnl ***********************
 381 dnl *** Tests for iconv ***
 382 dnl ***********************
 383 dnl
 384 dnl We do this before the gettext checks, to avoid distortion
 385
 386 dnl On Windows we use a native implementation
 387
 388 AS_IF([ test x"$glib_native_win32" = xyes], [
 389   with_libiconv=native
 390 ], [
 391   AC_ARG_WITH(libiconv,
 392               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 393                               [use the libiconv library])],,
 394               [with_libiconv=maybe])
 395
 396   found_iconv=no
 397   case $with_libiconv in
 398     maybe)
 399       # Check in the C library first
 400       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 401       # Check if we have GNU libiconv
 402       if test $found_iconv = "no"; then
 403         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 404       fi
 405       # Check if we have a iconv in -liconv, possibly from vendor
 406       if test $found_iconv = "no"; then
 407         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 408       fi
 409       ;;
 410     no)
 411       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 412       ;;
 413     gnu|yes)
 414       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 415       ;;
 416     native)
 417       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 418       ;;
 419   esac
 420
 421   if test "x$found_iconv" = "xno" ; then
 422      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 423   fi
 424 ])
 425
 426 dnl
 427 dnl zlib support
 428 dnl
 429 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 430 AS_IF([test "x$found_zlib" = "xno"], [
 431   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 432   if test "x$found_zlib" = "xno" ; then
 433     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 434   fi
 435   ZLIB_LIBS='-lz'
 436   AC_SUBST(ZLIB_LIBS)
 437 ])
 438
 439 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 440 AC_SUBST(LIBFFI_CFLAGS)
 441 AC_SUBST(LIBFFI_LIBS)
 442
 443 dnl
 444 dnl gettext support
 445 dnl
 446
 447 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 448 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 449 GLIB_GNU_GETTEXT
 450
 451 if test "$gt_cv_have_gettext" != "yes" ; then
 452   AC_MSG_ERROR([
 453 *** You must have either have gettext support in your C library, or use the
 454 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 455 ])
 456 fi
 457
 458 LIBS="$INTLLIBS $LIBS"
 459
 460 GETTEXT_PACKAGE=glib20
 461 AC_SUBST(GETTEXT_PACKAGE)
 462 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 463   [Define the gettext package to be used])
 464
 465 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 466
 467 dnl
 468 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 469 dnl
 470
 471 AS_IF([test x"$glib_native_win32" != xyes], [
 472   if test x$with_libiconv != xno ; then
 473     case " $INTLLIBS " in
 474     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 475     *) ICONV_LIBS="-liconv" ;;
 476     esac
 477   fi
 478 ])
 479 AC_SUBST(ICONV_LIBS)
 480
 481 case $with_libiconv in
 482   gnu)
 483     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 484     ;;
 485   native)
 486     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 487     ;;
 488 esac
 489
 490 dnl Initialize libtool
 491 LT_PREREQ([2.2])
 492 LT_INIT([disable-static win32-dll])
 493 dnl when using libtool 2.x create libtool early, because it's used in configure
 494 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 495
 496
 497 AS_IF([test "$glib_native_win32" = "yes"], [
 498   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 499     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 500   fi
 501   if test x$enable_static = xyes; then
 502     glib_win32_static_compilation=yes
 503     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 504 #define GOBJECT_STATIC_COMPILATION 1"
 505     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 506   fi
 507 ])
 508 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 509
 510 dnl
 511 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 512 dnl
 513 AS_IF([test $cross_compiling != yes], [
 514     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 515     glib_save_LIBS=$LIBS
 516     LIBS="$LIBS -lm"
 517     AC_TRY_RUN([#include <math.h>
 518                  int main (void) { return (log(1) != log(1.)); }],
 519          AC_MSG_RESULT(none needed),
 520          glib_save_CFLAGS=$CFLAGS
 521          CFLAGS="$CFLAGS -std1"
 522          AC_TRY_RUN([#include <math.h>
 523                      int main (void) { return (log(1) != log(1.)); }],
 524              AC_MSG_RESULT(-std1),
 525              AC_MSG_RESULT()
 526              CFLAGS=$glib_save_CFLAGS
 527              AC_MSG_WARN(
 528                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 529          )
 530     )
 531     LIBS=$glib_save_LIBS
 532 ])
 533
 534 dnl NeXTStep cc seems to need this
 535 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 536 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 537   AC_MSG_RESULT(none needed),
 538   glib_save_CFLAGS=$CFLAGS
 539   CFLAGS="$CFLAGS -posix"
 540   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 541     AC_MSG_RESULT(-posix),
 542     AC_MSG_RESULT()
 543     CFLAGS=$glib_save_CFLAGS
 544     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 545
 546 # Checks for library functions.
 547 AC_FUNC_VPRINTF
 548 AC_FUNC_ALLOCA
 549 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 550 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 551
 552 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 553   [AC_TRY_LINK([#include <unistd.h>
 554     extern int __libc_enable_secure;],
 555     [return __libc_enable_secure;],
 556    glib_cv_have_libc_enable_secure=yes,
 557    glib_cv_have_libc_enable_secure=no)])
 558 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 559    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 560      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 561 ])
 562
 563 AC_CHECK_SIZEOF(char)
 564 AC_CHECK_SIZEOF(short)
 565 AC_CHECK_SIZEOF(long)
 566 AC_CHECK_SIZEOF(int)
 567 AC_CHECK_SIZEOF(void *)
 568 AC_CHECK_SIZEOF(long long)
 569 AC_CHECK_SIZEOF(__int64)
 570
 571 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 572   [AC_TRY_LINK([#include <signal.h>
 573      #include <sys/types.h>
 574      sig_atomic_t val = 42;],
 575     [return val == 42 ? 0 : 1],
 576    ac_cv_type_sig_atomic_t=yes,
 577    ac_cv_type_sig_atomic_t=no)])
 578 if test x$ac_cv_type_sig_atomic_t = xyes; then
 579    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 580      [Define if you have the 'sig_atomic_t' type.])
 581 fi
 582
 583 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 584   :
 585 else
 586   AC_MSG_ERROR([
 587 *** GLib requires a 64 bit type. You might want to consider
 588 *** using the GNU C compiler.
 589 ])
 590 fi
 591
 592 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 593         # long long is a 64 bit integer.
 594         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 595         AC_CACHE_VAL(glib_cv_long_long_format,[
 596                 for format in ll q I64; do
 597                   AC_TRY_RUN([#include <stdio.h>
 598                         int main()
 599                         {
 600                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 601                           char buffer[1000];
 602                           sprintf (buffer, "%${format}u", a);
 603                           sscanf (buffer, "%${format}u", &b);
 604                           exit (b!=a);
 605                         }
 606                         ],
 607                         [glib_cv_long_long_format=${format}
 608                         break],
 609                         [],[:])
 610                 done])
 611         AS_IF([ test -n "$glib_cv_long_long_format"], [
 612           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 613           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 614           if test x"$glib_cv_long_long_format" = xI64; then
 615             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 616           fi
 617         ], [AC_MSG_RESULT(none)])
 618 ],[ test x$ac_cv_sizeof___int64 = x8], [
 619         # __int64 is a 64 bit integer.
 620         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 621         # We know this is MSVCRT.DLL, and what the formats are
 622         glib_cv_long_long_format=I64
 623         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 624         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 625         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 626 ])
 627
 628 AC_C_CONST
 629
 630 dnl
 631 dnl check in which direction the stack grows
 632 dnl
 633 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 634         AC_TRY_RUN([
 635         volatile int *a = 0, *b = 0;
 636         void foo (void);
 637         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 638         void foo (void) { volatile int x = 5; b = &x; }
 639         ],
 640         glib_cv_stack_grows=no
 641         ,
 642         glib_cv_stack_grows=yes
 643         ,)
 644 ])
 645
 646 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 647 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 648 dnl actually supported.
 649 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 650         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 651         __inline int foo () { return 0; }
 652         int main () { return foo (); }
 653         ]])],
 654         glib_cv_has__inline=yes
 655         ,
 656         glib_cv_has__inline=no
 657         ,)
 658 ])
 659 case x$glib_cv_has__inline in
 660 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 661 esac
 662 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 663         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 664         __inline__ int foo () { return 0; }
 665         int main () { return foo (); }
 666         ]])],
 667         glib_cv_has__inline__=yes
 668         ,
 669         glib_cv_has__inline__=no
 670         ,)
 671 ])
 672 case x$glib_cv_has__inline__ in
 673 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 674 esac
 675 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 676         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 677         #undef inline
 678         inline int foo () { return 0; }
 679         int main () { return foo (); }
 680         ]])],
 681         glib_cv_hasinline=yes
 682         ,
 683         glib_cv_hasinline=no
 684         ,)
 685 ])
 686 case x$glib_cv_hasinline in
 687 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 688 esac
 689
 690 # if we can use inline functions in headers
 691 AC_MSG_CHECKING(if inline functions in headers work)
 692 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 693 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 694 #  undef inline
 695 #  define inline __inline__
 696 #elif !defined (G_HAVE_INLINE)
 697 #  undef inline
 698 #  if defined (G_HAVE___INLINE__)
 699 #    define inline __inline__
 700 #  elif defined (G_HAVE___INLINE)
 701 #    define inline __inline
 702 #  endif
 703 #endif
 704
 705 int glib_test_func2 (int);
 706
 707 static inline int
 708 glib_test_func1 (void) {
 709   return glib_test_func2 (1);
 710 }
 711
 712 int
 713 main (void) {
 714   int i = 1;
 715 }]])],[g_can_inline=yes],[g_can_inline=no])
 716 AC_MSG_RESULT($g_can_inline)
 717
 718 dnl *** check for working do while(0) macros ***
 719 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 720         AC_TRY_COMPILE([],[
 721         #define STMT_START do
 722         #define STMT_END while(0)
 723         #define STMT_TEST STMT_START { i = 0; } STMT_END
 724         int main(void) { int i = 1; STMT_TEST; return i; }],
 725         [g_cv_support_dowhile_macros=yes],
 726         [g_cv_support_dowhile_macros=no],
 727         [g_cv_support_dowhile_macros=yes])
 728 ])
 729 if test x$g_cv_support_dowhile_macros = xyes; then
 730   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 731 fi
 732
 733 # check for flavours of varargs macros
 734 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 735 AC_TRY_COMPILE([],[
 736 int a(int p1, int p2, int p3);
 737 #define call_a(...) a(1,__VA_ARGS__)
 738 call_a(2,3);
 739 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 740 AC_MSG_RESULT($g_have_iso_c_varargs)
 741
 742 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 743 AS_IF([test "$CXX" = ""], [
 744 dnl No C++ compiler
 745   g_have_iso_cxx_varargs=no
 746 else
 747   AC_LANG_CPLUSPLUS
 748   AC_TRY_COMPILE([],[
 749 int a(int p1, int p2, int p3);
 750 #define call_a(...) a(1,__VA_ARGS__)
 751 call_a(2,3);
 752 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 753   AC_LANG_C
 754 ])
 755 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 756
 757 AC_MSG_CHECKING(for GNUC varargs macros)
 758 AC_TRY_COMPILE([],[
 759 int a(int p1, int p2, int p3);
 760 #define call_a(params...) a(1,params)
 761 call_a(2,3);
 762 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 763 AC_MSG_RESULT($g_have_gnuc_varargs)
 764
 765 # check for GNUC visibility support
 766 AC_MSG_CHECKING(for GNUC visibility attribute)
 767 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 768 void
 769 __attribute__ ((visibility ("hidden")))
 770      f_hidden (void)
 771 {
 772 }
 773 void
 774 __attribute__ ((visibility ("internal")))
 775      f_internal (void)
 776 {
 777 }
 778 void
 779 __attribute__ ((visibility ("protected")))
 780      f_protected (void)
 781 {
 782 }
 783 void
 784 __attribute__ ((visibility ("default")))
 785      f_default (void)
 786 {
 787 }
 788 int main (void)
 789 {
 790         f_hidden();
 791         f_internal();
 792         f_protected();
 793         f_default();
 794         return 0;
 795 }
 796 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 797 AC_MSG_RESULT($g_have_gnuc_visibility)
 798 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 799
 800 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 801 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 802 #else
 803 # include "error: this is not Sun Studio."
 804 #endif
 805 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 806 AC_MSG_RESULT($g_have_sunstudio_visibility)
 807 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 808
 809 # check for bytesex stuff
 810 AC_C_BIGENDIAN
 811 if test x$ac_cv_c_bigendian = xuniversal ; then
 812 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 813 #else
 814 #error Not a big endian.
 815 #endif],
 816     ac_cv_c_bigendian=yes
 817     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 818 #else
 819 #error Not a little endian.
 820 #endif],
 821     ac_cv_c_bigendian=no
 822     ,AC_MSG_WARN([Could not determine endianness.])))
 823 fi
 824
 825
 826 # check for header files
 827 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 828 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 829 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 830 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 831 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 832 AC_CHECK_HEADERS([sys/uio.h])
 833 AC_CHECK_HEADERS([linux/magic.h])
 834 AC_CHECK_HEADERS([sys/prctl.h])
 835
 836 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 837 [#if HAVE_SYS_PARAM_H
 838  #include <sys/param.h>
 839  #endif
 840 ])
 841 AC_CHECK_FUNCS(sysctlbyname)
 842
 843 AC_HEADER_MAJOR
 844 AC_CHECK_HEADERS([xlocale.h])
 845
 846 # check for structure fields
 847 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 848 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 849 #include <sys/stat.h>
 850 #include <unistd.h>
 851 #ifdef HAVE_SYS_STATFS_H
 852 #include <sys/statfs.h>
 853 #endif
 854 #ifdef HAVE_SYS_PARAM_H
 855 #include <sys/param.h>
 856 #endif
 857 #ifdef HAVE_SYS_MOUNT_H
 858 #include <sys/mount.h>
 859 #endif])
 860 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 861 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 862 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 863 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 864
 865 AC_STRUCT_DIRENT_D_TYPE
 866
 867 # Checks for libcharset
 868 AM_LANGINFO_CODESET
 869 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 870 AC_CHECK_FUNCS(setlocale)
 871 gl_GLIBC21
 872
 873 # check additional type sizes
 874 AC_CHECK_SIZEOF(size_t)
 875
 876 dnl Try to figure out whether gsize should be long or int
 877 AC_MSG_CHECKING([for the appropriate definition for size_t])
 878
 879 case $ac_cv_sizeof_size_t in
 880   $ac_cv_sizeof_short)
 881       glib_size_type=short
 882       ;;
 883   $ac_cv_sizeof_int)
 884       glib_size_type=int
 885       ;;
 886   $ac_cv_sizeof_long)
 887       glib_size_type=long
 888       ;;
 889   $ac_cv_sizeof_long_long)
 890       glib_size_type='long long'
 891       ;;
 892   $ac_cv_sizeof__int64)
 893       glib_size_type='__int64'
 894       ;;
 895   *)  AC_MSG_ERROR([No type matching size_t in size])
 896       ;;
 897 esac
 898
 899 dnl If int/long are the same size, we see which one produces
 900 dnl warnings when used in the location as size_t. (This matters
 901 dnl on AIX with xlc)
 902 dnl
 903 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 904        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 905   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 906 #if defined(_AIX) && !defined(__GNUC__)
 907 #pragma options langlvl=stdc89
 908 #endif
 909 #include <stddef.h>
 910 int main ()
 911 {
 912   size_t s = 1;
 913   unsigned int *size_int = &s;
 914   return (int)*size_int;
 915 }
 916     ]])],glib_size_type=int,
 917       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 918 #if defined(_AIX) && !defined(__GNUC__)
 919 #pragma options langlvl=stdc89
 920 #endif
 921 #include <stddef.h>
 922 int main ()
 923 {
 924    size_t s = 1;
 925    unsigned long *size_long = &s;
 926    return (int)*size_long;
 927 }
 928         ]])],glib_size_type=long)])
 929 ])
 930
 931 AC_MSG_RESULT(unsigned $glib_size_type)
 932
 933 AC_CHECK_SIZEOF(ssize_t)
 934
 935 dnl Try to figure out whether gssize should be long or int
 936 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 937
 938 case $ac_cv_sizeof_ssize_t in
 939   $ac_cv_sizeof_short)
 940       glib_ssize_type=short
 941       ;;
 942   $ac_cv_sizeof_int)
 943       glib_ssize_type=int
 944       ;;
 945   $ac_cv_sizeof_long)
 946       glib_ssize_type=long
 947       ;;
 948   $ac_cv_sizeof_long_long)
 949       glib_ssize_type='long long'
 950       ;;
 951   $ac_cv_sizeof__int64)
 952       glib_ssize_type='__int64'
 953       ;;
 954   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 955       ;;
 956 esac
 957
 958 dnl If int/long are the same size, we see which one produces
 959 dnl warnings when used in the location as ssize_t. (This matters
 960 dnl on Android where ssize_t is long and size_t is unsigned int)
 961 dnl
 962 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 963        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 964   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 965 #if defined(_AIX) && !defined(__GNUC__)
 966 #pragma options langlvl=stdc89
 967 #endif
 968 #include <stddef.h>
 969 #ifdef HAVE_INTTYPES_H
 970 # include <inttypes.h>
 971 #endif
 972 #ifdef HAVE_STDINT_H
 973 # include <stdint.h>
 974 #endif
 975 #ifdef HAVE_UNISTD_H
 976 # include <unistd.h>
 977 #endif
 978 #ifdef HAVE_SYS_TYPES_H
 979 # include <sys/types.h>
 980 #endif
 981 int main ()
 982 {
 983   ssize_t s = 1;
 984   int *size_int = &s;
 985   return (int)*size_int;
 986 }
 987     ]])],glib_ssize_type=int,
 988       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 989 #if defined(_AIX) && !defined(__GNUC__)
 990 #pragma options langlvl=stdc89
 991 #endif
 992 #include <stddef.h>
 993 #ifdef HAVE_INTTYPES_H
 994 # include <inttypes.h>
 995 #endif
 996 #ifdef HAVE_STDINT_H
 997 # include <stdint.h>
 998 #endif
 999 #ifdef HAVE_UNISTD_H
1000 # include <unistd.h>
1001 #endif
1002 #ifdef HAVE_SYS_TYPES_H
1003 # include <sys/types.h>
1004 #endif
1005 int main ()
1006 {
1007    ssize_t s = 1;
1008    long *size_long = &s;
1009    return (int)*size_long;
1010 }
1011         ]])],glib_ssize_type=long)])
1012 ])
1013
1014 AC_MSG_RESULT($glib_ssize_type)
1015
1016 # Check for some functions
1017 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1018 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
1019 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
1020 # Check for high-resolution sleep functions
1021 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
1022 AC_CHECK_FUNCS(splice)
1023 AC_CHECK_FUNCS(prlimit)
1024
1025 # To avoid finding a compatibility unusable statfs, which typically
1026 # successfully compiles, but warns to use the newer statvfs interface:
1027 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1028 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1029
1030 AC_MSG_CHECKING([whether to use statfs or statvfs])
1031 # Some systems have both statfs and statvfs, pick the most "native" for these
1032 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1033    [
1034    # on solaris and irix, statfs doesn't even have the f_bavail field
1035    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1036       [ac_cv_func_statfs=no],
1037    # else, at least on linux, statfs is the actual syscall
1038       [ac_cv_func_statvfs=no])
1039    ])
1040
1041 AS_IF([test x$ac_cv_func_statfs = xyes],
1042       [
1043          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1044          AC_MSG_RESULT([statfs])
1045       ],
1046       [test x$ac_cv_func_statvfs = xyes],
1047       [
1048          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1049          AC_MSG_RESULT([statvfs])
1050       ],
1051       [  AC_MSG_RESULT([neither])])
1052
1053 AC_CHECK_HEADERS(crt_externs.h)
1054 AC_CHECK_FUNCS(_NSGetEnviron)
1055
1056 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1057
1058 AC_FUNC_VSNPRINTF_C99
1059 AC_FUNC_PRINTF_UNIX98
1060
1061 # Internet address families
1062 if test $glib_native_win32 = yes; then
1063   glib_inet_includes=["
1064 #include <winsock2.h>
1065   "]
1066 else
1067   glib_inet_includes=["
1068 #include <sys/types.h>
1069 #include <sys/socket.h>
1070   "]
1071 fi
1072
1073 glib_failed=false
1074 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1075 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1076 # winsock defines this even though it doesn't support it
1077 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1078 if $glib_failed ; then
1079   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1080 fi
1081
1082 glib_failed=false
1083 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1084 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1085 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1086 if $glib_failed ; then
1087   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1088 fi
1089
1090 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname)
1091
1092 AS_IF([test $glib_native_win32 = yes], [
1093   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1094   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1095   # they aren't present at run-time (on Windows 2000).
1096   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1097   AC_SUBST(WSPIAPI_INCLUDE)
1098 ], [
1099   # Android does not have C_IN in public headers, we define it wherever necessary
1100   AS_IF([test $glib_native_android != yes], [
1101     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1102     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1103                                         #include <arpa/nameser.h>],
1104                                        [int qclass = C_IN;])],
1105                       [AC_MSG_RESULT([no])],
1106                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1107                                                            #include <arpa/nameser.h>
1108                                                            #include <arpa/nameser_compat.h>],
1109                                                           [int qclass = C_IN;])],
1110                                          [AC_MSG_RESULT([yes])
1111                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1112                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1113   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1114
1115   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1116   NETWORK_LIBS=""
1117   AC_MSG_CHECKING([for res_query])
1118   AC_TRY_LINK([#include <sys/types.h>
1119                #include <netinet/in.h>
1120                #include <arpa/nameser.h>
1121                #include <resolv.h>
1122               ],[
1123                res_query("test", 0, 0, (void *)0, 0);
1124               ],[AC_MSG_RESULT([yes])],
1125               [save_libs="$LIBS"
1126                LIBS="-lresolv $LIBS"
1127                AC_TRY_LINK([#include <sys/types.h>
1128                             #include <netinet/in.h>
1129                             #include <arpa/nameser.h>
1130                             #include <resolv.h>
1131                            ],[
1132                             res_query("test", 0, 0, (void *)0, 0);
1133                            ],[AC_MSG_RESULT([in -lresolv])
1134                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1135                            [LIBS="-lbind $save_libs"
1136                             AC_TRY_LINK([#include <resolv.h>],
1137                                         [res_query("test", 0, 0, (void *)0, 0);],
1138                                         [AC_MSG_RESULT([in -lbind])
1139                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1140                                         [AC_MSG_ERROR(not found)])])
1141                LIBS="$save_libs"])
1142   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1143                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1144                                         [AC_MSG_ERROR(Could not find socket())]))
1145   save_libs="$LIBS"
1146   LIBS="$LIBS $NETWORK_LIBS"
1147   AC_MSG_CHECKING([for res_init])
1148   AC_TRY_LINK([#include <sys/types.h>
1149                #include <netinet/in.h>
1150                #include <arpa/nameser.h>
1151                #include <resolv.h>
1152               ],[
1153                res_init();
1154               ],[AC_MSG_RESULT([yes])
1155                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1156               ],[AC_MSG_RESULT([no])])
1157   LIBS="$save_libs"
1158 ])
1159 AC_SUBST(NETWORK_LIBS)
1160
1161 AC_CHECK_HEADER([linux/netlink.h],
1162                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1163                 [#include <sys/socket.h>])
1164 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1165
1166 AC_CHECK_TYPE([struct ip_mreqn], [
1167               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1168               [#include <netinet/in.h>])
1169
1170 case $host in
1171   *-*-solaris* )
1172      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1173      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1174      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1175      ;;
1176 esac
1177
1178 dnl
1179 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1180 dnl
1181 AS_IF([test "$ac_cv_func_statfs" = yes], [
1182   AC_MSG_CHECKING([number of arguments to statfs()])
1183   AC_TRY_COMPILE([#include <unistd.h>
1184   #ifdef HAVE_SYS_PARAM_H
1185   #include <sys/param.h>
1186   #endif
1187   #ifdef HAVE_SYS_VFS_H
1188   #include <sys/vfs.h>
1189   #endif
1190   #ifdef HAVE_SYS_MOUNT_H
1191   #include <sys/mount.h>
1192   #endif
1193   #ifdef HAVE_SYS_STATFS_H
1194   #include <sys/statfs.h>
1195   #endif], [struct statfs st;
1196   statfs(NULL, &st);],[
1197     AC_MSG_RESULT([2])
1198     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1199     AC_TRY_COMPILE([#include <unistd.h>
1200   #ifdef HAVE_SYS_PARAM_H
1201   #include <sys/param.h>
1202   #endif
1203   #ifdef HAVE_SYS_VFS_H
1204   #include <sys/vfs.h>
1205   #endif
1206   #ifdef HAVE_SYS_MOUNT_H
1207   #include <sys/mount.h>
1208   #endif
1209   #ifdef HAVE_SYS_STATFS_H
1210   #include <sys/statfs.h>
1211   #endif], [struct statfs st;
1212   statfs(NULL, &st, sizeof (st), 0);],[
1213       AC_MSG_RESULT([4])
1214       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1215       AC_MSG_RESULT(unknown)
1216       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1217 ])
1218
1219 dnl
1220 dnl open takes O_DIRECTORY as an option
1221 dnl
1222 AC_MSG_CHECKING([open() option O_DIRECTORY])
1223 AC_TRY_COMPILE([#include <fcntl.h>
1224 #include <sys/types.h>
1225 #include <sys/stat.h>],
1226 [open(0, O_DIRECTORY, 0);],[
1227         AC_MSG_RESULT([yes])
1228         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1229         AC_MSG_RESULT([no])])
1230
1231 #
1232 # Check whether to use an included printf
1233 #
1234
1235 AC_ARG_ENABLE(included-printf,
1236               [AS_HELP_STRING([--enable-included-printf],
1237                               [use included printf [default=auto]])],
1238               enable_included_printf="$enableval")
1239
1240 need_included_printf=no
1241 if test "x$enable_included_printf" = "xyes" ; then
1242   need_included_printf=yes
1243 fi
1244 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1245   need_included_printf=yes
1246 fi
1247 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1248   need_included_printf=yes
1249 fi
1250 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1251    test -z "$glib_cv_long_long_format" ; then
1252   need_included_printf=yes
1253 fi
1254
1255 if test "x$enable_included_printf" = "xno" &&
1256    test "x$need_included_printf" = "xyes" ; then
1257   AC_MSG_ERROR([
1258 *** Your C library's printf doesn't appear to have the features that
1259 *** GLib needs, but you specified --enable-included-printf=no.])
1260 fi
1261
1262 enable_included_printf=$need_included_printf
1263
1264 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1265 AS_IF([test "$enable_included_printf" != "yes"], [
1266   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1267 ], [
1268   if test -z "$glib_cv_long_long_format" ; then
1269     glib_cv_long_long_format="ll"
1270   fi
1271   AC_DEFINE(HAVE_VASPRINTF,1)
1272 ])
1273
1274 # Checks needed for gnulib vasnprintf
1275 bh_C_SIGNED
1276 jm_AC_TYPE_LONG_LONG
1277 gt_TYPE_LONGDOUBLE
1278 gt_TYPE_WCHAR_T
1279 gt_TYPE_WINT_T
1280 AC_TYPE_SIZE_T
1281 AC_CHECK_TYPES(ptrdiff_t)
1282 jm_AC_TYPE_INTMAX_T
1283 AC_CHECK_FUNCS([snprintf wcslen])
1284 AC_FUNC_SNPRINTF_C99
1285
1286 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1287 # The check is borrowed from the PERL Configure script.
1288 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1289   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1290     glib_cv_working_bcopy,[AC_TRY_RUN([
1291       int main() {
1292         char buf[128], abc[128], *b;
1293         int len, off, align;
1294         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1295         for (align = 7; align >= 0; align--) {
1296           for (len = 36; len; len--) {
1297             b = buf+align; bcopy(abc, b, len);
1298             for (off = 1; off <= len; off++) {
1299               bcopy(b, b+off, len); bcopy(b+off, b, len);
1300                 if (bcmp(b, abc, len)) return(1);
1301             }
1302           }
1303         }
1304         return(0);
1305       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1306
1307   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1308   if test "$glib_cv_working_bcopy" = "yes"; then
1309     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1310   fi
1311 ])
1312
1313 # Check if <sys/select.h> needs to be included for fd_set
1314 AC_MSG_CHECKING([for fd_set])
1315 AC_TRY_COMPILE([#include <sys/types.h>],
1316         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1317 AS_IF([test "$gtk_ok" = "yes"], [
1318     AC_MSG_RESULT([yes, found in sys/types.h])
1319 ], [
1320     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1321     if test "$gtk_ok" = "yes"; then
1322         # *** FIXME: give it a different name
1323         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1324         AC_MSG_RESULT([yes, found in sys/select.h])
1325     else
1326         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1327         AC_MSG_RESULT(no)
1328     fi
1329 ])
1330
1331 dnl Check for nl_langinfo and CODESET
1332 AC_LANG_SAVE
1333 AC_LANG_C
1334 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1335         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1336                        [char *codeset = nl_langinfo (CODESET);])],
1337                 [glib_cv_langinfo_codeset=yes],
1338                 [glib_cv_langinfo_codeset=no])])
1339 if test x$glib_cv_langinfo_codeset = xyes; then
1340   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1341 fi
1342
1343 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1344 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1345         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1346                  [char *str;
1347                  str = nl_langinfo (PM_STR);
1348                  str = nl_langinfo (D_T_FMT);
1349                  str = nl_langinfo (D_FMT);
1350                  str = nl_langinfo (T_FMT);
1351                  str = nl_langinfo (T_FMT_AMPM);
1352                  str = nl_langinfo (MON_1);
1353                  str = nl_langinfo (ABMON_12);
1354                  str = nl_langinfo (DAY_1);
1355                  str = nl_langinfo (ABDAY_7);])],
1356                 [glib_cv_langinfo_time=yes],
1357                 [glib_cv_langinfo_time=no])])
1358 if test x$glib_cv_langinfo_time = xyes; then
1359   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1360 fi
1361
1362 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1363 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1364         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1365                 [char *str;
1366                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1367                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1368                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1369                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1370                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1371                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1372                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1373                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1374                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1375                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1376                 [glib_cv_langinfo_outdigit=yes],
1377                 [glib_cv_langinfo_outdigit=no])])
1378 if test x$glib_cv_langinfo_outdigit = xyes; then
1379   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1380 fi
1381 AC_LANG_RESTORE
1382
1383 dnl ****************************************
1384 dnl *** posix_memalign                   ***
1385 dnl ****************************************
1386 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1387 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1388     glib_cv_compliant_posix_memalign=0
1389     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1390         AC_TRY_RUN([
1391                 #define _XOPEN_SOURCE 600
1392                 #include <stdlib.h> /* posix_memalign() should be defined here */
1393                 /* some systems break if #include <malloc.h> used */
1394                 static void test_memalign (size_t boundary, size_t size) {
1395                     void *mem = 0;
1396                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1397                         exit (1);
1398                     else
1399                       free (mem);
1400                 }
1401                 int main() {
1402                     test_memalign (  128,   128 - 2 * sizeof (void*));
1403                     test_memalign (  256,   256 - 2 * sizeof (void*));
1404                     test_memalign (  512,   512 - 2 * sizeof (void*));
1405                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1406                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1407                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1408                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1409                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1410                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1411                     exit (0); /* success */
1412                 }
1413                 ],
1414             [glib_cv_compliant_posix_memalign=1], [], [:])
1415       :
1416     fi
1417     ])
1418 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1419     AC_MSG_RESULT(yes)
1420     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1421 ], [
1422     AC_MSG_RESULT(no)
1423 ])
1424
1425
1426 dnl ****************************************
1427 dnl *** strlcpy/strlcat                  ***
1428 dnl ****************************************
1429 # Check for strlcpy
1430 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1431 AC_TRY_RUN([#include <stdlib.h>
1432 #include <string.h>
1433 int main() {
1434   char p[10];
1435   (void) strlcpy (p, "hi", 10);
1436   if (strlcat (p, "bye", 0) != 3)
1437     return 1;
1438   return 0;
1439 }], glib_cv_have_strlcpy=yes,
1440     glib_cv_have_strlcpy=no,
1441     glib_cv_have_strlcpy=no)])
1442 if test "$glib_cv_have_strlcpy" = "yes"; then
1443     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1444 fi
1445
1446
1447 dnl **********************
1448 dnl *** va_copy checks ***
1449 dnl **********************
1450 dnl we currently check for all three va_copy possibilities, so we get
1451 dnl all results in config.log for bug reports.
1452 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1453         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1454 #include <stdlib.h>
1455         void f (int i, ...) {
1456         va_list args1, args2;
1457         va_start (args1, i);
1458         va_copy (args2, args1);
1459         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1460           exit (1);
1461         va_end (args1); va_end (args2);
1462         }
1463         int main() {
1464           f (0, 42);
1465           return 0;
1466         }]])],
1467         [glib_cv_va_copy=yes],
1468         [glib_cv_va_copy=no])
1469 ])
1470 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1471         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1472 #include <stdlib.h>
1473         void f (int i, ...) {
1474         va_list args1, args2;
1475         va_start (args1, i);
1476         __va_copy (args2, args1);
1477         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1478           exit (1);
1479         va_end (args1); va_end (args2);
1480         }
1481         int main() {
1482           f (0, 42);
1483           return 0;
1484         }]])],
1485         [glib_cv___va_copy=yes],
1486         [glib_cv___va_copy=no])
1487 ])
1488
1489 if test "x$glib_cv_va_copy" = "xyes"; then
1490   g_va_copy_func=va_copy
1491 else if test "x$glib_cv___va_copy" = "xyes"; then
1492   g_va_copy_func=__va_copy
1493 fi
1494 fi
1495
1496 if test -n "$g_va_copy_func"; then
1497   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1498 fi
1499
1500 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1501         AC_TRY_RUN([#include <stdarg.h>
1502 #include <stdlib.h>
1503         void f (int i, ...) {
1504         va_list args1, args2;
1505         va_start (args1, i);
1506         args2 = args1;
1507         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1508           exit (1);
1509         va_end (args1); va_end (args2);
1510         }
1511         int main() {
1512           f (0, 42);
1513           return 0;
1514         }],
1515         [glib_cv_va_val_copy=yes],
1516         [glib_cv_va_val_copy=no],
1517         [glib_cv_va_val_copy=yes])
1518 ])
1519
1520 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1521   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1522 ])
1523
1524 dnl ***********************
1525 dnl *** g_module checks ***
1526 dnl ***********************
1527 G_MODULE_LIBS=
1528 G_MODULE_LIBS_EXTRA=
1529 G_MODULE_PLUGIN_LIBS=
1530 if test x"$glib_native_win32" = xyes; then
1531   dnl No use for this on Win32
1532   G_MODULE_LDFLAGS=
1533 else
1534   export SED
1535   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1536 fi
1537 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1538 G_MODULE_NEED_USCORE=0
1539 G_MODULE_BROKEN_RTLD_GLOBAL=0
1540 G_MODULE_HAVE_DLERROR=0
1541 dnl *** force native WIN32 shared lib loader
1542 if test -z "$G_MODULE_IMPL"; then
1543   case "$host" in
1544   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1545   esac
1546 fi
1547 dnl *** force native AIX library loader
1548 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1549 if test -z "$G_MODULE_IMPL"; then
1550   case "$host" in
1551   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1552   esac
1553 fi
1554 dnl *** dlopen() and dlsym() in system libraries
1555 AS_IF([ test -z "$G_MODULE_IMPL"], [
1556         AC_CHECK_FUNC(dlopen,
1557                       [AC_CHECK_FUNC(dlsym,
1558                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1559                       [])
1560 ])
1561 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1562 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1563         AC_CHECK_FUNC(NSLinkModule,
1564                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1565                        G_MODULE_NEED_USCORE=1],
1566                       [])
1567 ])
1568 dnl *** dlopen() and dlsym() in libdl
1569 AS_IF([ test -z "$G_MODULE_IMPL"], [
1570         AC_CHECK_LIB(dl, dlopen,
1571                      [AC_CHECK_LIB(dl, dlsym,
1572                                    [G_MODULE_LIBS=-ldl
1573                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1574                      [])
1575 ])
1576 dnl *** shl_load() in libdld (HP-UX)
1577 AS_IF([ test -z "$G_MODULE_IMPL"], [
1578         AC_CHECK_LIB(dld, shl_load,
1579                 [G_MODULE_LIBS=-ldld
1580                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1581                 [])
1582 ])
1583 dnl *** additional checks for G_MODULE_IMPL_DL
1584 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1585         LIBS_orig="$LIBS"
1586         LDFLAGS_orig="$LDFLAGS"
1587         LIBS="$G_MODULE_LIBS $LIBS"
1588         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1589 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1590         echo "void glib_plugin_test(void) { }" > plugin.c
1591         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1592                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1593         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1594                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1595                 -shrext ".o" -avoid-version plugin.lo \
1596                 -rpath /dont/care >/dev/null 2>&1
1597         eval `./libtool --config | grep ^objdir`
1598         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1599                 glib_cv_rtldglobal_broken,[
1600                 AC_TRY_RUN([
1601 #include <dlfcn.h>
1602 #ifndef RTLD_GLOBAL
1603 #  define RTLD_GLOBAL 0
1604 #endif
1605 #ifndef RTLD_LAZY
1606 #  define RTLD_LAZY 0
1607 #endif
1608 int glib_plugin_test;
1609 int main () {
1610     void *handle, *global, *local;
1611     global = &glib_plugin_test;
1612     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1613     if (!handle) return 0;
1614     local = dlsym (handle, "glib_plugin_test");
1615     return global == local;
1616 }                       ],
1617                         [glib_cv_rtldglobal_broken=no],
1618                         [glib_cv_rtldglobal_broken=yes],
1619                         [glib_cv_rtldglobal_broken=no])
1620                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1621                 rmdir ${objdir} 2>/dev/null
1622         ])
1623         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1624                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1625         else
1626                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1627         fi
1628 dnl *** check whether we need preceeding underscores
1629         AC_CACHE_CHECK([for preceeding underscore in symbols],
1630                 glib_cv_uscore,[
1631                 AC_TRY_RUN([#include <dlfcn.h>
1632                 int glib_underscore_test (void) { return 42; }
1633                 int main() {
1634                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1635                   handle = dlopen ((void*)0, 0);
1636                   if (handle) {
1637                     f1 = dlsym (handle, "glib_underscore_test");
1638                     f2 = dlsym (handle, "_glib_underscore_test");
1639                   } return (!f2 || f1);
1640                 }],
1641                         [glib_cv_uscore=yes],
1642                         [glib_cv_uscore=no],
1643                         [])
1644                 rm -f plugin.c plugin.$ac_objext plugin.lo
1645         ])
1646         GLIB_ASSERT_SET(glib_cv_uscore)
1647         if test "x$glib_cv_uscore" = "xyes"; then
1648                 G_MODULE_NEED_USCORE=1
1649         else
1650                 G_MODULE_NEED_USCORE=0
1651         fi
1652
1653         LDFLAGS="$LDFLAGS_orig"
1654 dnl *** check for having dlerror()
1655         AC_CHECK_FUNC(dlerror,
1656                 [G_MODULE_HAVE_DLERROR=1],
1657                 [G_MODULE_HAVE_DLERROR=0])
1658         LIBS="$LIBS_orig"
1659 ])
1660 dnl *** done, have we got an implementation?
1661 if test -z "$G_MODULE_IMPL"; then
1662         G_MODULE_IMPL=0
1663         G_MODULE_SUPPORTED=false
1664 else
1665         G_MODULE_SUPPORTED=true
1666 fi
1667
1668 AC_MSG_CHECKING(for the suffix of module shared libraries)
1669 export SED
1670 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1671 eval $shrext_cmds
1672 module=yes eval std_shrext=$shrext_cmds
1673 # chop the initial dot
1674 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1675 AC_MSG_RESULT(.$glib_gmodule_suffix)
1676 # any reason it may fail?
1677 if test "x$glib_gmodule_suffix" = x; then
1678         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1679 fi
1680
1681 AC_SUBST(G_MODULE_SUPPORTED)
1682 AC_SUBST(G_MODULE_IMPL)
1683 AC_SUBST(G_MODULE_LIBS)
1684 AC_SUBST(G_MODULE_LIBS_EXTRA)
1685 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1686 AC_SUBST(G_MODULE_LDFLAGS)
1687 AC_SUBST(G_MODULE_HAVE_DLERROR)
1688 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1689 AC_SUBST(G_MODULE_NEED_USCORE)
1690 AC_SUBST(GLIB_DEBUG_FLAGS)
1691
1692 dnl **********************
1693 dnl *** g_spawn checks ***
1694 dnl **********************
1695
1696 AC_MSG_CHECKING(for gspawn implementation)
1697 case "$host" in
1698   *-*-mingw*)
1699     GSPAWN=gspawn-win32.lo
1700     ;;
1701   *)
1702     GSPAWN=gspawn.lo
1703     ;;
1704 esac
1705 AC_MSG_RESULT($GSPAWN)
1706 AC_SUBST(GSPAWN)
1707
1708 dnl *************************
1709 dnl *** GIOChannel checks ***
1710 dnl *************************
1711
1712 AC_MSG_CHECKING(for GIOChannel implementation)
1713 case "$host" in
1714   *-*-mingw*)
1715     GIO=giowin32.lo
1716     ;;
1717   *)
1718     GIO=giounix.lo
1719     ;;
1720 esac
1721 AC_MSG_RESULT($GIO)
1722 AC_SUBST(GIO)
1723
1724 dnl *********************************
1725 dnl *** Directory for GIO modules ***
1726 dnl *********************************
1727
1728 AC_ARG_WITH(gio-module-dir,
1729            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1730                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1731            [],
1732            [with_gio_module_dir='${libdir}/gio/modules'])
1733 GIO_MODULE_DIR=$with_gio_module_dir
1734 AC_SUBST(GIO_MODULE_DIR)
1735
1736 dnl **********************************
1737 dnl *** Check for libselinux (GIO) ***
1738 dnl **********************************
1739 AC_ARG_ENABLE(selinux,
1740               AS_HELP_STRING([--disable-selinux],
1741                              [build without selinux support]))
1742 msg_selinux=no
1743 SELINUX_LIBS=
1744 AS_IF([ test "x$enable_selinux" != "xno"], [
1745
1746  AC_CHECK_LIB(selinux, is_selinux_enabled,
1747    [AC_CHECK_HEADERS(selinux/selinux.h,
1748      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1749        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1750         SELINUX_LIBS="-lselinux"
1751         msg_selinux=yes])
1752      ])
1753    ])
1754 ])
1755 AC_SUBST(SELINUX_LIBS)
1756
1757 dnl *****************************
1758 dnl ** Check for inotify (GIO) **
1759 dnl *****************************
1760 inotify_support=no
1761 AC_CHECK_HEADERS([sys/inotify.h],
1762 [
1763         inotify_support=yes
1764         AC_CHECK_FUNCS(inotify_init1)
1765 ])
1766
1767 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1768
1769 dnl ****************************
1770 dnl ** Check for kqueue (GIO) **
1771 dnl ****************************
1772 kqueue_support=no
1773 AC_CHECK_HEADERS([sys/event.h],
1774 [
1775         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1776 ])
1777
1778 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1779
1780 dnl *********************************
1781 dnl ** Check for Solaris FEN (GIO) **
1782 dnl *********************************
1783 fen_support=no
1784 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1785 #include <port.h>
1786 #ifndef PORT_SOURCE_FILE
1787 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1788 #endif
1789 int main() { return 0; } ]])],
1790 [
1791         fen_support=yes
1792 ],)
1793
1794 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1795
1796 dnl ****************************
1797 dnl *** Checks for FAM (GIO) ***
1798 dnl ****************************
1799
1800 should_disable_fam=no
1801
1802 AC_ARG_ENABLE(fam,
1803               AS_HELP_STRING([--disable-fam],
1804                              [don't use fam for file system monitoring]),
1805                          [
1806                                 if test "x$enable_fam" = "xno"; then
1807                                         should_disable_fam=yes
1808                                 fi
1809                          ]
1810                          )
1811 fam_support=no
1812 FAM_LIBS=
1813 if test "x$should_disable_fam" = "xno"; then
1814 AC_CHECK_LIB(fam, FAMOpen,
1815   [AC_CHECK_HEADERS(fam.h,
1816     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1817      AC_CHECK_LIB(fam, FAMNoExists,
1818                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1819      FAM_LIBS="-lfam"]
1820      fam_support=yes,
1821     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1822   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1823 AC_SUBST(FAM_LIBS)
1824 fi
1825 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1826
1827
1828 dnl *****************************
1829 dnl *** Check for xattr (GIO) ***
1830 dnl *****************************
1831 AC_ARG_ENABLE(xattr,
1832               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1833 msg_xattr=no
1834 XATTR_LIBS=
1835 AS_IF([ test "x$enable_xattr" != "xno"], [
1836
1837 dnl either glibc or libattr can provide xattr support
1838
1839 dnl for both of them, we check for getxattr being in
1840 dnl the library and a valid xattr header.
1841
1842 dnl try glibc
1843  AC_CHECK_LIB(c, getxattr,
1844    [AC_CHECK_HEADERS(sys/xattr.h,
1845      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1846       msg_xattr=yes])
1847    ])
1848
1849   AS_IF([ test "x$msg_xattr" != "xyes"], [
1850 dnl   failure. try libattr
1851    AC_CHECK_LIB(attr, getxattr,
1852       [AC_CHECK_HEADERS(attr/xattr.h,
1853        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1854         XATTR_LIBS="-lattr"
1855         msg_xattr=yes])
1856       ])
1857   ])
1858
1859   AS_IF([ test "x$msg_xattr" = "xyes"], [
1860     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1861     AC_TRY_COMPILE([
1862       #include <stdio.h>
1863       #ifdef HAVE_SYS_TYPES_H
1864       #include <sys/types.h>
1865       #endif
1866       #ifdef HAVE_SYS_XATTR_H
1867       #include <sys/xattr.h>
1868       #elif HAVE_ATTR_XATTR_H
1869       #include <attr/xattr.h>
1870       #endif
1871     ],
1872     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1873     [
1874       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1875       AC_MSG_RESULT([yes])
1876     ],
1877     [AC_MSG_RESULT([no])]
1878     )
1879   ])
1880 ])
1881 AC_SUBST(XATTR_LIBS)
1882
1883 dnl ************************
1884 dnl *** check for libelf ***
1885 dnl ************************
1886 AC_ARG_ENABLE(libelf,
1887               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1888 AS_IF([ test "x$enable_libelf" != "xno"],[
1889 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1890 AS_IF([ test $have_libelf = maybe ], [
1891   glib_save_LIBS=$LIBS
1892   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1893   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1894   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1895   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1896   LIBS=$glib_save_LIBS
1897
1898   if test $have_libelf != no; then
1899     LIBELF_LIBS=-lelf
1900     have_libelf=yes
1901   fi
1902 ])
1903 ])
1904
1905 if test x$have_libelf = xyes; then
1906   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1907 fi
1908
1909 dnl ****************************************
1910 dnl *** platform dependent source checks ***
1911 dnl ****************************************
1912
1913 AC_MSG_CHECKING(for platform-dependent source)
1914 case "$host" in
1915   *-*-cygwin*|*-*-mingw*)
1916     PLATFORMDEP=gwin32.lo
1917     ;;
1918   *)
1919     PLATFORMDEP=
1920     ;;
1921 esac
1922 AC_MSG_RESULT($PLATFORMDEP)
1923 AC_SUBST(PLATFORMDEP)
1924
1925 AC_MSG_CHECKING([whether to compile timeloop])
1926 case "$host" in
1927   *-*-cygwin*|*-*-mingw*|*-*-minix)
1928     enable_timeloop=no
1929     ;;
1930   *)
1931     enable_timeloop=yes
1932     ;;
1933 esac
1934 AC_MSG_RESULT($enable_timeloop)
1935 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1936
1937 AC_MSG_CHECKING([if building for some Win32 platform])
1938 case "$host" in
1939   *-*-mingw*|*-*-cygwin*)
1940     platform_win32=yes
1941     ;;
1942   *)
1943     platform_win32=no
1944     ;;
1945 esac
1946 AC_MSG_RESULT($platform_win32)
1947 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1948
1949 dnl ***********************
1950 dnl *** g_thread checks ***
1951 dnl ***********************
1952
1953 AC_ARG_WITH(threads,
1954            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1955                            [specify a thread implementation to use])],
1956            [],
1957            [with_threads=yes])
1958
1959 dnl error and warning message
1960 dnl *************************
1961
1962 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1963
1964 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1965                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1966                 compilation now, but then your programs might not work.
1967                 Please provide information on how it is done on your system."
1968
1969 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1970                  "
1971
1972 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1973                   provide information on your thread implementation."
1974
1975 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1976                 functions will not be MT-safe during their first call because
1977                 there is no working 'getpwuid_r' on your system."
1978
1979 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1980                 because there is no 'localtime_r' on your system."
1981
1982 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1983                 linking threaded applications. As GLib cannot do that
1984                 automatically, you will get an linkg error everytime you are
1985                 not using the right compiler. In that case you have to relink
1986                 with the right compiler. Ususally just '_r' is appended
1987                 to the compiler name."
1988
1989 dnl determination of thread implementation
1990 dnl ***************************************
1991
1992 AC_MSG_CHECKING(for thread implementation)
1993
1994 have_threads=no
1995 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1996         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1997         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1998         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1999         glib_save_CPPFLAGS="$CPPFLAGS"
2000         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2001         AS_IF([ test "x$have_threads" = xno], [
2002                 AC_TRY_COMPILE([#include <pthread.h>],
2003                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2004                         have_threads=posix)
2005         ])
2006         # Tru64Unix requires -pthread to find pthread.h. See #103020
2007         CPPFLAGS="$CPPFLAGS -pthread"
2008         if test "x$have_threads" = xno; then
2009         AC_TRY_COMPILE([#include <pthread.h>],
2010                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2011                        have_threads=posix)
2012         fi
2013         CPPFLAGS="$glib_save_CPPFLAGS"
2014 ])
2015 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
2016         case $host in
2017                 *-*-mingw*)
2018                 have_threads=win32
2019                 ;;
2020         esac
2021 fi
2022
2023 if test "x$have_threads" = xno; then
2024         AC_MSG_RESULT(none available)
2025         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
2026 else
2027         AC_MSG_RESULT($have_threads)
2028 fi
2029
2030
2031 dnl determination of G_THREAD_CFLAGS
2032 dnl ********************************
2033
2034 G_THREAD_LIBS=
2035 G_THREAD_LIBS_EXTRA=
2036 G_THREAD_CFLAGS=
2037
2038 dnl
2039 dnl Test program for basic POSIX threads functionality
2040 dnl
2041 m4_define([glib_thread_test],[
2042 #include <pthread.h>
2043 int check_me = 0;
2044 void* func(void* data) {check_me = 42; return &check_me;}
2045 int main()
2046  { pthread_t t;
2047    void *ret;
2048    pthread_create (&t, $1, func, 0);
2049    pthread_join (t, &ret);
2050    return (check_me != 42 || ret != &check_me);
2051 }])
2052
2053 AS_IF([ test x"$have_threads" = xposix], [
2054   # First we test for posix, whether -pthread or -pthreads do the trick as
2055   # both CPPFLAG and LIBS.
2056   # One of them does for most gcc versions and some other platforms/compilers
2057   # too and could be considered as the canonical way to go.
2058   case $host in
2059     *-*-cygwin*|*-*-darwin*)
2060        # skip cygwin and darwin -pthread or -pthreads test
2061        ;;
2062     *-solaris*)
2063       # These compiler/linker flags work with both Sun Studio and gcc
2064       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2065       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2066       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2067       G_THREAD_LIBS="-lpthread -lthread"
2068       ;;
2069     *)
2070       for flag in pthread pthreads mt; do
2071         glib_save_CFLAGS="$CFLAGS"
2072         CFLAGS="$CFLAGS -$flag"
2073         AC_TRY_RUN(glib_thread_test(0),
2074                    glib_flag_works=yes,
2075                    glib_flag_works=no,
2076                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2077                                    glib_flag_works=yes,
2078                                    glib_flag_works=no)])
2079         CFLAGS="$glib_save_CFLAGS"
2080         if test $glib_flag_works = yes ; then
2081            G_THREAD_CFLAGS=-$flag
2082         G_THREAD_LIBS=-$flag
2083         break;
2084         fi
2085       done
2086        ;;
2087   esac
2088 ])
2089
2090 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2091
2092   # The canonical -pthread[s] does not work. Try something different.
2093
2094   case $host in
2095         *-aix*)
2096                 if test x"$GCC" = xyes; then
2097                         # GCC 3.0 and above needs -pthread.
2098                         # Should be coverd by the case above.
2099                         # GCC 2.x and below needs -mthreads
2100                         G_THREAD_CFLAGS="-mthreads"
2101                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2102                 else
2103                         # We are probably using the aix compiler. Normaly a
2104                         # program would have to be compiled with the _r variant
2105                         # of the corresponding compiler, but we as GLib cannot
2106                         # do that: but the good news is that for compiling the
2107                         # only difference is the added -D_THREAD_SAFE compile
2108                         # option. This is according to the "C for AIX User's
2109                         # Guide".
2110                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2111                 fi
2112                 ;;
2113         *-dg-dgux*)  # DG/UX
2114                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2115                 ;;
2116         *-sysv5uw7*) # UnixWare 7
2117                 # We are not using gcc with -pthread. Catched above.
2118                 G_THREAD_CFLAGS="-Kthread"
2119                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2120                 ;;
2121         *-mingw*)
2122                 # No flag needed when using MSVCRT.DLL
2123                 G_THREAD_CFLAGS=""
2124                 ;;
2125         *)
2126                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2127                 ;;
2128   esac
2129 ])
2130
2131 # if we are not finding the localtime_r function, then we probably are
2132 # not using the proper multithread flag
2133
2134 glib_save_CPPFLAGS="$CPPFLAGS"
2135 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2136
2137 # First we test, whether localtime_r is declared in time.h
2138 # directly. Then we test whether a macro localtime_r exists, in
2139 # which case localtime_r in the test program is replaced and thus
2140 # if we still find localtime_r in the output, it is not defined as
2141 # a macro.
2142
2143 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2144   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2145                                                            localtime_r(a,b)],
2146                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2147
2148 CPPFLAGS="$glib_save_CPPFLAGS"
2149
2150 AC_MSG_CHECKING(thread related cflags)
2151 AC_MSG_RESULT($G_THREAD_CFLAGS)
2152 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2153
2154 dnl determination of G_THREAD_LIBS
2155 dnl ******************************
2156
2157 AS_IF([test x$have_threads = xposix], [
2158           glib_save_CPPFLAGS="$CPPFLAGS"
2159           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2160           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2161             case $host in
2162               *-aix*)
2163                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2164                 # probably using the aix compiler.
2165                 AC_MSG_WARN($AIX_COMPILE_INFO)
2166                 ;;
2167               *)
2168                 G_THREAD_LIBS=error
2169                 glib_save_LIBS="$LIBS"
2170                 for thread_lib in "" pthread pthread32 pthreads thread; do
2171                         if test x"$thread_lib" = x; then
2172                                 add_thread_lib=""
2173                                 IN=""
2174                         else
2175                                 add_thread_lib="-l$thread_lib"
2176                                 IN=" in -l$thread_lib"
2177                         fi
2178                         if test x"$have_threads" = xposix; then
2179                                 defattr=0
2180                         else
2181                                 defattr=pthread_attr_default
2182                         fi
2183
2184                         LIBS="$add_thread_lib $glib_save_LIBS"
2185
2186                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2187                         AC_TRY_RUN(glib_thread_test($defattr),
2188                                    glib_result=yes,
2189                                    glib_result=no,
2190                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2191                                                    glib_result=yes,
2192                                                    glib_result=no)])
2193                         AC_MSG_RESULT($glib_result)
2194
2195                         if test "$glib_result" = "yes" ; then
2196                           G_THREAD_LIBS="$add_thread_lib"
2197                           break
2198                         fi
2199                 done
2200                 if test "x$G_THREAD_LIBS" = xerror; then
2201                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2202                 fi
2203                 LIBS="$glib_save_LIBS"
2204                 ;;
2205             esac
2206           ])
2207
2208           g_threads_impl="POSIX"
2209           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2210           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2211           CPPFLAGS="$glib_save_CPPFLAGS"
2212 ], [test x$have_threads = xwin32], [
2213            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2214            g_threads_impl="WIN32"
2215 ], [
2216            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2217            g_threads_impl="NONE"
2218            G_THREAD_LIBS=error
2219 ])
2220 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2221 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2222 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2223
2224 if test "x$G_THREAD_LIBS" = xerror; then
2225         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2226 fi
2227
2228 AC_MSG_CHECKING(thread related libraries)
2229 AC_MSG_RESULT($G_THREAD_LIBS)
2230
2231 dnl check for mt safe function variants and some posix functions
2232 dnl ************************************************************
2233
2234 glib_save_LIBS="$LIBS"
2235 # we are not doing the following for now, as this might require glib
2236 # to always be linked with the thread libs on some platforms.
2237 # LIBS="$LIBS $G_THREAD_LIBS"
2238 AC_CHECK_FUNCS(localtime_r gmtime_r)
2239 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2240         AC_CACHE_CHECK([for posix getpwuid_r],
2241                 ac_cv_func_posix_getpwuid_r,
2242                 [AC_TRY_RUN([
2243 #include <errno.h>
2244 #include <pwd.h>
2245 int main () {
2246     char buffer[10000];
2247     struct passwd pwd, *pwptr = &pwd;
2248     int error;
2249     errno = 0;
2250     error = getpwuid_r (0, &pwd, buffer,
2251                         sizeof (buffer), &pwptr);
2252    return (error < 0 && errno == ENOSYS)
2253            || error == ENOSYS;
2254 }                               ],
2255                         [ac_cv_func_posix_getpwuid_r=yes],
2256                         [ac_cv_func_posix_getpwuid_r=no])])
2257         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2258         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2259                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2260                         [Have POSIX function getpwuid_r])
2261         else
2262                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2263                         ac_cv_func_nonposix_getpwuid_r,
2264                         [AC_TRY_LINK([#include <pwd.h>],
2265                                 [char buffer[10000];
2266                                 struct passwd pwd;
2267                                 getpwuid_r (0, &pwd, buffer,
2268                                                 sizeof (buffer));],
2269                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2270                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2271                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2272                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2273                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2274                                 [Have non-POSIX function getpwuid_r])
2275                 fi
2276         fi
2277 ])
2278 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2279         AC_CACHE_CHECK([for posix getgrgid_r],
2280                 ac_cv_func_posix_getgrgid_r,
2281                 [AC_TRY_RUN([
2282 #include <errno.h>
2283 #include <grp.h>
2284 int main () {
2285     char buffer[10000];
2286     struct group grp, *grpptr = &grp;
2287     int error;
2288     errno = 0;
2289     error = getgrgid_r (0, &grp, buffer,
2290                         sizeof (buffer), &grpptr);
2291    return (error < 0 && errno == ENOSYS)
2292            || error == ENOSYS;
2293 }                              ],
2294                        [ac_cv_func_posix_getgrgid_r=yes],
2295                        [ac_cv_func_posix_getgrgid_r=no])])
2296         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2297         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2298                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2299                         [Have POSIX function getgrgid_r])
2300         ], [
2301                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2302                         ac_cv_func_nonposix_getgrgid_r,
2303                         [AC_TRY_LINK([#include <grp.h>],
2304                                 [char buffer[10000];
2305                                 struct group grp;
2306                                 getgrgid_r (0, &grp, buffer,
2307                                 sizeof (buffer));],
2308                         [ac_cv_func_nonposix_getgrgid_r=yes],
2309                         [ac_cv_func_nonposix_getgrgid_r=no])])
2310                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2311                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2312                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2313                                 [Have non-POSIX function getgrgid_r])
2314                 fi
2315         ])
2316 ])
2317 LIBS="$G_THREAD_LIBS $LIBS"
2318 AS_IF([ test x"$have_threads" = xposix], [
2319         glib_save_CPPFLAGS="$CPPFLAGS"
2320         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2321         # This is not AC_CHECK_FUNC to also work with function
2322         # name mangling in header files.
2323         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2324         AC_LINK_IFELSE(
2325             [AC_LANG_PROGRAM(
2326                 [#include <pthread.h>],
2327                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2328             [AC_MSG_RESULT(yes)
2329              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2330                 [Have function pthread_attr_setstacksize])],
2331             [AC_MSG_RESULT(no)])
2332         AC_MSG_CHECKING(for pthread_condattr_setclock)
2333         AC_LINK_IFELSE(
2334             [AC_LANG_PROGRAM(
2335                 [#include <pthread.h>],
2336                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2337             [AC_MSG_RESULT(yes)
2338              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2339                 [Have function pthread_condattr_setclock])],
2340             [AC_MSG_RESULT(no)])
2341         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic)
2342         AC_LINK_IFELSE(
2343             [AC_LANG_PROGRAM(
2344                 [#include <pthread.h>],
2345                 [pthread_cond_timedwait_monotonic(NULL, NULL, NULL)])],
2346             [AC_MSG_RESULT(yes)
2347              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC,1,
2348                 [Have function pthread_cond_timedwait_monotonic])],
2349             [AC_MSG_RESULT(no)])
2350         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic_np)
2351         AC_LINK_IFELSE(
2352             [AC_LANG_PROGRAM(
2353                 [#include <pthread.h>],
2354                 [pthread_cond_timedwait_monotonic_np(NULL, NULL, NULL)])],
2355             [AC_MSG_RESULT(yes)
2356              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC_NP,1,
2357                 [Have function pthread_cond_timedwait_monotonic_np])],
2358             [AC_MSG_RESULT(no)])
2359         CPPFLAGS="$glib_save_CPPFLAGS"
2360 ])
2361
2362 LIBS="$glib_save_LIBS"
2363
2364 # now spit out all the warnings.
2365 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2366    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2367         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2368 fi
2369 if test "$ac_cv_func_localtime_r" != "yes"; then
2370         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2371 fi
2372
2373 #
2374 # Hack to deal with:
2375 #
2376 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2377 #     building shared libraries with linux.
2378 #  b) FreeBSD doesn't do this either.
2379 #
2380 case $host in
2381   *android*)
2382     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2383     ;;
2384   *-*-freebsd*|*-*-linux*)
2385     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2386     ;;
2387   *-*-openbsd*)
2388     LDFLAGS="$LDFLAGS -pthread"
2389     ;;
2390   *)
2391     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2392     ;;
2393 esac
2394
2395 AC_SUBST(G_THREAD_CFLAGS)
2396 AC_SUBST(G_THREAD_LIBS)
2397 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2398 AC_SUBST(G_THREAD_LIBS_EXTRA)
2399
2400 AC_CHECK_FUNCS(clock_gettime, [], [
2401   AC_CHECK_LIB(rt, clock_gettime, [
2402     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2403     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2404     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2405   ])
2406 ])
2407
2408
2409 dnl ************************
2410 dnl *** g_atomic_* tests ***
2411 dnl ************************
2412
2413 dnl We need to decide at configure time if GLib will use real atomic
2414 dnl operations ("lock free") or emulated ones with a mutex.  This is
2415 dnl because we must put this information in glibconfig.h so we know if
2416 dnl it is safe or not to inline using compiler intrinsics directly from
2417 dnl the header.
2418 dnl
2419 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2420 dnl user is interested in knowing if they can use the atomic ops across
2421 dnl processes.
2422 dnl
2423 dnl We can currently support the atomic ops natively when building GLib
2424 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2425 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2426 dnl we are using GCC (and not mingw*).
2427 dnl
2428 dnl Note that the atomic ops are only available with GCC on x86 when
2429 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2430 dnl not available but would be available given the right flags, we want
2431 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2432 dnl that then to silently fall back on emulated atomic ops just because
2433 dnl the user had the wrong build environment.
2434
2435 dnl We may add other compilers here in the future...
2436
2437 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2438   case $host in
2439     *-*-mingw*)
2440       glib_cv_g_atomic_lock_free=yes
2441       ;;
2442     *)
2443       AC_TRY_LINK([],
2444                      [volatile int atomic = 2;\
2445                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2446                      [glib_cv_g_atomic_lock_free=yes],
2447                      [glib_cv_g_atomic_lock_free=no])
2448       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2449         SAVE_CFLAGS="${CFLAGS}"
2450         CFLAGS="-march=i486"
2451         AC_TRY_LINK([],
2452                        [volatile int atomic = 2;\
2453                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2454                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2455                        [])
2456         CFLAGS="${SAVE_CFLAGS}"
2457       fi
2458       ;;
2459   esac])
2460
2461
2462 case $host in
2463   *-*-mingw*)
2464     ;;
2465   *)
2466     # Some compilers support atomic operations but do not define
2467     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2468     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2469       AC_TRY_LINK([],
2470                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2471                      [],
2472                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2473     fi
2474     ;;
2475  esac
2476
2477 dnl We need a more robust approach here...
2478 case $host_cpu in
2479   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2480     glib_memory_barrier_needed=no
2481     ;;
2482   sparc*|alpha*|powerpc*|ia64)
2483     glib_memory_barrier_needed=yes
2484     ;;
2485   *)
2486     glib_memory_barrier_needed=yes
2487     ;;
2488 esac
2489
2490 dnl ************************
2491 dnl ** Check for futex(2) **
2492 dnl ************************
2493 AC_CACHE_CHECK(for futex(2) system call,
2494     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2495 #include <linux/futex.h>
2496 #include <sys/syscall.h>
2497 #include <unistd.h>
2498 ],[
2499 int
2500 main (void)
2501 {
2502   /* it is not like this actually runs or anything... */
2503   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2504   return 0;
2505 }
2506 ])],glib_cv_futex=yes,glib_cv_futex=no))
2507 if test x"$glib_cv_futex" = xyes; then
2508   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2509 fi
2510
2511 AC_CACHE_CHECK(for eventfd(2) system call,
2512     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2513 #include <sys/eventfd.h>
2514 #include <unistd.h>
2515 ],[
2516 int
2517 main (void)
2518 {
2519   eventfd (0, EFD_CLOEXEC);
2520   return 0;
2521 }
2522 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2523 if test x"$glib_cv_eventfd" = x"yes"; then
2524   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2525 fi
2526 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2527
2528 dnl ****************************************
2529 dnl *** GLib POLL* compatibility defines ***
2530 dnl ****************************************
2531
2532 glib_poll_includes=["
2533 #include <sys/types.h>
2534 #include <sys/poll.h>
2535 "]
2536
2537 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2538    test $ac_cv_header_sys_poll_h = yes ], [
2539   glib_failed=false
2540   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2541   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2542   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2543   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2544   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2545   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2546   if $glib_failed ; then
2547     AC_MSG_ERROR([Could not determine values for POLL* constants])
2548   fi
2549 ], [
2550   glib_cv_value_POLLIN=1
2551   glib_cv_value_POLLOUT=4
2552   glib_cv_value_POLLPRI=2
2553   glib_cv_value_POLLERR=8
2554   glib_cv_value_POLLHUP=16
2555   glib_cv_value_POLLNVAL=32
2556 ])
2557
2558 AC_MSG_CHECKING([for broken poll])
2559 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2560         #include <stdlib.h>
2561         #include <fcntl.h>
2562         #include <poll.h>
2563         #ifdef HAVE_SYS_POLL_H
2564         #include <sys/poll.h>
2565         #endif
2566         int main(void) {
2567           struct pollfd fds[1];
2568           int fd;
2569           fd = open("/dev/null", 1);
2570           fds[0].fd = fd;
2571           fds[0].events = POLLIN;
2572           fds[0].revents = 0;
2573           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2574                 exit(1);  /* Does not work for devices -- fail */
2575           }
2576           exit(0);
2577         }]])],
2578   [broken_poll=no],
2579   [broken_poll=yes
2580    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2581   [broken_poll="no (cross compiling)"])
2582 AC_MSG_RESULT($broken_poll)
2583
2584 dnl *********************
2585 dnl *** GRegex checks ***
2586 dnl *********************
2587
2588 PCRE_REQUIRED_VERSION=8.13
2589
2590 # Check if we should use the internal or the system-supplied pcre
2591 AC_ARG_WITH(pcre,
2592             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2593                             [whether to use system PCRE [default=internal]])])
2594
2595 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2596
2597 AS_IF([ test "x$with_pcre" = xsystem], [
2598   PKG_CHECK_MODULES(PCRE,
2599                     libpcre >= $PCRE_REQUIRED_VERSION)
2600   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2601                   glib_save_CFLAGS="$CFLAGS"
2602                   glib_save_LIBS="$LIBS"
2603                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2604                   AC_TRY_RUN([#include <pcre.h>
2605                               int main () {
2606                                 int support;
2607                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2608                                 if (!support)
2609                                   return 1;
2610                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2611                                 if (!support)
2612                                   return 1;
2613                                 return 0;
2614                               }],
2615                   glib_cv_pcre_has_unicode=yes,
2616                   glib_cv_pcre_has_unicode=no,
2617                   glib_cv_pcre_has_unicode=yes)
2618                   CFLAGS="$glib_save_CFLAGS"
2619                   LIBS="$glib_save_LIBS"
2620       ])
2621   if test "$glib_cv_pcre_has_unicode" = "no"; then
2622     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2623   fi
2624   AC_SUBST(PCRE_CFLAGS)
2625   AC_SUBST(PCRE_LIBS)
2626   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2627   PCRE_REQUIRES=libpcre
2628   AC_SUBST(PCRE_REQUIRES)
2629 ], [
2630   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2631   AS_IF([ test x"$GCC" = xyes], [
2632     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2633     save_CFLAGS="$CFLAGS"
2634     CFLAGS="$CFLAGS -Wno-pointer-sign"
2635     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2636                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2637     CFLAGS="$save_CFLAGS"
2638   ])
2639 ])
2640 AC_SUBST(PCRE_WARN_CFLAGS)
2641
2642 dnl **********************
2643 dnl *** Win32 API libs ***
2644 dnl **********************
2645
2646 case $host in
2647   *-*-cygwin*)
2648         G_LIBS_EXTRA="-luser32 -lkernel32"
2649     ;;
2650   *-*-mingw*)
2651         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2652     ;;
2653   *)
2654         G_LIBS_EXTRA=""
2655     ;;
2656 esac
2657 AC_SUBST(G_LIBS_EXTRA)
2658
2659 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2660 dnl since we need it for g_iconv()
2661
2662 AC_MSG_CHECKING([for EILSEQ])
2663 AC_TRY_COMPILE([
2664 #include <errno.h>
2665 ],
2666 [
2667 int error = EILSEQ;
2668 ], have_eilseq=yes, have_eilseq=no);
2669 AC_MSG_RESULT($have_eilseq)
2670
2671 dnl ******************************************************************
2672 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2673 dnl *** glib-compile-schemas in PATH                               ***
2674 dnl ******************************************************************
2675
2676 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2677
2678 AS_IF([ test $cross_compiling = yes ], [
2679   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2680   if test x$GLIB_GENMARSHAL = xno; then
2681     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2682   fi
2683
2684   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2685   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2686     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2687   fi
2688
2689   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2690   if test x$GLIB_COMPILE_RESOURCES = xno; then
2691     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2692   fi
2693 ])
2694
2695 dnl **************************
2696 dnl *** Checks for gtk-doc ***
2697 dnl **************************
2698 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2699 # it on it's own line.
2700 m4_ifdef([GTK_DOC_CHECK], [
2701 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2702 ],[
2703 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2704 ])
2705
2706 AC_ARG_ENABLE(man,
2707               [AS_HELP_STRING([--enable-man],
2708                               [generate man pages [default=auto]])],,
2709               enable_man=maybe)
2710
2711 AS_IF([test "$enable_man" != no], [
2712   AC_PATH_PROG([XSLTPROC], [xsltproc])
2713   AS_IF([test -z "$XSLTPROC"], [
2714     AS_IF([test "$enable_man" = yes], [
2715       AC_MSG_ERROR([xsltproc is required for --enable-man])
2716     ])
2717     enable_man=no
2718   ])
2719 ])
2720
2721 AS_IF([ test "$enable_man" != no ], [
2722   dnl check for DocBook DTD in the local catalog
2723   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2724      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2725   AS_IF([test "$have_docbook_dtd" != yes], [
2726     AS_IF([test "$enable_man" = yes ], [
2727       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2728     ])
2729     enable_man=no
2730   ])
2731 ])
2732
2733 AS_IF([test "$enable_man" != no], [
2734   dnl check for DocBook XSL stylesheets in the local catalog
2735   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2736      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2737   AS_IF([ test "$have_docbook_dtd" != yes ], [
2738     AS_IF([ test "$enable_man" = yes ], [
2739       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2740     ])
2741     enable_man=no
2742   ])
2743 ])
2744
2745 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2746
2747 AC_MSG_CHECKING([whether to generate man pages])
2748 AS_IF([ test "$enable_man" != no ], [
2749   AC_MSG_RESULT([yes])
2750 ], [
2751   AC_MSG_RESULT([no])
2752 ])
2753
2754 dnl
2755 dnl Tracing
2756 dnl
2757
2758 AC_ARG_ENABLE([dtrace],
2759              [AS_HELP_STRING([--enable-dtrace],
2760                               [include tracing support for dtrace])])
2761 have_dtrace=no
2762 AC_MSG_CHECKING([whether to include dtrace tracing support])
2763 AS_IF([ test "x$enable_dtrace" != xno], [
2764   if test x$glib_have_carbon = xyes; then
2765     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2766   else
2767     AC_MSG_RESULT([yes])
2768     AC_CHECK_PROGS(DTRACE, dtrace)
2769     if test -z "$DTRACE"; then
2770       if test "x$enable_dtrace" = xyes; then
2771         AC_MSG_ERROR([dtrace not found])
2772       fi
2773     else
2774       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2775                       [if test "x$enable_dtrace" = xyes; then
2776                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2777                        fi])
2778     fi
2779   fi
2780 ], [
2781   AC_MSG_RESULT([no])
2782 ])
2783 if test "x$have_dtrace" = xyes; then
2784   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2785 fi
2786 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2787
2788 AC_MSG_CHECKING([whether to include systemtap tracing support])
2789 AC_ARG_ENABLE([systemtap],
2790              [AS_HELP_STRING([--enable-systemtap],
2791                               [include tracing support for systemtap])])
2792 have_systemtap=no
2793 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2794   have_systemtap=yes
2795 fi
2796 AC_MSG_RESULT(${have_systemtap})
2797
2798 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2799
2800 AC_ARG_WITH([tapset-install-dir],
2801             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2802                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2803             [if test "x${withval}" = x; then
2804                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2805              else
2806                ABS_TAPSET_DIR="${withval}"
2807               fi],
2808             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2809 AC_SUBST(ABS_TAPSET_DIR)
2810
2811 dnl ************************************
2812 dnl *** Enable lcov coverage reports ***
2813 dnl ************************************
2814
2815 AC_ARG_ENABLE(gcov,
2816   AS_HELP_STRING([--enable-gcov],
2817                  [enable coverage testing with gcov]),
2818   [use_gcov=$enableval], [use_gcov=no])
2819
2820 AS_IF([ test "x$use_gcov" = "xyes"], [
2821   dnl we need gcc:
2822   if test "$GCC" != "yes"; then
2823     AC_MSG_ERROR([GCC is required for --enable-gcov])
2824   fi
2825
2826   dnl Check if ccache is being used
2827   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2828   case `$SHTOOL path $CC` in
2829     *ccache*[)] gcc_ccache=yes;;
2830     *[)] gcc_ccache=no;;
2831   esac
2832
2833   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2834     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2835   fi
2836
2837   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2838   AC_CHECK_PROG(LTP, lcov, lcov)
2839   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2840
2841   AS_IF([ test "$LTP" ], [
2842     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2843       glib_cv_ltp_version=invalid
2844       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2845       for ltp_check_version in $ltp_version_list; do
2846         if test "$ltp_version" = "$ltp_check_version"; then
2847           glib_cv_ltp_version="$ltp_check_version (ok)"
2848         fi
2849       done
2850     ])
2851   ], [
2852     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2853     AC_MSG_ERROR([$ltp_msg])
2854   ])
2855
2856   case $glib_cv_ltp_version in
2857     ""|invalid[)]
2858       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2859       AC_MSG_ERROR([$ltp_msg])
2860       LTP="exit 0;"
2861       ;;
2862   esac
2863
2864   if test -z "$LTP_GENHTML"; then
2865     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2866   fi
2867
2868   dnl Remove all optimization flags from CFLAGS
2869   changequote({,})
2870   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2871   changequote([,])
2872
2873   dnl Add the special gcc flags
2874   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2875   LDFLAGS="$LDFLAGS -lgcov"
2876 ])
2877
2878 dnl ******************************
2879 dnl *** output the whole stuff ***
2880 dnl ******************************
2881
2882 dnl this section will only be run if config.status is invoked with no
2883 dnl arguments, or with "glib/glibconfig.h" as an argument.
2884 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2885 [
2886         outfile=glib/glibconfig.h-tmp
2887         cat > $outfile <<\_______EOF
2888 /* glibconfig.h
2889  *
2890  * This is a generated file.  Please modify 'configure.ac'
2891  */
2892
2893 #ifndef __GLIBCONFIG_H__
2894 #define __GLIBCONFIG_H__
2895
2896 #include <glib/gmacros.h>
2897
2898 _______EOF
2899
2900         if test x$glib_limits_h = xyes; then
2901           echo '#include <limits.h>' >> $outfile
2902         fi
2903         if test x$glib_float_h = xyes; then
2904           echo '#include <float.h>' >> $outfile
2905         fi
2906         if test x$glib_values_h = xyes; then
2907           echo '#include <values.h>' >> $outfile
2908         fi
2909         if test "$glib_header_alloca_h" = "yes"; then
2910           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2911         fi
2912         if test x$glib_sys_poll_h = xyes; then
2913           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2914         fi
2915         if test x$glib_included_printf != xyes; then
2916           echo "
2917 /* Specifies that GLib's g_print*() functions wrap the
2918  * system printf functions.  This is useful to know, for example,
2919  * when using glibc's register_printf_function().
2920  */" >> $outfile
2921           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2922         fi
2923
2924         cat >> $outfile <<_______EOF
2925
2926 G_BEGIN_DECLS
2927
2928 #define G_MINFLOAT      $glib_mf
2929 #define G_MAXFLOAT      $glib_Mf
2930 #define G_MINDOUBLE     $glib_md
2931 #define G_MAXDOUBLE     $glib_Md
2932 #define G_MINSHORT      $glib_ms
2933 #define G_MAXSHORT      $glib_Ms
2934 #define G_MAXUSHORT     $glib_Mus
2935 #define G_MININT        $glib_mi
2936 #define G_MAXINT        $glib_Mi
2937 #define G_MAXUINT       $glib_Mui
2938 #define G_MINLONG       $glib_ml
2939 #define G_MAXLONG       $glib_Ml
2940 #define G_MAXULONG      $glib_Mul
2941
2942 _______EOF
2943
2944
2945         ### this should always be true in a modern C/C++ compiler
2946         cat >>$outfile <<_______EOF
2947 typedef signed char gint8;
2948 typedef unsigned char guint8;
2949 _______EOF
2950
2951
2952         if test -n "$gint16"; then
2953           cat >>$outfile <<_______EOF
2954 typedef signed $gint16 gint16;
2955 typedef unsigned $gint16 guint16;
2956 #define G_GINT16_MODIFIER $gint16_modifier
2957 #define G_GINT16_FORMAT $gint16_format
2958 #define G_GUINT16_FORMAT $guint16_format
2959 _______EOF
2960         fi
2961
2962
2963         if test -n "$gint32"; then
2964           cat >>$outfile <<_______EOF
2965 typedef signed $gint32 gint32;
2966 typedef unsigned $gint32 guint32;
2967 #define G_GINT32_MODIFIER $gint32_modifier
2968 #define G_GINT32_FORMAT $gint32_format
2969 #define G_GUINT32_FORMAT $guint32_format
2970 _______EOF
2971         fi
2972
2973         cat >>$outfile <<_______EOF
2974 #define G_HAVE_GINT64 1          /* deprecated, always true */
2975
2976 ${glib_extension}typedef signed $gint64 gint64;
2977 ${glib_extension}typedef unsigned $gint64 guint64;
2978
2979 #define G_GINT64_CONSTANT(val)  $gint64_constant
2980 #define G_GUINT64_CONSTANT(val) $guint64_constant
2981 _______EOF
2982
2983         if test x$gint64_format != x ; then
2984           cat >>$outfile <<_______EOF
2985 #define G_GINT64_MODIFIER $gint64_modifier
2986 #define G_GINT64_FORMAT $gint64_format
2987 #define G_GUINT64_FORMAT $guint64_format
2988 _______EOF
2989         else
2990           cat >>$outfile <<_______EOF
2991 #undef G_GINT64_MODIFIER
2992 #undef G_GINT64_FORMAT
2993 #undef G_GUINT64_FORMAT
2994 _______EOF
2995         fi
2996
2997         cat >>$outfile <<_______EOF
2998
2999 #define GLIB_SIZEOF_VOID_P $glib_void_p
3000 #define GLIB_SIZEOF_LONG   $glib_long
3001 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3002 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
3003
3004 _______EOF
3005
3006         cat >>$outfile <<_______EOF
3007 typedef signed $glib_ssize_type_define gssize;
3008 typedef unsigned $glib_size_type_define gsize;
3009 #define G_GSIZE_MODIFIER $gsize_modifier
3010 #define G_GSSIZE_MODIFIER $gssize_modifier
3011 #define G_GSIZE_FORMAT $gsize_format
3012 #define G_GSSIZE_FORMAT $gssize_format
3013
3014 #define G_MAXSIZE       G_MAXU$glib_msize_type
3015 #define G_MINSSIZE      G_MIN$glib_mssize_type
3016 #define G_MAXSSIZE      G_MAX$glib_mssize_type
3017
3018 typedef gint64 goffset;
3019 #define G_MINOFFSET     G_MININT64
3020 #define G_MAXOFFSET     G_MAXINT64
3021
3022 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3023 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3024 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3025
3026 _______EOF
3027
3028         if test -z "$glib_unknown_void_p"; then
3029           cat >>$outfile <<_______EOF
3030
3031 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3032 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3033
3034 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3035 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3036
3037 typedef signed $glib_intptr_type_define gintptr;
3038 typedef unsigned $glib_intptr_type_define guintptr;
3039
3040 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3041 #define G_GINTPTR_FORMAT        $gintptr_format
3042 #define G_GUINTPTR_FORMAT       $guintptr_format
3043 _______EOF
3044         else
3045           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3046         fi
3047
3048
3049
3050         cat >>$outfile <<_______EOF
3051 $glib_atexit
3052 $glib_memmove
3053 $glib_defines
3054 $glib_os
3055 $glib_static_compilation
3056
3057 $glib_vacopy
3058
3059 #ifdef  __cplusplus
3060 #define G_HAVE_INLINE   1
3061 #else   /* !__cplusplus */
3062 $glib_inline
3063 #endif  /* !__cplusplus */
3064
3065 #ifdef  __cplusplus
3066 #define G_CAN_INLINE    1
3067 _______EOF
3068
3069         if test x$g_can_inline = xyes ; then
3070                 cat >>$outfile <<_______EOF
3071 #else   /* !__cplusplus */
3072 #define G_CAN_INLINE    1
3073 _______EOF
3074         fi
3075
3076         cat >>$outfile <<_______EOF
3077 #endif
3078
3079 _______EOF
3080
3081         if test x$g_have_iso_c_varargs = xyes ; then
3082                 cat >>$outfile <<_______EOF
3083 #ifndef __cplusplus
3084 # define G_HAVE_ISO_VARARGS 1
3085 #endif
3086 _______EOF
3087         fi
3088         if test x$g_have_iso_cxx_varargs = xyes ; then
3089                 cat >>$outfile <<_______EOF
3090 #ifdef __cplusplus
3091 # define G_HAVE_ISO_VARARGS 1
3092 #endif
3093 _______EOF
3094         fi
3095         if test x$g_have_gnuc_varargs = xyes ; then
3096                 cat >>$outfile <<_______EOF
3097
3098 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3099  * is passed ISO vararg support is turned off, and there is no work
3100  * around to turn it on, so we unconditionally turn it off.
3101  */
3102 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3103 #  undef G_HAVE_ISO_VARARGS
3104 #endif
3105
3106 #define G_HAVE_GNUC_VARARGS 1
3107 _______EOF
3108         fi
3109
3110         case x$g_stack_grows in
3111         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3112         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3113         esac
3114
3115
3116         echo >>$outfile
3117         if test x$g_have_eilseq = xno; then
3118                 cat >>$outfile <<_______EOF
3119 #ifndef EILSEQ
3120 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3121  * The correspondence between this and the corresponding definition
3122  * in libiconv is essential.
3123  */
3124 #  define EILSEQ ENOENT
3125 #endif
3126 _______EOF
3127
3128         fi
3129
3130         if test x$g_have_gnuc_visibility = xyes; then
3131                 cat >>$outfile <<_______EOF
3132 #define G_HAVE_GNUC_VISIBILITY 1
3133 _______EOF
3134         fi
3135                 cat >>$outfile <<_______EOF
3136 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3137 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3138 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3139 #define G_GNUC_INTERNAL __hidden
3140 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3141 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3142 #else
3143 #define G_GNUC_INTERNAL
3144 #endif
3145 _______EOF
3146
3147         echo >>$outfile
3148         cat >>$outfile <<_______EOF
3149 #define G_THREADS_ENABLED
3150 #define G_THREADS_IMPL_$g_threads_impl_def
3151 _______EOF
3152
3153         if test x"$g_memory_barrier_needed" != xno; then
3154           echo >>$outfile
3155           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3156         fi
3157         if test x"$g_atomic_lock_free" = xyes; then
3158           echo >>$outfile
3159           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3160         fi
3161         echo >>$outfile
3162         g_bit_sizes="16 32 64"
3163         for bits in $g_bit_sizes; do
3164           cat >>$outfile <<_______EOF
3165 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3166 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3167 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3168 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3169 _______EOF
3170         done
3171
3172         cat >>$outfile <<_______EOF
3173 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3174 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3175 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3176 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3177 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3178 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3179 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3180 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3181 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3182 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3183 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3184 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3185 #define G_BYTE_ORDER $g_byte_order
3186
3187 #define GLIB_SYSDEF_POLLIN =$g_pollin
3188 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3189 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3190 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3191 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3192 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3193
3194 #define G_MODULE_SUFFIX "$g_module_suffix"
3195
3196 typedef $g_pid_type GPid;
3197
3198 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3199 #define GLIB_SYSDEF_AF_INET $g_af_inet
3200 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3201
3202 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3203 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3204 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3205
3206 G_END_DECLS
3207
3208 #endif /* __GLIBCONFIG_H__ */
3209 _______EOF
3210
3211
3212         if cmp -s $outfile glib/glibconfig.h; then
3213           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3214           rm -f $outfile
3215         else
3216           mv $outfile glib/glibconfig.h
3217         fi
3218 ],[
3219
3220 # Note that if two cases are the same, case goes with the first one.
3221 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3222 # on variable expansion in case labels.  Look at the generated config.status
3223 # for a hint.
3224
3225 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3226   glib_header_alloca_h="$ac_cv_working_alloca_h"
3227 else
3228   glib_header_alloca_h="$ac_cv_header_alloca_h"
3229 fi
3230
3231 case xyes in
3232 x$ac_cv_header_float_h)
3233   glib_float_h=yes
3234   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3235   glib_md=DBL_MIN glib_Md=DBL_MAX
3236   ;;
3237 x$ac_cv_header_values_h)
3238   glib_values_h=yes
3239   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3240   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3241   ;;
3242 esac
3243
3244 case xyes in
3245 x$ac_cv_header_limits_h)
3246   glib_limits_h=yes
3247   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3248   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3249   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3250   ;;
3251 x$ac_cv_header_values_h)
3252   glib_values_h=yes
3253   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3254   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3255   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3256   ;;
3257 esac
3258
3259 if test x$ac_cv_header_sys_poll_h = xyes ; then
3260   glib_sys_poll_h=yes
3261 fi
3262
3263 if test x$enable_included_printf = xyes ; then
3264   glib_included_printf=yes
3265 fi
3266
3267 case 2 in
3268 $ac_cv_sizeof_short)
3269   gint16=short
3270   gint16_modifier='"h"'
3271   gint16_format='"hi"'
3272   guint16_format='"hu"'
3273   ;;
3274 $ac_cv_sizeof_int)
3275   gint16=int
3276   gint16_modifier='""'
3277   gint16_format='"i"'
3278   guint16_format='"u"'
3279   ;;
3280 esac
3281 case 4 in
3282 $ac_cv_sizeof_short)
3283   gint32=short
3284   gint32_modifier='"h"'
3285   gint32_format='"hi"'
3286   guint32_format='"hu"'
3287   ;;
3288 $ac_cv_sizeof_int)
3289   gint32=int
3290   gint32_modifier='""'
3291   gint32_format='"i"'
3292   guint32_format='"u"'
3293   ;;
3294 $ac_cv_sizeof_long)
3295   gint32=long
3296   gint32_modifier='"l"'
3297   gint32_format='"li"'
3298   guint32_format='"lu"'
3299   ;;
3300 esac
3301 case 8 in
3302 $ac_cv_sizeof_int)
3303   gint64=int
3304   gint64_modifier='""'
3305   gint64_format='"i"'
3306   guint64_format='"u"'
3307   glib_extension=
3308   gint64_constant='(val)'
3309   guint64_constant='(val)'
3310   ;;
3311 $ac_cv_sizeof_long)
3312   gint64=long
3313   gint64_modifier='"l"'
3314   gint64_format='"li"'
3315   guint64_format='"lu"'
3316   glib_extension=
3317   gint64_constant='(val##L)'
3318   guint64_constant='(val##UL)'
3319   ;;
3320 $ac_cv_sizeof_long_long)
3321   gint64='long long'
3322   if test -n "$glib_cv_long_long_format"; then
3323     gint64_modifier='"'$glib_cv_long_long_format'"'
3324     gint64_format='"'$glib_cv_long_long_format'i"'
3325     guint64_format='"'$glib_cv_long_long_format'u"'
3326   fi
3327   glib_extension='G_GNUC_EXTENSION '
3328   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3329   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3330   ;;
3331 $ac_cv_sizeof___int64)
3332   gint64='__int64'
3333   if test -n "$glib_cv_long_long_format"; then
3334     gint64_modifier='"'$glib_cv_long_long_format'"'
3335     gint64_format='"'$glib_cv_long_long_format'i"'
3336     guint64_format='"'$glib_cv_long_long_format'u"'
3337   fi
3338   glib_extension=
3339   gint64_constant='(val##i64)'
3340   guint64_constant='(val##ui64)'
3341   ;;
3342 esac
3343 glib_size_t=$ac_cv_sizeof_size_t
3344 glib_ssize_t=$ac_cv_sizeof_ssize_t
3345 glib_size_type_define="$glib_size_type"
3346 glib_ssize_type_define="$glib_ssize_type"
3347 glib_void_p=$ac_cv_sizeof_void_p
3348 glib_long=$ac_cv_sizeof_long
3349
3350 case "$glib_size_type" in
3351 short)
3352   gsize_modifier='"h"'
3353   gsize_format='"hu"'
3354   glib_msize_type='SHRT'
3355   ;;
3356 int)
3357   gsize_modifier='""'
3358   gsize_format='"u"'
3359   glib_msize_type='INT'
3360   ;;
3361 long)
3362   gsize_modifier='"l"'
3363   gsize_format='"lu"'
3364   glib_msize_type='LONG'
3365   ;;
3366 "long long"|__int64)
3367   gsize_modifier='"I64"'
3368   gsize_format='"I64u"'
3369   glib_msize_type='INT64'
3370   ;;
3371 esac
3372
3373 case "$glib_ssize_type" in
3374 short)
3375   gssize_modifier='"h"'
3376   gssize_format='"hi"'
3377   glib_mssize_type='SHRT'
3378   ;;
3379 int)
3380   gssize_modifier='""'
3381   gssize_format='"i"'
3382   glib_mssize_type='INT'
3383   ;;
3384 long)
3385   gssize_modifier='"l"'
3386   gssize_format='"li"'
3387   glib_mssize_type='LONG'
3388   ;;
3389 "long long"|__int64)
3390   gssize_modifier='"I64"'
3391   gssize_format='"I64i"'
3392   glib_mssize_type='INT64'
3393   ;;
3394 esac
3395
3396 gintbits=`expr $ac_cv_sizeof_int \* 8`
3397 glongbits=`expr $ac_cv_sizeof_long \* 8`
3398 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3399 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3400
3401 case $ac_cv_sizeof_void_p in
3402 $ac_cv_sizeof_int)
3403   glib_intptr_type_define=int
3404   gintptr_modifier='""'
3405   gintptr_format='"i"'
3406   guintptr_format='"u"'
3407   glib_gpi_cast='(gint)'
3408   glib_gpui_cast='(guint)'
3409   ;;
3410 $ac_cv_sizeof_long)
3411   glib_intptr_type_define=long
3412   gintptr_modifier='"l"'
3413   gintptr_format='"li"'
3414   guintptr_format='"lu"'
3415   glib_gpi_cast='(glong)'
3416   glib_gpui_cast='(gulong)'
3417   ;;
3418 $ac_cv_sizeof_long_long)
3419   glib_intptr_type_define='long long'
3420   gintptr_modifier='"I64"'
3421   gintptr_format='"I64i"'
3422   guintptr_format='"I64u"'
3423   glib_gpi_cast='(gint64)'
3424   glib_gpui_cast='(guint64)'
3425   ;;
3426 $ac_cv_sizeof___int64)
3427   glib_intptr_type_define=__int64
3428   gintptr_modifier='"I64"'
3429   gintptr_format='"I64i"'
3430   guintptr_format='"I64u"'
3431   glib_gpi_cast='(gint64)'
3432   glib_gpui_cast='(guint64)'
3433   ;;
3434 *)
3435   glib_unknown_void_p=yes
3436   ;;
3437 esac
3438
3439
3440 case xyes in
3441 x$ac_cv_func_atexit)
3442   glib_atexit="
3443 #ifdef NeXT /* @#%@! NeXTStep */
3444 # define g_ATEXIT(proc) (!atexit (proc))
3445 #else
3446 # define g_ATEXIT(proc) (atexit (proc))
3447 #endif"
3448   ;;
3449 x$ac_cv_func_on_exit)
3450   glib_atexit="
3451 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3452   ;;
3453 esac
3454
3455 case xyes in
3456 x$ac_cv_func_memmove)
3457   glib_memmove='
3458 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3459   ;;
3460 x$glib_cv_working_bcopy)
3461   glib_memmove="
3462 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3463 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3464   ;;
3465 *)
3466   glib_memmove="
3467 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3468  * so we have to roll our own copy routine. */
3469 void g_memmove (void* dest, const void * src, unsigned long len);"
3470   ;;
3471 esac
3472
3473 glib_defines="
3474 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3475 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3476 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3477 "
3478
3479 case xyes in
3480 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3481 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3482 *)                      glib_vacopy=''
3483 esac
3484
3485 if test x$glib_cv_va_val_copy = xno; then
3486   glib_vacopy="\$glib_vacopy
3487 #define G_VA_COPY_AS_ARRAY 1"
3488 fi
3489
3490 if test x$glib_cv_hasinline = xyes; then
3491     glib_inline='#define G_HAVE_INLINE 1'
3492 fi
3493 if test x$glib_cv_has__inline = xyes; then
3494     glib_inline="\$glib_inline
3495 #define G_HAVE___INLINE 1"
3496 fi
3497 if test x$glib_cv_has__inline__ = xyes; then
3498     glib_inline="\$glib_inline
3499 #define G_HAVE___INLINE__ 1"
3500 fi
3501
3502 g_have_gnuc_varargs=$g_have_gnuc_varargs
3503 g_have_iso_c_varargs=$g_have_iso_c_varargs
3504 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3505
3506 g_can_inline=$g_can_inline
3507 g_have_gnuc_visibility=$g_have_gnuc_visibility
3508 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3509
3510 if test x$ac_cv_c_bigendian = xyes; then
3511   g_byte_order=G_BIG_ENDIAN
3512   g_bs_native=BE
3513   g_bs_alien=LE
3514 else
3515   g_byte_order=G_LITTLE_ENDIAN
3516   g_bs_native=LE
3517   g_bs_alien=BE
3518 fi
3519
3520 g_pollin=$glib_cv_value_POLLIN
3521 g_pollout=$glib_cv_value_POLLOUT
3522 g_pollpri=$glib_cv_value_POLLPRI
3523 g_pollhup=$glib_cv_value_POLLHUP
3524 g_pollerr=$glib_cv_value_POLLERR
3525 g_pollnval=$glib_cv_value_POLLNVAL
3526
3527 # If a family is not found on the system, define that family to
3528 # a negative value, picking a different one for each undefined
3529 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3530 # This is needed because glib-mkenums doesn't handle optional
3531 # values in enums, and thus we have to have all existing values
3532 # defined in the enum.
3533 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3534   g_af_unix=$glib_cv_value_AF_UNIX
3535 else
3536   g_af_unix=-1
3537 fi
3538 g_af_inet=$glib_cv_value_AF_INET
3539 g_af_inet6=$glib_cv_value_AF_INET6
3540
3541 g_msg_peek=$glib_cv_value_MSG_PEEK
3542 g_msg_oob=$glib_cv_value_MSG_OOB
3543 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3544
3545 g_stack_grows=$glib_cv_stack_grows
3546
3547 g_have_eilseq=$have_eilseq
3548
3549 g_threads_impl_def=$g_threads_impl
3550
3551 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3552 g_memory_barrier_needed="$glib_memory_barrier_needed"
3553 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3554
3555 g_module_suffix="$glib_gmodule_suffix"
3556
3557 g_pid_type="$glib_pid_type"
3558 case $host in
3559   *-*-cygwin*)
3560     glib_os="#define G_OS_UNIX
3561 #define G_PLATFORM_WIN32
3562 #define G_WITH_CYGWIN"
3563     ;;
3564   *-*-mingw*)
3565     glib_os="#define G_OS_WIN32
3566 #define G_PLATFORM_WIN32"
3567     ;;
3568   *)
3569     glib_os="#define G_OS_UNIX"
3570     ;;
3571 esac
3572 glib_static_compilation=""
3573 if test x$glib_win32_static_compilation = xyes; then
3574   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3575 #define GOBJECT_STATIC_COMPILATION 1"
3576 fi
3577 ])
3578
3579 # Redo enough to get guint32 and guint64 for the alignment checks below
3580 case 4 in
3581 $ac_cv_sizeof_short)
3582   gint32=short
3583   ;;
3584 $ac_cv_sizeof_int)
3585   gint32=int
3586   ;;
3587 $ac_cv_sizeof_long)
3588   gint32=long
3589   ;;
3590 esac
3591 case 8 in
3592 $ac_cv_sizeof_int)
3593   gint64=int
3594   ;;
3595 $ac_cv_sizeof_long)
3596   gint64=long
3597   ;;
3598 $ac_cv_sizeof_long_long)
3599   gint64='long long'
3600   ;;
3601 $ac_cv_sizeof___int64)
3602   gint64='__int64'
3603   ;;
3604 esac
3605
3606 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3607 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3608 typedef unsigned $gint32 guint32;])
3609 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3610 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3611 typedef unsigned $gint64 guint64;])
3612 AC_CHECK_TYPE([unsigned long])
3613 AC_CHECK_ALIGNOF([unsigned long])
3614
3615 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3616 #
3617 # 1.2.14 required for dbus_message_set_serial
3618 PKG_CHECK_MODULES(DBUS1,
3619      dbus-1 >= 1.2.14,
3620      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3621      have_dbus1=no)
3622 AC_SUBST(DBUS1_CFLAGS)
3623 AC_SUBST(DBUS1_LIBS)
3624 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3625
3626 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3627 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3628
3629 dnl
3630 dnl Check for -Bsymbolic-functions linker flag used to avoid
3631 dnl intra-library PLT jumps, if available.
3632 dnl
3633
3634 AC_ARG_ENABLE(Bsymbolic,
3635               [AS_HELP_STRING([--disable-Bsymbolic],
3636                               [avoid linking with -Bsymbolic])],,
3637               [SAVED_LDFLAGS="${LDFLAGS}"
3638                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3639                LDFLAGS=-Wl,-Bsymbolic-functions
3640                AC_TRY_LINK([], [int main (void) { return 0; }],
3641                            AC_MSG_RESULT(yes)
3642                            enable_Bsymbolic=yes,
3643                            AC_MSG_RESULT(no)
3644                            enable_Bsymbolic=no)
3645                LDFLAGS="${SAVED_LDFLAGS}"])
3646
3647 if test "x${enable_Bsymbolic}" = "xyes"; then
3648   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3649 fi
3650
3651 AC_SUBST(GLIB_LINK_FLAGS)
3652
3653 dnl
3654 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3655 dnl visibility attributes for symbol export control
3656 dnl
3657 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3658 case "$host" in
3659   *-*-mingw*)
3660     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3661     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3662               [defines how to decorate public symbols while building])
3663     CFLAGS="${CFLAGS} -fvisibility=hidden"
3664     ;;
3665   *)
3666     dnl on other compilers, check if we can do -fvisibility=hidden
3667     SAVED_CFLAGS="${CFLAGS}"
3668     CFLAGS="-fvisibility=hidden"
3669     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3670     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3671                    AC_MSG_RESULT(yes)
3672                    enable_fvisibility_hidden=yes,
3673                    AC_MSG_RESULT(no)
3674                    enable_fvisibility_hidden=no)
3675     CFLAGS="${SAVED_CFLAGS}"
3676
3677     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3678       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3679                 [defines how to decorate public symbols while building])
3680       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3681     ])
3682     ;;
3683 esac
3684 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3685
3686 dnl Compiler flags; macro originates from systemd
3687 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3688 AC_ARG_ENABLE(compile-warnings,
3689               [AS_HELP_STRING([--disable-compile-warnings],
3690                               [Don't use builtin compiler warnings])],,
3691                               enable_compile_warnings=yes)
3692 AS_IF([test "x$enable_compile_warnings" = xyes], [
3693   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3694    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3695    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3696    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3697    -Werror=format=2 -Werror=missing-include-dirs])
3698 ])
3699 AC_SUBST(GLIB_WARN_CFLAGS)
3700
3701 #
3702 # Define variables corresponding to the correct include paths to use for
3703 # in-tree building.
3704 #
3705
3706 # for config.h:
3707 config_h_INCLUDES='-I$(top_builddir)'
3708 AC_SUBST(config_h_INCLUDES)
3709
3710 # glib:
3711 #   config.h
3712 #   $(top_builddir)/glib: for glibconfig.h
3713 #   $(top_srcdir)/glib:   for glib.h
3714 #   $(top_srcdir):        for everything
3715 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3716 AC_SUBST(glib_INCLUDES)
3717
3718 # gobject:
3719 #   same as glib
3720 gobject_INCLUDES='$(glib_INCLUDES)'
3721 AC_SUBST(gobject_INCLUDES)
3722
3723 # gmodule:
3724 #   glib includes
3725 #   $(top_srcdir)/gmodule: for gmodule.h
3726 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3727 AC_SUBST(gmodule_INCLUDES)
3728
3729 # gio:
3730 #   same as gmodule
3731 gio_INCLUDES='$(gmodule_INCLUDES)'
3732 AC_SUBST(gio_INCLUDES)
3733
3734
3735 AC_CONFIG_FILES([
3736 glib-2.0.pc
3737 gmodule-2.0.pc
3738 gmodule-export-2.0.pc
3739 gmodule-no-export-2.0.pc
3740 gthread-2.0.pc
3741 gobject-2.0.pc
3742 gio-2.0.pc
3743 gio-unix-2.0.pc
3744 gio-windows-2.0.pc
3745 glib-zip
3746 glib-gettextize
3747 Makefile
3748 build/Makefile
3749 build/win32/Makefile
3750 build/win32/dirent/Makefile
3751 build/win32/vs9/Makefile
3752 build/win32/vs10/Makefile
3753 build/win32/vs11/Makefile
3754 glib/Makefile
3755 glib/glib.stp
3756 glib/libcharset/Makefile
3757 glib/gnulib/Makefile
3758 glib/pcre/Makefile
3759 glib/update-pcre/Makefile
3760 glib/tests/Makefile
3761 gmodule/Makefile
3762 gmodule/gmoduleconf.h
3763 gobject/Makefile
3764 gobject/gobject.stp
3765 gobject/glib-mkenums
3766 gobject/tests/Makefile
3767 gthread/Makefile
3768 gio/Makefile
3769 gio/gdbus-2.0/codegen/Makefile
3770 gio/gdbus-2.0/codegen/config.py
3771 gio/gnetworking.h
3772 gio/xdgmime/Makefile
3773 gio/inotify/Makefile
3774 gio/kqueue/Makefile
3775 gio/fen/Makefile
3776 gio/fam/Makefile
3777 gio/win32/Makefile
3778 gio/tests/Makefile
3779 gio/tests/gdbus-object-manager-example/Makefile
3780 gio/tests/services/Makefile
3781 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3782 po/Makefile.in
3783 docs/Makefile
3784 docs/reference/Makefile
3785 docs/reference/glib/Makefile
3786 docs/reference/glib/version.xml
3787 docs/reference/gobject/Makefile
3788 docs/reference/gobject/version.xml
3789 docs/reference/gio/Makefile
3790 docs/reference/gio/gdbus-object-manager-example/Makefile
3791 docs/reference/gio/version.xml
3792 tests/Makefile
3793 tests/gobject/Makefile
3794 tests/refcount/Makefile
3795 m4macros/Makefile
3796 ])
3797
3798 AC_CONFIG_COMMANDS([chmod-scripts],
3799 [chmod 0755 glib-zip
3800 chmod 0755 glib-gettextize
3801 chmod 0755 gobject/glib-mkenums])
3802
3803 # we want to invoke this macro solely so that the config.status script
3804 # and automake generated makefiles know about these generated files.
3805 # They are only needed to distcheck the package
3806 if false; then
3807   AC_CONFIG_FILES([
3808     INSTALL
3809     README
3810     config.h.win32
3811     glib/glibconfig.h.win32
3812     glib/makefile.msc
3813     glib/glib.rc
3814     gmodule/makefile.msc
3815     gmodule/gmodule.rc
3816     gobject/makefile.msc
3817     gobject/gobject.rc
3818     gthread/makefile.msc
3819     gthread/gthread.rc
3820     gio/gio.rc
3821     tests/makefile.msc
3822   ])
3823 fi
3824
3825 AC_OUTPUT