configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.5.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 501, 0, 501)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.5.1.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.12])
 161 AG_GST_PLUGIN_DOCS([1.12])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 LT_LIB_M
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl check for GCC specific SSE headers
 175 dnl these are used by the speex resampler code
 176 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/rtsp
 184 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 185 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 186 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 187   WIN32_LIBS="-lws2_32"
 188   AC_SUBST(WIN32_LIBS)
 189 fi
 190
 191 dnl used in gst-libs/gst/pbutils and associated unit test
 192 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 193
 194 dnl checks for ARM NEON support
 195 dnl this instruction set is used by the speex resampler code
 196 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 197 AC_LINK_IFELSE([
 198 AC_LANG_PROGRAM([[
 199   #include <arm_neon.h>
 200   int32x4_t testfunc(int16_t *a, int16_t *b) {
 201       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 202       return vmull_s16(vld1_s16(a), vld1_s16(b));
 203   }
 204 ]])],
 205 [
 206   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 207   AC_MSG_RESULT(yes)
 208 ],
 209 [
 210   AC_MSG_RESULT(no)
 211 ])
 212
 213 dnl also, Windows does not have long long
 214 AX_CREATE_STDINT_H
 215
 216 dnl *** checks for functions ***
 217 AC_CHECK_FUNCS([localtime_r gmtime_r])
 218
 219 dnl *** checks for math functions ***
 220 LIBS_SAVE=$LIBS
 221 LIBS="$LIBS $LIBM"
 222 AC_CHECK_FUNCS(log2)
 223 LIBS=$LIBS_SAVE
 224
 225 dnl *** checks for types/defines ***
 226
 227 dnl *** checks for structures ***
 228
 229 dnl *** checks for compiler characteristics ***
 230
 231 dnl *** checks for library functions ***
 232
 233 dnl check for fseeko()
 234 AC_FUNC_FSEEKO
 235
 236 dnl Check for fast float to int casting as defined in C99
 237 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 238 save_libs=$LIBS
 239 LIBS="$LIBS $LIBM"
 240 AC_C99_FUNC_LRINT
 241 AC_C99_FUNC_LRINTF
 242 LIBS=$save_libs
 243
 244 dnl Check for a way to display the function name in debug output
 245 AG_GST_CHECK_FUNCTION
 246
 247 dnl *** checks for dependency libraries ***
 248
 249 dnl GLib
 250 GLIB_REQ=2.32
 251 AG_GST_GLIB_CHECK([$GLIB_REQ])
 252
 253 ORC_CHECK([0.4.23])
 254
 255 dnl checks for gstreamer
 256 dnl uninstalled is selected preferentially -- see pkg-config(1)
 257 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 259 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 260 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 261 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 262 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 263
 264 dnl Check for documentation xrefs
 265 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 266 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 267 AC_SUBST(GLIB_PREFIX)
 268 AC_SUBST(GST_PREFIX)
 269
 270 dnl GTK is optional and only used in examples
 271 HAVE_GTK=no
 272 HAVE_GTK_X11=no
 273 GTK_REQ=3.10
 274 if test "x$BUILD_EXAMPLES" = "xyes"; then
 275   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 276   dnl some examples need gtk+-x11
 277   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 278   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 279   AC_SUBST(GTK_LIBS)
 280   AC_SUBST(GTK_CFLAGS)
 281 fi
 282 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 283 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 284 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 285
 286 HAVE_QT=no
 287 HAVE_QT_MOC=no
 288 dnl QT is optional and only used in examples
 289 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 290   HAVE_QT=yes
 291 ], [
 292   HAVE_QT=no
 293 ])
 294 if test "x$HAVE_QT" = "xyes"; then
 295   AC_CHECK_TOOL(QT_MOC, moc)
 296   AC_MSG_CHECKING([for Qt5 moc])
 297   mocversion=`$QT_MOC -v 2>&1`
 298   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 299   if test x"$mocversiongrep" != x"$mocversion"; then
 300     AC_MSG_RESULT([no])
 301     # moc was not the qt5 one, try with moc-qt5
 302     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 303     AC_MSG_CHECKING([for Qt5 moc-qt5])
 304     mocversion=`$QT_MOC -v 2>&1`
 305     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 306     if test x"$mocversiongrep" != x"$mocversion"; then
 307       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 308       AC_MSG_CHECKING([for qtchooser])
 309       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 310       mocversion=`$qt5tooldir/moc -v 2>&1`
 311       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 312       if test x"$mocversiongrep" != x"$mocversion"; then
 313         # no valid moc found
 314         QT_MOC="no"
 315       else
 316         QT_MOC=$qt5tooldir/moc
 317       fi
 318     else
 319       QT_MOC=$QT_MOC
 320     fi
 321   fi
 322   AC_SUBST(QT_MOC)
 323   AC_MSG_RESULT([$QT_MOC])
 324 fi
 325 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 326 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 327
 328 dnl chck for linux headers needed by the joystick seek example
 329 AC_COMPILE_IFELSE(
 330 [
 331   AC_LANG_PROGRAM([
 332     #include <linux/input.h>
 333     #include <linux/joystick.h>
 334   ],[
 335     struct js_event js;
 336     js.type = JS_EVENT_AXIS;
 337   ])
 338 ], [
 339   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 340 ], [
 341   HAVE_LINUX_JOYSTICK_HEADERS="no"
 342 ])
 343 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 344
 345 dnl Check for -Bsymbolic-functions linker flag used to avoid
 346 dnl intra-library PLT jumps, if available.
 347 AC_ARG_ENABLE(Bsymbolic,
 348               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 349               [SAVED_LDFLAGS="${LDFLAGS}"
 350                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 351                LDFLAGS=-Wl,-Bsymbolic-functions
 352                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 353                            AC_MSG_RESULT(yes)
 354                            enable_Bsymbolic=yes],[
 355                            AC_MSG_RESULT(no)
 356                            enable_Bsymbolic=no])
 357                LDFLAGS="${SAVED_LDFLAGS}"])
 358
 359
 360 dnl *** set variables based on configure arguments ***
 361
 362 dnl set license and copyright notice
 363 GST_LICENSE="LGPL"
 364 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 365 AC_SUBST(GST_LICENSE)
 366
 367 dnl set location of plugin directory
 368 AG_GST_SET_PLUGINDIR
 369
 370 dnl set release date/time
 371 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 372   ["${srcdir}/gst-plugins-base.doap"],
 373   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 374
 375 dnl build static plugins or not
 376 AC_MSG_CHECKING([whether to build static plugins or not])
 377 AC_ARG_ENABLE(
 378   static-plugins,
 379   AC_HELP_STRING(
 380     [--enable-static-plugins],
 381     [build static plugins @<:@default=no@:>@]),
 382   [AS_CASE(
 383     [$enableval], [no], [], [yes], [],
 384     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 385   [enable_static_plugins=no])
 386 AC_MSG_RESULT([$enable_static_plugins])
 387 if test "x$enable_static_plugins" = xyes; then
 388   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 389     [Define if static plugins should be built])
 390   GST_PLUGIN_LIBTOOLFLAGS=""
 391 else
 392   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 393 fi
 394 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 395 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 396
 397 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 398 dnl make sure it doesn't complain about unused variables if debugging is disabled
 399 NO_WARNINGS=""
 400 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 401
 402 dnl define an ERROR_CFLAGS Makefile variable
 403 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 404 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 405     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 406     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 407     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 408     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 409
 410 dnl define an ERROR_CXXFLAGS Makefile variable
 411 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 412     -Wmissing-declarations -Wredundant-decls -Wundef
 413     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 414     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 415     -Wno-multichar $NO_WARNINGS])
 416
 417 dnl define correct level for debugging messages
 418 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 419
 420 dnl used in examples
 421 AG_GST_DEFAULT_ELEMENTS
 422
 423 dnl needed for encoding-target
 424 GST_DATADIR="$GST_PREFIX/share"
 425 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 426 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 427
 428 dnl behaviour of speex based audio resampler
 429 AC_MSG_CHECKING(which audio resample format to use for integer)
 430 AC_ARG_WITH([audioresample_format],
 431         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 432         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 433 AC_MSG_RESULT($ac_cv_audioresample_format)
 434 case $ac_cv_audioresample_format in
 435   int)
 436     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 437     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 438   ;;
 439   float)
 440     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 441     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 442   ;;
 443   auto)
 444     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 445     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 446 esac
 447
 448 dnl Check for mmap (needed by allocators library)
 449 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 450
 451 dnl *** plug-ins to include ***
 452
 453 dnl these are all the gst plug-ins, compilable without additional libs
 454 AG_GST_CHECK_PLUGIN(adder)
 455 AG_GST_CHECK_PLUGIN(app)
 456 AG_GST_CHECK_PLUGIN(audioconvert)
 457 AG_GST_CHECK_PLUGIN(audiorate)
 458 AG_GST_CHECK_PLUGIN(audiotestsrc)
 459 AG_GST_CHECK_PLUGIN(encoding)
 460 AG_GST_CHECK_PLUGIN(videoconvert)
 461 AG_GST_CHECK_PLUGIN(gio)
 462 AG_GST_CHECK_PLUGIN(playback)
 463 AG_GST_CHECK_PLUGIN(audioresample)
 464 AG_GST_CHECK_PLUGIN(subparse)
 465 AG_GST_CHECK_PLUGIN(tcp)
 466 AG_GST_CHECK_PLUGIN(typefind)
 467 AG_GST_CHECK_PLUGIN(videotestsrc)
 468 AG_GST_CHECK_PLUGIN(videorate)
 469 AG_GST_CHECK_PLUGIN(videoscale)
 470 AG_GST_CHECK_PLUGIN(volume)
 471
 472 dnl iso-codes is optional, used by libgsttag
 473 AC_ARG_ENABLE(iso-codes,
 474 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 475 [case "${enableval}" in
 476   yes) enable_iso_codes=yes ;;
 477   no)  enable_iso_codes=no ;;
 478   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 479 esac
 480 ],
 481 [enable_iso_codes=yes]) dnl Default value
 482
 483 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 484 if test "x$enable_iso_codes" = "xyes"; then
 485   AC_MSG_RESULT([yes])
 486   have_iso_codes=no
 487   AC_MSG_CHECKING([whether iso-codes are available on this system])
 488   if $PKG_CONFIG iso-codes; then
 489     AC_MSG_RESULT([yes])
 490     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 491     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 492       AC_MSG_RESULT([yes])
 493       AC_MSG_CHECKING([for iso-codes prefix])
 494       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 495       if test -d "$ISO_CODES_PREFIX"; then
 496         AC_MSG_RESULT([yes])
 497         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 498         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 499         ISO_639_DOMAIN="iso_639"
 500         AC_MSG_CHECKING([ISO_639_DOMAIN])
 501         AC_MSG_RESULT([$ISO_639_DOMAIN])
 502         have_iso_codes=yes
 503         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 504         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 505         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 506         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 507       else
 508         AC_MSG_RESULT([no])
 509       fi
 510     else
 511       AC_MSG_RESULT([no])
 512     fi
 513   else
 514     AC_MSG_RESULT([no])
 515   fi
 516   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 517 else
 518   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 519   AM_CONDITIONAL(USE_ISO_CODES, false)
 520 fi
 521
 522 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 523 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 524 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 525   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 526       HAVE_ZLIB="yes"
 527     ], [
 528       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 529         HAVE_ZLIB="yes"
 530         ZLIB_LIBS="-lz"
 531         AC_SUBST(ZLIB_LIBS)
 532       ])
 533     ])
 534 ])
 535
 536 dnl *** sys plug-ins ***
 537
 538 echo
 539 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 540 echo
 541
 542 dnl *** X11 ***
 543 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 544 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 545                   [ximagesink], [
 546   AG_GST_PKG_CHECK_MODULES(X, x11)
 547 ])
 548
 549 dnl Check for Xv extension
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 551 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 552                   [xvimagesink], [
 553   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 554 ])
 555
 556 dnl check for X Shm
 557 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 558 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 559   if test x$HAVE_X = xyes; then
 560     PKG_CHECK_MODULES(XSHM, xext, [
 561       AC_CHECK_LIB(Xext, XShmAttach, [
 562         HAVE_XSHM="yes"
 563       ], [
 564         HAVE_XSHM="no"
 565         XSHM_LIBS=""
 566       ], [ $X_LIBS ])
 567     ], [
 568       HAVE_XSHM="no"
 569     ])
 570   fi
 571 ], , [
 572   AC_SUBST(HAVE_XSHM)
 573   AC_SUBST(XSHM_LIBS)
 574 ])
 575
 576 dnl *** ext plug-ins ***
 577 dnl keep this list sorted alphabetically !
 578
 579 if test "x$BUILD_EXTERNAL" = "xyes"; then
 580
 581 echo
 582 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 583 echo
 584
 585 dnl *** alsa ***
 586 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 587 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 588   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 589     HAVE_ALSA="yes"
 590     AC_SUBST(ALSA_CFLAGS)
 591     AC_SUBST(ALSA_LIBS)
 592   ], [
 593     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 594   ])
 595 ])
 596
 597 dnl *** CDParanoia ***
 598 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 599 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 600 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 601   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 602     HAVE_CDPARANOIA="yes"
 603   ], [
 604     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 605                         cdda_open, -lm,
 606                         cdda_interface.h,
 607                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 608                         HEADER_DIR="no"
 609                         FOUND_CDPARANOIA="yes")
 610     if test "x$FOUND_CDPARANOIA" != "xyes";
 611     then
 612       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 613                           cdda_open, -lm,
 614                           cdda/cdda_interface.h,
 615                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 616                           HEADER_DIR="yes"
 617                           FOUND_CDPARANOIA="yes")
 618     fi
 619     if test "x$HEADER_DIR" = "xyes";
 620     then
 621       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 622                          defined if cdda headers are in a cdda/ directory)
 623     fi
 624     if test "x$FOUND_CDPARANOIA" = "xyes";
 625     then
 626       AC_CHECK_LIB(cdda_paranoia,
 627                    paranoia_cachemodel_size,
 628                    : ,
 629                    HAVE_CDPARANOIA=no,
 630                  [-lcdda_interface])
 631     fi
 632
 633     AC_SUBST(CDPARANOIA_LIBS)
 634   ])
 635 ])
 636 dnl FIXME : add second check somehow if that is necessary
 637 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 638 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 639
 640 dnl *** ivorbis ***
 641 dnl AM_PATH_IVORBIS only takes two options
 642 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 643 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 644   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 645   if test $HAVE_IVORBIS = no
 646   then
 647     IVORBIS_LIBS=
 648     IVORBIS_CFLAGS=
 649     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 650       [IVORBIS_LIBS=-lvorbisidec
 651       HAVE_IVORBIS=yes
 652       case $host in
 653       arm-*-*)
 654         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 655       esac
 656       ],
 657       HAVE_IVORBIS=no)
 658     AC_SUBST(IVORBIS_LIBS)
 659     AC_SUBST(IVORBIS_CFLAGS)
 660   else
 661     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 662       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 663       USE_TREMOLO=no)
 664   fi
 665 ])
 666
 667 dnl *** libvisual ***
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 669 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 670   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 671   if test x$HAVE_LIBVISUAL = xyes; then
 672     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 673   fi
 674   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 675   if test x$LIBVIS_PLUGINSDIR != x; then
 676     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 677         "$LIBVIS_PLUGINSDIR",
 678         [directory in which the detected libvisual's plugins are located])
 679   fi
 680 ])
 681
 682 dnl *** ogg ***
 683 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 684 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 685   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 686 ])
 687
 688 dnl *** pango ***
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 690 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 691   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 692 ])
 693
 694 dnl *** theora ***
 695 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 696 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 697   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 698 ])
 699
 700 dnl *** vorbis ***
 701 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 702 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 703   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 704 ])
 705
 706 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO_UNIX_2_0, true)
 708 AG_GST_CHECK_FEATURE(GIO_UNIX_2_0, [glib GIO unix], gio-unix-2.0, [
 709   AG_GST_PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24)
 710 ])
 711
 712 if test "x$HAVE_VORBIS" = "xyes"; then
 713   ac_cflags_save="$CFLAGS"
 714   AC_COMPILE_IFELSE([
 715     AC_LANG_PROGRAM([[
 716 #include <vorbis/codec.h>
 717                      ]],[[
 718 vorbis_dsp_state *v;
 719
 720 vorbis_synthesis_restart (v);
 721                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 722   if test "x$HAVE_VSR" = "xyes"; then
 723     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 724                        [defined if vorbis_synthesis_restart is present])
 725   fi
 726   CFLAGS="$ac_cflags_save"
 727 fi
 728
 729 else
 730
 731 dnl not building plugins with external dependencies,
 732 dnl but we still need to set the conditionals
 733 AM_CONDITIONAL(USE_ALSA, false)
 734 AM_CONDITIONAL(USE_CDPARANOIA, false)
 735 AM_CONDITIONAL(USE_IVORBIS, false)
 736 AM_CONDITIONAL(USE_LIBVISUAL, false)
 737 AM_CONDITIONAL(USE_OGG, false)
 738 AM_CONDITIONAL(USE_PANGO, false)
 739 AM_CONDITIONAL(USE_THEORA, false)
 740 AM_CONDITIONAL(USE_VORBIS, false)
 741
 742 fi dnl of EXT plugins
 743
 744 dnl seeking needs freetype, so check for it here
 745 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 746   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 747 ])
 748 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 749 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 750 AC_SUBST(FT2_CFLAGS)
 751 AC_SUBST(FT2_LIBS)
 752
 753 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 754
 755 dnl Overview:
 756 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 757 dnl GST_*:              flags shared by built objects to link against GStreamer
 758 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 759 dnl                          (compare to other modules) or for i18n
 760 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 761 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 762 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 763 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 764
 765 dnl GST_OPTION_CFLAGS
 766 if test "x$USE_DEBUG" = xyes; then
 767    PROFILE_CFLAGS="-g"
 768 fi
 769 AC_SUBST(PROFILE_CFLAGS)
 770
 771 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 772   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 773   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 774 else
 775   DEPRECATED_CFLAGS=""
 776 fi
 777 AC_SUBST(DEPRECATED_CFLAGS)
 778
 779 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 780 dnl at make time with e.g. make ERROR_CFLAGS=""
 781 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 782 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 783 AC_SUBST(GST_OPTION_CFLAGS)
 784 AC_SUBST(GST_OPTION_CXXFLAGS)
 785
 786 dnl our libraries need to be versioned correctly
 787 AC_SUBST(GST_LT_LDFLAGS)
 788
 789 dnl GST_PLUGINS_BASE_CFLAGS
 790 dnl prefer internal headers to already installed ones
 791 dnl also add builddir include for enumtypes and marshal
 792 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 793 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 794
 795 dnl FIXME: do we want to rename to GST_ALL_* ?
 796 dnl add GST_OPTION_CFLAGS, but overridable
 797 GST_CFLAGS="$GST_CFLAGS"
 798 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 799 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 800 AC_SUBST(GST_CFLAGS)
 801 AC_SUBST(GST_CXXFLAGS)
 802 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 803 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 804 AC_SUBST(GST_LIBS)
 805
 806 dnl LDFLAGS really should only contain flags, not libs - they get added before
 807 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 808 GST_ALL_LDFLAGS="-no-undefined"
 809 if test "x${enable_Bsymbolic}" = "xyes"; then
 810   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 811 fi
 812 AC_SUBST(GST_ALL_LDFLAGS)
 813
 814 dnl GST_LIB_LDFLAGS
 815 dnl linker flags shared by all libraries
 816 dnl LDFLAGS modifier defining exported symbols from built libraries
 817 dnl (export _gst_foo but not __gst_foo)
 818 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 819 AC_SUBST(GST_LIB_LDFLAGS)
 820
 821 dnl this really should only contain flags, not libs - they get added before
 822 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 823 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 824 AC_SUBST(GST_PLUGIN_LDFLAGS)
 825
 826 dnl *** output files ***
 827
 828 $MKDIR_P tests/check/orc
 829
 830 AC_CONFIG_FILES(
 831 Makefile
 832 gst-plugins-base.spec
 833 gst/Makefile
 834 gst/adder/Makefile
 835 gst/app/Makefile
 836 gst/audioconvert/Makefile
 837 gst/audiorate/Makefile
 838 gst/audiotestsrc/Makefile
 839 gst/encoding/Makefile
 840 gst/videoconvert/Makefile
 841 gst/gio/Makefile
 842 gst/playback/Makefile
 843 gst/audioresample/Makefile
 844 gst/subparse/Makefile
 845 gst/tcp/Makefile
 846 gst/typefind/Makefile
 847 gst/videotestsrc/Makefile
 848 gst/videorate/Makefile
 849 gst/videoscale/Makefile
 850 gst/volume/Makefile
 851 sys/Makefile
 852 sys/ximage/Makefile
 853 sys/xvimage/Makefile
 854 ext/Makefile
 855 ext/alsa/Makefile
 856 ext/cdparanoia/Makefile
 857 ext/libvisual/Makefile
 858 ext/ogg/Makefile
 859 ext/pango/Makefile
 860 ext/theora/Makefile
 861 ext/vorbis/Makefile
 862 gst-libs/Makefile
 863 gst-libs/gst/Makefile
 864 gst-libs/gst/allocators/Makefile
 865 gst-libs/gst/audio/Makefile
 866 gst-libs/gst/app/Makefile
 867 gst-libs/gst/fft/Makefile
 868 gst-libs/gst/riff/Makefile
 869 gst-libs/gst/rtp/Makefile
 870 gst-libs/gst/rtsp/Makefile
 871 gst-libs/gst/sdp/Makefile
 872 gst-libs/gst/tag/Makefile
 873 gst-libs/gst/pbutils/Makefile
 874 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 875 gst-libs/gst/video/Makefile
 876 tools/Makefile
 877 pkgconfig/Makefile
 878 pkgconfig/gstreamer-allocators.pc
 879 pkgconfig/gstreamer-allocators-uninstalled.pc
 880 pkgconfig/gstreamer-audio.pc
 881 pkgconfig/gstreamer-audio-uninstalled.pc
 882 pkgconfig/gstreamer-app.pc
 883 pkgconfig/gstreamer-app-uninstalled.pc
 884 pkgconfig/gstreamer-fft.pc
 885 pkgconfig/gstreamer-fft-uninstalled.pc
 886 pkgconfig/gstreamer-pbutils.pc
 887 pkgconfig/gstreamer-pbutils-uninstalled.pc
 888 pkgconfig/gstreamer-riff.pc
 889 pkgconfig/gstreamer-riff-uninstalled.pc
 890 pkgconfig/gstreamer-rtp.pc
 891 pkgconfig/gstreamer-rtp-uninstalled.pc
 892 pkgconfig/gstreamer-rtsp.pc
 893 pkgconfig/gstreamer-rtsp-uninstalled.pc
 894 pkgconfig/gstreamer-sdp.pc
 895 pkgconfig/gstreamer-sdp-uninstalled.pc
 896 pkgconfig/gstreamer-tag.pc
 897 pkgconfig/gstreamer-tag-uninstalled.pc
 898 pkgconfig/gstreamer-video.pc
 899 pkgconfig/gstreamer-video-uninstalled.pc
 900 pkgconfig/gstreamer-plugins-base.pc
 901 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 902 tests/Makefile
 903 tests/check/Makefile
 904 tests/examples/Makefile
 905 tests/examples/app/Makefile
 906 tests/examples/audio/Makefile
 907 tests/examples/dynamic/Makefile
 908 tests/examples/encoding/Makefile
 909 tests/examples/fft/Makefile
 910 tests/examples/gio/Makefile
 911 tests/examples/overlay/Makefile
 912 tests/examples/seek/Makefile
 913 tests/examples/snapshot/Makefile
 914 tests/examples/playback/Makefile
 915 tests/examples/playrec/Makefile
 916 tests/files/Makefile
 917 tests/icles/Makefile
 918 tests/icles/playback/Makefile
 919 docs/Makefile
 920 docs/design/Makefile
 921 docs/libs/Makefile
 922 docs/plugins/Makefile
 923 docs/version.entities
 924 po/Makefile.in
 925 common/Makefile
 926 common/m4/Makefile
 927 m4/Makefile
 928 )
 929
 930 dnl Create the config.h file for Visual Studio builds
 931 dnl Beware of spaces and /'s in some of the shell variable contents.
 932 sed \
 933     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 934     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 935     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 936     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 937     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 938     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 939     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 940     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 941     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 942     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 943     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 944     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 945     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 946     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 947     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 948     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 949     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 950     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 951     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 952     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 953     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 954     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 955     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 956     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 957     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 958     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 959     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 960     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 961     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 962     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 963     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 964     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 965     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 966     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 967     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 968     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 969     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 970     config.h.in >win32/common/config.h-new
 971
 972
 973
 974 AC_OUTPUT
 975
 976 AG_GST_OUTPUT_PLUGINS
 977 ORC_OUTPUT
 978