configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.14.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.22
  51 GSTPB_REQ=0.10.22.1
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 120 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 121
 122 dnl check for gconftool-2
 123 dnl this macro defines an am conditional, so it needs to be run always
 124 AM_GCONF_SOURCE_2
 125
 126 dnl check for documentation tools
 127 GTK_DOC_CHECK([1.3])
 128 AS_PATH_PYTHON([2.1])
 129 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 AC_CHECK_LIBM
 135 AC_SUBST(LIBM)
 136
 137 dnl *** checks for header files ***
 138
 139 dnl check if we have ANSI C header files
 140 AC_HEADER_STDC
 141
 142 dnl used by ext/wavpack
 143 AX_CREATE_STDINT_H
 144
 145 dnl used in gst/rtp/gstasteriskh263.c
 146 AC_CHECK_HEADERS([netinet/in.h])
 147 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 148 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 149
 150 dnl used in gst/udp
 151 AC_CHECK_HEADERS([sys/time.h])
 152
 153 dnl *** checks for types/defines ***
 154
 155 dnl Check for FIONREAD ioctl declaration.  This check is needed
 156 dnl for the UDP plugin to build on Solaris
 157 GST_CHECK_FIONREAD
 158
 159 dnl *** checks for structures ***
 160
 161 dnl *** checks for compiler characteristics ***
 162
 163 dnl check if we have GCC inline-asm
 164 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 165 if test x$HAVE_GCC_ASM = xyes ; then
 166   AC_DEFINE(HAVE_GCC_ASM, 1,
 167     [Define if compiler supports gcc inline assembly])
 168 fi
 169 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 170
 171 dnl *** checks for library functions ***
 172
 173 LIBS_SAVE=$LIBS
 174 LIBS="$LIBS $LIBM"
 175 AC_CHECK_FUNCS(rint sinh cosh asinh)
 176 LIBS=$LIBS_SAVE
 177
 178 dnl Check for mmap (needed by electricfence plugin)
 179 AC_FUNC_MMAP
 180 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 181
 182 dnl *** checks for dependency libraries ***
 183
 184 dnl GLib is required
 185 AG_GST_GLIB_CHECK([2.12])
 186
 187 dnl liboil is required
 188 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 189 if test "x$HAVE_LIBOIL" != "xyes"; then
 190   AC_ERROR([liboil-0.3.8 or later is required])
 191 fi
 192
 193 dnl checks for gstreamer
 194 dnl uninstalled is selected preferentially -- see pkg-config(1)
 195 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 196 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 197 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 198 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 199 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 200 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 201
 202 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 203 if test -z $GST_TOOLS_DIR; then
 204   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 205 fi
 206 AC_SUBST(GST_TOOLS_DIR)
 207
 208 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 209 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 210
 211 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 212
 213 dnl Check for documentation xrefs
 214 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 215 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 216 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 217 AC_SUBST(GLIB_PREFIX)
 218 AC_SUBST(GST_PREFIX)
 219 AC_SUBST(GSTPB_PREFIX)
 220
 221 dnl GTK is optional and used in examples
 222 HAVE_GTK=NO
 223 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 224 if test "x$HAVE_GTK_22" = "xyes"; then
 225   HAVE_GTK=yes
 226   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 227   AC_SUBST(GTK_VERSION)
 228   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 229   AC_SUBST(GTK_BASE_DIR)
 230   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 231   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 232   AC_SUBST(GTK_BASE_DIR)
 233 else
 234   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 235 fi
 236 if test "x$HAVE_GTK_20" = "xyes"; then
 237   HAVE_GTK=yes
 238 fi
 239 GTK_CFLAGS=$GTK2_CFLAGS
 240 GTK_LIBS=$GTK2_LIBS
 241 AC_SUBST(GTK_LIBS)
 242 AC_SUBST(GTK_CFLAGS)
 243 AC_SUBST(HAVE_GTK)
 244 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 245
 246 dnl should we install schemas ?
 247 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 248 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 249   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 250   if test x$GCONFTOOL = xno; then
 251     AC_MSG_WARN(Not installing GConf schemas)
 252     HAVE_GCONFTOOL="no"
 253   else
 254     HAVE_GCONFTOOL="yes"
 255   fi
 256   AC_SUBST(HAVE_GCONFTOOL)
 257 ])
 258
 259 dnl *** set variables based on configure arguments ***
 260
 261 dnl set license and copyright notice
 262 GST_LICENSE="LGPL"
 263 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 264 AC_SUBST(GST_LICENSE)
 265
 266 dnl set location of plugin directory
 267 AG_GST_SET_PLUGINDIR
 268
 269 dnl define an ERROR_CFLAGS Makefile variable
 270 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 271
 272 dnl define an ERROR_CXXFLAGS Makefile variable
 273 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 274
 275 dnl define correct level for debugging messages
 276 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 277
 278 dnl used in examples
 279 AG_GST_DEFAULT_ELEMENTS
 280
 281 dnl *** plug-ins to include ***
 282
 283 dnl these are all the gst plug-ins, compilable without additional libs
 284 dnl videofilter is at the top because others depend on it
 285 AG_GST_CHECK_PLUGIN(videofilter)
 286 AG_GST_CHECK_PLUGIN(alpha)
 287 AG_GST_CHECK_PLUGIN(apetag)
 288 AG_GST_CHECK_PLUGIN(audiofx)
 289 AG_GST_CHECK_PLUGIN(auparse)
 290 AG_GST_CHECK_PLUGIN(autodetect)
 291 AG_GST_CHECK_PLUGIN(avi)
 292 AG_GST_CHECK_PLUGIN(cutter)
 293 AG_GST_CHECK_PLUGIN(debug)
 294 AG_GST_CHECK_PLUGIN(effectv)
 295 AG_GST_CHECK_PLUGIN(equalizer)
 296 AG_GST_CHECK_PLUGIN(id3demux)
 297 AG_GST_CHECK_PLUGIN(icydemux)
 298 AG_GST_CHECK_PLUGIN(interleave)
 299 AG_GST_CHECK_PLUGIN(flx)
 300 AG_GST_CHECK_PLUGIN(goom)
 301 AG_GST_CHECK_PLUGIN(goom2k1)
 302 AG_GST_CHECK_PLUGIN(law)
 303 AG_GST_CHECK_PLUGIN(level)
 304 AG_GST_CHECK_PLUGIN(matroska)
 305 AG_GST_CHECK_PLUGIN(monoscope)
 306 AG_GST_CHECK_PLUGIN(multifile)
 307 AG_GST_CHECK_PLUGIN(multipart)
 308 AG_GST_CHECK_PLUGIN(qtdemux)
 309 AG_GST_CHECK_PLUGIN(replaygain)
 310 AG_GST_CHECK_PLUGIN(rtp)
 311 AG_GST_CHECK_PLUGIN(rtsp)
 312 AG_GST_CHECK_PLUGIN(smpte)
 313 AG_GST_CHECK_PLUGIN(spectrum)
 314 AG_GST_CHECK_PLUGIN(udp)
 315 AG_GST_CHECK_PLUGIN(videobox)
 316 AG_GST_CHECK_PLUGIN(videocrop)
 317 AG_GST_CHECK_PLUGIN(videomixer)
 318 AG_GST_CHECK_PLUGIN(wavenc)
 319 AG_GST_CHECK_PLUGIN(wavparse)
 320
 321 dnl *** checks for socket and nsl libraries ***
 322 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 323
 324 dnl disable gst plugins we might not be able to build on this
 325 dnl platform: udp and rtsp (ugly but minimally invasive)
 326 dnl FIXME: maybe move to sys
 327 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 328 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 329
 330 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 331   AG_GST_DISABLE_PLUGIN(udp)
 332   AG_GST_DISABLE_PLUGIN(rtsp)
 333 fi
 334
 335 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 336   WIN32_LIBS="-lws2_32"
 337   AC_SUBST(WIN32_LIBS)
 338 fi
 339
 340 dnl disable experimental plug-ins
 341 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 342   AG_GST_DISABLE_PLUGIN(monoscope)
 343 fi
 344
 345 dnl *** sys plug-ins ***
 346
 347 echo
 348 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 349 echo
 350
 351 dnl DirectDraw
 352 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 353 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 354   HAVE_DIRECTDRAW="no"
 355   save_CFLAGS="$CFLAGS"
 356   save_LDFLAGS="$LDFLAGS"
 357   save_LIBS="$LIBS"
 358   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 359   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 360   LIBS="$LIBS -lddraw -lgdi32"
 361   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 362   AC_LINK_IFELSE([
 363 #include <windows.h>
 364 #include <ddraw.h>
 365
 366 int main ()
 367 {
 368   GetStockObject(0);
 369   DirectDrawCreate(NULL, NULL, NULL);
 370
 371   return 0;
 372 }
 373 ],
 374     [HAVE_DIRECTDRAW="yes"],
 375     [HAVE_DIRECTDRAW="no"])
 376   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 377   CFLAGS=$save_CFLAGS
 378   LDFLAGS=$save_LDFLAGS
 379   LIBS=$save_LIBS
 380
 381   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 382     dnl this is much more than we want
 383     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 384     AC_SUBST(DIRECTDRAW_CFLAGS)
 385     AC_SUBST(DIRECTDRAW_LDFLAGS)
 386     AC_SUBST(DIRECTDRAW_LIBS)
 387   fi
 388   AC_SUBST(HAVE_DIRECTDRAW)
 389 ])
 390
 391 dnl DirectSound
 392 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 393 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 394   HAVE_DIRECTSOUND="no"
 395   save_CFLAGS="$CFLAGS"
 396   save_LDFLAGS="$LDFLAGS"
 397   save_LIBS="$LIBS"
 398   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 399   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 400   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 401   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 402   AC_LINK_IFELSE([
 403 #include <windows.h>
 404 #include <dxerr9.h>
 405 #include <dsound.h>
 406
 407 int main ()
 408 {
 409   DXGetErrorString9 (0);
 410   DirectSoundCreate(NULL, NULL, NULL);
 411
 412   return 0;
 413 }
 414 ],
 415     [HAVE_DIRECTSOUND="yes"],
 416     [HAVE_DIRECTSOUND="no"])
 417   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 418   CFLAGS=$save_CFLAGS
 419   LDFLAGS=$save_LDFLAGS
 420   LIBS=$save_LIBS
 421
 422   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 423     dnl this is much more than we want
 424     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 425     AC_SUBST(DIRECTSOUND_CFLAGS)
 426     AC_SUBST(DIRECTSOUND_LDFLAGS)
 427     AC_SUBST(DIRECTSOUND_LIBS)
 428   fi
 429   AC_SUBST(HAVE_DIRECTSOUND)
 430 ])
 431
 432 dnl *** OSS audio *** (Linux, *BSD)
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 434 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 435  HAVE_OSS="yes"
 436 dnl Linux and newer BSD versions :
 437  AC_CHECK_HEADER(sys/soundcard.h, [
 438    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 439    ] , [
 440 dnl Some old BSD versions and also newer OpenBSD versions :
 441    AC_CHECK_HEADER(soundcard.h, [
 442      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 443      ], [
 444   dnl Some old BSD versions :
 445      AC_CHECK_HEADER(machine/soundcard.h, [
 446        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 447          [Define if OSS includes are in /machine/])
 448        ], [
 449        HAVE_OSS="no"
 450      ])
 451    ])
 452  ])
 453 ])
 454
 455 dnl *** Sun Audio ***
 456 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 457 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 458   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 459 ])
 460
 461 dnl *** OSX Audio ***
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 463 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 464   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 465 ])
 466
 467 dnl *** OS X video ***
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 469 HAVE_OSX_VIDEO="no"
 470 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 471   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 472 ])
 473 dnl in case header OpenGL/gl.h is found on other platforms
 474 case "$host" in
 475   *-*darwin*)
 476     dnl do nothing
 477     ;;
 478   *)
 479     HAVE_OSX_VIDEO="no"
 480     ;;
 481 esac
 482
 483
 484 dnl *** Video 4 Linux 2 ***
 485 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 486 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 487 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 488 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 489   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 490   AC_TRY_COMPILE([
 491 #include <sys/types.h>
 492 #ifdef __sun /* Solaris */
 493 #include <sys/types.h>
 494 #include <sys/videodev2.h>
 495 #else /* Linux */
 496 #include <linux/types.h>
 497 #define _LINUX_TIME_H
 498 #define __user
 499 #include <linux/videodev2.h>
 500 #endif
 501 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 502 #error too early v4l2 version or no v4l2 at all
 503 #endif
 504     ], [
 505 return 0;
 506     ], [
 507       HAVE_GST_V4L2="yes"
 508       AC_MSG_RESULT(yes)
 509     ], [
 510       HAVE_GST_V4L2="no"
 511       AC_MSG_RESULT(no)
 512
 513       HAVE_VIDEODEV=no
 514       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 515       [
 516         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 517       ])
 518
 519       if test "x$HAVE_VIDEODEV" = "xyes"; then
 520         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 521         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 522       else
 523         AC_MSG_WARN([video4linux2 was not found])
 524       fi
 525     ])
 526
 527   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 528     dnl check for missing v4l2_buffer declaration (see #135919)
 529     MISSING_DECL=0
 530     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 531     AC_TRY_COMPILE([
 532 #include <sys/types.h>
 533 #ifdef __sun /* Solaris */
 534 #include <sys/types.h>
 535 #include <sys/videodev2.h>
 536 #else /* Linux */
 537 #include <linux/types.h>
 538 #define _LINUX_TIME_H
 539 #define __user
 540 #include <linux/videodev2.h>
 541 #endif
 542     ],[
 543 struct v4l2_buffer buf;
 544 buf.index = 0;
 545 return 0;
 546     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 547     if [ test x$MISSING_DECL = x1 ]; then
 548       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 549     fi
 550
 551     dnl check for XOverlay libraries
 552     AG_GST_CHECK_XV
 553   fi
 554 ])
 555
 556 # Make libv4l2 non-automagic
 557 AC_ARG_WITH([libv4l2],
 558   AC_HELP_STRING([--with-libv4l2],
 559     [support video buffer conversion using libv4l2]),
 560   [],
 561   [with_libv4l2=check])
 562 if test x$HAVE_GST_V4L2 = xyes; then
 563   if test x$with_libv4l2 != xno; then
 564       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 565           [ have_libv4l2=yes
 566             AC_DEFINE(HAVE_LIBV4L2, 1,
 567                 [Whether libv4l2 is available for video buffer conversion])
 568           ], [
 569           have_libv4l2=no
 570           ])
 571   else
 572     have_libv4l2=no
 573   fi
 574 fi
 575
 576 dnl Check for X11
 577 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 578 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 579                   [ximagesrc], [
 580   AC_PATH_XTRA
 581
 582   dnl now try to find the HEADER
 583   ac_cflags_save="$CFLAGS"
 584   ac_cppflags_save="$CPPFLAGS"
 585   CFLAGS="$CFLAGS $X_CFLAGS"
 586   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 587   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 588
 589   if test "x$HAVE_X" = "xno"
 590   then
 591     AC_MSG_NOTICE([cannot find X11 development files])
 592   else
 593     dnl this is much more than we want
 594     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 595     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 596     dnl it does not add the libs; therefore we add them here
 597     X_LIBS="$X_LIBS -lX11"
 598     AC_SUBST(X_CFLAGS)
 599     AC_SUBST(X_LIBS)
 600
 601     dnl check for Xfixes
 602     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 603     if test "x$HAVE_XFIXES" = "xyes"
 604     then
 605         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 606     fi
 607     AC_SUBST(XFIXES_LIBS)
 608     AC_SUBST(XFIXES_CFLAGS)
 609
 610     dnl check for Xdamage
 611     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 612     if test "x$HAVE_XDAMAGE" = "xyes"
 613     then
 614         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 615     fi
 616     AC_SUBST(XDAMAGE_LIBS)
 617     AC_SUBST(XDAMAGE_CFLAGS)
 618   fi
 619   AC_SUBST(HAVE_X)
 620   CFLAGS="$ac_cflags_save"
 621   CPPFLAGS="$ac_cppflags_save"
 622 ])
 623
 624 dnl FIXME: this should be rolled into the test above, it's just an additional
 625 dnl feature of the ximagesrc plug-in
 626 dnl This is the same as in gst-plugins-base
 627 dnl check for X Shm
 628 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 629 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 630   if test x$HAVE_X = xyes; then
 631     AC_CHECK_LIB(Xext, XShmAttach,
 632                  HAVE_XSHM="yes", HAVE_XSHM="no",
 633                  $X_LIBS)
 634     if test "x$HAVE_XSHM" = "xyes"; then
 635       XSHM_LIBS="-lXext"
 636     else
 637       dnl On AIX, it is in XextSam instead, but we still need -lXext
 638       AC_CHECK_LIB(XextSam, XShmAttach,
 639                    HAVE_XSHM="yes", HAVE_XSHM="no",
 640                    $X_LIBS)
 641       if test "x$HAVE_XSHM" = "xyes"; then
 642         XSHM_LIBS="-lXext -lXextSam"
 643       fi
 644     fi
 645   fi
 646 ], ,[
 647   AC_SUBST(HAVE_XSHM)
 648   AC_SUBST(XSHM_LIBS)
 649 ])
 650
 651 dnl for V4L2, we also need to know if we have XVIDEO
 652 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 653 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 654                   [], [
 655   AG_GST_CHECK_XV
 656 ])
 657
 658 dnl *** ext plug-ins ***
 659 dnl keep this list sorted alphabetically !
 660
 661 if test "x$BUILD_EXTERNAL" = "xyes"; then
 662
 663 echo
 664 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 665 echo
 666
 667 dnl *** aalib ***
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 669 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 670   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 671   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 672 ])
 673
 674 dnl *** annodex ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 676 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 677   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 678 ])
 679
 680 dnl *** cairo ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 682 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 683   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 684 ])
 685
 686 dnl **** ESound ****
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 688 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 689   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 690   if test $HAVE_ESD = no
 691   then
 692     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 693     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 694   fi
 695 ])
 696
 697 dnl *** FLAC ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 699 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 700   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.3)
 701 ])
 702
 703 dnl *** GConf ***
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 705 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 706   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 707 ])
 708
 709 dnl *** GDK pixbuf ***
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 711 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 712   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 713 ])
 714
 715 dnl *** HAL ***
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 717 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 718   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 719 ])
 720
 721 dnl *** jpeg ***
 722 dnl FIXME: we could use header checks here as well IMO
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 724 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 725   AC_ARG_WITH(jpeg-mmx,
 726     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 727   OLD_LIBS="$LIBS"
 728   if test x$with_jpeg_mmx != x; then
 729     LIBS="$LIBS -L$with_jpeg_mmx"
 730   fi
 731   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 732   JPEG_LIBS="$LIBS -ljpeg-mmx"
 733   LIBS="$OLD_LIBS"
 734   if test x$HAVE_JPEG != xyes; then
 735     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 736     JPEG_LIBS="-ljpeg"
 737   fi
 738   AC_SUBST(JPEG_LIBS)
 739 ])
 740
 741 dnl *** libcaca ***
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 743 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 744   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 745   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 746   if test "x$HAVE_LIBCACA" != "xyes"; then
 747     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 748     dnl see if it compilation works too, might not if we are cross-compiling
 749     if test "x$HAVE_LIBCACA" = "xyes"; then
 750       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 751                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 752     fi
 753   fi
 754 ])
 755
 756 dnl *** libdv ***
 757 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 758 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 759   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 760 ])
 761
 762 dnl *** libpng ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 764 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 765   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 766 ])
 767
 768 dnl *** pulseaudio ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 770 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 771   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.8)
 772   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 773   if test x$HAVE_PULSE_0_9_11 = xyes; then
 774     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 775   fi
 776   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 777   if test x$HAVE_PULSE_0_9_12 = xyes; then
 778     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 779   fi
 780   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 781   if test x$HAVE_PULSE_0_9_13 = xyes; then
 782     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 783   fi
 784 ])
 785
 786 dnl *** dv1394 ***
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 788 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 789   dnl first test for libraw1394 >= 1.2.1
 790   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 791   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 792   dnl now see how far we got
 793   if test x$HAVE_RAW1394 = xyes && \
 794      test x$HAVE_LIBIEC61883 = xyes; then
 795        AG_GST_CHECK_LIBHEADER(AVC1394,
 796         avc1394, avc1394_send_command, $RAW1394_LIBS,
 797         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 798        AG_GST_CHECK_LIBHEADER(ROM1394,
 799         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 800         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 801        if test x$HAVE_AVC1394 = xyes && \
 802           test x$HAVE_AVC1394 = xyes && \
 803           test x$HAVE_ROM1394 = xyes; then
 804           HAVE_DV1394=yes
 805           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 806           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 807           AC_SUBST(DV1394_CFLAGS)
 808           AC_SUBST(DV1394_LIBS)
 809         fi
 810   else
 811        if test x$HAVE_RAW1394 = xno; then
 812           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 813           AG_GST_CHECK_LIBHEADER(AVC1394,
 814            avc1394, avc1394_send_command, $RAW1394_LIBS,
 815            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 816           AG_GST_CHECK_LIBHEADER(ROM1394,
 817            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 818            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 819           if test x$HAVE_RAW1394 = xyes && \
 820              test x$HAVE_AVC1394 = xyes && \
 821              test x$HAVE_ROM1394 = xyes; then
 822              HAVE_DV1394=yes
 823              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 824              DV1394_CFLAGS="$RAW1394_CFLAGS"
 825              if test x$HAVE_LIBIEC61883 = xyes; then
 826                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 827                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 828              fi
 829              AC_SUBST(DV1394_CFLAGS)
 830              AC_SUBST(DV1394_LIBS)
 831            fi
 832          fi
 833   fi
 834 ])
 835
 836 dnl *** shout2 ***
 837 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 838 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 839   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 840   if test $HAVE_SHOUT2 = no
 841   then
 842     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 843     AC_SUBST(SHOUT2_CFLAGS)
 844     AC_SUBST(SHOUT2_LIBS)
 845   fi
 846 ])
 847
 848 dnl *** soup ***
 849 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 850 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 851   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 852     HAVE_SOUP="yes"
 853     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 854   ],[
 855     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.3.2, HAVE_SOUP="yes", [
 856       HAVE_SOUP="no"
 857       AC_MSG_RESULT(no)
 858     ])
 859   ])
 860   AC_SUBST(SOUP_CFLAGS)
 861   AC_SUBST(SOUP_LIBS)
 862 ])
 863
 864 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 865 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 866 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 867 dnl   speex_jitter.h is 1.1.x only
 868 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 869 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 870   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 871   if test $HAVE_SPEEX = no
 872   then
 873     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 874       AC_CHECK_HEADER(speex/speex_jitter.h, [
 875         dnl speex 1.1.x :
 876         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 877           dnl speex 1.1.5 or + :
 878           HAVE_SPEEX="yes"
 879           SPEEX_LIBS="-lspeex"
 880           AC_SUBST(SPEEX_CFLAGS)
 881           AC_SUBST(SPEEX_LIBS)
 882         ],[
 883           HAVE_SPEEX="no"
 884         ])
 885       ],[
 886         dnl speex 1.0.x :
 887           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 888             dnl speex 1.0.4
 889             HAVE_SPEEX="yes"
 890             SPEEX_LIBS="-lspeex"
 891             AC_SUBST(SPEEX_CFLAGS)
 892             AC_SUBST(SPEEX_LIBS)
 893
 894             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 895               [defined if speex 1.0.x API detected])
 896         ],[
 897             HAVE_SPEEX="no"
 898             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 899         ], [
 900 #include <speex/speex.h>
 901         ])
 902       ])
 903     ])
 904   fi
 905 ])
 906
 907 dnl *** taglib ***
 908 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 909 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 910   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 911   if test "x$HAVE_CXX" != "xyes"; then
 912     USE_TAGLIB=false
 913     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 914   else
 915     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 916     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 917         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 918       ], [
 919         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 920     ])
 921     AC_SUBST(TAGLIB_CXXFLAGS)
 922   fi
 923 ])
 924
 925 dnl *** wavpack ***
 926 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 927 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 928   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 929     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 930       HAVE_WAVPACK=yes
 931       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 932     ],[
 933       HAVE_WAVPACK=no
 934       AC_MSG_RESULT(no)
 935     ])
 936   ])
 937   AC_SUBST(WAVPACK_CFLAGS)
 938   AC_SUBST(WAVPACK_LIBS)
 939 ])
 940
 941 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 942 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 943 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 944   AG_GST_CHECK_LIBHEADER(ZLIB,
 945     z, uncompress,, zlib.h, [
 946     HAVE_ZLIB="yes"
 947     ZLIB_LIBS="-lz"
 948     AC_SUBST(ZLIB_LIBS)
 949   ])
 950 ])
 951
 952 dnl *** matroska prefers to have bz2 ***
 953 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 954 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 955   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 956   AC_SUBST(BZ2_LIBS)
 957 ])
 958
 959 else
 960
 961 dnl not building plugins with external dependencies,
 962 dnl but we still need to set the conditionals
 963 AM_CONDITIONAL(USE_AALIB, false)
 964 AM_CONDITIONAL(USE_ANNODEX, false)
 965 AM_CONDITIONAL(USE_BZ2, false)
 966 AM_CONDITIONAL(USE_CAIRO, false)
 967 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 968 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 969 AM_CONDITIONAL(USE_DV1394, false)
 970 AM_CONDITIONAL(USE_ESD, false)
 971 AM_CONDITIONAL(USE_FLAC, false)
 972 AM_CONDITIONAL(USE_GCONF, false)
 973 AM_CONDITIONAL(USE_GCONFTOOL, false)
 974 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 975 AM_CONDITIONAL(USE_GST_V4L2, false)
 976 AM_CONDITIONAL(USE_HAL, false)
 977 AM_CONDITIONAL(USE_JPEG, false)
 978 AM_CONDITIONAL(USE_LIBCACA, false)
 979 AM_CONDITIONAL(USE_LIBDV, false)
 980 AM_CONDITIONAL(USE_LIBPNG, false)
 981 AM_CONDITIONAL(USE_OSS, false)
 982 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 983 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 984 AM_CONDITIONAL(USE_PULSE, false)
 985 AM_CONDITIONAL(USE_SHOUT2, false)
 986 AM_CONDITIONAL(USE_SOUP, false)
 987 AM_CONDITIONAL(USE_SPEEX, false)
 988 AM_CONDITIONAL(USE_SUNAUDIO, false)
 989 AM_CONDITIONAL(USE_TAGLIB, false)
 990 AM_CONDITIONAL(USE_WAVPACK, false)
 991 AM_CONDITIONAL(USE_X, false)
 992 AM_CONDITIONAL(USE_XSHM, false)
 993 AM_CONDITIONAL(USE_XVIDEO, false)
 994 AM_CONDITIONAL(USE_ZLIB, false)
 995
 996 fi dnl of EXT plugins
 997
 998 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 999
