configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [3])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286
 287   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 288 else
 289   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 290
 291   if test "x$enable_debug" = "xno"; then
 292     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 293   fi
 294 fi
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$glib_native_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 331 AC_SUBST(GLIB_EXTRA_CFLAGS)
 332
 333 AC_EXEEXT
 334
 335 # define a MAINT-like variable REBUILD which is set if Perl
 336 # and awk are found, so autogenerated sources can be rebuilt
 337 AC_PROG_AWK
 338 AC_CHECK_PROGS(PERL, [perl5 perl])
 339 # We would like indent, but don't require it.
 340 AC_CHECK_PROG(INDENT, indent, indent)
 341 REBUILD=\#
 342 if test "x$enable_rebuilds" = "xyes" && \
 343      test -n "$PERL" && \
 344      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 345      test -n "$AWK" ; then
 346   REBUILD=
 347 fi
 348 AC_SUBST(REBUILD)
 349
 350 # Need full path to Perl for glib-mkenums
 351 #
 352 if test "x$PERL" != x ; then
 353   AC_PATH_PROG(PERL_PATH, [$PERL])
 354 fi
 355 if test "x$PERL_PATH" = x ; then
 356   PERL_PATH="/usr/bin/env perl"
 357 fi
 358 AC_SUBST(PERL_PATH)
 359
 360 # Need suitable python path for greport
 361 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 362
 363
 364 dnl ***********************
 365 dnl *** Tests for iconv ***
 366 dnl ***********************
 367 dnl
 368 dnl We do this before the gettext checks, to avoid distortion
 369
 370 dnl On Windows we use a native implementation
 371
 372 if test x"$glib_native_win32" = xyes; then
 373   with_libiconv=native
 374 else
 375   AC_ARG_WITH(libiconv,
 376               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 377                               [use the libiconv library])],,
 378               [with_libiconv=maybe])
 379
 380   found_iconv=no
 381   case $with_libiconv in
 382     maybe)
 383       # Check in the C library first
 384       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385       # Check if we have GNU libiconv
 386       if test $found_iconv = "no"; then
 387         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388       fi
 389       # Check if we have a iconv in -liconv, possibly from vendor
 390       if test $found_iconv = "no"; then
 391         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 392       fi
 393       ;;
 394     no)
 395       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 396       ;;
 397     gnu|yes)
 398       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 399       ;;
 400     native)
 401       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 402       ;;
 403   esac
 404
 405   if test "x$found_iconv" = "xno" ; then
 406      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 407   fi
 408 fi
 409
 410 AC_ARG_ENABLE(iconv-cache,
 411               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 412                               [cache iconv descriptors [default=auto]])],,
 413               [enable_iconv_cache=auto])
 414
 415 AC_MSG_CHECKING([whether to cache iconv descriptors])
 416 case $enable_iconv_cache in
 417   auto)
 418     if test $ac_cv_gnu_library_2_1 = yes; then
 419       enable_iconv_cache=no
 420     else
 421       enable_iconv_cache=yes
 422     fi
 423   ;;
 424   yes|no)
 425   ;;
 426   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 427   ;;
 428 esac
 429
 430 if test $enable_iconv_cache = yes; then
 431    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 432 fi
 433
 434 AC_MSG_RESULT($enable_iconv_cache)
 435
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 if test "x$found_zlib" = "xno" ; then
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 fi
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 if test x"$glib_native_win32" != xyes; then
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 fi
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 if test "x$GCC" = "xyes"; then
 509   case " $CFLAGS " in
 510   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 511   *) CFLAGS="$CFLAGS -Wall" ;;
 512   esac
 513 fi
 514
 515 if test "$glib_native_win32" = "yes"; then
 516   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 517     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 518   fi
 519   if test x$enable_static = xyes; then
 520     glib_win32_static_compilation=yes
 521     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 522 #define GOBJECT_STATIC_COMPILATION 1"
 523     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 524   fi
 525 fi
 526 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 527
 528 dnl
 529 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 530 dnl
 531 if test $cross_compiling != yes ; then
 532     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 533     glib_save_LIBS=$LIBS
 534     LIBS="$LIBS -lm"
 535     AC_TRY_RUN([#include <math.h>
 536                  int main (void) { return (log(1) != log(1.)); }],
 537          AC_MSG_RESULT(none needed),
 538          glib_save_CFLAGS=$CFLAGS
 539          CFLAGS="$CFLAGS -std1"
 540          AC_TRY_RUN([#include <math.h>
 541                      int main (void) { return (log(1) != log(1.)); }],
 542              AC_MSG_RESULT(-std1),
 543              AC_MSG_RESULT()
 544              CFLAGS=$glib_save_CFLAGS
 545              AC_MSG_WARN(
 546                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 547          )
 548     )
 549     LIBS=$glib_save_LIBS
 550 fi
 551
 552 dnl NeXTStep cc seems to need this
 553 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 554 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 555   AC_MSG_RESULT(none needed),
 556   glib_save_CFLAGS=$CFLAGS
 557   CFLAGS="$CFLAGS -posix"
 558   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 559     AC_MSG_RESULT(-posix),
 560     AC_MSG_RESULT()
 561     CFLAGS=$glib_save_CFLAGS
 562     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 563
 564 # Checks for header files.
 565 AC_HEADER_STDC
 566
 567 # Checks for library functions.
 568 AC_FUNC_VPRINTF
 569 AC_FUNC_ALLOCA
 570 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 571 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 572
 573 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 574 dnl be automatically defined, which we don't want to do
 575 dnl until we have checked this function is actually usable
 576 AC_CHECK_FUNC([qsort_r])
 577
 578 # BSD has a qsort_r with wrong argument order
 579 if test x$ac_cv_func_qsort_r = xyes ; then
 580   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 581   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 582   #define _GNU_SOURCE
 583   #include <stdlib.h>
 584
 585   static int
 586   cmp (const void *a, const void *b, void *c)
 587   {
 588     const int *ia = a;
 589     const int *ib = b;
 590
 591     if (*ia < *ib)
 592       return -1;
 593     else if (*ia > *ib)
 594       return 1;
 595     else
 596       return 0;
 597   }
 598
 599   int
 600   main (int argc, char **argv)
 601   {
 602     int arr[3] = { 1, 2, 0 };
 603     int d = 3;
 604
 605     qsort_r (arr, 3, sizeof (int), cmp, &d);
 606
 607     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 608       return 0;
 609     else
 610       return 1;
 611   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 612 fi
 613
 614 if test x$glib_cv_have_qsort_r = xyes ; then
 615   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 616 fi
 617
 618 AC_CHECK_SIZEOF(char)
 619 AC_CHECK_SIZEOF(short)
 620 AC_CHECK_SIZEOF(long)
 621 AC_CHECK_SIZEOF(int)
 622 AC_CHECK_SIZEOF(void *)
 623 AC_CHECK_SIZEOF(long long)
 624 AC_CHECK_SIZEOF(__int64)
 625
 626 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 627   :
 628 else
 629   AC_MSG_ERROR([
 630 *** GLib requires a 64 bit type. You might want to consider
 631 *** using the GNU C compiler.
 632 ])
 633 fi
 634
 635 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 636         # long long is a 64 bit integer.
 637         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 638         AC_CACHE_VAL(glib_cv_long_long_format,[
 639                 for format in ll q I64; do
 640                   AC_TRY_RUN([#include <stdio.h>
 641                         int main()
 642                         {
 643                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 644                           char buffer[1000];
 645                           sprintf (buffer, "%${format}u", a);
 646                           sscanf (buffer, "%${format}u", &b);
 647                           exit (b!=a);
 648                         }
 649                         ],
 650                         [glib_cv_long_long_format=${format}
 651                         break],
 652                         [],[:])
 653                 done])
 654         if test -n "$glib_cv_long_long_format"; then
 655           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 656           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 657           if test x"$glib_cv_long_long_format" = xI64; then
 658             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 659           fi
 660         else
 661           AC_MSG_RESULT(none)
 662         fi
 663 elif test x$ac_cv_sizeof___int64 = x8; then
 664         # __int64 is a 64 bit integer.
 665         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 666         # We know this is MSVCRT.DLL, and what the formats are
 667         glib_cv_long_long_format=I64
 668         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 669         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 670         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 671 fi
 672
 673 dnl long doubles were not used, and a portability problem
 674 dnl AC_C_LONG_DOUBLE
 675 AC_C_CONST
 676
 677 dnl ok, here we try to check whether the systems prototypes for
 678 dnl malloc and friends actually match the prototypes provided
 679 dnl by gmem.h (keep in sync). i currently only know how to check
 680 dnl this reliably with gcc (-Werror), improvements for other
 681 dnl compilers are apprechiated.
 682 SANE_MALLOC_PROTOS=no
 683 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 684 glib_save_CFLAGS=$CFLAGS
 685 if test "x$GCC" = "xyes"; then
 686   CFLAGS="$CFLAGS -Werror"
 687   AC_TRY_COMPILE([#include <stdlib.h>], [
 688     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 689     void* (*my_malloc_p)  (size_t)         = malloc;
 690     void  (*my_free_p)    (void*)          = free;
 691     void* (*my_realloc_p) (void*, size_t)  = realloc;
 692     my_calloc_p = 0;
 693     my_malloc_p = 0;
 694     my_free_p = 0;
 695     my_realloc_p = 0;
 696   ],
 697     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 698       [Define if you have correct malloc prototypes])
 699     SANE_MALLOC_PROTOS=yes)
 700 fi
 701 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 702 CFLAGS=$glib_save_CFLAGS
 703
 704 dnl
 705 dnl check in which direction the stack grows
 706 dnl
 707 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 708         AC_TRY_RUN([
 709         volatile int *a = 0, *b = 0;
 710         void foo (void);
 711         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 712         void foo (void) { volatile int x = 5; b = &x; }
 713         ],
 714         glib_cv_stack_grows=no
 715         ,
 716         glib_cv_stack_grows=yes
 717         ,)
 718 ])
 719
 720 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 721 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 722 dnl actually supported.
 723 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 724         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 725         __inline int foo () { return 0; }
 726         int main () { return foo (); }
 727         ]])],
 728         glib_cv_has__inline=yes
 729         ,
 730         glib_cv_has__inline=no
 731         ,)
 732 ])
 733 case x$glib_cv_has__inline in
 734 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 735 esac
 736 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 737         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 738         __inline__ int foo () { return 0; }
 739         int main () { return foo (); }
 740         ]])],
 741         glib_cv_has__inline__=yes
 742         ,
 743         glib_cv_has__inline__=no
 744         ,)
 745 ])
 746 case x$glib_cv_has__inline__ in
 747 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 748 esac
 749 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 750         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 751         #undef inline
 752         inline int foo () { return 0; }
 753         int main () { return foo (); }
 754         ]])],
 755         glib_cv_hasinline=yes
 756         ,
 757         glib_cv_hasinline=no
 758         ,)
 759 ])
 760 case x$glib_cv_hasinline in
 761 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 762 esac
 763
 764 # if we can use inline functions in headers
 765 AC_MSG_CHECKING(if inline functions in headers work)
 766 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 767 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 768 #  undef inline
 769 #  define inline __inline__
 770 #elif !defined (G_HAVE_INLINE)
 771 #  undef inline
 772 #  if defined (G_HAVE___INLINE__)
 773 #    define inline __inline__
 774 #  elif defined (G_HAVE___INLINE)
 775 #    define inline __inline
 776 #  endif
 777 #endif
 778
 779 int glib_test_func2 (int);
 780
 781 static inline int
 782 glib_test_func1 (void) {
 783   return glib_test_func2 (1);
 784 }
 785
 786 int
 787 main (void) {
 788   int i = 1;
 789 }]])],[g_can_inline=yes],[g_can_inline=no])
 790 AC_MSG_RESULT($g_can_inline)
 791
 792 dnl *** check for working do while(0) macros ***
 793 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 794         AC_TRY_COMPILE([],[
 795         #define STMT_START do
 796         #define STMT_END while(0)
 797         #define STMT_TEST STMT_START { i = 0; } STMT_END
 798         int main(void) { int i = 1; STMT_TEST; return i; }],
 799         [g_cv_support_dowhile_macros=yes],
 800         [g_cv_support_dowhile_macros=no],
 801         [g_cv_support_dowhile_macros=yes])
 802 ])
 803 if test x$g_cv_support_dowhile_macros = xyes; then
 804   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 805 fi
 806
 807 # check for flavours of varargs macros
 808 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 809 AC_TRY_COMPILE([],[
 810 int a(int p1, int p2, int p3);
 811 #define call_a(...) a(1,__VA_ARGS__)
 812 call_a(2,3);
 813 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 814 AC_MSG_RESULT($g_have_iso_c_varargs)
 815
 816 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 817 if test "$CXX" = ""; then
 818 dnl No C++ compiler
 819   g_have_iso_cxx_varargs=no
 820 else
 821   AC_LANG_CPLUSPLUS
 822   AC_TRY_COMPILE([],[
 823 int a(int p1, int p2, int p3);
 824 #define call_a(...) a(1,__VA_ARGS__)
 825 call_a(2,3);
 826 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 827   AC_LANG_C
 828 fi
 829 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 830
 831 AC_MSG_CHECKING(for GNUC varargs macros)
 832 AC_TRY_COMPILE([],[
 833 int a(int p1, int p2, int p3);
 834 #define call_a(params...) a(1,params)
 835 call_a(2,3);
 836 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 837 AC_MSG_RESULT($g_have_gnuc_varargs)
 838
 839 # check for GNUC visibility support
 840 AC_MSG_CHECKING(for GNUC visibility attribute)
 841 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 842 void
 843 __attribute__ ((visibility ("hidden")))
 844      f_hidden (void)
 845 {
 846 }
 847 void
 848 __attribute__ ((visibility ("internal")))
 849      f_internal (void)
 850 {
 851 }
 852 void
 853 __attribute__ ((visibility ("protected")))
 854      f_protected (void)
 855 {
 856 }
 857 void
 858 __attribute__ ((visibility ("default")))
 859      f_default (void)
 860 {
 861 }
 862 int main (int argc, char **argv)
 863 {
 864         f_hidden();
 865         f_internal();
 866         f_protected();
 867         f_default();
 868         return 0;
 869 }
 870 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 871 AC_MSG_RESULT($g_have_gnuc_visibility)
 872 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 873
 874 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 875 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 876 #else
 877 # include "error: this is not Sun Studio."
 878 #endif
 879 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 880 AC_MSG_RESULT($g_have_sunstudio_visibility)
 881 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 882
 883 # check for bytesex stuff
 884 AC_C_BIGENDIAN
 885 if test x$ac_cv_c_bigendian = xuniversal ; then
 886 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 887 #else
 888 #error Not a big endian.
 889 #endif],
 890     ac_cv_c_bigendian=yes
 891     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 892 #else
 893 #error Not a little endian.
 894 #endif],
 895     ac_cv_c_bigendian=no
 896     ,AC_MSG_WARN([Could not determine endianness.])))
 897 fi
 898
 899
 900 # check for header files
 901 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 902 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 903 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 904 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 905 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 906 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 907 AC_CHECK_HEADERS([linux/magic.h])
 908 AC_CHECK_HEADERS([sys/prctl.h])
 909
 910 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 911 [#if HAVE_SYS_PARAM_H
 912  #include <sys/param.h>
 913  #endif
 914 ])
 915
 916 AC_CHECK_HEADERS([xlocale.h])
 917
 918 # check for structure fields
 919 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 921 #include <sys/stat.h>
 922 #include <unistd.h>
 923 #ifdef HAVE_SYS_STATFS_H
 924 #include <sys/statfs.h>
 925 #endif
 926 #ifdef HAVE_SYS_PARAM_H
 927 #include <sys/param.h>
 928 #endif
 929 #ifdef HAVE_SYS_MOUNT_H
 930 #include <sys/mount.h>
 931 #endif])
 932 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 933 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 935 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 936
 937 AC_STRUCT_DIRENT_D_TYPE
 938
 939 # Checks for libcharset
 940 AM_LANGINFO_CODESET
 941 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 942 AC_CHECK_FUNCS(setlocale)
 943
 944 # check additional type sizes
 945 AC_CHECK_SIZEOF(size_t)
 946
 947 dnl Try to figure out whether gsize, gssize should be long or int
 948 AC_MSG_CHECKING([for the appropriate definition for size_t])
 949
 950 case $ac_cv_sizeof_size_t in
 951   $ac_cv_sizeof_short)
 952       glib_size_type=short
 953       ;;
 954   $ac_cv_sizeof_int)
 955       glib_size_type=int
 956       ;;
 957   $ac_cv_sizeof_long)
 958       glib_size_type=long
 959       ;;
 960   $ac_cv_sizeof_long_long)
 961       glib_size_type='long long'
 962       ;;
 963   $ac_cv_sizeof__int64)
 964       glib_size_type='__int64'
 965       ;;
 966   *)  AC_MSG_ERROR([No type matching size_t in size])
 967       ;;
 968 esac
 969
 970 dnl If int/long are the same size, we see which one produces
 971 dnl warnings when used in the location as size_t. (This matters
 972 dnl on AIX with xlc)
 973 dnl
 974 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 975    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 976   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 977 #if defined(_AIX) && !defined(__GNUC__)
 978 #pragma options langlvl=stdc89
 979 #endif
 980 #include <stddef.h>
 981 int main ()
 982 {
 983   size_t s = 1;
 984   unsigned int *size_int = &s;
 985   return (int)*size_int;
 986 }
 987     ]])],glib_size_type=int,
 988       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 989 #if defined(_AIX) && !defined(__GNUC__)
 990 #pragma options langlvl=stdc89
 991 #endif
 992 #include <stddef.h>
 993 int main ()
 994 {
 995    size_t s = 1;
 996    unsigned long *size_long = &s;
 997    return (int)*size_long;
 998 }
 999         ]])],glib_size_type=long)])
