configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 GLIB_REQUIRED=2.31.13
  32 VALA_REQUIRED=0.16.1
  33 VALADOC_REQUIRED=0.2
  34 GSSDP_REQUIRED=0.11.0
  35 GUPNP_REQUIRED=0.17.1
  36 GUPNP_AV_REQUIRED=0.9.0
  37 GUPNP_DLNA_REQUIRED=0.5.0
  38 GUPNP_VALA_REQUIRED=0.10.2
  39 GSTREAMER_REQUIRED=0.10.36
  40 GSTPBU_REQUIRED=0.10.35
  41 GIO_REQUIRED=2.26
  42 GEE_REQUIRED=0.5.2
  43 UUID_REQUIRED=1.41.3
  44 LIBSOUP_REQUIRED=2.34.0
  45 GTK_REQUIRED=2.90.3
  46
  47 dnl Additional requirements for media-export plugin
  48 GSTREAMER_TAG_REQUIRED=0.10.28
  49 GSTREAMER_APP_REQUIRED=0.10.28
  50 LIBSQLITE3_REQUIRED=3.5
  51
  52 dnl Additional requirements for tracker plugin
  53 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  54
  55 PKG_CHECK_MODULES(LIBGLIB, glib-2.0 >= $GLIB_REQUIRED)
  56 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  57
  58 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED)
  59 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  60 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  61 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  62 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  63 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  64 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  65
  66 dnl Media engine to use
  67 BUILT_ENGINES="librygel-media-engine-simple"
  68
  69 AC_ARG_WITH([media_engine],
  70             AS_HELP_STRING(
  71                 [--with-media-engine=@<:@gstreamer|none@:>@],
  72                 [Media Engine to use]),
  73             [with_media_engine="$withval"],
  74             [with_media_engine="gstreamer"])
  75
  76 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  77       [
  78         PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED)
  79         PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  80         PKG_CHECK_MODULES(GSTREAMER_BASE, gstreamer-base-0.10 >= $GSTREAMER_REQUIRED)
  81         PKG_CHECK_MODULES(GST_PBU, gstreamer-pbutils-0.10 >= $GSTPBU_REQUIRED)
  82         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_1_0_la_vala.stamp])
  83         enable_gstreamer="yes"
  84         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
  85       ],
  86       [enable_gstreamer="no"])
  87 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
  88 AC_SUBST([BUILT_ENGINES])
  89
  90 dnl Add plugins
  91 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
  92 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
  93 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
  94 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
  95
  96 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  97       [
  98         RYGEL_ADD_PLUGIN([test],[Test],[no])
  99         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
 100         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 101         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 102         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 103       ],
 104       [
 105         RYGEL_DISABLE_PLUGIN([test])
 106         RYGEL_DISABLE_PLUGIN([playbin])
 107         RYGEL_DISABLE_PLUGIN([media-export])
 108         RYGEL_DISABLE_PLUGIN([gst-launch])
 109       ])
 110
 111 dnl Explicitly add stamp files for targets that are not plugins
 112 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_1_0_la_vala.stamp])
 113 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_1_0_la_vala.stamp])
 114 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_1_0_la_vala.stamp])
 115 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 116 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 117 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 118
 119 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 120                  [gupnp-1.0
 121                   gupnp-av-1.0
 122                   gio-2.0
 123                   gee-1.0
 124                   posix])
 125
 126 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 127       [
 128         RYGEL_CHECK_PACKAGES([gupnp-dlna-1.0 gstreamer-0.10 gstreamer-pbutils-0.10])
 129       ])
 130
 131 dnl Debugging
 132 AC_ARG_ENABLE(debug,
 133         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 134         enable_debug=no)
 135 if test "x$enable_debug" = "xyes"; then
 136         CFLAGS="$CFLAGS -O0 -g"
 137         RYGEL_DEBUG_VALAFLAGS="-g"
 138 fi
 139
 140 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 141
 142 dnl Strict compiler
 143 AC_ARG_ENABLE(strict-cc,
 144         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 145         enable_strict_cc=no)
 146 if test "x$enable_strict_cc" = "xyes"; then
 147         CFLAGS="$CFLAGS -Wall -Werror"
 148 else
 149         CFLAGS="$CFLAGS -w"
 150 fi
 151
 152 dnl Run uninstalled
 153 AC_ARG_ENABLE(uninstalled,
 154     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 155         enable_uninstalled=no)
 156 if test "x$enable_uninstalled" = "xyes"; then
 157         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 158 fi
 159 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 160
 161 dnl Check wether user wants to build UIs
 162 AC_ARG_WITH( ui,
 163   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 164   try_ui=$withval, try_ui=yes )
 165
 166 HAVE_GTK=no
 167 if test x$try_ui = xyes ; then
 168     dnl check for gtk
 169     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 170       [
 171         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 172       ],
 173       [
 174         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 175         AC_MSG_WARN([UI applications will not be built.])
 176       ])
 177 else
 178     AC_MSG_NOTICE([UI applications disabled.])
 179 fi
 180
 181 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 182
 183 dnl Tests
 184 AC_ARG_ENABLE([tests],
 185               AS_HELP_STRING([--enable-tests],[always build tests]),,
 186               enable_tests=no)
 187 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 188
 189 dnl Generate coverage data
 190 AC_ARG_ENABLE([coverage],
 191   AS_HELP_STRING([--enable-coverage],
 192                  [Generate converage reports for unit tests]),
 193   [],
 194   [enable_coverage=no])
 195 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 196 AS_IF([test "x$enable_coverage" != "xno"],
 197   [
 198     AC_PATH_PROG([LCOV], [lcov])
 199     AC_PATH_PROG([GENHTML], [genhtml])
 200     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 201     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 202     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 203   ]
 204 )
 205
 206 dnl Check additional requirements for MediaExport plugins
 207 if test "x$enable_media_export_plugin" = "xyes";
 208 then
 209     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 210     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 211     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 212     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-0.10 gstreamer-app-0.10])
 213     AC_CHECK_HEADER([unistr.h],
 214                     AC_CHECK_LIB([unistring],
 215                                  [u8_strcoll],
 216                                  [have_unistring=yes],[have_unistring=no]))
 217     if test "x$have_unistring" = "xyes"; then
 218         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 219         COLLATION_CFLAGS=
 220         COLLATION_LIBS=-lunistring
 221         AC_SUBST([COLLATION_CFLAGS])
 222         AC_SUBST([COLLATION_LIBS])
 223     fi
 224 fi
 225
 226 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 227   [
 228     PKG_CHECK_MODULES(TRACKER_SPARQL,
 229                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN)
 230     AS_IF([test "x$enable_vala" = "xyes"],
 231           [VALA_CHECK_PACKAGES([tracker-sparql-0.14])])
 232   ])
 233
 234 dnl Gettext
 235 GETTEXT_PACKAGE=rygel
 236 AC_SUBST(GETTEXT_PACKAGE)
 237 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 238   [Define the gettext package to be used])
 239
 240 AM_GLIB_GNU_GETTEXT
 241 IT_PROG_INTLTOOL([0.40.0])
 242
 243 dnl Shave the output
 244 AM_SILENT_RULES([yes])
 245
 246 dnl documenation
 247 AC_PATH_PROG([XSLTPROC], [xsltproc])
 248 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 249
 250 dnl Use valadoc for API documentation:
 251 AC_ARG_ENABLE(valadoc,
 252   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 253     [enable_valadoc=auto])
 254
 255 found_valadoc=no
 256 AS_IF([test "x$enable_valadoc" != "xno"], [
 257     AC_PATH_PROG(VALADOC, valadoc, :)
 258     AS_IF([test -x "$VALADOC"], [
 259       found_valadoc=yes
 260       AC_SUBST(VALADOC)
 261       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0])
 262     ], [
 263       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 264     ])
 265   ])
 266
 267 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 268
 269 AC_CONFIG_FILES([
 270 Makefile
 271 src/Makefile
 272 src/librygel-core/Makefile
 273 src/librygel-renderer/Makefile
 274 src/librygel-renderer-gst/Makefile
 275 src/librygel-server/Makefile
 276 src/rygel/Makefile
 277 src/ui/Makefile
 278 src/media-engines/Makefile
 279 src/media-engines/gstreamer/Makefile
 280 src/media-engines/simple/Makefile
 281 src/plugins/Makefile
 282 data/Makefile
 283 data/xml/Makefile
 284 data/icons/Makefile
 285 data/icons/32x32/Makefile
 286 data/icons/48x48/Makefile
 287 data/icons/120x120/Makefile
 288 data/icons/128x128/Makefile
 289 data/icons/scalable/Makefile
 290 data/rygel.desktop.in
 291 data/rygel-preferences.desktop.in
 292 doc/Makefile
 293 doc/reference/Makefile
 294 doc/reference/librygel-core/Makefile
 295 doc/reference/librygel-renderer/Makefile
 296 doc/reference/librygel-server/Makefile
 297 doc/reference/librygel-renderer-gst/Makefile
 298 po/Makefile.in
 299 rygel-core-1.0.pc
 300 rygel-renderer-1.0.pc
 301 rygel-server-1.0.pc
 302 rygel-renderer-gst-1.0.pc
 303 tests/Makefile
 304 examples/Makefile
 305 ])
 306 AC_OUTPUT
 307
 308 echo "
 309
 310                     ${PACKAGE} ${VERSION}
 311                     ============
 312
 313
 314         Prefix:                 ${prefix}
 315         Source code location:   ${srcdir}
 316         Compiler:               ${CC}
 317         CFLAGS:                 ${CFLAGS}
 318         VALAFLAGS:              ${VALAFLAGS}
 319         uninstalled:            ${enable_uninstalled}
 320         preferences ui:         ${HAVE_GTK}
 321         Media Engine:           ${with_media_engine}
 322     Plugins:
 323         test:                   ${enable_test_plugin}
 324         tracker:                ${enable_tracker_plugin}
 325         mediathek:              ${enable_mediathek_plugin}
 326         media-export            ${enable_media_export_plugin}
 327         external:               ${enable_external_plugin}
 328         MPRIS2:                 ${enable_mpris_plugin}
 329         gst-launch:             ${enable_gst_launch_plugin}
 330         playbin:                ${enable_playbin_plugin}
 331 "