1000 dnl Overview:
1001 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1002 dnl GST_*:              flags shared by all built objects
1003 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1004 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1005 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1006 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1007
1008 dnl GST_OPTION_CFLAGS
1009 if test "x$USE_DEBUG" = xyes; then
1010    PROFILE_CFLAGS="-g"
1011 fi
1012 AC_SUBST(PROFILE_CFLAGS)
1013
1014 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1015   dnl Define _only_ during CVS (not pre-releases or releases)
1016   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1017 else
1018   DEPRECATED_CFLAGS=""
1019 fi
1020 AC_SUBST(DEPRECATED_CFLAGS)
1021
1022 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1023 dnl at make time with e.g. make ERROR_CFLAGS=""
1024 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1025 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1026 AC_SUBST(GST_OPTION_CFLAGS)
1027 AC_SUBST(GST_OPTION_CXXFLAGS)
1028
1029 dnl our libraries need to be versioned correctly
1030 AC_SUBST(GST_LT_LDFLAGS)
1031
1032 dnl FIXME: do we want to rename to GST_ALL_* ?
1033 dnl prefer internal headers to already installed ones
1034 dnl also add builddir include for enumtypes and marshal
1035 dnl add ERROR_CFLAGS, but overridable
1036 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1037 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
1038 AC_SUBST(GST_CFLAGS)
1039 AC_SUBST(GST_CXXFLAGS)
1040 AC_SUBST(GST_LIBS)
1041
1042 dnl LDFLAGS really should only contain flags, not libs - they get added before
1043 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1044 GST_ALL_LDFLAGS="-no-undefined"
1045 AC_SUBST(GST_ALL_LDFLAGS)
1046
1047 dnl this really should only contain flags, not libs - they get added before
1048 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1049 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1050 AC_SUBST(GST_PLUGIN_LDFLAGS)
1051
1052 SHAVE_INIT([common])
1053 dnl *** output files ***
1054
1055 dnl keep this alphabetic per directory, please
1056 AC_CONFIG_FILES(
1057 Makefile
1058 common/shave
1059 common/shave-libtool
1060 gst/Makefile
1061 gst/alpha/Makefile
1062 gst/apetag/Makefile
1063 gst/audiofx/Makefile
1064 gst/auparse/Makefile
1065 gst/autodetect/Makefile
1066 gst/avi/Makefile
1067 gst/cutter/Makefile
1068 gst/debug/Makefile
1069 gst/effectv/Makefile
1070 gst/equalizer/Makefile
1071 gst/id3demux/Makefile
1072 gst/icydemux/Makefile
1073 gst/interleave/Makefile
1074 gst/goom/Makefile
1075 gst/goom2k1/Makefile
1076 gst/law/Makefile
1077 gst/level/Makefile
1078 gst/matroska/Makefile
1079 gst/monoscope/Makefile
1080 gst/multifile/Makefile
1081 gst/multipart/Makefile
1082 gst/qtdemux/Makefile
1083 gst/replaygain/Makefile
1084 gst/rtp/Makefile
1085 gst/rtsp/Makefile
1086 gst/smpte/Makefile
1087 gst/spectrum/Makefile
1088 gst/udp/Makefile
1089 gst/videobox/Makefile
1090 gst/videocrop/Makefile
1091 gst/videofilter/Makefile
1092 gst/videomixer/Makefile
1093 gst/wavenc/Makefile
1094 gst/wavparse/Makefile
1095 gst/flx/Makefile
1096 ext/jpeg/Makefile
1097 ext/Makefile
1098 ext/aalib/Makefile
1099 ext/annodex/Makefile
1100 ext/cairo/Makefile
1101 ext/dv/Makefile
1102 ext/esd/Makefile
1103 ext/flac/Makefile
1104 ext/gconf/Makefile
1105 ext/gdk_pixbuf/Makefile
1106 ext/hal/Makefile
1107 ext/ladspa/Makefile
1108 ext/libcaca/Makefile
1109 ext/libpng/Makefile
1110 ext/pulse/Makefile
1111 ext/raw1394/Makefile
1112 ext/shout2/Makefile
1113 ext/soup/Makefile
1114 ext/speex/Makefile
1115 ext/taglib/Makefile
1116 ext/wavpack/Makefile
1117 sys/Makefile
1118 sys/directdraw/Makefile
1119 sys/directsound/Makefile
1120 sys/oss/Makefile
1121 sys/sunaudio/Makefile
1122 sys/osxaudio/Makefile
1123 sys/osxvideo/Makefile
1124 sys/v4l2/Makefile
1125 sys/waveform/Makefile
1126 sys/ximage/Makefile
1127 po/Makefile.in
1128 tests/Makefile
1129 tests/check/Makefile
1130 tests/examples/Makefile
1131 tests/examples/audiofx/Makefile
1132 tests/examples/equalizer/Makefile
1133 tests/examples/level/Makefile
1134 tests/examples/rtp/Makefile
1135 tests/examples/spectrum/Makefile
1136 tests/files/Makefile
1137 tests/icles/Makefile
1138 gconf/Makefile
1139 gconf/gstreamer.schemas
1140 common/Makefile
1141 common/m4/Makefile
1142 m4/Makefile
1143 docs/Makefile
1144 docs/plugins/Makefile
1145 docs/version.entities
1146 win32/common/config.h
1147 pkgconfig/Makefile
1148 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1149 gst-plugins-good.spec
1150 )
1151 AC_OUTPUT
1152
1153 AG_GST_OUTPUT_PLUGINS