1000 fi
1001
1002 AC_MSG_RESULT(unsigned $glib_size_type)
1003
1004 # Check for some functions
1005 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1006 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1007 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1008 # Check for high-resolution sleep functions
1009 AC_CHECK_FUNCS(splice)
1010 AC_CHECK_FUNCS(prlimit)
1011
1012 # To avoid finding a compatibility unusable statfs, which typically
1013 # successfully compiles, but warns to use the newer statvfs interface:
1014 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1015 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1016
1017 AC_MSG_CHECKING([whether to use statfs or statvfs])
1018 # Some systems have both statfs and statvfs, pick the most "native" for these
1019 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1020    [
1021    # on solaris and irix, statfs doesn't even have the f_bavail field
1022    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1023       [ac_cv_func_statfs=no],
1024    # else, at least on linux, statfs is the actual syscall
1025       [ac_cv_func_statvfs=no])
1026    ])
1027
1028 AS_IF([test x$ac_cv_func_statfs = xyes],
1029       [
1030          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1031          AC_MSG_RESULT([statfs])
1032       ],
1033       [test x$ac_cv_func_statvfs = xyes],
1034       [
1035          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1036          AC_MSG_RESULT([statvfs])
1037       ],
1038       [  AC_MSG_RESULT([neither])])
1039
1040 AC_CHECK_HEADERS(crt_externs.h)
1041 AC_CHECK_FUNCS(_NSGetEnviron)
1042
1043 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1044
1045 AC_FUNC_VSNPRINTF_C99
1046 AC_FUNC_PRINTF_UNIX98
1047
1048 # Internet address families
1049 if test $glib_native_win32 = yes; then
1050   glib_inet_includes=["
1051 #include <winsock2.h>
1052   "]
1053 else
1054   glib_inet_includes=["
1055 #include <sys/types.h>
1056 #include <sys/socket.h>
1057   "]
1058 fi
1059
1060 glib_failed=false
1061 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1062 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1063 # winsock defines this even though it doesn't support it
1064 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1065 if $glib_failed ; then
1066   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1067 fi
1068
1069 glib_failed=false
1070 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1071 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1072 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1073 if $glib_failed ; then
1074   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1075 fi
1076
1077 AC_CHECK_FUNCS(getprotobyname_r endservent)
1078 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1079
1080 if test $glib_native_win32 = no; then
1081   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1082   NETWORK_LIBS=""
1083   AC_MSG_CHECKING([for res_query])
1084   AC_TRY_LINK([#include <sys/types.h>
1085                #include <netinet/in.h>
1086                #include <arpa/nameser.h>
1087                #include <resolv.h>
1088               ],[
1089                res_query("test", 0, 0, (void *)0, 0);
1090               ],[AC_MSG_RESULT([yes])],
1091               [save_libs="$LIBS"
1092                LIBS="-lresolv $LIBS"
1093                AC_TRY_LINK([#include <sys/types.h>
1094                             #include <netinet/in.h>
1095                             #include <arpa/nameser.h>
1096                             #include <resolv.h>
1097                            ],[
1098                             res_query("test", 0, 0, (void *)0, 0);
1099                            ],[AC_MSG_RESULT([in -lresolv])
1100                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1101                            [LIBS="-lbind $save_libs"
1102                             AC_TRY_LINK([#include <resolv.h>],
1103                                         [res_query("test", 0, 0, (void *)0, 0);],
1104                                         [AC_MSG_RESULT([in -lbind])
1105                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1106                                         [AC_MSG_ERROR(not found)])])
1107                LIBS="$save_libs"])
1108   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1109                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1110                                         [AC_MSG_ERROR(Could not find socket())]))
1111 fi
1112 AC_SUBST(NETWORK_LIBS)
1113
1114 AC_CHECK_HEADER([linux/netlink.h],
1115                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])])
1116 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1117
1118 case $host in
1119   *-*-solaris* )
1120      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1121      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1122      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1123      ;;
1124 esac
1125
1126 dnl
1127 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1128 dnl
1129 if test "$ac_cv_func_statfs" = yes ; then
1130   AC_MSG_CHECKING([number of arguments to statfs()])
1131   AC_TRY_COMPILE([#include <unistd.h>
1132   #ifdef HAVE_SYS_PARAM_H
1133   #include <sys/param.h>
1134   #endif
1135   #ifdef HAVE_SYS_VFS_H
1136   #include <sys/vfs.h>
1137   #endif
1138   #ifdef HAVE_SYS_MOUNT_H
1139   #include <sys/mount.h>
1140   #endif
1141   #ifdef HAVE_SYS_STATFS_H
1142   #include <sys/statfs.h>
1143   #endif], [struct statfs st;
1144   statfs(NULL, &st);],[
1145     AC_MSG_RESULT([2])
1146     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1147     AC_TRY_COMPILE([#include <unistd.h>
1148   #ifdef HAVE_SYS_PARAM_H
1149   #include <sys/param.h>
1150   #endif
1151   #ifdef HAVE_SYS_VFS_H
1152   #include <sys/vfs.h>
1153   #endif
1154   #ifdef HAVE_SYS_MOUNT_H
1155   #include <sys/mount.h>
1156   #endif
1157   #ifdef HAVE_SYS_STATFS_H
1158   #include <sys/statfs.h>
1159   #endif], [struct statfs st;
1160   statfs(NULL, &st, sizeof (st), 0);],[
1161       AC_MSG_RESULT([4])
1162       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1163       AC_MSG_RESULT(unknown)
1164       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1165 fi
1166
1167 #
1168 # Check whether to use an included printf
1169 #
1170
1171 AC_ARG_ENABLE(included-printf,
1172               [AC_HELP_STRING([--enable-included-printf],
1173                               [use included printf [default=auto]])],
1174               enable_included_printf="$enableval")
1175
1176 need_included_printf=no
1177 if test "x$enable_included_printf" = "xyes" ; then
1178   need_included_printf=yes
1179 fi
1180 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1181   need_included_printf=yes
1182 fi
1183 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1184   need_included_printf=yes
1185 fi
1186 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1187    test -z "$glib_cv_long_long_format" ; then
1188   need_included_printf=yes
1189 fi
1190
1191 if test "x$enable_included_printf" = "xno" &&
1192    test "x$need_included_printf" = "xyes" ; then
1193   AC_MSG_ERROR([
1194 *** Your C library's printf doesn't appear to have the features that
1195 *** GLib needs, but you specified --enable-included-printf=no.])
1196 fi
1197
1198 enable_included_printf=$need_included_printf
1199
1200 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1201 if test "$enable_included_printf" != "yes" ; then
1202   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1203 else
1204   if test -z "$glib_cv_long_long_format" ; then
1205     glib_cv_long_long_format="ll"
1206   fi
1207   AC_DEFINE(HAVE_VASPRINTF,1)
1208 fi
1209
1210 # Checks needed for gnulib vasnprintf
1211 bh_C_SIGNED
1212 jm_AC_TYPE_LONG_LONG
1213 gt_TYPE_LONGDOUBLE
1214 gt_TYPE_WCHAR_T
1215 gt_TYPE_WINT_T
1216 AC_TYPE_SIZE_T
1217 AC_CHECK_TYPES(ptrdiff_t)
1218 jm_AC_TYPE_INTMAX_T
1219 AC_CHECK_FUNCS([snprintf wcslen])
1220 AC_FUNC_SNPRINTF_C99
1221
1222 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1223 # The check is borrowed from the PERL Configure script.
1224 if test "$ac_cv_func_memmove" != "yes"; then
1225   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1226     glib_cv_working_bcopy,[AC_TRY_RUN([
1227       int main() {
1228         char buf[128], abc[128], *b;
1229         int len, off, align;
1230         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1231         for (align = 7; align >= 0; align--) {
1232           for (len = 36; len; len--) {
1233             b = buf+align; bcopy(abc, b, len);
1234             for (off = 1; off <= len; off++) {
1235               bcopy(b, b+off, len); bcopy(b+off, b, len);
1236                 if (bcmp(b, abc, len)) return(1);
1237             }
1238           }
1239         }
1240         return(0);
1241       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1242
1243   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1244   if test "$glib_cv_working_bcopy" = "yes"; then
1245     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1246   fi
1247 fi
1248
1249 # Check if <sys/select.h> needs to be included for fd_set
1250 AC_MSG_CHECKING([for fd_set])
1251 AC_TRY_COMPILE([#include <sys/types.h>],
1252         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1253 if test "$gtk_ok" = "yes"; then
1254     AC_MSG_RESULT([yes, found in sys/types.h])
1255 else
1256     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1257     if test "$gtk_ok" = "yes"; then
1258         # *** FIXME: give it a different name
1259         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1260         AC_MSG_RESULT([yes, found in sys/select.h])
1261     else
1262         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1263         AC_MSG_RESULT(no)
1264     fi
1265 fi
1266
1267 dnl *** check for sane realloc() ***
1268 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1269         AC_TRY_RUN([#include <stdlib.h>
1270         int main() {
1271           return realloc (0, sizeof (int)) == 0;
1272         }],
1273         [glib_cv_sane_realloc=yes],
1274         [glib_cv_sane_realloc=no],
1275         [glib_cv_sane_realloc=yes])
1276 ])
1277 if test x$glib_cv_sane_realloc = xyes; then
1278   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1279 fi
1280
1281 dnl Check for nl_langinfo and CODESET
1282 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1283         AC_TRY_COMPILE([#include <langinfo.h>],
1284                 [char *codeset = nl_langinfo (CODESET);],
1285                 [glib_cv_langinfo_codeset=yes],
1286                 [glib_cv_langinfo_codeset=no])])
1287 if test x$glib_cv_langinfo_codeset = xyes; then
1288   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1289 fi
1290
1291 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1292 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1293         AC_TRY_COMPILE([#include <langinfo.h>],
1294                 [char *str;
1295                  str = nl_langinfo (PM_STR);
1296                  str = nl_langinfo (D_T_FMT);
1297                  str = nl_langinfo (D_FMT);
1298                  str = nl_langinfo (T_FMT);
1299                  str = nl_langinfo (T_FMT_AMPM);
1300                  str = nl_langinfo (MON_1);
1301                  str = nl_langinfo (ABMON_12);
1302                  str = nl_langinfo (DAY_1);
1303                  str = nl_langinfo (ABDAY_7);],
1304                 [glib_cv_langinfo_time=yes],
1305                 [glib_cv_langinfo_time=no])])
1306 if test x$glib_cv_langinfo_time = xyes; then
1307   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1308 fi
1309
1310 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1311 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1312         AC_TRY_COMPILE([#include <langinfo.h>],
1313                 [char *str;
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1315                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1318                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1319                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1320                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1321                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1322                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1323                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1324                 [glib_cv_langinfo_outdigit=yes],
1325                 [glib_cv_langinfo_outdigit=no])])
1326 if test x$glib_cv_langinfo_outdigit = xyes; then
1327   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1328 fi
1329
1330 dnl ****************************************
1331 dnl *** posix_memalign                   ***
1332 dnl ****************************************
1333 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1334 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1335     glib_cv_compliant_posix_memalign=0
1336     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1337         AC_TRY_RUN([
1338                 #define _XOPEN_SOURCE 600
1339                 #include <stdlib.h> /* posix_memalign() should be defined here */
1340                 /* some systems break if #include <malloc.h> used */
1341                 static void test_memalign (size_t boundary, size_t size) {
1342                     void *mem = 0;
1343                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1344                         exit (1);
1345                     else
1346                       free (mem);
1347                 }
1348                 int main() {
1349                     test_memalign (  128,   128 - 2 * sizeof (void*));
1350                     test_memalign (  256,   256 - 2 * sizeof (void*));
1351                     test_memalign (  512,   512 - 2 * sizeof (void*));
1352                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1353                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1354                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1355                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1356                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1357                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1358                     exit (0); /* success */
1359                 }
1360                 ],
1361             [glib_cv_compliant_posix_memalign=1], [], [:])
1362       :
1363     fi
1364     ])
1365 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1366     AC_MSG_RESULT(yes)
1367     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1368 else
1369     AC_MSG_RESULT(no)
1370 fi
1371
1372
1373 dnl ****************************************
1374 dnl *** strlcpy/strlcat                  ***
1375 dnl ****************************************
1376 # Check for strlcpy
1377 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1378 AC_TRY_RUN([#include <stdlib.h>
1379 #include <string.h>
1380 int main() {
1381   char p[10];
1382   (void) strlcpy (p, "hi", 10);
1383   if (strlcat (p, "bye", 0) != 3)
1384     return 1;
1385   return 0;
1386 }], glib_cv_have_strlcpy=yes,
1387     glib_cv_have_strlcpy=no,
1388     glib_cv_have_strlcpy=no)])
1389 if test "$glib_cv_have_strlcpy" = "yes"; then
1390     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1391 fi
1392
1393
1394 dnl **********************
1395 dnl *** va_copy checks ***
1396 dnl **********************
1397 dnl we currently check for all three va_copy possibilities, so we get
1398 dnl all results in config.log for bug reports.
1399 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1400         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1401 #include <stdlib.h>
1402         void f (int i, ...) {
1403         va_list args1, args2;
1404         va_start (args1, i);
1405         va_copy (args2, args1);
1406         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1407           exit (1);
1408         va_end (args1); va_end (args2);
1409         }
1410         int main() {
1411           f (0, 42);
1412           return 0;
1413         }]])],
1414         [glib_cv_va_copy=yes],
1415         [glib_cv_va_copy=no])
1416 ])
1417 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1418         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1419 #include <stdlib.h>
1420         void f (int i, ...) {
1421         va_list args1, args2;
1422         va_start (args1, i);
1423         __va_copy (args2, args1);
1424         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1425           exit (1);
1426         va_end (args1); va_end (args2);
1427         }
1428         int main() {
1429           f (0, 42);
1430           return 0;
1431         }]])],
1432         [glib_cv___va_copy=yes],
1433         [glib_cv___va_copy=no])
1434 ])
1435
1436 if test "x$glib_cv_va_copy" = "xyes"; then
1437   g_va_copy_func=va_copy
1438 else if test "x$glib_cv___va_copy" = "xyes"; then
1439   g_va_copy_func=__va_copy
1440 fi
1441 fi
1442
1443 if test -n "$g_va_copy_func"; then
1444   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1445 fi
1446
1447 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1448         AC_TRY_RUN([#include <stdarg.h>
1449 #include <stdlib.h>
1450         void f (int i, ...) {
1451         va_list args1, args2;
1452         va_start (args1, i);
1453         args2 = args1;
1454         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1455           exit (1);
1456         va_end (args1); va_end (args2);
1457         }
1458         int main() {
1459           f (0, 42);
1460           return 0;
1461         }],
1462         [glib_cv_va_val_copy=yes],
1463         [glib_cv_va_val_copy=no],
1464         [glib_cv_va_val_copy=yes])
1465 ])
1466
1467 if test "x$glib_cv_va_val_copy" = "xno"; then
1468   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1469 fi
1470
1471 dnl ***********************
1472 dnl *** g_module checks ***
1473 dnl ***********************
1474 G_MODULE_LIBS=
1475 G_MODULE_LIBS_EXTRA=
1476 G_MODULE_PLUGIN_LIBS=
1477 if test x"$glib_native_win32" = xyes; then
1478   dnl No use for this on Win32
1479   G_MODULE_LDFLAGS=
1480 else
1481   export SED
1482   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1483 fi
1484 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1485 G_MODULE_NEED_USCORE=0
1486 G_MODULE_BROKEN_RTLD_GLOBAL=0
1487 G_MODULE_HAVE_DLERROR=0
1488 dnl *** force native WIN32 shared lib loader
1489 if test -z "$G_MODULE_IMPL"; then
1490   case "$host" in
1491   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1492   esac
1493 fi
1494 dnl *** force native AIX library loader
1495 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1496 if test -z "$G_MODULE_IMPL"; then
1497   case "$host" in
1498   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1499   esac
1500 fi
1501 dnl *** dlopen() and dlsym() in system libraries
1502 if test -z "$G_MODULE_IMPL"; then
1503         AC_CHECK_FUNC(dlopen,
1504                       [AC_CHECK_FUNC(dlsym,
1505                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1506                       [])
1507 fi
1508 dnl *** load_image (BeOS)
1509 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1510   AC_CHECK_LIB(root, load_image,
1511       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1512       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1513       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1514       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1515       [])
1516 fi
1517 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1518 if test -z "$G_MODULE_IMPL"; then
1519         AC_CHECK_FUNC(NSLinkModule,
1520                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1521                        G_MODULE_NEED_USCORE=1],
1522                       [])
1523 fi
1524 dnl *** dlopen() and dlsym() in libdl
1525 if test -z "$G_MODULE_IMPL"; then
1526         AC_CHECK_LIB(dl, dlopen,
1527                      [AC_CHECK_LIB(dl, dlsym,
1528                                    [G_MODULE_LIBS=-ldl
1529                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1530                      [])
1531 fi
1532 dnl *** shl_load() in libdld (HP-UX)
1533 if test -z "$G_MODULE_IMPL"; then
1534         AC_CHECK_LIB(dld, shl_load,
1535                 [G_MODULE_LIBS=-ldld
1536                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1537                 [])
1538 fi
1539 dnl *** additional checks for G_MODULE_IMPL_DL
1540 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1541         LIBS_orig="$LIBS"
1542         LDFLAGS_orig="$LDFLAGS"
1543         LIBS="$G_MODULE_LIBS $LIBS"
1544         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1545 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1546         echo "void glib_plugin_test(void) { }" > plugin.c
1547         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1548                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1549         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1550                 glib_cv_rtldglobal_broken,[
1551                 AC_TRY_RUN([
1552 #include <dlfcn.h>
1553 #ifndef RTLD_GLOBAL
1554 #  define RTLD_GLOBAL 0
1555 #endif
1556 #ifndef RTLD_LAZY
1557 #  define RTLD_LAZY 0
1558 #endif
1559 int glib_plugin_test;
1560 int main () {
1561     void *handle, *global, *local;
1562     global = &glib_plugin_test;
1563     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1564     if (!handle) return 0;
1565     local = dlsym (handle, "glib_plugin_test");
1566     return global == local;
1567 }                       ],
1568                         [glib_cv_rtldglobal_broken=no],
1569                         [glib_cv_rtldglobal_broken=yes],
1570                         [glib_cv_rtldglobal_broken=no])
1571                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1572                 rmdir .libs 2>/dev/null
1573         ])
1574         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1575                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1576         else
1577                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1578         fi
1579 dnl *** check whether we need preceeding underscores
1580         AC_CACHE_CHECK([for preceeding underscore in symbols],
1581                 glib_cv_uscore,[
1582                 AC_TRY_RUN([#include <dlfcn.h>
1583                 int glib_underscore_test (void) { return 42; }
1584                 int main() {
1585                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1586                   handle = dlopen ((void*)0, 0);
1587                   if (handle) {
1588                     f1 = dlsym (handle, "glib_underscore_test");
1589                     f2 = dlsym (handle, "_glib_underscore_test");
1590                   } return (!f2 || f1);
1591                 }],
1592                         [glib_cv_uscore=yes],
1593                         [glib_cv_uscore=no],
1594                         [])
1595                 rm -f plugin.c plugin.$ac_objext plugin.lo
1596         ])
1597         GLIB_ASSERT_SET(glib_cv_uscore)
1598         if test "x$glib_cv_uscore" = "xyes"; then
1599                 G_MODULE_NEED_USCORE=1
1600         else
1601                 G_MODULE_NEED_USCORE=0
1602         fi
1603
1604         LDFLAGS="$LDFLAGS_orig"
1605 dnl *** check for having dlerror()
1606         AC_CHECK_FUNC(dlerror,
1607                 [G_MODULE_HAVE_DLERROR=1],
1608                 [G_MODULE_HAVE_DLERROR=0])
1609         LIBS="$LIBS_orig"
1610 fi
1611 dnl *** done, have we got an implementation?
1612 if test -z "$G_MODULE_IMPL"; then
1613         G_MODULE_IMPL=0
1614         G_MODULE_SUPPORTED=false
1615 else
1616         G_MODULE_SUPPORTED=true
1617 fi
1618
1619 AC_MSG_CHECKING(for the suffix of module shared libraries)
1620 export SED
1621 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1622 eval $shrext_cmds
1623 module=yes eval std_shrext=$shrext_cmds
1624 # chop the initial dot
1625 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1626 AC_MSG_RESULT(.$glib_gmodule_suffix)
1627 # any reason it may fail?
1628 if test "x$glib_gmodule_suffix" = x; then
1629         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1630 fi
1631
1632 AC_SUBST(G_MODULE_SUPPORTED)
1633 AC_SUBST(G_MODULE_IMPL)
1634 AC_SUBST(G_MODULE_LIBS)
1635 AC_SUBST(G_MODULE_LIBS_EXTRA)
1636 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1637 AC_SUBST(G_MODULE_LDFLAGS)
1638 AC_SUBST(G_MODULE_HAVE_DLERROR)
1639 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1640 AC_SUBST(G_MODULE_NEED_USCORE)
1641 AC_SUBST(GLIB_DEBUG_FLAGS)
1642
1643 dnl **********************
1644 dnl *** g_spawn checks ***
1645 dnl **********************
1646
1647 AC_MSG_CHECKING(for gspawn implementation)
1648 case "$host" in
1649   *-*-mingw*)
1650     GSPAWN=gspawn-win32.lo
1651     ;;
1652   *)
1653     GSPAWN=gspawn.lo
1654     ;;
1655 esac
1656 AC_MSG_RESULT($GSPAWN)
1657 AC_SUBST(GSPAWN)
1658
1659 dnl *************************
1660 dnl *** GIOChannel checks ***
1661 dnl *************************
1662
1663 AC_MSG_CHECKING(for GIOChannel implementation)
1664 case "$host" in
1665   *-*-mingw*)
1666     GIO=giowin32.lo
1667     ;;
1668   *)
1669     GIO=giounix.lo
1670     ;;
1671 esac
1672 AC_MSG_RESULT($GIO)
1673 AC_SUBST(GIO)
1674
1675 dnl *********************************
1676 dnl *** Directory for GIO modules ***
1677 dnl *********************************
1678
1679 AC_ARG_WITH(gio-module-dir,
1680            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1681                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1682            [],
1683            [with_gio_module_dir='${libdir}/gio/modules'])
1684 GIO_MODULE_DIR=$with_gio_module_dir
1685 AC_SUBST(GIO_MODULE_DIR)
1686
1687 dnl **********************************
1688 dnl *** Check for libselinux (GIO) ***
1689 dnl **********************************
1690 AC_ARG_ENABLE(selinux,
1691               AC_HELP_STRING([--disable-selinux],
1692                              [build without selinux support]))
1693 msg_selinux=no
1694 SELINUX_LIBS=
1695 if test "x$enable_selinux" != "xno"; then
1696
1697  AC_CHECK_LIB(selinux, is_selinux_enabled,
1698    [AC_CHECK_HEADERS(selinux/selinux.h,
1699      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1700        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1701         SELINUX_LIBS="-lselinux"
1702         msg_selinux=yes])
1703      ])
1704    ])
1705 fi
1706 AC_SUBST(SELINUX_LIBS)
1707
1708 dnl *****************************
1709 dnl ** Check for inotify (GIO) **
1710 dnl *****************************
1711 inotify_support=no
1712 AC_CHECK_HEADERS([sys/inotify.h],
1713 [
1714         inotify_support=yes
1715         AC_CHECK_FUNCS(inotify_init1)
1716 ])
1717
1718 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1719
1720 dnl *********************************
1721 dnl ** Check for Solaris FEN (GIO) **
1722 dnl *********************************
1723 fen_support=no
1724 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1725 #include <port.h>
1726 #ifndef PORT_SOURCE_FILE
1727 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1728 #endif
1729 int main() { return 0; } ]])],
1730 [
1731         fen_support=yes
1732 ],)
1733
1734 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1735
1736 dnl ****************************
1737 dnl *** Checks for FAM (GIO) ***
1738 dnl ****************************
1739
1740 should_disable_fam=no
1741
1742 AC_ARG_ENABLE(fam,
1743               AC_HELP_STRING([--disable-fam],
1744                              [don't use fam for file system monitoring]),
1745                          [
1746                                 if test "x$enable_fam" = "xno"; then
1747                                         should_disable_fam=yes
1748                                 fi
1749                          ]
1750                          )
1751 fam_support=no
1752 FAM_LIBS=
1753 if test "x$should_disable_fam" = "xno"; then
1754 AC_CHECK_LIB(fam, FAMOpen,
1755   [AC_CHECK_HEADERS(fam.h,
1756     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1757      AC_CHECK_LIB(fam, FAMNoExists,
1758                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1759      FAM_LIBS="-lfam"]
1760      fam_support=yes,
1761     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1762   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1763 AC_SUBST(FAM_LIBS)
1764 fi
1765 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1766
1767
1768 dnl *****************************
1769 dnl *** Check for xattr (GIO) ***
1770 dnl *****************************
1771 AC_ARG_ENABLE(xattr,
1772               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1773 msg_xattr=no
1774 XATTR_LIBS=
1775 if test "x$enable_xattr" != "xno"; then
1776
1777 dnl either glibc or libattr can provide xattr support
1778
1779 dnl for both of them, we check for getxattr being in
1780 dnl the library and a valid xattr header.
1781
1782 dnl try glibc
1783  AC_CHECK_LIB(c, getxattr,
1784    [AC_CHECK_HEADERS(sys/xattr.h,
1785      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1786       msg_xattr=yes])
1787    ])
1788
1789   if test "x$msg_xattr" != "xyes"; then
1790 dnl   failure. try libattr
1791    AC_CHECK_LIB(attr, getxattr,
1792       [AC_CHECK_HEADERS(attr/xattr.h,
1793        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1794         XATTR_LIBS="-lattr"
1795         msg_xattr=yes])
1796       ])
1797   fi
1798
1799   if test "x$msg_xattr" = "xyes"; then
1800     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1801     AC_TRY_COMPILE([
1802       #include <stdio.h>
1803       #ifdef HAVE_SYS_TYPES_H
1804       #include <sys/types.h>
1805       #endif
1806       #ifdef HAVE_SYS_XATTR_H
1807       #include <sys/xattr.h>
1808       #elif HAVE_ATTR_XATTR_H
1809       #include <attr/xattr.h>
1810       #endif
1811     ],
1812     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1813     [
1814       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1815       AC_MSG_RESULT([yes])
1816     ],
1817     [AC_MSG_RESULT([no])]
1818     )
1819   fi
1820
1821 fi
1822 AC_SUBST(XATTR_LIBS)
1823
1824 dnl ****************************************
1825 dnl *** platform dependent source checks ***
1826 dnl ****************************************
1827
1828 AC_MSG_CHECKING(for platform-dependent source)
1829 case "$host" in
1830   *-*-cygwin*|*-*-mingw*)
1831     PLATFORMDEP=gwin32.lo
1832     ;;
1833   *)
1834     PLATFORMDEP=
1835     ;;
1836 esac
1837 AC_MSG_RESULT($PLATFORMDEP)
1838 AC_SUBST(PLATFORMDEP)
1839
1840 AC_MSG_CHECKING([whether to compile timeloop])
1841 case "$host" in
1842   *-*-cygwin*|*-*-mingw*|*-*-minix)
1843     enable_timeloop=no
1844     ;;
1845   *)
1846     enable_timeloop=yes
1847     ;;
1848 esac
1849 AC_MSG_RESULT($enable_timeloop)
1850 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1851
1852 AC_MSG_CHECKING([if building for some Win32 platform])
1853 case "$host" in
1854   *-*-mingw*|*-*-cygwin*)
1855     platform_win32=yes
1856     ;;
1857   *)
1858     platform_win32=no
1859     ;;
1860 esac
1861 AC_MSG_RESULT($platform_win32)
1862 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1863
1864 dnl ***********************
1865 dnl *** g_thread checks ***
1866 dnl ***********************
1867
1868 AC_ARG_WITH(threads,
1869            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1870                            [specify a thread implementation to use])],
1871            [if test "x$with_threads" = x; then
1872                 want_threads=yes
1873             else
1874                 want_threads=$with_threads
1875             fi],
1876            [want_threads=yes])
1877
1878 dnl error and warning message
1879 dnl *************************
1880
1881 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1882                 computer."
1883
1884 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1885                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1886                 compilation now, but then your programs might not work.
1887                 Please provide information on how it is done on your system."
1888
1889 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1890                 "
1891
1892 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1893                 provide information on your thread implementation."
1894
1895 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1896                 functions will not be MT-safe during their first call because
1897                 there is no working 'getpwuid_r' on your system."
1898
1899 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1900                 because there is no 'localtime_r' on your system."
1901
1902 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1903                 crude surrogate will be used. If you happen to know a
1904                 yield function for your system, please inform the GLib
1905                 developers."
1906
1907 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1908                 threads on your system. Thus threads can only have the default
1909                 priority. If you happen to know these main/max
1910                 priorities, please inform the GLib developers."
1911
1912 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1913                 linking threaded applications. As GLib cannot do that
1914                 automatically, you will get an linkg error everytime you are
1915                 not using the right compiler. In that case you have to relink
1916                 with the right compiler. Ususally just '_r' is appended
1917                 to the compiler name."
1918
1919 dnl determination of thread implementation
1920 dnl ***************************************
1921
1922 have_threads=no
1923 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1924                                 || test "x$want_threads" = xdce; then
1925         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1926         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1927         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1928         glib_save_CPPFLAGS="$CPPFLAGS"
1929         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1930         if test "x$have_threads" = xno; then
1931                 AC_TRY_COMPILE([#include <pthread.h>],
1932                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1933                         have_threads=posix)
1934         fi
1935         # Tru64Unix requires -pthread to find pthread.h. See #103020
1936         CPPFLAGS="$CPPFLAGS -pthread"
1937         if test "x$have_threads" = xno; then
1938         AC_TRY_COMPILE([#include <pthread.h>],
1939                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1940                        have_threads=posix)
1941         fi
1942         CPPFLAGS="$glib_save_CPPFLAGS"
1943 fi
1944 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1945         case $host in
1946                 *-*-mingw*)
1947                 have_threads=win32
1948                 ;;
1949         esac
1950 fi
1951
1952 AC_MSG_CHECKING(for thread implementation)
1953
1954 if test "x$have_threads" = xno; then
1955         AC_MSG_RESULT(none available)
1956         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1957 else
1958         AC_MSG_RESULT($have_threads)
1959 fi
1960
1961
1962 dnl determination of G_THREAD_CFLAGS
1963 dnl ********************************
1964
1965 G_THREAD_LIBS=
1966 G_THREAD_LIBS_EXTRA=
1967 G_THREAD_CFLAGS=
1968
1969 dnl
1970 dnl Test program for basic POSIX threads functionality
1971 dnl
1972 m4_define([glib_thread_test],[
1973 #include <pthread.h>
1974 int check_me = 0;
1975 void* func(void* data) {check_me = 42; return &check_me;}
1976 int main()
1977  { pthread_t t;
1978    void *ret;
1979    pthread_create (&t, $1, func, 0);
1980    pthread_join (t, &ret);
1981    return (check_me != 42 || ret != &check_me);
1982 }])
1983
1984 dnl
1985 dnl Test program for sched_get_priority_min()
1986 dnl
1987 m4_define([glib_sched_priority_test],[
1988 #include <sched.h>
1989 #include <errno.h>
1990 int main() {
1991     errno = 0;
1992     return sched_get_priority_min(SCHED_OTHER)==-1
1993            && errno != 0;
1994 }])
1995
1996 if test x"$have_threads" = xposix; then
1997   # First we test for posix, whether -pthread or -pthreads do the trick as
1998   # both CPPFLAG and LIBS.
1999   # One of them does for most gcc versions and some other platforms/compilers
2000   # too and could be considered as the canonical way to go.
2001   case $host in
2002     *-*-cygwin*|*-*-darwin*)
2003        # skip cygwin and darwin -pthread or -pthreads test
2004        ;;
2005     *-solaris*)
2006       # These compiler/linker flags work with both Sun Studio and gcc
2007       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2008       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2009       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2010       G_THREAD_LIBS="-lpthread -lthread"
2011       ;;
2012     *)
2013       for flag in pthread pthreads mt; do
2014         glib_save_CFLAGS="$CFLAGS"
2015         CFLAGS="$CFLAGS -$flag"
2016         AC_TRY_RUN(glib_thread_test(0),
2017                    glib_flag_works=yes,
2018                    glib_flag_works=no,
2019                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2020                                    glib_flag_works=yes,
2021                                    glib_flag_works=no)])
2022         CFLAGS="$glib_save_CFLAGS"
2023         if test $glib_flag_works = yes ; then
2024            G_THREAD_CFLAGS=-$flag
2025         G_THREAD_LIBS=-$flag
2026         break;
2027         fi
2028       done
2029        ;;
2030   esac
2031 fi
2032
2033 if test x"$G_THREAD_CFLAGS" = x; then
2034
2035   # The canonical -pthread[s] does not work. Try something different.
2036
2037   case $host in
2038         *-aix*)
2039                 if test x"$GCC" = xyes; then
2040                         # GCC 3.0 and above needs -pthread.
2041                         # Should be coverd by the case above.
2042                         # GCC 2.x and below needs -mthreads
2043                         G_THREAD_CFLAGS="-mthreads"
2044                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2045                 else
2046                         # We are probably using the aix compiler. Normaly a
2047                         # program would have to be compiled with the _r variant
2048                         # of the corresponding compiler, but we as GLib cannot
2049                         # do that: but the good news is that for compiling the
2050                         # only difference is the added -D_THREAD_SAFE compile
2051                         # option. This is according to the "C for AIX User's
2052                         # Guide".
2053                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2054                 fi
2055                 ;;
2056         *-dg-dgux*)  # DG/UX
2057                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2058                 ;;
2059         *-sysv5uw7*) # UnixWare 7
2060                 # We are not using gcc with -pthread. Catched above.
2061                 G_THREAD_CFLAGS="-Kthread"
2062                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2063                 ;;
2064         *-mingw*)
2065                 # No flag needed when using MSVCRT.DLL
2066                 G_THREAD_CFLAGS=""
2067                 ;;
2068         *)
2069                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2070                 ;;
2071   esac
2072
2073 fi
2074
2075 # if we are not finding the localtime_r function, then we probably are
2076 # not using the proper multithread flag
2077
2078 glib_save_CPPFLAGS="$CPPFLAGS"
2079 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2080
2081 # First we test, whether localtime_r is declared in time.h
2082 # directly. Then we test whether a macro localtime_r exists, in
2083 # which case localtime_r in the test program is replaced and thus
2084 # if we still find localtime_r in the output, it is not defined as
2085 # a macro.
2086
2087 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2088   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2089                                                            localtime_r(a,b)],
2090                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2091
2092 CPPFLAGS="$glib_save_CPPFLAGS"
2093
2094 AC_MSG_CHECKING(thread related cflags)
2095 AC_MSG_RESULT($G_THREAD_CFLAGS)
2096 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2097
2098 dnl determination of G_THREAD_LIBS
2099 dnl ******************************
2100
2101 case $have_threads in
2102         posix)
2103           glib_save_CPPFLAGS="$CPPFLAGS"
2104           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2105           if test x"$G_THREAD_LIBS" = x; then
2106             case $host in
2107               *-aix*)
2108                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2109                 # probably using the aix compiler.
2110                 AC_MSG_WARN($AIX_COMPILE_INFO)
2111                 ;;
2112               *)
2113                 G_THREAD_LIBS=error
2114                 glib_save_LIBS="$LIBS"
2115                 for thread_lib in "" pthread pthread32 pthreads thread; do
2116                         if test x"$thread_lib" = x; then
2117                                 add_thread_lib=""
2118                                 IN=""
2119                         else
2120                                 add_thread_lib="-l$thread_lib"
2121                                 IN=" in -l$thread_lib"
2122                         fi
2123                         if test x"$have_threads" = xposix; then
2124                                 defattr=0
2125                         else
2126                                 defattr=pthread_attr_default
2127                         fi
2128
2129                         LIBS="$add_thread_lib $glib_save_LIBS"
2130
2131                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2132                         AC_TRY_RUN(glib_thread_test($defattr),
2133                                    glib_result=yes,
2134                                    glib_result=no,
2135                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2136                                                    glib_result=yes,
2137                                                    glib_result=no)])
2138                         AC_MSG_RESULT($glib_result)
2139
2140                         if test "$glib_result" = "yes" ; then
2141                           G_THREAD_LIBS="$add_thread_lib"
2142                           break
2143                         fi
2144                 done
2145                 if test "x$G_THREAD_LIBS" = xerror; then
2146                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2147                 fi
2148                 LIBS="$glib_save_LIBS"
2149                 ;;
2150             esac
2151           fi
2152
2153           glib_save_LIBS="$LIBS"
2154           for thread_lib in "" rt rte; do
2155             if test x"$thread_lib" = x; then
2156               add_thread_lib=""
2157               IN=""
2158             else
2159               add_thread_lib="-l$thread_lib"
2160               IN=" in -l$thread_lib"
2161             fi
2162             LIBS="$add_thread_lib $glib_save_LIBS"
2163
2164             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2165             AC_TRY_RUN(glib_sched_priority_test,
2166                        glib_result=yes,
2167                        glib_result=no,
2168                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2169                                        glib_result=yes,
2170                                        glib_result=no)])
2171             AC_MSG_RESULT($glib_result)
2172
2173             if test "$glib_result" = "yes" ; then
2174                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2175                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2176                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2177                break
2178             fi
2179           done
2180           LIBS="$glib_save_LIBS"
2181           g_threads_impl="POSIX"
2182           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2183           CPPFLAGS="$glib_save_CPPFLAGS"
2184           ;;
2185         win32)
2186            g_threads_impl="WIN32"
2187            ;;
2188         *)
2189            g_threads_impl="NONE"
2190            G_THREAD_LIBS=error
2191            ;;
2192 esac
2193
2194 if test "x$G_THREAD_LIBS" = xerror; then
2195         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2196 fi
2197
2198 case $host in
2199   *-*-beos*)
2200     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2201     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2202     ;;
2203   *)
2204     ;;
2205 esac
2206
2207 AC_MSG_CHECKING(thread related libraries)
2208 AC_MSG_RESULT($G_THREAD_LIBS)
2209
2210 dnl check for mt safe function variants and some posix functions
2211 dnl ************************************************************
2212
2213 glib_save_LIBS="$LIBS"
2214 # we are not doing the following for now, as this might require glib
2215 # to always be linked with the thread libs on some platforms.
2216 # LIBS="$LIBS $G_THREAD_LIBS"
2217 AC_CHECK_FUNCS(localtime_r gmtime_r)
2218 if test "$ac_cv_header_pwd_h" = "yes"; then
2219         AC_CACHE_CHECK([for posix getpwuid_r],
2220                 ac_cv_func_posix_getpwuid_r,
2221                 [AC_TRY_RUN([
2222 #include <errno.h>
2223 #include <pwd.h>
2224 int main () {
2225     char buffer[10000];
2226     struct passwd pwd, *pwptr = &pwd;
2227     int error;
2228     errno = 0;
2229     error = getpwuid_r (0, &pwd, buffer,
2230                         sizeof (buffer), &pwptr);
2231    return (error < 0 && errno == ENOSYS)
2232            || error == ENOSYS;
2233 }                               ],
2234                         [ac_cv_func_posix_getpwuid_r=yes],
2235                         [ac_cv_func_posix_getpwuid_r=no])])
2236         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2237         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2238                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2239                         [Have POSIX function getpwuid_r])
2240         else
2241                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2242                         ac_cv_func_nonposix_getpwuid_r,
2243                         [AC_TRY_LINK([#include <pwd.h>],
2244                                 [char buffer[10000];
2245                                 struct passwd pwd;
2246                                 getpwuid_r (0, &pwd, buffer,
2247                                                 sizeof (buffer));],
2248                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2249                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2250                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2251                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2252                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2253                                 [Have non-POSIX function getpwuid_r])
2254                 fi
2255         fi
2256 fi
2257 if test "$ac_cv_header_grp_h" = "yes"; then
2258         AC_CACHE_CHECK([for posix getgrgid_r],
2259                 ac_cv_func_posix_getgrgid_r,
2260                 [AC_TRY_RUN([
2261 #include <errno.h>
2262 #include <grp.h>
2263 int main () {
2264     char buffer[10000];
2265     struct group grp, *grpptr = &grp;
2266     int error;
2267     errno = 0;
2268     error = getgrgid_r (0, &grp, buffer,
2269                         sizeof (buffer), &grpptr);
2270    return (error < 0 && errno == ENOSYS)
2271            || error == ENOSYS;
2272 }                              ],
2273                        [ac_cv_func_posix_getgrgid_r=yes],
2274                        [ac_cv_func_posix_getgrgid_r=no])])
2275         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2276         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2277                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2278                         [Have POSIX function getgrgid_r])
2279         else
2280                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2281                         ac_cv_func_nonposix_getgrgid_r,
2282                         [AC_TRY_LINK([#include <grp.h>],
2283                                 [char buffer[10000];
2284                                 struct group grp;
2285                                 getgrgid_r (0, &grp, buffer,
2286                                 sizeof (buffer));],
2287                         [ac_cv_func_nonposix_getgrgid_r=yes],
2288                         [ac_cv_func_nonposix_getgrgid_r=no])])
2289                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2290                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2291                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2292                                 [Have non-POSIX function getgrgid_r])
2293                 fi
2294         fi
2295 fi
2296 LIBS="$G_THREAD_LIBS $LIBS"
2297 if test x"$have_threads" = xposix; then
2298         glib_save_CPPFLAGS="$CPPFLAGS"
2299         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2300         dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2301         GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2302         # This is not AC_CHECK_FUNC to also work with function
2303         # name mangling in header files.
2304         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2305         AC_TRY_LINK([#include <pthread.h>],
2306                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2307                 [AC_MSG_RESULT(yes)
2308                 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2309                           [Have function pthread_attr_setstacksize])],
2310                 [AC_MSG_RESULT(no)])
2311         AC_MSG_CHECKING(for minimal/maximal thread priority)
2312         if test x"$posix_priority_min" = x; then
2313                 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2314                         PX_PRIO_MIN],,[
2315                         posix_priority_min=PX_PRIO_MIN
2316                         posix_priority_max=PX_PRIO_MAX])
2317         fi
2318         if test x"$posix_priority_min" = x; then
2319                 # AIX
2320                 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2321                         PTHREAD_PRIO_MIN],,[
2322                         posix_priority_min=PTHREAD_PRIO_MIN
2323                         posix_priority_max=PTHREAD_PRIO_MAX])
2324         fi
2325         if test x"$posix_priority_min" = x; then
2326                 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2327                         PRI_OTHER_MIN],,[
2328                         posix_priority_min=PRI_OTHER_MIN
2329                         posix_priority_max=PRI_OTHER_MAX])
2330         fi
2331         if test x"$posix_priority_min" = x; then
2332                 AC_MSG_RESULT(none found)
2333                 AC_MSG_WARN($POSIX_NO_PRIORITIES)
2334                 posix_priority_min=-1
2335                 posix_priority_max=-1
2336         else
2337                 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2338                 AC_MSG_CHECKING(for pthread_setschedparam)
2339                 AC_TRY_LINK([#include <pthread.h>],
2340                   [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2341                   [AC_MSG_RESULT(yes)
2342                 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2343                    AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2344                   [AC_MSG_RESULT(no)
2345                    AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2346         fi
2347         posix_yield_func=none
2348         AC_MSG_CHECKING(for posix yield function)
2349         for yield_func in sched_yield pthread_yield_np pthread_yield \
2350                                                 thr_yield; do
2351                 AC_TRY_LINK([#include <pthread.h>],
2352                         [$yield_func()],
2353                         [posix_yield_func="$yield_func"
2354                         break])
2355         done
2356         if test x"$posix_yield_func" = xnone; then
2357                 AC_MSG_RESULT(none found)
2358                 AC_MSG_WARN($POSIX_NO_YIELD)
2359                 posix_yield_func="g_usleep(1000)"
2360         else
2361                 AC_MSG_RESULT($posix_yield_func)
2362                 posix_yield_func="$posix_yield_func()"
2363         fi
2364         AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2365         CPPFLAGS="$glib_save_CPPFLAGS"
2366
2367 elif test x"$have_threads" = xwin32; then
2368         # It's a pointer to a private struct
2369         GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2370 fi
2371
2372 LIBS="$glib_save_LIBS"
2373
2374 # now spit out all the warnings.
2375 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2376    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2377         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2378 fi
2379 if test "$ac_cv_func_localtime_r" != "yes"; then
2380         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2381 fi
2382
2383 if test x"$glib_cv_sizeof_system_thread" = x; then
2384    # use a pointer as a fallback.
2385    GLIB_SIZEOF(,void *, system_thread)
2386 fi
2387
2388 #
2389 # Hack to deal with:
2390 #
2391 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2392 #     building shared libraries with linux.
2393 #  b) FreeBSD doesn't do this either.
2394 #
2395 case $host in
2396   *-*-freebsd*|*-*-linux*)
2397     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2398     ;;
2399   *-*-openbsd*)
2400     LDFLAGS="$LDFLAGS -pthread"
2401     ;;
2402   *)
2403     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2404     ;;
2405 esac
2406
2407 AC_SUBST(G_THREAD_CFLAGS)
2408 AC_SUBST(G_THREAD_LIBS)
2409 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2410 AC_SUBST(G_THREAD_LIBS_EXTRA)
2411
2412 AC_CHECK_FUNCS(clock_gettime, [], [
2413   AC_CHECK_LIB(rt, clock_gettime, [
2414     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2415     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2416     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2417     GLIB_RT_LIBS="-lrt"
2418   ])
2419 ])
2420 AC_SUBST(GLIB_RT_LIBS)
2421
2422
2423 dnl ************************
2424 dnl *** g_atomic_* tests ***
2425 dnl ************************
2426
2427 dnl We need to decide at configure time if GLib will use real atomic
2428 dnl operations ("lock free") or emulated ones with a mutex.  This is
2429 dnl because we must put this information in glibconfig.h so we know if
2430 dnl it is safe or not to inline using compiler intrinsics directly from
2431 dnl the header.
2432 dnl
2433 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2434 dnl user is interested in knowing if they can use the atomic ops across
2435 dnl processes.
2436 dnl
2437 dnl We can currently support the atomic ops natively when building GLib
2438 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2439 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2440 dnl we are using GCC.
2441 dnl
2442 dnl Note that the atomic ops are only available with GCC on x86 when
2443 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2444 dnl not available but would be available given the right flags, we want
2445 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2446 dnl that then to silently fall back on emulated atomic ops just because
2447 dnl the user had the wrong build environment.
2448
2449 dnl We may add other compilers here in the future...
2450 AC_MSG_CHECKING([for lock-free atomic intrinsics])
2451 AC_TRY_COMPILE([],
2452                [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2453                [glib_cv_g_atomic_lock_free=yes],
2454                [glib_cv_g_atomic_lock_free=no])
2455 AC_MSG_RESULT($glib_cv_g_atomic_lock_free)
2456
2457 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2458   SAVE_CFLAGS="${CFLAGS}"
2459   CFLAGS="-march=i486"
2460   AC_TRY_COMPILE([],
2461                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2462                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2463                  [])
2464   CFLAGS="${SAVE_CFLAGS}"
2465 fi
2466
2467 dnl We need a more robust approach here...
2468 case $host_cpu in
2469   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2470     glib_memory_barrier_needed=no
2471     ;;
2472   sparc*|alpha*|powerpc*|ia64)
2473     glib_memory_barrier_needed=yes
2474     ;;
2475   *)
2476     glib_memory_barrier_needed=yes
2477     ;;
2478 esac
2479
2480 dnl ************************
2481 dnl ** Check for futex(2) **
2482 dnl ************************
2483 AC_CACHE_CHECK(for futex(2) system call,
2484     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2485 #include <linux/futex.h>
2486 #include <sys/syscall.h>
2487 #include <unistd.h>
2488 ],[
2489 int
2490 main (void)
2491 {
2492   /* it is not like this actually runs or anything... */
2493   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2494   return 0;
2495 }
2496 ])],glib_cv_futex=yes,glib_cv_futex=no))
2497 if test x"$glib_cv_futex" = xyes; then
2498   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2499 fi
2500
2501 AC_CACHE_CHECK(for eventfd(2) system call,
2502     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2503 #include <sys/eventfd.h>
2504 #include <unistd.h>
2505 ],[
2506 int
2507 main (void)
2508 {
2509   eventfd (0, EFD_CLOEXEC);
2510   return 0;
2511 }
2512 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2513 if test x"$glib_cv_eventfd" = x"yes"; then
2514   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2515 fi
2516 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2517
2518 dnl ****************************************
2519 dnl *** GLib POLL* compatibility defines ***
2520 dnl ****************************************
2521
2522 glib_poll_includes=["
2523 #include <sys/types.h>
2524 #include <sys/poll.h>
2525 "]
2526
2527 if test $ac_cv_header_sys_types_h = yes &&
2528    test $ac_cv_header_sys_poll_h = yes ; then
2529   glib_failed=false
2530   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2531   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2532   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2533   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2534   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2535   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2536   if $glib_failed ; then
2537     AC_MSG_ERROR([Could not determine values for POLL* constants])
2538   fi
2539 else
2540   glib_cv_value_POLLIN=1
2541   glib_cv_value_POLLOUT=4
2542   glib_cv_value_POLLPRI=2
2543   glib_cv_value_POLLERR=8
2544   glib_cv_value_POLLHUP=16
2545   glib_cv_value_POLLNVAL=32
2546 fi
2547
2548 AC_MSG_CHECKING([for broken poll])
2549 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2550         #include <stdlib.h>
2551         #include <fcntl.h>
2552         #include <poll.h>
2553         #ifdef HAVE_SYS_POLL_H
2554         #include <sys/poll.h>
2555         #endif
2556         int main(void) {
2557           struct pollfd fds[1];
2558           int fd;
2559           fd = open("/dev/null", 1);
2560           fds[0].fd = fd;
2561           fds[0].events = POLLIN;
2562           fds[0].revents = 0;
2563           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2564                 exit(1);  /* Does not work for devices -- fail */
2565           }
2566           exit(0);
2567         }]])],
2568   [broken_poll=no],
2569   [broken_poll=yes
2570    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2571   [broken_poll="no (cross compiling)"])
2572 AC_MSG_RESULT($broken_poll)
2573
2574 dnl *********************
2575 dnl *** GRegex checks ***
2576 dnl *********************
2577 PCRE_REQUIRED_VERSION=8.11
2578
2579 # Check if we should compile GRegex
2580 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2581                                     [disable the compilation of GRegex]),
2582 [case "${enableval}" in
2583   yes) enable_regex=true ;;
2584   no)  enable_regex=false ;;
2585   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2586 esac],
2587 [enable_regex=true])
2588
2589 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2590
2591 if test x$enable_regex = xtrue; then
2592   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2593   # Check if we should use the internal or the system-supplied pcre
2594   AC_ARG_WITH(pcre,
2595              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2596                              [whether to use system PCRE [default=internal]])])
2597
2598   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2599
2600   if test "x$with_pcre" = xsystem; then
2601     PKG_CHECK_MODULES(PCRE,
2602                       libpcre >= $PCRE_REQUIRED_VERSION)
2603     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2604                    glib_save_CFLAGS="$CFLAGS"
2605                    glib_save_LIBS="$LIBS"
2606                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2607                    AC_TRY_RUN([#include <pcre.h>
2608                                int main () {
2609                                  int support;
2610                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2611                                  if (!support)
2612                                    return 1;
2613                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2614                                  if (!support)
2615                                    return 1;
2616                                  return 0;
2617                                }],
2618                    glib_cv_pcre_has_unicode=yes,
2619                    glib_cv_pcre_has_unicode=no,
2620                    glib_cv_pcre_has_unicode=yes)
2621                    CFLAGS="$glib_save_CFLAGS"
2622                    LIBS="$glib_save_LIBS"
2623         ])
2624     if test "$glib_cv_pcre_has_unicode" = "no"; then
2625       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2626     fi
2627     AC_SUBST(PCRE_CFLAGS)
2628     AC_SUBST(PCRE_LIBS)
2629     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2630     PCRE_REQUIRES=libpcre
2631     AC_SUBST(PCRE_REQUIRES)
2632   else
2633     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2634     if test x"$GCC" = xyes; then
2635       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2636       save_CFLAGS="$CFLAGS"
2637       CFLAGS="$CFLAGS -Wno-pointer-sign"
2638       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2639                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2640       CFLAGS="$save_CFLAGS"
2641     fi
2642   fi
2643   AC_SUBST(PCRE_WARN_CFLAGS)
2644 else
2645   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2646 fi
2647
2648 dnl **********************
2649 dnl *** Win32 API libs ***
2650 dnl **********************
2651
2652 case $host in
2653   *-*-cygwin*)
2654         G_LIBS_EXTRA="-luser32 -lkernel32"
2655     ;;
2656   *-*-mingw*)
2657         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm"
2658     ;;
2659   *)
2660         G_LIBS_EXTRA=""
2661     ;;
2662 esac
2663 AC_SUBST(G_LIBS_EXTRA)
2664
2665 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2666 dnl since we need it for g_iconv()
2667
2668 AC_MSG_CHECKING([for EILSEQ])
2669 AC_TRY_COMPILE([
2670 #include <errno.h>
2671 ],
2672 [
2673 int error = EILSEQ;
2674 ], have_eilseq=yes, have_eilseq=no);
2675 AC_MSG_RESULT($have_eilseq)
2676
2677 dnl ******************************************************************
2678 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2679 dnl *** glib-compile-schemas in PATH                               ***
2680 dnl ******************************************************************
2681
2682 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2683
2684 if test $cross_compiling = yes; then
2685   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2686   if test x$GLIB_GENMARSHAL = xno; then
2687     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2688   fi
2689
2690   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2691   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2692     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2693   fi
2694 fi
2695
2696 dnl **************************
2697 dnl *** Checks for gtk-doc ***
2698 dnl **************************
2699
2700 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2701
2702 AC_ARG_ENABLE(man,
2703               [AC_HELP_STRING([--enable-man],
2704                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2705               enable_man=no)
2706
2707 if test "${enable_man}" != no; then
2708 dnl
2709 dnl Check for xsltproc
2710 dnl
2711 AC_PATH_PROG([XSLTPROC], [xsltproc])
2712   if test -z "$XSLTPROC"; then
2713     enable_man=no
2714   fi
2715
2716   dnl check for DocBook DTD and stylesheets in the local catalog.
2717   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2718      [DocBook XML DTD V4.1.2],,enable_man=no)
2719   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2720      [DocBook XSL Stylesheets],,enable_man=no)
2721 fi
2722
2723 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2724
2725 dnl
2726 dnl Tracing
2727 dnl
2728
2729 AC_ARG_ENABLE([dtrace],
2730              [AS_HELP_STRING([--enable-dtrace],
2731                               [include tracing support for dtrace])])
2732 have_dtrace=no
2733 AC_MSG_CHECKING([whether to include dtrace tracing support])
2734 if test "x$enable_dtrace" != xno; then
2735   if test x$glib_have_carbon = xyes; then
2736     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2737   else
2738     AC_MSG_RESULT([yes])
2739     AC_CHECK_PROGS(DTRACE, dtrace)
2740     if test -z "$DTRACE"; then
2741       if test "x$enable_dtrace" = xyes; then
2742         AC_MSG_ERROR([dtrace not found])
2743       fi
2744     else
2745       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2746                       [if test "x$enable_dtrace" = xyes; then
2747                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2748                        fi])
2749     fi
2750   fi
2751 else
2752   AC_MSG_RESULT([no])
2753 fi
2754 if test "x$have_dtrace" = xyes; then
2755   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2756 fi
2757 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2758
2759 AC_MSG_CHECKING([whether to include systemtap tracing support])
2760 AC_ARG_ENABLE([systemtap],
2761              [AS_HELP_STRING([--enable-systemtap],
2762                               [include tracing support for systemtap])])
2763 have_systemtap=no
2764 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2765   have_systemtap=yes
2766 fi
2767 AC_MSG_RESULT(${have_systemtap})
2768
2769 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2770
2771 AC_ARG_WITH([tapset-install-dir],
2772             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2773                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2774             [if test "x${withval}" = x; then
2775                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2776              else
2777                ABS_TAPSET_DIR="${withval}"
2778               fi],
2779             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2780 AC_SUBST(ABS_TAPSET_DIR)
2781
2782 dnl ************************************
2783 dnl *** Enable lcov coverage reports ***
2784 dnl ************************************
2785
2786 AC_ARG_ENABLE(gcov,
2787   AS_HELP_STRING([--enable-gcov],
2788                  [enable coverage testing with gcov]),
2789   [use_gcov=$enableval], [use_gcov=no])
2790
2791 if test "x$use_gcov" = "xyes"; then
2792   dnl we need gcc:
2793   if test "$GCC" != "yes"; then
2794     AC_MSG_ERROR([GCC is required for --enable-gcov])
2795   fi
2796
2797   dnl Check if ccache is being used
2798   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2799   case `$SHTOOL path $CC` in
2800     *ccache*[)] gcc_ccache=yes;;
2801     *[)] gcc_ccache=no;;
2802   esac
2803
2804   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2805     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2806   fi
2807
2808   ltp_version_list="1.6 1.7 1.8 1.9"
2809   AC_CHECK_PROG(LTP, lcov, lcov)
2810   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2811
2812   if test "$LTP"; then
2813     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2814       glib_cv_ltp_version=invalid
2815       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2816       for ltp_check_version in $ltp_version_list; do
2817         if test "$ltp_version" = "$ltp_check_version"; then
2818           glib_cv_ltp_version="$ltp_check_version (ok)"
2819         fi
2820       done
2821     ])
2822   else
2823     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2824     AC_MSG_ERROR([$ltp_msg])
2825   fi
2826
2827   case $glib_cv_ltp_version in
2828     ""|invalid[)]
2829       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2830       AC_MSG_ERROR([$ltp_msg])
2831       LTP="exit 0;"
2832       ;;
2833   esac
2834
2835   if test -z "$LTP_GENHTML"; then
2836     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2837   fi
2838
2839   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2840
2841   dnl Remove all optimization flags from CFLAGS
2842   changequote({,})
2843   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2844   changequote([,])
2845
2846   dnl Add the special gcc flags
2847   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2848   LDFLAGS="$LDFLAGS -lgcov"
2849 fi
2850
2851 dnl ******************************
2852 dnl *** output the whole stuff ***
2853 dnl ******************************
2854
2855 dnl this section will only be run if config.status is invoked with no
2856 dnl arguments, or with "glib/glibconfig.h" as an argument.
2857 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2858 [
2859         outfile=glib/glibconfig.h-tmp
2860         cat > $outfile <<\_______EOF
2861 /* glibconfig.h
2862  *
2863  * This is a generated file.  Please modify 'configure.ac'
2864  */
2865
2866 #ifndef __G_LIBCONFIG_H__
2867 #define __G_LIBCONFIG_H__
2868
2869 #include <glib/gmacros.h>
2870
2871 _______EOF
2872
2873         if test x$glib_limits_h = xyes; then
2874           echo '#include <limits.h>' >> $outfile
2875         fi
2876         if test x$glib_float_h = xyes; then
2877           echo '#include <float.h>' >> $outfile
2878         fi
2879         if test x$glib_values_h = xyes; then
2880           echo '#include <values.h>' >> $outfile
2881         fi
2882         if test "$glib_header_alloca_h" = "yes"; then
2883           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2884         fi
2885         if test x$glib_sys_poll_h = xyes; then
2886           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2887         fi
2888         if test x$glib_included_printf != xyes; then
2889           echo "
2890 /* Specifies that GLib's g_print*() functions wrap the
2891  * system printf functions.  This is useful to know, for example,
2892  * when using glibc's register_printf_function().
2893  */" >> $outfile
2894           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2895         fi
2896
2897         cat >> $outfile <<_______EOF
2898
2899 G_BEGIN_DECLS
2900
2901 #define G_MINFLOAT      $glib_mf
2902 #define G_MAXFLOAT      $glib_Mf
2903 #define G_MINDOUBLE     $glib_md
2904 #define G_MAXDOUBLE     $glib_Md
2905 #define G_MINSHORT      $glib_ms
2906 #define G_MAXSHORT      $glib_Ms
2907 #define G_MAXUSHORT     $glib_Mus
2908 #define G_MININT        $glib_mi
2909 #define G_MAXINT        $glib_Mi
2910 #define G_MAXUINT       $glib_Mui
2911 #define G_MINLONG       $glib_ml
2912 #define G_MAXLONG       $glib_Ml
2913 #define G_MAXULONG      $glib_Mul
2914
2915 _______EOF
2916
2917
2918         ### this should always be true in a modern C/C++ compiler
2919         cat >>$outfile <<_______EOF
2920 typedef signed char gint8;
2921 typedef unsigned char guint8;
2922 _______EOF
2923
2924
2925         if test -n "$gint16"; then
2926           cat >>$outfile <<_______EOF
2927 typedef signed $gint16 gint16;
2928 typedef unsigned $gint16 guint16;
2929 #define G_GINT16_MODIFIER $gint16_modifier
2930 #define G_GINT16_FORMAT $gint16_format
2931 #define G_GUINT16_FORMAT $guint16_format
2932 _______EOF
2933         fi
2934
2935
2936         if test -n "$gint32"; then
2937           cat >>$outfile <<_______EOF
2938 typedef signed $gint32 gint32;
2939 typedef unsigned $gint32 guint32;
2940 #define G_GINT32_MODIFIER $gint32_modifier
2941 #define G_GINT32_FORMAT $gint32_format
2942 #define G_GUINT32_FORMAT $guint32_format
2943 _______EOF
2944         fi
2945
2946         cat >>$outfile <<_______EOF
2947 #define G_HAVE_GINT64 1          /* deprecated, always true */
2948
2949 ${glib_extension}typedef signed $gint64 gint64;
2950 ${glib_extension}typedef unsigned $gint64 guint64;
2951
2952 #define G_GINT64_CONSTANT(val)  $gint64_constant
2953 #define G_GUINT64_CONSTANT(val) $guint64_constant
2954 _______EOF
2955
2956         if test x$gint64_format != x ; then
2957           cat >>$outfile <<_______EOF
2958 #define G_GINT64_MODIFIER $gint64_modifier
2959 #define G_GINT64_FORMAT $gint64_format
2960 #define G_GUINT64_FORMAT $guint64_format
2961 _______EOF
2962         else
2963           cat >>$outfile <<_______EOF
2964 #undef G_GINT64_MODIFIER
2965 #undef G_GINT64_FORMAT
2966 #undef G_GUINT64_FORMAT
2967 _______EOF
2968         fi
2969
2970         cat >>$outfile <<_______EOF
2971
2972 #define GLIB_SIZEOF_VOID_P $glib_void_p
2973 #define GLIB_SIZEOF_LONG   $glib_long
2974 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2975
2976 _______EOF
2977
2978         cat >>$outfile <<_______EOF
2979 typedef signed $glib_size_type_define gssize;
2980 typedef unsigned $glib_size_type_define gsize;
2981 #define G_GSIZE_MODIFIER $gsize_modifier
2982 #define G_GSSIZE_FORMAT $gssize_format
2983 #define G_GSIZE_FORMAT $gsize_format
2984
2985 #define G_MAXSIZE       G_MAXU$glib_msize_type
2986 #define G_MINSSIZE      G_MIN$glib_msize_type
2987 #define G_MAXSSIZE      G_MAX$glib_msize_type
2988
2989 typedef gint64 goffset;
2990 #define G_MINOFFSET     G_MININT64
2991 #define G_MAXOFFSET     G_MAXINT64
2992
2993 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2994 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2995 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2996
2997 _______EOF
2998
2999         if test -z "$glib_unknown_void_p"; then
3000           cat >>$outfile <<_______EOF
3001
3002 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3003 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3004
3005 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3006 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3007
3008 typedef signed $glib_intptr_type_define gintptr;
3009 typedef unsigned $glib_intptr_type_define guintptr;
3010
3011 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3012 #define G_GINTPTR_FORMAT        $gintptr_format
3013 #define G_GUINTPTR_FORMAT       $guintptr_format
3014 _______EOF
3015         else
3016           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3017         fi
3018
3019
3020
3021         cat >>$outfile <<_______EOF
3022 $glib_atexit
3023 $glib_memmove
3024 $glib_defines
3025 $glib_os
3026 $glib_static_compilation
3027
3028 $glib_vacopy
3029
3030 #ifdef  __cplusplus
3031 #define G_HAVE_INLINE   1
3032 #else   /* !__cplusplus */
3033 $glib_inline
3034 #endif  /* !__cplusplus */
3035
3036 #ifdef  __cplusplus
3037 #define G_CAN_INLINE    1
3038 _______EOF
3039
3040         if test x$g_can_inline = xyes ; then
3041                 cat >>$outfile <<_______EOF
3042 #else   /* !__cplusplus */
3043 #define G_CAN_INLINE    1
3044 _______EOF
3045         fi
3046
3047         cat >>$outfile <<_______EOF
3048 #endif
3049
3050 _______EOF
3051
3052         if test x$g_have_iso_c_varargs = xyes ; then
3053                 cat >>$outfile <<_______EOF
3054 #ifndef __cplusplus
3055 # define G_HAVE_ISO_VARARGS 1
3056 #endif
3057 _______EOF
3058         fi
3059         if test x$g_have_iso_cxx_varargs = xyes ; then
3060                 cat >>$outfile <<_______EOF
3061 #ifdef __cplusplus
3062 # define G_HAVE_ISO_VARARGS 1
3063 #endif
3064 _______EOF
3065         fi
3066         if test x$g_have_gnuc_varargs = xyes ; then
3067                 cat >>$outfile <<_______EOF
3068
3069 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3070  * is passed ISO vararg support is turned off, and there is no work
3071  * around to turn it on, so we unconditionally turn it off.
3072  */
3073 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3074 #  undef G_HAVE_ISO_VARARGS
3075 #endif
3076
3077 #define G_HAVE_GNUC_VARARGS 1
3078 _______EOF
3079         fi
3080
3081         case x$g_stack_grows in
3082         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3083         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3084         esac
3085
3086
3087         echo >>$outfile
3088         if test x$g_have_eilseq = xno; then
3089                 cat >>$outfile <<_______EOF
3090 #ifndef EILSEQ
3091 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3092  * The correspondence between this and the corresponding definition
3093  * in libiconv is essential.
3094  */
3095 #  define EILSEQ ENOENT
3096 #endif
3097 _______EOF
3098
3099         fi
3100
3101         if test x$g_have_gnuc_visibility = xyes; then
3102                 cat >>$outfile <<_______EOF
3103 #define G_HAVE_GNUC_VISIBILITY 1
3104 _______EOF
3105         fi
3106                 cat >>$outfile <<_______EOF
3107 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3108 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3109 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3110 #define G_GNUC_INTERNAL __hidden
3111 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3112 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3113 #else
3114 #define G_GNUC_INTERNAL
3115 #endif
3116 _______EOF
3117
3118         echo >>$outfile
3119         cat >>$outfile <<_______EOF
3120 #define G_THREADS_ENABLED
3121 #define G_THREADS_IMPL_$g_threads_impl_def
3122 _______EOF
3123
3124         if test x"$g_memory_barrier_needed" != xno; then
3125           echo >>$outfile
3126           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3127         fi
3128         if test x"$g_atomic_lock_free" = xyes; then
3129           echo >>$outfile
3130           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3131         fi
3132         echo >>$outfile
3133         g_bit_sizes="16 32 64"
3134         for bits in $g_bit_sizes; do
3135           cat >>$outfile <<_______EOF
3136 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3137 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3138 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3139 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3140 _______EOF
3141         done
3142
3143         cat >>$outfile <<_______EOF
3144 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3145 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3146 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3147 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3148 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3149 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3150 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3151 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3152 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3153 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3154 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3155 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3156 #define G_BYTE_ORDER $g_byte_order
3157
3158 #define GLIB_SYSDEF_POLLIN =$g_pollin
3159 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3160 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3161 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3162 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3163 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3164
3165 #define G_MODULE_SUFFIX "$g_module_suffix"
3166
3167 /* A GPid is an abstraction for a process "handle". It is *not* an
3168  * abstraction for a process identifier in general. GPid is used in
3169  * GLib only for descendant processes spawned with the g_spawn*
3170  * functions. On POSIX there is no "process handle" concept as such,
3171  * but on Windows a GPid is a handle to a process, a kind of pointer,
3172  * not a process identifier.
3173  */
3174 typedef $g_pid_type GPid;
3175
3176 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3177 #define GLIB_SYSDEF_AF_INET $g_af_inet
3178 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3179
3180 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3181 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3182 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3183
3184 G_END_DECLS
3185
3186 #endif /* GLIBCONFIG_H */
3187 _______EOF
3188
3189
3190         if cmp -s $outfile glib/glibconfig.h; then
3191           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3192           rm -f $outfile
3193         else
3194           mv $outfile glib/glibconfig.h
3195         fi
3196 ],[
3197
3198 # Note that if two cases are the same, case goes with the first one.
3199 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3200 # on variable expansion in case labels.  Look at the generated config.status
3201 # for a hint.
3202
3203 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3204   glib_header_alloca_h="$ac_cv_working_alloca_h"
3205 else
3206   glib_header_alloca_h="$ac_cv_header_alloca_h"
3207 fi
3208
3209 case xyes in
3210 x$ac_cv_header_float_h)
3211   glib_float_h=yes
3212   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3213   glib_md=DBL_MIN glib_Md=DBL_MAX
3214   ;;
3215 x$ac_cv_header_values_h)
3216   glib_values_h=yes
3217   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3218   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3219   ;;
3220 esac
3221
3222 case xyes in
3223 x$ac_cv_header_limits_h)
3224   glib_limits_h=yes
3225   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3226   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3227   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3228   ;;
3229 x$ac_cv_header_values_h)
3230   glib_values_h=yes
3231   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3232   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3233   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3234   ;;
3235 esac
3236
3237 if test x$ac_cv_header_sys_poll_h = xyes ; then
3238   glib_sys_poll_h=yes
3239 fi
3240
3241 if test x$enable_included_printf = xyes ; then
3242   glib_included_printf=yes
3243 fi
3244
3245 case 2 in
3246 $ac_cv_sizeof_short)
3247   gint16=short
3248   gint16_modifier='"h"'
3249   gint16_format='"hi"'
3250   guint16_format='"hu"'
3251   ;;
3252 $ac_cv_sizeof_int)
3253   gint16=int
3254   gint16_modifier='""'
3255   gint16_format='"i"'
3256   guint16_format='"u"'
3257   ;;
3258 esac
3259 case 4 in
3260 $ac_cv_sizeof_short)
3261   gint32=short
3262   gint32_modifier='"h"'
3263   gint32_format='"hi"'
3264   guint32_format='"hu"'
3265   ;;
3266 $ac_cv_sizeof_int)
3267   gint32=int
3268   gint32_modifier='""'
3269   gint32_format='"i"'
3270   guint32_format='"u"'
3271   ;;
3272 $ac_cv_sizeof_long)
3273   gint32=long
3274   gint32_modifier='"l"'
3275   gint32_format='"li"'
3276   guint32_format='"lu"'
3277   ;;
3278 esac
3279 case 8 in
3280 $ac_cv_sizeof_int)
3281   gint64=int
3282   gint64_modifier='""'
3283   gint64_format='"i"'
3284   guint64_format='"u"'
3285   glib_extension=
3286   gint64_constant='(val)'
3287   guint64_constant='(val)'
3288   ;;
3289 $ac_cv_sizeof_long)
3290   gint64=long
3291   gint64_modifier='"l"'
3292   gint64_format='"li"'
3293   guint64_format='"lu"'
3294   glib_extension=
3295   gint64_constant='(val##L)'
3296   guint64_constant='(val##UL)'
3297   ;;
3298 $ac_cv_sizeof_long_long)
3299   gint64='long long'
3300   if test -n "$glib_cv_long_long_format"; then
3301     gint64_modifier='"'$glib_cv_long_long_format'"'
3302     gint64_format='"'$glib_cv_long_long_format'i"'
3303     guint64_format='"'$glib_cv_long_long_format'u"'
3304   fi
3305   glib_extension='G_GNUC_EXTENSION '
3306   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3307   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3308   ;;
3309 $ac_cv_sizeof___int64)
3310   gint64='__int64'
3311   if test -n "$glib_cv_long_long_format"; then
3312     gint64_modifier='"'$glib_cv_long_long_format'"'
3313     gint64_format='"'$glib_cv_long_long_format'i"'
3314     guint64_format='"'$glib_cv_long_long_format'u"'
3315   fi
3316   glib_extension=
3317   gint64_constant='(val##i64)'
3318   guint64_constant='(val##ui64)'
3319   ;;
3320 esac
3321 glib_size_t=$ac_cv_sizeof_size_t
3322 glib_size_type_define="$glib_size_type"
3323 glib_void_p=$ac_cv_sizeof_void_p
3324 glib_long=$ac_cv_sizeof_long
3325
3326 case "$glib_size_type" in
3327 short)
3328   gsize_modifier='"h"'
3329   gsize_format='"hu"'
3330   gssize_format='"hi"'
3331   glib_msize_type='SHRT'
3332   ;;
3333 int)
3334   gsize_modifier='""'
3335   gsize_format='"u"'
3336   gssize_format='"i"'
3337   glib_msize_type='INT'
3338   ;;
3339 long)
3340   gsize_modifier='"l"'
3341   gsize_format='"lu"'
3342   gssize_format='"li"'
3343   glib_msize_type='LONG'
3344   ;;
3345 "long long"|__int64)
3346   gsize_modifier='"I64"'
3347   gsize_format='"I64u"'
3348   gssize_format='"I64i"'
3349   glib_msize_type='INT64'
3350   ;;
3351 esac
3352
3353 gintbits=`expr $ac_cv_sizeof_int \* 8`
3354 glongbits=`expr $ac_cv_sizeof_long \* 8`
3355 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3356
3357 case $ac_cv_sizeof_void_p in
3358 $ac_cv_sizeof_int)
3359   glib_intptr_type_define=int
3360   gintptr_modifier='""'
3361   gintptr_format='"i"'
3362   guintptr_format='"u"'
3363   glib_gpi_cast='(gint)'
3364   glib_gpui_cast='(guint)'
3365   ;;
3366 $ac_cv_sizeof_long)
3367   glib_intptr_type_define=long
3368   gintptr_modifier='"l"'
3369   gintptr_format='"li"'
3370   guintptr_format='"lu"'
3371   glib_gpi_cast='(glong)'
3372   glib_gpui_cast='(gulong)'
3373   ;;
3374 $ac_cv_sizeof_long_long)
3375   glib_intptr_type_define='long long'
3376   gintptr_modifier='"I64"'
3377   gintptr_format='"I64i"'
3378   guintptr_format='"I64u"'
3379   glib_gpi_cast='(gint64)'
3380   glib_gpui_cast='(guint64)'
3381   ;;
3382 $ac_cv_sizeof___int64)
3383   glib_intptr_type_define=__int64
3384   gintptr_modifier='"I64"'
3385   gintptr_format='"I64i"'
3386   guintptr_format='"I64u"'
3387   glib_gpi_cast='(gint64)'
3388   glib_gpui_cast='(guint64)'
3389   ;;
3390 *)
3391   glib_unknown_void_p=yes
3392   ;;
3393 esac
3394
3395
3396 case xyes in
3397 x$ac_cv_func_atexit)
3398   glib_atexit="
3399 #ifdef NeXT /* @#%@! NeXTStep */
3400 # define g_ATEXIT(proc) (!atexit (proc))
3401 #else
3402 # define g_ATEXIT(proc) (atexit (proc))
3403 #endif"
3404   ;;
3405 x$ac_cv_func_on_exit)
3406   glib_atexit="
3407 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3408   ;;
3409 esac
3410
3411 case xyes in
3412 x$ac_cv_func_memmove)
3413   glib_memmove='
3414 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3415   ;;
3416 x$glib_cv_working_bcopy)
3417   glib_memmove="
3418 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3419 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3420   ;;
3421 *)
3422   glib_memmove="
3423 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3424  * so we have to roll our own copy routine. */
3425 void g_memmove (void* dest, const void * src, unsigned long len);"
3426   ;;
3427 esac
3428
3429 glib_defines="
3430 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3431 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3432 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3433 "
3434
3435 case xyes in
3436 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3437 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3438 *)                      glib_vacopy=''
3439 esac
3440
3441 if test x$glib_cv_va_val_copy = xno; then
3442   glib_vacopy="\$glib_vacopy
3443 #define G_VA_COPY_AS_ARRAY 1"
3444 fi
3445
3446 if test x$glib_cv_hasinline = xyes; then
3447     glib_inline='#define G_HAVE_INLINE 1'
3448 fi
3449 if test x$glib_cv_has__inline = xyes; then
3450     glib_inline="\$glib_inline
3451 #define G_HAVE___INLINE 1"
3452 fi
3453 if test x$glib_cv_has__inline__ = xyes; then
3454     glib_inline="\$glib_inline
3455 #define G_HAVE___INLINE__ 1"
3456 fi
3457
3458 g_have_gnuc_varargs=$g_have_gnuc_varargs
3459 g_have_iso_c_varargs=$g_have_iso_c_varargs
3460 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3461
3462 g_can_inline=$g_can_inline
3463 g_have_gnuc_visibility=$g_have_gnuc_visibility
3464 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3465
3466 if test x$ac_cv_c_bigendian = xyes; then
3467   g_byte_order=G_BIG_ENDIAN
3468   g_bs_native=BE
3469   g_bs_alien=LE
3470 else
3471   g_byte_order=G_LITTLE_ENDIAN
3472   g_bs_native=LE
3473   g_bs_alien=BE
3474 fi
3475
3476 g_pollin=$glib_cv_value_POLLIN
3477 g_pollout=$glib_cv_value_POLLOUT
3478 g_pollpri=$glib_cv_value_POLLPRI
3479 g_pollhup=$glib_cv_value_POLLHUP
3480 g_pollerr=$glib_cv_value_POLLERR
3481 g_pollnval=$glib_cv_value_POLLNVAL
3482
3483 g_af_unix=$glib_cv_value_AF_UNIX
3484 g_af_inet=$glib_cv_value_AF_INET
3485 g_af_inet6=$glib_cv_value_AF_INET6
3486
3487 g_msg_peek=$glib_cv_value_MSG_PEEK
3488 g_msg_oob=$glib_cv_value_MSG_OOB
3489 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3490
3491 g_stack_grows=$glib_cv_stack_grows
3492
3493 g_have_eilseq=$have_eilseq
3494
3495 g_threads_impl_def=$g_threads_impl
3496
3497 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3498
3499 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3500 g_memory_barrier_needed="$glib_memory_barrier_needed"
3501 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3502
3503 g_module_suffix="$glib_gmodule_suffix"
3504
3505 g_pid_type="$glib_pid_type"
3506 case $host in
3507   *-*-beos*)
3508     glib_os="#define G_OS_BEOS"
3509     ;;
3510   *-*-cygwin*)
3511     glib_os="#define G_OS_UNIX
3512 #define G_PLATFORM_WIN32
3513 #define G_WITH_CYGWIN"
3514     ;;
3515   *-*-mingw*)
3516     glib_os="#define G_OS_WIN32
3517 #define G_PLATFORM_WIN32"
3518     ;;
3519   *)
3520     glib_os="#define G_OS_UNIX"
3521     ;;
3522 esac
3523 glib_static_compilation=""
3524 if test x$glib_win32_static_compilation = xyes; then
3525   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3526 #define GOBJECT_STATIC_COMPILATION 1"
3527 fi
3528 ])
3529
3530 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3531 #
3532 # 1.2.14 required for dbus_message_set_serial
3533 PKG_CHECK_MODULES(DBUS1,
3534                   dbus-1 >= 1.2.14,
3535                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3536                   have_dbus1=no)
3537 AC_SUBST(DBUS1_CFLAGS)
3538 AC_SUBST(DBUS1_LIBS)
3539 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3540
3541 dnl
3542 dnl Check for -Bsymbolic-functions linker flag used to avoid
3543 dnl intra-library PLT jumps, if available.
3544 dnl
3545
3546 AC_ARG_ENABLE(Bsymbolic,
3547               [AC_HELP_STRING([--disable-Bsymbolic],
3548                               [avoid linking with -Bsymbolic])],,
3549               [SAVED_LDFLAGS="${LDFLAGS}"
3550                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3551                LDFLAGS=-Wl,-Bsymbolic-functions
3552                AC_TRY_LINK([], [int main (void) { return 0; }],
3553                            AC_MSG_RESULT(yes)
3554                            enable_Bsymbolic=yes,
3555                            AC_MSG_RESULT(no)
3556                            enable_Bsymbolic=no)
3557                LDFLAGS="${SAVED_LDFLAGS}"])
3558
3559 if test "x${enable_Bsymbolic}" == "xyes"; then
3560   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3561 fi
3562
3563 AC_SUBST(GLIB_LINK_FLAGS)
3564
3565 #
3566 # Define variables corresponding to the correct include paths to use for
3567 # in-tree building.
3568 #
3569
3570 # for config.h:
3571 config_h_INCLUDES='-I$(top_builddir)'
3572 AC_SUBST(config_h_INCLUDES)
3573
3574 # glib:
3575 #   config.h
3576 #   $(top_builddir)/glib: for glibconfig.h
3577 #   $(top_srcdir)/glib:   for glib.h
3578 #   $(top_srcdir):        for everything
3579 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3580 AC_SUBST(glib_INCLUDES)
3581
3582 # gthread:
3583 #   same as glib
3584 gthread_INCLUDES='$(glib_INCLUDES)'
3585 AC_SUBST(gthread_INCLUDES)
3586
3587 # gobject:
3588 #   same as gthread
3589 gobject_INCLUDES='$(gthread_INCLUDES)'
3590 AC_SUBST(gobject_INCLUDES)
3591
3592 # gmodule:
3593 #   glib includes
3594 #   $(top_srcdir)/gmodule: for gmodule.h
3595 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3596 AC_SUBST(gmodule_INCLUDES)
3597
3598 # gio:
3599 #   same as gmodule
3600 gio_INCLUDES='$(gmodule_INCLUDES)'
3601 AC_SUBST(gio_INCLUDES)
3602
3603
3604 AC_CONFIG_FILES([
3605 glib-2.0.pc
3606 gmodule-2.0.pc
3607 gmodule-export-2.0.pc
3608 gmodule-no-export-2.0.pc
3609 gthread-2.0.pc
3610 gobject-2.0.pc
3611 gio-2.0.pc
3612 gio-unix-2.0.pc
3613 gio-windows-2.0.pc
3614 glib-zip
3615 glib-gettextize
3616 Makefile
3617 build/Makefile
3618 build/win32/Makefile
3619 build/win32/dirent/Makefile
3620 build/win32/vs9/Makefile
3621 build/win32/vs10/Makefile
3622 glib/Makefile
3623 glib/glib.stp
3624 glib/libcharset/Makefile
3625 glib/gnulib/Makefile
3626 glib/pcre/Makefile
3627 glib/update-pcre/Makefile
3628 glib/tests/Makefile
3629 gmodule/Makefile
3630 gmodule/gmoduleconf.h
3631 gobject/Makefile
3632 gobject/gobject.stp
3633 gobject/glib-mkenums
3634 gobject/tests/Makefile
3635 gthread/Makefile
3636 gio/Makefile
3637 gio/gdbus-2.0/codegen/Makefile
3638 gio/gdbus-2.0/codegen/config.py
3639 gio/xdgmime/Makefile
3640 gio/inotify/Makefile
3641 gio/fen/Makefile
3642 gio/fam/Makefile
3643 gio/win32/Makefile
3644 gio/tests/Makefile
3645 gio/tests/gdbus-object-manager-example/Makefile
3646 po/Makefile.in
3647 docs/Makefile
3648 docs/reference/Makefile
3649 docs/reference/glib/Makefile
3650 docs/reference/glib/version.xml
3651 docs/reference/gobject/Makefile
3652 docs/reference/gobject/version.xml
3653 docs/reference/gio/Makefile
3654 docs/reference/gio/gdbus-object-manager-example/Makefile
3655 docs/reference/gio/version.xml
3656 tests/Makefile
3657 tests/gobject/Makefile
3658 tests/refcount/Makefile
3659 m4macros/Makefile
3660 ])
3661
3662 AC_CONFIG_COMMANDS([chmod-scripts],
3663 [chmod 0755 glib-zip
3664 chmod 0755 glib-gettextize
3665 chmod 0755 gobject/glib-mkenums])
3666
3667 # we want to invoke this macro solely so that the config.status script
3668 # and automake generated makefiles know about these generated files.
3669 # They are only needed to distcheck the package
3670 if false; then
3671   AC_CONFIG_FILES([
3672     INSTALL
3673     README
3674     config.h.win32
3675     glib/glibconfig.h.win32
3676     glib/makefile.msc
3677     glib/glib.rc
3678     gmodule/makefile.msc
3679     gmodule/gmodule.rc
3680     gobject/makefile.msc
3681     gobject/gobject.rc
3682     gthread/makefile.msc
3683     gthread/gthread.rc
3684     gio/gio.rc
3685     tests/makefile.msc
3686   ])
3687 fi
3688
3689 AC_OUTPUT