configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [4])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # glib version number
  13 m4_define([glib_major_version], [2])
  14 m4_define([glib_minor_version], [28])
  15 m4_define([glib_micro_version], [0])
  16 m4_define([glib_major_minor_version],
  17           [glib_major_version.glib_minor_version])
  18 m4_define([glib_version],
  19           [glib_major_version.glib_minor_version.glib_micro_version])
  20
  21 # gst version number
  22 m4_define([gst_major_version], [0])
  23 m4_define([gst_minor_version], [10])
  24 m4_define([gst_micro_version], [14])
  25 m4_define([gst_major_minor_version],
  26           [gst_major_version.gst_minor_version])
  27 m4_define([gst_version],
  28           [gst_major_version.gst_minor_version.gst_micro_version])
  29
  30 # gst plugins-base version number
  31 m4_define([gst_plugins_base_major_version], [0])
  32 m4_define([gst_plugins_base_minor_version], [10])
  33 m4_define([gst_plugins_base_micro_version], [31])
  34 m4_define([gst_plugins_base_version],
  35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  36
  37 # gst plugins-bad version number
  38 m4_define([gst_plugins_bad_major_version], [0])
  39 m4_define([gst_plugins_bad_minor_version], [10])
  40 m4_define([gst_plugins_bad_micro_version], [22])
  41 m4_define([gst_plugins_bad_version],
  42           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  43
  44 # VA-API minimum version number
  45 m4_define([va_api_version],     [0.30.4])
  46 m4_define([va_api_drm_version], [0.34.0])
  47 m4_define([va_api_x11_version], [0.31.0])
  48 m4_define([va_api_glx_version], [0.32.0])
  49 m4_define([va_api_wld_version], [0.34.0])
  50
  51 # libva package version number
  52 m4_define([libva_drm_package_version], [1.2.0])
  53 m4_define([libva_x11_package_version], [1.0.3])
  54 m4_define([libva_glx_package_version], [1.0.9])
  55 m4_define([libva_wld_package_version], [1.2.0])
  56
  57 # gtk-doc version number
  58 # XXX: introspection annotations require gtk-doc >= 1.12
  59 m4_define([gtkdoc_major_version], [1])
  60 m4_define([gtkdoc_minor_version], [9])
  61 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  62
  63 AC_PREREQ([2.58])
  64 AC_INIT([gst_vaapi], [gst_vaapi_version],
  65     [gwenole.beauchesne@intel.com],
  66     [gstreamer-vaapi])
  67
  68 AC_CONFIG_HEADERS([config.h])
  69 AC_CONFIG_SRCDIR([Makefile.am])
  70 AC_CONFIG_MACRO_DIR([m4])
  71 AC_CONFIG_AUX_DIR([build-aux])
  72
  73 AC_CANONICAL_TARGET
  74
  75 AM_INIT_AUTOMAKE
  76
  77 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  78 AC_SUBST(TODAY)
  79
  80 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  81 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  82
  83 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  84 AC_SUBST(LIBVA_PACKAGE_VERSION)
  85
  86 dnl Versions for GStreamer and plugins-base
  87 GST_MAJORMINOR=gst_major_minor_version
  88 GST_VERSION_REQUIRED=gst_version
  89 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  90 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
  91 AC_SUBST(GST_MAJORMINOR)
  92 AC_SUBST(GST_VERSION_REQUIRED)
  93 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
  94 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
  95
  96 dnl Use pretty build output with automake >= 1.11
  97 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  98   AM_DEFAULT_VERBOSITY=1
  99   AC_SUBST(AM_DEFAULT_VERBOSITY)
 100 ])
 101
 102 dnl Check for tools
 103 AC_PROG_CC
 104 AM_PROG_CC_C_O
 105
 106 dnl Initialize libtool
 107 LT_PREREQ([2.2])
 108 LT_INIT
 109
 110 AC_ARG_ENABLE(drm,
 111     AS_HELP_STRING([--enable-drm],
 112                    [enable DRM backend @<:@default=yes@:>@]),
 113     [], [enable_drm="yes"])
 114
 115 AC_ARG_ENABLE(x11,
 116     AS_HELP_STRING([--enable-x11],
 117                    [enable X11 output @<:@default=yes@:>@]),
 118     [], [enable_x11="yes"])
 119
 120 AC_ARG_ENABLE(glx,
 121     AS_HELP_STRING([--enable-glx],
 122                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 123     [], [enable_glx="yes"])
 124
 125 AC_ARG_ENABLE(wayland,
 126     AC_HELP_STRING([--enable-wayland],
 127                    [enable Wayland output @<:@default=yes@:>@]),
 128     [], [enable_wayland="yes"])
 129
 130 dnl Check for basic libraries
 131 AC_CHECK_LIB(m, tan)
 132
 133 dnl Check for Gtk doc
 134 GTKDOC_VERSION=gtkdoc_version
 135 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 136 m4_ifdef([GTK_DOC_CHECK], [
 137 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 138 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 139 AC_SUBST(GTKDOC_VERSION)
 140
 141 dnl Check for GLib
 142 GLIB_VERSION_REQUIRED=glib_version
 143 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 144 AC_SUBST(GLIB_VERSION_REQUIRED)
 145
 146 dnl ---------------------------------------------------------------------------
 147 dnl -- GStreamer                                                             --
 148 dnl ---------------------------------------------------------------------------
 149
 150 dnl GStreamer Core
 151 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 152 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 153
 154 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 155     saved_CFLAGS="$CFLAGS"
 156     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
 157     saved_LIBS="$LIBS"
 158     LIBS="$LIBS $GST_BASE_LIBS"
 159     AC_COMPILE_IFELSE(
 160         [AC_LANG_PROGRAM(
 161             [[#include <gst/base/gstbasesink.h>]],
 162             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 163         [ac_cv_have_gst_base_sink_query="yes"],
 164         [ac_cv_have_gst_base_sink_query="no"]
 165     )
 166     CFLAGS="$saved_CFLAGS"
 167     LIBS="$saved_LIBS"
 168 ])
 169 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 170     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 171 fi
 172
 173 dnl GStreamer -base plugins
 174 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 175     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 176 PKG_CHECK_MODULES([GST_INTERFACES],
 177     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 178
 179 dnl ... GstVideoOverlayComposition (gstreamer-video)
 180 PKG_CHECK_MODULES([GST_VIDEO],
 181     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 182
 183 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 184     ac_cv_have_gst_video_overlay_composition, [
 185     saved_CFLAGS="$CFLAGS"
 186     CFLAGS="$CFLAGS $GST_CFLAGS"
 187     saved_LIBS="$LIBS"
 188     LIBS="$LIBS $GST_LIBS"
 189     AC_COMPILE_IFELSE(
 190         [AC_LANG_PROGRAM(
 191             [[#include <gst/video/video-overlay-composition.h>]],
 192             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 193         [ac_cv_have_gst_video_overlay_composition="yes"],
 194         [ac_cv_have_gst_video_overlay_composition="no"]
 195     )
 196     CFLAGS="$saved_CFLAGS"
 197     LIBS="$saved_LIBS"
 198 ])
 199 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 200     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 201 fi
 202
 203 dnl GStreamer -bad plugins
 204 PKG_CHECK_MODULES([GST_BASEVIDEO],
 205     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 206
 207 dnl ... bitstream parsers
 208 USE_CODEC_PARSERS=1
 209 USE_LOCAL_CODEC_PARSERS=0
 210
 211 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 212     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 213
 214 dnl ... 0.10.23 addition, could be implemented otherwise
 215 AC_CACHE_CHECK([for GstH264SliceHdr::n_emulation_prevention_bytes],
 216     ac_cv_have_gst_h264_slice_hdr_epb_count, [
 217     saved_CFLAGS="$CFLAGS"
 218     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 219     saved_LIBS="$LIBS"
 220     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 221     AC_COMPILE_IFELSE(
 222         [AC_LANG_PROGRAM(
 223             [[#include <gst/codecparsers/gsth264parser.h>]],
 224             [[GstH264SliceHdr slice_hdr;
 225               slice_hdr.n_emulation_prevention_bytes = 0;]])],
 226         [ac_cv_have_gst_h264_slice_hdr_epb_count="yes"],
 227         [ac_cv_have_gst_h264_slice_hdr_epb_count="no"]
 228     )
 229     CFLAGS="$saved_CFLAGS"
 230     LIBS="$saved_LIBS"
 231 ])
 232
 233 if test "$ac_cv_have_gst_h264_slice_hdr_epb_count" = "yes"; then
 234     AC_DEFINE_UNQUOTED(HAVE_GST_H264_SLICE_HDR_EPB_COUNT, 1,
 235         [Defined to 1 if GstH264SliceHdr::n_emulation_prevention_bytes exists.])
 236 fi
 237
 238 dnl ... JPEG parser, not upstream yet
 239 AC_CACHE_CHECK([for JPEG parser],
 240     ac_cv_have_gst_jpeg_parser, [
 241     saved_CFLAGS="$CFLAGS"
 242     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 243     saved_LIBS="$LIBS"
 244     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 245     AC_COMPILE_IFELSE(
 246         [AC_LANG_PROGRAM(
 247             [[#include <gst/codecparsers/gstjpegparser.h>]],
 248             [[GstJpegImage jpeg_image;]])],
 249         [ac_cv_have_gst_jpeg_parser="yes"],
 250         [ac_cv_have_gst_jpeg_parser="no" USE_LOCAL_CODEC_PARSERS=1]
 251     )
 252     CFLAGS="$saved_CFLAGS"
 253     LIBS="$saved_LIBS"
 254 ])
 255
 256 if test "$ac_cv_have_gst_jpeg_parser" = "yes"; then
 257     AC_DEFINE_UNQUOTED(HAVE_GST_JPEG_PARSER, 1,
 258         [Defined to 1 if JPEG parser exists.])
 259 fi
 260 AM_CONDITIONAL(USE_LOCAL_CODEC_PARSERS, test $USE_LOCAL_CODEC_PARSERS -eq 1)
 261
 262 dnl GST_ALL_LDFLAGS:
 263 dnl LDFLAGS really should only contain flags, not libs - they get added before
 264 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 265 GST_ALL_LDFLAGS="-no-undefined"
 266 AC_SUBST(GST_ALL_LDFLAGS)
 267
 268 dnl GST_PLUGIN_LDFLAGS:
 269 dnl this really should only contain flags, not libs - they get added before
 270 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 271 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 272 AC_SUBST(GST_PLUGIN_LDFLAGS)
 273
 274 dnl Check for the GStreamer plugins directory
 275 AC_MSG_CHECKING([for GStreamer plugins directory])
 276 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 277 if test -z "$GST_PLUGINS_DIR"; then
 278     echo "FAIL FAIL FAIL"
 279     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 280 fi
 281 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 282 plugindir="$GST_PLUGINS_DIR"
 283 AC_SUBST(plugindir)
 284
 285 dnl ---------------------------------------------------------------------------
 286 dnl -- Renderers                                                             --
 287 dnl ---------------------------------------------------------------------------
 288
 289 dnl Check for DRM/libudev
 290 USE_DRM=0
 291 if test "$enable_drm" = "yes"; then
 292     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 293     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 294
 295     if test $USE_DRM -eq 1; then
 296         saved_CPPFLAGS="$CPPFLAGS"
 297         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 298         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 299         CPPFLAGS="$saved_CPPFLAGS"
 300     fi
 301 fi
 302
 303 dnl Check for X11
 304 USE_X11=0
 305 if test "$enable_x11" = "yes"; then
 306     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 307     if test $USE_X11 -eq 1; then
 308         saved_CPPFLAGS="$CPPFLAGS"
 309         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 310         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 311         CPPFLAGS="$saved_CPPFLAGS"
 312     fi
 313 fi
 314
 315 dnl OpenGL
 316 enable_opengl="no"
 317 if test "$enable_glx" = "yes"; then
 318     enable_opengl="yes"
 319 fi
 320
 321 HAVE_GL=0
 322 if test "$enable_opengl" = "yes"; then
 323     HAVE_GL=1
 324     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 325     saved_CPPFLAGS="$CPPFLAGS"
 326     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 327     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 328 #ifdef HAVE_GL_GL_H
 329 # include <GL/gl.h>
 330 #endif
 331     ])
 332     CPPFLAGS="$saved_CPPFLAGS"
 333 fi
 334
 335 dnl ... GLX
 336 USE_GLX=0
 337 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 338     USE_GLX=1
 339     saved_CPPFLAGS="$CPPFLAGS"
 340     saved_LIBS="$LIBS"
 341     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 342     LIBS="$LIBS $GL_LIBS"
 343     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 344 #ifdef HAVE_GL_GL_H
 345 # include <GL/gl.h>
 346 #endif
 347     ])
 348     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 349     CPPFLAGS="$saved_CPPFLAGS"
 350     LIBS="$saved_LIBS"
 351 fi
 352
 353 dnl Check for Wayland
 354 USE_WAYLAND=0
 355 if test "$enable_wayland" = "yes"; then
 356     PKG_CHECK_MODULES(WAYLAND, [wayland-client],
 357         [USE_WAYLAND=1], [USE_WAYLAND=0])
 358
 359     if test $USE_WAYLAND -eq 1; then
 360         saved_CPPFLAGS="$CPPFLAGS"
 361         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 362         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 363         CPPFLAGS="$saved_CPPFLAGS"
 364     fi
 365 fi
 366
 367 dnl ---------------------------------------------------------------------------
 368 dnl -- VA-API                                                                --
 369 dnl ---------------------------------------------------------------------------
 370
 371 dnl Core API
 372 LIBVA_PKGNAME="libva"
 373 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 374 AC_SUBST(LIBVA_PKGNAME)
 375
 376 VA_VERSION=`$PKG_CONFIG --modversion libva`
 377 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 378 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 379 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 380 VA_VERSION_STR="$VA_VERSION"
 381
 382 dnl VA/DRM API
 383 if test "$enable_drm" = "yes"; then
 384     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 385         [:], [USE_DRM=0])
 386 fi
 387
 388 dnl VA/X11 API
 389 HAVE_VA_X11=0
 390 LIBVA_X11_PKGNAME="libva-x11"
 391 if test $USE_X11 -eq 1; then
 392     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 393         [HAVE_VA_X11=1], [USE_X11=0])
 394 fi
 395 AC_SUBST(LIBVA_X11_PKGNAME)
 396
 397 dnl VA/GLX API
 398 HAVE_VA_GLX=0
 399 LIBVA_GLX_PKGNAME="libva-glx"
 400 if test $USE_GLX -eq 1; then
 401     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 402         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 403
 404     if test $HAVE_VA_GLX -eq 1; then
 405         saved_CPPFLAGS="$CPPFLAGS"
 406         CPPFLAGS="$LIBVA_GLX_CPPFLAGS"
 407         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 408         CPPFLAGS="$saved_CPPFLAGS"
 409     fi
 410 fi
 411 AC_SUBST(LIBVA_GLX_PKGNAME)
 412
 413 dnl Check for JPEG decoding API (0.32.1+)
 414 USE_JPEG_DECODER=0
 415 AC_CACHE_CHECK([for JPEG decoding API],
 416     ac_cv_have_jpeg_decoding_api, [
 417     saved_CFLAGS="$CFLAGS"
 418     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 419     saved_LIBS="$LIBS"
 420     LIBS="$CFLAGS $LIBVA_LIBS"
 421     AC_COMPILE_IFELSE(
 422         [AC_LANG_PROGRAM(
 423             [[#include <va/va.h>]],
 424             [[VAPictureParameterBufferJPEGBaseline pic_param;
 425               VASliceParameterBufferJPEGBaseline slice_param;
 426               VAHuffmanTableBufferJPEGBaseline huffman_table;
 427               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 428         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 429         [ac_cv_have_jpeg_decoding_api="no"]
 430     )
 431     CFLAGS="$saved_CFLAGS"
 432     LIBS="$saved_LIBS"
 433 ])
 434
 435 dnl VA/Wayland API
 436 if test "$enable_wayland" = "yes"; then
 437     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 438         [:], [USE_WAYLAND=0])
 439 fi
 440
 441 dnl ---------------------------------------------------------------------------
 442 dnl -- Generate files and summary                                            --
 443 dnl ---------------------------------------------------------------------------
 444
 445 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 446 *:1:*)
 447     ;;
 448 *)
 449     AC_MSG_ERROR([No renderer is enabled])
 450     ;;
 451 esac
 452
 453 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 454     [Defined to 1 if JPEG decoder is used])
 455 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 456
 457 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 458     [Defined to 1 if DRM is enabled])
 459 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 460
 461 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 462     [Defined to 1 if X11 is enabled])
 463 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 464
 465 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 466     [Defined to 1 if GLX is enabled])
 467 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 468
 469 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 470     [Defined to 1 if WAYLAND is enabled])
 471 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 472
 473 pkgconfigdir=${libdir}/pkgconfig
 474 AC_SUBST(pkgconfigdir)
 475
 476 AC_CONFIG_FILES([
 477     Makefile
 478     debian.upstream/Makefile
 479     debian.upstream/changelog
 480     debian.upstream/control
 481     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 482 debian.upstream/gstreamer-vaapi-doc.install.in
 483     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 484 debian.upstream/gstreamer-vaapi.install.in
 485     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 486 debian.upstream/libgstvaapi.install.in
 487     debian.upstream/libgstvaapi-dev.install
 488     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 489 debian.upstream/libgstvaapi-drm.install.in
 490     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 491 debian.upstream/libgstvaapi-glx.install.in
 492     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 493 debian.upstream/libgstvaapi-wayland.install.in
 494     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 495 debian.upstream/libgstvaapi-x11.install.in
 496     docs/Makefile
 497     docs/reference/Makefile
 498     docs/reference/libs/Makefile
 499     docs/reference/libs/libs-docs.xml
 500     docs/reference/plugins/Makefile
 501     docs/reference/plugins/plugins-docs.xml
 502     gst-libs/Makefile
 503     gst-libs/gst/Makefile
 504     gst-libs/gst/codecparsers/Makefile
 505     gst-libs/gst/vaapi/Makefile
 506     gst/Makefile
 507     gst/vaapi/Makefile
 508     pkgconfig/Makefile
 509     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 510 pkgconfig/gstreamer-vaapi.pc.in
 511     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
 512 pkgconfig/gstreamer-vaapi-drm.pc.in
 513     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 514 pkgconfig/gstreamer-vaapi-glx.pc.in
 515     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
 516 pkgconfig/gstreamer-vaapi-wayland.pc.in
 517     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 518 pkgconfig/gstreamer-vaapi-x11.pc.in
 519     tests/Makefile
 520 ])
 521 AC_OUTPUT
 522
 523 dnl Print summary
 524 yesno() {
 525     test $1 -eq 1 && echo yes || echo no
 526 }
 527
 528 VIDEO_OUTPUTS=""
 529 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 530 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 531 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 532 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 533
 534 echo
 535 echo $PACKAGE configuration summary:
 536 echo
 537 echo VA-API version ................... : $VA_VERSION_STR
 538 echo Video outputs .................... : $VIDEO_OUTPUTS
 539 echo