configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [999])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([ecore], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39
  40 AC_LIBTOOL_WIN32_DLL
  41 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  42 AC_PROG_LIBTOOL
  43
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  46 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  47 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  48 AC_DEFINE_UNQUOTED(VERS_MAJ, [v_maj], [Major version])
  49 AC_DEFINE_UNQUOTED(VERS_MIN, [v_min], [Minor version])
  50 AC_DEFINE_UNQUOTED(VERS_MIC, [v_mic], [Micro version])
  51 AC_DEFINE_UNQUOTED(VERS_REV, [v_rev], [Revison])
  52 version_info="lt_cur:lt_rev:lt_age"
  53 release_info="v_rel"
  54 AC_SUBST(version_info)
  55 AC_SUBST(release_info)
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  58 VMAJ=v_maj
  59 AC_SUBST(VMAJ)
  60
  61 m4_ifdef([AM_GNU_GETTEXT_VERSION], [
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 ])
  64
  65 m4_ifdef([AM_GNU_GETTEXT], [
  66 AM_GNU_GETTEXT([external])
  67 po_makefile_in=po/Makefile.in
  68 have_po="yes"
  69 ],[
  70 have_po="no"
  71 ])
  72 AC_SUBST(LTLIBINTL)
  73
  74 if test "x${POSUB}" = "x" ; then
  75    have_po="no"
  76 fi
  77
  78 AM_CONDITIONAL([HAVE_PO], [test "x${have_po}" = "xyes"])
  79
  80 with_max_log_level="<unset>"
  81 AC_ARG_WITH(internal-maximum-log-level,
  82    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
  83                    [limit ecore internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
  84    [
  85     if test "x${withval}" != "xno"; then
  86        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
  87           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
  88           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
  89           with_max_log_level="${withval}"
  90        else
  91           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
  92        fi
  93     fi
  94     ], [:])
  95
  96
  97 ### Default options with respect to host
  98
  99 AC_CANONICAL_BUILD
 100 AC_CANONICAL_HOST
 101
 102 # dependencies and options
 103 want_curl="no"
 104 want_local_sockets="yes"
 105 want_abstract_sockets="no"
 106 want_gnutls="no"
 107 want_openssl="no"
 108 want_cares="no"
 109 want_cipher="no"
 110 want_signature="no"
 111 want_poll="yes"
 112 want_inotify="no"
 113 want_notify_win32="no"
 114 want_tslib="no"
 115 want_glib="no"
 116
 117 # core modules
 118 want_ecore_con="yes"
 119 want_ecore_ipc="yes"
 120 want_ecore_file="yes"
 121 #want_ecore_config="no"
 122 want_ecore_imf="no"
 123 want_ecore_input="yes"
 124
 125 # graphic system modules
 126 want_evas_simple_x11="no"
 127 want_ecore_x_xcb="no"
 128 want_ecore_x="no"
 129 want_ecore_win32="no"
 130 want_ecore_cocoa="no"
 131 want_ecore_sdl="no"
 132 want_ecore_fb="no"
 133 want_ecore_directfb="no"
 134 want_ecore_wince="no"
 135
 136 # ecore_x options (both xlib and xcb)
 137 want_ecore_x_composite="yes"
 138 want_ecore_x_damage="yes"
 139 want_ecore_x_dpms="yes"
 140 want_ecore_x_randr="yes"
 141 want_ecore_x_render="yes"
 142 want_ecore_x_screensaver="yes"
 143 want_ecore_x_shape="yes"
 144 want_ecore_x_sync="yes"
 145 want_ecore_x_xfixes="yes"
 146 want_ecore_x_xinerama="yes"
 147 want_ecore_x_xprint="yes"
 148 want_ecore_x_xtest="yes"
 149 want_ecore_x_cursor="yes"
 150 want_ecore_x_input="yes"
 151 want_ecore_x_dri="yes"
 152
 153 # ecore_evas modules
 154 want_ecore_evas="yes"
 155 want_ecore_evas_software_buffer="yes"
 156 want_ecore_evas_software_x11="no"
 157 want_ecore_evas_opengl_x11="no"
 158 want_ecore_evas_software_16_x11="no"
 159 want_ecore_evas_software_8_x11="no"
 160 want_ecore_evas_software_xcb="no"
 161 want_ecore_evas_software_gdi="no"
 162 want_ecore_evas_software_ddraw="no"
 163 want_ecore_evas_direct3d="no"
 164 want_ecore_evas_opengl_glew="no"
 165 want_ecore_evas_software_16_ddraw="no"
 166 want_ecore_evas_software_sdl="no"
 167 want_ecore_evas_gl_sdl="no"
 168 want_ecore_evas_directfb="no"
 169 want_ecore_evas_fb="no"
 170 want_ecore_evas_software_16_wince="no"
 171 want_ecore_evas_ews="yes"
 172
 173 # ecore_imf modules
 174 want_ecore_imf_xim="no"
 175
 176 case "$host_os" in
 177    mingw32ce* | cegcc*)
 178       want_ecore_con="no"
 179       want_ecore_ipc="no"
 180       want_ecore_wince="yes"
 181       want_ecore_evas_software_16_wince="yes"
 182       ;;
 183    mingw*)
 184       want_notify_win32="yes"
 185       want_curl="yes"
 186       want_glib="auto"
 187       want_gnutls="auto"
 188       want_openssl="auto"
 189       want_ecore_imf="yes"
 190       want_ecore_win32="yes"
 191       want_ecore_evas_software_gdi="yes"
 192       want_ecore_evas_software_ddraw="yes"
 193       want_ecore_evas_direct3d="yes"
 194       want_ecore_evas_opengl_glew="yes"
 195       want_ecore_evas_software_16_ddraw="auto"
 196       want_ecore_evas_software_sdl="yes"
 197       want_ecore_evas_gl_sdl="yes"
 198       ;;
 199    darwin*)
 200       want_curl="yes"
 201       want_glib="auto"
 202       want_gnutls="auto"
 203       want_openssl="auto"
 204       want_ecore_imf="yes"
 205       want_ecore_cocoa="yes"
 206       want_ecore_evas_software_sdl="yes"
 207       want_ecore_evas_gl_sdl="yes"
 208       ;;
 209    *)
 210       want_curl="yes"
 211       want_glib="auto"
 212       want_abstract_sockets="yes"
 213       want_gnutls="auto"
 214       want_openssl="auto"
 215       want_cipher="yes"
 216       want_signature="yes"
 217       want_inotify="yes"
 218       want_tslib="yes"
 219       want_ecore_fb="yes"
 220       want_ecore_imf="yes"
 221       want_ecore_x="yes"
 222       want_ecore_evas_software_x11="yes"
 223       want_ecore_evas_opengl_x11="yes"
 224       want_ecore_evas_software_16_x11="yes"
 225       want_ecore_evas_software_8_x11="yes"
 226       want_ecore_evas_software_xcb="no"
 227       want_ecore_evas_software_sdl="yes"
 228       want_ecore_evas_gl_sdl="yes"
 229       want_ecore_evas_directfb="yes"
 230       want_ecore_evas_fb="yes"
 231       want_ecore_imf_xim="yes"
 232       ;;
 233 esac
 234
 235 case "$host_vendor" in
 236   ps3*)
 237       want_local_sockets="no"
 238       ;;
 239 esac
 240 requirements_ecore=""
 241 requirements_ecore_con=""
 242 #requirements_ecore_config=""
 243 requirements_ecore_directfb=""
 244 requirements_ecore_evas=""
 245 requirements_ecore_fb=""
 246 requirements_ecore_file=""
 247 requirements_ecore_imf=""
 248 requirements_ecore_imf_evas=""
 249 requirements_ecore_input=""
 250 requirements_ecore_input_evas=""
 251 requirements_ecore_ipc=""
 252 requirements_ecore_cocoa=""
 253 requirements_ecore_sdl=""
 254 requirements_ecore_x=""
 255 requirements_ecore_win32=""
 256 requirements_ecore_wince=""
 257 requirements_ecore_imf_xim=""
 258
 259 AC_CHECK_DECL([MAXHOSTNAMELEN],[FOUND_MAXHOSTNAMELEN=yes])
 260
 261 if test x$FOUND_MAXHOSTNAMELEN != xyes ; then
 262   AC_MSG_CHECKING([for header that defines MAXHOSTNAMELEN])
 263
 264   FOUND_MAXHOSTNAMELEN='not found'
 265
 266   AC_COMPILE_IFELSE(
 267         AC_LANG_PROGRAM([#include <sys/param.h>],
 268                 [int h = MAXHOSTNAMELEN;]),
 269         [FOUND_MAXHOSTNAMELEN='sys/param.h'
 270            AC_DEFINE(NEED_SYS_PARAM_H,1,
 271              [Define to 1 if you need <sys/param.h> to define MAXHOSTNAMELEN])])
 272
 273         AC_COMPILE_IFELSE(
 274             AC_LANG_PROGRAM([#include <netdb.h>],
 275                             [int h = MAXHOSTNAMELEN;]),
 276             [FOUND_MAXHOSTNAMELEN='netdb.h'
 277              AC_DEFINE(NEED_NETDB_H,1,
 278                [Define to 1 if you need <netdb.h> to define MAXHOSTNAMELEN])])
 279
 280   AC_MSG_RESULT([$FOUND_MAXHOSTNAMELEN])
 281 fi
 282
 283 ### Additional options to configure
 284
 285 want_glib_integration_always=no
 286 AC_ARG_ENABLE(glib-integration-always,
 287   AC_HELP_STRING([--enable-glib-integration-always], [enable glib integration when ecore_init() is called always]),
 288   [want_glib_integration_always=$enableval])
 289
 290 if test "x${want_glib_integration_always}" = "xyes" ; then
 291   AC_DEFINE([GLIB_INTEGRATION_ALWAYS], [1], [Always integrate glib if support compiled])
 292   want_glib=yes
 293 fi
 294
 295 want_g_main_loop=no
 296 AC_ARG_ENABLE(g-main-loop,
 297   AC_HELP_STRING([--enable-g-main-loop], [ecore_main_loop based on g_main_loop]),
 298   [want_g_main_loop=$enableval])
 299
 300 if test "x${want_g_main_loop}" = "xyes" ; then
 301   AC_DEFINE([USE_G_MAIN_LOOP], [1], [Use g_main_loop in ecore])
 302   want_glib=yes
 303 fi
 304
 305 if test "x${want_glib_integration_always}" = "xyes" -a "x${want_g_main_loop}" = "xyes"; then
 306   AC_MSG_ERROR([--enable-glib-integration-always and --enable-glib-main-loop are mutually exclusive])
 307 fi
 308
 309 # local sockets (ecore_con.c)
 310 AC_ARG_ENABLE([local-sockets],
 311    [AC_HELP_STRING([--disable-local-sockets], [disable local sockets.])],
 312    [
 313     if test "x${enableval}" = "xyes" ; then
 314        want_ecore_con_local_sockets="yes"
 315     else
 316        want_ecore_con_local_sockets="no"
 317     fi
 318    ],
 319    [want_ecore_con_local_sockets=${want_local_sockets}])
 320
 321 if test "x${want_ecore_con_local_sockets}" = "xyes" ; then
 322    AC_DEFINE([HAVE_LOCAL_SOCKETS], [1], [Have local sockets support])
 323 fi
 324
 325 # abstract sockets (ecore_con.c)
 326 AC_ARG_ENABLE([abstract-sockets],
 327    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 328    [
 329     if test "x${enableval}" = "xyes" ; then
 330        want_ecore_con_abstract_sockets="yes"
 331     else
 332        want_ecore_con_abstract_sockets="no"
 333     fi
 334    ],
 335    [want_ecore_con_abstract_sockets=${want_abstract_sockets}])
 336
 337 if test "x${want_ecore_con_abstract_sockets}" = "xyes" ; then
 338    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 339 fi
 340
 341 # Simple X11 build/link
 342
 343 AC_ARG_ENABLE(simple-x11,
 344   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 345   [want_evas_simple_x11=$enableval])
 346
 347 # XIM
 348 AC_ARG_ENABLE([xim],
 349    [AC_HELP_STRING([--disable-xim], [disable X Input Method.])],
 350    [
 351     if test "x${enableval}" = "xyes" ; then
 352        want_xim="yes"
 353     else
 354        want_xim="no"
 355     fi
 356    ],
 357    [want_xim="yes"])
 358
 359 if test "x${want_xim}" = "xyes" ; then
 360    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 361 fi
 362
 363 # Unit tests
 364
 365 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 366
 367 ### Checks for programs
 368
 369 m4_ifdef([AC_PROG_OBJC],
 370    [
 371     AC_PROG_OBJC
 372     _AM_DEPENDENCIES(OBJC)
 373    ],
 374    [
 375     AC_CHECK_TOOL([OBJC], [gcc])
 376     AC_SUBST([OBJC])
 377     AC_SUBST([OBJCFLAGS])
 378    ])
 379 m4_ifndef([am__fastdepOBJC], [
 380     AM_CONDITIONAL([am__fastdepOBJC], [false])
 381     AC_SUBST([cocoa_ldflags])
 382 ])
 383
 384 AC_PROG_CXX
 385 AC_PROG_CC
 386
 387 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 388
 389 # doxygen program for documentation building
 390
 391 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 392
 393 m4_ifdef([v_mic],
 394    [
 395     EFL_COMPILER_FLAG([-Wall])
 396     EFL_COMPILER_FLAG([-W])
 397    ])
 398
 399 # The first call to PKG_CHECK_MODULES is done conditionally,
 400 # so we should include this here:
 401 PKG_PROG_PKG_CONFIG
 402
 403 # Check whether pkg-config supports Requires.private
 404 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 405    pkgconfig_requires_private="Requires.private"
 406 else
 407    pkgconfig_requires_private="Requires"
 408 fi
 409 AC_SUBST(pkgconfig_requires_private)
 410
 411 ### Checks for some build time option
 412 have_backtrace="no"
 413 AC_CHECK_FUNCS([backtrace], [have_backtrace="yes"], [])
 414
 415 want_ecore_timer_dump="yes"
 416
 417 AC_ARG_ENABLE([ecore-timer-dump],
 418    [AC_HELP_STRING([--disable-ecore-timer-dump], [disable tracking of timer allocation. @<:@default=enable@:>@])],
 419    [want_ecore_timer_dump=$enableval], [])
 420
 421 if test "x$want_ecore_timer_dump" = "xyes" -a "x$have_backtrace" = "xyes"; then
 422    AC_DEFINE(WANT_ECORE_TIMER_DUMP, [1], [Want Ecore_Timer dump infrastructure])
 423 fi
 424
 425 ### Checks for libraries
 426
 427 # Evil library for compilation on Windows
 428
 429 case "$host_os" in
 430    mingw* | cegcc*)
 431       PKG_CHECK_MODULES([EVIL], [evil])
 432       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 433       requirements_ecore="evil ${requirements_ecore}"
 434       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 435       requirements_ecore_file="evil ${requirements_ecore_file}"
 436       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 437       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 438       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 439       EFL_ECORE_CON_BUILD="-DEFL_ECORE_CON_BUILD"
 440       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 441       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 442       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 443       EFL_ECORE_IMF_EVAS_BUILD="-DEFL_ECORE_IMF_EVAS_BUILD"
 444       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 445       EFL_ECORE_INPUT_EVAS_BUILD="-DEFL_ECORE_INPUT_EVAS_BUILD"
 446       EFL_ECORE_IPC_BUILD="-DEFL_ECORE_IPC_BUILD"
 447       ;;
 448 esac
 449
 450 have_win32=""
 451 have_wince=""
 452 case "$host_os" in
 453    mingw32ce* | cegcc*)
 454       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 455       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 456       have_wince="yes"
 457       ;;
 458    mingw*)
 459       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 460       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 461       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 462       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 463       have_win32="yes"
 464       ;;
 465 esac
 466
 467 AC_SUBST(EFL_ECORE_BUILD)
 468 AC_SUBST(EFL_ECORE_CON_BUILD)
 469 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 470 AC_SUBST(EFL_ECORE_FILE_BUILD)
 471 AC_SUBST(EFL_ECORE_IMF_BUILD)
 472 AC_SUBST(EFL_ECORE_IMF_EVAS_BUILD)
 473 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 474 AC_SUBST(EFL_ECORE_INPUT_EVAS_BUILD)
 475 AC_SUBST(EFL_ECORE_IPC_BUILD)
 476 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 477 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 478 AC_SUBST(EFL_ECORE_SDL_BUILD)
 479
 480 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 481 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 482
 483 WIN32_LIBS=""
 484 case "$host_os" in
 485    mingw32ce* | cegcc*)
 486       WIN32_LIBS="-lws2"
 487       dlopen_libs="-ldl"
 488       ;;
 489    mingw*)
 490       WIN32_LIBS="-lws2_32"
 491       dlopen_libs="-ldl"
 492       ;;
 493    *)
 494       AC_CHECK_LIB([c], [dlopen],
 495          [],
 496          [AC_CHECK_LIB([dl], [dlopen],
 497              [dlopen_libs=-ldl])
 498          ])
 499       AC_CHECK_LIB([c], [clock_gettime],
 500          [AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])],
 501          [AC_CHECK_LIB([rt], [clock_gettime],
 502              [
 503               rt_libs=-lrt
 504               AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])
 505              ])
 506          ])
 507       ;;
 508 esac
 509 AC_SUBST(WIN32_LIBS)
 510 AC_SUBST(dlopen_libs)
 511 AC_SUBST(rt_libs)
 512
 513 # Eina library
 514
 515 PKG_CHECK_MODULES(EINA, [eina >= 1.0.0])
 516 #FIXME check all the requirements when the eina move will be finished
 517 requirements_ecore="eina >= 1.0.0 ${requirements_ecore}"
 518 requirements_ecore_con="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_con}"
 519 #requirements_ecore_config="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_config}"
 520 requirements_ecore_directfb="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_directfb}"
 521 requirements_ecore_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_evas}"
 522 requirements_ecore_fb="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_fb}"
 523 requirements_ecore_file="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_file}"
 524 requirements_ecore_imf="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_imf}"
 525 requirements_ecore_imf_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_imf_evas}"
 526 requirements_ecore_input="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_input}"
 527 requirements_ecore_input_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_input_evas}"
 528 requirements_ecore_ipc="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_ipc}"
 529 requirements_ecore_cocoa="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_cocoa}"
 530 requirements_ecore_sdl="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_sdl}"
 531 requirements_ecore_win32="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_win32}"
 532 requirements_ecore_wince="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_wince}"
 533 requirements_ecore_x="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_x}"
 534
 535
 536 # glib support (main loop integration)
 537 AC_ARG_ENABLE([glib],
 538    [AC_HELP_STRING([--disable-glib], [disable glib support. @<:@default=detect@:>@])],
 539    [want_glib=$enableval], [])
 540
 541 if test "x$want_glib" != "xno"; then
 542    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 543 else
 544    have_glib="no"
 545 fi
 546 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 547    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 548 elif test "x$have_glib" = "xyes"; then
 549    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 550    requirements_ecore="glib-2.0 ${requirements_ecore}"
 551 fi
 552
 553
 554 # SDL library (ecore_sdl)
 555
 556 have_sdl="no"
 557 PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 558 if test "x${have_sdl}" != "xyes" ; then
 559    SDL_CONFIG="sdl-config"
 560    AC_ARG_WITH([sdl-config],
 561       [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 562       [
 563        SDL_CONFIG=$withval
 564        AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 565       ])
 566
 567    AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 568
 569    if test -n "$SDL_CONFIG" ; then
 570       SDL_CFLAGS=`$SDL_CONFIG --cflags`
 571       SDL_LIBS=`$SDL_CONFIG --libs`
 572       AC_SUBST(SDL_CFLAGS)
 573       AC_SUBST(SDL_LIBS)
 574       have_sdl="yes"
 575    fi
 576 fi
 577
 578 if test "x${have_sdl}" = "xyes" ; then
 579    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 580       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 581 fi
 582
 583
 584 # DirectFB library (ecore_directfb)
 585
 586 PKG_CHECK_MODULES([DIRECTFB],
 587    [directfb >= 0.9.16],
 588    [have_directfb="yes"],
 589    [have_directfb="no"])
 590
 591
 592 # Eet library (ecore_config)
 593
 594 #PKG_CHECK_MODULES([EET],
 595 #   [eet >= 1.4.0],
 596 #   [have_eet="yes"],
 597 #   [have_eet="no"])
 598
 599
 600 # Xlib and XCB (ecore_x)
 601
 602 have_x="no"
 603 have_ecore_x="no"
 604 have_ecore_x_xlib="no"
 605 have_ecore_x_xcb="no"
 606
 607 x_dir="";
 608 x_includes="";
 609 x_cflags="";
 610 x_libs="";
 611
 612 ecore_x_libs_private=""
 613
 614 AC_ARG_ENABLE(ecore-x-composite,
 615    [AC_HELP_STRING([--disable-ecore-x-composite],
 616        [disable the ecore_x support for Xcomposite extension.
 617         @<:@default=detect@:>@])],
 618    [want_ecore_x_composite=$enableval])
 619
 620 AC_ARG_ENABLE(ecore-x-damage,
 621    [AC_HELP_STRING([--disable-ecore-x-damage],
 622        [disable the ecore_x support for Xdamage extension.
 623         @<:@default=detect@:>@])],
 624    [want_ecore_x_damage=$enableval])
 625
 626 AC_ARG_ENABLE(ecore-x-dpms,
 627    [AC_HELP_STRING([--disable-ecore-x-dpms],
 628        [disable the ecore_x support for Xdpms extension.
 629         @<:@default=detect@:>@])],
 630    [want_ecore_x_dpms=$enableval])
 631
 632 AC_ARG_ENABLE(ecore-x-randr,
 633    [AC_HELP_STRING([--disable-ecore-x-randr],
 634        [disable the ecore_x support for Xrandr extension.
 635         @<:@default=detect@:>@])],
 636    [want_ecore_x_randr=$enableval])
 637
 638 AC_ARG_ENABLE(ecore-x-render,
 639    [AC_HELP_STRING([--disable-ecore-x-render],
 640        [disable the ecore_x support for Xrender extension.
 641         @<:@default=detect@:>@])],
 642    [want_ecore_x_render=$enableval])
 643
 644 AC_ARG_ENABLE(ecore-x-screensaver,
 645    [AC_HELP_STRING([--disable-ecore-x-screensaver],
 646        [disable the ecore_x support for Xscreensaver extension.
 647         @<:@default=detect@:>@])],
 648    [want_ecore_x_screensaver=$enableval])
 649
 650 AC_ARG_ENABLE(ecore-x-shape,
 651    [AC_HELP_STRING([--disable-ecore-x-shape],
 652        [disable the ecore_x support for Xshape extension.
 653         @<:@default=detect@:>@])],
 654    [want_ecore_x_shape=$enableval])
 655
 656 AC_ARG_ENABLE(ecore-x-sync,
 657    [AC_HELP_STRING([--disable-ecore-x-sync],
 658        [disable the ecore_x support for Xsync extension.
 659         @<:@default=detect@:>@])],
 660    [want_ecore_x_sync=$enableval])
 661
 662 AC_ARG_ENABLE(ecore-x-xfixes,
 663    [AC_HELP_STRING([--disable-ecore-x-xfixes],
 664        [disable the ecore_x support for Xfixes extension.
 665         @<:@default=detect@:>@])],
 666    [want_ecore_x_xfixes=$enableval])
 667
 668 AC_ARG_ENABLE(ecore-x-xinerama,
 669    [AC_HELP_STRING([--disable-ecore-x-xinerama],
 670        [disable the ecore_x support for Xinerama extension.
 671         @<:@default=detect@:>@])],
 672    [want_ecore_x_xinerama=$enableval])
 673
 674 AC_ARG_ENABLE(ecore-x-xprint,
 675    [AC_HELP_STRING([--disable-ecore-x-xprint],
 676        [disable the ecore_x support for Xprint extension.
 677         @<:@default=detect@:>@])],
 678    [want_ecore_x_xprint=$enableval])
 679
 680 AC_ARG_ENABLE(ecore-x-xtest,
 681    [AC_HELP_STRING([--disable-ecore-x-xtest],
 682        [disable the ecore_x support for Xtest extension.
 683         @<:@default=detect@:>@])],
 684    [want_ecore_x_xtest=$enableval])
 685
 686 AC_ARG_ENABLE(ecore-x-cursor,
 687    [AC_HELP_STRING([--disable-ecore-x-cursor],
 688        [disable the ecore_x support for Xcursor extension.
 689         @<:@default=detect@:>@])],
 690    [want_ecore_x_cursor=$enableval])
 691
 692 AC_ARG_ENABLE(ecore-x-input,
 693    [AC_HELP_STRING([--disable-ecore-x-input],
 694        [disable the ecore_x support for Xinput/Xinput2 extension.
 695         @<:@default=detect@:>@])],
 696    [want_ecore_x_input=$enableval])
 697
 698 AC_ARG_ENABLE(ecore-x-dri,
 699    [AC_HELP_STRING([--disable-ecore-x-dri],
 700        [disable the ecore_x support for DRI extension.
 701         @<:@default=detect@:>@])],
 702    [want_ecore_x_dri=$enableval])
 703
 704 AC_ARG_ENABLE(ecore-x-xcb,
 705    [AC_HELP_STRING([--enable-ecore-x-xcb],
 706        [enable the ecore_x module with XCB backend. @<:@default=disabled@:>@])],
 707    [want_ecore_x_xcb=$enableval])
 708
 709 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 710 AC_MSG_RESULT($want_ecore_x_xcb)
 711
 712 if test "x$want_ecore_x_xcb" = "xyes" ; then
 713
 714   AC_MSG_CHECKING([keysym definitions])
 715   KEYSYMDEFDIR=`$PKG_CONFIG --variable=includedir xproto`/X11
 716   FILES="keysymdef.h XF86keysym.h Sunkeysym.h DECkeysym.h HPkeysym.h"
 717   for i in $FILES; do
 718       if test -f "$KEYSYMDEFDIR/$i"; then
 719         KEYSYMDEFS="$KEYSYMDEFS $KEYSYMDEFDIR/$i"
 720       elif test "x$i" = "xkeysymdef.h"; then
 721         AC_MSG_ERROR([Cannot find keysymdef.h])
 722       fi
 723   done
 724   AC_MSG_RESULT([$KEYSYMDEFS])
 725   AC_SUBST(KEYSYMDEFS)
 726
 727   have_iconv="no"
 728   AC_ARG_WITH([iconv-link],
 729     AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 730       [
 731         LIBS="$withval $LIBS"
 732         have_iconv="yes"
 733       ])
 734
 735   AC_MSG_CHECKING(for explicit iconv link options)
 736   if test "x${iconv_libs}" = "x" ; then
 737     AC_MSG_RESULT([no explicit iconv link option])
 738   else
 739     AC_MSG_RESULT([$iconv_libs])
 740   fi
 741
 742   if test "x${have_iconv}" = "xno" ; then
 743     AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 744
 745     if test "x${have_iconv}" = "xyes" ; then
 746       AC_MSG_CHECKING([whether iconv() is in libc])
 747
 748       AC_LINK_IFELSE(
 749         [AC_LANG_PROGRAM(
 750         [[
 751           #include <stdlib.h>
 752           #include <iconv.h>
 753         ]],
 754         [[
 755           iconv_t ic;
 756           size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 757         ]])],
 758         [have_iconv="yes"],
 759         [have_iconv="no"])
 760
 761       AC_MSG_RESULT([${have_iconv}])
 762     fi
 763
 764     if test "x${have_iconv}" = "xno" ; then
 765       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 766
 767       LIBS_save="${LIBS}"
 768       LIBS="-liconv $LIBS"
 769       AC_LINK_IFELSE(
 770       [AC_LANG_PROGRAM(
 771         [[
 772           #include <stdlib.h>
 773           #include <iconv.h>
 774         ]],
 775         [[
 776           iconv_t ic;
 777           size_t count;
 778           count = iconv(ic, NULL, NULL, NULL, NULL);
 779         ]])],
 780         [have_iconv="yes"],
 781         [
 782           have_iconv="no"
 783           LIBS=${LIBS_save}
 784         ])
 785
 786       AC_MSG_RESULT([${have_iconv}])
 787     fi
 788
 789     if test "x${have_iconv}" = "xno" ; then
 790       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 791
 792       LIBS_save="${LIBS}"
 793       LIBS="-liconv_plug $LIBS"
 794       AC_LINK_IFELSE(
 795       [AC_LANG_PROGRAM(
 796       [[
 797         #include <stdlib.h>
 798         #include <iconv.h>
 799       ]],
 800       [[
 801         iconv_t ic;
 802         size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 803       ]])],
 804       [have_iconv="yes"],
 805       [
 806         have_iconv="no"
 807         LIBS=${LIBS_save}
 808       ])
 809
 810       AC_MSG_RESULT([${have_iconv}])
 811     fi
 812
 813     if test "x${have_iconv}" = "xyes" ; then
 814       AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 815     fi
 816   fi
 817
 818   PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-shm xcb-event xcb-icccm >= 0.3.8 xcb-util >= 0.3.8 xcb-image xcb-keysyms >= 0.3.8,
 819     [ have_ecore_x_xcb="yes"
 820       requirements_ecore_x="x11-xcb xcb xcb-shm xcb-event xcb-icccm xcb-util xcb-image xcb-keysyms ${requirements_ecore_x}"
 821     ],
 822     [
 823         PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms,
 824           [ have_ecore_x_xcb="yes"
 825             AC_DEFINE(OLD_XCB_VERSION, 1, [xcb version])
 826             requirements_ecore_x="x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms ${requirements_ecore_x}" ],
 827           [ have_ecore_x_xcb="no" ])
 828     ],
 829     [have_ecore_x_xcb="no" ])
 830
 831   if test "x$have_ecore_x_xcb" = "xyes" ; then
 832
 833    PKG_CHECK_MODULES([PIXMAN],
 834       [pixman-1],
 835       [
 836        have_pixman="yes"
 837        AC_DEFINE(HAVE_PIXMAN, 1, [have pixman for rendering])
 838        requirements_ecore_x="pixman-1 ${requirements_ecore_x}"
 839       ],
 840       [
 841        if test "x${want_pixman}" = "xyes" -a "x${use_strict}" = "xyes" ; then
 842           AC_MSG_ERROR([Pixman not found (strict dependencies checking)])
 843        fi
 844       ])
 845
 846     if test "x$want_ecore_x_composite" != "xno"; then
 847       PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 848         [ have_ecore_x_xcb_composite="yes"
 849           requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 850           AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 851         [ have_ecore_x_xcb_composite="no" ])
 852     else
 853       have_ecore_x_xcb_composite="no"
 854       AC_MSG_NOTICE("composite extension explicitly disabled")
 855     fi
 856
 857     if test "x$want_ecore_x_damage" != "xno"; then
 858       PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 859         [ have_ecore_x_xcb_damage="yes"
 860           requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 861           AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 862         [ have_ecore_x_xcb_damage="no" ])
 863     else
 864       have_ecore_x_xcb_damage="no"
 865       AC_MSG_NOTICE("damage extension explicitly disabled")
 866     fi
 867
 868     if test "x$want_ecore_x_dpms" != "xno"; then
 869       PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 870         [ have_ecore_x_xcb_dpms="yes"
 871           requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 872           AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 873         [ have_ecore_x_xcb_dpms="no" ])
 874     else
 875       have_ecore_x_xcb_dpms="no"
 876       AC_MSG_NOTICE("dpms extension explicitly disabled")
 877     fi
 878
 879     if test "x$want_ecore_x_randr" != "xno"; then
 880       PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 881         [ have_ecore_x_xcb_randr="yes"
 882           requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 883           AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 884         [ have_ecore_x_xcb_randr="no" ])
 885     else
 886       have_ecore_x_xcb_randr="no"
 887       AC_MSG_NOTICE("randr extension explicitly disabled")
 888     fi
 889
 890     if test "x$want_ecore_x_render" != "xno"; then
 891       PKG_CHECK_MODULES(XCB_RENDER, xcb-render xcb-renderutil,
 892         [ have_ecore_x_xcb_render="yes"
 893           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
 894           AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 895         [ have_ecore_x_xcb_render="no" ])
 896     else
 897       have_ecore_x_xcb_render="no"
 898       AC_MSG_NOTICE("render extension explicitly disabled")
 899     fi
 900
 901     if test "x$want_ecore_x_screensaver" != "xno"; then
 902       PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 903         [ have_ecore_x_xcb_screensaver="yes"
 904           requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 905           AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 906         [ have_ecore_x_xcb_screensaver="no" ])
 907     else
 908       have_ecore_x_xcb_screensaver="no"
 909       AC_MSG_NOTICE("screensaver extension explicitly disabled")
 910     fi
 911
 912     if test "x$want_ecore_x_shape" != "xno"; then
 913       PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 914         [ have_ecore_x_xcb_shape="yes"
 915           requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 916           AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 917         [ have_ecore_x_xcb_shape="no" ])
 918     else
 919       have_ecore_x_xcb_shape="no"
 920       AC_MSG_NOTICE("shape extension explicitly disabled")
 921     fi
 922
 923     if test "x$want_ecore_x_sync" != "xno"; then
 924       PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 925         [ have_ecore_x_xcb_sync="yes"
 926           requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
 927           AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 928         [ have_ecore_x_xcb_sync="no" ])
 929     else
 930       have_ecore_x_xcb_sync="no"
 931       AC_MSG_NOTICE("sync extension explicitly disabled")
 932     fi
 933
 934     if test "x$want_ecore_x_xfixes" != "xno"; then
 935       PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 936         [ have_ecore_x_xcb_xfixes="yes"
 937           requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
 938           AC_DEFINE(ECORE_XCB_XFIXES, 1, [Build support for XCB xfixes]) ],
 939         [ have_ecore_x_xcb_xfixes="no" ])
 940     else
 941       have_ecore_x_xcb_xfixes="no"
 942       AC_MSG_NOTICE("xfixes extension explicitly disabled")
 943     fi
 944
 945     if test "x$want_ecore_x_xinerama" != "xno"; then
 946       PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
 947         [ have_ecore_x_xcb_xinerama="yes"
 948           requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
 949           AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
 950         [ have_ecore_x_xcb_xinerama="no" ])
 951     else
 952       have_ecore_x_xcb_xinerama="no"
 953       AC_MSG_NOTICE("xinerama extension explicitly disabled")
 954     fi
 955
 956     if test "x$want_ecore_x_xprint" != "xno"; then
 957       PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
 958         [ have_ecore_x_xcb_xprint="yes"
 959           requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
 960           AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
 961         [ have_ecore_x_xcb_xprint="no" ])
 962     else
 963       have_ecore_x_xcb_xprint="no"
 964       AC_MSG_NOTICE("xprint extension explicitly disabled")
 965     fi
 966
 967     if test "x$want_ecore_x_xtest" != "xno"; then
 968       PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
 969         [ have_ecore_x_xcb_xtest="yes"
 970           requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
 971           AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
 972         [ have_ecore_x_xcb_xtest="no" ])
 973     else
 974       have_ecore_x_xcb_xtest="no"
 975       AC_MSG_NOTICE("xtest extension explicitly disabled")
 976     fi
 977
 978 # input extension disabled currently in xcb as xcb-input has some issues
 979     want_ecore_x_input="no"
 980     if test "x$want_ecore_x_input" != "xno"; then
 981       PKG_CHECK_MODULES(XCB_XINPUT, xcb-xinput,
 982         [ have_ecore_x_xcb_xinput="yes"
 983           requirements_ecore_x="xcb-xinput ${requirements_ecore_x}"
 984           AC_DEFINE(ECORE_XCB_XINPUT, 1, [Build support for XCB xinput]) ],
 985         [ have_ecore_x_xcb_xinput="no" ])
 986     else
 987       have_ecore_x_xcb_xinput="no"
 988       AC_MSG_NOTICE("xinput extension explicitly disabled")
 989     fi
 990
 991     if test "x$want_ecore_x_cursor" != "xno"; then
 992       PKG_CHECK_MODULES(XCB_CURSOR, xcb-render xcb-renderutil,
 993         [ have_ecore_x_xcb_cursor="yes"
 994           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
 995           AC_DEFINE(ECORE_XCB_CURSOR, 1, [Build support for XCB cursor]) ],
 996         [ have_ecore_x_xcb_cursor="no" ])
 997     else
 998       have_ecore_x_xcb_cursor="no"
 999       AC_MSG_NOTICE("cursor extension explicitly disabled")
