configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [39])
  34 m4_define([glib_micro_version], [2])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 AC_MSG_CHECKING([for the BeOS])
 121 case $host in
 122   *-*-beos*)
 123     glib_native_beos="yes"
 124     ;;
 125   *)
 126     glib_native_beos="no"
 127     ;;
 128 esac
 129 AC_MSG_RESULT([$glib_native_beos])
 130
 131 dnl
 132
 133 AC_MSG_CHECKING([for Win32])
 134 LIB_EXE_MACHINE_FLAG=X86
 135 case "$host" in
 136   *-*-mingw*)
 137     glib_native_win32=yes
 138     glib_pid_type='void *'
 139     glib_cv_stack_grows=no
 140     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 141     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 142     # (Sorry, I don't know exactly what is the problem, but it is related to
 143     # floating point formatting and decimal point vs. comma.)
 144     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 145     # rigorous enough to notice, though.
 146     # So preset the autoconf cache variables.
 147     ac_cv_func_vsnprintf_c99=no
 148     ac_cv_func_snprintf_c99=no
 149     case "$host" in
 150     x86_64-*-*)
 151       LIB_EXE_MACHINE_FLAG=X64
 152       ;;
 153     esac
 154
 155     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 156     ;;
 157   *)
 158     glib_native_win32=no
 159     glib_pid_type=int
 160     ;;
 161 esac
 162 case $host in
 163   *-*-linux*)
 164     glib_os_linux=yes
 165     ;;
 166 esac
 167
 168 AC_MSG_RESULT([$glib_native_win32])
 169
 170 AC_MSG_CHECKING([for the Android])
 171 case $host in
 172   *android*)
 173     glib_native_android="yes"
 174     ;;
 175   *)
 176     glib_native_android="no"
 177     ;;
 178 esac
 179 AC_MSG_RESULT([$glib_native_android])
 180
 181 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 182
 183 glib_have_carbon=no
 184 AC_MSG_CHECKING([for Mac OS X Carbon support])
 185 AC_TRY_CPP([
 186 #include <Carbon/Carbon.h>
 187 #include <CoreServices/CoreServices.h>
 188 ], glib_have_carbon=yes)
 189
 190 AC_MSG_RESULT([$glib_have_carbon])
 191
 192 glib_have_cocoa=no
 193 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 194 AC_TRY_CPP([
 195 #include <Cocoa/Cocoa.h>
 196 #ifdef GNUSTEP_BASE_VERSION
 197 #error "Detected GNUstep, not Cocoa"
 198 #endif
 199 ], glib_have_cocoa=yes)
 200
 201 AC_MSG_RESULT([$glib_have_cocoa])
 202
 203 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 204 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 205 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 206 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 207 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 208 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 209
 210 AS_IF([test "$glib_native_win32" = "yes"], [
 211   AC_CHECK_TOOL(WINDRES, windres, no)
 212   if test "$WINDRES" = no; then
 213     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 214   fi
 215   AC_CHECK_TOOL(NM, nm, no)
 216   if test "$NM" = no; then
 217     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 218   fi
 219   AC_CHECK_TOOL(RANLIB, ranlib, :)
 220   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 221   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 222 ])
 223 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 224
 225 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 226   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 227   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 228 ])
 229
 230 if test "x$glib_have_cocoa" = "xyes"; then
 231   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 232   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 233 fi
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 239               enable_debug=glib_debug_default)
 240
 241 AC_ARG_ENABLE(gc_friendly,
 242               [AS_HELP_STRING([--enable-gc-friendly],
 243                               [turn on garbage collector friendliness [default=no]])],,
 244               [enable_gc_friendly=no])
 245 AC_ARG_ENABLE(mem_pools,
 246               [AS_HELP_STRING([--disable-mem-pools],
 247                               [disable all glib memory pools])],,
 248               [disable_mem_pools=no])
 249 AC_ARG_ENABLE(rebuilds,
 250               [AS_HELP_STRING([--disable-rebuilds],
 251                               [disable all source autogeneration rules])],,
 252               [enable_rebuilds=yes])
 253
 254 GLIB_TESTS
 255
 256 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 257 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 258   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 259   AC_MSG_RESULT([yes])
 260 ], [ AC_MSG_RESULT([no]) ])
 261
 262 AC_MSG_CHECKING([whether to disable memory pools])
 263 AS_IF([test "x$disable_mem_pools" = "xno"], [
 264   AC_MSG_RESULT([no])
 265 ], [
 266   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 267   AC_MSG_RESULT([yes])
 268 ])
 269
 270 dnl location to install runtime libraries, e.g. ../../lib to install
 271 dnl to /lib if libdir is /usr/lib
 272 AC_ARG_WITH(runtime-libdir,
 273            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 274                            [install runtime libraries relative to libdir])],
 275            [],
 276            [with_runtime_libdir=""])
 277 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 278 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 279 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 280 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 281 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 282
 283 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 284 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 285 AC_LANG_SAVE
 286 AC_LANG_CPLUSPLUS
 287 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 288 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 289 AC_LANG_RESTORE
 290
 291 AM_PROG_CC_C_O
 292 AC_PROG_INSTALL
 293
 294 AC_SYS_LARGEFILE
 295
 296 PKG_PROG_PKG_CONFIG(0.16)
 297
 298 if test "x$enable_debug" = "xyes"; then
 299   if test x$cflags_set != xset ; then
 300       case " $CFLAGS " in
 301       *[[\ \    ]]-g[[\ \       ]]*) ;;
 302       *) CFLAGS="$CFLAGS -g" ;;
 303       esac
 304   fi
 305   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 306 else
 307   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 308
 309   if test "x$enable_debug" = "xno"; then
 310     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 311   fi
 312 fi
 313
 314 # Ensure MSVC-compatible struct packing convention is used when
 315 # compiling for Win32 with gcc.
 316 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 317 # gcc2 uses "-fnative-struct".
 318 if test x"$glib_native_win32" = xyes; then
 319   if test x"$GCC" = xyes; then
 320     msnative_struct=''
 321     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 322     if test -z "$ac_cv_prog_CC"; then
 323       our_gcc="$CC"
 324     else
 325       our_gcc="$ac_cv_prog_CC"
 326     fi
 327     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 328       2.)
 329         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 330           msnative_struct='-fnative-struct'
 331         fi
 332         ;;
 333       *)
 334         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 335           msnative_struct='-mms-bitfields'
 336         fi
 337         ;;
 338     esac
 339     if test x"$msnative_struct" = x ; then
 340       AC_MSG_RESULT([no way])
 341       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 342     else
 343       CFLAGS="$CFLAGS $msnative_struct"
 344       AC_MSG_RESULT([${msnative_struct}])
 345     fi
 346   fi
 347 fi
 348 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 349 AC_SUBST(GLIB_EXTRA_CFLAGS)
 350
 351 AC_EXEEXT
 352
 353 # define a MAINT-like variable REBUILD which is set if Perl
 354 # and awk are found, so autogenerated sources can be rebuilt
 355 AC_PROG_AWK
 356 AC_CHECK_PROGS(PERL, [perl5 perl])
 357 # We would like indent, but don't require it.
 358 AC_CHECK_PROG(INDENT, indent, indent)
 359 REBUILD=\#
 360 if test "x$enable_rebuilds" = "xyes" && \
 361      test -n "$PERL" && \
 362      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 363      test -n "$AWK" ; then
 364   REBUILD=
 365 fi
 366 AC_SUBST(REBUILD)
 367
 368 # Need full path to Perl for glib-mkenums
 369 #
 370 if test "x$PERL" != x ; then
 371   AC_PATH_PROG(PERL_PATH, [$PERL])
 372 fi
 373 if test "x$PERL_PATH" = x ; then
 374   PERL_PATH="/usr/bin/env perl"
 375 fi
 376 AC_SUBST(PERL_PATH)
 377
 378 # option to specify python interpreter to use; this just sets $PYTHON, so that
 379 # we will fallback to reading $PYTHON if --with-python is not given, and
 380 # python.m4 will get the expected input
 381 AC_ARG_WITH(python,
 382             AS_HELP_STRING([--with-python=PATH],
 383                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 384             [PYTHON="$withval"], [])
 385 if test x"$PYTHON" = xyes; then
 386   AC_MSG_ERROR([--with-python option requires a path or program argument])
 387 fi
 388 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 389
 390
 391 dnl ***********************
 392 dnl *** Tests for iconv ***
 393 dnl ***********************
 394 dnl
 395 dnl We do this before the gettext checks, to avoid distortion
 396
 397 dnl On Windows we use a native implementation
 398
 399 AS_IF([ test x"$glib_native_win32" = xyes], [
 400   with_libiconv=native
 401 ], [
 402   AC_ARG_WITH(libiconv,
 403               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 404                               [use the libiconv library])],,
 405               [with_libiconv=maybe])
 406
 407   found_iconv=no
 408   case $with_libiconv in
 409     maybe)
 410       # Check in the C library first
 411       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 412       # Check if we have GNU libiconv
 413       if test $found_iconv = "no"; then
 414         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 415       fi
 416       # Check if we have a iconv in -liconv, possibly from vendor
 417       if test $found_iconv = "no"; then
 418         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 419       fi
 420       ;;
 421     no)
 422       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 423       ;;
 424     gnu|yes)
 425       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 426       ;;
 427     native)
 428       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 429       ;;
 430   esac
 431
 432   if test "x$found_iconv" = "xno" ; then
 433      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 434   fi
 435 ])
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 AS_IF([test "x$found_zlib" = "xno"], [
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 ])
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 AS_IF([test x"$glib_native_win32" != xyes], [
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 ])
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 AS_IF([test "$glib_native_win32" = "yes"], [
 509   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 510     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 511   fi
 512   if test x$enable_static = xyes; then
 513     glib_win32_static_compilation=yes
 514     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 515 #define GOBJECT_STATIC_COMPILATION 1"
 516     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 517   fi
 518 ])
 519 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 520
 521 dnl
 522 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 523 dnl
 524 AS_IF([test $cross_compiling != yes], [
 525     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 526     glib_save_LIBS=$LIBS
 527     LIBS="$LIBS -lm"
 528     AC_TRY_RUN([#include <math.h>
 529                  int main (void) { return (log(1) != log(1.)); }],
 530          AC_MSG_RESULT(none needed),
 531          glib_save_CFLAGS=$CFLAGS
 532          CFLAGS="$CFLAGS -std1"
 533          AC_TRY_RUN([#include <math.h>
 534                      int main (void) { return (log(1) != log(1.)); }],
 535              AC_MSG_RESULT(-std1),
 536              AC_MSG_RESULT()
 537              CFLAGS=$glib_save_CFLAGS
 538              AC_MSG_WARN(
 539                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 540          )
 541     )
 542     LIBS=$glib_save_LIBS
 543 ])
 544
 545 dnl NeXTStep cc seems to need this
 546 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 547 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 548   AC_MSG_RESULT(none needed),
 549   glib_save_CFLAGS=$CFLAGS
 550   CFLAGS="$CFLAGS -posix"
 551   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 552     AC_MSG_RESULT(-posix),
 553     AC_MSG_RESULT()
 554     CFLAGS=$glib_save_CFLAGS
 555     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 556
 557 # Checks for library functions.
 558 AC_FUNC_VPRINTF
 559 AC_FUNC_ALLOCA
 560 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 561 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 562
 563 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 564   [AC_TRY_LINK([#include <unistd.h>
 565     extern int __libc_enable_secure;],
 566     [return __libc_enable_secure;],
 567    glib_cv_have_libc_enable_secure=yes,
 568    glib_cv_have_libc_enable_secure=no)])
 569 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 570    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 571      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 572 ])
 573
 574 AC_CHECK_SIZEOF(char)
 575 AC_CHECK_SIZEOF(short)
 576 AC_CHECK_SIZEOF(long)
 577 AC_CHECK_SIZEOF(int)
 578 AC_CHECK_SIZEOF(void *)
 579 AC_CHECK_SIZEOF(long long)
 580 AC_CHECK_SIZEOF(__int64)
 581
 582 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 583   [AC_TRY_LINK([#include <signal.h>
 584      #include <sys/types.h>
 585      sig_atomic_t val = 42;],
 586     [return val == 42 ? 0 : 1],
 587    ac_cv_type_sig_atomic_t=yes,
 588    ac_cv_type_sig_atomic_t=no)])
 589 if test x$ac_cv_type_sig_atomic_t = xyes; then
 590    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 591      [Define if you have the 'sig_atomic_t' type.])
 592 fi
 593
 594 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 595   :
 596 else
 597   AC_MSG_ERROR([
 598 *** GLib requires a 64 bit type. You might want to consider
 599 *** using the GNU C compiler.
 600 ])
 601 fi
 602
 603 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 604         # long long is a 64 bit integer.
 605         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 606         AC_CACHE_VAL(glib_cv_long_long_format,[
 607                 for format in ll q I64; do
 608                   AC_TRY_RUN([#include <stdio.h>
 609                         int main()
 610                         {
 611                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 612                           char buffer[1000];
 613                           sprintf (buffer, "%${format}u", a);
 614                           sscanf (buffer, "%${format}u", &b);
 615                           exit (b!=a);
 616                         }
 617                         ],
 618                         [glib_cv_long_long_format=${format}
 619                         break],
 620                         [],[:])
 621                 done])
 622         AS_IF([ test -n "$glib_cv_long_long_format"], [
 623           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 624           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 625           if test x"$glib_cv_long_long_format" = xI64; then
 626             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 627           fi
 628         ], [AC_MSG_RESULT(none)])
 629 ],[ test x$ac_cv_sizeof___int64 = x8], [
 630         # __int64 is a 64 bit integer.
 631         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 632         # We know this is MSVCRT.DLL, and what the formats are
 633         glib_cv_long_long_format=I64
 634         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 635         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 636         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 637 ])
 638
 639 AC_C_CONST
 640
 641 dnl
 642 dnl check in which direction the stack grows
 643 dnl
 644 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 645         AC_TRY_RUN([
 646         volatile int *a = 0, *b = 0;
 647         void foo (void);
 648         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 649         void foo (void) { volatile int x = 5; b = &x; }
 650         ],
 651         glib_cv_stack_grows=no
 652         ,
 653         glib_cv_stack_grows=yes
 654         ,)
 655 ])
 656
 657 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 658 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 659 dnl actually supported.
 660 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 661         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 662         __inline int foo () { return 0; }
 663         int main () { return foo (); }
 664         ]])],
 665         glib_cv_has__inline=yes
 666         ,
 667         glib_cv_has__inline=no
 668         ,)
 669 ])
 670 case x$glib_cv_has__inline in
 671 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 672 esac
 673 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 674         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 675         __inline__ int foo () { return 0; }
 676         int main () { return foo (); }
 677         ]])],
 678         glib_cv_has__inline__=yes
 679         ,
 680         glib_cv_has__inline__=no
 681         ,)
 682 ])
 683 case x$glib_cv_has__inline__ in
 684 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 685 esac
 686 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 687         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 688         #undef inline
 689         inline int foo () { return 0; }
 690         int main () { return foo (); }
 691         ]])],
 692         glib_cv_hasinline=yes
 693         ,
 694         glib_cv_hasinline=no
 695         ,)
 696 ])
 697 case x$glib_cv_hasinline in
 698 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 699 esac
 700
 701 # if we can use inline functions in headers
 702 AC_MSG_CHECKING(if inline functions in headers work)
 703 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 704 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 705 #  undef inline
 706 #  define inline __inline__
 707 #elif !defined (G_HAVE_INLINE)
 708 #  undef inline
 709 #  if defined (G_HAVE___INLINE__)
 710 #    define inline __inline__
 711 #  elif defined (G_HAVE___INLINE)
 712 #    define inline __inline
 713 #  endif
 714 #endif
 715
 716 int glib_test_func2 (int);
 717
 718 static inline int
 719 glib_test_func1 (void) {
 720   return glib_test_func2 (1);
 721 }
 722
 723 int
 724 main (void) {
 725   int i = 1;
 726 }]])],[g_can_inline=yes],[g_can_inline=no])
 727 AC_MSG_RESULT($g_can_inline)
 728
 729 dnl *** check for working do while(0) macros ***
 730 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 731         AC_TRY_COMPILE([],[
 732         #define STMT_START do
 733         #define STMT_END while(0)
 734         #define STMT_TEST STMT_START { i = 0; } STMT_END
 735         int main(void) { int i = 1; STMT_TEST; return i; }],
 736         [g_cv_support_dowhile_macros=yes],
 737         [g_cv_support_dowhile_macros=no],
 738         [g_cv_support_dowhile_macros=yes])
 739 ])
 740 if test x$g_cv_support_dowhile_macros = xyes; then
 741   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 742 fi
 743
 744 # check for flavours of varargs macros
 745 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 746 AC_TRY_COMPILE([],[
 747 int a(int p1, int p2, int p3);
 748 #define call_a(...) a(1,__VA_ARGS__)
 749 call_a(2,3);
 750 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 751 AC_MSG_RESULT($g_have_iso_c_varargs)
 752
 753 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 754 AS_IF([test "$CXX" = ""], [
 755 dnl No C++ compiler
 756   g_have_iso_cxx_varargs=no
 757 else
 758   AC_LANG_CPLUSPLUS
 759   AC_TRY_COMPILE([],[
 760 int a(int p1, int p2, int p3);
 761 #define call_a(...) a(1,__VA_ARGS__)
 762 call_a(2,3);
 763 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 764   AC_LANG_C
 765 ])
 766 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 767
 768 AC_MSG_CHECKING(for GNUC varargs macros)
 769 AC_TRY_COMPILE([],[
 770 int a(int p1, int p2, int p3);
 771 #define call_a(params...) a(1,params)
 772 call_a(2,3);
 773 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 774 AC_MSG_RESULT($g_have_gnuc_varargs)
 775
 776 # check for GNUC visibility support
 777 AC_MSG_CHECKING(for GNUC visibility attribute)
 778 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 779 void
 780 __attribute__ ((visibility ("hidden")))
 781      f_hidden (void)
 782 {
 783 }
 784 void
 785 __attribute__ ((visibility ("internal")))
 786      f_internal (void)
 787 {
 788 }
 789 void
 790 __attribute__ ((visibility ("protected")))
 791      f_protected (void)
 792 {
 793 }
 794 void
 795 __attribute__ ((visibility ("default")))
 796      f_default (void)
 797 {
 798 }
 799 int main (void)
 800 {
 801         f_hidden();
 802         f_internal();
 803         f_protected();
 804         f_default();
 805         return 0;
 806 }
 807 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 808 AC_MSG_RESULT($g_have_gnuc_visibility)
 809 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 810
 811 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 812 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 813 #else
 814 # include "error: this is not Sun Studio."
 815 #endif
 816 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 817 AC_MSG_RESULT($g_have_sunstudio_visibility)
 818 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 819
 820 # check for bytesex stuff
 821 AC_C_BIGENDIAN
 822 if test x$ac_cv_c_bigendian = xuniversal ; then
 823 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 824 #else
 825 #error Not a big endian.
 826 #endif],
 827     ac_cv_c_bigendian=yes
 828     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 829 #else
 830 #error Not a little endian.
 831 #endif],
 832     ac_cv_c_bigendian=no
 833     ,AC_MSG_WARN([Could not determine endianness.])))
 834 fi
 835
 836
 837 # check for header files
 838 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 839 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 840 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 841 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 842 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 843 AC_CHECK_HEADERS([sys/uio.h])
 844 AC_CHECK_HEADERS([linux/magic.h])
 845 AC_CHECK_HEADERS([sys/prctl.h])
 846
 847 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 848 [#if HAVE_SYS_PARAM_H
 849  #include <sys/param.h>
 850  #endif
 851 ])
 852 AC_CHECK_FUNCS(sysctlbyname)
 853
 854 AC_HEADER_MAJOR
 855 AC_CHECK_HEADERS([xlocale.h])
 856
 857 # check for structure fields
 858 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 859 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 860 #include <sys/stat.h>
 861 #include <unistd.h>
 862 #ifdef HAVE_SYS_STATFS_H
 863 #include <sys/statfs.h>
 864 #endif
 865 #ifdef HAVE_SYS_PARAM_H
 866 #include <sys/param.h>
 867 #endif
 868 #ifdef HAVE_SYS_MOUNT_H
 869 #include <sys/mount.h>
 870 #endif])
 871 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 872 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 873 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 874 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 875
 876 AC_STRUCT_DIRENT_D_TYPE
 877
 878 # Checks for libcharset
 879 AM_LANGINFO_CODESET
 880 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 881 AC_CHECK_FUNCS(setlocale)
 882 gl_GLIBC21
 883
 884 # check additional type sizes
 885 AC_CHECK_SIZEOF(size_t)
 886
 887 dnl Try to figure out whether gsize should be long or int
 888 AC_MSG_CHECKING([for the appropriate definition for size_t])
 889
 890 case $ac_cv_sizeof_size_t in
 891   $ac_cv_sizeof_short)
 892       glib_size_type=short
 893       ;;
 894   $ac_cv_sizeof_int)
 895       glib_size_type=int
 896       ;;
 897   $ac_cv_sizeof_long)
 898       glib_size_type=long
 899       ;;
 900   $ac_cv_sizeof_long_long)
 901       glib_size_type='long long'
 902       ;;
 903   $ac_cv_sizeof__int64)
 904       glib_size_type='__int64'
 905       ;;
 906   *)  AC_MSG_ERROR([No type matching size_t in size])
 907       ;;
 908 esac
 909
 910 dnl If int/long are the same size, we see which one produces
 911 dnl warnings when used in the location as size_t. (This matters
 912 dnl on AIX with xlc)
 913 dnl
 914 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 915        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 916   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 917 #if defined(_AIX) && !defined(__GNUC__)
 918 #pragma options langlvl=stdc89
 919 #endif
 920 #include <stddef.h>
 921 int main ()
 922 {
 923   size_t s = 1;
 924   unsigned int *size_int = &s;
 925   return (int)*size_int;
 926 }
 927     ]])],glib_size_type=int,
 928       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 929 #if defined(_AIX) && !defined(__GNUC__)
 930 #pragma options langlvl=stdc89
 931 #endif
 932 #include <stddef.h>
 933 int main ()
 934 {
 935    size_t s = 1;
 936    unsigned long *size_long = &s;
 937    return (int)*size_long;
 938 }
 939         ]])],glib_size_type=long)])
 940 ])
 941
 942 AC_MSG_RESULT(unsigned $glib_size_type)
 943
 944 AC_CHECK_SIZEOF(ssize_t)
 945
 946 dnl Try to figure out whether gssize should be long or int
 947 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 948
 949 case $ac_cv_sizeof_ssize_t in
 950   $ac_cv_sizeof_short)
 951       glib_ssize_type=short
 952       ;;
 953   $ac_cv_sizeof_int)
 954       glib_ssize_type=int
 955       ;;
 956   $ac_cv_sizeof_long)
 957       glib_ssize_type=long
 958       ;;
 959   $ac_cv_sizeof_long_long)
 960       glib_ssize_type='long long'
 961       ;;
 962   $ac_cv_sizeof__int64)
 963       glib_ssize_type='__int64'
 964       ;;
 965   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 966       ;;
 967 esac
 968
 969 dnl If int/long are the same size, we see which one produces
 970 dnl warnings when used in the location as ssize_t. (This matters
 971 dnl on Android where ssize_t is long and size_t is unsigned int)
 972 dnl
 973 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 974        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 975   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 976 #if defined(_AIX) && !defined(__GNUC__)
 977 #pragma options langlvl=stdc89
 978 #endif
 979 #include <stddef.h>
 980 #ifdef HAVE_INTTYPES_H
 981 # include <inttypes.h>
 982 #endif
 983 #ifdef HAVE_STDINT_H
 984 # include <stdint.h>
 985 #endif
 986 #ifdef HAVE_UNISTD_H
 987 # include <unistd.h>
 988 #endif
 989 #ifdef HAVE_SYS_TYPES_H
 990 # include <sys/types.h>
 991 #endif
 992 int main ()
 993 {
 994   ssize_t s = 1;
 995   int *size_int = &s;
 996   return (int)*size_int;
 997 }
 998     ]])],glib_ssize_type=int,
 999       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
