configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [29])
  30 m4_define([glib_micro_version], [9])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.10 no-define no-dist-gzip dist-bzip2 tar-ustar])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 GLIB_MAJOR_VERSION=glib_major_version
  70 GLIB_MINOR_VERSION=glib_minor_version
  71 GLIB_MICRO_VERSION=glib_micro_version
  72 GLIB_INTERFACE_AGE=glib_interface_age
  73 GLIB_BINARY_AGE=glib_binary_age
  74 GLIB_VERSION=glib_version
  75
  76 AC_SUBST(GLIB_MAJOR_VERSION)
  77 AC_SUBST(GLIB_MINOR_VERSION)
  78 AC_SUBST(GLIB_MICRO_VERSION)
  79 AC_SUBST(GLIB_VERSION)
  80 AC_SUBST(GLIB_INTERFACE_AGE)
  81 AC_SUBST(GLIB_BINARY_AGE)
  82
  83 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  84           [Define to the GLIB major version])
  85 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  86           [Define to the GLIB minor version])
  87 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  88           [Define to the GLIB micro version])
  89 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  90           [Define to the GLIB interface age])
  91 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  92           [Define to the GLIB binary age])
  93
  94 # libtool versioning
  95 LT_RELEASE=glib_lt_release
  96 LT_CURRENT=glib_lt_current
  97 LT_REVISION=glib_lt_revision
  98 LT_AGE=glib_lt_age
  99 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 100 AC_SUBST(LT_RELEASE)
 101 AC_SUBST(LT_CURRENT)
 102 AC_SUBST(LT_REVISION)
 103 AC_SUBST(LT_AGE)
 104 AC_SUBST(LT_CURRENT_MINUS_AGE)
 105
 106 dnl Initialize maintainer mode
 107 AM_MAINTAINER_MODE
 108
 109 dnl Checks for programs.
 110 AC_PROG_CC
 111 AC_PROG_CPP
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(threads,
 229               [AC_HELP_STRING([--enable-threads],
 230                               [turn on basic thread support [default=yes]
 231 ([=no] will override --with-threads)])],,
 232               [enable_threads=yes])
 233 AC_ARG_ENABLE(rebuilds,
 234               [AC_HELP_STRING([--disable-rebuilds],
 235                               [disable all source autogeneration rules])],,
 236               [enable_rebuilds=yes])
 237
 238 if test "x$enable_threads" != "xyes"; then
 239   enable_threads=no
 240 fi
 241
 242 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 243 if test "x$enable_gc_friendly" = "xyes"; then
 244   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 245   AC_MSG_RESULT([yes])
 246 else
 247   AC_MSG_RESULT([no])
 248 fi
 249
 250 AC_MSG_CHECKING([whether to disable memory pools])
 251 if test "x$disable_mem_pools" = "xno"; then
 252   AC_MSG_RESULT([no])
 253 else
 254   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 255   AC_SUBST(DISABLE_MEM_POOLS)
 256   AC_MSG_RESULT([yes])
 257 fi
 258
 259 dnl location to install runtime libraries, e.g. ../../lib to install
 260 dnl to /lib if libdir is /usr/lib
 261 AC_ARG_WITH(runtime-libdir,
 262            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 263                            [Install runtime libraries relative to libdir])],
 264            [],
 265            [with_runtime_libdir=""])
 266 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 267 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 268 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 269 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 270 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 271
 272 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 273 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 274 AC_LANG_SAVE
 275 AC_LANG_CPLUSPLUS
 276 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 277 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 278 AC_LANG_RESTORE
 279
 280 AM_PROG_CC_STDC
 281 AM_PROG_CC_C_O
 282 AC_PROG_INSTALL
 283
 284 AC_SYS_LARGEFILE
 285
 286 PKG_PROG_PKG_CONFIG(0.16)
 287
 288 if test "x$enable_debug" = "xyes"; then
 289   if test x$cflags_set != xset ; then
 290       case " $CFLAGS " in
 291       *[[\ \    ]]-g[[\ \       ]]*) ;;
 292       *) CFLAGS="$CFLAGS -g" ;;
 293       esac
 294   fi
 295
 296   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 297 else
 298   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 299
 300   if test "x$enable_debug" = "xno"; then
 301     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 302   fi
 303 fi
 304
 305 # Ensure MSVC-compatible struct packing convention is used when
 306 # compiling for Win32 with gcc.
 307 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 308 # gcc2 uses "-fnative-struct".
 309 if test x"$glib_native_win32" = xyes; then
 310   if test x"$GCC" = xyes; then
 311     msnative_struct=''
 312     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 313     if test -z "$ac_cv_prog_CC"; then
 314       our_gcc="$CC"
 315     else
 316       our_gcc="$ac_cv_prog_CC"
 317     fi
 318     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 319       2.)
 320         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 321           msnative_struct='-fnative-struct'
 322         fi
 323         ;;
 324       *)
 325         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 326           msnative_struct='-mms-bitfields'
 327         fi
 328         ;;
 329     esac
 330     if test x"$msnative_struct" = x ; then
 331       AC_MSG_RESULT([no way])
 332       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 333     else
 334       CFLAGS="$CFLAGS $msnative_struct"
 335       AC_MSG_RESULT([${msnative_struct}])
 336     fi
 337   fi
 338 fi
 339 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 340 AC_SUBST(GLIB_EXTRA_CFLAGS)
 341
 342 AC_EXEEXT
 343
 344 # define a MAINT-like variable REBUILD which is set if Perl
 345 # and awk are found, so autogenerated sources can be rebuilt
 346 AC_PROG_AWK
 347 AC_CHECK_PROGS(PERL, [perl5 perl])
 348 # We would like indent, but don't require it.
 349 AC_CHECK_PROG(INDENT, indent, indent)
 350 REBUILD=\#
 351 if test "x$enable_rebuilds" = "xyes" && \
 352      test -n "$PERL" && \
 353      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 354      test -n "$AWK" ; then
 355   REBUILD=
 356 fi
 357 AC_SUBST(REBUILD)
 358
 359 # Need full path to Perl for glib-mkenums
 360 #
 361 if test "x$PERL" != x ; then
 362   AC_PATH_PROG(PERL_PATH, [$PERL])
 363 fi
 364 if test "x$PERL_PATH" = x ; then
 365   PERL_PATH="/usr/bin/env perl"
 366 fi
 367 AC_SUBST(PERL_PATH)
 368
 369 # Need suitable python path for greport
 370 AM_PATH_PYTHON(2.4,,PYTHON="/usr/bin/env python2.4")
 371
 372
 373 dnl ***********************
 374 dnl *** Tests for iconv ***
 375 dnl ***********************
 376 dnl
 377 dnl We do this before the gettext checks, to avoid distortion
 378
 379 dnl On Windows we use a native implementation
 380
 381 if test x"$glib_native_win32" = xyes; then
 382   with_libiconv=native
 383 else
 384   AC_ARG_WITH(libiconv,
 385               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 386                               [use the libiconv library])],,
 387               [with_libiconv=maybe])
 388
 389   found_iconv=no
 390   case $with_libiconv in
 391     maybe)
 392       # Check in the C library first
 393       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 394       # Check if we have GNU libiconv
 395       if test $found_iconv = "no"; then
 396         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 397       fi
 398       # Check if we have a iconv in -liconv, possibly from vendor
 399       if test $found_iconv = "no"; then
 400         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 401       fi
 402       ;;
 403     no)
 404       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 405       ;;
 406     gnu|yes)
 407       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 408       ;;
 409     native)
 410       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 411       ;;
 412   esac
 413
 414   if test "x$found_iconv" = "xno" ; then
 415      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 416   fi
 417 fi
 418
 419 AC_ARG_ENABLE(iconv-cache,
 420               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 421                               [cache iconv descriptors [default=auto]])],,
 422               [enable_iconv_cache=auto])
 423
 424 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 425 case $enable_iconv_cache in
 426   auto)
 427     if test $ac_cv_gnu_library_2_1 = yes; then
 428       enable_iconv_cache=no
 429     else
 430       enable_iconv_cache=yes
 431     fi
 432   ;;
 433   yes|no)
 434   ;;
 435   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 436   ;;
 437 esac
 438
 439 if test $enable_iconv_cache = yes; then
 440    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 441 fi
 442
 443 AC_MSG_RESULT($enable_iconv_cache)
 444
 445
 446 dnl
 447 dnl zlib support
 448 dnl
 449 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 450 if test "x$found_zlib" = "xno" ; then
 451   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 452   if test "x$found_zlib" = "xno" ; then
 453     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 454   fi
 455   ZLIB_LIBS='-lz'
 456   AC_SUBST(ZLIB_LIBS)
 457 fi
 458
 459 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 460 AC_SUBST(LIBFFI_CFLAGS)
 461 AC_SUBST(LIBFFI_LIBS)
 462
 463 dnl
 464 dnl gettext support
 465 dnl
 466
 467 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 468 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 469 GLIB_GNU_GETTEXT
 470
 471 if test "$gt_cv_have_gettext" != "yes" ; then
 472   AC_MSG_ERROR([
 473 *** You must have either have gettext support in your C library, or use the
 474 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 475 ])
 476 fi
 477
 478 LIBS="$INTLLIBS $LIBS"
 479
 480 GETTEXT_PACKAGE=glib20
 481 AC_SUBST(GETTEXT_PACKAGE)
 482 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 483   [Define the gettext package to be used])
 484
 485 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 486
 487 dnl
 488 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 489 dnl
 490
 491 if test x"$glib_native_win32" != xyes; then
 492   if test x$with_libiconv != xno ; then
 493     case " $INTLLIBS " in
 494     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 495     *) ICONV_LIBS="-liconv" ;;
 496     esac
 497   fi
 498 fi
 499 AC_SUBST(ICONV_LIBS)
 500
 501 case $with_libiconv in
 502   gnu)
 503     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 504     ;;
 505   native)
 506     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 507     ;;
 508 esac
 509
 510 dnl Initialize libtool
 511 LT_PREREQ([2.2])
 512 LT_INIT([disable-static win32-dll])
 513 dnl when using libtool 2.x create libtool early, because it's used in configure
 514 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 515
 516
 517 if test "x$GCC" = "xyes"; then
 518   case " $CFLAGS " in
 519   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 520   *) CFLAGS="$CFLAGS -Wall" ;;
 521   esac
 522 fi
 523
 524 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 525
 526 if test "$glib_native_win32" = "yes"; then
 527   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 528     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 529   fi
 530   if test x$enable_static = xyes; then
 531     glib_win32_static_compilation=yes
 532     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 533 #define GOBJECT_STATIC_COMPILATION 1"
 534     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 535   fi
 536 fi
 537 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 538
 539 dnl
 540 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 541 dnl
 542 if test $cross_compiling != yes ; then
 543     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 544     glib_save_LIBS=$LIBS
 545     LIBS="$LIBS -lm"
 546     AC_TRY_RUN([#include <math.h>
 547                  int main (void) { return (log(1) != log(1.)); }],
 548          AC_MSG_RESULT(none needed),
 549          glib_save_CFLAGS=$CFLAGS
 550          CFLAGS="$CFLAGS -std1"
 551          AC_TRY_RUN([#include <math.h>
 552                      int main (void) { return (log(1) != log(1.)); }],
 553              AC_MSG_RESULT(-std1),
 554              AC_MSG_RESULT()
 555              CFLAGS=$glib_save_CFLAGS
 556              AC_MSG_WARN(
 557                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 558          )
 559     )
 560     LIBS=$glib_save_LIBS
 561 fi
 562
 563 dnl NeXTStep cc seems to need this
 564 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 565 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 566   AC_MSG_RESULT(none needed),
 567   glib_save_CFLAGS=$CFLAGS
 568   CFLAGS="$CFLAGS -posix"
 569   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 570     AC_MSG_RESULT(-posix),
 571     AC_MSG_RESULT()
 572     CFLAGS=$glib_save_CFLAGS
 573     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 574
 575 # Checks for header files.
 576 AC_HEADER_STDC
 577
 578 # Checks for library functions.
 579 AC_FUNC_VPRINTF
 580 AC_FUNC_ALLOCA
 581 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 582 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 583
 584 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 585 dnl be automatically defined, which we don't want to do
 586 dnl until we have checked this function is actually usable
 587 AC_CHECK_FUNC([qsort_r])
 588
 589 # BSD has a qsort_r with wrong argument order
 590 if test x$ac_cv_func_qsort_r = xyes ; then
 591   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 592   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 593   #define _GNU_SOURCE
 594   #include <stdlib.h>
 595
 596   static int
 597   cmp (const void *a, const void *b, void *c)
 598   {
 599     const int *ia = a;
 600     const int *ib = b;
 601
 602     if (*ia < *ib)
 603       return -1;
 604     else if (*ia > *ib)
 605       return 1;
 606     else
 607       return 0;
 608   }
 609
 610   int
 611   main (int argc, char **argv)
 612   {
 613     int arr[3] = { 1, 2, 0 };
 614     int d = 3;
 615
 616     qsort_r (arr, 3, sizeof (int), cmp, &d);
 617
 618     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 619       return 0;
 620     else
 621       return 1;
 622   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 623 fi
 624
 625 if test x$glib_cv_have_qsort_r = xyes ; then
 626   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 627 fi
 628
 629 AC_CHECK_SIZEOF(char)
 630 AC_CHECK_SIZEOF(short)
 631 AC_CHECK_SIZEOF(long)
 632 AC_CHECK_SIZEOF(int)
 633 AC_CHECK_SIZEOF(void *)
 634 AC_CHECK_SIZEOF(long long)
 635 AC_CHECK_SIZEOF(__int64)
 636
 637 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 638   :
 639 else
 640   AC_MSG_ERROR([
 641 *** GLib requires a 64 bit type. You might want to consider
 642 *** using the GNU C compiler.
 643 ])
 644 fi
 645
 646 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 647         # long long is a 64 bit integer.
 648         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 649         AC_CACHE_VAL(glib_cv_long_long_format,[
 650                 for format in ll q I64; do
 651                   AC_TRY_RUN([#include <stdio.h>
 652                         int main()
 653                         {
 654                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 655                           char buffer[1000];
 656                           sprintf (buffer, "%${format}u", a);
 657                           sscanf (buffer, "%${format}u", &b);
 658                           exit (b!=a);
 659                         }
 660                         ],
 661                         [glib_cv_long_long_format=${format}
 662                         break],
 663                         [],[:])
 664                 done])
 665         if test -n "$glib_cv_long_long_format"; then
 666           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 667           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 668           if test x"$glib_cv_long_long_format" = xI64; then
 669             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 670           fi
 671         else
 672           AC_MSG_RESULT(none)
 673         fi
 674 elif test x$ac_cv_sizeof___int64 = x8; then
 675         # __int64 is a 64 bit integer.
 676         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 677         # We know this is MSVCRT.DLL, and what the formats are
 678         glib_cv_long_long_format=I64
 679         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 680         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 681         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 682 fi
 683
 684 dnl long doubles were not used, and a portability problem
 685 dnl AC_C_LONG_DOUBLE
 686 AC_C_CONST
 687
 688 dnl ok, here we try to check whether the systems prototypes for
 689 dnl malloc and friends actually match the prototypes provided
 690 dnl by gmem.h (keep in sync). i currently only know how to check
 691 dnl this reliably with gcc (-Werror), improvements for other
 692 dnl compilers are apprechiated.
 693 SANE_MALLOC_PROTOS=no
 694 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 695 glib_save_CFLAGS=$CFLAGS
 696 if test "x$GCC" = "xyes"; then
 697   CFLAGS="$CFLAGS -Werror"
 698   AC_TRY_COMPILE([#include <stdlib.h>], [
 699     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 700     void* (*my_malloc_p)  (size_t)         = malloc;
 701     void  (*my_free_p)    (void*)          = free;
 702     void* (*my_realloc_p) (void*, size_t)  = realloc;
 703     my_calloc_p = 0;
 704     my_malloc_p = 0;
 705     my_free_p = 0;
 706     my_realloc_p = 0;
 707   ],
 708     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 709       [Define if you have correct malloc prototypes])
 710     SANE_MALLOC_PROTOS=yes)
 711 fi
 712 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 713 CFLAGS=$glib_save_CFLAGS
 714
 715 dnl
 716 dnl check in which direction the stack grows
 717 dnl
 718 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 719         AC_TRY_RUN([
 720         volatile int *a = 0, *b = 0;
 721         void foo (void);
 722         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 723         void foo (void) { volatile int x = 5; b = &x; }
 724         ],
 725         glib_cv_stack_grows=no
 726         ,
 727         glib_cv_stack_grows=yes
 728         ,)
 729 ])
 730
 731 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 732 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 733 dnl actually supported.
 734 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 735         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 736         __inline int foo () { return 0; }
 737         int main () { return foo (); }
 738         ]])],
 739         glib_cv_has__inline=yes
 740         ,
 741         glib_cv_has__inline=no
 742         ,)
 743 ])
 744 case x$glib_cv_has__inline in
 745 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 746 esac
 747 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 748         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 749         __inline__ int foo () { return 0; }
 750         int main () { return foo (); }
 751         ]])],
 752         glib_cv_has__inline__=yes
 753         ,
 754         glib_cv_has__inline__=no
 755         ,)
 756 ])
 757 case x$glib_cv_has__inline__ in
 758 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 759 esac
 760 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 761         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 762         #undef inline
 763         inline int foo () { return 0; }
 764         int main () { return foo (); }
 765         ]])],
 766         glib_cv_hasinline=yes
 767         ,
 768         glib_cv_hasinline=no
 769         ,)
 770 ])
 771 case x$glib_cv_hasinline in
 772 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 773 esac
 774
 775 # if we can use inline functions in headers
 776 AC_MSG_CHECKING(if inline functions in headers work)
 777 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 778 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 779 #  undef inline
 780 #  define inline __inline__
 781 #elif !defined (G_HAVE_INLINE)
 782 #  undef inline
 783 #  if defined (G_HAVE___INLINE__)
 784 #    define inline __inline__
 785 #  elif defined (G_HAVE___INLINE)
 786 #    define inline __inline
 787 #  endif
 788 #endif
 789
 790 int glib_test_func2 (int);
 791
 792 static inline int
 793 glib_test_func1 (void) {
 794   return glib_test_func2 (1);
 795 }
 796
 797 int
 798 main (void) {
 799   int i = 1;
 800 }]])],[g_can_inline=yes],[g_can_inline=no])
 801 AC_MSG_RESULT($g_can_inline)
 802
 803 dnl *** check for working do while(0) macros ***
 804 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 805         AC_TRY_COMPILE([],[
 806         #define STMT_START do
 807         #define STMT_END while(0)
 808         #define STMT_TEST STMT_START { i = 0; } STMT_END
 809         int main(void) { int i = 1; STMT_TEST; return i; }],
 810         [g_cv_support_dowhile_macros=yes],
 811         [g_cv_support_dowhile_macros=no],
 812         [g_cv_support_dowhile_macros=yes])
 813 ])
 814 if test x$g_cv_support_dowhile_macros = xyes; then
 815   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 816 fi
 817
 818 # check for flavours of varargs macros
 819 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 820 AC_TRY_COMPILE([],[
 821 int a(int p1, int p2, int p3);
 822 #define call_a(...) a(1,__VA_ARGS__)
 823 call_a(2,3);
 824 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 825 AC_MSG_RESULT($g_have_iso_c_varargs)
 826
 827 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 828 if test "$CXX" = ""; then
 829 dnl No C++ compiler
 830   g_have_iso_cxx_varargs=no
 831 else
 832   AC_LANG_CPLUSPLUS
 833   AC_TRY_COMPILE([],[
 834 int a(int p1, int p2, int p3);
 835 #define call_a(...) a(1,__VA_ARGS__)
 836 call_a(2,3);
 837 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 838   AC_LANG_C
 839 fi
 840 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 841
 842 AC_MSG_CHECKING(for GNUC varargs macros)
 843 AC_TRY_COMPILE([],[
 844 int a(int p1, int p2, int p3);
 845 #define call_a(params...) a(1,params)
 846 call_a(2,3);
 847 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 848 AC_MSG_RESULT($g_have_gnuc_varargs)
 849
 850 # check for GNUC visibility support
 851 AC_MSG_CHECKING(for GNUC visibility attribute)
 852 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 853 void
 854 __attribute__ ((visibility ("hidden")))
 855      f_hidden (void)
 856 {
 857 }
 858 void
 859 __attribute__ ((visibility ("internal")))
 860      f_internal (void)
 861 {
 862 }
 863 void
 864 __attribute__ ((visibility ("protected")))
 865      f_protected (void)
 866 {
 867 }
 868 void
 869 __attribute__ ((visibility ("default")))
 870      f_default (void)
 871 {
 872 }
 873 int main (int argc, char **argv)
 874 {
 875         f_hidden();
 876         f_internal();
 877         f_protected();
 878         f_default();
 879         return 0;
 880 }
 881 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 882 AC_MSG_RESULT($g_have_gnuc_visibility)
 883 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 884
 885 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 886 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 887 #else
 888 # include "error: this is not Sun Studio."
 889 #endif
 890 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 891 AC_MSG_RESULT($g_have_sunstudio_visibility)
 892 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 893
 894 # check for bytesex stuff
 895 AC_C_BIGENDIAN
 896 if test x$ac_cv_c_bigendian = xuniversal ; then
 897 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 898 #else
 899 #error Not a big endian.
 900 #endif],
 901     ac_cv_c_bigendian=yes
 902     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 903 #else
 904 #error Not a little endian.
 905 #endif],
 906     ac_cv_c_bigendian=no
 907     ,AC_MSG_WARN([Could not determine endianness.])))
 908 fi
 909
 910
 911 # check for header files
 912 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 913 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 914 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 915 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 916 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 917 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 918 AC_CHECK_HEADERS([linux/magic.h])
 919
 920 # check for structure fields
 921 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 922 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 923 #include <sys/stat.h>
 924 #include <unistd.h>
 925 #ifdef HAVE_SYS_STATFS_H
 926 #include <sys/statfs.h>
 927 #endif
 928 #ifdef HAVE_SYS_PARAM_H
 929 #include <sys/param.h>
 930 #endif
 931 #ifdef HAVE_SYS_MOUNT_H
 932 #include <sys/mount.h>
 933 #endif])
 934 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 935 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 936 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 937
 938 # Checks for libcharset
 939 AM_LANGINFO_CODESET
 940 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 941 AC_CHECK_FUNCS(setlocale)
 942
 943 # check additional type sizes
 944 AC_CHECK_SIZEOF(size_t)
 945
 946 dnl Try to figure out whether gsize, gssize should be long or int
 947 AC_MSG_CHECKING([for the appropriate definition for size_t])
 948
 949 case $ac_cv_sizeof_size_t in
 950   $ac_cv_sizeof_short)
 951       glib_size_type=short
 952       ;;
 953   $ac_cv_sizeof_int)
 954       glib_size_type=int
 955       ;;
 956   $ac_cv_sizeof_long)
 957       glib_size_type=long
 958       ;;
 959   $ac_cv_sizeof_long_long)
 960       glib_size_type='long long'
 961       ;;
 962   $ac_cv_sizeof__int64)
 963       glib_size_type='__int64'
 964       ;;
 965   *)  AC_MSG_ERROR([No type matching size_t in size])
 966       ;;
 967 esac
 968
 969 dnl If int/long are the same size, we see which one produces
 970 dnl warnings when used in the location as size_t. (This matters
 971 dnl on AIX with xlc)
 972 dnl
 973 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 974    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 975   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 976 #if defined(_AIX) && !defined(__GNUC__)
 977 #pragma options langlvl=stdc89
 978 #endif
 979 #include <stddef.h>
 980 int main ()
 981 {
 982   size_t s = 1;
 983   unsigned int *size_int = &s;
 984   return (int)*size_int;
 985 }
 986     ]])],glib_size_type=int,
 987       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 988 #if defined(_AIX) && !defined(__GNUC__)
 989 #pragma options langlvl=stdc89
 990 #endif
 991 #include <stddef.h>
 992 int main ()
 993 {
 994    size_t s = 1;
 995    unsigned long *size_long = &s;
 996    return (int)*size_long;
 997 }
 998         ]])],glib_size_type=long)])
 999 fi