1000     fi
1001
1002 #    if test "x$want_ecore_x_dri" != "xno"; then
1003 #      PKG_CHECK_MODULES(XCB_DRI, xcb-dri2,
1004 #        [ have_ecore_x_xcb_dri="yes"
1005 #          requirements_ecore_x="xcb-dri2 ${requirements_ecore_x}"
1006 #          AC_DEFINE(ECORE_XCB_DRI, 1, [Build support for XCB dri/dri2]) ],
1007 #        [ have_ecore_x_xcb_dri="no" ])
1008 #    else
1009 #      have_ecore_x_xcb_dri="no"
1010 #      AC_MSG_NOTICE("dri extension explicitly disabled")
1011 #    fi
1012
1013     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
1014
1015     x_cflags=$ECORE_XCB_CFLAGS
1016     x_libs=$ECORE_XCB_LIBS
1017     have_x="yes"
1018
1019     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
1020     AC_SUBST(have_ecore_x_xcb_define)
1021   fi
1022 fi
1023
1024 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
1025   AC_PATH_XTRA
1026   AC_CHECK_HEADER(X11/X.h,
1027     [
1028      if test "x$want_evas_simple_x11" = "xyes"; then
1029        x_libs="${x_libs} -lX11 -lXext"
1030      else
1031        x_dir=${x_dir:-/usr/X11R6}
1032        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
1033        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
1034      fi
1035      have_ecore_x_xlib="yes"
1036     ]
1037   )
1038
1039   if test "x$have_ecore_x_xlib" = "xyes"; then
1040     Xcursor_libs=""
1041     Xcursor_cflags=""
1042     use_Xcursor="no"
1043     PCFLAGS=$CFLAGS
1044     CFLAGS="$x_cflags $x_includes"
1045
1046     if test "x$want_ecore_x_cursor" = "xyes"; then
1047       AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
1048         [
1049           AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
1050             [
1051               AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
1052               Xcursor_cflags=""
1053               Xcursor_libs="-lXcursor"
1054               use_Xcursor="yes"
1055             ], [
1056               Xcursor_cflags=""
1057               Xcursor_libs=""
1058               use_Xcursor="no"
1059             ], [
1060               $x_libs -lXrender
1061             ]
1062           )
1063         ], [
1064           Xcursor_cflags=""
1065           Xcursor_libs=""
1066           use_Xcursor="no"
1067         ], [
1068           #include <X11/Xlib.h>
1069         ]
1070       )
1071       CFLAGS=$PCFLAGS
1072     else
1073       Xcursor_cflags=""
1074       Xcursor_libs=""
1075       use_Xcursor="no"
1076       AC_MSG_NOTICE("Xcursor explicitly disabled")
1077     fi
1078
1079     AC_SUBST(Xcursor_cflags)
1080     AC_SUBST(Xcursor_libs)
1081
1082     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat], [$want_ecore_x_xkb])
1083     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension], [$want_ecore_x_composite])
1084     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract], [$want_ecore_x_damage])
1085     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension], [$want_ecore_x_dpms])
1086     if test "x$use_xdpms" = "xno" ; then
1087       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension], [$want_ecore_x_dpms])
1088     fi
1089     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion], [$want_ecore_x_xfixes])
1090     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens], [$want_ecore_x_xinerama])
1091     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens], [$want_ecore_x_xprint])
1092     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent], [$want_ecore_x_randr])
1093     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat], [$want_ecore_x_render])
1094     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent], [$want_ecore_x_xtest])
1095     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput], [$want_ecore_x_screensaver])
1096     ECORE_CHECK_X_EXTENSION([Xi2], [XInput2.h], [Xi], [XIQueryDevice], [$want_ecore_x_input])
1097
1098     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} ${XI2_LIBS}"
1099
1100     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
1101     have_x="yes"
1102
1103     have_ecore_x_xlib="yes"
1104   fi
1105 fi
1106
1107 AC_SUBST(x_cflags)
1108 AC_SUBST(x_includes)
1109 AC_SUBST(x_libs)
1110 AC_SUBST(ecore_x_libs_private)
1111
1112 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
1113 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
1114
1115
1116 # Evas library (ecore_config, ecore_input_evas, ecore_imf_evas and ecore_evas)
1117
1118 PKG_CHECK_MODULES([EVAS], [evas >= 1.0.0],
1119    [have_evas="yes"],
1120    [have_evas="no"])
1121
1122
1123 ### Checks for header files
1124
1125 AC_CHECK_HEADERS([sys/select.h sys/prctl.h])
1126
1127 EFL_CHECK_PATH_MAX
1128
1129 AC_HEADER_SYS_WAIT
1130 AC_SYS_LARGEFILE
1131
1132 have_addrinfo="no"
1133 case "$host_os" in
1134    mingw* | cegcc*)
1135       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
1136       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
1137       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
1138       have_addrinfo="yes"
1139       ;;
1140    *)
1141       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h sys/time.h sys/mman.h signal.h sys/resource.h])
1142       ;;
1143 esac
1144
1145 # ecore_con
1146
1147 AC_CHECK_HEADERS([arpa/inet.h arpa/nameser.h netinet/tcp.h netinet/in.h sys/socket.h sys/un.h ws2tcpip.h netdb.h])
1148
1149 if test "x${ac_cv_header_netdb_h}" = "xyes" ; then
1150    have_addrinfo="yes"
1151 fi
1152
1153 # Framebuffer (ecore_fb)
1154 have_fb="no"
1155 AC_CHECK_HEADER([linux/fb.h],
1156    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
1157
1158 # Cocoa header files (ecore_cocoa)
1159
1160 cocoa_ldflags="";
1161 have_cocoa="no"
1162 m4_ifdef([AC_PROG_OBJC], [
1163     if test "x${have_gnu_objc}" = "xyes" ; then
1164        AC_LANG_PUSH([Objective C])
1165        AC_CHECK_HEADER([Cocoa/Cocoa.h],
1166           [
1167            have_cocoa="yes"
1168            cocoa_ldflags="-framework Cocoa"
1169           ])
1170        AC_LANG_POP([Objective C])
1171     fi
1172 ])
1173 AC_SUBST(cocoa_ldflags)
1174
1175 want_epoll=yes
1176 AC_ARG_ENABLE(epoll,
1177   AC_HELP_STRING([--enable-epoll], [enable or disable epoll support]),
1178   [want_epoll=$enableval])
1179
1180 if test "x${want_epoll}" = "xyes" ; then
1181   # check for epoll support
1182   AC_CHECK_HEADERS([sys/epoll.h])
1183 fi
1184
1185 # timerfd_create
1186 AC_CHECK_HEADERS([sys/timerfd.h])
1187 AC_CHECK_FUNCS(timerfd_create)
1188
1189 # thread support
1190
1191 EFL_CHECK_THREADS(
1192    [
1193     if test "x${_efl_have_posix_threads}" = "xyes" ; then
1194        have_threads="POSIX"
1195     else
1196        if test "x${_efl_have_win32_threads}" = "xyes" ; then
1197           have_threads="Win32"
1198        else
1199           have_threads="no"
1200        fi
1201     fi
1202    ],
1203    [have_threads="no"])
1204
1205 ### enable thread safety if we have threads, unless specifically asked not to
1206 if test "x${have_threads}" = "xno"
1207 then
1208   want_thread_safety="no"
1209 else
1210   want_thread_safety="no"  # to be changed to yes when ready
1211   AC_ARG_ENABLE(thread-safety,
1212     AC_HELP_STRING([--enable-thread-safety], [enable or disable thread safety]),
1213     [want_thread_safety=$enableval])
1214 fi
1215
1216 if test "x${want_thread_safety}" = "xyes"
1217 then
1218    AC_DEFINE([HAVE_THREAD_SAFETY], [1], [Define to enable thread safety])
1219 fi
1220
1221 ### Checks for types
1222 AC_CHECK_SIZEOF(int, 4)
1223 AC_CHECK_SIZEOF(long, 4)
1224
1225
1226 ### Checks for structures
1227
1228
1229 ### Checks for compiler characteristics
1230 AM_PROG_CC_STDC
1231 AC_C_CONST
1232 AC_C_BIGENDIAN
1233 AC_HEADER_STDC
1234 AC_C___ATTRIBUTE__
1235
1236 WIN32_CPPFLAGS=""
1237 WIN32_CFLAGS=""
1238 case "$host_os" in
1239    mingw32ce*)
1240       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1241       ;;
1242    cegcc*)
1243       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1244       WIN32_CFLAGS="-mwin32"
1245       ;;
1246    mingw*)
1247       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0501"
1248       ;;
1249 esac
1250 AC_SUBST(WIN32_CPPFLAGS)
1251 AC_SUBST(WIN32_CFLAGS)
1252
1253
1254 ### Checks for linker characteristics
1255
1256 # use --enable-auto-import on Windows
1257
1258 lt_enable_auto_import=""
1259 case "$host_os" in
1260    mingw* | cegcc*)
1261       lt_enable_auto_import="-Wl,--enable-auto-import"
1262       ;;
1263 esac
1264 AC_SUBST(lt_enable_auto_import)
1265
1266 ### Checks for library functions
1267 AC_ISC_POSIX
1268 AC_FUNC_ALLOCA
1269 AC_CHECK_FUNCS([gettimeofday strlcpy execvp])
1270
1271 AC_COMPILE_IFELSE(
1272    [AC_LANG_PROGRAM(
1273        [[
1274 #include <math.h>
1275        ]],
1276        [[
1277 int i = isfinite(0);
1278        ]])],
1279    [
1280     AC_DEFINE(HAVE_ISFINITE, 1, [Define to 1 if you have `isfinite', as a function or macro.])
1281     have_isfinite="yes"
1282    ],
1283    [have_isfinite="no"])
1284
1285 AC_MSG_CHECKING([for isfinite])
1286 AC_MSG_RESULT([${have_isfinite}])
1287
1288 have_atfile_source=auto
1289 AC_ARG_ENABLE([atfile-source],
1290    [AC_HELP_STRING([--disable-atfile-source],
1291        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@])],
1292    [
1293     if test "x${enableval}" = "xyes" ; then
1294        have_atfile_source="yes"
1295     else
1296        have_atfile_source="no"
1297     fi],
1298    [have_atfile_source=auto])
1299
1300 if ! test "x${have_atfile_source}" = "xno" ; then
1301    AC_CHECK_FUNCS(mkdirat,
1302       [
1303        have_atfile_source="yes"
1304        AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
1305       ],
1306       [
1307        if test "x${have_atfile_source}" = "xyes" ; then
1308           AC_MSG_ERROR([required atfile-source but no mkdirat()])
1309        fi
1310        have_atfile_source="no"
1311       ])
1312 fi
1313
1314 ### Checks for optionnal feature
1315 AC_CHECK_FUNC([mallinfo],
1316    [
1317     have_mallinfo="yes"
1318     AC_DEFINE(HAVE_MALLINFO, 1, [Gather memory statistic])
1319    ],
1320    [have_mallinfo="no"])
1321
1322 ### Ecore modules
1323
1324 ## Core modules
1325
1326 # ecore_con
1327 ECORE_CHECK_MODULE([con], [${want_ecore_con}], [Con], [${have_addrinfo}])
1328
1329 have_curl="no"
1330 have_gnutls="no"
1331 have_openssl="no"
1332 have_cares="no"
1333 if test "x${have_ecore_con}" = "xyes" ; then
1334
1335    # Verify IPV6 availability in headers
1336    have_ipv6="no"
1337    AC_CHECK_TYPES([struct ipv6_mreq], [have_ipv6="yes"], [have_ipv6="no"],
1338                [[
1339 #ifdef HAVE_NETINET_IN_H
1340 # include <netinet/in.h>
1341 #endif
1342 #ifdef HAVE_WS2TCPIP_H
1343 # include <ws2tcpip.h>
1344 #endif
1345         ]])
1346
1347    if test "x${have_ipv6}" = "xyes" ; then
1348       AC_DEFINE(HAVE_IPV6, 1, [Define if IPV6 is supported])
1349    fi
1350
1351    ECORE_CHECK_CURL([${want_curl}],
1352       [
1353        have_curl="yes"
1354        requirements_ecore_con="libcurl ${requirements_ecore_con}"
1355       ],
1356       [have_curl="no"])
1357
1358    ECORE_CHECK_GNUTLS([${want_gnutls}],
1359       [have_gnutls="yes"],
1360       [have_gnutls="no"])
1361
1362    ECORE_CHECK_OPENSSL([${want_openssl}],
1363       [have_openssl="yes"],
1364       [have_openssl="no"])
1365
1366    if test "x${have_gnutls}" = "xyes" ; then
1367       requirements_ecore_con="gnutls ${requirements_ecore_con}"
1368       # no need to add it to req_ecore_ipc, since they
1369       # depends on ecore_con anyway.
1370    else
1371       if test "x${have_openssl}" = "xyes" ; then
1372          requirements_ecore_con="openssl ${requirements_ecore_con}"
1373          # no need to add it to req_ecore_ipc, since they
1374          # depends on ecore_con anyway.
1375       fi
1376    fi
1377
1378    ECORE_CHECK_CARES([${want_cares}],
1379       [
1380        have_cares="yes"
1381        requirements_ecore_con="libcares ${requirements_ecore_con}"
1382       ],
1383       [have_cares="no"])
1384
1385 fi
1386
1387 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
1388
1389 # ecore_ipc
1390 ECORE_CHECK_MODULE([ipc], [${want_ecore_ipc}], [Ipc], [${have_ecore_con}],
1391    [requirements_ecore_ipc="ecore-con >= 1.0.0 ${requirements_ecore_ipc}"])
1392
1393 # ecore_file
1394 ECORE_CHECK_MODULE([file], [${want_ecore_file}], [File])
1395
1396 have_poll="no"
1397 have_inotify="no"
1398 have_notify_win32="no"
1399 if test "x${have_ecore_file}" = "xyes" ; then
1400    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
1401    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
1402    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
1403
1404    if test "x${have_ecore_con}" = "xyes" ; then
1405       requirements_ecore_file="ecore-con >= 1.0.0 ${requirements_ecore_file}"
1406    else
1407       ECORE_CHECK_CURL([${want_curl}],
1408          [
1409           have_curl="yes"
1410           requirements_ecore_file="libcurl ${requirements_ecore_file}"
1411          ],
1412          [have_curl="no"])
1413    fi
1414
1415 fi
1416
1417 # ecore_config
1418 #ecore_config_deps="no"
1419 #if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
1420 #   ecore_config_deps="yes"
1421 #fi
1422
1423 #ECORE_CHECK_MODULE([config], [${want_ecore_config}], [Config], [${ecore_config_deps}],
1424 #   [requirements_ecore_config="ecore-ipc >= 1.0.0 evas >= 1.0.0 eet >= 1.4.0 ${requirements_ecore_config}"])
1425
1426 AM_CONDITIONAL(BUILD_ECORE_CONFIG, false)
1427
1428 # ecore_imf
1429
1430 ECORE_CHECK_MODULE([imf], [${want_ecore_imf}], [Imf])
1431
1432 # ecore_imf_evas
1433
1434 ecore_imf_evas_deps="no"
1435 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
1436    ecore_imf_evas_deps="yes"
1437 fi
1438
1439 ECORE_CHECK_MODULE([imf-evas], [${want_ecore_imf}], [Imf_Evas], [${ecore_imf_evas_deps}],
1440    [requirements_ecore_imf_evas="ecore-imf >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_imf_evas}"])
1441
1442 # ecore_input{_evas}
1443 ECORE_CHECK_MODULE([input], [${want_ecore_input}], [Input])
1444 ECORE_CHECK_MODULE([input-evas], [${want_ecore_input}], [Input_Evas], [${have_evas}],
1445    [requirements_ecore_input_evas="ecore-input >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_input}"])
1446
1447 # ecore_imf_xim
1448 AM_CONDITIONAL(BUILD_ECORE_IMF_XIM, false)
1449 ecore_imf_xim_deps="no"
1450 echo "have_ecore_x_xlib: ${have_ecore_x_xlib}"
1451 if test    "x${have_ecore_imf}" = "xyes" \
1452         -a "x${have_ecore_x_xlib}" = "xyes" \
1453         -a "x${have_ecore_input}" = "xyes" ; then
1454    ecore_imf_xim_deps="yes"
1455    AC_DEFINE(BUILD_ECORE_IMF_XIM, 1, [Ecore Imf XIM Support])
1456 fi
1457
1458 ECORE_CHECK_MODULE([imf-xim], [${want_ecore_imf}], [Imf_XIM], [${ecore_imf_xim_deps}],
1459    [requirements_ecore_imf_xim="ecore-imf >= 1.0.0 ecore-x >= 1.0.0 ecore-input >= 1.0.0 ${requirements_ecore_imf_xim}"])
1460
1461 ## Graphic systems
1462
1463 # ecore_x{cb}
1464
1465 ecore_x_deps="no"
1466 if test "x${have_x}" = "xyes" -a \
1467         "x${have_ecore_input}" = "xyes" ; then
1468    ecore_x_deps="yes"
1469 fi
1470
1471 ECORE_CHECK_MODULE([x], [${want_ecore_x}], [X], [${ecore_x_deps}],
1472   [
1473    ecore_x_libs="$ecore_x_libs $x_libs"
1474    requirements_ecore_x="ecore-input >= 1.0.0 ${requirements_ecore_x}"
1475   ])
1476
1477 # ecore_win32
1478
1479 ECORE_CHECK_MODULE([win32], [${want_ecore_win32}], [Win32], [${have_ecore_input}],
1480    [
1481     ecore_win32_libs="-lole32 -lgdi32"
1482     requirements_ecore_win32="ecore-input >= 1.0.0 ${requirements_ecore_win32}"
1483    ])
1484 AC_SUBST(ecore_win32_libs)
1485
1486 # ecore_cocoa
1487
1488 ecore_cocoa_deps="no"
1489 if test "x${have_ecore_input}" = "xyes" -a "x${have_cocoa}" = "xyes" ; then
1490    ecore_cocoa_deps="yes"
1491 fi
1492
1493 ECORE_CHECK_MODULE([cocoa], [${want_ecore_cocoa}], [Cocoa], [${ecore_cocoa_deps}],
1494    [requirements_ecore_cocoa="ecore-input >= 1.0.0 ${requirements_ecore_cocoa}"])
1495
1496 # ecore_sdl
1497
1498 ecore_sdl_deps="no"
1499 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
1500    ecore_sdl_deps="yes"
1501 fi
1502
1503 ECORE_CHECK_MODULE([sdl], [${want_ecore_sdl}], [Sdl], [${ecore_sdl_deps}],
1504    [requirements_ecore_sdl="ecore-input >= 1.0.0 ${requirements_ecore_sdl}"])
1505
1506 # ecore_fb
1507 ECORE_CHECK_MODULE([fb], [${want_ecore_fb}], [FB], [$have_fb])
1508
1509 if test "x${have_ecore_fb}" = "xyes" ; then
1510    ECORE_CHECK_TSLIB([${want_tslib}],
1511       [
1512        have_tslib="yes"
1513        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
1514       ],
1515       [have_tslib="no"])
1516 fi
1517
1518 # ecore_directfb
1519
1520 ECORE_CHECK_MODULE([directfb], [${want_ecore_directfb}], [DirectFB], [${have_directfb}],
1521    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
1522
1523 # ecore_wince
1524
1525 ECORE_CHECK_MODULE([wince], [${want_ecore_wince}], [WinCE], [${have_ecore_input}],
1526    [requirements_ecore_win32="ecore-input >= 1.0.0 ${requirements_ecore_win32}"])
1527
1528 ## Ecore Evas
1529
1530 # ecore_evas
1531
1532 ecore_evas_deps="no"
1533 if test "x${have_evas}" = "xyes" -a "x${have_ecore_input}" = "xyes" -a "x${have_ecore_input_evas}" = "xyes" ; then
1534    ecore_evas_deps="yes"
1535 fi
1536
1537 ECORE_CHECK_MODULE([evas], [${want_ecore_evas}], [Evas], [${ecore_evas_deps}],
1538   [requirements_ecore_evas="ecore-input >= 1.0.0 ecore-input-evas >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_evas}"])
1539
1540 # ecore_evas_buffer
1541
1542 ECORE_EVAS_CHECK_MODULE([software-buffer],
1543    [${want_ecore_evas_software_buffer}],
1544    [Software Buffer],
1545    [yes])
1546
1547 # ecore_evas_x11
1548
1549 # ecore_evas_software_x11
1550
1551 ECORE_EVAS_CHECK_MODULE([software-x11],
1552    [${want_ecore_evas_software_x11}],
1553    [Software X11],
1554    [${have_ecore_x}])
1555
1556 have_ecore_evas_software_xlib="no"
1557 have_ecore_evas_software_xcb="no"
1558 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
1559    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
1560    if test "x${have_ecore_evas_software_xlib}" = "xstatic"; then
1561       have_ecore_evas_software_xlib="yes"
1562    fi
1563    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
1564       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
1565    fi
1566    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
1567    if test "x$have_ecore_evas_software_xcb" = "xstatic"; then
1568       have_ecore_evas_software_xcb="yes"
1569    fi
1570    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1571       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
1572    fi
1573 fi
1574
1575 # ecore_evas_opengl_x11
1576
1577 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1578    [${want_ecore_evas_opengl_x11}],
1579    [OpenGL Xlib],
1580    [${have_ecore_x}])
1581
1582 have_ecore_evas_opengl_xlib="no"
1583 have_ecore_evas_opengl_xcb="no"
1584 if test "x${have_ecore_evas_opengl_x11}" = "xyes" -o "x${have_ecore_evas_opengl_x11}" = "xstatic" ; then
1585    have_ecore_evas_opengl_xlib=`${PKG_CONFIG} --variable=Xlib evas-opengl-x11`
1586    if test "x${have_ecore_evas_opengl_xlib}" = "xyes" ; then
1587       AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XLIB, 1, [OpenGL Xlib rendering backend])
1588    fi
1589
1590 # opengl does not work with xcb (yet)
1591    have_ecore_evas_opengl_xcb=`${PKG_CONFIG} --variable=XCB evas-opengl-x11`
1592    if test "x${have_ecore_evas_opengl_xcb}" = "xstatic"; then
1593       have_ecore_evas_opengl_xcb="yes"
1594    fi
1595    if test "x${have_ecore_evas_opengl_xcb}" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1596       PKG_CHECK_MODULES(XCB_X11, x11-xcb,
1597         [ have_ecore_x_opengl_xcb="yes"
1598           requirements_ecore_x="x11-xcb ${requirements_ecore_x}"
1599           AC_DEFINE(BUILD_ECORE_X_OPENGL_XCB, 1, [Build support for XCB-based OpenGL])
1600           AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XCB, 1, [OpenGL XCB rendering backend])
1601         ],
1602         [ have_ecore_x_opengl_xcb="no" ])
1603     else
1604       have_ecore_x_opengl_xcb="no"
1605       AC_MSG_NOTICE("XCB-based OpenGL explicitly disabled")
1606     fi
1607 fi
1608
1609 # ecore_evas_software_x11 16 bits
1610
1611 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1612    [${want_ecore_evas_software_16_x11}],
1613    [Software Xlib 16 bits],
1614    [${have_ecore_x_xlib}])
1615
1616 ECORE_EVAS_CHECK_MODULE([software-8-x11],
1617     [$want_ecore_evas_software_8_x11],
1618     [Software 8bit X11],
1619     $have_ecore_x_xcb)
1620
1621
1622 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1623         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1624         "x$have_ecore_evas_software_8_x11" = "xyes" -o \
1625         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1626         "x$have_ecore_evas_software_xcb" = "xyes"; then
1627    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1628    requirements_ecore_evas="ecore-x >= 1.0.0 ${requirements_ecore_evas}"
1629 fi
1630
1631 # ecore_evas_win32
1632
1633 ECORE_EVAS_CHECK_MODULE([software-gdi],
1634    [${want_ecore_evas_software_gdi}],
1635    [Software GDI],
1636    [${have_ecore_win32}])
1637
1638 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1639    [${want_ecore_evas_software_ddraw}],
1640    [Software DirectDraw],
1641    [${have_ecore_win32}])
1642
1643 ECORE_EVAS_CHECK_MODULE([direct3d],
1644    [${want_ecore_evas_direct3d}],
1645    [Direct3d],
1646    [${have_ecore_win32}])
1647
1648 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1649    [${want_ecore_evas_opengl_glew}],
1650    [Glew OpenGL],
1651    [${have_ecore_win32}])
1652
1653 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1654    [${want_ecore_evas_software_16_ddraw}],
1655    [16 bpp Software DirectDraw],
1656    [${have_ecore_win32}])
1657
1658 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1659         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1660         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1661         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1662         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1663    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1664    requirements_ecore_evas="ecore-win32 >= 1.0.0 ${requirements_ecore_evas}"
1665 fi
1666
1667 # ecore_evas_software_sdl
1668
1669 ECORE_EVAS_CHECK_MODULE([software-sdl],
1670    [${want_ecore_evas_software_sdl}],
1671    [Software SDL],
1672    [${have_ecore_sdl}],
1673    [requirements_ecore_evas="ecore-sdl >= 1.0.0 ${requirements_ecore_evas}"])
1674
1675 # ecore_evas_gl_sdl
1676
1677 ECORE_EVAS_CHECK_MODULE([opengl-sdl],
1678    [${want_ecore_evas_gl_sdl}],
1679    [OpenGL SDL],
1680    [${have_ecore_sdl}],
1681    [requirements_ecore_evas="ecore-sdl >= 1.0.0 ${requirements_ecore_evas}"])
1682
1683 # ecore_evas_directfb
1684
1685 ECORE_EVAS_CHECK_MODULE([directfb],
1686    [${want_ecore_evas_directfb}],
1687    [DirectFB],
1688    [${have_ecore_directfb}],
1689    [requirements_ecore_evas="ecore-directfb >= 1.0.0 ${requirements_ecore_evas}"])
1690
1691 # ecore_evas_fb
1692
1693 ECORE_EVAS_CHECK_MODULE([fb],
1694    [${want_ecore_evas_fb}],
1695    [Linux Framebuffer],
1696    [${have_ecore_fb}],
1697    [requirements_ecore_evas="ecore-fb >= 1.0.0 ${requirements_ecore_evas}"])
1698
1699 # ecore_evas_wince
1700
1701 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1702    [${want_ecore_evas_software_16_wince}],
1703    [16 bpp Software Windows CE],
1704    [${have_ecore_wince}],
1705    [requirements_ecore_evas="ecore-wince >= 1.0.0 ${requirements_ecore_evas}"])
1706
1707 # ecore_evas_ews
1708
1709 ECORE_EVAS_CHECK_MODULE_FULL([ews], [software-buffer],
1710    [${want_ecore_evas_ews}],
1711    [Ecore Evas Single Process Windowing System],
1712    [yes], [])
1713
1714 ### install and build examples
1715
1716 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
1717 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
1718
1719 ### requirements
1720
1721 AC_SUBST(requirements_ecore)
1722 AC_SUBST(requirements_ecore_con)
1723 #AC_SUBST(requirements_ecore_config)
1724 AC_SUBST(requirements_ecore_directfb)
1725 AC_SUBST(requirements_ecore_evas)
1726 AC_SUBST(requirements_ecore_fb)
1727 AC_SUBST(requirements_ecore_file)
1728 AC_SUBST(requirements_ecore_imf)
1729 AC_SUBST(requirements_ecore_imf_evas)
1730 AC_SUBST(requirements_ecore_input)
1731 AC_SUBST(requirements_ecore_input_evas)
1732 AC_SUBST(requirements_ecore_ipc)
1733 AC_SUBST(requirements_ecore_cocoa)
1734 AC_SUBST(requirements_ecore_sdl)
1735 AC_SUBST(requirements_ecore_x)
1736 AC_SUBST(requirements_ecore_win32)
1737 AC_SUBST(requirements_ecore_wince)
1738 AC_SUBST(requirements_ecore_imf_xim)
1739
1740 AC_CONFIG_FILES([
1741 Makefile
1742 ecore-con.pc
1743 ecore-config.pc
1744 ecore-directfb.pc
1745 ecore-evas.pc
1746 ecore-fb.pc
1747 ecore-file.pc
1748 ecore-cocoa.pc
1749 ecore-imf.pc
1750 ecore-imf-evas.pc
1751 ecore-ipc.pc
1752 ecore-x.pc
1753 ecore-input.pc
1754 ecore-input-evas.pc
1755 ecore-win32.pc
1756 ecore-sdl.pc
1757 ecore-wince.pc
1758 ecore.pc
1759 doc/ecore.dox
1760 doc/Makefile
1761 doc/Doxyfile
1762 src/Makefile
1763 src/util/Makefile
1764 src/bin/Makefile
1765 src/lib/Makefile
1766 src/lib/ecore/Makefile
1767 src/lib/ecore_con/Makefile
1768 src/lib/ecore_config/Makefile
1769 src/lib/ecore_directfb/Makefile
1770 src/lib/ecore_evas/Makefile
1771 src/lib/ecore_fb/Makefile
1772 src/lib/ecore_file/Makefile
1773 src/lib/ecore_cocoa/Makefile
1774 src/lib/ecore_sdl/Makefile
1775 src/lib/ecore_imf/Makefile
1776 src/lib/ecore_imf_evas/Makefile
1777 src/lib/ecore_input/Makefile
1778 src/lib/ecore_input_evas/Makefile
1779 src/lib/ecore_ipc/Makefile
1780 src/lib/ecore_win32/Makefile
1781 src/lib/ecore_wince/Makefile
1782 src/lib/ecore_x/Makefile
1783 src/lib/ecore_x/xlib/Makefile
1784 src/lib/ecore_x/xcb/Makefile
1785 src/examples/Makefile
1786 src/tests/Makefile
1787 src/modules/Makefile
1788 src/modules/immodules/Makefile
1789 src/modules/immodules/xim/Makefile
1790 README
1791 ecore.spec
1792 $po_makefile_in
1793 ])
1794
1795 AC_OUTPUT
1796
1797 echo
1798 echo "$PACKAGE $VERSION"
1799 echo
1800 echo "Optional Modules:"
1801 echo
1802 echo " Core:"
1803 echo
1804 echo "  Ecore........................: always"
1805 echo "    Thread support.............: $have_threads"
1806 echo "    Thread safety..............: $want_thread_safety"
1807 echo "    GLib support...............: $have_glib"
1808 echo "    Always integrate GLib......: $want_glib_integration_always"
1809 echo "    Use g_main_loop............: $want_g_main_loop"
1810 echo "    Gathering memory statistic.: $have_mallinfo"
1811 echo "    Gathering timer allocation.: $want_ecore_timer_dump"
1812 echo "  Ecore_Con....................: $have_ecore_con"
1813 if test "x$have_ecore_con" = "xyes" ; then
1814   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1815 if test "x$have_gnutls" = "xyes" ; then
1816   echo " (disabled)"
1817 else
1818   echo
1819 fi
1820   echo "    GnuTLS.....................: $have_gnutls"
1821   echo "    CURL.......................: $have_curl"
1822   echo "    Local Sockets..............: $want_ecore_con_local_sockets"
1823 if test "x$want_ecore_con_local_sockets" = "xyes" ; then
1824   echo "      Abstract Sockets.........: $want_ecore_con_abstract_sockets"
1825 fi
1826   echo "    c-ares.....................: $have_cares"
1827 fi
1828 echo "  Ecore_Ipc....................: $have_ecore_ipc"
1829 if test "x$have_ecore_ipc" = "xyes" ; then
1830   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1831 if test "x$have_gnutls" = "xyes" ; then
1832   echo " (disabled)"
1833 else
1834   echo
1835 fi
1836   echo "    GnuTLS.....................: $have_gnutls"
1837 fi
1838 echo "  Ecore_File...................: $have_ecore_file"
1839 if test "x$have_ecore_file" = "xyes" ; then
1840   echo "    Inotify....................: $have_inotify"
1841   echo "    Windows notification.......: $have_notify_win32"
1842   echo "    Poll.......................: $have_poll"
1843   echo "    CURL.......................: $have_curl"
1844 fi
1845 #echo "  Ecore_Config.................: $have_ecore_config (deprecated)"
1846 echo "  Ecore_IMF....................: $have_ecore_imf"
1847 echo "    XIM........................: $have_ecore_imf_xim"
1848 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
1849 echo "  Ecore_Input..................: $have_ecore_input"
1850 echo "  Ecore_Input_Evas.............: $have_ecore_input_evas"
1851
1852 echo
1853 echo " Graphic systems:"
1854 echo
1855
1856 if test "x$have_ecore_x" = "xyes" ; then
1857   if test "x$have_ecore_x_xcb" = "xyes" ; then
1858     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
1859     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
1860     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
1861     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
1862     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
1863     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
1864     echo "    Xsync......................: $have_ecore_x_xcb_sync"
1865     echo "    Xrender....................: $have_ecore_x_xcb_render"
1866     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
1867     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
1868     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
1869     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
1870     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
1871   else
1872     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
1873     echo "    Xcursor....................: $use_Xcursor"
1874     echo "    Xkb........................: $use_xkb"
1875     echo "    Xprint.....................: $use_xprint"
1876     echo "    Xinerama...................: $use_xinerama"
1877     echo "    Xrandr.....................: $use_xrandr"
1878     echo "    Xscreensaver...............: $use_xss"
1879     echo "    Xrender....................: $use_xrender"
1880     echo "    Xcomposite.................: $use_xcomposite"
1881     echo "    Xfixes.....................: $use_xfixes"
1882     echo "    Xdamage....................: $use_xdamage"
1883     echo "    Xdpms......................: $use_xdpms"
1884     echo "    Xtest......................: $use_xtest"
1885     echo "    XIM........................: $want_xim"
1886     echo "    Xi2........................: $use_xi2"
1887   fi
1888 else
1889   echo "  Ecore_X......................: $have_ecore_x"
1890 fi
1891 echo "  Ecore_Win32..................: $have_ecore_win32"
1892 echo "  Ecore_Cocoa..................: $have_ecore_cocoa"
1893 echo "  Ecore_SDL....................: $have_ecore_sdl"
1894 echo "  Ecore_FB.....................: $have_ecore_fb"
1895 if test "x${have_ecore_fb}" = "xyes" ; then
1896   echo "    Touchscreen................: $have_tslib"
1897 fi
1898 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
1899 echo "  Ecore_WinCE..................: $have_ecore_wince"
1900
1901 echo
1902 echo " Ecore Evas:"
1903 echo
1904
1905 echo "  Ecore_Evas...................: $have_ecore_evas"
1906 if test "x${have_ecore_evas}" = "xyes" ; then
1907   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
1908   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
1909     echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib=${have_ecore_evas_software_xlib}) (XCB=${have_ecore_evas_software_xcb})"
1910   else
1911     echo "    Software X11...............: $have_ecore_evas_software_x11"
1912   fi
1913   if test "x${have_ecore_evas_opengl_x11}" = "xyes" ; then
1914     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11 (Xlib=${have_ecore_evas_opengl_xlib}) (XCB=${have_ecore_evas_opengl_xcb})"
1915   else
1916     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
1917   fi
1918   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
1919   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
1920   echo "    Direct3D...................: $have_ecore_evas_direct3d"
1921   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
1922   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
1923   echo "    OpenGL SDL.................: $have_ecore_evas_opengl_sdl"
1924   echo "    DirectFB...................: $have_ecore_evas_directfb"
1925   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
1926   echo "    Software 8bit grayscale XCB: $have_ecore_evas_software_8_x11"
1927   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
1928   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
1929   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
1930   echo "    Sing.Proc. Windowing System: $have_ecore_evas_ews"
1931 fi
1932 echo
1933 echo "  Tests................: ${enable_tests}"
1934 echo "  Maximum log level....: ${with_max_log_level}"
1935 echo "Documentation..........: ${build_doc}"
1936 echo
1937 echo "Compilation............: make (or gmake)"
1938 echo "  CPPFLAGS.............: $CPPFLAGS"
1939 echo "  CFLAGS...............: $CFLAGS"
1940 echo "  CXXFLAGS.............: $CXXFLAGS"
1941 echo "  LDFLAGS..............: $LDFLAGS"
1942 echo
1943 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
1944 echo "  prefix...............: $prefix"
1945 echo