configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.12.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 8, 0, 8)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.12.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107
 108 dnl these are all the gst plug-ins, compilable without additional libs
 109 GST_PLUGINS_ALL="\
 110         adder \
 111         audioconvert \
 112         audiorate \
 113         audioresample \
 114         audiotestsrc \
 115         ffmpegcolorspace \
 116         gdp \
 117         playback \
 118         typefind \
 119         videotestsrc \
 120         videorate \
 121         videoscale \
 122         volume \
 123         "
 124 AC_SUBST(GST_PLUGINS_ALL)
 125
 126 GST_PLUGINS_SELECTED=""
 127
 128 AC_ARG_WITH(plugins,
 129     AC_HELP_STRING([--with-plugins],
 130       [comma-separated list of plug-ins to compile]),
 131     [for i in `echo $withval | tr , ' '`; do
 132         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 133         then
 134             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 135         else
 136             echo "plug-in $i not recognized, ignoring..."
 137         fi
 138     done],
 139     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 140
 141 AC_SUBST(GST_PLUGINS_SELECTED)
 142
 143 dnl ext plug-ins; plug-ins that have external dependencies
 144 AG_GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 145   [HAVE_EXTERNAL=yes], enabled,
 146   [
 147     AC_MSG_NOTICE(building external plug-ins)
 148     BUILD_EXTERNAL="yes"
 149   ],[
 150     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 151     BUILD_EXTERNAL="no"
 152   ])
 153 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 154
 155 dnl *** checks for platform ***
 156
 157 dnl * hardware/architecture *
 158
 159 dnl common/m4/gst-arch.m4
 160 dnl check CPU type
 161 AG_GST_ARCH
 162
 163 dnl *** checks for programs ***
 164
 165 dnl find a compiler
 166 AC_PROG_CC
 167
 168 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 169 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 170
 171 dnl check for documentation tools
 172 GTK_DOC_CHECK([1.3])
 173 AS_PATH_PYTHON([2.1])
 174 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 175
 176 dnl *** checks for libraries ***
 177
 178 dnl For interactive UNIX (a Sun thing)
 179 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 180 AC_ISC_POSIX
 181
 182 dnl libm, for sin() etc.
 183 AC_CHECK_LIBM
 184 AC_SUBST(LIBM)
 185
 186 dnl *** checks for header files ***
 187
 188 dnl check if we have ANSI C header files
 189 AC_HEADER_STDC
 190
 191 dnl used in gst/ffmpegcolorspace/mem.c
 192 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 193 AC_CHECK_HEADERS([malloc.h])
 194
 195 dnl used in gst/subparse/gstsubparse.c
 196 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 197 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 198
 199 dnl used in gst/tcp
 200 AC_CHECK_HEADERS([sys/socket.h],
 201   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 202 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 203
 204 dnl used in gst-libs/gst/pbutils and associated unit test
 205 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 206
 207 dnl ffmpegcolorspace includes _stdint.h
 208 dnl also, Windows does not have long long
 209 AX_CREATE_STDINT_H
 210
 211 dnl *** checks for functions ***
 212 AC_CHECK_FUNCS([localtime_r])
 213
 214 dnl *** checks for types/defines ***
 215
 216 dnl Check for FIONREAD ioctl declaration
 217 dnl used in gst/tcp
 218 GST_CHECK_FIONREAD
 219
 220 dnl *** checks for structures ***
 221
 222 dnl *** checks for compiler characteristics ***
 223
 224 dnl make sure we can use "inline" from C code
 225 AC_C_INLINE
 226
 227 dnl *** checks for library functions ***
 228
 229 dnl Check for fast float to int casting as defined in C99
 230 dnl used in gst-libs/gst/floatcast/floatcast.h
 231 AC_C99_FUNC_LRINT
 232 AC_C99_FUNC_LRINTF
 233
 234 dnl Check for a way to display the function name in debug output
 235 AG_GST_CHECK_FUNCTION
 236
 237 dnl *** checks for dependency libraries ***
 238
 239 dnl GLib is required
 240 AG_GST_GLIB_CHECK([2.6])
 241
 242 dnl liboil is required
 243 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 244 if test "x$HAVE_LIBOIL" != "xyes"
 245 then
 246   AC_ERROR([liboil-0.3.8 or later is required])
 247 fi
 248
 249 dnl checks for gstreamer
 250 dnl uninstalled is selected preferentially -- see pkg-config(1)
 251 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 252 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 253 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 254 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 255 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 256
 257 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 258 dnl check for "check", unit testing library/header
 259 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 260 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 261
 262 dnl Check for documentation xrefs
 263 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 264 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 265 AC_SUBST(GLIB_PREFIX)
 266 AC_SUBST(GST_PREFIX)
 267
 268 dnl GTK is optional and used in examples
 269 HAVE_GTK=NO
 270 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 271 if test "x$HAVE_GTK_22" = "xyes"; then
 272   HAVE_GTK=yes
 273   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 274   AC_SUBST(GTK_VERSION)
 275   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 276   AC_SUBST(GTK_BASE_DIR)
 277 else
 278   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 279 fi
 280 if test "x$HAVE_GTK_20" = "xyes"; then
 281   HAVE_GTK=yes
 282 fi
 283 GTK_CFLAGS=$GTK2_CFLAGS
 284 GTK_LIBS=$GTK2_LIBS
 285 AC_SUBST(GTK_LIBS)
 286 AC_SUBST(GTK_CFLAGS)
 287 AC_SUBST(HAVE_GTK)
 288 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 289
 290 dnl *** set variables based on configure arguments ***
 291
 292 dnl set license and copyright notice
 293 GST_LICENSE="LGPL"
 294 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 295 AC_SUBST(GST_LICENSE)
 296
 297 dnl set location of plugin directory
 298 AG_GST_SET_PLUGINDIR
 299
 300 dnl define an ERROR_CFLAGS Makefile variable
 301 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 302
 303 dnl define correct level for debugging messages
 304 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 305
 306 dnl used in examples
 307 AG_GST_DEFAULT_ELEMENTS
 308
 309 dnl *** sys plug-ins ***
 310
 311 echo
 312 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 313 echo
 314
 315 dnl *** X11 ***
 316 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 317 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 318                   [ximagesink], [
 319   AC_PATH_XTRA
 320   ac_cflags_save="$CFLAGS"
 321   ac_cppflags_save="$CPPFLAGS"
 322   CFLAGS="$CFLAGS $X_CFLAGS"
 323   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 324
 325   dnl now try to find the HEADER
 326   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 327
 328   if test "x$HAVE_X" = "xno"
 329   then
 330     AC_MSG_NOTICE([cannot find X11 development files])
 331   else
 332     dnl this is much more than we want
 333     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 334     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 335     dnl it does not add the libs; therefore we add them here
 336     X_LIBS="$X_LIBS -lX11"
 337     AC_SUBST(X_CFLAGS)
 338     AC_SUBST(X_LIBS)
 339   fi
 340   AC_SUBST(HAVE_X)
 341   CFLAGS="$ac_cflags_save"
 342   CPPFLAGS="$ac_cppflags_save"
 343 ])
 344
 345 dnl Check for Xv extension
 346 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 347 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 348                   [xvimagesink], [
 349   AG_GST_CHECK_XV
 350 ])
 351
 352 dnl check for X Shm
 353 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 354 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 355   if test x$HAVE_X = xyes; then
 356     AC_CHECK_LIB(Xext, XShmAttach,
 357                  HAVE_XSHM="yes", HAVE_XSHM="no",
 358                  $X_LIBS)
 359     if test "x$HAVE_XSHM" = "xyes"; then
 360       XSHM_LIBS="-lXext"
 361     else
 362       dnl On AIX, it is in XextSam instead, but we still need -lXext
 363       AC_CHECK_LIB(XextSam, XShmAttach,
 364                    HAVE_XSHM="yes", HAVE_XSHM="no",
 365                    $X_LIBS)
 366       if test "x$HAVE_XSHM" = "xyes"; then
 367         XSHM_LIBS="-lXext -lXextSam"
 368       fi
 369     fi
 370   fi
 371 ], , [
 372   AC_SUBST(HAVE_XSHM)
 373   AC_SUBST(XSHM_LIBS)
 374 ])
 375
 376 dnl v4l/v4l2 checks have been moved down because they require X
 377
 378 dnl *** Video 4 Linux ***
 379 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 380 dnl renamed to GST_V4L in accordance with V4L2 below
 381 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 382 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 383   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 384 #include <sys/types.h>
 385 #define _LINUX_TIME_H
 386 #define __user
 387 #include <linux/videodev.h>
 388   ])
 389
 390   dnl we can build v4l without Xv, but then we won't have XOverlay support
 391   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 392   then
 393     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 394     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 395   fi
 396 ])
 397
 398 dnl *** ext plug-ins ***
 399 dnl keep this list sorted alphabetically !
 400
 401 if test "x$BUILD_EXTERNAL" = "xyes"; then
 402
 403 echo
 404 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 405 echo
 406
 407 dnl *** alsa ***
 408 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 409 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 410   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 411     HAVE_ALSA="yes"
 412     AC_SUBST(ALSA_CFLAGS)
 413     AC_SUBST(ALSA_LIBS)
 414   ], [
 415     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 416   ])
 417 ])
 418
 419 dnl *** CDParanoia ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 421 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 422   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 423                       cdda_open, -lm,
 424                       cdda_interface.h,
 425                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 426                       HEADER_DIR="no"
 427                       FOUND_CDPARANOIA="yes")
 428   if test "x$FOUND_CDPARANOIA" != "xyes";
 429   then
 430     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 431                         cdda_open, -lm,
 432                         cdda/cdda_interface.h,
 433                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 434                         HEADER_DIR="yes"
 435                         FOUND_CDPARANOIA="yes")
 436   fi
 437   if test "x$HEADER_DIR" = "xyes";
 438   then
 439     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 440                        defined if cdda headers are in a cdda/ directory)
 441   fi
 442   AC_SUBST(CDPARANOIA_LIBS)
 443 ])
 444 dnl FIXME : add second check somehow if that is necessary
 445 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 446 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 447
 448 dnl *** GNOME VFS ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 450 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 451   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 452 ])
 453
 454 dnl *** libvisual ***
 455 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 456 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 457   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 458   if test $HAVE_LIBVISUAL = no
 459   then
 460     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 461   fi
 462 ])
 463
 464 dnl *** ogg ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 466 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 467   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 468   if test $HAVE_OGG = no
 469   then
 470     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 471     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 472   fi
 473 ])
 474
 475 dnl *** pango ***
 476 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 477 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 478   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 479 ])
 480
 481 dnl *** theora ***
 482 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 483 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 484   dnl this check will work as long as theora uses 1.0.x or similar for the
 485   dnl first post-alpha release and not just 1.0
 486   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 487 ])
 488
 489 dnl *** vorbis ***
 490 dnl AM_PATH_VORBIS only takes two options
 491 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 492 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 493   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 494   if test $HAVE_VORBIS = no
 495   then
 496     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 497     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 498   fi
 499 ])
 500
 501 if test "x$HAVE_VORBIS" = "xyes"; then
 502   ac_cflags_save="$CFLAGS"
 503   dnl FIXME: does this work on non-gcc? -- Company
 504   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 505   CFLAGS="-Wall -Werror"
 506   AC_COMPILE_IFELSE(
 507     AC_LANG_PROGRAM([
 508 #include <vorbis/codec.h>
 509                      ],[
 510 vorbis_dsp_state *v;
 511
 512 vorbis_synthesis_restart (v);
 513                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 514   if test "x$HAVE_VSR" = "xyes"; then
 515     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 516                        [defined if vorbis_synthesis_restart is present])
 517   fi
 518   CFLAGS="$ac_cflags_save"
 519 fi
 520
 521 else
 522
 523 dnl not building plugins with external dependencies,
 524 dnl but we still need to set the conditionals
 525 AM_CONDITIONAL(USE_ALSA, false)
 526 AM_CONDITIONAL(USE_CDPARANOIA, false)
 527 AM_CONDITIONAL(USE_GNOME_VFS, false)
 528 AM_CONDITIONAL(USE_LIBVISUAL, false)
 529 AM_CONDITIONAL(USE_OGG, false)
 530 AM_CONDITIONAL(USE_PANGO, false)
 531 AM_CONDITIONAL(USE_THEORA, false)
 532 AM_CONDITIONAL(USE_VORBIS, false)
 533
 534 fi dnl of EXT plugins
 535
 536 dnl seeking needs freetype, so check for it here
 537 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 538   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 539 ])
 540 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 541 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 542 AC_SUBST(FT2_CFLAGS)
 543 AC_SUBST(FT2_LIBS)
 544
 545 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 546
 547 dnl Overview:
 548 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 549 dnl GST_*:              flags shared by built objects to link against GStreamer
 550 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 551 dnl                          (compare to other modules) or for i18n
 552 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 553 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 554 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 555 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 556
 557 dnl GST_OPTION_CFLAGS
 558 if test "x$USE_DEBUG" = xyes; then
 559    PROFILE_CFLAGS="-g"
 560 fi
 561 AC_SUBST(PROFILE_CFLAGS)
 562
 563 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 564 AC_SUBST(DEPRECATED_CFLAGS)
 565
 566 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 567 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 568 AC_SUBST(GST_OPTION_CFLAGS)
 569
 570 dnl our libraries need to be versioned correctly
 571 AC_SUBST(GST_LT_LDFLAGS)
 572
 573 dnl GST_PLUGINS_BASE_CFLAGS
 574 dnl prefer internal headers to already installed ones
 575 dnl also add builddir include for enumtypes and marshal
 576 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 577 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 578
 579 dnl FIXME: do we want to rename to GST_ALL_* ?
 580 dnl add GST_OPTION_CFLAGS, but overridable
 581 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 582 AC_SUBST(GST_CFLAGS)
 583 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 584 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 585 AC_SUBST(GST_LIBS)
 586
 587 dnl LDFLAGS really should only contain flags, not libs - they get added before
 588 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 589 GST_ALL_LDFLAGS="-no-undefined"
 590 AC_SUBST(GST_ALL_LDFLAGS)
 591
 592 dnl GST_LIB_LDFLAGS
 593 dnl linker flags shared by all libraries
 594 dnl LDFLAGS modifier defining exported symbols from built libraries
 595 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 596 AC_SUBST(GST_LIB_LDFLAGS)
 597
 598 dnl this really should only contain flags, not libs - they get added before
 599 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 600 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 601 AC_SUBST(GST_PLUGIN_LDFLAGS)
 602
 603 dnl *** output files ***
 604
 605 AC_CONFIG_FILES(
 606 Makefile
 607 gst-plugins-base.spec
 608 gst/Makefile
 609 gst/adder/Makefile
 610 gst/audioconvert/Makefile
 611 gst/audiorate/Makefile
 612 gst/audioresample/Makefile
 613 gst/audiotestsrc/Makefile
 614 gst/ffmpegcolorspace/Makefile
 615 gst/gdp/Makefile
 616 gst/playback/Makefile
 617 gst/subparse/Makefile
 618 gst/tcp/Makefile
 619 gst/typefind/Makefile
 620 gst/videotestsrc/Makefile
 621 gst/videorate/Makefile
 622 gst/videoscale/Makefile
 623 gst/volume/Makefile
 624 sys/Makefile
 625 sys/ximage/Makefile
 626 sys/xvimage/Makefile
 627 sys/v4l/Makefile
 628 ext/Makefile
 629 ext/alsa/Makefile
 630 ext/cdparanoia/Makefile
 631 ext/gnomevfs/Makefile
 632 ext/libvisual/Makefile
 633 ext/ogg/Makefile
 634 ext/pango/Makefile
 635 ext/theora/Makefile
 636 ext/vorbis/Makefile
 637 gst-libs/Makefile
 638 gst-libs/gst/Makefile
 639 gst-libs/gst/audio/Makefile
 640 gst-libs/gst/cdda/Makefile
 641 gst-libs/gst/floatcast/Makefile
 642 gst-libs/gst/interfaces/Makefile
 643 gst-libs/gst/netbuffer/Makefile
 644 gst-libs/gst/riff/Makefile
 645 gst-libs/gst/rtp/Makefile
 646 gst-libs/gst/tag/Makefile
 647 gst-libs/gst/pbutils/Makefile
 648 gst-libs/gst/video/Makefile
 649 tools/Makefile
 650 win32/common/config.h
 651 pkgconfig/Makefile
 652 pkgconfig/gstreamer-plugins-base.pc
 653 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 654 tests/Makefile
 655 tests/check/Makefile
 656 tests/examples/Makefile
 657 tests/examples/seek/Makefile
 658 tests/examples/volume/Makefile
 659 tests/icles/Makefile
 660 docs/Makefile
 661 docs/design/Makefile
 662 docs/libs/Makefile
 663 docs/plugins/Makefile
 664 docs/version.entities
 665 po/Makefile.in
 666 common/Makefile
 667 common/m4/Makefile
 668 m4/Makefile
 669 )
 670 AC_OUTPUT
 671
 672 AG_GST_OUTPUT_PLUGINS