configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([gssdp],
   3         [0.14.4],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=gupnp&component=gssdp],
   5         [gssdp],
   6         [http://www.gupnp.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_SRCDIR(libgssdp/gssdp-client.c)
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-xz])
  14 AM_MAINTAINER_MODE([enable])
  15
  16 GNOME_COMPILE_WARNINGS
  17
  18 AM_SILENT_RULES([yes])
  19
  20 AC_SEARCH_LIBS([strerror],[cposix])
  21 AC_PROG_CC
  22 AC_HEADER_STDC
  23
  24 LT_PREREQ([2.2])
  25 LT_INIT
  26
  27 PKG_CHECK_MODULES(LIBGSSDP, glib-2.0 >= 2.32 \
  28                             gobject-2.0 >= 2.32 \
  29                             gio-2.0 >= 2.32 \
  30                             libsoup-2.4 >= 2.26.1)
  31
  32 LIBGTK_REQUIRED=3.0
  33
  34 AC_ARG_WITH( gtk,
  35   AS_HELP_STRING([--without-gtk],[compile without gtk+ support]),
  36   try_gtk=$withval, try_gtk=yes )
  37
  38 HAVE_LIBGTK=no
  39 if test x$try_gtk = xyes ; then
  40     dnl check for gtk+
  41     PKG_CHECK_MODULES(LIBGTK, gtk+-3.0 >= $LIBGTK_REQUIRED ,
  42       [
  43         HAVE_LIBGTK=yes
  44         AC_SUBST(LIBGTK_CFLAGS)
  45         AC_SUBST(LIBGTK_LIBS)
  46       ],
  47       [
  48         HAVE_LIBGTK=no
  49         AC_MSG_WARN([gtk+ $LIBGTK_REQUIRED or greater not found, some tools will not build.])
  50       ])
  51 else
  52     AC_MSG_NOTICE([gtk+ usage disabled, some tools may not build.])
  53 fi
  54
  55 if test x$HAVE_LIBGTK = xno; then
  56   USE_LIBGTK=no
  57 else
  58   USE_LIBGTK=yes
  59   AC_DEFINE(HAVE_LIBGTK, , [Use gtk+])
  60 fi
  61
  62 AC_SUBST(HAVE_LIBGTK)
  63 AM_CONDITIONAL(USE_LIBGTK, test x$USE_LIBGTK = xyes)
  64
  65 # glib-genmarshal
  66 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  67 AC_SUBST(GLIB_GENMARSHAL)
  68
  69 # Debugging
  70 AC_ARG_ENABLE(debug,
  71         [  --enable-debug          enable debugging],,
  72         enable_debug=no)
  73 if test "x$enable_debug" = "xyes"; then
  74         CFLAGS="$CFLAGS -g -Wall"
  75 fi
  76
  77 AC_ARG_ENABLE([strict-c],
  78               AS_HELP_STRING([--enable-strict-c],[Error out on warnings]),,
  79               [enable_strict_c=no])
  80 AS_IF([test "x$[]enable_strict_c" = "xyes"],
  81       [CFLAGS="$CFLAGS -Werror"])
  82
  83 GOBJECT_INTROSPECTION_CHECK([0.6.7])
  84
  85 # vapigen
  86 have_vapigen=no
  87 AS_IF([test "x$found_introspection" = "xyes"],
  88       [
  89        dnl output of g-i >= 1.36.0 needs vapigen >= 0.20 to process
  90        AC_MSG_CHECKING([whether G-I is 1.36 or newer])
  91        VAPIGEN_MIN_VERSION=0.14
  92        AS_IF([pkg-config --atleast-version=1.36.0 gobject-introspection-1.0],
  93              [
  94               AC_MSG_RESULT([yes])
  95               VAPIGEN_MIN_VERSION=0.20
  96              ],[AC_MSG_RESULT([no])]
  97        )
  98        GUPNP_PROG_VAPIGEN([$VAPIGEN_MIN_VERSION])
  99       ]
 100 )
 101 AS_IF([test "x$VAPIGEN" != "x"], [have_vapigen=yes])
 102 AM_CONDITIONAL([HAVE_VAPIGEN], [test "x$VAPIGEN" != "x"])
 103
 104 dnl Check for Win32
 105 AC_MSG_CHECKING([for Win32])
 106 case "$host" in
 107     *-*-mingw*)
 108         os_win32=yes
 109         ;;
 110     *)
 111         os_win32=no
 112         ;;
 113 esac
 114 AC_MSG_RESULT([$os_win32])
 115 AM_CONDITIONAL(OS_WIN32, [test $os_win32 = yes])
 116
 117 GTK_DOC_CHECK([1.0])
 118
 119 AC_CONFIG_FILES([
 120 Makefile
 121 libgssdp/Makefile
 122 tools/Makefile
 123 tests/Makefile
 124 tests/gtest/Makefile
 125 vala/Makefile
 126 doc/Makefile
 127 doc/version.xml
 128 gssdp-1.0.pc
 129 gssdp-1.0-uninstalled.pc
 130 ])
 131 AC_OUTPUT
 132
 133 echo "
 134     ${PACKAGE} ${VERSION}
 135     ---------------------
 136
 137     Prefix:                ${prefix}
 138     GObject-Introspection: ${found_introspection}
 139     VALA bindings:         ${have_vapigen}
 140 "