configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.31,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.36
  58 GSTPB_REQ=0.10.36
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for gconftool-2
 134 dnl this macro defines an am conditional, so it needs to be run always
 135 AM_GCONF_SOURCE_2
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl check for libm, for sin()
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used by ext/wavpack
 154 AX_CREATE_STDINT_H
 155
 156 dnl used in gst/rtp/gstasteriskh263.c
 157 AC_CHECK_HEADERS([netinet/in.h])
 158 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 159 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 160
 161 dnl used in gst/udp
 162 AC_CHECK_HEADERS([sys/time.h])
 163
 164 dnl *** checks for types/defines ***
 165
 166 dnl Check for FIONREAD ioctl declaration.  This check is needed
 167 dnl for the UDP plugin to build on Solaris
 168 GST_CHECK_FIONREAD
 169
 170 dnl *** checks for structures ***
 171
 172 dnl *** checks for compiler characteristics ***
 173
 174 dnl check if we have GCC inline-asm
 175 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 176 if test x$HAVE_GCC_ASM = xyes ; then
 177   AC_DEFINE(HAVE_GCC_ASM, 1,
 178     [Define if compiler supports gcc inline assembly])
 179 fi
 180 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 181
 182 dnl *** checks for library functions ***
 183
 184 LIBS_SAVE=$LIBS
 185 LIBS="$LIBS $LIBM"
 186 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 187 LIBS=$LIBS_SAVE
 188
 189 dnl Check whether isinf() is defined by math.h
 190 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 191     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 192 if test "$ac_cv_have_isinf" = "yes"
 193 then
 194     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 195 fi
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198 AC_FUNC_MMAP
 199 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 200
 201 dnl Check for mmap (needed by electricfence plugin)
 202
 203 AC_CHECK_TYPE([struct ip_mreqn], [
 204               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 205               [#include <netinet/in.h>])
 206
 207 dnl *** checks for dependency libraries ***
 208
 209 dnl GLib is required
 210 AG_GST_GLIB_CHECK([2.24])
 211 PKG_CHECK_MODULES(GIO, [ gio-2.0 >= 2.20 ], , AC_MSG_ERROR([gio is required]))
 212
 213 dnl Orc
 214 ORC_CHECK([0.4.11])
 215
 216 dnl checks for gstreamer
 217 dnl uninstalled is selected preferentially -- see pkg-config(1)
 218 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 223 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 224
 225 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 226 if test -z $GST_TOOLS_DIR; then
 227   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 228 fi
 229 AC_SUBST(GST_TOOLS_DIR)
 230
 231 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 232 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 233
 234 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 235
 236 dnl Check for documentation xrefs
 237 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 238 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 239 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 240 AC_SUBST(GLIB_PREFIX)
 241 AC_SUBST(GST_PREFIX)
 242 AC_SUBST(GSTPB_PREFIX)
 243
 244 dnl GTK is optional and used in examples
 245 HAVE_GTK=no
 246 GTK2_REQ=2.14.0
 247 GTK3_REQ=2.91.3
 248 if test "x$BUILD_EXAMPLES" = "xyes"; then
 249   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 250   AC_ARG_WITH([gtk],
 251     AC_HELP_STRING([--with-gtk=3.0|2.0],
 252                    [which gtk+ version to compile against (default: 2.0)]),
 253     [case "$with_gtk" in
 254         2.0) GTK_REQ=$GTK2_REQ ;;
 255         3.0) GTK_REQ=$GTK3_REQ ;;
 256         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 257     esac],
 258     [with_gtk=2.0
 259      GTK_REQ=$GTK2_REQ])
 260   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 261   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 262   dnl some examples need gtk+-x11
 263   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 264   AC_SUBST(GTK_LIBS)
 265   AC_SUBST(GTK_CFLAGS)
 266 fi
 267 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 268 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 269
 270 dnl should we install schemas ?
 271 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 272 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 273   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 274   if test x$GCONFTOOL = xno; then
 275     AC_MSG_WARN(Not installing GConf schemas)
 276     HAVE_GCONFTOOL="no"
 277   else
 278     HAVE_GCONFTOOL="yes"
 279   fi
 280   AC_SUBST(HAVE_GCONFTOOL)
 281 ])
 282
 283 dnl use divx drm --------------------------------------------------------------------------
 284 AC_ARG_ENABLE(divx-drm, AC_HELP_STRING([--enable-divx-drm], [using divx drm]),
 285   [
 286     case "${enableval}" in
 287       yes) USE_DIVX_DRM=yes ;;
 288        no) USE_DIVX_DRM=no ;;
 289         *) AC_MSG_ERROR(bad value ${enableval} for --enable-divx-drm) ;;
 290     esac
 291   ],
 292   [USE_DIVX_DRM=no])
 293 AM_CONDITIONAL(USE_DIVX_DRM, test "x$USE_DIVX_DRM" = "xyes")
 294
 295 dnl *** set variables based on configure arguments ***
 296
 297 dnl set license and copyright notice
 298 GST_LICENSE="LGPL"
 299 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 300 AC_SUBST(GST_LICENSE)
 301
 302 dnl set location of plugin directory
 303 AG_GST_SET_PLUGINDIR
 304
 305 dnl set release date/time
 306 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 307   ["${srcdir}/gst-plugins-good.doap"],
 308   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 309
 310 dnl define an ERROR_CFLAGS Makefile variable
 311 dnl -Wundef: too many broken headers
 312 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 313   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 314         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 315         -Wwrite-strings -Wold-style-definition -Waggregate-return
 316         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 317         -Wnested-externs ])
 318 else
 319   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 320   dnl doesn't understand all warning flags that the C compiler knows about
 321   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 322   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 323         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 324         -Wwrite-strings -Wold-style-definition
 325         -Winit-self -Wmissing-include-dirs -Wno-multichar
 326         -Wnested-externs ])
 327 fi
 328
 329 dnl define an ERROR_CXXFLAGS Makefile variable
 330 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 331         -Wmissing-declarations -Wredundant-decls
 332         -Wwrite-strings
 333         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 334
 335 dnl define correct level for debugging messages
 336 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 337
 338 dnl used in examples
 339 AG_GST_DEFAULT_ELEMENTS
 340
 341 dnl *** plug-ins to include ***
 342
 343 dnl these are all the gst plug-ins, compilable without additional libs
 344 dnl videofilter is at the top because others depend on it
 345 AG_GST_CHECK_PLUGIN(videofilter)
 346 AG_GST_CHECK_PLUGIN(alpha)
 347 AG_GST_CHECK_PLUGIN(apetag)
 348 AG_GST_CHECK_PLUGIN(audiofx)
 349 AG_GST_CHECK_PLUGIN(audioparsers)
 350 AG_GST_CHECK_PLUGIN(auparse)
 351 AG_GST_CHECK_PLUGIN(autodetect)
 352 AG_GST_CHECK_PLUGIN(avi)
 353 AG_GST_CHECK_PLUGIN(cutter)
 354 AG_GST_CHECK_PLUGIN(debugutils)
 355 AG_GST_CHECK_PLUGIN(deinterlace)
 356 AG_GST_CHECK_PLUGIN(effectv)
 357 AG_GST_CHECK_PLUGIN(equalizer)
 358 AG_GST_CHECK_PLUGIN(flv)
 359 AG_GST_CHECK_PLUGIN(id3demux)
 360 AG_GST_CHECK_PLUGIN(icydemux)
 361 AG_GST_CHECK_PLUGIN(interleave)
 362 AG_GST_CHECK_PLUGIN(flx)
 363 AG_GST_CHECK_PLUGIN(goom)
 364 AG_GST_CHECK_PLUGIN(goom2k1)
 365 AG_GST_CHECK_PLUGIN(imagefreeze)
 366 AG_GST_CHECK_PLUGIN(isomp4)
 367 AG_GST_CHECK_PLUGIN(law)
 368 AG_GST_CHECK_PLUGIN(level)
 369 AG_GST_CHECK_PLUGIN(matroska)
 370 AG_GST_CHECK_PLUGIN(monoscope)
 371 AG_GST_CHECK_PLUGIN(multifile)
 372 AG_GST_CHECK_PLUGIN(multipart)
 373 AG_GST_CHECK_PLUGIN(replaygain)
 374 AG_GST_CHECK_PLUGIN(rtp)
 375 AG_GST_CHECK_PLUGIN(rtpmanager)
 376 AG_GST_CHECK_PLUGIN(rtsp)
 377 AG_GST_CHECK_PLUGIN(shapewipe)
 378 AG_GST_CHECK_PLUGIN(smpte)
 379 AG_GST_CHECK_PLUGIN(spectrum)
 380 AG_GST_CHECK_PLUGIN(udp)
 381 AG_GST_CHECK_PLUGIN(videobox)
 382 AG_GST_CHECK_PLUGIN(videocrop)
 383 AG_GST_CHECK_PLUGIN(videomixer)
 384 AG_GST_CHECK_PLUGIN(wavenc)
 385 AG_GST_CHECK_PLUGIN(wavparse)
 386 AG_GST_CHECK_PLUGIN(y4m)
 387
 388 dnl *** checks for socket and nsl libraries ***
 389 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 390
 391 dnl disable gst plugins we might not be able to build on this
 392 dnl platform: udp and rtsp (ugly but minimally invasive)
 393 dnl FIXME: maybe move to sys
 394 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 395 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 396
 397 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 398   AG_GST_DISABLE_PLUGIN(udp)
 399   AG_GST_DISABLE_PLUGIN(rtsp)
 400 fi
 401
 402 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 403   WIN32_LIBS="-lws2_32"
 404   AC_SUBST(WIN32_LIBS)
 405 fi
 406
 407 dnl disable experimental plug-ins
 408 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 409   AG_GST_DISABLE_PLUGIN(monoscope)
 410 fi
 411
 412 dnl *** sys plug-ins ***
 413
 414 echo
 415 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 416 echo
 417
 418 dnl DirectSound
 419 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 420 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 421   HAVE_DIRECTSOUND="no"
 422   save_CFLAGS="$CFLAGS"
 423   save_LDFLAGS="$LDFLAGS"
 424   save_LIBS="$LIBS"
 425   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 426   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 427   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 428   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 429   AC_LINK_IFELSE([
 430 #include <windows.h>
 431 #include <dxerr9.h>
 432 #include <dsound.h>
 433
 434 int main ()
 435 {
 436   DXGetErrorString9 (0);
 437   DirectSoundCreate(NULL, NULL, NULL);
 438
 439   return 0;
 440 }
 441 ],
 442     [HAVE_DIRECTSOUND="yes"],
 443     [HAVE_DIRECTSOUND="no"])
 444   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 445   CFLAGS=$save_CFLAGS
 446   LDFLAGS=$save_LDFLAGS
 447   LIBS=$save_LIBS
 448
 449   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 450     dnl this is much more than we want
 451     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 452     AC_SUBST(DIRECTSOUND_CFLAGS)
 453     AC_SUBST(DIRECTSOUND_LDFLAGS)
 454     AC_SUBST(DIRECTSOUND_LIBS)
 455   fi
 456   AC_SUBST(HAVE_DIRECTSOUND)
 457 ])
 458
 459 dnl *** OSS audio *** (Linux, *BSD)
 460 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 461 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 462  HAVE_OSS="yes"
 463 dnl Linux and newer BSD versions :
 464  AC_CHECK_HEADER(sys/soundcard.h, [
 465    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 466    ] , [
 467 dnl Some old BSD versions and also newer OpenBSD versions :
 468    AC_CHECK_HEADER(soundcard.h, [
 469      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 470      ], [
 471   dnl Some old BSD versions :
 472      AC_CHECK_HEADER(machine/soundcard.h, [
 473        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 474          [Define if OSS includes are in /machine/])
 475        ], [
 476        HAVE_OSS="no"
 477      ])
 478    ])
 479  ])
 480 ])
 481
 482 dnl *** oss4 ***
 483 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 484 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 485   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 486   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 487       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 488       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 489 ])
 490
 491 dnl *** Sun Audio ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 493 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 494   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 495 ])
 496
 497 dnl *** OSX Audio ***
 498 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 499 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 500   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 501 ])
 502
 503 dnl *** OS X video ***
 504 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 505 HAVE_OSX_VIDEO="no"
 506 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 507   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 508 ])
 509 dnl in case header OpenGL/gl.h is found on other platforms
 510 case "$host" in
 511   *-*darwin*)
 512     dnl do nothing
 513     ;;
 514   *)
 515     HAVE_OSX_VIDEO="no"
 516     ;;
 517 esac
 518
 519
 520 dnl *** Video 4 Linux 2 ***
 521 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 522 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 523 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 524 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 525   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 526   AC_TRY_COMPILE([
 527 #include <sys/types.h>
 528 #ifdef __sun /* Solaris */
 529 #include <sys/types.h>
 530 #include <sys/videodev2.h>
 531 #else /* Linux */
 532 #include <linux/types.h>
 533 #define _LINUX_TIME_H
 534 #define __user
 535 #include <linux/videodev2.h>
 536 #endif
 537 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 538 #error too early v4l2 version or no v4l2 at all
 539 #endif
 540     ], [
 541 return 0;
 542     ], [
 543       HAVE_GST_V4L2="yes"
 544       AC_MSG_RESULT(yes)
 545     ], [
 546       HAVE_GST_V4L2="no"
 547       AC_MSG_RESULT(no)
 548
 549       HAVE_VIDEODEV=no
 550       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 551       [
 552         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 553       ])
 554
 555       if test "x$HAVE_VIDEODEV" = "xyes"; then
 556         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 557         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 558       else
 559         AC_MSG_WARN([video4linux2 was not found])
 560       fi
 561     ])
 562
 563   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 564     dnl check for missing v4l2_buffer declaration (see #135919)
 565     MISSING_DECL=0
 566     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 567     AC_TRY_COMPILE([
 568 #include <sys/types.h>
 569 #ifdef __sun /* Solaris */
 570 #include <sys/types.h>
 571 #include <sys/videodev2.h>
 572 #else /* Linux */
 573 #include <linux/types.h>
 574 #define _LINUX_TIME_H
 575 #define __user
 576 #include <linux/videodev2.h>
 577 #endif
 578     ],[
 579 struct v4l2_buffer buf;
 580 buf.index = 0;
 581 return 0;
 582     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 583     if [ test x$MISSING_DECL = x1 ]; then
 584       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 585     fi
 586
 587     dnl check for XOverlay libraries
 588     AG_GST_CHECK_XV
 589   fi
 590 ])
 591
 592 # Optional gudev for device probing
 593 AC_ARG_WITH([gudev],
 594   AC_HELP_STRING([--with-gudev],
 595     [device detection with gudev]),
 596   [],
 597   [with_gudev=check])
 598 if test x$HAVE_GST_V4L2 = xyes; then
 599   if test x$with_gudev != xno; then
 600       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 601           [ have_gudev=yes
 602             AC_DEFINE(HAVE_GUDEV, 1,
 603                [Whether gudev is available for device detection])
 604             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 605           ], [
 606           have_gudev=no
 607           ])
 608   else
 609     have_gudev=no
 610   fi
 611 fi
 612 AC_SUBST(GUDEV_CFLAGS)
 613 AC_SUBST(GUDEV_LIBS)
 614
 615 # Make libv4l2 non-automagic
 616 AC_ARG_WITH([libv4l2],
 617   AC_HELP_STRING([--with-libv4l2],
 618     [support video buffer conversion using libv4l2]),
 619   [],
 620   [with_libv4l2=check])
 621 if test x$HAVE_GST_V4L2 = xyes; then
 622   if test x$with_libv4l2 != xno; then
 623       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 624           [ have_libv4l2=yes
 625             AC_DEFINE(HAVE_LIBV4L2, 1,
 626                 [Whether libv4l2 is available for video buffer conversion])
 627           ], [
 628           have_libv4l2=no
 629           ])
 630   else
 631     have_libv4l2=no
 632   fi
 633 fi
 634
 635 dnl Check for X11
 636 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 637 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 638                   [ximagesrc], [
 639   AC_PATH_XTRA
 640
 641   dnl now try to find the HEADER
 642   ac_cflags_save="$CFLAGS"
 643   ac_cppflags_save="$CPPFLAGS"
 644   CFLAGS="$CFLAGS $X_CFLAGS"
 645   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 646   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 647
 648   if test "x$HAVE_X" = "xno"
 649   then
 650     AC_MSG_NOTICE([cannot find X11 development files])
 651   else
 652     dnl this is much more than we want
 653     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 654     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 655     dnl it does not add the libs; therefore we add them here
 656     X_LIBS="$X_LIBS -lX11"
 657     AC_SUBST(X_CFLAGS)
 658     AC_SUBST(X_LIBS)
 659
 660     dnl check for Xfixes
 661     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 662     if test "x$HAVE_XFIXES" = "xyes"
 663     then
 664         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 665     fi
 666     AC_SUBST(XFIXES_LIBS)
 667     AC_SUBST(XFIXES_CFLAGS)
 668
 669     dnl check for Xdamage
 670     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 671     if test "x$HAVE_XDAMAGE" = "xyes"
 672     then
 673         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 674     fi
 675     AC_SUBST(XDAMAGE_LIBS)
 676     AC_SUBST(XDAMAGE_CFLAGS)
 677   fi
 678   AC_SUBST(HAVE_X)
 679   CFLAGS="$ac_cflags_save"
 680   CPPFLAGS="$ac_cppflags_save"
 681 ])
 682
 683 dnl FIXME: this should be rolled into the test above, it's just an additional
 684 dnl feature of the ximagesrc plug-in
 685 dnl This is the same as in gst-plugins-base
 686 dnl check for X Shm
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 688 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 689   if test x$HAVE_X = xyes; then
 690     AC_CHECK_LIB(Xext, XShmAttach,
 691                  HAVE_XSHM="yes", HAVE_XSHM="no",
 692                  $X_LIBS)
 693     if test "x$HAVE_XSHM" = "xyes"; then
 694       XSHM_LIBS="-lXext"
 695     else
 696       dnl On AIX, it is in XextSam instead, but we still need -lXext
 697       AC_CHECK_LIB(XextSam, XShmAttach,
 698                    HAVE_XSHM="yes", HAVE_XSHM="no",
 699                    $X_LIBS)
 700       if test "x$HAVE_XSHM" = "xyes"; then
 701         XSHM_LIBS="-lXext -lXextSam"
 702       fi
 703     fi
 704   fi
 705 ], ,[
 706   AC_SUBST(HAVE_XSHM)
 707   AC_SUBST(XSHM_LIBS)
 708 ])
 709
 710 dnl for V4L2, we also need to know if we have XVIDEO
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 712 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 713                   [], [
 714   AG_GST_CHECK_XV
 715 ])
 716
 717 dnl *** ext plug-ins ***
 718 dnl keep this list sorted alphabetically !
 719
 720 if test "x$BUILD_EXTERNAL" = "xyes"; then
 721
 722 echo
 723 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 724 echo
 725
 726 dnl *** aalib ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 728 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 729   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 730   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 731 ])
 732
 733 dnl *** annodex ***
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 735 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 736   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 737 ])
 738
 739 dnl *** cairo ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 741 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 742   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 743 ])
 744
 745 dnl *** cairo-gobject ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 747 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 748   [Cairo graphics rendering gobject bindings], cairooverlay, [
 749   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 750 ])
 751
 752 dnl **** ESound ****
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 754 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 755   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 756   if test $HAVE_ESD = no
 757   then
 758     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 759     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 760   fi
 761 ])
 762
 763 dnl *** FLAC ***
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 765 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 766   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 767 ])
 768
 769 dnl *** GConf ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 771 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 772   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 773 ])
 774
 775 dnl *** GDK pixbuf ***
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 777 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 778   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 779 ])
 780
 781 dnl *** HAL ***
 782 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 783 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 784   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 785 ])
 786
 787 dnl *** Jack ***
 788 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 789 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 790   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 791   AC_SUBST(JACK_CFLAGS)
 792   AC_SUBST(JACK_LIBS)
 793
 794   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 795   if test x$HAVE_JACK_0_120_1 = xyes; then
 796     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 797   fi
 798   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 799   if test x$HAVE_JACK_1_9_7 = xyes; then
 800     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 801   fi
 802
 803 ])
 804
 805 dnl *** jpeg ***
 806 dnl FIXME: we could use header checks here as well IMO
 807 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 808 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 809   AC_ARG_WITH(jpeg-mmx,
 810     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 811   OLD_LIBS="$LIBS"
 812   if test x$with_jpeg_mmx != x; then
 813     LIBS="$LIBS -L$with_jpeg_mmx"
 814   fi
 815   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 816   JPEG_LIBS="$LIBS -ljpeg-mmx"
 817   LIBS="$OLD_LIBS"
 818   if test x$HAVE_JPEG != xyes; then
 819     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 820     JPEG_LIBS="-ljpeg"
 821   fi
 822   AC_SUBST(JPEG_LIBS)
 823 ])
 824
 825 dnl *** libcaca ***
 826 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 827 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 828   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 829 ])
 830
 831 dnl *** libdv ***
 832 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 833 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 834   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 835 ])
 836
 837 dnl *** libpng ***
 838 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 839 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 840   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 841 ])
 842
 843 dnl *** pulseaudio ***
 844 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 845 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 846
 847   dnl used in ext/pulse/pulseutil.c
 848   AC_CHECK_HEADERS([process.h])
 849
 850   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.16)
 851   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 852   if test x$HAVE_PULSE_0_9_20 = xyes; then
 853     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 854   fi
 855   AG_GST_PKG_CHECK_MODULES(PULSE_1_0, libpulse >= 0.98)
 856   if test x$HAVE_PULSE_1_0 = xyes; then
 857     AC_DEFINE(HAVE_PULSE_1_0, 1, [defined if pulseaudio >= 1.0 is available])
 858   fi
 859 ])
 860
 861 dnl *** dv1394 ***
 862 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 863 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 864   dnl first test for libraw1394 >= 2.0.0
 865   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 866   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 867   dnl now see how far we got
 868   if test x$HAVE_RAW1394 = xyes && \
 869      test x$HAVE_LIBIEC61883 = xyes; then
 870        AG_GST_CHECK_LIBHEADER(AVC1394,
 871         avc1394, avc1394_send_command, $RAW1394_LIBS,
 872         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 873        AG_GST_CHECK_LIBHEADER(ROM1394,
 874         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 875         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 876        if test x$HAVE_AVC1394 = xyes && \
 877           test x$HAVE_AVC1394 = xyes && \
 878           test x$HAVE_ROM1394 = xyes; then
 879           HAVE_DV1394=yes
 880           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 881           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 882           AC_SUBST(DV1394_CFLAGS)
 883           AC_SUBST(DV1394_LIBS)
 884         fi
 885   else
 886        if test x$HAVE_RAW1394 = xno; then
 887           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 888           AG_GST_CHECK_LIBHEADER(AVC1394,
 889            avc1394, avc1394_send_command, $RAW1394_LIBS,
 890            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 891           AG_GST_CHECK_LIBHEADER(ROM1394,
 892            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 893            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 894           if test x$HAVE_RAW1394 = xyes && \
 895              test x$HAVE_AVC1394 = xyes && \
 896              test x$HAVE_ROM1394 = xyes; then
 897              HAVE_DV1394=yes
 898              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 899              DV1394_CFLAGS="$RAW1394_CFLAGS"
 900              if test x$HAVE_LIBIEC61883 = xyes; then
 901                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 902                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 903              fi
 904              AC_SUBST(DV1394_CFLAGS)
 905              AC_SUBST(DV1394_LIBS)
 906            fi
 907          fi
 908   fi
 909 ])
 910 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 911
 912 dnl *** shout2 ***
 913 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 914 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 915   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 916 ])
 917
 918 dnl *** soup ***
 919 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 920 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 921   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 922     HAVE_SOUP="yes"
 923     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 924   ],[
 925     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 926       HAVE_SOUP="no"
 927     ])
 928   ])
 929   AC_SUBST(SOUP_CFLAGS)
 930   AC_SUBST(SOUP_LIBS)
 931 ])
 932
 933 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 934 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 935 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 936 dnl   speex_jitter.h is 1.1.x only
 937 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 938 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 939   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 940   if test $HAVE_SPEEX = no
 941   then
 942     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 943       AC_CHECK_HEADER(speex/speex_jitter.h, [
 944         dnl speex 1.1.x :
 945         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 946           dnl speex 1.1.5 or + :
 947           HAVE_SPEEX="yes"
 948           SPEEX_LIBS="-lspeex"
 949           AC_SUBST(SPEEX_CFLAGS)
 950           AC_SUBST(SPEEX_LIBS)
 951         ],[
 952           HAVE_SPEEX="no"
 953         ])
 954       ],[
 955         dnl speex 1.0.x :
 956           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 957             dnl speex 1.0.4
 958             HAVE_SPEEX="yes"
 959             SPEEX_LIBS="-lspeex"
 960             AC_SUBST(SPEEX_CFLAGS)
 961             AC_SUBST(SPEEX_LIBS)
 962
 963             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 964               [defined if speex 1.0.x API detected])
 965         ],[
 966             HAVE_SPEEX="no"
 967             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 968         ], [
 969 #include <speex/speex.h>
 970         ])
 971       ])
 972     ])
 973   fi
 974 ])
 975
 976 dnl *** taglib ***
 977 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 978 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 979   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 980   if test "x$HAVE_CXX" != "xyes"; then
 981     USE_TAGLIB=false
 982     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 983   else
 984     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 985     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 986         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 987       ], [
 988         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 989     ])
 990     AC_SUBST(TAGLIB_CXXFLAGS)
 991   fi
 992 ])
 993
 994 dnl *** wavpack ***
 995 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 996 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 997   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 998     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 999       HAVE_WAVPACK=yes