1000 #if defined(_AIX) && !defined(__GNUC__)
1001 #pragma options langlvl=stdc89
1002 #endif
1003 #include <stddef.h>
1004 #ifdef HAVE_INTTYPES_H
1005 # include <inttypes.h>
1006 #endif
1007 #ifdef HAVE_STDINT_H
1008 # include <stdint.h>
1009 #endif
1010 #ifdef HAVE_UNISTD_H
1011 # include <unistd.h>
1012 #endif
1013 #ifdef HAVE_SYS_TYPES_H
1014 # include <sys/types.h>
1015 #endif
1016 int main ()
1017 {
1018    ssize_t s = 1;
1019    long *size_long = &s;
1020    return (int)*size_long;
1021 }
1022         ]])],glib_ssize_type=long)])
1023 ])
1024
1025 AC_MSG_RESULT($glib_ssize_type)
1026
1027 # Check for some functions
1028 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1029 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
1030 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
1031 # Check for high-resolution sleep functions
1032 AC_CHECK_FUNCS(splice)
1033 AC_CHECK_FUNCS(prlimit)
1034
1035 # To avoid finding a compatibility unusable statfs, which typically
1036 # successfully compiles, but warns to use the newer statvfs interface:
1037 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1038 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1039
1040 AC_MSG_CHECKING([whether to use statfs or statvfs])
1041 # Some systems have both statfs and statvfs, pick the most "native" for these
1042 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1043    [
1044    # on solaris and irix, statfs doesn't even have the f_bavail field
1045    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1046       [ac_cv_func_statfs=no],
1047    # else, at least on linux, statfs is the actual syscall
1048       [ac_cv_func_statvfs=no])
1049    ])
1050
1051 AS_IF([test x$ac_cv_func_statfs = xyes],
1052       [
1053          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1054          AC_MSG_RESULT([statfs])
1055       ],
1056       [test x$ac_cv_func_statvfs = xyes],
1057       [
1058          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1059          AC_MSG_RESULT([statvfs])
1060       ],
1061       [  AC_MSG_RESULT([neither])])
1062
1063 AC_CHECK_HEADERS(crt_externs.h)
1064 AC_CHECK_FUNCS(_NSGetEnviron)
1065
1066 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1067
1068 AC_FUNC_VSNPRINTF_C99
1069 AC_FUNC_PRINTF_UNIX98
1070
1071 # Internet address families
1072 if test $glib_native_win32 = yes; then
1073   glib_inet_includes=["
1074 #include <winsock2.h>
1075   "]
1076 else
1077   glib_inet_includes=["
1078 #include <sys/types.h>
1079 #include <sys/socket.h>
1080   "]
1081 fi
1082
1083 glib_failed=false
1084 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1085 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1086 # winsock defines this even though it doesn't support it
1087 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1088 if $glib_failed ; then
1089   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1090 fi
1091
1092 glib_failed=false
1093 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1094 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1095 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1096 if $glib_failed ; then
1097   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1098 fi
1099
1100 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname)
1101
1102 AS_IF([test $glib_native_win32 = yes], [
1103   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1104   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1105   # they aren't present at run-time (on Windows 2000).
1106   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1107   AC_SUBST(WSPIAPI_INCLUDE)
1108 ], [
1109   # Android does not have C_IN in public headers, we define it wherever necessary
1110   AS_IF([test $glib_native_android != yes], [
1111     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1112     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1113                                         #include <arpa/nameser.h>],
1114                                        [int qclass = C_IN;])],
1115                       [AC_MSG_RESULT([no])],
1116                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1117                                                            #include <arpa/nameser.h>
1118                                                            #include <arpa/nameser_compat.h>],
1119                                                           [int qclass = C_IN;])],
1120                                          [AC_MSG_RESULT([yes])
1121                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1122                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1123   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1124
1125   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1126   NETWORK_LIBS=""
1127   AC_MSG_CHECKING([for res_query])
1128   AC_TRY_LINK([#include <sys/types.h>
1129                #include <netinet/in.h>
1130                #include <arpa/nameser.h>
1131                #include <resolv.h>
1132               ],[
1133                res_query("test", 0, 0, (void *)0, 0);
1134               ],[AC_MSG_RESULT([yes])],
1135               [save_libs="$LIBS"
1136                LIBS="-lresolv $LIBS"
1137                AC_TRY_LINK([#include <sys/types.h>
1138                             #include <netinet/in.h>
1139                             #include <arpa/nameser.h>
1140                             #include <resolv.h>
1141                            ],[
1142                             res_query("test", 0, 0, (void *)0, 0);
1143                            ],[AC_MSG_RESULT([in -lresolv])
1144                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1145                            [LIBS="-lbind $save_libs"
1146                             AC_TRY_LINK([#include <resolv.h>],
1147                                         [res_query("test", 0, 0, (void *)0, 0);],
1148                                         [AC_MSG_RESULT([in -lbind])
1149                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1150                                         [AC_MSG_ERROR(not found)])])
1151                LIBS="$save_libs"])
1152   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1153                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1154                                         [AC_MSG_ERROR(Could not find socket())]))
1155   save_libs="$LIBS"
1156   LIBS="$LIBS $NETWORK_LIBS"
1157   AC_MSG_CHECKING([for res_init])
1158   AC_TRY_LINK([#include <sys/types.h>
1159                #include <netinet/in.h>
1160                #include <arpa/nameser.h>
1161                #include <resolv.h>
1162               ],[
1163                res_init();
1164               ],[AC_MSG_RESULT([yes])
1165                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1166               ],[AC_MSG_RESULT([no])])
1167   LIBS="$save_libs"
1168 ])
1169 AC_SUBST(NETWORK_LIBS)
1170
1171 AC_CHECK_HEADER([linux/netlink.h],
1172                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1173                 [#include <sys/socket.h>])
1174 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1175
1176 AC_CHECK_TYPE([struct ip_mreqn], [
1177               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1178               [#include <netinet/in.h>])
1179
1180 case $host in
1181   *-*-solaris* )
1182      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1183      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1184      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1185      ;;
1186 esac
1187
1188 dnl
1189 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1190 dnl
1191 AS_IF([test "$ac_cv_func_statfs" = yes], [
1192   AC_MSG_CHECKING([number of arguments to statfs()])
1193   AC_TRY_COMPILE([#include <unistd.h>
1194   #ifdef HAVE_SYS_PARAM_H
1195   #include <sys/param.h>
1196   #endif
1197   #ifdef HAVE_SYS_VFS_H
1198   #include <sys/vfs.h>
1199   #endif
1200   #ifdef HAVE_SYS_MOUNT_H
1201   #include <sys/mount.h>
1202   #endif
1203   #ifdef HAVE_SYS_STATFS_H
1204   #include <sys/statfs.h>
1205   #endif], [struct statfs st;
1206   statfs(NULL, &st);],[
1207     AC_MSG_RESULT([2])
1208     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1209     AC_TRY_COMPILE([#include <unistd.h>
1210   #ifdef HAVE_SYS_PARAM_H
1211   #include <sys/param.h>
1212   #endif
1213   #ifdef HAVE_SYS_VFS_H
1214   #include <sys/vfs.h>
1215   #endif
1216   #ifdef HAVE_SYS_MOUNT_H
1217   #include <sys/mount.h>
1218   #endif
1219   #ifdef HAVE_SYS_STATFS_H
1220   #include <sys/statfs.h>
1221   #endif], [struct statfs st;
1222   statfs(NULL, &st, sizeof (st), 0);],[
1223       AC_MSG_RESULT([4])
1224       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1225       AC_MSG_RESULT(unknown)
1226       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1227 ])
1228
1229 dnl
1230 dnl open takes O_DIRECTORY as an option
1231 dnl
1232 AC_MSG_CHECKING([open() option O_DIRECTORY])
1233 AC_TRY_COMPILE([#include <fcntl.h>
1234 #include <sys/types.h>
1235 #include <sys/stat.h>],
1236 [open(0, O_DIRECTORY, 0);],[
1237         AC_MSG_RESULT([yes])
1238         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1239         AC_MSG_RESULT([no])])
1240
1241 #
1242 # Check whether to use an included printf
1243 #
1244
1245 AC_ARG_ENABLE(included-printf,
1246               [AS_HELP_STRING([--enable-included-printf],
1247                               [use included printf [default=auto]])],
1248               enable_included_printf="$enableval")
1249
1250 need_included_printf=no
1251 if test "x$enable_included_printf" = "xyes" ; then
1252   need_included_printf=yes
1253 fi
1254 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1255   need_included_printf=yes
1256 fi
1257 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1258   need_included_printf=yes
1259 fi
1260 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1261    test -z "$glib_cv_long_long_format" ; then
1262   need_included_printf=yes
1263 fi
1264
1265 if test "x$enable_included_printf" = "xno" &&
1266    test "x$need_included_printf" = "xyes" ; then
1267   AC_MSG_ERROR([
1268 *** Your C library's printf doesn't appear to have the features that
1269 *** GLib needs, but you specified --enable-included-printf=no.])
1270 fi
1271
1272 enable_included_printf=$need_included_printf
1273
1274 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1275 AS_IF([test "$enable_included_printf" != "yes"], [
1276   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1277 ], [
1278   if test -z "$glib_cv_long_long_format" ; then
1279     glib_cv_long_long_format="ll"
1280   fi
1281   AC_DEFINE(HAVE_VASPRINTF,1)
1282 ])
1283
1284 # Checks needed for gnulib vasnprintf
1285 bh_C_SIGNED
1286 jm_AC_TYPE_LONG_LONG
1287 gt_TYPE_LONGDOUBLE
1288 gt_TYPE_WCHAR_T
1289 gt_TYPE_WINT_T
1290 AC_TYPE_SIZE_T
1291 AC_CHECK_TYPES(ptrdiff_t)
1292 jm_AC_TYPE_INTMAX_T
1293 AC_CHECK_FUNCS([snprintf wcslen])
1294 AC_FUNC_SNPRINTF_C99
1295
1296 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1297 # The check is borrowed from the PERL Configure script.
1298 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1299   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1300     glib_cv_working_bcopy,[AC_TRY_RUN([
1301       int main() {
1302         char buf[128], abc[128], *b;
1303         int len, off, align;
1304         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1305         for (align = 7; align >= 0; align--) {
1306           for (len = 36; len; len--) {
1307             b = buf+align; bcopy(abc, b, len);
1308             for (off = 1; off <= len; off++) {
1309               bcopy(b, b+off, len); bcopy(b+off, b, len);
1310                 if (bcmp(b, abc, len)) return(1);
1311             }
1312           }
1313         }
1314         return(0);
1315       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1316
1317   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1318   if test "$glib_cv_working_bcopy" = "yes"; then
1319     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1320   fi
1321 ])
1322
1323 # Check if <sys/select.h> needs to be included for fd_set
1324 AC_MSG_CHECKING([for fd_set])
1325 AC_TRY_COMPILE([#include <sys/types.h>],
1326         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1327 AS_IF([test "$gtk_ok" = "yes"], [
1328     AC_MSG_RESULT([yes, found in sys/types.h])
1329 ], [
1330     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1331     if test "$gtk_ok" = "yes"; then
1332         # *** FIXME: give it a different name
1333         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1334         AC_MSG_RESULT([yes, found in sys/select.h])
1335     else
1336         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1337         AC_MSG_RESULT(no)
1338     fi
1339 ])
1340
1341 dnl Check for nl_langinfo and CODESET
1342 AC_LANG_SAVE
1343 AC_LANG_C
1344 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1345         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1346                        [char *codeset = nl_langinfo (CODESET);])],
1347                 [glib_cv_langinfo_codeset=yes],
1348                 [glib_cv_langinfo_codeset=no])])
1349 if test x$glib_cv_langinfo_codeset = xyes; then
1350   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1351 fi
1352
1353 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1354 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1355         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1356                  [char *str;
1357                  str = nl_langinfo (PM_STR);
1358                  str = nl_langinfo (D_T_FMT);
1359                  str = nl_langinfo (D_FMT);
1360                  str = nl_langinfo (T_FMT);
1361                  str = nl_langinfo (T_FMT_AMPM);
1362                  str = nl_langinfo (MON_1);
1363                  str = nl_langinfo (ABMON_12);
1364                  str = nl_langinfo (DAY_1);
1365                  str = nl_langinfo (ABDAY_7);])],
1366                 [glib_cv_langinfo_time=yes],
1367                 [glib_cv_langinfo_time=no])])
1368 if test x$glib_cv_langinfo_time = xyes; then
1369   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1370 fi
1371
1372 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1373 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1374         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1375                 [char *str;
1376                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1377                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1378                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1379                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1380                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1381                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1382                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1383                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1384                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1385                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1386                 [glib_cv_langinfo_outdigit=yes],
1387                 [glib_cv_langinfo_outdigit=no])])
1388 if test x$glib_cv_langinfo_outdigit = xyes; then
1389   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1390 fi
1391 AC_LANG_RESTORE
1392
1393 dnl ****************************************
1394 dnl *** posix_memalign                   ***
1395 dnl ****************************************
1396 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1397 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1398     glib_cv_compliant_posix_memalign=0
1399     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1400         AC_TRY_RUN([
1401                 #define _XOPEN_SOURCE 600
1402                 #include <stdlib.h> /* posix_memalign() should be defined here */
1403                 /* some systems break if #include <malloc.h> used */
1404                 static void test_memalign (size_t boundary, size_t size) {
1405                     void *mem = 0;
1406                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1407                         exit (1);
1408                     else
1409                       free (mem);
1410                 }
1411                 int main() {
1412                     test_memalign (  128,   128 - 2 * sizeof (void*));
1413                     test_memalign (  256,   256 - 2 * sizeof (void*));
1414                     test_memalign (  512,   512 - 2 * sizeof (void*));
1415                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1416                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1417                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1418                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1419                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1420                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1421                     exit (0); /* success */
1422                 }
1423                 ],
1424             [glib_cv_compliant_posix_memalign=1], [], [:])
1425       :
1426     fi
1427     ])
1428 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1429     AC_MSG_RESULT(yes)
1430     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1431 ], [
1432     AC_MSG_RESULT(no)
1433 ])
1434
1435
1436 dnl ****************************************
1437 dnl *** strlcpy/strlcat                  ***
1438 dnl ****************************************
1439 # Check for strlcpy
1440 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1441 AC_TRY_RUN([#include <stdlib.h>
1442 #include <string.h>
1443 int main() {
1444   char p[10];
1445   (void) strlcpy (p, "hi", 10);
1446   if (strlcat (p, "bye", 0) != 3)
1447     return 1;
1448   return 0;
1449 }], glib_cv_have_strlcpy=yes,
1450     glib_cv_have_strlcpy=no,
1451     glib_cv_have_strlcpy=no)])
1452 if test "$glib_cv_have_strlcpy" = "yes"; then
1453     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1454 fi
1455
1456
1457 dnl **********************
1458 dnl *** va_copy checks ***
1459 dnl **********************
1460 dnl we currently check for all three va_copy possibilities, so we get
1461 dnl all results in config.log for bug reports.
1462 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1463         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1464 #include <stdlib.h>
1465         void f (int i, ...) {
1466         va_list args1, args2;
1467         va_start (args1, i);
1468         va_copy (args2, args1);
1469         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1470           exit (1);
1471         va_end (args1); va_end (args2);
1472         }
1473         int main() {
1474           f (0, 42);
1475           return 0;
1476         }]])],
1477         [glib_cv_va_copy=yes],
1478         [glib_cv_va_copy=no])
1479 ])
1480 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1481         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1482 #include <stdlib.h>
1483         void f (int i, ...) {
1484         va_list args1, args2;
1485         va_start (args1, i);
1486         __va_copy (args2, args1);
1487         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1488           exit (1);
1489         va_end (args1); va_end (args2);
1490         }
1491         int main() {
1492           f (0, 42);
1493           return 0;
1494         }]])],
1495         [glib_cv___va_copy=yes],
1496         [glib_cv___va_copy=no])
1497 ])
1498
1499 if test "x$glib_cv_va_copy" = "xyes"; then
1500   g_va_copy_func=va_copy
1501 else if test "x$glib_cv___va_copy" = "xyes"; then
1502   g_va_copy_func=__va_copy
1503 fi
1504 fi
1505
1506 if test -n "$g_va_copy_func"; then
1507   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1508 fi
1509
1510 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1511         AC_TRY_RUN([#include <stdarg.h>
1512 #include <stdlib.h>
1513         void f (int i, ...) {
1514         va_list args1, args2;
1515         va_start (args1, i);
1516         args2 = args1;
1517         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1518           exit (1);
1519         va_end (args1); va_end (args2);
1520         }
1521         int main() {
1522           f (0, 42);
1523           return 0;
1524         }],
1525         [glib_cv_va_val_copy=yes],
1526         [glib_cv_va_val_copy=no],
1527         [glib_cv_va_val_copy=yes])
1528 ])
1529
1530 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1531   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1532 ])
1533
1534 dnl ***********************
1535 dnl *** g_module checks ***
1536 dnl ***********************
1537 G_MODULE_LIBS=
1538 G_MODULE_LIBS_EXTRA=
1539 G_MODULE_PLUGIN_LIBS=
1540 if test x"$glib_native_win32" = xyes; then
1541   dnl No use for this on Win32
1542   G_MODULE_LDFLAGS=
1543 else
1544   export SED
1545   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1546 fi
1547 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1548 G_MODULE_NEED_USCORE=0
1549 G_MODULE_BROKEN_RTLD_GLOBAL=0
1550 G_MODULE_HAVE_DLERROR=0
1551 dnl *** force native WIN32 shared lib loader
1552 if test -z "$G_MODULE_IMPL"; then
1553   case "$host" in
1554   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1555   esac
1556 fi
1557 dnl *** force native AIX library loader
1558 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1559 if test -z "$G_MODULE_IMPL"; then
1560   case "$host" in
1561   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1562   esac
1563 fi
1564 dnl *** dlopen() and dlsym() in system libraries
1565 AS_IF([ test -z "$G_MODULE_IMPL"], [
1566         AC_CHECK_FUNC(dlopen,
1567                       [AC_CHECK_FUNC(dlsym,
1568                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1569                       [])
1570 ])
1571 dnl *** load_image (BeOS)
1572 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1573   AC_CHECK_LIB(root, load_image,
1574       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1575       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1576       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1577       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1578       [])
1579 ])
1580 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1581 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1582         AC_CHECK_FUNC(NSLinkModule,
1583                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1584                        G_MODULE_NEED_USCORE=1],
1585                       [])
1586 ])
1587 dnl *** dlopen() and dlsym() in libdl
1588 AS_IF([ test -z "$G_MODULE_IMPL"], [
1589         AC_CHECK_LIB(dl, dlopen,
1590                      [AC_CHECK_LIB(dl, dlsym,
1591                                    [G_MODULE_LIBS=-ldl
1592                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1593                      [])
1594 ])
1595 dnl *** shl_load() in libdld (HP-UX)
1596 AS_IF([ test -z "$G_MODULE_IMPL"], [
1597         AC_CHECK_LIB(dld, shl_load,
1598                 [G_MODULE_LIBS=-ldld
1599                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1600                 [])
1601 ])
1602 dnl *** additional checks for G_MODULE_IMPL_DL
1603 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1604         LIBS_orig="$LIBS"
1605         LDFLAGS_orig="$LDFLAGS"
1606         LIBS="$G_MODULE_LIBS $LIBS"
1607         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1608 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1609         echo "void glib_plugin_test(void) { }" > plugin.c
1610         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1611                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1612         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1613                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1614                 -shrext ".o" -avoid-version plugin.lo \
1615                 -rpath /dont/care >/dev/null 2>&1
1616         eval `./libtool --config | grep ^objdir`
1617         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1618                 glib_cv_rtldglobal_broken,[
1619                 AC_TRY_RUN([
1620 #include <dlfcn.h>
1621 #ifndef RTLD_GLOBAL
1622 #  define RTLD_GLOBAL 0
1623 #endif
1624 #ifndef RTLD_LAZY
1625 #  define RTLD_LAZY 0
1626 #endif
1627 int glib_plugin_test;
1628 int main () {
1629     void *handle, *global, *local;
1630     global = &glib_plugin_test;
1631     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1632     if (!handle) return 0;
1633     local = dlsym (handle, "glib_plugin_test");
1634     return global == local;
1635 }                       ],
1636                         [glib_cv_rtldglobal_broken=no],
1637                         [glib_cv_rtldglobal_broken=yes],
1638                         [glib_cv_rtldglobal_broken=no])
1639                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1640                 rmdir ${objdir} 2>/dev/null
1641         ])
1642         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1643                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1644         else
1645                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1646         fi
1647 dnl *** check whether we need preceeding underscores
1648         AC_CACHE_CHECK([for preceeding underscore in symbols],
1649                 glib_cv_uscore,[
1650                 AC_TRY_RUN([#include <dlfcn.h>
1651                 int glib_underscore_test (void) { return 42; }
1652                 int main() {
1653                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1654                   handle = dlopen ((void*)0, 0);
1655                   if (handle) {
1656                     f1 = dlsym (handle, "glib_underscore_test");
1657                     f2 = dlsym (handle, "_glib_underscore_test");
1658                   } return (!f2 || f1);
1659                 }],
1660                         [glib_cv_uscore=yes],
1661                         [glib_cv_uscore=no],
1662                         [])
1663                 rm -f plugin.c plugin.$ac_objext plugin.lo
1664         ])
1665         GLIB_ASSERT_SET(glib_cv_uscore)
1666         if test "x$glib_cv_uscore" = "xyes"; then
1667                 G_MODULE_NEED_USCORE=1
1668         else
1669                 G_MODULE_NEED_USCORE=0
1670         fi
1671
1672         LDFLAGS="$LDFLAGS_orig"
1673 dnl *** check for having dlerror()
1674         AC_CHECK_FUNC(dlerror,
1675                 [G_MODULE_HAVE_DLERROR=1],
1676                 [G_MODULE_HAVE_DLERROR=0])
1677         LIBS="$LIBS_orig"
1678 ])
1679 dnl *** done, have we got an implementation?
1680 if test -z "$G_MODULE_IMPL"; then
1681         G_MODULE_IMPL=0
1682         G_MODULE_SUPPORTED=false
1683 else
1684         G_MODULE_SUPPORTED=true
1685 fi
1686
1687 AC_MSG_CHECKING(for the suffix of module shared libraries)
1688 export SED
1689 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1690 eval $shrext_cmds
1691 module=yes eval std_shrext=$shrext_cmds
1692 # chop the initial dot
1693 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1694 AC_MSG_RESULT(.$glib_gmodule_suffix)
1695 # any reason it may fail?
1696 if test "x$glib_gmodule_suffix" = x; then
1697         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1698 fi
1699
1700 AC_SUBST(G_MODULE_SUPPORTED)
1701 AC_SUBST(G_MODULE_IMPL)
1702 AC_SUBST(G_MODULE_LIBS)
1703 AC_SUBST(G_MODULE_LIBS_EXTRA)
1704 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1705 AC_SUBST(G_MODULE_LDFLAGS)
1706 AC_SUBST(G_MODULE_HAVE_DLERROR)
1707 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1708 AC_SUBST(G_MODULE_NEED_USCORE)
1709 AC_SUBST(GLIB_DEBUG_FLAGS)
1710
1711 dnl **********************
1712 dnl *** g_spawn checks ***
1713 dnl **********************
1714
1715 AC_MSG_CHECKING(for gspawn implementation)
1716 case "$host" in
1717   *-*-mingw*)
1718     GSPAWN=gspawn-win32.lo
1719     ;;
1720   *)
1721     GSPAWN=gspawn.lo
1722     ;;
1723 esac
1724 AC_MSG_RESULT($GSPAWN)
1725 AC_SUBST(GSPAWN)
1726
1727 dnl *************************
1728 dnl *** GIOChannel checks ***
1729 dnl *************************
1730
1731 AC_MSG_CHECKING(for GIOChannel implementation)
1732 case "$host" in
1733   *-*-mingw*)
1734     GIO=giowin32.lo
1735     ;;
1736   *)
1737     GIO=giounix.lo
1738     ;;
1739 esac
1740 AC_MSG_RESULT($GIO)
1741 AC_SUBST(GIO)
1742
1743 dnl *********************************
1744 dnl *** Directory for GIO modules ***
1745 dnl *********************************
1746
1747 AC_ARG_WITH(gio-module-dir,
1748            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1749                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1750            [],
1751            [with_gio_module_dir='${libdir}/gio/modules'])
1752 GIO_MODULE_DIR=$with_gio_module_dir
1753 AC_SUBST(GIO_MODULE_DIR)
1754
1755 dnl **********************************
1756 dnl *** Check for libselinux (GIO) ***
1757 dnl **********************************
1758 AC_ARG_ENABLE(selinux,
1759               AS_HELP_STRING([--disable-selinux],
1760                              [build without selinux support]))
1761 msg_selinux=no
1762 SELINUX_LIBS=
1763 AS_IF([ test "x$enable_selinux" != "xno"], [
1764
1765  AC_CHECK_LIB(selinux, is_selinux_enabled,
1766    [AC_CHECK_HEADERS(selinux/selinux.h,
1767      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1768        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1769         SELINUX_LIBS="-lselinux"
1770         msg_selinux=yes])
1771      ])
1772    ])
1773 ])
1774 AC_SUBST(SELINUX_LIBS)
1775
1776 dnl *****************************
1777 dnl ** Check for inotify (GIO) **
1778 dnl *****************************
1779 inotify_support=no
1780 AC_CHECK_HEADERS([sys/inotify.h],
1781 [
1782         inotify_support=yes
1783         AC_CHECK_FUNCS(inotify_init1)
1784 ])
1785
1786 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1787
1788 dnl ****************************
1789 dnl ** Check for kqueue (GIO) **
1790 dnl ****************************
1791 kqueue_support=no
1792 AC_CHECK_HEADERS([sys/event.h],
1793 [
1794         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1795 ])
1796
1797 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1798
1799 dnl *********************************
1800 dnl ** Check for Solaris FEN (GIO) **
1801 dnl *********************************
1802 fen_support=no
1803 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1804 #include <port.h>
1805 #ifndef PORT_SOURCE_FILE
1806 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1807 #endif
1808 int main() { return 0; } ]])],
1809 [
1810         fen_support=yes
1811 ],)
1812
1813 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1814
1815 dnl ****************************
1816 dnl *** Checks for FAM (GIO) ***
1817 dnl ****************************
1818
1819 should_disable_fam=no
1820
1821 AC_ARG_ENABLE(fam,
1822               AS_HELP_STRING([--disable-fam],
1823                              [don't use fam for file system monitoring]),
1824                          [
1825                                 if test "x$enable_fam" = "xno"; then
1826                                         should_disable_fam=yes
1827                                 fi
1828                          ]
1829                          )
1830 fam_support=no
1831 FAM_LIBS=
1832 if test "x$should_disable_fam" = "xno"; then
1833 AC_CHECK_LIB(fam, FAMOpen,
1834   [AC_CHECK_HEADERS(fam.h,
1835     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1836      AC_CHECK_LIB(fam, FAMNoExists,
1837                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1838      FAM_LIBS="-lfam"]
1839      fam_support=yes,
1840     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1841   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1842 AC_SUBST(FAM_LIBS)
1843 fi
1844 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1845
1846
1847 dnl *****************************
1848 dnl *** Check for xattr (GIO) ***
1849 dnl *****************************
1850 AC_ARG_ENABLE(xattr,
1851               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1852 msg_xattr=no
1853 XATTR_LIBS=
1854 AS_IF([ test "x$enable_xattr" != "xno"], [
1855
1856 dnl either glibc or libattr can provide xattr support
1857
1858 dnl for both of them, we check for getxattr being in
1859 dnl the library and a valid xattr header.
1860
1861 dnl try glibc
1862  AC_CHECK_LIB(c, getxattr,
1863    [AC_CHECK_HEADERS(sys/xattr.h,
1864      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1865       msg_xattr=yes])
1866    ])
1867
1868   AS_IF([ test "x$msg_xattr" != "xyes"], [
1869 dnl   failure. try libattr
1870    AC_CHECK_LIB(attr, getxattr,
1871       [AC_CHECK_HEADERS(attr/xattr.h,
1872        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1873         XATTR_LIBS="-lattr"
1874         msg_xattr=yes])
1875       ])
1876   ])
1877
1878   AS_IF([ test "x$msg_xattr" = "xyes"], [
1879     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1880     AC_TRY_COMPILE([
1881       #include <stdio.h>
1882       #ifdef HAVE_SYS_TYPES_H
1883       #include <sys/types.h>
1884       #endif
1885       #ifdef HAVE_SYS_XATTR_H
1886       #include <sys/xattr.h>
1887       #elif HAVE_ATTR_XATTR_H
1888       #include <attr/xattr.h>
1889       #endif
1890     ],
1891     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1892     [
1893       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1894       AC_MSG_RESULT([yes])
1895     ],
1896     [AC_MSG_RESULT([no])]
1897     )
1898   ])
1899 ])
1900 AC_SUBST(XATTR_LIBS)
1901
1902 dnl ************************
1903 dnl *** check for libelf ***
1904 dnl ************************
1905 AC_ARG_ENABLE(libelf,
1906               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1907 AS_IF([ test "x$enable_libelf" != "xno"],[
1908 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1909 AS_IF([ test $have_libelf = maybe ], [
1910   glib_save_LIBS=$LIBS
1911   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1912   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1913   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1914   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1915   LIBS=$glib_save_LIBS
1916
1917   if test $have_libelf != no; then
1918     LIBELF_LIBS=-lelf
1919     have_libelf=yes
1920   fi
1921 ])
1922 ])
1923
1924 if test x$have_libelf = xyes; then
1925   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1926 fi
1927
1928 dnl ****************************************
1929 dnl *** platform dependent source checks ***
1930 dnl ****************************************
1931
1932 AC_MSG_CHECKING(for platform-dependent source)
1933 case "$host" in
1934   *-*-cygwin*|*-*-mingw*)
1935     PLATFORMDEP=gwin32.lo
1936     ;;
1937   *)
1938     PLATFORMDEP=
1939     ;;
1940 esac
1941 AC_MSG_RESULT($PLATFORMDEP)
1942 AC_SUBST(PLATFORMDEP)
1943
1944 AC_MSG_CHECKING([whether to compile timeloop])
1945 case "$host" in
1946   *-*-cygwin*|*-*-mingw*|*-*-minix)
1947     enable_timeloop=no
1948     ;;
1949   *)
1950     enable_timeloop=yes
1951     ;;
1952 esac
1953 AC_MSG_RESULT($enable_timeloop)
1954 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1955
1956 AC_MSG_CHECKING([if building for some Win32 platform])
1957 case "$host" in
1958   *-*-mingw*|*-*-cygwin*)
1959     platform_win32=yes
1960     ;;
1961   *)
1962     platform_win32=no
1963     ;;
1964 esac
1965 AC_MSG_RESULT($platform_win32)
1966 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1967
1968 dnl ***********************
1969 dnl *** g_thread checks ***
1970 dnl ***********************
1971
1972 AC_ARG_WITH(threads,
1973            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1974                            [specify a thread implementation to use])],
1975            [],
1976            [with_threads=yes])
1977
1978 dnl error and warning message
1979 dnl *************************
1980
1981 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1982
1983 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1984                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1985                 compilation now, but then your programs might not work.
1986                 Please provide information on how it is done on your system."
1987
1988 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1989                  "
1990
1991 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1992                   provide information on your thread implementation."
1993
1994 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1995                 functions will not be MT-safe during their first call because
1996                 there is no working 'getpwuid_r' on your system."
1997
1998 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1999                 because there is no 'localtime_r' on your system."
2000
2001 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
2002                 linking threaded applications. As GLib cannot do that
2003                 automatically, you will get an linkg error everytime you are
2004                 not using the right compiler. In that case you have to relink
2005                 with the right compiler. Ususally just '_r' is appended
2006                 to the compiler name."
2007
2008 dnl determination of thread implementation
2009 dnl ***************************************
2010
2011 AC_MSG_CHECKING(for thread implementation)
2012
2013 have_threads=no
2014 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
2015         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
2016         # -U_OSF_SOURCE is for Digital UNIX 4.0d
2017         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
2018         glib_save_CPPFLAGS="$CPPFLAGS"
2019         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2020         AS_IF([ test "x$have_threads" = xno], [
2021                 AC_TRY_COMPILE([#include <pthread.h>],
2022                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2023                         have_threads=posix)
2024         ])
2025         # Tru64Unix requires -pthread to find pthread.h. See #103020
2026         CPPFLAGS="$CPPFLAGS -pthread"
2027         if test "x$have_threads" = xno; then
2028         AC_TRY_COMPILE([#include <pthread.h>],
2029                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2030                        have_threads=posix)
2031         fi
2032         CPPFLAGS="$glib_save_CPPFLAGS"
2033 ])
2034 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
2035         case $host in
2036                 *-*-mingw*)
2037                 have_threads=win32
2038                 ;;
2039         esac
2040 fi
2041
2042 if test "x$have_threads" = xno; then
2043         AC_MSG_RESULT(none available)
2044         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
2045 else
2046         AC_MSG_RESULT($have_threads)
2047 fi
2048
2049
2050 dnl determination of G_THREAD_CFLAGS
2051 dnl ********************************
2052
2053 G_THREAD_LIBS=
2054 G_THREAD_LIBS_EXTRA=
2055 G_THREAD_CFLAGS=
2056
2057 dnl
2058 dnl Test program for basic POSIX threads functionality
2059 dnl
2060 m4_define([glib_thread_test],[
2061 #include <pthread.h>
2062 int check_me = 0;
2063 void* func(void* data) {check_me = 42; return &check_me;}
2064 int main()
2065  { pthread_t t;
2066    void *ret;
2067    pthread_create (&t, $1, func, 0);
2068    pthread_join (t, &ret);
2069    return (check_me != 42 || ret != &check_me);
2070 }])
2071
2072 AS_IF([ test x"$have_threads" = xposix], [
2073   # First we test for posix, whether -pthread or -pthreads do the trick as
2074   # both CPPFLAG and LIBS.
2075   # One of them does for most gcc versions and some other platforms/compilers
2076   # too and could be considered as the canonical way to go.
2077   case $host in
2078     *-*-cygwin*|*-*-darwin*)
2079        # skip cygwin and darwin -pthread or -pthreads test
2080        ;;
2081     *-solaris*)
2082       # These compiler/linker flags work with both Sun Studio and gcc
2083       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2084       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2085       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2086       G_THREAD_LIBS="-lpthread -lthread"
2087       ;;
2088     *)
2089       for flag in pthread pthreads mt; do
2090         glib_save_CFLAGS="$CFLAGS"
2091         CFLAGS="$CFLAGS -$flag"
2092         AC_TRY_RUN(glib_thread_test(0),
2093                    glib_flag_works=yes,
2094                    glib_flag_works=no,
2095                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2096                                    glib_flag_works=yes,
2097                                    glib_flag_works=no)])
2098         CFLAGS="$glib_save_CFLAGS"
2099         if test $glib_flag_works = yes ; then
2100            G_THREAD_CFLAGS=-$flag
2101         G_THREAD_LIBS=-$flag
2102         break;
2103         fi
2104       done
2105        ;;
2106   esac
2107 ])
2108
2109 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2110
2111   # The canonical -pthread[s] does not work. Try something different.
2112
2113   case $host in
2114         *-aix*)
2115                 if test x"$GCC" = xyes; then
2116                         # GCC 3.0 and above needs -pthread.
2117                         # Should be coverd by the case above.
2118                         # GCC 2.x and below needs -mthreads
2119                         G_THREAD_CFLAGS="-mthreads"
2120                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2121                 else
2122                         # We are probably using the aix compiler. Normaly a
2123                         # program would have to be compiled with the _r variant
2124                         # of the corresponding compiler, but we as GLib cannot
2125                         # do that: but the good news is that for compiling the
2126                         # only difference is the added -D_THREAD_SAFE compile
2127                         # option. This is according to the "C for AIX User's
2128                         # Guide".
2129                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2130                 fi
2131                 ;;
2132         *-dg-dgux*)  # DG/UX
2133                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2134                 ;;
2135         *-sysv5uw7*) # UnixWare 7
2136                 # We are not using gcc with -pthread. Catched above.
2137                 G_THREAD_CFLAGS="-Kthread"
2138                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2139                 ;;
2140         *-mingw*)
2141                 # No flag needed when using MSVCRT.DLL
2142                 G_THREAD_CFLAGS=""
2143                 ;;
2144         *)
2145                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2146                 ;;
2147   esac
2148 ])
2149
2150 # if we are not finding the localtime_r function, then we probably are
2151 # not using the proper multithread flag
2152
2153 glib_save_CPPFLAGS="$CPPFLAGS"
2154 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2155
2156 # First we test, whether localtime_r is declared in time.h
2157 # directly. Then we test whether a macro localtime_r exists, in
2158 # which case localtime_r in the test program is replaced and thus
2159 # if we still find localtime_r in the output, it is not defined as
2160 # a macro.
2161
2162 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2163   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2164                                                            localtime_r(a,b)],
2165                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2166
2167 CPPFLAGS="$glib_save_CPPFLAGS"
2168
2169 AC_MSG_CHECKING(thread related cflags)
2170 AC_MSG_RESULT($G_THREAD_CFLAGS)
2171 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2172
2173 dnl determination of G_THREAD_LIBS
2174 dnl ******************************
2175
2176 AS_IF([test x$have_threads = xposix], [
2177           glib_save_CPPFLAGS="$CPPFLAGS"
2178           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2179           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2180             case $host in
2181               *-aix*)
2182                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2183                 # probably using the aix compiler.
2184                 AC_MSG_WARN($AIX_COMPILE_INFO)
2185                 ;;
2186               *)
2187                 G_THREAD_LIBS=error
2188                 glib_save_LIBS="$LIBS"
2189                 for thread_lib in "" pthread pthread32 pthreads thread; do
2190                         if test x"$thread_lib" = x; then
2191                                 add_thread_lib=""
2192                                 IN=""
2193                         else
2194                                 add_thread_lib="-l$thread_lib"
2195                                 IN=" in -l$thread_lib"
2196                         fi
2197                         if test x"$have_threads" = xposix; then
2198                                 defattr=0
2199                         else
2200                                 defattr=pthread_attr_default
2201                         fi
2202
2203                         LIBS="$add_thread_lib $glib_save_LIBS"
2204
2205                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2206                         AC_TRY_RUN(glib_thread_test($defattr),
2207                                    glib_result=yes,
2208                                    glib_result=no,
2209                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2210                                                    glib_result=yes,
2211                                                    glib_result=no)])
2212                         AC_MSG_RESULT($glib_result)
2213
2214                         if test "$glib_result" = "yes" ; then
2215                           G_THREAD_LIBS="$add_thread_lib"
2216                           break
2217                         fi
2218                 done
2219                 if test "x$G_THREAD_LIBS" = xerror; then
2220                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2221                 fi
2222                 LIBS="$glib_save_LIBS"
2223                 ;;
2224             esac
2225           ])
2226
2227           g_threads_impl="POSIX"
2228           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2229           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2230           CPPFLAGS="$glib_save_CPPFLAGS"
2231 ], [test x$have_threads = xwin32], [
2232            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2233            g_threads_impl="WIN32"
2234 ], [
2235            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2236            g_threads_impl="NONE"
2237            G_THREAD_LIBS=error
2238 ])
2239 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2240 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2241 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2242
2243 if test "x$G_THREAD_LIBS" = xerror; then
2244         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2245 fi
2246
2247 case $host in
2248   *-*-beos*)
2249     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2250     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2251     ;;
2252   *)
2253     ;;
2254 esac
2255
2256 AC_MSG_CHECKING(thread related libraries)
2257 AC_MSG_RESULT($G_THREAD_LIBS)
2258
2259 dnl check for mt safe function variants and some posix functions
2260 dnl ************************************************************
2261
2262 glib_save_LIBS="$LIBS"
2263 # we are not doing the following for now, as this might require glib
2264 # to always be linked with the thread libs on some platforms.
2265 # LIBS="$LIBS $G_THREAD_LIBS"
2266 AC_CHECK_FUNCS(localtime_r gmtime_r)
2267 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2268         AC_CACHE_CHECK([for posix getpwuid_r],
2269                 ac_cv_func_posix_getpwuid_r,
2270                 [AC_TRY_RUN([
2271 #include <errno.h>
2272 #include <pwd.h>
2273 int main () {
2274     char buffer[10000];
2275     struct passwd pwd, *pwptr = &pwd;
2276     int error;
2277     errno = 0;
2278     error = getpwuid_r (0, &pwd, buffer,
2279                         sizeof (buffer), &pwptr);
2280    return (error < 0 && errno == ENOSYS)
2281            || error == ENOSYS;
2282 }                               ],
2283                         [ac_cv_func_posix_getpwuid_r=yes],
2284                         [ac_cv_func_posix_getpwuid_r=no])])
2285         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2286         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2287                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2288                         [Have POSIX function getpwuid_r])
2289         else
2290                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2291                         ac_cv_func_nonposix_getpwuid_r,
2292                         [AC_TRY_LINK([#include <pwd.h>],
2293                                 [char buffer[10000];
2294                                 struct passwd pwd;
2295                                 getpwuid_r (0, &pwd, buffer,
2296                                                 sizeof (buffer));],
2297                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2298                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2299                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2300                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2301                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2302                                 [Have non-POSIX function getpwuid_r])
2303                 fi
2304         fi
2305 ])
2306 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2307         AC_CACHE_CHECK([for posix getgrgid_r],
2308                 ac_cv_func_posix_getgrgid_r,
2309                 [AC_TRY_RUN([
2310 #include <errno.h>
2311 #include <grp.h>
2312 int main () {
2313     char buffer[10000];
2314     struct group grp, *grpptr = &grp;
2315     int error;
2316     errno = 0;
2317     error = getgrgid_r (0, &grp, buffer,
2318                         sizeof (buffer), &grpptr);
2319    return (error < 0 && errno == ENOSYS)
2320            || error == ENOSYS;
2321 }                              ],
2322                        [ac_cv_func_posix_getgrgid_r=yes],
2323                        [ac_cv_func_posix_getgrgid_r=no])])
2324         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2325         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2326                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2327                         [Have POSIX function getgrgid_r])
2328         ], [
2329                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2330                         ac_cv_func_nonposix_getgrgid_r,
2331                         [AC_TRY_LINK([#include <grp.h>],
2332                                 [char buffer[10000];
2333                                 struct group grp;
2334                                 getgrgid_r (0, &grp, buffer,
2335                                 sizeof (buffer));],
2336                         [ac_cv_func_nonposix_getgrgid_r=yes],
2337                         [ac_cv_func_nonposix_getgrgid_r=no])])
2338                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2339                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2340                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2341                                 [Have non-POSIX function getgrgid_r])
2342                 fi
2343         ])
2344 ])
2345 LIBS="$G_THREAD_LIBS $LIBS"
2346 AS_IF([ test x"$have_threads" = xposix], [
2347         glib_save_CPPFLAGS="$CPPFLAGS"
2348         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2349         # This is not AC_CHECK_FUNC to also work with function
2350         # name mangling in header files.
2351         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2352         AC_LINK_IFELSE(
2353             [AC_LANG_PROGRAM(
2354                 [#include <pthread.h>],
2355                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2356             [AC_MSG_RESULT(yes)
2357              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2358                 [Have function pthread_attr_setstacksize])],
2359             [AC_MSG_RESULT(no)])
2360         AC_MSG_CHECKING(for pthread_condattr_setclock)
2361         AC_LINK_IFELSE(
2362             [AC_LANG_PROGRAM(
2363                 [#include <pthread.h>],
2364                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2365             [AC_MSG_RESULT(yes)
2366              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2367                 [Have function pthread_condattr_setclock])],
2368             [AC_MSG_RESULT(no)])
2369         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic)
2370         AC_LINK_IFELSE(
2371             [AC_LANG_PROGRAM(
2372                 [#include <pthread.h>],
2373                 [pthread_cond_timedwait_monotonic(NULL, NULL, NULL)])],
2374             [AC_MSG_RESULT(yes)
2375              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC,1,
2376                 [Have function pthread_cond_timedwait_monotonic])],
2377             [AC_MSG_RESULT(no)])
2378         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic_np)
2379         AC_LINK_IFELSE(
2380             [AC_LANG_PROGRAM(
2381                 [#include <pthread.h>],
2382                 [pthread_cond_timedwait_monotonic_np(NULL, NULL, NULL)])],
2383             [AC_MSG_RESULT(yes)
2384              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC_NP,1,
2385                 [Have function pthread_cond_timedwait_monotonic_np])],
2386             [AC_MSG_RESULT(no)])
2387         CPPFLAGS="$glib_save_CPPFLAGS"
2388 ])
2389
2390 LIBS="$glib_save_LIBS"
2391
2392 # now spit out all the warnings.
2393 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2394    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2395         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2396 fi
2397 if test "$ac_cv_func_localtime_r" != "yes"; then
2398         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2399 fi
2400
2401 #
2402 # Hack to deal with:
2403 #
2404 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2405 #     building shared libraries with linux.
2406 #  b) FreeBSD doesn't do this either.
2407 #
2408 case $host in
2409   *android*)
2410     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2411     ;;
2412   *-*-freebsd*|*-*-linux*)
2413     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2414     ;;
2415   *-*-openbsd*)
2416     LDFLAGS="$LDFLAGS -pthread"
2417     ;;
2418   *)
2419     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2420     ;;
2421 esac
2422
2423 AC_SUBST(G_THREAD_CFLAGS)
2424 AC_SUBST(G_THREAD_LIBS)
2425 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2426 AC_SUBST(G_THREAD_LIBS_EXTRA)
2427
2428 AC_CHECK_FUNCS(clock_gettime, [], [
2429   AC_CHECK_LIB(rt, clock_gettime, [
2430     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2431     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2432     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2433   ])
2434 ])
2435
2436
2437 dnl ************************
2438 dnl *** g_atomic_* tests ***
2439 dnl ************************
2440
2441 dnl We need to decide at configure time if GLib will use real atomic
2442 dnl operations ("lock free") or emulated ones with a mutex.  This is
2443 dnl because we must put this information in glibconfig.h so we know if
2444 dnl it is safe or not to inline using compiler intrinsics directly from
2445 dnl the header.
2446 dnl
2447 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2448 dnl user is interested in knowing if they can use the atomic ops across
2449 dnl processes.
2450 dnl
2451 dnl We can currently support the atomic ops natively when building GLib
2452 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2453 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2454 dnl we are using GCC (and not mingw*).
2455 dnl
2456 dnl Note that the atomic ops are only available with GCC on x86 when
2457 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2458 dnl not available but would be available given the right flags, we want
2459 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2460 dnl that then to silently fall back on emulated atomic ops just because
2461 dnl the user had the wrong build environment.
2462
2463 dnl We may add other compilers here in the future...
2464
2465 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2466   case $host in
2467     *-*-mingw*)
2468       glib_cv_g_atomic_lock_free=yes
2469       ;;
2470     *)
2471       AC_TRY_LINK([],
2472                      [volatile int atomic = 2;\
2473                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2474                      [glib_cv_g_atomic_lock_free=yes],
2475                      [glib_cv_g_atomic_lock_free=no])
2476       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2477         SAVE_CFLAGS="${CFLAGS}"
2478         CFLAGS="-march=i486"
2479         AC_TRY_LINK([],
2480                        [volatile int atomic = 2;\
2481                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2482                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2483                        [])
2484         CFLAGS="${SAVE_CFLAGS}"
2485       fi
2486       ;;
2487   esac])
2488
2489
2490 case $host in
2491   *-*-mingw*)
2492     ;;
2493   *)
2494     # Some compilers support atomic operations but do not define
2495     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2496     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2497       AC_TRY_LINK([],
2498                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2499                      [],
2500                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2501     fi
2502     ;;
2503  esac
2504
2505 dnl We need a more robust approach here...
2506 case $host_cpu in
2507   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2508     glib_memory_barrier_needed=no
2509     ;;
2510   sparc*|alpha*|powerpc*|ia64)
2511     glib_memory_barrier_needed=yes
2512     ;;
2513   *)
2514     glib_memory_barrier_needed=yes
2515     ;;
2516 esac
2517
2518 dnl ************************
2519 dnl ** Check for futex(2) **
2520 dnl ************************
2521 AC_CACHE_CHECK(for futex(2) system call,
2522     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2523 #include <linux/futex.h>
2524 #include <sys/syscall.h>
2525 #include <unistd.h>
2526 ],[
2527 int
2528 main (void)
2529 {
2530   /* it is not like this actually runs or anything... */
2531   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2532   return 0;
2533 }
2534 ])],glib_cv_futex=yes,glib_cv_futex=no))
2535 if test x"$glib_cv_futex" = xyes; then
2536   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2537 fi
2538
2539 AC_CACHE_CHECK(for eventfd(2) system call,
2540     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2541 #include <sys/eventfd.h>
2542 #include <unistd.h>
2543 ],[
2544 int
2545 main (void)
2546 {
2547   eventfd (0, EFD_CLOEXEC);
2548   return 0;
2549 }
2550 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2551 if test x"$glib_cv_eventfd" = x"yes"; then
2552   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2553 fi
2554 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2555
2556 dnl ****************************************
2557 dnl *** GLib POLL* compatibility defines ***
2558 dnl ****************************************
2559
2560 glib_poll_includes=["
2561 #include <sys/types.h>
2562 #include <sys/poll.h>
2563 "]
2564
2565 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2566    test $ac_cv_header_sys_poll_h = yes ], [
2567   glib_failed=false
2568   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2569   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2570   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2571   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2572   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2573   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2574   if $glib_failed ; then
2575     AC_MSG_ERROR([Could not determine values for POLL* constants])
2576   fi
2577 ], [
2578   glib_cv_value_POLLIN=1
2579   glib_cv_value_POLLOUT=4
2580   glib_cv_value_POLLPRI=2
2581   glib_cv_value_POLLERR=8
2582   glib_cv_value_POLLHUP=16
2583   glib_cv_value_POLLNVAL=32
2584 ])
2585
2586 AC_MSG_CHECKING([for broken poll])
2587 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2588         #include <stdlib.h>
2589         #include <fcntl.h>
2590         #include <poll.h>
2591         #ifdef HAVE_SYS_POLL_H
2592         #include <sys/poll.h>
2593         #endif
2594         int main(void) {
2595           struct pollfd fds[1];
2596           int fd;
2597           fd = open("/dev/null", 1);
2598           fds[0].fd = fd;
2599           fds[0].events = POLLIN;
2600           fds[0].revents = 0;
2601           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2602                 exit(1);  /* Does not work for devices -- fail */
2603           }
2604           exit(0);
2605         }]])],
2606   [broken_poll=no],
2607   [broken_poll=yes
2608    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2609   [broken_poll="no (cross compiling)"])
2610 AC_MSG_RESULT($broken_poll)
2611
2612 dnl *********************
2613 dnl *** GRegex checks ***
2614 dnl *********************
2615
2616 PCRE_REQUIRED_VERSION=8.13
2617
2618 # Check if we should use the internal or the system-supplied pcre
2619 AC_ARG_WITH(pcre,
2620             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2621                             [whether to use system PCRE [default=internal]])])
2622
2623 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2624
2625 AS_IF([ test "x$with_pcre" = xsystem], [
2626   PKG_CHECK_MODULES(PCRE,
2627                     libpcre >= $PCRE_REQUIRED_VERSION)
2628   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2629                   glib_save_CFLAGS="$CFLAGS"
2630                   glib_save_LIBS="$LIBS"
2631                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2632                   AC_TRY_RUN([#include <pcre.h>
2633                               int main () {
2634                                 int support;
2635                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2636                                 if (!support)
2637                                   return 1;
2638                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2639                                 if (!support)
2640                                   return 1;
2641                                 return 0;
2642                               }],
2643                   glib_cv_pcre_has_unicode=yes,
2644                   glib_cv_pcre_has_unicode=no,
2645                   glib_cv_pcre_has_unicode=yes)
2646                   CFLAGS="$glib_save_CFLAGS"
2647                   LIBS="$glib_save_LIBS"
2648       ])
2649   if test "$glib_cv_pcre_has_unicode" = "no"; then
2650     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2651   fi
2652   AC_SUBST(PCRE_CFLAGS)
2653   AC_SUBST(PCRE_LIBS)
2654   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2655   PCRE_REQUIRES=libpcre
2656   AC_SUBST(PCRE_REQUIRES)
2657 ], [
2658   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2659   AS_IF([ test x"$GCC" = xyes], [
2660     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2661     save_CFLAGS="$CFLAGS"
2662     CFLAGS="$CFLAGS -Wno-pointer-sign"
2663     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2664                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2665     CFLAGS="$save_CFLAGS"
2666   ])
2667 ])
2668 AC_SUBST(PCRE_WARN_CFLAGS)
2669
2670 dnl **********************
2671 dnl *** Win32 API libs ***
2672 dnl **********************
2673
2674 case $host in
2675   *-*-cygwin*)
2676         G_LIBS_EXTRA="-luser32 -lkernel32"
2677     ;;
2678   *-*-mingw*)
2679         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2680     ;;
2681   *)
2682         G_LIBS_EXTRA=""
2683     ;;
2684 esac
2685 AC_SUBST(G_LIBS_EXTRA)
2686
2687 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2688 dnl since we need it for g_iconv()
2689
2690 AC_MSG_CHECKING([for EILSEQ])
2691 AC_TRY_COMPILE([
2692 #include <errno.h>
2693 ],
2694 [
2695 int error = EILSEQ;
2696 ], have_eilseq=yes, have_eilseq=no);
2697 AC_MSG_RESULT($have_eilseq)
2698
2699 dnl ******************************************************************
2700 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2701 dnl *** glib-compile-schemas in PATH                               ***
2702 dnl ******************************************************************
2703
2704 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2705
2706 AS_IF([ test $cross_compiling = yes ], [
2707   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2708   if test x$GLIB_GENMARSHAL = xno; then
2709     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2710   fi
2711
2712   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2713   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2714     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2715   fi
2716
2717   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2718   if test x$GLIB_COMPILE_RESOURCES = xno; then
2719     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2720   fi
2721 ])
2722
2723 dnl **************************
2724 dnl *** Checks for gtk-doc ***
2725 dnl **************************
2726 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2727 # it on it's own line.
2728 m4_ifdef([GTK_DOC_CHECK], [
2729 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2730 ],[
2731 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2732 ])
2733
2734 AC_ARG_ENABLE(man,
2735               [AS_HELP_STRING([--enable-man],
2736                               [generate man pages [default=auto]])],,
2737               enable_man=maybe)
2738
2739 AS_IF([test "$enable_man" != no], [
2740   AC_PATH_PROG([XSLTPROC], [xsltproc])
2741   AS_IF([test -z "$XSLTPROC"], [
2742     AS_IF([test "$enable_man" = yes], [
2743       AC_MSG_ERROR([xsltproc is required for --enable-man])
2744     ])
2745     enable_man=no
2746   ])
2747 ])
2748
2749 AS_IF([ test "$enable_man" != no ], [
2750   dnl check for DocBook DTD in the local catalog
2751   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2752      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2753   AS_IF([test "$have_docbook_dtd" != yes], [
2754     AS_IF([test "$enable_man" = yes ], [
2755       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2756     ])
2757     enable_man=no
2758   ])
2759 ])
2760
2761 AS_IF([test "$enable_man" != no], [
2762   dnl check for DocBook XSL stylesheets in the local catalog
2763   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2764      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2765   AS_IF([ test "$have_docbook_dtd" != yes ], [
2766     AS_IF([ test "$enable_man" = yes ], [
2767       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2768     ])
2769     enable_man=no
2770   ])
2771 ])
2772
2773 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2774
2775 AC_MSG_CHECKING([whether to generate man pages])
2776 AS_IF([ test "$enable_man" != no ], [
2777   AC_MSG_RESULT([yes])
2778 ], [
2779   AC_MSG_RESULT([no])
2780 ])
2781
2782 dnl
2783 dnl Tracing
2784 dnl
2785
2786 AC_ARG_ENABLE([dtrace],
2787              [AS_HELP_STRING([--enable-dtrace],
2788                               [include tracing support for dtrace])])
2789 have_dtrace=no
2790 AC_MSG_CHECKING([whether to include dtrace tracing support])
2791 AS_IF([ test "x$enable_dtrace" != xno], [
2792   if test x$glib_have_carbon = xyes; then
2793     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2794   else
2795     AC_MSG_RESULT([yes])
2796     AC_CHECK_PROGS(DTRACE, dtrace)
2797     if test -z "$DTRACE"; then
2798       if test "x$enable_dtrace" = xyes; then
2799         AC_MSG_ERROR([dtrace not found])
2800       fi
2801     else
2802       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2803                       [if test "x$enable_dtrace" = xyes; then
2804                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2805                        fi])
2806     fi
2807   fi
2808 ], [
2809   AC_MSG_RESULT([no])
2810 ])
2811 if test "x$have_dtrace" = xyes; then
2812   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2813 fi
2814 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2815
2816 AC_MSG_CHECKING([whether to include systemtap tracing support])
2817 AC_ARG_ENABLE([systemtap],
2818              [AS_HELP_STRING([--enable-systemtap],
2819                               [include tracing support for systemtap])])
2820 have_systemtap=no
2821 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2822   have_systemtap=yes
2823 fi
2824 AC_MSG_RESULT(${have_systemtap})
2825
2826 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2827
2828 AC_ARG_WITH([tapset-install-dir],
2829             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2830                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2831             [if test "x${withval}" = x; then
2832                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2833              else
2834                ABS_TAPSET_DIR="${withval}"
2835               fi],
2836             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2837 AC_SUBST(ABS_TAPSET_DIR)
2838
2839 dnl ************************************
2840 dnl *** Enable lcov coverage reports ***
2841 dnl ************************************
2842
2843 AC_ARG_ENABLE(gcov,
2844   AS_HELP_STRING([--enable-gcov],
2845                  [enable coverage testing with gcov]),
2846   [use_gcov=$enableval], [use_gcov=no])
2847
2848 AS_IF([ test "x$use_gcov" = "xyes"], [
2849   dnl we need gcc:
2850   if test "$GCC" != "yes"; then
2851     AC_MSG_ERROR([GCC is required for --enable-gcov])
2852   fi
2853
2854   dnl Check if ccache is being used
2855   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2856   case `$SHTOOL path $CC` in
2857     *ccache*[)] gcc_ccache=yes;;
2858     *[)] gcc_ccache=no;;
2859   esac
2860
2861   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2862     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2863   fi
2864
2865   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2866   AC_CHECK_PROG(LTP, lcov, lcov)
2867   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2868
2869   AS_IF([ test "$LTP" ], [
2870     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2871       glib_cv_ltp_version=invalid
2872       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2873       for ltp_check_version in $ltp_version_list; do
2874         if test "$ltp_version" = "$ltp_check_version"; then
2875           glib_cv_ltp_version="$ltp_check_version (ok)"
2876         fi
2877       done
2878     ])
2879   ], [
2880     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2881     AC_MSG_ERROR([$ltp_msg])
2882   ])
2883
2884   case $glib_cv_ltp_version in
2885     ""|invalid[)]
2886       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2887       AC_MSG_ERROR([$ltp_msg])
2888       LTP="exit 0;"
2889       ;;
2890   esac
2891
2892   if test -z "$LTP_GENHTML"; then
2893     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2894   fi
2895
2896   dnl Remove all optimization flags from CFLAGS
2897   changequote({,})
2898   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2899   changequote([,])
2900
2901   dnl Add the special gcc flags
2902   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2903   LDFLAGS="$LDFLAGS -lgcov"
2904 ])
2905
2906 dnl ******************************
2907 dnl *** output the whole stuff ***
2908 dnl ******************************
2909
2910 dnl this section will only be run if config.status is invoked with no
2911 dnl arguments, or with "glib/glibconfig.h" as an argument.
2912 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2913 [
2914         outfile=glib/glibconfig.h-tmp
2915         cat > $outfile <<\_______EOF
2916 /* glibconfig.h
2917  *
2918  * This is a generated file.  Please modify 'configure.ac'
2919  */
2920
2921 #ifndef __GLIBCONFIG_H__
2922 #define __GLIBCONFIG_H__
2923
2924 #include <glib/gmacros.h>
2925
2926 _______EOF
2927
2928         if test x$glib_limits_h = xyes; then
2929           echo '#include <limits.h>' >> $outfile
2930         fi
2931         if test x$glib_float_h = xyes; then
2932           echo '#include <float.h>' >> $outfile
2933         fi
2934         if test x$glib_values_h = xyes; then
2935           echo '#include <values.h>' >> $outfile
2936         fi
2937         if test "$glib_header_alloca_h" = "yes"; then
2938           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2939         fi
2940         if test x$glib_sys_poll_h = xyes; then
2941           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2942         fi
2943         if test x$glib_included_printf != xyes; then
2944           echo "
2945 /* Specifies that GLib's g_print*() functions wrap the
2946  * system printf functions.  This is useful to know, for example,
2947  * when using glibc's register_printf_function().
2948  */" >> $outfile
2949           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2950         fi
2951
2952         cat >> $outfile <<_______EOF
2953
2954 G_BEGIN_DECLS
2955
2956 #define G_MINFLOAT      $glib_mf
2957 #define G_MAXFLOAT      $glib_Mf
2958 #define G_MINDOUBLE     $glib_md
2959 #define G_MAXDOUBLE     $glib_Md
2960 #define G_MINSHORT      $glib_ms
2961 #define G_MAXSHORT      $glib_Ms
2962 #define G_MAXUSHORT     $glib_Mus
2963 #define G_MININT        $glib_mi
2964 #define G_MAXINT        $glib_Mi
2965 #define G_MAXUINT       $glib_Mui
2966 #define G_MINLONG       $glib_ml
2967 #define G_MAXLONG       $glib_Ml
2968 #define G_MAXULONG      $glib_Mul
2969
2970 _______EOF
2971
2972
2973         ### this should always be true in a modern C/C++ compiler
2974         cat >>$outfile <<_______EOF
2975 typedef signed char gint8;
2976 typedef unsigned char guint8;
2977 _______EOF
2978
2979
2980         if test -n "$gint16"; then
2981           cat >>$outfile <<_______EOF
2982 typedef signed $gint16 gint16;
2983 typedef unsigned $gint16 guint16;
2984 #define G_GINT16_MODIFIER $gint16_modifier
2985 #define G_GINT16_FORMAT $gint16_format
2986 #define G_GUINT16_FORMAT $guint16_format
2987 _______EOF
2988         fi
2989
2990
2991         if test -n "$gint32"; then
2992           cat >>$outfile <<_______EOF
2993 typedef signed $gint32 gint32;
2994 typedef unsigned $gint32 guint32;
2995 #define G_GINT32_MODIFIER $gint32_modifier
2996 #define G_GINT32_FORMAT $gint32_format
2997 #define G_GUINT32_FORMAT $guint32_format
2998 _______EOF
2999         fi
3000
3001         cat >>$outfile <<_______EOF
3002 #define G_HAVE_GINT64 1          /* deprecated, always true */
3003
3004 ${glib_extension}typedef signed $gint64 gint64;
3005 ${glib_extension}typedef unsigned $gint64 guint64;
3006
3007 #define G_GINT64_CONSTANT(val)  $gint64_constant
3008 #define G_GUINT64_CONSTANT(val) $guint64_constant
3009 _______EOF
3010
3011         if test x$gint64_format != x ; then
3012           cat >>$outfile <<_______EOF
3013 #define G_GINT64_MODIFIER $gint64_modifier
3014 #define G_GINT64_FORMAT $gint64_format
3015 #define G_GUINT64_FORMAT $guint64_format
3016 _______EOF
3017         else
3018           cat >>$outfile <<_______EOF
3019 #undef G_GINT64_MODIFIER
3020 #undef G_GINT64_FORMAT
3021 #undef G_GUINT64_FORMAT
3022 _______EOF
3023         fi
3024
3025         cat >>$outfile <<_______EOF
3026
3027 #define GLIB_SIZEOF_VOID_P $glib_void_p
3028 #define GLIB_SIZEOF_LONG   $glib_long
3029 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3030 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
3031
3032 _______EOF
3033
3034         cat >>$outfile <<_______EOF
3035 typedef signed $glib_ssize_type_define gssize;
3036 typedef unsigned $glib_size_type_define gsize;
3037 #define G_GSIZE_MODIFIER $gsize_modifier
3038 #define G_GSSIZE_MODIFIER $gssize_modifier
3039 #define G_GSIZE_FORMAT $gsize_format
3040 #define G_GSSIZE_FORMAT $gssize_format
3041
3042 #define G_MAXSIZE       G_MAXU$glib_msize_type
3043 #define G_MINSSIZE      G_MIN$glib_mssize_type
3044 #define G_MAXSSIZE      G_MAX$glib_mssize_type
3045
3046 typedef gint64 goffset;
3047 #define G_MINOFFSET     G_MININT64
3048 #define G_MAXOFFSET     G_MAXINT64
3049
3050 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3051 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3052 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3053
3054 _______EOF
3055
3056         if test -z "$glib_unknown_void_p"; then
3057           cat >>$outfile <<_______EOF
3058
3059 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3060 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3061
3062 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3063 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3064
3065 typedef signed $glib_intptr_type_define gintptr;
3066 typedef unsigned $glib_intptr_type_define guintptr;
3067
3068 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3069 #define G_GINTPTR_FORMAT        $gintptr_format
3070 #define G_GUINTPTR_FORMAT       $guintptr_format
3071 _______EOF
3072         else
3073           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3074         fi
3075
3076
3077
3078         cat >>$outfile <<_______EOF
3079 $glib_atexit
3080 $glib_memmove
3081 $glib_defines
3082 $glib_os
3083 $glib_static_compilation
3084
3085 $glib_vacopy
3086
3087 #ifdef  __cplusplus
3088 #define G_HAVE_INLINE   1
3089 #else   /* !__cplusplus */
3090 $glib_inline
3091 #endif  /* !__cplusplus */
3092
3093 #ifdef  __cplusplus
3094 #define G_CAN_INLINE    1
3095 _______EOF
3096
3097         if test x$g_can_inline = xyes ; then
3098                 cat >>$outfile <<_______EOF
3099 #else   /* !__cplusplus */
3100 #define G_CAN_INLINE    1
3101 _______EOF
3102         fi
3103
3104         cat >>$outfile <<_______EOF
3105 #endif
3106
3107 _______EOF
3108
3109         if test x$g_have_iso_c_varargs = xyes ; then
3110                 cat >>$outfile <<_______EOF
3111 #ifndef __cplusplus
3112 # define G_HAVE_ISO_VARARGS 1
3113 #endif
3114 _______EOF
3115         fi
3116         if test x$g_have_iso_cxx_varargs = xyes ; then
3117                 cat >>$outfile <<_______EOF
3118 #ifdef __cplusplus
3119 # define G_HAVE_ISO_VARARGS 1
3120 #endif
3121 _______EOF
3122         fi
3123         if test x$g_have_gnuc_varargs = xyes ; then
3124                 cat >>$outfile <<_______EOF
3125
3126 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3127  * is passed ISO vararg support is turned off, and there is no work
3128  * around to turn it on, so we unconditionally turn it off.
3129  */
3130 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3131 #  undef G_HAVE_ISO_VARARGS
3132 #endif
3133
3134 #define G_HAVE_GNUC_VARARGS 1
3135 _______EOF
3136         fi
3137
3138         case x$g_stack_grows in
3139         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3140         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3141         esac
3142
3143
3144         echo >>$outfile
3145         if test x$g_have_eilseq = xno; then
3146                 cat >>$outfile <<_______EOF
3147 #ifndef EILSEQ
3148 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3149  * The correspondence between this and the corresponding definition
3150  * in libiconv is essential.
3151  */
3152 #  define EILSEQ ENOENT
3153 #endif
3154 _______EOF
3155
3156         fi
3157
3158         if test x$g_have_gnuc_visibility = xyes; then
3159                 cat >>$outfile <<_______EOF
3160 #define G_HAVE_GNUC_VISIBILITY 1
3161 _______EOF
3162         fi
3163                 cat >>$outfile <<_______EOF
3164 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3165 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3166 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3167 #define G_GNUC_INTERNAL __hidden
3168 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3169 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3170 #else
3171 #define G_GNUC_INTERNAL
3172 #endif
3173 _______EOF
3174
3175         echo >>$outfile
3176         cat >>$outfile <<_______EOF
3177 #define G_THREADS_ENABLED
3178 #define G_THREADS_IMPL_$g_threads_impl_def
3179 _______EOF
3180
3181         if test x"$g_memory_barrier_needed" != xno; then
3182           echo >>$outfile
3183           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3184         fi
3185         if test x"$g_atomic_lock_free" = xyes; then
3186           echo >>$outfile
3187           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3188         fi
3189         echo >>$outfile
3190         g_bit_sizes="16 32 64"
3191         for bits in $g_bit_sizes; do
3192           cat >>$outfile <<_______EOF
3193 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3194 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3195 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3196 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3197 _______EOF
3198         done
3199
3200         cat >>$outfile <<_______EOF
3201 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3202 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3203 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3204 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3205 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3206 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3207 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3208 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3209 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3210 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3211 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3212 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3213 #define G_BYTE_ORDER $g_byte_order
3214
3215 #define GLIB_SYSDEF_POLLIN =$g_pollin
3216 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3217 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3218 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3219 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3220 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3221
3222 #define G_MODULE_SUFFIX "$g_module_suffix"
3223
3224 typedef $g_pid_type GPid;
3225
3226 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3227 #define GLIB_SYSDEF_AF_INET $g_af_inet
3228 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3229
3230 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3231 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3232 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3233
3234 G_END_DECLS
3235
3236 #endif /* __GLIBCONFIG_H__ */
3237 _______EOF
3238
3239
3240         if cmp -s $outfile glib/glibconfig.h; then
3241           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3242           rm -f $outfile
3243         else
3244           mv $outfile glib/glibconfig.h
3245         fi
3246 ],[
3247
3248 # Note that if two cases are the same, case goes with the first one.
3249 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3250 # on variable expansion in case labels.  Look at the generated config.status
3251 # for a hint.
3252
3253 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3254   glib_header_alloca_h="$ac_cv_working_alloca_h"
3255 else
3256   glib_header_alloca_h="$ac_cv_header_alloca_h"
3257 fi
3258
3259 case xyes in
3260 x$ac_cv_header_float_h)
3261   glib_float_h=yes
3262   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3263   glib_md=DBL_MIN glib_Md=DBL_MAX
3264   ;;
3265 x$ac_cv_header_values_h)
3266   glib_values_h=yes
3267   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3268   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3269   ;;
3270 esac
3271
3272 case xyes in
3273 x$ac_cv_header_limits_h)
3274   glib_limits_h=yes
3275   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3276   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3277   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3278   ;;
3279 x$ac_cv_header_values_h)
3280   glib_values_h=yes
3281   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3282   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3283   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3284   ;;
3285 esac
3286
3287 if test x$ac_cv_header_sys_poll_h = xyes ; then
3288   glib_sys_poll_h=yes
3289 fi
3290
3291 if test x$enable_included_printf = xyes ; then
3292   glib_included_printf=yes
3293 fi
3294
3295 case 2 in
3296 $ac_cv_sizeof_short)
3297   gint16=short
3298   gint16_modifier='"h"'
3299   gint16_format='"hi"'
3300   guint16_format='"hu"'
3301   ;;
3302 $ac_cv_sizeof_int)
3303   gint16=int
3304   gint16_modifier='""'
3305   gint16_format='"i"'
3306   guint16_format='"u"'
3307   ;;
3308 esac
3309 case 4 in
3310 $ac_cv_sizeof_short)
3311   gint32=short
3312   gint32_modifier='"h"'
3313   gint32_format='"hi"'
3314   guint32_format='"hu"'
3315   ;;
3316 $ac_cv_sizeof_int)
3317   gint32=int
3318   gint32_modifier='""'
3319   gint32_format='"i"'
3320   guint32_format='"u"'
3321   ;;
3322 $ac_cv_sizeof_long)
3323   gint32=long
3324   gint32_modifier='"l"'
3325   gint32_format='"li"'
3326   guint32_format='"lu"'
3327   ;;
3328 esac
3329 case 8 in
3330 $ac_cv_sizeof_int)
3331   gint64=int
3332   gint64_modifier='""'
3333   gint64_format='"i"'
3334   guint64_format='"u"'
3335   glib_extension=
3336   gint64_constant='(val)'
3337   guint64_constant='(val)'
3338   ;;
3339 $ac_cv_sizeof_long)
3340   gint64=long
3341   gint64_modifier='"l"'
3342   gint64_format='"li"'
3343   guint64_format='"lu"'
3344   glib_extension=
3345   gint64_constant='(val##L)'
3346   guint64_constant='(val##UL)'
3347   ;;
3348 $ac_cv_sizeof_long_long)
3349   gint64='long long'
3350   if test -n "$glib_cv_long_long_format"; then
3351     gint64_modifier='"'$glib_cv_long_long_format'"'
3352     gint64_format='"'$glib_cv_long_long_format'i"'
3353     guint64_format='"'$glib_cv_long_long_format'u"'
3354   fi
3355   glib_extension='G_GNUC_EXTENSION '
3356   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3357   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3358   ;;
3359 $ac_cv_sizeof___int64)
3360   gint64='__int64'
3361   if test -n "$glib_cv_long_long_format"; then
3362     gint64_modifier='"'$glib_cv_long_long_format'"'
3363     gint64_format='"'$glib_cv_long_long_format'i"'
3364     guint64_format='"'$glib_cv_long_long_format'u"'
3365   fi
3366   glib_extension=
3367   gint64_constant='(val##i64)'
3368   guint64_constant='(val##ui64)'
3369   ;;
3370 esac
3371 glib_size_t=$ac_cv_sizeof_size_t
3372 glib_ssize_t=$ac_cv_sizeof_ssize_t
3373 glib_size_type_define="$glib_size_type"
3374 glib_ssize_type_define="$glib_ssize_type"
3375 glib_void_p=$ac_cv_sizeof_void_p
3376 glib_long=$ac_cv_sizeof_long
3377
3378 case "$glib_size_type" in
3379 short)
3380   gsize_modifier='"h"'
3381   gsize_format='"hu"'
3382   glib_msize_type='SHRT'
3383   ;;
3384 int)
3385   gsize_modifier='""'
3386   gsize_format='"u"'
3387   glib_msize_type='INT'
3388   ;;
3389 long)
3390   gsize_modifier='"l"'
3391   gsize_format='"lu"'
3392   glib_msize_type='LONG'
3393   ;;
3394 "long long"|__int64)
3395   gsize_modifier='"I64"'
3396   gsize_format='"I64u"'
3397   glib_msize_type='INT64'
3398   ;;
3399 esac
3400
3401 case "$glib_ssize_type" in
3402 short)
3403   gssize_modifier='"h"'
3404   gssize_format='"hi"'
3405   glib_mssize_type='SHRT'
3406   ;;
3407 int)
3408   gssize_modifier='""'
3409   gssize_format='"i"'
3410   glib_mssize_type='INT'
3411   ;;
3412 long)
3413   gssize_modifier='"l"'
3414   gssize_format='"li"'
3415   glib_mssize_type='LONG'
3416   ;;
3417 "long long"|__int64)
3418   gssize_modifier='"I64"'
3419   gssize_format='"I64i"'
3420   glib_mssize_type='INT64'
3421   ;;
3422 esac
3423
3424 gintbits=`expr $ac_cv_sizeof_int \* 8`
3425 glongbits=`expr $ac_cv_sizeof_long \* 8`
3426 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3427 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3428
3429 case $ac_cv_sizeof_void_p in
3430 $ac_cv_sizeof_int)
3431   glib_intptr_type_define=int
3432   gintptr_modifier='""'
3433   gintptr_format='"i"'
3434   guintptr_format='"u"'
3435   glib_gpi_cast='(gint)'
3436   glib_gpui_cast='(guint)'
3437   ;;
3438 $ac_cv_sizeof_long)
3439   glib_intptr_type_define=long
3440   gintptr_modifier='"l"'
3441   gintptr_format='"li"'
3442   guintptr_format='"lu"'
3443   glib_gpi_cast='(glong)'
3444   glib_gpui_cast='(gulong)'
3445   ;;
3446 $ac_cv_sizeof_long_long)
3447   glib_intptr_type_define='long long'
3448   gintptr_modifier='"I64"'
3449   gintptr_format='"I64i"'
3450   guintptr_format='"I64u"'
3451   glib_gpi_cast='(gint64)'
3452   glib_gpui_cast='(guint64)'
3453   ;;
3454 $ac_cv_sizeof___int64)
3455   glib_intptr_type_define=__int64
3456   gintptr_modifier='"I64"'
3457   gintptr_format='"I64i"'
3458   guintptr_format='"I64u"'
3459   glib_gpi_cast='(gint64)'
3460   glib_gpui_cast='(guint64)'
3461   ;;
3462 *)
3463   glib_unknown_void_p=yes
3464   ;;
3465 esac
3466
3467
3468 case xyes in
3469 x$ac_cv_func_atexit)
3470   glib_atexit="
3471 #ifdef NeXT /* @#%@! NeXTStep */
3472 # define g_ATEXIT(proc) (!atexit (proc))
3473 #else
3474 # define g_ATEXIT(proc) (atexit (proc))
3475 #endif"
3476   ;;
3477 x$ac_cv_func_on_exit)
3478   glib_atexit="
3479 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3480   ;;
3481 esac
3482
3483 case xyes in
3484 x$ac_cv_func_memmove)
3485   glib_memmove='
3486 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3487   ;;
3488 x$glib_cv_working_bcopy)
3489   glib_memmove="
3490 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3491 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3492   ;;
3493 *)
3494   glib_memmove="
3495 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3496  * so we have to roll our own copy routine. */
3497 void g_memmove (void* dest, const void * src, unsigned long len);"
3498   ;;
3499 esac
3500
3501 glib_defines="
3502 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3503 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3504 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3505 "
3506
3507 case xyes in
3508 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3509 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3510 *)                      glib_vacopy=''
3511 esac
3512
3513 if test x$glib_cv_va_val_copy = xno; then
3514   glib_vacopy="\$glib_vacopy
3515 #define G_VA_COPY_AS_ARRAY 1"
3516 fi
3517
3518 if test x$glib_cv_hasinline = xyes; then
3519     glib_inline='#define G_HAVE_INLINE 1'
3520 fi
3521 if test x$glib_cv_has__inline = xyes; then
3522     glib_inline="\$glib_inline
3523 #define G_HAVE___INLINE 1"
3524 fi
3525 if test x$glib_cv_has__inline__ = xyes; then
3526     glib_inline="\$glib_inline
3527 #define G_HAVE___INLINE__ 1"
3528 fi
3529
3530 g_have_gnuc_varargs=$g_have_gnuc_varargs
3531 g_have_iso_c_varargs=$g_have_iso_c_varargs
3532 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3533
3534 g_can_inline=$g_can_inline
3535 g_have_gnuc_visibility=$g_have_gnuc_visibility
3536 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3537
3538 if test x$ac_cv_c_bigendian = xyes; then
3539   g_byte_order=G_BIG_ENDIAN
3540   g_bs_native=BE
3541   g_bs_alien=LE
3542 else
3543   g_byte_order=G_LITTLE_ENDIAN
3544   g_bs_native=LE
3545   g_bs_alien=BE
3546 fi
3547
3548 g_pollin=$glib_cv_value_POLLIN
3549 g_pollout=$glib_cv_value_POLLOUT
3550 g_pollpri=$glib_cv_value_POLLPRI
3551 g_pollhup=$glib_cv_value_POLLHUP
3552 g_pollerr=$glib_cv_value_POLLERR
3553 g_pollnval=$glib_cv_value_POLLNVAL
3554
3555 # If a family is not found on the system, define that family to
3556 # a negative value, picking a different one for each undefined
3557 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3558 # This is needed because glib-mkenums doesn't handle optional
3559 # values in enums, and thus we have to have all existing values
3560 # defined in the enum.
3561 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3562   g_af_unix=$glib_cv_value_AF_UNIX
3563 else
3564   g_af_unix=-1
3565 fi
3566 g_af_inet=$glib_cv_value_AF_INET
3567 g_af_inet6=$glib_cv_value_AF_INET6
3568
3569 g_msg_peek=$glib_cv_value_MSG_PEEK
3570 g_msg_oob=$glib_cv_value_MSG_OOB
3571 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3572
3573 g_stack_grows=$glib_cv_stack_grows
3574
3575 g_have_eilseq=$have_eilseq
3576
3577 g_threads_impl_def=$g_threads_impl
3578
3579 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3580 g_memory_barrier_needed="$glib_memory_barrier_needed"
3581 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3582
3583 g_module_suffix="$glib_gmodule_suffix"
3584
3585 g_pid_type="$glib_pid_type"
3586 case $host in
3587   *-*-beos*)
3588     glib_os="#define G_OS_BEOS"
3589     ;;
3590   *-*-cygwin*)
3591     glib_os="#define G_OS_UNIX
3592 #define G_PLATFORM_WIN32
3593 #define G_WITH_CYGWIN"
3594     ;;
3595   *-*-mingw*)
3596     glib_os="#define G_OS_WIN32
3597 #define G_PLATFORM_WIN32"
3598     ;;
3599   *)
3600     glib_os="#define G_OS_UNIX"
3601     ;;
3602 esac
3603 glib_static_compilation=""
3604 if test x$glib_win32_static_compilation = xyes; then
3605   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3606 #define GOBJECT_STATIC_COMPILATION 1"
3607 fi
3608 ])
3609
3610 # Redo enough to get guint32 and guint64 for the alignment checks below
3611 case 4 in
3612 $ac_cv_sizeof_short)
3613   gint32=short
3614   ;;
3615 $ac_cv_sizeof_int)
3616   gint32=int
3617   ;;
3618 $ac_cv_sizeof_long)
3619   gint32=long
3620   ;;
3621 esac
3622 case 8 in
3623 $ac_cv_sizeof_int)
3624   gint64=int
3625   ;;
3626 $ac_cv_sizeof_long)
3627   gint64=long
3628   ;;
3629 $ac_cv_sizeof_long_long)
3630   gint64='long long'
3631   ;;
3632 $ac_cv_sizeof___int64)
3633   gint64='__int64'
3634   ;;
3635 esac
3636
3637 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3638 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3639 typedef unsigned $gint32 guint32;])
3640 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3641 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3642 typedef unsigned $gint64 guint64;])
3643 AC_CHECK_TYPE([unsigned long])
3644 AC_CHECK_ALIGNOF([unsigned long])
3645
3646 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3647 #
3648 # 1.2.14 required for dbus_message_set_serial
3649 PKG_CHECK_MODULES(DBUS1,
3650      dbus-1 >= 1.2.14,
3651      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3652      have_dbus1=no)
3653 AC_SUBST(DBUS1_CFLAGS)
3654 AC_SUBST(DBUS1_LIBS)
3655 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3656
3657 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3658 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3659
3660 dnl
3661 dnl Check for -Bsymbolic-functions linker flag used to avoid
3662 dnl intra-library PLT jumps, if available.
3663 dnl
3664
3665 AC_ARG_ENABLE(Bsymbolic,
3666               [AS_HELP_STRING([--disable-Bsymbolic],
3667                               [avoid linking with -Bsymbolic])],,
3668               [SAVED_LDFLAGS="${LDFLAGS}"
3669                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3670                LDFLAGS=-Wl,-Bsymbolic-functions
3671                AC_TRY_LINK([], [int main (void) { return 0; }],
3672                            AC_MSG_RESULT(yes)
3673                            enable_Bsymbolic=yes,
3674                            AC_MSG_RESULT(no)
3675                            enable_Bsymbolic=no)
3676                LDFLAGS="${SAVED_LDFLAGS}"])
3677
3678 if test "x${enable_Bsymbolic}" = "xyes"; then
3679   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3680 fi
3681
3682 AC_SUBST(GLIB_LINK_FLAGS)
3683
3684 dnl
3685 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3686 dnl visibility attributes for symbol export control
3687 dnl
3688 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3689 case "$host" in
3690   *-*-mingw*)
3691     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3692     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3693               [defines how to decorate public symbols while building])
3694     CFLAGS="${CFLAGS} -fvisibility=hidden"
3695     ;;
3696   *)
3697     dnl on other compilers, check if we can do -fvisibility=hidden
3698     SAVED_CFLAGS="${CFLAGS}"
3699     CFLAGS="-fvisibility=hidden"
3700     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3701     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3702                    AC_MSG_RESULT(yes)
3703                    enable_fvisibility_hidden=yes,
3704                    AC_MSG_RESULT(no)
3705                    enable_fvisibility_hidden=no)
3706     CFLAGS="${SAVED_CFLAGS}"
3707
3708     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3709       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3710                 [defines how to decorate public symbols while building])
3711       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3712     ])
3713     ;;
3714 esac
3715 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3716
3717 dnl Compiler flags; macro originates from systemd
3718 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3719 AC_ARG_ENABLE(compile-warnings,
3720               [AS_HELP_STRING([--disable-compile-warnings],
3721                               [Don't use builtin compiler warnings])],,
3722                               enable_compile_warnings=yes)
3723 AS_IF([test "x$enable_compile_warnings" = xyes], [
3724   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3725    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3726    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3727    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3728    -Werror=format=2 -Werror=missing-include-dirs])
3729 ])
3730 AC_SUBST(GLIB_WARN_CFLAGS)
3731
3732 #
3733 # Define variables corresponding to the correct include paths to use for
3734 # in-tree building.
3735 #
3736
3737 # for config.h:
3738 config_h_INCLUDES='-I$(top_builddir)'
3739 AC_SUBST(config_h_INCLUDES)
3740
3741 # glib:
3742 #   config.h
3743 #   $(top_builddir)/glib: for glibconfig.h
3744 #   $(top_srcdir)/glib:   for glib.h
3745 #   $(top_srcdir):        for everything
3746 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3747 AC_SUBST(glib_INCLUDES)
3748
3749 # gobject:
3750 #   same as glib
3751 gobject_INCLUDES='$(glib_INCLUDES)'
3752 AC_SUBST(gobject_INCLUDES)
3753
3754 # gmodule:
3755 #   glib includes
3756 #   $(top_srcdir)/gmodule: for gmodule.h
3757 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3758 AC_SUBST(gmodule_INCLUDES)
3759
3760 # gio:
3761 #   same as gmodule
3762 gio_INCLUDES='$(gmodule_INCLUDES)'
3763 AC_SUBST(gio_INCLUDES)
3764
3765
3766 AC_CONFIG_FILES([
3767 glib-2.0.pc
3768 gmodule-2.0.pc
3769 gmodule-export-2.0.pc
3770 gmodule-no-export-2.0.pc
3771 gthread-2.0.pc
3772 gobject-2.0.pc
3773 gio-2.0.pc
3774 gio-unix-2.0.pc
3775 gio-windows-2.0.pc
3776 glib-zip
3777 glib-gettextize
3778 Makefile
3779 build/Makefile
3780 build/win32/Makefile
3781 build/win32/dirent/Makefile
3782 build/win32/vs9/Makefile
3783 build/win32/vs10/Makefile
3784 build/win32/vs11/Makefile
3785 glib/Makefile
3786 glib/glib.stp
3787 glib/libcharset/Makefile
3788 glib/gnulib/Makefile
3789 glib/pcre/Makefile
3790 glib/update-pcre/Makefile
3791 glib/tests/Makefile
3792 gmodule/Makefile
3793 gmodule/gmoduleconf.h
3794 gobject/Makefile
3795 gobject/gobject.stp
3796 gobject/glib-mkenums
3797 gobject/tests/Makefile
3798 gthread/Makefile
3799 gio/Makefile
3800 gio/gdbus-2.0/codegen/Makefile
3801 gio/gdbus-2.0/codegen/config.py
3802 gio/gnetworking.h
3803 gio/xdgmime/Makefile
3804 gio/inotify/Makefile
3805 gio/kqueue/Makefile
3806 gio/fen/Makefile
3807 gio/fam/Makefile
3808 gio/win32/Makefile
3809 gio/tests/Makefile
3810 gio/tests/gdbus-object-manager-example/Makefile
3811 gio/tests/services/Makefile
3812 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3813 po/Makefile.in
3814 docs/Makefile
3815 docs/reference/Makefile
3816 docs/reference/glib/Makefile
3817 docs/reference/glib/version.xml
3818 docs/reference/gobject/Makefile
3819 docs/reference/gobject/version.xml
3820 docs/reference/gio/Makefile
3821 docs/reference/gio/gdbus-object-manager-example/Makefile
3822 docs/reference/gio/version.xml
3823 tests/Makefile
3824 tests/gobject/Makefile
3825 tests/refcount/Makefile
3826 m4macros/Makefile
3827 ])
3828
3829 AC_CONFIG_COMMANDS([chmod-scripts],
3830 [chmod 0755 glib-zip
3831 chmod 0755 glib-gettextize
3832 chmod 0755 gobject/glib-mkenums])
3833
3834 # we want to invoke this macro solely so that the config.status script
3835 # and automake generated makefiles know about these generated files.
3836 # They are only needed to distcheck the package
3837 if false; then
3838   AC_CONFIG_FILES([
3839     INSTALL
3840     README
3841     config.h.win32
3842     glib/glibconfig.h.win32
3843     glib/makefile.msc
3844     glib/glib.rc
3845     gmodule/makefile.msc
3846     gmodule/gmodule.rc
3847     gobject/makefile.msc
3848     gobject/gobject.rc
3849     gthread/makefile.msc
3850     gthread/gthread.rc
3851     gio/gio.rc
3852     tests/makefile.msc
3853   ])
3854 fi
3855
3856 AC_OUTPUT