configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [39])
  34 m4_define([glib_micro_version], [5])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS:+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_cv_stack_grows=no
 129     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 130     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 131     # (Sorry, I don't know exactly what is the problem, but it is related to
 132     # floating point formatting and decimal point vs. comma.)
 133     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 134     # rigorous enough to notice, though.
 135     # So preset the autoconf cache variables.
 136     ac_cv_func_vsnprintf_c99=no
 137     ac_cv_func_snprintf_c99=no
 138     case "$host" in
 139     x86_64-*-*)
 140       LIB_EXE_MACHINE_FLAG=X64
 141       ;;
 142     esac
 143
 144     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 145     ;;
 146   *)
 147     glib_native_win32=no
 148     glib_pid_type=int
 149     ;;
 150 esac
 151 case $host in
 152   *-*-linux*)
 153     glib_os_linux=yes
 154     ;;
 155 esac
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158
 159 AC_MSG_CHECKING([for the Android])
 160 case $host in
 161   *android*)
 162     glib_native_android="yes"
 163     ;;
 164   *)
 165     glib_native_android="no"
 166     ;;
 167 esac
 168 AC_MSG_RESULT([$glib_native_android])
 169
 170 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 171
 172 glib_have_carbon=no
 173 AC_MSG_CHECKING([for Mac OS X Carbon support])
 174 AC_TRY_CPP([
 175 #include <Carbon/Carbon.h>
 176 #include <CoreServices/CoreServices.h>
 177 ], glib_have_carbon=yes)
 178
 179 AC_MSG_RESULT([$glib_have_carbon])
 180
 181 glib_have_cocoa=no
 182 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 183 AC_TRY_CPP([
 184 #include <Cocoa/Cocoa.h>
 185 #ifdef GNUSTEP_BASE_VERSION
 186 #error "Detected GNUstep, not Cocoa"
 187 #endif
 188 ], glib_have_cocoa=yes)
 189
 190 AC_MSG_RESULT([$glib_have_cocoa])
 191
 192 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 193 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 194 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 195 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 196 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 197 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 198
 199 AS_IF([test "$glib_native_win32" = "yes"], [
 200   AC_CHECK_TOOL(WINDRES, windres, no)
 201   if test "$WINDRES" = no; then
 202     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 203   fi
 204   AC_CHECK_TOOL(NM, nm, no)
 205   if test "$NM" = no; then
 206     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 207   fi
 208   AC_CHECK_TOOL(RANLIB, ranlib, :)
 209   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 210   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 211 ])
 212 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 213
 214 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 215   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 216   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 217 ])
 218
 219 if test "x$glib_have_cocoa" = "xyes"; then
 220   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 221   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 222 fi
 223
 224 dnl declare --enable-* args and collect ac_help strings
 225 AC_ARG_ENABLE(debug,
 226               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 227                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 228               enable_debug=glib_debug_default)
 229
 230 AC_ARG_ENABLE(gc_friendly,
 231               [AS_HELP_STRING([--enable-gc-friendly],
 232                               [turn on garbage collector friendliness [default=no]])],,
 233               [enable_gc_friendly=no])
 234 AC_ARG_ENABLE(mem_pools,
 235               [AS_HELP_STRING([--disable-mem-pools],
 236                               [disable all glib memory pools])],,
 237               [disable_mem_pools=no])
 238 AC_ARG_ENABLE(rebuilds,
 239               [AS_HELP_STRING([--disable-rebuilds],
 240                               [disable all source autogeneration rules])],,
 241               [enable_rebuilds=yes])
 242
 243 GLIB_TESTS
 244
 245 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 246 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 247   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 248   AC_MSG_RESULT([yes])
 249 ], [ AC_MSG_RESULT([no]) ])
 250
 251 AC_MSG_CHECKING([whether to disable memory pools])
 252 AS_IF([test "x$disable_mem_pools" = "xno"], [
 253   AC_MSG_RESULT([no])
 254 ], [
 255   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 256   AC_MSG_RESULT([yes])
 257 ])
 258
 259 dnl location to install runtime libraries, e.g. ../../lib to install
 260 dnl to /lib if libdir is /usr/lib
 261 AC_ARG_WITH(runtime-libdir,
 262            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 263                            [install runtime libraries relative to libdir])],
 264            [],
 265            [with_runtime_libdir=""])
 266 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 267 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 268 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 269 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 270 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 271
 272 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 273 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 274 AC_LANG_SAVE
 275 AC_LANG_CPLUSPLUS
 276 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 277 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 278 AC_LANG_RESTORE
 279
 280 AM_PROG_CC_C_O
 281 AC_PROG_INSTALL
 282
 283 AC_SYS_LARGEFILE
 284
 285 PKG_PROG_PKG_CONFIG(0.16)
 286
 287 if test "x$enable_debug" = "xyes"; then
 288   if test "x$cflags_set" != "x" ; then
 289       case " $CFLAGS " in
 290       *[[\ \    ]]-g[[\ \       ]]*) ;;
 291       *) CFLAGS="$CFLAGS -g" ;;
 292       esac
 293   fi
 294   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 295 else
 296   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 297
 298   if test "x$enable_debug" = "xno"; then
 299     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 300   fi
 301 fi
 302
 303 # Ensure MSVC-compatible struct packing convention is used when
 304 # compiling for Win32 with gcc.
 305 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 306 # gcc2 uses "-fnative-struct".
 307 if test x"$glib_native_win32" = xyes; then
 308   if test x"$GCC" = xyes; then
 309     msnative_struct=''
 310     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 311     if test -z "$ac_cv_prog_CC"; then
 312       our_gcc="$CC"
 313     else
 314       our_gcc="$ac_cv_prog_CC"
 315     fi
 316     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 317       2.)
 318         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 319           msnative_struct='-fnative-struct'
 320         fi
 321         ;;
 322       *)
 323         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 324           msnative_struct='-mms-bitfields'
 325         fi
 326         ;;
 327     esac
 328     if test x"$msnative_struct" = x ; then
 329       AC_MSG_RESULT([no way])
 330       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 331     else
 332       CFLAGS="$CFLAGS $msnative_struct"
 333       AC_MSG_RESULT([${msnative_struct}])
 334     fi
 335   fi
 336 fi
 337 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 338 AC_SUBST(GLIB_EXTRA_CFLAGS)
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 fi
 362 if test "x$PERL_PATH" = x ; then
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 # option to specify python interpreter to use; this just sets $PYTHON, so that
 368 # we will fallback to reading $PYTHON if --with-python is not given, and
 369 # python.m4 will get the expected input
 370 AC_ARG_WITH(python,
 371             AS_HELP_STRING([--with-python=PATH],
 372                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 373             [PYTHON="$withval"], [])
 374 if test x"$PYTHON" = xyes; then
 375   AC_MSG_ERROR([--with-python option requires a path or program argument])
 376 fi
 377 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 378
 379
 380 dnl ***********************
 381 dnl *** Tests for iconv ***
 382 dnl ***********************
 383 dnl
 384 dnl We do this before the gettext checks, to avoid distortion
 385
 386 dnl On Windows we use a native implementation
 387
 388 AS_IF([ test x"$glib_native_win32" = xyes], [
 389   with_libiconv=native
 390 ], [
 391   AC_ARG_WITH(libiconv,
 392               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 393                               [use the libiconv library])],,
 394               [with_libiconv=maybe])
 395
 396   found_iconv=no
 397   case $with_libiconv in
 398     maybe)
 399       # Check in the C library first
 400       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 401       # Check if we have GNU libiconv
 402       if test $found_iconv = "no"; then
 403         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 404       fi
 405       # Check if we have a iconv in -liconv, possibly from vendor
 406       if test $found_iconv = "no"; then
 407         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 408       fi
 409       ;;
 410     no)
 411       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 412       ;;
 413     gnu|yes)
 414       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 415       ;;
 416     native)
 417       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 418       ;;
 419   esac
 420
 421   if test "x$found_iconv" = "xno" ; then
 422      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 423   fi
 424 ])
 425
 426 dnl
 427 dnl zlib support
 428 dnl
 429 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 430 AS_IF([test "x$found_zlib" = "xno"], [
 431   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 432   if test "x$found_zlib" = "xno" ; then
 433     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 434   fi
 435   ZLIB_LIBS='-lz'
 436   AC_SUBST(ZLIB_LIBS)
 437 ])
 438
 439 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 440 AC_SUBST(LIBFFI_CFLAGS)
 441 AC_SUBST(LIBFFI_LIBS)
 442
 443 dnl
 444 dnl gettext support
 445 dnl
 446
 447 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 448 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 449 GLIB_GNU_GETTEXT
 450
 451 if test "$gt_cv_have_gettext" != "yes" ; then
 452   AC_MSG_ERROR([
 453 *** You must have either have gettext support in your C library, or use the
 454 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 455 ])
 456 fi
 457
 458 LIBS="$INTLLIBS $LIBS"
 459
 460 GETTEXT_PACKAGE=glib20
 461 AC_SUBST(GETTEXT_PACKAGE)
 462 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 463   [Define the gettext package to be used])
 464
 465 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 466
 467 dnl
 468 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 469 dnl
 470
 471 AS_IF([test x"$glib_native_win32" != xyes], [
 472   if test x$with_libiconv != xno ; then
 473     case " $INTLLIBS " in
 474     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 475     *) ICONV_LIBS="-liconv" ;;
 476     esac
 477   fi
 478 ])
 479 AC_SUBST(ICONV_LIBS)
 480
 481 case $with_libiconv in
 482   gnu)
 483     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 484     ;;
 485   native)
 486     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 487     ;;
 488 esac
 489
 490 dnl Initialize libtool
 491 LT_PREREQ([2.2])
 492 LT_INIT([disable-static win32-dll])
 493 dnl when using libtool 2.x create libtool early, because it's used in configure
 494 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 495
 496
 497 AS_IF([test "$glib_native_win32" = "yes"], [
 498   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 499     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 500   fi
 501   if test x$enable_static = xyes; then
 502     glib_win32_static_compilation=yes
 503     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 504 #define GOBJECT_STATIC_COMPILATION 1"
 505     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 506   fi
 507 ])
 508 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 509
 510 # Checks for library functions.
 511 AC_FUNC_ALLOCA
 512 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 513 AC_CHECK_FUNCS(timegm gmtime_r)
 514
 515 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 516   [AC_TRY_LINK([#include <unistd.h>
 517     extern int __libc_enable_secure;],
 518     [return __libc_enable_secure;],
 519    glib_cv_have_libc_enable_secure=yes,
 520    glib_cv_have_libc_enable_secure=no)])
 521 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 522    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 523      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 524 ])
 525
 526 AC_CHECK_SIZEOF(char)
 527 AC_CHECK_SIZEOF(short)
 528 AC_CHECK_SIZEOF(long)
 529 AC_CHECK_SIZEOF(int)
 530 AC_CHECK_SIZEOF(void *)
 531 AC_CHECK_SIZEOF(long long)
 532 AC_CHECK_SIZEOF(__int64)
 533
 534 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 535   [AC_TRY_LINK([#include <signal.h>
 536      #include <sys/types.h>
 537      sig_atomic_t val = 42;],
 538     [return val == 42 ? 0 : 1],
 539    ac_cv_type_sig_atomic_t=yes,
 540    ac_cv_type_sig_atomic_t=no)])
 541 if test x$ac_cv_type_sig_atomic_t = xyes; then
 542    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 543      [Define if you have the 'sig_atomic_t' type.])
 544 fi
 545
 546 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 547   :
 548 else
 549   AC_MSG_ERROR([
 550 *** GLib requires a 64 bit type. You might want to consider
 551 *** using the GNU C compiler.
 552 ])
 553 fi
 554
 555 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 556         # long long is a 64 bit integer.
 557         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 558         AC_CACHE_VAL(glib_cv_long_long_format,[
 559                 for format in ll q I64; do
 560                   AC_TRY_RUN([#include <stdio.h>
 561                         int main()
 562                         {
 563                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 564                           char buffer[1000];
 565                           sprintf (buffer, "%${format}u", a);
 566                           sscanf (buffer, "%${format}u", &b);
 567                           exit (b!=a);
 568                         }
 569                         ],
 570                         [glib_cv_long_long_format=${format}
 571                         break],
 572                         [],[:])
 573                 done])
 574         AS_IF([ test -n "$glib_cv_long_long_format"], [
 575           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 576           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 577           if test x"$glib_cv_long_long_format" = xI64; then
 578             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 579           fi
 580         ], [AC_MSG_RESULT(none)])
 581 ],[ test x$ac_cv_sizeof___int64 = x8], [
 582         # __int64 is a 64 bit integer.
 583         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 584         # We know this is MSVCRT.DLL, and what the formats are
 585         glib_cv_long_long_format=I64
 586         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 587         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 588         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 589 ])
 590
 591 AC_C_CONST
 592
 593 dnl
 594 dnl check in which direction the stack grows
 595 dnl
 596 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 597         AC_TRY_RUN([
 598         volatile int *a = 0, *b = 0;
 599         void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
 600         int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
 601         ],
 602         glib_cv_stack_grows=yes
 603         ,
 604         glib_cv_stack_grows=no
 605         ,)
 606 ])
 607
 608 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 609 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 610 dnl actually supported.
 611 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 612         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 613         __inline int foo () { return 0; }
 614         int main () { return foo (); }
 615         ]])],
 616         glib_cv_has__inline=yes
 617         ,
 618         glib_cv_has__inline=no
 619         ,)
 620 ])
 621 case x$glib_cv_has__inline in
 622 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 623 esac
 624 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 625         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 626         __inline__ int foo () { return 0; }
 627         int main () { return foo (); }
 628         ]])],
 629         glib_cv_has__inline__=yes
 630         ,
 631         glib_cv_has__inline__=no
 632         ,)
 633 ])
 634 case x$glib_cv_has__inline__ in
 635 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 636 esac
 637 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 638         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 639         #undef inline
 640         inline int foo () { return 0; }
 641         int main () { return foo (); }
 642         ]])],
 643         glib_cv_hasinline=yes
 644         ,
 645         glib_cv_hasinline=no
 646         ,)
 647 ])
 648 case x$glib_cv_hasinline in
 649 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 650 esac
 651
 652 # if we can use inline functions in headers
 653 AC_MSG_CHECKING(if inline functions in headers work)
 654 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 655 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 656 #  undef inline
 657 #  define inline __inline__
 658 #elif !defined (G_HAVE_INLINE)
 659 #  undef inline
 660 #  if defined (G_HAVE___INLINE__)
 661 #    define inline __inline__
 662 #  elif defined (G_HAVE___INLINE)
 663 #    define inline __inline
 664 #  endif
 665 #endif
 666
 667 int glib_test_func2 (int);
 668
 669 static inline int
 670 glib_test_func1 (void) {
 671   return glib_test_func2 (1);
 672 }
 673
 674 int
 675 main (void) {
 676   int i = 1;
 677 }]])],[g_can_inline=yes],[g_can_inline=no])
 678 AC_MSG_RESULT($g_can_inline)
 679
 680 # check for flavours of varargs macros
 681 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 682 AC_TRY_COMPILE([],[
 683 int a(int p1, int p2, int p3);
 684 #define call_a(...) a(1,__VA_ARGS__)
 685 call_a(2,3);
 686 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 687 AC_MSG_RESULT($g_have_iso_c_varargs)
 688
 689 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 690 AS_IF([test "$CXX" = ""], [
 691 dnl No C++ compiler
 692   g_have_iso_cxx_varargs=no
 693 else
 694   AC_LANG_CPLUSPLUS
 695   AC_TRY_COMPILE([],[
 696 int a(int p1, int p2, int p3);
 697 #define call_a(...) a(1,__VA_ARGS__)
 698 call_a(2,3);
 699 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 700   AC_LANG_C
 701 ])
 702 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 703
 704 AC_MSG_CHECKING(for GNUC varargs macros)
 705 AC_TRY_COMPILE([],[
 706 int a(int p1, int p2, int p3);
 707 #define call_a(params...) a(1,params)
 708 call_a(2,3);
 709 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 710 AC_MSG_RESULT($g_have_gnuc_varargs)
 711
 712 # check for GNUC visibility support
 713 AC_MSG_CHECKING(for GNUC visibility attribute)
 714 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 715 void
 716 __attribute__ ((visibility ("hidden")))
 717      f_hidden (void)
 718 {
 719 }
 720 void
 721 __attribute__ ((visibility ("internal")))
 722      f_internal (void)
 723 {
 724 }
 725 void
 726 __attribute__ ((visibility ("protected")))
 727      f_protected (void)
 728 {
 729 }
 730 void
 731 __attribute__ ((visibility ("default")))
 732      f_default (void)
 733 {
 734 }
 735 int main (void)
 736 {
 737         f_hidden();
 738         f_internal();
 739         f_protected();
 740         f_default();
 741         return 0;
 742 }
 743 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 744 AC_MSG_RESULT($g_have_gnuc_visibility)
 745 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 746
 747 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 748 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 749 #else
 750 # include "error: this is not Sun Studio."
 751 #endif
 752 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 753 AC_MSG_RESULT($g_have_sunstudio_visibility)
 754 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 755
 756 # check for bytesex stuff
 757 AC_C_BIGENDIAN
 758 if test x$ac_cv_c_bigendian = xuniversal ; then
 759 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 760 #else
 761 #error Not a big endian.
 762 #endif],
 763     ac_cv_c_bigendian=yes
 764     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 765 #else
 766 #error Not a little endian.
 767 #endif],
 768     ac_cv_c_bigendian=no
 769     ,AC_MSG_WARN([Could not determine endianness.])))
 770 fi
 771
 772
 773 # check for header files
 774 AC_CHECK_HEADERS([sys/param.h sys/resource.h])
 775 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
 776 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 777 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 778 AC_CHECK_HEADERS([linux/magic.h sys/prctl.h])
 779
 780 # Some versions of MSC lack these
 781 AC_CHECK_HEADERS([dirent.h sys/time.h])
 782
 783 # We don't care about this, but we need to keep including it in
 784 # glibconfig.h for backward compatibility
 785 AC_CHECK_HEADERS([values.h])
 786
 787 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 788 [#if HAVE_SYS_PARAM_H
 789  #include <sys/param.h>
 790  #endif
 791 ])
 792 AC_CHECK_FUNCS(sysctlbyname)
 793
 794 AC_HEADER_MAJOR
 795 AC_CHECK_HEADERS([xlocale.h])
 796
 797 # check for structure fields
 798 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 799 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 800 #include <sys/stat.h>
 801 #ifdef G_OS_UNIX
 802 #include <unistd.h>
 803 #endif
 804 #ifdef HAVE_SYS_STATFS_H
 805 #include <sys/statfs.h>
 806 #endif
 807 #ifdef HAVE_SYS_PARAM_H
 808 #include <sys/param.h>
 809 #endif
 810 #ifdef HAVE_SYS_MOUNT_H
 811 #include <sys/mount.h>
 812 #endif])
 813 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 814 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 815 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 816 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 817
 818 AC_STRUCT_DIRENT_D_TYPE
 819
 820 # Checks for libcharset
 821 AM_LANGINFO_CODESET
 822 gl_GLIBC21
 823
 824 # check additional type sizes
 825 AC_CHECK_SIZEOF(size_t)
 826
 827 dnl Try to figure out whether gsize should be long or int
 828 AC_MSG_CHECKING([for the appropriate definition for size_t])
 829
 830 case $ac_cv_sizeof_size_t in
 831   $ac_cv_sizeof_short)
 832       glib_size_type=short
 833       ;;
 834   $ac_cv_sizeof_int)
 835       glib_size_type=int
 836       ;;
 837   $ac_cv_sizeof_long)
 838       glib_size_type=long
 839       ;;
 840   $ac_cv_sizeof_long_long)
 841       glib_size_type='long long'
 842       ;;
 843   $ac_cv_sizeof__int64)
 844       glib_size_type='__int64'
 845       ;;
 846   *)  AC_MSG_ERROR([No type matching size_t in size])
 847       ;;
 848 esac
 849
 850 dnl If int/long are the same size, we see which one produces
 851 dnl warnings when used in the location as size_t. (This matters
 852 dnl on AIX with xlc)
 853 dnl
 854 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 855        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 856   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 857 #if defined(_AIX) && !defined(__GNUC__)
 858 #pragma options langlvl=stdc89
 859 #endif
 860 #include <stddef.h>
 861 int main ()
 862 {
 863   size_t s = 1;
 864   unsigned int *size_int = &s;
 865   return (int)*size_int;
 866 }
 867     ]])],glib_size_type=int,
 868       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 869 #if defined(_AIX) && !defined(__GNUC__)
 870 #pragma options langlvl=stdc89
 871 #endif
 872 #include <stddef.h>
 873 int main ()
 874 {
 875    size_t s = 1;
 876    unsigned long *size_long = &s;
 877    return (int)*size_long;
 878 }
 879         ]])],glib_size_type=long)])
 880 ])
 881
 882 AC_MSG_RESULT(unsigned $glib_size_type)
 883
 884 AC_CHECK_SIZEOF(ssize_t)
 885
 886 dnl Try to figure out whether gssize should be long or int
 887 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 888
 889 case $ac_cv_sizeof_ssize_t in
 890   $ac_cv_sizeof_short)
 891       glib_ssize_type=short
 892       ;;
 893   $ac_cv_sizeof_int)
 894       glib_ssize_type=int
 895       ;;
 896   $ac_cv_sizeof_long)
 897       glib_ssize_type=long
 898       ;;
 899   $ac_cv_sizeof_long_long)
 900       glib_ssize_type='long long'
 901       ;;
 902   $ac_cv_sizeof__int64)
 903       glib_ssize_type='__int64'
 904       ;;
 905   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 906       ;;
 907 esac
 908
 909 dnl If int/long are the same size, we see which one produces
 910 dnl warnings when used in the location as ssize_t. (This matters
 911 dnl on Android where ssize_t is long and size_t is unsigned int)
 912 dnl
 913 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 914        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 915   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 916 #if defined(_AIX) && !defined(__GNUC__)
 917 #pragma options langlvl=stdc89
 918 #endif
 919 #include <stddef.h>
 920 #ifdef HAVE_INTTYPES_H
 921 # include <inttypes.h>
 922 #endif
 923 #ifdef HAVE_STDINT_H
 924 # include <stdint.h>
 925 #endif
 926 #include <sys/types.h>
 927 int main ()
 928 {
 929   ssize_t s = 1;
 930   int *size_int = &s;
 931   return (int)*size_int;
 932 }
 933     ]])],glib_ssize_type=int,
 934       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 935 #if defined(_AIX) && !defined(__GNUC__)
 936 #pragma options langlvl=stdc89
 937 #endif
 938 #include <stddef.h>
 939 #ifdef HAVE_INTTYPES_H
 940 # include <inttypes.h>
 941 #endif
 942 #ifdef HAVE_STDINT_H
 943 # include <stdint.h>
 944 #endif
 945 #include <sys/types.h>
 946 int main ()
 947 {
 948    ssize_t s = 1;
 949    long *size_long = &s;
 950    return (int)*size_long;
 951 }
 952         ]])],glib_ssize_type=long)])
 953 ])
 954
 955 AC_MSG_RESULT($glib_ssize_type)
 956
 957 # Check for some functions
 958 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 959 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
 960 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
 961 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
 962 AC_CHECK_FUNCS(splice)
 963 AC_CHECK_FUNCS(prlimit)
 964
 965 # To avoid finding a compatibility unusable statfs, which typically
 966 # successfully compiles, but warns to use the newer statvfs interface:
 967 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 968 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 969
 970 AC_MSG_CHECKING([whether to use statfs or statvfs])
 971 # Some systems have both statfs and statvfs, pick the most "native" for these
 972 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 973    [
 974    # on solaris and irix, statfs doesn't even have the f_bavail field
 975    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
 976       [ac_cv_func_statfs=no],
 977    # else, at least on linux, statfs is the actual syscall
 978       [ac_cv_func_statvfs=no])
 979    ])
 980
 981 AS_IF([test x$ac_cv_func_statfs = xyes],
 982       [
 983          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
 984          AC_MSG_RESULT([statfs])
 985       ],
 986       [test x$ac_cv_func_statvfs = xyes],
 987       [
 988          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
 989          AC_MSG_RESULT([statvfs])
 990       ],
 991       [  AC_MSG_RESULT([neither])])
 992
 993 AC_CHECK_HEADERS(crt_externs.h)
 994 AC_CHECK_FUNCS(_NSGetEnviron)
 995
 996 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
 997
 998 # Internet address families
 999 if test $glib_native_win32 = yes; then