1000
1001 AC_MSG_RESULT(unsigned $glib_size_type)
1002
1003 # Check for some functions
1004 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1005 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link statvfs statfs utimes getgrgid getpwuid)
1006 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
1007 # Check for high-resolution sleep functions
1008 AC_CHECK_FUNCS(splice)
1009
1010 AC_CHECK_HEADERS(crt_externs.h)
1011 AC_CHECK_FUNCS(_NSGetEnviron)
1012
1013 AC_FUNC_VSNPRINTF_C99
1014 AC_FUNC_PRINTF_UNIX98
1015
1016 # Internet address families
1017 if test $glib_native_win32 = yes; then
1018   glib_inet_includes=["
1019 #include <winsock2.h>
1020   "]
1021 else
1022   glib_inet_includes=["
1023 #include <sys/types.h>
1024 #include <sys/socket.h>
1025   "]
1026 fi
1027
1028 glib_failed=false
1029 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1030 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1031 # winsock defines this even though it doesn't support it
1032 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1033 if $glib_failed ; then
1034   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1035 fi
1036
1037 glib_failed=false
1038 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1039 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1040 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1041 if $glib_failed ; then
1042   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1043 fi
1044
1045 AC_CHECK_FUNCS(getprotobyname_r endservent)
1046 AC_CHECK_HEADERS([netdb.h wspiapi.h])
1047
1048 # For gio/libasyncns
1049 if test $glib_native_win32 = no; then
1050   AC_CHECK_FUNCS(strndup setresuid setreuid)
1051   AC_CHECK_HEADERS(sys/prctl.h arpa/nameser_compat.h)
1052
1053   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1054   AC_MSG_CHECKING([for res_query])
1055   AC_TRY_LINK([#include <sys/types.h>
1056 #include <netinet/in.h>
1057 #include <arpa/nameser.h>
1058 #include <resolv.h>],
1059               [res_query("test", 0, 0, (void *)0, 0);],
1060               [AC_MSG_RESULT([yes])],
1061               [save_libs="$LIBS"
1062                LIBS="-lresolv $LIBS"
1063                AC_TRY_LINK([#include <sys/types.h>
1064 #include <netinet/in.h>
1065 #include <arpa/nameser.h>
1066 #include <resolv.h>],
1067                            [res_query("test", 0, 0, (void *)0, 0);],
1068                            [AC_MSG_RESULT([in -lresolv])
1069                             LIBASYNCNS_LIBADD="-lresolv"],
1070                            [LIBS="-lbind $save_libs"
1071                             AC_TRY_LINK([#include <resolv.h>],
1072                                         [res_query("test", 0, 0, (void *)0, 0);],
1073                                         [AC_MSG_RESULT([in -lbind])
1074                                          LIBASYNCNS_LIBADD="-lbind"],
1075                                         [AC_MSG_ERROR(not found)])])
1076                LIBS="$save_libs"])
1077   AC_SUBST(LIBASYNCNS_LIBADD)
1078 fi
1079
1080 case $host in
1081   *-*-solaris* )
1082      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1083      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1084      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1085      ;;
1086 esac
1087
1088 dnl
1089 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1090 dnl
1091 if test "$ac_cv_func_statfs" = yes ; then
1092   AC_MSG_CHECKING([number of arguments to statfs()])
1093   AC_TRY_COMPILE([#include <unistd.h>
1094   #ifdef HAVE_SYS_PARAM_H
1095   #include <sys/param.h>
1096   #endif
1097   #ifdef HAVE_SYS_VFS_H
1098   #include <sys/vfs.h>
1099   #endif
1100   #ifdef HAVE_SYS_MOUNT_H
1101   #include <sys/mount.h>
1102   #endif
1103   #ifdef HAVE_SYS_STATFS_H
1104   #include <sys/statfs.h>
1105   #endif], [struct statfs st;
1106   statfs(NULL, &st);],[
1107     AC_MSG_RESULT([2])
1108     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1109     AC_TRY_COMPILE([#include <unistd.h>
1110   #ifdef HAVE_SYS_PARAM_H
1111   #include <sys/param.h>
1112   #endif
1113   #ifdef HAVE_SYS_VFS_H
1114   #include <sys/vfs.h>
1115   #endif
1116   #ifdef HAVE_SYS_MOUNT_H
1117   #include <sys/mount.h>
1118   #endif
1119   #ifdef HAVE_SYS_STATFS_H
1120   #include <sys/statfs.h>
1121   #endif], [struct statfs st;
1122   statfs(NULL, &st, sizeof (st), 0);],[
1123       AC_MSG_RESULT([4])
1124       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1125       AC_MSG_RESULT(unknown)
1126       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1127 fi
1128
1129 #
1130 # Check whether to use an included printf
1131 #
1132
1133 AC_ARG_ENABLE(included-printf,
1134               [AC_HELP_STRING([--enable-included-printf],
1135                               [use included printf [default=auto]])],
1136               enable_included_printf="$enableval")
1137
1138 need_included_printf=no
1139 if test "x$enable_included_printf" = "xyes" ; then
1140   need_included_printf=yes
1141 fi
1142 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1143   need_included_printf=yes
1144 fi
1145 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1146   need_included_printf=yes
1147 fi
1148 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1149    test -z "$glib_cv_long_long_format" ; then
1150   need_included_printf=yes
1151 fi
1152
1153 if test "x$enable_included_printf" = "xno" &&
1154    test "x$need_included_printf" = "xyes" ; then
1155   AC_MSG_ERROR([
1156 *** Your C library's printf doesn't appear to have the features that
1157 *** GLib needs, but you specified --enable-included-printf=no.])
1158 fi
1159
1160 enable_included_printf=$need_included_printf
1161
1162 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1163 if test "$enable_included_printf" != "yes" ; then
1164   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1165 else
1166   if test -z "$glib_cv_long_long_format" ; then
1167     glib_cv_long_long_format="ll"
1168   fi
1169   AC_DEFINE(HAVE_VASPRINTF,1)
1170 fi
1171
1172 # Checks needed for gnulib vasnprintf
1173 bh_C_SIGNED
1174 jm_AC_TYPE_LONG_LONG
1175 gt_TYPE_LONGDOUBLE
1176 gt_TYPE_WCHAR_T
1177 gt_TYPE_WINT_T
1178 AC_TYPE_SIZE_T
1179 AC_CHECK_TYPES(ptrdiff_t)
1180 jm_AC_TYPE_INTMAX_T
1181 AC_CHECK_FUNCS([snprintf wcslen])
1182 AC_FUNC_SNPRINTF_C99
1183
1184 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1185 # The check is borrowed from the PERL Configure script.
1186 if test "$ac_cv_func_memmove" != "yes"; then
1187   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1188     glib_cv_working_bcopy,[AC_TRY_RUN([
1189       int main() {
1190         char buf[128], abc[128], *b;
1191         int len, off, align;
1192         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1193         for (align = 7; align >= 0; align--) {
1194           for (len = 36; len; len--) {
1195             b = buf+align; bcopy(abc, b, len);
1196             for (off = 1; off <= len; off++) {
1197               bcopy(b, b+off, len); bcopy(b+off, b, len);
1198                 if (bcmp(b, abc, len)) return(1);
1199             }
1200           }
1201         }
1202         return(0);
1203       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1204
1205   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1206   if test "$glib_cv_working_bcopy" = "yes"; then
1207     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1208   fi
1209 fi
1210
1211 # Check for sys_errlist
1212 AC_MSG_CHECKING(for sys_errlist)
1213 AC_TRY_LINK(, [
1214 extern char *sys_errlist[];
1215 extern int sys_nerr;
1216 sys_errlist[sys_nerr-1][0] = 0;
1217 ], glib_ok=yes, glib_ok=no)
1218 AC_MSG_RESULT($glib_ok)
1219 if test "$glib_ok" = "no"; then
1220     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1221 fi
1222
1223 # Check for sys_siglist
1224 AC_MSG_CHECKING(for sys_siglist)
1225 AC_TRY_LINK(, [
1226 extern char *sys_siglist[];
1227 exit (sys_siglist[0]);
1228 ], glib_ok=yes, glib_ok=no)
1229 AC_MSG_RESULT($glib_ok)
1230 if test "$glib_ok" = "no"; then
1231     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1232 fi
1233
1234 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1235 AC_MSG_CHECKING(for sys_siglist declaration)
1236 AC_TRY_COMPILE([#include <signal.h>], [
1237 strlen (sys_siglist[0]);
1238 ], glib_ok=yes, glib_ok=no)
1239 AC_MSG_RESULT($glib_ok)
1240 if test "$glib_ok" = "no"; then
1241     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1242 fi
1243
1244 # Check if <sys/select.h> needs to be included for fd_set
1245 AC_MSG_CHECKING([for fd_set])
1246 AC_TRY_COMPILE([#include <sys/types.h>],
1247         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1248 if test "$gtk_ok" = "yes"; then
1249     AC_MSG_RESULT([yes, found in sys/types.h])
1250 else
1251     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1252     if test "$gtk_ok" = "yes"; then
1253         # *** FIXME: give it a different name
1254         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1255         AC_MSG_RESULT([yes, found in sys/select.h])
1256     else
1257         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1258         AC_MSG_RESULT(no)
1259     fi
1260 fi
1261
1262 dnl *** check for sane realloc() ***
1263 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1264         AC_TRY_RUN([#include <stdlib.h>
1265         int main() {
1266           return realloc (0, sizeof (int)) == 0;
1267         }],
1268         [glib_cv_sane_realloc=yes],
1269         [glib_cv_sane_realloc=no],
1270         [glib_cv_sane_realloc=yes])
1271 ])
1272 if test x$glib_cv_sane_realloc = xyes; then
1273   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1274 fi
1275
1276 dnl Check for nl_langinfo and CODESET
1277 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1278         AC_TRY_COMPILE([#include <langinfo.h>],
1279                 [char *codeset = nl_langinfo (CODESET);],
1280                 [glib_cv_langinfo_codeset=yes],
1281                 [glib_cv_langinfo_codeset=no])])
1282 if test x$glib_cv_langinfo_codeset = xyes; then
1283   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1284 fi
1285
1286 dnl ****************************************
1287 dnl *** posix_memalign                   ***
1288 dnl ****************************************
1289 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1290 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1291     glib_cv_compliant_posix_memalign=0
1292     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1293         AC_TRY_RUN([
1294                 #define _XOPEN_SOURCE 600
1295                 #include <stdlib.h> /* posix_memalign() should be defined here */
1296                 /* some systems break if #include <malloc.h> used */
1297                 static void test_memalign (size_t boundary, size_t size) {
1298                     void *mem = 0;
1299                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1300                         exit (1);
1301                     else
1302                       free (mem);
1303                 }
1304                 int main() {
1305                     test_memalign (  128,   128 - 2 * sizeof (void*));
1306                     test_memalign (  256,   256 - 2 * sizeof (void*));
1307                     test_memalign (  512,   512 - 2 * sizeof (void*));
1308                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1309                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1310                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1311                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1312                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1313                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1314                     exit (0); /* success */
1315                 }
1316                 ],
1317             [glib_cv_compliant_posix_memalign=1], [], [:])
1318       :
1319     fi
1320     ])
1321 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1322     AC_MSG_RESULT(yes)
1323     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1324 else
1325     AC_MSG_RESULT(no)
1326 fi
1327
1328
1329 dnl ****************************************
1330 dnl *** strlcpy/strlcat                  ***
1331 dnl ****************************************
1332 # Check for strlcpy
1333 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1334 AC_TRY_RUN([#include <stdlib.h>
1335 #include <string.h>
1336 int main() {
1337   char p[10];
1338   (void) strlcpy (p, "hi", 10);
1339   if (strlcat (p, "bye", 0) != 3)
1340     return 1;
1341   return 0;
1342 }], glib_cv_have_strlcpy=yes,
1343     glib_cv_have_strlcpy=no,
1344     glib_cv_have_strlcpy=no)])
1345 if test "$glib_cv_have_strlcpy" = "yes"; then
1346     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1347 fi
1348
1349
1350 dnl **********************
1351 dnl *** va_copy checks ***
1352 dnl **********************
1353 dnl we currently check for all three va_copy possibilities, so we get
1354 dnl all results in config.log for bug reports.
1355 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1356         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1357 #include <stdlib.h>
1358         void f (int i, ...) {
1359         va_list args1, args2;
1360         va_start (args1, i);
1361         va_copy (args2, args1);
1362         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1363           exit (1);
1364         va_end (args1); va_end (args2);
1365         }
1366         int main() {
1367           f (0, 42);
1368           return 0;
1369         }]])],
1370         [glib_cv_va_copy=yes],
1371         [glib_cv_va_copy=no])
1372 ])
1373 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1374         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1375 #include <stdlib.h>
1376         void f (int i, ...) {
1377         va_list args1, args2;
1378         va_start (args1, i);
1379         __va_copy (args2, args1);
1380         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1381           exit (1);
1382         va_end (args1); va_end (args2);
1383         }
1384         int main() {
1385           f (0, 42);
1386           return 0;
1387         }]])],
1388         [glib_cv___va_copy=yes],
1389         [glib_cv___va_copy=no])
1390 ])
1391
1392 if test "x$glib_cv_va_copy" = "xyes"; then
1393   g_va_copy_func=va_copy
1394 else if test "x$glib_cv___va_copy" = "xyes"; then
1395   g_va_copy_func=__va_copy
1396 fi
1397 fi
1398
1399 if test -n "$g_va_copy_func"; then
1400   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1401 fi
1402
1403 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1404         AC_TRY_RUN([#include <stdarg.h>
1405 #include <stdlib.h>
1406         void f (int i, ...) {
1407         va_list args1, args2;
1408         va_start (args1, i);
1409         args2 = args1;
1410         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1411           exit (1);
1412         va_end (args1); va_end (args2);
1413         }
1414         int main() {
1415           f (0, 42);
1416           return 0;
1417         }],
1418         [glib_cv_va_val_copy=yes],
1419         [glib_cv_va_val_copy=no],
1420         [glib_cv_va_val_copy=yes])
1421 ])
1422
1423 if test "x$glib_cv_va_val_copy" = "xno"; then
1424   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1425 fi
1426
1427 dnl ***********************
1428 dnl *** g_module checks ***
1429 dnl ***********************
1430 G_MODULE_LIBS=
1431 G_MODULE_LIBS_EXTRA=
1432 G_MODULE_PLUGIN_LIBS=
1433 if test x"$glib_native_win32" = xyes; then
1434   dnl No use for this on Win32
1435   G_MODULE_LDFLAGS=
1436 else
1437   export SED
1438   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1439 fi
1440 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1441 G_MODULE_NEED_USCORE=0
1442 G_MODULE_BROKEN_RTLD_GLOBAL=0
1443 G_MODULE_HAVE_DLERROR=0
1444 dnl *** force native WIN32 shared lib loader
1445 if test -z "$G_MODULE_IMPL"; then
1446   case "$host" in
1447   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1448   esac
1449 fi
1450 dnl *** force native AIX library loader
1451 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1452 if test -z "$G_MODULE_IMPL"; then
1453   case "$host" in
1454   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1455   esac
1456 fi
1457 dnl *** dlopen() and dlsym() in system libraries
1458 if test -z "$G_MODULE_IMPL"; then
1459         AC_CHECK_FUNC(dlopen,
1460                       [AC_CHECK_FUNC(dlsym,
1461                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1462                       [])
1463 fi
1464 dnl *** load_image (BeOS)
1465 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1466   AC_CHECK_LIB(root, load_image,
1467       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1468       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1469       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1470       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1471       [])
1472 fi
1473 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1474 if test -z "$G_MODULE_IMPL"; then
1475         AC_CHECK_FUNC(NSLinkModule,
1476                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1477                        G_MODULE_NEED_USCORE=1],
1478                       [])
1479 fi
1480 dnl *** dlopen() and dlsym() in libdl
1481 if test -z "$G_MODULE_IMPL"; then
1482         AC_CHECK_LIB(dl, dlopen,
1483                      [AC_CHECK_LIB(dl, dlsym,
1484                                    [G_MODULE_LIBS=-ldl
1485                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1486                      [])
1487 fi
1488 dnl *** shl_load() in libdld (HP-UX)
1489 if test -z "$G_MODULE_IMPL"; then
1490         AC_CHECK_LIB(dld, shl_load,
1491                 [G_MODULE_LIBS=-ldld
1492                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1493                 [])
1494 fi
1495 dnl *** additional checks for G_MODULE_IMPL_DL
1496 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1497         LIBS_orig="$LIBS"
1498         LDFLAGS_orig="$LDFLAGS"
1499         LIBS="$G_MODULE_LIBS $LIBS"
1500         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1501 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1502         echo "void glib_plugin_test(void) { }" > plugin.c
1503         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1504                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1505         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1506                 glib_cv_rtldglobal_broken,[
1507                 AC_TRY_RUN([
1508 #include <dlfcn.h>
1509 #ifndef RTLD_GLOBAL
1510 #  define RTLD_GLOBAL 0
1511 #endif
1512 #ifndef RTLD_LAZY
1513 #  define RTLD_LAZY 0
1514 #endif
1515 int glib_plugin_test;
1516 int main () {
1517     void *handle, *global, *local;
1518     global = &glib_plugin_test;
1519     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1520     if (!handle) return 0;
1521     local = dlsym (handle, "glib_plugin_test");
1522     return global == local;
1523 }                       ],
1524                         [glib_cv_rtldglobal_broken=no],
1525                         [glib_cv_rtldglobal_broken=yes],
1526                         [glib_cv_rtldglobal_broken=no])
1527                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1528                 rmdir .libs 2>/dev/null
1529         ])
1530         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1531                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1532         else
1533                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1534         fi
1535 dnl *** check whether we need preceeding underscores
1536         AC_CACHE_CHECK([for preceeding underscore in symbols],
1537                 glib_cv_uscore,[
1538                 AC_TRY_RUN([#include <dlfcn.h>
1539                 int glib_underscore_test (void) { return 42; }
1540                 int main() {
1541                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1542                   handle = dlopen ((void*)0, 0);
1543                   if (handle) {
1544                     f1 = dlsym (handle, "glib_underscore_test");
1545                     f2 = dlsym (handle, "_glib_underscore_test");
1546                   } return (!f2 || f1);
1547                 }],
1548                         [glib_cv_uscore=yes],
1549                         [glib_cv_uscore=no],
1550                         [])
1551                 rm -f plugin.c plugin.$ac_objext plugin.lo
1552         ])
1553         GLIB_ASSERT_SET(glib_cv_uscore)
1554         if test "x$glib_cv_uscore" = "xyes"; then
1555                 G_MODULE_NEED_USCORE=1
1556         else
1557                 G_MODULE_NEED_USCORE=0
1558         fi
1559
1560         LDFLAGS="$LDFLAGS_orig"
1561 dnl *** check for having dlerror()
1562         AC_CHECK_FUNC(dlerror,
1563                 [G_MODULE_HAVE_DLERROR=1],
1564                 [G_MODULE_HAVE_DLERROR=0])
1565         LIBS="$LIBS_orig"
1566 fi
1567 dnl *** done, have we got an implementation?
1568 if test -z "$G_MODULE_IMPL"; then
1569         G_MODULE_IMPL=0
1570         G_MODULE_SUPPORTED=false
1571 else
1572         G_MODULE_SUPPORTED=true
1573 fi
1574
1575 AC_MSG_CHECKING(for the suffix of module shared libraries)
1576 export SED
1577 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1578 eval $shrext_cmds
1579 module=yes eval std_shrext=$shrext_cmds
1580 # chop the initial dot
1581 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1582 AC_MSG_RESULT(.$glib_gmodule_suffix)
1583 # any reason it may fail?
1584 if test "x$glib_gmodule_suffix" = x; then
1585         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1586 fi
1587
1588 AC_SUBST(G_MODULE_SUPPORTED)
1589 AC_SUBST(G_MODULE_IMPL)
1590 AC_SUBST(G_MODULE_LIBS)
1591 AC_SUBST(G_MODULE_LIBS_EXTRA)
1592 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1593 AC_SUBST(G_MODULE_LDFLAGS)
1594 AC_SUBST(G_MODULE_HAVE_DLERROR)
1595 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1596 AC_SUBST(G_MODULE_NEED_USCORE)
1597 AC_SUBST(GLIB_DEBUG_FLAGS)
1598
1599 dnl **********************
1600 dnl *** g_spawn checks ***
1601 dnl **********************
1602
1603 AC_MSG_CHECKING(for gspawn implementation)
1604 case "$host" in
1605   *-*-mingw*)
1606     GSPAWN=gspawn-win32.lo
1607     ;;
1608   *)
1609     GSPAWN=gspawn.lo
1610     ;;
1611 esac
1612 AC_MSG_RESULT($GSPAWN)
1613 AC_SUBST(GSPAWN)
1614
1615 dnl *************************
1616 dnl *** GIOChannel checks ***
1617 dnl *************************
1618
1619 AC_MSG_CHECKING(for GIOChannel implementation)
1620 case "$host" in
1621   *-*-mingw*)
1622     GIO=giowin32.lo
1623     ;;
1624   *)
1625     GIO=giounix.lo
1626     ;;
1627 esac
1628 AC_MSG_RESULT($GIO)
1629 AC_SUBST(GIO)
1630
1631 dnl *********************************
1632 dnl *** Directory for GIO modules ***
1633 dnl *********************************
1634
1635 AC_ARG_WITH(gio-module-dir,
1636            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1637                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1638            [],
1639            [with_gio_module_dir='${libdir}/gio/modules'])
1640 GIO_MODULE_DIR=$with_gio_module_dir
1641 AC_SUBST(GIO_MODULE_DIR)
1642
1643 dnl **********************************
1644 dnl *** Check for libselinux (GIO) ***
1645 dnl **********************************
1646 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1647 msg_selinux=no
1648 SELINUX_LIBS=
1649 if test "x$enable_selinux" != "xno"; then
1650
1651  AC_CHECK_LIB(selinux, is_selinux_enabled,
1652    [AC_CHECK_HEADERS(selinux/selinux.h,
1653      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1654        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1655         SELINUX_LIBS="-lselinux"
1656         msg_selinux=yes])
1657      ])
1658    ])
1659 fi
1660 AC_SUBST(SELINUX_LIBS)
1661
1662 dnl *****************************
1663 dnl ** Check for inotify (GIO) **
1664 dnl *****************************
1665 inotify_support=no
1666 AC_CHECK_HEADERS([sys/inotify.h],
1667 [
1668         inotify_support=yes
1669         AC_CHECK_FUNCS(inotify_init1)
1670 ])
1671
1672 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1673
1674 dnl *********************************
1675 dnl ** Check for Solaris FEN (GIO) **
1676 dnl *********************************
1677 fen_support=no
1678 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1679 #include <port.h>
1680 #ifndef PORT_SOURCE_FILE
1681 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1682 #endif
1683 int main() { return 0; } ]])],
1684 [
1685         fen_support=yes
1686 ],)
1687
1688 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1689
1690 dnl ****************************
1691 dnl *** Checks for FAM (GIO) ***
1692 dnl ****************************
1693
1694 should_disable_fam=no
1695
1696 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1697                          [
1698                                 if test "x$enable_fam" = "xno"; then
1699                                         should_disable_fam=yes
1700                                         echo "Not building FAM support"
1701                                 fi
1702                          ]
1703                          )
1704 fam_support=no
1705 FAM_LIBS=
1706 if test "x$should_disable_fam" = "xno"; then
1707 AC_CHECK_LIB(fam, FAMOpen,
1708   [AC_CHECK_HEADERS(fam.h,
1709     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1710      AC_CHECK_LIB(fam, FAMNoExists,
1711                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1712      FAM_LIBS="-lfam"]
1713      fam_support=yes,
1714     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1715   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1716 AC_SUBST(FAM_LIBS)
1717 fi
1718 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1719
1720
1721 dnl *****************************
1722 dnl *** Check for xattr (GIO) ***
1723 dnl *****************************
1724 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1725 msg_xattr=no
1726 XATTR_LIBS=
1727 if test "x$enable_xattr" != "xno"; then
1728
1729 dnl either glibc or libattr can provide xattr support
1730
1731 dnl for both of them, we check for getxattr being in
1732 dnl the library and a valid xattr header.
1733
1734 dnl try glibc
1735  AC_CHECK_LIB(c, getxattr,
1736    [AC_CHECK_HEADERS(sys/xattr.h,
1737      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1738       msg_xattr=yes])
1739    ])
1740
1741   if test "x$msg_xattr" != "xyes"; then
1742 dnl   failure. try libattr
1743    AC_CHECK_LIB(attr, getxattr,
1744       [AC_CHECK_HEADERS(attr/xattr.h,
1745        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1746         XATTR_LIBS="-lattr"
1747         msg_xattr=yes])
1748       ])
1749   fi
1750
1751   if test "x$msg_xattr" = "xyes"; then
1752     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1753     AC_TRY_COMPILE([
1754       #include <stdio.h>
1755       #ifdef HAVE_SYS_TYPES_H
1756       #include <sys/types.h>
1757       #endif
1758       #ifdef HAVE_SYS_XATTR_H
1759       #include <sys/xattr.h>
1760       #elif HAVE_ATTR_XATTR_H
1761       #include <attr/xattr.h>
1762       #endif
1763     ],
1764     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1765     [
1766       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1767       AC_MSG_RESULT([yes])
1768     ],
1769     [AC_MSG_RESULT([no])]
1770     )
1771   fi
1772
1773 fi
1774 AC_SUBST(XATTR_LIBS)
1775
1776 dnl ****************************************
1777 dnl *** platform dependent source checks ***
1778 dnl ****************************************
1779
1780 AC_MSG_CHECKING(for platform-dependent source)
1781 case "$host" in
1782   *-*-cygwin*|*-*-mingw*)
1783     PLATFORMDEP=gwin32.lo
1784     ;;
1785   *)
1786     PLATFORMDEP=
1787     ;;
1788 esac
1789 AC_MSG_RESULT($PLATFORMDEP)
1790 AC_SUBST(PLATFORMDEP)
1791
1792 AC_MSG_CHECKING([whether to compile timeloop])
1793 case "$host" in
1794   *-*-cygwin*|*-*-mingw*|*-*-minix)
1795     enable_timeloop=no
1796     ;;
1797   *)
1798     enable_timeloop=yes
1799     ;;
1800 esac
1801 AC_MSG_RESULT($enable_timeloop)
1802 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1803
1804 AC_MSG_CHECKING([if building for some Win32 platform])
1805 case "$host" in
1806   *-*-mingw*|*-*-cygwin*)
1807     platform_win32=yes
1808     ;;
1809   *)
1810     platform_win32=no
1811     ;;
1812 esac
1813 AC_MSG_RESULT($platform_win32)
1814 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1815
1816 dnl ***********************
1817 dnl *** g_thread checks ***
1818 dnl ***********************
1819
1820 AC_ARG_WITH(threads,
1821            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1822                            [specify a thread implementation to use])],
1823            [if test "x$with_threads" = x; then
1824                 want_threads=yes
1825             else
1826                 want_threads=$with_threads
1827             fi],
1828            [want_threads=yes])
1829 if test "x$enable_threads" = "xno"; then
1830         want_threads=no
1831 fi
1832
1833 dnl error and warning message
1834 dnl *************************
1835
1836 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1837                 computer. GLib will not have a default thread implementation."
1838
1839 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1840                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1841                 compilation now, but then your programs might not work.
1842                 Please provide information on how it is done on your system."
1843
1844 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1845                 "
1846
1847 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1848                 provide information on your thread implementation.
1849                 You can also run 'configure --disable-threads'
1850                 to compile without thread support."
1851
1852 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1853                 functions will not be MT-safe during their first call because
1854                 there is no working 'getpwuid_r' on your system."
1855
1856 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1857                 because there is no 'localtime_r' on your system."
1858
1859 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1860                 crude surrogate will be used. If you happen to know a
1861                 yield function for your system, please inform the GLib
1862                 developers."
1863
1864 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1865                 threads on your system. Thus threads can only have the default
1866                 priority. If you happen to know these main/max
1867                 priorities, please inform the GLib developers."
1868
1869 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1870                 linking threaded applications. As GLib cannot do that
1871                 automatically, you will get an linkg error everytime you are
1872                 not using the right compiler. In that case you have to relink
1873                 with the right compiler. Ususally just '_r' is appended
1874                 to the compiler name."
1875
1876 dnl determination of thread implementation
1877 dnl ***************************************
1878
1879 # have_threads=no   means no thread support
1880 # have_threads=none means no default thread implementation
1881
1882 have_threads=no
1883 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1884                                 || test "x$want_threads" = xdce; then
1885         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1886         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1887         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1888         glib_save_CPPFLAGS="$CPPFLAGS"
1889         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1890         if test "x$have_threads" = xno; then
1891                 AC_TRY_COMPILE([#include <pthread.h>],
1892                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1893                         have_threads=posix)
1894         fi
1895         if test "x$have_threads" = xno; then
1896                 AC_TRY_COMPILE([#include <pthread.h>],
1897                         [pthread_mutex_t m;
1898                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1899                         have_threads=dce)
1900         fi
1901         # Tru64Unix requires -pthread to find pthread.h. See #103020
1902         CPPFLAGS="$CPPFLAGS -pthread"
1903         if test "x$have_threads" = xno; then
1904         AC_TRY_COMPILE([#include <pthread.h>],
1905                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1906                        have_threads=posix)
1907         fi
1908         CPPFLAGS="$glib_save_CPPFLAGS"
1909 fi
1910 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1911         case $host in
1912                 *-*-mingw*)
1913                 have_threads=win32
1914                 ;;
1915         esac
1916 fi
1917 if test "x$want_threads" = xnone; then
1918         have_threads=none
1919 fi
1920
1921 AC_MSG_CHECKING(for thread implementation)
1922
1923 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1924         AC_MSG_RESULT(none available)
1925         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1926 else
1927         AC_MSG_RESULT($have_threads)
1928 fi
1929
1930
1931 dnl determination of G_THREAD_CFLAGS
1932 dnl ********************************
1933
1934 G_THREAD_LIBS=
1935 G_THREAD_LIBS_EXTRA=
1936 G_THREAD_CFLAGS=
1937
1938 dnl
1939 dnl Test program for basic POSIX threads functionality
1940 dnl
1941 m4_define([glib_thread_test],[
1942 #include <pthread.h>
1943 int check_me = 0;
1944 void* func(void* data) {check_me = 42; return &check_me;}
1945 int main()
1946  { pthread_t t;
1947    void *ret;
1948    pthread_create (&t, $1, func, 0);
1949    pthread_join (t, &ret);
1950    return (check_me != 42 || ret != &check_me);
1951 }])
1952
1953 dnl
1954 dnl Test program for sched_get_priority_min()
1955 dnl
1956 m4_define([glib_sched_priority_test],[
1957 #include <sched.h>
1958 #include <errno.h>
1959 int main() {
1960     errno = 0;
1961     return sched_get_priority_min(SCHED_OTHER)==-1
1962            && errno != 0;
1963 }])
1964
1965 if test x"$have_threads" != xno; then
1966
1967   if test x"$have_threads" = xposix; then
1968     # First we test for posix, whether -pthread or -pthreads do the trick as
1969     # both CPPFLAG and LIBS.
1970     # One of them does for most gcc versions and some other platforms/compilers
1971     # too and could be considered as the canonical way to go.
1972     case $host in
1973       *-*-cygwin*|*-*-darwin*)
1974          # skip cygwin and darwin -pthread or -pthreads test
1975          ;;
1976       *-solaris*)
1977         # These compiler/linker flags work with both Sun Studio and gcc
1978         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1979         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1980         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1981         G_THREAD_LIBS="-lpthread -lthread"
1982         ;;
1983       *)
1984         for flag in pthread pthreads mt; do
1985           glib_save_CFLAGS="$CFLAGS"
1986           CFLAGS="$CFLAGS -$flag"
1987           AC_TRY_RUN(glib_thread_test(0),
1988                      glib_flag_works=yes,
1989                      glib_flag_works=no,
1990                      [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1991                                      glib_flag_works=yes,
1992                                      glib_flag_works=no)])
1993           CFLAGS="$glib_save_CFLAGS"
1994           if test $glib_flag_works = yes ; then
1995              G_THREAD_CFLAGS=-$flag
1996              G_THREAD_LIBS=-$flag
1997              break;
1998           fi
1999         done
2000          ;;
2001     esac
2002   fi
2003
2004   if test x"$G_THREAD_CFLAGS" = x; then
2005
2006     # The canonical -pthread[s] does not work. Try something different.
2007
2008     case $host in
2009         *-aix*)
2010                 if test x"$GCC" = xyes; then
2011                         # GCC 3.0 and above needs -pthread.
2012                         # Should be coverd by the case above.
2013                         # GCC 2.x and below needs -mthreads
2014                         G_THREAD_CFLAGS="-mthreads"
2015                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2016                 else
2017                         # We are probably using the aix compiler. Normaly a
2018                         # program would have to be compiled with the _r variant
2019                         # of the corresponding compiler, but we as GLib cannot
2020                         # do that: but the good news is that for compiling the
2021                         # only difference is the added -D_THREAD_SAFE compile
2022                         # option. This is according to the "C for AIX User's
2023                         # Guide".
2024                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2025                 fi
2026                 ;;
2027         *-dg-dgux*)  # DG/UX
2028                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2029                 ;;
2030         *-osf*)
2031                 # So we are using dce threads. posix threads are already
2032                 # catched above.
2033                 G_THREAD_CFLAGS="-threads"
2034                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2035                 ;;
2036         *-sysv5uw7*) # UnixWare 7
2037                 # We are not using gcc with -pthread. Catched above.
2038                 G_THREAD_CFLAGS="-Kthread"
2039                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2040                 ;;
2041         *-mingw*)
2042                 # No flag needed when using MSVCRT.DLL
2043                 G_THREAD_CFLAGS=""
2044                 ;;
2045         *)
2046                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2047                 ;;
2048     esac
2049
2050   fi
2051
2052     # if we are not finding the localtime_r function, then we probably are
2053     # not using the proper multithread flag
2054
2055     glib_save_CPPFLAGS="$CPPFLAGS"
2056     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2057
2058     # First we test, whether localtime_r is declared in time.h
2059     # directly. Then we test whether a macro localtime_r exists, in
2060     # which case localtime_r in the test program is replaced and thus
2061     # if we still find localtime_r in the output, it is not defined as
2062     # a macro.
2063
2064     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2065       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2066                                                            localtime_r(a,b)],
2067                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2068
2069     CPPFLAGS="$glib_save_CPPFLAGS"
2070
2071     AC_MSG_CHECKING(thread related cflags)
2072     AC_MSG_RESULT($G_THREAD_CFLAGS)
2073     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2074 fi
2075
2076 dnl determination of G_THREAD_LIBS
2077 dnl ******************************
2078
2079 mutex_has_default=no
2080 case $have_threads in
2081         posix|dce)
2082           glib_save_CPPFLAGS="$CPPFLAGS"
2083           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2084           if test x"$G_THREAD_LIBS" = x; then
2085             case $host in
2086               *-aix*)
2087                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2088                 # probably using the aix compiler.
2089                 AC_MSG_WARN($AIX_COMPILE_INFO)
2090                 ;;
2091               *)
2092                 G_THREAD_LIBS=error
2093                 glib_save_LIBS="$LIBS"
2094                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2095                         if test x"$thread_lib" = x; then
2096                                 add_thread_lib=""
2097                                 IN=""
2098                         else
2099                                 add_thread_lib="-l$thread_lib"
2100                                 IN=" in -l$thread_lib"
2101                         fi
2102                         if test x"$have_threads" = xposix; then
2103                                 defattr=0
2104                         else
2105                                 defattr=pthread_attr_default
2106                         fi
2107
2108                         LIBS="$add_thread_lib $glib_save_LIBS"
2109
2110                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2111                         AC_TRY_RUN(glib_thread_test($defattr),
2112                                    glib_result=yes,
2113                                    glib_result=no,
2114                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2115                                                    glib_result=yes,
2116                                                    glib_result=no)])
2117                         AC_MSG_RESULT($glib_result)
2118
2119                         if test "$glib_result" = "yes" ; then
2120                           G_THREAD_LIBS="$add_thread_lib"
2121                           break
2122                         fi
2123                 done
2124                 if test "x$G_THREAD_LIBS" = xerror; then
2125                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2126                 fi
2127                 LIBS="$glib_save_LIBS"
2128                 ;;
2129             esac
2130           fi
2131
2132           glib_save_LIBS="$LIBS"
2133           for thread_lib in "" rt rte; do
2134             if test x"$thread_lib" = x; then
2135               add_thread_lib=""
2136               IN=""
2137             else
2138               add_thread_lib="-l$thread_lib"
2139               IN=" in -l$thread_lib"
2140             fi
2141             LIBS="$add_thread_lib $glib_save_LIBS"
2142
2143             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2144             AC_TRY_RUN(glib_sched_priority_test,
2145                        glib_result=yes,
2146                        glib_result=no,
2147                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2148                                        glib_result=yes,
2149                                        glib_result=no)])
2150             AC_MSG_RESULT($glib_result)
2151
2152             if test "$glib_result" = "yes" ; then
2153                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2154                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2155                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2156                break
2157             fi
2158           done
2159           LIBS="$glib_save_LIBS"
2160           mutex_has_default=yes
2161           mutex_default_type='pthread_mutex_t'
2162           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2163           mutex_header_file='pthread.h'
2164           if test "x$have_threads" = "xposix"; then
2165             g_threads_impl="POSIX"
2166           else
2167             g_threads_impl="DCE"
2168             have_threads="posix"
2169           fi
2170           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2171           CPPFLAGS="$glib_save_CPPFLAGS"
2172           ;;
2173         win32)
2174            g_threads_impl="WIN32"
2175            ;;
2176         none|no)
2177            g_threads_impl="NONE"
2178            ;;
2179         *)
2180            g_threads_impl="NONE"
2181            G_THREAD_LIBS=error
2182            ;;
2183 esac
2184
2185 if test "x$G_THREAD_LIBS" = xerror; then
2186         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2187 fi
2188
2189 case $host in
2190   *-*-beos*)
2191     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2192     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2193     ;;
2194   *)
2195     ;;
2196 esac
2197
2198 AC_MSG_CHECKING(thread related libraries)
2199 AC_MSG_RESULT($G_THREAD_LIBS)
2200
2201 dnl check for mt safe function variants and some posix functions
2202 dnl ************************************************************
2203
2204 if test x"$have_threads" != xno; then
2205         glib_save_LIBS="$LIBS"
2206         # we are not doing the following for now, as this might require glib
2207         # to always be linked with the thread libs on some platforms.
2208         # LIBS="$LIBS $G_THREAD_LIBS"
2209         AC_CHECK_FUNCS(localtime_r gmtime_r)
2210         if test "$ac_cv_header_pwd_h" = "yes"; then
2211                 AC_CACHE_CHECK([for posix getpwuid_r],
2212                         ac_cv_func_posix_getpwuid_r,
2213                         [AC_TRY_RUN([
2214 #include <errno.h>
2215 #include <pwd.h>
2216 int main () {
2217     char buffer[10000];
2218     struct passwd pwd, *pwptr = &pwd;
2219     int error;
2220     errno = 0;
2221     error = getpwuid_r (0, &pwd, buffer,
2222                         sizeof (buffer), &pwptr);
2223    return (error < 0 && errno == ENOSYS)
2224            || error == ENOSYS;
2225 }                               ],
2226                                 [ac_cv_func_posix_getpwuid_r=yes],
2227                                 [ac_cv_func_posix_getpwuid_r=no])])
2228                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2229                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2230                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2231                                 [Have POSIX function getpwuid_r])
2232                 else
2233                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2234                                 ac_cv_func_nonposix_getpwuid_r,
2235                                 [AC_TRY_LINK([#include <pwd.h>],
2236                                         [char buffer[10000];
2237                                         struct passwd pwd;
2238                                         getpwuid_r (0, &pwd, buffer,
2239                                                         sizeof (buffer));],
2240                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2241                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2242                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2243                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2244                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2245                                         [Have non-POSIX function getpwuid_r])
2246                         fi
2247                 fi
2248         fi
2249         if test "$ac_cv_header_grp_h" = "yes"; then
2250                 AC_CACHE_CHECK([for posix getgrgid_r],
2251                         ac_cv_func_posix_getgrgid_r,
2252                         [AC_TRY_RUN([
2253 #include <errno.h>
2254 #include <grp.h>
2255 int main () {
2256     char buffer[10000];
2257     struct group grp, *grpptr = &grp;
2258     int error;
2259     errno = 0;
2260     error = getgrgid_r (0, &grp, buffer,
2261                         sizeof (buffer), &grpptr);
2262    return (error < 0 && errno == ENOSYS)
2263            || error == ENOSYS;
2264 }                              ],
2265                                [ac_cv_func_posix_getgrgid_r=yes],
2266                                [ac_cv_func_posix_getgrgid_r=no])])
2267                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2268                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2269                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2270                                 [Have POSIX function getgrgid_r])
2271                 else
2272                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2273                                 ac_cv_func_nonposix_getgrgid_r,
2274                                 [AC_TRY_LINK([#include <grp.h>],
2275                                         [char buffer[10000];
2276                                         struct group grp;
2277                                         getgrgid_r (0, &grp, buffer,
2278                                         sizeof (buffer));],
2279                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2280                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2281                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2282                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2283                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2284                                         [Have non-POSIX function getgrgid_r])
2285                         fi
2286                 fi
2287         fi
2288         LIBS="$G_THREAD_LIBS $LIBS"
2289         if test x"$have_threads" = xposix; then
2290                 glib_save_CPPFLAGS="$CPPFLAGS"
2291                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2292                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2293                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2294                 # This is not AC_CHECK_FUNC to also work with function
2295                 # name mangling in header files.
2296                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2297                 AC_TRY_LINK([#include <pthread.h>],
2298                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2299                         [AC_MSG_RESULT(yes)
2300                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2301                                   [Have function pthread_attr_setstacksize])],
2302                         [AC_MSG_RESULT(no)])
2303                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2304                 if test x"$posix_priority_min" = x; then
2305                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2306                                 PX_PRIO_MIN],,[
2307                                 posix_priority_min=PX_PRIO_MIN
2308                                 posix_priority_max=PX_PRIO_MAX])
2309                 fi
2310                 if test x"$posix_priority_min" = x; then
2311                         # AIX
2312                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2313                                 PTHREAD_PRIO_MIN],,[
2314                                 posix_priority_min=PTHREAD_PRIO_MIN
2315                                 posix_priority_max=PTHREAD_PRIO_MAX])
2316                 fi
2317                 if test x"$posix_priority_min" = x; then
2318                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2319                                 PRI_OTHER_MIN],,[
2320                                 posix_priority_min=PRI_OTHER_MIN
2321                                 posix_priority_max=PRI_OTHER_MAX])
2322                 fi
2323                 if test x"$posix_priority_min" = x; then
2324                         AC_MSG_RESULT(none found)
2325                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2326                         posix_priority_min=-1
2327                         posix_priority_max=-1
2328                 else
2329                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2330                         AC_MSG_CHECKING(for pthread_setschedparam)
2331                         AC_TRY_LINK([#include <pthread.h>],
2332                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2333                           [AC_MSG_RESULT(yes)
2334                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2335                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2336                           [AC_MSG_RESULT(no)
2337                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2338                 fi
2339                 posix_yield_func=none
2340                 AC_MSG_CHECKING(for posix yield function)
2341                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2342                                                         thr_yield; do
2343                         AC_TRY_LINK([#include <pthread.h>],
2344                                 [$yield_func()],
2345                                 [posix_yield_func="$yield_func"
2346                                 break])
2347                 done
2348                 if test x"$posix_yield_func" = xnone; then
2349                         AC_MSG_RESULT(none found)
2350                         AC_MSG_WARN($POSIX_NO_YIELD)
2351                         posix_yield_func="g_usleep(1000)"
2352                 else
2353                         AC_MSG_RESULT($posix_yield_func)
2354                         posix_yield_func="$posix_yield_func()"
2355                 fi
2356                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2357                 CPPFLAGS="$glib_save_CPPFLAGS"
2358
2359         elif test x"$have_threads" = xwin32; then
2360                 # It's a pointer to a private struct
2361                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2362         fi
2363
2364         LIBS="$glib_save_LIBS"
2365
2366         # now spit out all the warnings.
2367         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2368            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2369                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2370         fi
2371         if test "$ac_cv_func_localtime_r" != "yes"; then
2372                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2373         fi
2374 fi
2375
2376 if test x"$glib_cv_sizeof_system_thread" = x; then
2377    # use a pointer as a fallback.
2378    GLIB_SIZEOF(,void *, system_thread)
2379 fi
2380
2381 #
2382 # Hack to deal with:
2383 #
2384 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2385 #     building shared libraries with linux.
2386 #  b) FreeBSD doesn't do this either.
2387 #
2388 case $host in
2389   *-*-freebsd*|*-*-linux*)
2390     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2391     ;;
2392   *)
2393     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2394     ;;
2395 esac
2396
2397 AM_CONDITIONAL(HAVE_THREADS, [test "$have_threads" != "none"])
2398 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2399                    [Source file containing theread implementation])
2400 AC_SUBST(G_THREAD_CFLAGS)
2401 AC_SUBST(G_THREAD_LIBS)
2402 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2403 AC_SUBST(G_THREAD_LIBS_EXTRA)
2404
2405 dnl **********************************************
2406 dnl *** GDefaultMutex setup and initialization ***
2407 dnl **********************************************
2408 dnl
2409 dnl if mutex_has_default = yes, we also got
2410 dnl mutex_default_type, mutex_default_init and mutex_header_file
2411 if test $mutex_has_default = yes ; then
2412         glib_save_CPPFLAGS="$CPPFLAGS"
2413         glib_save_LIBS="$LIBS"
2414         LIBS="$G_THREAD_LIBS $LIBS"
2415         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2416         GLIB_SIZEOF([#include <$mutex_header_file>],
2417                     $mutex_default_type,
2418                     gmutex)
2419         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2420                            $mutex_default_type,
2421                            gmutex,
2422                            $glib_cv_sizeof_gmutex,
2423                            $mutex_default_init)
2424         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2425                 mutex_has_default=no
2426         fi
2427         CPPFLAGS="$glib_save_CPPFLAGS"
2428         LIBS="$glib_save_LIBS"
2429 fi
2430
2431 AC_CHECK_FUNCS(clock_gettime, [], [
2432   AC_CHECK_LIB(rt, clock_gettime, [
2433     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2434     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2435     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2436     GLIB_RT_LIBS="-lrt"
2437   ])
2438 ])
2439 AC_SUBST(GLIB_RT_LIBS)
2440
2441 AC_CACHE_CHECK(for monotonic clocks,
2442     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2443 #include <time.h>
2444 #include <unistd.h>
2445 int main() {
2446 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2447         #error No monotonic clock
2448 #endif
2449         return 0;
2450 }
2451 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2452 if test "$glib_cv_monotonic_clock" = "yes"; then
2453   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2454 fi
2455
2456
2457 dnl ********************************
2458 dnl *** g_atomic_* tests for gcc ***
2459 dnl ********************************
2460
2461 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2462
2463 glib_cv_gcc_has_builtin_atomic_operations=no
2464 if test x"$GCC" = xyes; then
2465   AC_MSG_CHECKING([whether GCC supports build-in atomic intrinsics])
2466   AC_TRY_LINK([],
2467               [int i;
2468                __sync_synchronize ();
2469                __sync_bool_compare_and_swap (&i, 0, 1);
2470                __sync_fetch_and_add (&i, 1);
2471               ],
2472               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2473               [glib_cv_gcc_has_builtin_atomic_operations=no])
2474
2475   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2476     case $host_cpu in
2477       i386)
2478         AC_MSG_RESULT([none])
2479         glib_memory_barrier_needed=no
2480         ;;
2481       i?86)
2482         AC_MSG_RESULT([i486])
2483         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2484                            [i486 atomic implementation])
2485         glib_memory_barrier_needed=no
2486         ;;
2487       sparc*)
2488         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2489                          when you are using a sparc with v9 instruction set (most
2490                          sparcs nowadays). This will make the code for atomic
2491                          operations much faster. The resulting code will not run
2492                          on very old sparcs though."
2493
2494         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2495           main ()
2496           {
2497             int tmp1, tmp2, tmp3;
2498             __asm__ __volatile__("casx [%2], %0, %1"
2499                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2500           }]])],
2501           AC_MSG_RESULT([sparcv9])
2502           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2503                              [sparcv9 atomic implementation]),
2504           AC_MSG_RESULT([no])
2505           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2506         glib_memory_barrier_needed=yes
2507         ;;
2508       alpha*)
2509         AC_MSG_RESULT([alpha])
2510         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2511                            [alpha atomic implementation])
2512         glib_memory_barrier_needed=yes
2513         ;;
2514       x86_64)
2515         AC_MSG_RESULT([x86_64])
2516         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2517                            [x86_64 atomic implementation])
2518         glib_memory_barrier_needed=no
2519        ;;
2520       powerpc*)
2521         AC_MSG_RESULT([powerpc])
2522         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2523                            [powerpc atomic implementation])
2524         glib_memory_barrier_needed=yes
2525         AC_MSG_CHECKING([whether asm supports numbered local labels])
2526         AC_TRY_COMPILE(
2527                        ,[
2528                        __asm__ __volatile__ ("1:       nop\n"
2529                                "         bne-    1b")
2530                        ],[
2531                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2532                        AC_MSG_RESULT([yes])
2533                        ],[
2534                        AC_MSG_RESULT([no])
2535                        ])
2536         ;;
2537       ia64)
2538         AC_MSG_RESULT([ia64])
2539         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2540                            [ia64 atomic implementation])
2541         glib_memory_barrier_needed=yes
2542         ;;
2543       s390|s390x)
2544         AC_MSG_RESULT([s390])
2545         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2546                            [s390 atomic implementation])
2547         glib_memory_barrier_needed=no
2548         ;;
2549       arm*)
2550         AC_MSG_RESULT([arm])
2551         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2552                            [arm atomic implementation])
2553         glib_memory_barrier_needed=no
2554         ;;
2555       crisv32*|etraxfs*)
2556         AC_MSG_RESULT([crisv32])
2557         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2558                            [crisv32 atomic implementation])
2559         glib_memory_barrier_needed=no
2560         ;;
2561       cris*|etrax*)
2562         AC_MSG_RESULT([cris])
2563         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2564                            [cris atomic implementation])
2565         glib_memory_barrier_needed=no
2566         ;;
2567       *)
2568         AC_MSG_RESULT([none])
2569         glib_memory_barrier_needed=yes
2570         ;;
2571     esac
2572 else
2573   if test $glib_native_win32 = yes; then
2574     # For Windows but not using gcc. No barriers needed then either.
2575     glib_memory_barrier_needed=no
2576   fi
2577 fi
2578
2579 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2580                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2581
2582 dnl ************************
2583 dnl ** Check for futex(2) **
2584 dnl ************************
2585 AC_MSG_CHECKING([for futex(2) system call])
2586 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2587 #include <linux/futex.h>
2588 #include <sys/syscall.h>
2589 #include <unistd.h>
2590 ],[
2591 int
2592 main (void)
2593 {
2594   /* it is not like this actually runs or anything... */
2595   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2596   return 0;
2597 }
2598 ])],
2599 [
2600   AC_MSG_RESULT(yes)
2601   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2602 ],
2603 [
2604   AC_MSG_RESULT(no)
2605 ])
2606
2607 dnl ****************************************
2608 dnl *** GLib POLL* compatibility defines ***
2609 dnl ****************************************
2610
2611 glib_poll_includes=["
2612 #include <sys/types.h>
2613 #include <sys/poll.h>
2614 "]
2615
2616 if test $ac_cv_header_sys_types_h = yes &&
2617    test $ac_cv_header_sys_poll_h = yes ; then
2618   glib_failed=false
2619   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2620   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2621   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2622   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2623   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2624   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2625   if $glib_failed ; then
2626     AC_MSG_ERROR([Could not determine values for POLL* constants])
2627   fi
2628 else
2629   glib_cv_value_POLLIN=1
2630   glib_cv_value_POLLOUT=4
2631   glib_cv_value_POLLPRI=2
2632   glib_cv_value_POLLERR=8
2633   glib_cv_value_POLLHUP=16
2634   glib_cv_value_POLLNVAL=32
2635 fi
2636
2637 AC_MSG_CHECKING([for broken poll])
2638 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2639         #include <stdlib.h>
2640         #include <fcntl.h>
2641         #include <poll.h>
2642         #ifdef HAVE_SYS_POLL_H
2643         #include <sys/poll.h>
2644         #endif
2645         int main(void) {
2646           struct pollfd fds[1];
2647           int fd;
2648           fd = open("/dev/null", 1);
2649           fds[0].fd = fd;
2650           fds[0].events = POLLIN;
2651           fds[0].revents = 0;
2652           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2653                 exit(1);  /* Does not work for devices -- fail */
2654           }
2655           exit(0);
2656         }]])],
2657   [broken_poll=no],
2658   [broken_poll=yes
2659    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2660   [broken_poll="no (cross compiling)"])
2661 AC_MSG_RESULT($broken_poll)
2662
2663 dnl *********************
2664 dnl *** GRegex checks ***
2665 dnl *********************
2666 PCRE_REQUIRED_VERSION=8.11
2667
2668 # Check if we should compile GRegex
2669 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2670               [disable the compilation of GRegex]),
2671 [case "${enableval}" in
2672   yes) enable_regex=true ;;
2673   no)  enable_regex=false ;;
2674   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2675 esac],
2676 [enable_regex=true])
2677
2678 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2679
2680 if test x$enable_regex = xtrue; then
2681   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2682   # Check if we should use the internal or the system-supplied pcre
2683   AC_ARG_WITH(pcre,
2684              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2685                              [specify whether to use the internal or the
2686                               system-supplied PCRE library])])
2687
2688   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2689
2690   if test "x$with_pcre" = xsystem; then
2691     PKG_CHECK_MODULES(PCRE,
2692                       libpcre >= $PCRE_REQUIRED_VERSION)
2693     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2694                    glib_save_CFLAGS="$CFLAGS"
2695                    glib_save_LIBS="$LIBS"
2696                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2697                    AC_TRY_RUN([#include <pcre.h>
2698                                int main () {
2699                                  int support;
2700                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2701                                  if (!support)
2702                                    return 1;
2703                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2704                                  if (!support)
2705                                    return 1;
2706                                  return 0;
2707                                }],
2708                    glib_cv_pcre_has_unicode=yes,
2709                    glib_cv_pcre_has_unicode=no,
2710                    glib_cv_pcre_has_unicode=yes)
2711                    CFLAGS="$glib_save_CFLAGS"
2712                    LIBS="$glib_save_LIBS"
2713         ])
2714     if test "$glib_cv_pcre_has_unicode" = "no"; then
2715       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2716     fi
2717     AC_SUBST(PCRE_CFLAGS)
2718     AC_SUBST(PCRE_LIBS)
2719     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2720     PCRE_REQUIRES=libpcre
2721     AC_SUBST(PCRE_REQUIRES)
2722   else
2723     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2724     if test x"$GCC" = xyes; then
2725       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2726       save_CFLAGS="$CFLAGS"
2727       CFLAGS="$CFLAGS -Wno-pointer-sign"
2728       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2729                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2730       CFLAGS="$save_CFLAGS"
2731     fi
2732   fi
2733   AC_SUBST(PCRE_WARN_CFLAGS)
2734 else
2735   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2736 fi
2737
2738 dnl **********************
2739 dnl *** Win32 API libs ***
2740 dnl **********************
2741
2742 case $host in
2743   *-*-cygwin*)
2744         G_LIBS_EXTRA="-luser32 -lkernel32"
2745     ;;
2746   *-*-mingw*)
2747         G_LIBS_EXTRA="-lws2_32 -lole32"
2748     ;;
2749   *)
2750         G_LIBS_EXTRA=""
2751     ;;
2752 esac
2753 AC_SUBST(G_LIBS_EXTRA)
2754
2755 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2756 dnl since we need it for g_iconv()
2757
2758 AC_MSG_CHECKING([for EILSEQ])
2759 AC_TRY_COMPILE([
2760 #include <errno.h>
2761 ],
2762 [
2763 int error = EILSEQ;
2764 ], have_eilseq=yes, have_eilseq=no);
2765 AC_MSG_RESULT($have_eilseq)
2766
2767 dnl ******************************************************************
2768 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2769 dnl *** glib-compile-schemas in PATH                               ***
2770 dnl ******************************************************************
2771
2772 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2773
2774 if test $cross_compiling = yes; then
2775   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2776   if test x$GLIB_GENMARSHAL = xno; then
2777     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2778   fi
2779
2780   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2781   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2782     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2783   fi
2784 fi
2785
2786 dnl **************************
2787 dnl *** Checks for gtk-doc ***
2788 dnl **************************
2789
2790 GTK_DOC_CHECK([1.15])
2791
2792 AC_ARG_ENABLE(man,
2793               [AC_HELP_STRING([--enable-man],
2794                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2795               enable_man=no)
2796
2797 if test "${enable_man}" != no; then
2798 dnl
2799 dnl Check for xsltproc
2800 dnl
2801 AC_PATH_PROG([XSLTPROC], [xsltproc])
2802   if test -z "$XSLTPROC"; then
2803     enable_man=no
2804   fi
2805
2806   dnl check for DocBook DTD and stylesheets in the local catalog.
2807   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2808      [DocBook XML DTD V4.1.2],,enable_man=no)
2809   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2810      [DocBook XSL Stylesheets],,enable_man=no)
2811 fi
2812
2813 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2814
2815 dnl
2816 dnl Tracing
2817 dnl
2818
2819 AC_ARG_ENABLE([dtrace],
2820              [AS_HELP_STRING([--enable-dtrace],
2821                               [Enable inclusion of dtrace trace support])])
2822 have_dtrace=no
2823 AC_MSG_CHECKING([whether to include dtrace tracing support])
2824 if test "x$enable_dtrace" != xno; then
2825   if test x$glib_have_carbon = xyes; then
2826     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2827   else
2828     AC_MSG_RESULT([yes])
2829     AC_CHECK_PROGS(DTRACE, dtrace)
2830     if test -z "$DTRACE"; then
2831       if test "x$enable_dtrace" = xyes; then
2832         AC_MSG_ERROR([dtrace not found])
2833       fi
2834     else
2835       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2836                       [if test "x$enable_dtrace" = xyes; then
2837                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2838                        fi])
2839     fi
2840   fi
2841 else
2842   AC_MSG_RESULT([no])
2843 fi
2844 if test "x$have_dtrace" = xyes; then
2845   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2846 fi
2847 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2848
2849 AC_MSG_CHECKING([whether to include systemtap tracing support])
2850 AC_ARG_ENABLE([systemtap],
2851              [AS_HELP_STRING([--enable-systemtap],
2852                               [Enable inclusion of systemtap trace support])])
2853 have_systemtap=no
2854 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2855   have_systemtap=yes
2856 fi
2857 AC_MSG_RESULT(${have_systemtap})
2858
2859 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2860
2861 AC_ARG_WITH([tapset-install-dir],
2862             [AS_HELP_STRING([--with-tapset-install-dir],
2863             [The absolute path where the systemtap tapsets will be installed])],
2864             [if test "x${withval}" = x; then
2865                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2866              else
2867                ABS_TAPSET_DIR="${withval}"
2868               fi],
2869             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2870 AC_SUBST(ABS_TAPSET_DIR)
2871
2872 dnl ************************************
2873 dnl *** Enable lcov coverage reports ***
2874 dnl ************************************
2875
2876 AC_ARG_ENABLE(gcov,
2877   AS_HELP_STRING([--enable-gcov],
2878                  [Enable gcov]),
2879   [use_gcov=$enableval], [use_gcov=no])
2880
2881 if test "x$use_gcov" = "xyes"; then
2882   dnl we need gcc:
2883   if test "$GCC" != "yes"; then
2884     AC_MSG_ERROR([GCC is required for --enable-gcov])
2885   fi
2886
2887   dnl Check if ccache is being used
2888   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2889   case `$SHTOOL path $CC` in
2890     *ccache*[)] gcc_ccache=yes;;
2891     *[)] gcc_ccache=no;;
2892   esac
2893
2894   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2895     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2896   fi
2897
2898   ltp_version_list="1.6 1.7 1.8"
2899   AC_CHECK_PROG(LTP, lcov, lcov)
2900   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2901
2902   if test "$LTP"; then
2903     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2904       glib_cv_ltp_version=invalid
2905       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2906       for ltp_check_version in $ltp_version_list; do
2907         if test "$ltp_version" = "$ltp_check_version"; then
2908           glib_cv_ltp_version="$ltp_check_version (ok)"
2909         fi
2910       done
2911     ])
2912   else
2913     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2914     AC_MSG_ERROR([$ltp_msg])
2915   fi
2916
2917   case $glib_cv_ltp_version in
2918     ""|invalid[)]
2919       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2920       AC_MSG_ERROR([$ltp_msg])
2921       LTP="exit 0;"
2922       ;;
2923   esac
2924
2925   if test -z "$LTP_GENHTML"; then
2926     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2927   fi
2928
2929   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2930
2931   dnl Remove all optimization flags from CFLAGS
2932   changequote({,})
2933   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2934   changequote([,])
2935
2936   dnl Add the special gcc flags
2937   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2938   LDFLAGS="$LDFLAGS -lgcov"
2939 fi
2940
2941 dnl ******************************
2942 dnl *** output the whole stuff ***
2943 dnl ******************************
2944
2945 dnl this section will only be run if config.status is invoked with no
2946 dnl arguments, or with "glib/glibconfig.h" as an argument.
2947 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2948 [
2949         outfile=glib/glibconfig.h-tmp
2950         cat > $outfile <<\_______EOF
2951 /* glibconfig.h
2952  *
2953  * This is a generated file.  Please modify 'configure.ac'
2954  */
2955
2956 #ifndef __G_LIBCONFIG_H__
2957 #define __G_LIBCONFIG_H__
2958
2959 #include <glib/gmacros.h>
2960
2961 _______EOF
2962
2963         if test x$glib_limits_h = xyes; then
2964           echo '#include <limits.h>' >> $outfile
2965         fi
2966         if test x$glib_float_h = xyes; then
2967           echo '#include <float.h>' >> $outfile
2968         fi
2969         if test x$glib_values_h = xyes; then
2970           echo '#include <values.h>' >> $outfile
2971         fi
2972         if test "$glib_header_alloca_h" = "yes"; then
2973           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2974         fi
2975         if test x$glib_sys_poll_h = xyes; then
2976           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2977         fi
2978         if test x$glib_included_printf != xyes; then
2979           echo "
2980 /* Specifies that GLib's g_print*() functions wrap the
2981  * system printf functions.  This is useful to know, for example,
2982  * when using glibc's register_printf_function().
2983  */" >> $outfile
2984           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2985         fi
2986
2987         cat >> $outfile <<_______EOF
2988
2989 G_BEGIN_DECLS
2990
2991 #define G_MINFLOAT      $glib_mf
2992 #define G_MAXFLOAT      $glib_Mf
2993 #define G_MINDOUBLE     $glib_md
2994 #define G_MAXDOUBLE     $glib_Md
2995 #define G_MINSHORT      $glib_ms
2996 #define G_MAXSHORT      $glib_Ms
2997 #define G_MAXUSHORT     $glib_Mus
2998 #define G_MININT        $glib_mi
2999 #define G_MAXINT        $glib_Mi
3000 #define G_MAXUINT       $glib_Mui
3001 #define G_MINLONG       $glib_ml
3002 #define G_MAXLONG       $glib_Ml
3003 #define G_MAXULONG      $glib_Mul
3004
3005 _______EOF
3006
3007
3008         ### this should always be true in a modern C/C++ compiler
3009         cat >>$outfile <<_______EOF
3010 typedef signed char gint8;
3011 typedef unsigned char guint8;
3012 _______EOF
3013
3014
3015         if test -n "$gint16"; then
3016           cat >>$outfile <<_______EOF
3017 typedef signed $gint16 gint16;
3018 typedef unsigned $gint16 guint16;
3019 #define G_GINT16_MODIFIER $gint16_modifier
3020 #define G_GINT16_FORMAT $gint16_format
3021 #define G_GUINT16_FORMAT $guint16_format
3022 _______EOF
3023         fi
3024
3025
3026         if test -n "$gint32"; then
3027           cat >>$outfile <<_______EOF
3028 typedef signed $gint32 gint32;
3029 typedef unsigned $gint32 guint32;
3030 #define G_GINT32_MODIFIER $gint32_modifier
3031 #define G_GINT32_FORMAT $gint32_format
3032 #define G_GUINT32_FORMAT $guint32_format
3033 _______EOF
3034         fi
3035
3036         cat >>$outfile <<_______EOF
3037 #define G_HAVE_GINT64 1          /* deprecated, always true */
3038
3039 ${glib_extension}typedef signed $gint64 gint64;
3040 ${glib_extension}typedef unsigned $gint64 guint64;
3041
3042 #define G_GINT64_CONSTANT(val)  $gint64_constant
3043 #define G_GUINT64_CONSTANT(val) $guint64_constant
3044 _______EOF
3045
3046         if test x$gint64_format != x ; then
3047           cat >>$outfile <<_______EOF
3048 #define G_GINT64_MODIFIER $gint64_modifier
3049 #define G_GINT64_FORMAT $gint64_format
3050 #define G_GUINT64_FORMAT $guint64_format
3051 _______EOF
3052         else
3053           cat >>$outfile <<_______EOF
3054 #undef G_GINT64_MODIFIER
3055 #undef G_GINT64_FORMAT
3056 #undef G_GUINT64_FORMAT
3057 _______EOF
3058         fi
3059
3060         cat >>$outfile <<_______EOF
3061
3062 #define GLIB_SIZEOF_VOID_P $glib_void_p
3063 #define GLIB_SIZEOF_LONG   $glib_long
3064 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3065
3066 _______EOF
3067
3068         cat >>$outfile <<_______EOF
3069 typedef signed $glib_size_type_define gssize;
3070 typedef unsigned $glib_size_type_define gsize;
3071 #define G_GSIZE_MODIFIER $gsize_modifier
3072 #define G_GSSIZE_FORMAT $gssize_format
3073 #define G_GSIZE_FORMAT $gsize_format
3074
3075 #define G_MAXSIZE       G_MAXU$glib_msize_type
3076 #define G_MINSSIZE      G_MIN$glib_msize_type
3077 #define G_MAXSSIZE      G_MAX$glib_msize_type
3078
3079 typedef gint64 goffset;
3080 #define G_MINOFFSET     G_MININT64
3081 #define G_MAXOFFSET     G_MAXINT64
3082
3083 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3084 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3085 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3086
3087 _______EOF
3088
3089         if test -z "$glib_unknown_void_p"; then
3090           cat >>$outfile <<_______EOF
3091
3092 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3093 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3094
3095 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3096 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3097
3098 typedef signed $glib_intptr_type_define gintptr;
3099 typedef unsigned $glib_intptr_type_define guintptr;
3100
3101 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3102 #define G_GINTPTR_FORMAT        $gintptr_format
3103 #define G_GUINTPTR_FORMAT       $guintptr_format
3104 _______EOF
3105         else
3106           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3107         fi
3108
3109
3110
3111         cat >>$outfile <<_______EOF
3112 $glib_atexit
3113 $glib_memmove
3114 $glib_defines
3115 $glib_os
3116 $glib_static_compilation
3117
3118 $glib_vacopy
3119
3120 #ifdef  __cplusplus
3121 #define G_HAVE_INLINE   1
3122 #else   /* !__cplusplus */
3123 $glib_inline
3124 #endif  /* !__cplusplus */
3125
3126 #ifdef  __cplusplus
3127 #define G_CAN_INLINE    1
3128 _______EOF
3129
3130         if test x$g_can_inline = xyes ; then
3131                 cat >>$outfile <<_______EOF
3132 #else   /* !__cplusplus */
3133 #define G_CAN_INLINE    1
3134 _______EOF
3135         fi
3136
3137         cat >>$outfile <<_______EOF
3138 #endif
3139
3140 _______EOF
3141
3142         if test x$g_have_iso_c_varargs = xyes ; then
3143                 cat >>$outfile <<_______EOF
3144 #ifndef __cplusplus
3145 # define G_HAVE_ISO_VARARGS 1
3146 #endif
3147 _______EOF
3148         fi
3149         if test x$g_have_iso_cxx_varargs = xyes ; then
3150                 cat >>$outfile <<_______EOF
3151 #ifdef __cplusplus
3152 # define G_HAVE_ISO_VARARGS 1
3153 #endif
3154 _______EOF
3155         fi
3156         if test x$g_have_gnuc_varargs = xyes ; then
3157                 cat >>$outfile <<_______EOF
3158
3159 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3160  * is passed ISO vararg support is turned off, and there is no work
3161  * around to turn it on, so we unconditionally turn it off.
3162  */
3163 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3164 #  undef G_HAVE_ISO_VARARGS
3165 #endif
3166
3167 #define G_HAVE_GNUC_VARARGS 1
3168 _______EOF
3169         fi
3170
3171         case x$g_stack_grows in
3172         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3173         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3174         esac
3175
3176
3177         echo >>$outfile
3178         if test x$g_have_eilseq = xno; then
3179                 cat >>$outfile <<_______EOF
3180 #ifndef EILSEQ
3181 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3182  * The correspondence between this and the corresponding definition
3183  * in libiconv is essential.
3184  */
3185 #  define EILSEQ ENOENT
3186 #endif
3187 _______EOF
3188
3189         fi
3190
3191         if test x$g_have_gnuc_visibility = xyes; then
3192                 cat >>$outfile <<_______EOF
3193 #define G_HAVE_GNUC_VISIBILITY 1
3194 _______EOF
3195         fi
3196                 cat >>$outfile <<_______EOF
3197 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3198 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3199 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3200 #define G_GNUC_INTERNAL __hidden
3201 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3202 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3203 #else
3204 #define G_GNUC_INTERNAL
3205 #endif
3206 _______EOF
3207
3208
3209         echo >>$outfile
3210         if test x$g_mutex_has_default = xyes; then
3211                 cat >>$outfile <<_______EOF
3212 $g_enable_threads_def G_THREADS_ENABLED
3213 #define G_THREADS_IMPL_$g_threads_impl_def
3214 typedef struct _GStaticMutex GStaticMutex;
3215 struct _GStaticMutex
3216 {
3217   struct _GMutex *runtime_mutex;
3218   union {
3219     char   pad[[$g_mutex_sizeof]];
3220     double dummy_double;
3221     void  *dummy_pointer;
3222     long   dummy_long;
3223   } static_mutex;
3224 };
3225 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3226 #define g_static_mutex_get_mutex(mutex) \\
3227   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3228    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3229 _______EOF
3230         else
3231                 cat >>$outfile <<_______EOF
3232 $g_enable_threads_def G_THREADS_ENABLED
3233 #define G_THREADS_IMPL_$g_threads_impl_def
3234 typedef struct _GMutex* GStaticMutex;
3235 #define G_STATIC_MUTEX_INIT NULL
3236 #define g_static_mutex_get_mutex(mutex) \\
3237   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3238 _______EOF
3239         fi
3240
3241         cat >>$outfile <<_______EOF
3242 /* This represents a system thread as used by the implementation. An
3243  * alien implementaion, as loaded by g_thread_init can only count on
3244  * "sizeof (gpointer)" bytes to store their info. We however need more
3245  * for some of our native implementations. */
3246 typedef union _GSystemThread GSystemThread;
3247 union _GSystemThread
3248 {
3249   char   data[[$g_system_thread_sizeof]];
3250   double dummy_double;
3251   void  *dummy_pointer;
3252   long   dummy_long;
3253 };
3254 _______EOF
3255         if test x"$g_memory_barrier_needed" != xno; then
3256           echo >>$outfile
3257           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3258         fi
3259         if test x"$g_gcc_atomic_ops" != xno; then
3260           echo >>$outfile
3261           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3262         fi
3263         echo >>$outfile
3264         g_bit_sizes="16 32 64"
3265         for bits in $g_bit_sizes; do
3266           cat >>$outfile <<_______EOF
3267 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3268 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3269 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3270 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3271 _______EOF
3272         done
3273
3274         cat >>$outfile <<_______EOF
3275 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3276 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3277 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3278 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3279 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3280 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3281 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3282 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3283 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3284 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3285 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3286 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3287 #define G_BYTE_ORDER $g_byte_order
3288
3289 #define GLIB_SYSDEF_POLLIN =$g_pollin
3290 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3291 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3292 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3293 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3294 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3295
3296 #define G_MODULE_SUFFIX "$g_module_suffix"
3297
3298 /* A GPid is an abstraction for a process "handle". It is *not* an
3299  * abstraction for a process identifier in general. GPid is used in
3300  * GLib only for descendant processes spawned with the g_spawn*
3301  * functions. On POSIX there is no "process handle" concept as such,
3302  * but on Windows a GPid is a handle to a process, a kind of pointer,
3303  * not a process identifier.
3304  */
3305 typedef $g_pid_type GPid;
3306
3307 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3308 #define GLIB_SYSDEF_AF_INET $g_af_inet
3309 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3310
3311 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3312 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3313 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3314
3315 G_END_DECLS
3316
3317 #endif /* GLIBCONFIG_H */
3318 _______EOF
3319
3320
3321         if cmp -s $outfile glib/glibconfig.h; then
3322           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3323           rm -f $outfile
3324         else
3325           mv $outfile glib/glibconfig.h
3326         fi
3327 ],[
3328
3329 # Note that if two cases are the same, case goes with the first one.
3330 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3331 # on variable expansion in case labels.  Look at the generated config.status
3332 # for a hint.
3333
3334 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3335   glib_header_alloca_h="$ac_cv_working_alloca_h"
3336 else
3337   glib_header_alloca_h="$ac_cv_header_alloca_h"
3338 fi
3339
3340 case xyes in
3341 x$ac_cv_header_float_h)
3342   glib_float_h=yes
3343   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3344   glib_md=DBL_MIN glib_Md=DBL_MAX
3345   ;;
3346 x$ac_cv_header_values_h)
3347   glib_values_h=yes
3348   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3349   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3350   ;;
3351 esac
3352
3353 case xyes in
3354 x$ac_cv_header_limits_h)
3355   glib_limits_h=yes
3356   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3357   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3358   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3359   ;;
3360 x$ac_cv_header_values_h)
3361   glib_values_h=yes
3362   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3363   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3364   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3365   ;;
3366 esac
3367
3368 if test x$ac_cv_header_sys_poll_h = xyes ; then
3369   glib_sys_poll_h=yes
3370 fi
3371
3372 if test x$enable_included_printf = xyes ; then
3373   glib_included_printf=yes
3374 fi
3375
3376 case 2 in
3377 $ac_cv_sizeof_short)
3378   gint16=short
3379   gint16_modifier='"h"'
3380   gint16_format='"hi"'
3381   guint16_format='"hu"'
3382   ;;
3383 $ac_cv_sizeof_int)
3384   gint16=int
3385   gint16_modifier='""'
3386   gint16_format='"i"'
3387   guint16_format='"u"'
3388   ;;
3389 esac
3390 case 4 in
3391 $ac_cv_sizeof_short)
3392   gint32=short
3393   gint32_modifier='"h"'
3394   gint32_format='"hi"'
3395   guint32_format='"hu"'
3396   ;;
3397 $ac_cv_sizeof_int)
3398   gint32=int
3399   gint32_modifier='""'
3400   gint32_format='"i"'
3401   guint32_format='"u"'
3402   ;;
3403 $ac_cv_sizeof_long)
3404   gint32=long
3405   gint32_modifier='"l"'
3406   gint32_format='"li"'
3407   guint32_format='"lu"'
3408   ;;
3409 esac
3410 case 8 in
3411 $ac_cv_sizeof_int)
3412   gint64=int
3413   gint64_modifier='""'
3414   gint64_format='"i"'
3415   guint64_format='"u"'
3416   glib_extension=
3417   gint64_constant='(val)'
3418   guint64_constant='(val)'
3419   ;;
3420 $ac_cv_sizeof_long)
3421   gint64=long
3422   gint64_modifier='"l"'
3423   gint64_format='"li"'
3424   guint64_format='"lu"'
3425   glib_extension=
3426   gint64_constant='(val##L)'
3427   guint64_constant='(val##UL)'
3428   ;;
3429 $ac_cv_sizeof_long_long)
3430   gint64='long long'
3431   if test -n "$glib_cv_long_long_format"; then
3432     gint64_modifier='"'$glib_cv_long_long_format'"'
3433     gint64_format='"'$glib_cv_long_long_format'i"'
3434     guint64_format='"'$glib_cv_long_long_format'u"'
3435   fi
3436   glib_extension='G_GNUC_EXTENSION '
3437   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3438   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3439   ;;
3440 $ac_cv_sizeof___int64)
3441   gint64='__int64'
3442   if test -n "$glib_cv_long_long_format"; then
3443     gint64_modifier='"'$glib_cv_long_long_format'"'
3444     gint64_format='"'$glib_cv_long_long_format'i"'
3445     guint64_format='"'$glib_cv_long_long_format'u"'
3446   fi
3447   glib_extension=
3448   gint64_constant='(val##i64)'
3449   guint64_constant='(val##ui64)'
3450   ;;
3451 esac
3452 glib_size_t=$ac_cv_sizeof_size_t
3453 glib_size_type_define="$glib_size_type"
3454 glib_void_p=$ac_cv_sizeof_void_p
3455 glib_long=$ac_cv_sizeof_long
3456
3457 case "$glib_size_type" in
3458 short)
3459   gsize_modifier='"h"'
3460   gsize_format='"hu"'
3461   gssize_format='"hi"'
3462   glib_msize_type='SHRT'
3463   ;;
3464 int)
3465   gsize_modifier='""'
3466   gsize_format='"u"'
3467   gssize_format='"i"'
3468   glib_msize_type='INT'
3469   ;;
3470 long)
3471   gsize_modifier='"l"'
3472   gsize_format='"lu"'
3473   gssize_format='"li"'
3474   glib_msize_type='LONG'
3475   ;;
3476 "long long"|__int64)
3477   gsize_modifier='"I64"'
3478   gsize_format='"I64u"'
3479   gssize_format='"I64i"'
3480   glib_msize_type='INT64'
3481   ;;
3482 esac
3483
3484 gintbits=`expr $ac_cv_sizeof_int \* 8`
3485 glongbits=`expr $ac_cv_sizeof_long \* 8`
3486 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3487
3488 case $ac_cv_sizeof_void_p in
3489 $ac_cv_sizeof_int)
3490   glib_intptr_type_define=int
3491   gintptr_modifier='""'
3492   gintptr_format='"i"'
3493   guintptr_format='"u"'
3494   glib_gpi_cast=''
3495   glib_gpui_cast=''
3496   ;;
3497 $ac_cv_sizeof_long)
3498   glib_intptr_type_define=long
3499   gintptr_modifier='"l"'
3500   gintptr_format='"li"'
3501   guintptr_format='"lu"'
3502   glib_gpi_cast='(glong)'
3503   glib_gpui_cast='(gulong)'
3504   ;;
3505 $ac_cv_sizeof_long_long)
3506   glib_intptr_type_define='long long'
3507   gintptr_modifier='"I64"'
3508   gintptr_format='"I64i"'
3509   guintptr_format='"I64u"'
3510   glib_gpi_cast='(gint64)'
3511   glib_gpui_cast='(guint64)'
3512   ;;
3513 $ac_cv_sizeof___int64)
3514   glib_intptr_type_define=__int64
3515   gintptr_modifier='"I64"'
3516   gintptr_format='"I64i"'
3517   guintptr_format='"I64u"'
3518   glib_gpi_cast='(gint64)'
3519   glib_gpui_cast='(guint64)'
3520   ;;
3521 *)
3522   glib_unknown_void_p=yes
3523   ;;
3524 esac
3525
3526
3527 case xyes in
3528 x$ac_cv_func_atexit)
3529   glib_atexit="
3530 #ifdef NeXT /* @#%@! NeXTStep */
3531 # define g_ATEXIT(proc) (!atexit (proc))
3532 #else
3533 # define g_ATEXIT(proc) (atexit (proc))
3534 #endif"
3535   ;;
3536 x$ac_cv_func_on_exit)
3537   glib_atexit="
3538 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3539   ;;
3540 esac
3541
3542 case xyes in
3543 x$ac_cv_func_memmove)
3544   glib_memmove='
3545 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3546   ;;
3547 x$glib_cv_working_bcopy)
3548   glib_memmove="
3549 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3550 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3551   ;;
3552 *)
3553   glib_memmove="
3554 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3555  * so we have to roll our own copy routine. */
3556 void g_memmove (void* dest, const void * src, unsigned long len);"
3557   ;;
3558 esac
3559
3560 glib_defines="
3561 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3562 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3563 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3564 "
3565
3566 case xyes in
3567 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3568 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3569 *)                      glib_vacopy=''
3570 esac
3571
3572 if test x$glib_cv_va_val_copy = xno; then
3573   glib_vacopy="\$glib_vacopy
3574 #define G_VA_COPY_AS_ARRAY 1"
3575 fi
3576
3577 if test x$glib_cv_hasinline = xyes; then
3578     glib_inline='#define G_HAVE_INLINE 1'
3579 fi
3580 if test x$glib_cv_has__inline = xyes; then
3581     glib_inline="\$glib_inline
3582 #define G_HAVE___INLINE 1"
3583 fi
3584 if test x$glib_cv_has__inline__ = xyes; then
3585     glib_inline="\$glib_inline
3586 #define G_HAVE___INLINE__ 1"
3587 fi
3588
3589 g_have_gnuc_varargs=$g_have_gnuc_varargs
3590 g_have_iso_c_varargs=$g_have_iso_c_varargs
3591 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3592
3593 g_can_inline=$g_can_inline
3594 g_have_gnuc_visibility=$g_have_gnuc_visibility
3595 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3596
3597 if test x$ac_cv_c_bigendian = xyes; then
3598   g_byte_order=G_BIG_ENDIAN
3599   g_bs_native=BE
3600   g_bs_alien=LE
3601 else
3602   g_byte_order=G_LITTLE_ENDIAN
3603   g_bs_native=LE
3604   g_bs_alien=BE
3605 fi
3606
3607 g_pollin=$glib_cv_value_POLLIN
3608 g_pollout=$glib_cv_value_POLLOUT
3609 g_pollpri=$glib_cv_value_POLLPRI
3610 g_pollhup=$glib_cv_value_POLLHUP
3611 g_pollerr=$glib_cv_value_POLLERR
3612 g_pollnval=$glib_cv_value_POLLNVAL
3613
3614 g_af_unix=$glib_cv_value_AF_UNIX
3615 g_af_inet=$glib_cv_value_AF_INET
3616 g_af_inet6=$glib_cv_value_AF_INET6
3617
3618 g_msg_peek=$glib_cv_value_MSG_PEEK
3619 g_msg_oob=$glib_cv_value_MSG_OOB
3620 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3621
3622 g_stack_grows=$glib_cv_stack_grows
3623
3624 g_have_eilseq=$have_eilseq
3625
3626 case x$have_threads in
3627 xno)    g_enable_threads_def="#undef";;
3628 *)      g_enable_threads_def="#define";;
3629 esac
3630
3631 g_threads_impl_def=$g_threads_impl
3632
3633 g_mutex_has_default="$mutex_has_default"
3634 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3635 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3636 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3637
3638 g_memory_barrier_needed="$glib_memory_barrier_needed"
3639 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3640
3641 g_module_suffix="$glib_gmodule_suffix"
3642
3643 g_pid_type="$glib_pid_type"
3644 case $host in
3645   *-*-beos*)
3646     glib_os="#define G_OS_BEOS"
3647     ;;
3648   *-*-cygwin*)
3649     glib_os="#define G_OS_UNIX
3650 #define G_PLATFORM_WIN32
3651 #define G_WITH_CYGWIN"
3652     ;;
3653   *-*-mingw*)
3654     glib_os="#define G_OS_WIN32
3655 #define G_PLATFORM_WIN32"
3656     ;;
3657   *)
3658     glib_os="#define G_OS_UNIX"
3659     ;;
3660 esac
3661 glib_static_compilation=""
3662 if test x$glib_win32_static_compilation = xyes; then
3663   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3664 #define GOBJECT_STATIC_COMPILATION 1"
3665 fi
3666 ])
3667
3668 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3669 #
3670 # 1.2.14 required for dbus_message_set_serial
3671 PKG_CHECK_MODULES(DBUS1,
3672                   dbus-1 >= 1.2.14,
3673                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3674                   have_dbus1=no)
3675 AC_SUBST(DBUS1_CFLAGS)
3676 AC_SUBST(DBUS1_LIBS)
3677 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3678
3679 dnl
3680 dnl Check for -Bsymbolic-functions linker flag used to avoid
3681 dnl intra-library PLT jumps, if available.
3682 dnl
3683
3684 AC_ARG_ENABLE(Bsymbolic,
3685               [AC_HELP_STRING([--disable-Bsymbolic],
3686                               [avoid linking with -Bsymbolic])],,
3687               [SAVED_LDFLAGS="${LDFLAGS}"
3688                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3689                LDFLAGS=-Wl,-Bsymbolic-functions
3690                AC_TRY_LINK([], [int main (void) { return 0; }],
3691                            AC_MSG_RESULT(yes)
3692                            enable_Bsymbolic=yes,
3693                            AC_MSG_RESULT(no)
3694                            enable_Bsymbolic=no)
3695                LDFLAGS="${SAVED_LDFLAGS}"])
3696
3697 if test "x${enable_Bsymbolic}" == "xyes"; then
3698   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3699 fi
3700
3701 AC_SUBST(GLIB_LINK_FLAGS)
3702
3703 #
3704 # Define variables corresponding to the correct include paths to use for
3705 # in-tree building.
3706 #
3707
3708 # for config.h:
3709 config_h_INCLUDES='-I$(top_builddir)'
3710 AC_SUBST(config_h_INCLUDES)
3711
3712 # glib:
3713 #   config.h
3714 #   $(top_builddir)/glib: for glibconfig.h
3715 #   $(top_srcdir)/glib:   for glib.h
3716 #   $(top_srcdir):        for everything
3717 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3718 AC_SUBST(glib_INCLUDES)
3719
3720 # gthread:
3721 #   same as glib
3722 gthread_INCLUDES='$(glib_INCLUDES)'
3723 AC_SUBST(gthread_INCLUDES)
3724
3725 # gobject:
3726 #   same as gthread
3727 gobject_INCLUDES='$(gthread_INCLUDES)'
3728 AC_SUBST(gobject_INCLUDES)
3729
3730 # gmodule:
3731 #   glib includes
3732 #   $(top_srcdir)/gmodule: for gmodule.h
3733 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3734 AC_SUBST(gmodule_INCLUDES)
3735
3736 # gio:
3737 #   same as gmodule
3738 gio_INCLUDES='$(gmodule_INCLUDES)'
3739 AC_SUBST(gio_INCLUDES)
3740
3741
3742 AC_CONFIG_FILES([
3743 glib-2.0.pc
3744 glib-2.0-uninstalled.pc
3745 gmodule-2.0.pc
3746 gmodule-export-2.0.pc
3747 gmodule-no-export-2.0.pc
3748 gmodule-2.0-uninstalled.pc
3749 gmodule-no-export-2.0-uninstalled.pc
3750 gthread-2.0.pc
3751 gthread-2.0-uninstalled.pc
3752 gobject-2.0.pc
3753 gobject-2.0-uninstalled.pc
3754 gio-2.0.pc
3755 gio-unix-2.0.pc
3756 gio-windows-2.0.pc
3757 gio-2.0-uninstalled.pc
3758 gio-unix-2.0-uninstalled.pc
3759 glib-zip
3760 glib-gettextize
3761 Makefile
3762 build/Makefile
3763 build/win32/Makefile
3764 build/win32/dirent/Makefile
3765 build/win32/vs9/Makefile
3766 build/win32/vs10/Makefile
3767 glib/Makefile
3768 glib/glib.stp
3769 glib/libcharset/Makefile
3770 glib/gnulib/Makefile
3771 glib/pcre/Makefile
3772 glib/update-pcre/Makefile
3773 glib/tests/Makefile
3774 gmodule/Makefile
3775 gmodule/gmoduleconf.h
3776 gobject/Makefile
3777 gobject/gobject.stp
3778 gobject/glib-mkenums
3779 gobject/tests/Makefile
3780 gthread/Makefile
3781 gthread/tests/Makefile
3782 gio/Makefile
3783 gio/gdbus-codegen/Makefile
3784 gio/gdbus-codegen/config.py
3785 gio/xdgmime/Makefile
3786 gio/inotify/Makefile
3787 gio/libasyncns/Makefile
3788 gio/fen/Makefile
3789 gio/fam/Makefile
3790 gio/win32/Makefile
3791 gio/tests/Makefile
3792 gio/tests/gdbus-object-manager-example/Makefile
3793 po/Makefile.in
3794 docs/Makefile
3795 docs/reference/Makefile
3796 docs/reference/glib/Makefile
3797 docs/reference/glib/version.xml
3798 docs/reference/gobject/Makefile
3799 docs/reference/gobject/version.xml
3800 docs/reference/gio/Makefile
3801 docs/reference/gio/gdbus-object-manager-example/Makefile
3802 docs/reference/gio/version.xml
3803 tests/Makefile
3804 tests/gobject/Makefile
3805 tests/refcount/Makefile
3806 m4macros/Makefile
3807 ])
3808
3809 AC_CONFIG_COMMANDS([chmod-scripts],
3810 [chmod 0755 glib-zip
3811 chmod 0755 glib-gettextize
3812 chmod 0755 gobject/glib-mkenums])
3813
3814 # we want to invoke this macro solely so that the config.status script
3815 # and automake generated makefiles know about these generated files.
3816 # They are only needed to distcheck the package
3817 if false; then
3818   AC_CONFIG_FILES([
3819     INSTALL
3820     README
3821     config.h.win32
3822     glib/glibconfig.h.win32
3823     glib/makefile.msc
3824     glib/glib.rc
3825     gmodule/makefile.msc
3826     gmodule/gmodule.rc
3827     gobject/makefile.msc
3828     gobject/gobject.rc
3829     gthread/makefile.msc
3830     gthread/gthread.rc
3831     gio/gio.rc
3832     tests/makefile.msc
3833   ])
3834 fi
3835
3836 AC_OUTPUT