1000       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
1001     ],[
1002       HAVE_WAVPACK=no
1003     ])
1004   ])
1005   AC_SUBST(WAVPACK_CFLAGS)
1006   AC_SUBST(WAVPACK_LIBS)
1007 ])
1008
1009 dnl *** qtdemux & matroska prefer to have zlib ***
1010 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
1011 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
1012   AG_GST_CHECK_LIBHEADER(ZLIB,
1013     z, uncompress,, zlib.h, [
1014     HAVE_ZLIB="yes"
1015     ZLIB_LIBS="-lz"
1016     AC_SUBST(ZLIB_LIBS)
1017   ])
1018 ])
1019
1020 dnl *** matroska prefers to have bz2 ***
1021 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1022 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1023   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
1024   AC_SUBST(BZ2_LIBS)
1025 ])
1026
1027 else
1028
1029 dnl not building plugins with external dependencies,
1030 dnl but we still need to set the conditionals
1031 AM_CONDITIONAL(USE_AALIB, false)
1032 AM_CONDITIONAL(USE_ANNODEX, false)
1033 AM_CONDITIONAL(USE_BZ2, false)
1034 AM_CONDITIONAL(USE_CAIRO, false)
1035 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1036 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1037 AM_CONDITIONAL(USE_DV1394, false)
1038 AM_CONDITIONAL(USE_ESD, false)
1039 AM_CONDITIONAL(USE_FLAC, false)
1040 AM_CONDITIONAL(USE_GCONF, false)
1041 AM_CONDITIONAL(USE_GCONFTOOL, false)
1042 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1043 AM_CONDITIONAL(USE_GST_V4L2, false)
1044 AM_CONDITIONAL(USE_HAL, false)
1045 AM_CONDITIONAL(USE_JACK, false)
1046 AM_CONDITIONAL(USE_JPEG, false)
1047 AM_CONDITIONAL(USE_LIBCACA, false)
1048 AM_CONDITIONAL(USE_LIBDV, false)
1049 AM_CONDITIONAL(USE_LIBIEC61883, false)
1050 AM_CONDITIONAL(USE_LIBPNG, false)
1051 AM_CONDITIONAL(USE_OSS, false)
1052 AM_CONDITIONAL(USE_OSS4, false)
1053 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1054 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1055 AM_CONDITIONAL(USE_PULSE, false)
1056 AM_CONDITIONAL(USE_SHOUT2, false)
1057 AM_CONDITIONAL(USE_SOUP, false)
1058 AM_CONDITIONAL(USE_SPEEX, false)
1059 AM_CONDITIONAL(USE_SUNAUDIO, false)
1060 AM_CONDITIONAL(USE_TAGLIB, false)
1061 AM_CONDITIONAL(USE_WAVPACK, false)
1062 AM_CONDITIONAL(USE_X, false)
1063 AM_CONDITIONAL(USE_XSHM, false)
1064 AM_CONDITIONAL(USE_XVIDEO, false)
1065 AM_CONDITIONAL(USE_ZLIB, false)
1066
1067 fi dnl of EXT plugins
1068
1069 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1070
1071 dnl Overview:
1072 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1073 dnl GST_*:              flags shared by all built objects
1074 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1075 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1076 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1077 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1078
1079 dnl GST_OPTION_CFLAGS
1080 if test "x$USE_DEBUG" = xyes; then
1081    PROFILE_CFLAGS="-g"
1082 fi
1083 AC_SUBST(PROFILE_CFLAGS)
1084
1085 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1086   dnl Define _only_ for git (not pre-releases or releases)
1087   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1088 else
1089   DEPRECATED_CFLAGS=""
1090 fi
1091 AC_SUBST(DEPRECATED_CFLAGS)
1092
1093 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1094 dnl at make time with e.g. make ERROR_CFLAGS=""
1095 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1096 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1097 AC_SUBST(GST_OPTION_CFLAGS)
1098 AC_SUBST(GST_OPTION_CXXFLAGS)
1099
1100 dnl our libraries need to be versioned correctly
1101 AC_SUBST(GST_LT_LDFLAGS)
1102
1103 dnl FIXME: do we want to rename to GST_ALL_* ?
1104 dnl prefer internal headers to already installed ones
1105 dnl also add builddir include for enumtypes and marshal
1106 dnl add ERROR_CFLAGS, but overridable
1107 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1108 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1109 AC_SUBST(GST_CFLAGS)
1110 AC_SUBST(GST_CXXFLAGS)
1111 AC_SUBST(GST_LIBS)
1112
1113 dnl LDFLAGS really should only contain flags, not libs - they get added before
1114 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1115 GST_ALL_LDFLAGS="-no-undefined"
1116 AC_SUBST(GST_ALL_LDFLAGS)
1117
1118 dnl this really should only contain flags, not libs - they get added before
1119 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1120 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1121 AC_SUBST(GST_PLUGIN_LDFLAGS)
1122
1123 dnl *** output files ***
1124
1125 dnl keep this alphabetic per directory, please
1126 AC_CONFIG_FILES(
1127 Makefile
1128 gst/Makefile
1129 gst/alpha/Makefile
1130 gst/apetag/Makefile
1131 gst/audiofx/Makefile
1132 gst/audioparsers/Makefile
1133 gst/auparse/Makefile
1134 gst/autodetect/Makefile
1135 gst/avi/Makefile
1136 gst/cutter/Makefile
1137 gst/deinterlace/Makefile
1138 gst/debugutils/Makefile
1139 gst/effectv/Makefile
1140 gst/equalizer/Makefile
1141 gst/flv/Makefile
1142 gst/goom/Makefile
1143 gst/goom2k1/Makefile
1144 gst/id3demux/Makefile
1145 gst/icydemux/Makefile
1146 gst/imagefreeze/Makefile
1147 gst/interleave/Makefile
1148 gst/isomp4/Makefile
1149 gst/law/Makefile
1150 gst/level/Makefile
1151 gst/matroska/Makefile
1152 gst/monoscope/Makefile
1153 gst/multifile/Makefile
1154 gst/multipart/Makefile
1155 gst/replaygain/Makefile
1156 gst/rtp/Makefile
1157 gst/rtpmanager/Makefile
1158 gst/rtsp/Makefile
1159 gst/shapewipe/Makefile
1160 gst/smpte/Makefile
1161 gst/spectrum/Makefile
1162 gst/udp/Makefile
1163 gst/videobox/Makefile
1164 gst/videocrop/Makefile
1165 gst/videofilter/Makefile
1166 gst/videomixer/Makefile
1167 gst/wavenc/Makefile
1168 gst/wavparse/Makefile
1169 gst/flx/Makefile
1170 gst/y4m/Makefile
1171 ext/Makefile
1172 ext/aalib/Makefile
1173 ext/annodex/Makefile
1174 ext/cairo/Makefile
1175 ext/dv/Makefile
1176 ext/esd/Makefile
1177 ext/flac/Makefile
1178 ext/gconf/Makefile
1179 ext/gdk_pixbuf/Makefile
1180 ext/hal/Makefile
1181 ext/jack/Makefile
1182 ext/jpeg/Makefile
1183 ext/libcaca/Makefile
1184 ext/libpng/Makefile
1185 ext/pulse/Makefile
1186 ext/raw1394/Makefile
1187 ext/shout2/Makefile
1188 ext/soup/Makefile
1189 ext/speex/Makefile
1190 ext/taglib/Makefile
1191 ext/wavpack/Makefile
1192 sys/Makefile
1193 sys/directsound/Makefile
1194 sys/oss/Makefile
1195 sys/oss4/Makefile
1196 sys/osxaudio/Makefile
1197 sys/osxvideo/Makefile
1198 sys/sunaudio/Makefile
1199 sys/v4l2/Makefile
1200 sys/waveform/Makefile
1201 sys/ximage/Makefile
1202 po/Makefile.in
1203 tests/Makefile
1204 tests/check/Makefile
1205 tests/examples/Makefile
1206 tests/examples/audiofx/Makefile
1207 tests/examples/cairo/Makefile
1208 tests/examples/equalizer/Makefile
1209 tests/examples/jack/Makefile
1210 tests/examples/level/Makefile
1211 tests/examples/pulse/Makefile
1212 tests/examples/rtp/Makefile
1213 tests/examples/shapewipe/Makefile
1214 tests/examples/spectrum/Makefile
1215 tests/examples/v4l2/Makefile
1216 tests/files/Makefile
1217 tests/icles/Makefile
1218 gconf/Makefile
1219 gconf/gstreamer.schemas
1220 common/Makefile
1221 common/m4/Makefile
1222 m4/Makefile
1223 docs/Makefile
1224 docs/plugins/Makefile
1225 docs/version.entities
1226 pkgconfig/Makefile
1227 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1228 gst-plugins-good.spec
1229 )
1230
1231 dnl Create the config.h file for Visual Studio builds
1232 dnl Beware of spaces and /'s in some of the shell variable contents.
1233 sed \
1234     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1235     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1236     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1237     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1238     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1239     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1240     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1241     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1242     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1243     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1244     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1245     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1246     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1247     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1248     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1249     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1250     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1251     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1252     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1253     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1254     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1255     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1256     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1257     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1258     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1259     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1260     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1261     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1262     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1263     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1264     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1265     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1266     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1267     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1268     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1269     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1270     config.h.in >win32/common/config.h-new
1271
1272 AC_OUTPUT
1273
1274 AG_GST_OUTPUT_PLUGINS
1275 ORC_OUTPUT
1276