1000   glib_inet_includes=["
1001 #include <winsock2.h>
1002   "]
1003 else
1004   glib_inet_includes=["
1005 #include <sys/types.h>
1006 #include <sys/socket.h>
1007   "]
1008 fi
1009
1010 glib_failed=false
1011 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1012 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1013 # winsock defines this even though it doesn't support it
1014 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1015 if $glib_failed ; then
1016   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1017 fi
1018
1019 glib_failed=false
1020 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1021 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1022 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1023 if $glib_failed ; then
1024   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1025 fi
1026
1027 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname)
1028
1029 AS_IF([test $glib_native_win32 = yes], [
1030   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1031   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1032   # they aren't present at run-time (on Windows 2000).
1033   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1034   AC_SUBST(WSPIAPI_INCLUDE)
1035 ], [
1036   # Android does not have C_IN in public headers, we define it wherever necessary
1037   AS_IF([test $glib_native_android != yes], [
1038     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1039     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1040                                         #include <arpa/nameser.h>],
1041                                        [int qclass = C_IN;])],
1042                       [AC_MSG_RESULT([no])],
1043                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1044                                                            #include <arpa/nameser.h>
1045                                                            #include <arpa/nameser_compat.h>],
1046                                                           [int qclass = C_IN;])],
1047                                          [AC_MSG_RESULT([yes])
1048                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1049                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1050   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1051
1052   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1053   NETWORK_LIBS=""
1054   AC_MSG_CHECKING([for res_query])
1055   AC_TRY_LINK([#include <sys/types.h>
1056                #include <netinet/in.h>
1057                #include <arpa/nameser.h>
1058                #include <resolv.h>
1059               ],[
1060                res_query("test", 0, 0, (void *)0, 0);
1061               ],[AC_MSG_RESULT([yes])],
1062               [save_libs="$LIBS"
1063                LIBS="-lresolv $LIBS"
1064                AC_TRY_LINK([#include <sys/types.h>
1065                             #include <netinet/in.h>
1066                             #include <arpa/nameser.h>
1067                             #include <resolv.h>
1068                            ],[
1069                             res_query("test", 0, 0, (void *)0, 0);
1070                            ],[AC_MSG_RESULT([in -lresolv])
1071                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1072                            [LIBS="-lbind $save_libs"
1073                             AC_TRY_LINK([#include <resolv.h>],
1074                                         [res_query("test", 0, 0, (void *)0, 0);],
1075                                         [AC_MSG_RESULT([in -lbind])
1076                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1077                                         [AC_MSG_ERROR(not found)])])
1078                LIBS="$save_libs"])
1079   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1080                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1081                                         [AC_MSG_ERROR(Could not find socket())]))
1082   save_libs="$LIBS"
1083   LIBS="$LIBS $NETWORK_LIBS"
1084   AC_MSG_CHECKING([for res_init])
1085   AC_TRY_LINK([#include <sys/types.h>
1086                #include <netinet/in.h>
1087                #include <arpa/nameser.h>
1088                #include <resolv.h>
1089               ],[
1090                res_init();
1091               ],[AC_MSG_RESULT([yes])
1092                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1093               ],[AC_MSG_RESULT([no])])
1094   LIBS="$save_libs"
1095 ])
1096 AC_SUBST(NETWORK_LIBS)
1097
1098 AC_CHECK_HEADER([linux/netlink.h],
1099                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1100                 [#include <sys/socket.h>])
1101 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1102
1103 AC_CHECK_TYPE([struct ip_mreqn], [
1104               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1105               [#include <netinet/in.h>])
1106
1107 case $host in
1108   *-*-solaris* )
1109      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1111      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1112      ;;
1113 esac
1114
1115 dnl
1116 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1117 dnl
1118 AS_IF([test "$ac_cv_func_statfs" = yes], [
1119   AC_MSG_CHECKING([number of arguments to statfs()])
1120   AC_TRY_COMPILE([#include <unistd.h>
1121   #ifdef HAVE_SYS_PARAM_H
1122   #include <sys/param.h>
1123   #endif
1124   #ifdef HAVE_SYS_VFS_H
1125   #include <sys/vfs.h>
1126   #endif
1127   #ifdef HAVE_SYS_MOUNT_H
1128   #include <sys/mount.h>
1129   #endif
1130   #ifdef HAVE_SYS_STATFS_H
1131   #include <sys/statfs.h>
1132   #endif], [struct statfs st;
1133   statfs(NULL, &st);],[
1134     AC_MSG_RESULT([2])
1135     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1136     AC_TRY_COMPILE([#include <unistd.h>
1137   #ifdef HAVE_SYS_PARAM_H
1138   #include <sys/param.h>
1139   #endif
1140   #ifdef HAVE_SYS_VFS_H
1141   #include <sys/vfs.h>
1142   #endif
1143   #ifdef HAVE_SYS_MOUNT_H
1144   #include <sys/mount.h>
1145   #endif
1146   #ifdef HAVE_SYS_STATFS_H
1147   #include <sys/statfs.h>
1148   #endif], [struct statfs st;
1149   statfs(NULL, &st, sizeof (st), 0);],[
1150       AC_MSG_RESULT([4])
1151       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1152       AC_MSG_RESULT(unknown)
1153       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1154 ])
1155
1156 dnl
1157 dnl open takes O_DIRECTORY as an option
1158 dnl
1159 AC_MSG_CHECKING([open() option O_DIRECTORY])
1160 AC_TRY_COMPILE([#include <fcntl.h>
1161 #include <sys/types.h>
1162 #include <sys/stat.h>],
1163 [open(0, O_DIRECTORY, 0);],[
1164         AC_MSG_RESULT([yes])
1165         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1166         AC_MSG_RESULT([no])])
1167
1168 #
1169 # Check whether to use an included printf
1170 #
1171 AC_FUNC_VSNPRINTF_C99
1172 AC_FUNC_PRINTF_UNIX98
1173
1174 AC_ARG_ENABLE(included-printf,
1175               [AS_HELP_STRING([--enable-included-printf],
1176                               [use included printf [default=auto]])],
1177               enable_included_printf="$enableval")
1178
1179 need_included_printf=no
1180 if test "x$enable_included_printf" = "xyes" ; then
1181   need_included_printf=yes
1182 fi
1183 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1184   need_included_printf=yes
1185 fi
1186 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1187   need_included_printf=yes
1188 fi
1189 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1190    test -z "$glib_cv_long_long_format" ; then
1191   need_included_printf=yes
1192 fi
1193
1194 if test "x$enable_included_printf" = "xno" &&
1195    test "x$need_included_printf" = "xyes" ; then
1196   AC_MSG_ERROR([
1197 *** Your C library's printf doesn't appear to have the features that
1198 *** GLib needs, but you specified --enable-included-printf=no.])
1199 fi
1200
1201 enable_included_printf=$need_included_printf
1202
1203 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1204 AS_IF([test "$enable_included_printf" != "yes"], [
1205   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1206 ], [
1207   if test -z "$glib_cv_long_long_format" ; then
1208     glib_cv_long_long_format="ll"
1209   fi
1210   AC_DEFINE(HAVE_VASPRINTF,1)
1211 ])
1212
1213 # Checks needed for gnulib vasnprintf
1214 bh_C_SIGNED
1215 jm_AC_TYPE_LONG_LONG
1216 gt_TYPE_LONGDOUBLE
1217 gt_TYPE_WCHAR_T
1218 gt_TYPE_WINT_T
1219 AC_TYPE_SIZE_T
1220 AC_CHECK_TYPES(ptrdiff_t)
1221 jm_AC_TYPE_INTMAX_T
1222 AC_CHECK_FUNCS([snprintf wcslen])
1223 AC_FUNC_SNPRINTF_C99
1224
1225 # Check if <sys/select.h> needs to be included for fd_set
1226 AC_MSG_CHECKING([for fd_set])
1227 AC_TRY_COMPILE([#include <sys/types.h>],
1228         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1229 AS_IF([test "$gtk_ok" = "yes"], [
1230     AC_MSG_RESULT([yes, found in sys/types.h])
1231 ], [
1232     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1233     if test "$gtk_ok" = "yes"; then
1234         # *** FIXME: give it a different name
1235         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1236         AC_MSG_RESULT([yes, found in sys/select.h])
1237     else
1238         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1239         AC_MSG_RESULT(no)
1240     fi
1241 ])
1242
1243 dnl Check for nl_langinfo and CODESET
1244 AC_LANG_SAVE
1245 AC_LANG_C
1246 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1247         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1248                        [char *codeset = nl_langinfo (CODESET);])],
1249                 [glib_cv_langinfo_codeset=yes],
1250                 [glib_cv_langinfo_codeset=no])])
1251 if test x$glib_cv_langinfo_codeset = xyes; then
1252   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1253 fi
1254
1255 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1256 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1257         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1258                  [char *str;
1259                  str = nl_langinfo (PM_STR);
1260                  str = nl_langinfo (D_T_FMT);
1261                  str = nl_langinfo (D_FMT);
1262                  str = nl_langinfo (T_FMT);
1263                  str = nl_langinfo (T_FMT_AMPM);
1264                  str = nl_langinfo (MON_1);
1265                  str = nl_langinfo (ABMON_12);
1266                  str = nl_langinfo (DAY_1);
1267                  str = nl_langinfo (ABDAY_7);])],
1268                 [glib_cv_langinfo_time=yes],
1269                 [glib_cv_langinfo_time=no])])
1270 if test x$glib_cv_langinfo_time = xyes; then
1271   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1272 fi
1273
1274 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1275 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1276         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1277                 [char *str;
1278                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1279                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1280                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1281                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1282                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1283                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1284                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1285                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1286                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1287                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1288                 [glib_cv_langinfo_outdigit=yes],
1289                 [glib_cv_langinfo_outdigit=no])])
1290 if test x$glib_cv_langinfo_outdigit = xyes; then
1291   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1292 fi
1293 AC_LANG_RESTORE
1294
1295 dnl ****************************************
1296 dnl *** posix_memalign                   ***
1297 dnl ****************************************
1298 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1299 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1300     glib_cv_compliant_posix_memalign=0
1301     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1302         AC_TRY_RUN([
1303                 #define _XOPEN_SOURCE 600
1304                 #include <stdlib.h> /* posix_memalign() should be defined here */
1305                 /* some systems break if #include <malloc.h> used */
1306                 static void test_memalign (size_t boundary, size_t size) {
1307                     void *mem = 0;
1308                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1309                         exit (1);
1310                     else
1311                       free (mem);
1312                 }
1313                 int main() {
1314                     test_memalign (  128,   128 - 2 * sizeof (void*));
1315                     test_memalign (  256,   256 - 2 * sizeof (void*));
1316                     test_memalign (  512,   512 - 2 * sizeof (void*));
1317                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1318                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1319                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1320                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1321                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1322                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1323                     exit (0); /* success */
1324                 }
1325                 ],
1326             [glib_cv_compliant_posix_memalign=1], [], [:])
1327       :
1328     fi
1329     ])
1330 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1331     AC_MSG_RESULT(yes)
1332     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1333 ], [
1334     AC_MSG_RESULT(no)
1335 ])
1336
1337
1338 dnl ****************************************
1339 dnl *** strlcpy/strlcat                  ***
1340 dnl ****************************************
1341 # Check for strlcpy
1342 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1343 AC_TRY_RUN([#include <stdlib.h>
1344 #include <string.h>
1345 int main() {
1346   char p[10];
1347   (void) strlcpy (p, "hi", 10);
1348   if (strlcat (p, "bye", 0) != 3)
1349     return 1;
1350   return 0;
1351 }], glib_cv_have_strlcpy=yes,
1352     glib_cv_have_strlcpy=no,
1353     glib_cv_have_strlcpy=no)])
1354 if test "$glib_cv_have_strlcpy" = "yes"; then
1355     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1356 fi
1357
1358
1359 dnl **********************
1360 dnl *** va_copy checks ***
1361 dnl **********************
1362 dnl we currently check for all three va_copy possibilities, so we get
1363 dnl all results in config.log for bug reports.
1364 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1365         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1366 #include <stdlib.h>
1367         void f (int i, ...) {
1368         va_list args1, args2;
1369         va_start (args1, i);
1370         va_copy (args2, args1);
1371         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1372           exit (1);
1373         va_end (args1); va_end (args2);
1374         }
1375         int main() {
1376           f (0, 42);
1377           return 0;
1378         }]])],
1379         [glib_cv_va_copy=yes],
1380         [glib_cv_va_copy=no])
1381 ])
1382 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1383         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1384 #include <stdlib.h>
1385         void f (int i, ...) {
1386         va_list args1, args2;
1387         va_start (args1, i);
1388         __va_copy (args2, args1);
1389         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1390           exit (1);
1391         va_end (args1); va_end (args2);
1392         }
1393         int main() {
1394           f (0, 42);
1395           return 0;
1396         }]])],
1397         [glib_cv___va_copy=yes],
1398         [glib_cv___va_copy=no])
1399 ])
1400
1401 if test "x$glib_cv_va_copy" = "xyes"; then
1402   g_va_copy_func=va_copy
1403 else if test "x$glib_cv___va_copy" = "xyes"; then
1404   g_va_copy_func=__va_copy
1405 fi
1406 fi
1407
1408 if test -n "$g_va_copy_func"; then
1409   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1410 fi
1411
1412 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1413         AC_TRY_RUN([#include <stdarg.h>
1414 #include <stdlib.h>
1415         void f (int i, ...) {
1416         va_list args1, args2;
1417         va_start (args1, i);
1418         args2 = args1;
1419         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1420           exit (1);
1421         va_end (args1); va_end (args2);
1422         }
1423         int main() {
1424           f (0, 42);
1425           return 0;
1426         }],
1427         [glib_cv_va_val_copy=yes],
1428         [glib_cv_va_val_copy=no],
1429         [glib_cv_va_val_copy=yes])
1430 ])
1431
1432 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1433   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1434 ])
1435
1436 dnl ***********************
1437 dnl *** g_module checks ***
1438 dnl ***********************
1439 G_MODULE_LIBS=
1440 G_MODULE_LIBS_EXTRA=
1441 G_MODULE_PLUGIN_LIBS=
1442 if test x"$glib_native_win32" = xyes; then
1443   dnl No use for this on Win32
1444   G_MODULE_LDFLAGS=
1445 else
1446   export SED
1447   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1448 fi
1449 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1450 G_MODULE_NEED_USCORE=0
1451 G_MODULE_BROKEN_RTLD_GLOBAL=0
1452 G_MODULE_HAVE_DLERROR=0
1453 dnl *** force native WIN32 shared lib loader
1454 if test -z "$G_MODULE_IMPL"; then
1455   case "$host" in
1456   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1457   esac
1458 fi
1459 dnl *** force native AIX library loader
1460 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1461 if test -z "$G_MODULE_IMPL"; then
1462   case "$host" in
1463   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1464   esac
1465 fi
1466 dnl *** dlopen() and dlsym() in system libraries
1467 AS_IF([ test -z "$G_MODULE_IMPL"], [
1468         AC_CHECK_FUNC(dlopen,
1469                       [AC_CHECK_FUNC(dlsym,
1470                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1471                       [])
1472 ])
1473 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1474 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1475         AC_CHECK_FUNC(NSLinkModule,
1476                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1477                        G_MODULE_NEED_USCORE=1],
1478                       [])
1479 ])
1480 dnl *** dlopen() and dlsym() in libdl
1481 AS_IF([ test -z "$G_MODULE_IMPL"], [
1482         AC_CHECK_LIB(dl, dlopen,
1483                      [AC_CHECK_LIB(dl, dlsym,
1484                                    [G_MODULE_LIBS=-ldl
1485                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1486                      [])
1487 ])
1488 dnl *** additional checks for G_MODULE_IMPL_DL
1489 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1490         LIBS_orig="$LIBS"
1491         LDFLAGS_orig="$LDFLAGS"
1492         LIBS="$G_MODULE_LIBS $LIBS"
1493         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1494 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1495         echo "void glib_plugin_test(void) { }" > plugin.c
1496         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1497                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1498         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1499                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1500                 -shrext ".o" -avoid-version plugin.lo \
1501                 -rpath /dont/care >/dev/null 2>&1
1502         eval `./libtool --config | grep ^objdir`
1503         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1504                 glib_cv_rtldglobal_broken,[
1505                 AC_TRY_RUN([
1506 #include <dlfcn.h>
1507 #ifndef RTLD_GLOBAL
1508 #  define RTLD_GLOBAL 0
1509 #endif
1510 #ifndef RTLD_LAZY
1511 #  define RTLD_LAZY 0
1512 #endif
1513 int glib_plugin_test;
1514 int main () {
1515     void *handle, *global, *local;
1516     global = &glib_plugin_test;
1517     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1518     if (!handle) return 0;
1519     local = dlsym (handle, "glib_plugin_test");
1520     return global == local;
1521 }                       ],
1522                         [glib_cv_rtldglobal_broken=no],
1523                         [glib_cv_rtldglobal_broken=yes],
1524                         [glib_cv_rtldglobal_broken=no])
1525                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1526                 rmdir ${objdir} 2>/dev/null
1527         ])
1528         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1529                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1530         else
1531                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1532         fi
1533 dnl *** check whether we need preceeding underscores
1534         AC_CACHE_CHECK([for preceeding underscore in symbols],
1535                 glib_cv_uscore,[
1536                 AC_TRY_RUN([#include <dlfcn.h>
1537                 int glib_underscore_test (void) { return 42; }
1538                 int main() {
1539                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1540                   handle = dlopen ((void*)0, 0);
1541                   if (handle) {
1542                     f1 = dlsym (handle, "glib_underscore_test");
1543                     f2 = dlsym (handle, "_glib_underscore_test");
1544                   } return (!f2 || f1);
1545                 }],
1546                         [glib_cv_uscore=yes],
1547                         [glib_cv_uscore=no],
1548                         [])
1549                 rm -f plugin.c plugin.$ac_objext plugin.lo
1550         ])
1551         GLIB_ASSERT_SET(glib_cv_uscore)
1552         if test "x$glib_cv_uscore" = "xyes"; then
1553                 G_MODULE_NEED_USCORE=1
1554         else
1555                 G_MODULE_NEED_USCORE=0
1556         fi
1557
1558         LDFLAGS="$LDFLAGS_orig"
1559 dnl *** check for having dlerror()
1560         AC_CHECK_FUNC(dlerror,
1561                 [G_MODULE_HAVE_DLERROR=1],
1562                 [G_MODULE_HAVE_DLERROR=0])
1563         LIBS="$LIBS_orig"
1564 ])
1565 dnl *** done, have we got an implementation?
1566 if test -z "$G_MODULE_IMPL"; then
1567         G_MODULE_IMPL=0
1568         G_MODULE_SUPPORTED=false
1569 else
1570         G_MODULE_SUPPORTED=true
1571 fi
1572
1573 AC_MSG_CHECKING(for the suffix of module shared libraries)
1574 export SED
1575 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1576 eval $shrext_cmds
1577 module=yes eval std_shrext=$shrext_cmds
1578 # chop the initial dot
1579 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1580 AC_MSG_RESULT(.$glib_gmodule_suffix)
1581 # any reason it may fail?
1582 if test "x$glib_gmodule_suffix" = x; then
1583         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1584 fi
1585
1586 AC_SUBST(G_MODULE_SUPPORTED)
1587 AC_SUBST(G_MODULE_IMPL)
1588 AC_SUBST(G_MODULE_LIBS)
1589 AC_SUBST(G_MODULE_LIBS_EXTRA)
1590 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1591 AC_SUBST(G_MODULE_LDFLAGS)
1592 AC_SUBST(G_MODULE_HAVE_DLERROR)
1593 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1594 AC_SUBST(G_MODULE_NEED_USCORE)
1595 AC_SUBST(GLIB_DEBUG_FLAGS)
1596
1597 dnl **********************
1598 dnl *** g_spawn checks ***
1599 dnl **********************
1600
1601 AC_MSG_CHECKING(for gspawn implementation)
1602 case "$host" in
1603   *-*-mingw*)
1604     GSPAWN=gspawn-win32.lo
1605     ;;
1606   *)
1607     GSPAWN=gspawn.lo
1608     ;;
1609 esac
1610 AC_MSG_RESULT($GSPAWN)
1611 AC_SUBST(GSPAWN)
1612
1613 dnl *************************
1614 dnl *** GIOChannel checks ***
1615 dnl *************************
1616
1617 AC_MSG_CHECKING(for GIOChannel implementation)
1618 case "$host" in
1619   *-*-mingw*)
1620     GIO=giowin32.lo
1621     ;;
1622   *)
1623     GIO=giounix.lo
1624     ;;
1625 esac
1626 AC_MSG_RESULT($GIO)
1627 AC_SUBST(GIO)
1628
1629 dnl *********************************
1630 dnl *** Directory for GIO modules ***
1631 dnl *********************************
1632
1633 AC_ARG_WITH(gio-module-dir,
1634            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1635                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1636            [],
1637            [with_gio_module_dir='${libdir}/gio/modules'])
1638 GIO_MODULE_DIR=$with_gio_module_dir
1639 AC_SUBST(GIO_MODULE_DIR)
1640
1641 dnl **********************************
1642 dnl *** Check for libselinux (GIO) ***
1643 dnl **********************************
1644 AC_ARG_ENABLE(selinux,
1645               AS_HELP_STRING([--disable-selinux],
1646                              [build without selinux support]))
1647 msg_selinux=no
1648 SELINUX_LIBS=
1649 AS_IF([ test "x$enable_selinux" != "xno"], [
1650
1651  AC_CHECK_LIB(selinux, is_selinux_enabled,
1652    [AC_CHECK_HEADERS(selinux/selinux.h,
1653      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1654        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1655         SELINUX_LIBS="-lselinux"
1656         msg_selinux=yes])
1657      ])
1658    ])
1659 ])
1660 AC_SUBST(SELINUX_LIBS)
1661
1662 dnl *****************************
1663 dnl ** Check for inotify (GIO) **
1664 dnl *****************************
1665 inotify_support=no
1666 AC_CHECK_HEADERS([sys/inotify.h],
1667 [
1668         inotify_support=yes
1669         AC_CHECK_FUNCS(inotify_init1)
1670 ])
1671
1672 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1673
1674 dnl ****************************
1675 dnl ** Check for kqueue (GIO) **
1676 dnl ****************************
1677 kqueue_support=no
1678 AC_CHECK_HEADERS([sys/event.h],
1679 [
1680         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1681 ])
1682
1683 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1684
1685 dnl *********************************
1686 dnl ** Check for Solaris FEN (GIO) **
1687 dnl *********************************
1688 fen_support=no
1689 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1690 #include <port.h>
1691 #ifndef PORT_SOURCE_FILE
1692 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1693 #endif
1694 int main() { return 0; } ]])],
1695 [
1696         fen_support=yes
1697 ],)
1698
1699 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1700
1701 dnl ****************************
1702 dnl *** Checks for FAM (GIO) ***
1703 dnl ****************************
1704
1705 should_disable_fam=no
1706
1707 AC_ARG_ENABLE(fam,
1708               AS_HELP_STRING([--disable-fam],
1709                              [don't use fam for file system monitoring]),
1710                          [
1711                                 if test "x$enable_fam" = "xno"; then
1712                                         should_disable_fam=yes
1713                                 fi
1714                          ]
1715                          )
1716 fam_support=no
1717 FAM_LIBS=
1718 if test "x$should_disable_fam" = "xno"; then
1719 AC_CHECK_LIB(fam, FAMOpen,
1720   [AC_CHECK_HEADERS(fam.h,
1721     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1722      AC_CHECK_LIB(fam, FAMNoExists,
1723                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1724      FAM_LIBS="-lfam"]
1725      fam_support=yes,
1726     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1727   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1728 AC_SUBST(FAM_LIBS)
1729 fi
1730 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1731
1732
1733 dnl *****************************
1734 dnl *** Check for xattr (GIO) ***
1735 dnl *****************************
1736 AC_ARG_ENABLE(xattr,
1737               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1738 msg_xattr=no
1739 XATTR_LIBS=
1740 AS_IF([ test "x$enable_xattr" != "xno"], [
1741
1742 dnl either glibc or libattr can provide xattr support
1743
1744 dnl for both of them, we check for getxattr being in
1745 dnl the library and a valid xattr header.
1746
1747 dnl try glibc
1748  AC_CHECK_LIB(c, getxattr,
1749    [AC_CHECK_HEADERS(sys/xattr.h,
1750      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1751       msg_xattr=yes])
1752    ])
1753
1754   AS_IF([ test "x$msg_xattr" != "xyes"], [
1755 dnl   failure. try libattr
1756    AC_CHECK_LIB(attr, getxattr,
1757       [AC_CHECK_HEADERS(attr/xattr.h,
1758        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1759         XATTR_LIBS="-lattr"
1760         msg_xattr=yes])
1761       ])
1762   ])
1763
1764   AS_IF([ test "x$msg_xattr" = "xyes"], [
1765     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1766     AC_TRY_COMPILE([
1767       #include <stdio.h>
1768       #ifdef HAVE_SYS_TYPES_H
1769       #include <sys/types.h>
1770       #endif
1771       #ifdef HAVE_SYS_XATTR_H
1772       #include <sys/xattr.h>
1773       #elif HAVE_ATTR_XATTR_H
1774       #include <attr/xattr.h>
1775       #endif
1776     ],
1777     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1778     [
1779       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1780       AC_MSG_RESULT([yes])
1781     ],
1782     [AC_MSG_RESULT([no])]
1783     )
1784   ])
1785 ])
1786 AC_SUBST(XATTR_LIBS)
1787
1788 dnl ************************
1789 dnl *** check for libelf ***
1790 dnl ************************
1791 AC_ARG_ENABLE(libelf,
1792               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1793 AS_IF([ test "x$enable_libelf" != "xno"],[
1794 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1795 AS_IF([ test $have_libelf = maybe ], [
1796   glib_save_LIBS=$LIBS
1797   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1798   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1799   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1800   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1801   LIBS=$glib_save_LIBS
1802
1803   if test $have_libelf != no; then
1804     LIBELF_LIBS=-lelf
1805     have_libelf=yes
1806   fi
1807 ])
1808 ])
1809
1810 if test x$have_libelf = xyes; then
1811   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1812 fi
1813
1814 dnl ****************************************
1815 dnl *** platform dependent source checks ***
1816 dnl ****************************************
1817
1818 AC_MSG_CHECKING(for platform-dependent source)
1819 case "$host" in
1820   *-*-cygwin*|*-*-mingw*)
1821     PLATFORMDEP=gwin32.lo
1822     ;;
1823   *)
1824     PLATFORMDEP=
1825     ;;
1826 esac
1827 AC_MSG_RESULT($PLATFORMDEP)
1828 AC_SUBST(PLATFORMDEP)
1829
1830 AC_MSG_CHECKING([whether to compile timeloop])
1831 case "$host" in
1832   *-*-cygwin*|*-*-mingw*|*-*-minix)
1833     enable_timeloop=no
1834     ;;
1835   *)
1836     enable_timeloop=yes
1837     ;;
1838 esac
1839 AC_MSG_RESULT($enable_timeloop)
1840 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1841
1842 AC_MSG_CHECKING([if building for some Win32 platform])
1843 case "$host" in
1844   *-*-mingw*|*-*-cygwin*)
1845     platform_win32=yes
1846     ;;
1847   *)
1848     platform_win32=no
1849     ;;
1850 esac
1851 AC_MSG_RESULT($platform_win32)
1852 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1853
1854 dnl ***********************
1855 dnl *** g_thread checks ***
1856 dnl ***********************
1857
1858 AC_ARG_WITH(threads,
1859            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1860                            [specify a thread implementation to use])],
1861            [],
1862            [with_threads=yes])
1863
1864 dnl error and warning message
1865 dnl *************************
1866
1867 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1868
1869 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1870                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1871                 compilation now, but then your programs might not work.
1872                 Please provide information on how it is done on your system."
1873
1874 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1875                  "
1876
1877 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1878                   provide information on your thread implementation."
1879
1880 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1881                 functions will not be MT-safe during their first call because
1882                 there is no working 'getpwuid_r' on your system."
1883
1884 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1885                 because there is no 'localtime_r' on your system."
1886
1887 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1888                 linking threaded applications. As GLib cannot do that
1889                 automatically, you will get an linkg error everytime you are
1890                 not using the right compiler. In that case you have to relink
1891                 with the right compiler. Ususally just '_r' is appended
1892                 to the compiler name."
1893
1894 dnl determination of thread implementation
1895 dnl ***************************************
1896
1897 AC_MSG_CHECKING(for thread implementation)
1898
1899 have_threads=no
1900 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1901         AS_IF([ test "x$have_threads" = xno], [
1902                 AC_TRY_COMPILE([#include <pthread.h>],
1903                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1904                         have_threads=posix)
1905         ])
1906         # Tru64Unix requires -pthread to find pthread.h. See #103020
1907         if test "x$have_threads" = xno; then
1908                 glib_save_CPPFLAGS="$CPPFLAGS"
1909                 CPPFLAGS="$CPPFLAGS -pthread"
1910                 AC_TRY_COMPILE([#include <pthread.h>],
1911                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1912                        have_threads=posix)
1913                 CPPFLAGS="$glib_save_CPPFLAGS"
1914         fi
1915 ])
1916 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1917         case $host in
1918                 *-*-mingw*)
1919                 have_threads=win32
1920                 ;;
1921         esac
1922 fi
1923
1924 if test "x$have_threads" = xno; then
1925         AC_MSG_RESULT(none available)
1926         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1927 else
1928         AC_MSG_RESULT($have_threads)
1929 fi
1930
1931
1932 dnl determination of G_THREAD_CFLAGS
1933 dnl ********************************
1934
1935 G_THREAD_LIBS=
1936 G_THREAD_LIBS_EXTRA=
1937 G_THREAD_CFLAGS=
1938
1939 dnl
1940 dnl Test program for basic POSIX threads functionality
1941 dnl
1942 m4_define([glib_thread_test],[
1943 #include <pthread.h>
1944 int check_me = 0;
1945 void* func(void* data) {check_me = 42; return &check_me;}
1946 int main()
1947  { pthread_t t;
1948    void *ret;
1949    pthread_create (&t, $1, func, 0);
1950    pthread_join (t, &ret);
1951    return (check_me != 42 || ret != &check_me);
1952 }])
1953
1954 AS_IF([ test x"$have_threads" = xposix], [
1955   # First we test for posix, whether -pthread or -pthreads do the trick as
1956   # both CPPFLAG and LIBS.
1957   # One of them does for most gcc versions and some other platforms/compilers
1958   # too and could be considered as the canonical way to go.
1959   case $host in
1960     *-*-cygwin*|*-*-darwin*)
1961        # skip cygwin and darwin -pthread or -pthreads test
1962        ;;
1963     *-solaris*)
1964       # These compiler/linker flags work with both Sun Studio and gcc
1965       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1966       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1967       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1968       G_THREAD_LIBS="-lpthread -lthread"
1969       ;;
1970     *)
1971       for flag in pthread pthreads mt; do
1972         glib_save_CFLAGS="$CFLAGS"
1973         CFLAGS="$CFLAGS -$flag"
1974         AC_TRY_RUN(glib_thread_test(0),
1975                    glib_flag_works=yes,
1976                    glib_flag_works=no,
1977                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1978                                    glib_flag_works=yes,
1979                                    glib_flag_works=no)])
1980         CFLAGS="$glib_save_CFLAGS"
1981         if test $glib_flag_works = yes ; then
1982            G_THREAD_CFLAGS=-$flag
1983         G_THREAD_LIBS=-$flag
1984         break;
1985         fi
1986       done
1987        ;;
1988   esac
1989 ])
1990
1991 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1992
1993   # The canonical -pthread[s] does not work. Try something different.
1994
1995   case $host in
1996         *-aix*)
1997                 if test x"$GCC" = xyes; then
1998                         # GCC 3.0 and above needs -pthread.
1999                         # Should be coverd by the case above.
2000                         # GCC 2.x and below needs -mthreads
2001                         G_THREAD_CFLAGS="-mthreads"
2002                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2003                 else
2004                         # We are probably using the aix compiler. Normaly a
2005                         # program would have to be compiled with the _r variant
2006                         # of the corresponding compiler, but we as GLib cannot
2007                         # do that: but the good news is that for compiling the
2008                         # only difference is the added -D_THREAD_SAFE compile
2009                         # option. This is according to the "C for AIX User's
2010                         # Guide".
2011                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2012                 fi
2013                 ;;
2014         *-sysv5uw7*) # UnixWare 7
2015                 # We are not using gcc with -pthread. Catched above.
2016                 G_THREAD_CFLAGS="-Kthread"
2017                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2018                 ;;
2019         *-mingw*)
2020                 # No flag needed when using MSVCRT.DLL
2021                 G_THREAD_CFLAGS=""
2022                 ;;
2023         *)
2024                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2025                 ;;
2026   esac
2027 ])
2028
2029 # if we are not finding the localtime_r function, then we probably are
2030 # not using the proper multithread flag
2031
2032 glib_save_CPPFLAGS="$CPPFLAGS"
2033 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2034
2035 # First we test, whether localtime_r is declared in time.h
2036 # directly. Then we test whether a macro localtime_r exists, in
2037 # which case localtime_r in the test program is replaced and thus
2038 # if we still find localtime_r in the output, it is not defined as
2039 # a macro.
2040
2041 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2042   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2043                                                            localtime_r(a,b)],
2044                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2045
2046 CPPFLAGS="$glib_save_CPPFLAGS"
2047
2048 AC_MSG_CHECKING(thread related cflags)
2049 AC_MSG_RESULT($G_THREAD_CFLAGS)
2050 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2051
2052 dnl determination of G_THREAD_LIBS
2053 dnl ******************************
2054
2055 AS_IF([test x$have_threads = xposix], [
2056           glib_save_CPPFLAGS="$CPPFLAGS"
2057           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2058           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2059             case $host in
2060               *-aix*)
2061                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2062                 # probably using the aix compiler.
2063                 AC_MSG_WARN($AIX_COMPILE_INFO)
2064                 ;;
2065               *)
2066                 G_THREAD_LIBS=error
2067                 glib_save_LIBS="$LIBS"
2068                 for thread_lib in "" pthread pthread32 pthreads thread; do
2069                         if test x"$thread_lib" = x; then
2070                                 add_thread_lib=""
2071                                 IN=""
2072                         else
2073                                 add_thread_lib="-l$thread_lib"
2074                                 IN=" in -l$thread_lib"
2075                         fi
2076                         if test x"$have_threads" = xposix; then
2077                                 defattr=0
2078                         else
2079                                 defattr=pthread_attr_default
2080                         fi
2081
2082                         LIBS="$add_thread_lib $glib_save_LIBS"
2083
2084                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2085                         AC_TRY_RUN(glib_thread_test($defattr),
2086                                    glib_result=yes,
2087                                    glib_result=no,
2088                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2089                                                    glib_result=yes,
2090                                                    glib_result=no)])
2091                         AC_MSG_RESULT($glib_result)
2092
2093                         if test "$glib_result" = "yes" ; then
2094                           G_THREAD_LIBS="$add_thread_lib"
2095                           break
2096                         fi
2097                 done
2098                 if test "x$G_THREAD_LIBS" = xerror; then
2099                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2100                 fi
2101                 LIBS="$glib_save_LIBS"
2102                 ;;
2103             esac
2104           ])
2105
2106           g_threads_impl="POSIX"
2107           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2108           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2109           CPPFLAGS="$glib_save_CPPFLAGS"
2110 ], [test x$have_threads = xwin32], [
2111            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2112            g_threads_impl="WIN32"
2113 ], [
2114            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2115            g_threads_impl="NONE"
2116            G_THREAD_LIBS=error
2117 ])
2118 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2119 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2120 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2121
2122 if test "x$G_THREAD_LIBS" = xerror; then
2123         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2124 fi
2125
2126 AC_MSG_CHECKING(thread related libraries)
2127 AC_MSG_RESULT($G_THREAD_LIBS)
2128
2129 dnl check for mt safe function variants and some posix functions
2130 dnl ************************************************************
2131
2132 glib_save_LIBS="$LIBS"
2133 # we are not doing the following for now, as this might require glib
2134 # to always be linked with the thread libs on some platforms.
2135 # LIBS="$LIBS $G_THREAD_LIBS"
2136 AC_CHECK_FUNCS(localtime_r gmtime_r)
2137 AS_IF([ test "$glib_native_win32" != "yes"], [
2138         AC_CACHE_CHECK([for posix getpwuid_r],
2139                 ac_cv_func_posix_getpwuid_r,
2140                 [AC_TRY_RUN([
2141 #include <errno.h>
2142 #include <pwd.h>
2143 int main () {
2144     char buffer[10000];
2145     struct passwd pwd, *pwptr = &pwd;
2146     int error;
2147     errno = 0;
2148     error = getpwuid_r (0, &pwd, buffer,
2149                         sizeof (buffer), &pwptr);
2150    return (error < 0 && errno == ENOSYS)
2151            || error == ENOSYS;
2152 }                               ],
2153                         [ac_cv_func_posix_getpwuid_r=yes],
2154                         [ac_cv_func_posix_getpwuid_r=no])])
2155         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2156         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2157                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2158                         [Have POSIX function getpwuid_r])
2159         else
2160                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2161                         ac_cv_func_nonposix_getpwuid_r,
2162                         [AC_TRY_LINK([#include <pwd.h>],
2163                                 [char buffer[10000];
2164                                 struct passwd pwd;
2165                                 getpwuid_r (0, &pwd, buffer,
2166                                                 sizeof (buffer));],
2167                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2168                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2169                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2170                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2171                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2172                                 [Have non-POSIX function getpwuid_r])
2173                 fi
2174         fi
2175 ])
2176 AS_IF([ test "$glib_native_win32" != "yes"], [
2177         AC_CACHE_CHECK([for posix getgrgid_r],
2178                 ac_cv_func_posix_getgrgid_r,
2179                 [AC_TRY_RUN([
2180 #include <errno.h>
2181 #include <grp.h>
2182 int main () {
2183     char buffer[10000];
2184     struct group grp, *grpptr = &grp;
2185     int error;
2186     errno = 0;
2187     error = getgrgid_r (0, &grp, buffer,
2188                         sizeof (buffer), &grpptr);
2189    return (error < 0 && errno == ENOSYS)
2190            || error == ENOSYS;
2191 }                              ],
2192                        [ac_cv_func_posix_getgrgid_r=yes],
2193                        [ac_cv_func_posix_getgrgid_r=no])])
2194         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2195         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2196                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2197                         [Have POSIX function getgrgid_r])
2198         ], [
2199                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2200                         ac_cv_func_nonposix_getgrgid_r,
2201                         [AC_TRY_LINK([#include <grp.h>],
2202                                 [char buffer[10000];
2203                                 struct group grp;
2204                                 getgrgid_r (0, &grp, buffer,
2205                                 sizeof (buffer));],
2206                         [ac_cv_func_nonposix_getgrgid_r=yes],
2207                         [ac_cv_func_nonposix_getgrgid_r=no])])
2208                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2209                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2210                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2211                                 [Have non-POSIX function getgrgid_r])
2212                 fi
2213         ])
2214 ])
2215 LIBS="$G_THREAD_LIBS $LIBS"
2216 AS_IF([ test x"$have_threads" = xposix], [
2217         glib_save_CPPFLAGS="$CPPFLAGS"
2218         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2219         # This is not AC_CHECK_FUNC to also work with function
2220         # name mangling in header files.
2221         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2222         AC_LINK_IFELSE(
2223             [AC_LANG_PROGRAM(
2224                 [#include <pthread.h>],
2225                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2226             [AC_MSG_RESULT(yes)
2227              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2228                 [Have function pthread_attr_setstacksize])],
2229             [AC_MSG_RESULT(no)])
2230         AC_MSG_CHECKING(for pthread_condattr_setclock)
2231         AC_LINK_IFELSE(
2232             [AC_LANG_PROGRAM(
2233                 [#include <pthread.h>],
2234                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2235             [AC_MSG_RESULT(yes)
2236              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2237                 [Have function pthread_condattr_setclock])],
2238             [AC_MSG_RESULT(no)])
2239         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic)
2240         AC_LINK_IFELSE(
2241             [AC_LANG_PROGRAM(
2242                 [#include <pthread.h>],
2243                 [pthread_cond_timedwait_monotonic(NULL, NULL, NULL)])],
2244             [AC_MSG_RESULT(yes)
2245              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC,1,
2246                 [Have function pthread_cond_timedwait_monotonic])],
2247             [AC_MSG_RESULT(no)])
2248         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic_np)
2249         AC_LINK_IFELSE(
2250             [AC_LANG_PROGRAM(
2251                 [#include <pthread.h>],
2252                 [pthread_cond_timedwait_monotonic_np(NULL, NULL, NULL)])],
2253             [AC_MSG_RESULT(yes)
2254              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC_NP,1,
2255                 [Have function pthread_cond_timedwait_monotonic_np])],
2256             [AC_MSG_RESULT(no)])
2257         CPPFLAGS="$glib_save_CPPFLAGS"
2258 ])
2259
2260 LIBS="$glib_save_LIBS"
2261
2262 # now spit out all the warnings.
2263 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2264    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2265         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2266 fi
2267 if test "$ac_cv_func_localtime_r" != "yes"; then
2268         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2269 fi
2270
2271 #
2272 # Hack to deal with:
2273 #
2274 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2275 #     building shared libraries with linux.
2276 #  b) FreeBSD doesn't do this either.
2277 #
2278 case $host in
2279   *android*)
2280     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2281     ;;
2282   *-*-freebsd*|*-*-linux*)
2283     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2284     ;;
2285   *-*-openbsd*)
2286     LDFLAGS="$LDFLAGS -pthread"
2287     ;;
2288   *)
2289     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2290     ;;
2291 esac
2292
2293 AC_SUBST(G_THREAD_CFLAGS)
2294 AC_SUBST(G_THREAD_LIBS)
2295 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2296 AC_SUBST(G_THREAD_LIBS_EXTRA)
2297
2298 AC_CHECK_FUNCS(clock_gettime, [], [
2299   AC_CHECK_LIB(rt, clock_gettime, [
2300     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2301     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2302     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2303   ])
2304 ])
2305
2306
2307 dnl ************************
2308 dnl *** g_atomic_* tests ***
2309 dnl ************************
2310
2311 dnl We need to decide at configure time if GLib will use real atomic
2312 dnl operations ("lock free") or emulated ones with a mutex.  This is
2313 dnl because we must put this information in glibconfig.h so we know if
2314 dnl it is safe or not to inline using compiler intrinsics directly from
2315 dnl the header.
2316 dnl
2317 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2318 dnl user is interested in knowing if they can use the atomic ops across
2319 dnl processes.
2320 dnl
2321 dnl We can currently support the atomic ops natively when building GLib
2322 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2323 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2324 dnl we are using GCC (and not mingw*).
2325 dnl
2326 dnl Note that the atomic ops are only available with GCC on x86 when
2327 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2328 dnl not available but would be available given the right flags, we want
2329 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2330 dnl that then to silently fall back on emulated atomic ops just because
2331 dnl the user had the wrong build environment.
2332
2333 dnl We may add other compilers here in the future...
2334
2335 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2336   case $host in
2337     *-*-mingw*)
2338       glib_cv_g_atomic_lock_free=yes
2339       ;;
2340     *)
2341       AC_TRY_LINK([],
2342                      [volatile int atomic = 2;\
2343                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2344                      [glib_cv_g_atomic_lock_free=yes],
2345                      [glib_cv_g_atomic_lock_free=no])
2346       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2347         SAVE_CFLAGS="${CFLAGS}"
2348         CFLAGS="-march=i486"
2349         AC_TRY_LINK([],
2350                        [volatile int atomic = 2;\
2351                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2352                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2353                        [])
2354         CFLAGS="${SAVE_CFLAGS}"
2355       fi
2356       ;;
2357   esac])
2358
2359
2360 case $host in
2361   *-*-mingw*)
2362     ;;
2363   *)
2364     # Some compilers support atomic operations but do not define
2365     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2366     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2367       AC_TRY_LINK([],
2368                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2369                      [],
2370                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2371     fi
2372     ;;
2373  esac
2374
2375 dnl We need a more robust approach here...
2376 case $host_cpu in
2377   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2378     glib_memory_barrier_needed=no
2379     ;;
2380   sparc*|alpha*|powerpc*|ia64)
2381     glib_memory_barrier_needed=yes
2382     ;;
2383   *)
2384     glib_memory_barrier_needed=yes
2385     ;;
2386 esac
2387
2388 dnl ************************
2389 dnl ** Check for futex(2) **
2390 dnl ************************
2391 AC_CACHE_CHECK(for futex(2) system call,
2392     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2393 #include <linux/futex.h>
2394 #include <sys/syscall.h>
2395 #include <unistd.h>
2396 ],[
2397 int
2398 main (void)
2399 {
2400   /* it is not like this actually runs or anything... */
2401   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2402   return 0;
2403 }
2404 ])],glib_cv_futex=yes,glib_cv_futex=no))
2405 if test x"$glib_cv_futex" = xyes; then
2406   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2407 fi
2408
2409 AC_CACHE_CHECK(for eventfd(2) system call,
2410     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2411 #include <sys/eventfd.h>
2412 #include <unistd.h>
2413 ],[
2414 int
2415 main (void)
2416 {
2417   eventfd (0, EFD_CLOEXEC);
2418   return 0;
2419 }
2420 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2421 if test x"$glib_cv_eventfd" = x"yes"; then
2422   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2423 fi
2424 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2425
2426 dnl ****************************************
2427 dnl *** GLib POLL* compatibility defines ***
2428 dnl ****************************************
2429
2430 glib_poll_includes=["
2431 #include <sys/types.h>
2432 #include <poll.h>
2433 "]
2434
2435 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2436    test $ac_cv_func_poll = yes ], [
2437   glib_failed=false
2438   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2439   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2440   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2441   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2442   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2443   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2444   if $glib_failed ; then
2445     AC_MSG_ERROR([Could not determine values for POLL* constants])
2446   fi
2447 ], [
2448   glib_cv_value_POLLIN=1
2449   glib_cv_value_POLLOUT=4
2450   glib_cv_value_POLLPRI=2
2451   glib_cv_value_POLLERR=8
2452   glib_cv_value_POLLHUP=16
2453   glib_cv_value_POLLNVAL=32
2454 ])
2455
2456 AC_MSG_CHECKING([for broken poll])
2457 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2458         #include <stdlib.h>
2459         #include <fcntl.h>
2460         #include <poll.h>
2461         int main(void) {
2462           struct pollfd fds[1];
2463           int fd;
2464           fd = open("/dev/null", 1);
2465           fds[0].fd = fd;
2466           fds[0].events = POLLIN;
2467           fds[0].revents = 0;
2468           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2469                 exit(1);  /* Does not work for devices -- fail */
2470           }
2471           exit(0);
2472         }]])],
2473   [broken_poll=no],
2474   [broken_poll=yes
2475    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2476   [broken_poll="no (cross compiling)"])
2477 AC_MSG_RESULT($broken_poll)
2478
2479 dnl *********************
2480 dnl *** GRegex checks ***
2481 dnl *********************
2482
2483 PCRE_REQUIRED_VERSION=8.13
2484
2485 # Check if we should use the internal or the system-supplied pcre
2486 AC_ARG_WITH(pcre,
2487             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2488                             [whether to use system PCRE [default=internal]])])
2489
2490 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2491
2492 AS_IF([ test "x$with_pcre" = xsystem], [
2493   PKG_CHECK_MODULES(PCRE,
2494                     libpcre >= $PCRE_REQUIRED_VERSION)
2495   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2496                   glib_save_CFLAGS="$CFLAGS"
2497                   glib_save_LIBS="$LIBS"
2498                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2499                   AC_TRY_RUN([#include <pcre.h>
2500                               int main () {
2501                                 int support;
2502                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2503                                 if (!support)
2504                                   return 1;
2505                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2506                                 if (!support)
2507                                   return 1;
2508                                 return 0;
2509                               }],
2510                   glib_cv_pcre_has_unicode=yes,
2511                   glib_cv_pcre_has_unicode=no,
2512                   glib_cv_pcre_has_unicode=yes)
2513                   CFLAGS="$glib_save_CFLAGS"
2514                   LIBS="$glib_save_LIBS"
2515       ])
2516   if test "$glib_cv_pcre_has_unicode" = "no"; then
2517     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2518   fi
2519   AC_SUBST(PCRE_CFLAGS)
2520   AC_SUBST(PCRE_LIBS)
2521   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2522   PCRE_REQUIRES=libpcre
2523   AC_SUBST(PCRE_REQUIRES)
2524 ], [
2525   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2526   AS_IF([ test x"$GCC" = xyes], [
2527     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2528     save_CFLAGS="$CFLAGS"
2529     CFLAGS="$CFLAGS -Wno-pointer-sign"
2530     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2531                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2532     CFLAGS="$save_CFLAGS"
2533   ])
2534 ])
2535 AC_SUBST(PCRE_WARN_CFLAGS)
2536
2537 dnl **********************
2538 dnl *** Win32 API libs ***
2539 dnl **********************
2540
2541 case $host in
2542   *-*-cygwin*)
2543         G_LIBS_EXTRA="-luser32 -lkernel32"
2544     ;;
2545   *-*-mingw*)
2546         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2547     ;;
2548   *)
2549         G_LIBS_EXTRA=""
2550     ;;
2551 esac
2552 AC_SUBST(G_LIBS_EXTRA)
2553
2554 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2555 dnl since we need it for g_iconv()
2556
2557 AC_MSG_CHECKING([for EILSEQ])
2558 AC_TRY_COMPILE([
2559 #include <errno.h>
2560 ],
2561 [
2562 int error = EILSEQ;
2563 ], have_eilseq=yes, have_eilseq=no);
2564 AC_MSG_RESULT($have_eilseq)
2565
2566 dnl ******************************************************************
2567 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2568 dnl *** glib-compile-schemas in PATH                               ***
2569 dnl ******************************************************************
2570
2571 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2572
2573 AS_IF([ test $cross_compiling = yes ], [
2574   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2575   if test x$GLIB_GENMARSHAL = xno; then
2576     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2577   fi
2578
2579   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2580   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2581     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2582   fi
2583
2584   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2585   if test x$GLIB_COMPILE_RESOURCES = xno; then
2586     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2587   fi
2588 ])
2589
2590 dnl **************************
2591 dnl *** Checks for gtk-doc ***
2592 dnl **************************
2593 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2594 # it on it's own line.
2595 m4_ifdef([GTK_DOC_CHECK], [
2596 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2597 ],[
2598 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2599 ])
2600
2601 AC_ARG_ENABLE(man,
2602               [AS_HELP_STRING([--enable-man],
2603                               [generate man pages [default=auto]])],,
2604               enable_man=maybe)
2605
2606 AS_IF([test "$enable_man" != no], [
2607   AC_PATH_PROG([XSLTPROC], [xsltproc])
2608   AS_IF([test -z "$XSLTPROC"], [
2609     AS_IF([test "$enable_man" = yes], [
2610       AC_MSG_ERROR([xsltproc is required for --enable-man])
2611     ])
2612     enable_man=no
2613   ])
2614 ])
2615
2616 AS_IF([ test "$enable_man" != no ], [
2617   dnl check for DocBook DTD in the local catalog
2618   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2619      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2620   AS_IF([test "$have_docbook_dtd" != yes], [
2621     AS_IF([test "$enable_man" = yes ], [
2622       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2623     ])
2624     enable_man=no
2625   ])
2626 ])
2627
2628 AS_IF([test "$enable_man" != no], [
2629   dnl check for DocBook XSL stylesheets in the local catalog
2630   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2631      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2632   AS_IF([ test "$have_docbook_dtd" != yes ], [
2633     AS_IF([ test "$enable_man" = yes ], [
2634       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2635     ])
2636     enable_man=no
2637   ])
2638 ])
2639
2640 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2641
2642 AC_MSG_CHECKING([whether to generate man pages])
2643 AS_IF([ test "$enable_man" != no ], [
2644   AC_MSG_RESULT([yes])
2645 ], [
2646   AC_MSG_RESULT([no])
2647 ])
2648
2649 dnl
2650 dnl Tracing
2651 dnl
2652
2653 AC_ARG_ENABLE([dtrace],
2654              [AS_HELP_STRING([--enable-dtrace],
2655                               [include tracing support for dtrace])])
2656 have_dtrace=no
2657 AC_MSG_CHECKING([whether to include dtrace tracing support])
2658 AS_IF([ test "x$enable_dtrace" != xno], [
2659   if test x$glib_have_carbon = xyes; then
2660     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2661   else
2662     AC_MSG_RESULT([yes])
2663     AC_CHECK_PROGS(DTRACE, dtrace)
2664     if test -z "$DTRACE"; then
2665       if test "x$enable_dtrace" = xyes; then
2666         AC_MSG_ERROR([dtrace not found])
2667       fi
2668     else
2669       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2670                       [if test "x$enable_dtrace" = xyes; then
2671                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2672                        fi])
2673     fi
2674   fi
2675 ], [
2676   AC_MSG_RESULT([no])
2677 ])
2678 if test "x$have_dtrace" = xyes; then
2679   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2680 fi
2681 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2682
2683 AC_MSG_CHECKING([whether to include systemtap tracing support])
2684 AC_ARG_ENABLE([systemtap],
2685              [AS_HELP_STRING([--enable-systemtap],
2686                               [include tracing support for systemtap])])
2687 have_systemtap=no
2688 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2689   have_systemtap=yes
2690 fi
2691 AC_MSG_RESULT(${have_systemtap})
2692
2693 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2694
2695 AC_ARG_WITH([tapset-install-dir],
2696             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2697                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2698             [if test "x${withval}" = x; then
2699                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2700              else
2701                ABS_TAPSET_DIR="${withval}"
2702               fi],
2703             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2704 AC_SUBST(ABS_TAPSET_DIR)
2705
2706 dnl ************************************
2707 dnl *** Enable lcov coverage reports ***
2708 dnl ************************************
2709
2710 AC_ARG_ENABLE(coverage,
2711   AS_HELP_STRING([--enable-coverage],
2712                  [enable coverage testing with gcov]),
2713   [use_gcov=$enableval], [use_gcov=no])
2714
2715 AS_IF([ test "x$use_gcov" = "xyes"], [
2716   dnl we need gcc:
2717   if test "$GCC" != "yes"; then
2718     AC_MSG_ERROR([GCC is required for --enable-coverage])
2719   fi
2720
2721   dnl Check if ccache is being used
2722   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2723   case `$SHTOOL path $CC` in
2724     *ccache*[)] gcc_ccache=yes;;
2725     *[)] gcc_ccache=no;;
2726   esac
2727
2728   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2729     AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2730   fi
2731
2732   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2733   AC_CHECK_PROG(LTP, lcov, lcov)
2734   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2735
2736   AS_IF([ test "$LTP" ], [
2737     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2738       glib_cv_ltp_version=invalid
2739       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2740       for ltp_check_version in $ltp_version_list; do
2741         if test "$ltp_version" = "$ltp_check_version"; then
2742           glib_cv_ltp_version="$ltp_check_version (ok)"
2743         fi
2744       done
2745     ])
2746   ], [
2747     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2748     AC_MSG_ERROR([$ltp_msg])
2749   ])
2750
2751   case $glib_cv_ltp_version in
2752     ""|invalid[)]
2753       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2754       AC_MSG_ERROR([$ltp_msg])
2755       LTP="exit 0;"
2756       ;;
2757   esac
2758
2759   if test -z "$LTP_GENHTML"; then
2760     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2761   fi
2762
2763   dnl Remove all optimization flags from CFLAGS
2764   changequote({,})
2765   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2766   changequote([,])
2767
2768   dnl Add the special gcc flags
2769   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2770   LDFLAGS="$LDFLAGS -lgcov"
2771 ])
2772
2773 dnl ******************************
2774 dnl *** output the whole stuff ***
2775 dnl ******************************
2776
2777 dnl this section will only be run if config.status is invoked with no
2778 dnl arguments, or with "glib/glibconfig.h" as an argument.
2779 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2780 [
2781         outfile=glib/glibconfig.h-tmp
2782         cat > $outfile <<\_______EOF
2783 /* glibconfig.h
2784  *
2785  * This is a generated file.  Please modify 'configure.ac'
2786  */
2787
2788 #ifndef __GLIBCONFIG_H__
2789 #define __GLIBCONFIG_H__
2790
2791 #include <glib/gmacros.h>
2792
2793 _______EOF
2794
2795         echo '#include <limits.h>' >> $outfile
2796         echo '#include <float.h>' >> $outfile
2797         if test x$glib_values_h = xyes; then
2798           echo '#include <values.h>' >> $outfile
2799         fi
2800         if test "$glib_header_alloca_h" = "yes"; then
2801           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2802         fi
2803         if test x$glib_included_printf != xyes; then
2804           echo "
2805 /* Specifies that GLib's g_print*() functions wrap the
2806  * system printf functions.  This is useful to know, for example,
2807  * when using glibc's register_printf_function().
2808  */" >> $outfile
2809           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2810         fi
2811
2812         cat >> $outfile <<_______EOF
2813
2814 G_BEGIN_DECLS
2815
2816 #define G_MINFLOAT      FLT_MIN
2817 #define G_MAXFLOAT      FLT_MAX
2818 #define G_MINDOUBLE     DBL_MIN
2819 #define G_MAXDOUBLE     DBL_MAX
2820 #define G_MINSHORT      SHRT_MIN
2821 #define G_MAXSHORT      SHRT_MAX
2822 #define G_MAXUSHORT     USHRT_MAX
2823 #define G_MININT        INT_MIN
2824 #define G_MAXINT        INT_MAX
2825 #define G_MAXUINT       UINT_MAX
2826 #define G_MINLONG       LONG_MIN
2827 #define G_MAXLONG       LONG_MAX
2828 #define G_MAXULONG      ULONG_MAX
2829
2830 _______EOF
2831
2832
2833         ### this should always be true in a modern C/C++ compiler
2834         cat >>$outfile <<_______EOF
2835 typedef signed char gint8;
2836 typedef unsigned char guint8;
2837 _______EOF
2838
2839
2840         if test -n "$gint16"; then
2841           cat >>$outfile <<_______EOF
2842 typedef signed $gint16 gint16;
2843 typedef unsigned $gint16 guint16;
2844 #define G_GINT16_MODIFIER $gint16_modifier
2845 #define G_GINT16_FORMAT $gint16_format
2846 #define G_GUINT16_FORMAT $guint16_format
2847 _______EOF
2848         fi
2849
2850
2851         if test -n "$gint32"; then
2852           cat >>$outfile <<_______EOF
2853 typedef signed $gint32 gint32;
2854 typedef unsigned $gint32 guint32;
2855 #define G_GINT32_MODIFIER $gint32_modifier
2856 #define G_GINT32_FORMAT $gint32_format
2857 #define G_GUINT32_FORMAT $guint32_format
2858 _______EOF
2859         fi
2860
2861         cat >>$outfile <<_______EOF
2862 #define G_HAVE_GINT64 1          /* deprecated, always true */
2863
2864 ${glib_extension}typedef signed $gint64 gint64;
2865 ${glib_extension}typedef unsigned $gint64 guint64;
2866
2867 #define G_GINT64_CONSTANT(val)  $gint64_constant
2868 #define G_GUINT64_CONSTANT(val) $guint64_constant
2869 _______EOF
2870
2871         if test x$gint64_format != x ; then
2872           cat >>$outfile <<_______EOF
2873 #define G_GINT64_MODIFIER $gint64_modifier
2874 #define G_GINT64_FORMAT $gint64_format
2875 #define G_GUINT64_FORMAT $guint64_format
2876 _______EOF
2877         else
2878           cat >>$outfile <<_______EOF
2879 #undef G_GINT64_MODIFIER
2880 #undef G_GINT64_FORMAT
2881 #undef G_GUINT64_FORMAT
2882 _______EOF
2883         fi
2884
2885         cat >>$outfile <<_______EOF
2886
2887 #define GLIB_SIZEOF_VOID_P $glib_void_p
2888 #define GLIB_SIZEOF_LONG   $glib_long
2889 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2890 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2891
2892 _______EOF
2893
2894         cat >>$outfile <<_______EOF
2895 typedef signed $glib_ssize_type_define gssize;
2896 typedef unsigned $glib_size_type_define gsize;
2897 #define G_GSIZE_MODIFIER $gsize_modifier
2898 #define G_GSSIZE_MODIFIER $gssize_modifier
2899 #define G_GSIZE_FORMAT $gsize_format
2900 #define G_GSSIZE_FORMAT $gssize_format
2901
2902 #define G_MAXSIZE       G_MAXU$glib_msize_type
2903 #define G_MINSSIZE      G_MIN$glib_mssize_type
2904 #define G_MAXSSIZE      G_MAX$glib_mssize_type
2905
2906 typedef gint64 goffset;
2907 #define G_MINOFFSET     G_MININT64
2908 #define G_MAXOFFSET     G_MAXINT64
2909
2910 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2911 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2912 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2913
2914 _______EOF
2915
2916         if test -z "$glib_unknown_void_p"; then
2917           cat >>$outfile <<_______EOF
2918
2919 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2920 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2921
2922 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2923 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2924
2925 typedef signed $glib_intptr_type_define gintptr;
2926 typedef unsigned $glib_intptr_type_define guintptr;
2927
2928 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2929 #define G_GINTPTR_FORMAT        $gintptr_format
2930 #define G_GUINTPTR_FORMAT       $guintptr_format
2931 _______EOF
2932         else
2933           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2934         fi
2935
2936
2937
2938         cat >>$outfile <<_______EOF
2939 #ifndef G_DISABLE_DEPRECATED
2940 #define g_ATEXIT(proc)  (atexit (proc))
2941 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2942 #endif
2943 $glib_defines
2944 $glib_os
2945 $glib_static_compilation
2946
2947 $glib_vacopy
2948
2949 #ifdef  __cplusplus
2950 #define G_HAVE_INLINE   1
2951 #else   /* !__cplusplus */
2952 $glib_inline
2953 #endif  /* !__cplusplus */
2954
2955 #ifdef  __cplusplus
2956 #define G_CAN_INLINE    1
2957 _______EOF
2958
2959         if test x$g_can_inline = xyes ; then
2960                 cat >>$outfile <<_______EOF
2961 #else   /* !__cplusplus */
2962 #define G_CAN_INLINE    1
2963 _______EOF
2964         fi
2965
2966         cat >>$outfile <<_______EOF
2967 #endif
2968
2969 _______EOF
2970
2971         if test x$g_have_iso_c_varargs = xyes ; then
2972                 cat >>$outfile <<_______EOF
2973 #ifndef __cplusplus
2974 # define G_HAVE_ISO_VARARGS 1
2975 #endif
2976 _______EOF
2977         fi
2978         if test x$g_have_iso_cxx_varargs = xyes ; then
2979                 cat >>$outfile <<_______EOF
2980 #ifdef __cplusplus
2981 # define G_HAVE_ISO_VARARGS 1
2982 #endif
2983 _______EOF
2984         fi
2985         if test x$g_have_gnuc_varargs = xyes ; then
2986                 cat >>$outfile <<_______EOF
2987
2988 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2989  * is passed ISO vararg support is turned off, and there is no work
2990  * around to turn it on, so we unconditionally turn it off.
2991  */
2992 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2993 #  undef G_HAVE_ISO_VARARGS
2994 #endif
2995
2996 #define G_HAVE_GNUC_VARARGS 1
2997 _______EOF
2998         fi
2999
3000         case x$g_stack_grows in
3001         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3002         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3003         esac
3004
3005
3006         echo >>$outfile
3007         if test x$g_have_eilseq = xno; then
3008                 cat >>$outfile <<_______EOF
3009 #ifndef EILSEQ
3010 /* On some pre-C99 systems, EILSEQ is not defined.
3011  * The correspondence between this and the corresponding definition
3012  * in libiconv is essential.
3013  */
3014 #  define EILSEQ ENOENT
3015 #endif
3016 _______EOF
3017
3018         fi
3019
3020         if test x$g_have_gnuc_visibility = xyes; then
3021                 cat >>$outfile <<_______EOF
3022 #define G_HAVE_GNUC_VISIBILITY 1
3023 _______EOF
3024         fi
3025                 cat >>$outfile <<_______EOF
3026 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3027 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3028 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3029 #define G_GNUC_INTERNAL __hidden
3030 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3031 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3032 #else
3033 #define G_GNUC_INTERNAL
3034 #endif
3035 _______EOF
3036
3037         echo >>$outfile
3038         cat >>$outfile <<_______EOF
3039 #define G_THREADS_ENABLED
3040 #define G_THREADS_IMPL_$g_threads_impl_def
3041 _______EOF
3042
3043         if test x"$g_memory_barrier_needed" != xno; then
3044           echo >>$outfile
3045           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3046         fi
3047         if test x"$g_atomic_lock_free" = xyes; then
3048           echo >>$outfile
3049           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3050         fi
3051         echo >>$outfile
3052         g_bit_sizes="16 32 64"
3053         for bits in $g_bit_sizes; do
3054           cat >>$outfile <<_______EOF
3055 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3056 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3057 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3058 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3059 _______EOF
3060         done
3061
3062         cat >>$outfile <<_______EOF
3063 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3064 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3065 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3066 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3067 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3068 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3069 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3070 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3071 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3072 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3073 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3074 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3075 #define G_BYTE_ORDER $g_byte_order
3076
3077 #define GLIB_SYSDEF_POLLIN =$g_pollin
3078 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3079 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3080 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3081 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3082 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3083
3084 #define G_MODULE_SUFFIX "$g_module_suffix"
3085
3086 typedef $g_pid_type GPid;
3087
3088 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3089 #define GLIB_SYSDEF_AF_INET $g_af_inet
3090 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3091
3092 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3093 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3094 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3095
3096 G_END_DECLS
3097
3098 #endif /* __GLIBCONFIG_H__ */
3099 _______EOF
3100
3101
3102         if cmp -s $outfile glib/glibconfig.h; then
3103           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3104           rm -f $outfile
3105         else
3106           mv $outfile glib/glibconfig.h
3107         fi
3108 ],[
3109
3110 # Note that if two cases are the same, case goes with the first one.
3111 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3112 # on variable expansion in case labels.  Look at the generated config.status
3113 # for a hint.
3114
3115 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3116   glib_header_alloca_h="$ac_cv_working_alloca_h"
3117 else
3118   glib_header_alloca_h="$ac_cv_header_alloca_h"
3119 fi
3120
3121 if test x$enable_included_printf = xyes ; then
3122   glib_included_printf=yes
3123 fi
3124
3125 case 2 in
3126 $ac_cv_sizeof_short)
3127   gint16=short
3128   gint16_modifier='"h"'
3129   gint16_format='"hi"'
3130   guint16_format='"hu"'
3131   ;;
3132 $ac_cv_sizeof_int)
3133   gint16=int
3134   gint16_modifier='""'
3135   gint16_format='"i"'
3136   guint16_format='"u"'
3137   ;;
3138 esac
3139 case 4 in
3140 $ac_cv_sizeof_short)
3141   gint32=short
3142   gint32_modifier='"h"'
3143   gint32_format='"hi"'
3144   guint32_format='"hu"'
3145   ;;
3146 $ac_cv_sizeof_int)
3147   gint32=int
3148   gint32_modifier='""'
3149   gint32_format='"i"'
3150   guint32_format='"u"'
3151   ;;
3152 $ac_cv_sizeof_long)
3153   gint32=long
3154   gint32_modifier='"l"'
3155   gint32_format='"li"'
3156   guint32_format='"lu"'
3157   ;;
3158 esac
3159 case 8 in
3160 $ac_cv_sizeof_int)
3161   gint64=int
3162   gint64_modifier='""'
3163   gint64_format='"i"'
3164   guint64_format='"u"'
3165   glib_extension=
3166   gint64_constant='(val)'
3167   guint64_constant='(val)'
3168   ;;
3169 $ac_cv_sizeof_long)
3170   gint64=long
3171   gint64_modifier='"l"'
3172   gint64_format='"li"'
3173   guint64_format='"lu"'
3174   glib_extension=
3175   gint64_constant='(val##L)'
3176   guint64_constant='(val##UL)'
3177   ;;
3178 $ac_cv_sizeof_long_long)
3179   gint64='long long'
3180   if test -n "$glib_cv_long_long_format"; then
3181     gint64_modifier='"'$glib_cv_long_long_format'"'
3182     gint64_format='"'$glib_cv_long_long_format'i"'
3183     guint64_format='"'$glib_cv_long_long_format'u"'
3184   fi
3185   glib_extension='G_GNUC_EXTENSION '
3186   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3187   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3188   ;;
3189 $ac_cv_sizeof___int64)
3190   gint64='__int64'
3191   if test -n "$glib_cv_long_long_format"; then
3192     gint64_modifier='"'$glib_cv_long_long_format'"'
3193     gint64_format='"'$glib_cv_long_long_format'i"'
3194     guint64_format='"'$glib_cv_long_long_format'u"'
3195   fi
3196   glib_extension=
3197   gint64_constant='(val##i64)'
3198   guint64_constant='(val##ui64)'
3199   ;;
3200 esac
3201 glib_size_t=$ac_cv_sizeof_size_t
3202 glib_ssize_t=$ac_cv_sizeof_ssize_t
3203 glib_size_type_define="$glib_size_type"
3204 glib_ssize_type_define="$glib_ssize_type"
3205 glib_void_p=$ac_cv_sizeof_void_p
3206 glib_long=$ac_cv_sizeof_long
3207
3208 case "$glib_size_type" in
3209 short)
3210   gsize_modifier='"h"'
3211   gsize_format='"hu"'
3212   glib_msize_type='SHRT'
3213   ;;
3214 int)
3215   gsize_modifier='""'
3216   gsize_format='"u"'
3217   glib_msize_type='INT'
3218   ;;
3219 long)
3220   gsize_modifier='"l"'
3221   gsize_format='"lu"'
3222   glib_msize_type='LONG'
3223   ;;
3224 "long long"|__int64)
3225   gsize_modifier='"I64"'
3226   gsize_format='"I64u"'
3227   glib_msize_type='INT64'
3228   ;;
3229 esac
3230
3231 case "$glib_ssize_type" in
3232 short)
3233   gssize_modifier='"h"'
3234   gssize_format='"hi"'
3235   glib_mssize_type='SHRT'
3236   ;;
3237 int)
3238   gssize_modifier='""'
3239   gssize_format='"i"'
3240   glib_mssize_type='INT'
3241   ;;
3242 long)
3243   gssize_modifier='"l"'
3244   gssize_format='"li"'
3245   glib_mssize_type='LONG'
3246   ;;
3247 "long long"|__int64)
3248   gssize_modifier='"I64"'
3249   gssize_format='"I64i"'
3250   glib_mssize_type='INT64'
3251   ;;
3252 esac
3253
3254 gintbits=`expr $ac_cv_sizeof_int \* 8`
3255 glongbits=`expr $ac_cv_sizeof_long \* 8`
3256 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3257 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3258
3259 case $ac_cv_sizeof_void_p in
3260 $ac_cv_sizeof_int)
3261   glib_intptr_type_define=int
3262   gintptr_modifier='""'
3263   gintptr_format='"i"'
3264   guintptr_format='"u"'
3265   glib_gpi_cast='(gint)'
3266   glib_gpui_cast='(guint)'
3267   ;;
3268 $ac_cv_sizeof_long)
3269   glib_intptr_type_define=long
3270   gintptr_modifier='"l"'
3271   gintptr_format='"li"'
3272   guintptr_format='"lu"'
3273   glib_gpi_cast='(glong)'
3274   glib_gpui_cast='(gulong)'
3275   ;;
3276 $ac_cv_sizeof_long_long)
3277   glib_intptr_type_define='long long'
3278   gintptr_modifier='"I64"'
3279   gintptr_format='"I64i"'
3280   guintptr_format='"I64u"'
3281   glib_gpi_cast='(gint64)'
3282   glib_gpui_cast='(guint64)'
3283   ;;
3284 $ac_cv_sizeof___int64)
3285   glib_intptr_type_define=__int64
3286   gintptr_modifier='"I64"'
3287   gintptr_format='"I64i"'
3288   guintptr_format='"I64u"'
3289   glib_gpi_cast='(gint64)'
3290   glib_gpui_cast='(guint64)'
3291   ;;
3292 *)
3293   glib_unknown_void_p=yes
3294   ;;
3295 esac
3296
3297
3298 glib_defines="
3299 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3300 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3301 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3302 "
3303
3304 case xyes in
3305 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3306 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3307 *)                      glib_vacopy=''
3308 esac
3309
3310 if test x$glib_cv_va_val_copy = xno; then
3311   glib_vacopy="\$glib_vacopy
3312 #define G_VA_COPY_AS_ARRAY 1"
3313 fi
3314
3315 if test x$glib_cv_hasinline = xyes; then
3316     glib_inline='#define G_HAVE_INLINE 1'
3317 fi
3318 if test x$glib_cv_has__inline = xyes; then
3319     glib_inline="\$glib_inline
3320 #define G_HAVE___INLINE 1"
3321 fi
3322 if test x$glib_cv_has__inline__ = xyes; then
3323     glib_inline="\$glib_inline
3324 #define G_HAVE___INLINE__ 1"
3325 fi
3326
3327 g_have_gnuc_varargs=$g_have_gnuc_varargs
3328 g_have_iso_c_varargs=$g_have_iso_c_varargs
3329 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3330
3331 g_can_inline=$g_can_inline
3332 g_have_gnuc_visibility=$g_have_gnuc_visibility
3333 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3334
3335 if test x$ac_cv_c_bigendian = xyes; then
3336   g_byte_order=G_BIG_ENDIAN
3337   g_bs_native=BE
3338   g_bs_alien=LE
3339 else
3340   g_byte_order=G_LITTLE_ENDIAN
3341   g_bs_native=LE
3342   g_bs_alien=BE
3343 fi
3344
3345 g_pollin=$glib_cv_value_POLLIN
3346 g_pollout=$glib_cv_value_POLLOUT
3347 g_pollpri=$glib_cv_value_POLLPRI
3348 g_pollhup=$glib_cv_value_POLLHUP
3349 g_pollerr=$glib_cv_value_POLLERR
3350 g_pollnval=$glib_cv_value_POLLNVAL
3351
3352 # If a family is not found on the system, define that family to
3353 # a negative value, picking a different one for each undefined
3354 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3355 # This is needed because glib-mkenums doesn't handle optional
3356 # values in enums, and thus we have to have all existing values
3357 # defined in the enum.
3358 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3359   g_af_unix=$glib_cv_value_AF_UNIX
3360 else
3361   g_af_unix=-1
3362 fi
3363 g_af_inet=$glib_cv_value_AF_INET
3364 g_af_inet6=$glib_cv_value_AF_INET6
3365
3366 g_msg_peek=$glib_cv_value_MSG_PEEK
3367 g_msg_oob=$glib_cv_value_MSG_OOB
3368 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3369
3370 g_stack_grows=$glib_cv_stack_grows
3371
3372 g_have_eilseq=$have_eilseq
3373
3374 g_threads_impl_def=$g_threads_impl
3375
3376 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3377 g_memory_barrier_needed="$glib_memory_barrier_needed"
3378 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3379
3380 g_module_suffix="$glib_gmodule_suffix"
3381
3382 g_pid_type="$glib_pid_type"
3383 case $host in
3384   *-*-cygwin*)
3385     glib_os="#define G_OS_UNIX
3386 #define G_PLATFORM_WIN32
3387 #define G_WITH_CYGWIN"
3388     ;;
3389   *-*-mingw*)
3390     glib_os="#define G_OS_WIN32
3391 #define G_PLATFORM_WIN32"
3392     ;;
3393   *)
3394     glib_os="#define G_OS_UNIX"
3395     ;;
3396 esac
3397 glib_static_compilation=""
3398 if test x$glib_win32_static_compilation = xyes; then
3399   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3400 #define GOBJECT_STATIC_COMPILATION 1"
3401 fi
3402 ])
3403
3404 # Redo enough to get guint32 and guint64 for the alignment checks below
3405 case 4 in
3406 $ac_cv_sizeof_short)
3407   gint32=short
3408   ;;
3409 $ac_cv_sizeof_int)
3410   gint32=int
3411   ;;
3412 $ac_cv_sizeof_long)
3413   gint32=long
3414   ;;
3415 esac
3416 case 8 in
3417 $ac_cv_sizeof_int)
3418   gint64=int
3419   ;;
3420 $ac_cv_sizeof_long)
3421   gint64=long
3422   ;;
3423 $ac_cv_sizeof_long_long)
3424   gint64='long long'
3425   ;;
3426 $ac_cv_sizeof___int64)
3427   gint64='__int64'
3428   ;;
3429 esac
3430
3431 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3432 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3433 typedef unsigned $gint32 guint32;])
3434 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3435 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3436 typedef unsigned $gint64 guint64;])
3437 AC_CHECK_TYPE([unsigned long])
3438 AC_CHECK_ALIGNOF([unsigned long])
3439
3440 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3441 #
3442 # 1.2.14 required for dbus_message_set_serial
3443 PKG_CHECK_MODULES(DBUS1,
3444      dbus-1 >= 1.2.14,
3445      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3446      have_dbus1=no)
3447 AC_SUBST(DBUS1_CFLAGS)
3448 AC_SUBST(DBUS1_LIBS)
3449 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3450
3451 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3452 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3453
3454 dnl
3455 dnl Check for -Bsymbolic-functions linker flag used to avoid
3456 dnl intra-library PLT jumps, if available.
3457 dnl
3458
3459 AC_ARG_ENABLE(Bsymbolic,
3460               [AS_HELP_STRING([--disable-Bsymbolic],
3461                               [avoid linking with -Bsymbolic])],,
3462               [SAVED_LDFLAGS="${LDFLAGS}"
3463                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3464                LDFLAGS=-Wl,-Bsymbolic-functions
3465                AC_TRY_LINK([], [int main (void) { return 0; }],
3466                            AC_MSG_RESULT(yes)
3467                            enable_Bsymbolic=yes,
3468                            AC_MSG_RESULT(no)
3469                            enable_Bsymbolic=no)
3470                LDFLAGS="${SAVED_LDFLAGS}"])
3471
3472 if test "x${enable_Bsymbolic}" = "xyes"; then
3473   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3474 fi
3475
3476 AC_SUBST(GLIB_LINK_FLAGS)
3477
3478 dnl
3479 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3480 dnl visibility attributes for symbol export control
3481 dnl
3482 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3483 case "$host" in
3484   *-*-mingw*)
3485     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3486     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3487               [defines how to decorate public symbols while building])
3488     CFLAGS="${CFLAGS} -fvisibility=hidden"
3489     ;;
3490   *)
3491     dnl on other compilers, check if we can do -fvisibility=hidden
3492     SAVED_CFLAGS="${CFLAGS}"
3493     CFLAGS="-fvisibility=hidden"
3494     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3495     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3496                    AC_MSG_RESULT(yes)
3497                    enable_fvisibility_hidden=yes,
3498                    AC_MSG_RESULT(no)
3499                    enable_fvisibility_hidden=no)
3500     CFLAGS="${SAVED_CFLAGS}"
3501
3502     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3503       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3504                 [defines how to decorate public symbols while building])
3505       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3506     ])
3507     ;;
3508 esac
3509 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3510
3511 dnl Compiler flags; macro originates from systemd
3512 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3513 AC_ARG_ENABLE(compile-warnings,
3514               [AS_HELP_STRING([--disable-compile-warnings],
3515                               [Don't use builtin compiler warnings])],,
3516                               enable_compile_warnings=yes)
3517 AS_IF([test "x$enable_compile_warnings" = xyes], [
3518   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3519    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3520    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3521    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3522    -Werror=format=2 -Werror=missing-include-dirs])
3523 ])
3524 AC_SUBST(GLIB_WARN_CFLAGS)
3525
3526 #
3527 # Define variables corresponding to the correct include paths to use for
3528 # in-tree building.
3529 #
3530
3531 # for config.h:
3532 config_h_INCLUDES='-I$(top_builddir)'
3533 AC_SUBST(config_h_INCLUDES)
3534
3535 # glib:
3536 #   config.h
3537 #   $(top_builddir)/glib: for glibconfig.h
3538 #   $(top_srcdir)/glib:   for glib.h
3539 #   $(top_srcdir):        for everything
3540 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3541 AC_SUBST(glib_INCLUDES)
3542
3543 # gobject:
3544 #   same as glib
3545 gobject_INCLUDES='$(glib_INCLUDES)'
3546 AC_SUBST(gobject_INCLUDES)
3547
3548 # gmodule:
3549 #   glib includes
3550 #   $(top_srcdir)/gmodule: for gmodule.h
3551 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3552 AC_SUBST(gmodule_INCLUDES)
3553
3554 # gio:
3555 #   same as gmodule
3556 gio_INCLUDES='$(gmodule_INCLUDES)'
3557 AC_SUBST(gio_INCLUDES)
3558
3559
3560 AC_CONFIG_FILES([
3561 glib-2.0.pc
3562 gmodule-2.0.pc
3563 gmodule-export-2.0.pc
3564 gmodule-no-export-2.0.pc
3565 gthread-2.0.pc
3566 gobject-2.0.pc
3567 gio-2.0.pc
3568 gio-unix-2.0.pc
3569 gio-windows-2.0.pc
3570 glib-zip
3571 glib-gettextize
3572 Makefile
3573 build/Makefile
3574 build/win32/Makefile
3575 build/win32/dirent/Makefile
3576 build/win32/vs9/Makefile
3577 build/win32/vs10/Makefile
3578 build/win32/vs11/Makefile
3579 glib/Makefile
3580 glib/glib.stp
3581 glib/libcharset/Makefile
3582 glib/gnulib/Makefile
3583 glib/pcre/Makefile
3584 glib/update-pcre/Makefile
3585 glib/tests/Makefile
3586 gmodule/Makefile
3587 gmodule/gmoduleconf.h
3588 gobject/Makefile
3589 gobject/gobject.stp
3590 gobject/glib-mkenums
3591 gobject/tests/Makefile
3592 gthread/Makefile
3593 gio/Makefile
3594 gio/gdbus-2.0/codegen/Makefile
3595 gio/gdbus-2.0/codegen/config.py
3596 gio/gnetworking.h
3597 gio/xdgmime/Makefile
3598 gio/inotify/Makefile
3599 gio/kqueue/Makefile
3600 gio/fen/Makefile
3601 gio/fam/Makefile
3602 gio/win32/Makefile
3603 gio/tests/Makefile
3604 gio/tests/gdbus-object-manager-example/Makefile
3605 gio/tests/services/Makefile
3606 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3607 gio/tests/modules/Makefile
3608 po/Makefile.in
3609 docs/Makefile
3610 docs/reference/Makefile
3611 docs/reference/glib/Makefile
3612 docs/reference/glib/version.xml
3613 docs/reference/gobject/Makefile
3614 docs/reference/gobject/version.xml
3615 docs/reference/gio/Makefile
3616 docs/reference/gio/gdbus-object-manager-example/Makefile
3617 docs/reference/gio/version.xml
3618 tests/Makefile
3619 tests/gobject/Makefile
3620 tests/refcount/Makefile
3621 m4macros/Makefile
3622 ])
3623
3624 AC_CONFIG_COMMANDS([chmod-scripts],
3625 [chmod 0755 glib-zip
3626 chmod 0755 glib-gettextize
3627 chmod 0755 gobject/glib-mkenums])
3628
3629 # we want to invoke this macro solely so that the config.status script
3630 # and automake generated makefiles know about these generated files.
3631 # They are only needed to distcheck the package
3632 if false; then
3633   AC_CONFIG_FILES([
3634     INSTALL
3635     README
3636     config.h.win32
3637     glib/glibconfig.h.win32
3638     glib/makefile.msc
3639     glib/glib.rc
3640     gmodule/makefile.msc
3641     gmodule/gmodule.rc
3642     gobject/makefile.msc
3643     gobject/gobject.rc
3644     gthread/makefile.msc
3645     gthread/gthread.rc
3646     gio/gio.rc
3647     tests/makefile.msc
3648   ])
3649 fi
3650
3651 AC_OUTPUT